qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.iscreature = oldself.iscreature;
 115         self.angles = oldself.angles;
 116         self.avelocity = oldself.avelocity;
 117         self.classname = "body";
 118         self.damageforcescale = oldself.damageforcescale;
 119         self.effects = oldself.effects;
 120         self.event_damage = oldself.event_damage;
 121         self.animstate_startframe = oldself.animstate_startframe;
 122         self.animstate_numframes = oldself.animstate_numframes;
 123         self.animstate_framerate = oldself.animstate_framerate;
 124         self.animstate_starttime = oldself.animstate_starttime;
 125         self.animstate_endtime = oldself.animstate_endtime;
 126         self.animstate_override = oldself.animstate_override;
 127         self.animstate_looping = oldself.animstate_looping;
 128         self.frame = oldself.frame;
 129         self.dead_frame = oldself.dead_frame;
 130         self.pain_finished = oldself.pain_finished;
 131         self.health = oldself.health;
 132         self.armorvalue = oldself.armorvalue;
 133         self.armortype = oldself.armortype;
 134         self.model = oldself.model;
 135         self.modelindex = oldself.modelindex;
 136         self.modelindex_lod0 = oldself.modelindex_lod0;
 137         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 138         self.modelindex_lod1 = oldself.modelindex_lod1;
 139         self.modelindex_lod2 = oldself.modelindex_lod2;
 140         self.skinindex = oldself.skinindex;
 141         self.species = oldself.species;
 142         self.movetype = oldself.movetype;
 143         self.nextthink = oldself.nextthink;
 144         self.solid = oldself.solid;
 145         self.takedamage = oldself.takedamage;
 146         self.think = oldself.think;
 147         self.customizeentityforclient = oldself.customizeentityforclient;
 148         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 149         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 150         if (keepvelocity == 1)
 151                 self.velocity = oldself.velocity;
 152         self.oldvelocity = self.velocity;
 153         self.fade_time = oldself.fade_time;
 154         self.fade_rate = oldself.fade_rate;
 155         //self.weapon = oldself.weapon;
 156         setorigin(self, oldself.origin);
 157         setsize(self, oldself.mins, oldself.maxs);
 158         self.prevorigin = oldself.origin;
 159         self.reset = SUB_Remove;
 160
 161         Drag_MoveDrag(oldself, self);
 162
 163         self = oldself;
 164 }
 165
 166 float player_getspecies()
 167 {
 168         float s;
 169         get_model_parameters(self.playermodel, self.skinindex);
 170         s = get_model_parameters_species;
 171         get_model_parameters(string_null, 0);
 172         if(s < 0)
 173                 return SPECIES_HUMAN;
 174         return s;
 175 }
 176
 177 void player_setupanimsformodel()
 178 {
 179         local string animfilename;
 180         local float animfile;
 181         // defaults for legacy .zym models without animinfo files
 182         self.anim_die1 = '0 1 0.5'; // 2 seconds
 183         self.anim_die2 = '1 1 0.5'; // 2 seconds
 184         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 185         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 186         self.anim_duckwalk = '4 1 1';
 187         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 188         self.anim_duckidle = '6 1 1';
 189         self.anim_idle = '7 1 1';
 190         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 191         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 192         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 193         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 194         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 195         self.anim_run = '13 1 1';
 196         self.anim_runbackwards = '14 1 1';
 197         self.anim_strafeleft = '15 1 1';
 198         self.anim_straferight = '16 1 1';
 199         self.anim_dead1 = '17 1 1';
 200         self.anim_dead2 = '18 1 1';
 201         self.anim_forwardright = '19 1 1';
 202         self.anim_forwardleft = '20 1 1';
 203         self.anim_backright = '21 1 1';
 204         self.anim_backleft  = '22 1 1';
 205         animparseerror = FALSE;
 206         animfilename = strcat(self.model, ".animinfo");
 207         animfile = fopen(animfilename, FILE_READ);
 208         if (animfile >= 0)
 209         {
 210                 self.anim_die1         = animparseline(animfile);
 211                 self.anim_die2         = animparseline(animfile);
 212                 self.anim_draw         = animparseline(animfile);
 213                 self.anim_duck         = animparseline(animfile);
 214                 self.anim_duckwalk     = animparseline(animfile);
 215                 self.anim_duckjump     = animparseline(animfile);
 216                 self.anim_duckidle     = animparseline(animfile);
 217                 self.anim_idle         = animparseline(animfile);
 218                 self.anim_jump         = animparseline(animfile);
 219                 self.anim_pain1        = animparseline(animfile);
 220                 self.anim_pain2        = animparseline(animfile);
 221                 self.anim_shoot        = animparseline(animfile);
 222                 self.anim_taunt        = animparseline(animfile);
 223                 self.anim_run          = animparseline(animfile);
 224                 self.anim_runbackwards = animparseline(animfile);
 225                 self.anim_strafeleft   = animparseline(animfile);
 226                 self.anim_straferight  = animparseline(animfile);
 227                 self.anim_forwardright = animparseline(animfile);
 228                 self.anim_forwardleft  = animparseline(animfile);
 229                 self.anim_backright    = animparseline(animfile);
 230                 self.anim_backleft     = animparseline(animfile);
 231                 fclose(animfile);
 232
 233                 // derived anims
 234                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 235                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 236
 237                 if (animparseerror)
 238                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 239         }
 240         else
 241                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 242         // reset animstate now
 243         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 244 };
 245
 246 void player_anim (void)
 247 {
 248         updateanim(self);
 249         if (self.weaponentity)
 250                 updateanim(self.weaponentity);
 251
 252         if (self.deadflag != DEAD_NO)
 253         {
 254                 if (time > self.animstate_endtime)
 255                 {
 256                         if (self.maxs_z > 5)
 257                         {
 258                                 self.maxs_z = 5;
 259                                 setsize(self, self.mins, self.maxs);
 260                         }
 261                         self.frame = self.dead_frame;
 262                 }
 263                 return;
 264         }
 265
 266         if (!self.animstate_override)
 267         {
 268                 if (!(self.flags & FL_ONGROUND))
 269                 {
 270                         if (self.crouch)
 271                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 272                         else
 273                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 274                         self.restart_jump = FALSE;
 275                 }
 276                 else if (self.crouch)
 277                 {
 278                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 279                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 280                         else
 281                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 282                 }
 283                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 284                 {
 285                         if (self.movement_x > 0 && self.movement_y == 0)
 286                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 287                         else if (self.movement_x < 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x == 0 && self.movement_y > 0)
 290                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y < 0)
 292                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x > 0 && self.movement_y > 0)
 294                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y < 0)
 296                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x < 0 && self.movement_y > 0)
 298                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y < 0)
 300                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 301                         else
 302                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 303                 }
 304                 else
 305                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 306         }
 307
 308         if (self.weaponentity)
 309         if (!self.weaponentity.animstate_override)
 310                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 311 }
 312
 313 void SpawnThrownWeapon (vector org, float w)
 314 {
 315         if(g_minstagib)
 316         if(self.ammo_cells <= 0)
 317                 return;
 318
 319         if(g_pinata)
 320         {
 321                 float j;
 322                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 323                 {
 324                         if(self.weapons & W_WeaponBit(j))
 325                                 if(W_IsWeaponThrowable(j))
 326                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 327                 }
 328         }
 329         else
 330                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 331 }
 332
 333 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 334 {
 335         local float take, save;
 336         vector v;
 337         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 338
 339         // damage resistance (ignore most of the damage from a bullet or similar)
 340         damage = max(damage - 5, 1);
 341
 342         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 343         take = v_x;
 344         save = v_y;
 345
 346         if(sound_allowed(MSG_BROADCAST, attacker))
 347         {
 348                 if (save > 10)
 349                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 350                 else if (take > 30)
 351                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 10)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 354         }
 355
 356         if (take > 50)
 357                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 358         if (take > 100)
 359                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 360
 361         if (!(self.flags & FL_GODMODE))
 362         {
 363                 self.armorvalue = self.armorvalue - save;
 364                 self.health = self.health - take;
 365                 // pause regeneration for 5 seconds
 366                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 367         }
 368         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 369         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 370         self.dmg_inflictor = inflictor;
 371
 372         if (self.health <= -100 && self.modelindex != 0)
 373         {
 374                 // don't use any animations as a gib
 375                 self.frame = 0;
 376                 self.dead_frame = 0;
 377                 // view just above the floor
 378                 self.view_ofs = '0 0 4';
 379
 380                 Violence_GibSplash(self, 1, 1, attacker);
 381                 self.modelindex = 0; // restore later
 382                 self.solid = SOLID_NOT; // restore later
 383         }
 384 }
 385
 386 void ClientKill_Now_TeamChange();
 387
 388 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 389 {
 390         local float take, save, waves, sdelay, dh, da, j;
 391         vector v;
 392         float valid_damage_for_weaponstats;
 393
 394         dh = max(self.health, 0);
 395         da = max(self.armorvalue, 0);
 396
 397         if(!DEATH_ISSPECIAL(deathtype))
 398         {
 399                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 400                 if(self != attacker)
 401                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 402         }
 403
 404         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 405         {
 406                 // tuba causes blood to come out of the ears
 407                 vector ear1, ear2;
 408                 vector d;
 409                 float f;
 410                 ear1 = self.origin;
 411                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 412                 ear2 = ear1;
 413                 makevectors(self.angles);
 414                 ear1 += v_right * -10;
 415                 ear2 += v_right * +10;
 416                 d = inflictor.origin - self.origin;
 417                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 418                 force = v_right * vlen(force);
 419                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 420                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 421                 if(f > 0)
 422                 {
 423                         hitloc = ear1;
 424                         force = force * -1;
 425                 }
 426                 else
 427                 {
 428                         hitloc = ear2;
 429                         // force is already good
 430                 }
 431         }
 432         else
 433                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 434
 435         if((g_arena && numspawned < 2) || (g_ca && player_cnt < 2) && !inWarmupStage)
 436                 return;
 437
 438         if (!g_minstagib)
 439         {
 440                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 441                 take = v_x;
 442                 save = v_y;
 443         }
 444         else
 445         {
 446                 save = 0;
 447                 take = damage;
 448         }
 449
 450         if(sound_allowed(MSG_BROADCAST, attacker))
 451         {
 452                 if (save > 10)
 453                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 454                 else if (take > 30)
 455                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 456                 else if (take > 10)
 457                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 458         }
 459
 460         if (take > 50)
 461                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 462         if (take > 100)
 463                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 464
 465         if (time >= self.spawnshieldtime)
 466         {
 467                 if (!(self.flags & FL_GODMODE))
 468                 {
 469                         self.armorvalue = self.armorvalue - save;
 470                         self.health = self.health - take;
 471                         // pause regeneration for 5 seconds
 472                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 473
 474                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 475                         {
 476                                 self.pain_finished = time + 0.5;        //Supajoe
 477
 478                                 if(sv_gentle < 1) {
 479                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 480                                         {
 481                                                 if (random() > 0.5)
 482                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 483                                                 else
 484                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 485                                         }
 486
 487                                         if(sound_allowed(MSG_BROADCAST, attacker))
 488                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 489                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 490                                         {
 491                                                 if(self.health > 75) // TODO make a "gentle" version?
 492                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 493                                                 else if(self.health > 50)
 494                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 495                                                 else if(self.health > 25)
 496                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 497                                                 else if(self.health > 1)
 498                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 499                                         }
 500                                 }
 501
 502                                 // throw off bot aim temporarily
 503                                 local float shake;
 504                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 505                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 506                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 507                         }
 508                 }
 509                 else
 510                         self.max_armorvalue += (save + take);
 511         }
 512         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 513         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 514         self.dmg_inflictor = inflictor;
 515
 516         if(attacker == self)
 517         {
 518                 // don't reset pushltime for self damage as it may be an attempt to
 519                 // escape a lava pit or similar
 520                 //self.pushltime = 0;
 521         }
 522         else if(attacker.classname == "player" || attacker.classname == "gib")
 523         {
 524                 self.pusher = attacker;
 525                 self.pushltime = time + cvar("g_maxpushtime");
 526         }
 527         else if(time < self.pushltime)
 528         {
 529                 attacker = self.pusher;
 530                 self.pushltime = max(self.pushltime, time + 0.6);
 531         }
 532         else
 533                 self.pushltime = 0;
 534
 535         valid_damage_for_weaponstats = 0;
 536         if(clienttype(self) == CLIENTTYPE_REAL)
 537         if(clienttype(attacker) == CLIENTTYPE_REAL)
 538         if(self != attacker)
 539         if(!DEATH_ISSPECIAL(deathtype))
 540         if(IsDifferentTeam(self, attacker))
 541                 valid_damage_for_weaponstats = 1;
 542
 543         if(valid_damage_for_weaponstats)
 544         {
 545                 dh = dh - max(self.health, 0);
 546                 da = da - max(self.armorvalue, 0);
 547                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 548         }
 549
 550         if (self.health < 1)
 551         {
 552                 float defer_ClientKill_Now_TeamChange;
 553                 defer_ClientKill_Now_TeamChange = FALSE;
 554
 555                 if(valid_damage_for_weaponstats)
 556                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 557
 558                 if(sv_gentle < 1) // TODO make a "gentle" version?
 559                 if(sound_allowed(MSG_BROADCAST, attacker))
 560                 {
 561                         if(deathtype == DEATH_DROWN)
 562                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 563                         else
 564                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 565                 }
 566
 567                 // get rid of kill indicator
 568                 if(self.killindicator)
 569                 {
 570                         remove(self.killindicator);
 571                         self.killindicator = world;
 572                         if(self.killindicator_teamchange)
 573                                 defer_ClientKill_Now_TeamChange = TRUE;
 574
 575                         if(self.classname == "body")
 576                         if(deathtype == DEATH_KILL)
 577                         {
 578                                 // for the lemmings fans, a small harmless explosion
 579                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 580                         }
 581                 }
 582
 583                 // become fully visible
 584                 self.alpha = 1;
 585                 // clear selected player display
 586                 ClearSelectedPlayer();
 587                 // throw a weapon
 588                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 589                 // print an obituary message
 590                 Obituary (attacker, inflictor, self, deathtype);
 591                 race_PreDie();
 592                 DropAllRunes(self);
 593
 594                 frag_attacker = attacker;
 595                 frag_inflictor = inflictor;
 596                 frag_target = self;
 597                 MUTATOR_CALLHOOK(PlayerDies);
 598
 599                 if(self.flagcarried)
 600                 {
 601                         if(attacker.classname != "player" && attacker.classname != "gib")
 602                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 603                         else if(attacker.team == self.team)
 604                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 605                         else
 606                                 DropFlag(self.flagcarried, world, attacker);
 607                 }
 608                 if(self.ballcarried)
 609                         DropBall(self.ballcarried, self.origin, self.velocity);
 610                 Portal_ClearAllLater(self);
 611                 // clear waypoints
 612                 WaypointSprite_PlayerDead();
 613                 // make the corpse upright (not tilted)
 614                 self.angles_x = 0;
 615                 self.angles_z = 0;
 616                 // don't spin
 617                 self.avelocity = '0 0 0';
 618                 // view from the floor
 619                 self.view_ofs = '0 0 -8';
 620                 // toss the corpse
 621                 self.movetype = MOVETYPE_TOSS;
 622                 // shootable corpse
 623                 self.solid = SOLID_CORPSE;
 624                 // don't stick to the floor
 625                 self.flags &~= FL_ONGROUND;
 626                 // dying animation
 627                 self.deadflag = DEAD_DYING;
 628                 // when to allow respawn
 629                 sdelay = 0;
 630                 waves = 0;
 631                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 632                 if(!sdelay)
 633                         sdelay = cvar("g_respawn_delay");
 634                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 635                 if(!waves)
 636                         waves = cvar("g_respawn_waves");
 637                 if(waves)
 638                         self.death_time = ceil((time + sdelay) / waves) * waves;
 639                 else
 640                         self.death_time = time + sdelay;
 641                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 642                         self.respawn_countdown = 10; // first number to count down from is 10
 643                 else
 644                         self.respawn_countdown = -1; // do not count down
 645                 if (random() < 0.5)
 646                 {
 647                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 648                         self.dead_frame = self.anim_dead1_x;
 649                 }
 650                 else
 651                 {
 652                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 653                         self.dead_frame = self.anim_dead2_x;
 654                 }
 655                 // set damage function to corpse damage
 656                 self.event_damage = PlayerCorpseDamage;
 657                 // call the corpse damage function just in case it wants to gib
 658                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 659                 // set up to fade out later
 660                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 661
 662                 // remove laserdot
 663                 if(self.weaponentity)
 664                         if(self.weaponentity.lasertarget)
 665                                 remove(self.weaponentity.lasertarget);
 666
 667                 if(clienttype(self) == CLIENTTYPE_REAL)
 668                 {
 669                         self.fixangle = TRUE;
 670                         //msg_entity = self;
 671                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 672                         //WriteAngle (MSG_ONE, self.v_angle_x);
 673                         //WriteAngle (MSG_ONE, self.v_angle_y);
 674                         //WriteAngle (MSG_ONE, 80);
 675                 }
 676
 677                 if(g_arena)
 678                         Spawnqueue_Unmark(self);
 679
 680                 if(defer_ClientKill_Now_TeamChange)
 681                         ClientKill_Now_TeamChange();
 682
 683                 if(sv_gentle > 0 || cvar("ekg")) {
 684                         // remove corpse
 685                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 686                 }
 687
 688                 // reset fields the weapons may use just in case
 689         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 690                 {
 691             weapon_action(j, WR_RESETPLAYER);
 692                         ATTACK_FINISHED_FOR(self, j) = 0;
 693                 }
 694         }
 695 }
 696
 697 float UpdateSelectedPlayer_countvalue(float v)
 698 {
 699         return max(0, (v - 1.0) / 0.5);
 700 }
 701
 702 // returns: -2 if no hit, otherwise cos of the angle
 703 // uses the global v_angle
 704 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 705 {
 706         vector so, d;
 707         float c;
 708
 709         if(p == self)
 710                 return -2;
 711
 712         if(p.deadflag)
 713                 return -2;
 714
 715         so = self.origin + self.view_ofs;
 716         d = p.origin - so;
 717
 718         // misaimed?
 719         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 720                 return -2;
 721
 722         // now find the cos of the angle...
 723         c = normalize(d) * v_forward;
 724
 725         if(c <= mincosangle)
 726                 return -2;
 727
 728         // not visible in any way? forget it
 729         if(!checkpvs(so, p))
 730                 return -2;
 731
 732         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 733         if(trace_fraction < 1)
 734                 return -2;
 735
 736         return c;
 737 }
 738
 739 void ClearSelectedPlayer()
 740 {
 741         if(self.selected_player)
 742         {
 743                 centerprint_expire(self, CENTERPRIO_POINT);
 744                 self.selected_player = world;
 745                 self.selected_player_display_needs_update = FALSE;
 746         }
 747 }
 748
 749 void UpdateSelectedPlayer()
 750 {
 751         entity selected;
 752         float selected_score;
 753         selected = world;
 754         selected_score = 0.95; // 18 degrees
 755
 756         if(!cvar("sv_allow_shownames"))
 757                 return;
 758
 759         if(clienttype(self) != CLIENTTYPE_REAL)
 760                 return;
 761
 762         if(self.cvar_cl_shownames == 0)
 763                 return;
 764
 765         if(self.cvar_cl_shownames == 1 && !teams_matter)
 766                 return;
 767
 768         makevectors(self.v_angle); // sets v_forward
 769
 770         // 1. cursor trace is always right
 771         WarpZone_crosshair_trace(self);
 772         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 773         {
 774                 selected = trace_ent;
 775         }
 776         else
 777         {
 778                 // 2. if we don't have a cursor trace, find the player which is least
 779                 //    mis-aimed at
 780                 entity p;
 781                 FOR_EACH_PLAYER(p)
 782                 {
 783                         float c;
 784                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 785                         if(c >= -1)
 786                         {
 787                                 selected = p;
 788                                 selected_score = c;
 789                         }
 790                 }
 791         }
 792
 793         if(selected)
 794         {
 795                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 796         }
 797         else
 798         {
 799                 if(time < self.selected_player_display_timeout)
 800                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 801                                 selected = self.selected_player;
 802         }
 803
 804         if(selected)
 805         {
 806                 if(selected == self.selected_player)
 807                 {
 808                         float save;
 809                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 810                         self.selected_player_count = self.selected_player_count + frametime;
 811                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 812                         {
 813                                 string namestr, healthstr;
 814                                 namestr = playername(selected);
 815                                 if(teams_matter)
 816                                 {
 817                                         healthstr = ftos(floor(selected.health));
 818                                         if(self.team == selected.team)
 819                                         {
 820                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 821                                                 self.selected_player_display_needs_update = TRUE;
 822                                         }
 823                                 }
 824                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 825                         }
 826                 }
 827                 else
 828                 {
 829                         ClearSelectedPlayer();
 830                         self.selected_player = selected;
 831                         self.selected_player_time = time;
 832                         self.selected_player_count = 0;
 833                         self.selected_player_display_needs_update = FALSE;
 834                 }
 835         }
 836         else
 837         {
 838                 ClearSelectedPlayer();
 839         }
 840
 841         if(self.selected_player)
 842                 self.last_selected_player = self.selected_player;
 843 }
 844
 845 .float muted; // to be used by prvm_edictset server playernumber muted 1
 846 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 847 // message "": do not say, just test flood control
 848 // return value:
 849 //   1 = accept
 850 //   0 = reject
 851 //  -1 = fake accept
 852 {
 853         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 854         float flood, privatemsgprefixlen;
 855         entity head;
 856         float ret;
 857
 858         if(Ban_MaybeEnforceBan(source))
 859                 return 0;
 860
 861         if(!teamsay && !privatesay)
 862                 if(substring(msgin, 0, 1) == " ")
 863                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 864
 865         msgin = formatmessage(msgin);
 866
 867         if(source.classname != "player")
 868                 colorstr = "^0"; // black for spectators
 869         else if(teams_matter)
 870                 colorstr = Team_ColorCode(source.team);
 871         else
 872                 teamsay = FALSE;
 873
 874         if(intermission_running)
 875                 teamsay = FALSE;
 876
 877         if(msgin != "")
 878                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 879
 880         /*
 881          * using bprint solves this... me stupid
 882         // how can we prevent the message from appearing in a listen server?
 883         // for now, just give "say" back and only handle say_team
 884         if(!teamsay)
 885         {
 886                 clientcommand(self, strcat("say ", msgin));
 887                 return;
 888         }
 889         */
 890
 891         if(cvar("g_chat_teamcolors"))
 892                 namestr = playername(source);
 893         else
 894                 namestr = source.netname;
 895
 896         if(msgin != "")
 897         {
 898                 if(privatesay)
 899                 {
 900                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 901                         privatemsgprefixlen = strlen(msgstr);
 902                         msgstr = strcat(msgstr, msgin);
 903                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 904                         if(cvar("g_chat_teamcolors"))
 905                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 906                         else
 907                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 908                 }
 909                 else if(teamsay)
 910                 {
 911                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 912                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 913                 }
 914                 else
 915                 {
 916                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 917                         cmsgstr = "";
 918                 }
 919                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 920         }
 921         else
 922         {
 923                 msgstr = cmsgstr = "";
 924         }
 925
 926         fullmsgstr = msgstr;
 927         fullcmsgstr = cmsgstr;
 928
 929         // FLOOD CONTROL
 930         flood = 0;
 931         if(floodcontrol)
 932         {
 933                 float flood_spl;
 934                 float flood_burst;
 935                 float flood_lmax;
 936                 var .float flood_field;
 937                 float lines;
 938                 if(privatesay)
 939                 {
 940                         flood_spl = cvar("g_chat_flood_spl_tell");
 941                         flood_burst = cvar("g_chat_flood_burst_tell");
 942                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 943                         flood_field = floodcontrol_chattell;
 944                 }
 945                 else if(teamsay)
 946                 {
 947                         flood_spl = cvar("g_chat_flood_spl_team");
 948                         flood_burst = cvar("g_chat_flood_burst_team");
 949                         flood_lmax = cvar("g_chat_flood_lmax_team");
 950                         flood_field = floodcontrol_chatteam;
 951                 }
 952                 else
 953                 {
 954                         flood_spl = cvar("g_chat_flood_spl");
 955                         flood_burst = cvar("g_chat_flood_burst");
 956                         flood_lmax = cvar("g_chat_flood_lmax");
 957                         flood_field = floodcontrol_chat;
 958                 }
 959                 flood_burst = max(0, flood_burst - 1);
 960                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 961
 962                 // do flood control for the default line size
 963                 if(msgstr != "")
 964                 {
 965                         getWrappedLine_remaining = msgstr;
 966                         msgstr = "";
 967                         lines = 0;
 968                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 969                         {
 970                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 971                                 ++lines;
 972                         }
 973                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 974
 975                         if(getWrappedLine_remaining != "")
 976                         {
 977                                 msgstr = strcat(msgstr, "\n");
 978                                 flood = 2;
 979                         }
 980
 981                         if(time >= source.flood_field)
 982                         {
 983                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 984                         }
 985                         else
 986                         {
 987                                 flood = 1;
 988                                 msgstr = fullmsgstr;
 989                         }
 990                 }
 991                 else
 992                 {
 993                         if(time >= source.flood_field)
 994                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 995                         else
 996                                 flood = 1;
 997                 }
 998         }
 999
1000         if (timeoutStatus == 2) //when game is paused, no flood protection
1001                 source.flood_field = flood = 0;
1002
1003         if(flood == 2) // cannot happen for empty msgstr
1004         {
1005                 if(cvar("g_chat_flood_notify_flooder"))
1006                 {
1007                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1008                         sourcecmsgstr = "";
1009                 }
1010                 else
1011                 {
1012                         sourcemsgstr = fullmsgstr;
1013                         sourcecmsgstr = fullcmsgstr;
1014                 }
1015                 cmsgstr = "";
1016         }
1017         else
1018         {
1019                 sourcemsgstr = msgstr;
1020                 sourcecmsgstr = cmsgstr;
1021         }
1022
1023         if(!privatesay)
1024         if(source.classname != "player")
1025         {
1026                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1027                         teamsay = -1; // spectators
1028         }
1029
1030         if(flood)
1031                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1032
1033         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1034         if(privatesay)
1035                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1036
1037         if(source.muted)
1038         {
1039                 // always fake the message
1040                 ret = -1;
1041         }
1042         else if(flood == 1)
1043         {
1044                 if(cvar("g_chat_flood_notify_flooder"))
1045                 {
1046                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1047                         ret = 0;
1048                 }
1049                 else
1050                         ret = -1;
1051         }
1052         else
1053         {
1054                 ret = 1;
1055         }
1056
1057         if(sourcemsgstr != "" && ret != 0)
1058         {
1059                 if(ret < 0) // fake
1060                 {
1061                         sprint(source, sourcemsgstr);
1062                         if(sourcecmsgstr != "" && !privatesay)
1063                                 centerprint(source, sourcecmsgstr);
1064                 }
1065                 else if(privatesay)
1066                 {
1067                         sprint(source, sourcemsgstr);
1068                         sprint(privatesay, msgstr);
1069                         if(cmsgstr != "")
1070                                 centerprint(privatesay, cmsgstr);
1071                 }
1072                 else if(teamsay > 0)
1073                 {
1074                         sprint(source, sourcemsgstr);
1075                         if(sourcecmsgstr != "")
1076                                 centerprint(source, sourcecmsgstr);
1077                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1078                                 if(head != source)
1079                                 {
1080                                         sprint(head, msgstr);
1081                                         if(cmsgstr != "")
1082                                                 centerprint(head, cmsgstr);
1083                                 }
1084                 }
1085                 else if(teamsay < 0)
1086                 {
1087                         sprint(source, sourcemsgstr);
1088                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1089                                 if(head != source)
1090                                         sprint(head, msgstr);
1091                 }
1092                 else if(sourcemsgstr != msgstr)
1093                 {
1094                         sprint(source, sourcemsgstr);
1095                         FOR_EACH_REALCLIENT(head)
1096                                 if(head != source)
1097                                         sprint(head, msgstr);
1098                 }
1099                 else
1100                         bprint(msgstr);
1101         }
1102
1103         return ret;
1104 }
1105
1106 float GetVoiceMessageVoiceType(string type)
1107 {
1108         if(type == "taunt")
1109                 return VOICETYPE_TAUNT;
1110         if(type == "teamshoot")
1111                 return VOICETYPE_LASTATTACKER;
1112         return VOICETYPE_TEAMRADIO;
1113 }
1114
1115 string allvoicesamples;
1116 float GetPlayerSoundSampleField_notFound;
1117 float GetPlayerSoundSampleField_fixed;
1118 .string GetVoiceMessageSampleField(string type)
1119 {
1120         GetPlayerSoundSampleField_notFound = 0;
1121         GetPlayerSoundSampleField_fixed = 0;
1122         switch(type)
1123         {
1124 #define _VOICEMSG(m) case #m: return playersound_##m;
1125                 ALLVOICEMSGS
1126 #undef _VOICEMSG
1127         }
1128         GetPlayerSoundSampleField_notFound = 1;
1129         return playersound_taunt;
1130 }
1131
1132 .string GetPlayerSoundSampleField(string type)
1133 {
1134         GetPlayerSoundSampleField_notFound = 0;
1135         GetPlayerSoundSampleField_fixed = 0;
1136         switch(type)
1137         {
1138 #define _VOICEMSG(m) case #m: return playersound_##m;
1139                 ALLPLAYERSOUNDS
1140 #undef _VOICEMSG
1141         }
1142         GetPlayerSoundSampleField_notFound = 1;
1143         return playersound_taunt;
1144 }
1145
1146 void PrecacheGlobalSound(string samplestring)
1147 {
1148         float n, i;
1149         tokenize_console(samplestring);
1150         n = stof(argv(1));
1151         if(n > 0)
1152         {
1153                 for(i = 1; i <= n; ++i)
1154                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1155         }
1156         else
1157         {
1158                 precache_sound(strcat(argv(0), ".wav"));
1159         }
1160 }
1161
1162 void PrecachePlayerSounds(string f)
1163 {
1164         float fh;
1165         string s;
1166         fh = fopen(f, FILE_READ);
1167         if(fh < 0)
1168                 return;
1169         while((s = fgets(fh)))
1170         {
1171                 if(tokenize_console(s) != 3)
1172                 {
1173                         dprint("Invalid sound info line: ", s, "\n");
1174                         continue;
1175                 }
1176                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1177         }
1178         fclose(fh);
1179
1180         if not(allvoicesamples)
1181         {
1182 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1183                 ALLVOICEMSGS
1184 #undef _VOICEMSG
1185                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1186         }
1187 }
1188
1189 void ClearPlayerSounds()
1190 {
1191 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1192         ALLPLAYERSOUNDS
1193         ALLVOICEMSGS
1194 #undef _VOICEMSG
1195 }
1196
1197 void LoadPlayerSounds(string f, float first)
1198 {
1199         float fh;
1200         string s;
1201         var .string field;
1202         fh = fopen(f, FILE_READ);
1203         if(fh < 0)
1204         {
1205                 dprint("Player sound file not found: ", f, "\n");
1206                 return;
1207         }
1208         while((s = fgets(fh)))
1209         {
1210                 if(tokenize_console(s) != 3)
1211                         continue;
1212                 field = GetPlayerSoundSampleField(argv(0));
1213                 if(GetPlayerSoundSampleField_notFound)
1214                         field = GetVoiceMessageSampleField(argv(0));
1215                 if(GetPlayerSoundSampleField_notFound)
1216                         continue;
1217                 if(GetPlayerSoundSampleField_fixed)
1218                         if not(first)
1219                                 continue;
1220                 if(self.field)
1221                         strunzone(self.field);
1222                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1223         }
1224         fclose(fh);
1225 }
1226
1227 .float modelindex_for_playersound;
1228 .float skinindex_for_playersound;
1229 void UpdatePlayerSounds()
1230 {
1231         if(self.modelindex == self.modelindex_for_playersound)
1232         if(self.skinindex == self.skinindex_for_playersound)
1233                 return;
1234         self.modelindex_for_playersound = self.modelindex;
1235         self.skinindex_for_playersound = self.skinindex;
1236         ClearPlayerSounds();
1237         LoadPlayerSounds("sound/player/default.sounds", 1);
1238         LoadPlayerSounds(get_model_datafilename(self.playermodel, self.skinindex, "sounds"), 0);
1239 }
1240
1241 void FakeGlobalSound(string sample, float chan, float voicetype)
1242 {
1243         float n;
1244         float tauntrand;
1245
1246         if(sample == "")
1247                 return;
1248
1249         tokenize_console(sample);
1250         n = stof(argv(1));
1251         if(n > 0)
1252                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1253         else
1254                 sample = strcat(argv(0), ".wav"); // randomization
1255
1256         switch(voicetype)
1257         {
1258                 case VOICETYPE_LASTATTACKER_ONLY:
1259                         break;
1260                 case VOICETYPE_LASTATTACKER:
1261                         if(self.pusher)
1262                         {
1263                                 msg_entity = self;
1264                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1265                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1266                         }
1267                         break;
1268                 case VOICETYPE_TEAMRADIO:
1269                         msg_entity = self;
1270                         if(msg_entity.cvar_cl_voice_directional == 1)
1271                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1272                         else
1273                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1274                         break;
1275                 case VOICETYPE_AUTOTAUNT:
1276                         if(!sv_autotaunt)
1277                                 break;
1278                         if(!sv_taunt)
1279                                 break;
1280                         if(sv_gentle)
1281                                 break;
1282                         tauntrand = random();
1283                         msg_entity = self;
1284                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1285                         {
1286                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1287                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1288                                 else
1289                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1290                         }
1291                         break;
1292                 case VOICETYPE_TAUNT:
1293                         if(self.classname == "player")
1294                                 if(self.deadflag == DEAD_NO)
1295                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1296                         if(!sv_taunt)
1297                                 break;
1298                         if(sv_gentle)
1299                                 break;
1300                         msg_entity = self;
1301                         if (msg_entity.cvar_cl_voice_directional >= 1)
1302                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1303                         else
1304                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1305                         break;
1306                 case VOICETYPE_PLAYERSOUND:
1307                         msg_entity = self;
1308                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1309                         break;
1310                 default:
1311                         backtrace("Invalid voice type!");
1312                         break;
1313         }
1314 }
1315
1316 void GlobalSound(string sample, float chan, float voicetype)
1317 {
1318         float n;
1319         float tauntrand;
1320
1321         if(sample == "")
1322                 return;
1323
1324         tokenize_console(sample);
1325         n = stof(argv(1));
1326         if(n > 0)
1327                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1328         else
1329                 sample = strcat(argv(0), ".wav"); // randomization
1330
1331         switch(voicetype)
1332         {
1333                 case VOICETYPE_LASTATTACKER_ONLY:
1334                         if(self.pusher)
1335                         {
1336                                 msg_entity = self.pusher;
1337                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1338                                 {
1339                                         if(msg_entity.cvar_cl_voice_directional == 1)
1340                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1341                                         else
1342                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1343                                 }
1344                         }
1345                         break;
1346                 case VOICETYPE_LASTATTACKER:
1347                         if(self.pusher)
1348                         {
1349                                 msg_entity = self.pusher;
1350                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1351                                 {
1352                                         if(msg_entity.cvar_cl_voice_directional == 1)
1353                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1354                                         else
1355                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1356                                 }
1357                                 msg_entity = self;
1358                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1359                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1360                         }
1361                         break;
1362                 case VOICETYPE_TEAMRADIO:
1363                         FOR_EACH_REALCLIENT(msg_entity)
1364                                 if(!teams_matter || msg_entity.team == self.team)
1365                                 {
1366                                         if(msg_entity.cvar_cl_voice_directional == 1)
1367                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1368                                         else
1369                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1370                                 }
1371                         break;
1372                 case VOICETYPE_AUTOTAUNT:
1373                         if(!sv_autotaunt)
1374                                 break;
1375                         if(!sv_taunt)
1376                                 break;
1377                         if(sv_gentle)
1378                                 break;
1379                         tauntrand = random();
1380                         FOR_EACH_REALCLIENT(msg_entity)
1381                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1382                                 {
1383                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1384                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1385                                         else
1386                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1387                                 }
1388                         break;
1389                 case VOICETYPE_TAUNT:
1390                         if(self.classname == "player")
1391                                 if(self.deadflag == DEAD_NO)
1392                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1393                         if(!sv_taunt)
1394                                 break;
1395                         if(sv_gentle)
1396                                 break;
1397                         FOR_EACH_REALCLIENT(msg_entity)
1398                         {
1399                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1400                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1401                                 else
1402                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1403                         }
1404                         break;
1405                 case VOICETYPE_PLAYERSOUND:
1406                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1407                         break;
1408                 default:
1409                         backtrace("Invalid voice type!");
1410                         break;
1411         }
1412 }
1413
1414 void PlayerSound(.string samplefield, float chan, float voicetype)
1415 {
1416         GlobalSound(self.samplefield, chan, voicetype);
1417 }
1418
1419 void VoiceMessage(string type, string msg)
1420 {
1421         var .string sample;
1422         float voicetype, ownteam;
1423         float flood;
1424         sample = GetVoiceMessageSampleField(type);
1425
1426         if(GetPlayerSoundSampleField_notFound)
1427         {
1428                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1429                 return;
1430         }
1431
1432         voicetype = GetVoiceMessageVoiceType(type);
1433         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1434
1435         flood = Say(self, ownteam, world, msg, 1);
1436
1437         if (flood > 0)
1438                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1439         else if (flood < 0)
1440                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1441 }
1442
1443 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1444 {
1445 //      show_message
1446 //      0 (00) automove centerprint, admin message
1447 //      1 (01) automove centerprint, no admin message
1448 //      2 (10) no centerprint, admin message
1449 //      3 (11) no centerprint, no admin message
1450
1451         float lockteams_backup;
1452
1453         lockteams_backup = lockteams;  // backup any team lock
1454
1455         lockteams = 0;  // disable locked teams
1456
1457         TeamchangeFrags(client);  // move the players frags
1458         SetPlayerColors(client, team_colour - 1);  // set the players colour
1459         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1460
1461         lockteams = lockteams_backup;  // restore the team lock
1462
1463         LogTeamchange(client.playerid, client.team, type);
1464
1465         if not(show_message & 1) // admin message
1466                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1467
1468         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1469 }