qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.playermodel, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389
 390 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 391 {
 392         local float take, save, waves, sdelay, dh, da, j;
 393         vector v;
 394         float valid_damage_for_weaponstats;
 395
 396         dh = max(self.health, 0);
 397         da = max(self.armorvalue, 0);
 398
 399         if(!DEATH_ISSPECIAL(deathtype))
 400         {
 401                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 402                 if(self != attacker)
 403                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 404         }
 405
 406         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 407         {
 408                 // tuba causes blood to come out of the ears
 409                 vector ear1, ear2;
 410                 vector d;
 411                 float f;
 412                 ear1 = self.origin;
 413                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 414                 ear2 = ear1;
 415                 makevectors(self.angles);
 416                 ear1 += v_right * -10;
 417                 ear2 += v_right * +10;
 418                 d = inflictor.origin - self.origin;
 419                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 420                 force = v_right * vlen(force);
 421                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 422                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 423                 if(f > 0)
 424                 {
 425                         hitloc = ear1;
 426                         force = force * -1;
 427                 }
 428                 else
 429                 {
 430                         hitloc = ear2;
 431                         // force is already good
 432                 }
 433         }
 434         else
 435                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 436
 437         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 438                 return;
 439
 440         if (!g_minstagib)
 441         {
 442                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 443                 take = v_x;
 444                 save = v_y;
 445         }
 446         else
 447         {
 448                 save = 0;
 449                 take = damage;
 450         }
 451
 452         if(sound_allowed(MSG_BROADCAST, attacker))
 453         {
 454                 if (save > 10)
 455                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 456                 else if (take > 30)
 457                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 458                 else if (take > 10)
 459                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 460         }
 461
 462         if (take > 50)
 463                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 464         if (take > 100)
 465                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 466
 467         if (time >= self.spawnshieldtime)
 468         {
 469                 if (!(self.flags & FL_GODMODE))
 470                 {
 471                         self.armorvalue = self.armorvalue - save;
 472                         self.health = self.health - take;
 473                         // pause regeneration for 5 seconds
 474                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 475
 476                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 477                         {
 478                                 self.pain_finished = time + 0.5;        //Supajoe
 479
 480                                 if(sv_gentle < 1) {
 481                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 482                                         {
 483                                                 if (random() > 0.5)
 484                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 485                                                 else
 486                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 487                                         }
 488
 489                                         if(sound_allowed(MSG_BROADCAST, attacker))
 490                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 491                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 492                                         {
 493                                                 if(self.health > 75) // TODO make a "gentle" version?
 494                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 495                                                 else if(self.health > 50)
 496                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 497                                                 else if(self.health > 25)
 498                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 499                                                 else if(self.health > 1)
 500                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 501                                         }
 502                                 }
 503
 504                                 // throw off bot aim temporarily
 505                                 local float shake;
 506                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 507                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 508                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 509                         }
 510                 }
 511                 else
 512                         self.max_armorvalue += (save + take);
 513         }
 514         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 515         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 516         self.dmg_inflictor = inflictor;
 517
 518         if(attacker == self)
 519         {
 520                 // don't reset pushltime for self damage as it may be an attempt to
 521                 // escape a lava pit or similar
 522                 //self.pushltime = 0;
 523         }
 524         else if(attacker.classname == "player" || attacker.classname == "gib")
 525         {
 526                 self.pusher = attacker;
 527                 self.pushltime = time + cvar("g_maxpushtime");
 528         }
 529         else if(time < self.pushltime)
 530         {
 531                 attacker = self.pusher;
 532                 self.pushltime = max(self.pushltime, time + 0.6);
 533         }
 534         else
 535                 self.pushltime = 0;
 536
 537         valid_damage_for_weaponstats = 0;
 538         if(clienttype(self) == CLIENTTYPE_REAL)
 539         if(clienttype(attacker) == CLIENTTYPE_REAL)
 540         if(self != attacker)
 541         if(!DEATH_ISSPECIAL(deathtype))
 542         if(IsDifferentTeam(self, attacker))
 543                 valid_damage_for_weaponstats = 1;
 544
 545         if(valid_damage_for_weaponstats)
 546         {
 547                 dh = dh - max(self.health, 0);
 548                 da = da - max(self.armorvalue, 0);
 549                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 550         }
 551
 552         if (self.health < 1)
 553         {
 554                 float defer_ClientKill_Now_TeamChange;
 555                 defer_ClientKill_Now_TeamChange = FALSE;
 556
 557                 if(valid_damage_for_weaponstats)
 558                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 559
 560                 if(sv_gentle < 1) // TODO make a "gentle" version?
 561                 if(sound_allowed(MSG_BROADCAST, attacker))
 562                 {
 563                         if(deathtype == DEATH_DROWN)
 564                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 565                         else
 566                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 567                 }
 568
 569                 // get rid of kill indicator
 570                 if(self.killindicator)
 571                 {
 572                         remove(self.killindicator);
 573                         self.killindicator = world;
 574                         if(self.killindicator_teamchange)
 575                                 defer_ClientKill_Now_TeamChange = TRUE;
 576
 577                         if(self.classname == "body")
 578                         if(deathtype == DEATH_KILL)
 579                         {
 580                                 // for the lemmings fans, a small harmless explosion
 581                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 582                         }
 583                 }
 584
 585                 // become fully visible
 586                 self.alpha = 1;
 587                 // clear selected player display
 588                 ClearSelectedPlayer();
 589                 // throw a weapon
 590                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 591                 // print an obituary message
 592                 Obituary (attacker, inflictor, self, deathtype);
 593                 race_PreDie();
 594                 DropAllRunes(self);
 595
 596                 frag_attacker = attacker;
 597                 frag_inflictor = inflictor;
 598                 frag_target = self;
 599                 MUTATOR_CALLHOOK(PlayerDies);
 600
 601                 if(self.flagcarried)
 602                 {
 603                         if(attacker.classname != "player" && attacker.classname != "gib")
 604                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 605                         else if(attacker.team == self.team)
 606                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 607                         else
 608                                 DropFlag(self.flagcarried, world, attacker);
 609                 }
 610                 if(self.ballcarried)
 611                         DropBall(self.ballcarried, self.origin, self.velocity);
 612                 Portal_ClearAllLater(self);
 613                 // clear waypoints
 614                 WaypointSprite_PlayerDead();
 615                 // make the corpse upright (not tilted)
 616                 self.angles_x = 0;
 617                 self.angles_z = 0;
 618                 // don't spin
 619                 self.avelocity = '0 0 0';
 620                 // view from the floor
 621                 self.view_ofs = '0 0 -8';
 622                 // toss the corpse
 623                 self.movetype = MOVETYPE_TOSS;
 624                 // shootable corpse
 625                 self.solid = SOLID_CORPSE;
 626                 self.ballistics_density = cvar("g_ballistics_density_corpse");
 627                 // don't stick to the floor
 628                 self.flags &~= FL_ONGROUND;
 629                 // dying animation
 630                 self.deadflag = DEAD_DYING;
 631                 // when to allow respawn
 632                 sdelay = 0;
 633                 waves = 0;
 634                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 635                 if(!sdelay)
 636                         sdelay = cvar("g_respawn_delay");
 637                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 638                 if(!waves)
 639                         waves = cvar("g_respawn_waves");
 640                 if(waves)
 641                         self.death_time = ceil((time + sdelay) / waves) * waves;
 642                 else
 643                         self.death_time = time + sdelay;
 644                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 645                         self.respawn_countdown = 10; // first number to count down from is 10
 646                 else
 647                         self.respawn_countdown = -1; // do not count down
 648                 if (random() < 0.5)
 649                 {
 650                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 651                         self.dead_frame = self.anim_dead1_x;
 652                 }
 653                 else
 654                 {
 655                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 656                         self.dead_frame = self.anim_dead2_x;
 657                 }
 658                 // set damage function to corpse damage
 659                 self.event_damage = PlayerCorpseDamage;
 660                 // call the corpse damage function just in case it wants to gib
 661                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 662                 // set up to fade out later
 663                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 664
 665                 // remove laserdot
 666                 if(self.weaponentity)
 667                         if(self.weaponentity.lasertarget)
 668                                 remove(self.weaponentity.lasertarget);
 669
 670                 if(clienttype(self) == CLIENTTYPE_REAL)
 671                 {
 672                         self.fixangle = TRUE;
 673                         //msg_entity = self;
 674                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 675                         //WriteAngle (MSG_ONE, self.v_angle_x);
 676                         //WriteAngle (MSG_ONE, self.v_angle_y);
 677                         //WriteAngle (MSG_ONE, 80);
 678                 }
 679
 680                 if(g_arena)
 681                         Spawnqueue_Unmark(self);
 682
 683                 if(defer_ClientKill_Now_TeamChange)
 684                         ClientKill_Now_TeamChange();
 685
 686                 if(sv_gentle > 0 || cvar("ekg")) {
 687                         // remove corpse
 688                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 689                 }
 690
 691                 // reset fields the weapons may use just in case
 692         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 693                 {
 694             weapon_action(j, WR_RESETPLAYER);
 695                         ATTACK_FINISHED_FOR(self, j) = 0;
 696                 }
 697         }
 698 }
 699
 700 float UpdateSelectedPlayer_countvalue(float v)
 701 {
 702         return max(0, (v - 1.0) / 0.5);
 703 }
 704
 705 // returns: -2 if no hit, otherwise cos of the angle
 706 // uses the global v_angle
 707 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 708 {
 709         vector so, d;
 710         float c;
 711
 712         if(p == self)
 713                 return -2;
 714
 715         if(p.deadflag)
 716                 return -2;
 717
 718         so = self.origin + self.view_ofs;
 719         d = p.origin - so;
 720
 721         // misaimed?
 722         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 723                 return -2;
 724
 725         // now find the cos of the angle...
 726         c = normalize(d) * v_forward;
 727
 728         if(c <= mincosangle)
 729                 return -2;
 730
 731         // not visible in any way? forget it
 732         if(!checkpvs(so, p))
 733                 return -2;
 734
 735         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 736         if(trace_fraction < 1)
 737                 return -2;
 738
 739         return c;
 740 }
 741
 742 void ClearSelectedPlayer()
 743 {
 744         if(self.selected_player)
 745         {
 746                 centerprint_expire(self, CENTERPRIO_POINT);
 747                 self.selected_player = world;
 748                 self.selected_player_display_needs_update = FALSE;
 749         }
 750 }
 751
 752 void UpdateSelectedPlayer()
 753 {
 754         entity selected;
 755         float selected_score;
 756         selected = world;
 757         selected_score = 0.95; // 18 degrees
 758
 759         if(!cvar("sv_allow_shownames"))
 760                 return;
 761
 762         if(clienttype(self) != CLIENTTYPE_REAL)
 763                 return;
 764
 765         if(self.cvar_cl_shownames == 0)
 766                 return;
 767
 768         if(self.cvar_cl_shownames == 1 && !teams_matter)
 769                 return;
 770
 771         makevectors(self.v_angle); // sets v_forward
 772
 773         // 1. cursor trace is always right
 774         WarpZone_crosshair_trace(self);
 775         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 776         {
 777                 selected = trace_ent;
 778         }
 779         else
 780         {
 781                 // 2. if we don't have a cursor trace, find the player which is least
 782                 //    mis-aimed at
 783                 entity p;
 784                 FOR_EACH_PLAYER(p)
 785                 {
 786                         float c;
 787                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 788                         if(c >= -1)
 789                         {
 790                                 selected = p;
 791                                 selected_score = c;
 792                         }
 793                 }
 794         }
 795
 796         if(selected)
 797         {
 798                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 799         }
 800         else
 801         {
 802                 if(time < self.selected_player_display_timeout)
 803                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 804                                 selected = self.selected_player;
 805         }
 806
 807         if(selected)
 808         {
 809                 if(selected == self.selected_player)
 810                 {
 811                         float save;
 812                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 813                         self.selected_player_count = self.selected_player_count + frametime;
 814                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 815                         {
 816                                 string namestr, healthstr;
 817                                 namestr = playername(selected);
 818                                 if(teams_matter)
 819                                 {
 820                                         healthstr = ftos(floor(selected.health));
 821                                         if(self.team == selected.team)
 822                                         {
 823                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 824                                                 self.selected_player_display_needs_update = TRUE;
 825                                         }
 826                                 }
 827                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 828                         }
 829                 }
 830                 else
 831                 {
 832                         ClearSelectedPlayer();
 833                         self.selected_player = selected;
 834                         self.selected_player_time = time;
 835                         self.selected_player_count = 0;
 836                         self.selected_player_display_needs_update = FALSE;
 837                 }
 838         }
 839         else
 840         {
 841                 ClearSelectedPlayer();
 842         }
 843
 844         if(self.selected_player)
 845                 self.last_selected_player = self.selected_player;
 846 }
 847
 848 .float muted; // to be used by prvm_edictset server playernumber muted 1
 849 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 850 // message "": do not say, just test flood control
 851 // return value:
 852 //   1 = accept
 853 //   0 = reject
 854 //  -1 = fake accept
 855 {
 856         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 857         float flood, privatemsgprefixlen;
 858         entity head;
 859         float ret;
 860
 861         if(Ban_MaybeEnforceBan(source))
 862                 return 0;
 863
 864         if(!teamsay && !privatesay)
 865                 if(substring(msgin, 0, 1) == " ")
 866                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 867
 868         msgin = formatmessage(msgin);
 869
 870         if(source.classname != "player")
 871                 colorstr = "^0"; // black for spectators
 872         else if(teams_matter)
 873                 colorstr = Team_ColorCode(source.team);
 874         else
 875                 teamsay = FALSE;
 876
 877         if(intermission_running)
 878                 teamsay = FALSE;
 879
 880         if(msgin != "")
 881                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 882
 883         /*
 884          * using bprint solves this... me stupid
 885         // how can we prevent the message from appearing in a listen server?
 886         // for now, just give "say" back and only handle say_team
 887         if(!teamsay)
 888         {
 889                 clientcommand(self, strcat("say ", msgin));
 890                 return;
 891         }
 892         */
 893
 894         if(cvar("g_chat_teamcolors"))
 895                 namestr = playername(source);
 896         else
 897                 namestr = source.netname;
 898
 899         if(msgin != "")
 900         {
 901                 if(privatesay)
 902                 {
 903                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 904                         privatemsgprefixlen = strlen(msgstr);
 905                         msgstr = strcat(msgstr, msgin);
 906                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 907                         if(cvar("g_chat_teamcolors"))
 908                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 909                         else
 910                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 911                 }
 912                 else if(teamsay)
 913                 {
 914                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 915                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 916                 }
 917                 else
 918                 {
 919                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 920                         cmsgstr = "";
 921                 }
 922                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 923         }
 924         else
 925         {
 926                 msgstr = cmsgstr = "";
 927         }
 928
 929         fullmsgstr = msgstr;
 930         fullcmsgstr = cmsgstr;
 931
 932         // FLOOD CONTROL
 933         flood = 0;
 934         if(floodcontrol)
 935         {
 936                 float flood_spl;
 937                 float flood_burst;
 938                 float flood_lmax;
 939                 var .float flood_field;
 940                 float lines;
 941                 if(privatesay)
 942                 {
 943                         flood_spl = cvar("g_chat_flood_spl_tell");
 944                         flood_burst = cvar("g_chat_flood_burst_tell");
 945                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 946                         flood_field = floodcontrol_chattell;
 947                 }
 948                 else if(teamsay)
 949                 {
 950                         flood_spl = cvar("g_chat_flood_spl_team");
 951                         flood_burst = cvar("g_chat_flood_burst_team");
 952                         flood_lmax = cvar("g_chat_flood_lmax_team");
 953                         flood_field = floodcontrol_chatteam;
 954                 }
 955                 else
 956                 {
 957                         flood_spl = cvar("g_chat_flood_spl");
 958                         flood_burst = cvar("g_chat_flood_burst");
 959                         flood_lmax = cvar("g_chat_flood_lmax");
 960                         flood_field = floodcontrol_chat;
 961                 }
 962                 flood_burst = max(0, flood_burst - 1);
 963                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 964
 965                 // do flood control for the default line size
 966                 if(msgstr != "")
 967                 {
 968                         getWrappedLine_remaining = msgstr;
 969                         msgstr = "";
 970                         lines = 0;
 971                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 972                         {
 973                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 974                                 ++lines;
 975                         }
 976                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 977
 978                         if(getWrappedLine_remaining != "")
 979                         {
 980                                 msgstr = strcat(msgstr, "\n");
 981                                 flood = 2;
 982                         }
 983
 984                         if(time >= source.flood_field)
 985                         {
 986                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 987                         }
 988                         else
 989                         {
 990                                 flood = 1;
 991                                 msgstr = fullmsgstr;
 992                         }
 993                 }
 994                 else
 995                 {
 996                         if(time >= source.flood_field)
 997                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 998                         else
 999                                 flood = 1;
1000                 }
1001         }
1002
1003         if (timeoutStatus == 2) //when game is paused, no flood protection
1004                 source.flood_field = flood = 0;
1005
1006         if(flood == 2) // cannot happen for empty msgstr
1007         {
1008                 if(cvar("g_chat_flood_notify_flooder"))
1009                 {
1010                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1011                         sourcecmsgstr = "";
1012                 }
1013                 else
1014                 {
1015                         sourcemsgstr = fullmsgstr;
1016                         sourcecmsgstr = fullcmsgstr;
1017                 }
1018                 cmsgstr = "";
1019         }
1020         else
1021         {
1022                 sourcemsgstr = msgstr;
1023                 sourcecmsgstr = cmsgstr;
1024         }
1025
1026         if(!privatesay)
1027         if(source.classname != "player")
1028         {
1029                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1030                         teamsay = -1; // spectators
1031         }
1032
1033         if(flood)
1034                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1035
1036         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1037         if(privatesay)
1038                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1039
1040         if(source.muted)
1041         {
1042                 // always fake the message
1043                 ret = -1;
1044         }
1045         else if(flood == 1)
1046         {
1047                 if(cvar("g_chat_flood_notify_flooder"))
1048                 {
1049                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1050                         ret = 0;
1051                 }
1052                 else
1053                         ret = -1;
1054         }
1055         else
1056         {
1057                 ret = 1;
1058         }
1059
1060         if(sourcemsgstr != "" && ret != 0)
1061         {
1062                 if(ret < 0) // fake
1063                 {
1064                         sprint(source, sourcemsgstr);
1065                         if(sourcecmsgstr != "" && !privatesay)
1066                                 centerprint(source, sourcecmsgstr);
1067                 }
1068                 else if(privatesay)
1069                 {
1070                         sprint(source, sourcemsgstr);
1071                         sprint(privatesay, msgstr);
1072                         if(cmsgstr != "")
1073                                 centerprint(privatesay, cmsgstr);
1074                 }
1075                 else if(teamsay > 0)
1076                 {
1077                         sprint(source, sourcemsgstr);
1078                         if(sourcecmsgstr != "")
1079                                 centerprint(source, sourcecmsgstr);
1080                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1081                                 if(head != source)
1082                                 {
1083                                         sprint(head, msgstr);
1084                                         if(cmsgstr != "")
1085                                                 centerprint(head, cmsgstr);
1086                                 }
1087                 }
1088                 else if(teamsay < 0)
1089                 {
1090                         sprint(source, sourcemsgstr);
1091                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1092                                 if(head != source)
1093                                         sprint(head, msgstr);
1094                 }
1095                 else if(sourcemsgstr != msgstr)
1096                 {
1097                         sprint(source, sourcemsgstr);
1098                         FOR_EACH_REALCLIENT(head)
1099                                 if(head != source)
1100                                         sprint(head, msgstr);
1101                 }
1102                 else
1103                         bprint(msgstr);
1104         }
1105
1106         return ret;
1107 }
1108
1109 float GetVoiceMessageVoiceType(string type)
1110 {
1111         if(type == "taunt")
1112                 return VOICETYPE_TAUNT;
1113         if(type == "teamshoot")
1114                 return VOICETYPE_LASTATTACKER;
1115         return VOICETYPE_TEAMRADIO;
1116 }
1117
1118 string allvoicesamples;
1119 float GetPlayerSoundSampleField_notFound;
1120 float GetPlayerSoundSampleField_fixed;
1121 .string GetVoiceMessageSampleField(string type)
1122 {
1123         GetPlayerSoundSampleField_notFound = 0;
1124         GetPlayerSoundSampleField_fixed = 0;
1125         switch(type)
1126         {
1127 #define _VOICEMSG(m) case #m: return playersound_##m;
1128                 ALLVOICEMSGS
1129 #undef _VOICEMSG
1130         }
1131         GetPlayerSoundSampleField_notFound = 1;
1132         return playersound_taunt;
1133 }
1134
1135 .string GetPlayerSoundSampleField(string type)
1136 {
1137         GetPlayerSoundSampleField_notFound = 0;
1138         GetPlayerSoundSampleField_fixed = 0;
1139         switch(type)
1140         {
1141 #define _VOICEMSG(m) case #m: return playersound_##m;
1142                 ALLPLAYERSOUNDS
1143 #undef _VOICEMSG
1144         }
1145         GetPlayerSoundSampleField_notFound = 1;
1146         return playersound_taunt;
1147 }
1148
1149 void PrecacheGlobalSound(string samplestring)
1150 {
1151         float n, i;
1152         tokenize_console(samplestring);
1153         n = stof(argv(1));
1154         if(n > 0)
1155         {
1156                 for(i = 1; i <= n; ++i)
1157                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1158         }
1159         else
1160         {
1161                 precache_sound(strcat(argv(0), ".wav"));
1162         }
1163 }
1164
1165 void PrecachePlayerSounds(string f)
1166 {
1167         float fh;
1168         string s;
1169         fh = fopen(f, FILE_READ);
1170         if(fh < 0)
1171                 return;
1172         while((s = fgets(fh)))
1173         {
1174                 if(tokenize_console(s) != 3)
1175                 {
1176                         dprint("Invalid sound info line: ", s, "\n");
1177                         continue;
1178                 }
1179                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1180         }
1181         fclose(fh);
1182
1183         if not(allvoicesamples)
1184         {
1185 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1186                 ALLVOICEMSGS
1187 #undef _VOICEMSG
1188                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1189         }
1190 }
1191
1192 void ClearPlayerSounds()
1193 {
1194 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1195         ALLPLAYERSOUNDS
1196         ALLVOICEMSGS
1197 #undef _VOICEMSG
1198 }
1199
1200 void LoadPlayerSounds(string f, float first)
1201 {
1202         float fh;
1203         string s;
1204         var .string field;
1205         fh = fopen(f, FILE_READ);
1206         if(fh < 0)
1207         {
1208                 dprint("Player sound file not found: ", f, "\n");
1209                 return;
1210         }
1211         while((s = fgets(fh)))
1212         {
1213                 if(tokenize_console(s) != 3)
1214                         continue;
1215                 field = GetPlayerSoundSampleField(argv(0));
1216                 if(GetPlayerSoundSampleField_notFound)
1217                         field = GetVoiceMessageSampleField(argv(0));
1218                 if(GetPlayerSoundSampleField_notFound)
1219                         continue;
1220                 if(GetPlayerSoundSampleField_fixed)
1221                         if not(first)
1222                                 continue;
1223                 if(self.field)
1224                         strunzone(self.field);
1225                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1226         }
1227         fclose(fh);
1228 }
1229
1230 .float modelindex_for_playersound;
1231 .float skinindex_for_playersound;
1232 void UpdatePlayerSounds()
1233 {
1234         if(self.modelindex == self.modelindex_for_playersound)
1235         if(self.skinindex == self.skinindex_for_playersound)
1236                 return;
1237         self.modelindex_for_playersound = self.modelindex;
1238         self.skinindex_for_playersound = self.skinindex;
1239         ClearPlayerSounds();
1240         LoadPlayerSounds("sound/player/default.sounds", 1);
1241         LoadPlayerSounds(get_model_datafilename(self.playermodel, self.skinindex, "sounds"), 0);
1242 }
1243
1244 void FakeGlobalSound(string sample, float chan, float voicetype)
1245 {
1246         float n;
1247         float tauntrand;
1248
1249         if(sample == "")
1250                 return;
1251
1252         tokenize_console(sample);
1253         n = stof(argv(1));
1254         if(n > 0)
1255                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1256         else
1257                 sample = strcat(argv(0), ".wav"); // randomization
1258
1259         switch(voicetype)
1260         {
1261                 case VOICETYPE_LASTATTACKER_ONLY:
1262                         break;
1263                 case VOICETYPE_LASTATTACKER:
1264                         if(self.pusher)
1265                         {
1266                                 msg_entity = self;
1267                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1268                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1269                         }
1270                         break;
1271                 case VOICETYPE_TEAMRADIO:
1272                         msg_entity = self;
1273                         if(msg_entity.cvar_cl_voice_directional == 1)
1274                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1275                         else
1276                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1277                         break;
1278                 case VOICETYPE_AUTOTAUNT:
1279                         if(!sv_autotaunt)
1280                                 break;
1281                         if(!sv_taunt)
1282                                 break;
1283                         if(sv_gentle)
1284                                 break;
1285                         tauntrand = random();
1286                         msg_entity = self;
1287                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1288                         {
1289                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1290                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1291                                 else
1292                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1293                         }
1294                         break;
1295                 case VOICETYPE_TAUNT:
1296                         if(self.classname == "player")
1297                                 if(self.deadflag == DEAD_NO)
1298                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1299                         if(!sv_taunt)
1300                                 break;
1301                         if(sv_gentle)
1302                                 break;
1303                         msg_entity = self;
1304                         if (msg_entity.cvar_cl_voice_directional >= 1)
1305                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1306                         else
1307                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1308                         break;
1309                 case VOICETYPE_PLAYERSOUND:
1310                         msg_entity = self;
1311                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1312                         break;
1313                 default:
1314                         backtrace("Invalid voice type!");
1315                         break;
1316         }
1317 }
1318
1319 void GlobalSound(string sample, float chan, float voicetype)
1320 {
1321         float n;
1322         float tauntrand;
1323
1324         if(sample == "")
1325                 return;
1326
1327         tokenize_console(sample);
1328         n = stof(argv(1));
1329         if(n > 0)
1330                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1331         else
1332                 sample = strcat(argv(0), ".wav"); // randomization
1333
1334         switch(voicetype)
1335         {
1336                 case VOICETYPE_LASTATTACKER_ONLY:
1337                         if(self.pusher)
1338                         {
1339                                 msg_entity = self.pusher;
1340                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1341                                 {
1342                                         if(msg_entity.cvar_cl_voice_directional == 1)
1343                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1344                                         else
1345                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1346                                 }
1347                         }
1348                         break;
1349                 case VOICETYPE_LASTATTACKER:
1350                         if(self.pusher)
1351                         {
1352                                 msg_entity = self.pusher;
1353                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1354                                 {
1355                                         if(msg_entity.cvar_cl_voice_directional == 1)
1356                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1357                                         else
1358                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1359                                 }
1360                                 msg_entity = self;
1361                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1362                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1363                         }
1364                         break;
1365                 case VOICETYPE_TEAMRADIO:
1366                         FOR_EACH_REALCLIENT(msg_entity)
1367                                 if(!teams_matter || msg_entity.team == self.team)
1368                                 {
1369                                         if(msg_entity.cvar_cl_voice_directional == 1)
1370                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1371                                         else
1372                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1373                                 }
1374                         break;
1375                 case VOICETYPE_AUTOTAUNT:
1376                         if(!sv_autotaunt)
1377                                 break;
1378                         if(!sv_taunt)
1379                                 break;
1380                         if(sv_gentle)
1381                                 break;
1382                         tauntrand = random();
1383                         FOR_EACH_REALCLIENT(msg_entity)
1384                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1385                                 {
1386                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1387                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1388                                         else
1389                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1390                                 }
1391                         break;
1392                 case VOICETYPE_TAUNT:
1393                         if(self.classname == "player")
1394                                 if(self.deadflag == DEAD_NO)
1395                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1396                         if(!sv_taunt)
1397                                 break;
1398                         if(sv_gentle)
1399                                 break;
1400                         FOR_EACH_REALCLIENT(msg_entity)
1401                         {
1402                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1403                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1404                                 else
1405                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1406                         }
1407                         break;
1408                 case VOICETYPE_PLAYERSOUND:
1409                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1410                         break;
1411                 default:
1412                         backtrace("Invalid voice type!");
1413                         break;
1414         }
1415 }
1416
1417 void PlayerSound(.string samplefield, float chan, float voicetype)
1418 {
1419         GlobalSound(self.samplefield, chan, voicetype);
1420 }
1421
1422 void VoiceMessage(string type, string msg)
1423 {
1424         var .string sample;
1425         float voicetype, ownteam;
1426         float flood;
1427         sample = GetVoiceMessageSampleField(type);
1428
1429         if(GetPlayerSoundSampleField_notFound)
1430         {
1431                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1432                 return;
1433         }
1434
1435         voicetype = GetVoiceMessageVoiceType(type);
1436         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1437
1438         flood = Say(self, ownteam, world, msg, 1);
1439
1440         if (flood > 0)
1441                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1442         else if (flood < 0)
1443                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1444 }
1445
1446 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1447 {
1448 //      show_message
1449 //      0 (00) automove centerprint, admin message
1450 //      1 (01) automove centerprint, no admin message
1451 //      2 (10) no centerprint, admin message
1452 //      3 (11) no centerprint, no admin message
1453
1454         float lockteams_backup;
1455
1456         lockteams_backup = lockteams;  // backup any team lock
1457
1458         lockteams = 0;  // disable locked teams
1459
1460         TeamchangeFrags(client);  // move the players frags
1461         SetPlayerColors(client, team_colour - 1);  // set the players colour
1462         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1463
1464         lockteams = lockteams_backup;  // restore the team lock
1465
1466         LogTeamchange(client.playerid, client.team, type);
1467
1468         if not(show_message & 1) // admin message
1469                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1470
1471         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1472 }