qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 void CopyBody(float keepvelocity)
 128 {
 129         local entity oldself;
 130         if (self.effects & EF_NODRAW)
 131                 return;
 132         oldself = self;
 133         self = spawn();
 134         self.enemy = oldself;
 135         self.lip = oldself.lip;
 136         self.colormap = oldself.colormap;
 137         self.glowmod = oldself.glowmod;
 138         self.iscreature = oldself.iscreature;
 139         self.damagedbycontents = oldself.damagedbycontents;
 140         self.angles = oldself.angles;
 141         self.avelocity = oldself.avelocity;
 142         self.classname = "body";
 143         self.damageforcescale = oldself.damageforcescale;
 144         self.effects = oldself.effects;
 145         self.event_damage = oldself.event_damage;
 146         self.animstate_startframe = oldself.animstate_startframe;
 147         self.animstate_numframes = oldself.animstate_numframes;
 148         self.animstate_framerate = oldself.animstate_framerate;
 149         self.animstate_starttime = oldself.animstate_starttime;
 150         self.animstate_endtime = oldself.animstate_endtime;
 151         self.animstate_override = oldself.animstate_override;
 152         self.animstate_looping = oldself.animstate_looping;
 153         self.frame = oldself.frame;
 154         self.dead_frame = oldself.dead_frame;
 155         self.pain_finished = oldself.pain_finished;
 156         self.health = oldself.health;
 157         self.armorvalue = oldself.armorvalue;
 158         self.armortype = oldself.armortype;
 159         self.model = oldself.model;
 160         self.modelindex = oldself.modelindex;
 161         self.modelindex_lod0 = oldself.modelindex_lod0;
 162         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 163         self.modelindex_lod1 = oldself.modelindex_lod1;
 164         self.modelindex_lod2 = oldself.modelindex_lod2;
 165         self.skinindex = oldself.skinindex;
 166         self.species = oldself.species;
 167         self.movetype = oldself.movetype;
 168         self.nextthink = oldself.nextthink;
 169         self.solid = oldself.solid;
 170         self.ballistics_density = oldself.ballistics_density;
 171         self.takedamage = oldself.takedamage;
 172         self.think = oldself.think;
 173         self.customizeentityforclient = oldself.customizeentityforclient;
 174         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 175         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 176         if (keepvelocity == 1)
 177                 self.velocity = oldself.velocity;
 178         self.oldvelocity = self.velocity;
 179         self.fade_time = oldself.fade_time;
 180         self.fade_rate = oldself.fade_rate;
 181         //self.weapon = oldself.weapon;
 182         setorigin(self, oldself.origin);
 183         setsize(self, oldself.mins, oldself.maxs);
 184         self.prevorigin = oldself.origin;
 185         self.reset = SUB_Remove;
 186
 187         Drag_MoveDrag(oldself, self);
 188
 189         self = oldself;
 190 }
 191
 192 float player_getspecies()
 193 {
 194         float s;
 195         get_model_parameters(self.model, self.skinindex);
 196         s = get_model_parameters_species;
 197         get_model_parameters(string_null, 0);
 198         if(s < 0)
 199                 return SPECIES_HUMAN;
 200         return s;
 201 }
 202
 203 void player_setupanimsformodel()
 204 {
 205         // defaults for legacy .zym models without animinfo files
 206         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 207         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 208         self.anim_draw = animfixfps(self, '2 1 3');
 209         self.anim_duck = '3 1 100'; // FIXME ARRRRRGH this anim seems bogus in most models, so make it play VERY briefly!
 210         self.anim_duckwalk = animfixfps(self, '4 1 1');
 211         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 212         self.anim_duckidle = animfixfps(self, '6 1 1');
 213         self.anim_idle = animfixfps(self, '7 1 1');
 214         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 215         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 216         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 217         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 218         self.anim_taunt = animfixfps(self, '12 1 0.33');
 219         self.anim_run = animfixfps(self, '13 1 1');
 220         self.anim_runbackwards = animfixfps(self, '14 1 1');
 221         self.anim_strafeleft = animfixfps(self, '15 1 1');
 222         self.anim_straferight = animfixfps(self, '16 1 1');
 223         self.anim_dead1 = animfixfps(self, '17 1 1');
 224         self.anim_dead2 = animfixfps(self, '18 1 1');
 225         self.anim_forwardright = animfixfps(self, '19 1 1');
 226         self.anim_forwardleft = animfixfps(self, '20 1 1');
 227         self.anim_backright = animfixfps(self, '21 1 1');
 228         self.anim_backleft  = animfixfps(self, '22 1 1');
 229         self.anim_melee = animfixfps(self, '23 1 1');
 230         // TODO introspect models for finding right "fps" value (1/duration)
 231         // reset animstate now
 232         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 233 };
 234
 235 void player_anim (void)
 236 {
 237         updateanim(self);
 238         if (self.weaponentity)
 239                 updateanim(self.weaponentity);
 240
 241         if (self.deadflag != DEAD_NO)
 242         {
 243                 if (time > self.animstate_endtime)
 244                 {
 245                         if (self.maxs_z > 5)
 246                         {
 247                                 self.maxs_z = 5;
 248                                 setsize(self, self.mins, self.maxs);
 249                         }
 250                         self.frame = self.dead_frame;
 251                 }
 252                 return;
 253         }
 254
 255         if (!self.animstate_override)
 256         {
 257                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 258                 {
 259                         if (self.crouch)
 260                         {
 261                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 262                                 {
 263                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 264                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 265                                         {
 266                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 267                                                 self.restart_jump = FALSE;
 268                                         }
 269                                 }
 270                         }
 271                         else
 272                         {
 273                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 274                 {
 275                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 276                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 277                     {
 278                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 279                         self.restart_jump = FALSE;
 280                     }
 281                 }
 282                         }
 283                 }
 284                 else if (self.crouch)
 285                 {
 286                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 287                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 288                         else
 289                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 290                 }
 291                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 292                 {
 293                         if (self.movement_x > 0 && self.movement_y == 0)
 294                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x < 0 && self.movement_y == 0)
 296                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x == 0 && self.movement_y > 0)
 298                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x == 0 && self.movement_y < 0)
 300                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x > 0 && self.movement_y > 0)
 302                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 303                         else if (self.movement_x > 0 && self.movement_y < 0)
 304                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 305                         else if (self.movement_x < 0 && self.movement_y > 0)
 306                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x < 0 && self.movement_y < 0)
 308                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 309                         else
 310                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 311                 }
 312                 else
 313                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 314         }
 315
 316         if (self.weaponentity)
 317         if (!self.weaponentity.animstate_override)
 318                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 319 }
 320
 321 void SpawnThrownWeapon (vector org, float w)
 322 {
 323         if(g_minstagib)
 324         if(self.ammo_cells <= 0)
 325                 return;
 326
 327         if(g_pinata)
 328         {
 329                 float j;
 330                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 331                 {
 332                         if(self.weapons & W_WeaponBit(j))
 333                                 if(W_IsWeaponThrowable(j))
 334                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 335                 }
 336         }
 337         else
 338         {
 339                 if(W_IsWeaponThrowable(self.weapon))
 340                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 341         }
 342 }
 343
 344 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 345 {
 346         local float take, save;
 347         vector v;
 348         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 349
 350         // damage resistance (ignore most of the damage from a bullet or similar)
 351         damage = max(damage - 5, 1);
 352
 353         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 354         take = v_x;
 355         save = v_y;
 356
 357         if(sound_allowed(MSG_BROADCAST, attacker))
 358         {
 359                 if (save > 10)
 360                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 361                 else if (take > 30)
 362                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 363                 else if (take > 10)
 364                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 365         }
 366
 367         if (take > 50)
 368                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 369         if (take > 100)
 370                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 371
 372         if (!(self.flags & FL_GODMODE))
 373         {
 374                 self.armorvalue = self.armorvalue - save;
 375                 self.health = self.health - take;
 376                 // pause regeneration for 5 seconds
 377                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 378         }
 379         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 380         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 381         self.dmg_inflictor = inflictor;
 382
 383         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 384         {
 385                 // don't use any animations as a gib
 386                 self.frame = 0;
 387                 self.dead_frame = 0;
 388                 // view just above the floor
 389                 self.view_ofs = '0 0 4';
 390
 391                 Violence_GibSplash(self, 1, 1, attacker);
 392                 self.modelindex = 0; // restore later
 393                 self.solid = SOLID_NOT; // restore later
 394         }
 395 }
 396
 397 void ClientKill_Now_TeamChange();
 398 void freezetag_CheckWinner();
 399
 400 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 401 {
 402         local float take, save, waves, sdelay, dh, da, j;
 403         vector v;
 404         float valid_damage_for_weaponstats;
 405         float excess;
 406
 407         if((g_arena && numspawned < 2) || (g_ca && !ca_teams_ok) && !inWarmupStage)
 408                 return;
 409
 410         dh = max(self.health, 0);
 411         da = max(self.armorvalue, 0);
 412
 413         if(!DEATH_ISSPECIAL(deathtype))
 414         {
 415                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 416                 if(self != attacker)
 417                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 418         }
 419
 420         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 421         {
 422                 // tuba causes blood to come out of the ears
 423                 vector ear1, ear2;
 424                 vector d;
 425                 float f;
 426                 ear1 = self.origin;
 427                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 428                 ear2 = ear1;
 429                 makevectors(self.angles);
 430                 ear1 += v_right * -10;
 431                 ear2 += v_right * +10;
 432                 d = inflictor.origin - self.origin;
 433                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 434                 force = v_right * vlen(force);
 435                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 436                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 437                 if(f > 0)
 438                 {
 439                         hitloc = ear1;
 440                         force = force * -1;
 441                 }
 442                 else
 443                 {
 444                         hitloc = ear2;
 445                         // force is already good
 446                 }
 447         }
 448         else
 449                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 450
 451         if (!g_minstagib)
 452         {
 453                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 454                 take = v_x;
 455                 save = v_y;
 456         }
 457         else
 458         {
 459                 save = 0;
 460                 take = damage;
 461         }
 462
 463         frag_inflictor = inflictor;
 464         frag_attacker = attacker;
 465         frag_target = self;
 466         damage_take = take;
 467         damage_save = save;
 468         damage_force = force;
 469         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 470         take = bound(0, damage_take, self.health);
 471         save = bound(0, damage_save, self.armorvalue);
 472         excess = max(0, damage - take - save);
 473
 474         if(sound_allowed(MSG_BROADCAST, attacker))
 475         {
 476                 if (save > 10)
 477                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 478                 else if (take > 30)
 479                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 480                 else if (take > 10)
 481                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 482         }
 483
 484         if (take > 50)
 485                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 486         if (take > 100)
 487                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 488
 489         if (time >= self.spawnshieldtime)
 490         {
 491                 if (!(self.flags & FL_GODMODE))
 492                 {
 493                         self.armorvalue = self.armorvalue - save;
 494                         self.health = self.health - take;
 495                         // pause regeneration for 5 seconds
 496                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 497
 498                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 499                         {
 500                                 self.pain_finished = time + 0.5;        //Supajoe
 501
 502                                 if(sv_gentle < 1) {
 503                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 504                                         {
 505                                                 if (!self.animstate_override)
 506                                                 {
 507                                                         if (random() > 0.5)
 508                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 509                                                         else
 510                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 511                                                 }
 512                                         }
 513
 514                                         if(sound_allowed(MSG_BROADCAST, attacker))
 515                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 516                                         if(self.health > 1)
 517                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 518                                         {
 519                                                 if(deathtype == DEATH_FALL)
 520                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 521                                                 else if(self.health > 75) // TODO make a "gentle" version?
 522                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 523                                                 else if(self.health > 50)
 524                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 525                                                 else if(self.health > 25)
 526                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 527                                                 else
 528                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 529                                         }
 530                                 }
 531
 532                                 // throw off bot aim temporarily
 533                                 local float shake;
 534                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 535                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 536                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 537                         }
 538                 }
 539                 else
 540                         self.max_armorvalue += (save + take);
 541         }
 542         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 543         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 544         self.dmg_inflictor = inflictor;
 545
 546         if(attacker == self)
 547         {
 548                 // don't reset pushltime for self damage as it may be an attempt to
 549                 // escape a lava pit or similar
 550                 //self.pushltime = 0;
 551         }
 552         else if(attacker.classname == "player")
 553         {
 554                 self.pusher = attacker;
 555                 self.pushltime = time + autocvar_g_maxpushtime;
 556         }
 557         else if(time < self.pushltime)
 558         {
 559                 attacker = self.pusher;
 560                 self.pushltime = max(self.pushltime, time + 0.6);
 561         }
 562         else
 563                 self.pushltime = 0;
 564
 565         float abot, vbot, awep;
 566         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 567         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 568
 569         valid_damage_for_weaponstats = 0;
 570         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 571         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 572         if(attacker && self != attacker)
 573         if(IsDifferentTeam(self, attacker))
 574         {
 575                 if(DEATH_ISSPECIAL(deathtype))
 576                         awep = attacker.weapon;
 577                 else
 578                         awep = DEATH_WEAPONOF(deathtype);
 579                 valid_damage_for_weaponstats = 1;
 580         }
 581
 582         if(valid_damage_for_weaponstats)
 583         {
 584                 dh = dh - max(self.health, 0);
 585                 da = da - max(self.armorvalue, 0);
 586                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 587         }
 588
 589         if (self.health < 1)
 590         {
 591                 float defer_ClientKill_Now_TeamChange;
 592                 defer_ClientKill_Now_TeamChange = FALSE;
 593
 594                 if(self.alivetime)
 595                 {
 596                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 597                         self.alivetime = 0;
 598                 }
 599
 600                 if(valid_damage_for_weaponstats)
 601                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 602
 603                 if(sv_gentle < 1) // TODO make a "gentle" version?
 604                 if(sound_allowed(MSG_BROADCAST, attacker))
 605                 {
 606                         if(deathtype == DEATH_DROWN)
 607                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 608                         else
 609                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 610                 }
 611
 612                 // get rid of kill indicator
 613                 if(self.killindicator)
 614                 {
 615                         remove(self.killindicator);
 616                         self.killindicator = world;
 617                         if(self.killindicator_teamchange)
 618                                 defer_ClientKill_Now_TeamChange = TRUE;
 619
 620                         if(self.classname == "body")
 621                         if(deathtype == DEATH_KILL)
 622                         {
 623                                 // for the lemmings fans, a small harmless explosion
 624                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 625                         }
 626                 }
 627
 628                 if(!g_freezetag)
 629                 {
 630                         // become fully visible
 631                         self.alpha = 1;
 632                         // throw a weapon
 633                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 634                 }
 635
 636                 // print an obituary message
 637                 Obituary (attacker, inflictor, self, deathtype);
 638                 race_PreDie();
 639                 DropAllRunes(self);
 640
 641         // increment frag counter for used weapon type
 642         float w;
 643         w = DEATH_WEAPONOF(deathtype);
 644         if(WEP_VALID(w))
 645         if(self.classname == "player")
 646         if(self != attacker)
 647         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 648
 649                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 650                 {
 651                         PutClientInServer();
 652                         count_alive_players(); // re-count players
 653                         freezetag_CheckWinner();
 654                         return;
 655                 }
 656
 657                 frag_attacker = attacker;
 658                 frag_inflictor = inflictor;
 659                 frag_target = self;
 660                 MUTATOR_CALLHOOK(PlayerDies);
 661                 weapon_action(self.weapon, WR_PLAYERDEATH);
 662
 663                 if(self.flagcarried)
 664                 {
 665                         if(attacker.classname != "player")
 666                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 667                         else if(attacker.team == self.team)
 668                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 669                         else
 670                                 DropFlag(self.flagcarried, world, attacker);
 671                 }
 672                 if(self.ballcarried && g_nexball)
 673                         DropBall(self.ballcarried, self.origin, self.velocity);
 674                 Portal_ClearAllLater(self);
 675
 676                 if(clienttype(self) == CLIENTTYPE_REAL)
 677                 {
 678                         stuffcmd(self, "-zoom\n");
 679                         self.fixangle = TRUE;
 680                         //msg_entity = self;
 681                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 682                         //WriteAngle (MSG_ONE, self.v_angle_x);
 683                         //WriteAngle (MSG_ONE, self.v_angle_y);
 684                         //WriteAngle (MSG_ONE, 80);
 685                 }
 686
 687                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 688                         ClientKill_Now_TeamChange();
 689
 690                 if(g_arena)
 691                         Spawnqueue_Unmark(self);
 692
 693                 if(g_freezetag)
 694                         return;
 695
 696                 // when we get here, player actually dies
 697                 // clear waypoints (do this AFTER FreezeTag)
 698                 WaypointSprite_PlayerDead();
 699
 700                 // make the corpse upright (not tilted)
 701                 self.angles_x = 0;
 702                 self.angles_z = 0;
 703                 // don't spin
 704                 self.avelocity = '0 0 0';
 705                 // view from the floor
 706                 self.view_ofs = '0 0 -8';
 707                 // toss the corpse
 708                 self.movetype = MOVETYPE_TOSS;
 709                 // shootable corpse
 710                 self.solid = SOLID_CORPSE;
 711                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 712                 // don't stick to the floor
 713                 self.flags &~= FL_ONGROUND;
 714                 // dying animation
 715                 self.deadflag = DEAD_DYING;
 716                 // when to allow respawn
 717                 sdelay = 0;
 718                 waves = 0;
 719                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 720                 if(!sdelay)
 721                 {
 722                         if(g_cts)
 723                                 sdelay = 0; // no respawn delay in CTS
 724                         else
 725                                 sdelay = autocvar_g_respawn_delay;
 726                 }
 727                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 728                 if(!waves)
 729                         waves = autocvar_g_respawn_waves;
 730                 if(waves)
 731                         self.death_time = ceil((time + sdelay) / waves) * waves;
 732                 else
 733                         self.death_time = time + sdelay;
 734                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 735                         self.respawn_countdown = 10; // first number to count down from is 10
 736                 else
 737                         self.respawn_countdown = -1; // do not count down
 738                 if (random() < 0.5)
 739                 {
 740                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 741                         self.dead_frame = self.anim_dead1_x;
 742                 }
 743                 else
 744                 {
 745                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 746                         self.dead_frame = self.anim_dead2_x;
 747                 }
 748                 // set damage function to corpse damage
 749                 self.event_damage = PlayerCorpseDamage;
 750                 // call the corpse damage function just in case it wants to gib
 751                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 752                 // set up to fade out later
 753                 SUB_SetFade (self, time + 6 + random (), 1);
 754
 755                 if(sv_gentle > 0 || autocvar_ekg) {
 756                         // remove corpse
 757                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 758                 }
 759
 760                 // reset fields the weapons may use just in case
 761                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 762                 {
 763                         weapon_action(j, WR_RESETPLAYER);
 764                         ATTACK_FINISHED_FOR(self, j) = 0;
 765                 }
 766         }
 767 }
 768
 769 .float muted; // to be used by prvm_edictset server playernumber muted 1
 770 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 771 // message "": do not say, just test flood control
 772 // return value:
 773 //   1 = accept
 774 //   0 = reject
 775 //  -1 = fake accept
 776 {
 777         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 778         float flood, privatemsgprefixlen;
 779         var .float flood_field;
 780         entity head;
 781         float ret;
 782
 783         if(Ban_MaybeEnforceBan(source))
 784                 return 0;
 785
 786         if(!teamsay && !privatesay)
 787                 if(substring(msgin, 0, 1) == " ")
 788                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 789
 790         msgin = formatmessage(msgin);
 791
 792         if(source.classname != "player")
 793                 colorstr = "^0"; // black for spectators
 794         else if(teamplay)
 795                 colorstr = Team_ColorCode(source.team);
 796         else
 797                 teamsay = FALSE;
 798
 799         if(intermission_running)
 800                 teamsay = FALSE;
 801
 802         if(msgin != "")
 803                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 804
 805         /*
 806          * using bprint solves this... me stupid
 807         // how can we prevent the message from appearing in a listen server?
 808         // for now, just give "say" back and only handle say_team
 809         if(!teamsay)
 810         {
 811                 clientcommand(self, strcat("say ", msgin));
 812                 return;
 813         }
 814         */
 815
 816         if(autocvar_g_chat_teamcolors)
 817                 namestr = playername(source);
 818         else
 819                 namestr = source.netname;
 820
 821         if(msgin != "")
 822         {
 823                 if(privatesay)
 824                 {
 825                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 826                         privatemsgprefixlen = strlen(msgstr);
 827                         msgstr = strcat(msgstr, msgin);
 828                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 829                         if(autocvar_g_chat_teamcolors)
 830                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 831                         else
 832                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 833                 }
 834                 else if(teamsay)
 835                 {
 836                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 837                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 838                 }
 839                 else
 840                 {
 841                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 842                         cmsgstr = "";
 843                 }
 844                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 845         }
 846         else
 847         {
 848                 msgstr = cmsgstr = "";
 849         }
 850
 851         fullmsgstr = msgstr;
 852         fullcmsgstr = cmsgstr;
 853
 854         // FLOOD CONTROL
 855         flood = 0;
 856         if(floodcontrol)
 857         {
 858                 float flood_spl;
 859                 float flood_burst;
 860                 float flood_lmax;
 861                 float lines;
 862                 if(privatesay)
 863                 {
 864                         flood_spl = autocvar_g_chat_flood_spl_tell;
 865                         flood_burst = autocvar_g_chat_flood_burst_tell;
 866                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 867                         flood_field = floodcontrol_chattell;
 868                 }
 869                 else if(teamsay)
 870                 {
 871                         flood_spl = autocvar_g_chat_flood_spl_team;
 872                         flood_burst = autocvar_g_chat_flood_burst_team;
 873                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 874                         flood_field = floodcontrol_chatteam;
 875                 }
 876                 else
 877                 {
 878                         flood_spl = autocvar_g_chat_flood_spl;
 879                         flood_burst = autocvar_g_chat_flood_burst;
 880                         flood_lmax = autocvar_g_chat_flood_lmax;
 881                         flood_field = floodcontrol_chat;
 882                 }
 883                 flood_burst = max(0, flood_burst - 1);
 884                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 885
 886                 // do flood control for the default line size
 887                 if(msgstr != "")
 888                 {
 889                         getWrappedLine_remaining = msgstr;
 890                         msgstr = "";
 891                         lines = 0;
 892                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 893                         {
 894                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 895                                 ++lines;
 896                         }
 897                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 898
 899                         if(getWrappedLine_remaining != "")
 900                         {
 901                                 msgstr = strcat(msgstr, "\n");
 902                                 flood = 2;
 903                         }
 904
 905                         if(time >= source.flood_field)
 906                         {
 907                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 908                         }
 909                         else
 910                         {
 911                                 flood = 1;
 912                                 msgstr = fullmsgstr;
 913                         }
 914                 }
 915                 else
 916                 {
 917                         if(time >= source.flood_field)
 918                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 919                         else
 920                                 flood = 1;
 921                 }
 922
 923                 if (timeoutStatus == 2) //when game is paused, no flood protection
 924                         source.flood_field = flood = 0;
 925         }
 926
 927         if(flood == 2) // cannot happen for empty msgstr
 928         {
 929                 if(autocvar_g_chat_flood_notify_flooder)
 930                 {
 931                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 932                         sourcecmsgstr = "";
 933                 }
 934                 else
 935                 {
 936                         sourcemsgstr = fullmsgstr;
 937                         sourcecmsgstr = fullcmsgstr;
 938                 }
 939                 cmsgstr = "";
 940         }
 941         else
 942         {
 943                 sourcemsgstr = msgstr;
 944                 sourcecmsgstr = cmsgstr;
 945         }
 946
 947         if(!privatesay)
 948         if(source.classname != "player")
 949         {
 950                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 951                         teamsay = -1; // spectators
 952         }
 953
 954         if(flood)
 955                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 956
 957         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 958         if(privatesay)
 959                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 960
 961         if(source.muted)
 962         {
 963                 // always fake the message
 964                 ret = -1;
 965         }
 966         else if(flood == 1)
 967         {
 968                 if(autocvar_g_chat_flood_notify_flooder)
 969                 {
 970                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 971                         ret = 0;
 972                 }
 973                 else
 974                         ret = -1;
 975         }
 976         else
 977         {
 978                 ret = 1;
 979         }
 980
 981         if(sourcemsgstr != "" && ret != 0)
 982         {
 983                 if(ret < 0) // fake
 984                 {
 985                         sprint(source, sourcemsgstr);
 986                         if(sourcecmsgstr != "" && !privatesay)
 987                                 centerprint(source, sourcecmsgstr);
 988                 }
 989                 else if(privatesay)
 990                 {
 991                         sprint(source, sourcemsgstr);
 992                         sprint(privatesay, msgstr);
 993                         if(cmsgstr != "")
 994                                 centerprint(privatesay, cmsgstr);
 995                 }
 996                 else if(teamsay > 0)
 997                 {
 998                         sprint(source, sourcemsgstr);
 999                         if(sourcecmsgstr != "")
1000                                 centerprint(source, sourcecmsgstr);
1001                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1002                                 if(head != source)
1003                                 {
1004                                         sprint(head, msgstr);
1005                                         if(cmsgstr != "")
1006                                                 centerprint(head, cmsgstr);
1007                                 }
1008                 }
1009                 else if(teamsay < 0)
1010                 {
1011                         sprint(source, sourcemsgstr);
1012                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1013                                 if(head != source)
1014                                         sprint(head, msgstr);
1015                 }
1016                 else if(sourcemsgstr != msgstr)
1017                 {
1018                         sprint(source, sourcemsgstr);
1019                         FOR_EACH_REALCLIENT(head)
1020                                 if(head != source)
1021                                         sprint(head, msgstr);
1022                 }
1023                 else
1024                         bprint(msgstr);
1025         }
1026
1027         return ret;
1028 }
1029
1030 float GetVoiceMessageVoiceType(string type)
1031 {
1032         if(type == "taunt")
1033                 return VOICETYPE_TAUNT;
1034         if(type == "teamshoot")
1035                 return VOICETYPE_LASTATTACKER;
1036         return VOICETYPE_TEAMRADIO;
1037 }
1038
1039 string allvoicesamples;
1040 .string GetVoiceMessageSampleField(string type)
1041 {
1042         GetPlayerSoundSampleField_notFound = 0;
1043         switch(type)
1044         {
1045 #define _VOICEMSG(m) case #m: return playersound_##m;
1046                 ALLVOICEMSGS
1047 #undef _VOICEMSG
1048         }
1049         GetPlayerSoundSampleField_notFound = 1;
1050         return playersound_taunt;
1051 }
1052
1053 .string GetPlayerSoundSampleField(string type)
1054 {
1055         GetPlayerSoundSampleField_notFound = 0;
1056         switch(type)
1057         {
1058 #define _VOICEMSG(m) case #m: return playersound_##m;
1059                 ALLPLAYERSOUNDS
1060 #undef _VOICEMSG
1061         }
1062         GetPlayerSoundSampleField_notFound = 1;
1063         return playersound_taunt;
1064 }
1065
1066 void PrecacheGlobalSound(string samplestring)
1067 {
1068         float n, i;
1069         tokenize_console(samplestring);
1070         n = stof(argv(1));
1071         if(n > 0)
1072         {
1073                 for(i = 1; i <= n; ++i)
1074                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1075         }
1076         else
1077         {
1078                 precache_sound(strcat(argv(0), ".wav"));
1079         }
1080 }
1081
1082 void PrecachePlayerSounds(string f)
1083 {
1084         float fh;
1085         string s;
1086         fh = fopen(f, FILE_READ);
1087         if(fh < 0)
1088                 return;
1089         while((s = fgets(fh)))
1090         {
1091                 if(tokenize_console(s) != 3)
1092                 {
1093                         dprint("Invalid sound info line: ", s, "\n");
1094                         continue;
1095                 }
1096                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1097         }
1098         fclose(fh);
1099
1100         if not(allvoicesamples)
1101         {
1102 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1103                 ALLVOICEMSGS
1104 #undef _VOICEMSG
1105                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1106         }
1107 }
1108
1109 void ClearPlayerSounds()
1110 {
1111 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1112         ALLPLAYERSOUNDS
1113         ALLVOICEMSGS
1114 #undef _VOICEMSG
1115 }
1116
1117 float LoadPlayerSounds(string f, float first)
1118 {
1119         float fh;
1120         string s;
1121         var .string field;
1122         fh = fopen(f, FILE_READ);
1123         if(fh < 0)
1124         {
1125                 dprint("Player sound file not found: ", f, "\n");
1126                 return 0;
1127         }
1128         while((s = fgets(fh)))
1129         {
1130                 if(tokenize_console(s) != 3)
1131                         continue;
1132                 field = GetPlayerSoundSampleField(argv(0));
1133                 if(GetPlayerSoundSampleField_notFound)
1134                         field = GetVoiceMessageSampleField(argv(0));
1135                 if(GetPlayerSoundSampleField_notFound)
1136                         continue;
1137                 if(self.field)
1138                         strunzone(self.field);
1139                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1140         }
1141         fclose(fh);
1142         return 1;
1143 }
1144
1145 .float modelindex_for_playersound;
1146 .float skinindex_for_playersound;
1147 void UpdatePlayerSounds()
1148 {
1149         if(self.modelindex == self.modelindex_for_playersound)
1150         if(self.skinindex == self.skinindex_for_playersound)
1151                 return;
1152         self.modelindex_for_playersound = self.modelindex;
1153         self.skinindex_for_playersound = self.skinindex;
1154         ClearPlayerSounds();
1155         LoadPlayerSounds("sound/player/default.sounds", 1);
1156         if(!autocvar_g_debug_defaultsounds)
1157                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1158                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1159 }
1160
1161 void FakeGlobalSound(string sample, float chan, float voicetype)
1162 {
1163         float n;
1164         float tauntrand;
1165
1166         if(sample == "")
1167                 return;
1168
1169         tokenize_console(sample);
1170         n = stof(argv(1));
1171         if(n > 0)
1172                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1173         else
1174                 sample = strcat(argv(0), ".wav"); // randomization
1175
1176         switch(voicetype)
1177         {
1178                 case VOICETYPE_LASTATTACKER_ONLY:
1179                         break;
1180                 case VOICETYPE_LASTATTACKER:
1181                         if(self.pusher)
1182                         {
1183                                 msg_entity = self;
1184                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1185                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1186                         }
1187                         break;
1188                 case VOICETYPE_TEAMRADIO:
1189                         msg_entity = self;
1190                         if(msg_entity.cvar_cl_voice_directional == 1)
1191                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1192                         else
1193                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1194                         break;
1195                 case VOICETYPE_AUTOTAUNT:
1196                         if(!sv_autotaunt)
1197                                 break;
1198                         if(!sv_taunt)
1199                                 break;
1200                         if(sv_gentle)
1201                                 break;
1202                         tauntrand = random();
1203                         msg_entity = self;
1204                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1205                         {
1206                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1207                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1208                                 else
1209                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1210                         }
1211                         break;
1212                 case VOICETYPE_TAUNT:
1213                         if(self.classname == "player")
1214                                 if(self.deadflag == DEAD_NO)
1215                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1216                         if(!sv_taunt)
1217                                 break;
1218                         if(sv_gentle)
1219                                 break;
1220                         msg_entity = self;
1221                         if (msg_entity.cvar_cl_voice_directional >= 1)
1222                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1223                         else
1224                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1225                         break;
1226                 case VOICETYPE_PLAYERSOUND:
1227                         msg_entity = self;
1228                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1229                         break;
1230                 default:
1231                         backtrace("Invalid voice type!");
1232                         break;
1233         }
1234 }
1235
1236 void GlobalSound(string sample, float chan, float voicetype)
1237 {
1238         float n;
1239         float tauntrand;
1240
1241         if(sample == "")
1242                 return;
1243
1244         tokenize_console(sample);
1245         n = stof(argv(1));
1246         if(n > 0)
1247                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1248         else
1249                 sample = strcat(argv(0), ".wav"); // randomization
1250
1251         switch(voicetype)
1252         {
1253                 case VOICETYPE_LASTATTACKER_ONLY:
1254                         if(self.pusher)
1255                         {
1256                                 msg_entity = self.pusher;
1257                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1258                                 {
1259                                         if(msg_entity.cvar_cl_voice_directional == 1)
1260                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1261                                         else
1262                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1263                                 }
1264                         }
1265                         break;
1266                 case VOICETYPE_LASTATTACKER:
1267                         if(self.pusher)
1268                         {
1269                                 msg_entity = self.pusher;
1270                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1271                                 {
1272                                         if(msg_entity.cvar_cl_voice_directional == 1)
1273                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1274                                         else
1275                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1276                                 }
1277                                 msg_entity = self;
1278                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1279                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1280                         }
1281                         break;
1282                 case VOICETYPE_TEAMRADIO:
1283                         FOR_EACH_REALCLIENT(msg_entity)
1284                                 if(!teamplay || msg_entity.team == self.team)
1285                                 {
1286                                         if(msg_entity.cvar_cl_voice_directional == 1)
1287                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1288                                         else
1289                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1290                                 }
1291                         break;
1292                 case VOICETYPE_AUTOTAUNT:
1293                         if(!sv_autotaunt)
1294                                 break;
1295                         if(!sv_taunt)
1296                                 break;
1297                         if(sv_gentle)
1298                                 break;
1299                         tauntrand = random();
1300                         FOR_EACH_REALCLIENT(msg_entity)
1301                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1302                                 {
1303                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1304                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1305                                         else
1306                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1307                                 }
1308                         break;
1309                 case VOICETYPE_TAUNT:
1310                         if(self.classname == "player")
1311                                 if(self.deadflag == DEAD_NO)
1312                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1313                         if(!sv_taunt)
1314                                 break;
1315                         if(sv_gentle)
1316                                 break;
1317                         FOR_EACH_REALCLIENT(msg_entity)
1318                         {
1319                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1320                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1321                                 else
1322                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1323                         }
1324                         break;
1325                 case VOICETYPE_PLAYERSOUND:
1326                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1327                         break;
1328                 default:
1329                         backtrace("Invalid voice type!");
1330                         break;
1331         }
1332 }
1333
1334 void PlayerSound(.string samplefield, float chan, float voicetype)
1335 {
1336         GlobalSound(self.samplefield, chan, voicetype);
1337 }
1338
1339 void VoiceMessage(string type, string msg)
1340 {
1341         var .string sample;
1342         float voicetype, ownteam;
1343         float flood;
1344         sample = GetVoiceMessageSampleField(type);
1345
1346         if(GetPlayerSoundSampleField_notFound)
1347         {
1348                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1349                 return;
1350         }
1351
1352         voicetype = GetVoiceMessageVoiceType(type);
1353         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1354
1355         flood = Say(self, ownteam, world, msg, 1);
1356
1357         if (flood > 0)
1358                 GlobalSound(self.sample, CH_VOICE, voicetype);
1359         else if (flood < 0)
1360                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1361 }
1362
1363 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1364 {
1365 //      show_message
1366 //      0 (00) automove centerprint, admin message
1367 //      1 (01) automove centerprint, no admin message
1368 //      2 (10) no centerprint, admin message
1369 //      3 (11) no centerprint, no admin message
1370
1371         float lockteams_backup;
1372
1373         lockteams_backup = lockteams;  // backup any team lock
1374
1375         lockteams = 0;  // disable locked teams
1376
1377         TeamchangeFrags(client);  // move the players frags
1378         SetPlayerColors(client, team_colour - 1);  // set the players colour
1379         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1380
1381         lockteams = lockteams_backup;  // restore the team lock
1382
1383         LogTeamchange(client.playerid, client.team, type);
1384
1385         if not(show_message & 1) // admin message
1386                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1387
1388         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1389 }