qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // url_fopen returned, we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh, WeaponStats_ready, world);
  50                         buf_del(weaponstats_buffer);
  51                         weaponstats_buffer = -1;
  52                         break;
  53                 case URL_READY_CANREAD:
  54                         // url_fclose is processing, we got a response for writing the data
  55                         // this must come from HTTP
  56                         print("Got response from weapon stats server:\n");
  57                         while((s = url_fgets(fh)))
  58                                 print("  ", s, "\n");
  59                         print("End of response.\n");
  60                         url_fclose(fh, WeaponStats_ready, world);
  61                         break;
  62                 case URL_READY_CLOSED:
  63                         // url_fclose has finished
  64                         print("Weapon stats written\n");
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         break;
  70         }
  71 }
  72
  73 void WeaponStats_Shutdown()
  74 {
  75         if(weaponstats_buffer < 0)
  76                 return;
  77         if(autocvar_sv_weaponstats_file != "")
  78         {
  79                 url_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  80         }
  81         else
  82         {
  83                 buf_del(weaponstats_buffer);
  84                 weaponstats_buffer = -1;
  85         }
  86 }
  87
  88 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  89 {
  90         float idx;
  91         if(weaponstats_buffer < 0)
  92                 return;
  93         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  94                 return;
  95         if(awep > WEP_LAST || vwep > WEP_LAST)
  96                 return;
  97         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  98         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  99 }
 100 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 101 {
 102         if(damage < 0)
 103                 error("negative damage?");
 104         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 105 }
 106 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 107 {
 108         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 109 }
 110
 111 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 112 // merged player_run and player_stand to player_anim
 113 // added death animations to player_anim
 114 // can now spawn thrown weapons from anywhere, not just from players
 115 // thrown weapons now fade out after 20 seconds
 116 // created PlayerGib function
 117 // PlayerDie no longer uses hitloc or damage
 118 // PlayerDie now supports dying animations as well as gibbing
 119 // cleaned up PlayerDie a lot
 120 // added CopyBody
 121
 122 .entity pusher;
 123 .float pushltime;
 124
 125 void CopyBody(float keepvelocity)
 126 {
 127         local entity oldself;
 128         if (self.effects & EF_NODRAW)
 129                 return;
 130         oldself = self;
 131         self = spawn();
 132         self.enemy = oldself;
 133         self.lip = oldself.lip;
 134         self.colormap = oldself.colormap;
 135         self.glowmod = oldself.glowmod;
 136         self.iscreature = oldself.iscreature;
 137         self.angles = oldself.angles;
 138         self.avelocity = oldself.avelocity;
 139         self.classname = "body";
 140         self.damageforcescale = oldself.damageforcescale;
 141         self.effects = oldself.effects;
 142         self.event_damage = oldself.event_damage;
 143         self.animstate_startframe = oldself.animstate_startframe;
 144         self.animstate_numframes = oldself.animstate_numframes;
 145         self.animstate_framerate = oldself.animstate_framerate;
 146         self.animstate_starttime = oldself.animstate_starttime;
 147         self.animstate_endtime = oldself.animstate_endtime;
 148         self.animstate_override = oldself.animstate_override;
 149         self.animstate_looping = oldself.animstate_looping;
 150         self.frame = oldself.frame;
 151         self.dead_frame = oldself.dead_frame;
 152         self.pain_finished = oldself.pain_finished;
 153         self.health = oldself.health;
 154         self.armorvalue = oldself.armorvalue;
 155         self.armortype = oldself.armortype;
 156         self.model = oldself.model;
 157         self.modelindex = oldself.modelindex;
 158         self.modelindex_lod0 = oldself.modelindex_lod0;
 159         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 160         self.modelindex_lod1 = oldself.modelindex_lod1;
 161         self.modelindex_lod2 = oldself.modelindex_lod2;
 162         self.skinindex = oldself.skinindex;
 163         self.species = oldself.species;
 164         self.movetype = oldself.movetype;
 165         self.nextthink = oldself.nextthink;
 166         self.solid = oldself.solid;
 167         self.ballistics_density = oldself.ballistics_density;
 168         self.takedamage = oldself.takedamage;
 169         self.think = oldself.think;
 170         self.customizeentityforclient = oldself.customizeentityforclient;
 171         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 172         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 173         if (keepvelocity == 1)
 174                 self.velocity = oldself.velocity;
 175         self.oldvelocity = self.velocity;
 176         self.fade_time = oldself.fade_time;
 177         self.fade_rate = oldself.fade_rate;
 178         //self.weapon = oldself.weapon;
 179         setorigin(self, oldself.origin);
 180         setsize(self, oldself.mins, oldself.maxs);
 181         self.prevorigin = oldself.origin;
 182         self.reset = SUB_Remove;
 183
 184         Drag_MoveDrag(oldself, self);
 185
 186         self = oldself;
 187 }
 188
 189 float player_getspecies()
 190 {
 191         float s;
 192         get_model_parameters(self.model, self.skinindex);
 193         s = get_model_parameters_species;
 194         get_model_parameters(string_null, 0);
 195         if(s < 0)
 196                 return SPECIES_HUMAN;
 197         return s;
 198 }
 199
 200 void player_setupanimsformodel()
 201 {
 202         local string animfilename;
 203         local float animfile;
 204         // defaults for legacy .zym models without animinfo files
 205         self.anim_die1 = '0 1 0.5'; // 2 seconds
 206         self.anim_die2 = '1 1 0.5'; // 2 seconds
 207         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 208         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 209         self.anim_duckwalk = '4 1 1';
 210         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 211         self.anim_duckidle = '6 1 1';
 212         self.anim_idle = '7 1 1';
 213         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 214         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 215         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 216         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 217         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 218         self.anim_run = '13 1 1';
 219         self.anim_runbackwards = '14 1 1';
 220         self.anim_strafeleft = '15 1 1';
 221         self.anim_straferight = '16 1 1';
 222         self.anim_dead1 = '17 1 1';
 223         self.anim_dead2 = '18 1 1';
 224         self.anim_forwardright = '19 1 1';
 225         self.anim_forwardleft = '20 1 1';
 226         self.anim_backright = '21 1 1';
 227         self.anim_backleft  = '22 1 1';
 228         self.anim_melee = '23 1 1';
 229         animparseerror = FALSE;
 230         animfilename = strcat(self.model, ".animinfo");
 231         animfile = fopen(animfilename, FILE_READ);
 232         if (animfile >= 0)
 233         {
 234                 self.anim_die1         = animparseline(animfile);
 235                 self.anim_die2         = animparseline(animfile);
 236                 self.anim_draw         = animparseline(animfile);
 237                 self.anim_duck         = animparseline(animfile);
 238                 self.anim_duckwalk     = animparseline(animfile);
 239                 self.anim_duckjump     = animparseline(animfile);
 240                 self.anim_duckidle     = animparseline(animfile);
 241                 self.anim_idle         = animparseline(animfile);
 242                 self.anim_jump         = animparseline(animfile);
 243                 self.anim_pain1        = animparseline(animfile);
 244                 self.anim_pain2        = animparseline(animfile);
 245                 self.anim_shoot        = animparseline(animfile);
 246                 self.anim_taunt        = animparseline(animfile);
 247                 self.anim_run          = animparseline(animfile);
 248                 self.anim_runbackwards = animparseline(animfile);
 249                 self.anim_strafeleft   = animparseline(animfile);
 250                 self.anim_straferight  = animparseline(animfile);
 251                 self.anim_forwardright = animparseline(animfile);
 252                 self.anim_forwardleft  = animparseline(animfile);
 253                 self.anim_backright    = animparseline(animfile);
 254                 self.anim_backleft     = animparseline(animfile);
 255                 self.anim_melee        = animparseline(animfile);
 256                 fclose(animfile);
 257
 258                 // derived anims
 259                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 260                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 261
 262                 if (animparseerror)
 263                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 264         }
 265         else
 266                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 267         // reset animstate now
 268         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 269 };
 270
 271 void player_anim (void)
 272 {
 273         updateanim(self);
 274         if (self.weaponentity)
 275                 updateanim(self.weaponentity);
 276
 277         if (self.deadflag != DEAD_NO)
 278         {
 279                 if (time > self.animstate_endtime)
 280                 {
 281                         if (self.maxs_z > 5)
 282                         {
 283                                 self.maxs_z = 5;
 284                                 setsize(self, self.mins, self.maxs);
 285                         }
 286                         self.frame = self.dead_frame;
 287                 }
 288                 return;
 289         }
 290
 291         if (!self.animstate_override)
 292         {
 293                 if (!(self.flags & FL_ONGROUND))
 294                 {
 295                         if (self.crouch)
 296                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 297                         else
 298                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 299                         self.restart_jump = FALSE;
 300                 }
 301                 else if (self.crouch)
 302                 {
 303                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 304                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 305                         else
 306                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 307                 }
 308                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 309                 {
 310                         if (self.movement_x > 0 && self.movement_y == 0)
 311                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 312                         else if (self.movement_x < 0 && self.movement_y == 0)
 313                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 314                         else if (self.movement_x == 0 && self.movement_y > 0)
 315                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 316                         else if (self.movement_x == 0 && self.movement_y < 0)
 317                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 318                         else if (self.movement_x > 0 && self.movement_y > 0)
 319                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 320                         else if (self.movement_x > 0 && self.movement_y < 0)
 321                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 322                         else if (self.movement_x < 0 && self.movement_y > 0)
 323                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 324                         else if (self.movement_x < 0 && self.movement_y < 0)
 325                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 326                         else
 327                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 328                 }
 329                 else
 330                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 331         }
 332
 333         if (self.weaponentity)
 334         if (!self.weaponentity.animstate_override)
 335                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 336 }
 337
 338 void SpawnThrownWeapon (vector org, float w)
 339 {
 340         if(g_minstagib)
 341         if(self.ammo_cells <= 0)
 342                 return;
 343
 344         if(g_pinata)
 345         {
 346                 float j;
 347                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 348                 {
 349                         if(self.weapons & W_WeaponBit(j))
 350                                 if(W_IsWeaponThrowable(j))
 351                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 352                 }
 353         }
 354         else
 355         {
 356                 if(W_IsWeaponThrowable(self.weapon))
 357                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 358         }
 359 }
 360
 361 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 362 {
 363         local float take, save;
 364         vector v;
 365         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 366
 367         // damage resistance (ignore most of the damage from a bullet or similar)
 368         damage = max(damage - 5, 1);
 369
 370         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 371         take = v_x;
 372         save = v_y;
 373
 374         if(sound_allowed(MSG_BROADCAST, attacker))
 375         {
 376                 if (save > 10)
 377                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 378                 else if (take > 30)
 379                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 380                 else if (take > 10)
 381                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 382         }
 383
 384         if (take > 50)
 385                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 386         if (take > 100)
 387                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 388
 389         if (!(self.flags & FL_GODMODE))
 390         {
 391                 self.armorvalue = self.armorvalue - save;
 392                 self.health = self.health - take;
 393                 // pause regeneration for 5 seconds
 394                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 395         }
 396         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 397         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 398         self.dmg_inflictor = inflictor;
 399
 400         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 401         {
 402                 // don't use any animations as a gib
 403                 self.frame = 0;
 404                 self.dead_frame = 0;
 405                 // view just above the floor
 406                 self.view_ofs = '0 0 4';
 407
 408                 Violence_GibSplash(self, 1, 1, attacker);
 409                 self.modelindex = 0; // restore later
 410                 self.solid = SOLID_NOT; // restore later
 411         }
 412 }
 413
 414 void ClientKill_Now_TeamChange();
 415 void freezetag_CheckWinner();
 416
 417 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 418 {
 419         local float take, save, waves, sdelay, dh, da, j;
 420         vector v;
 421         float valid_damage_for_weaponstats;
 422         float excess;
 423
 424         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 425                 return;
 426
 427         dh = max(self.health, 0);
 428         da = max(self.armorvalue, 0);
 429
 430         if(!DEATH_ISSPECIAL(deathtype))
 431         {
 432                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 433                 if(self != attacker)
 434                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 435         }
 436
 437         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 438         {
 439                 // tuba causes blood to come out of the ears
 440                 vector ear1, ear2;
 441                 vector d;
 442                 float f;
 443                 ear1 = self.origin;
 444                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 445                 ear2 = ear1;
 446                 makevectors(self.angles);
 447                 ear1 += v_right * -10;
 448                 ear2 += v_right * +10;
 449                 d = inflictor.origin - self.origin;
 450                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 451                 force = v_right * vlen(force);
 452                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 453                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 454                 if(f > 0)
 455                 {
 456                         hitloc = ear1;
 457                         force = force * -1;
 458                 }
 459                 else
 460                 {
 461                         hitloc = ear2;
 462                         // force is already good
 463                 }
 464         }
 465         else
 466                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 467
 468         if (!g_minstagib)
 469         {
 470                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 471                 take = v_x;
 472                 save = v_y;
 473         }
 474         else
 475         {
 476                 save = 0;
 477                 take = damage;
 478         }
 479
 480         frag_inflictor = inflictor;
 481         frag_attacker = attacker;
 482         frag_target = self;
 483         damage_take = take;
 484         damage_save = save;
 485         damage_force = force;
 486         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 487         take = bound(0, damage_take, self.health);
 488         save = bound(0, damage_save, self.armorvalue);
 489         excess = max(0, damage - take - save);
 490
 491         if(sound_allowed(MSG_BROADCAST, attacker))
 492         {
 493                 if (save > 10)
 494                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 495                 else if (take > 30)
 496                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 497                 else if (take > 10)
 498                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 499         }
 500
 501         if (take > 50)
 502                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 503         if (take > 100)
 504                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 505
 506         if (time >= self.spawnshieldtime)
 507         {
 508                 if (!(self.flags & FL_GODMODE))
 509                 {
 510                         self.armorvalue = self.armorvalue - save;
 511                         self.health = self.health - take;
 512                         // pause regeneration for 5 seconds
 513                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 514
 515                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 516                         {
 517                                 self.pain_finished = time + 0.5;        //Supajoe
 518
 519                                 if(sv_gentle < 1) {
 520                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 521                                         {
 522                                                 if (random() > 0.5)
 523                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 524                                                 else
 525                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 526                                         }
 527
 528                                         if(sound_allowed(MSG_BROADCAST, attacker))
 529                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 530                                         if(self.health > 1)
 531                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 532                                         {
 533                                                 if(deathtype == DEATH_FALL)
 534                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 535                                                 else if(self.health > 75) // TODO make a "gentle" version?
 536                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 537                                                 else if(self.health > 50)
 538                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 539                                                 else if(self.health > 25)
 540                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 541                                                 else
 542                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 543                                         }
 544                                 }
 545
 546                                 // throw off bot aim temporarily
 547                                 local float shake;
 548                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 549                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 550                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 551                         }
 552                 }
 553                 else
 554                         self.max_armorvalue += (save + take);
 555         }
 556         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 557         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 558         self.dmg_inflictor = inflictor;
 559
 560         if(attacker == self)
 561         {
 562                 // don't reset pushltime for self damage as it may be an attempt to
 563                 // escape a lava pit or similar
 564                 //self.pushltime = 0;
 565         }
 566         else if(attacker.classname == "player")
 567         {
 568                 self.pusher = attacker;
 569                 self.pushltime = time + autocvar_g_maxpushtime;
 570         }
 571         else if(time < self.pushltime)
 572         {
 573                 attacker = self.pusher;
 574                 self.pushltime = max(self.pushltime, time + 0.6);
 575         }
 576         else
 577                 self.pushltime = 0;
 578
 579         float abot, vbot, awep;
 580         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 581         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 582
 583         valid_damage_for_weaponstats = 0;
 584         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 585         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 586         if(attacker && self != attacker)
 587         if(IsDifferentTeam(self, attacker))
 588         {
 589                 if(DEATH_ISSPECIAL(deathtype))
 590                         awep = attacker.weapon;
 591                 else
 592                         awep = DEATH_WEAPONOF(deathtype);
 593                 valid_damage_for_weaponstats = 1;
 594         }
 595
 596         if(valid_damage_for_weaponstats)
 597         {
 598                 dh = dh - max(self.health, 0);
 599                 da = da - max(self.armorvalue, 0);
 600                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 601         }
 602
 603         if (self.health < 1)
 604         {
 605                 float defer_ClientKill_Now_TeamChange;
 606                 defer_ClientKill_Now_TeamChange = FALSE;
 607
 608                 if(self.alivetime)
 609                 {
 610                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 611                         self.alivetime = 0;
 612                 }
 613
 614                 if(valid_damage_for_weaponstats)
 615                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 616
 617                 if(sv_gentle < 1) // TODO make a "gentle" version?
 618                 if(sound_allowed(MSG_BROADCAST, attacker))
 619                 {
 620                         if(deathtype == DEATH_DROWN)
 621                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 622                         else
 623                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 624                 }
 625
 626                 // get rid of kill indicator
 627                 if(self.killindicator)
 628                 {
 629                         remove(self.killindicator);
 630                         self.killindicator = world;
 631                         if(self.killindicator_teamchange)
 632                                 defer_ClientKill_Now_TeamChange = TRUE;
 633
 634                         if(self.classname == "body")
 635                         if(deathtype == DEATH_KILL)
 636                         {
 637                                 // for the lemmings fans, a small harmless explosion
 638                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 639                         }
 640                 }
 641
 642                 if(!g_freezetag)
 643                 {
 644                         // become fully visible
 645                         self.alpha = 1;
 646                         // throw a weapon
 647                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 648                 }
 649
 650                 // print an obituary message
 651                 Obituary (attacker, inflictor, self, deathtype);
 652                 race_PreDie();
 653                 DropAllRunes(self);
 654
 655         // increment frag counter for used weapon type
 656         float w;
 657         w = DEATH_WEAPONOF(deathtype);
 658         if(WEP_VALID(w))
 659         if(self.classname == "player")
 660         if(self != attacker)
 661         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 662
 663                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 664                 {
 665                         PutClientInServer();
 666                         count_alive_players(); // re-count players
 667                         freezetag_CheckWinner();
 668                         return;
 669                 }
 670
 671                 frag_attacker = attacker;
 672                 frag_inflictor = inflictor;
 673                 frag_target = self;
 674                 MUTATOR_CALLHOOK(PlayerDies);
 675                 weapon_action(self.weapon, WR_PLAYERDEATH);
 676
 677                 if(self.flagcarried)
 678                 {
 679                         if(attacker.classname != "player")
 680                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 681                         else if(attacker.team == self.team)
 682                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 683                         else
 684                                 DropFlag(self.flagcarried, world, attacker);
 685                 }
 686                 if(self.ballcarried && g_nexball)
 687                         DropBall(self.ballcarried, self.origin, self.velocity);
 688                 Portal_ClearAllLater(self);
 689
 690                 if(clienttype(self) == CLIENTTYPE_REAL)
 691                 {
 692                         stuffcmd(self, "-zoom\n");
 693                         self.fixangle = TRUE;
 694                         //msg_entity = self;
 695                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 696                         //WriteAngle (MSG_ONE, self.v_angle_x);
 697                         //WriteAngle (MSG_ONE, self.v_angle_y);
 698                         //WriteAngle (MSG_ONE, 80);
 699                 }
 700
 701                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 702                         ClientKill_Now_TeamChange();
 703
 704                 if(g_arena)
 705                         Spawnqueue_Unmark(self);
 706
 707                 if(g_freezetag)
 708                         return;
 709
 710                 // when we get here, player actually dies
 711                 // clear waypoints (do this AFTER FreezeTag)
 712                 WaypointSprite_PlayerDead();
 713
 714                 // make the corpse upright (not tilted)
 715                 self.angles_x = 0;
 716                 self.angles_z = 0;
 717                 // don't spin
 718                 self.avelocity = '0 0 0';
 719                 // view from the floor
 720                 self.view_ofs = '0 0 -8';
 721                 // toss the corpse
 722                 self.movetype = MOVETYPE_TOSS;
 723                 // shootable corpse
 724                 self.solid = SOLID_CORPSE;
 725                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 726                 // don't stick to the floor
 727                 self.flags &~= FL_ONGROUND;
 728                 // dying animation
 729                 self.deadflag = DEAD_DYING;
 730                 // when to allow respawn
 731                 sdelay = 0;
 732                 waves = 0;
 733                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 734                 if(!sdelay)
 735                 {
 736                         if(g_cts)
 737                                 sdelay = 0; // no respawn delay in CTS
 738                         else
 739                                 sdelay = autocvar_g_respawn_delay;
 740                 }
 741                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 742                 if(!waves)
 743                         waves = autocvar_g_respawn_waves;
 744                 if(waves)
 745                         self.death_time = ceil((time + sdelay) / waves) * waves;
 746                 else
 747                         self.death_time = time + sdelay;
 748                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 749                         self.respawn_countdown = 10; // first number to count down from is 10
 750                 else
 751                         self.respawn_countdown = -1; // do not count down
 752                 if (random() < 0.5)
 753                 {
 754                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 755                         self.dead_frame = self.anim_dead1_x;
 756                 }
 757                 else
 758                 {
 759                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 760                         self.dead_frame = self.anim_dead2_x;
 761                 }
 762                 // set damage function to corpse damage
 763                 self.event_damage = PlayerCorpseDamage;
 764                 // call the corpse damage function just in case it wants to gib
 765                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 766                 // set up to fade out later
 767                 SUB_SetFade (self, time + 6 + random (), 1);
 768
 769                 if(sv_gentle > 0 || autocvar_ekg) {
 770                         // remove corpse
 771                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 772                 }
 773
 774                 // reset fields the weapons may use just in case
 775                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 776                 {
 777                         weapon_action(j, WR_RESETPLAYER);
 778                         ATTACK_FINISHED_FOR(self, j) = 0;
 779                 }
 780         }
 781 }
 782
 783 .float muted; // to be used by prvm_edictset server playernumber muted 1
 784 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 785 // message "": do not say, just test flood control
 786 // return value:
 787 //   1 = accept
 788 //   0 = reject
 789 //  -1 = fake accept
 790 {
 791         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 792         float flood, privatemsgprefixlen;
 793         var .float flood_field;
 794         entity head;
 795         float ret;
 796
 797         if(Ban_MaybeEnforceBan(source))
 798                 return 0;
 799
 800         if(!teamsay && !privatesay)
 801                 if(substring(msgin, 0, 1) == " ")
 802                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 803
 804         msgin = formatmessage(msgin);
 805
 806         if(source.classname != "player")
 807                 colorstr = "^0"; // black for spectators
 808         else if(teamplay)
 809                 colorstr = Team_ColorCode(source.team);
 810         else
 811                 teamsay = FALSE;
 812
 813         if(intermission_running)
 814                 teamsay = FALSE;
 815
 816         if(msgin != "")
 817                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 818
 819         /*
 820          * using bprint solves this... me stupid
 821         // how can we prevent the message from appearing in a listen server?
 822         // for now, just give "say" back and only handle say_team
 823         if(!teamsay)
 824         {
 825                 clientcommand(self, strcat("say ", msgin));
 826                 return;
 827         }
 828         */
 829
 830         if(autocvar_g_chat_teamcolors)
 831                 namestr = playername(source);
 832         else
 833                 namestr = source.netname;
 834
 835         if(msgin != "")
 836         {
 837                 if(privatesay)
 838                 {
 839                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 840                         privatemsgprefixlen = strlen(msgstr);
 841                         msgstr = strcat(msgstr, msgin);
 842                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 843                         if(autocvar_g_chat_teamcolors)
 844                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 845                         else
 846                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 847                 }
 848                 else if(teamsay)
 849                 {
 850                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 851                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 852                 }
 853                 else
 854                 {
 855                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 856                         cmsgstr = "";
 857                 }
 858                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 859         }
 860         else
 861         {
 862                 msgstr = cmsgstr = "";
 863         }
 864
 865         fullmsgstr = msgstr;
 866         fullcmsgstr = cmsgstr;
 867
 868         // FLOOD CONTROL
 869         flood = 0;
 870         if(floodcontrol)
 871         {
 872                 float flood_spl;
 873                 float flood_burst;
 874                 float flood_lmax;
 875                 float lines;
 876                 if(privatesay)
 877                 {
 878                         flood_spl = autocvar_g_chat_flood_spl_tell;
 879                         flood_burst = autocvar_g_chat_flood_burst_tell;
 880                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 881                         flood_field = floodcontrol_chattell;
 882                 }
 883                 else if(teamsay)
 884                 {
 885                         flood_spl = autocvar_g_chat_flood_spl_team;
 886                         flood_burst = autocvar_g_chat_flood_burst_team;
 887                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 888                         flood_field = floodcontrol_chatteam;
 889                 }
 890                 else
 891                 {
 892                         flood_spl = autocvar_g_chat_flood_spl;
 893                         flood_burst = autocvar_g_chat_flood_burst;
 894                         flood_lmax = autocvar_g_chat_flood_lmax;
 895                         flood_field = floodcontrol_chat;
 896                 }
 897                 flood_burst = max(0, flood_burst - 1);
 898                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 899
 900                 // do flood control for the default line size
 901                 if(msgstr != "")
 902                 {
 903                         getWrappedLine_remaining = msgstr;
 904                         msgstr = "";
 905                         lines = 0;
 906                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 907                         {
 908                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 909                                 ++lines;
 910                         }
 911                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 912
 913                         if(getWrappedLine_remaining != "")
 914                         {
 915                                 msgstr = strcat(msgstr, "\n");
 916                                 flood = 2;
 917                         }
 918
 919                         if(time >= source.flood_field)
 920                         {
 921                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 922                         }
 923                         else
 924                         {
 925                                 flood = 1;
 926                                 msgstr = fullmsgstr;
 927                         }
 928                 }
 929                 else
 930                 {
 931                         if(time >= source.flood_field)
 932                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 933                         else
 934                                 flood = 1;
 935                 }
 936
 937                 if (timeoutStatus == 2) //when game is paused, no flood protection
 938                         source.flood_field = flood = 0;
 939         }
 940
 941         if(flood == 2) // cannot happen for empty msgstr
 942         {
 943                 if(autocvar_g_chat_flood_notify_flooder)
 944                 {
 945                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 946                         sourcecmsgstr = "";
 947                 }
 948                 else
 949                 {
 950                         sourcemsgstr = fullmsgstr;
 951                         sourcecmsgstr = fullcmsgstr;
 952                 }
 953                 cmsgstr = "";
 954         }
 955         else
 956         {
 957                 sourcemsgstr = msgstr;
 958                 sourcecmsgstr = cmsgstr;
 959         }
 960
 961         if(!privatesay)
 962         if(source.classname != "player")
 963         {
 964                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 965                         teamsay = -1; // spectators
 966         }
 967
 968         if(flood)
 969                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 970
 971         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 972         if(privatesay)
 973                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 974
 975         if(source.muted)
 976         {
 977                 // always fake the message
 978                 ret = -1;
 979         }
 980         else if(flood == 1)
 981         {
 982                 if(autocvar_g_chat_flood_notify_flooder)
 983                 {
 984                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 985                         ret = 0;
 986                 }
 987                 else
 988                         ret = -1;
 989         }
 990         else
 991         {
 992                 ret = 1;
 993         }
 994
 995         if(sourcemsgstr != "" && ret != 0)
 996         {
 997                 if(ret < 0) // fake
 998                 {
 999                         sprint(source, sourcemsgstr);
1000                         if(sourcecmsgstr != "" && !privatesay)
1001                                 centerprint(source, sourcecmsgstr);
1002                 }
1003                 else if(privatesay)
1004                 {
1005                         sprint(source, sourcemsgstr);
1006                         sprint(privatesay, msgstr);
1007                         if(cmsgstr != "")
1008                                 centerprint(privatesay, cmsgstr);
1009                 }
1010                 else if(teamsay > 0)
1011                 {
1012                         sprint(source, sourcemsgstr);
1013                         if(sourcecmsgstr != "")
1014                                 centerprint(source, sourcecmsgstr);
1015                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1016                                 if(head != source)
1017                                 {
1018                                         sprint(head, msgstr);
1019                                         if(cmsgstr != "")
1020                                                 centerprint(head, cmsgstr);
1021                                 }
1022                 }
1023                 else if(teamsay < 0)
1024                 {
1025                         sprint(source, sourcemsgstr);
1026                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1027                                 if(head != source)
1028                                         sprint(head, msgstr);
1029                 }
1030                 else if(sourcemsgstr != msgstr)
1031                 {
1032                         sprint(source, sourcemsgstr);
1033                         FOR_EACH_REALCLIENT(head)
1034                                 if(head != source)
1035                                         sprint(head, msgstr);
1036                 }
1037                 else
1038                         bprint(msgstr);
1039         }
1040
1041         return ret;
1042 }
1043
1044 float GetVoiceMessageVoiceType(string type)
1045 {
1046         if(type == "taunt")
1047                 return VOICETYPE_TAUNT;
1048         if(type == "teamshoot")
1049                 return VOICETYPE_LASTATTACKER;
1050         return VOICETYPE_TEAMRADIO;
1051 }
1052
1053 string allvoicesamples;
1054 .string GetVoiceMessageSampleField(string type)
1055 {
1056         GetPlayerSoundSampleField_notFound = 0;
1057         switch(type)
1058         {
1059 #define _VOICEMSG(m) case #m: return playersound_##m;
1060                 ALLVOICEMSGS
1061 #undef _VOICEMSG
1062         }
1063         GetPlayerSoundSampleField_notFound = 1;
1064         return playersound_taunt;
1065 }
1066
1067 .string GetPlayerSoundSampleField(string type)
1068 {
1069         GetPlayerSoundSampleField_notFound = 0;
1070         switch(type)
1071         {
1072 #define _VOICEMSG(m) case #m: return playersound_##m;
1073                 ALLPLAYERSOUNDS
1074 #undef _VOICEMSG
1075         }
1076         GetPlayerSoundSampleField_notFound = 1;
1077         return playersound_taunt;
1078 }
1079
1080 void PrecacheGlobalSound(string samplestring)
1081 {
1082         float n, i;
1083         tokenize_console(samplestring);
1084         n = stof(argv(1));
1085         if(n > 0)
1086         {
1087                 for(i = 1; i <= n; ++i)
1088                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1089         }
1090         else
1091         {
1092                 precache_sound(strcat(argv(0), ".wav"));
1093         }
1094 }
1095
1096 void PrecachePlayerSounds(string f)
1097 {
1098         float fh;
1099         string s;
1100         fh = fopen(f, FILE_READ);
1101         if(fh < 0)
1102                 return;
1103         while((s = fgets(fh)))
1104         {
1105                 if(tokenize_console(s) != 3)
1106                 {
1107                         dprint("Invalid sound info line: ", s, "\n");
1108                         continue;
1109                 }
1110                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1111         }
1112         fclose(fh);
1113
1114         if not(allvoicesamples)
1115         {
1116 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1117                 ALLVOICEMSGS
1118 #undef _VOICEMSG
1119                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1120         }
1121 }
1122
1123 void ClearPlayerSounds()
1124 {
1125 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1126         ALLPLAYERSOUNDS
1127         ALLVOICEMSGS
1128 #undef _VOICEMSG
1129 }
1130
1131 float LoadPlayerSounds(string f, float first)
1132 {
1133         float fh;
1134         string s;
1135         var .string field;
1136         fh = fopen(f, FILE_READ);
1137         if(fh < 0)
1138         {
1139                 dprint("Player sound file not found: ", f, "\n");
1140                 return 0;
1141         }
1142         while((s = fgets(fh)))
1143         {
1144                 if(tokenize_console(s) != 3)
1145                         continue;
1146                 field = GetPlayerSoundSampleField(argv(0));
1147                 if(GetPlayerSoundSampleField_notFound)
1148                         field = GetVoiceMessageSampleField(argv(0));
1149                 if(GetPlayerSoundSampleField_notFound)
1150                         continue;
1151                 if(self.field)
1152                         strunzone(self.field);
1153                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1154         }
1155         fclose(fh);
1156         return 1;
1157 }
1158
1159 .float modelindex_for_playersound;
1160 .float skinindex_for_playersound;
1161 void UpdatePlayerSounds()
1162 {
1163         if(self.modelindex == self.modelindex_for_playersound)
1164         if(self.skinindex == self.skinindex_for_playersound)
1165                 return;
1166         self.modelindex_for_playersound = self.modelindex;
1167         self.skinindex_for_playersound = self.skinindex;
1168         ClearPlayerSounds();
1169         LoadPlayerSounds("sound/player/default.sounds", 1);
1170         if(!autocvar_g_debug_defaultsounds)
1171                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1172                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1173 }
1174
1175 void FakeGlobalSound(string sample, float chan, float voicetype)
1176 {
1177         float n;
1178         float tauntrand;
1179
1180         if(sample == "")
1181                 return;
1182
1183         tokenize_console(sample);
1184         n = stof(argv(1));
1185         if(n > 0)
1186                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1187         else
1188                 sample = strcat(argv(0), ".wav"); // randomization
1189
1190         switch(voicetype)
1191         {
1192                 case VOICETYPE_LASTATTACKER_ONLY:
1193                         break;
1194                 case VOICETYPE_LASTATTACKER:
1195                         if(self.pusher)
1196                         {
1197                                 msg_entity = self;
1198                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1199                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1200                         }
1201                         break;
1202                 case VOICETYPE_TEAMRADIO:
1203                         msg_entity = self;
1204                         if(msg_entity.cvar_cl_voice_directional == 1)
1205                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1206                         else
1207                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1208                         break;
1209                 case VOICETYPE_AUTOTAUNT:
1210                         if(!sv_autotaunt)
1211                                 break;
1212                         if(!sv_taunt)
1213                                 break;
1214                         if(sv_gentle)
1215                                 break;
1216                         tauntrand = random();
1217                         msg_entity = self;
1218                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1219                         {
1220                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1221                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1222                                 else
1223                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1224                         }
1225                         break;
1226                 case VOICETYPE_TAUNT:
1227                         if(self.classname == "player")
1228                                 if(self.deadflag == DEAD_NO)
1229                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1230                         if(!sv_taunt)
1231                                 break;
1232                         if(sv_gentle)
1233                                 break;
1234                         msg_entity = self;
1235                         if (msg_entity.cvar_cl_voice_directional >= 1)
1236                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1237                         else
1238                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1239                         break;
1240                 case VOICETYPE_PLAYERSOUND:
1241                         msg_entity = self;
1242                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1243                         break;
1244                 default:
1245                         backtrace("Invalid voice type!");
1246                         break;
1247         }
1248 }
1249
1250 void GlobalSound(string sample, float chan, float voicetype)
1251 {
1252         float n;
1253         float tauntrand;
1254
1255         if(sample == "")
1256                 return;
1257
1258         tokenize_console(sample);
1259         n = stof(argv(1));
1260         if(n > 0)
1261                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1262         else
1263                 sample = strcat(argv(0), ".wav"); // randomization
1264
1265         switch(voicetype)
1266         {
1267                 case VOICETYPE_LASTATTACKER_ONLY:
1268                         if(self.pusher)
1269                         {
1270                                 msg_entity = self.pusher;
1271                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1272                                 {
1273                                         if(msg_entity.cvar_cl_voice_directional == 1)
1274                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1275                                         else
1276                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1277                                 }
1278                         }
1279                         break;
1280                 case VOICETYPE_LASTATTACKER:
1281                         if(self.pusher)
1282                         {
1283                                 msg_entity = self.pusher;
1284                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1285                                 {
1286                                         if(msg_entity.cvar_cl_voice_directional == 1)
1287                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1288                                         else
1289                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1290                                 }
1291                                 msg_entity = self;
1292                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1293                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1294                         }
1295                         break;
1296                 case VOICETYPE_TEAMRADIO:
1297                         FOR_EACH_REALCLIENT(msg_entity)
1298                                 if(!teamplay || msg_entity.team == self.team)
1299                                 {
1300                                         if(msg_entity.cvar_cl_voice_directional == 1)
1301                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1302                                         else
1303                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1304                                 }
1305                         break;
1306                 case VOICETYPE_AUTOTAUNT:
1307                         if(!sv_autotaunt)
1308                                 break;
1309                         if(!sv_taunt)
1310                                 break;
1311                         if(sv_gentle)
1312                                 break;
1313                         tauntrand = random();
1314                         FOR_EACH_REALCLIENT(msg_entity)
1315                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1316                                 {
1317                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1318                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1319                                         else
1320                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1321                                 }
1322                         break;
1323                 case VOICETYPE_TAUNT:
1324                         if(self.classname == "player")
1325                                 if(self.deadflag == DEAD_NO)
1326                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1327                         if(!sv_taunt)
1328                                 break;
1329                         if(sv_gentle)
1330                                 break;
1331                         FOR_EACH_REALCLIENT(msg_entity)
1332                         {
1333                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1334                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1335                                 else
1336                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1337                         }
1338                         break;
1339                 case VOICETYPE_PLAYERSOUND:
1340                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1341                         break;
1342                 default:
1343                         backtrace("Invalid voice type!");
1344                         break;
1345         }
1346 }
1347
1348 void PlayerSound(.string samplefield, float chan, float voicetype)
1349 {
1350         GlobalSound(self.samplefield, chan, voicetype);
1351 }
1352
1353 void VoiceMessage(string type, string msg)
1354 {
1355         var .string sample;
1356         float voicetype, ownteam;
1357         float flood;
1358         sample = GetVoiceMessageSampleField(type);
1359
1360         if(GetPlayerSoundSampleField_notFound)
1361         {
1362                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1363                 return;
1364         }
1365
1366         voicetype = GetVoiceMessageVoiceType(type);
1367         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1368
1369         flood = Say(self, ownteam, world, msg, 1);
1370
1371         if (flood > 0)
1372                 GlobalSound(self.sample, CH_VOICE, voicetype);
1373         else if (flood < 0)
1374                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1375 }
1376
1377 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1378 {
1379 //      show_message
1380 //      0 (00) automove centerprint, admin message
1381 //      1 (01) automove centerprint, no admin message
1382 //      2 (10) no centerprint, admin message
1383 //      3 (11) no centerprint, no admin message
1384
1385         float lockteams_backup;
1386
1387         lockteams_backup = lockteams;  // backup any team lock
1388
1389         lockteams = 0;  // disable locked teams
1390
1391         TeamchangeFrags(client);  // move the players frags
1392         SetPlayerColors(client, team_colour - 1);  // set the players colour
1393         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1394
1395         lockteams = lockteams_backup;  // restore the team lock
1396
1397         LogTeamchange(client.playerid, client.team, type);
1398
1399         if not(show_message & 1) // admin message
1400                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1401
1402         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1403 }