Merge remote-tracking branch 'origin/master' into fruitiex/animations
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 .float weapon_frametime;
11
12 float W_WeaponRateFactor()
13 {
14         float t;
15         t = 1.0 / g_weaponratefactor;
16
17         if(g_runematch)
18         {
19                 if(self.runes & RUNE_SPEED)
20                 {
21                         if(self.runes & CURSE_SLOW)
22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
23                         else
24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
25                 }
26                 else if(self.runes & CURSE_SLOW)
27                 {
28                         t = t * autocvar_g_balance_curse_slow_atkrate;
29                 }
30         }
31
32         return t;
33 }
34
35 void W_SwitchWeapon_Force(entity e, float w)
36 {
37         e.cnt = e.switchweapon;
38         e.switchweapon = w;
39         e.selectweapon = w;
40 }
41
42 .float antilag_debug;
43
44 // VorteX: static frame globals
45 float WFRAME_DONTCHANGE = -1;
46 float WFRAME_FIRE1 = 0;
47 float WFRAME_FIRE2 = 1;
48 float WFRAME_IDLE = 2;
49 float WFRAME_RELOAD = 3;
50 .float wframe;
51
52 void(float fr, float t, void() func) weapon_thinkf;
53
54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
55 {
56         vector ret;
57         ret_x = screenright * v;
58         ret_y = screenup * v;
59         ret_z = screenforward * v;
60         return ret;
61 }
62
63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
64 {
65         float i, j, k;
66         vector mi, ma, thisv, myv, ret;
67
68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
69
70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
71
72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
73         {
74                 thisv = targ.origin;
75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
79                 if(i || j || k)
80                 {
81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
84                 }
85                 else
86                 {
87                         // first run
88                         mi = ma = thisv;
89                 }
90         }
91
92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
95         ret_z = thisv_z - myv_z;
96         return ret;
97 }
98
99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
100 {
101         vector hitplot;
102         vector org;
103         float lag;
104
105         if(player.hitplotfh >= 0)
106         {
107                 lag = ANTILAG_LATENCY(player);
108                 if(lag < 0.001)
109                         lag = 0;
110                 if(clienttype(player) != CLIENTTYPE_REAL)
111                         lag = 0; // only antilag for clients
112
113                 org = player.origin + player.view_ofs;
114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
115                 if(trace_ent.flags & FL_CLIENT)
116                 {
117                         antilag_takeback(trace_ent, time - lag);
118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
119                         antilag_restore(trace_ent);
120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
122                 }
123         }
124 }
125
126 vector w_shotorg;
127 vector w_shotdir;
128 vector w_shotend;
129
130 // this function calculates w_shotorg and w_shotdir based on the weapon model
131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
132 // make sure you call makevectors first (FIXME?)
133 .float prevstrengthsound;
134 .float prevstrengthsoundattempt;
135 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
136 {
137         float nudge = 1; // added to traceline target and subtracted from result
138         local float oldsolid;
139         vector vecs, dv;
140         oldsolid = ent.dphitcontentsmask;
141         if(ent.weapon == WEP_RIFLE)
142                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
143         else
144                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
145         if(antilag)
146                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
147                 // passing world, because we do NOT want it to touch dphitcontentsmask
148         else
149                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
150         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
151
152         vector vf, vr, vu;
153         vf = v_forward;
154         vr = v_right;
155         vu = v_up;
156         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
157         v_forward = vf;
158         v_right = vr;
159         v_up = vu;
160
161         // un-adjust trueaim if shotend is too close
162         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
163                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
164
165         // track max damage
166         if(accuracy_canbegooddamage(ent))
167                 accuracy_add(ent, ent.weapon, maxdamage, 0);
168
169         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
170
171         if(ent.weaponentity.movedir_x > 0)
172                 vecs = ent.weaponentity.movedir;
173         else
174                 vecs = '0 0 0';
175         if(debug_shotorg != '0 0 0')
176                 vecs = debug_shotorg;
177
178         dv = v_right * -vecs_y + v_up * vecs_z;
179         w_shotorg = ent.origin + ent.view_ofs + dv;
180
181         // now move the shotorg forward as much as requested if possible
182         if(antilag)
183         {
184                 if(ent.antilag_debug)
185                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
186                 else
187                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
188         }
189         else
190                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
191         w_shotorg = trace_endpos - v_forward * nudge;
192         // calculate the shotdir from the chosen shotorg
193         w_shotdir = normalize(w_shotend - w_shotorg);
194
195         if (antilag)
196         if (!ent.cvar_cl_noantilag)
197         {
198                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
199                 {
200                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
201                         if (!trace_ent.takedamage)
202                         {
203                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
204                                 if (trace_ent.takedamage && trace_ent.classname == "player")
205                                 {
206                                         entity e;
207                                         e = trace_ent;
208                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
209                                         if(trace_ent == e)
210                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
211                                 }
212                         }
213                 }
214                 else if(autocvar_g_antilag == 3) // client side hitscan
215                 {
216                         // this part MUST use prydon cursor
217                         if (ent.cursor_trace_ent)                 // client was aiming at someone
218                         if (ent.cursor_trace_ent != ent)         // just to make sure
219                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
220                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
221                         {
222                                 // verify that the shot would miss without antilag
223                                 // (avoids an issue where guns would always shoot at their origin)
224                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
225                                 if (!trace_ent.takedamage)
226                                 {
227                                         // verify that the shot would hit if altered
228                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
229                                         if (trace_ent == ent.cursor_trace_ent)
230                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
231                                         else
232                                                 print("antilag fail\n");
233                                 }
234                         }
235                 }
236         }
237
238         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
239
240         if (!g_norecoil)
241                 ent.punchangle_x = recoil * -1;
242
243         if (snd != "")
244                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
245
246         if(ent.items & IT_STRENGTH)
247         if(!g_minstagib)
248         if(
249                 (time > ent.prevstrengthsound + autocvar_sv_strengthsound_antispam_time)
250                 ||
251                 (time > ent.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)
252         ) // prevent insane sound spam
253         {
254                 sound(ent, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
255                 ent.prevstrengthsound = time;
256         }
257         ent.prevstrengthsoundattempt = time;
258
259         // nudge w_shotend so a trace to w_shotend hits
260         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
261 };
262
263 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
264 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
265 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
266 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
267 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
268
269 float CL_Weaponentity_CustomizeEntityForClient()
270 {
271         self.viewmodelforclient = self.owner;
272         if(other.classname == "spectator")
273                 if(other.enemy == self.owner)
274                         self.viewmodelforclient = other;
275         return TRUE;
276 }
277
278 float qcweaponanimation;
279 vector weapon_offset = '0 -10 0';
280 vector weapon_adjust = '10 0 -15';
281 .vector weapon_morph0origin;
282 .vector weapon_morph0angles;
283 .float  weapon_morph0time;
284 .vector weapon_morph1origin;
285 .vector weapon_morph1angles;
286 .float  weapon_morph1time;
287 .vector weapon_morph2origin;
288 .vector weapon_morph2angles;
289 .float  weapon_morph2time;
290 .vector weapon_morph3origin;
291 .vector weapon_morph3angles;
292 .float  weapon_morph3time;
293 .vector weapon_morph4origin;
294 .vector weapon_morph4angles;
295 .float  weapon_morph4time;
296 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
297
298 /*
299  * supported formats:
300  *
301  * 1. simple animated model, muzzle flash handling on h_ model:
302  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
303  *      tags:
304  *        shot = muzzle end (shot origin, also used for muzzle flashes)
305  *        shell = casings ejection point (must be on the right hand side of the gun)
306  *        weapon = attachment for v_tuba.md3
307  *    v_tuba.md3 - first and third person model
308  *    g_tuba.md3 - pickup model
309  *
310  * 2. simple animated model, muzzle flash handling on v_ model:
311  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
312  *      tags:
313  *        weapon = attachment for v_tuba.md3
314  *    v_tuba.md3 - first and third person model
315  *      tags:
316  *        shot = muzzle end (shot origin, also used for muzzle flashes)
317  *        shell = casings ejection point (must be on the right hand side of the gun)
318  *    g_tuba.md3 - pickup model
319  *
320  * 3. fully animated model, muzzle flash handling on h_ model:
321  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
322  *      tags:
323  *        shot = muzzle end (shot origin, also used for muzzle flashes)
324  *        shell = casings ejection point (must be on the right hand side of the gun)
325  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
326  *    v_tuba.md3 - third person model
327  *    g_tuba.md3 - pickup model
328  *
329  * 4. fully animated model, muzzle flash handling on v_ model:
330  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
331  *      tags:
332  *        shot = muzzle end (shot origin)
333  *        shell = casings ejection point (must be on the right hand side of the gun)
334  *    v_tuba.md3 - third person model
335  *      tags:
336  *        shot = muzzle end (for muzzle flashes)
337  *    g_tuba.md3 - pickup model
338  */
339
340 // writes:
341 //   self.origin, self.angles
342 //   self.weaponentity
343 //   self.movedir, self.view_ofs
344 //   attachment stuff
345 //   anim stuff
346 // to free:
347 //   call again with ""
348 //   remove the ent
349 void CL_WeaponEntity_SetModel(string name)
350 {
351         string animfilename;
352         float animfile;
353         float v_shot_idx;
354         if (name != "")
355         {
356                 // if there is a child entity, hide it until we're sure we use it
357                 if (self.weaponentity)
358                         self.weaponentity.model = "";
359                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
360                 v_shot_idx = gettagindex(self, "shot"); // used later
361                 if(!v_shot_idx)
362                         v_shot_idx = gettagindex(self, "tag_shot");
363
364                 if(qcweaponanimation)
365                 {
366                         self.angles = '0 0 0';
367                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
368                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
369                         self.movedir_x += 32;
370                         self.spawnorigin = self.movedir;
371                         // oldorigin - not calculated here
372                 }
373                 else
374                 {
375                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
376                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
377                         animfile = fopen(animfilename, FILE_READ);
378                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
379                         self.anim_fire1  = '0 1 0.01';
380                         self.anim_fire2  = '1 1 0.01';
381                         self.anim_idle   = '2 1 0.01';
382                         self.anim_reload = '3 1 0.01';
383                         if (animfile >= 0)
384                         {
385                                 animparseerror = FALSE;
386                                 self.anim_fire1  = animparseline(animfile);
387                                 self.anim_fire2  = animparseline(animfile);
388                                 self.anim_idle   = animparseline(animfile);
389                                 self.anim_reload = animparseline(animfile);
390                                 fclose(animfile);
391                                 if (animparseerror)
392                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
393                         }
394
395                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
396                         // if we don't, this is a "real" animated model
397                         if(gettagindex(self, "weapon"))
398                         {
399                                 if (!self.weaponentity)
400                                         self.weaponentity = spawn();
401                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
402                                 setattachment(self.weaponentity, self, "weapon");
403                         }
404                         else if(gettagindex(self, "tag_weapon"))
405                         {
406                                 if (!self.weaponentity)
407                                         self.weaponentity = spawn();
408                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
409                                 setattachment(self.weaponentity, self, "tag_weapon");
410                         }
411                         else
412                         {
413                                 if(self.weaponentity)
414                                         remove(self.weaponentity);
415                                 self.weaponentity = world;
416                         }
417
418                         setorigin(self,'0 0 0');
419                         self.angles = '0 0 0';
420                         self.frame = 0;
421                         self.viewmodelforclient = world;
422
423                         float idx;
424
425                         if(v_shot_idx) // v_ model attached to invisible h_ model
426                         {
427                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
428                         }
429                         else
430                         {
431                                 idx = gettagindex(self, "shot");
432                                 if(!idx)
433                                         idx = gettagindex(self, "tag_shot");
434                                 if(idx)
435                                         self.movedir = gettaginfo(self, idx);
436                                 else
437                                 {
438                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
439                                         self.movedir = '0 0 0';
440                                 }
441                         }
442
443                         if(self.weaponentity) // v_ model attached to invisible h_ model
444                         {
445                                 idx = gettagindex(self.weaponentity, "shell");
446                                 if(!idx)
447                                         idx = gettagindex(self.weaponentity, "tag_shell");
448                                 if(idx)
449                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
450                         }
451                         else
452                                 idx = 0;
453                         if(!idx)
454                         {
455                                 idx = gettagindex(self, "shell");
456                                 if(!idx)
457                                         idx = gettagindex(self, "tag_shell");
458                                 if(idx)
459                                         self.spawnorigin = gettaginfo(self, idx);
460                                 else
461                                 {
462                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
463                                         self.spawnorigin = self.movedir;
464                                 }
465                         }
466
467                         if(v_shot_idx)
468                         {
469                                 self.oldorigin = '0 0 0'; // use regular attachment
470                         }
471                         else
472                         {
473                                 if(self.weaponentity)
474                                 {
475                                         idx = gettagindex(self, "weapon");
476                                         if(!idx)
477                                                 idx = gettagindex(self, "tag_weapon");
478                                 }
479                                 else
480                                 {
481                                         idx = gettagindex(self, "handle");
482                                         if(!idx)
483                                                 idx = gettagindex(self, "tag_handle");
484                                 }
485                                 if(idx)
486                                 {
487                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
488                                 }
489                                 else
490                                 {
491                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
492                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
493                                 }
494                         }
495
496                         self.viewmodelforclient = self.owner;
497                 }
498         }
499         else
500         {
501                 self.model = "";
502                 if(self.weaponentity)
503                         remove(self.weaponentity);
504                 self.weaponentity = world;
505                 self.movedir = '0 0 0';
506                 self.spawnorigin = '0 0 0';
507                 self.oldorigin = '0 0 0';
508                 self.anim_fire1  = '0 1 0.01';
509                 self.anim_fire2  = '0 1 0.01';
510                 self.anim_idle   = '0 1 0.01';
511                 self.anim_reload = '0 1 0.01';
512         }
513
514         self.view_ofs = '0 0 0';
515
516         if(self.movedir_x >= 0)
517         {
518                 vector v0;
519                 v0 = self.movedir;
520                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
521                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
522         }
523         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
524         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
525
526         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
527
528         // check if an instant weapon switch occurred
529         if (qcweaponanimation)
530         {
531                 if (self.state == WS_READY)
532                 {
533                         self.angles = '0 0 0';
534                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
535                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
536                 }
537         }
538         else
539                 setorigin(self, self.view_ofs);
540         // reset animstate now
541         self.wframe = WFRAME_IDLE;
542         self.weapon_morph0time = 0;
543         self.weapon_morph1time = 0;
544         self.weapon_morph2time = 0;
545         self.weapon_morph3time = 0;
546         self.weapon_morph4time = 0;
547         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
548 }
549
550 vector CL_Weapon_GetShotOrg(float wpn)
551 {
552         entity wi, oldself;
553         vector ret;
554         wi = get_weaponinfo(wpn);
555         oldself = self;
556         self = spawn();
557         CL_WeaponEntity_SetModel(wi.mdl);
558         ret = self.movedir;
559         CL_WeaponEntity_SetModel("");
560         remove(self);
561         self = oldself;
562         return ret;
563 }
564
565 void CL_Weaponentity_Think()
566 {
567         float tb;
568         self.nextthink = time;
569         if (intermission_running)
570                 self.frame = self.anim_idle_x;
571         if (self.owner.weaponentity != self)
572         {
573                 if (self.weaponentity)
574                         remove(self.weaponentity);
575                 remove(self);
576                 return;
577         }
578         if (self.owner.deadflag != DEAD_NO)
579         {
580                 self.model = "";
581                 if (self.weaponentity)
582                         self.weaponentity.model = "";
583                 return;
584         }
585         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
586         {
587                 self.weaponname = self.owner.weaponname;
588                 self.dmg = self.owner.modelindex;
589                 self.deadflag = self.owner.deadflag;
590
591                 CL_WeaponEntity_SetModel(self.owner.weaponname);
592         }
593
594         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
595         self.effects = self.owner.effects & EFMASK_CHEAP;
596         self.effects &~= EF_LOWPRECISION;
597         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
598         self.effects &~= EF_TELEPORT_BIT;
599         self.effects &~= EF_RESTARTANIM_BIT;
600         self.effects |= tb;
601
602         if(self.owner.alpha == default_player_alpha)
603                 self.alpha = default_weapon_alpha;
604         else if(self.owner.alpha != 0)
605                 self.alpha = self.owner.alpha;
606         else
607                 self.alpha = 1;
608
609         self.glowmod = self.owner.weaponentity_glowmod;
610         self.colormap = self.owner.colormap;
611         if (self.weaponentity)
612         {
613                 self.weaponentity.effects = self.effects;
614                 self.weaponentity.alpha = self.alpha;
615                 self.weaponentity.colormap = self.colormap;
616                 self.weaponentity.glowmod = self.glowmod;
617         }
618
619         self.angles = '0 0 0';
620         local float f;
621         f = 0;
622         if (self.state == WS_RAISE && !intermission_running)
623         {
624                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
625                 self.angles_x = -90 * f * f;
626                 if (qcweaponanimation)
627                 {
628                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
629                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
630                 }
631         }
632         else if (self.state == WS_DROP && !intermission_running)
633         {
634                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
635                 self.angles_x = -90 * f * f;
636                 if (qcweaponanimation)
637                 {
638                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
639                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
640                 }
641         }
642         else if (self.state == WS_CLEAR)
643         {
644                 f = 1;
645                 self.angles_x = -90 * f * f;
646                 if (qcweaponanimation)
647                 {
648                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
649                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
650                 }
651         }
652         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
653         {
654                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
655                 f = 1 - pow(1 - f, 3);
656                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
657                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
658         }
659         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
660         {
661                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
662                 f = 1 - pow(1 - f, 3);
663                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
664                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
665         }
666         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
667         {
668                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
669                 f = 1 - pow(1 - f, 3);
670                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
671                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
672         }
673         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
674         {
675                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
676                 f = 1 - pow(1 - f, 3);
677                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
678                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
679         }
680         else if (qcweaponanimation)
681         {
682                 // begin a new idle morph
683                 self.owner.weapon_morph0time   = time;
684                 self.owner.weapon_morph0angles = self.angles;
685                 self.owner.weapon_morph0origin = self.origin;
686
687                 float r;
688                 float t;
689
690                 r = random();
691                 if (r < 0.1)
692                 {
693                         // turn gun to the left to look at it
694                         t = 2;
695                         self.owner.weapon_morph1time   = time + t * 0.2;
696                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
697                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
698                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
699
700                         self.owner.weapon_morph2time   = time + t * 0.6;
701                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
702                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
703                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
704
705                         self.owner.weapon_morph3time   = time + t;
706                         self.owner.weapon_morph3angles = '0 0 0';
707                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
708                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
709                 }
710                 else if (r < 0.2)
711                 {
712                         // raise the gun a bit
713                         t = 2;
714                         self.owner.weapon_morph1time   = time + t * 0.2;
715                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
716                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
717                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
718
719                         self.owner.weapon_morph2time   = time + t * 0.5;
720                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
721                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
722                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
723
724                         self.owner.weapon_morph3time   = time + t;
725                         self.owner.weapon_morph3angles = '0 0 0';
726                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
727                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
728                 }
729                 else if (r < 0.3)
730                 {
731                         // tweak it a bit
732                         t = 5;
733                         self.owner.weapon_morph1time   = time + t * 0.3;
734                         self.owner.weapon_morph1angles = randomvec() * 6;
735                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
736                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
737
738                         self.owner.weapon_morph2time   = time + t * 0.7;
739                         self.owner.weapon_morph2angles = randomvec() * 6;
740                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
741                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
742
743                         self.owner.weapon_morph3time   = time + t;
744                         self.owner.weapon_morph3angles = '0 0 0';
745                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
746                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
747                 }
748                 else
749                 {
750                         // hold it mostly steady
751                         t = random() * 6 + 4;
752                         self.owner.weapon_morph1time   = time + t * 0.2;
753                         self.owner.weapon_morph1angles = randomvec() * 1;
754                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
755                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
756
757                         self.owner.weapon_morph2time   = time + t * 0.5;
758                         self.owner.weapon_morph2angles = randomvec() * 1;
759                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
760                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
761
762                         self.owner.weapon_morph3time   = time + t * 0.7;
763                         self.owner.weapon_morph3angles = randomvec() * 1;
764                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
765                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
766                 }
767
768                 self.owner.weapon_morph4time   = time + t;
769                 self.owner.weapon_morph4angles = '0 0 0';
770                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
771                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
772
773         }
774 };
775
776 void CL_ExteriorWeaponentity_Think()
777 {
778         float tag_found;
779         vector ang;
780         self.nextthink = time;
781         if (self.owner.exteriorweaponentity != self)
782         {
783                 remove(self);
784                 return;
785         }
786         if (self.owner.deadflag != DEAD_NO)
787         {
788                 self.model = "";
789                 return;
790         }
791         if (self.weaponname != self.owner.weaponname || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
792         {
793                 self.weaponname = self.owner.weaponname;
794                 self.dmg = self.owner.modelindex;
795                 self.deadflag = self.owner.deadflag;
796                 if (self.owner.weaponname != "")
797                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
798                 else
799                         self.model = "";
800
801                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
802                 {
803                         self.tag_index = tag_found;
804                         self.tag_entity = self.owner;
805                 }
806                 else
807                         setattachment(self, self.owner, "bip01 r hand");
808
809                 // if that didn't find a tag, hide the exterior weapon model
810                 if (!self.tag_index)
811                         self.model = "";
812         }
813         self.effects = self.owner.effects;
814         if(sv_pitch_min == sv_pitch_max)
815                 self.effects |= EF_LOWPRECISION;
816         else
817                 self.effects &~= EF_LOWPRECISION;
818         self.effects = self.effects & EFMASK_CHEAP; // eat performance
819         if(self.owner.alpha == default_player_alpha)
820                 self.alpha = default_weapon_alpha;
821         else if(self.owner.alpha != 0)
822                 self.alpha = self.owner.alpha;
823         else
824                 self.alpha = 1;
825
826         if (!intermission_running)
827         {
828                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
829                 ang_y = 0;
830                 ang_z = 0;
831
832                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
833                 {
834                         ang_y = self.owner.v_angle_y;
835                         makevectors(ang);
836                         var vector v = v_forward;
837                         var float t = self.tag_entity.frame1time;
838                         var float f = self.tag_entity.frame;
839                         self.tag_entity.frame1time = time;
840                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
841                         gettaginfo(self.tag_entity, self.tag_index);
842                         self.tag_entity.frame1time = t;
843                         self.tag_entity.frame = f;
844                         // untransform v according to this coordinate space
845                         vector w;
846                         w_x = v_forward * v;
847                         w_y = -v_right * v;
848                         w_z = v_up * v;
849                         self.angles = vectoangles(w);
850                 }
851                 else
852                 {
853                         ang_x = -/* don't ask */ang_x;
854                         self.angles = ang;
855                 }
856         }
857
858         self.glowmod = self.owner.weaponentity_glowmod;
859         self.colormap = self.owner.colormap;
860 };
861
862 // spawning weaponentity for client
863 void CL_SpawnWeaponentity()
864 {
865         self.weaponentity = spawn();
866         self.weaponentity.classname = "weaponentity";
867         self.weaponentity.solid = SOLID_NOT;
868         self.weaponentity.owner = self;
869         setmodel(self.weaponentity, ""); // precision set when changed
870         setorigin(self.weaponentity, '0 0 0');
871         self.weaponentity.angles = '0 0 0';
872         self.weaponentity.viewmodelforclient = self;
873         self.weaponentity.flags = 0;
874         self.weaponentity.think = CL_Weaponentity_Think;
875         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
876         self.weaponentity.nextthink = time;
877
878         self.exteriorweaponentity = spawn();
879         self.exteriorweaponentity.classname = "exteriorweaponentity";
880         self.exteriorweaponentity.solid = SOLID_NOT;
881         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
882         self.exteriorweaponentity.owner = self;
883         setorigin(self.exteriorweaponentity, '0 0 0');
884         self.exteriorweaponentity.angles = '0 0 0';
885         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
886         self.exteriorweaponentity.nextthink = time;
887 };
888
889 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
890 {
891         msg_entity = e;
892         WriteByte(MSG_ONE, SVC_TEMPENTITY);
893         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
894         WriteByte(MSG_ONE, wpn);
895         WriteString(MSG_ONE, wpnname);
896         WriteByte(MSG_ONE, type);
897 }
898
899 .float hasweapon_complain_spam;
900
901 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
902 {
903         local float weaponbit, f;
904         local entity oldself;
905
906         if(time < self.hasweapon_complain_spam)
907                 complain = 0;
908         if(complain)
909                 self.hasweapon_complain_spam = time + 0.2;
910
911         if (wpn < WEP_FIRST || wpn > WEP_LAST)
912         {
913                 if (complain)
914                         sprint(self, "Invalid weapon\n");
915                 return FALSE;
916         }
917         weaponbit = W_WeaponBit(wpn);
918         if (cl.weapons & weaponbit)
919         {
920                 if (andammo)
921                 {
922                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
923                         {
924                                 f = 1;
925                         }
926                         else
927                         {
928                                 oldself = self;
929                                 self = cl;
930                                 f = weapon_action(wpn, WR_CHECKAMMO1);
931                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
932
933                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
934                                 local entity mine;
935                                 if(wpn == WEP_MINE_LAYER)
936                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
937                                         f = 1;
938
939                                 self = oldself;
940                         }
941                         if (!f)
942                         {
943                                 if (complain)
944                                 if(clienttype(cl) == CLIENTTYPE_REAL)
945                                 {
946                                         play2(cl, "weapons/unavailable.wav");
947                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
948                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
949                                 }
950                                 return FALSE;
951                         }
952                 }
953                 return TRUE;
954         }
955         if (complain)
956         {
957                 // DRESK - 3/16/07
958                 // Report Proper Weapon Status / Modified Weapon Ownership Message
959                 if(weaponsInMap & weaponbit)
960                 {
961                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
962                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
963
964                         if(autocvar_g_showweaponspawns)
965                         {
966                                 entity e;
967                                 string s;
968
969                                 e = get_weaponinfo(wpn);
970                                 s = e.model2;
971
972                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
973                                 {
974                                         if(e.classname == "droppedweapon")
975                                                 continue;
976                                         if not(e.flags & FL_ITEM)
977                                                 continue;
978                                         WaypointSprite_Spawn(
979                                                 s,
980                                                 1, 0,
981                                                 world, e.origin,
982                                                 self, 0,
983                                                 world, enemy,
984                                                 0,
985                                                 RADARICON_NONE, '0 0 0'
986                                         );
987                                 }
988                         }
989                 }
990                 else
991                 {
992                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
993                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
994                 }
995
996                 play2(cl, "weapons/unavailable.wav");
997         }
998         return FALSE;
999 };
1000
1001 // Weapon subs
1002 void w_clear()
1003 {
1004         if (self.weapon != -1)
1005         {
1006                 self.weapon = 0;
1007                 self.switchingweapon = 0;
1008         }
1009         if (self.weaponentity)
1010         {
1011                 self.weaponentity.state = WS_CLEAR;
1012                 self.weaponentity.effects = 0;
1013         }
1014 };
1015
1016 void w_ready()
1017 {
1018         if (self.weaponentity)
1019                 self.weaponentity.state = WS_READY;
1020         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1021 };
1022
1023 // Setup weapon for client (after this raise frame will be launched)
1024 void weapon_setup(float windex)
1025 {
1026         entity e;
1027         qcweaponanimation = autocvar_sv_qcweaponanimation;
1028         e = get_weaponinfo(windex);
1029         self.items &~= IT_AMMO;
1030         self.items = self.items | e.items;
1031
1032         // the two weapon entities will notice this has changed and update their models
1033         self.weapon = windex;
1034         self.switchingweapon = windex; // to make sure
1035         self.weaponname = e.mdl;
1036         self.bulletcounter = 0;
1037 };
1038
1039 // perform weapon to attack (weaponstate and attack_finished check is here)
1040 void W_SwitchToOtherWeapon(entity pl)
1041 {
1042         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1043         float w, ww;
1044         w = W_WeaponBit(pl.weapon);
1045         pl.weapons &~= w;
1046         ww = w_getbestweapon(pl);
1047         pl.weapons |= w;
1048         if(ww)
1049                 W_SwitchWeapon_Force(pl, ww);
1050 }
1051 .float prevdryfire;
1052 float weapon_prepareattack_checkammo(float secondary)
1053 {
1054         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1055         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1056         {
1057                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1058                 local entity mine;
1059                 if(self.weapon == WEP_MINE_LAYER)
1060                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1061                         return FALSE;
1062
1063                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1064                 {
1065                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1066                         self.prevdryfire = time;
1067                 }
1068
1069                 W_SwitchToOtherWeapon(self);
1070                 return FALSE;
1071         }
1072         return TRUE;
1073 }
1074 .float race_penalty;
1075 float weapon_prepareattack_check(float secondary, float attacktime)
1076 {
1077         if(!weapon_prepareattack_checkammo(secondary))
1078                 return FALSE;
1079
1080         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1081         //if all players readied up and the countdown is running
1082         if(time < game_starttime || time < self.race_penalty) {
1083                 return FALSE;
1084         }
1085
1086         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1087                 return FALSE;
1088
1089         // do not even think about shooting if switching
1090         if(self.switchweapon != self.weapon)
1091                 return FALSE;
1092
1093         if(attacktime >= 0)
1094         {
1095                 // don't fire if previous attack is not finished
1096                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1097                         return FALSE;
1098                 // don't fire while changing weapon
1099                 if (self.weaponentity.state != WS_READY)
1100                         return FALSE;
1101         }
1102
1103         return TRUE;
1104 }
1105 float weapon_prepareattack_do(float secondary, float attacktime)
1106 {
1107         self.weaponentity.state = WS_INUSE;
1108
1109         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1110
1111         // if the weapon hasn't been firing continuously, reset the timer
1112         if(attacktime >= 0)
1113         {
1114                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1115                 {
1116                         ATTACK_FINISHED(self) = time;
1117                         //dprint("resetting attack finished to ", ftos(time), "\n");
1118                 }
1119                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1120         }
1121         self.bulletcounter += 1;
1122         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1123         return TRUE;
1124 }
1125 float weapon_prepareattack(float secondary, float attacktime)
1126 {
1127         if(weapon_prepareattack_check(secondary, attacktime))
1128         {
1129                 weapon_prepareattack_do(secondary, attacktime);
1130                 return TRUE;
1131         }
1132         else
1133                 return FALSE;
1134 }
1135
1136 void weapon_thinkf(float fr, float t, void() func)
1137 {
1138         vector a;
1139         vector of, or, ou;
1140         float restartanim;
1141
1142         if(fr == WFRAME_DONTCHANGE)
1143         {
1144                 fr = self.weaponentity.wframe;
1145                 restartanim = FALSE;
1146         }
1147         else if (fr == WFRAME_IDLE)
1148                 restartanim = FALSE;
1149         else
1150                 restartanim = TRUE;
1151
1152         of = v_forward;
1153         or = v_right;
1154         ou = v_up;
1155
1156         if (self.weaponentity)
1157         {
1158                 self.weaponentity.wframe = fr;
1159                 if (qcweaponanimation)
1160                 {
1161                         if (fr != WFRAME_IDLE)
1162                         {
1163                                 self.weapon_morph0time = time;
1164                                 self.weapon_morph0angles = self.weaponentity.angles;
1165                                 self.weapon_morph0origin = self.weaponentity.origin;
1166
1167                                 self.weapon_morph1angles = '0 0 0';
1168                                 self.weapon_morph1time = time + t;
1169                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1170                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1171
1172                                 self.weapon_morph2angles = '0 0 0';
1173                                 self.weapon_morph2time = time + t;
1174                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1175                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1176
1177                                 self.weapon_morph3angles = '0 0 0';
1178                                 self.weapon_morph3time = time + t;
1179                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1180                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1181
1182                                 self.weapon_morph4angles = '0 0 0';
1183                                 self.weapon_morph4time = time + t;
1184                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1185                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1186
1187                                 if (fr == WFRAME_FIRE1)
1188                                 {
1189                                         self.weapon_morph1angles = '5 0 0';
1190                                         self.weapon_morph1time = time + t * 0.1;
1191                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1192                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1193                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1194                                 }
1195                                 else if (fr == WFRAME_FIRE2)
1196                                 {
1197                                         self.weapon_morph1angles = '10 0 0';
1198                                         self.weapon_morph1time = time + t * 0.1;
1199                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1200                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1201                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1202                                 }
1203                                 else if (fr == WFRAME_RELOAD)
1204                                 {
1205                                         self.weapon_morph1time = time + t * 0.05;
1206                                         self.weapon_morph1angles = '-10 40 0';
1207                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1208                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1209
1210                                         self.weapon_morph2time = time + t * 0.15;
1211                                         self.weapon_morph2angles = '-10 40 5';
1212                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1213                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1214
1215                                         self.weapon_morph3time = time + t * 0.25;
1216                                         self.weapon_morph3angles = '-10 40 0';
1217                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1218                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1219                                 }
1220                         }
1221                 }
1222                 else
1223                 {
1224                         if (fr == WFRAME_IDLE)
1225                                 a = self.weaponentity.anim_idle;
1226                         else if (fr == WFRAME_FIRE1)
1227                                 a = self.weaponentity.anim_fire1;
1228                         else if (fr == WFRAME_FIRE2)
1229                                 a = self.weaponentity.anim_fire2;
1230                         else if (fr == WFRAME_RELOAD)
1231                                 a = self.weaponentity.anim_reload;
1232                         a_z *= g_weaponratefactor;
1233                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1234                 }
1235         }
1236
1237         v_forward = of;
1238         v_right = or;
1239         v_up = ou;
1240
1241         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1242         {
1243                 backtrace("Tried to override initial weapon think function - should this really happen?");
1244         }
1245
1246         t *= W_WeaponRateFactor();
1247
1248         // VorteX: haste can be added here
1249         if (self.weapon_think == w_ready)
1250         {
1251                 self.weapon_nextthink = time;
1252                 //dprint("started firing at ", ftos(time), "\n");
1253         }
1254         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1255         {
1256                 self.weapon_nextthink = time;
1257                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1258         }
1259         self.weapon_nextthink = self.weapon_nextthink + t;
1260         self.weapon_think = func;
1261         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1262
1263         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1264         //anim = self.anim_shoot;
1265         if (restartanim)
1266         if (t)
1267         if (!self.crouch) // shoot anim stands up, this looks bad
1268         {
1269                 vector anim;
1270                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1271                 {
1272                         anim = self.anim_melee;
1273                         anim_z = anim_y / (t + sys_frametime);
1274                         setanim(self, anim, FALSE, TRUE, TRUE);
1275                 }
1276                 else if (self.animstate_startframe == self.anim_idle_x) // only allow shoot anim to override idle animation until we have animation blending
1277                 {
1278                         anim = self.anim_shoot;
1279                         anim_z = anim_y / (t + sys_frametime);
1280                         setanim(self, anim, FALSE, TRUE, TRUE);
1281                 }
1282         }
1283 };
1284
1285 void weapon_boblayer1(float spd, vector org)
1286 {
1287         // VorteX: haste can be added here
1288 };
1289
1290 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1291 {
1292         vector mdirection;
1293         float mspeed;
1294         float outspeed;
1295         float nstyle;
1296         vector outvelocity;
1297
1298         mvelocity = mvelocity * g_weaponspeedfactor;
1299
1300         mdirection = normalize(mvelocity);
1301         mspeed = vlen(mvelocity);
1302
1303         nstyle = autocvar_g_projectiles_newton_style;
1304         if(nstyle == 0 || forceAbsolute)
1305         {
1306                 // absolute velocity
1307                 outvelocity = mvelocity;
1308         }
1309         else if(nstyle == 1)
1310         {
1311                 // true Newtonian projectiles
1312                 outvelocity = pvelocity + mvelocity;
1313         }
1314         else if(nstyle == 2)
1315         {
1316                 // true Newtonian projectiles with automatic aim adjustment
1317                 //
1318                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1319                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1320                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1321                 // PLUS SIGN!
1322                 // not defined?
1323                 // then...
1324                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1325                 // velocity without mdirection component > mspeed
1326                 // fire at smallest possible mspeed that works?
1327                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1328
1329                 vector solution;
1330                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1331                 if(solution_z)
1332                         outspeed = solution_y; // the larger one
1333                 else
1334                 {
1335                         //outspeed = 0; // slowest possible shot
1336                         outspeed = solution_x; // the real part (that is, the average!)
1337                         //dprint("impossible shot, adjusting\n");
1338                 }
1339
1340                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1341                 outvelocity = mdirection * outspeed;
1342         }
1343         else if(nstyle == 3)
1344         {
1345                 // pseudo-Newtonian:
1346                 outspeed = mspeed + mdirection * pvelocity;
1347                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1348                 outvelocity = mdirection * outspeed;
1349         }
1350         else if(nstyle == 4)
1351         {
1352                 // tZorkian:
1353                 outspeed = mspeed + vlen(pvelocity);
1354                 outvelocity = mdirection * outspeed;
1355         }
1356         else
1357                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1358
1359         return outvelocity;
1360 }
1361
1362 void W_AttachToShotorg(entity flash, vector offset)
1363 {
1364         entity xflash;
1365         flash.owner = self;
1366         flash.angles_z = random() * 360;
1367         if(qcweaponanimation)
1368         {
1369                 setorigin(flash, w_shotorg + w_shotdir * 50);
1370                 flash.angles = vectoangles(w_shotdir);
1371                 flash.angles_z = random() * 360;
1372         }
1373         else
1374         {
1375                 if(gettagindex(self.weaponentity, "shot"))
1376                         setattachment(flash, self.weaponentity, "shot");
1377                 else
1378                         setattachment(flash, self.weaponentity, "tag_shot");
1379                 setorigin(flash, offset);
1380
1381                 xflash = spawn();
1382                 copyentity(flash, xflash);
1383
1384                 flash.viewmodelforclient = self;
1385
1386                 if(self.weaponentity.oldorigin_x > 0)
1387                 {
1388                         setattachment(xflash, self.exteriorweaponentity, "");
1389                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1390                 }
1391                 else
1392                 {
1393                         if(gettagindex(self.exteriorweaponentity, "shot"))
1394                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1395                         else
1396                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1397                         setorigin(xflash, offset);
1398                 }
1399         }
1400 }
1401
1402 vector cliptoplane(vector v, vector p)
1403 {
1404         return v - (v * p) * p;
1405 }
1406
1407 vector solve_cubic_pq(float p, float q)
1408 {
1409         float D, u, v, a;
1410         D = q*q/4.0 + p*p*p/27.0;
1411         if(D < 0)
1412         {
1413                 // irreducibilis
1414                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1415                 u = sqrt(-4.0/3.0 * p);
1416                 // a in range 0..pi/3
1417                 // cos(a)
1418                 // cos(a + 2pi/3)
1419                 // cos(a + 4pi/3)
1420                 return
1421                         u *
1422                         (
1423                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1424                                 +
1425                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1426                                 +
1427                                 '0 0 1' * cos(a)
1428                         );
1429         }
1430         else if(D == 0)
1431         {
1432                 // simple
1433                 if(p == 0)
1434                         return '0 0 0';
1435                 u = 3*q/p;
1436                 v = -u/2;
1437                 if(u >= v)
1438                         return '1 1 0' * v + '0 0 1' * u;
1439                 else
1440                         return '0 1 1' * v + '1 0 0' * u;
1441         }
1442         else
1443         {
1444                 // cardano
1445                 u = cbrt(-q/2.0 + sqrt(D));
1446                 v = cbrt(-q/2.0 - sqrt(D));
1447                 return '1 1 1' * (u + v);
1448         }
1449 }
1450 vector solve_cubic_abcd(float a, float b, float c, float d)
1451 {
1452         // y = 3*a*x + b
1453         // x = (y - b) / 3a
1454         float p, q;
1455         vector v;
1456         p = (9*a*c - 3*b*b);
1457         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1458         v = solve_cubic_pq(p, q);
1459         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1460         if(a < 0)
1461                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1462         return v;
1463 }
1464
1465 vector findperpendicular(vector v)
1466 {
1467         vector p;
1468         p_x = v_z;
1469         p_y = -v_x;
1470         p_z = v_y;
1471         return normalize(cliptoplane(p, v));
1472 }
1473
1474 vector W_CalculateProjectileSpread(vector forward, float spread)
1475 {
1476         float sigma;
1477         vector v1, v2;
1478         float dx, dy, r;
1479         float sstyle;
1480         spread *= g_weaponspreadfactor;
1481         if(spread <= 0)
1482                 return forward;
1483         sstyle = autocvar_g_projectiles_spread_style;
1484         
1485         if(sstyle == 0)
1486         {
1487                 // this is the baseline for the spread value!
1488                 // standard deviation: sqrt(2/5)
1489                 // density function: sqrt(1-r^2)
1490                 return forward + randomvec() * spread;
1491         }
1492         else if(sstyle == 1)
1493         {
1494                 // same thing, basically
1495                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1496         }
1497         else if(sstyle == 2)
1498         {
1499                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1500                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1501                 v1 = findperpendicular(forward);
1502                 v2 = cross(forward, v1);
1503                 // random point on unit circle
1504                 dx = random() * 2 * M_PI;
1505                 dy = sin(dx);
1506                 dx = cos(dx);
1507                 // radius in our dist function
1508                 r = random();
1509                 r = sqrt(r);
1510                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1511         }
1512         else if(sstyle == 3) // gauss 3d
1513         {
1514                 sigma = spread * 0.44721359549996; // match baseline stddev
1515                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1516                 v1 = forward;
1517                 v1_x += gsl_ran_gaussian(sigma);
1518                 v1_y += gsl_ran_gaussian(sigma);
1519                 v1_z += gsl_ran_gaussian(sigma);
1520                 return v1;
1521         }
1522         else if(sstyle == 4) // gauss 2d
1523         {
1524                 sigma = spread * 0.44721359549996; // match baseline stddev
1525                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1526                 v1_x = gsl_ran_gaussian(sigma);
1527                 v1_y = gsl_ran_gaussian(sigma);
1528                 v1_z = gsl_ran_gaussian(sigma);
1529                 return normalize(forward + cliptoplane(v1, forward));
1530         }
1531         else if(sstyle == 5) // 1-r
1532         {
1533                 sigma = spread * 1.154700538379252; // match baseline stddev
1534                 v1 = findperpendicular(forward);
1535                 v2 = cross(forward, v1);
1536                 // random point on unit circle
1537                 dx = random() * 2 * M_PI;
1538                 dy = sin(dx);
1539                 dx = cos(dx);
1540                 // radius in our dist function
1541                 r = random();
1542                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1543                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1544         }
1545         else if(sstyle == 6) // 1-r^2
1546         {
1547                 sigma = spread * 1.095445115010332; // match baseline stddev
1548                 v1 = findperpendicular(forward);
1549                 v2 = cross(forward, v1);
1550                 // random point on unit circle
1551                 dx = random() * 2 * M_PI;
1552                 dy = sin(dx);
1553                 dx = cos(dx);
1554                 // radius in our dist function
1555                 r = random();
1556                 r = sqrt(1 - r);
1557                 r = sqrt(1 - r);
1558                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1559         }
1560         else if(sstyle == 7) // (1-r) (2-r)
1561         {
1562                 sigma = spread * 1.224744871391589; // match baseline stddev
1563                 v1 = findperpendicular(forward);
1564                 v2 = cross(forward, v1);
1565                 // random point on unit circle
1566                 dx = random() * 2 * M_PI;
1567                 dy = sin(dx);
1568                 dx = cos(dx);
1569                 // radius in our dist function
1570                 r = random();
1571                 r = 1 - sqrt(r);
1572                 r = 1 - sqrt(r);
1573                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1574         }
1575         else
1576                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1577         return '0 0 0';
1578         /*
1579          * how to derive falloff functions:
1580          * rho(r) := (2-r) * (1-r);
1581          * a : 0;
1582          * b : 1;
1583          * rhor(r) := r * rho(r);
1584          * cr(t) := integrate(rhor(r), r, a, t);
1585          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1586          * variance : scr(b) / cr(b);
1587          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1588          * sqrt(0.4 / variance), numer;
1589          */
1590 }
1591
1592 #if 0
1593 float mspercallsum;
1594 float mspercallsstyle;
1595 float mspercallcount;
1596 #endif
1597 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1598 {
1599         if(missile.owner == world)
1600                 error("Unowned missile");
1601
1602         dir = dir + upDir * (pUpSpeed / pSpeed);
1603         dir_z += pZSpeed / pSpeed;
1604         pSpeed *= vlen(dir);
1605         dir = normalize(dir);
1606
1607 #if 0
1608         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1609         {
1610                 mspercallsum = mspercallcount = 0;
1611                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1612         }
1613         mspercallsum -= gettime(GETTIME_HIRES);
1614 #endif
1615         dir = W_CalculateProjectileSpread(dir, spread);
1616 #if 0
1617         mspercallsum += gettime(GETTIME_HIRES);
1618         mspercallcount += 1;
1619         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1620 #endif
1621
1622         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1623 }
1624
1625 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1626 {
1627         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1628 }
1629
1630 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1631 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1632
1633 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1634 {
1635         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1636                 return;
1637
1638         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1639         if(ammo_reload)
1640         {
1641                 self.clip_load -= ammo_use;
1642                 self.weapon_load[self.weapon] = self.clip_load;
1643         }
1644         else
1645                 self.(self.current_ammo) -= ammo_use;
1646 }
1647
1648 // weapon reloading code
1649
1650 .float reload_ammo_amount, reload_ammo_min, reload_time;
1651 .float reload_complain;
1652 .string reload_sound;
1653
1654 void W_ReloadedAndReady()
1655 {
1656         // finish the reloading process, and do the ammo transfer
1657
1658         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1659
1660         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1661         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1662                 self.clip_load = self.reload_ammo_amount;
1663         else
1664         {
1665                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1666                 {
1667                         self.clip_load += 1;
1668                         self.(self.current_ammo) -= 1;
1669                 }
1670         }
1671         self.weapon_load[self.weapon] = self.clip_load;
1672
1673         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1674         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1675         // so your weapon is disabled for a few seconds without reason
1676
1677         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1678
1679         w_ready();
1680 }
1681
1682 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1683 {
1684         // set global values to work with
1685
1686         self.reload_ammo_min = sent_ammo_min;
1687         self.reload_ammo_amount = sent_ammo_amount;
1688         self.reload_time = sent_time;
1689         self.reload_sound = sent_sound;
1690
1691         // check if we meet the necessary conditions to reload
1692
1693         entity e;
1694         e = get_weaponinfo(self.weapon);
1695
1696         // don't reload weapons that don't have the RELOADABLE flag
1697         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1698         {
1699                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1700                 return;
1701         }
1702
1703         // return if reloading is disabled for this weapon
1704         if(!self.reload_ammo_amount)
1705                 return;
1706
1707         // our weapon is fully loaded, no need to reload
1708         if (self.clip_load >= self.reload_ammo_amount)
1709                 return;
1710
1711         // no ammo, so nothing to load
1712         if(!self.(self.current_ammo) && self.reload_ammo_min)
1713         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1714         {
1715                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1716                 {
1717                         play2(self, "weapons/unavailable.wav");
1718                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1719                         self.reload_complain = time + 1;
1720                 }
1721                 // switch away if the amount of ammo is not enough to keep using this weapon
1722                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1723                 {
1724                         self.clip_load = -1; // reload later
1725                         W_SwitchToOtherWeapon(self);
1726                 }
1727                 return;
1728         }
1729
1730         if (self.weaponentity)
1731         {
1732                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1733                         return;
1734
1735                 // allow switching away while reloading, but this will cause a new reload!
1736                 self.weaponentity.state = WS_READY;
1737         }
1738
1739         // now begin the reloading process
1740
1741         sound (self, CH_WEAPON_B, self.reload_sound, VOL_BASE, ATTN_NORM);
1742
1743         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1744         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1745         // so your weapon is disabled for a few seconds without reason
1746
1747         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1748
1749         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1750
1751         if(self.clip_load < 0)
1752                 self.clip_load = 0;
1753         self.old_clip_load = self.clip_load;
1754         self.clip_load = self.weapon_load[self.weapon] = -1;
1755 }