qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 void CopyBody_Think(void)
 128 {
 129         CSQCMODEL_AUTOUPDATE();
 130         self.nextthink = time;
 131 }
 132 void CopyBody(float keepvelocity)
 133 {
 134         entity oldself;
 135         if (self.effects & EF_NODRAW)
 136                 return;
 137         oldself = self;
 138         self = spawn();
 139         self.enemy = oldself;
 140         self.lip = oldself.lip;
 141         self.colormap = oldself.colormap;
 142         self.iscreature = oldself.iscreature;
 143         self.damagedbycontents = oldself.damagedbycontents;
 144         self.angles = oldself.angles;
 145         self.avelocity = oldself.avelocity;
 146         self.classname = "body";
 147         self.damageforcescale = oldself.damageforcescale;
 148         self.effects = oldself.effects;
 149         self.glowmod = oldself.glowmod;
 150         self.event_damage = oldself.event_damage;
 151         self.animstate_startframe = oldself.animstate_startframe;
 152         self.animstate_numframes = oldself.animstate_numframes;
 153         self.animstate_framerate = oldself.animstate_framerate;
 154         self.animstate_starttime = oldself.animstate_starttime;
 155         self.animstate_endtime = oldself.animstate_endtime;
 156         self.animstate_override = oldself.animstate_override;
 157         self.animstate_looping = oldself.animstate_looping;
 158         self.frame = oldself.frame;
 159         self.dead_frame = oldself.dead_frame;
 160         self.pain_finished = oldself.pain_finished;
 161         self.health = oldself.health;
 162         self.armorvalue = oldself.armorvalue;
 163         self.armortype = oldself.armortype;
 164         self.model = oldself.model;
 165         self.modelindex = oldself.modelindex;
 166         self.skin = oldself.skin;
 167         self.species = oldself.species;
 168         self.movetype = oldself.movetype;
 169         self.solid = oldself.solid;
 170         self.ballistics_density = oldself.ballistics_density;
 171         self.takedamage = oldself.takedamage;
 172         self.customizeentityforclient = oldself.customizeentityforclient;
 173         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 174         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 175         if (keepvelocity == 1)
 176                 self.velocity = oldself.velocity;
 177         self.oldvelocity = self.velocity;
 178         self.fade_time = oldself.fade_time;
 179         self.fade_rate = oldself.fade_rate;
 180         //self.weapon = oldself.weapon;
 181         setorigin(self, oldself.origin);
 182         setsize(self, oldself.mins, oldself.maxs);
 183         self.prevorigin = oldself.origin;
 184         self.reset = SUB_Remove;
 185
 186         Drag_MoveDrag(oldself, self);
 187
 188         if(self.colormap <= maxclients && self.colormap > 0)
 189                 self.colormap = 1024 + self.clientcolors;
 190
 191         CSQCMODEL_AUTOINIT();
 192         self.nextthink = time;
 193         self.think = CopyBody_Think;
 194
 195         self = oldself;
 196 }
 197
 198 float player_getspecies()
 199 {
 200         float s;
 201         get_model_parameters(self.model, self.skin);
 202         s = get_model_parameters_species;
 203         get_model_parameters(string_null, 0);
 204         if(s < 0)
 205                 return SPECIES_HUMAN;
 206         return s;
 207 }
 208
 209 void player_setupanimsformodel()
 210 {
 211         // defaults for legacy .zym models without animinfo files
 212         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 213         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 214         self.anim_draw = animfixfps(self, '2 1 3');
 215         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 216         self.anim_duckwalk = animfixfps(self, '4 1 1');
 217         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 218         self.anim_duckidle = animfixfps(self, '6 1 1');
 219         self.anim_idle = animfixfps(self, '7 1 1');
 220         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 221         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 222         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 223         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 224         self.anim_taunt = animfixfps(self, '12 1 0.33');
 225         self.anim_run = animfixfps(self, '13 1 1');
 226         self.anim_runbackwards = animfixfps(self, '14 1 1');
 227         self.anim_strafeleft = animfixfps(self, '15 1 1');
 228         self.anim_straferight = animfixfps(self, '16 1 1');
 229         self.anim_dead1 = animfixfps(self, '17 1 1');
 230         self.anim_dead2 = animfixfps(self, '18 1 1');
 231         self.anim_forwardright = animfixfps(self, '19 1 1');
 232         self.anim_forwardleft = animfixfps(self, '20 1 1');
 233         self.anim_backright = animfixfps(self, '21 1 1');
 234         self.anim_backleft  = animfixfps(self, '22 1 1');
 235         self.anim_melee = animfixfps(self, '23 1 1');
 236         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 237         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 238         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 239         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 240         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 241         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 242         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 243         // TODO introspect models for finding right "fps" value (1/duration)
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 }
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 271                 {
 272                         if (self.crouch)
 273                         {
 274                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 275                                 {
 276                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 277                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 278                                         {
 279                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 280                                                 self.restart_jump = FALSE;
 281                                         }
 282                                 }
 283                         }
 284                         else
 285                         {
 286                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 287                 {
 288                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 289                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 290                     {
 291                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 292                         self.restart_jump = FALSE;
 293                     }
 294                 }
 295                         }
 296                 }
 297                 else if (self.crouch)
 298                 {
 299                         if (self.movement_x > 0 && self.movement_y == 0)
 300                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y == 0)
 302                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 303                         else if (self.movement_x == 0 && self.movement_y > 0)
 304                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 305                         else if (self.movement_x == 0 && self.movement_y < 0)
 306                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x > 0 && self.movement_y > 0)
 308                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x > 0 && self.movement_y < 0)
 310                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x < 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x < 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 315                         else
 316                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 317                 }
 318                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 319                 {
 320                         if (self.movement_x > 0 && self.movement_y == 0)
 321                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 322                         else if (self.movement_x < 0 && self.movement_y == 0)
 323                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 324                         else if (self.movement_x == 0 && self.movement_y > 0)
 325                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 326                         else if (self.movement_x == 0 && self.movement_y < 0)
 327                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 328                         else if (self.movement_x > 0 && self.movement_y > 0)
 329                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x > 0 && self.movement_y < 0)
 331                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x < 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x < 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 336                         else
 337                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 338                 }
 339                 else
 340                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 341         }
 342
 343         if (self.weaponentity)
 344         if (!self.weaponentity.animstate_override)
 345                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 346 }
 347
 348 void SpawnThrownWeapon (vector org, float w)
 349 {
 350         if(g_minstagib)
 351         if(self.ammo_cells <= 0)
 352                 return;
 353
 354         if(g_pinata)
 355         {
 356                 float j;
 357                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 358                 {
 359                         if(self.weapons & W_WeaponBit(j))
 360                                 if(W_IsWeaponThrowable(j))
 361                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 362                 }
 363         }
 364         else
 365         {
 366                 if(W_IsWeaponThrowable(self.weapon))
 367                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 368         }
 369 }
 370
 371 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 372 {
 373         float take, save;
 374         vector v;
 375         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 376
 377         // damage resistance (ignore most of the damage from a bullet or similar)
 378         damage = max(damage - 5, 1);
 379
 380         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 381         take = v_x;
 382         save = v_y;
 383
 384         if(sound_allowed(MSG_BROADCAST, attacker))
 385         {
 386                 if (save > 10)
 387                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 388                 else if (take > 30)
 389                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 390                 else if (take > 10)
 391                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 392         }
 393
 394         if (take > 50)
 395                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 396         if (take > 100)
 397                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 398
 399         if (!(self.flags & FL_GODMODE))
 400         {
 401                 self.armorvalue = self.armorvalue - save;
 402                 self.health = self.health - take;
 403                 // pause regeneration for 5 seconds
 404                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 405         }
 406         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 407         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 408         self.dmg_inflictor = inflictor;
 409
 410         if (self.health <= -autocvar_sv_gibhealth && !(self.effects & CSQCMODEL_EF_INVISIBLE))
 411         {
 412                 // don't use any animations as a gib
 413                 self.frame = 0;
 414                 self.dead_frame = 0;
 415                 // view just above the floor
 416                 self.view_ofs = '0 0 4';
 417
 418                 Violence_GibSplash(self, 1, 1, attacker);
 419                 self.effects |= CSQCMODEL_EF_INVISIBLE;
 420                 self.solid = SOLID_NOT; // restore later
 421         }
 422 }
 423
 424 void ClientKill_Now_TeamChange();
 425 void freezetag_CheckWinner();
 426
 427 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 428 {
 429         float take, save, waves, sdelay, dh, da, j;
 430         vector v;
 431         float valid_damage_for_weaponstats;
 432         float excess;
 433
 434         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 435                 return;
 436
 437         dh = max(self.health, 0);
 438         da = max(self.armorvalue, 0);
 439
 440         if(!DEATH_ISSPECIAL(deathtype))
 441         {
 442                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 443                 if(self != attacker)
 444                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 445         }
 446
 447         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 448         {
 449                 // tuba causes blood to come out of the ears
 450                 vector ear1, ear2;
 451                 vector d;
 452                 float f;
 453                 ear1 = self.origin;
 454                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 455                 ear2 = ear1;
 456                 makevectors(self.angles);
 457                 ear1 += v_right * -10;
 458                 ear2 += v_right * +10;
 459                 d = inflictor.origin - self.origin;
 460                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 461                 force = v_right * vlen(force);
 462                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 463                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 464                 if(f > 0)
 465                 {
 466                         hitloc = ear1;
 467                         force = force * -1;
 468                 }
 469                 else
 470                 {
 471                         hitloc = ear2;
 472                         // force is already good
 473                 }
 474         }
 475         else
 476                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 477
 478         if (!g_minstagib)
 479         {
 480                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 481                 take = v_x;
 482                 save = v_y;
 483         }
 484         else
 485         {
 486                 save = 0;
 487                 take = damage;
 488         }
 489
 490         frag_inflictor = inflictor;
 491         frag_attacker = attacker;
 492         frag_target = self;
 493         damage_take = take;
 494         damage_save = save;
 495         damage_force = force;
 496         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 497         take = bound(0, damage_take, self.health);
 498         save = bound(0, damage_save, self.armorvalue);
 499         excess = max(0, damage - take - save);
 500
 501         if(sound_allowed(MSG_BROADCAST, attacker))
 502         {
 503                 if (save > 10)
 504                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 505                 else if (take > 30)
 506                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 507                 else if (take > 10)
 508                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 509         }
 510
 511         if (take > 50)
 512                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 513         if (take > 100)
 514                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 515
 516         if (time >= self.spawnshieldtime)
 517         {
 518                 if (!(self.flags & FL_GODMODE))
 519                 {
 520                         self.armorvalue = self.armorvalue - save;
 521                         self.health = self.health - take;
 522                         // pause regeneration for 5 seconds
 523                         if(take)
 524                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 525
 526                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 527                         {
 528                                 self.pain_finished = time + 0.5;        //Supajoe
 529
 530                                 if(sv_gentle < 1) {
 531                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 532                                         {
 533                                                 if (!self.animstate_override)
 534                                                 {
 535                                                         if (random() > 0.5)
 536                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 537                                                         else
 538                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 539                                                 }
 540                                         }
 541
 542                                         if(sound_allowed(MSG_BROADCAST, attacker))
 543                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 544                                         if(self.health > 1)
 545                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 546                                         {
 547                                                 if(deathtype == DEATH_FALL)
 548                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 549                                                 else if(self.health > 75) // TODO make a "gentle" version?
 550                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 551                                                 else if(self.health > 50)
 552                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 553                                                 else if(self.health > 25)
 554                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 555                                                 else
 556                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 557                                         }
 558                                 }
 559
 560                                 // throw off bot aim temporarily
 561                                 float shake;
 562                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 563                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 564                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 565                         }
 566                 }
 567                 else
 568                         self.max_armorvalue += (save + take);
 569         }
 570         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 571         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 572         self.dmg_inflictor = inflictor;
 573
 574         if(attacker == self)
 575         {
 576                 // don't reset pushltime for self damage as it may be an attempt to
 577                 // escape a lava pit or similar
 578                 //self.pushltime = 0;
 579         }
 580         else if(attacker.classname == "player")
 581         {
 582                 self.pusher = attacker;
 583                 self.pushltime = time + autocvar_g_maxpushtime;
 584         }
 585         else if(time < self.pushltime)
 586         {
 587                 attacker = self.pusher;
 588                 self.pushltime = max(self.pushltime, time + 0.6);
 589         }
 590         else
 591                 self.pushltime = 0;
 592
 593         float abot, vbot, awep;
 594         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 595         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 596
 597         valid_damage_for_weaponstats = 0;
 598         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 599         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 600         if(attacker && self != attacker)
 601         if(IsDifferentTeam(self, attacker))
 602         {
 603                 if(DEATH_ISSPECIAL(deathtype))
 604                         awep = attacker.weapon;
 605                 else
 606                         awep = DEATH_WEAPONOF(deathtype);
 607                 valid_damage_for_weaponstats = 1;
 608         }
 609
 610         if(valid_damage_for_weaponstats)
 611         {
 612                 dh = dh - max(self.health, 0);
 613                 da = da - max(self.armorvalue, 0);
 614                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 615         }
 616
 617         if (self.health < 1)
 618         {
 619                 float defer_ClientKill_Now_TeamChange;
 620                 defer_ClientKill_Now_TeamChange = FALSE;
 621
 622                 if(self.alivetime)
 623                 {
 624                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 625                         self.alivetime = 0;
 626                 }
 627
 628                 if(valid_damage_for_weaponstats)
 629                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 630
 631                 if(sv_gentle < 1) // TODO make a "gentle" version?
 632                 if(sound_allowed(MSG_BROADCAST, attacker))
 633                 {
 634                         if(deathtype == DEATH_DROWN)
 635                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 636                         else
 637                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 638                 }
 639
 640                 // get rid of kill indicator
 641                 if(self.killindicator)
 642                 {
 643                         remove(self.killindicator);
 644                         self.killindicator = world;
 645                         if(self.killindicator_teamchange)
 646                                 defer_ClientKill_Now_TeamChange = TRUE;
 647
 648                         if(self.classname == "body")
 649                         if(deathtype == DEATH_KILL)
 650                         {
 651                                 // for the lemmings fans, a small harmless explosion
 652                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 653                         }
 654                 }
 655
 656                 if(!g_freezetag)
 657                 {
 658                         // become fully visible
 659                         self.alpha = 1;
 660                         // throw a weapon
 661                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 662                 }
 663
 664                 // print an obituary message
 665                 Obituary (attacker, inflictor, self, deathtype);
 666                 race_PreDie();
 667                 DropAllRunes(self);
 668
 669         // increment frag counter for used weapon type
 670         float w;
 671         w = DEATH_WEAPONOF(deathtype);
 672         if(WEP_VALID(w))
 673         if(accuracy_isgooddamage(attacker, self))
 674         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 675
 676                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 677                 {
 678                         PutClientInServer();
 679                         count_alive_players(); // re-count players
 680                         freezetag_CheckWinner();
 681                         return;
 682                 }
 683
 684                 frag_attacker = attacker;
 685                 frag_inflictor = inflictor;
 686                 frag_target = self;
 687                 MUTATOR_CALLHOOK(PlayerDies);
 688                 weapon_action(self.weapon, WR_PLAYERDEATH);
 689
 690                 RemoveGrapplingHook(self);
 691
 692                 if(self.flagcarried)
 693                 {
 694                         if(attacker.classname != "player")
 695                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 696                         else if(attacker.team == self.team)
 697                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 698                         else
 699                                 DropFlag(self.flagcarried, world, attacker);
 700                 }
 701                 if(self.ballcarried && g_nexball)
 702                         DropBall(self.ballcarried, self.origin, self.velocity);
 703                 Portal_ClearAllLater(self);
 704
 705                 if(clienttype(self) == CLIENTTYPE_REAL)
 706                 {
 707                         stuffcmd(self, "-zoom\n");
 708                         self.fixangle = TRUE;
 709                         //msg_entity = self;
 710                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 711                         //WriteAngle (MSG_ONE, self.v_angle_x);
 712                         //WriteAngle (MSG_ONE, self.v_angle_y);
 713                         //WriteAngle (MSG_ONE, 80);
 714                 }
 715
 716                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 717                         ClientKill_Now_TeamChange();
 718
 719                 if(g_arena)
 720                         Spawnqueue_Unmark(self);
 721
 722                 if(g_freezetag)
 723                         return;
 724
 725                 // when we get here, player actually dies
 726                 // clear waypoints (do this AFTER FreezeTag)
 727                 WaypointSprite_PlayerDead();
 728
 729                 // make the corpse upright (not tilted)
 730                 self.angles_x = 0;
 731                 self.angles_z = 0;
 732                 // don't spin
 733                 self.avelocity = '0 0 0';
 734                 // view from the floor
 735                 self.view_ofs = '0 0 -8';
 736                 // toss the corpse
 737                 self.movetype = MOVETYPE_TOSS;
 738                 // shootable corpse
 739                 self.solid = SOLID_CORPSE;
 740                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 741                 // don't stick to the floor
 742                 self.flags &~= FL_ONGROUND;
 743                 // dying animation
 744                 self.deadflag = DEAD_DYING;
 745                 // when to allow respawn
 746                 sdelay = 0;
 747                 waves = 0;
 748                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 749                 if(!sdelay)
 750                 {
 751                         if(g_cts)
 752                                 sdelay = 0; // no respawn delay in CTS
 753                         else
 754                                 sdelay = autocvar_g_respawn_delay;
 755                 }
 756                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 757                 if(!waves)
 758                         waves = autocvar_g_respawn_waves;
 759                 if(waves)
 760                         self.death_time = ceil((time + sdelay) / waves) * waves;
 761                 else
 762                         self.death_time = time + sdelay;
 763                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 764                         self.respawn_countdown = 10; // first number to count down from is 10
 765                 else
 766                         self.respawn_countdown = -1; // do not count down
 767                 if (random() < 0.5)
 768                 {
 769                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 770                         self.dead_frame = self.anim_dead1_x;
 771                 }
 772                 else
 773                 {
 774                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 775                         self.dead_frame = self.anim_dead2_x;
 776                 }
 777                 // set damage function to corpse damage
 778                 self.event_damage = PlayerCorpseDamage;
 779                 // call the corpse damage function just in case it wants to gib
 780                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 781                 // set up to fade out later
 782                 SUB_SetFade (self, time + 6 + random (), 1);
 783
 784                 if(sv_gentle > 0 || autocvar_ekg) {
 785                         // remove corpse
 786                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 787                 }
 788
 789                 // reset fields the weapons may use just in case
 790                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 791                 {
 792                         weapon_action(j, WR_RESETPLAYER);
 793                         ATTACK_FINISHED_FOR(self, j) = 0;
 794                 }
 795         }
 796 }
 797
 798 .float muted; // to be used by prvm_edictset server playernumber muted 1
 799 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 800 // message "": do not say, just test flood control
 801 // return value:
 802 //   1 = accept
 803 //   0 = reject
 804 //  -1 = fake accept
 805 {
 806         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 807         float flood, privatemsgprefixlen;
 808         var .float flood_field;
 809         entity head;
 810         float ret;
 811
 812         if(Ban_MaybeEnforceBan(source))
 813                 return 0;
 814
 815         if(!teamsay && !privatesay)
 816                 if(substring(msgin, 0, 1) == " ")
 817                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 818
 819         msgin = formatmessage(msgin);
 820
 821         if(source.classname != "player")
 822                 colorstr = "^0"; // black for spectators
 823         else if(teamplay)
 824                 colorstr = Team_ColorCode(source.team);
 825         else
 826                 teamsay = FALSE;
 827
 828         if(intermission_running)
 829                 teamsay = FALSE;
 830
 831         if(msgin != "")
 832                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 833
 834         /*
 835          * using bprint solves this... me stupid
 836         // how can we prevent the message from appearing in a listen server?
 837         // for now, just give "say" back and only handle say_team
 838         if(!teamsay)
 839         {
 840                 clientcommand(self, strcat("say ", msgin));
 841                 return;
 842         }
 843         */
 844
 845         if(autocvar_g_chat_teamcolors)
 846                 namestr = playername(source);
 847         else
 848                 namestr = source.netname;
 849
 850         if(msgin != "")
 851         {
 852                 if(privatesay)
 853                 {
 854                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 855                         privatemsgprefixlen = strlen(msgstr);
 856                         msgstr = strcat(msgstr, msgin);
 857                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 858                         if(autocvar_g_chat_teamcolors)
 859                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 860                         else
 861                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 862                 }
 863                 else if(teamsay)
 864                 {
 865                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 866                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 867                 }
 868                 else
 869                 {
 870                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 871                         cmsgstr = "";
 872                 }
 873                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 874         }
 875         else
 876         {
 877                 msgstr = cmsgstr = "";
 878         }
 879
 880         fullmsgstr = msgstr;
 881         fullcmsgstr = cmsgstr;
 882
 883         // FLOOD CONTROL
 884         flood = 0;
 885         if(floodcontrol)
 886         {
 887                 float flood_spl;
 888                 float flood_burst;
 889                 float flood_lmax;
 890                 float lines;
 891                 if(privatesay)
 892                 {
 893                         flood_spl = autocvar_g_chat_flood_spl_tell;
 894                         flood_burst = autocvar_g_chat_flood_burst_tell;
 895                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 896                         flood_field = floodcontrol_chattell;
 897                 }
 898                 else if(teamsay)
 899                 {
 900                         flood_spl = autocvar_g_chat_flood_spl_team;
 901                         flood_burst = autocvar_g_chat_flood_burst_team;
 902                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 903                         flood_field = floodcontrol_chatteam;
 904                 }
 905                 else
 906                 {
 907                         flood_spl = autocvar_g_chat_flood_spl;
 908                         flood_burst = autocvar_g_chat_flood_burst;
 909                         flood_lmax = autocvar_g_chat_flood_lmax;
 910                         flood_field = floodcontrol_chat;
 911                 }
 912                 flood_burst = max(0, flood_burst - 1);
 913                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 914
 915                 // do flood control for the default line size
 916                 if(msgstr != "")
 917                 {
 918                         getWrappedLine_remaining = msgstr;
 919                         msgstr = "";
 920                         lines = 0;
 921                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 922                         {
 923                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 924                                 ++lines;
 925                         }
 926                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 927
 928                         if(getWrappedLine_remaining != "")
 929                         {
 930                                 msgstr = strcat(msgstr, "\n");
 931                                 flood = 2;
 932                         }
 933
 934                         if(time >= source.flood_field)
 935                         {
 936                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 937                         }
 938                         else
 939                         {
 940                                 flood = 1;
 941                                 msgstr = fullmsgstr;
 942                         }
 943                 }
 944                 else
 945                 {
 946                         if(time >= source.flood_field)
 947                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 948                         else
 949                                 flood = 1;
 950                 }
 951
 952                 if (timeoutStatus == 2) //when game is paused, no flood protection
 953                         source.flood_field = flood = 0;
 954         }
 955
 956         if(flood == 2) // cannot happen for empty msgstr
 957         {
 958                 if(autocvar_g_chat_flood_notify_flooder)
 959                 {
 960                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 961                         sourcecmsgstr = "";
 962                 }
 963                 else
 964                 {
 965                         sourcemsgstr = fullmsgstr;
 966                         sourcecmsgstr = fullcmsgstr;
 967                 }
 968                 cmsgstr = "";
 969         }
 970         else
 971         {
 972                 sourcemsgstr = msgstr;
 973                 sourcecmsgstr = cmsgstr;
 974         }
 975
 976         if(!privatesay)
 977         if(source.classname != "player")
 978         {
 979                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 980                         teamsay = -1; // spectators
 981         }
 982
 983         if(flood)
 984                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 985
 986         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 987         if(privatesay)
 988                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 989
 990         if(source.muted)
 991         {
 992                 // always fake the message
 993                 ret = -1;
 994         }
 995         else if(flood == 1)
 996         {
 997                 if(autocvar_g_chat_flood_notify_flooder)
 998                 {
 999                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1000                         ret = 0;
1001                 }
1002                 else
1003                         ret = -1;
1004         }
1005         else
1006         {
1007                 ret = 1;
1008         }
1009
1010         if(sourcemsgstr != "" && ret != 0)
1011         {
1012                 if(ret < 0) // fake
1013                 {
1014                         sprint(source, sourcemsgstr);
1015                         if(sourcecmsgstr != "" && !privatesay)
1016                                 centerprint(source, sourcecmsgstr);
1017                 }
1018                 else if(privatesay)
1019                 {
1020                         sprint(source, sourcemsgstr);
1021                         sprint(privatesay, msgstr);
1022                         if(cmsgstr != "")
1023                                 centerprint(privatesay, cmsgstr);
1024                 }
1025                 else if(teamsay > 0)
1026                 {
1027                         sprint(source, sourcemsgstr);
1028                         if(sourcecmsgstr != "")
1029                                 centerprint(source, sourcecmsgstr);
1030                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1031                                 if(head != source)
1032                                 {
1033                                         sprint(head, msgstr);
1034                                         if(cmsgstr != "")
1035                                                 centerprint(head, cmsgstr);
1036                                 }
1037                 }
1038                 else if(teamsay < 0)
1039                 {
1040                         sprint(source, sourcemsgstr);
1041                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1042                                 if(head != source)
1043                                         sprint(head, msgstr);
1044                 }
1045                 else if(sourcemsgstr != msgstr)
1046                 {
1047                         sprint(source, sourcemsgstr);
1048                         FOR_EACH_REALCLIENT(head)
1049                                 if(head != source)
1050                                         sprint(head, msgstr);
1051                 }
1052                 else
1053                         bprint(msgstr);
1054         }
1055
1056         return ret;
1057 }
1058
1059 float GetVoiceMessageVoiceType(string type)
1060 {
1061         if(type == "taunt")
1062                 return VOICETYPE_TAUNT;
1063         if(type == "teamshoot")
1064                 return VOICETYPE_LASTATTACKER;
1065         return VOICETYPE_TEAMRADIO;
1066 }
1067
1068 string allvoicesamples;
1069 .string GetVoiceMessageSampleField(string type)
1070 {
1071         GetPlayerSoundSampleField_notFound = 0;
1072         switch(type)
1073         {
1074 #define _VOICEMSG(m) case #m: return playersound_##m;
1075                 ALLVOICEMSGS
1076 #undef _VOICEMSG
1077         }
1078         GetPlayerSoundSampleField_notFound = 1;
1079         return playersound_taunt;
1080 }
1081
1082 .string GetPlayerSoundSampleField(string type)
1083 {
1084         GetPlayerSoundSampleField_notFound = 0;
1085         switch(type)
1086         {
1087 #define _VOICEMSG(m) case #m: return playersound_##m;
1088                 ALLPLAYERSOUNDS
1089 #undef _VOICEMSG
1090         }
1091         GetPlayerSoundSampleField_notFound = 1;
1092         return playersound_taunt;
1093 }
1094
1095 void PrecacheGlobalSound(string samplestring)
1096 {
1097         float n, i;
1098         tokenize_console(samplestring);
1099         n = stof(argv(1));
1100         if(n > 0)
1101         {
1102                 for(i = 1; i <= n; ++i)
1103                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1104         }
1105         else
1106         {
1107                 precache_sound(strcat(argv(0), ".wav"));
1108         }
1109 }
1110
1111 void PrecachePlayerSounds(string f)
1112 {
1113         float fh;
1114         string s;
1115         fh = fopen(f, FILE_READ);
1116         if(fh < 0)
1117                 return;
1118         while((s = fgets(fh)))
1119         {
1120                 if(tokenize_console(s) != 3)
1121                 {
1122                         dprint("Invalid sound info line: ", s, "\n");
1123                         continue;
1124                 }
1125                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1126         }
1127         fclose(fh);
1128
1129         if not(allvoicesamples)
1130         {
1131 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1132                 ALLVOICEMSGS
1133 #undef _VOICEMSG
1134                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1135         }
1136 }
1137
1138 void ClearPlayerSounds()
1139 {
1140 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1141         ALLPLAYERSOUNDS
1142         ALLVOICEMSGS
1143 #undef _VOICEMSG
1144 }
1145
1146 float LoadPlayerSounds(string f, float first)
1147 {
1148         float fh;
1149         string s;
1150         var .string field;
1151         fh = fopen(f, FILE_READ);
1152         if(fh < 0)
1153         {
1154                 dprint("Player sound file not found: ", f, "\n");
1155                 return 0;
1156         }
1157         while((s = fgets(fh)))
1158         {
1159                 if(tokenize_console(s) != 3)
1160                         continue;
1161                 field = GetPlayerSoundSampleField(argv(0));
1162                 if(GetPlayerSoundSampleField_notFound)
1163                         field = GetVoiceMessageSampleField(argv(0));
1164                 if(GetPlayerSoundSampleField_notFound)
1165                         continue;
1166                 if(self.field)
1167                         strunzone(self.field);
1168                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1169         }
1170         fclose(fh);
1171         return 1;
1172 }
1173
1174 .float modelindex_for_playersound;
1175 .float skin_for_playersound;
1176 void UpdatePlayerSounds()
1177 {
1178         if(self.modelindex == self.modelindex_for_playersound)
1179         if(self.skin == self.skin_for_playersound)
1180                 return;
1181         self.modelindex_for_playersound = self.modelindex;
1182         self.skin_for_playersound = self.skin;
1183         ClearPlayerSounds();
1184         LoadPlayerSounds("sound/player/default.sounds", 1);
1185         if(!autocvar_g_debug_defaultsounds)
1186                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1187                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1188 }
1189
1190 void FakeGlobalSound(string sample, float chan, float voicetype)
1191 {
1192         float n;
1193         float tauntrand;
1194
1195         if(sample == "")
1196                 return;
1197
1198         tokenize_console(sample);
1199         n = stof(argv(1));
1200         if(n > 0)
1201                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1202         else
1203                 sample = strcat(argv(0), ".wav"); // randomization
1204
1205         switch(voicetype)
1206         {
1207                 case VOICETYPE_LASTATTACKER_ONLY:
1208                         break;
1209                 case VOICETYPE_LASTATTACKER:
1210                         if(self.pusher)
1211                         {
1212                                 msg_entity = self;
1213                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1214                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1215                         }
1216                         break;
1217                 case VOICETYPE_TEAMRADIO:
1218                         msg_entity = self;
1219                         if(msg_entity.cvar_cl_voice_directional == 1)
1220                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1221                         else
1222                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1223                         break;
1224                 case VOICETYPE_AUTOTAUNT:
1225                         if(!sv_autotaunt)
1226                                 break;
1227                         if(!sv_taunt)
1228                                 break;
1229                         if(sv_gentle)
1230                                 break;
1231                         tauntrand = random();
1232                         msg_entity = self;
1233                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1234                         {
1235                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1236                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1237                                 else
1238                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1239                         }
1240                         break;
1241                 case VOICETYPE_TAUNT:
1242                         if(self.classname == "player")
1243                                 if(self.deadflag == DEAD_NO)
1244                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1245                         if(!sv_taunt)
1246                                 break;
1247                         if(sv_gentle)
1248                                 break;
1249                         msg_entity = self;
1250                         if (msg_entity.cvar_cl_voice_directional >= 1)
1251                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1252                         else
1253                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1254                         break;
1255                 case VOICETYPE_PLAYERSOUND:
1256                         msg_entity = self;
1257                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1258                         break;
1259                 default:
1260                         backtrace("Invalid voice type!");
1261                         break;
1262         }
1263 }
1264
1265 void GlobalSound(string sample, float chan, float voicetype)
1266 {
1267         float n;
1268         float tauntrand;
1269
1270         if(sample == "")
1271                 return;
1272
1273         tokenize_console(sample);
1274         n = stof(argv(1));
1275         if(n > 0)
1276                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1277         else
1278                 sample = strcat(argv(0), ".wav"); // randomization
1279
1280         switch(voicetype)
1281         {
1282                 case VOICETYPE_LASTATTACKER_ONLY:
1283                         if(self.pusher)
1284                         {
1285                                 msg_entity = self.pusher;
1286                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1287                                 {
1288                                         if(msg_entity.cvar_cl_voice_directional == 1)
1289                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1290                                         else
1291                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1292                                 }
1293                         }
1294                         break;
1295                 case VOICETYPE_LASTATTACKER:
1296                         if(self.pusher)
1297                         {
1298                                 msg_entity = self.pusher;
1299                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1300                                 {
1301                                         if(msg_entity.cvar_cl_voice_directional == 1)
1302                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1303                                         else
1304                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1305                                 }
1306                                 msg_entity = self;
1307                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1308                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1309                         }
1310                         break;
1311                 case VOICETYPE_TEAMRADIO:
1312                         FOR_EACH_REALCLIENT(msg_entity)
1313                                 if(!teamplay || msg_entity.team == self.team)
1314                                 {
1315                                         if(msg_entity.cvar_cl_voice_directional == 1)
1316                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1317                                         else
1318                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1319                                 }
1320                         break;
1321                 case VOICETYPE_AUTOTAUNT:
1322                         if(!sv_autotaunt)
1323                                 break;
1324                         if(!sv_taunt)
1325                                 break;
1326                         if(sv_gentle)
1327                                 break;
1328                         tauntrand = random();
1329                         FOR_EACH_REALCLIENT(msg_entity)
1330                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1331                                 {
1332                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1333                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1334                                         else
1335                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1336                                 }
1337                         break;
1338                 case VOICETYPE_TAUNT:
1339                         if(self.classname == "player")
1340                                 if(self.deadflag == DEAD_NO)
1341                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1342                         if(!sv_taunt)
1343                                 break;
1344                         if(sv_gentle)
1345                                 break;
1346                         FOR_EACH_REALCLIENT(msg_entity)
1347                         {
1348                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1349                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1350                                 else
1351                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1352                         }
1353                         break;
1354                 case VOICETYPE_PLAYERSOUND:
1355                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1356                         break;
1357                 default:
1358                         backtrace("Invalid voice type!");
1359                         break;
1360         }
1361 }
1362
1363 void PlayerSound(.string samplefield, float chan, float voicetype)
1364 {
1365         GlobalSound(self.samplefield, chan, voicetype);
1366 }
1367
1368 void VoiceMessage(string type, string msg)
1369 {
1370         var .string sample;
1371         float voicetype, ownteam;
1372         float flood;
1373         sample = GetVoiceMessageSampleField(type);
1374
1375         if(GetPlayerSoundSampleField_notFound)
1376         {
1377                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1378                 return;
1379         }
1380
1381         voicetype = GetVoiceMessageVoiceType(type);
1382         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1383
1384         flood = Say(self, ownteam, world, msg, 1);
1385
1386         if (flood > 0)
1387                 GlobalSound(self.sample, CH_VOICE, voicetype);
1388         else if (flood < 0)
1389                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1390 }
1391
1392 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1393 {
1394 //      show_message
1395 //      0 (00) automove centerprint, admin message
1396 //      1 (01) automove centerprint, no admin message
1397 //      2 (10) no centerprint, admin message
1398 //      3 (11) no centerprint, no admin message
1399
1400         float lockteams_backup;
1401
1402         lockteams_backup = lockteams;  // backup any team lock
1403
1404         lockteams = 0;  // disable locked teams
1405
1406         TeamchangeFrags(client);  // move the players frags
1407         SetPlayerColors(client, team_colour - 1);  // set the players colour
1408         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1409
1410         lockteams = lockteams_backup;  // restore the team lock
1411
1412         LogTeamchange(client.playerid, client.team, type);
1413
1414         if not(show_message & 1) // admin message
1415                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1416
1417         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1418 }