qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(self.weapons & WepSet_FromWeapon(self.weapon))
 266                 if(W_IsWeaponThrowable(self.weapon))
 267                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 268 }
 269
 270 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 271 {
 272         float take, save;
 273         vector v;
 274         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 275
 276         // damage resistance (ignore most of the damage from a bullet or similar)
 277         damage = max(damage - 5, 1);
 278
 279         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 280         take = v_x;
 281         save = v_y;
 282
 283         if(sound_allowed(MSG_BROADCAST, attacker))
 284         {
 285                 if (save > 10)
 286                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 287                 else if (take > 30)
 288                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 289                 else if (take > 10)
 290                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 291         }
 292
 293         if (take > 50)
 294                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 295         if (take > 100)
 296                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 297
 298         if (!(self.flags & FL_GODMODE))
 299         {
 300                 self.armorvalue = self.armorvalue - save;
 301                 self.health = self.health - take;
 302                 // pause regeneration for 5 seconds
 303                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 304         }
 305         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 306         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 307         self.dmg_inflictor = inflictor;
 308
 309         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 310         {
 311                 // don't use any animations as a gib
 312                 self.frame = 0;
 313                 // view just above the floor
 314                 self.view_ofs = '0 0 4';
 315
 316                 Violence_GibSplash(self, 1, 1, attacker);
 317                 self.alpha = -1;
 318                 self.solid = SOLID_NOT; // restore later
 319                 self.takedamage = DAMAGE_NO; // restore later
 320                 self.damagedbycontents = FALSE;
 321         }
 322 }
 323
 324 void ClientKill_Now_TeamChange();
 325
 326 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 327 {
 328         float take, save, waves, sdelay, dh, da, j;
 329         vector v;
 330         float valid_damage_for_weaponstats;
 331         float excess;
 332
 333         dh = max(self.health, 0);
 334         da = max(self.armorvalue, 0);
 335
 336         if(!DEATH_ISSPECIAL(deathtype))
 337         {
 338                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 339                 if(self != attacker)
 340                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 341         }
 342
 343         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 344         {
 345                 // tuba causes blood to come out of the ears
 346                 vector ear1, ear2;
 347                 vector d;
 348                 float f;
 349                 ear1 = self.origin;
 350                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 351                 ear2 = ear1;
 352                 makevectors(self.angles);
 353                 ear1 += v_right * -10;
 354                 ear2 += v_right * +10;
 355                 d = inflictor.origin - self.origin;
 356                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 357                 force = v_right * vlen(force);
 358                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 359                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 360                 if(f > 0)
 361                 {
 362                         hitloc = ear1;
 363                         force = force * -1;
 364                 }
 365                 else
 366                 {
 367                         hitloc = ear2;
 368                         // force is already good
 369                 }
 370         }
 371         else
 372                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 373
 374
 375         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 376         take = v_x;
 377         save = v_y;
 378
 379         if(attacker == self)
 380         {
 381                 // don't reset pushltime for self damage as it may be an attempt to
 382                 // escape a lava pit or similar
 383                 //self.pushltime = 0;
 384                 self.istypefrag = 0;
 385         }
 386         else if(IS_PLAYER(attacker))
 387         {
 388                 self.pusher = attacker;
 389                 self.pushltime = time + autocvar_g_maxpushtime;
 390                 self.istypefrag = self.BUTTON_CHAT;
 391         }
 392         else if(time < self.pushltime)
 393         {
 394                 attacker = self.pusher;
 395                 self.pushltime = max(self.pushltime, time + 0.6);
 396         }
 397         else
 398         {
 399                 self.pushltime = 0;
 400                 self.istypefrag = 0;
 401         }
 402
 403         frag_inflictor = inflictor;
 404         frag_attacker = attacker;
 405         frag_target = self;
 406         frag_damage = damage;
 407         damage_take = take;
 408         damage_save = save;
 409         damage_force = force;
 410         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 411         take = bound(0, damage_take, self.health);
 412         save = bound(0, damage_save, self.armorvalue);
 413         excess = max(0, damage - take - save);
 414
 415         if(sound_allowed(MSG_BROADCAST, attacker))
 416         {
 417                 if (save > 10)
 418                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 419                 else if (take > 30)
 420                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 421                 else if (take > 10)
 422                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 423         }
 424
 425         if (take > 50)
 426                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 427         if (take > 100)
 428                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 429
 430         if (time >= self.spawnshieldtime)
 431         {
 432                 if (!(self.flags & FL_GODMODE))
 433                 {
 434                         self.armorvalue = self.armorvalue - save;
 435                         self.health = self.health - take;
 436                         // pause regeneration for 5 seconds
 437                         if(take)
 438                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 439
 440                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 441                         {
 442                                 self.pain_finished = time + 0.5;        //Supajoe
 443
 444                                 if(autocvar_sv_gentle < 1) {
 445                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 446                                         {
 447                                                 if (!self.animstate_override)
 448                                                 {
 449                                                         if (random() > 0.5)
 450                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 451                                                         else
 452                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 453                                                 }
 454                                         }
 455
 456                                         if(sound_allowed(MSG_BROADCAST, attacker))
 457                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 458                                         if(self.health > 1)
 459                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 460                                         {
 461                                                 if(deathtype == DEATH_FALL)
 462                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 463                                                 else if(self.health > 75) // TODO make a "gentle" version?
 464                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 465                                                 else if(self.health > 50)
 466                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 467                                                 else if(self.health > 25)
 468                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 469                                                 else
 470                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 471                                         }
 472                                 }
 473
 474                                 // throw off bot aim temporarily
 475                                 float shake;
 476                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 477                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 478                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 479                         }
 480                 }
 481                 else
 482                         self.max_armorvalue += (save + take);
 483         }
 484         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 485         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 486         self.dmg_inflictor = inflictor;
 487
 488         float abot, vbot, awep;
 489         abot = (IS_BOT_CLIENT(attacker));
 490         vbot = (IS_BOT_CLIENT(self));
 491
 492         valid_damage_for_weaponstats = 0;
 493         awep = 0;
 494
 495         if(vbot || IS_REAL_CLIENT(self))
 496         if(abot || IS_REAL_CLIENT(attacker))
 497         if(attacker && self != attacker)
 498         if(DIFF_TEAM(self, attacker))
 499         {
 500                 if(DEATH_ISSPECIAL(deathtype))
 501                         awep = attacker.weapon;
 502                 else
 503                         awep = DEATH_WEAPONOF(deathtype);
 504                 valid_damage_for_weaponstats = 1;
 505         }
 506
 507         if(valid_damage_for_weaponstats)
 508         {
 509                 dh = dh - max(self.health, 0);
 510                 da = da - max(self.armorvalue, 0);
 511                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 512         }
 513
 514         if (self.health < 1)
 515         {
 516                 float defer_ClientKill_Now_TeamChange;
 517                 defer_ClientKill_Now_TeamChange = FALSE;
 518
 519                 if(self.alivetime)
 520                 {
 521                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 522                         self.alivetime = 0;
 523                 }
 524
 525                 if(valid_damage_for_weaponstats)
 526                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 527
 528                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 529                 if(sound_allowed(MSG_BROADCAST, attacker))
 530                 {
 531                         if(deathtype == DEATH_DROWN)
 532                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 533                         else
 534                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 535                 }
 536
 537                 // get rid of kill indicator
 538                 if(self.killindicator)
 539                 {
 540                         remove(self.killindicator);
 541                         self.killindicator = world;
 542                         if(self.killindicator_teamchange)
 543                                 defer_ClientKill_Now_TeamChange = TRUE;
 544
 545                         if(self.classname == "body")
 546                         if(deathtype == DEATH_KILL)
 547                         {
 548                                 // for the lemmings fans, a small harmless explosion
 549                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 550                         }
 551                 }
 552
 553                 // print an obituary message
 554                 Obituary (attacker, inflictor, self, deathtype);
 555                 race_PreDie();
 556
 557         // increment frag counter for used weapon type
 558         float w;
 559         w = DEATH_WEAPONOF(deathtype);
 560         if(WEP_VALID(w))
 561         if(accuracy_isgooddamage(attacker, self))
 562         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 563
 564                 frag_attacker = attacker;
 565                 frag_inflictor = inflictor;
 566                 frag_target = self;
 567                 frag_deathtype = deathtype;
 568                 MUTATOR_CALLHOOK(PlayerDies);
 569
 570                 weapon_action(self.weapon, WR_PLAYERDEATH);
 571
 572                 RemoveGrapplingHook(self);
 573
 574                 Portal_ClearAllLater(self);
 575
 576                 if(IS_REAL_CLIENT(self))
 577                 {
 578                         self.fixangle = TRUE;
 579                         //msg_entity = self;
 580                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 581                         //WriteAngle (MSG_ONE, self.v_angle_x);
 582                         //WriteAngle (MSG_ONE, self.v_angle_y);
 583                         //WriteAngle (MSG_ONE, 80);
 584                 }
 585
 586                 if(defer_ClientKill_Now_TeamChange)
 587                         ClientKill_Now_TeamChange(); // can turn player into spectator
 588
 589                 // player could have been miraculously resuscitated ;)
 590                 // e.g. players in freezetag get frozen, they don't really die
 591                 if(self.health >= 1 || !IS_PLAYER(self))
 592                         return;
 593
 594                 // when we get here, player actually dies
 595
 596                 // clear waypoints
 597                 WaypointSprite_PlayerDead();
 598                 // throw a weapon
 599                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 600
 601                 // become fully visible
 602                 self.alpha = default_player_alpha;
 603                 // make the corpse upright (not tilted)
 604                 self.angles_x = 0;
 605                 self.angles_z = 0;
 606                 // don't spin
 607                 self.avelocity = '0 0 0';
 608                 // view from the floor
 609                 self.view_ofs = '0 0 -8';
 610                 // toss the corpse
 611                 self.movetype = MOVETYPE_TOSS;
 612                 // shootable corpse
 613                 self.solid = SOLID_CORPSE;
 614                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 615                 // don't stick to the floor
 616                 self.flags &= ~FL_ONGROUND;
 617                 // dying animation
 618                 self.deadflag = DEAD_DYING;
 619                 // when to allow respawn
 620                 sdelay = 0;
 621                 waves = 0;
 622                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 623                 if(!sdelay)
 624                 {
 625                         if(g_cts)
 626                                 sdelay = 0; // no respawn delay in CTS
 627                         else
 628                                 sdelay = autocvar_g_respawn_delay;
 629                 }
 630                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 631                 if(!waves)
 632                         waves = autocvar_g_respawn_waves;
 633                 if(waves)
 634                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 635                 else
 636                         self.respawn_time = time + sdelay;
 637                 if(autocvar_g_respawn_delay_max > self.respawn_time)
 638                         self.respawn_time_max = time + autocvar_g_respawn_delay_max;
 639                 else
 640                         self.respawn_time_max = self.respawn_time;
 641                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 642                         self.respawn_countdown = 10; // first number to count down from is 10
 643                 else
 644                         self.respawn_countdown = -1; // do not count down
 645
 646                 if(g_cts || autocvar_g_forced_respawn)
 647                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 648
 649                 self.death_time = time;
 650                 if (random() < 0.5)
 651                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 652                 else
 653                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 654                 if (self.maxs_z > 5)
 655                 {
 656                         self.maxs_z = 5;
 657                         setsize(self, self.mins, self.maxs);
 658                 }
 659                 // set damage function to corpse damage
 660                 self.event_damage = PlayerCorpseDamage;
 661                 // call the corpse damage function just in case it wants to gib
 662                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 663                 // set up to fade out later
 664                 SUB_SetFade (self, time + 6 + random (), 1);
 665
 666                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 667                         // remove corpse
 668                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 669                 }
 670
 671                 // reset fields the weapons may use just in case
 672                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 673                 {
 674                         weapon_action(j, WR_RESETPLAYER);
 675                         ATTACK_FINISHED_FOR(self, j) = 0;
 676                 }
 677         }
 678 }
 679
 680 .float muted; // to be used by prvm_edictset server playernumber muted 1
 681 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 682 // message "": do not say, just test flood control
 683 // return value:
 684 //   1 = accept
 685 //   0 = reject
 686 //  -1 = fake accept
 687 {
 688         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 689         float flood;
 690         var .float flood_field;
 691         entity head;
 692         float ret;
 693         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 694
 695         if(!teamsay && !privatesay)
 696                 if(substring(msgin, 0, 1) == " ")
 697                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 698
 699         msgin = formatmessage(msgin);
 700
 701         if not(IS_PLAYER(source))
 702                 colorstr = "^0"; // black for spectators
 703         else if(teamplay)
 704                 colorstr = Team_ColorCode(source.team);
 705         else
 706         {
 707                 colorstr = "";
 708                 teamsay = FALSE;
 709         }
 710
 711         if(intermission_running)
 712                 teamsay = FALSE;
 713
 714         if(msgin != "")
 715                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 716
 717         /*
 718          * using bprint solves this... me stupid
 719         // how can we prevent the message from appearing in a listen server?
 720         // for now, just give "say" back and only handle say_team
 721         if(!teamsay)
 722         {
 723                 clientcommand(self, strcat("say ", msgin));
 724                 return;
 725         }
 726         */
 727
 728         if(autocvar_g_chat_teamcolors)
 729                 namestr = playername(source);
 730         else
 731                 namestr = source.netname;
 732
 733         if(msgin != "")
 734         {
 735                 if(privatesay)
 736                 {
 737                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 738                         privatemsgprefixlen = strlen(msgstr);
 739                         msgstr = strcat(msgstr, msgin);
 740                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 741                         if(autocvar_g_chat_teamcolors)
 742                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 743                         else
 744                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 745                 }
 746                 else if(teamsay)
 747                 {
 748                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 749                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 750                 }
 751                 else
 752                 {
 753                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 754                         cmsgstr = "";
 755                 }
 756                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 757         }
 758         else
 759         {
 760                 msgstr = cmsgstr = "";
 761         }
 762
 763         fullmsgstr = msgstr;
 764         fullcmsgstr = cmsgstr;
 765
 766         // FLOOD CONTROL
 767         flood = 0;
 768         flood_field = floodcontrol_chat;
 769         if(floodcontrol)
 770         {
 771                 float flood_spl;
 772                 float flood_burst;
 773                 float flood_lmax;
 774                 float lines;
 775                 if(privatesay)
 776                 {
 777                         flood_spl = autocvar_g_chat_flood_spl_tell;
 778                         flood_burst = autocvar_g_chat_flood_burst_tell;
 779                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 780                         flood_field = floodcontrol_chattell;
 781                 }
 782                 else if(teamsay)
 783                 {
 784                         flood_spl = autocvar_g_chat_flood_spl_team;
 785                         flood_burst = autocvar_g_chat_flood_burst_team;
 786                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 787                         flood_field = floodcontrol_chatteam;
 788                 }
 789                 else
 790                 {
 791                         flood_spl = autocvar_g_chat_flood_spl;
 792                         flood_burst = autocvar_g_chat_flood_burst;
 793                         flood_lmax = autocvar_g_chat_flood_lmax;
 794                         flood_field = floodcontrol_chat;
 795                 }
 796                 flood_burst = max(0, flood_burst - 1);
 797                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 798
 799                 // do flood control for the default line size
 800                 if(msgstr != "")
 801                 {
 802                         getWrappedLine_remaining = msgstr;
 803                         msgstr = "";
 804                         lines = 0;
 805                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 806                         {
 807                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 808                                 ++lines;
 809                         }
 810                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 811
 812                         if(getWrappedLine_remaining != "")
 813                         {
 814                                 msgstr = strcat(msgstr, "\n");
 815                                 flood = 2;
 816                         }
 817
 818                         if(time >= source.flood_field)
 819                         {
 820                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 821                         }
 822                         else
 823                         {
 824                                 flood = 1;
 825                                 msgstr = fullmsgstr;
 826                         }
 827                 }
 828                 else
 829                 {
 830                         if(time >= source.flood_field)
 831                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 832                         else
 833                                 flood = 1;
 834                 }
 835
 836                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 837                         source.flood_field = flood = 0;
 838         }
 839
 840         if(flood == 2) // cannot happen for empty msgstr
 841         {
 842                 if(autocvar_g_chat_flood_notify_flooder)
 843                 {
 844                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 845                         sourcecmsgstr = "";
 846                 }
 847                 else
 848                 {
 849                         sourcemsgstr = fullmsgstr;
 850                         sourcecmsgstr = fullcmsgstr;
 851                 }
 852                 cmsgstr = "";
 853         }
 854         else
 855         {
 856                 sourcemsgstr = msgstr;
 857                 sourcecmsgstr = cmsgstr;
 858         }
 859
 860         if(!privatesay)
 861         if not(IS_PLAYER(source))
 862         {
 863                 if not(intermission_running)
 864                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 865                                 teamsay = -1; // spectators
 866         }
 867
 868         if(flood)
 869                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 870
 871         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 872         if(privatesay)
 873                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 874
 875         if(source.muted)
 876         {
 877                 // always fake the message
 878                 ret = -1;
 879         }
 880         else if(flood == 1)
 881         {
 882                 if(autocvar_g_chat_flood_notify_flooder)
 883                 {
 884                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 885                         ret = 0;
 886                 }
 887                 else
 888                         ret = -1;
 889         }
 890         else
 891         {
 892                 ret = 1;
 893         }
 894
 895         if(sourcemsgstr != "" && ret != 0)
 896         {
 897                 if(ret < 0) // faked message, because the player is muted
 898                 {
 899                         sprint(source, sourcemsgstr);
 900                         if(sourcecmsgstr != "" && !privatesay)
 901                                 centerprint(source, sourcecmsgstr);
 902                 }
 903                 else if(privatesay) // private message, between 2 people only
 904                 {
 905                         sprint(source, sourcemsgstr);
 906                         sprint(privatesay, msgstr);
 907                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 908                         if(cmsgstr != "")
 909                                 centerprint(privatesay, cmsgstr);
 910                 }
 911                 else if(teamsay > 0) // team message, only sent to team mates
 912                 {
 913                         sprint(source, sourcemsgstr);
 914                         dedicated_print(msgstr); // send to server console too
 915                         if(sourcecmsgstr != "")
 916                                 centerprint(source, sourcecmsgstr);
 917                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 918                                 if(head != source)
 919                                 {
 920                                         sprint(head, msgstr);
 921                                         if(cmsgstr != "")
 922                                                 centerprint(head, cmsgstr);
 923                                 }
 924                 }
 925                 else if(teamsay < 0) // spectator message, only sent to spectators
 926                 {
 927                         sprint(source, sourcemsgstr);
 928                         dedicated_print(msgstr); // send to server console too
 929                         FOR_EACH_REALCLIENT(head) if not(IS_PLAYER(head))
 930                                 if(head != source)
 931                                         sprint(head, msgstr);
 932                 }
 933                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 934                 {
 935                         sprint(source, sourcemsgstr);
 936                         dedicated_print(msgstr); // send to server console too
 937                         FOR_EACH_REALCLIENT(head)
 938                                 if(head != source)
 939                                         sprint(head, msgstr);
 940                 }
 941                 else
 942                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 943         }
 944
 945         return ret;
 946 }
 947
 948 float GetVoiceMessageVoiceType(string type)
 949 {
 950         if(type == "taunt")
 951                 return VOICETYPE_TAUNT;
 952         if(type == "teamshoot")
 953                 return VOICETYPE_LASTATTACKER;
 954         return VOICETYPE_TEAMRADIO;
 955 }
 956
 957 string allvoicesamples;
 958 .string GetVoiceMessageSampleField(string type)
 959 {
 960         GetPlayerSoundSampleField_notFound = 0;
 961         switch(type)
 962         {
 963 #define _VOICEMSG(m) case #m: return playersound_##m;
 964                 ALLVOICEMSGS
 965 #undef _VOICEMSG
 966         }
 967         GetPlayerSoundSampleField_notFound = 1;
 968         return playersound_taunt;
 969 }
 970
 971 .string GetPlayerSoundSampleField(string type)
 972 {
 973         GetPlayerSoundSampleField_notFound = 0;
 974         switch(type)
 975         {
 976 #define _VOICEMSG(m) case #m: return playersound_##m;
 977                 ALLPLAYERSOUNDS
 978 #undef _VOICEMSG
 979         }
 980         GetPlayerSoundSampleField_notFound = 1;
 981         return playersound_taunt;
 982 }
 983
 984 void PrecacheGlobalSound(string samplestring)
 985 {
 986         float n, i;
 987         tokenize_console(samplestring);
 988         n = stof(argv(1));
 989         if(n > 0)
 990         {
 991                 for(i = 1; i <= n; ++i)
 992                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 993         }
 994         else
 995         {
 996                 precache_sound(strcat(argv(0), ".wav"));
 997         }
 998 }
 999
