qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_file != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, ibot, jbot, idx;
  16         float fh;
  17         vector v;
  18         string prefix;
  19         if(weaponstats_buffer < 0)
  20                 return;
  21         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  22         if(autocvar_sv_weaponstats_file != "")
  23         {
  24                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  25                 if(fh >= 0)
  26                 {
  27                         fputs(fh, "#begin statsfile\n");
  28                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  29                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  30                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  31                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  32                                 {
  33                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  34                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  35                                         if(v != '0 0 0')
  36                                         {
  37                                                 //vector is: kills hits damage
  38                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  39                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  40                                         }
  41                                 }
  42                         fputs(fh, "#end\n\n");
  43                         fclose(fh);
  44                         print("Weapon stats written\n");
  45                 }
  46         }
  47         buf_del(weaponstats_buffer);
  48         weaponstats_buffer = -1;
  49 }
  50
  51 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  52 {
  53         float idx;
  54         if(weaponstats_buffer < 0)
  55                 return;
  56         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  57                 return;
  58         if(awep > WEP_LAST || vwep > WEP_LAST)
  59                 return;
  60         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  61         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  62 }
  63 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  64 {
  65         if(damage < 0)
  66                 error("negative damage?");
  67         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  68 }
  69 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  70 {
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  72 }
  73
  74 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  75 // merged player_run and player_stand to player_anim
  76 // added death animations to player_anim
  77 // can now spawn thrown weapons from anywhere, not just from players
  78 // thrown weapons now fade out after 20 seconds
  79 // created PlayerGib function
  80 // PlayerDie no longer uses hitloc or damage
  81 // PlayerDie now supports dying animations as well as gibbing
  82 // cleaned up PlayerDie a lot
  83 // added CopyBody
  84
  85 .entity pusher;
  86 .float pushltime;
  87
  88 void CopyBody(float keepvelocity)
  89 {
  90         local entity oldself;
  91         if (self.effects & EF_NODRAW)
  92                 return;
  93         oldself = self;
  94         self = spawn();
  95         self.enemy = oldself;
  96         self.lip = oldself.lip;
  97         self.colormap = oldself.colormap;
  98         self.glowmod = oldself.glowmod;
  99         self.iscreature = oldself.iscreature;
 100         self.angles = oldself.angles;
 101         self.avelocity = oldself.avelocity;
 102         self.classname = "body";
 103         self.damageforcescale = oldself.damageforcescale;
 104         self.effects = oldself.effects;
 105         self.event_damage = oldself.event_damage;
 106         self.animstate_startframe = oldself.animstate_startframe;
 107         self.animstate_numframes = oldself.animstate_numframes;
 108         self.animstate_framerate = oldself.animstate_framerate;
 109         self.animstate_starttime = oldself.animstate_starttime;
 110         self.animstate_endtime = oldself.animstate_endtime;
 111         self.animstate_override = oldself.animstate_override;
 112         self.animstate_looping = oldself.animstate_looping;
 113         self.frame = oldself.frame;
 114         self.dead_frame = oldself.dead_frame;
 115         self.pain_finished = oldself.pain_finished;
 116         self.health = oldself.health;
 117         self.armorvalue = oldself.armorvalue;
 118         self.armortype = oldself.armortype;
 119         self.model = oldself.model;
 120         self.modelindex = oldself.modelindex;
 121         self.modelindex_lod0 = oldself.modelindex_lod0;
 122         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 123         self.modelindex_lod1 = oldself.modelindex_lod1;
 124         self.modelindex_lod2 = oldself.modelindex_lod2;
 125         self.skinindex = oldself.skinindex;
 126         self.species = oldself.species;
 127         self.movetype = oldself.movetype;
 128         self.nextthink = oldself.nextthink;
 129         self.solid = oldself.solid;
 130         self.ballistics_density = oldself.ballistics_density;
 131         self.takedamage = oldself.takedamage;
 132         self.think = oldself.think;
 133         self.customizeentityforclient = oldself.customizeentityforclient;
 134         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 135         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 136         if (keepvelocity == 1)
 137                 self.velocity = oldself.velocity;
 138         self.oldvelocity = self.velocity;
 139         self.fade_time = oldself.fade_time;
 140         self.fade_rate = oldself.fade_rate;
 141         //self.weapon = oldself.weapon;
 142         setorigin(self, oldself.origin);
 143         setsize(self, oldself.mins, oldself.maxs);
 144         self.prevorigin = oldself.origin;
 145         self.reset = SUB_Remove;
 146
 147         Drag_MoveDrag(oldself, self);
 148
 149         self = oldself;
 150 }
 151
 152 float player_getspecies()
 153 {
 154         float s;
 155         get_model_parameters(self.model, self.skinindex);
 156         s = get_model_parameters_species;
 157         get_model_parameters(string_null, 0);
 158         if(s < 0)
 159                 return SPECIES_HUMAN;
 160         return s;
 161 }
 162
 163 void player_setupanimsformodel()
 164 {
 165         local string animfilename;
 166         local float animfile;
 167         // defaults for legacy .zym models without animinfo files
 168         self.anim_die1 = '0 1 0.5'; // 2 seconds
 169         self.anim_die2 = '1 1 0.5'; // 2 seconds
 170         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 171         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 172         self.anim_duckwalk = '4 1 1';
 173         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 174         self.anim_duckidle = '6 1 1';
 175         self.anim_idle = '7 1 1';
 176         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 177         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 178         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 179         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 180         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 181         self.anim_run = '13 1 1';
 182         self.anim_runbackwards = '14 1 1';
 183         self.anim_strafeleft = '15 1 1';
 184         self.anim_straferight = '16 1 1';
 185         self.anim_dead1 = '17 1 1';
 186         self.anim_dead2 = '18 1 1';
 187         self.anim_forwardright = '19 1 1';
 188         self.anim_forwardleft = '20 1 1';
 189         self.anim_backright = '21 1 1';
 190         self.anim_backleft  = '22 1 1';
 191         self.anim_melee = '23 1 1';
 192         animparseerror = FALSE;
 193         animfilename = strcat(self.model, ".animinfo");
 194         animfile = fopen(animfilename, FILE_READ);
 195         if (animfile >= 0)
 196         {
 197                 self.anim_die1         = animparseline(animfile);
 198                 self.anim_die2         = animparseline(animfile);
 199                 self.anim_draw         = animparseline(animfile);
 200                 self.anim_duck         = animparseline(animfile);
 201                 self.anim_duckwalk     = animparseline(animfile);
 202                 self.anim_duckjump     = animparseline(animfile);
 203                 self.anim_duckidle     = animparseline(animfile);
 204                 self.anim_idle         = animparseline(animfile);
 205                 self.anim_jump         = animparseline(animfile);
 206                 self.anim_pain1        = animparseline(animfile);
 207                 self.anim_pain2        = animparseline(animfile);
 208                 self.anim_shoot        = animparseline(animfile);
 209                 self.anim_taunt        = animparseline(animfile);
 210                 self.anim_run          = animparseline(animfile);
 211                 self.anim_runbackwards = animparseline(animfile);
 212                 self.anim_strafeleft   = animparseline(animfile);
 213                 self.anim_straferight  = animparseline(animfile);
 214                 self.anim_forwardright = animparseline(animfile);
 215                 self.anim_forwardleft  = animparseline(animfile);
 216                 self.anim_backright    = animparseline(animfile);
 217                 self.anim_backleft     = animparseline(animfile);
 218                 self.anim_melee        = animparseline(animfile);
 219                 fclose(animfile);
 220
 221                 // derived anims
 222                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 223                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 224
 225                 if (animparseerror)
 226                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 227         }
 228         else
 229                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 230         // reset animstate now
 231         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 232 };
 233
 234 void player_anim (void)
 235 {
 236         updateanim(self);
 237         if (self.weaponentity)
 238                 updateanim(self.weaponentity);
 239
 240         if (self.deadflag != DEAD_NO)
 241         {
 242                 if (time > self.animstate_endtime)
 243                 {
 244                         if (self.maxs_z > 5)
 245                         {
 246                                 self.maxs_z = 5;
 247                                 setsize(self, self.mins, self.maxs);
 248                         }
 249                         self.frame = self.dead_frame;
 250                 }
 251                 return;
 252         }
 253
 254         if (!self.animstate_override)
 255         {
 256                 if (!(self.flags & FL_ONGROUND))
 257                 {
 258                         if (self.crouch)
 259                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 260                         else
 261                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 262                         self.restart_jump = FALSE;
 263                 }
 264                 else if (self.crouch)
 265                 {
 266                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 267                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 268                         else
 269                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 270                 }
 271                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 272                 {
 273                         if (self.movement_x > 0 && self.movement_y == 0)
 274                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 275                         else if (self.movement_x < 0 && self.movement_y == 0)
 276                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 277                         else if (self.movement_x == 0 && self.movement_y > 0)
 278                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 279                         else if (self.movement_x == 0 && self.movement_y < 0)
 280                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 281                         else if (self.movement_x > 0 && self.movement_y > 0)
 282                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 283                         else if (self.movement_x > 0 && self.movement_y < 0)
 284                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 285                         else if (self.movement_x < 0 && self.movement_y > 0)
 286                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 287                         else if (self.movement_x < 0 && self.movement_y < 0)
 288                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 289                         else
 290                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 291                 }
 292                 else
 293                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 294         }
 295
 296         if (self.weaponentity)
 297         if (!self.weaponentity.animstate_override)
 298                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 299 }
 300
 301 void SpawnThrownWeapon (vector org, float w)
 302 {
 303         if(g_minstagib)
 304         if(self.ammo_cells <= 0)
 305                 return;
 306
 307         if(g_pinata)
 308         {
 309                 float j;
 310                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 311                 {
 312                         if(self.weapons & W_WeaponBit(j))
 313                                 if(W_IsWeaponThrowable(j))
 314                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 315                 }
 316         }
 317         else
 318         {
 319                 if(W_IsWeaponThrowable(self.weapon))
 320                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 321         }
 322 }
 323
 324 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 325 {
 326         local float take, save;
 327         vector v;
 328         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 329
 330         // damage resistance (ignore most of the damage from a bullet or similar)
 331         damage = max(damage - 5, 1);
 332
 333         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 334         take = v_x;
 335         save = v_y;
 336
 337         if(sound_allowed(MSG_BROADCAST, attacker))
 338         {
 339                 if (save > 10)
 340                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 341                 else if (take > 30)
 342                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 343                 else if (take > 10)
 344                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 345         }
 346
 347         if (take > 50)
 348                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 349         if (take > 100)
 350                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 351
 352         if (!(self.flags & FL_GODMODE))
 353         {
 354                 self.armorvalue = self.armorvalue - save;
 355                 self.health = self.health - take;
 356                 // pause regeneration for 5 seconds
 357                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 358         }
 359         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 360         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 361         self.dmg_inflictor = inflictor;
 362
 363         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 364         {
 365                 // don't use any animations as a gib
 366                 self.frame = 0;
 367                 self.dead_frame = 0;
 368                 // view just above the floor
 369                 self.view_ofs = '0 0 4';
 370
 371                 Violence_GibSplash(self, 1, 1, attacker);
 372                 self.modelindex = 0; // restore later
 373                 self.solid = SOLID_NOT; // restore later
 374         }
 375 }
 376
 377 void ClientKill_Now_TeamChange();
 378 void freezetag_CheckWinner();
 379
 380 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 381 {
 382         local float take, save, waves, sdelay, dh, da, j;
 383         vector v;
 384         float valid_damage_for_weaponstats;
 385         float excess;
 386
 387         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 388                 return;
 389
 390         dh = max(self.health, 0);
 391         da = max(self.armorvalue, 0);
 392
 393         if(!DEATH_ISSPECIAL(deathtype))
 394         {
 395                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 396                 if(self != attacker)
 397                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 398         }
 399
 400         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 401         {
 402                 // tuba causes blood to come out of the ears
 403                 vector ear1, ear2;
 404                 vector d;
 405                 float f;
 406                 ear1 = self.origin;
 407                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 408                 ear2 = ear1;
 409                 makevectors(self.angles);
 410                 ear1 += v_right * -10;
 411                 ear2 += v_right * +10;
 412                 d = inflictor.origin - self.origin;
 413                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 414                 force = v_right * vlen(force);
 415                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 416                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 417                 if(f > 0)
 418                 {
 419                         hitloc = ear1;
 420                         force = force * -1;
 421                 }
 422                 else
 423                 {
 424                         hitloc = ear2;
 425                         // force is already good
 426                 }
 427         }
 428         else
 429                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 430
 431         if (!g_minstagib)
 432         {
 433                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 434                 take = v_x;
 435                 save = v_y;
 436         }
 437         else
 438         {
 439                 save = 0;
 440                 take = damage;
 441         }
 442
 443         frag_inflictor = inflictor;
 444         frag_attacker = attacker;
 445         frag_target = self;
 446         damage_take = take;
 447         damage_save = save;
 448         damage_force = force;
 449         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 450         take = bound(0, damage_take, self.health);
 451         save = bound(0, damage_save, self.armorvalue);
 452         excess = max(0, damage - take - save);
 453
 454         if(sound_allowed(MSG_BROADCAST, attacker))
 455         {
 456                 if (save > 10)
 457                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 458                 else if (take > 30)
 459                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 460                 else if (take > 10)
 461                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 462         }
 463
 464         if (take > 50)
 465                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 466         if (take > 100)
 467                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 468
 469         if (time >= self.spawnshieldtime)
 470         {
 471                 if (!(self.flags & FL_GODMODE))
 472                 {
 473                         self.armorvalue = self.armorvalue - save;
 474                         self.health = self.health - take;
 475                         // pause regeneration for 5 seconds
 476                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 477
 478                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 479                         {
 480                                 self.pain_finished = time + 0.5;        //Supajoe
 481
 482                                 if(sv_gentle < 1) {
 483                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 484                                         {
 485                                                 if (random() > 0.5)
 486                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 487                                                 else
 488                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 489                                         }
 490
 491                                         if(sound_allowed(MSG_BROADCAST, attacker))
 492                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 493                                         if(self.health > 1)
 494                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 495                                         {
 496                                                 if(deathtype == DEATH_FALL)
 497                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 498                                                 else if(self.health > 75) // TODO make a "gentle" version?
 499                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 500                                                 else if(self.health > 50)
 501                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 502                                                 else if(self.health > 25)
 503                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 504                                                 else
 505                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 506                                         }
 507                                 }
 508
 509                                 // throw off bot aim temporarily
 510                                 local float shake;
 511                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 512                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 513                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 514                         }
 515                 }
 516                 else
 517                         self.max_armorvalue += (save + take);
 518         }
 519         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 520         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 521         self.dmg_inflictor = inflictor;
 522
 523         if(attacker == self)
 524         {
 525                 // don't reset pushltime for self damage as it may be an attempt to
 526                 // escape a lava pit or similar
 527                 //self.pushltime = 0;
 528         }
 529         else if(attacker.classname == "player" || attacker.classname == "gib")
 530         {
 531                 self.pusher = attacker;
 532                 self.pushltime = time + autocvar_g_maxpushtime;
 533         }
 534         else if(time < self.pushltime)
 535         {
 536                 attacker = self.pusher;
 537                 self.pushltime = max(self.pushltime, time + 0.6);
 538         }
 539         else
 540                 self.pushltime = 0;
 541
 542         float abot, vbot, awep;
 543         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 544         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 545
 546         valid_damage_for_weaponstats = 0;
 547         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 548         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 549         if(attacker && self != attacker)
 550         if(IsDifferentTeam(self, attacker))
 551         {
 552                 if(DEATH_ISSPECIAL(deathtype))
 553                         awep = attacker.weapon;
 554                 else
 555                         awep = DEATH_WEAPONOF(deathtype);
 556                 valid_damage_for_weaponstats = 1;
 557         }
 558
 559         if(valid_damage_for_weaponstats)
 560         {
 561                 dh = dh - max(self.health, 0);
 562                 da = da - max(self.armorvalue, 0);
 563                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 564         }
 565
 566         if (self.health < 1)
 567         {
 568                 float defer_ClientKill_Now_TeamChange;
 569                 defer_ClientKill_Now_TeamChange = FALSE;
 570
 571                 if(self.alivetime)
 572                 {
 573                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 574                         self.alivetime = 0;
 575                 }
 576
 577                 if(valid_damage_for_weaponstats)
 578                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 579
 580                 if(sv_gentle < 1) // TODO make a "gentle" version?
 581                 if(sound_allowed(MSG_BROADCAST, attacker))
 582                 {
 583                         if(deathtype == DEATH_DROWN)
 584                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 585                         else
 586                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 587                 }
 588
 589                 // get rid of kill indicator
 590                 if(self.killindicator)
 591                 {
 592                         remove(self.killindicator);
 593                         self.killindicator = world;
 594                         if(self.killindicator_teamchange)
 595                                 defer_ClientKill_Now_TeamChange = TRUE;
 596
 597                         if(self.classname == "body")
 598                         if(deathtype == DEATH_KILL)
 599                         {
 600                                 // for the lemmings fans, a small harmless explosion
 601                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 602                         }
 603                 }
 604
 605                 if(!g_freezetag)
 606                 {
 607                         // become fully visible
 608                         self.alpha = 1;
 609                         // throw a weapon
 610                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 611                 }
 612
 613                 // print an obituary message
 614                 Obituary (attacker, inflictor, self, deathtype);
 615                 race_PreDie();
 616                 DropAllRunes(self);
 617
 618                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 619                 {
 620                         PutClientInServer();
 621                         count_alive_players(); // re-count players
 622                         freezetag_CheckWinner();
 623                         return;
 624                 }
 625
 626                 frag_attacker = attacker;
 627                 frag_inflictor = inflictor;
 628                 frag_target = self;
 629                 MUTATOR_CALLHOOK(PlayerDies);
 630                 weapon_action(self.weapon, WR_PLAYERDEATH);
 631
 632                 if(self.flagcarried)
 633                 {
 634                         if(attacker.classname != "player" && attacker.classname != "gib")
 635                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 636                         else if(attacker.team == self.team)
 637                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 638                         else
 639                                 DropFlag(self.flagcarried, world, attacker);
 640                 }
 641                 if(self.ballcarried && g_nexball)
 642                         DropBall(self.ballcarried, self.origin, self.velocity);
 643                 Portal_ClearAllLater(self);
 644
 645                 if(clienttype(self) == CLIENTTYPE_REAL)
 646                 {
 647                         stuffcmd(self, "-zoom\n");
 648                         self.fixangle = TRUE;
 649                         //msg_entity = self;
 650                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 651                         //WriteAngle (MSG_ONE, self.v_angle_x);
 652                         //WriteAngle (MSG_ONE, self.v_angle_y);
 653                         //WriteAngle (MSG_ONE, 80);
 654                 }
 655
 656                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 657                         ClientKill_Now_TeamChange();
 658
 659                 if(g_arena)
 660                         Spawnqueue_Unmark(self);
 661
 662                 if(g_freezetag)
 663                         return;
 664
 665                 // when we get here, player actually dies
 666                 // clear waypoints (do this AFTER FreezeTag)
 667                 WaypointSprite_PlayerDead();
 668
 669                 // make the corpse upright (not tilted)
 670                 self.angles_x = 0;
 671                 self.angles_z = 0;
 672                 // don't spin
 673                 self.avelocity = '0 0 0';
 674                 // view from the floor
 675                 self.view_ofs = '0 0 -8';
 676                 // toss the corpse
 677                 self.movetype = MOVETYPE_TOSS;
 678                 // shootable corpse
 679                 self.solid = SOLID_CORPSE;
 680                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 681                 // don't stick to the floor
 682                 self.flags &~= FL_ONGROUND;
 683                 // dying animation
 684                 self.deadflag = DEAD_DYING;
 685                 // when to allow respawn
 686                 sdelay = 0;
 687                 waves = 0;
 688                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 689                 if(!sdelay)
 690                 {
 691                         if(g_cts)
 692                                 sdelay = 0; // no respawn delay in CTS
 693                         else
 694                                 sdelay = autocvar_g_respawn_delay;
 695                 }
 696                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 697                 if(!waves)
 698                         waves = autocvar_g_respawn_waves;
 699                 if(waves)
 700                         self.death_time = ceil((time + sdelay) / waves) * waves;
 701                 else
 702                         self.death_time = time + sdelay;
 703                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 704                         self.respawn_countdown = 10; // first number to count down from is 10
 705                 else
 706                         self.respawn_countdown = -1; // do not count down
 707                 if (random() < 0.5)
 708                 {
 709                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 710                         self.dead_frame = self.anim_dead1_x;
 711                 }
 712                 else
 713                 {
 714                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 715                         self.dead_frame = self.anim_dead2_x;
 716                 }
 717                 // set damage function to corpse damage
 718                 self.event_damage = PlayerCorpseDamage;
 719                 // call the corpse damage function just in case it wants to gib
 720                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 721                 // set up to fade out later
 722                 SUB_SetFade (self, time + 6 + random (), 1);
 723
 724                 if(sv_gentle > 0 || autocvar_ekg) {
 725                         // remove corpse
 726                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 727                 }
 728
 729                 // reset fields the weapons may use just in case
 730                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 731                 {
 732                         weapon_action(j, WR_RESETPLAYER);
 733                         ATTACK_FINISHED_FOR(self, j) = 0;
 734                 }
 735         }
 736 }
 737
 738 .float muted; // to be used by prvm_edictset server playernumber muted 1
 739 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 740 // message "": do not say, just test flood control
 741 // return value:
 742 //   1 = accept
 743 //   0 = reject
 744 //  -1 = fake accept
 745 {
 746         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 747         float flood, privatemsgprefixlen;
 748         var .float flood_field;
 749         entity head;
 750         float ret;
 751
 752         if(Ban_MaybeEnforceBan(source))
 753                 return 0;
 754
 755         if(!teamsay && !privatesay)
 756                 if(substring(msgin, 0, 1) == " ")
 757                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 758
 759         msgin = formatmessage(msgin);
 760
 761         if(source.classname != "player")
 762                 colorstr = "^0"; // black for spectators
 763         else if(teams_matter)
 764                 colorstr = Team_ColorCode(source.team);
 765         else
 766                 teamsay = FALSE;
 767
 768         if(intermission_running)
 769                 teamsay = FALSE;
 770
 771         if(msgin != "")
 772                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 773
 774         /*
 775          * using bprint solves this... me stupid
 776         // how can we prevent the message from appearing in a listen server?
 777         // for now, just give "say" back and only handle say_team
 778         if(!teamsay)
 779         {
 780                 clientcommand(self, strcat("say ", msgin));
 781                 return;
 782         }
 783         */
 784
 785         if(autocvar_g_chat_teamcolors)
 786                 namestr = playername(source);
 787         else
 788                 namestr = source.netname;
 789
 790         if(msgin != "")
 791         {
 792                 if(privatesay)
 793                 {
 794                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 795                         privatemsgprefixlen = strlen(msgstr);
 796                         msgstr = strcat(msgstr, msgin);
 797                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 798                         if(autocvar_g_chat_teamcolors)
 799                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 800                         else
 801                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 802                 }
 803                 else if(teamsay)
 804                 {
 805                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 806                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 807                 }
 808                 else
 809                 {
 810                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 811                         cmsgstr = "";
 812                 }
 813                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 814         }
 815         else
 816         {
 817                 msgstr = cmsgstr = "";
 818         }
 819
 820         fullmsgstr = msgstr;
 821         fullcmsgstr = cmsgstr;
 822
 823         // FLOOD CONTROL
 824         flood = 0;
 825         if(floodcontrol)
 826         {
 827                 float flood_spl;
 828                 float flood_burst;
 829                 float flood_lmax;
 830                 float lines;
 831                 if(privatesay)
 832                 {
 833                         flood_spl = autocvar_g_chat_flood_spl_tell;
 834                         flood_burst = autocvar_g_chat_flood_burst_tell;
 835                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 836                         flood_field = floodcontrol_chattell;
 837                 }
 838                 else if(teamsay)
 839                 {
 840                         flood_spl = autocvar_g_chat_flood_spl_team;
 841                         flood_burst = autocvar_g_chat_flood_burst_team;
 842                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 843                         flood_field = floodcontrol_chatteam;
 844                 }
 845                 else
 846                 {
 847                         flood_spl = autocvar_g_chat_flood_spl;
 848                         flood_burst = autocvar_g_chat_flood_burst;
 849                         flood_lmax = autocvar_g_chat_flood_lmax;
 850                         flood_field = floodcontrol_chat;
 851                 }
 852                 flood_burst = max(0, flood_burst - 1);
 853                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 854
 855                 // do flood control for the default line size
 856                 if(msgstr != "")
 857                 {
 858                         getWrappedLine_remaining = msgstr;
 859                         msgstr = "";
 860                         lines = 0;
 861                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 862                         {
 863                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 864                                 ++lines;
 865                         }
 866                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 867
 868                         if(getWrappedLine_remaining != "")
 869                         {
 870                                 msgstr = strcat(msgstr, "\n");
 871                                 flood = 2;
 872                         }
 873
 874                         if(time >= source.flood_field)
 875                         {
 876                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 877                         }
 878                         else
 879                         {
 880                                 flood = 1;
 881                                 msgstr = fullmsgstr;
 882                         }
 883                 }
 884                 else
 885                 {
 886                         if(time >= source.flood_field)
 887                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 888                         else
 889                                 flood = 1;
 890                 }
 891
 892                 if (timeoutStatus == 2) //when game is paused, no flood protection
 893                         source.flood_field = flood = 0;
 894         }
 895
 896         if(flood == 2) // cannot happen for empty msgstr
 897         {
 898                 if(autocvar_g_chat_flood_notify_flooder)
 899                 {
 900                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 901                         sourcecmsgstr = "";
 902                 }
 903                 else
 904                 {
 905                         sourcemsgstr = fullmsgstr;
 906                         sourcecmsgstr = fullcmsgstr;
 907                 }
 908                 cmsgstr = "";
 909         }
 910         else
 911         {
 912                 sourcemsgstr = msgstr;
 913                 sourcecmsgstr = cmsgstr;
 914         }
 915
 916         if(!privatesay)
 917         if(source.classname != "player")
 918         {
 919                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 920                         teamsay = -1; // spectators
 921         }
 922
 923         if(flood)
 924                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 925
 926         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 927         if(privatesay)
 928                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 929
 930         if(source.muted)
 931         {
 932                 // always fake the message
 933                 ret = -1;
 934         }
 935         else if(flood == 1)
 936         {
 937                 if(autocvar_g_chat_flood_notify_flooder)
 938                 {
 939                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 940                         ret = 0;
 941                 }
 942                 else
 943                         ret = -1;
 944         }
 945         else
 946         {
 947                 ret = 1;
 948         }
 949
 950         if(sourcemsgstr != "" && ret != 0)
 951         {
 952                 if(ret < 0) // fake
 953                 {
 954                         sprint(source, sourcemsgstr);
 955                         if(sourcecmsgstr != "" && !privatesay)
 956                                 centerprint(source, sourcecmsgstr);
 957                 }
 958                 else if(privatesay)
 959                 {
 960                         sprint(source, sourcemsgstr);
 961                         sprint(privatesay, msgstr);
 962                         if(cmsgstr != "")
 963                                 centerprint(privatesay, cmsgstr);
 964                 }
 965                 else if(teamsay > 0)
 966                 {
 967                         sprint(source, sourcemsgstr);
 968                         if(sourcecmsgstr != "")
 969                                 centerprint(source, sourcecmsgstr);
 970                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 971                                 if(head != source)
 972                                 {
 973                                         sprint(head, msgstr);
 974                                         if(cmsgstr != "")
 975                                                 centerprint(head, cmsgstr);
 976                                 }
 977                 }
 978                 else if(teamsay < 0)
 979                 {
 980                         sprint(source, sourcemsgstr);
 981                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 982                                 if(head != source)
 983                                         sprint(head, msgstr);
 984                 }
 985                 else if(sourcemsgstr != msgstr)
 986                 {
 987                         sprint(source, sourcemsgstr);
 988                         FOR_EACH_REALCLIENT(head)
 989                                 if(head != source)
 990                                         sprint(head, msgstr);
 991                 }
 992                 else
 993                         bprint(msgstr);
 994         }
 995
 996         return ret;
 997 }
 998
 999 float GetVoiceMessageVoiceType(string type)
