qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // url_fopen returned, we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh, WeaponStats_ready, world);
  50                         buf_del(weaponstats_buffer);
  51                         weaponstats_buffer = -1;
  52                         break;
  53                 case URL_READY_CANREAD:
  54                         // url_fclose is processing, we got a response for writing the data
  55                         // this must come from HTTP
  56                         print("Got response from weapon stats server:\n");
  57                         while((s = url_fgets(fh)))
  58                                 print("  ", s, "\n");
  59                         print("End of response.\n");
  60                         url_fclose(fh, WeaponStats_ready, world);
  61                         break;
  62                 case URL_READY_CLOSED:
  63                         // url_fclose has finished
  64                         print("Weapon stats written\n");
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         break;
  70         }
  71 }
  72
  73 void WeaponStats_Shutdown()
  74 {
  75         if(weaponstats_buffer < 0)
  76                 return;
  77         if(autocvar_sv_weaponstats_file != "")
  78         {
  79                 url_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  80         }
  81         else
  82         {
  83                 buf_del(weaponstats_buffer);
  84                 weaponstats_buffer = -1;
  85         }
  86 }
  87
  88 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  89 {
  90         float idx;
  91         if(weaponstats_buffer < 0)
  92                 return;
  93         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  94                 return;
  95         if(awep > WEP_LAST || vwep > WEP_LAST)
  96                 return;
  97         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  98         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  99 }
 100 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 101 {
 102         if(damage < 0)
 103                 error("negative damage?");
 104         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 105 }
 106 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 107 {
 108         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 109 }
 110
 111 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 112 // merged player_run and player_stand to player_anim
 113 // added death animations to player_anim
 114 // can now spawn thrown weapons from anywhere, not just from players
 115 // thrown weapons now fade out after 20 seconds
 116 // created PlayerGib function
 117 // PlayerDie no longer uses hitloc or damage
 118 // PlayerDie now supports dying animations as well as gibbing
 119 // cleaned up PlayerDie a lot
 120 // added CopyBody
 121
 122 .entity pusher;
 123 .float pushltime;
 124
 125 void CopyBody(float keepvelocity)
 126 {
 127         local entity oldself;
 128         if (self.effects & EF_NODRAW)
 129                 return;
 130         oldself = self;
 131         self = spawn();
 132         self.enemy = oldself;
 133         self.lip = oldself.lip;
 134         self.colormap = oldself.colormap;
 135         self.glowmod = oldself.glowmod;
 136         self.iscreature = oldself.iscreature;
 137         self.angles = oldself.angles;
 138         self.avelocity = oldself.avelocity;
 139         self.classname = "body";
 140         self.damageforcescale = oldself.damageforcescale;
 141         self.effects = oldself.effects;
 142         self.event_damage = oldself.event_damage;
 143         self.animstate_startframe = oldself.animstate_startframe;
 144         self.animstate_numframes = oldself.animstate_numframes;
 145         self.animstate_framerate = oldself.animstate_framerate;
 146         self.animstate_starttime = oldself.animstate_starttime;
 147         self.animstate_endtime = oldself.animstate_endtime;
 148         self.animstate_override = oldself.animstate_override;
 149         self.animstate_looping = oldself.animstate_looping;
 150         self.frame = oldself.frame;
 151         self.dead_frame = oldself.dead_frame;
 152         self.pain_finished = oldself.pain_finished;
 153         self.health = oldself.health;
 154         self.armorvalue = oldself.armorvalue;
 155         self.armortype = oldself.armortype;
 156         self.model = oldself.model;
 157         self.modelindex = oldself.modelindex;
 158         self.modelindex_lod0 = oldself.modelindex_lod0;
 159         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 160         self.modelindex_lod1 = oldself.modelindex_lod1;
 161         self.modelindex_lod2 = oldself.modelindex_lod2;
 162         self.skinindex = oldself.skinindex;
 163         self.species = oldself.species;
 164         self.movetype = oldself.movetype;
 165         self.nextthink = oldself.nextthink;
 166         self.solid = oldself.solid;
 167         self.ballistics_density = oldself.ballistics_density;
 168         self.takedamage = oldself.takedamage;
 169         self.think = oldself.think;
 170         self.customizeentityforclient = oldself.customizeentityforclient;
 171         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 172         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 173         if (keepvelocity == 1)
 174                 self.velocity = oldself.velocity;
 175         self.oldvelocity = self.velocity;
 176         self.fade_time = oldself.fade_time;
 177         self.fade_rate = oldself.fade_rate;
 178         //self.weapon = oldself.weapon;
 179         setorigin(self, oldself.origin);
 180         setsize(self, oldself.mins, oldself.maxs);
 181         self.prevorigin = oldself.origin;
 182         self.reset = SUB_Remove;
 183
 184         Drag_MoveDrag(oldself, self);
 185
 186         self = oldself;
 187 }
 188
 189 float player_getspecies()
 190 {
 191         float s;
 192         get_model_parameters(self.model, self.skinindex);
 193         s = get_model_parameters_species;
 194         get_model_parameters(string_null, 0);
 195         if(s < 0)
 196                 return SPECIES_HUMAN;
 197         return s;
 198 }
 199
 200 void player_setupanimsformodel()
 201 {
 202         local string animfilename;
 203         local float animfile;
 204         // defaults for legacy .zym models without animinfo files
 205         self.anim_die1 = '0 1 0.5'; // 2 seconds
 206         self.anim_die2 = '1 1 0.5'; // 2 seconds
 207         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 208         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 209         self.anim_duckwalk = '4 1 1';
 210         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 211         self.anim_duckidle = '6 1 1';
 212         self.anim_idle = '7 1 1';
 213         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 214         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 215         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 216         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 217         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 218         self.anim_run = '13 1 1';
 219         self.anim_runbackwards = '14 1 1';
 220         self.anim_strafeleft = '15 1 1';
 221         self.anim_straferight = '16 1 1';
 222         self.anim_dead1 = '17 1 1';
 223         self.anim_dead2 = '18 1 1';
 224         self.anim_forwardright = '19 1 1';
 225         self.anim_forwardleft = '20 1 1';
 226         self.anim_backright = '21 1 1';
 227         self.anim_backleft  = '22 1 1';
 228         self.anim_melee = '23 1 1';
 229         animparseerror = FALSE;
 230         animfilename = strcat(self.model, ".animinfo");
 231         animfile = fopen(animfilename, FILE_READ);
 232         if (animfile >= 0)
 233         {
 234                 self.anim_die1         = animparseline(animfile);
 235                 self.anim_die2         = animparseline(animfile);
 236                 self.anim_draw         = animparseline(animfile);
 237                 self.anim_duck         = animparseline(animfile);
 238                 self.anim_duckwalk     = animparseline(animfile);
 239                 self.anim_duckjump     = animparseline(animfile);
 240                 self.anim_duckidle     = animparseline(animfile);
 241                 self.anim_idle         = animparseline(animfile);
 242                 self.anim_jump         = animparseline(animfile);
 243                 self.anim_pain1        = animparseline(animfile);
 244                 self.anim_pain2        = animparseline(animfile);
 245                 self.anim_shoot        = animparseline(animfile);
 246                 self.anim_taunt        = animparseline(animfile);
 247                 self.anim_run          = animparseline(animfile);
 248                 self.anim_runbackwards = animparseline(animfile);
 249                 self.anim_strafeleft   = animparseline(animfile);
 250                 self.anim_straferight  = animparseline(animfile);
 251                 self.anim_forwardright = animparseline(animfile);
 252                 self.anim_forwardleft  = animparseline(animfile);
 253                 self.anim_backright    = animparseline(animfile);
 254                 self.anim_backleft     = animparseline(animfile);
 255                 self.anim_melee        = animparseline(animfile);
 256                 fclose(animfile);
 257
 258                 // derived anims
 259                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 260                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 261
 262                 if (animparseerror)
 263                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 264         }
 265         else
 266                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 267         // reset animstate now
 268         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 269 };
 270
 271 void player_anim (void)
 272 {
 273         updateanim(self);
 274         if (self.weaponentity)
 275                 updateanim(self.weaponentity);
 276
 277         if (self.deadflag != DEAD_NO)
 278         {
 279                 if (time > self.animstate_endtime)
 280                 {
 281                         if (self.maxs_z > 5)
 282                         {
 283                                 self.maxs_z = 5;
 284                                 setsize(self, self.mins, self.maxs);
 285                         }
 286                         self.frame = self.dead_frame;
 287                 }
 288                 return;
 289         }
 290
 291         if (!self.animstate_override)
 292         {
 293                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 294                 {
 295                         if (self.crouch)
 296                         {
 297                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 298                                 {
 299                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 300                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 301                                         {
 302                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 303                                                 self.restart_jump = FALSE;
 304                                         }
 305                                 }
 306                         }
 307                         else
 308                         {
 309                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 310                 {
 311                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 312                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 313                     {
 314                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 315                         self.restart_jump = FALSE;
 316                     }
 317                 }
 318                         }
 319                 }
 320                 else if (self.crouch)
 321                 {
 322                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 323                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 324                         else
 325                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 326                 }
 327                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 328                 {
 329                         if (self.movement_x > 0 && self.movement_y == 0)
 330                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 331                         else if (self.movement_x < 0 && self.movement_y == 0)
 332                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 333                         else if (self.movement_x == 0 && self.movement_y > 0)
 334                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 335                         else if (self.movement_x == 0 && self.movement_y < 0)
 336                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 337                         else if (self.movement_x > 0 && self.movement_y > 0)
 338                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 339                         else if (self.movement_x > 0 && self.movement_y < 0)
 340                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 341                         else if (self.movement_x < 0 && self.movement_y > 0)
 342                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 343                         else if (self.movement_x < 0 && self.movement_y < 0)
 344                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 345                         else
 346                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 347                 }
 348                 else
 349                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 350         }
 351
 352         if (self.weaponentity)
 353         if (!self.weaponentity.animstate_override)
 354                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 355 }
 356
 357 void SpawnThrownWeapon (vector org, float w)
 358 {
 359         if(g_minstagib)
 360         if(self.ammo_cells <= 0)
 361                 return;
 362
 363         if(g_pinata)
 364         {
 365                 float j;
 366                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 367                 {
 368                         if(self.weapons & W_WeaponBit(j))
 369                                 if(W_IsWeaponThrowable(j))
 370                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 371                 }
 372         }
 373         else
 374         {
 375                 if(W_IsWeaponThrowable(self.weapon))
 376                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 377         }
 378 }
 379
 380 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 381 {
 382         local float take, save;
 383         vector v;
 384         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 385
 386         // damage resistance (ignore most of the damage from a bullet or similar)
 387         damage = max(damage - 5, 1);
 388
 389         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 390         take = v_x;
 391         save = v_y;
 392
 393         if(sound_allowed(MSG_BROADCAST, attacker))
 394         {
 395                 if (save > 10)
 396                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 397                 else if (take > 30)
 398                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 399                 else if (take > 10)
 400                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 401         }
 402
 403         if (take > 50)
 404                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 405         if (take > 100)
 406                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 407
 408         if (!(self.flags & FL_GODMODE))
 409         {
 410                 self.armorvalue = self.armorvalue - save;
 411                 self.health = self.health - take;
 412                 // pause regeneration for 5 seconds
 413                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 414         }
 415         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 416         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 417         self.dmg_inflictor = inflictor;
 418
 419         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 420         {
 421                 // don't use any animations as a gib
 422                 self.frame = 0;
 423                 self.dead_frame = 0;
 424                 // view just above the floor
 425                 self.view_ofs = '0 0 4';
 426
 427                 Violence_GibSplash(self, 1, 1, attacker);
 428                 self.modelindex = 0; // restore later
 429                 self.solid = SOLID_NOT; // restore later
 430         }
 431 }
 432
 433 void ClientKill_Now_TeamChange();
 434 void freezetag_CheckWinner();
 435
 436 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 437 {
 438         local float take, save, waves, sdelay, dh, da, j;
 439         vector v;
 440         float valid_damage_for_weaponstats;
 441         float excess;
 442
 443         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 444                 return;
 445
 446         dh = max(self.health, 0);
 447         da = max(self.armorvalue, 0);
 448
 449         if(!DEATH_ISSPECIAL(deathtype))
 450         {
 451                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 452                 if(self != attacker)
 453                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 454         }
 455
 456         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 457         {
 458                 // tuba causes blood to come out of the ears
 459                 vector ear1, ear2;
 460                 vector d;
 461                 float f;
 462                 ear1 = self.origin;
 463                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 464                 ear2 = ear1;
 465                 makevectors(self.angles);
 466                 ear1 += v_right * -10;
 467                 ear2 += v_right * +10;
 468                 d = inflictor.origin - self.origin;
 469                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 470                 force = v_right * vlen(force);
 471                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 472                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 473                 if(f > 0)
 474                 {
 475                         hitloc = ear1;
 476                         force = force * -1;
 477                 }
 478                 else
 479                 {
 480                         hitloc = ear2;
 481                         // force is already good
 482                 }
 483         }
 484         else
 485                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 486
 487         if (!g_minstagib)
 488         {
 489                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 490                 take = v_x;
 491                 save = v_y;
 492         }
 493         else
 494         {
 495                 save = 0;
 496                 take = damage;
 497         }
 498
 499         frag_inflictor = inflictor;
 500         frag_attacker = attacker;
 501         frag_target = self;
 502         damage_take = take;
 503         damage_save = save;
 504         damage_force = force;
 505         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 506         take = bound(0, damage_take, self.health);
 507         save = bound(0, damage_save, self.armorvalue);
 508         excess = max(0, damage - take - save);
 509
 510         if(sound_allowed(MSG_BROADCAST, attacker))
 511         {
 512                 if (save > 10)
 513                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 514                 else if (take > 30)
 515                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 516                 else if (take > 10)
 517                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 518         }
 519
 520         if (take > 50)
 521                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 522         if (take > 100)
 523                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 524
 525         if (time >= self.spawnshieldtime)
 526         {
 527                 if (!(self.flags & FL_GODMODE))
 528                 {
 529                         self.armorvalue = self.armorvalue - save;
 530                         self.health = self.health - take;
 531                         // pause regeneration for 5 seconds
 532                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 533
 534                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 535                         {
 536                                 self.pain_finished = time + 0.5;        //Supajoe
 537
 538                                 if(sv_gentle < 1) {
 539                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 540                                         {
 541                                                 if (!self.animstate_override)
 542                                                 {
 543                                                         if (random() > 0.5)
 544                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 545                                                         else
 546                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 547                                                 }
 548                                         }
 549
 550                                         if(sound_allowed(MSG_BROADCAST, attacker))
 551                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 552                                         if(self.health > 1)
 553                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 554                                         {
 555                                                 if(deathtype == DEATH_FALL)
 556                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 557                                                 else if(self.health > 75) // TODO make a "gentle" version?
 558                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 559                                                 else if(self.health > 50)
 560                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 561                                                 else if(self.health > 25)
 562                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 563                                                 else
 564                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 565                                         }
 566                                 }
 567
 568                                 // throw off bot aim temporarily
 569                                 local float shake;
 570                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 571                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 572                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 573                         }
 574                 }
 575                 else
 576                         self.max_armorvalue += (save + take);
 577         }
 578         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 579         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 580         self.dmg_inflictor = inflictor;
 581
 582         if(attacker == self)
 583         {
 584                 // don't reset pushltime for self damage as it may be an attempt to
 585                 // escape a lava pit or similar
 586                 //self.pushltime = 0;
 587         }
 588         else if(attacker.classname == "player")
 589         {
 590                 self.pusher = attacker;
 591                 self.pushltime = time + autocvar_g_maxpushtime;
 592         }
 593         else if(time < self.pushltime)
 594         {
 595                 attacker = self.pusher;
 596                 self.pushltime = max(self.pushltime, time + 0.6);
 597         }
 598         else
 599                 self.pushltime = 0;
 600
 601         float abot, vbot, awep;
 602         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 603         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 604
 605         valid_damage_for_weaponstats = 0;
 606         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 607         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 608         if(attacker && self != attacker)
 609         if(IsDifferentTeam(self, attacker))
 610         {
 611                 if(DEATH_ISSPECIAL(deathtype))
 612                         awep = attacker.weapon;
 613                 else
 614                         awep = DEATH_WEAPONOF(deathtype);
 615                 valid_damage_for_weaponstats = 1;
 616         }
 617
 618         if(valid_damage_for_weaponstats)
 619         {
 620                 dh = dh - max(self.health, 0);
 621                 da = da - max(self.armorvalue, 0);
 622                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 623         }
 624
 625         if (self.health < 1)
 626         {
 627                 float defer_ClientKill_Now_TeamChange;
 628                 defer_ClientKill_Now_TeamChange = FALSE;
 629
 630                 if(self.alivetime)
 631                 {
 632                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 633                         self.alivetime = 0;
 634                 }
 635
 636                 if(valid_damage_for_weaponstats)
 637                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 638
 639                 if(sv_gentle < 1) // TODO make a "gentle" version?
 640                 if(sound_allowed(MSG_BROADCAST, attacker))
 641                 {
 642                         if(deathtype == DEATH_DROWN)
 643                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 644                         else
 645                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 646                 }
 647
 648                 // get rid of kill indicator
 649                 if(self.killindicator)
 650                 {
 651                         remove(self.killindicator);
 652                         self.killindicator = world;
 653                         if(self.killindicator_teamchange)
 654                                 defer_ClientKill_Now_TeamChange = TRUE;
 655
 656                         if(self.classname == "body")
 657                         if(deathtype == DEATH_KILL)
 658                         {
 659                                 // for the lemmings fans, a small harmless explosion
 660                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 661                         }
 662                 }
 663
 664                 if(!g_freezetag)
 665                 {
 666                         // become fully visible
 667                         self.alpha = 1;
 668                         // throw a weapon
 669                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 670                 }
 671
 672                 // print an obituary message
 673                 Obituary (attacker, inflictor, self, deathtype);
 674                 race_PreDie();
 675                 DropAllRunes(self);
 676
 677         // increment frag counter for used weapon type
 678         float w;
 679         w = DEATH_WEAPONOF(deathtype);
 680         if(WEP_VALID(w))
 681         if(self.classname == "player")
 682         if(self != attacker)
 683         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 684
 685                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 686                 {
 687                         PutClientInServer();
 688                         count_alive_players(); // re-count players
 689                         freezetag_CheckWinner();
 690                         return;
 691                 }
 692
 693                 frag_attacker = attacker;
 694                 frag_inflictor = inflictor;
 695                 frag_target = self;
 696                 MUTATOR_CALLHOOK(PlayerDies);
 697                 weapon_action(self.weapon, WR_PLAYERDEATH);
 698
 699                 if(self.flagcarried)
 700                 {
 701                         if(attacker.classname != "player")
 702                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 703                         else if(attacker.team == self.team)
 704                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 705                         else
 706                                 DropFlag(self.flagcarried, world, attacker);
 707                 }
 708                 if(self.ballcarried && g_nexball)
 709                         DropBall(self.ballcarried, self.origin, self.velocity);
 710                 Portal_ClearAllLater(self);
 711
 712                 if(clienttype(self) == CLIENTTYPE_REAL)
 713                 {
 714                         stuffcmd(self, "-zoom\n");
 715                         self.fixangle = TRUE;
 716                         //msg_entity = self;
 717                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 718                         //WriteAngle (MSG_ONE, self.v_angle_x);
 719                         //WriteAngle (MSG_ONE, self.v_angle_y);
 720                         //WriteAngle (MSG_ONE, 80);
 721                 }
 722
 723                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 724                         ClientKill_Now_TeamChange();
 725
 726                 if(g_arena)
 727                         Spawnqueue_Unmark(self);
 728
 729                 if(g_freezetag)
 730                         return;
 731
 732                 // when we get here, player actually dies
 733                 // clear waypoints (do this AFTER FreezeTag)
 734                 WaypointSprite_PlayerDead();
 735
 736                 // make the corpse upright (not tilted)
 737                 self.angles_x = 0;
 738                 self.angles_z = 0;
 739                 // don't spin
 740                 self.avelocity = '0 0 0';
 741                 // view from the floor
 742                 self.view_ofs = '0 0 -8';
 743                 // toss the corpse
 744                 self.movetype = MOVETYPE_TOSS;
 745                 // shootable corpse
 746                 self.solid = SOLID_CORPSE;
 747                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 748                 // don't stick to the floor
 749                 self.flags &~= FL_ONGROUND;
 750                 // dying animation
 751                 self.deadflag = DEAD_DYING;
 752                 // when to allow respawn
 753                 sdelay = 0;
 754                 waves = 0;
 755                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 756                 if(!sdelay)
 757                 {
 758                         if(g_cts)
 759                                 sdelay = 0; // no respawn delay in CTS
 760                         else
 761                                 sdelay = autocvar_g_respawn_delay;
 762                 }
 763                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 764                 if(!waves)
 765                         waves = autocvar_g_respawn_waves;
 766                 if(waves)
 767                         self.death_time = ceil((time + sdelay) / waves) * waves;
 768                 else
 769                         self.death_time = time + sdelay;
 770                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 771                         self.respawn_countdown = 10; // first number to count down from is 10
 772                 else
 773                         self.respawn_countdown = -1; // do not count down
 774                 if (random() < 0.5)
 775                 {
 776                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 777                         self.dead_frame = self.anim_dead1_x;
 778                 }
 779                 else
 780                 {
 781                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 782                         self.dead_frame = self.anim_dead2_x;
 783                 }
 784                 // set damage function to corpse damage
 785                 self.event_damage = PlayerCorpseDamage;
 786                 // call the corpse damage function just in case it wants to gib
 787                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 788                 // set up to fade out later
 789                 SUB_SetFade (self, time + 6 + random (), 1);
 790
 791                 if(sv_gentle > 0 || autocvar_ekg) {
 792                         // remove corpse
 793                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 794                 }
 795
 796                 // reset fields the weapons may use just in case
 797                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 798                 {
 799                         weapon_action(j, WR_RESETPLAYER);
 800                         ATTACK_FINISHED_FOR(self, j) = 0;
 801                 }
 802         }
 803 }
 804
 805 .float muted; // to be used by prvm_edictset server playernumber muted 1
 806 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 807 // message "": do not say, just test flood control
 808 // return value:
 809 //   1 = accept
 810 //   0 = reject
 811 //  -1 = fake accept
 812 {
 813         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 814         float flood, privatemsgprefixlen;
 815         var .float flood_field;
 816         entity head;
 817         float ret;
 818
 819         if(Ban_MaybeEnforceBan(source))
 820                 return 0;
 821
 822         if(!teamsay && !privatesay)
 823                 if(substring(msgin, 0, 1) == " ")
 824                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 825
 826         msgin = formatmessage(msgin);
 827
 828         if(source.classname != "player")
 829                 colorstr = "^0"; // black for spectators
 830         else if(teamplay)
 831                 colorstr = Team_ColorCode(source.team);
 832         else
 833                 teamsay = FALSE;
 834
 835         if(intermission_running)
 836                 teamsay = FALSE;
 837
 838         if(msgin != "")
 839                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 840
 841         /*
 842          * using bprint solves this... me stupid
 843         // how can we prevent the message from appearing in a listen server?
 844         // for now, just give "say" back and only handle say_team
 845         if(!teamsay)
 846         {
 847                 clientcommand(self, strcat("say ", msgin));
 848                 return;
 849         }
 850         */
 851
 852         if(autocvar_g_chat_teamcolors)
 853                 namestr = playername(source);
 854         else
 855                 namestr = source.netname;
 856
 857         if(msgin != "")
 858         {
 859                 if(privatesay)
 860                 {
 861                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 862                         privatemsgprefixlen = strlen(msgstr);
 863                         msgstr = strcat(msgstr, msgin);
 864                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 865                         if(autocvar_g_chat_teamcolors)
 866                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 867                         else
 868                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 869                 }
 870                 else if(teamsay)
 871                 {
 872                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 873                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 874                 }
 875                 else
 876                 {
 877                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 878                         cmsgstr = "";
 879                 }
 880                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 881         }
 882         else
 883         {
 884                 msgstr = cmsgstr = "";
 885         }
 886
 887         fullmsgstr = msgstr;
 888         fullcmsgstr = cmsgstr;
 889
 890         // FLOOD CONTROL
 891         flood = 0;
 892         if(floodcontrol)
 893         {
 894                 float flood_spl;
 895                 float flood_burst;
 896                 float flood_lmax;
 897                 float lines;
 898                 if(privatesay)
 899                 {
 900                         flood_spl = autocvar_g_chat_flood_spl_tell;
 901                         flood_burst = autocvar_g_chat_flood_burst_tell;
 902                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 903                         flood_field = floodcontrol_chattell;
 904                 }
 905                 else if(teamsay)
 906                 {
 907                         flood_spl = autocvar_g_chat_flood_spl_team;
 908                         flood_burst = autocvar_g_chat_flood_burst_team;
 909                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 910                         flood_field = floodcontrol_chatteam;
 911                 }
 912                 else
 913                 {
 914                         flood_spl = autocvar_g_chat_flood_spl;
 915                         flood_burst = autocvar_g_chat_flood_burst;
 916                         flood_lmax = autocvar_g_chat_flood_lmax;
 917                         flood_field = floodcontrol_chat;
 918                 }
 919                 flood_burst = max(0, flood_burst - 1);
 920                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 921
 922                 // do flood control for the default line size
 923                 if(msgstr != "")
 924                 {
 925                         getWrappedLine_remaining = msgstr;
 926                         msgstr = "";
 927                         lines = 0;
 928                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 929                         {
 930                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 931                                 ++lines;
 932                         }
 933                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 934
 935                         if(getWrappedLine_remaining != "")
 936                         {
 937                                 msgstr = strcat(msgstr, "\n");
 938                                 flood = 2;
 939                         }
 940
 941                         if(time >= source.flood_field)
 942                         {
 943                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 944                         }
 945                         else
 946                         {
 947                                 flood = 1;
 948                                 msgstr = fullmsgstr;
 949                         }
 950                 }
 951                 else
 952                 {
 953                         if(time >= source.flood_field)
 954                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 955                         else
 956                                 flood = 1;
 957                 }
 958
 959                 if (timeoutStatus == 2) //when game is paused, no flood protection
 960                         source.flood_field = flood = 0;
 961         }
 962
 963         if(flood == 2) // cannot happen for empty msgstr
 964         {
 965                 if(autocvar_g_chat_flood_notify_flooder)
 966                 {
 967                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 968                         sourcecmsgstr = "";
 969                 }
 970                 else
 971                 {
 972                         sourcemsgstr = fullmsgstr;
 973                         sourcecmsgstr = fullcmsgstr;
 974                 }
 975                 cmsgstr = "";
 976         }
 977         else
 978         {
 979                 sourcemsgstr = msgstr;
 980                 sourcecmsgstr = cmsgstr;
 981         }
 982
 983         if(!privatesay)
 984         if(source.classname != "player")
 985         {
 986                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 987                         teamsay = -1; // spectators
 988         }
 989
 990         if(flood)
 991                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 992
 993         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 994         if(privatesay)
 995                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 996
 997         if(source.muted)
 998         {
 999                 // always fake the message
1000                 ret = -1;
1001         }
1002         else if(flood == 1)
1003         {
1004                 if(autocvar_g_chat_flood_notify_flooder)
1005                 {
1006                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1007                         ret = 0;
1008                 }
1009                 else
1010                         ret = -1;
1011         }
1012         else
1013         {
1014                 ret = 1;
1015         }
1016
1017         if(sourcemsgstr != "" && ret != 0)
1018         {
1019                 if(ret < 0) // fake
1020                 {
1021                         sprint(source, sourcemsgstr);
1022                         if(sourcecmsgstr != "" && !privatesay)
1023                                 centerprint(source, sourcecmsgstr);
1024                 }
1025                 else if(privatesay)
1026                 {
1027                         sprint(source, sourcemsgstr);
1028                         sprint(privatesay, msgstr);
1029                         if(cmsgstr != "")
1030                                 centerprint(privatesay, cmsgstr);
1031                 }
1032                 else if(teamsay > 0)
1033                 {
1034                         sprint(source, sourcemsgstr);
1035                         if(sourcecmsgstr != "")
1036                                 centerprint(source, sourcecmsgstr);
1037                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1038                                 if(head != source)
1039                                 {
1040                                         sprint(head, msgstr);
1041                                         if(cmsgstr != "")
1042                                                 centerprint(head, cmsgstr);
1043                                 }
1044                 }
1045                 else if(teamsay < 0)
1046                 {
1047                         sprint(source, sourcemsgstr);
1048                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1049                                 if(head != source)
1050                                         sprint(head, msgstr);
1051                 }
1052                 else if(sourcemsgstr != msgstr)
1053                 {
1054                         sprint(source, sourcemsgstr);
1055                         FOR_EACH_REALCLIENT(head)
1056                                 if(head != source)
1057                                         sprint(head, msgstr);
1058                 }
1059                 else
1060                         bprint(msgstr);
1061         }
1062
1063         return ret;
1064 }
1065
1066 float GetVoiceMessageVoiceType(string type)
1067 {
1068         if(type == "taunt")
1069                 return VOICETYPE_TAUNT;
1070         if(type == "teamshoot")
1071                 return VOICETYPE_LASTATTACKER;
1072         return VOICETYPE_TEAMRADIO;
1073 }
1074
1075 string allvoicesamples;
1076 .string GetVoiceMessageSampleField(string type)
1077 {
1078         GetPlayerSoundSampleField_notFound = 0;
1079         switch(type)
1080         {
1081 #define _VOICEMSG(m) case #m: return playersound_##m;
1082                 ALLVOICEMSGS
1083 #undef _VOICEMSG
1084         }
1085         GetPlayerSoundSampleField_notFound = 1;
1086         return playersound_taunt;
1087 }
1088
1089 .string GetPlayerSoundSampleField(string type)
1090 {
1091         GetPlayerSoundSampleField_notFound = 0;
1092         switch(type)
1093         {
1094 #define _VOICEMSG(m) case #m: return playersound_##m;
1095                 ALLPLAYERSOUNDS
1096 #undef _VOICEMSG
1097         }
1098         GetPlayerSoundSampleField_notFound = 1;
1099         return playersound_taunt;
1100 }
1101
1102 void PrecacheGlobalSound(string samplestring)
1103 {
1104         float n, i;
1105         tokenize_console(samplestring);
1106         n = stof(argv(1));
1107         if(n > 0)
1108         {
1109                 for(i = 1; i <= n; ++i)
1110                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1111         }
1112         else
1113         {
1114                 precache_sound(strcat(argv(0), ".wav"));
1115         }
1116 }
1117
1118 void PrecachePlayerSounds(string f)
1119 {
1120         float fh;
1121         string s;
1122         fh = fopen(f, FILE_READ);
1123         if(fh < 0)
1124                 return;
1125         while((s = fgets(fh)))
1126         {
1127                 if(tokenize_console(s) != 3)
1128                 {
1129                         dprint("Invalid sound info line: ", s, "\n");
1130                         continue;
1131                 }
1132                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1133         }
1134         fclose(fh);
1135
1136         if not(allvoicesamples)
1137         {
1138 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1139                 ALLVOICEMSGS
1140 #undef _VOICEMSG
1141                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1142         }
1143 }
1144
1145 void ClearPlayerSounds()
1146 {
1147 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1148         ALLPLAYERSOUNDS
1149         ALLVOICEMSGS
1150 #undef _VOICEMSG
1151 }
1152
1153 float LoadPlayerSounds(string f, float first)
1154 {
1155         float fh;
1156         string s;
1157         var .string field;
1158         fh = fopen(f, FILE_READ);
1159         if(fh < 0)
1160         {
1161                 dprint("Player sound file not found: ", f, "\n");
1162                 return 0;
1163         }
1164         while((s = fgets(fh)))
1165         {
1166                 if(tokenize_console(s) != 3)
1167                         continue;
1168                 field = GetPlayerSoundSampleField(argv(0));
1169                 if(GetPlayerSoundSampleField_notFound)
1170                         field = GetVoiceMessageSampleField(argv(0));
1171                 if(GetPlayerSoundSampleField_notFound)
1172                         continue;
1173                 if(self.field)
1174                         strunzone(self.field);
1175                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1176         }
1177         fclose(fh);
1178         return 1;
1179 }
1180
1181 .float modelindex_for_playersound;
1182 .float skinindex_for_playersound;
1183 void UpdatePlayerSounds()
1184 {
1185         if(self.modelindex == self.modelindex_for_playersound)
1186         if(self.skinindex == self.skinindex_for_playersound)
1187                 return;
1188         self.modelindex_for_playersound = self.modelindex;
1189         self.skinindex_for_playersound = self.skinindex;
1190         ClearPlayerSounds();
1191         LoadPlayerSounds("sound/player/default.sounds", 1);
1192         if(!autocvar_g_debug_defaultsounds)
1193                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1194                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1195 }
1196
1197 void FakeGlobalSound(string sample, float chan, float voicetype)
1198 {
1199         float n;
1200         float tauntrand;
1201
1202         if(sample == "")
1203                 return;
1204
1205         tokenize_console(sample);
1206         n = stof(argv(1));
1207         if(n > 0)
1208                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1209         else
1210                 sample = strcat(argv(0), ".wav"); // randomization
1211
1212         switch(voicetype)
1213         {
1214                 case VOICETYPE_LASTATTACKER_ONLY:
1215                         break;
1216                 case VOICETYPE_LASTATTACKER:
1217                         if(self.pusher)
1218                         {
1219                                 msg_entity = self;
1220                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1221                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1222                         }
1223                         break;
1224                 case VOICETYPE_TEAMRADIO:
1225                         msg_entity = self;
1226                         if(msg_entity.cvar_cl_voice_directional == 1)
1227                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1228                         else
1229                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1230                         break;
1231                 case VOICETYPE_AUTOTAUNT:
1232                         if(!sv_autotaunt)
1233                                 break;
1234                         if(!sv_taunt)
1235                                 break;
1236                         if(sv_gentle)
1237                                 break;
1238                         tauntrand = random();
1239                         msg_entity = self;
1240                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1241                         {
1242                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1243                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1244                                 else
1245                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1246                         }
1247                         break;
1248                 case VOICETYPE_TAUNT:
1249                         if(self.classname == "player")
1250                                 if(self.deadflag == DEAD_NO)
1251                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1252                         if(!sv_taunt)
1253                                 break;
1254                         if(sv_gentle)
1255                                 break;
1256                         msg_entity = self;
1257                         if (msg_entity.cvar_cl_voice_directional >= 1)
1258                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1259                         else
1260                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1261                         break;
1262                 case VOICETYPE_PLAYERSOUND:
1263                         msg_entity = self;
1264                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1265                         break;
1266                 default:
1267                         backtrace("Invalid voice type!");
1268                         break;
1269         }
1270 }
1271
1272 void GlobalSound(string sample, float chan, float voicetype)
1273 {
1274         float n;
1275         float tauntrand;
1276
1277         if(sample == "")
1278                 return;
1279
1280         tokenize_console(sample);
1281         n = stof(argv(1));
1282         if(n > 0)
1283                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1284         else
1285                 sample = strcat(argv(0), ".wav"); // randomization
1286
1287         switch(voicetype)
1288         {
1289                 case VOICETYPE_LASTATTACKER_ONLY:
1290                         if(self.pusher)
1291                         {
1292                                 msg_entity = self.pusher;
1293                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1294                                 {
1295                                         if(msg_entity.cvar_cl_voice_directional == 1)
1296                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1297                                         else
1298                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1299                                 }
1300                         }
1301                         break;
1302                 case VOICETYPE_LASTATTACKER:
1303                         if(self.pusher)
1304                         {
1305                                 msg_entity = self.pusher;
1306                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1307                                 {
1308                                         if(msg_entity.cvar_cl_voice_directional == 1)
1309                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1310                                         else
1311                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1312                                 }
1313                                 msg_entity = self;
1314                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1315                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1316                         }
1317                         break;
1318                 case VOICETYPE_TEAMRADIO:
1319                         FOR_EACH_REALCLIENT(msg_entity)
1320                                 if(!teamplay || msg_entity.team == self.team)
1321                                 {
1322                                         if(msg_entity.cvar_cl_voice_directional == 1)
1323                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1324                                         else
1325                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1326                                 }
1327                         break;
1328                 case VOICETYPE_AUTOTAUNT:
1329                         if(!sv_autotaunt)
1330                                 break;
1331                         if(!sv_taunt)
1332                                 break;
1333                         if(sv_gentle)
1334                                 break;
1335                         tauntrand = random();
1336                         FOR_EACH_REALCLIENT(msg_entity)
1337                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1338                                 {
1339                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1340                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1341                                         else
1342                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1343                                 }
1344                         break;
1345                 case VOICETYPE_TAUNT:
1346                         if(self.classname == "player")
1347                                 if(self.deadflag == DEAD_NO)
1348                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1349                         if(!sv_taunt)
1350                                 break;
1351                         if(sv_gentle)
1352                                 break;
1353                         FOR_EACH_REALCLIENT(msg_entity)
1354                         {
1355                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1356                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1357                                 else
1358                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1359                         }
1360                         break;
1361                 case VOICETYPE_PLAYERSOUND:
1362                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1363                         break;
1364                 default:
1365                         backtrace("Invalid voice type!");
1366                         break;
1367         }
1368 }
1369
1370 void PlayerSound(.string samplefield, float chan, float voicetype)
1371 {
1372         GlobalSound(self.samplefield, chan, voicetype);
1373 }
1374
1375 void VoiceMessage(string type, string msg)
1376 {
1377         var .string sample;
1378         float voicetype, ownteam;
1379         float flood;
1380         sample = GetVoiceMessageSampleField(type);
1381
1382         if(GetPlayerSoundSampleField_notFound)
1383         {
1384                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1385                 return;
1386         }
1387
1388         voicetype = GetVoiceMessageVoiceType(type);
1389         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1390
1391         flood = Say(self, ownteam, world, msg, 1);
1392
1393         if (flood > 0)
1394                 GlobalSound(self.sample, CH_VOICE, voicetype);
1395         else if (flood < 0)
1396                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1397 }
1398
1399 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1400 {
1401 //      show_message
1402 //      0 (00) automove centerprint, admin message
1403 //      1 (01) automove centerprint, no admin message
1404 //      2 (10) no centerprint, admin message
1405 //      3 (11) no centerprint, no admin message
1406
1407         float lockteams_backup;
1408
1409         lockteams_backup = lockteams;  // backup any team lock
1410
1411         lockteams = 0;  // disable locked teams
1412
1413         TeamchangeFrags(client);  // move the players frags
1414         SetPlayerColors(client, team_colour - 1);  // set the players colour
1415         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1416
1417         lockteams = lockteams_backup;  // restore the team lock
1418
1419         LogTeamchange(client.playerid, client.team, type);
1420
1421         if not(show_message & 1) // admin message
1422                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1423
1424         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1425 }