1000 void PrecachePlayerSounds(string f)
1001 {
1002         float fh;
1003         string s;
1004         fh = fopen(f, FILE_READ);
1005         if(fh < 0)
1006                 return;
1007         while((s = fgets(fh)))
1008         {
1009                 if(tokenize_console(s) != 3)
1010                 {
1011                         dprint("Invalid sound info line: ", s, "\n");
1012                         continue;
1013                 }
1014                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1015         }
1016         fclose(fh);
1017
1018         if not(allvoicesamples)
1019         {
1020 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1021                 ALLVOICEMSGS
1022 #undef _VOICEMSG
1023                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1024         }
1025 }
1026
1027 void ClearPlayerSounds()
1028 {
1029 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1030         ALLPLAYERSOUNDS
1031         ALLVOICEMSGS
1032 #undef _VOICEMSG
1033 }
1034
1035 float LoadPlayerSounds(string f, float first)
1036 {
1037         float fh;
1038         string s;
1039         var .string field;
1040         fh = fopen(f, FILE_READ);
1041         if(fh < 0)
1042         {
1043                 dprint("Player sound file not found: ", f, "\n");
1044                 return 0;
1045         }
1046         while((s = fgets(fh)))
1047         {
1048                 if(tokenize_console(s) != 3)
1049                         continue;
1050                 field = GetPlayerSoundSampleField(argv(0));
1051                 if(GetPlayerSoundSampleField_notFound)
1052                         field = GetVoiceMessageSampleField(argv(0));
1053                 if(GetPlayerSoundSampleField_notFound)
1054                         continue;
1055                 if(self.field)
1056                         strunzone(self.field);
1057                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1058         }
1059         fclose(fh);
1060         return 1;
1061 }
1062
1063 .float modelindex_for_playersound;
1064 .float skin_for_playersound;
1065 void UpdatePlayerSounds()
1066 {
1067         if(self.modelindex == self.modelindex_for_playersound)
1068         if(self.skin == self.skin_for_playersound)
1069                 return;
1070         self.modelindex_for_playersound = self.modelindex;
1071         self.skin_for_playersound = self.skin;
1072         ClearPlayerSounds();
1073         LoadPlayerSounds("sound/player/default.sounds", 1);
1074         if(!autocvar_g_debug_defaultsounds)
1075                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1076                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1077 }
1078
1079 void FakeGlobalSound(string sample, float chan, float voicetype)
1080 {
1081         float n;
1082         float tauntrand;
1083
1084         if(sample == "")
1085                 return;
1086
1087         tokenize_console(sample);
1088         n = stof(argv(1));
1089         if(n > 0)
1090                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1091         else
1092                 sample = strcat(argv(0), ".wav"); // randomization
1093
1094         switch(voicetype)
1095         {
1096                 case VOICETYPE_LASTATTACKER_ONLY:
1097                         break;
1098                 case VOICETYPE_LASTATTACKER:
1099                         if(self.pusher)
1100                         {
1101                                 msg_entity = self;
1102                                 if(IS_REAL_CLIENT(msg_entity))
1103                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1104                         }
1105                         break;
1106                 case VOICETYPE_TEAMRADIO:
1107                         msg_entity = self;
1108                         if(msg_entity.cvar_cl_voice_directional == 1)
1109                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1110                         else
1111                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1112                         break;
1113                 case VOICETYPE_AUTOTAUNT:
1114                         if(!sv_autotaunt)
1115                                 break;
1116                         if(!sv_taunt)
1117                                 break;
1118                         if(autocvar_sv_gentle)
1119                                 break;
1120                         tauntrand = random();
1121                         msg_entity = self;
1122                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1123                         {
1124                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1125                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1126                                 else
1127                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1128                         }
1129                         break;
1130                 case VOICETYPE_TAUNT:
1131                         if(IS_PLAYER(self))
1132                                 if(self.deadflag == DEAD_NO)
1133                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1134                         if(!sv_taunt)
1135                                 break;
1136                         if(autocvar_sv_gentle)
1137                                 break;
1138                         msg_entity = self;
1139                         if (msg_entity.cvar_cl_voice_directional >= 1)
1140                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1141                         else
1142                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1143                         break;
1144                 case VOICETYPE_PLAYERSOUND:
1145                         msg_entity = self;
1146                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1147                         break;
1148                 default:
1149                         backtrace("Invalid voice type!");
1150                         break;
1151         }
1152 }
1153
1154 void GlobalSound(string sample, float chan, float voicetype)
1155 {
1156         float n;
1157         float tauntrand;
1158
1159         if(sample == "")
1160                 return;
1161
1162         tokenize_console(sample);
1163         n = stof(argv(1));
1164         if(n > 0)
1165                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1166         else
1167                 sample = strcat(argv(0), ".wav"); // randomization
1168
1169         switch(voicetype)
1170         {
1171                 case VOICETYPE_LASTATTACKER_ONLY:
1172                         if(self.pusher)
1173                         {
1174                                 msg_entity = self.pusher;
1175                                 if(IS_REAL_CLIENT(msg_entity))
1176                                 {
1177                                         if(msg_entity.cvar_cl_voice_directional == 1)
1178                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1179                                         else
1180                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1181                                 }
1182                         }
1183                         break;
1184                 case VOICETYPE_LASTATTACKER:
1185                         if(self.pusher)
1186                         {
1187                                 msg_entity = self.pusher;
1188                                 if(IS_REAL_CLIENT(msg_entity))
1189                                 {
1190                                         if(msg_entity.cvar_cl_voice_directional == 1)
1191                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1192                                         else
1193                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1194                                 }
1195                                 msg_entity = self;
1196                                 if(IS_REAL_CLIENT(msg_entity))
1197                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1198                         }
1199                         break;
1200                 case VOICETYPE_TEAMRADIO:
1201                         FOR_EACH_REALCLIENT(msg_entity)
1202                                 if(!teamplay || msg_entity.team == self.team)
1203                                 {
1204                                         if(msg_entity.cvar_cl_voice_directional == 1)
1205                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1206                                         else
1207                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1208                                 }
1209                         break;
1210                 case VOICETYPE_AUTOTAUNT:
1211                         if(!sv_autotaunt)
1212                                 break;
1213                         if(!sv_taunt)
1214                                 break;
1215                         if(autocvar_sv_gentle)
1216                                 break;
1217                         tauntrand = random();
1218                         FOR_EACH_REALCLIENT(msg_entity)
1219                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1220                                 {
1221                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1222                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1223                                         else
1224                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1225                                 }
1226                         break;
1227                 case VOICETYPE_TAUNT:
1228                         if(IS_PLAYER(self))
1229                                 if(self.deadflag == DEAD_NO)
1230                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1231                         if(!sv_taunt)
1232                                 break;
1233                         if(autocvar_sv_gentle)
1234                                 break;
1235                         FOR_EACH_REALCLIENT(msg_entity)
1236                         {
1237                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1238                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1239                                 else
1240                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1241                         }
1242                         break;
1243                 case VOICETYPE_PLAYERSOUND:
1244                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1245                         break;
1246                 default:
1247                         backtrace("Invalid voice type!");
1248                         break;
1249         }
1250 }
1251
1252 void PlayerSound(.string samplefield, float chan, float voicetype)
1253 {
1254         GlobalSound(self.samplefield, chan, voicetype);
1255 }
1256
1257 void VoiceMessage(string type, string msg)
1258 {
1259         var .string sample;
1260         float voicetype, ownteam;
1261         float flood;
1262         sample = GetVoiceMessageSampleField(type);
1263
1264         if(GetPlayerSoundSampleField_notFound)
1265         {
1266                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1267                 return;
1268         }
1269
1270         voicetype = GetVoiceMessageVoiceType(type);
1271         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1272
1273         flood = Say(self, ownteam, world, msg, 1);
1274
1275         if (flood > 0)
1276                 GlobalSound(self.sample, CH_VOICE, voicetype);
1277         else if (flood < 0)
1278                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1279 }
1280
1281 void MoveToTeam(entity client, float team_colour, float type)
1282 {
1283         float lockteams_backup;
1284
1285         lockteams_backup = lockteams;  // backup any team lock
1286
1287         lockteams = 0;  // disable locked teams
1288
1289         TeamchangeFrags(client);  // move the players frags
1290         SetPlayerColors(client, team_colour - 1);  // set the players colour
1291         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1292
1293         lockteams = lockteams_backup;  // restore the team lock
1294
1295         LogTeamchange(client.playerid, client.team, type);
1296 }