qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 void CopyBody(float keepvelocity)
 128 {
 129         entity oldself;
 130         if (self.effects & EF_NODRAW)
 131                 return;
 132         oldself = self;
 133         self = spawn();
 134         self.enemy = oldself;
 135         self.lip = oldself.lip;
 136         self.colormap = oldself.colormap;
 137         self.iscreature = oldself.iscreature;
 138         self.damagedbycontents = oldself.damagedbycontents;
 139         self.angles = oldself.angles;
 140         self.avelocity = oldself.avelocity;
 141         self.classname = "body";
 142         self.damageforcescale = oldself.damageforcescale;
 143         self.effects = oldself.effects;
 144         self.glowmod = oldself.glowmod;
 145         self.event_damage = oldself.event_damage;
 146         self.animstate_startframe = oldself.animstate_startframe;
 147         self.animstate_numframes = oldself.animstate_numframes;
 148         self.animstate_framerate = oldself.animstate_framerate;
 149         self.animstate_starttime = oldself.animstate_starttime;
 150         self.animstate_endtime = oldself.animstate_endtime;
 151         self.animstate_override = oldself.animstate_override;
 152         self.animstate_looping = oldself.animstate_looping;
 153         self.frame = oldself.frame;
 154         self.dead_frame = oldself.dead_frame;
 155         self.pain_finished = oldself.pain_finished;
 156         self.health = oldself.health;
 157         self.armorvalue = oldself.armorvalue;
 158         self.armortype = oldself.armortype;
 159         self.model = oldself.model;
 160         self.modelindex = oldself.modelindex;
 161         self.skin = oldself.skin;
 162         self.species = oldself.species;
 163         self.movetype = oldself.movetype;
 164         self.nextthink = oldself.nextthink;
 165         self.solid = oldself.solid;
 166         self.ballistics_density = oldself.ballistics_density;
 167         self.takedamage = oldself.takedamage;
 168         self.think = oldself.think;
 169         self.customizeentityforclient = oldself.customizeentityforclient;
 170         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 171         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 172         if (keepvelocity == 1)
 173                 self.velocity = oldself.velocity;
 174         self.oldvelocity = self.velocity;
 175         self.fade_time = oldself.fade_time;
 176         self.fade_rate = oldself.fade_rate;
 177         //self.weapon = oldself.weapon;
 178         setorigin(self, oldself.origin);
 179         setsize(self, oldself.mins, oldself.maxs);
 180         self.prevorigin = oldself.origin;
 181         self.reset = SUB_Remove;
 182
 183         Drag_MoveDrag(oldself, self);
 184
 185         if(self.colormap <= maxclients && self.colormap > 0)
 186                 self.colormap = 1024 + self.clientcolors;
 187
 188         self = oldself;
 189 }
 190
 191 float player_getspecies()
 192 {
 193         float s;
 194         get_model_parameters(self.model, self.skin);
 195         s = get_model_parameters_species;
 196         get_model_parameters(string_null, 0);
 197         if(s < 0)
 198                 return SPECIES_HUMAN;
 199         return s;
 200 }
 201
 202 void player_setupanimsformodel()
 203 {
 204         // defaults for legacy .zym models without animinfo files
 205         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 206         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 207         self.anim_draw = animfixfps(self, '2 1 3');
 208         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 209         self.anim_duckwalk = animfixfps(self, '4 1 1');
 210         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 211         self.anim_duckidle = animfixfps(self, '6 1 1');
 212         self.anim_idle = animfixfps(self, '7 1 1');
 213         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 214         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 215         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 216         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 217         self.anim_taunt = animfixfps(self, '12 1 0.33');
 218         self.anim_run = animfixfps(self, '13 1 1');
 219         self.anim_runbackwards = animfixfps(self, '14 1 1');
 220         self.anim_strafeleft = animfixfps(self, '15 1 1');
 221         self.anim_straferight = animfixfps(self, '16 1 1');
 222         self.anim_dead1 = animfixfps(self, '17 1 1');
 223         self.anim_dead2 = animfixfps(self, '18 1 1');
 224         self.anim_forwardright = animfixfps(self, '19 1 1');
 225         self.anim_forwardleft = animfixfps(self, '20 1 1');
 226         self.anim_backright = animfixfps(self, '21 1 1');
 227         self.anim_backleft  = animfixfps(self, '22 1 1');
 228         self.anim_melee = animfixfps(self, '23 1 1');
 229         // TODO introspect models for finding right "fps" value (1/duration)
 230         // reset animstate now
 231         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 232 }
 233
 234 void player_anim (void)
 235 {
 236         updateanim(self);
 237         if (self.weaponentity)
 238                 updateanim(self.weaponentity);
 239
 240         if (self.deadflag != DEAD_NO)
 241         {
 242                 if (time > self.animstate_endtime)
 243                 {
 244                         if (self.maxs_z > 5)
 245                         {
 246                                 self.maxs_z = 5;
 247                                 setsize(self, self.mins, self.maxs);
 248                         }
 249                         self.frame = self.dead_frame;
 250                 }
 251                 return;
 252         }
 253
 254         if (!self.animstate_override)
 255         {
 256                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 257                 {
 258                         if (self.crouch)
 259                         {
 260                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 261                                 {
 262                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 263                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 264                                         {
 265                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 266                                                 self.restart_jump = FALSE;
 267                                         }
 268                                 }
 269                         }
 270                         else
 271                         {
 272                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 273                 {
 274                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 275                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 276                     {
 277                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 278                         self.restart_jump = FALSE;
 279                     }
 280                 }
 281                         }
 282                 }
 283                 else if (self.crouch)
 284                 {
 285                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 286                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 287                         else
 288                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 289                 }
 290                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 291                 {
 292                         if (self.movement_x > 0 && self.movement_y == 0)
 293                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 294                         else if (self.movement_x < 0 && self.movement_y == 0)
 295                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 296                         else if (self.movement_x == 0 && self.movement_y > 0)
 297                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 298                         else if (self.movement_x == 0 && self.movement_y < 0)
 299                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 300                         else if (self.movement_x > 0 && self.movement_y > 0)
 301                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 302                         else if (self.movement_x > 0 && self.movement_y < 0)
 303                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 304                         else if (self.movement_x < 0 && self.movement_y > 0)
 305                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 306                         else if (self.movement_x < 0 && self.movement_y < 0)
 307                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 308                         else
 309                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 310                 }
 311                 else
 312                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 313         }
 314
 315         if (self.weaponentity)
 316         if (!self.weaponentity.animstate_override)
 317                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 318 }
 319
 320 void SpawnThrownWeapon (vector org, float w)
 321 {
 322         if(g_minstagib)
 323         if(self.ammo_cells <= 0)
 324                 return;
 325
 326         if(g_pinata)
 327         {
 328                 float j;
 329                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 330                 {
 331                         if(self.weapons & W_WeaponBit(j))
 332                                 if(W_IsWeaponThrowable(j))
 333                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 334                 }
 335         }
 336         else
 337         {
 338                 if(W_IsWeaponThrowable(self.weapon))
 339                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 340         }
 341 }
 342
 343 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 344 {
 345         float take, save;
 346         vector v;
 347         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 348
 349         // damage resistance (ignore most of the damage from a bullet or similar)
 350         damage = max(damage - 5, 1);
 351
 352         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 353         take = v_x;
 354         save = v_y;
 355
 356         if(sound_allowed(MSG_BROADCAST, attacker))
 357         {
 358                 if (save > 10)
 359                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 360                 else if (take > 30)
 361                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 362                 else if (take > 10)
 363                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 364         }
 365
 366         if (take > 50)
 367                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 368         if (take > 100)
 369                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 370
 371         if (!(self.flags & FL_GODMODE))
 372         {
 373                 self.armorvalue = self.armorvalue - save;
 374                 self.health = self.health - take;
 375                 // pause regeneration for 5 seconds
 376                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 377         }
 378         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 379         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 380         self.dmg_inflictor = inflictor;
 381
 382         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 383         {
 384                 // don't use any animations as a gib
 385                 self.frame = 0;
 386                 self.dead_frame = 0;
 387                 // view just above the floor
 388                 self.view_ofs = '0 0 4';
 389
 390                 Violence_GibSplash(self, 1, 1, attacker);
 391                 self.modelindex = 0; // restore later
 392                 self.solid = SOLID_NOT; // restore later
 393         }
 394 }
 395
 396 void ClientKill_Now_TeamChange();
 397 void freezetag_CheckWinner();
 398
 399 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 400 {
 401         float take, save, waves, sdelay, dh, da, j;
 402         vector v;
 403         float valid_damage_for_weaponstats;
 404         float excess;
 405
 406         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 407                 return;
 408
 409         dh = max(self.health, 0);
 410         da = max(self.armorvalue, 0);
 411
 412         if(!DEATH_ISSPECIAL(deathtype))
 413         {
 414                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 415                 if(self != attacker)
 416                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 417         }
 418
 419         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 420         {
 421                 // tuba causes blood to come out of the ears
 422                 vector ear1, ear2;
 423                 vector d;
 424                 float f;
 425                 ear1 = self.origin;
 426                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 427                 ear2 = ear1;
 428                 makevectors(self.angles);
 429                 ear1 += v_right * -10;
 430                 ear2 += v_right * +10;
 431                 d = inflictor.origin - self.origin;
 432                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 433                 force = v_right * vlen(force);
 434                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 435                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 436                 if(f > 0)
 437                 {
 438                         hitloc = ear1;
 439                         force = force * -1;
 440                 }
 441                 else
 442                 {
 443                         hitloc = ear2;
 444                         // force is already good
 445                 }
 446         }
 447         else
 448                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 449
 450         if (!g_minstagib)
 451         {
 452                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 453                 take = v_x;
 454                 save = v_y;
 455         }
 456         else
 457         {
 458                 save = 0;
 459                 take = damage;
 460         }
 461
 462         frag_inflictor = inflictor;
 463         frag_attacker = attacker;
 464         frag_target = self;
 465         damage_take = take;
 466         damage_save = save;
 467         damage_force = force;
 468         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 469         take = bound(0, damage_take, self.health);
 470         save = bound(0, damage_save, self.armorvalue);
 471         excess = max(0, damage - take - save);
 472
 473         if(sound_allowed(MSG_BROADCAST, attacker))
 474         {
 475                 if (save > 10)
 476                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 477                 else if (take > 30)
 478                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 479                 else if (take > 10)
 480                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 481         }
 482
 483         if (take > 50)
 484                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 485         if (take > 100)
 486                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 487
 488         if (time >= self.spawnshieldtime)
 489         {
 490                 if (!(self.flags & FL_GODMODE))
 491                 {
 492                         self.armorvalue = self.armorvalue - save;
 493                         self.health = self.health - take;
 494                         // pause regeneration for 5 seconds
 495                         if(take)
 496                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 497
 498                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 499                         {
 500                                 self.pain_finished = time + 0.5;        //Supajoe
 501
 502                                 if(sv_gentle < 1) {
 503                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 504                                         {
 505                                                 if (!self.animstate_override)
 506                                                 {
 507                                                         if (random() > 0.5)
 508                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 509                                                         else
 510                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 511                                                 }
 512                                         }
 513
 514                                         if(sound_allowed(MSG_BROADCAST, attacker))
 515                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 516                                         if(self.health > 1)
 517                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 518                                         {
 519                                                 if(deathtype == DEATH_FALL)
 520                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 521                                                 else if(self.health > 75) // TODO make a "gentle" version?
 522                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 523                                                 else if(self.health > 50)
 524                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 525                                                 else if(self.health > 25)
 526                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 527                                                 else
 528                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 529                                         }
 530                                 }
 531
 532                                 // throw off bot aim temporarily
 533                                 float shake;
 534                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 535                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 536                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 537                         }
 538                 }
 539                 else
 540                         self.max_armorvalue += (save + take);
 541         }
 542         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 543         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 544         self.dmg_inflictor = inflictor;
 545
 546         if(attacker == self)
 547         {
 548                 // don't reset pushltime for self damage as it may be an attempt to
 549                 // escape a lava pit or similar
 550                 //self.pushltime = 0;
 551         }
 552         else if(attacker.classname == "player")
 553         {
 554                 self.pusher = attacker;
 555                 self.pushltime = time + autocvar_g_maxpushtime;
 556         }
 557         else if(time < self.pushltime)
 558         {
 559                 attacker = self.pusher;
 560                 self.pushltime = max(self.pushltime, time + 0.6);
 561         }
 562         else
 563                 self.pushltime = 0;
 564
 565         float abot, vbot, awep;
 566         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 567         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 568
 569         valid_damage_for_weaponstats = 0;
 570         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 571         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 572         if(attacker && self != attacker)
 573         if(IsDifferentTeam(self, attacker))
 574         {
 575                 if(DEATH_ISSPECIAL(deathtype))
 576                         awep = attacker.weapon;
 577                 else
 578                         awep = DEATH_WEAPONOF(deathtype);
 579                 valid_damage_for_weaponstats = 1;
 580         }
 581
 582         if(valid_damage_for_weaponstats)
 583         {
 584                 dh = dh - max(self.health, 0);
 585                 da = da - max(self.armorvalue, 0);
 586                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 587         }
 588
 589         if (self.health < 1)
 590         {
 591                 float defer_ClientKill_Now_TeamChange;
 592                 defer_ClientKill_Now_TeamChange = FALSE;
 593
 594                 if(self.alivetime)
 595                 {
 596                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 597                         self.alivetime = 0;
 598                 }
 599
 600                 if(valid_damage_for_weaponstats)
 601                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 602
 603                 if(sv_gentle < 1) // TODO make a "gentle" version?
 604                 if(sound_allowed(MSG_BROADCAST, attacker))
 605                 {
 606                         if(deathtype == DEATH_DROWN)
 607                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 608                         else
 609                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 610                 }
 611
 612                 // get rid of kill indicator
 613                 if(self.killindicator)
 614                 {
 615                         remove(self.killindicator);
 616                         self.killindicator = world;
 617                         if(self.killindicator_teamchange)
 618                                 defer_ClientKill_Now_TeamChange = TRUE;
 619
 620                         if(self.classname == "body")
 621                         if(deathtype == DEATH_KILL)
 622                         {
 623                                 // for the lemmings fans, a small harmless explosion
 624                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 625                         }
 626                 }
 627
 628                 if(!g_freezetag)
 629                 {
 630                         // become fully visible
 631                         self.alpha = 1;
 632                         // throw a weapon
 633                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 634                 }
 635
 636                 // print an obituary message
 637                 Obituary (attacker, inflictor, self, deathtype);
 638                 race_PreDie();
 639                 DropAllRunes(self);
 640
 641         // increment frag counter for used weapon type
 642         float w;
 643         w = DEATH_WEAPONOF(deathtype);
 644         if(WEP_VALID(w))
 645         if(self.classname == "player")
 646         if(self != attacker)
 647         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 648
 649                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 650                 {
 651                         PutClientInServer();
 652                         count_alive_players(); // re-count players
 653                         freezetag_CheckWinner();
 654                         return;
 655                 }
 656
 657                 frag_attacker = attacker;
 658                 frag_inflictor = inflictor;
 659                 frag_target = self;
 660                 MUTATOR_CALLHOOK(PlayerDies);
 661                 weapon_action(self.weapon, WR_PLAYERDEATH);
 662
 663                 RemoveGrapplingHook(self);
 664
 665                 if(self.flagcarried)
 666                 {
 667                         if(attacker.classname != "player")
 668                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 669                         else if(attacker.team == self.team)
 670                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 671                         else
 672                                 DropFlag(self.flagcarried, world, attacker);
 673                 }
 674                 if(self.ballcarried && g_nexball)
 675                         DropBall(self.ballcarried, self.origin, self.velocity);
 676                 Portal_ClearAllLater(self);
 677
 678                 if(clienttype(self) == CLIENTTYPE_REAL)
 679                 {
 680                         stuffcmd(self, "-zoom\n");
 681                         self.fixangle = TRUE;
 682                         //msg_entity = self;
 683                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 684                         //WriteAngle (MSG_ONE, self.v_angle_x);
 685                         //WriteAngle (MSG_ONE, self.v_angle_y);
 686                         //WriteAngle (MSG_ONE, 80);
 687                 }
 688
 689                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 690                         ClientKill_Now_TeamChange();
 691
 692                 if(g_arena)
 693                         Spawnqueue_Unmark(self);
 694
 695                 if(g_freezetag)
 696                         return;
 697
 698                 // when we get here, player actually dies
 699                 // clear waypoints (do this AFTER FreezeTag)
 700                 WaypointSprite_PlayerDead();
 701
 702                 // make the corpse upright (not tilted)
 703                 self.angles_x = 0;
 704                 self.angles_z = 0;
 705                 // don't spin
 706                 self.avelocity = '0 0 0';
 707                 // view from the floor
 708                 self.view_ofs = '0 0 -8';
 709                 // toss the corpse
 710                 self.movetype = MOVETYPE_TOSS;
 711                 // shootable corpse
 712                 self.solid = SOLID_CORPSE;
 713                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 714                 // don't stick to the floor
 715                 self.flags &~= FL_ONGROUND;
 716                 // dying animation
 717                 self.deadflag = DEAD_DYING;
 718                 // when to allow respawn
 719                 sdelay = 0;
 720                 waves = 0;
 721                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 722                 if(!sdelay)
 723                 {
 724                         if(g_cts)
 725                                 sdelay = 0; // no respawn delay in CTS
 726                         else
 727                                 sdelay = autocvar_g_respawn_delay;
 728                 }
 729                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 730                 if(!waves)
 731                         waves = autocvar_g_respawn_waves;
 732                 if(waves)
 733                         self.death_time = ceil((time + sdelay) / waves) * waves;
 734                 else
 735                         self.death_time = time + sdelay;
 736                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 737                         self.respawn_countdown = 10; // first number to count down from is 10
 738                 else
 739                         self.respawn_countdown = -1; // do not count down
 740                 if (random() < 0.5)
 741                 {
 742                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 743                         self.dead_frame = self.anim_dead1_x;
 744                 }
 745                 else
 746                 {
 747                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 748                         self.dead_frame = self.anim_dead2_x;
 749                 }
 750                 // set damage function to corpse damage
 751                 self.event_damage = PlayerCorpseDamage;
 752                 // call the corpse damage function just in case it wants to gib
 753                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 754                 // set up to fade out later
 755                 SUB_SetFade (self, time + 6 + random (), 1);
 756
 757                 if(sv_gentle > 0 || autocvar_ekg) {
 758                         // remove corpse
 759                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 760                 }
 761
 762                 // reset fields the weapons may use just in case
 763                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 764                 {
 765                         weapon_action(j, WR_RESETPLAYER);
 766                         ATTACK_FINISHED_FOR(self, j) = 0;
 767                 }
 768         }
 769 }
 770
 771 .float muted; // to be used by prvm_edictset server playernumber muted 1
 772 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 773 // message "": do not say, just test flood control
 774 // return value:
 775 //   1 = accept
 776 //   0 = reject
 777 //  -1 = fake accept
 778 {
 779         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 780         float flood, privatemsgprefixlen;
 781         var .float flood_field;
 782         entity head;
 783         float ret;
 784
 785         if(Ban_MaybeEnforceBan(source))
 786                 return 0;
 787
 788         if(!teamsay && !privatesay)
 789                 if(substring(msgin, 0, 1) == " ")
 790                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 791
 792         msgin = formatmessage(msgin);
 793
 794         if(source.classname != "player")
 795                 colorstr = "^0"; // black for spectators
 796         else if(teamplay)
 797                 colorstr = Team_ColorCode(source.team);
 798         else
 799                 teamsay = FALSE;
 800
 801         if(intermission_running)
 802                 teamsay = FALSE;
 803
 804         if(msgin != "")
 805                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 806
 807         /*
 808          * using bprint solves this... me stupid
 809         // how can we prevent the message from appearing in a listen server?
 810         // for now, just give "say" back and only handle say_team
 811         if(!teamsay)
 812         {
 813                 clientcommand(self, strcat("say ", msgin));
 814                 return;
 815         }
 816         */
 817
 818         if(autocvar_g_chat_teamcolors)
 819                 namestr = playername(source);
 820         else
 821                 namestr = source.netname;
 822
 823         if(msgin != "")
 824         {
 825                 if(privatesay)
 826                 {
 827                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 828                         privatemsgprefixlen = strlen(msgstr);
 829                         msgstr = strcat(msgstr, msgin);
 830                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 831                         if(autocvar_g_chat_teamcolors)
 832                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 833                         else
 834                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 835                 }
 836                 else if(teamsay)
 837                 {
 838                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 839                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 840                 }
 841                 else
 842                 {
 843                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 844                         cmsgstr = "";
 845                 }
 846                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 847         }
 848         else
 849         {
 850                 msgstr = cmsgstr = "";
 851         }
 852
 853         fullmsgstr = msgstr;
 854         fullcmsgstr = cmsgstr;
 855
 856         // FLOOD CONTROL
 857         flood = 0;
 858         if(floodcontrol)
 859         {
 860                 float flood_spl;
 861                 float flood_burst;
 862                 float flood_lmax;
 863                 float lines;
 864                 if(privatesay)
 865                 {
 866                         flood_spl = autocvar_g_chat_flood_spl_tell;
 867                         flood_burst = autocvar_g_chat_flood_burst_tell;
 868                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 869                         flood_field = floodcontrol_chattell;
 870                 }
 871                 else if(teamsay)
 872                 {
 873                         flood_spl = autocvar_g_chat_flood_spl_team;
 874                         flood_burst = autocvar_g_chat_flood_burst_team;
 875                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 876                         flood_field = floodcontrol_chatteam;
 877                 }
 878                 else
 879                 {
 880                         flood_spl = autocvar_g_chat_flood_spl;
 881                         flood_burst = autocvar_g_chat_flood_burst;
 882                         flood_lmax = autocvar_g_chat_flood_lmax;
 883                         flood_field = floodcontrol_chat;
 884                 }
 885                 flood_burst = max(0, flood_burst - 1);
 886                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 887
 888                 // do flood control for the default line size
 889                 if(msgstr != "")
 890                 {
 891                         getWrappedLine_remaining = msgstr;
 892                         msgstr = "";
 893                         lines = 0;
 894                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 895                         {
 896                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 897                                 ++lines;
 898                         }
 899                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 900
 901                         if(getWrappedLine_remaining != "")
 902                         {
 903                                 msgstr = strcat(msgstr, "\n");
 904                                 flood = 2;
 905                         }
 906
 907                         if(time >= source.flood_field)
 908                         {
 909                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 910                         }
 911                         else
 912                         {
 913                                 flood = 1;
 914                                 msgstr = fullmsgstr;
 915                         }
 916                 }
 917                 else
 918                 {
 919                         if(time >= source.flood_field)
 920                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 921                         else
 922                                 flood = 1;
 923                 }
 924
 925                 if (timeoutStatus == 2) //when game is paused, no flood protection
 926                         source.flood_field = flood = 0;
 927         }
 928
 929         if(flood == 2) // cannot happen for empty msgstr
 930         {
 931                 if(autocvar_g_chat_flood_notify_flooder)
 932                 {
 933                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 934                         sourcecmsgstr = "";
 935                 }
 936                 else
 937                 {
 938                         sourcemsgstr = fullmsgstr;
 939                         sourcecmsgstr = fullcmsgstr;
 940                 }
 941                 cmsgstr = "";
 942         }
 943         else
 944         {
 945                 sourcemsgstr = msgstr;
 946                 sourcecmsgstr = cmsgstr;
 947         }
 948
 949         if(!privatesay)
 950         if(source.classname != "player")
 951         {
 952                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 953                         teamsay = -1; // spectators
 954         }
 955
 956         if(flood)
 957                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 958
 959         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 960         if(privatesay)
 961                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 962
 963         if(source.muted)
 964         {
 965                 // always fake the message
 966                 ret = -1;
 967         }
 968         else if(flood == 1)
 969         {
 970                 if(autocvar_g_chat_flood_notify_flooder)
 971                 {
 972                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 973                         ret = 0;
 974                 }
 975                 else
 976                         ret = -1;
 977         }
 978         else
 979         {
 980                 ret = 1;
 981         }
 982
 983         if(sourcemsgstr != "" && ret != 0)
 984         {
 985                 if(ret < 0) // fake
 986                 {
 987                         sprint(source, sourcemsgstr);
 988                         if(sourcecmsgstr != "" && !privatesay)
 989                                 centerprint(source, sourcecmsgstr);
 990                 }
 991                 else if(privatesay)
 992                 {
 993                         sprint(source, sourcemsgstr);
 994                         sprint(privatesay, msgstr);
 995                         if(cmsgstr != "")
 996                                 centerprint(privatesay, cmsgstr);
 997                 }
 998                 else if(teamsay > 0)
 999                 {
1000                         sprint(source, sourcemsgstr);
1001                         if(sourcecmsgstr != "")
1002                                 centerprint(source, sourcecmsgstr);
1003                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1004                                 if(head != source)
1005                                 {
1006                                         sprint(head, msgstr);
1007                                         if(cmsgstr != "")
1008                                                 centerprint(head, cmsgstr);
1009                                 }
1010                 }
1011                 else if(teamsay < 0)
1012                 {
1013                         sprint(source, sourcemsgstr);
1014                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1015                                 if(head != source)
1016                                         sprint(head, msgstr);
1017                 }
1018                 else if(sourcemsgstr != msgstr)
1019                 {
1020                         sprint(source, sourcemsgstr);
1021                         FOR_EACH_REALCLIENT(head)
1022                                 if(head != source)
1023                                         sprint(head, msgstr);
1024                 }
1025                 else
1026                         bprint(msgstr);
1027         }
1028
1029         return ret;
1030 }
1031
1032 float GetVoiceMessageVoiceType(string type)
1033 {
1034         if(type == "taunt")
1035                 return VOICETYPE_TAUNT;
1036         if(type == "teamshoot")
1037                 return VOICETYPE_LASTATTACKER;
1038         return VOICETYPE_TEAMRADIO;
1039 }
1040
1041 string allvoicesamples;
1042 .string GetVoiceMessageSampleField(string type)
1043 {
1044         GetPlayerSoundSampleField_notFound = 0;
1045         switch(type)
1046         {
1047 #define _VOICEMSG(m) case #m: return playersound_##m;
1048                 ALLVOICEMSGS
1049 #undef _VOICEMSG
1050         }
1051         GetPlayerSoundSampleField_notFound = 1;
1052         return playersound_taunt;
1053 }
1054
1055 .string GetPlayerSoundSampleField(string type)
1056 {
1057         GetPlayerSoundSampleField_notFound = 0;
1058         switch(type)
1059         {
1060 #define _VOICEMSG(m) case #m: return playersound_##m;
1061                 ALLPLAYERSOUNDS
1062 #undef _VOICEMSG
1063         }
1064         GetPlayerSoundSampleField_notFound = 1;
1065         return playersound_taunt;
1066 }
1067
1068 void PrecacheGlobalSound(string samplestring)
1069 {
1070         float n, i;
1071         tokenize_console(samplestring);
1072         n = stof(argv(1));
1073         if(n > 0)
1074         {
1075                 for(i = 1; i <= n; ++i)
1076                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1077         }
1078         else
1079         {
1080                 precache_sound(strcat(argv(0), ".wav"));
1081         }
1082 }
1083
1084 void PrecachePlayerSounds(string f)
1085 {
1086         float fh;
1087         string s;
1088         fh = fopen(f, FILE_READ);
1089         if(fh < 0)
1090                 return;
1091         while((s = fgets(fh)))
1092         {
1093                 if(tokenize_console(s) != 3)
1094                 {
1095                         dprint("Invalid sound info line: ", s, "\n");
1096                         continue;
1097                 }
1098                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1099         }
1100         fclose(fh);
1101
1102         if not(allvoicesamples)
1103         {
1104 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1105                 ALLVOICEMSGS
1106 #undef _VOICEMSG
1107                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1108         }
1109 }
1110
1111 void ClearPlayerSounds()
1112 {
1113 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1114         ALLPLAYERSOUNDS
1115         ALLVOICEMSGS
1116 #undef _VOICEMSG
1117 }
1118
1119 float LoadPlayerSounds(string f, float first)
1120 {
1121         float fh;
1122         string s;
1123         var .string field;
1124         fh = fopen(f, FILE_READ);
1125         if(fh < 0)
1126         {
1127                 dprint("Player sound file not found: ", f, "\n");
1128                 return 0;
1129         }
1130         while((s = fgets(fh)))
1131         {
1132                 if(tokenize_console(s) != 3)
1133                         continue;
1134                 field = GetPlayerSoundSampleField(argv(0));
1135                 if(GetPlayerSoundSampleField_notFound)
1136                         field = GetVoiceMessageSampleField(argv(0));
1137                 if(GetPlayerSoundSampleField_notFound)
1138                         continue;
1139                 if(self.field)
1140                         strunzone(self.field);
1141                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1142         }
1143         fclose(fh);
1144         return 1;
1145 }
1146
1147 .float modelindex_for_playersound;
1148 .float skin_for_playersound;
1149 void UpdatePlayerSounds()
1150 {
1151         if(self.modelindex == self.modelindex_for_playersound)
1152         if(self.skin == self.skin_for_playersound)
1153                 return;
1154         self.modelindex_for_playersound = self.modelindex;
1155         self.skin_for_playersound = self.skin;
1156         ClearPlayerSounds();
1157         LoadPlayerSounds("sound/player/default.sounds", 1);
1158         if(!autocvar_g_debug_defaultsounds)
1159                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1160                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1161 }
1162
1163 void FakeGlobalSound(string sample, float chan, float voicetype)
1164 {
1165         float n;
1166         float tauntrand;
1167
1168         if(sample == "")
1169                 return;
1170
1171         tokenize_console(sample);
1172         n = stof(argv(1));
1173         if(n > 0)
1174                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1175         else
1176                 sample = strcat(argv(0), ".wav"); // randomization
1177
1178         switch(voicetype)
1179         {
1180                 case VOICETYPE_LASTATTACKER_ONLY:
1181                         break;
1182                 case VOICETYPE_LASTATTACKER:
1183                         if(self.pusher)
1184                         {
1185                                 msg_entity = self;
1186                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1187                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1188                         }
1189                         break;
1190                 case VOICETYPE_TEAMRADIO:
1191                         msg_entity = self;
1192                         if(msg_entity.cvar_cl_voice_directional == 1)
1193                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1194                         else
1195                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1196                         break;
1197                 case VOICETYPE_AUTOTAUNT:
1198                         if(!sv_autotaunt)
1199                                 break;
1200                         if(!sv_taunt)
1201                                 break;
1202                         if(sv_gentle)
1203                                 break;
1204                         tauntrand = random();
1205                         msg_entity = self;
1206                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1207                         {
1208                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1209                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1210                                 else
1211                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1212                         }
1213                         break;
1214                 case VOICETYPE_TAUNT:
1215                         if(self.classname == "player")
1216                                 if(self.deadflag == DEAD_NO)
1217                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1218                         if(!sv_taunt)
1219                                 break;
1220                         if(sv_gentle)
1221                                 break;
1222                         msg_entity = self;
1223                         if (msg_entity.cvar_cl_voice_directional >= 1)
1224                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1225                         else
1226                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1227                         break;
1228                 case VOICETYPE_PLAYERSOUND:
1229                         msg_entity = self;
1230                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1231                         break;
1232                 default:
1233                         backtrace("Invalid voice type!");
1234                         break;
1235         }
1236 }
1237
1238 void GlobalSound(string sample, float chan, float voicetype)
1239 {
1240         float n;
1241         float tauntrand;
1242
1243         if(sample == "")
1244                 return;
1245
1246         tokenize_console(sample);
1247         n = stof(argv(1));
1248         if(n > 0)
1249                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1250         else
1251                 sample = strcat(argv(0), ".wav"); // randomization
1252
1253         switch(voicetype)
1254         {
1255                 case VOICETYPE_LASTATTACKER_ONLY:
1256                         if(self.pusher)
1257                         {
1258                                 msg_entity = self.pusher;
1259                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1260                                 {
1261                                         if(msg_entity.cvar_cl_voice_directional == 1)
1262                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1263                                         else
1264                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1265                                 }
1266                         }
1267                         break;
1268                 case VOICETYPE_LASTATTACKER:
1269                         if(self.pusher)
1270                         {
1271                                 msg_entity = self.pusher;
1272                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1273                                 {
1274                                         if(msg_entity.cvar_cl_voice_directional == 1)
1275                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1276                                         else
1277                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1278                                 }
1279                                 msg_entity = self;
1280                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1281                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1282                         }
1283                         break;
1284                 case VOICETYPE_TEAMRADIO:
1285                         FOR_EACH_REALCLIENT(msg_entity)
1286                                 if(!teamplay || msg_entity.team == self.team)
1287                                 {
1288                                         if(msg_entity.cvar_cl_voice_directional == 1)
1289                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1290                                         else
1291                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1292                                 }
1293                         break;
1294                 case VOICETYPE_AUTOTAUNT:
1295                         if(!sv_autotaunt)
1296                                 break;
1297                         if(!sv_taunt)
1298                                 break;
1299                         if(sv_gentle)
1300                                 break;
1301                         tauntrand = random();
1302                         FOR_EACH_REALCLIENT(msg_entity)
1303                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1304                                 {
1305                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1306                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1307                                         else
1308                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1309                                 }
1310                         break;
1311                 case VOICETYPE_TAUNT:
1312                         if(self.classname == "player")
1313                                 if(self.deadflag == DEAD_NO)
1314                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1315                         if(!sv_taunt)
1316                                 break;
1317                         if(sv_gentle)
1318                                 break;
1319                         FOR_EACH_REALCLIENT(msg_entity)
1320                         {
1321                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1322                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1323                                 else
1324                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1325                         }
1326                         break;
1327                 case VOICETYPE_PLAYERSOUND:
1328                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1329                         break;
1330                 default:
1331                         backtrace("Invalid voice type!");
1332                         break;
1333         }
1334 }
1335
1336 void PlayerSound(.string samplefield, float chan, float voicetype)
1337 {
1338         GlobalSound(self.samplefield, chan, voicetype);
1339 }
1340
1341 void VoiceMessage(string type, string msg)
1342 {
1343         var .string sample;
1344         float voicetype, ownteam;
1345         float flood;
1346         sample = GetVoiceMessageSampleField(type);
1347
1348         if(GetPlayerSoundSampleField_notFound)
1349         {
1350                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1351                 return;
1352         }
1353
1354         voicetype = GetVoiceMessageVoiceType(type);
1355         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1356
1357         flood = Say(self, ownteam, world, msg, 1);
1358
1359         if (flood > 0)
1360                 GlobalSound(self.sample, CH_VOICE, voicetype);
1361         else if (flood < 0)
1362                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1363 }
1364
1365 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1366 {
1367 //      show_message
1368 //      0 (00) automove centerprint, admin message
1369 //      1 (01) automove centerprint, no admin message
1370 //      2 (10) no centerprint, admin message
1371 //      3 (11) no centerprint, no admin message
1372
1373         float lockteams_backup;
1374
1375         lockteams_backup = lockteams;  // backup any team lock
1376
1377         lockteams = 0;  // disable locked teams
1378
1379         TeamchangeFrags(client);  // move the players frags
1380         SetPlayerColors(client, team_colour - 1);  // set the players colour
1381         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1382
1383         lockteams = lockteams_backup;  // restore the team lock
1384
1385         LogTeamchange(client.playerid, client.team, type);
1386
1387         if not(show_message & 1) // admin message
1388                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1389
1390         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1391 }