qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 .float CopyBody_nextthink;
 128 .void(void) CopyBody_think;
 129 void CopyBody_Think(void)
 130 {
 131         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 132         {
 133                 self.CopyBody_think();
 134                 if(wasfreed(self))
 135                         return;
 136                 self.CopyBody_nextthink = self.nextthink;
 137                 self.CopyBody_think = self.think;
 138                 self.think = CopyBody_Think;
 139         }
 140         CSQCMODEL_AUTOUPDATE();
 141         self.nextthink = time;
 142 }
 143 void CopyBody(float keepvelocity)
 144 {
 145         entity oldself;
 146         if (self.effects & EF_NODRAW)
 147                 return;
 148         oldself = self;
 149         self = spawn();
 150         self.enemy = oldself;
 151         self.lip = oldself.lip;
 152         self.colormap = oldself.colormap;
 153         self.iscreature = oldself.iscreature;
 154         self.damagedbycontents = oldself.damagedbycontents;
 155         self.angles = oldself.angles;
 156         self.avelocity = oldself.avelocity;
 157         self.classname = "body";
 158         self.damageforcescale = oldself.damageforcescale;
 159         self.effects = oldself.effects;
 160         self.glowmod = oldself.glowmod;
 161         self.event_damage = oldself.event_damage;
 162         self.animstate_startframe = oldself.animstate_startframe;
 163         self.animstate_numframes = oldself.animstate_numframes;
 164         self.animstate_framerate = oldself.animstate_framerate;
 165         self.animstate_starttime = oldself.animstate_starttime;
 166         self.animstate_endtime = oldself.animstate_endtime;
 167         self.animstate_override = oldself.animstate_override;
 168         self.animstate_looping = oldself.animstate_looping;
 169         self.frame = oldself.frame;
 170         self.dead_frame = oldself.dead_frame;
 171         self.pain_finished = oldself.pain_finished;
 172         self.health = oldself.health;
 173         self.armorvalue = oldself.armorvalue;
 174         self.armortype = oldself.armortype;
 175         self.model = oldself.model;
 176         self.modelindex = oldself.modelindex;
 177         self.skin = oldself.skin;
 178         self.species = oldself.species;
 179         self.movetype = oldself.movetype;
 180         self.solid = oldself.solid;
 181         self.ballistics_density = oldself.ballistics_density;
 182         self.takedamage = oldself.takedamage;
 183         self.customizeentityforclient = oldself.customizeentityforclient;
 184         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 185         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 186         if (keepvelocity == 1)
 187                 self.velocity = oldself.velocity;
 188         self.oldvelocity = self.velocity;
 189         self.fade_time = oldself.fade_time;
 190         self.fade_rate = oldself.fade_rate;
 191         //self.weapon = oldself.weapon;
 192         setorigin(self, oldself.origin);
 193         setsize(self, oldself.mins, oldself.maxs);
 194         self.prevorigin = oldself.origin;
 195         self.reset = SUB_Remove;
 196
 197         Drag_MoveDrag(oldself, self);
 198
 199         if(self.colormap <= maxclients && self.colormap > 0)
 200                 self.colormap = 1024 + self.clientcolors;
 201
 202         CSQCMODEL_AUTOINIT();
 203         self.CopyBody_nextthink = oldself.nextthink;
 204         self.CopyBody_think = oldself.think;
 205         self.nextthink = time;
 206         self.think = CopyBody_Think;
 207
 208         self = oldself;
 209 }
 210
 211 float player_getspecies()
 212 {
 213         float s;
 214         get_model_parameters(self.model, self.skin);
 215         s = get_model_parameters_species;
 216         get_model_parameters(string_null, 0);
 217         if(s < 0)
 218                 return SPECIES_HUMAN;
 219         return s;
 220 }
 221
 222 void player_setupanimsformodel()
 223 {
 224         // defaults for legacy .zym models without animinfo files
 225         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 226         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 227         self.anim_draw = animfixfps(self, '2 1 3');
 228         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 229         self.anim_duckwalk = animfixfps(self, '4 1 1');
 230         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 231         self.anim_duckidle = animfixfps(self, '6 1 1');
 232         self.anim_idle = animfixfps(self, '7 1 1');
 233         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 234         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 235         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 236         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 237         self.anim_taunt = animfixfps(self, '12 1 0.33');
 238         self.anim_run = animfixfps(self, '13 1 1');
 239         self.anim_runbackwards = animfixfps(self, '14 1 1');
 240         self.anim_strafeleft = animfixfps(self, '15 1 1');
 241         self.anim_straferight = animfixfps(self, '16 1 1');
 242         self.anim_dead1 = animfixfps(self, '17 1 1');
 243         self.anim_dead2 = animfixfps(self, '18 1 1');
 244         self.anim_forwardright = animfixfps(self, '19 1 1');
 245         self.anim_forwardleft = animfixfps(self, '20 1 1');
 246         self.anim_backright = animfixfps(self, '21 1 1');
 247         self.anim_backleft  = animfixfps(self, '22 1 1');
 248         self.anim_melee = animfixfps(self, '23 1 1');
 249         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 250         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 251         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 252         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 253         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 254         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 255         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 256         // TODO introspect models for finding right "fps" value (1/duration)
 257         // reset animstate now
 258         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 259 }
 260
 261 void player_anim (void)
 262 {
 263         updateanim(self);
 264         if (self.weaponentity)
 265                 updateanim(self.weaponentity);
 266
 267         if (self.deadflag != DEAD_NO)
 268         {
 269                 if (time > self.animstate_endtime)
 270                 {
 271                         if (self.maxs_z > 5)
 272                         {
 273                                 self.maxs_z = 5;
 274                                 setsize(self, self.mins, self.maxs);
 275                         }
 276                         self.frame = self.dead_frame;
 277                 }
 278                 return;
 279         }
 280
 281         if (!self.animstate_override)
 282         {
 283                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 284                 {
 285                         if (self.crouch)
 286                         {
 287                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 288                                 {
 289                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 290                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 291                                         {
 292                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 293                                                 self.restart_jump = FALSE;
 294                                         }
 295                                 }
 296                         }
 297                         else
 298                         {
 299                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 300                 {
 301                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 302                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 303                     {
 304                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 305                         self.restart_jump = FALSE;
 306                     }
 307                 }
 308                         }
 309                 }
 310                 else if (self.crouch)
 311                 {
 312                         if (self.movement_x > 0 && self.movement_y == 0)
 313                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 314                         else if (self.movement_x < 0 && self.movement_y == 0)
 315                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 316                         else if (self.movement_x == 0 && self.movement_y > 0)
 317                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 318                         else if (self.movement_x == 0 && self.movement_y < 0)
 319                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 320                         else if (self.movement_x > 0 && self.movement_y > 0)
 321                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 322                         else if (self.movement_x > 0 && self.movement_y < 0)
 323                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 324                         else if (self.movement_x < 0 && self.movement_y > 0)
 325                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 326                         else if (self.movement_x < 0 && self.movement_y < 0)
 327                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 328                         else
 329                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 330                 }
 331                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 332                 {
 333                         if (self.movement_x > 0 && self.movement_y == 0)
 334                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 335                         else if (self.movement_x < 0 && self.movement_y == 0)
 336                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 337                         else if (self.movement_x == 0 && self.movement_y > 0)
 338                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 339                         else if (self.movement_x == 0 && self.movement_y < 0)
 340                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 341                         else if (self.movement_x > 0 && self.movement_y > 0)
 342                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 343                         else if (self.movement_x > 0 && self.movement_y < 0)
 344                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 345                         else if (self.movement_x < 0 && self.movement_y > 0)
 346                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 347                         else if (self.movement_x < 0 && self.movement_y < 0)
 348                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 349                         else
 350                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 351                 }
 352                 else
 353                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 354         }
 355
 356         if (self.weaponentity)
 357         if (!self.weaponentity.animstate_override)
 358                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 359 }
 360
 361 void SpawnThrownWeapon (vector org, float w)
 362 {
 363         if(g_minstagib)
 364         if(self.ammo_cells <= 0)
 365                 return;
 366
 367         if(g_pinata)
 368         {
 369                 float j;
 370                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 371                 {
 372                         if(self.weapons & W_WeaponBit(j))
 373                                 if(W_IsWeaponThrowable(j))
 374                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 375                 }
 376         }
 377         else
 378         {
 379                 if(W_IsWeaponThrowable(self.weapon))
 380                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 381         }
 382 }
 383
 384 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 385 {
 386         float take, save;
 387         vector v;
 388         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 389
 390         // damage resistance (ignore most of the damage from a bullet or similar)
 391         damage = max(damage - 5, 1);
 392
 393         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 394         take = v_x;
 395         save = v_y;
 396
 397         if(sound_allowed(MSG_BROADCAST, attacker))
 398         {
 399                 if (save > 10)
 400                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 401                 else if (take > 30)
 402                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 403                 else if (take > 10)
 404                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 405         }
 406
 407         if (take > 50)
 408                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 409         if (take > 100)
 410                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 411
 412         if (!(self.flags & FL_GODMODE))
 413         {
 414                 self.armorvalue = self.armorvalue - save;
 415                 self.health = self.health - take;
 416                 // pause regeneration for 5 seconds
 417                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 418         }
 419         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 420         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 421         self.dmg_inflictor = inflictor;
 422
 423         if (self.health <= -autocvar_sv_gibhealth && !(self.effects & CSQCMODEL_EF_INVISIBLE))
 424         {
 425                 // don't use any animations as a gib
 426                 self.frame = 0;
 427                 self.dead_frame = 0;
 428                 // view just above the floor
 429                 self.view_ofs = '0 0 4';
 430
 431                 Violence_GibSplash(self, 1, 1, attacker);
 432                 self.effects |= CSQCMODEL_EF_INVISIBLE;
 433                 self.solid = SOLID_NOT; // restore later
 434         }
 435 }
 436
 437 void ClientKill_Now_TeamChange();
 438 void freezetag_CheckWinner();
 439
 440 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 441 {
 442         float take, save, waves, sdelay, dh, da, j;
 443         vector v;
 444         float valid_damage_for_weaponstats;
 445         float excess;
 446
 447         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 448                 return;
 449
 450         dh = max(self.health, 0);
 451         da = max(self.armorvalue, 0);
 452
 453         if(!DEATH_ISSPECIAL(deathtype))
 454         {
 455                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 456                 if(self != attacker)
 457                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 458         }
 459
 460         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 461         {
 462                 // tuba causes blood to come out of the ears
 463                 vector ear1, ear2;
 464                 vector d;
 465                 float f;
 466                 ear1 = self.origin;
 467                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 468                 ear2 = ear1;
 469                 makevectors(self.angles);
 470                 ear1 += v_right * -10;
 471                 ear2 += v_right * +10;
 472                 d = inflictor.origin - self.origin;
 473                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 474                 force = v_right * vlen(force);
 475                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 476                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 477                 if(f > 0)
 478                 {
 479                         hitloc = ear1;
 480                         force = force * -1;
 481                 }
 482                 else
 483                 {
 484                         hitloc = ear2;
 485                         // force is already good
 486                 }
 487         }
 488         else
 489                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 490
 491         if (!g_minstagib)
 492         {
 493                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 494                 take = v_x;
 495                 save = v_y;
 496         }
 497         else
 498         {
 499                 save = 0;
 500                 take = damage;
 501         }
 502
 503         frag_inflictor = inflictor;
 504         frag_attacker = attacker;
 505         frag_target = self;
 506         damage_take = take;
 507         damage_save = save;
 508         damage_force = force;
 509         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 510         take = bound(0, damage_take, self.health);
 511         save = bound(0, damage_save, self.armorvalue);
 512         excess = max(0, damage - take - save);
 513
 514         if(sound_allowed(MSG_BROADCAST, attacker))
 515         {
 516                 if (save > 10)
 517                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 518                 else if (take > 30)
 519                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 520                 else if (take > 10)
 521                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 522         }
 523
 524         if (take > 50)
 525                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 526         if (take > 100)
 527                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 528
 529         if (time >= self.spawnshieldtime)
 530         {
 531                 if (!(self.flags & FL_GODMODE))
 532                 {
 533                         self.armorvalue = self.armorvalue - save;
 534                         self.health = self.health - take;
 535                         // pause regeneration for 5 seconds
 536                         if(take)
 537                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 538
 539                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 540                         {
 541                                 self.pain_finished = time + 0.5;        //Supajoe
 542
 543                                 if(sv_gentle < 1) {
 544                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 545                                         {
 546                                                 if (!self.animstate_override)
 547                                                 {
 548                                                         if (random() > 0.5)
 549                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 550                                                         else
 551                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 552                                                 }
 553                                         }
 554
 555                                         if(sound_allowed(MSG_BROADCAST, attacker))
 556                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 557                                         if(self.health > 1)
 558                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 559                                         {
 560                                                 if(deathtype == DEATH_FALL)
 561                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 562                                                 else if(self.health > 75) // TODO make a "gentle" version?
 563                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 564                                                 else if(self.health > 50)
 565                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 566                                                 else if(self.health > 25)
 567                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 568                                                 else
 569                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 570                                         }
 571                                 }
 572
 573                                 // throw off bot aim temporarily
 574                                 float shake;
 575                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 576                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 577                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 578                         }
 579                 }
 580                 else
 581                         self.max_armorvalue += (save + take);
 582         }
 583         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 584         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 585         self.dmg_inflictor = inflictor;
 586
 587         if(attacker == self)
 588         {
 589                 // don't reset pushltime for self damage as it may be an attempt to
 590                 // escape a lava pit or similar
 591                 //self.pushltime = 0;
 592         }
 593         else if(attacker.classname == "player")
 594         {
 595                 self.pusher = attacker;
 596                 self.pushltime = time + autocvar_g_maxpushtime;
 597         }
 598         else if(time < self.pushltime)
 599         {
 600                 attacker = self.pusher;
 601                 self.pushltime = max(self.pushltime, time + 0.6);
 602         }
 603         else
 604                 self.pushltime = 0;
 605
 606         float abot, vbot, awep;
 607         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 608         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 609
 610         valid_damage_for_weaponstats = 0;
 611         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 612         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 613         if(attacker && self != attacker)
 614         if(IsDifferentTeam(self, attacker))
 615         {
 616                 if(DEATH_ISSPECIAL(deathtype))
 617                         awep = attacker.weapon;
 618                 else
 619                         awep = DEATH_WEAPONOF(deathtype);
 620                 valid_damage_for_weaponstats = 1;
 621         }
 622
 623         if(valid_damage_for_weaponstats)
 624         {
 625                 dh = dh - max(self.health, 0);
 626                 da = da - max(self.armorvalue, 0);
 627                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 628         }
 629
 630         if (self.health < 1)
 631         {
 632                 float defer_ClientKill_Now_TeamChange;
 633                 defer_ClientKill_Now_TeamChange = FALSE;
 634
 635                 if(self.alivetime)
 636                 {
 637                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 638                         self.alivetime = 0;
 639                 }
 640
 641                 if(valid_damage_for_weaponstats)
 642                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 643
 644                 if(sv_gentle < 1) // TODO make a "gentle" version?
 645                 if(sound_allowed(MSG_BROADCAST, attacker))
 646                 {
 647                         if(deathtype == DEATH_DROWN)
 648                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 649                         else
 650                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 651                 }
 652
 653                 // get rid of kill indicator
 654                 if(self.killindicator)
 655                 {
 656                         remove(self.killindicator);
 657                         self.killindicator = world;
 658                         if(self.killindicator_teamchange)
 659                                 defer_ClientKill_Now_TeamChange = TRUE;
 660
 661                         if(self.classname == "body")
 662                         if(deathtype == DEATH_KILL)
 663                         {
 664                                 // for the lemmings fans, a small harmless explosion
 665                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 666                         }
 667                 }
 668
 669                 if(!g_freezetag)
 670                 {
 671                         // become fully visible
 672                         self.alpha = 1;
 673                         // throw a weapon
 674                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 675                 }
 676
 677                 // print an obituary message
 678                 Obituary (attacker, inflictor, self, deathtype);
 679                 race_PreDie();
 680                 DropAllRunes(self);
 681
 682         // increment frag counter for used weapon type
 683         float w;
 684         w = DEATH_WEAPONOF(deathtype);
 685         if(WEP_VALID(w))
 686         if(accuracy_isgooddamage(attacker, self))
 687         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 688
 689                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 690                 {
 691                         PutClientInServer();
 692                         count_alive_players(); // re-count players
 693                         freezetag_CheckWinner();
 694                         return;
 695                 }
 696
 697                 frag_attacker = attacker;
 698                 frag_inflictor = inflictor;
 699                 frag_target = self;
 700                 MUTATOR_CALLHOOK(PlayerDies);
 701                 weapon_action(self.weapon, WR_PLAYERDEATH);
 702
 703                 RemoveGrapplingHook(self);
 704
 705                 if(self.flagcarried)
 706                 {
 707                         if(attacker.classname != "player")
 708                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 709                         else if(attacker.team == self.team)
 710                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 711                         else
 712                                 DropFlag(self.flagcarried, world, attacker);
 713                 }
 714                 if(self.ballcarried && g_nexball)
 715                         DropBall(self.ballcarried, self.origin, self.velocity);
 716                 Portal_ClearAllLater(self);
 717
 718                 if(clienttype(self) == CLIENTTYPE_REAL)
 719                 {
 720                         stuffcmd(self, "-zoom\n");
 721                         self.fixangle = TRUE;
 722                         //msg_entity = self;
 723                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 724                         //WriteAngle (MSG_ONE, self.v_angle_x);
 725                         //WriteAngle (MSG_ONE, self.v_angle_y);
 726                         //WriteAngle (MSG_ONE, 80);
 727                 }
 728
 729                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 730                         ClientKill_Now_TeamChange();
 731
 732                 if(g_arena)
 733                         Spawnqueue_Unmark(self);
 734
 735                 if(g_freezetag)
 736                         return;
 737
 738                 // when we get here, player actually dies
 739                 // clear waypoints (do this AFTER FreezeTag)
 740                 WaypointSprite_PlayerDead();
 741
 742                 // make the corpse upright (not tilted)
 743                 self.angles_x = 0;
 744                 self.angles_z = 0;
 745                 // don't spin
 746                 self.avelocity = '0 0 0';
 747                 // view from the floor
 748                 self.view_ofs = '0 0 -8';
 749                 // toss the corpse
 750                 self.movetype = MOVETYPE_TOSS;
 751                 // shootable corpse
 752                 self.solid = SOLID_CORPSE;
 753                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 754                 // don't stick to the floor
 755                 self.flags &~= FL_ONGROUND;
 756                 // dying animation
 757                 self.deadflag = DEAD_DYING;
 758                 // when to allow respawn
 759                 sdelay = 0;
 760                 waves = 0;
 761                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 762                 if(!sdelay)
 763                 {
 764                         if(g_cts)
 765                                 sdelay = 0; // no respawn delay in CTS
 766                         else
 767                                 sdelay = autocvar_g_respawn_delay;
 768                 }
 769                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 770                 if(!waves)
 771                         waves = autocvar_g_respawn_waves;
 772                 if(waves)
 773                         self.death_time = ceil((time + sdelay) / waves) * waves;
 774                 else
 775                         self.death_time = time + sdelay;
 776                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 777                         self.respawn_countdown = 10; // first number to count down from is 10
 778                 else
 779                         self.respawn_countdown = -1; // do not count down
 780                 if (random() < 0.5)
 781                 {
 782                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 783                         self.dead_frame = self.anim_dead1_x;
 784                 }
 785                 else
 786                 {
 787                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 788                         self.dead_frame = self.anim_dead2_x;
 789                 }
 790                 // set damage function to corpse damage
 791                 self.event_damage = PlayerCorpseDamage;
 792                 // call the corpse damage function just in case it wants to gib
 793                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 794                 // set up to fade out later
 795                 SUB_SetFade (self, time + 6 + random (), 1);
 796
 797                 if(sv_gentle > 0 || autocvar_ekg) {
 798                         // remove corpse
 799                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 800                 }
 801
 802                 // reset fields the weapons may use just in case
 803                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 804                 {
 805                         weapon_action(j, WR_RESETPLAYER);
 806                         ATTACK_FINISHED_FOR(self, j) = 0;
 807                 }
 808         }
 809 }
 810
 811 .float muted; // to be used by prvm_edictset server playernumber muted 1
 812 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 813 // message "": do not say, just test flood control
 814 // return value:
 815 //   1 = accept
 816 //   0 = reject
 817 //  -1 = fake accept
 818 {
 819         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 820         float flood, privatemsgprefixlen;
 821         var .float flood_field;
 822         entity head;
 823         float ret;
 824
 825         if(Ban_MaybeEnforceBan(source))
 826                 return 0;
 827
 828         if(!teamsay && !privatesay)
 829                 if(substring(msgin, 0, 1) == " ")
 830                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 831
 832         msgin = formatmessage(msgin);
 833
 834         if(source.classname != "player")
 835                 colorstr = "^0"; // black for spectators
 836         else if(teamplay)
 837                 colorstr = Team_ColorCode(source.team);
 838         else
 839                 teamsay = FALSE;
 840
 841         if(intermission_running)
 842                 teamsay = FALSE;
 843
 844         if(msgin != "")
 845                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 846
 847         /*
 848          * using bprint solves this... me stupid
 849         // how can we prevent the message from appearing in a listen server?
 850         // for now, just give "say" back and only handle say_team
 851         if(!teamsay)
 852         {
 853                 clientcommand(self, strcat("say ", msgin));
 854                 return;
 855         }
 856         */
 857
 858         if(autocvar_g_chat_teamcolors)
 859                 namestr = playername(source);
 860         else
 861                 namestr = source.netname;
 862
 863         if(msgin != "")
 864         {
 865                 if(privatesay)
 866                 {
 867                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 868                         privatemsgprefixlen = strlen(msgstr);
 869                         msgstr = strcat(msgstr, msgin);
 870                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 871                         if(autocvar_g_chat_teamcolors)
 872                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 873                         else
 874                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 875                 }
 876                 else if(teamsay)
 877                 {
 878                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 879                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 880                 }
 881                 else
 882                 {
 883                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 884                         cmsgstr = "";
 885                 }
 886                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 887         }
 888         else
 889         {
 890                 msgstr = cmsgstr = "";
 891         }
 892
 893         fullmsgstr = msgstr;
 894         fullcmsgstr = cmsgstr;
 895
 896         // FLOOD CONTROL
 897         flood = 0;
 898         if(floodcontrol)
 899         {
 900                 float flood_spl;
 901                 float flood_burst;
 902                 float flood_lmax;
 903                 float lines;
 904                 if(privatesay)
 905                 {
 906                         flood_spl = autocvar_g_chat_flood_spl_tell;
 907                         flood_burst = autocvar_g_chat_flood_burst_tell;
 908                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 909                         flood_field = floodcontrol_chattell;
 910                 }
 911                 else if(teamsay)
 912                 {
 913                         flood_spl = autocvar_g_chat_flood_spl_team;
 914                         flood_burst = autocvar_g_chat_flood_burst_team;
 915                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 916                         flood_field = floodcontrol_chatteam;
 917                 }
 918                 else
 919                 {
 920                         flood_spl = autocvar_g_chat_flood_spl;
 921                         flood_burst = autocvar_g_chat_flood_burst;
 922                         flood_lmax = autocvar_g_chat_flood_lmax;
 923                         flood_field = floodcontrol_chat;
 924                 }
 925                 flood_burst = max(0, flood_burst - 1);
 926                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 927
 928                 // do flood control for the default line size
 929                 if(msgstr != "")
 930                 {
 931                         getWrappedLine_remaining = msgstr;
 932                         msgstr = "";
 933                         lines = 0;
 934                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 935                         {
 936                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 937                                 ++lines;
 938                         }
 939                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 940
 941                         if(getWrappedLine_remaining != "")
 942                         {
 943                                 msgstr = strcat(msgstr, "\n");
 944                                 flood = 2;
 945                         }
 946
 947                         if(time >= source.flood_field)
 948                         {
 949                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 950                         }
 951                         else
 952                         {
 953                                 flood = 1;
 954                                 msgstr = fullmsgstr;
 955                         }
 956                 }
 957                 else
 958                 {
 959                         if(time >= source.flood_field)
 960                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 961                         else
 962                                 flood = 1;
 963                 }
 964
 965                 if (timeoutStatus == 2) //when game is paused, no flood protection
 966                         source.flood_field = flood = 0;
 967         }
 968
 969         if(flood == 2) // cannot happen for empty msgstr
 970         {
 971                 if(autocvar_g_chat_flood_notify_flooder)
 972                 {
 973                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 974                         sourcecmsgstr = "";
 975                 }
 976                 else
 977                 {
 978                         sourcemsgstr = fullmsgstr;
 979                         sourcecmsgstr = fullcmsgstr;
 980                 }
 981                 cmsgstr = "";
 982         }
 983         else
 984         {
 985                 sourcemsgstr = msgstr;
 986                 sourcecmsgstr = cmsgstr;
 987         }
 988
 989         if(!privatesay)
 990         if(source.classname != "player")
 991         {
 992                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 993                         teamsay = -1; // spectators
 994         }
 995
 996         if(flood)
 997                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 998
 999         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1000         if(privatesay)
1001                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1002
1003         if(source.muted)
1004         {
1005                 // always fake the message
1006                 ret = -1;
1007         }
1008         else if(flood == 1)
1009         {
1010                 if(autocvar_g_chat_flood_notify_flooder)
1011                 {
1012                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1013                         ret = 0;
1014                 }
1015                 else
1016                         ret = -1;
1017         }
1018         else
1019         {
1020                 ret = 1;
1021         }
1022
1023         if(sourcemsgstr != "" && ret != 0)
1024         {
1025                 if(ret < 0) // fake
1026                 {
1027                         sprint(source, sourcemsgstr);
1028                         if(sourcecmsgstr != "" && !privatesay)
1029                                 centerprint(source, sourcecmsgstr);
1030                 }
1031                 else if(privatesay)
1032                 {
1033                         sprint(source, sourcemsgstr);
1034                         sprint(privatesay, msgstr);
1035                         if(cmsgstr != "")
1036                                 centerprint(privatesay, cmsgstr);
1037                 }
1038                 else if(teamsay > 0)
1039                 {
1040                         sprint(source, sourcemsgstr);
1041                         if(sourcecmsgstr != "")
1042                                 centerprint(source, sourcecmsgstr);
1043                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1044                                 if(head != source)
1045                                 {
1046                                         sprint(head, msgstr);
1047                                         if(cmsgstr != "")
1048                                                 centerprint(head, cmsgstr);
1049                                 }
1050                 }
1051                 else if(teamsay < 0)
1052                 {
1053                         sprint(source, sourcemsgstr);
1054                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1055                                 if(head != source)
1056                                         sprint(head, msgstr);
1057                 }
1058                 else if(sourcemsgstr != msgstr)
1059                 {
1060                         sprint(source, sourcemsgstr);
1061                         FOR_EACH_REALCLIENT(head)
1062                                 if(head != source)
1063                                         sprint(head, msgstr);
1064                 }
1065                 else
1066                         bprint(msgstr);
1067         }
1068
1069         return ret;
1070 }
1071
1072 float GetVoiceMessageVoiceType(string type)
1073 {
1074         if(type == "taunt")
1075                 return VOICETYPE_TAUNT;
1076         if(type == "teamshoot")
1077                 return VOICETYPE_LASTATTACKER;
1078         return VOICETYPE_TEAMRADIO;
1079 }
1080
1081 string allvoicesamples;
1082 .string GetVoiceMessageSampleField(string type)
1083 {
1084         GetPlayerSoundSampleField_notFound = 0;
1085         switch(type)
1086         {
1087 #define _VOICEMSG(m) case #m: return playersound_##m;
1088                 ALLVOICEMSGS
1089 #undef _VOICEMSG
1090         }
1091         GetPlayerSoundSampleField_notFound = 1;
1092         return playersound_taunt;
1093 }
1094
1095 .string GetPlayerSoundSampleField(string type)
1096 {
1097         GetPlayerSoundSampleField_notFound = 0;
1098         switch(type)
1099         {
1100 #define _VOICEMSG(m) case #m: return playersound_##m;
1101                 ALLPLAYERSOUNDS
1102 #undef _VOICEMSG
1103         }
1104         GetPlayerSoundSampleField_notFound = 1;
1105         return playersound_taunt;
1106 }
1107
1108 void PrecacheGlobalSound(string samplestring)
1109 {
1110         float n, i;
1111         tokenize_console(samplestring);
1112         n = stof(argv(1));
1113         if(n > 0)
1114         {
1115                 for(i = 1; i <= n; ++i)
1116                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1117         }
1118         else
1119         {
1120                 precache_sound(strcat(argv(0), ".wav"));
1121         }
1122 }
1123
1124 void PrecachePlayerSounds(string f)
1125 {
1126         float fh;
1127         string s;
1128         fh = fopen(f, FILE_READ);
1129         if(fh < 0)
1130                 return;
1131         while((s = fgets(fh)))
1132         {
1133                 if(tokenize_console(s) != 3)
1134                 {
1135                         dprint("Invalid sound info line: ", s, "\n");
1136                         continue;
1137                 }
1138                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1139         }
1140         fclose(fh);
1141
1142         if not(allvoicesamples)
1143         {
1144 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1145                 ALLVOICEMSGS
1146 #undef _VOICEMSG
1147                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1148         }
1149 }
1150
1151 void ClearPlayerSounds()
1152 {
1153 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1154         ALLPLAYERSOUNDS
1155         ALLVOICEMSGS
1156 #undef _VOICEMSG
1157 }
1158
1159 float LoadPlayerSounds(string f, float first)
1160 {
1161         float fh;
1162         string s;
1163         var .string field;
1164         fh = fopen(f, FILE_READ);
1165         if(fh < 0)
1166         {
1167                 dprint("Player sound file not found: ", f, "\n");
1168                 return 0;
1169         }
1170         while((s = fgets(fh)))
1171         {
1172                 if(tokenize_console(s) != 3)
1173                         continue;
1174                 field = GetPlayerSoundSampleField(argv(0));
1175                 if(GetPlayerSoundSampleField_notFound)
1176                         field = GetVoiceMessageSampleField(argv(0));
1177                 if(GetPlayerSoundSampleField_notFound)
1178                         continue;
1179                 if(self.field)
1180                         strunzone(self.field);
1181                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1182         }
1183         fclose(fh);
1184         return 1;
1185 }
1186
1187 .float modelindex_for_playersound;
1188 .float skin_for_playersound;
1189 void UpdatePlayerSounds()
1190 {
1191         if(self.modelindex == self.modelindex_for_playersound)
1192         if(self.skin == self.skin_for_playersound)
1193                 return;
1194         self.modelindex_for_playersound = self.modelindex;
1195         self.skin_for_playersound = self.skin;
1196         ClearPlayerSounds();
1197         LoadPlayerSounds("sound/player/default.sounds", 1);
1198         if(!autocvar_g_debug_defaultsounds)
1199                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1200                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1201 }
1202
1203 void FakeGlobalSound(string sample, float chan, float voicetype)
1204 {
1205         float n;
1206         float tauntrand;
1207
1208         if(sample == "")
1209                 return;
1210
1211         tokenize_console(sample);
1212         n = stof(argv(1));
1213         if(n > 0)
1214                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1215         else
1216                 sample = strcat(argv(0), ".wav"); // randomization
1217
1218         switch(voicetype)
1219         {
1220                 case VOICETYPE_LASTATTACKER_ONLY:
1221                         break;
1222                 case VOICETYPE_LASTATTACKER:
1223                         if(self.pusher)
1224                         {
1225                                 msg_entity = self;
1226                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1227                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1228                         }
1229                         break;
1230                 case VOICETYPE_TEAMRADIO:
1231                         msg_entity = self;
1232                         if(msg_entity.cvar_cl_voice_directional == 1)
1233                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1234                         else
1235                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1236                         break;
1237                 case VOICETYPE_AUTOTAUNT:
1238                         if(!sv_autotaunt)
1239                                 break;
1240                         if(!sv_taunt)
1241                                 break;
1242                         if(sv_gentle)
1243                                 break;
1244                         tauntrand = random();
1245                         msg_entity = self;
1246                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1247                         {
1248                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1249                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1250                                 else
1251                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1252                         }
1253                         break;
1254                 case VOICETYPE_TAUNT:
1255                         if(self.classname == "player")
1256                                 if(self.deadflag == DEAD_NO)
1257                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1258                         if(!sv_taunt)
1259                                 break;
1260                         if(sv_gentle)
1261                                 break;
1262                         msg_entity = self;
1263                         if (msg_entity.cvar_cl_voice_directional >= 1)
1264                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1265                         else
1266                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1267                         break;
1268                 case VOICETYPE_PLAYERSOUND:
1269                         msg_entity = self;
1270                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1271                         break;
1272                 default:
1273                         backtrace("Invalid voice type!");
1274                         break;
1275         }
1276 }
1277
1278 void GlobalSound(string sample, float chan, float voicetype)
1279 {
1280         float n;
1281         float tauntrand;
1282
1283         if(sample == "")
1284                 return;
1285
1286         tokenize_console(sample);
1287         n = stof(argv(1));
1288         if(n > 0)
1289                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1290         else
1291                 sample = strcat(argv(0), ".wav"); // randomization
1292
1293         switch(voicetype)
1294         {
1295                 case VOICETYPE_LASTATTACKER_ONLY:
1296                         if(self.pusher)
1297                         {
1298                                 msg_entity = self.pusher;
1299                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1300                                 {
1301                                         if(msg_entity.cvar_cl_voice_directional == 1)
1302                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1303                                         else
1304                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1305                                 }
1306                         }
1307                         break;
1308                 case VOICETYPE_LASTATTACKER:
1309                         if(self.pusher)
1310                         {
1311                                 msg_entity = self.pusher;
1312                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1313                                 {
1314                                         if(msg_entity.cvar_cl_voice_directional == 1)
1315                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1316                                         else
1317                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1318                                 }
1319                                 msg_entity = self;
1320                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1321                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1322                         }
1323                         break;
1324                 case VOICETYPE_TEAMRADIO:
1325                         FOR_EACH_REALCLIENT(msg_entity)
1326                                 if(!teamplay || msg_entity.team == self.team)
1327                                 {
1328                                         if(msg_entity.cvar_cl_voice_directional == 1)
1329                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1330                                         else
1331                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1332                                 }
1333                         break;
1334                 case VOICETYPE_AUTOTAUNT:
1335                         if(!sv_autotaunt)
1336                                 break;
1337                         if(!sv_taunt)
1338                                 break;
1339                         if(sv_gentle)
1340                                 break;
1341                         tauntrand = random();
1342                         FOR_EACH_REALCLIENT(msg_entity)
1343                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1344                                 {
1345                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1346                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1347                                         else
1348                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1349                                 }
1350                         break;
1351                 case VOICETYPE_TAUNT:
1352                         if(self.classname == "player")
1353                                 if(self.deadflag == DEAD_NO)
1354                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1355                         if(!sv_taunt)
1356                                 break;
1357                         if(sv_gentle)
1358                                 break;
1359                         FOR_EACH_REALCLIENT(msg_entity)
1360                         {
1361                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1362                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1363                                 else
1364                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1365                         }
1366                         break;
1367                 case VOICETYPE_PLAYERSOUND:
1368                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1369                         break;
1370                 default:
1371                         backtrace("Invalid voice type!");
1372                         break;
1373         }
1374 }
1375
1376 void PlayerSound(.string samplefield, float chan, float voicetype)
1377 {
1378         GlobalSound(self.samplefield, chan, voicetype);
1379 }
1380
1381 void VoiceMessage(string type, string msg)
1382 {
1383         var .string sample;
1384         float voicetype, ownteam;
1385         float flood;
1386         sample = GetVoiceMessageSampleField(type);
1387
1388         if(GetPlayerSoundSampleField_notFound)
1389         {
1390                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1391                 return;
1392         }
1393
1394         voicetype = GetVoiceMessageVoiceType(type);
1395         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1396
1397         flood = Say(self, ownteam, world, msg, 1);
1398
1399         if (flood > 0)
1400                 GlobalSound(self.sample, CH_VOICE, voicetype);
1401         else if (flood < 0)
1402                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1403 }
1404
1405 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1406 {
1407 //      show_message
1408 //      0 (00) automove centerprint, admin message
1409 //      1 (01) automove centerprint, no admin message
1410 //      2 (10) no centerprint, admin message
1411 //      3 (11) no centerprint, no admin message
1412
1413         float lockteams_backup;
1414
1415         lockteams_backup = lockteams;  // backup any team lock
1416
1417         lockteams = 0;  // disable locked teams
1418
1419         TeamchangeFrags(client);  // move the players frags
1420         SetPlayerColors(client, team_colour - 1);  // set the players colour
1421         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1422
1423         lockteams = lockteams_backup;  // restore the team lock
1424
1425         LogTeamchange(client.playerid, client.team, type);
1426
1427         if not(show_message & 1) // admin message
1428                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1429
1430         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1431 }