qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(accuracy_frags);
   4
   5 float weaponstats_buffer;
   6
   7 void WeaponStats_Init()
   8 {
   9         if(autocvar_sv_weaponstats_file != "")
  10                 weaponstats_buffer = buf_create();
  11         else
  12                 weaponstats_buffer = -1;
  13 }
  14
  15 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  16
  17 void WeaponStats_Shutdown()
  18 {
  19         float i, j, ibot, jbot, idx;
  20         float fh;
  21         vector v;
  22         string prefix;
  23         if(weaponstats_buffer < 0)
  24                 return;
  25         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26         if(autocvar_sv_weaponstats_file != "")
  27         {
  28                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  29                 if(fh >= 0)
  30                 {
  31                         fputs(fh, "#begin statsfile\n");
  32                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  33                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  34                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  35                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  36                                 {
  37                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  38                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  39                                         if(v != '0 0 0')
  40                                         {
  41                                                 //vector is: kills hits damage
  42                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  43                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  44                                         }
  45                                 }
  46                         fputs(fh, "#end\n\n");
  47                         fclose(fh);
  48                         print("Weapon stats written\n");
  49                 }
  50         }
  51         buf_del(weaponstats_buffer);
  52         weaponstats_buffer = -1;
  53 }
  54
  55 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  56 {
  57         float idx;
  58         if(weaponstats_buffer < 0)
  59                 return;
  60         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  61                 return;
  62         if(awep > WEP_LAST || vwep > WEP_LAST)
  63                 return;
  64         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  65         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  66 }
  67 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  68 {
  69         if(damage < 0)
  70                 error("negative damage?");
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  72 }
  73 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  74 {
  75         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  76 }
  77
  78 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  79 // merged player_run and player_stand to player_anim
  80 // added death animations to player_anim
  81 // can now spawn thrown weapons from anywhere, not just from players
  82 // thrown weapons now fade out after 20 seconds
  83 // created PlayerGib function
  84 // PlayerDie no longer uses hitloc or damage
  85 // PlayerDie now supports dying animations as well as gibbing
  86 // cleaned up PlayerDie a lot
  87 // added CopyBody
  88
  89 .entity pusher;
  90 .float pushltime;
  91
  92 void CopyBody(float keepvelocity)
  93 {
  94         local entity oldself;
  95         if (self.effects & EF_NODRAW)
  96                 return;
  97         oldself = self;
  98         self = spawn();
  99         self.enemy = oldself;
 100         self.lip = oldself.lip;
 101         self.colormap = oldself.colormap;
 102         self.glowmod = oldself.glowmod;
 103         self.iscreature = oldself.iscreature;
 104         self.angles = oldself.angles;
 105         self.avelocity = oldself.avelocity;
 106         self.classname = "body";
 107         self.damageforcescale = oldself.damageforcescale;
 108         self.effects = oldself.effects;
 109         self.event_damage = oldself.event_damage;
 110         self.animstate_startframe = oldself.animstate_startframe;
 111         self.animstate_numframes = oldself.animstate_numframes;
 112         self.animstate_framerate = oldself.animstate_framerate;
 113         self.animstate_starttime = oldself.animstate_starttime;
 114         self.animstate_endtime = oldself.animstate_endtime;
 115         self.animstate_override = oldself.animstate_override;
 116         self.animstate_looping = oldself.animstate_looping;
 117         self.frame = oldself.frame;
 118         self.dead_frame = oldself.dead_frame;
 119         self.pain_finished = oldself.pain_finished;
 120         self.health = oldself.health;
 121         self.armorvalue = oldself.armorvalue;
 122         self.armortype = oldself.armortype;
 123         self.model = oldself.model;
 124         self.modelindex = oldself.modelindex;
 125         self.modelindex_lod0 = oldself.modelindex_lod0;
 126         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 127         self.modelindex_lod1 = oldself.modelindex_lod1;
 128         self.modelindex_lod2 = oldself.modelindex_lod2;
 129         self.skinindex = oldself.skinindex;
 130         self.species = oldself.species;
 131         self.movetype = oldself.movetype;
 132         self.nextthink = oldself.nextthink;
 133         self.solid = oldself.solid;
 134         self.ballistics_density = oldself.ballistics_density;
 135         self.takedamage = oldself.takedamage;
 136         self.think = oldself.think;
 137         self.customizeentityforclient = oldself.customizeentityforclient;
 138         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 139         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 140         if (keepvelocity == 1)
 141                 self.velocity = oldself.velocity;
 142         self.oldvelocity = self.velocity;
 143         self.fade_time = oldself.fade_time;
 144         self.fade_rate = oldself.fade_rate;
 145         //self.weapon = oldself.weapon;
 146         setorigin(self, oldself.origin);
 147         setsize(self, oldself.mins, oldself.maxs);
 148         self.prevorigin = oldself.origin;
 149         self.reset = SUB_Remove;
 150
 151         Drag_MoveDrag(oldself, self);
 152
 153         self = oldself;
 154 }
 155
 156 float player_getspecies()
 157 {
 158         float s;
 159         get_model_parameters(self.model, self.skinindex);
 160         s = get_model_parameters_species;
 161         get_model_parameters(string_null, 0);
 162         if(s < 0)
 163                 return SPECIES_HUMAN;
 164         return s;
 165 }
 166
 167 void player_setupanimsformodel()
 168 {
 169         local string animfilename;
 170         local float animfile;
 171         // defaults for legacy .zym models without animinfo files
 172         self.anim_die1 = '0 1 0.5'; // 2 seconds
 173         self.anim_die2 = '1 1 0.5'; // 2 seconds
 174         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 175         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 176         self.anim_duckwalk = '4 1 1';
 177         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 178         self.anim_duckidle = '6 1 1';
 179         self.anim_idle = '7 1 1';
 180         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 181         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 182         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 183         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 184         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 185         self.anim_run = '13 1 1';
 186         self.anim_runbackwards = '14 1 1';
 187         self.anim_strafeleft = '15 1 1';
 188         self.anim_straferight = '16 1 1';
 189         self.anim_dead1 = '17 1 1';
 190         self.anim_dead2 = '18 1 1';
 191         self.anim_forwardright = '19 1 1';
 192         self.anim_forwardleft = '20 1 1';
 193         self.anim_backright = '21 1 1';
 194         self.anim_backleft  = '22 1 1';
 195         self.anim_melee = '23 1 1';
 196         self.anim_fly = '24 1 1';
 197         animparseerror = FALSE;
 198         animfilename = strcat(self.model, ".animinfo");
 199         animfile = fopen(animfilename, FILE_READ);
 200         if (animfile >= 0)
 201         {
 202                 self.anim_die1         = animparseline(animfile);
 203                 self.anim_die2         = animparseline(animfile);
 204                 self.anim_draw         = animparseline(animfile);
 205                 self.anim_duck         = animparseline(animfile);
 206                 self.anim_duckwalk     = animparseline(animfile);
 207                 self.anim_duckjump     = animparseline(animfile);
 208                 self.anim_duckidle     = animparseline(animfile);
 209                 self.anim_idle         = animparseline(animfile);
 210                 self.anim_jump         = animparseline(animfile);
 211                 self.anim_pain1        = animparseline(animfile);
 212                 self.anim_pain2        = animparseline(animfile);
 213                 self.anim_shoot        = animparseline(animfile);
 214                 self.anim_taunt        = animparseline(animfile);
 215                 self.anim_run          = animparseline(animfile);
 216                 self.anim_runbackwards = animparseline(animfile);
 217                 self.anim_strafeleft   = animparseline(animfile);
 218                 self.anim_straferight  = animparseline(animfile);
 219                 self.anim_forwardright = animparseline(animfile);
 220                 self.anim_forwardleft  = animparseline(animfile);
 221                 self.anim_backright    = animparseline(animfile);
 222                 self.anim_backleft     = animparseline(animfile);
 223                 self.anim_melee        = animparseline(animfile);
 224                 self.anim_fly          = animparseline(animfile);
 225                 fclose(animfile);
 226
 227                 // derived anims
 228                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 229                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 230
 231                 if (animparseerror)
 232                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 233         }
 234         else
 235                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 236         // reset animstate now
 237         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 238 };
 239
 240 void player_anim (void)
 241 {
 242         updateanim(self);
 243         if (self.weaponentity)
 244                 updateanim(self.weaponentity);
 245
 246         if (self.deadflag != DEAD_NO)
 247         {
 248                 if (time > self.animstate_endtime)
 249                 {
 250                         if (self.maxs_z > 5)
 251                         {
 252                                 self.maxs_z = 5;
 253                                 setsize(self, self.mins, self.maxs);
 254                         }
 255                         self.frame = self.dead_frame;
 256                 }
 257                 return;
 258         }
 259
 260         if (!self.animstate_override)
 261         {
 262                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 263                 {
 264                         if (self.crouch)
 265                         {
 266                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 267                                 {
 268                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 269                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 270                                         {
 271                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 272                                                 self.restart_jump = FALSE;
 273                                         }
 274                                 }
 275                         }
 276                         else
 277                         {
 278                                 // 21/25 is the magic number here for how long the jump animation takes to play once (numframes/framerate)
 279                                 if((self.animstate_startframe == self.anim_jump_x && time - self.animstate_starttime >= 21/25))
 280                                         setanim(self, self.anim_fly, TRUE, FALSE, FALSE);
 281
 282                                 if(self.animstate_startframe != self.anim_fly_x) // no tracing if we're in the fly anim
 283                                 {
 284                                         if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 285                                         {
 286                                                 traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 287                                                 if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x) // don't get stuck on idle animation in midair
 288                                                 {
 289                                                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 290                                                         self.restart_jump = FALSE;
 291                                                 }
 292                                         }
 293                                 }
 294                         }
 295                 }
 296                 else if (self.crouch)
 297                 {
 298                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 299                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 300                         else
 301                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 302                 }
 303                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 304                 {
 305                         if (self.movement_x > 0 && self.movement_y == 0)
 306                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x < 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x == 0 && self.movement_y > 0)
 310                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y < 0)
 312                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x > 0 && self.movement_y > 0)
 314                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y < 0)
 316                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x < 0 && self.movement_y > 0)
 318                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y < 0)
 320                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 321                         else
 322                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 323                 }
 324                 else
 325                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 326                 print(ftos(time), " ", ftos(self.animstate_startframe), "\n");
 327         }
 328
 329         if (self.weaponentity)
 330         if (!self.weaponentity.animstate_override)
 331                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 332 }
 333
 334 void SpawnThrownWeapon (vector org, float w)
 335 {
 336         if(g_minstagib)
 337         if(self.ammo_cells <= 0)
 338                 return;
 339
 340         if(g_pinata)
 341         {
 342                 float j;
 343                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 344                 {
 345                         if(self.weapons & W_WeaponBit(j))
 346                                 if(W_IsWeaponThrowable(j))
 347                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 348                 }
 349         }
 350         else
 351         {
 352                 if(W_IsWeaponThrowable(self.weapon))
 353                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 354         }
 355 }
 356
 357 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 358 {
 359         local float take, save;
 360         vector v;
 361         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 362
 363         // damage resistance (ignore most of the damage from a bullet or similar)
 364         damage = max(damage - 5, 1);
 365
 366         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 367         take = v_x;
 368         save = v_y;
 369
 370         if(sound_allowed(MSG_BROADCAST, attacker))
 371         {
 372                 if (save > 10)
 373                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 374                 else if (take > 30)
 375                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 376                 else if (take > 10)
 377                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 378         }
 379
 380         if (take > 50)
 381                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 382         if (take > 100)
 383                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 384
 385         if (!(self.flags & FL_GODMODE))
 386         {
 387                 self.armorvalue = self.armorvalue - save;
 388                 self.health = self.health - take;
 389                 // pause regeneration for 5 seconds
 390                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 391         }
 392         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 393         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 394         self.dmg_inflictor = inflictor;
 395
 396         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 397         {
 398                 // don't use any animations as a gib
 399                 self.frame = 0;
 400                 self.dead_frame = 0;
 401                 // view just above the floor
 402                 self.view_ofs = '0 0 4';
 403
 404                 Violence_GibSplash(self, 1, 1, attacker);
 405                 self.modelindex = 0; // restore later
 406                 self.solid = SOLID_NOT; // restore later
 407         }
 408 }
 409
 410 void ClientKill_Now_TeamChange();
 411 void freezetag_CheckWinner();
 412
 413 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 414 {
 415         local float take, save, waves, sdelay, dh, da, j;
 416         vector v;
 417         float valid_damage_for_weaponstats;
 418         float excess;
 419
 420         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 421                 return;
 422
 423         dh = max(self.health, 0);
 424         da = max(self.armorvalue, 0);
 425
 426         if(!DEATH_ISSPECIAL(deathtype))
 427         {
 428                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 429                 if(self != attacker)
 430                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 431         }
 432
 433         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 434         {
 435                 // tuba causes blood to come out of the ears
 436                 vector ear1, ear2;
 437                 vector d;
 438                 float f;
 439                 ear1 = self.origin;
 440                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 441                 ear2 = ear1;
 442                 makevectors(self.angles);
 443                 ear1 += v_right * -10;
 444                 ear2 += v_right * +10;
 445                 d = inflictor.origin - self.origin;
 446                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 447                 force = v_right * vlen(force);
 448                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 449                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 450                 if(f > 0)
 451                 {
 452                         hitloc = ear1;
 453                         force = force * -1;
 454                 }
 455                 else
 456                 {
 457                         hitloc = ear2;
 458                         // force is already good
 459                 }
 460         }
 461         else
 462                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 463
 464         if (!g_minstagib)
 465         {
 466                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 467                 take = v_x;
 468                 save = v_y;
 469         }
 470         else
 471         {
 472                 save = 0;
 473                 take = damage;
 474         }
 475
 476         frag_inflictor = inflictor;
 477         frag_attacker = attacker;
 478         frag_target = self;
 479         damage_take = take;
 480         damage_save = save;
 481         damage_force = force;
 482         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 483         take = bound(0, damage_take, self.health);
 484         save = bound(0, damage_save, self.armorvalue);
 485         excess = max(0, damage - take - save);
 486
 487         if(sound_allowed(MSG_BROADCAST, attacker))
 488         {
 489                 if (save > 10)
 490                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 491                 else if (take > 30)
 492                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 493                 else if (take > 10)
 494                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 495         }
 496
 497         if (take > 50)
 498                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 499         if (take > 100)
 500                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 501
 502         if (time >= self.spawnshieldtime)
 503         {
 504                 if (!(self.flags & FL_GODMODE))
 505                 {
 506                         self.armorvalue = self.armorvalue - save;
 507                         self.health = self.health - take;
 508                         // pause regeneration for 5 seconds
 509                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 510
 511                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 512                         {
 513                                 self.pain_finished = time + 0.5;        //Supajoe
 514
 515                                 if(sv_gentle < 1) {
 516                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 517                                         {
 518                                                 if (!self.animstate_override)
 519                                                 {
 520                                                         if (random() > 0.5)
 521                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 522                                                         else
 523                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 524                                                 }
 525                                         }
 526
 527                                         if(sound_allowed(MSG_BROADCAST, attacker))
 528                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 529                                         if(self.health > 1)
 530                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 531                                         {
 532                                                 if(deathtype == DEATH_FALL)
 533                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 534                                                 else if(self.health > 75) // TODO make a "gentle" version?
 535                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 536                                                 else if(self.health > 50)
 537                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 538                                                 else if(self.health > 25)
 539                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 540                                                 else
 541                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 542                                         }
 543                                 }
 544
 545                                 // throw off bot aim temporarily
 546                                 local float shake;
 547                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 548                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 549                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 550                         }
 551                 }
 552                 else
 553                         self.max_armorvalue += (save + take);
 554         }
 555         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 556         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 557         self.dmg_inflictor = inflictor;
 558
 559         if(attacker == self)
 560         {
 561                 // don't reset pushltime for self damage as it may be an attempt to
 562                 // escape a lava pit or similar
 563                 //self.pushltime = 0;
 564         }
 565         else if(attacker.classname == "player" || attacker.classname == "gib")
 566         {
 567                 self.pusher = attacker;
 568                 self.pushltime = time + autocvar_g_maxpushtime;
 569         }
 570         else if(time < self.pushltime)
 571         {
 572                 attacker = self.pusher;
 573                 self.pushltime = max(self.pushltime, time + 0.6);
 574         }
 575         else
 576                 self.pushltime = 0;
 577
 578         float abot, vbot, awep;
 579         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 580         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 581
 582         valid_damage_for_weaponstats = 0;
 583         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 584         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 585         if(attacker && self != attacker)
 586         if(IsDifferentTeam(self, attacker))
 587         {
 588                 if(DEATH_ISSPECIAL(deathtype))
 589                         awep = attacker.weapon;
 590                 else
 591                         awep = DEATH_WEAPONOF(deathtype);
 592                 valid_damage_for_weaponstats = 1;
 593         }
 594
 595         if(valid_damage_for_weaponstats)
 596         {
 597                 dh = dh - max(self.health, 0);
 598                 da = da - max(self.armorvalue, 0);
 599                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 600         }
 601
 602         if (self.health < 1)
 603         {
 604                 float defer_ClientKill_Now_TeamChange;
 605                 defer_ClientKill_Now_TeamChange = FALSE;
 606
 607                 if(self.alivetime)
 608                 {
 609                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 610                         self.alivetime = 0;
 611                 }
 612
 613                 if(valid_damage_for_weaponstats)
 614                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 615
 616                 if(sv_gentle < 1) // TODO make a "gentle" version?
 617                 if(sound_allowed(MSG_BROADCAST, attacker))
 618                 {
 619                         if(deathtype == DEATH_DROWN)
 620                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 621                         else
 622                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 623                 }
 624
 625                 // get rid of kill indicator
 626                 if(self.killindicator)
 627                 {
 628                         remove(self.killindicator);
 629                         self.killindicator = world;
 630                         if(self.killindicator_teamchange)
 631                                 defer_ClientKill_Now_TeamChange = TRUE;
 632
 633                         if(self.classname == "body")
 634                         if(deathtype == DEATH_KILL)
 635                         {
 636                                 // for the lemmings fans, a small harmless explosion
 637                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 638                         }
 639                 }
 640
 641                 if(!g_freezetag)
 642                 {
 643                         // become fully visible
 644                         self.alpha = 1;
 645                         // throw a weapon
 646                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 647                 }
 648
 649                 // print an obituary message
 650                 Obituary (attacker, inflictor, self, deathtype);
 651                 race_PreDie();
 652                 DropAllRunes(self);
 653
 654         // increment frag counter for used weapon type
 655         float w;
 656         w = DEATH_WEAPONOF(deathtype);
 657         if(WEP_VALID(w))
 658         if(self.classname == "player")
 659         if(self != attacker)
 660         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 661
 662                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 663                 {
 664                         PutClientInServer();
 665                         count_alive_players(); // re-count players
 666                         freezetag_CheckWinner();
 667                         return;
 668                 }
 669
 670                 frag_attacker = attacker;
 671                 frag_inflictor = inflictor;
 672                 frag_target = self;
 673                 MUTATOR_CALLHOOK(PlayerDies);
 674                 weapon_action(self.weapon, WR_PLAYERDEATH);
 675
 676                 if(self.flagcarried)
 677                 {
 678                         if(attacker.classname != "player" && attacker.classname != "gib")
 679                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 680                         else if(attacker.team == self.team)
 681                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 682                         else
 683                                 DropFlag(self.flagcarried, world, attacker);
 684                 }
 685                 if(self.ballcarried && g_nexball)
 686                         DropBall(self.ballcarried, self.origin, self.velocity);
 687                 Portal_ClearAllLater(self);
 688
 689                 if(clienttype(self) == CLIENTTYPE_REAL)
 690                 {
 691                         stuffcmd(self, "-zoom\n");
 692                         self.fixangle = TRUE;
 693                         //msg_entity = self;
 694                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 695                         //WriteAngle (MSG_ONE, self.v_angle_x);
 696                         //WriteAngle (MSG_ONE, self.v_angle_y);
 697                         //WriteAngle (MSG_ONE, 80);
 698                 }
 699
 700                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 701                         ClientKill_Now_TeamChange();
 702
 703                 if(g_arena)
 704                         Spawnqueue_Unmark(self);
 705
 706                 if(g_freezetag)
 707                         return;
 708
 709                 // when we get here, player actually dies
 710                 // clear waypoints (do this AFTER FreezeTag)
 711                 WaypointSprite_PlayerDead();
 712
 713                 // make the corpse upright (not tilted)
 714                 self.angles_x = 0;
 715                 self.angles_z = 0;
 716                 // don't spin
 717                 self.avelocity = '0 0 0';
 718                 // view from the floor
 719                 self.view_ofs = '0 0 -8';
 720                 // toss the corpse
 721                 self.movetype = MOVETYPE_TOSS;
 722                 // shootable corpse
 723                 self.solid = SOLID_CORPSE;
 724                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 725                 // don't stick to the floor
 726                 self.flags &~= FL_ONGROUND;
 727                 // dying animation
 728                 self.deadflag = DEAD_DYING;
 729                 // when to allow respawn
 730                 sdelay = 0;
 731                 waves = 0;
 732                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 733                 if(!sdelay)
 734                 {
 735                         if(g_cts)
 736                                 sdelay = 0; // no respawn delay in CTS
 737                         else
 738                                 sdelay = autocvar_g_respawn_delay;
 739                 }
 740                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 741                 if(!waves)
 742                         waves = autocvar_g_respawn_waves;
 743                 if(waves)
 744                         self.death_time = ceil((time + sdelay) / waves) * waves;
 745                 else
 746                         self.death_time = time + sdelay;
 747                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 748                         self.respawn_countdown = 10; // first number to count down from is 10
 749                 else
 750                         self.respawn_countdown = -1; // do not count down
 751                 if (random() < 0.5)
 752                 {
 753                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 754                         self.dead_frame = self.anim_dead1_x;
 755                 }
 756                 else
 757                 {
 758                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 759                         self.dead_frame = self.anim_dead2_x;
 760                 }
 761                 // set damage function to corpse damage
 762                 self.event_damage = PlayerCorpseDamage;
 763                 // call the corpse damage function just in case it wants to gib
 764                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 765                 // set up to fade out later
 766                 SUB_SetFade (self, time + 6 + random (), 1);
 767
 768                 if(sv_gentle > 0 || autocvar_ekg) {
 769                         // remove corpse
 770                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 771                 }
 772
 773                 // reset fields the weapons may use just in case
 774                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 775                 {
 776                         weapon_action(j, WR_RESETPLAYER);
 777                         ATTACK_FINISHED_FOR(self, j) = 0;
 778                 }
 779         }
 780 }
 781
 782 .float muted; // to be used by prvm_edictset server playernumber muted 1
 783 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 784 // message "": do not say, just test flood control
 785 // return value:
 786 //   1 = accept
 787 //   0 = reject
 788 //  -1 = fake accept
 789 {
 790         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 791         float flood, privatemsgprefixlen;
 792         var .float flood_field;
 793         entity head;
 794         float ret;
 795
 796         if(Ban_MaybeEnforceBan(source))
 797                 return 0;
 798
 799         if(!teamsay && !privatesay)
 800                 if(substring(msgin, 0, 1) == " ")
 801                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 802
 803         msgin = formatmessage(msgin);
 804
 805         if(source.classname != "player")
 806                 colorstr = "^0"; // black for spectators
 807         else if(teams_matter)
 808                 colorstr = Team_ColorCode(source.team);
 809         else
 810                 teamsay = FALSE;
 811
 812         if(intermission_running)
 813                 teamsay = FALSE;
 814
 815         if(msgin != "")
 816                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 817
 818         /*
 819          * using bprint solves this... me stupid
 820         // how can we prevent the message from appearing in a listen server?
 821         // for now, just give "say" back and only handle say_team
 822         if(!teamsay)
 823         {
 824                 clientcommand(self, strcat("say ", msgin));
 825                 return;
 826         }
 827         */
 828
 829         if(autocvar_g_chat_teamcolors)
 830                 namestr = playername(source);
 831         else
 832                 namestr = source.netname;
 833
 834         if(msgin != "")
 835         {
 836                 if(privatesay)
 837                 {
 838                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 839                         privatemsgprefixlen = strlen(msgstr);
 840                         msgstr = strcat(msgstr, msgin);
 841                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 842                         if(autocvar_g_chat_teamcolors)
 843                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 844                         else
 845                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 846                 }
 847                 else if(teamsay)
 848                 {
 849                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 850                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 851                 }
 852                 else
 853                 {
 854                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 855                         cmsgstr = "";
 856                 }
 857                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 858         }
 859         else
 860         {
 861                 msgstr = cmsgstr = "";
 862         }
 863
 864         fullmsgstr = msgstr;
 865         fullcmsgstr = cmsgstr;
 866
 867         // FLOOD CONTROL
 868         flood = 0;
 869         if(floodcontrol)
 870         {
 871                 float flood_spl;
 872                 float flood_burst;
 873                 float flood_lmax;
 874                 float lines;
 875                 if(privatesay)
 876                 {
 877                         flood_spl = autocvar_g_chat_flood_spl_tell;
 878                         flood_burst = autocvar_g_chat_flood_burst_tell;
 879                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 880                         flood_field = floodcontrol_chattell;
 881                 }
 882                 else if(teamsay)
 883                 {
 884                         flood_spl = autocvar_g_chat_flood_spl_team;
 885                         flood_burst = autocvar_g_chat_flood_burst_team;
 886                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 887                         flood_field = floodcontrol_chatteam;
 888                 }
 889                 else
 890                 {
 891                         flood_spl = autocvar_g_chat_flood_spl;
 892                         flood_burst = autocvar_g_chat_flood_burst;
 893                         flood_lmax = autocvar_g_chat_flood_lmax;
 894                         flood_field = floodcontrol_chat;
 895                 }
 896                 flood_burst = max(0, flood_burst - 1);
 897                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 898
 899                 // do flood control for the default line size
 900                 if(msgstr != "")
 901                 {
 902                         getWrappedLine_remaining = msgstr;
 903                         msgstr = "";
 904                         lines = 0;
 905                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 906                         {
 907                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 908                                 ++lines;
 909                         }
 910                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 911
 912                         if(getWrappedLine_remaining != "")
 913                         {
 914                                 msgstr = strcat(msgstr, "\n");
 915                                 flood = 2;
 916                         }
 917
 918                         if(time >= source.flood_field)
 919                         {
 920                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 921                         }
 922                         else
 923                         {
 924                                 flood = 1;
 925                                 msgstr = fullmsgstr;
 926                         }
 927                 }
 928                 else
 929                 {
 930                         if(time >= source.flood_field)
 931                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 932                         else
 933                                 flood = 1;
 934                 }
 935
 936                 if (timeoutStatus == 2) //when game is paused, no flood protection
 937                         source.flood_field = flood = 0;
 938         }
 939
 940         if(flood == 2) // cannot happen for empty msgstr
 941         {
 942                 if(autocvar_g_chat_flood_notify_flooder)
 943                 {
 944                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 945                         sourcecmsgstr = "";
 946                 }
 947                 else
 948                 {
 949                         sourcemsgstr = fullmsgstr;
 950                         sourcecmsgstr = fullcmsgstr;
 951                 }
 952                 cmsgstr = "";
 953         }
 954         else
 955         {
 956                 sourcemsgstr = msgstr;
 957                 sourcecmsgstr = cmsgstr;
 958         }
 959
 960         if(!privatesay)
 961         if(source.classname != "player")
 962         {
 963                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 964                         teamsay = -1; // spectators
 965         }
 966
 967         if(flood)
 968                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 969
 970         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 971         if(privatesay)
 972                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 973
 974         if(source.muted)
 975         {
 976                 // always fake the message
 977                 ret = -1;
 978         }
 979         else if(flood == 1)
 980         {
 981                 if(autocvar_g_chat_flood_notify_flooder)
 982                 {
 983                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 984                         ret = 0;
 985                 }
 986                 else
 987                         ret = -1;
 988         }
 989         else
 990         {
 991                 ret = 1;
 992         }
 993
 994         if(sourcemsgstr != "" && ret != 0)
 995         {
 996                 if(ret < 0) // fake
 997                 {
 998                         sprint(source, sourcemsgstr);
 999                         if(sourcecmsgstr != "" && !privatesay)
1000                                 centerprint(source, sourcecmsgstr);
1001                 }
1002                 else if(privatesay)
1003                 {
1004                         sprint(source, sourcemsgstr);
1005                         sprint(privatesay, msgstr);
1006                         if(cmsgstr != "")
1007                                 centerprint(privatesay, cmsgstr);
1008                 }
1009                 else if(teamsay > 0)
1010                 {
1011                         sprint(source, sourcemsgstr);
1012                         if(sourcecmsgstr != "")
1013                                 centerprint(source, sourcecmsgstr);
1014                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1015                                 if(head != source)
1016                                 {
1017                                         sprint(head, msgstr);
1018                                         if(cmsgstr != "")
1019                                                 centerprint(head, cmsgstr);
1020                                 }
1021                 }
1022                 else if(teamsay < 0)
1023                 {
1024                         sprint(source, sourcemsgstr);
1025                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1026                                 if(head != source)
1027                                         sprint(head, msgstr);
1028                 }
1029                 else if(sourcemsgstr != msgstr)
1030                 {
1031                         sprint(source, sourcemsgstr);
1032                         FOR_EACH_REALCLIENT(head)
1033                                 if(head != source)
1034                                         sprint(head, msgstr);
1035                 }
1036                 else
1037                         bprint(msgstr);
1038         }
1039
1040         return ret;
1041 }
1042
1043 float GetVoiceMessageVoiceType(string type)
1044 {
1045         if(type == "taunt")
1046                 return VOICETYPE_TAUNT;
1047         if(type == "teamshoot")
1048                 return VOICETYPE_LASTATTACKER;
1049         return VOICETYPE_TEAMRADIO;
1050 }
1051
1052 string allvoicesamples;
1053 .string GetVoiceMessageSampleField(string type)
1054 {
1055         GetPlayerSoundSampleField_notFound = 0;
1056         switch(type)
1057         {
1058 #define _VOICEMSG(m) case #m: return playersound_##m;
1059                 ALLVOICEMSGS
1060 #undef _VOICEMSG
1061         }
1062         GetPlayerSoundSampleField_notFound = 1;
1063         return playersound_taunt;
1064 }
1065
1066 .string GetPlayerSoundSampleField(string type)
1067 {
1068         GetPlayerSoundSampleField_notFound = 0;
1069         switch(type)
1070         {
1071 #define _VOICEMSG(m) case #m: return playersound_##m;
1072                 ALLPLAYERSOUNDS
1073 #undef _VOICEMSG
1074         }
1075         GetPlayerSoundSampleField_notFound = 1;
1076         return playersound_taunt;
1077 }
1078
1079 void PrecacheGlobalSound(string samplestring)
1080 {
1081         float n, i;
1082         tokenize_console(samplestring);
1083         n = stof(argv(1));
1084         if(n > 0)
1085         {
1086                 for(i = 1; i <= n; ++i)
1087                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1088         }
1089         else
1090         {
1091                 precache_sound(strcat(argv(0), ".wav"));
1092         }
1093 }
1094
1095 void PrecachePlayerSounds(string f)
1096 {
1097         float fh;
1098         string s;
1099         fh = fopen(f, FILE_READ);
1100         if(fh < 0)
1101                 return;
1102         while((s = fgets(fh)))
1103         {
1104                 if(tokenize_console(s) != 3)
1105                 {
1106                         dprint("Invalid sound info line: ", s, "\n");
1107                         continue;
1108                 }
1109                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1110         }
1111         fclose(fh);
1112
1113         if not(allvoicesamples)
1114         {
1115 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1116                 ALLVOICEMSGS
1117 #undef _VOICEMSG
1118                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1119         }
1120 }
1121
1122 void ClearPlayerSounds()
1123 {
1124 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1125         ALLPLAYERSOUNDS
1126         ALLVOICEMSGS
1127 #undef _VOICEMSG
1128 }
1129
1130 float LoadPlayerSounds(string f, float first)
1131 {
1132         float fh;
1133         string s;
1134         var .string field;
1135         fh = fopen(f, FILE_READ);
1136         if(fh < 0)
1137         {
1138                 dprint("Player sound file not found: ", f, "\n");
1139                 return 0;
1140         }
1141         while((s = fgets(fh)))
1142         {
1143                 if(tokenize_console(s) != 3)
1144                         continue;
1145                 field = GetPlayerSoundSampleField(argv(0));
1146                 if(GetPlayerSoundSampleField_notFound)
1147                         field = GetVoiceMessageSampleField(argv(0));
1148                 if(GetPlayerSoundSampleField_notFound)
1149                         continue;
1150                 if(self.field)
1151                         strunzone(self.field);
1152                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1153         }
1154         fclose(fh);
1155         return 1;
1156 }
1157
1158 .float modelindex_for_playersound;
1159 .float skinindex_for_playersound;
1160 void UpdatePlayerSounds()
1161 {
1162         if(self.modelindex == self.modelindex_for_playersound)
1163         if(self.skinindex == self.skinindex_for_playersound)
1164                 return;
1165         self.modelindex_for_playersound = self.modelindex;
1166         self.skinindex_for_playersound = self.skinindex;
1167         ClearPlayerSounds();
1168         LoadPlayerSounds("sound/player/default.sounds", 1);
1169         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1170                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1171 }
1172
1173 void FakeGlobalSound(string sample, float chan, float voicetype)
1174 {
1175         float n;
1176         float tauntrand;
1177
1178         if(sample == "")
1179                 return;
1180
1181         tokenize_console(sample);
1182         n = stof(argv(1));
1183         if(n > 0)
1184                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1185         else
1186                 sample = strcat(argv(0), ".wav"); // randomization
1187
1188         switch(voicetype)
1189         {
1190                 case VOICETYPE_LASTATTACKER_ONLY:
1191                         break;
1192                 case VOICETYPE_LASTATTACKER:
1193                         if(self.pusher)
1194                         {
1195                                 msg_entity = self;
1196                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1197                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1198                         }
1199                         break;
1200                 case VOICETYPE_TEAMRADIO:
1201                         msg_entity = self;
1202                         if(msg_entity.cvar_cl_voice_directional == 1)
1203                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1204                         else
1205                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1206                         break;
1207                 case VOICETYPE_AUTOTAUNT:
1208                         if(!sv_autotaunt)
1209                                 break;
1210                         if(!sv_taunt)
1211                                 break;
1212                         if(sv_gentle)
1213                                 break;
1214                         tauntrand = random();
1215                         msg_entity = self;
1216                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1217                         {
1218                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1219                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1220                                 else
1221                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1222                         }
1223                         break;
1224                 case VOICETYPE_TAUNT:
1225                         if(self.classname == "player")
1226                                 if(self.deadflag == DEAD_NO)
1227                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1228                         if(!sv_taunt)
1229                                 break;
1230                         if(sv_gentle)
1231                                 break;
1232                         msg_entity = self;
1233                         if (msg_entity.cvar_cl_voice_directional >= 1)
1234                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1235                         else
1236                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1237                         break;
1238                 case VOICETYPE_PLAYERSOUND:
1239                         msg_entity = self;
1240                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1241                         break;
1242                 default:
1243                         backtrace("Invalid voice type!");
1244                         break;
1245         }
1246 }
1247
1248 void GlobalSound(string sample, float chan, float voicetype)
1249 {
1250         float n;
1251         float tauntrand;
1252
1253         if(sample == "")
1254                 return;
1255
1256         tokenize_console(sample);
1257         n = stof(argv(1));
1258         if(n > 0)
1259                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1260         else
1261                 sample = strcat(argv(0), ".wav"); // randomization
1262
1263         switch(voicetype)
1264         {
1265                 case VOICETYPE_LASTATTACKER_ONLY:
1266                         if(self.pusher)
1267                         {
1268                                 msg_entity = self.pusher;
1269                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1270                                 {
1271                                         if(msg_entity.cvar_cl_voice_directional == 1)
1272                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1273                                         else
1274                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1275                                 }
1276                         }
1277                         break;
1278                 case VOICETYPE_LASTATTACKER:
1279                         if(self.pusher)
1280                         {
1281                                 msg_entity = self.pusher;
1282                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1283                                 {
1284                                         if(msg_entity.cvar_cl_voice_directional == 1)
1285                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1286                                         else
1287                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1288                                 }
1289                                 msg_entity = self;
1290                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1291                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1292                         }
1293                         break;
1294                 case VOICETYPE_TEAMRADIO:
1295                         FOR_EACH_REALCLIENT(msg_entity)
1296                                 if(!teams_matter || msg_entity.team == self.team)
1297                                 {
1298                                         if(msg_entity.cvar_cl_voice_directional == 1)
1299                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1300                                         else
1301                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1302                                 }
1303                         break;
1304                 case VOICETYPE_AUTOTAUNT:
1305                         if(!sv_autotaunt)
1306                                 break;
1307                         if(!sv_taunt)
1308                                 break;
1309                         if(sv_gentle)
1310                                 break;
1311                         tauntrand = random();
1312                         FOR_EACH_REALCLIENT(msg_entity)
1313                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1314                                 {
1315                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1316                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1317                                         else
1318                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1319                                 }
1320                         break;
1321                 case VOICETYPE_TAUNT:
1322                         if(self.classname == "player")
1323                                 if(self.deadflag == DEAD_NO)
1324                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1325                         if(!sv_taunt)
1326                                 break;
1327                         if(sv_gentle)
1328                                 break;
1329                         FOR_EACH_REALCLIENT(msg_entity)
1330                         {
1331                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1332                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1333                                 else
1334                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1335                         }
1336                         break;
1337                 case VOICETYPE_PLAYERSOUND:
1338                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1339                         break;
1340                 default:
1341                         backtrace("Invalid voice type!");
1342                         break;
1343         }
1344 }
1345
1346 void PlayerSound(.string samplefield, float chan, float voicetype)
1347 {
1348         GlobalSound(self.samplefield, chan, voicetype);
1349 }
1350
1351 void VoiceMessage(string type, string msg)
1352 {
1353         var .string sample;
1354         float voicetype, ownteam;
1355         float flood;
1356         sample = GetVoiceMessageSampleField(type);
1357
1358         if(GetPlayerSoundSampleField_notFound)
1359         {
1360                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1361                 return;
1362         }
1363
1364         voicetype = GetVoiceMessageVoiceType(type);
1365         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1366
1367         flood = Say(self, ownteam, world, msg, 1);
1368
1369         if (flood > 0)
1370                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1371         else if (flood < 0)
1372                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1373 }
1374
1375 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1376 {
1377 //      show_message
1378 //      0 (00) automove centerprint, admin message
1379 //      1 (01) automove centerprint, no admin message
1380 //      2 (10) no centerprint, admin message
1381 //      3 (11) no centerprint, no admin message
1382
1383         float lockteams_backup;
1384
1385         lockteams_backup = lockteams;  // backup any team lock
1386
1387         lockteams = 0;  // disable locked teams
1388
1389         TeamchangeFrags(client);  // move the players frags
1390         SetPlayerColors(client, team_colour - 1);  // set the players colour
1391         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1392
1393         lockteams = lockteams_backup;  // restore the team lock
1394
1395         LogTeamchange(client.playerid, client.team, type);
1396
1397         if not(show_message & 1) // admin message
1398                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1399
1400         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1401 }