Add a mutator hook for CopyBody
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_player.qc
1 #include "cl_player.qh"
2
3 #include "bot/api.qh"
4 #include "cheats.qh"
5 #include "g_damage.qh"
6 #include "g_subs.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "weapons/throwing.qh"
11 #include "command/common.qh"
12 #include "../common/state.qh"
13 #include "../common/anim.qh"
14 #include "../common/animdecide.qh"
15 #include "../common/csqcmodel_settings.qh"
16 #include "../common/deathtypes/all.qh"
17 #include "../common/triggers/subs.qh"
18 #include "../common/playerstats.qh"
19 #include "../lib/csqcmodel/sv_model.qh"
20
21 #include "../common/minigames/sv_minigames.qh"
22
23 #include "../common/physics/player.qh"
24 #include "../common/effects/qc/all.qh"
25 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
26 #include "../common/triggers/include.qh"
27
28 #include "weapons/weaponstats.qh"
29
30 #include "../common/animdecide.qh"
31
32 void Drop_Special_Items(entity player)
33 {
34         // called when the player has become stuck or frozen
35         // so objective items aren't stuck with the player
36
37         MUTATOR_CALLHOOK(DropSpecialItems, player);
38 }
39
40 void CopyBody_Think(entity this)
41 {
42         if(this.CopyBody_nextthink && time > this.CopyBody_nextthink)
43         {
44                 this.CopyBody_think(this);
45                 if(wasfreed(this))
46                         return;
47                 this.CopyBody_nextthink = this.nextthink;
48                 this.CopyBody_think = getthink(this);
49                 setthink(this, CopyBody_Think);
50         }
51         CSQCMODEL_AUTOUPDATE(this);
52         this.nextthink = time;
53 }
54 void CopyBody(entity this, float keepvelocity)
55 {
56         if (this.effects & EF_NODRAW)
57                 return;
58         entity clone = new(body);
59         clone.enemy = this;
60         clone.lip = this.lip;
61         clone.colormap = this.colormap;
62         clone.iscreature = this.iscreature;
63         clone.teleportable = this.teleportable;
64         clone.damagedbycontents = this.damagedbycontents;
65         clone.angles = this.angles;
66         clone.v_angle = this.v_angle;
67         clone.avelocity = this.avelocity;
68         clone.damageforcescale = this.damageforcescale;
69         clone.effects = this.effects;
70         clone.glowmod = this.glowmod;
71         clone.event_damage = this.event_damage;
72         clone.anim_state = this.anim_state;
73         clone.anim_time = this.anim_time;
74         clone.anim_lower_action = this.anim_lower_action;
75         clone.anim_lower_time = this.anim_lower_time;
76         clone.anim_upper_action = this.anim_upper_action;
77         clone.anim_upper_time = this.anim_upper_time;
78         clone.anim_implicit_state = this.anim_implicit_state;
79         clone.anim_implicit_time = this.anim_implicit_time;
80         clone.anim_lower_implicit_action = this.anim_lower_implicit_action;
81         clone.anim_lower_implicit_time = this.anim_lower_implicit_time;
82         clone.anim_upper_implicit_action = this.anim_upper_implicit_action;
83         clone.anim_upper_implicit_time = this.anim_upper_implicit_time;
84         clone.dphitcontentsmask = this.dphitcontentsmask;
85         clone.death_time = this.death_time;
86         clone.pain_finished = this.pain_finished;
87         clone.health = this.health;
88         clone.armorvalue = this.armorvalue;
89         clone.armortype = this.armortype;
90         clone.model = this.model;
91         clone.modelindex = this.modelindex;
92         clone.skin = this.skin;
93         clone.species = this.species;
94         clone.move_qcphysics = false; // don't run gamecode logic on clones, too many
95         set_movetype(clone, this.move_movetype);
96         clone.solid = this.solid;
97         clone.ballistics_density = this.ballistics_density;
98         clone.takedamage = this.takedamage;
99         setcefc(clone, getcefc(this));
100         clone.uncustomizeentityforclient = this.uncustomizeentityforclient;
101         clone.uncustomizeentityforclient_set = this.uncustomizeentityforclient_set;
102         if (keepvelocity == 1)
103                 clone.velocity = this.velocity;
104         clone.oldvelocity = clone.velocity;
105         clone.alpha = this.alpha;
106         clone.fade_time = this.fade_time;
107         clone.fade_rate = this.fade_rate;
108         //clone.weapon = this.weapon;
109         setorigin(clone, this.origin);
110         setsize(clone, this.mins, this.maxs);
111         clone.prevorigin = this.origin;
112         clone.reset = SUB_Remove;
113         clone._ps = this._ps;
114
115         Drag_MoveDrag(this, clone);
116
117         if(clone.colormap <= maxclients && clone.colormap > 0)
118                 clone.colormap = 1024 + this.clientcolors;
119
120         CSQCMODEL_AUTOINIT(clone);
121         clone.CopyBody_nextthink = this.nextthink;
122         clone.CopyBody_think = getthink(this);
123         clone.nextthink = time;
124         setthink(clone, CopyBody_Think);
125         // "bake" the current animation frame for clones (they don't get clientside animation)
126         animdecide_load_if_needed(clone);
127         animdecide_setframes(clone, false, frame, frame1time, frame2, frame2time);
128
129         MUTATOR_CALLHOOK(CopyBody, this, clone, keepvelocity);
130 }
131
132 void player_setupanimsformodel(entity this)
133 {
134         // load animation info
135         animdecide_load_if_needed(this);
136         animdecide_setstate(this, 0, false);
137 }
138
139 void player_anim(entity this)
140 {
141         int deadbits = (this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
142         if(IS_DEAD(this)) {
143                 if (!deadbits) {
144                         // Decide on which death animation to use.
145                         if(random() < 0.5)
146                                 deadbits = ANIMSTATE_DEAD1;
147                         else
148                                 deadbits = ANIMSTATE_DEAD2;
149                 }
150         } else {
151                 // Clear a previous death animation.
152                 deadbits = 0;
153         }
154         int animbits = deadbits;
155         if(STAT(FROZEN, this))
156                 animbits |= ANIMSTATE_FROZEN;
157         if(this.move_movetype == MOVETYPE_FOLLOW)
158                 animbits |= ANIMSTATE_FOLLOW;
159         if(this.crouch)
160                 animbits |= ANIMSTATE_DUCK;
161         animdecide_setstate(this, animbits, false);
162         animdecide_setimplicitstate(this, IS_ONGROUND(this));
163 }
164
165 void PlayerCorpseDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
166 {
167         float take, save;
168         vector v;
169         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
170
171         // damage resistance (ignore most of the damage from a bullet or similar)
172         damage = max(damage - 5, 1);
173
174         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
175         take = v.x;
176         save = v.y;
177
178         if(sound_allowed(MSG_BROADCAST, attacker))
179         {
180                 if (save > 10)
181                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
182                 else if (take > 30)
183                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
184                 else if (take > 10)
185                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM);
186         }
187
188         if (take > 50)
189                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
190         if (take > 100)
191                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
192
193         this.armorvalue = this.armorvalue - save;
194         this.health = this.health - take;
195         // pause regeneration for 5 seconds
196         this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
197
198         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
199         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
200         this.dmg_inflictor = inflictor;
201
202         if (this.health <= -autocvar_sv_gibhealth && this.alpha >= 0)
203         {
204                 // don't use any animations as a gib
205                 this.frame = 0;
206                 // view just above the floor
207                 this.view_ofs = '0 0 4';
208
209                 Violence_GibSplash(this, 1, 1, attacker);
210                 this.alpha = -1;
211                 this.solid = SOLID_NOT; // restore later
212                 this.takedamage = DAMAGE_NO; // restore later
213                 this.damagedbycontents = false;
214         }
215 }
216
217 void calculate_player_respawn_time(entity this)
218 {
219         if(g_ca)
220                 return;
221
222         float gametype_setting_tmp;
223         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
224         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
225         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
226         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
227         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
228         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
229
230         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
231         if (teamplay)
232         {
233                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
234                         if(it.team == this.team)
235                                 ++pcount;
236                 ));
237                 if (sdelay_small_count == 0)
238                         sdelay_small_count = 1;
239                 if (sdelay_large_count == 0)
240                         sdelay_large_count = 1;
241         }
242         else
243         {
244                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, LAMBDA(
245                         ++pcount;
246                 ));
247                 if (sdelay_small_count == 0)
248                 {
249                         if (g_cts)
250                         {
251                                 // Players play independently. No point in requiring enemies.
252                                 sdelay_small_count = 1;
253                         }
254                         else
255                         {
256                                 // Players play AGAINST each other. Enemies required.
257                                 sdelay_small_count = 2;
258                         }
259                 }
260                 if (sdelay_large_count == 0)
261                 {
262                         if (g_cts)
263                         {
264                                 // Players play independently. No point in requiring enemies.
265                                 sdelay_large_count = 1;
266                         }
267                         else
268                         {
269                                 // Players play AGAINST each other. Enemies required.
270                                 sdelay_large_count = 2;
271                         }
272                 }
273         }
274
275         float sdelay;
276
277         if (pcount <= sdelay_small_count)
278                 sdelay = sdelay_small;
279         else if (pcount >= sdelay_large_count)
280                 sdelay = sdelay_large;
281         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
282                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
283
284         if(waves)
285                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
286         else
287                 this.respawn_time = time + sdelay;
288
289         if(sdelay < sdelay_max)
290                 this.respawn_time_max = time + sdelay_max;
291         else
292                 this.respawn_time_max = this.respawn_time;
293
294         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
295                 this.respawn_countdown = 10; // first number to count down from is 10
296         else
297                 this.respawn_countdown = -1; // do not count down
298
299         if(autocvar_g_forced_respawn)
300                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
301 }
302
303 void PlayerDamage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
304 {
305         float take, save, dh, da;
306         vector v;
307         float valid_damage_for_weaponstats;
308         float excess;
309
310         dh = max(this.health, 0);
311         da = max(this.armorvalue, 0);
312
313         if(!DEATH_ISSPECIAL(deathtype))
314         {
315                 damage *= sqrt(bound(1.0, this.cvar_cl_handicap, 100.0));
316                 if(this != attacker)
317                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
318         }
319
320         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
321         {
322                 // tuba causes blood to come out of the ears
323                 vector ear1, ear2;
324                 vector d;
325                 float f;
326                 ear1 = this.origin;
327                 ear1_z += 0.125 * this.view_ofs.z + 0.875 * this.maxs.z; // 7/8
328                 ear2 = ear1;
329                 makevectors(this.angles);
330                 ear1 += v_right * -10;
331                 ear2 += v_right * +10;
332                 d = inflictor.origin - this.origin;
333                 if (d)
334                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
335                 else
336                         f = 0;  // Assum ecenter.
337                 force = v_right * vlen(force);
338                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), this, attacker);
339                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), this, attacker);
340                 if(f > 0)
341                 {
342                         hitloc = ear1;
343                         force = force * -1;
344                 }
345                 else
346                 {
347                         hitloc = ear2;
348                         // force is already good
349                 }
350         }
351         else
352                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, this, attacker);
353
354
355         v = healtharmor_applydamage(this.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
356         take = v.x;
357         save = v.y;
358
359         if(attacker == this)
360         {
361                 // don't reset pushltime for this damage as it may be an attempt to
362                 // escape a lava pit or similar
363                 //this.pushltime = 0;
364                 this.istypefrag = 0;
365         }
366         else if(IS_PLAYER(attacker))
367         {
368                 this.pusher = attacker;
369                 this.pushltime = time + autocvar_g_maxpushtime;
370                 this.istypefrag = PHYS_INPUT_BUTTON_CHAT(this);
371         }
372         else if(time < this.pushltime)
373         {
374                 attacker = this.pusher;
375                 this.pushltime = max(this.pushltime, time + 0.6);
376         }
377         else
378         {
379                 this.pushltime = 0;
380                 this.istypefrag = 0;
381         }
382
383         if (time < this.spawnshieldtime && autocvar_g_spawnshield_blockdamage < 1)
384         {
385                 vector v = healtharmor_applydamage(this.armorvalue, max(0, autocvar_g_spawnshield_blockdamage), deathtype, damage);
386                 take = v.x;
387                 save = v.y;
388         }
389
390         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor, inflictor, attacker, this, force, take, save, deathtype, damage);
391         take = bound(0, M_ARGV(4, float), this.health);
392         save = bound(0, M_ARGV(5, float), this.armorvalue);
393         excess = max(0, damage - take - save);
394
395         if(sound_allowed(MSG_BROADCAST, attacker))
396         {
397                 if (save > 10)
398                         sound (this, CH_SHOTS, SND_ARMORIMPACT, VOL_BASE, ATTEN_NORM);
399                 else if (take > 30)
400                         sound (this, CH_SHOTS, SND_BODYIMPACT2, VOL_BASE, ATTEN_NORM);
401                 else if (take > 10)
402                         sound (this, CH_SHOTS, SND_BODYIMPACT1, VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
403         }
404
405         if (take > 50)
406                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, this, attacker);
407         if (take > 100)
408                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, this, attacker);
409
410         if (time >= this.spawnshieldtime || autocvar_g_spawnshield_blockdamage < 1)
411         {
412                 if (!(this.flags & FL_GODMODE))
413                 {
414                         this.armorvalue = this.armorvalue - save;
415                         this.health = this.health - take;
416                         // pause regeneration for 5 seconds
417                         if(take)
418                                 this.pauseregen_finished = max(this.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
419
420                         if (time > this.pain_finished)          //Don't switch pain sequences like crazy
421                         {
422                                 this.pain_finished = time + 0.5;        //Supajoe
423
424                                 if(autocvar_sv_gentle < 1) {
425                                         if(this.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
426                                         {
427                                                 if (!this.animstate_override)
428                                                 {
429                                                         if (random() > 0.5)
430                                                                 animdecide_setaction(this, ANIMACTION_PAIN1, true);
431                                                         else
432                                                                 animdecide_setaction(this, ANIMACTION_PAIN2, true);
433                                                 }
434                                         }
435
436                                         if(sound_allowed(MSG_BROADCAST, attacker))
437                                         if((this.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !(DEATH_WEAPONOF(deathtype).spawnflags & WEP_FLAG_CANCLIMB) || attacker != this) // WEAPONTODO: create separate limit for pain notification with laser
438                                         if(this.health > 1)
439                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
440                                         {
441                                                 if(deathtype == DEATH_FALL.m_id)
442                                                         PlayerSound(this, playersound_fall, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
443                                                 else if(this.health > 75)
444                                                         PlayerSound(this, playersound_pain100, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
445                                                 else if(this.health > 50)
446                                                         PlayerSound(this, playersound_pain75, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
447                                                 else if(this.health > 25)
448                                                         PlayerSound(this, playersound_pain50, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
449                                                 else
450                                                         PlayerSound(this, playersound_pain25, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
451                                         }
452                                 }
453                         }
454
455                         // throw off bot aim temporarily
456                         float shake;
457                         if(IS_BOT_CLIENT(this) && this.health >= 1)
458                         {
459                                 shake = damage * 5 / (bound(0,skill,100) + 1);
460                                 this.v_angle_x = this.v_angle.x + (random() * 2 - 1) * shake;
461                                 this.v_angle_y = this.v_angle.y + (random() * 2 - 1) * shake;
462                                 this.v_angle_x = bound(-90, this.v_angle.x, 90);
463                         }
464                 }
465                 else
466                         this.max_armorvalue += (save + take);
467         }
468         this.dmg_save = this.dmg_save + save;//max(save - 10, 0);
469         this.dmg_take = this.dmg_take + take;//max(take - 10, 0);
470         this.dmg_inflictor = inflictor;
471
472         if (this != attacker) {
473                 float realdmg = damage - excess;
474                 if (IS_PLAYER(attacker)) {
475                         PlayerScore_Add(attacker, SP_DMG, realdmg);
476                 }
477                 if (IS_PLAYER(this)) {
478                         PlayerScore_Add(this, SP_DMGTAKEN, realdmg);
479                 }
480         }
481
482         bool abot = (IS_BOT_CLIENT(attacker));
483         bool vbot = (IS_BOT_CLIENT(this));
484
485         valid_damage_for_weaponstats = 0;
486         Weapon awep = WEP_Null;
487
488         if(vbot || IS_REAL_CLIENT(this))
489         if(abot || IS_REAL_CLIENT(attacker))
490         if(attacker && this != attacker)
491         if(DIFF_TEAM(this, attacker))
492         {
493                 if(DEATH_ISSPECIAL(deathtype))
494                         awep = PS(attacker).m_weapon;
495                 else
496                         awep = DEATH_WEAPONOF(deathtype);
497                 valid_damage_for_weaponstats = 1;
498         }
499
500         dh = dh - max(this.health, 0);
501         da = da - max(this.armorvalue, 0);
502         if(valid_damage_for_weaponstats)
503         {
504                 WeaponStats_LogDamage(awep.m_id, abot, PS(this).m_weapon.m_id, vbot, dh + da);
505         }
506         if (dh + da)
507         {
508                 MUTATOR_CALLHOOK(PlayerDamaged, attacker, this, dh, da, hitloc, deathtype);
509         }
510
511         if (this.health < 1)
512         {
513                 float defer_ClientKill_Now_TeamChange;
514                 defer_ClientKill_Now_TeamChange = false;
515
516                 if(this.alivetime)
517                 {
518                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
519                         this.alivetime = 0;
520                 }
521
522                 if(valid_damage_for_weaponstats)
523                         WeaponStats_LogKill(awep.m_id, abot, PS(this).m_weapon.m_id, vbot);
524
525                 if(autocvar_sv_gentle < 1)
526                 if(sound_allowed(MSG_BROADCAST, attacker))
527                 {
528                         if(deathtype == DEATH_DROWN.m_id)
529                                 PlayerSound(this, playersound_drown, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
530                         else
531                                 PlayerSound(this, playersound_death, CH_PAIN, VOL_BASE, VOICETYPE_PLAYERSOUND);
532                 }
533
534                 // get rid of kill indicator
535                 if(this.killindicator)
536                 {
537                         delete(this.killindicator);
538                         this.killindicator = NULL;
539                         if(this.killindicator_teamchange)
540                                 defer_ClientKill_Now_TeamChange = true;
541
542                         if(this.classname == "body")
543                         if(deathtype == DEATH_KILL.m_id)
544                         {
545                                 // for the lemmings fans, a small harmless explosion
546                                 Send_Effect(EFFECT_ROCKET_EXPLODE, this.origin, '0 0 0', 1);
547                         }
548                 }
549
550                 // print an obituary message
551                 if(this.classname != "body")
552                         Obituary (attacker, inflictor, this, deathtype);
553
554         // increment frag counter for used weapon type
555         Weapon w = DEATH_WEAPONOF(deathtype);
556         if(w != WEP_Null)
557         if(accuracy_isgooddamage(attacker, this))
558         attacker.accuracy.(accuracy_frags[w.m_id-1]) += 1;
559
560                 MUTATOR_CALLHOOK(PlayerDies, inflictor, attacker, this, deathtype, damage);
561                 excess = M_ARGV(4, float);
562
563                 Weapon wep = PS(this).m_weapon;
564                 /*for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
565                 {
566                         .entity weaponentity = weaponentities[slot];
567                         wep.wr_playerdeath(wep, this, weaponentity);
568                 }*/
569                 .entity weaponentity = weaponentities[0]; // TODO: unhardcode
570                 wep.wr_playerdeath(wep, this, weaponentity);
571
572                 RemoveGrapplingHook(this);
573
574                 Portal_ClearAllLater(this);
575
576                 this.fixangle = true;
577
578                 if(defer_ClientKill_Now_TeamChange)
579                         ClientKill_Now_TeamChange(this); // can turn player into spectator
580
581                 // player could have been miraculously resuscitated ;)
582                 // e.g. players in freezetag get frozen, they don't really die
583                 if(this.health >= 1 || !(IS_PLAYER(this) || this.classname == "body"))
584                         return;
585
586                 // when we get here, player actually dies
587
588                 Unfreeze(this); // remove any icy remains
589                 this.health = 0; // Unfreeze resets health, so we need to set it back
590
591                 // clear waypoints
592                 WaypointSprite_PlayerDead(this);
593                 // throw a weapon
594                 SpawnThrownWeapon(this, this.origin + (this.mins + this.maxs) * 0.5, PS(this).m_switchweapon.m_id);
595
596                 // become fully visible
597                 this.alpha = default_player_alpha;
598                 // make the corpse upright (not tilted)
599                 this.angles_x = 0;
600                 this.angles_z = 0;
601                 // don't spin
602                 this.avelocity = '0 0 0';
603                 // view from the floor
604                 this.view_ofs = '0 0 -8';
605                 // toss the corpse
606                 set_movetype(this, MOVETYPE_TOSS);
607                 // shootable corpse
608                 this.solid = SOLID_CORPSE;
609                 this.ballistics_density = autocvar_g_ballistics_density_corpse;
610                 // don't stick to the floor
611                 UNSET_ONGROUND(this);
612                 // dying animation
613                 this.deadflag = DEAD_DYING;
614
615                 // when to allow respawn
616                 calculate_player_respawn_time(this);
617
618                 this.death_time = time;
619                 if (random() < 0.5)
620                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD1, true);
621                 else
622                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DEAD2, true);
623                 if (this.maxs.z > 5)
624                 {
625                         this.maxs_z = 5;
626                         setsize(this, this.mins, this.maxs);
627                 }
628                 // set damage function to corpse damage
629                 this.event_damage = PlayerCorpseDamage;
630                 // call the corpse damage function just in case it wants to gib
631                 this.event_damage(this, inflictor, attacker, excess, deathtype, hitloc, force);
632
633                 // set up to fade out later
634                 SUB_SetFade (this, time + 6 + random (), 1);
635                 // reset body think wrapper broken by SUB_SetFade
636                 if(this.classname == "body" && getthink(this) != CopyBody_Think) {
637                         this.CopyBody_think = getthink(this);
638                         this.CopyBody_nextthink = this.nextthink;
639                         setthink(this, CopyBody_Think);
640                         this.nextthink = time;
641                 }
642
643                 if(autocvar_sv_gentle > 0 || autocvar_ekg || this.classname == "body") {
644                         // remove corpse
645                         // clones don't run any animation code any more, so we must gib them when they die :(
646                         PlayerCorpseDamage(this, inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
647                 }
648
649                 // reset fields the weapons may use just in case
650                 FOREACH(Weapons, it != WEP_Null, LAMBDA(
651                         it.wr_resetplayer(it, this);
652                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
653                         {
654                                 ATTACK_FINISHED_FOR(this, it.m_id, slot) = 0;
655                         }
656                 ));
657         }
658 }
659
660 void MoveToTeam(entity client, int team_colour, int type)
661 {
662         int lockteams_backup = lockteams;  // backup any team lock
663         lockteams = 0;  // disable locked teams
664         TeamchangeFrags(client);  // move the players frags
665         SetPlayerColors(client, team_colour - 1);  // set the players colour
666         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE.m_id, client.origin, '0 0 0');  // kill the player
667         lockteams = lockteams_backup;  // restore the team lock
668         LogTeamchange(client.playerid, client.team, type);
669 }
670
671 /** print(), but only print if the server is not local */
672 void dedicated_print(string input)
673 {
674         if (server_is_dedicated) print(input);
675 }
676
677 /**
678  * message "": do not say, just test flood control
679  * return value:
680  *   1 = accept
681  *   0 = reject
682  *  -1 = fake accept
683  */
684 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
685 {
686         if (!teamsay && !privatesay) if (substring(msgin, 0, 1) == " ")
687         msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
688
689         msgin = formatmessage(source, msgin);
690
691     string colorstr;
692         if (!IS_PLAYER(source))
693                 colorstr = "^0"; // black for spectators
694         else if(teamplay)
695                 colorstr = Team_ColorCode(source.team);
696         else
697         {
698                 colorstr = "";
699                 teamsay = false;
700         }
701
702         if(intermission_running)
703                 teamsay = false;
704
705     if (!source) {
706                 colorstr = "";
707                 teamsay = false;
708     }
709
710         if(msgin != "")
711                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
712
713         /*
714          * using bprint solves this... me stupid
715         // how can we prevent the message from appearing in a listen server?
716         // for now, just give "say" back and only handle say_team
717         if(!teamsay)
718         {
719                 clientcommand(source, strcat("say ", msgin));
720                 return;
721         }
722         */
723
724     string namestr = "";
725     if (source)
726         namestr = autocvar_g_chat_teamcolors ? playername(source) : source.netname;
727
728     string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
729
730     string msgstr, cmsgstr;
731     string privatemsgprefix = string_null;
732     int privatemsgprefixlen = 0;
733         if (msgin == "") {
734         msgstr = cmsgstr = "";
735         } else {
736                 if(privatesay)
737                 {
738                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
739                         privatemsgprefixlen = strlen(msgstr);
740                         msgstr = strcat(msgstr, msgin);
741                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
742                         if(autocvar_g_chat_teamcolors)
743                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
744                         else
745                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
746                 }
747                 else if(teamsay)
748                 {
749                         if(strstrofs(msgin, "/me", 0) >= 0)
750                         {
751                                 //msgin = strreplace("/me", "", msgin);
752                                 //msgin = substring(msgin, 3, strlen(msgin));
753                                 msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
754                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
755                         }
756                         else
757                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
758                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
759                 }
760                 else
761                 {
762                         if(strstrofs(msgin, "/me", 0) >= 0)
763                         {
764                                 //msgin = strreplace("/me", "", msgin);
765                                 //msgin = substring(msgin, 3, strlen(msgin));
766                                 msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
767                                 msgstr = strcat("\{1}^4* ", "^7", msgin);
768                         }
769                         else {
770                 msgstr = "\{1}";
771                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
772                 msgstr = strcat(msgstr, msgin);
773             }
774                         cmsgstr = "";
775                 }
776                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
777         }
778
779         string fullmsgstr = msgstr;
780         string fullcmsgstr = cmsgstr;
781
782         // FLOOD CONTROL
783         int flood = 0;
784         var .float flood_field = floodcontrol_chat;
785         if(floodcontrol)
786         {
787                 float flood_spl;
788                 float flood_burst;
789                 float flood_lmax;
790                 float lines;
791                 if(privatesay)
792                 {
793                         flood_spl = autocvar_g_chat_flood_spl_tell;
794                         flood_burst = autocvar_g_chat_flood_burst_tell;
795                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
796                         flood_field = floodcontrol_chattell;
797                 }
798                 else if(teamsay)
799                 {
800                         flood_spl = autocvar_g_chat_flood_spl_team;
801                         flood_burst = autocvar_g_chat_flood_burst_team;
802                         flood_lmax = autocvar_g_chat_flood_lmax_team;
803                         flood_field = floodcontrol_chatteam;
804                 }
805                 else
806                 {
807                         flood_spl = autocvar_g_chat_flood_spl;
808                         flood_burst = autocvar_g_chat_flood_burst;
809                         flood_lmax = autocvar_g_chat_flood_lmax;
810                         flood_field = floodcontrol_chat;
811                 }
812                 flood_burst = max(0, flood_burst - 1);
813                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
814
815                 // do flood control for the default line size
816                 if(msgstr != "")
817                 {
818                         getWrappedLine_remaining = msgstr;
819                         msgstr = "";
820                         lines = 0;
821                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
822                         {
823                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
824                                 ++lines;
825                         }
826                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
827
828                         if(getWrappedLine_remaining != "")
829                         {
830                                 msgstr = strcat(msgstr, "\n");
831                                 flood = 2;
832                         }
833
834                         if (time >= source.(flood_field))
835                         {
836                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
837                         }
838                         else
839                         {
840                                 flood = 1;
841                                 msgstr = fullmsgstr;
842                         }
843                 }
844                 else
845                 {
846                         if (time >= source.(flood_field))
847                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
848                         else
849                                 flood = 1;
850                 }
851
852                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
853                         source.(flood_field) = flood = 0;
854         }
855
856     string sourcemsgstr, sourcecmsgstr;
857         if(flood == 2) // cannot happen for empty msgstr
858         {
859                 if(autocvar_g_chat_flood_notify_flooder)
860                 {
861                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
862                         sourcecmsgstr = "";
863                 }
864                 else
865                 {
866                         sourcemsgstr = fullmsgstr;
867                         sourcecmsgstr = fullcmsgstr;
868                 }
869                 cmsgstr = "";
870         }
871         else
872         {
873                 sourcemsgstr = msgstr;
874                 sourcecmsgstr = cmsgstr;
875         }
876
877         if (!privatesay && source && !IS_PLAYER(source))
878         {
879                 if (!intermission_running)
880                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
881                                 teamsay = -1; // spectators
882         }
883
884         if(flood)
885                 LOG_INFO("NOTE: ", playername(source), "^7 is flooding.\n");
886
887         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
888         if(privatesay)
889                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
890
891     int ret;
892         if(source.muted)
893         {
894                 // always fake the message
895                 ret = -1;
896         }
897         else if(flood == 1)
898         {
899                 if (autocvar_g_chat_flood_notify_flooder)
900                 {
901                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
902                         ret = 0;
903                 }
904                 else
905                         ret = -1;
906         }
907         else
908         {
909                 ret = 1;
910         }
911
912         if(sourcemsgstr != "" && ret != 0)
913         {
914                 if(ret < 0) // faked message, because the player is muted
915                 {
916                         sprint(source, sourcemsgstr);
917                         if(sourcecmsgstr != "" && !privatesay)
918                                 centerprint(source, sourcecmsgstr);
919                 }
920                 else if(privatesay) // private message, between 2 people only
921                 {
922                         sprint(source, sourcemsgstr);
923                         sprint(privatesay, msgstr);
924                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
925                         if(cmsgstr != "")
926                                 centerprint(privatesay, cmsgstr);
927                 }
928                 else if ( teamsay && source.active_minigame )
929                 {
930                         sprint(source, sourcemsgstr);
931                         dedicated_print(msgstr); // send to server console too
932                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && it.active_minigame == source.active_minigame, sprint(it, msgstr));
933                 }
934                 else if(teamsay > 0) // team message, only sent to team mates
935                 {
936                         sprint(source, sourcemsgstr);
937                         dedicated_print(msgstr); // send to server console too
938                         if(sourcecmsgstr != "")
939                                 centerprint(source, sourcecmsgstr);
940                         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source && it.team == source.team, {
941                                 sprint(it, msgstr);
942                                 if(cmsgstr != "")
943                                         centerprint(it, cmsgstr);
944                         });
945                 }
946                 else if(teamsay < 0) // spectator message, only sent to spectators
947                 {
948                         sprint(source, sourcemsgstr);
949                         dedicated_print(msgstr); // send to server console too
950                         FOREACH_CLIENT(!IS_PLAYER(it) && IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
951                 }
952                 else
953                 {
954             if (source) {
955                 sprint(source, sourcemsgstr);
956                 dedicated_print(msgstr); // send to server console too
957                 MX_Say(strcat(playername(source), "^7: ", msgin));
958             }
959             FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source, sprint(it, msgstr));
960         }
961         }
962
963         return ret;
964 }