qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.iscreature = oldself.iscreature;
 115         self.angles = oldself.angles;
 116         self.avelocity = oldself.avelocity;
 117         self.classname = "body";
 118         self.damageforcescale = oldself.damageforcescale;
 119         self.effects = oldself.effects;
 120         self.event_damage = oldself.event_damage;
 121         self.animstate_startframe = oldself.animstate_startframe;
 122         self.animstate_numframes = oldself.animstate_numframes;
 123         self.animstate_framerate = oldself.animstate_framerate;
 124         self.animstate_starttime = oldself.animstate_starttime;
 125         self.animstate_endtime = oldself.animstate_endtime;
 126         self.animstate_override = oldself.animstate_override;
 127         self.animstate_looping = oldself.animstate_looping;
 128         self.frame = oldself.frame;
 129         self.dead_frame = oldself.dead_frame;
 130         self.pain_finished = oldself.pain_finished;
 131         self.health = oldself.health;
 132         self.armorvalue = oldself.armorvalue;
 133         self.armortype = oldself.armortype;
 134         self.model = oldself.model;
 135         self.modelindex = oldself.modelindex;
 136         self.modelindex_lod0 = oldself.modelindex_lod0;
 137         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 138         self.modelindex_lod1 = oldself.modelindex_lod1;
 139         self.modelindex_lod2 = oldself.modelindex_lod2;
 140         self.skinindex = oldself.skinindex;
 141         self.species = oldself.species;
 142         self.movetype = oldself.movetype;
 143         self.nextthink = oldself.nextthink;
 144         self.solid = oldself.solid;
 145         self.takedamage = oldself.takedamage;
 146         self.think = oldself.think;
 147         self.customizeentityforclient = oldself.customizeentityforclient;
 148         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 149         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 150         if (keepvelocity == 1)
 151                 self.velocity = oldself.velocity;
 152         self.oldvelocity = self.velocity;
 153         self.fade_time = oldself.fade_time;
 154         self.fade_rate = oldself.fade_rate;
 155         //self.weapon = oldself.weapon;
 156         setorigin(self, oldself.origin);
 157         setsize(self, oldself.mins, oldself.maxs);
 158         self.prevorigin = oldself.origin;
 159         self.reset = SUB_Remove;
 160
 161         Drag_MoveDrag(oldself, self);
 162
 163         self = oldself;
 164 }
 165
 166 float player_getspecies()
 167 {
 168         local float glob, i, j, fh, len, s, sk;
 169         local string fn, l;
 170
 171         s = -1;
 172
 173         glob = search_begin("models/player/*.txt", TRUE, TRUE);
 174         if(glob < 0)
 175                 return s;
 176         for(j = 0; j <= 1; ++j)
 177         {
 178                 for(i = 0; i < search_getsize(glob); ++i)
 179                 {
 180                         fn = search_getfilename(glob, i);
 181                         fh = fopen(fn, FILE_READ);
 182                         if(fh < 0)
 183                                 continue;
 184                         fgets(fh); fgets(fh);
 185                         sk = stof(fgets(fh));
 186                         if(sk == (j ? 0 : self.skinindex)) // 2nd pass skips the skin test
 187                         if(fgets(fh) == self.model)
 188                         {
 189                                 l = fgets(fh);
 190                                 len = tokenize_console(l);
 191                                 if (len != 2)
 192                                         goto nospecies;
 193                                 if (argv(0) != "species")
 194                                         goto nospecies;
 195                                 switch(argv(1))
 196                                 {
 197                                         case "human":       s = SPECIES_HUMAN;       break;
 198                                         case "alien":       s = SPECIES_ALIEN;       break;
 199                                         case "robot_shiny": s = SPECIES_ROBOT_SHINY; break;
 200                                         case "robot_rusty": s = SPECIES_ROBOT_RUSTY; break;
 201                                         case "robot_solid": s = SPECIES_ROBOT_SOLID; break;
 202                                         case "animal":      s = SPECIES_ANIMAL;      break;
 203                                         case "reserved":    s = SPECIES_RESERVED;    break;
 204                                 }
 205                         }
 206 :nospecies
 207                         fclose(fh);
 208                 }
 209                 if (s >= 0)
 210                         break;
 211         }
 212         search_end(glob);
 213
 214         if (s < 0)
 215                 s = SPECIES_HUMAN;
 216
 217         return s;
 218 }
 219
 220 void player_setupanimsformodel()
 221 {
 222         local string animfilename;
 223         local float animfile;
 224         // defaults for legacy .zym models without animinfo files
 225         self.anim_die1 = '0 1 0.5'; // 2 seconds
 226         self.anim_die2 = '1 1 0.5'; // 2 seconds
 227         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 228         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 229         self.anim_duckwalk = '4 1 1';
 230         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 231         self.anim_duckidle = '6 1 1';
 232         self.anim_idle = '7 1 1';
 233         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 234         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 235         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 236         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 237         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 238         self.anim_run = '13 1 1';
 239         self.anim_runbackwards = '14 1 1';
 240         self.anim_strafeleft = '15 1 1';
 241         self.anim_straferight = '16 1 1';
 242         self.anim_dead1 = '17 1 1';
 243         self.anim_dead2 = '18 1 1';
 244         self.anim_forwardright = '19 1 1';
 245         self.anim_forwardleft = '20 1 1';
 246         self.anim_backright = '21 1 1';
 247         self.anim_backleft  = '22 1 1';
 248         animparseerror = FALSE;
 249         animfilename = strcat(self.model, ".animinfo");
 250         animfile = fopen(animfilename, FILE_READ);
 251         if (animfile >= 0)
 252         {
 253                 self.anim_die1         = animparseline(animfile);
 254                 self.anim_die2         = animparseline(animfile);
 255                 self.anim_draw         = animparseline(animfile);
 256                 self.anim_duck         = animparseline(animfile);
 257                 self.anim_duckwalk     = animparseline(animfile);
 258                 self.anim_duckjump     = animparseline(animfile);
 259                 self.anim_duckidle     = animparseline(animfile);
 260                 self.anim_idle         = animparseline(animfile);
 261                 self.anim_jump         = animparseline(animfile);
 262                 self.anim_pain1        = animparseline(animfile);
 263                 self.anim_pain2        = animparseline(animfile);
 264                 self.anim_shoot        = animparseline(animfile);
 265                 self.anim_taunt        = animparseline(animfile);
 266                 self.anim_run          = animparseline(animfile);
 267                 self.anim_runbackwards = animparseline(animfile);
 268                 self.anim_strafeleft   = animparseline(animfile);
 269                 self.anim_straferight  = animparseline(animfile);
 270                 self.anim_forwardright = animparseline(animfile);
 271                 self.anim_forwardleft  = animparseline(animfile);
 272                 self.anim_backright    = animparseline(animfile);
 273                 self.anim_backleft     = animparseline(animfile);
 274                 fclose(animfile);
 275
 276                 // derived anims
 277                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 278                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 279
 280                 if (animparseerror)
 281                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 282         }
 283         else
 284                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 285         // reset animstate now
 286         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 287 };
 288
 289 void player_anim (void)
 290 {
 291         updateanim(self);
 292         if (self.weaponentity)
 293                 updateanim(self.weaponentity);
 294
 295         if (self.deadflag != DEAD_NO)
 296         {
 297                 if (time > self.animstate_endtime)
 298                 {
 299                         if (self.maxs_z > 5)
 300                         {
 301                                 self.maxs_z = 5;
 302                                 setsize(self, self.mins, self.maxs);
 303                         }
 304                         self.frame = self.dead_frame;
 305                 }
 306                 return;
 307         }
 308
 309         if (!self.animstate_override)
 310         {
 311                 if (!(self.flags & FL_ONGROUND))
 312                 {
 313                         if (self.crouch)
 314                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 315                         else
 316                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 317                         self.restart_jump = FALSE;
 318                 }
 319                 else if (self.crouch)
 320                 {
 321                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 322                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 323                         else
 324                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 325                 }
 326                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 327                 {
 328                         if (self.movement_x > 0 && self.movement_y == 0)
 329                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x < 0 && self.movement_y == 0)
 331                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x == 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x == 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x > 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x > 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x < 0 && self.movement_y > 0)
 341                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 342                         else if (self.movement_x < 0 && self.movement_y < 0)
 343                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 344                         else
 345                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 346                 }
 347                 else
 348                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 349         }
 350
 351         if (self.weaponentity)
 352         if (!self.weaponentity.animstate_override)
 353                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 354 }
 355
 356 void SpawnThrownWeapon (vector org, float w)
 357 {
 358         if(g_minstagib)
 359         if(self.ammo_cells <= 0)
 360                 return;
 361
 362         if(g_pinata)
 363         {
 364                 float j;
 365                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 366                 {
 367                         if(self.weapons & W_WeaponBit(j))
 368                                 if(W_IsWeaponThrowable(j))
 369                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 370                 }
 371         }
 372         else
 373                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 374 }
 375
 376 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 377 {
 378         local float take, save;
 379         vector v;
 380         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 381
 382         // damage resistance (ignore most of the damage from a bullet or similar)
 383         damage = max(damage - 5, 1);
 384
 385         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 386         take = v_x;
 387         save = v_y;
 388
 389         if(sound_allowed(MSG_BROADCAST, attacker))
 390         {
 391                 if (save > 10)
 392                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 393                 else if (take > 30)
 394                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 395                 else if (take > 10)
 396                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 397         }
 398
 399         if (take > 50)
 400                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 401         if (take > 100)
 402                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 403
 404         if (!(self.flags & FL_GODMODE))
 405         {
 406                 self.armorvalue = self.armorvalue - save;
 407                 self.health = self.health - take;
 408                 // pause regeneration for 5 seconds
 409                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 410         }
 411         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 412         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 413         self.dmg_inflictor = inflictor;
 414
 415         if (self.health <= -100 && self.modelindex != 0)
 416         {
 417                 // don't use any animations as a gib
 418                 self.frame = 0;
 419                 self.dead_frame = 0;
 420                 // view just above the floor
 421                 self.view_ofs = '0 0 4';
 422
 423                 Violence_GibSplash(self, 1, 1, attacker);
 424                 self.modelindex = 0; // restore later
 425                 self.solid = SOLID_NOT; // restore later
 426         }
 427 }
 428
 429 void ClientKill_Now_TeamChange();
 430
 431 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 432 {
 433         local float take, save, waves, sdelay, dh, da, j;
 434         vector v;
 435         float valid_damage_for_weaponstats;
 436
 437         dh = max(self.health, 0);
 438         da = max(self.armorvalue, 0);
 439
 440         if(!DEATH_ISSPECIAL(deathtype))
 441         {
 442                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 443                 if(self != attacker)
 444                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 445         }
 446
 447         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 448         {
 449                 // tuba causes blood to come out of the ears
 450                 vector ear1, ear2;
 451                 vector d;
 452                 float f;
 453                 ear1 = self.origin;
 454                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 455                 ear2 = ear1;
 456                 makevectors(self.angles);
 457                 ear1 += v_right * -10;
 458                 ear2 += v_right * +10;
 459                 d = inflictor.origin - self.origin;
 460                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 461                 force = v_right * vlen(force);
 462                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 463                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 464                 if(f > 0)
 465                 {
 466                         hitloc = ear1;
 467                         force = force * -1;
 468                 }
 469                 else
 470                 {
 471                         hitloc = ear2;
 472                         // force is already good
 473                 }
 474         }
 475         else
 476                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 477
 478         if((g_arena && numspawned < 2) || (g_ca && player_cnt < 2) && !inWarmupStage)
 479                 return;
 480
 481         if (!g_minstagib)
 482         {
 483                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 484                 take = v_x;
 485                 save = v_y;
 486         }
 487         else
 488         {
 489                 save = 0;
 490                 take = damage;
 491         }
 492
 493         if(sound_allowed(MSG_BROADCAST, attacker))
 494         {
 495                 if (save > 10)
 496                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 497                 else if (take > 30)
 498                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 499                 else if (take > 10)
 500                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 501         }
 502
 503         if (take > 50)
 504                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 505         if (take > 100)
 506                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 507
 508         if (time >= self.spawnshieldtime)
 509         {
 510                 if (!(self.flags & FL_GODMODE))
 511                 {
 512                         self.armorvalue = self.armorvalue - save;
 513                         self.health = self.health - take;
 514                         // pause regeneration for 5 seconds
 515                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 516
 517                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 518                         {
 519                                 self.pain_finished = time + 0.5;        //Supajoe
 520
 521                                 if(sv_gentle < 1) {
 522                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 523                                         {
 524                                                 if (random() > 0.5)
 525                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 526                                                 else
 527                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 528                                         }
 529
 530                                         if(sound_allowed(MSG_BROADCAST, attacker))
 531                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 532                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 533                                         {
 534                                                 if(self.health > 75) // TODO make a "gentle" version?
 535                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 536                                                 else if(self.health > 50)
 537                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 538                                                 else if(self.health > 25)
 539                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 540                                                 else if(self.health > 1)
 541                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 542                                         }
 543                                 }
 544
 545                                 // throw off bot aim temporarily
 546                                 local float shake;
 547                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 548                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 549                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 550                         }
 551                 }
 552                 else
 553                         self.max_armorvalue += (save + take);
 554         }
 555         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 556         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 557         self.dmg_inflictor = inflictor;
 558
 559         if(attacker == self)
 560         {
 561                 // don't reset pushltime for self damage as it may be an attempt to
 562                 // escape a lava pit or similar
 563                 //self.pushltime = 0;
 564         }
 565         else if(attacker.classname == "player" || attacker.classname == "gib")
 566         {
 567                 self.pusher = attacker;
 568                 self.pushltime = time + cvar("g_maxpushtime");
 569         }
 570         else if(time < self.pushltime)
 571         {
 572                 attacker = self.pusher;
 573                 self.pushltime = max(self.pushltime, time + 0.6);
 574         }
 575         else
 576                 self.pushltime = 0;
 577
 578         valid_damage_for_weaponstats = 0;
 579         if(clienttype(self) == CLIENTTYPE_REAL)
 580         if(clienttype(attacker) == CLIENTTYPE_REAL)
 581         if(self != attacker)
 582         if(!DEATH_ISSPECIAL(deathtype))
 583         if(IsDifferentTeam(self, attacker))
 584                 valid_damage_for_weaponstats = 1;
 585
 586         if(valid_damage_for_weaponstats)
 587         {
 588                 dh = dh - max(self.health, 0);
 589                 da = da - max(self.armorvalue, 0);
 590                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 591         }
 592
 593         if (self.health < 1)
 594         {
 595                 float defer_ClientKill_Now_TeamChange;
 596                 defer_ClientKill_Now_TeamChange = FALSE;
 597
 598                 if(valid_damage_for_weaponstats)
 599                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 600
 601                 if(sv_gentle < 1) // TODO make a "gentle" version?
 602                 if(sound_allowed(MSG_BROADCAST, attacker))
 603                 {
 604                         if(deathtype == DEATH_DROWN)
 605                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 606                         else
 607                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 608                 }
 609
 610                 // get rid of kill indicator
 611                 if(self.killindicator)
 612                 {
 613                         remove(self.killindicator);
 614                         self.killindicator = world;
 615                         if(self.killindicator_teamchange)
 616                                 defer_ClientKill_Now_TeamChange = TRUE;
 617
 618                         if(self.classname == "body")
 619                         if(deathtype == DEATH_KILL)
 620                         {
 621                                 // for the lemmings fans, a small harmless explosion
 622                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 623                         }
 624                 }
 625
 626                 // become fully visible
 627                 self.alpha = 1;
 628                 // clear selected player display
 629                 ClearSelectedPlayer();
 630                 // throw a weapon
 631                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 632                 // print an obituary message
 633                 Obituary (attacker, inflictor, self, deathtype);
 634                 race_PreDie();
 635                 DropAllRunes(self);
 636
 637                 frag_attacker = attacker;
 638                 frag_inflictor = inflictor;
 639                 frag_target = self;
 640                 MUTATOR_CALLHOOK(PlayerDies);
 641
 642                 if(self.flagcarried)
 643                 {
 644                         if(attacker.classname != "player" && attacker.classname != "gib")
 645                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 646                         else if(attacker.team == self.team)
 647                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 648                         else
 649                                 DropFlag(self.flagcarried, world, attacker);
 650                 }
 651                 if(self.ballcarried)
 652                         DropBall(self.ballcarried, self.origin, self.velocity);
 653                 Portal_ClearAllLater(self);
 654                 // clear waypoints
 655                 WaypointSprite_PlayerDead();
 656                 // make the corpse upright (not tilted)
 657                 self.angles_x = 0;
 658                 self.angles_z = 0;
 659                 // don't spin
 660                 self.avelocity = '0 0 0';
 661                 // view from the floor
 662                 self.view_ofs = '0 0 -8';
 663                 // toss the corpse
 664                 self.movetype = MOVETYPE_TOSS;
 665                 // shootable corpse
 666                 self.solid = SOLID_CORPSE;
 667                 // don't stick to the floor
 668                 self.flags &~= FL_ONGROUND;
 669                 // dying animation
 670                 self.deadflag = DEAD_DYING;
 671                 // when to allow respawn
 672                 sdelay = 0;
 673                 waves = 0;
 674                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 675                 if(!sdelay)
 676                         sdelay = cvar("g_respawn_delay");
 677                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 678                 if(!waves)
 679                         waves = cvar("g_respawn_waves");
 680                 if(waves)
 681                         self.death_time = ceil((time + sdelay) / waves) * waves;
 682                 else
 683                         self.death_time = time + sdelay;
 684                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 685                         self.respawn_countdown = 10; // first number to count down from is 10
 686                 else
 687                         self.respawn_countdown = -1; // do not count down
 688                 if (random() < 0.5)
 689                 {
 690                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 691                         self.dead_frame = self.anim_dead1_x;
 692                 }
 693                 else
 694                 {
 695                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 696                         self.dead_frame = self.anim_dead2_x;
 697                 }
 698                 // set damage function to corpse damage
 699                 self.event_damage = PlayerCorpseDamage;
 700                 // call the corpse damage function just in case it wants to gib
 701                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 702                 // set up to fade out later
 703                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 704
 705                 // remove laserdot
 706                 if(self.weaponentity)
 707                         if(self.weaponentity.lasertarget)
 708                                 remove(self.weaponentity.lasertarget);
 709
 710                 if(clienttype(self) == CLIENTTYPE_REAL)
 711                 {
 712                         self.fixangle = TRUE;
 713                         //msg_entity = self;
 714                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 715                         //WriteAngle (MSG_ONE, self.v_angle_x);
 716                         //WriteAngle (MSG_ONE, self.v_angle_y);
 717                         //WriteAngle (MSG_ONE, 80);
 718                 }
 719
 720                 if(g_arena)
 721                         Spawnqueue_Unmark(self);
 722
 723                 if(defer_ClientKill_Now_TeamChange)
 724                         ClientKill_Now_TeamChange();
 725
 726                 if(sv_gentle > 0 || cvar("ekg")) {
 727                         // remove corpse
 728                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 729                 }
 730
 731                 // reset fields the weapons may use just in case
 732         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 733                 {
 734             weapon_action(j, WR_RESETPLAYER);
 735                         ATTACK_FINISHED_FOR(self, j) = 0;
 736                 }
 737         }
 738 }
 739
 740 float UpdateSelectedPlayer_countvalue(float v)
 741 {
 742         return max(0, (v - 1.0) / 0.5);
 743 }
 744
 745 // returns: -2 if no hit, otherwise cos of the angle
 746 // uses the global v_angle
 747 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 748 {
 749         vector so, d;
 750         float c;
 751
 752         if(p == self)
 753                 return -2;
 754
 755         if(p.deadflag)
 756                 return -2;
 757
 758         so = self.origin + self.view_ofs;
 759         d = p.origin - so;
 760
 761         // misaimed?
 762         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 763                 return -2;
 764
 765         // now find the cos of the angle...
 766         c = normalize(d) * v_forward;
 767
 768         if(c <= mincosangle)
 769                 return -2;
 770
 771         // not visible in any way? forget it
 772         if(!checkpvs(so, p))
 773                 return -2;
 774
 775         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 776         if(trace_fraction < 1)
 777                 return -2;
 778
 779         return c;
 780 }
 781
 782 void ClearSelectedPlayer()
 783 {
 784         if(self.selected_player)
 785         {
 786                 centerprint_expire(self, CENTERPRIO_POINT);
 787                 self.selected_player = world;
 788                 self.selected_player_display_needs_update = FALSE;
 789         }
 790 }
 791
 792 void UpdateSelectedPlayer()
 793 {
 794         entity selected;
 795         float selected_score;
 796         selected = world;
 797         selected_score = 0.95; // 18 degrees
 798
 799         if(!cvar("sv_allow_shownames"))
 800                 return;
 801
 802         if(clienttype(self) != CLIENTTYPE_REAL)
 803                 return;
 804
 805         if(self.cvar_cl_shownames == 0)
 806                 return;
 807
 808         if(self.cvar_cl_shownames == 1 && !teams_matter)
 809                 return;
 810
 811         makevectors(self.v_angle); // sets v_forward
 812
 813         // 1. cursor trace is always right
 814         WarpZone_crosshair_trace(self);
 815         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 816         {
 817                 selected = trace_ent;
 818         }
 819         else
 820         {
 821                 // 2. if we don't have a cursor trace, find the player which is least
 822                 //    mis-aimed at
 823                 entity p;
 824                 FOR_EACH_PLAYER(p)
 825                 {
 826                         float c;
 827                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 828                         if(c >= -1)
 829                         {
 830                                 selected = p;
 831                                 selected_score = c;
 832                         }
 833                 }
 834         }
 835
 836         if(selected)
 837         {
 838                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 839         }
 840         else
 841         {
 842                 if(time < self.selected_player_display_timeout)
 843                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 844                                 selected = self.selected_player;
 845         }
 846
 847         if(selected)
 848         {
 849                 if(selected == self.selected_player)
 850                 {
 851                         float save;
 852                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 853                         self.selected_player_count = self.selected_player_count + frametime;
 854                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 855                         {
 856                                 string namestr, healthstr;
 857                                 namestr = playername(selected);
 858                                 if(teams_matter)
 859                                 {
 860                                         healthstr = ftos(floor(selected.health));
 861                                         if(self.team == selected.team)
 862                                         {
 863                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 864                                                 self.selected_player_display_needs_update = TRUE;
 865                                         }
 866                                 }
 867                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 868                         }
 869                 }
 870                 else
 871                 {
 872                         ClearSelectedPlayer();
 873                         self.selected_player = selected;
 874                         self.selected_player_time = time;
 875                         self.selected_player_count = 0;
 876                         self.selected_player_display_needs_update = FALSE;
 877                 }
 878         }
 879         else
 880         {
 881                 ClearSelectedPlayer();
 882         }
 883
 884         if(self.selected_player)
 885                 self.last_selected_player = self.selected_player;
 886 }
 887
 888 .float muted; // to be used by prvm_edictset server playernumber muted 1
 889 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 890 // message "": do not say, just test flood control
 891 // return value:
 892 //   1 = accept
 893 //   0 = reject
 894 //  -1 = fake accept
 895 {
 896         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 897         float flood, privatemsgprefixlen;
 898         entity head;
 899         float ret;
 900
 901         if(Ban_MaybeEnforceBan(source))
 902                 return 0;
 903
 904         if(!teamsay && !privatesay)
 905                 if(substring(msgin, 0, 1) == " ")
 906                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 907
 908         msgin = formatmessage(msgin);
 909
 910         if(source.classname != "player")
 911                 colorstr = "^0"; // black for spectators
 912         else if(teams_matter)
 913                 colorstr = Team_ColorCode(source.team);
 914         else
 915                 teamsay = FALSE;
 916
 917         if(intermission_running)
 918                 teamsay = FALSE;
 919
 920         if(msgin != "")
 921                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 922
 923         /*
 924          * using bprint solves this... me stupid
 925         // how can we prevent the message from appearing in a listen server?
 926         // for now, just give "say" back and only handle say_team
 927         if(!teamsay)
 928         {
 929                 clientcommand(self, strcat("say ", msgin));
 930                 return;
 931         }
 932         */
 933
 934         if(cvar("g_chat_teamcolors"))
 935                 namestr = playername(source);
 936         else
 937                 namestr = source.netname;
 938
 939         if(msgin != "")
 940         {
 941                 if(privatesay)
 942                 {
 943                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 944                         privatemsgprefixlen = strlen(msgstr);
 945                         msgstr = strcat(msgstr, msgin);
 946                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 947                         if(cvar("g_chat_teamcolors"))
 948                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 949                         else
 950                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 951                 }
 952                 else if(teamsay)
 953                 {
 954                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 955                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 956                 }
 957                 else
 958                 {
 959                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 960                         cmsgstr = "";
 961                 }
 962                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 963         }
 964         else
 965         {
 966                 msgstr = cmsgstr = "";
 967         }
 968
 969         fullmsgstr = msgstr;
 970         fullcmsgstr = cmsgstr;
 971
 972         // FLOOD CONTROL
 973         flood = 0;
 974         if(floodcontrol)
 975         {
 976                 float flood_spl;
 977                 float flood_burst;
 978                 float flood_lmax;
 979                 var .float flood_field;
 980                 float lines;
 981                 if(privatesay)
 982                 {
 983                         flood_spl = cvar("g_chat_flood_spl_tell");
 984                         flood_burst = cvar("g_chat_flood_burst_tell");
 985                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 986                         flood_field = floodcontrol_chattell;
 987                 }
 988                 else if(teamsay)
 989                 {
 990                         flood_spl = cvar("g_chat_flood_spl_team");
 991                         flood_burst = cvar("g_chat_flood_burst_team");
 992                         flood_lmax = cvar("g_chat_flood_lmax_team");
 993                         flood_field = floodcontrol_chatteam;
 994                 }
 995                 else
 996                 {
 997                         flood_spl = cvar("g_chat_flood_spl");
 998                         flood_burst = cvar("g_chat_flood_burst");
 999                         flood_lmax = cvar("g_chat_flood_lmax");
1000                         flood_field = floodcontrol_chat;
1001                 }
1002                 flood_burst = max(0, flood_burst - 1);
1003                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1004
1005                 // do flood control for the default line size
1006                 if(msgstr != "")
1007                 {
1008                         getWrappedLine_remaining = msgstr;
1009                         msgstr = "";
1010                         lines = 0;
1011                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1012                         {
1013                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1014                                 ++lines;
1015                         }
1016                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1017
1018                         if(getWrappedLine_remaining != "")
1019                         {
1020                                 msgstr = strcat(msgstr, "\n");
1021                                 flood = 2;
1022                         }
1023
1024                         if(time >= source.flood_field)
1025                         {
1026                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1027                         }
1028                         else
1029                         {
1030                                 flood = 1;
1031                                 msgstr = fullmsgstr;
1032                         }
1033                 }
1034                 else
1035                 {
1036                         if(time >= source.flood_field)
1037                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1038                         else
1039                                 flood = 1;
1040                 }
1041         }
1042
1043         if (timeoutStatus == 2) //when game is paused, no flood protection
1044                 source.flood_field = flood = 0;
1045
1046         if(flood == 2) // cannot happen for empty msgstr
1047         {
1048                 if(cvar("g_chat_flood_notify_flooder"))
1049                 {
1050                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1051                         sourcecmsgstr = "";
1052                 }
1053                 else
1054                 {
1055                         sourcemsgstr = fullmsgstr;
1056                         sourcecmsgstr = fullcmsgstr;
1057                 }
1058                 cmsgstr = "";
1059         }
1060         else
1061         {
1062                 sourcemsgstr = msgstr;
1063                 sourcecmsgstr = cmsgstr;
1064         }
1065
1066         if(!privatesay)
1067         if(source.classname != "player")
1068         {
1069                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1070                         teamsay = -1; // spectators
1071         }
1072
1073         if(flood)
1074                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1075
1076         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1077         if(privatesay)
1078                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1079
1080         if(source.muted)
1081         {
1082                 // always fake the message
1083                 ret = -1;
1084         }
1085         else if(flood == 1)
1086         {
1087                 if(cvar("g_chat_flood_notify_flooder"))
1088                 {
1089                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1090                         ret = 0;
1091                 }
1092                 else
1093                         ret = -1;
1094         }
1095         else
1096         {
1097                 ret = 1;
1098         }
1099
1100         if(sourcemsgstr != "" && ret != 0)
1101         {
1102                 if(ret < 0) // fake
1103                 {
1104                         sprint(source, sourcemsgstr);
1105                         if(sourcecmsgstr != "" && !privatesay)
1106                                 centerprint(source, sourcecmsgstr);
1107                 }
1108                 else if(privatesay)
1109                 {
1110                         sprint(source, sourcemsgstr);
1111                         sprint(privatesay, msgstr);
1112                         if(cmsgstr != "")
1113                                 centerprint(privatesay, cmsgstr);
1114                 }
1115                 else if(teamsay > 0)
1116                 {
1117                         sprint(source, sourcemsgstr);
1118                         if(sourcecmsgstr != "")
1119                                 centerprint(source, sourcecmsgstr);
1120                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1121                                 if(head != source)
1122                                 {
1123                                         sprint(head, msgstr);
1124                                         if(cmsgstr != "")
1125                                                 centerprint(head, cmsgstr);
1126                                 }
1127                 }
1128                 else if(teamsay < 0)
1129                 {
1130                         sprint(source, sourcemsgstr);
1131                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1132                                 if(head != source)
1133                                         sprint(head, msgstr);
1134                 }
1135                 else if(sourcemsgstr != msgstr)
1136                 {
1137                         sprint(source, sourcemsgstr);
1138                         FOR_EACH_REALCLIENT(head)
1139                                 if(head != source)
1140                                         sprint(head, msgstr);
1141                 }
1142                 else
1143                         bprint(msgstr);
1144         }
1145
1146         return ret;
1147 }
1148
1149 float GetVoiceMessageVoiceType(string type)
1150 {
1151         if(type == "taunt")
1152                 return VOICETYPE_TAUNT;
1153         if(type == "teamshoot")
1154                 return VOICETYPE_LASTATTACKER;
1155         return VOICETYPE_TEAMRADIO;
1156 }
1157
1158 string allvoicesamples;
1159 float GetPlayerSoundSampleField_notFound;
1160 float GetPlayerSoundSampleField_fixed;
1161 .string GetVoiceMessageSampleField(string type)
1162 {
1163         GetPlayerSoundSampleField_notFound = 0;
1164         GetPlayerSoundSampleField_fixed = 0;
1165         switch(type)
1166         {
1167 #define _VOICEMSG(m) case #m: return playersound_##m;
1168                 ALLVOICEMSGS
1169 #undef _VOICEMSG
1170         }
1171         GetPlayerSoundSampleField_notFound = 1;
1172         return playersound_taunt;
1173 }
1174
1175 .string GetPlayerSoundSampleField(string type)
1176 {
1177         GetPlayerSoundSampleField_notFound = 0;
1178         GetPlayerSoundSampleField_fixed = 0;
1179         switch(type)
1180         {
1181 #define _VOICEMSG(m) case #m: return playersound_##m;
1182                 ALLPLAYERSOUNDS
1183 #undef _VOICEMSG
1184         }
1185         GetPlayerSoundSampleField_notFound = 1;
1186         return playersound_taunt;
1187 }
1188
1189 void PrecacheGlobalSound(string samplestring)
1190 {
1191         float n, i;
1192         tokenize_console(samplestring);
1193         n = stof(argv(1));
1194         if(n > 0)
1195         {
1196                 for(i = 1; i <= n; ++i)
1197                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1198         }
1199         else
1200         {
1201                 precache_sound(strcat(argv(0), ".wav"));
1202         }
1203 }
1204
1205 void PrecachePlayerSounds(string f)
1206 {
1207         float fh;
1208         string s;
1209         fh = fopen(f, FILE_READ);
1210         if(fh < 0)
1211                 return;
1212         while((s = fgets(fh)))
1213         {
1214                 if(tokenize_console(s) != 3)
1215                 {
1216                         dprint("Invalid sound info line: ", s, "\n");
1217                         continue;
1218                 }
1219                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1220         }
1221         fclose(fh);
1222
1223         if not(allvoicesamples)
1224         {
1225 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1226                 ALLVOICEMSGS
1227 #undef _VOICEMSG
1228                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1229         }
1230 }
1231
1232 void ClearPlayerSounds()
1233 {
1234 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1235         ALLPLAYERSOUNDS
1236         ALLVOICEMSGS
1237 #undef _VOICEMSG
1238 }
1239
1240 void LoadPlayerSounds(string f, float first)
1241 {
1242         float fh;
1243         string s;
1244         var .string field;
1245         fh = fopen(f, FILE_READ);
1246         if(fh < 0)
1247                 return;
1248         while((s = fgets(fh)))
1249         {
1250                 if(tokenize_console(s) != 3)
1251                         continue;
1252                 field = GetPlayerSoundSampleField(argv(0));
1253                 if(GetPlayerSoundSampleField_notFound)
1254                         field = GetVoiceMessageSampleField(argv(0));
1255                 if(GetPlayerSoundSampleField_notFound)
1256                         continue;
1257                 if(GetPlayerSoundSampleField_fixed)
1258                         if not(first)
1259                                 continue;
1260                 if(self.field)
1261                         strunzone(self.field);
1262                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1263         }
1264         fclose(fh);
1265 }
1266
1267 .float modelindex_for_playersound;
1268 void UpdatePlayerSounds()
1269 {
1270         if(self.modelindex == self.modelindex_for_playersound)
1271                 return;
1272         self.modelindex_for_playersound = self.modelindex;
1273         ClearPlayerSounds();
1274         LoadPlayerSounds("sound/player/default.sounds", 1);
1275         LoadPlayerSounds(strcat(self.model, ".sounds"), 0);
1276 }
1277
1278 void FakeGlobalSound(string sample, float chan, float voicetype)
1279 {
1280         float n;
1281         float tauntrand;
1282
1283         if(sample == "")
1284                 return;
1285
1286         tokenize_console(sample);
1287         n = stof(argv(1));
1288         if(n > 0)
1289                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1290         else
1291                 sample = strcat(argv(0), ".wav"); // randomization
1292
1293         switch(voicetype)
1294         {
1295                 case VOICETYPE_LASTATTACKER_ONLY:
1296                         break;
1297                 case VOICETYPE_LASTATTACKER:
1298                         if(self.pusher)
1299                         {
1300                                 msg_entity = self;
1301                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1302                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1303                         }
1304                         break;
1305                 case VOICETYPE_TEAMRADIO:
1306                         msg_entity = self;
1307                         if(msg_entity.cvar_cl_voice_directional == 1)
1308                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1309                         else
1310                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1311                         break;
1312                 case VOICETYPE_AUTOTAUNT:
1313                         if(!sv_autotaunt)
1314                                 break;
1315                         if(!sv_taunt)
1316                                 break;
1317                         if(sv_gentle)
1318                                 break;
1319                         tauntrand = random();
1320                         msg_entity = self;
1321                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1322                         {
1323                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1324                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1325                                 else
1326                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1327                         }
1328                         break;
1329                 case VOICETYPE_TAUNT:
1330                         if(self.classname == "player")
1331                                 if(self.deadflag == DEAD_NO)
1332                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1333                         if(!sv_taunt)
1334                                 break;
1335                         if(sv_gentle)
1336                                 break;
1337                         msg_entity = self;
1338                         if (msg_entity.cvar_cl_voice_directional >= 1)
1339                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1340                         else
1341                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1342                         break;
1343                 case VOICETYPE_PLAYERSOUND:
1344                         msg_entity = self;
1345                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1346                         break;
1347                 default:
1348                         backtrace("Invalid voice type!");
1349                         break;
1350         }
1351 }
1352
1353 void GlobalSound(string sample, float chan, float voicetype)
1354 {
1355         float n;
1356         float tauntrand;
1357
1358         if(sample == "")
1359                 return;
1360
1361         tokenize_console(sample);
1362         n = stof(argv(1));
1363         if(n > 0)
1364                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1365         else
1366                 sample = strcat(argv(0), ".wav"); // randomization
1367
1368         switch(voicetype)
1369         {
1370                 case VOICETYPE_LASTATTACKER_ONLY:
1371                         if(self.pusher)
1372                         {
1373                                 msg_entity = self.pusher;
1374                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1375                                 {
1376                                         if(msg_entity.cvar_cl_voice_directional == 1)
1377                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1378                                         else
1379                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1380                                 }
1381                         }
1382                         break;
1383                 case VOICETYPE_LASTATTACKER:
1384                         if(self.pusher)
1385                         {
1386                                 msg_entity = self.pusher;
1387                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1388                                 {
1389                                         if(msg_entity.cvar_cl_voice_directional == 1)
1390                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1391                                         else
1392                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1393                                 }
1394                                 msg_entity = self;
1395                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1396                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1397                         }
1398                         break;
1399                 case VOICETYPE_TEAMRADIO:
1400                         FOR_EACH_REALCLIENT(msg_entity)
1401                                 if(!teams_matter || msg_entity.team == self.team)
1402                                 {
1403                                         if(msg_entity.cvar_cl_voice_directional == 1)
1404                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1405                                         else
1406                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1407                                 }
1408                         break;
1409                 case VOICETYPE_AUTOTAUNT:
1410                         if(!sv_autotaunt)
1411                                 break;
1412                         if(!sv_taunt)
1413                                 break;
1414                         if(sv_gentle)
1415                                 break;
1416                         tauntrand = random();
1417                         FOR_EACH_REALCLIENT(msg_entity)
1418                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1419                                 {
1420                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1421                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1422                                         else
1423                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1424                                 }
1425                         break;
1426                 case VOICETYPE_TAUNT:
1427                         if(self.classname == "player")
1428                                 if(self.deadflag == DEAD_NO)
1429                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1430                         if(!sv_taunt)
1431                                 break;
1432                         if(sv_gentle)
1433                                 break;
1434                         FOR_EACH_REALCLIENT(msg_entity)
1435                         {
1436                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1437                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1438                                 else
1439                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1440                         }
1441                         break;
1442                 case VOICETYPE_PLAYERSOUND:
1443                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1444                         break;
1445                 default:
1446                         backtrace("Invalid voice type!");
1447                         break;
1448         }
1449 }
1450
1451 void PlayerSound(.string samplefield, float chan, float voicetype)
1452 {
1453         GlobalSound(self.samplefield, chan, voicetype);
1454 }
1455
1456 void VoiceMessage(string type, string msg)
1457 {
1458         var .string sample;
1459         float voicetype, ownteam;
1460         float flood;
1461         sample = GetVoiceMessageSampleField(type);
1462
1463         if(GetPlayerSoundSampleField_notFound)
1464         {
1465                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1466                 return;
1467         }
1468
1469         voicetype = GetVoiceMessageVoiceType(type);
1470         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1471
1472         flood = Say(self, ownteam, world, msg, 1);
1473
1474         if (flood > 0)
1475                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1476         else if (flood < 0)
1477                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1478 }
1479
1480 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1481 {
1482 //      show_message
1483 //      0 (00) automove centerprint, admin message
1484 //      1 (01) automove centerprint, no admin message
1485 //      2 (10) no centerprint, admin message
1486 //      3 (11) no centerprint, no admin message
1487
1488         float lockteams_backup;
1489
1490         lockteams_backup = lockteams;  // backup any team lock
1491
1492         lockteams = 0;  // disable locked teams
1493
1494         TeamchangeFrags(client);  // move the players frags
1495         SetPlayerColors(client, team_colour - 1);  // set the players colour
1496         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1497
1498         lockteams = lockteams_backup;  // restore the team lock
1499
1500         LogTeamchange(client.playerid, client.team, type);
1501
1502         if not(show_message & 1) // admin message
1503                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1504
1505         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1506 }