1000 {
1001         if(type == "taunt")
1002                 return VOICETYPE_TAUNT;
1003         if(type == "teamshoot")
1004                 return VOICETYPE_LASTATTACKER;
1005         return VOICETYPE_TEAMRADIO;
1006 }
1007
1008 string allvoicesamples;
1009 .string GetVoiceMessageSampleField(string type)
1010 {
1011         GetPlayerSoundSampleField_notFound = 0;
1012         switch(type)
1013         {
1014 #define _VOICEMSG(m) case #m: return playersound_##m;
1015                 ALLVOICEMSGS
1016 #undef _VOICEMSG
1017         }
1018         GetPlayerSoundSampleField_notFound = 1;
1019         return playersound_taunt;
1020 }
1021
1022 .string GetPlayerSoundSampleField(string type)
1023 {
1024         GetPlayerSoundSampleField_notFound = 0;
1025         switch(type)
1026         {
1027 #define _VOICEMSG(m) case #m: return playersound_##m;
1028                 ALLPLAYERSOUNDS
1029 #undef _VOICEMSG
1030         }
1031         GetPlayerSoundSampleField_notFound = 1;
1032         return playersound_taunt;
1033 }
1034
1035 void PrecacheGlobalSound(string samplestring)
1036 {
1037         float n, i;
1038         tokenize_console(samplestring);
1039         n = stof(argv(1));
1040         if(n > 0)
1041         {
1042                 for(i = 1; i <= n; ++i)
1043                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1044         }
1045         else
1046         {
1047                 precache_sound(strcat(argv(0), ".wav"));
1048         }
1049 }
1050
1051 void PrecachePlayerSounds(string f)
1052 {
1053         float fh;
1054         string s;
1055         fh = fopen(f, FILE_READ);
1056         if(fh < 0)
1057                 return;
1058         while((s = fgets(fh)))
1059         {
1060                 if(tokenize_console(s) != 3)
1061                 {
1062                         dprint("Invalid sound info line: ", s, "\n");
1063                         continue;
1064                 }
1065                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1066         }
1067         fclose(fh);
1068
1069         if not(allvoicesamples)
1070         {
1071 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1072                 ALLVOICEMSGS
1073 #undef _VOICEMSG
1074                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1075         }
1076 }
1077
1078 void ClearPlayerSounds()
1079 {
1080 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1081         ALLPLAYERSOUNDS
1082         ALLVOICEMSGS
1083 #undef _VOICEMSG
1084 }
1085
1086 float LoadPlayerSounds(string f, float first)
1087 {
1088         float fh;
1089         string s;
1090         var .string field;
1091         fh = fopen(f, FILE_READ);
1092         if(fh < 0)
1093         {
1094                 dprint("Player sound file not found: ", f, "\n");
1095                 return 0;
1096         }
1097         while((s = fgets(fh)))
1098         {
1099                 if(tokenize_console(s) != 3)
1100                         continue;
1101                 field = GetPlayerSoundSampleField(argv(0));
1102                 if(GetPlayerSoundSampleField_notFound)
1103                         field = GetVoiceMessageSampleField(argv(0));
1104                 if(GetPlayerSoundSampleField_notFound)
1105                         continue;
1106                 if(self.field)
1107                         strunzone(self.field);
1108                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1109         }
1110         fclose(fh);
1111         return 1;
1112 }
1113
1114 .float modelindex_for_playersound;
1115 .float skinindex_for_playersound;
1116 void UpdatePlayerSounds()
1117 {
1118         if(self.modelindex == self.modelindex_for_playersound)
1119         if(self.skinindex == self.skinindex_for_playersound)
1120                 return;
1121         self.modelindex_for_playersound = self.modelindex;
1122         self.skinindex_for_playersound = self.skinindex;
1123         ClearPlayerSounds();
1124         LoadPlayerSounds("sound/player/default.sounds", 1);
1125         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1126                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1127 }
1128
1129 void FakeGlobalSound(string sample, float chan, float voicetype)
1130 {
1131         float n;
1132         float tauntrand;
1133
1134         if(sample == "")
1135                 return;
1136
1137         tokenize_console(sample);
1138         n = stof(argv(1));
1139         if(n > 0)
1140                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1141         else
1142                 sample = strcat(argv(0), ".wav"); // randomization
1143
1144         switch(voicetype)
1145         {
1146                 case VOICETYPE_LASTATTACKER_ONLY:
1147                         break;
1148                 case VOICETYPE_LASTATTACKER:
1149                         if(self.pusher)
1150                         {
1151                                 msg_entity = self;
1152                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1153                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1154                         }
1155                         break;
1156                 case VOICETYPE_TEAMRADIO:
1157                         msg_entity = self;
1158                         if(msg_entity.cvar_cl_voice_directional == 1)
1159                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1160                         else
1161                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1162                         break;
1163                 case VOICETYPE_AUTOTAUNT:
1164                         if(!sv_autotaunt)
1165                                 break;
1166                         if(!sv_taunt)
1167                                 break;
1168                         if(sv_gentle)
1169                                 break;
1170                         tauntrand = random();
1171                         msg_entity = self;
1172                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1173                         {
1174                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1175                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1176                                 else
1177                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1178                         }
1179                         break;
1180                 case VOICETYPE_TAUNT:
1181                         if(self.classname == "player")
1182                                 if(self.deadflag == DEAD_NO)
1183                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1184                         if(!sv_taunt)
1185                                 break;
1186                         if(sv_gentle)
1187                                 break;
1188                         msg_entity = self;
1189                         if (msg_entity.cvar_cl_voice_directional >= 1)
1190                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1191                         else
1192                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1193                         break;
1194                 case VOICETYPE_PLAYERSOUND:
1195                         msg_entity = self;
1196                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1197                         break;
1198                 default:
1199                         backtrace("Invalid voice type!");
1200                         break;
1201         }
1202 }
1203
1204 void GlobalSound(string sample, float chan, float voicetype)
1205 {
1206         float n;
1207         float tauntrand;
1208
1209         if(sample == "")
1210                 return;
1211
1212         tokenize_console(sample);
1213         n = stof(argv(1));
1214         if(n > 0)
1215                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1216         else
1217                 sample = strcat(argv(0), ".wav"); // randomization
1218
1219         switch(voicetype)
1220         {
1221                 case VOICETYPE_LASTATTACKER_ONLY:
1222                         if(self.pusher)
1223                         {
1224                                 msg_entity = self.pusher;
1225                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1226                                 {
1227                                         if(msg_entity.cvar_cl_voice_directional == 1)
1228                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1229                                         else
1230                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1231                                 }
1232                         }
1233                         break;
1234                 case VOICETYPE_LASTATTACKER:
1235                         if(self.pusher)
1236                         {
1237                                 msg_entity = self.pusher;
1238                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1239                                 {
1240                                         if(msg_entity.cvar_cl_voice_directional == 1)
1241                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1242                                         else
1243                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1244                                 }
1245                                 msg_entity = self;
1246                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1247                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1248                         }
1249                         break;
1250                 case VOICETYPE_TEAMRADIO:
1251                         FOR_EACH_REALCLIENT(msg_entity)
1252                                 if(!teams_matter || msg_entity.team == self.team)
1253                                 {
1254                                         if(msg_entity.cvar_cl_voice_directional == 1)
1255                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1256                                         else
1257                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1258                                 }
1259                         break;
1260                 case VOICETYPE_AUTOTAUNT:
1261                         if(!sv_autotaunt)
1262                                 break;
1263                         if(!sv_taunt)
1264                                 break;
1265                         if(sv_gentle)
1266                                 break;
1267                         tauntrand = random();
1268                         FOR_EACH_REALCLIENT(msg_entity)
1269                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1270                                 {
1271                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1272                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1273                                         else
1274                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1275                                 }
1276                         break;
1277                 case VOICETYPE_TAUNT:
1278                         if(self.classname == "player")
1279                                 if(self.deadflag == DEAD_NO)
1280                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1281                         if(!sv_taunt)
1282                                 break;
1283                         if(sv_gentle)
1284                                 break;
1285                         FOR_EACH_REALCLIENT(msg_entity)
1286                         {
1287                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1288                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1289                                 else
1290                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1291                         }
1292                         break;
1293                 case VOICETYPE_PLAYERSOUND:
1294                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1295                         break;
1296                 default:
1297                         backtrace("Invalid voice type!");
1298                         break;
1299         }
1300 }
1301
1302 void PlayerSound(.string samplefield, float chan, float voicetype)
1303 {
1304         GlobalSound(self.samplefield, chan, voicetype);
1305 }
1306
1307 void VoiceMessage(string type, string msg)
1308 {
1309         var .string sample;
1310         float voicetype, ownteam;
1311         float flood;
1312         sample = GetVoiceMessageSampleField(type);
1313
1314         if(GetPlayerSoundSampleField_notFound)
1315         {
1316                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1317                 return;
1318         }
1319
1320         voicetype = GetVoiceMessageVoiceType(type);
1321         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1322
1323         flood = Say(self, ownteam, world, msg, 1);
1324
1325         if (flood > 0)
1326                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1327         else if (flood < 0)
1328                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1329 }
1330
1331 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1332 {
1333 //      show_message
1334 //      0 (00) automove centerprint, admin message
1335 //      1 (01) automove centerprint, no admin message
1336 //      2 (10) no centerprint, admin message
1337 //      3 (11) no centerprint, no admin message
1338
1339         float lockteams_backup;
1340
1341         lockteams_backup = lockteams;  // backup any team lock
1342
1343         lockteams = 0;  // disable locked teams
1344
1345         TeamchangeFrags(client);  // move the players frags
1346         SetPlayerColors(client, team_colour - 1);  // set the players colour
1347         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1348
1349         lockteams = lockteams_backup;  // restore the team lock
1350
1351         LogTeamchange(client.playerid, client.team, type);
1352
1353         if not(show_message & 1) // admin message
1354                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1355
1356         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1357 }