qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 string WeaponStats_prefix;
  17 void WeaponStats_ready(entity fh, entity pass, float status)
  18 {
  19         float i, j, ibot, jbot, idx;
  20         vector v;
  21         string prefix;
  22         switch(status)
  23         {
  24                 case URL_READY_CANWRITE:
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  33                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  34                                         if(v != '0 0 0')
  35                                         {
  36                                                 //vector is: kills hits damage
  37                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  38                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  39                                         }
  40                                 }
  41                         url_fputs(fh, "#end\n\n");
  42                         url_fclose(fh, WeaponStats_ready, world);
  43                         buf_del(weaponstats_buffer);
  44                         weaponstats_buffer = -1;
  45                         break;
  46                 case URL_READY_CANREAD:
  47                         print("Got response from weapon stats server\n");
  48                         url_fclose(fh, WeaponStats_ready, world);
  49                         break;
  50                 case URL_READY_CLOSED:
  51                         print("Weapon stats written\n");
  52                         break;
  53                 case URL_READY_ERROR:
  54                 default:
  55                         print("Weapon stats writing failed: ", ftos(status), "\n");
  56                         break;
  57         }
  58 }
  59
  60 void WeaponStats_Shutdown()
  61 {
  62         if(weaponstats_buffer < 0)
  63                 return;
  64         if(autocvar_sv_weaponstats_file != "")
  65         {
  66                 url_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  67         }
  68         else
  69         {
  70                 buf_del(weaponstats_buffer);
  71                 weaponstats_buffer = -1;
  72         }
  73 }
  74
  75 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  76 {
  77         float idx;
  78         if(weaponstats_buffer < 0)
  79                 return;
  80         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  81                 return;
  82         if(awep > WEP_LAST || vwep > WEP_LAST)
  83                 return;
  84         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  85         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  86 }
  87 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  88 {
  89         if(damage < 0)
  90                 error("negative damage?");
  91         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  92 }
  93 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  94 {
  95         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  96 }
  97
  98 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  99 // merged player_run and player_stand to player_anim
 100 // added death animations to player_anim
 101 // can now spawn thrown weapons from anywhere, not just from players
 102 // thrown weapons now fade out after 20 seconds
 103 // created PlayerGib function
 104 // PlayerDie no longer uses hitloc or damage
 105 // PlayerDie now supports dying animations as well as gibbing
 106 // cleaned up PlayerDie a lot
 107 // added CopyBody
 108
 109 .entity pusher;
 110 .float pushltime;
 111
 112 void CopyBody(float keepvelocity)
 113 {
 114         local entity oldself;
 115         if (self.effects & EF_NODRAW)
 116                 return;
 117         oldself = self;
 118         self = spawn();
 119         self.enemy = oldself;
 120         self.lip = oldself.lip;
 121         self.colormap = oldself.colormap;
 122         self.glowmod = oldself.glowmod;
 123         self.iscreature = oldself.iscreature;
 124         self.angles = oldself.angles;
 125         self.avelocity = oldself.avelocity;
 126         self.classname = "body";
 127         self.damageforcescale = oldself.damageforcescale;
 128         self.effects = oldself.effects;
 129         self.event_damage = oldself.event_damage;
 130         self.animstate_startframe = oldself.animstate_startframe;
 131         self.animstate_numframes = oldself.animstate_numframes;
 132         self.animstate_framerate = oldself.animstate_framerate;
 133         self.animstate_starttime = oldself.animstate_starttime;
 134         self.animstate_endtime = oldself.animstate_endtime;
 135         self.animstate_override = oldself.animstate_override;
 136         self.animstate_looping = oldself.animstate_looping;
 137         self.frame = oldself.frame;
 138         self.dead_frame = oldself.dead_frame;
 139         self.pain_finished = oldself.pain_finished;
 140         self.health = oldself.health;
 141         self.armorvalue = oldself.armorvalue;
 142         self.armortype = oldself.armortype;
 143         self.model = oldself.model;
 144         self.modelindex = oldself.modelindex;
 145         self.modelindex_lod0 = oldself.modelindex_lod0;
 146         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 147         self.modelindex_lod1 = oldself.modelindex_lod1;
 148         self.modelindex_lod2 = oldself.modelindex_lod2;
 149         self.skinindex = oldself.skinindex;
 150         self.species = oldself.species;
 151         self.movetype = oldself.movetype;
 152         self.nextthink = oldself.nextthink;
 153         self.solid = oldself.solid;
 154         self.ballistics_density = oldself.ballistics_density;
 155         self.takedamage = oldself.takedamage;
 156         self.think = oldself.think;
 157         self.customizeentityforclient = oldself.customizeentityforclient;
 158         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 159         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 160         if (keepvelocity == 1)
 161                 self.velocity = oldself.velocity;
 162         self.oldvelocity = self.velocity;
 163         self.fade_time = oldself.fade_time;
 164         self.fade_rate = oldself.fade_rate;
 165         //self.weapon = oldself.weapon;
 166         setorigin(self, oldself.origin);
 167         setsize(self, oldself.mins, oldself.maxs);
 168         self.prevorigin = oldself.origin;
 169         self.reset = SUB_Remove;
 170
 171         Drag_MoveDrag(oldself, self);
 172
 173         self = oldself;
 174 }
 175
 176 float player_getspecies()
 177 {
 178         float s;
 179         get_model_parameters(self.model, self.skinindex);
 180         s = get_model_parameters_species;
 181         get_model_parameters(string_null, 0);
 182         if(s < 0)
 183                 return SPECIES_HUMAN;
 184         return s;
 185 }
 186
 187 void player_setupanimsformodel()
 188 {
 189         local string animfilename;
 190         local float animfile;
 191         // defaults for legacy .zym models without animinfo files
 192         self.anim_die1 = '0 1 0.5'; // 2 seconds
 193         self.anim_die2 = '1 1 0.5'; // 2 seconds
 194         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 195         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 196         self.anim_duckwalk = '4 1 1';
 197         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 198         self.anim_duckidle = '6 1 1';
 199         self.anim_idle = '7 1 1';
 200         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 201         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 202         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 203         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 204         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 205         self.anim_run = '13 1 1';
 206         self.anim_runbackwards = '14 1 1';
 207         self.anim_strafeleft = '15 1 1';
 208         self.anim_straferight = '16 1 1';
 209         self.anim_dead1 = '17 1 1';
 210         self.anim_dead2 = '18 1 1';
 211         self.anim_forwardright = '19 1 1';
 212         self.anim_forwardleft = '20 1 1';
 213         self.anim_backright = '21 1 1';
 214         self.anim_backleft  = '22 1 1';
 215         self.anim_melee = '23 1 1';
 216         animparseerror = FALSE;
 217         animfilename = strcat(self.model, ".animinfo");
 218         animfile = fopen(animfilename, FILE_READ);
 219         if (animfile >= 0)
 220         {
 221                 self.anim_die1         = animparseline(animfile);
 222                 self.anim_die2         = animparseline(animfile);
 223                 self.anim_draw         = animparseline(animfile);
 224                 self.anim_duck         = animparseline(animfile);
 225                 self.anim_duckwalk     = animparseline(animfile);
 226                 self.anim_duckjump     = animparseline(animfile);
 227                 self.anim_duckidle     = animparseline(animfile);
 228                 self.anim_idle         = animparseline(animfile);
 229                 self.anim_jump         = animparseline(animfile);
 230                 self.anim_pain1        = animparseline(animfile);
 231                 self.anim_pain2        = animparseline(animfile);
 232                 self.anim_shoot        = animparseline(animfile);
 233                 self.anim_taunt        = animparseline(animfile);
 234                 self.anim_run          = animparseline(animfile);
 235                 self.anim_runbackwards = animparseline(animfile);
 236                 self.anim_strafeleft   = animparseline(animfile);
 237                 self.anim_straferight  = animparseline(animfile);
 238                 self.anim_forwardright = animparseline(animfile);
 239                 self.anim_forwardleft  = animparseline(animfile);
 240                 self.anim_backright    = animparseline(animfile);
 241                 self.anim_backleft     = animparseline(animfile);
 242                 self.anim_melee        = animparseline(animfile);
 243                 fclose(animfile);
 244
 245                 // derived anims
 246                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 247                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 248
 249                 if (animparseerror)
 250                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 251         }
 252         else
 253                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 254         // reset animstate now
 255         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 256 };
 257
 258 void player_anim (void)
 259 {
 260         updateanim(self);
 261         if (self.weaponentity)
 262                 updateanim(self.weaponentity);
 263
 264         if (self.deadflag != DEAD_NO)
 265         {
 266                 if (time > self.animstate_endtime)
 267                 {
 268                         if (self.maxs_z > 5)
 269                         {
 270                                 self.maxs_z = 5;
 271                                 setsize(self, self.mins, self.maxs);
 272                         }
 273                         self.frame = self.dead_frame;
 274                 }
 275                 return;
 276         }
 277
 278         if (!self.animstate_override)
 279         {
 280                 if (!(self.flags & FL_ONGROUND))
 281                 {
 282                         if (self.crouch)
 283                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 284                         else
 285                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 286                         self.restart_jump = FALSE;
 287                 }
 288                 else if (self.crouch)
 289                 {
 290                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 291                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 292                         else
 293                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 294                 }
 295                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 296                 {
 297                         if (self.movement_x > 0 && self.movement_y == 0)
 298                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y == 0)
 300                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x == 0 && self.movement_y > 0)
 302                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 303                         else if (self.movement_x == 0 && self.movement_y < 0)
 304                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 305                         else if (self.movement_x > 0 && self.movement_y > 0)
 306                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x > 0 && self.movement_y < 0)
 308                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x < 0 && self.movement_y > 0)
 310                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x < 0 && self.movement_y < 0)
 312                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 313                         else
 314                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 315                 }
 316                 else
 317                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 318         }
 319
 320         if (self.weaponentity)
 321         if (!self.weaponentity.animstate_override)
 322                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 323 }
 324
 325 void SpawnThrownWeapon (vector org, float w)
 326 {
 327         if(g_minstagib)
 328         if(self.ammo_cells <= 0)
 329                 return;
 330
 331         if(g_pinata)
 332         {
 333                 float j;
 334                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 335                 {
 336                         if(self.weapons & W_WeaponBit(j))
 337                                 if(W_IsWeaponThrowable(j))
 338                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 339                 }
 340         }
 341         else
 342         {
 343                 if(W_IsWeaponThrowable(self.weapon))
 344                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 345         }
 346 }
 347
 348 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 349 {
 350         local float take, save;
 351         vector v;
 352         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 353
 354         // damage resistance (ignore most of the damage from a bullet or similar)
 355         damage = max(damage - 5, 1);
 356
 357         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 358         take = v_x;
 359         save = v_y;
 360
 361         if(sound_allowed(MSG_BROADCAST, attacker))
 362         {
 363                 if (save > 10)
 364                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 365                 else if (take > 30)
 366                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 367                 else if (take > 10)
 368                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 369         }
 370
 371         if (take > 50)
 372                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 373         if (take > 100)
 374                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 375
 376         if (!(self.flags & FL_GODMODE))
 377         {
 378                 self.armorvalue = self.armorvalue - save;
 379                 self.health = self.health - take;
 380                 // pause regeneration for 5 seconds
 381                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 382         }
 383         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 384         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 385         self.dmg_inflictor = inflictor;
 386
 387         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 388         {
 389                 // don't use any animations as a gib
 390                 self.frame = 0;
 391                 self.dead_frame = 0;
 392                 // view just above the floor
 393                 self.view_ofs = '0 0 4';
 394
 395                 Violence_GibSplash(self, 1, 1, attacker);
 396                 self.modelindex = 0; // restore later
 397                 self.solid = SOLID_NOT; // restore later
 398         }
 399 }
 400
 401 void ClientKill_Now_TeamChange();
 402 void freezetag_CheckWinner();
 403
 404 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 405 {
 406         local float take, save, waves, sdelay, dh, da, j;
 407         vector v;
 408         float valid_damage_for_weaponstats;
 409         float excess;
 410
 411         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 412                 return;
 413
 414         dh = max(self.health, 0);
 415         da = max(self.armorvalue, 0);
 416
 417         if(!DEATH_ISSPECIAL(deathtype))
 418         {
 419                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 420                 if(self != attacker)
 421                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 422         }
 423
 424         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 425         {
 426                 // tuba causes blood to come out of the ears
 427                 vector ear1, ear2;
 428                 vector d;
 429                 float f;
 430                 ear1 = self.origin;
 431                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 432                 ear2 = ear1;
 433                 makevectors(self.angles);
 434                 ear1 += v_right * -10;
 435                 ear2 += v_right * +10;
 436                 d = inflictor.origin - self.origin;
 437                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 438                 force = v_right * vlen(force);
 439                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 440                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 441                 if(f > 0)
 442                 {
 443                         hitloc = ear1;
 444                         force = force * -1;
 445                 }
 446                 else
 447                 {
 448                         hitloc = ear2;
 449                         // force is already good
 450                 }
 451         }
 452         else
 453                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 454
 455         if (!g_minstagib)
 456         {
 457                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 458                 take = v_x;
 459                 save = v_y;
 460         }
 461         else
 462         {
 463                 save = 0;
 464                 take = damage;
 465         }
 466
 467         frag_inflictor = inflictor;
 468         frag_attacker = attacker;
 469         frag_target = self;
 470         damage_take = take;
 471         damage_save = save;
 472         damage_force = force;
 473         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 474         take = bound(0, damage_take, self.health);
 475         save = bound(0, damage_save, self.armorvalue);
 476         excess = max(0, damage - take - save);
 477
 478         if(sound_allowed(MSG_BROADCAST, attacker))
 479         {
 480                 if (save > 10)
 481                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 482                 else if (take > 30)
 483                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 484                 else if (take > 10)
 485                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 486         }
 487
 488         if (take > 50)
 489                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 490         if (take > 100)
 491                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 492
 493         if (time >= self.spawnshieldtime)
 494         {
 495                 if (!(self.flags & FL_GODMODE))
 496                 {
 497                         self.armorvalue = self.armorvalue - save;
 498                         self.health = self.health - take;
 499                         // pause regeneration for 5 seconds
 500                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 501
 502                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 503                         {
 504                                 self.pain_finished = time + 0.5;        //Supajoe
 505
 506                                 if(sv_gentle < 1) {
 507                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 508                                         {
 509                                                 if (random() > 0.5)
 510                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 511                                                 else
 512                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 513                                         }
 514
 515                                         if(sound_allowed(MSG_BROADCAST, attacker))
 516                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 517                                         if(self.health > 1)
 518                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 519                                         {
 520                                                 if(deathtype == DEATH_FALL)
 521                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 522                                                 else if(self.health > 75) // TODO make a "gentle" version?
 523                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 524                                                 else if(self.health > 50)
 525                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 526                                                 else if(self.health > 25)
 527                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 528                                                 else
 529                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 530                                         }
 531                                 }
 532
 533                                 // throw off bot aim temporarily
 534                                 local float shake;
 535                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 536                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 537                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 538                         }
 539                 }
 540                 else
 541                         self.max_armorvalue += (save + take);
 542         }
 543         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 544         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 545         self.dmg_inflictor = inflictor;
 546
 547         if(attacker == self)
 548         {
 549                 // don't reset pushltime for self damage as it may be an attempt to
 550                 // escape a lava pit or similar
 551                 //self.pushltime = 0;
 552         }
 553         else if(attacker.classname == "player")
 554         {
 555                 self.pusher = attacker;
 556                 self.pushltime = time + autocvar_g_maxpushtime;
 557         }
 558         else if(time < self.pushltime)
 559         {
 560                 attacker = self.pusher;
 561                 self.pushltime = max(self.pushltime, time + 0.6);
 562         }
 563         else
 564                 self.pushltime = 0;
 565
 566         float abot, vbot, awep;
 567         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 568         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 569
 570         valid_damage_for_weaponstats = 0;
 571         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 572         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 573         if(attacker && self != attacker)
 574         if(IsDifferentTeam(self, attacker))
 575         {
 576                 if(DEATH_ISSPECIAL(deathtype))
 577                         awep = attacker.weapon;
 578                 else
 579                         awep = DEATH_WEAPONOF(deathtype);
 580                 valid_damage_for_weaponstats = 1;
 581         }
 582
 583         if(valid_damage_for_weaponstats)
 584         {
 585                 dh = dh - max(self.health, 0);
 586                 da = da - max(self.armorvalue, 0);
 587                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 588         }
 589
 590         if (self.health < 1)
 591         {
 592                 float defer_ClientKill_Now_TeamChange;
 593                 defer_ClientKill_Now_TeamChange = FALSE;
 594
 595                 if(self.alivetime)
 596                 {
 597                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 598                         self.alivetime = 0;
 599                 }
 600
 601                 if(valid_damage_for_weaponstats)
 602                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 603
 604                 if(sv_gentle < 1) // TODO make a "gentle" version?
 605                 if(sound_allowed(MSG_BROADCAST, attacker))
 606                 {
 607                         if(deathtype == DEATH_DROWN)
 608                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 609                         else
 610                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 611                 }
 612
 613                 // get rid of kill indicator
 614                 if(self.killindicator)
 615                 {
 616                         remove(self.killindicator);
 617                         self.killindicator = world;
 618                         if(self.killindicator_teamchange)
 619                                 defer_ClientKill_Now_TeamChange = TRUE;
 620
 621                         if(self.classname == "body")
 622                         if(deathtype == DEATH_KILL)
 623                         {
 624                                 // for the lemmings fans, a small harmless explosion
 625                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 626                         }
 627                 }
 628
 629                 if(!g_freezetag)
 630                 {
 631                         // become fully visible
 632                         self.alpha = 1;
 633                         // throw a weapon
 634                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 635                 }
 636
 637                 // print an obituary message
 638                 Obituary (attacker, inflictor, self, deathtype);
 639                 race_PreDie();
 640                 DropAllRunes(self);
 641
 642         // increment frag counter for used weapon type
 643         float w;
 644         w = DEATH_WEAPONOF(deathtype);
 645         if(WEP_VALID(w))
 646         if(self.classname == "player")
 647         if(self != attacker)
 648         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 649
 650                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 651                 {
 652                         PutClientInServer();
 653                         count_alive_players(); // re-count players
 654                         freezetag_CheckWinner();
 655                         return;
 656                 }
 657
 658                 frag_attacker = attacker;
 659                 frag_inflictor = inflictor;
 660                 frag_target = self;
 661                 MUTATOR_CALLHOOK(PlayerDies);
 662                 weapon_action(self.weapon, WR_PLAYERDEATH);
 663
 664                 if(self.flagcarried)
 665                 {
 666                         if(attacker.classname != "player")
 667                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 668                         else if(attacker.team == self.team)
 669                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 670                         else
 671                                 DropFlag(self.flagcarried, world, attacker);
 672                 }
 673                 if(self.ballcarried && g_nexball)
 674                         DropBall(self.ballcarried, self.origin, self.velocity);
 675                 Portal_ClearAllLater(self);
 676
 677                 if(clienttype(self) == CLIENTTYPE_REAL)
 678                 {
 679                         stuffcmd(self, "-zoom\n");
 680                         self.fixangle = TRUE;
 681                         //msg_entity = self;
 682                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 683                         //WriteAngle (MSG_ONE, self.v_angle_x);
 684                         //WriteAngle (MSG_ONE, self.v_angle_y);
 685                         //WriteAngle (MSG_ONE, 80);
 686                 }
 687
 688                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 689                         ClientKill_Now_TeamChange();
 690
 691                 if(g_arena)
 692                         Spawnqueue_Unmark(self);
 693
 694                 if(g_freezetag)
 695                         return;
 696
 697                 // when we get here, player actually dies
 698                 // clear waypoints (do this AFTER FreezeTag)
 699                 WaypointSprite_PlayerDead();
 700
 701                 // make the corpse upright (not tilted)
 702                 self.angles_x = 0;
 703                 self.angles_z = 0;
 704                 // don't spin
 705                 self.avelocity = '0 0 0';
 706                 // view from the floor
 707                 self.view_ofs = '0 0 -8';
 708                 // toss the corpse
 709                 self.movetype = MOVETYPE_TOSS;
 710                 // shootable corpse
 711                 self.solid = SOLID_CORPSE;
 712                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 713                 // don't stick to the floor
 714                 self.flags &~= FL_ONGROUND;
 715                 // dying animation
 716                 self.deadflag = DEAD_DYING;
 717                 // when to allow respawn
 718                 sdelay = 0;
 719                 waves = 0;
 720                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 721                 if(!sdelay)
 722                 {
 723                         if(g_cts)
 724                                 sdelay = 0; // no respawn delay in CTS
 725                         else
 726                                 sdelay = autocvar_g_respawn_delay;
 727                 }
 728                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 729                 if(!waves)
 730                         waves = autocvar_g_respawn_waves;
 731                 if(waves)
 732                         self.death_time = ceil((time + sdelay) / waves) * waves;
 733                 else
 734                         self.death_time = time + sdelay;
 735                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 736                         self.respawn_countdown = 10; // first number to count down from is 10
 737                 else
 738                         self.respawn_countdown = -1; // do not count down
 739                 if (random() < 0.5)
 740                 {
 741                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 742                         self.dead_frame = self.anim_dead1_x;
 743                 }
 744                 else
 745                 {
 746                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 747                         self.dead_frame = self.anim_dead2_x;
 748                 }
 749                 // set damage function to corpse damage
 750                 self.event_damage = PlayerCorpseDamage;
 751                 // call the corpse damage function just in case it wants to gib
 752                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 753                 // set up to fade out later
 754                 SUB_SetFade (self, time + 6 + random (), 1);
 755
 756                 if(sv_gentle > 0 || autocvar_ekg) {
 757                         // remove corpse
 758                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 759                 }
 760
 761                 // reset fields the weapons may use just in case
 762                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 763                 {
 764                         weapon_action(j, WR_RESETPLAYER);
 765                         ATTACK_FINISHED_FOR(self, j) = 0;
 766                 }
 767         }
 768 }
 769
 770 .float muted; // to be used by prvm_edictset server playernumber muted 1
 771 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 772 // message "": do not say, just test flood control
 773 // return value:
 774 //   1 = accept
 775 //   0 = reject
 776 //  -1 = fake accept
 777 {
 778         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 779         float flood, privatemsgprefixlen;
 780         var .float flood_field;
 781         entity head;
 782         float ret;
 783
 784         if(Ban_MaybeEnforceBan(source))
 785                 return 0;
 786
 787         if(!teamsay && !privatesay)
 788                 if(substring(msgin, 0, 1) == " ")
 789                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 790
 791         msgin = formatmessage(msgin);
 792
 793         if(source.classname != "player")
 794                 colorstr = "^0"; // black for spectators
 795         else if(teamplay)
 796                 colorstr = Team_ColorCode(source.team);
 797         else
 798                 teamsay = FALSE;
 799
 800         if(intermission_running)
 801                 teamsay = FALSE;
 802
 803         if(msgin != "")
 804                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 805
 806         /*
 807          * using bprint solves this... me stupid
 808         // how can we prevent the message from appearing in a listen server?
 809         // for now, just give "say" back and only handle say_team
 810         if(!teamsay)
 811         {
 812                 clientcommand(self, strcat("say ", msgin));
 813                 return;
 814         }
 815         */
 816
 817         if(autocvar_g_chat_teamcolors)
 818                 namestr = playername(source);
 819         else
 820                 namestr = source.netname;
 821
 822         if(msgin != "")
 823         {
 824                 if(privatesay)
 825                 {
 826                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 827                         privatemsgprefixlen = strlen(msgstr);
 828                         msgstr = strcat(msgstr, msgin);
 829                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 830                         if(autocvar_g_chat_teamcolors)
 831                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 832                         else
 833                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 834                 }
 835                 else if(teamsay)
 836                 {
 837                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 838                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 839                 }
 840                 else
 841                 {
 842                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 843                         cmsgstr = "";
 844                 }
 845                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 846         }
 847         else
 848         {
 849                 msgstr = cmsgstr = "";
 850         }
 851
 852         fullmsgstr = msgstr;
 853         fullcmsgstr = cmsgstr;
 854
 855         // FLOOD CONTROL
 856         flood = 0;
 857         if(floodcontrol)
 858         {
 859                 float flood_spl;
 860                 float flood_burst;
 861                 float flood_lmax;
 862                 float lines;
 863                 if(privatesay)
 864                 {
 865                         flood_spl = autocvar_g_chat_flood_spl_tell;
 866                         flood_burst = autocvar_g_chat_flood_burst_tell;
 867                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 868                         flood_field = floodcontrol_chattell;
 869                 }
 870                 else if(teamsay)
 871                 {
 872                         flood_spl = autocvar_g_chat_flood_spl_team;
 873                         flood_burst = autocvar_g_chat_flood_burst_team;
 874                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 875                         flood_field = floodcontrol_chatteam;
 876                 }
 877                 else
 878                 {
 879                         flood_spl = autocvar_g_chat_flood_spl;
 880                         flood_burst = autocvar_g_chat_flood_burst;
 881                         flood_lmax = autocvar_g_chat_flood_lmax;
 882                         flood_field = floodcontrol_chat;
 883                 }
 884                 flood_burst = max(0, flood_burst - 1);
 885                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 886
 887                 // do flood control for the default line size
 888                 if(msgstr != "")
 889                 {
 890                         getWrappedLine_remaining = msgstr;
 891                         msgstr = "";
 892                         lines = 0;
 893                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 894                         {
 895                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 896                                 ++lines;
 897                         }
 898                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 899
 900                         if(getWrappedLine_remaining != "")
 901                         {
 902                                 msgstr = strcat(msgstr, "\n");
 903                                 flood = 2;
 904                         }
 905
 906                         if(time >= source.flood_field)
 907                         {
 908                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 909                         }
 910                         else
 911                         {
 912                                 flood = 1;
 913                                 msgstr = fullmsgstr;
 914                         }
 915                 }
 916                 else
 917                 {
 918                         if(time >= source.flood_field)
 919                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 920                         else
 921                                 flood = 1;
 922                 }
 923
 924                 if (timeoutStatus == 2) //when game is paused, no flood protection
 925                         source.flood_field = flood = 0;
 926         }
 927
 928         if(flood == 2) // cannot happen for empty msgstr
 929         {
 930                 if(autocvar_g_chat_flood_notify_flooder)
 931                 {
 932                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 933                         sourcecmsgstr = "";
 934                 }
 935                 else
 936                 {
 937                         sourcemsgstr = fullmsgstr;
 938                         sourcecmsgstr = fullcmsgstr;
 939                 }
 940                 cmsgstr = "";
 941         }
 942         else
 943         {
 944                 sourcemsgstr = msgstr;
 945                 sourcecmsgstr = cmsgstr;
 946         }
 947
 948         if(!privatesay)
 949         if(source.classname != "player")
 950         {
 951                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 952                         teamsay = -1; // spectators
 953         }
 954
 955         if(flood)
 956                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 957
 958         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 959         if(privatesay)
 960                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 961
 962         if(source.muted)
 963         {
 964                 // always fake the message
 965                 ret = -1;
 966         }
 967         else if(flood == 1)
 968         {
 969                 if(autocvar_g_chat_flood_notify_flooder)
 970                 {
 971                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 972                         ret = 0;
 973                 }
 974                 else
 975                         ret = -1;
 976         }
 977         else
 978         {
 979                 ret = 1;
 980         }
 981
 982         if(sourcemsgstr != "" && ret != 0)
 983         {
 984                 if(ret < 0) // fake
 985                 {
 986                         sprint(source, sourcemsgstr);
 987                         if(sourcecmsgstr != "" && !privatesay)
 988                                 centerprint(source, sourcecmsgstr);
 989                 }
 990                 else if(privatesay)
 991                 {
 992                         sprint(source, sourcemsgstr);
 993                         sprint(privatesay, msgstr);
 994                         if(cmsgstr != "")
 995                                 centerprint(privatesay, cmsgstr);
 996                 }
 997                 else if(teamsay > 0)
 998                 {
 999                         sprint(source, sourcemsgstr);
1000                         if(sourcecmsgstr != "")
1001                                 centerprint(source, sourcecmsgstr);
1002                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1003                                 if(head != source)
1004                                 {
1005                                         sprint(head, msgstr);
1006                                         if(cmsgstr != "")
1007                                                 centerprint(head, cmsgstr);
1008                                 }
1009                 }
1010                 else if(teamsay < 0)
1011                 {
1012                         sprint(source, sourcemsgstr);
1013                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1014                                 if(head != source)
1015                                         sprint(head, msgstr);
1016                 }
1017                 else if(sourcemsgstr != msgstr)
1018                 {
1019                         sprint(source, sourcemsgstr);
1020                         FOR_EACH_REALCLIENT(head)
1021                                 if(head != source)
1022                                         sprint(head, msgstr);
1023                 }
1024                 else
1025                         bprint(msgstr);
1026         }
1027
1028         return ret;
1029 }
1030
1031 float GetVoiceMessageVoiceType(string type)
1032 {
1033         if(type == "taunt")
1034                 return VOICETYPE_TAUNT;
1035         if(type == "teamshoot")
1036                 return VOICETYPE_LASTATTACKER;
1037         return VOICETYPE_TEAMRADIO;
1038 }
1039
1040 string allvoicesamples;
1041 .string GetVoiceMessageSampleField(string type)
1042 {
1043         GetPlayerSoundSampleField_notFound = 0;
1044         switch(type)
1045         {
1046 #define _VOICEMSG(m) case #m: return playersound_##m;
1047                 ALLVOICEMSGS
1048 #undef _VOICEMSG
1049         }
1050         GetPlayerSoundSampleField_notFound = 1;
1051         return playersound_taunt;
1052 }
1053
1054 .string GetPlayerSoundSampleField(string type)
1055 {
1056         GetPlayerSoundSampleField_notFound = 0;
1057         switch(type)
1058         {
1059 #define _VOICEMSG(m) case #m: return playersound_##m;
1060                 ALLPLAYERSOUNDS
1061 #undef _VOICEMSG
1062         }
1063         GetPlayerSoundSampleField_notFound = 1;
1064         return playersound_taunt;
1065 }
1066
1067 void PrecacheGlobalSound(string samplestring)
1068 {
1069         float n, i;
1070         tokenize_console(samplestring);
1071         n = stof(argv(1));
1072         if(n > 0)
1073         {
1074                 for(i = 1; i <= n; ++i)
1075                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1076         }
1077         else
1078         {
1079                 precache_sound(strcat(argv(0), ".wav"));
1080         }
1081 }
1082
1083 void PrecachePlayerSounds(string f)
1084 {
1085         float fh;
1086         string s;
1087         fh = fopen(f, FILE_READ);
1088         if(fh < 0)
1089                 return;
1090         while((s = fgets(fh)))
1091         {
1092                 if(tokenize_console(s) != 3)
1093                 {
1094                         dprint("Invalid sound info line: ", s, "\n");
1095                         continue;
1096                 }
1097                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1098         }
1099         fclose(fh);
1100
1101         if not(allvoicesamples)
1102         {
1103 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1104                 ALLVOICEMSGS
1105 #undef _VOICEMSG
1106                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1107         }
1108 }
1109
1110 void ClearPlayerSounds()
1111 {
1112 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1113         ALLPLAYERSOUNDS
1114         ALLVOICEMSGS
1115 #undef _VOICEMSG
1116 }
1117
1118 float LoadPlayerSounds(string f, float first)
1119 {
1120         float fh;
1121         string s;
1122         var .string field;
1123         fh = fopen(f, FILE_READ);
1124         if(fh < 0)
1125         {
1126                 dprint("Player sound file not found: ", f, "\n");
1127                 return 0;
1128         }
1129         while((s = fgets(fh)))
1130         {
1131                 if(tokenize_console(s) != 3)
1132                         continue;
1133                 field = GetPlayerSoundSampleField(argv(0));
1134                 if(GetPlayerSoundSampleField_notFound)
1135                         field = GetVoiceMessageSampleField(argv(0));
1136                 if(GetPlayerSoundSampleField_notFound)
1137                         continue;
1138                 if(self.field)
1139                         strunzone(self.field);
1140                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1141         }
1142         fclose(fh);
1143         return 1;
1144 }
1145
1146 .float modelindex_for_playersound;
1147 .float skinindex_for_playersound;
1148 void UpdatePlayerSounds()
1149 {
1150         if(self.modelindex == self.modelindex_for_playersound)
1151         if(self.skinindex == self.skinindex_for_playersound)
1152                 return;
1153         self.modelindex_for_playersound = self.modelindex;
1154         self.skinindex_for_playersound = self.skinindex;
1155         ClearPlayerSounds();
1156         LoadPlayerSounds("sound/player/default.sounds", 1);
1157         if(!autocvar_g_debug_defaultsounds)
1158                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1159                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1160 }
1161
1162 void FakeGlobalSound(string sample, float chan, float voicetype)
1163 {
1164         float n;
1165         float tauntrand;
1166
1167         if(sample == "")
1168                 return;
1169
1170         tokenize_console(sample);
1171         n = stof(argv(1));
1172         if(n > 0)
1173                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1174         else
1175                 sample = strcat(argv(0), ".wav"); // randomization
1176
1177         switch(voicetype)
1178         {
1179                 case VOICETYPE_LASTATTACKER_ONLY:
1180                         break;
1181                 case VOICETYPE_LASTATTACKER:
1182                         if(self.pusher)
1183                         {
1184                                 msg_entity = self;
1185                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1186                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1187                         }
1188                         break;
1189                 case VOICETYPE_TEAMRADIO:
1190                         msg_entity = self;
1191                         if(msg_entity.cvar_cl_voice_directional == 1)
1192                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1193                         else
1194                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1195                         break;
1196                 case VOICETYPE_AUTOTAUNT:
1197                         if(!sv_autotaunt)
1198                                 break;
1199                         if(!sv_taunt)
1200                                 break;
1201                         if(sv_gentle)
1202                                 break;
1203                         tauntrand = random();
1204                         msg_entity = self;
1205                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1206                         {
1207                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1208                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1209                                 else
1210                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1211                         }
1212                         break;
1213                 case VOICETYPE_TAUNT:
1214                         if(self.classname == "player")
1215                                 if(self.deadflag == DEAD_NO)
1216                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1217                         if(!sv_taunt)
1218                                 break;
1219                         if(sv_gentle)
1220                                 break;
1221                         msg_entity = self;
1222                         if (msg_entity.cvar_cl_voice_directional >= 1)
1223                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1224                         else
1225                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1226                         break;
1227                 case VOICETYPE_PLAYERSOUND:
1228                         msg_entity = self;
1229                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1230                         break;
1231                 default:
1232                         backtrace("Invalid voice type!");
1233                         break;
1234         }
1235 }
1236
1237 void GlobalSound(string sample, float chan, float voicetype)
1238 {
1239         float n;
1240         float tauntrand;
1241
1242         if(sample == "")
1243                 return;
1244
1245         tokenize_console(sample);
1246         n = stof(argv(1));
1247         if(n > 0)
1248                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1249         else
1250                 sample = strcat(argv(0), ".wav"); // randomization
1251
1252         switch(voicetype)
1253         {
1254                 case VOICETYPE_LASTATTACKER_ONLY:
1255                         if(self.pusher)
1256                         {
1257                                 msg_entity = self.pusher;
1258                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1259                                 {
1260                                         if(msg_entity.cvar_cl_voice_directional == 1)
1261                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1262                                         else
1263                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1264                                 }
1265                         }
1266                         break;
1267                 case VOICETYPE_LASTATTACKER:
1268                         if(self.pusher)
1269                         {
1270                                 msg_entity = self.pusher;
1271                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1272                                 {
1273                                         if(msg_entity.cvar_cl_voice_directional == 1)
1274                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1275                                         else
1276                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1277                                 }
1278                                 msg_entity = self;
1279                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1280                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1281                         }
1282                         break;
1283                 case VOICETYPE_TEAMRADIO:
1284                         FOR_EACH_REALCLIENT(msg_entity)
1285                                 if(!teamplay || msg_entity.team == self.team)
1286                                 {
1287                                         if(msg_entity.cvar_cl_voice_directional == 1)
1288                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1289                                         else
1290                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1291                                 }
1292                         break;
1293                 case VOICETYPE_AUTOTAUNT:
1294                         if(!sv_autotaunt)
1295                                 break;
1296                         if(!sv_taunt)
1297                                 break;
1298                         if(sv_gentle)
1299                                 break;
1300                         tauntrand = random();
1301                         FOR_EACH_REALCLIENT(msg_entity)
1302                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1303                                 {
1304                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1305                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1306                                         else
1307                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1308                                 }
1309                         break;
1310                 case VOICETYPE_TAUNT:
1311                         if(self.classname == "player")
1312                                 if(self.deadflag == DEAD_NO)
1313                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1314                         if(!sv_taunt)
1315                                 break;
1316                         if(sv_gentle)
1317                                 break;
1318                         FOR_EACH_REALCLIENT(msg_entity)
1319                         {
1320                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1321                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1322                                 else
1323                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1324                         }
1325                         break;
1326                 case VOICETYPE_PLAYERSOUND:
1327                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1328                         break;
1329                 default:
1330                         backtrace("Invalid voice type!");
1331                         break;
1332         }
1333 }
1334
1335 void PlayerSound(.string samplefield, float chan, float voicetype)
1336 {
1337         GlobalSound(self.samplefield, chan, voicetype);
1338 }
1339
1340 void VoiceMessage(string type, string msg)
1341 {
1342         var .string sample;
1343         float voicetype, ownteam;
1344         float flood;
1345         sample = GetVoiceMessageSampleField(type);
1346
1347         if(GetPlayerSoundSampleField_notFound)
1348         {
1349                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1350                 return;
1351         }
1352
1353         voicetype = GetVoiceMessageVoiceType(type);
1354         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1355
1356         flood = Say(self, ownteam, world, msg, 1);
1357
1358         if (flood > 0)
1359                 GlobalSound(self.sample, CH_VOICE, voicetype);
1360         else if (flood < 0)
1361                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1362 }
1363
1364 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1365 {
1366 //      show_message
1367 //      0 (00) automove centerprint, admin message
1368 //      1 (01) automove centerprint, no admin message
1369 //      2 (10) no centerprint, admin message
1370 //      3 (11) no centerprint, no admin message
1371
1372         float lockteams_backup;
1373
1374         lockteams_backup = lockteams;  // backup any team lock
1375
1376         lockteams = 0;  // disable locked teams
1377
1378         TeamchangeFrags(client);  // move the players frags
1379         SetPlayerColors(client, team_colour - 1);  // set the players colour
1380         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1381
1382         lockteams = lockteams_backup;  // restore the team lock
1383
1384         LogTeamchange(client.playerid, client.team, type);
1385
1386         if not(show_message & 1) // admin message
1387                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1388
1389         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1390 }