qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // url_fopen returned, we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  29                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  30                         n = tokenizebyseparator(cvar_purechanges, "\n");
  31                         for(i = 0; i < n; ++i)
  32                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  33                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  34                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  35                                 {
  36                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  37                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  38                                         if(v != '0 0 0')
  39                                         {
  40                                                 //vector is: kills hits damage
  41                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  42                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  43                                         }
  44                                 }
  45                         url_fputs(fh, "#end\n\n");
  46                         url_fclose(fh, WeaponStats_ready, world);
  47                         buf_del(weaponstats_buffer);
  48                         weaponstats_buffer = -1;
  49                         break;
  50                 case URL_READY_CANREAD:
  51                         // url_fclose is processing, we got a response for writing the data
  52                         // this must come from HTTP
  53                         print("Got response from weapon stats server:\n");
  54                         while((s = url_fgets(fh)))
  55                                 print("  ", s, "\n");
  56                         print("End of response.\n");
  57                         url_fclose(fh, WeaponStats_ready, world);
  58                         break;
  59                 case URL_READY_CLOSED:
  60                         // url_fclose has finished
  61                         print("Weapon stats written\n");
  62                         break;
  63                 case URL_READY_ERROR:
  64                 default:
  65                         print("Weapon stats writing failed: ", ftos(status), "\n");
  66                         break;
  67         }
  68 }
  69
  70 void WeaponStats_Shutdown()
  71 {
  72         if(weaponstats_buffer < 0)
  73                 return;
  74         if(autocvar_sv_weaponstats_file != "")
  75         {
  76                 url_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  77         }
  78         else
  79         {
  80                 buf_del(weaponstats_buffer);
  81                 weaponstats_buffer = -1;
  82         }
  83 }
  84
  85 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  86 {
  87         float idx;
  88         if(weaponstats_buffer < 0)
  89                 return;
  90         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  91                 return;
  92         if(awep > WEP_LAST || vwep > WEP_LAST)
  93                 return;
  94         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  95         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  96 }
  97 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  98 {
  99         if(damage < 0)
 100                 error("negative damage?");
 101         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 102 }
 103 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 104 {
 105         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 106 }
 107
 108 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 109 // merged player_run and player_stand to player_anim
 110 // added death animations to player_anim
 111 // can now spawn thrown weapons from anywhere, not just from players
 112 // thrown weapons now fade out after 20 seconds
 113 // created PlayerGib function
 114 // PlayerDie no longer uses hitloc or damage
 115 // PlayerDie now supports dying animations as well as gibbing
 116 // cleaned up PlayerDie a lot
 117 // added CopyBody
 118
 119 .entity pusher;
 120 .float pushltime;
 121
 122 void CopyBody(float keepvelocity)
 123 {
 124         local entity oldself;
 125         if (self.effects & EF_NODRAW)
 126                 return;
 127         oldself = self;
 128         self = spawn();
 129         self.enemy = oldself;
 130         self.lip = oldself.lip;
 131         self.colormap = oldself.colormap;
 132         self.glowmod = oldself.glowmod;
 133         self.iscreature = oldself.iscreature;
 134         self.angles = oldself.angles;
 135         self.avelocity = oldself.avelocity;
 136         self.classname = "body";
 137         self.damageforcescale = oldself.damageforcescale;
 138         self.effects = oldself.effects;
 139         self.event_damage = oldself.event_damage;
 140         self.animstate_startframe = oldself.animstate_startframe;
 141         self.animstate_numframes = oldself.animstate_numframes;
 142         self.animstate_framerate = oldself.animstate_framerate;
 143         self.animstate_starttime = oldself.animstate_starttime;
 144         self.animstate_endtime = oldself.animstate_endtime;
 145         self.animstate_override = oldself.animstate_override;
 146         self.animstate_looping = oldself.animstate_looping;
 147         self.frame = oldself.frame;
 148         self.dead_frame = oldself.dead_frame;
 149         self.pain_finished = oldself.pain_finished;
 150         self.health = oldself.health;
 151         self.armorvalue = oldself.armorvalue;
 152         self.armortype = oldself.armortype;
 153         self.model = oldself.model;
 154         self.modelindex = oldself.modelindex;
 155         self.modelindex_lod0 = oldself.modelindex_lod0;
 156         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 157         self.modelindex_lod1 = oldself.modelindex_lod1;
 158         self.modelindex_lod2 = oldself.modelindex_lod2;
 159         self.skinindex = oldself.skinindex;
 160         self.species = oldself.species;
 161         self.movetype = oldself.movetype;
 162         self.nextthink = oldself.nextthink;
 163         self.solid = oldself.solid;
 164         self.ballistics_density = oldself.ballistics_density;
 165         self.takedamage = oldself.takedamage;
 166         self.think = oldself.think;
 167         self.customizeentityforclient = oldself.customizeentityforclient;
 168         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 169         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 170         if (keepvelocity == 1)
 171                 self.velocity = oldself.velocity;
 172         self.oldvelocity = self.velocity;
 173         self.fade_time = oldself.fade_time;
 174         self.fade_rate = oldself.fade_rate;
 175         //self.weapon = oldself.weapon;
 176         setorigin(self, oldself.origin);
 177         setsize(self, oldself.mins, oldself.maxs);
 178         self.prevorigin = oldself.origin;
 179         self.reset = SUB_Remove;
 180
 181         Drag_MoveDrag(oldself, self);
 182
 183         self = oldself;
 184 }
 185
 186 float player_getspecies()
 187 {
 188         float s;
 189         get_model_parameters(self.model, self.skinindex);
 190         s = get_model_parameters_species;
 191         get_model_parameters(string_null, 0);
 192         if(s < 0)
 193                 return SPECIES_HUMAN;
 194         return s;
 195 }
 196
 197 void player_setupanimsformodel()
 198 {
 199         local string animfilename;
 200         local float animfile;
 201         // defaults for legacy .zym models without animinfo files
 202         self.anim_die1 = '0 1 0.5'; // 2 seconds
 203         self.anim_die2 = '1 1 0.5'; // 2 seconds
 204         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 205         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 206         self.anim_duckwalk = '4 1 1';
 207         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 208         self.anim_duckidle = '6 1 1';
 209         self.anim_idle = '7 1 1';
 210         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 211         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 212         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 213         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 214         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 215         self.anim_run = '13 1 1';
 216         self.anim_runbackwards = '14 1 1';
 217         self.anim_strafeleft = '15 1 1';
 218         self.anim_straferight = '16 1 1';
 219         self.anim_dead1 = '17 1 1';
 220         self.anim_dead2 = '18 1 1';
 221         self.anim_forwardright = '19 1 1';
 222         self.anim_forwardleft = '20 1 1';
 223         self.anim_backright = '21 1 1';
 224         self.anim_backleft  = '22 1 1';
 225         self.anim_melee = '23 1 1';
 226         animparseerror = FALSE;
 227         animfilename = strcat(self.model, ".animinfo");
 228         animfile = fopen(animfilename, FILE_READ);
 229         if (animfile >= 0)
 230         {
 231                 self.anim_die1         = animparseline(animfile);
 232                 self.anim_die2         = animparseline(animfile);
 233                 self.anim_draw         = animparseline(animfile);
 234                 self.anim_duck         = animparseline(animfile);
 235                 self.anim_duckwalk     = animparseline(animfile);
 236                 self.anim_duckjump     = animparseline(animfile);
 237                 self.anim_duckidle     = animparseline(animfile);
 238                 self.anim_idle         = animparseline(animfile);
 239                 self.anim_jump         = animparseline(animfile);
 240                 self.anim_pain1        = animparseline(animfile);
 241                 self.anim_pain2        = animparseline(animfile);
 242                 self.anim_shoot        = animparseline(animfile);
 243                 self.anim_taunt        = animparseline(animfile);
 244                 self.anim_run          = animparseline(animfile);
 245                 self.anim_runbackwards = animparseline(animfile);
 246                 self.anim_strafeleft   = animparseline(animfile);
 247                 self.anim_straferight  = animparseline(animfile);
 248                 self.anim_forwardright = animparseline(animfile);
 249                 self.anim_forwardleft  = animparseline(animfile);
 250                 self.anim_backright    = animparseline(animfile);
 251                 self.anim_backleft     = animparseline(animfile);
 252                 self.anim_melee        = animparseline(animfile);
 253                 fclose(animfile);
 254
 255                 // derived anims
 256                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 257                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 258
 259                 if (animparseerror)
 260                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 261         }
 262         else
 263                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 264         // reset animstate now
 265         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 266 };
 267
 268 void player_anim (void)
 269 {
 270         updateanim(self);
 271         if (self.weaponentity)
 272                 updateanim(self.weaponentity);
 273
 274         if (self.deadflag != DEAD_NO)
 275         {
 276                 if (time > self.animstate_endtime)
 277                 {
 278                         if (self.maxs_z > 5)
 279                         {
 280                                 self.maxs_z = 5;
 281                                 setsize(self, self.mins, self.maxs);
 282                         }
 283                         self.frame = self.dead_frame;
 284                 }
 285                 return;
 286         }
 287
 288         if (!self.animstate_override)
 289         {
 290                 if (!(self.flags & FL_ONGROUND))
 291                 {
 292                         if (self.crouch)
 293                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 294                         else
 295                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 296                         self.restart_jump = FALSE;
 297                 }
 298                 else if (self.crouch)
 299                 {
 300                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 301                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 302                         else
 303                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 304                 }
 305                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 306                 {
 307                         if (self.movement_x > 0 && self.movement_y == 0)
 308                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x < 0 && self.movement_y == 0)
 310                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x == 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x == 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x > 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x > 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 319                         else if (self.movement_x < 0 && self.movement_y > 0)
 320                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 321                         else if (self.movement_x < 0 && self.movement_y < 0)
 322                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 323                         else
 324                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 325                 }
 326                 else
 327                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 328         }
 329
 330         if (self.weaponentity)
 331         if (!self.weaponentity.animstate_override)
 332                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 333 }
 334
 335 void SpawnThrownWeapon (vector org, float w)
 336 {
 337         if(g_minstagib)
 338         if(self.ammo_cells <= 0)
 339                 return;
 340
 341         if(g_pinata)
 342         {
 343                 float j;
 344                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 345                 {
 346                         if(self.weapons & W_WeaponBit(j))
 347                                 if(W_IsWeaponThrowable(j))
 348                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 349                 }
 350         }
 351         else
 352         {
 353                 if(W_IsWeaponThrowable(self.weapon))
 354                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 355         }
 356 }
 357
 358 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 359 {
 360         local float take, save;
 361         vector v;
 362         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 363
 364         // damage resistance (ignore most of the damage from a bullet or similar)
 365         damage = max(damage - 5, 1);
 366
 367         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 368         take = v_x;
 369         save = v_y;
 370
 371         if(sound_allowed(MSG_BROADCAST, attacker))
 372         {
 373                 if (save > 10)
 374                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 375                 else if (take > 30)
 376                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 377                 else if (take > 10)
 378                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 379         }
 380
 381         if (take > 50)
 382                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 383         if (take > 100)
 384                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 385
 386         if (!(self.flags & FL_GODMODE))
 387         {
 388                 self.armorvalue = self.armorvalue - save;
 389                 self.health = self.health - take;
 390                 // pause regeneration for 5 seconds
 391                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 392         }
 393         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 394         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 395         self.dmg_inflictor = inflictor;
 396
 397         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 398         {
 399                 // don't use any animations as a gib
 400                 self.frame = 0;
 401                 self.dead_frame = 0;
 402                 // view just above the floor
 403                 self.view_ofs = '0 0 4';
 404
 405                 Violence_GibSplash(self, 1, 1, attacker);
 406                 self.modelindex = 0; // restore later
 407                 self.solid = SOLID_NOT; // restore later
 408         }
 409 }
 410
 411 void ClientKill_Now_TeamChange();
 412 void freezetag_CheckWinner();
 413
 414 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 415 {
 416         local float take, save, waves, sdelay, dh, da, j;
 417         vector v;
 418         float valid_damage_for_weaponstats;
 419         float excess;
 420
 421         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 422                 return;
 423
 424         dh = max(self.health, 0);
 425         da = max(self.armorvalue, 0);
 426
 427         if(!DEATH_ISSPECIAL(deathtype))
 428         {
 429                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 430                 if(self != attacker)
 431                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 432         }
 433
 434         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 435         {
 436                 // tuba causes blood to come out of the ears
 437                 vector ear1, ear2;
 438                 vector d;
 439                 float f;
 440                 ear1 = self.origin;
 441                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 442                 ear2 = ear1;
 443                 makevectors(self.angles);
 444                 ear1 += v_right * -10;
 445                 ear2 += v_right * +10;
 446                 d = inflictor.origin - self.origin;
 447                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 448                 force = v_right * vlen(force);
 449                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 450                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 451                 if(f > 0)
 452                 {
 453                         hitloc = ear1;
 454                         force = force * -1;
 455                 }
 456                 else
 457                 {
 458                         hitloc = ear2;
 459                         // force is already good
 460                 }
 461         }
 462         else
 463                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 464
 465         if (!g_minstagib)
 466         {
 467                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 468                 take = v_x;
 469                 save = v_y;
 470         }
 471         else
 472         {
 473                 save = 0;
 474                 take = damage;
 475         }
 476
 477         frag_inflictor = inflictor;
 478         frag_attacker = attacker;
 479         frag_target = self;
 480         damage_take = take;
 481         damage_save = save;
 482         damage_force = force;
 483         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 484         take = bound(0, damage_take, self.health);
 485         save = bound(0, damage_save, self.armorvalue);
 486         excess = max(0, damage - take - save);
 487
 488         if(sound_allowed(MSG_BROADCAST, attacker))
 489         {
 490                 if (save > 10)
 491                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 492                 else if (take > 30)
 493                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 494                 else if (take > 10)
 495                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 496         }
 497
 498         if (take > 50)
 499                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 500         if (take > 100)
 501                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 502
 503         if (time >= self.spawnshieldtime)
 504         {
 505                 if (!(self.flags & FL_GODMODE))
 506                 {
 507                         self.armorvalue = self.armorvalue - save;
 508                         self.health = self.health - take;
 509                         // pause regeneration for 5 seconds
 510                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 511
 512                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 513                         {
 514                                 self.pain_finished = time + 0.5;        //Supajoe
 515
 516                                 if(sv_gentle < 1) {
 517                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 518                                         {
 519                                                 if (random() > 0.5)
 520                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 521                                                 else
 522                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 523                                         }
 524
 525                                         if(sound_allowed(MSG_BROADCAST, attacker))
 526                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 527                                         if(self.health > 1)
 528                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 529                                         {
 530                                                 if(deathtype == DEATH_FALL)
 531                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 532                                                 else if(self.health > 75) // TODO make a "gentle" version?
 533                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 534                                                 else if(self.health > 50)
 535                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 536                                                 else if(self.health > 25)
 537                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 538                                                 else
 539                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 540                                         }
 541                                 }
 542
 543                                 // throw off bot aim temporarily
 544                                 local float shake;
 545                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 546                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 547                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 548                         }
 549                 }
 550                 else
 551                         self.max_armorvalue += (save + take);
 552         }
 553         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 554         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 555         self.dmg_inflictor = inflictor;
 556
 557         if(attacker == self)
 558         {
 559                 // don't reset pushltime for self damage as it may be an attempt to
 560                 // escape a lava pit or similar
 561                 //self.pushltime = 0;
 562         }
 563         else if(attacker.classname == "player")
 564         {
 565                 self.pusher = attacker;
 566                 self.pushltime = time + autocvar_g_maxpushtime;
 567         }
 568         else if(time < self.pushltime)
 569         {
 570                 attacker = self.pusher;
 571                 self.pushltime = max(self.pushltime, time + 0.6);
 572         }
 573         else
 574                 self.pushltime = 0;
 575
 576         float abot, vbot, awep;
 577         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 578         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 579
 580         valid_damage_for_weaponstats = 0;
 581         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 582         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 583         if(attacker && self != attacker)
 584         if(IsDifferentTeam(self, attacker))
 585         {
 586                 if(DEATH_ISSPECIAL(deathtype))
 587                         awep = attacker.weapon;
 588                 else
 589                         awep = DEATH_WEAPONOF(deathtype);
 590                 valid_damage_for_weaponstats = 1;
 591         }
 592
 593         if(valid_damage_for_weaponstats)
 594         {
 595                 dh = dh - max(self.health, 0);
 596                 da = da - max(self.armorvalue, 0);
 597                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 598         }
 599
 600         if (self.health < 1)
 601         {
 602                 float defer_ClientKill_Now_TeamChange;
 603                 defer_ClientKill_Now_TeamChange = FALSE;
 604
 605                 if(self.alivetime)
 606                 {
 607                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 608                         self.alivetime = 0;
 609                 }
 610
 611                 if(valid_damage_for_weaponstats)
 612                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 613
 614                 if(sv_gentle < 1) // TODO make a "gentle" version?
 615                 if(sound_allowed(MSG_BROADCAST, attacker))
 616                 {
 617                         if(deathtype == DEATH_DROWN)
 618                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 619                         else
 620                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 621                 }
 622
 623                 // get rid of kill indicator
 624                 if(self.killindicator)
 625                 {
 626                         remove(self.killindicator);
 627                         self.killindicator = world;
 628                         if(self.killindicator_teamchange)
 629                                 defer_ClientKill_Now_TeamChange = TRUE;
 630
 631                         if(self.classname == "body")
 632                         if(deathtype == DEATH_KILL)
 633                         {
 634                                 // for the lemmings fans, a small harmless explosion
 635                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 636                         }
 637                 }
 638
 639                 if(!g_freezetag)
 640                 {
 641                         // become fully visible
 642                         self.alpha = 1;
 643                         // throw a weapon
 644                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 645                 }
 646
 647                 // print an obituary message
 648                 Obituary (attacker, inflictor, self, deathtype);
 649                 race_PreDie();
 650                 DropAllRunes(self);
 651
 652         // increment frag counter for used weapon type
 653         float w;
 654         w = DEATH_WEAPONOF(deathtype);
 655         if(WEP_VALID(w))
 656         if(self.classname == "player")
 657         if(self != attacker)
 658         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 659
 660                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 661                 {
 662                         PutClientInServer();
 663                         count_alive_players(); // re-count players
 664                         freezetag_CheckWinner();
 665                         return;
 666                 }
 667
 668                 frag_attacker = attacker;
 669                 frag_inflictor = inflictor;
 670                 frag_target = self;
 671                 MUTATOR_CALLHOOK(PlayerDies);
 672                 weapon_action(self.weapon, WR_PLAYERDEATH);
 673
 674                 if(self.flagcarried)
 675                 {
 676                         if(attacker.classname != "player")
 677                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 678                         else if(attacker.team == self.team)
 679                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 680                         else
 681                                 DropFlag(self.flagcarried, world, attacker);
 682                 }
 683                 if(self.ballcarried && g_nexball)
 684                         DropBall(self.ballcarried, self.origin, self.velocity);
 685                 Portal_ClearAllLater(self);
 686
 687                 if(clienttype(self) == CLIENTTYPE_REAL)
 688                 {
 689                         stuffcmd(self, "-zoom\n");
 690                         self.fixangle = TRUE;
 691                         //msg_entity = self;
 692                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 693                         //WriteAngle (MSG_ONE, self.v_angle_x);
 694                         //WriteAngle (MSG_ONE, self.v_angle_y);
 695                         //WriteAngle (MSG_ONE, 80);
 696                 }
 697
 698                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 699                         ClientKill_Now_TeamChange();
 700
 701                 if(g_arena)
 702                         Spawnqueue_Unmark(self);
 703
 704                 if(g_freezetag)
 705                         return;
 706
 707                 // when we get here, player actually dies
 708                 // clear waypoints (do this AFTER FreezeTag)
 709                 WaypointSprite_PlayerDead();
 710
 711                 // make the corpse upright (not tilted)
 712                 self.angles_x = 0;
 713                 self.angles_z = 0;
 714                 // don't spin
 715                 self.avelocity = '0 0 0';
 716                 // view from the floor
 717                 self.view_ofs = '0 0 -8';
 718                 // toss the corpse
 719                 self.movetype = MOVETYPE_TOSS;
 720                 // shootable corpse
 721                 self.solid = SOLID_CORPSE;
 722                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 723                 // don't stick to the floor
 724                 self.flags &~= FL_ONGROUND;
 725                 // dying animation
 726                 self.deadflag = DEAD_DYING;
 727                 // when to allow respawn
 728                 sdelay = 0;
 729                 waves = 0;
 730                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 731                 if(!sdelay)
 732                 {
 733                         if(g_cts)
 734                                 sdelay = 0; // no respawn delay in CTS
 735                         else
 736                                 sdelay = autocvar_g_respawn_delay;
 737                 }
 738                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 739                 if(!waves)
 740                         waves = autocvar_g_respawn_waves;
 741                 if(waves)
 742                         self.death_time = ceil((time + sdelay) / waves) * waves;
 743                 else
 744                         self.death_time = time + sdelay;
 745                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 746                         self.respawn_countdown = 10; // first number to count down from is 10
 747                 else
 748                         self.respawn_countdown = -1; // do not count down
 749                 if (random() < 0.5)
 750                 {
 751                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 752                         self.dead_frame = self.anim_dead1_x;
 753                 }
 754                 else
 755                 {
 756                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 757                         self.dead_frame = self.anim_dead2_x;
 758                 }
 759                 // set damage function to corpse damage
 760                 self.event_damage = PlayerCorpseDamage;
 761                 // call the corpse damage function just in case it wants to gib
 762                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 763                 // set up to fade out later
 764                 SUB_SetFade (self, time + 6 + random (), 1);
 765
 766                 if(sv_gentle > 0 || autocvar_ekg) {
 767                         // remove corpse
 768                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 769                 }
 770
 771                 // reset fields the weapons may use just in case
 772                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 773                 {
 774                         weapon_action(j, WR_RESETPLAYER);
 775                         ATTACK_FINISHED_FOR(self, j) = 0;
 776                 }
 777         }
 778 }
 779
 780 .float muted; // to be used by prvm_edictset server playernumber muted 1
 781 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 782 // message "": do not say, just test flood control
 783 // return value:
 784 //   1 = accept
 785 //   0 = reject
 786 //  -1 = fake accept
 787 {
 788         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 789         float flood, privatemsgprefixlen;
 790         var .float flood_field;
 791         entity head;
 792         float ret;
 793
 794         if(Ban_MaybeEnforceBan(source))
 795                 return 0;
 796
 797         if(!teamsay && !privatesay)
 798                 if(substring(msgin, 0, 1) == " ")
 799                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 800
 801         msgin = formatmessage(msgin);
 802
 803         if(source.classname != "player")
 804                 colorstr = "^0"; // black for spectators
 805         else if(teamplay)
 806                 colorstr = Team_ColorCode(source.team);
 807         else
 808                 teamsay = FALSE;
 809
 810         if(intermission_running)
 811                 teamsay = FALSE;
 812
 813         if(msgin != "")
 814                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 815
 816         /*
 817          * using bprint solves this... me stupid
 818         // how can we prevent the message from appearing in a listen server?
 819         // for now, just give "say" back and only handle say_team
 820         if(!teamsay)
 821         {
 822                 clientcommand(self, strcat("say ", msgin));
 823                 return;
 824         }
 825         */
 826
 827         if(autocvar_g_chat_teamcolors)
 828                 namestr = playername(source);
 829         else
 830                 namestr = source.netname;
 831
 832         if(msgin != "")
 833         {
 834                 if(privatesay)
 835                 {
 836                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 837                         privatemsgprefixlen = strlen(msgstr);
 838                         msgstr = strcat(msgstr, msgin);
 839                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 840                         if(autocvar_g_chat_teamcolors)
 841                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 842                         else
 843                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 844                 }
 845                 else if(teamsay)
 846                 {
 847                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 848                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 849                 }
 850                 else
 851                 {
 852                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 853                         cmsgstr = "";
 854                 }
 855                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 856         }
 857         else
 858         {
 859                 msgstr = cmsgstr = "";
 860         }
 861
 862         fullmsgstr = msgstr;
 863         fullcmsgstr = cmsgstr;
 864
 865         // FLOOD CONTROL
 866         flood = 0;
 867         if(floodcontrol)
 868         {
 869                 float flood_spl;
 870                 float flood_burst;
 871                 float flood_lmax;
 872                 float lines;
 873                 if(privatesay)
 874                 {
 875                         flood_spl = autocvar_g_chat_flood_spl_tell;
 876                         flood_burst = autocvar_g_chat_flood_burst_tell;
 877                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 878                         flood_field = floodcontrol_chattell;
 879                 }
 880                 else if(teamsay)
 881                 {
 882                         flood_spl = autocvar_g_chat_flood_spl_team;
 883                         flood_burst = autocvar_g_chat_flood_burst_team;
 884                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 885                         flood_field = floodcontrol_chatteam;
 886                 }
 887                 else
 888                 {
 889                         flood_spl = autocvar_g_chat_flood_spl;
 890                         flood_burst = autocvar_g_chat_flood_burst;
 891                         flood_lmax = autocvar_g_chat_flood_lmax;
 892                         flood_field = floodcontrol_chat;
 893                 }
 894                 flood_burst = max(0, flood_burst - 1);
 895                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 896
 897                 // do flood control for the default line size
 898                 if(msgstr != "")
 899                 {
 900                         getWrappedLine_remaining = msgstr;
 901                         msgstr = "";
 902                         lines = 0;
 903                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 904                         {
 905                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 906                                 ++lines;
 907                         }
 908                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 909
 910                         if(getWrappedLine_remaining != "")
 911                         {
 912                                 msgstr = strcat(msgstr, "\n");
 913                                 flood = 2;
 914                         }
 915
 916                         if(time >= source.flood_field)
 917                         {
 918                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 919                         }
 920                         else
 921                         {
 922                                 flood = 1;
 923                                 msgstr = fullmsgstr;
 924                         }
 925                 }
 926                 else
 927                 {
 928                         if(time >= source.flood_field)
 929                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 930                         else
 931                                 flood = 1;
 932                 }
 933
 934                 if (timeoutStatus == 2) //when game is paused, no flood protection
 935                         source.flood_field = flood = 0;
 936         }
 937
 938         if(flood == 2) // cannot happen for empty msgstr
 939         {
 940                 if(autocvar_g_chat_flood_notify_flooder)
 941                 {
 942                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 943                         sourcecmsgstr = "";
 944                 }
 945                 else
 946                 {
 947                         sourcemsgstr = fullmsgstr;
 948                         sourcecmsgstr = fullcmsgstr;
 949                 }
 950                 cmsgstr = "";
 951         }
 952         else
 953         {
 954                 sourcemsgstr = msgstr;
 955                 sourcecmsgstr = cmsgstr;
 956         }
 957
 958         if(!privatesay)
 959         if(source.classname != "player")
 960         {
 961                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 962                         teamsay = -1; // spectators
 963         }
 964
 965         if(flood)
 966                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 967
 968         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 969         if(privatesay)
 970                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 971
 972         if(source.muted)
 973         {
 974                 // always fake the message
 975                 ret = -1;
 976         }
 977         else if(flood == 1)
 978         {
 979                 if(autocvar_g_chat_flood_notify_flooder)
 980                 {
 981                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 982                         ret = 0;
 983                 }
 984                 else
 985                         ret = -1;
 986         }
 987         else
 988         {
 989                 ret = 1;
 990         }
 991
 992         if(sourcemsgstr != "" && ret != 0)
 993         {
 994                 if(ret < 0) // fake
 995                 {
 996                         sprint(source, sourcemsgstr);
 997                         if(sourcecmsgstr != "" && !privatesay)
 998                                 centerprint(source, sourcecmsgstr);
 999                 }
1000                 else if(privatesay)
1001                 {
1002                         sprint(source, sourcemsgstr);
1003                         sprint(privatesay, msgstr);
1004                         if(cmsgstr != "")
1005                                 centerprint(privatesay, cmsgstr);
1006                 }
1007                 else if(teamsay > 0)
1008                 {
1009                         sprint(source, sourcemsgstr);
1010                         if(sourcecmsgstr != "")
1011                                 centerprint(source, sourcecmsgstr);
1012                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1013                                 if(head != source)
1014                                 {
1015                                         sprint(head, msgstr);
1016                                         if(cmsgstr != "")
1017                                                 centerprint(head, cmsgstr);
1018                                 }
1019                 }
1020                 else if(teamsay < 0)
1021                 {
1022                         sprint(source, sourcemsgstr);
1023                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1024                                 if(head != source)
1025                                         sprint(head, msgstr);
1026                 }
1027                 else if(sourcemsgstr != msgstr)
1028                 {
1029                         sprint(source, sourcemsgstr);
1030                         FOR_EACH_REALCLIENT(head)
1031                                 if(head != source)
1032                                         sprint(head, msgstr);
1033                 }
1034                 else
1035                         bprint(msgstr);
1036         }
1037
1038         return ret;
1039 }
1040
1041 float GetVoiceMessageVoiceType(string type)
1042 {
1043         if(type == "taunt")
1044                 return VOICETYPE_TAUNT;
1045         if(type == "teamshoot")
1046                 return VOICETYPE_LASTATTACKER;
1047         return VOICETYPE_TEAMRADIO;
1048 }
1049
1050 string allvoicesamples;
1051 .string GetVoiceMessageSampleField(string type)
1052 {
1053         GetPlayerSoundSampleField_notFound = 0;
1054         switch(type)
1055         {
1056 #define _VOICEMSG(m) case #m: return playersound_##m;
1057                 ALLVOICEMSGS
1058 #undef _VOICEMSG
1059         }
1060         GetPlayerSoundSampleField_notFound = 1;
1061         return playersound_taunt;
1062 }
1063
1064 .string GetPlayerSoundSampleField(string type)
1065 {
1066         GetPlayerSoundSampleField_notFound = 0;
1067         switch(type)
1068         {
1069 #define _VOICEMSG(m) case #m: return playersound_##m;
1070                 ALLPLAYERSOUNDS
1071 #undef _VOICEMSG
1072         }
1073         GetPlayerSoundSampleField_notFound = 1;
1074         return playersound_taunt;
1075 }
1076
1077 void PrecacheGlobalSound(string samplestring)
1078 {
1079         float n, i;
1080         tokenize_console(samplestring);
1081         n = stof(argv(1));
1082         if(n > 0)
1083         {
1084                 for(i = 1; i <= n; ++i)
1085                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1086         }
1087         else
1088         {
1089                 precache_sound(strcat(argv(0), ".wav"));
1090         }
1091 }
1092
1093 void PrecachePlayerSounds(string f)
1094 {
1095         float fh;
1096         string s;
1097         fh = fopen(f, FILE_READ);
1098         if(fh < 0)
1099                 return;
1100         while((s = fgets(fh)))
1101         {
1102                 if(tokenize_console(s) != 3)
1103                 {
1104                         dprint("Invalid sound info line: ", s, "\n");
1105                         continue;
1106                 }
1107                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1108         }
1109         fclose(fh);
1110
1111         if not(allvoicesamples)
1112         {
1113 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1114                 ALLVOICEMSGS
1115 #undef _VOICEMSG
1116                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1117         }
1118 }
1119
1120 void ClearPlayerSounds()
1121 {
1122 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1123         ALLPLAYERSOUNDS
1124         ALLVOICEMSGS
1125 #undef _VOICEMSG
1126 }
1127
1128 float LoadPlayerSounds(string f, float first)
1129 {
1130         float fh;
1131         string s;
1132         var .string field;
1133         fh = fopen(f, FILE_READ);
1134         if(fh < 0)
1135         {
1136                 dprint("Player sound file not found: ", f, "\n");
1137                 return 0;
1138         }
1139         while((s = fgets(fh)))
1140         {
1141                 if(tokenize_console(s) != 3)
1142                         continue;
1143                 field = GetPlayerSoundSampleField(argv(0));
1144                 if(GetPlayerSoundSampleField_notFound)
1145                         field = GetVoiceMessageSampleField(argv(0));
1146                 if(GetPlayerSoundSampleField_notFound)
1147                         continue;
1148                 if(self.field)
1149                         strunzone(self.field);
1150                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1151         }
1152         fclose(fh);
1153         return 1;
1154 }
1155
1156 .float modelindex_for_playersound;
1157 .float skinindex_for_playersound;
1158 void UpdatePlayerSounds()
1159 {
1160         if(self.modelindex == self.modelindex_for_playersound)
1161         if(self.skinindex == self.skinindex_for_playersound)
1162                 return;
1163         self.modelindex_for_playersound = self.modelindex;
1164         self.skinindex_for_playersound = self.skinindex;
1165         ClearPlayerSounds();
1166         LoadPlayerSounds("sound/player/default.sounds", 1);
1167         if(!autocvar_g_debug_defaultsounds)
1168                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1169                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1170 }
1171
1172 void FakeGlobalSound(string sample, float chan, float voicetype)
1173 {
1174         float n;
1175         float tauntrand;
1176
1177         if(sample == "")
1178                 return;
1179
1180         tokenize_console(sample);
1181         n = stof(argv(1));
1182         if(n > 0)
1183                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1184         else
1185                 sample = strcat(argv(0), ".wav"); // randomization
1186
1187         switch(voicetype)
1188         {
1189                 case VOICETYPE_LASTATTACKER_ONLY:
1190                         break;
1191                 case VOICETYPE_LASTATTACKER:
1192                         if(self.pusher)
1193                         {
1194                                 msg_entity = self;
1195                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1196                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1197                         }
1198                         break;
1199                 case VOICETYPE_TEAMRADIO:
1200                         msg_entity = self;
1201                         if(msg_entity.cvar_cl_voice_directional == 1)
1202                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1203                         else
1204                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1205                         break;
1206                 case VOICETYPE_AUTOTAUNT:
1207                         if(!sv_autotaunt)
1208                                 break;
1209                         if(!sv_taunt)
1210                                 break;
1211                         if(sv_gentle)
1212                                 break;
1213                         tauntrand = random();
1214                         msg_entity = self;
1215                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1216                         {
1217                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1218                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1219                                 else
1220                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1221                         }
1222                         break;
1223                 case VOICETYPE_TAUNT:
1224                         if(self.classname == "player")
1225                                 if(self.deadflag == DEAD_NO)
1226                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1227                         if(!sv_taunt)
1228                                 break;
1229                         if(sv_gentle)
1230                                 break;
1231                         msg_entity = self;
1232                         if (msg_entity.cvar_cl_voice_directional >= 1)
1233                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1234                         else
1235                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1236                         break;
1237                 case VOICETYPE_PLAYERSOUND:
1238                         msg_entity = self;
1239                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1240                         break;
1241                 default:
1242                         backtrace("Invalid voice type!");
1243                         break;
1244         }
1245 }
1246
1247 void GlobalSound(string sample, float chan, float voicetype)
1248 {
1249         float n;
1250         float tauntrand;
1251
1252         if(sample == "")
1253                 return;
1254
1255         tokenize_console(sample);
1256         n = stof(argv(1));
1257         if(n > 0)
1258                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1259         else
1260                 sample = strcat(argv(0), ".wav"); // randomization
1261
1262         switch(voicetype)
1263         {
1264                 case VOICETYPE_LASTATTACKER_ONLY:
1265                         if(self.pusher)
1266                         {
1267                                 msg_entity = self.pusher;
1268                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1269                                 {
1270                                         if(msg_entity.cvar_cl_voice_directional == 1)
1271                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1272                                         else
1273                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1274                                 }
1275                         }
1276                         break;
1277                 case VOICETYPE_LASTATTACKER:
1278                         if(self.pusher)
1279                         {
1280                                 msg_entity = self.pusher;
1281                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1282                                 {
1283                                         if(msg_entity.cvar_cl_voice_directional == 1)
1284                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1285                                         else
1286                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1287                                 }
1288                                 msg_entity = self;
1289                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1290                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1291                         }
1292                         break;
1293                 case VOICETYPE_TEAMRADIO:
1294                         FOR_EACH_REALCLIENT(msg_entity)
1295                                 if(!teamplay || msg_entity.team == self.team)
1296                                 {
1297                                         if(msg_entity.cvar_cl_voice_directional == 1)
1298                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1299                                         else
1300                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1301                                 }
1302                         break;
1303                 case VOICETYPE_AUTOTAUNT:
1304                         if(!sv_autotaunt)
1305                                 break;
1306                         if(!sv_taunt)
1307                                 break;
1308                         if(sv_gentle)
1309                                 break;
1310                         tauntrand = random();
1311                         FOR_EACH_REALCLIENT(msg_entity)
1312                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1313                                 {
1314                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1315                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1316                                         else
1317                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1318                                 }
1319                         break;
1320                 case VOICETYPE_TAUNT:
1321                         if(self.classname == "player")
1322                                 if(self.deadflag == DEAD_NO)
1323                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1324                         if(!sv_taunt)
1325                                 break;
1326                         if(sv_gentle)
1327                                 break;
1328                         FOR_EACH_REALCLIENT(msg_entity)
1329                         {
1330                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1331                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1332                                 else
1333                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1334                         }
1335                         break;
1336                 case VOICETYPE_PLAYERSOUND:
1337                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1338                         break;
1339                 default:
1340                         backtrace("Invalid voice type!");
1341                         break;
1342         }
1343 }
1344
1345 void PlayerSound(.string samplefield, float chan, float voicetype)
1346 {
1347         GlobalSound(self.samplefield, chan, voicetype);
1348 }
1349
1350 void VoiceMessage(string type, string msg)
1351 {
1352         var .string sample;
1353         float voicetype, ownteam;
1354         float flood;
1355         sample = GetVoiceMessageSampleField(type);
1356
1357         if(GetPlayerSoundSampleField_notFound)
1358         {
1359                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1360                 return;
1361         }
1362
1363         voicetype = GetVoiceMessageVoiceType(type);
1364         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1365
1366         flood = Say(self, ownteam, world, msg, 1);
1367
1368         if (flood > 0)
1369                 GlobalSound(self.sample, CH_VOICE, voicetype);
1370         else if (flood < 0)
1371                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1372 }
1373
1374 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1375 {
1376 //      show_message
1377 //      0 (00) automove centerprint, admin message
1378 //      1 (01) automove centerprint, no admin message
1379 //      2 (10) no centerprint, admin message
1380 //      3 (11) no centerprint, no admin message
1381
1382         float lockteams_backup;
1383
1384         lockteams_backup = lockteams;  // backup any team lock
1385
1386         lockteams = 0;  // disable locked teams
1387
1388         TeamchangeFrags(client);  // move the players frags
1389         SetPlayerColors(client, team_colour - 1);  // set the players colour
1390         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1391
1392         lockteams = lockteams_backup;  // restore the team lock
1393
1394         LogTeamchange(client.playerid, client.team, type);
1395
1396         if not(show_message & 1) // admin message
1397                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1398
1399         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1400 }