attempt at melee icon sending/receiving code for notify panel
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 .float weapon_frametime;
11
12 float W_WeaponRateFactor()
13 {
14         float t;
15         t = 1.0 / g_weaponratefactor;
16
17         if(g_runematch)
18         {
19                 if(self.runes & RUNE_SPEED)
20                 {
21                         if(self.runes & CURSE_SLOW)
22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
23                         else
24                                 t = t * cvar("g_balance_rune_speed_atkrate");
25                 }
26                 else if(self.runes & CURSE_SLOW)
27                 {
28                         t = t * cvar("g_balance_curse_slow_atkrate");
29                 }
30         }
31
32         return t;
33 }
34
35 void W_SwitchWeapon_Force(entity e, float w)
36 {
37         e.cnt = e.switchweapon;
38         e.switchweapon = w;
39         e.selectweapon = w;
40 }
41
42 .float antilag_debug;
43
44 // VorteX: static frame globals
45 float WFRAME_DONTCHANGE = -1;
46 float WFRAME_FIRE1 = 0;
47 float WFRAME_FIRE2 = 1;
48 float WFRAME_IDLE = 2;
49 float WFRAME_RELOAD = 3;
50 .float wframe;
51
52 void(float fr, float t, void() func) weapon_thinkf;
53
54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
55 {
56         vector ret;
57         ret_x = screenright * v;
58         ret_y = screenup * v;
59         ret_z = screenforward * v;
60         return ret;
61 }
62
63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
64 {
65         float i, j, k;
66         vector mi, ma, thisv, myv, ret;
67
68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
69
70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
71
72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
73         {
74                 thisv = targ.origin;
75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
79                 if(i || j || k)
80                 {
81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
84                 }
85                 else
86                 {
87                         // first run
88                         mi = ma = thisv;
89                 }
90         }
91
92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
95         ret_z = thisv_z - myv_z;
96         return ret;
97 }
98
99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
100 {
101         vector hitplot;
102         vector org;
103         float lag;
104
105         if(player.hitplotfh >= 0)
106         {
107                 lag = ANTILAG_LATENCY(player);
108                 if(lag < 0.001)
109                         lag = 0;
110                 if(clienttype(player) != CLIENTTYPE_REAL)
111                         lag = 0; // only antilag for clients
112
113                 org = player.origin + player.view_ofs;
114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
115                 if(trace_ent.flags & FL_CLIENT)
116                 {
117                         antilag_takeback(trace_ent, time - lag);
118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
119                         antilag_restore(trace_ent);
120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
122                 }
123         }
124 }
125
126 vector w_shotorg;
127 vector w_shotdir;
128
129 // this function calculates w_shotorg and w_shotdir based on the weapon model
130 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
131 // make sure you call makevectors first (FIXME?)
132 void W_SetupShot_Dir_ProjectileSize(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage)
133 {
134         float nudge = 1; // added to traceline target and subtracted from result
135         local vector trueaimpoint;
136         local float oldsolid;
137         vector vecs, dv;
138         oldsolid = ent.dphitcontentsmask;
139         if(ent.weapon == WEP_CAMPINGRIFLE)
140                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
141         else
142                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
143         if(antilag)
144                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
145                 // passing world, because we do NOT want it to touch dphitcontentsmask
146         else
147                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, ent);
148         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
149
150         vector vf, vr, vu;
151         vf = v_forward;
152         vr = v_right;
153         vu = v_up;
154         trueaimpoint = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
155         v_forward = vf;
156         v_right = vr;
157         v_up = vu;
158
159         // track max damage
160         if not(inWarmupStage) {
161                 entity w;
162                 w = get_weaponinfo(ent.weapon);
163                 if(w.spawnflags & WEP_TYPE_SPLASH) {  // splash damage
164                         ent.stats_fired[ent.weapon - 1] += maxdamage;
165                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);
166                 }
167         }
168
169         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
170
171         if(ent.weaponentity.movedir_x > 0)
172         {
173                 vecs = ent.weaponentity.movedir;
174                 vecs_y = -vecs_y;
175         }
176         else
177                 vecs = '0 0 0';
178
179         if(debug_shotorg != '0 0 0')
180                 vecs = debug_shotorg;
181
182         dv = v_right * vecs_y + v_up * vecs_z;
183         w_shotorg = ent.origin + ent.view_ofs + dv;
184
185         // now move the shotorg forward as much as requested if possible
186         if(antilag)
187         {
188                 if(ent.antilag_debug)
189                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
190                 else
191                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
192         }
193         else
194                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
195         w_shotorg = trace_endpos - v_forward * nudge;
196         // calculate the shotdir from the chosen shotorg
197         w_shotdir = normalize(trueaimpoint - w_shotorg);
198
199         if (antilag)
200         if (!ent.cvar_cl_noantilag)
201         {
202                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
203                 {
204                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
205                         if (!trace_ent.takedamage)
206                         {
207                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
208                                 if (trace_ent.takedamage && trace_ent.classname == "player")
209                                 {
210                                         entity e;
211                                         e = trace_ent;
212                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
213                                         if(trace_ent == e)
214                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
215                                 }
216                         }
217                 }
218                 else if(cvar("g_antilag") == 3) // client side hitscan
219                 {
220                         // this part MUST use prydon cursor
221                         if (ent.cursor_trace_ent)                 // client was aiming at someone
222                         if (ent.cursor_trace_ent != ent)         // just to make sure
223                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
224                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
225                         {
226                                 // verify that the shot would miss without antilag
227                                 // (avoids an issue where guns would always shoot at their origin)
228                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
229                                 if (!trace_ent.takedamage)
230                                 {
231                                         // verify that the shot would hit if altered
232                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
233                                         if (trace_ent == ent.cursor_trace_ent)
234                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
235                                         else
236                                                 print("antilag fail\n");
237                                 }
238                         }
239                 }
240         }
241
242         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
243
244         if (!g_norecoil)
245                 ent.punchangle_x = recoil * -1;
246
247         if (snd != "")
248         {
249                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
250         }
251
252         if (ent.items & IT_STRENGTH)
253         if (!g_minstagib)
254                 sound (ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
255 };
256
257 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
258 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
259 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
260
261 void LaserTarget_Think()
262 {
263         entity e;
264         vector offset;
265         float uselaser;
266         uselaser = 0;
267
268         // list of weapons that will use the laser, and the options that enable it
269         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
270                 uselaser = 1;
271         // example
272         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
273         //      uselaser = 1;
274
275
276
277         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
278         if(!uselaser)
279         {
280                 // rocket launcher isn't selected, so no laser target.
281                 if(self.lasertarget != world)
282                 {
283                         remove(self.lasertarget);
284                         self.lasertarget = world;
285                 }
286                 return;
287         }
288
289         if(!self.lasertarget)
290         {
291                 // we don't have a lasertarget entity, so spawn one
292                 //bprint("create laser target\n");
293                 e = self.lasertarget = spawn();
294                 e.owner = self.owner;                   // Its owner is my owner
295                 e.classname = "laser_target";
296                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
297                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
298                 e.scale = 1.25;                         // make it larger
299                 e.alpha = 0.25;                         // transparency
300                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
301                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
302                 // make it dynamically glow
303                 // you should avoid over-using this, as it can slow down the player's computer.
304                 e.glow_color = 251; // red color
305                 e.glow_size = 12;
306         }
307         else
308                 e = self.lasertarget;
309
310         // move the laser dot to where the player is looking
311
312         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
313         offset = '0 0 26' + v_right*3;
314         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
315         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
316         if(trace_plane_normal != '0 0 0')
317                 e.angles = vectoangles(trace_plane_normal);
318         else
319                 e.angles = vectoangles(v_forward);
320 }
321
322 float CL_Weaponentity_CustomizeEntityForClient()
323 {
324         self.viewmodelforclient = self.owner;
325         if(other.classname == "spectator")
326                 if(other.enemy == self.owner)
327                         self.viewmodelforclient = other;
328         return TRUE;
329 }
330
331 float qcweaponanimation;
332 vector weapon_offset = '0 -10 0';
333 vector weapon_adjust = '10 0 -15';
334 .vector weapon_morph0origin;
335 .vector weapon_morph0angles;
336 .float  weapon_morph0time;
337 .vector weapon_morph1origin;
338 .vector weapon_morph1angles;
339 .float  weapon_morph1time;
340 .vector weapon_morph2origin;
341 .vector weapon_morph2angles;
342 .float  weapon_morph2time;
343 .vector weapon_morph3origin;
344 .vector weapon_morph3angles;
345 .float  weapon_morph3time;
346 .vector weapon_morph4origin;
347 .vector weapon_morph4angles;
348 .float  weapon_morph4time;
349 .string weaponname;
350 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
351
352 /*
353  * supported formats:
354  *
355  * 1. simple animated model, muzzle flash handling on h_ model:
356  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
357  *      tags:
358  *        shot = muzzle end (shot origin, also used for muzzle flashes)
359  *        shell = casings ejection point (must be on the right hand side of the gun)
360  *        weapon = attachment for v_tuba.md3
361  *    v_tuba.md3 - first and third person model
362  *    g_tuba.md3 - pickup model
363  *
364  * 2. simple animated model, muzzle flash handling on v_ model:
365  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
366  *      tags:
367  *        weapon = attachment for v_tuba.md3
368  *    v_tuba.md3 - first and third person model
369  *      tags:
370  *        shot = muzzle end (shot origin, also used for muzzle flashes)
371  *        shell = casings ejection point (must be on the right hand side of the gun)
372  *    g_tuba.md3 - pickup model
373  *
374  * 3. fully animated model, muzzle flash handling on h_ model:
375  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
376  *      tags:
377  *        shot = muzzle end (shot origin, also used for muzzle flashes)
378  *        shell = casings ejection point (must be on the right hand side of the gun)
379  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
380  *    v_tuba.md3 - third person model
381  *    g_tuba.md3 - pickup model
382  *
383  * 4. fully animated model, muzzle flash handling on v_ model:
384  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
385  *      tags:
386  *        shot = muzzle end (shot origin)
387  *        shell = casings ejection point (must be on the right hand side of the gun)
388  *    v_tuba.md3 - third person model
389  *      tags:
390  *        shot = muzzle end (for muzzle flashes)
391  *    g_tuba.md3 - pickup model
392  */
393
394 void CL_Weaponentity_Think()
395 {
396         float tb, v_shot_idx;
397         self.nextthink = time;
398         if (intermission_running)
399                 self.frame = self.anim_idle_x;
400         if (self.owner.weaponentity != self)
401         {
402                 if (self.weaponentity)
403                         remove(self.weaponentity);
404                 remove(self);
405                 return;
406         }
407         if (self.owner.deadflag != DEAD_NO)
408         {
409                 self.model = "";
410                 if (self.weaponentity)
411                         self.weaponentity.model = "";
412                 return;
413         }
414         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
415         {
416                 self.cnt = self.owner.weapon;
417                 self.dmg = self.owner.modelindex;
418                 self.deadflag = self.owner.deadflag;
419
420                 string animfilename;
421                 float animfile;
422                 if (self.owner.weaponname != "")
423                 {
424                         // if there is a child entity, hide it until we're sure we use it
425                         if (self.weaponentity)
426                                 self.weaponentity.model = "";
427                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
428                         v_shot_idx = gettagindex(self, "shot"); // used later
429                         if(!v_shot_idx)
430                                 v_shot_idx = gettagindex(self, "tag_shot");
431
432                         if(qcweaponanimation)
433                         {
434                                 self.angles = '0 0 0';
435                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
436                                 self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
437                                 self.movedir_x += 32;
438                                 self.spawnorigin = self.movedir;
439                                 // oldorigin - not calculated here
440                         }
441                         else
442                         {
443                                 setmodel(self, strcat("models/weapons/h_", self.owner.weaponname, ".iqm")); // precision set below
444                                 animfilename = strcat("models/weapons/h_", self.owner.weaponname, ".iqm.animinfo");
445                                 animfile = fopen(animfilename, FILE_READ);
446                                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
447                                 self.anim_fire1  = '0 1 0.01';
448                                 self.anim_fire2  = '1 1 0.01';
449                                 self.anim_idle   = '2 1 0.01';
450                                 self.anim_reload = '3 1 0.01';
451                                 if (animfile >= 0)
452                                 {
453                                         animparseerror = FALSE;
454                                         self.anim_fire1  = animparseline(animfile);
455                                         self.anim_fire2  = animparseline(animfile);
456                                         self.anim_idle   = animparseline(animfile);
457                                         self.anim_reload = animparseline(animfile);
458                                         fclose(animfile);
459                                         if (animparseerror)
460                                                 print("Parse error in ", animfilename, ", some player animations are broken\n");
461                                 }
462
463                                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
464                                 // if we don't, this is a "real" animated model
465                                 if(gettagindex(self, "weapon"))
466                                 {
467                                         if (!self.weaponentity)
468                                                 self.weaponentity = spawn();
469                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
470                                         setattachment(self.weaponentity, self, "weapon");
471                                 }
472                                 else if(gettagindex(self, "tag_weapon"))
473                                 {
474                                         if (!self.weaponentity)
475                                                 self.weaponentity = spawn();
476                                         setmodel(self.weaponentity, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision does not matter
477                                         setattachment(self.weaponentity, self, "tag_weapon");
478                                 }
479                                 else
480                                 {
481                                         if(self.weaponentity)
482                                                 remove(self.weaponentity);
483                                         self.weaponentity = world;
484                                 }
485
486                                 setorigin(self,'0 0 0');
487                                 self.angles = '0 0 0';
488                                 self.frame = 0;
489                                 self.viewmodelforclient = world;
490
491                                 float idx;
492
493                                 if(v_shot_idx) // v_ model attached to invisible h_ model
494                                 {
495                                         self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
496                                 }
497                                 else
498                                 {
499                                         idx = gettagindex(self, "shot");
500                                         if(!idx)
501                                                 idx = gettagindex(self, "tag_shot");
502                                         if(idx)
503                                                 self.movedir = gettaginfo(self, idx);
504                                         else
505                                         {
506                                                 print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
507                                                 self.movedir = '0 0 0';
508                                         }
509                                 }
510
511                                 if(self.weaponentity) // v_ model attached to invisible h_ model
512                                 {
513                                         idx = gettagindex(self.weaponentity, "shell");
514                                         if(!idx)
515                                                 idx = gettagindex(self.weaponentity, "tag_shell");
516                                         if(idx)
517                                                 self.spawnorigin = gettaginfo(self.weaponentity, idx);
518                                 }
519                                 else
520                                         idx = 0;
521                                 if(!idx)
522                                 {
523                                         idx = gettagindex(self, "shell");
524                                         if(!idx)
525                                                 idx = gettagindex(self, "tag_shell");
526                                         if(idx)
527                                                 self.spawnorigin = gettaginfo(self, idx);
528                                         else
529                                         {
530                                                 print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
531                                                 self.spawnorigin = self.movedir;
532                                         }
533                                 }
534
535                                 if(v_shot_idx)
536                                 {
537                                         self.oldorigin = '0 0 0'; // use regular attachment
538                                 }
539                                 else
540                                 {
541                                         if(self.weaponentity)
542                                         {
543                                                 idx = gettagindex(self, "weapon");
544                                                 if(!idx)
545                                                         idx = gettagindex(self, "tag_weapon");
546                                         }
547                                         else
548                                         {
549                                                 idx = gettagindex(self, "handle");
550                                                 if(!idx)
551                                                         idx = gettagindex(self, "tag_handle");
552                                         }
553                                         if(idx)
554                                         {
555                                                 self.oldorigin = self.movedir - gettaginfo(self, idx);
556                                         }
557                                         else
558                                         {
559                                                 print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
560                                                 self.oldorigin = '0 0 0'; // there is no way to recover from this
561                                         }
562                                 }
563
564                                 self.viewmodelforclient = self.owner;
565                         }
566                 }
567                 else
568                 {
569                         self.model = "";
570                         if(self.weaponentity)
571                                 remove(self.weaponentity);
572                         self.weaponentity = world;
573                         self.movedir = '0 0 0';
574                         self.spawnorigin = '0 0 0';
575                         self.oldorigin = '0 0 0';
576                         self.anim_fire1  = '0 1 0.01';
577                         self.anim_fire2  = '0 1 0.01';
578                         self.anim_idle   = '0 1 0.01';
579                         self.anim_reload = '0 1 0.01';
580                 }
581
582                 self.view_ofs = '0 0 0';
583
584                 if(self.movedir_x >= 0)
585                 {
586                         vector v0;
587                         v0 = self.movedir;
588                         self.movedir = shotorg_adjust(v0, FALSE, FALSE);
589                         self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
590                 }
591                 self.owner.stat_shotorg = compressShotOrigin(self.movedir);
592                 self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
593
594                 self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
595
596                 // check if an instant weapon switch occurred
597                 if (qcweaponanimation)
598                 {
599                         if (self.state == WS_READY)
600                         {
601                                 self.angles = '0 0 0';
602                                 makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
603                                 setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
604                         }
605                 }
606                 else
607                         setorigin(self, self.view_ofs);
608                 // reset animstate now
609                 self.wframe = WFRAME_IDLE;
610                 self.weapon_morph0time = 0;
611                 self.weapon_morph1time = 0;
612                 self.weapon_morph2time = 0;
613                 self.weapon_morph3time = 0;
614                 self.weapon_morph4time = 0;
615                 setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
616         }
617
618         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
619         self.effects = self.owner.effects & EFMASK_CHEAP;
620         self.effects &~= EF_LOWPRECISION;
621         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
622         self.effects &~= EF_TELEPORT_BIT;
623         self.effects &~= EF_RESTARTANIM_BIT;
624         self.effects |= tb;
625
626         if(self.owner.alpha == default_player_alpha)
627                 self.alpha = default_weapon_alpha;
628         else if(self.owner.alpha != 0)
629                 self.alpha = self.owner.alpha;
630         else
631                 self.alpha = 1;
632
633         self.colormap = self.owner.colormap;
634         if (self.weaponentity)
635         {
636                 self.weaponentity.effects = self.effects;
637                 self.weaponentity.alpha = self.alpha;
638                 self.weaponentity.colormap = self.colormap;
639         }
640
641         self.angles = '0 0 0';
642         local float f;
643         f = 0;
644         if (self.state == WS_RAISE && !intermission_running)
645         {
646                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
647                 self.angles_x = -90 * f * f;
648                 if (qcweaponanimation)
649                 {
650                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
651                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
652                 }
653         }
654         else if (self.state == WS_DROP && !intermission_running)
655         {
656                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
657                 self.angles_x = -90 * f * f;
658                 if (qcweaponanimation)
659                 {
660                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
661                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
662                 }
663         }
664         else if (self.state == WS_CLEAR)
665         {
666                 f = 1;
667                 self.angles_x = -90 * f * f;
668                 if (qcweaponanimation)
669                 {
670                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
671                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
672                 }
673         }
674         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
675         {
676                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
677                 f = 1 - pow(1 - f, 3);
678                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
679                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
680         }
681         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
682         {
683                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
684                 f = 1 - pow(1 - f, 3);
685                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
686                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
687         }
688         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
689         {
690                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
691                 f = 1 - pow(1 - f, 3);
692                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
693                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
694         }
695         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
696         {
697                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
698                 f = 1 - pow(1 - f, 3);
699                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
700                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
701         }
702         else if (qcweaponanimation)
703         {
704                 // begin a new idle morph
705                 self.owner.weapon_morph0time   = time;
706                 self.owner.weapon_morph0angles = self.angles;
707                 self.owner.weapon_morph0origin = self.origin;
708
709                 float r;
710                 float t;
711
712                 r = random();
713                 if (r < 0.1)
714                 {
715                         // turn gun to the left to look at it
716                         t = 2;
717                         self.owner.weapon_morph1time   = time + t * 0.2;
718                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
719                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
720                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
721
722                         self.owner.weapon_morph2time   = time + t * 0.6;
723                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
724                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
725                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
726
727                         self.owner.weapon_morph3time   = time + t;
728                         self.owner.weapon_morph3angles = '0 0 0';
729                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
730                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
731                 }
732                 else if (r < 0.2)
733                 {
734                         // raise the gun a bit
735                         t = 2;
736                         self.owner.weapon_morph1time   = time + t * 0.2;
737                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
738                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
739                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
740
741                         self.owner.weapon_morph2time   = time + t * 0.5;
742                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
743                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
744                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
745
746                         self.owner.weapon_morph3time   = time + t;
747                         self.owner.weapon_morph3angles = '0 0 0';
748                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
749                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
750                 }
751                 else if (r < 0.3)
752                 {
753                         // tweak it a bit
754                         t = 5;
755                         self.owner.weapon_morph1time   = time + t * 0.3;
756                         self.owner.weapon_morph1angles = randomvec() * 6;
757                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
758                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
759
760                         self.owner.weapon_morph2time   = time + t * 0.7;
761                         self.owner.weapon_morph2angles = randomvec() * 6;
762                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
763                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
764
765                         self.owner.weapon_morph3time   = time + t;
766                         self.owner.weapon_morph3angles = '0 0 0';
767                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
768                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
769                 }
770                 else
771                 {
772                         // hold it mostly steady
773                         t = random() * 6 + 4;
774                         self.owner.weapon_morph1time   = time + t * 0.2;
775                         self.owner.weapon_morph1angles = randomvec() * 1;
776                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
777                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
778
779                         self.owner.weapon_morph2time   = time + t * 0.5;
780                         self.owner.weapon_morph2angles = randomvec() * 1;
781                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
782                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
783
784                         self.owner.weapon_morph3time   = time + t * 0.7;
785                         self.owner.weapon_morph3angles = randomvec() * 1;
786                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
787                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
788                 }
789
790                 self.owner.weapon_morph4time   = time + t;
791                 self.owner.weapon_morph4angles = '0 0 0';
792                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
793                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
794
795         }
796
797         // create or update the lasertarget entity
798         LaserTarget_Think();
799 };
800
801 void CL_ExteriorWeaponentity_Think()
802 {
803         float tag_found;
804         vector ang;
805         self.nextthink = time;
806         if (self.owner.exteriorweaponentity != self)
807         {
808                 remove(self);
809                 return;
810         }
811         if (self.owner.deadflag != DEAD_NO)
812         {
813                 self.model = "";
814                 return;
815         }
816         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
817         {
818                 self.cnt = self.owner.weapon;
819                 self.dmg = self.owner.modelindex;
820                 self.deadflag = self.owner.deadflag;
821                 if (self.owner.weaponname != "")
822                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
823                 else
824                         self.model = "";
825
826                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
827                 {
828                         self.tag_index = tag_found;
829                         self.tag_entity = self.owner;
830                 }
831                 else
832                         setattachment(self, self.owner, "bip01 r hand");
833
834                 // if that didn't find a tag, hide the exterior weapon model
835                 if (!self.tag_index)
836                         self.model = "";
837         }
838         self.effects = self.owner.effects;
839         if(sv_pitch_min == sv_pitch_max)
840                 self.effects |= EF_LOWPRECISION;
841         else
842                 self.effects &~= EF_LOWPRECISION;
843         self.effects = self.effects & EFMASK_CHEAP; // eat performance
844         if(self.owner.alpha == default_player_alpha)
845                 self.alpha = default_weapon_alpha;
846         else if(self.owner.alpha != 0)
847                 self.alpha = self.owner.alpha;
848         else
849                 self.alpha = 1;
850
851         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
852         ang_y = 0;
853         ang_z = 0;
854
855         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
856         {
857                 ang_y = self.owner.v_angle_y;
858                 makevectors(ang);
859                 var vector v = v_forward;
860                 var float t = self.tag_entity.frame1time;
861                 var float f = self.tag_entity.frame;
862                 self.tag_entity.frame1time = time;
863                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
864                 gettaginfo(self.tag_entity, self.tag_index);
865                 self.tag_entity.frame1time = t;
866                 self.tag_entity.frame = f;
867                 // untransform v according to this coordinate space
868                 vector w;
869                 w_x = v_forward * v;
870                 w_y = -v_right * v;
871                 w_z = v_up * v;
872                 self.angles = vectoangles(w);
873         }
874         else
875         {
876                 ang_x = -/* don't ask */ang_x;
877                 self.angles = ang;
878         }
879
880         self.colormap = self.owner.colormap;
881 };
882
883 // spawning weaponentity for client
884 void CL_SpawnWeaponentity()
885 {
886         self.weaponentity = spawn();
887         self.weaponentity.classname = "weaponentity";
888         self.weaponentity.solid = SOLID_NOT;
889         self.weaponentity.owner = self;
890         setmodel(self.weaponentity, ""); // precision set when changed
891         setorigin(self.weaponentity, '0 0 0');
892         self.weaponentity.angles = '0 0 0';
893         self.weaponentity.viewmodelforclient = self;
894         self.weaponentity.flags = 0;
895         self.weaponentity.think = CL_Weaponentity_Think;
896         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
897         self.weaponentity.nextthink = time;
898
899         self.exteriorweaponentity = spawn();
900         self.exteriorweaponentity.classname = "exteriorweaponentity";
901         self.exteriorweaponentity.solid = SOLID_NOT;
902         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
903         self.exteriorweaponentity.owner = self;
904         setorigin(self.exteriorweaponentity, '0 0 0');
905         self.exteriorweaponentity.angles = '0 0 0';
906         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
907         self.exteriorweaponentity.nextthink = time;
908 };
909
910 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
911 {
912         msg_entity = e;
913         WriteByte(MSG_ONE, SVC_TEMPENTITY);
914         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
915         WriteByte(MSG_ONE, wpn);
916         WriteString(MSG_ONE, wpnname);
917         WriteByte(MSG_ONE, type);
918 }
919
920 .float hasweapon_complain_spam;
921
922 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
923 {
924         local float weaponbit, f;
925         local entity oldself;
926
927         if(time < self.hasweapon_complain_spam)
928                 complain = 0;
929         if(complain)
930                 self.hasweapon_complain_spam = time + 0.2;
931
932         if (wpn < WEP_FIRST || wpn > WEP_LAST)
933         {
934                 if (complain)
935                         sprint(self, "Invalid weapon\n");
936                 return FALSE;
937         }
938         weaponbit = W_WeaponBit(wpn);
939         if (cl.weapons & weaponbit)
940         {
941                 if (andammo)
942                 {
943                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
944                         {
945                                 f = 1;
946                         }
947                         else
948                         {
949                                 oldself = self;
950                                 self = cl;
951                                 f = weapon_action(wpn, WR_CHECKAMMO1);
952                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
953                                 self = oldself;
954                         }
955                         if (!f)
956                         {
957                                 if (complain)
958                                 if(clienttype(cl) == CLIENTTYPE_REAL)
959                                 {
960                                         play2(cl, "weapons/unavailable.wav");
961                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
962                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
963                                 }
964                                 return FALSE;
965                         }
966                 }
967                 return TRUE;
968         }
969         if (complain)
970         {
971                 // DRESK - 3/16/07
972                 // Report Proper Weapon Status / Modified Weapon Ownership Message
973                 if(weaponsInMap & weaponbit)
974                 {
975                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
976                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
977
978                         if(cvar("g_showweaponspawns"))
979                         {
980                                 entity e;
981                                 string s;
982
983                                 e = get_weaponinfo(wpn);
984                                 s = e.model2;
985
986                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
987                                 {
988                                         if(e.classname == "droppedweapon")
989                                                 continue;
990                                         if not(e.flags & FL_ITEM)
991                                                 continue;
992                                         WaypointSprite_Spawn(
993                                                 s,
994                                                 1, 0,
995                                                 world, e.origin,
996                                                 self, 0,
997                                                 world, enemy,
998                                                 0
999                                         );
1000                                 }
1001                         }
1002                 }
1003                 else
1004                 {
1005                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
1006                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
1007                 }
1008
1009                 play2(cl, "weapons/unavailable.wav");
1010         }
1011         return FALSE;
1012 };
1013
1014 // Weapon subs
1015 void w_clear()
1016 {
1017         if (self.weapon != -1)
1018                 self.weapon = 0;
1019         if (self.weaponentity)
1020         {
1021                 self.weaponentity.state = WS_CLEAR;
1022                 self.weaponentity.effects = 0;
1023         }
1024 };
1025
1026 void w_ready()
1027 {
1028         if (self.weaponentity)
1029                 self.weaponentity.state = WS_READY;
1030         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1031 };
1032
1033 // Setup weapon for client (after this raise frame will be launched)
1034 void weapon_setup(float windex)
1035 {
1036         entity e;
1037         qcweaponanimation = cvar("sv_qcweaponanimation");
1038         e = get_weaponinfo(windex);
1039         self.items &~= IT_AMMO;
1040         self.items = self.items | e.items;
1041
1042         // the two weapon entities will notice this has changed and update their models
1043         self.weapon = windex;
1044         self.weaponname = e.mdl;
1045         self.bulletcounter = 0;
1046 };
1047
1048 // perform weapon to attack (weaponstate and attack_finished check is here)
1049 void W_SwitchToOtherWeapon(entity pl)
1050 {
1051         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1052         float w, ww;
1053         w = W_WeaponBit(pl.weapon);
1054         pl.weapons &~= w;
1055         ww = w_getbestweapon(pl);
1056         pl.weapons |= w;
1057         if(ww)
1058                 W_SwitchWeapon_Force(pl, ww);
1059 }
1060 float weapon_prepareattack_checkammo(float secondary)
1061 {
1062         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1063         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1064         {
1065                 W_SwitchToOtherWeapon(self);
1066                 return FALSE;
1067         }
1068         return TRUE;
1069 }
1070 .float race_penalty;
1071 float weapon_prepareattack_check(float secondary, float attacktime)
1072 {
1073         if(!weapon_prepareattack_checkammo(secondary))
1074                 return FALSE;
1075
1076         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1077         //if all players readied up and the countdown is running
1078         if(time < game_starttime || time < self.race_penalty) {
1079                 return FALSE;
1080         }
1081
1082         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1083                 return FALSE;
1084
1085         // do not even think about shooting if switching
1086         if(self.switchweapon != self.weapon)
1087                 return FALSE;
1088
1089         if(attacktime >= 0)
1090         {
1091                 // don't fire if previous attack is not finished
1092                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1093                         return FALSE;
1094                 // don't fire while changing weapon
1095                 if (self.weaponentity.state != WS_READY)
1096                         return FALSE;
1097         }
1098
1099         return TRUE;
1100 }
1101 float weapon_prepareattack_do(float secondary, float attacktime)
1102 {
1103         self.weaponentity.state = WS_INUSE;
1104
1105         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1106
1107         // if the weapon hasn't been firing continuously, reset the timer
1108         if(attacktime >= 0)
1109         {
1110                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1111                 {
1112                         ATTACK_FINISHED(self) = time;
1113                         //dprint("resetting attack finished to ", ftos(time), "\n");
1114                 }
1115                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1116         }
1117         self.bulletcounter += 1;
1118         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1119         return TRUE;
1120 }
1121 float weapon_prepareattack(float secondary, float attacktime)
1122 {
1123         if(weapon_prepareattack_check(secondary, attacktime))
1124         {
1125                 weapon_prepareattack_do(secondary, attacktime);
1126                 return TRUE;
1127         }
1128         else
1129                 return FALSE;
1130 }
1131
1132 void weapon_thinkf(float fr, float t, void() func)
1133 {
1134         vector a;
1135         vector of, or, ou;
1136         float restartanim;
1137
1138         if(fr == WFRAME_DONTCHANGE)
1139         {
1140                 fr = self.weaponentity.wframe;
1141                 restartanim = FALSE;
1142         }
1143         else if (fr == WFRAME_IDLE)
1144                 restartanim = FALSE;
1145         else
1146                 restartanim = TRUE;
1147
1148         of = v_forward;
1149         or = v_right;
1150         ou = v_up;
1151
1152         if (self.weaponentity)
1153         {
1154                 self.weaponentity.wframe = fr;
1155                 if (qcweaponanimation)
1156                 {
1157                         if (fr != WFRAME_IDLE)
1158                         {
1159                                 self.weapon_morph0time = time;
1160                                 self.weapon_morph0angles = self.weaponentity.angles;
1161                                 self.weapon_morph0origin = self.weaponentity.origin;
1162
1163                                 self.weapon_morph1angles = '0 0 0';
1164                                 self.weapon_morph1time = time + t;
1165                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1166                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1167
1168                                 self.weapon_morph2angles = '0 0 0';
1169                                 self.weapon_morph2time = time + t;
1170                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1171                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1172
1173                                 self.weapon_morph3angles = '0 0 0';
1174                                 self.weapon_morph3time = time + t;
1175                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1176                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1177
1178                                 self.weapon_morph4angles = '0 0 0';
1179                                 self.weapon_morph4time = time + t;
1180                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1181                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1182
1183                                 if (fr == WFRAME_FIRE1)
1184                                 {
1185                                         self.weapon_morph1angles = '5 0 0';
1186                                         self.weapon_morph1time = time + t * 0.1;
1187                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1188                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1189                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1190                                 }
1191                                 else if (fr == WFRAME_FIRE2)
1192                                 {
1193                                         self.weapon_morph1angles = '10 0 0';
1194                                         self.weapon_morph1time = time + t * 0.1;
1195                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1196                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1197                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1198                                 }
1199                                 else if (fr == WFRAME_RELOAD)
1200                                 {
1201                                         self.weapon_morph1time = time + t * 0.05;
1202                                         self.weapon_morph1angles = '-10 40 0';
1203                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1204                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1205
1206                                         self.weapon_morph2time = time + t * 0.15;
1207                                         self.weapon_morph2angles = '-10 40 5';
1208                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1209                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1210
1211                                         self.weapon_morph3time = time + t * 0.25;
1212                                         self.weapon_morph3angles = '-10 40 0';
1213                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1214                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1215                                 }
1216                         }
1217                 }
1218                 else
1219                 {
1220                         if (fr == WFRAME_IDLE)
1221                                 a = self.weaponentity.anim_idle;
1222                         else if (fr == WFRAME_FIRE1)
1223                                 a = self.weaponentity.anim_fire1;
1224                         else if (fr == WFRAME_FIRE2)
1225                                 a = self.weaponentity.anim_fire2;
1226                         else if (fr == WFRAME_RELOAD)
1227                                 a = self.weaponentity.anim_reload;
1228                         a_z *= g_weaponratefactor;
1229                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1230                 }
1231         }
1232
1233         v_forward = of;
1234         v_right = or;
1235         v_up = ou;
1236
1237         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1238         {
1239                 backtrace("Tried to override initial weapon think function - should this really happen?");
1240         }
1241
1242         t *= W_WeaponRateFactor();
1243
1244         // VorteX: haste can be added here
1245         if (self.weapon_think == w_ready)
1246         {
1247                 self.weapon_nextthink = time;
1248                 //dprint("started firing at ", ftos(time), "\n");
1249         }
1250         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1251         {
1252                 self.weapon_nextthink = time;
1253                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1254         }
1255         self.weapon_nextthink = self.weapon_nextthink + t;
1256         self.weapon_think = func;
1257         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1258
1259         if (restartanim)
1260         if (t)
1261         if (!self.crouch) // shoot anim stands up, this looks bad
1262         {
1263                 local vector anim;
1264                 anim = self.anim_shoot;
1265                 anim_z = anim_y / (t + sys_frametime);
1266                 setanim(self, anim, FALSE, TRUE, TRUE);
1267         }
1268 };
1269
1270 void weapon_boblayer1(float spd, vector org)
1271 {
1272         // VorteX: haste can be added here
1273 };
1274
1275 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1276 {
1277         vector mdirection;
1278         float mspeed;
1279         float outspeed;
1280         float nstyle;
1281         vector outvelocity;
1282
1283         mvelocity = mvelocity * g_weaponspeedfactor;
1284
1285         mdirection = normalize(mvelocity);
1286         mspeed = vlen(mvelocity);
1287
1288         nstyle = cvar("g_projectiles_newton_style");
1289         if(nstyle == 0)
1290         {
1291                 // absolute velocity
1292                 outvelocity = mvelocity;
1293         }
1294         else if(nstyle == 1)
1295         {
1296                 // true Newtonian projectiles
1297                 outvelocity = pvelocity + mvelocity;
1298         }
1299         else if(nstyle == 2)
1300         {
1301                 // true Newtonian projectiles with automatic aim adjustment
1302                 //
1303                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1304                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1305                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1306                 // PLUS SIGN!
1307                 // not defined?
1308                 // then...
1309                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1310                 // velocity without mdirection component > mspeed
1311                 // fire at smallest possible mspeed that works?
1312                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1313
1314                 vector solution;
1315                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1316                 if(solution_z)
1317                         outspeed = solution_y; // the larger one
1318                 else
1319                 {
1320                         //outspeed = 0; // slowest possible shot
1321                         outspeed = solution_x; // the real part (that is, the average!)
1322                         //dprint("impossible shot, adjusting\n");
1323                 }
1324
1325                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1326                 outvelocity = mdirection * outspeed;
1327         }
1328         else if(nstyle == 3)
1329         {
1330                 // pseudo-Newtonian:
1331                 outspeed = mspeed + mdirection * pvelocity;
1332                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1333                 outvelocity = mdirection * outspeed;
1334         }
1335         else if(nstyle == 4)
1336         {
1337                 // tZorkian:
1338                 outspeed = mspeed + vlen(pvelocity);
1339                 outvelocity = mdirection * outspeed;
1340         }
1341         else
1342                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1343
1344         return outvelocity;
1345 }
1346
1347 void W_AttachToShotorg(entity flash, vector offset)
1348 {
1349         entity xflash;
1350         flash.owner = self;
1351         flash.angles_z = random() * 360;
1352         if(qcweaponanimation)
1353         {
1354                 setorigin(flash, w_shotorg + w_shotdir * 50);
1355                 flash.angles = vectoangles(w_shotdir);
1356                 flash.angles_z = random() * 360;
1357         }
1358         else
1359         {
1360                 setattachment(flash, self.weaponentity, "shot");
1361                 setorigin(flash, offset);
1362
1363                 xflash = spawn();
1364                 copyentity(flash, xflash);
1365
1366                 flash.viewmodelforclient = self;
1367
1368                 if(self.weaponentity.oldorigin_x > 0)
1369                 {
1370                         setattachment(xflash, self.exteriorweaponentity, "");
1371                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1372                 }
1373                 else
1374                 {
1375                         setattachment(xflash, self.exteriorweaponentity, "shot");
1376                 }
1377         }
1378 }
1379
1380 vector cliptoplane(vector v, vector p)
1381 {
1382         return v - (v * p) * p;
1383 }
1384
1385 vector solve_cubic_pq(float p, float q)
1386 {
1387         float D, u, v, a;
1388         D = q*q/4.0 + p*p*p/27.0;
1389         if(D < 0)
1390         {
1391                 // irreducibilis
1392                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1393                 u = sqrt(-4.0/3.0 * p);
1394                 // a in range 0..pi/3
1395                 // cos(a)
1396                 // cos(a + 2pi/3)
1397                 // cos(a + 4pi/3)
1398                 return
1399                         u *
1400                         (
1401                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1402                                 +
1403                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1404                                 +
1405                                 '0 0 1' * cos(a)
1406                         );
1407         }
1408         else if(D == 0)
1409         {
1410                 // simple
1411                 if(p == 0)
1412                         return '0 0 0';
1413                 u = 3*q/p;
1414                 v = -u/2;
1415                 if(u >= v)
1416                         return '1 1 0' * v + '0 0 1' * u;
1417                 else
1418                         return '0 1 1' * v + '1 0 0' * u;
1419         }
1420         else
1421         {
1422                 // cardano
1423                 u = cbrt(-q/2.0 + sqrt(D));
1424                 v = cbrt(-q/2.0 - sqrt(D));
1425                 return '1 1 1' * (u + v);
1426         }
1427 }
1428 vector solve_cubic_abcd(float a, float b, float c, float d)
1429 {
1430         // y = 3*a*x + b
1431         // x = (y - b) / 3a
1432         float p, q;
1433         vector v;
1434         p = (9*a*c - 3*b*b);
1435         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1436         v = solve_cubic_pq(p, q);
1437         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1438         if(a < 0)
1439                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1440         return v;
1441 }
1442
1443 vector findperpendicular(vector v)
1444 {
1445         vector p;
1446         p_x = v_z;
1447         p_y = -v_x;
1448         p_z = v_y;
1449         return normalize(cliptoplane(p, v));
1450 }
1451
1452 vector W_CalculateProjectileSpread(vector forward, float spread)
1453 {
1454         float sigma;
1455         vector v1, v2;
1456         float dx, dy, r;
1457         float sstyle;
1458         spread *= g_weaponspreadfactor;
1459         if(spread <= 0)
1460                 return forward;
1461         sstyle = cvar("g_projectiles_spread_style");
1462         
1463         if(sstyle == 0)
1464         {
1465                 // this is the baseline for the spread value!
1466                 // standard deviation: sqrt(2/5)
1467                 // density function: sqrt(1-r^2)
1468                 return forward + randomvec() * spread;
1469         }
1470         else if(sstyle == 1)
1471         {
1472                 // same thing, basically
1473                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1474         }
1475         else if(sstyle == 2)
1476         {
1477                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1478                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1479                 v1 = findperpendicular(forward);
1480                 v2 = cross(forward, v1);
1481                 // random point on unit circle
1482                 dx = random() * 2 * M_PI;
1483                 dy = sin(dx);
1484                 dx = cos(dx);
1485                 // radius in our dist function
1486                 r = random();
1487                 r = sqrt(r);
1488                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1489         }
1490         else if(sstyle == 3) // gauss 3d
1491         {
1492                 sigma = spread * 0.44721359549996; // match baseline stddev
1493                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1494                 v1 = forward;
1495                 v1_x += gsl_ran_gaussian(sigma);
1496                 v1_y += gsl_ran_gaussian(sigma);
1497                 v1_z += gsl_ran_gaussian(sigma);
1498                 return v1;
1499         }
1500         else if(sstyle == 4) // gauss 2d
1501         {
1502                 sigma = spread * 0.44721359549996; // match baseline stddev
1503                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1504                 v1_x = gsl_ran_gaussian(sigma);
1505                 v1_y = gsl_ran_gaussian(sigma);
1506                 v1_z = gsl_ran_gaussian(sigma);
1507                 return normalize(forward + cliptoplane(v1, forward));
1508         }
1509         else if(sstyle == 5) // 1-r
1510         {
1511                 sigma = spread * 1.154700538379252; // match baseline stddev
1512                 v1 = findperpendicular(forward);
1513                 v2 = cross(forward, v1);
1514                 // random point on unit circle
1515                 dx = random() * 2 * M_PI;
1516                 dy = sin(dx);
1517                 dx = cos(dx);
1518                 // radius in our dist function
1519                 r = random();
1520                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1521                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1522         }
1523         else if(sstyle == 6) // 1-r^2
1524         {
1525                 sigma = spread * 1.095445115010332; // match baseline stddev
1526                 v1 = findperpendicular(forward);
1527                 v2 = cross(forward, v1);
1528                 // random point on unit circle
1529                 dx = random() * 2 * M_PI;
1530                 dy = sin(dx);
1531                 dx = cos(dx);
1532                 // radius in our dist function
1533                 r = random();
1534                 r = sqrt(1 - r);
1535                 r = sqrt(1 - r);
1536                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1537         }
1538         else if(sstyle == 7) // (1-r) (2-r)
1539         {
1540                 sigma = spread * 1.224744871391589; // match baseline stddev
1541                 v1 = findperpendicular(forward);
1542                 v2 = cross(forward, v1);
1543                 // random point on unit circle
1544                 dx = random() * 2 * M_PI;
1545                 dy = sin(dx);
1546                 dx = cos(dx);
1547                 // radius in our dist function
1548                 r = random();
1549                 r = 1 - sqrt(r);
1550                 r = 1 - sqrt(r);
1551                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1552         }
1553         else
1554                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1555         return '0 0 0';
1556         /*
1557          * how to derive falloff functions:
1558          * rho(r) := (2-r) * (1-r);
1559          * a : 0;
1560          * b : 1;
1561          * rhor(r) := r * rho(r);
1562          * cr(t) := integrate(rhor(r), r, a, t);
1563          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1564          * variance : scr(b) / cr(b);
1565          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1566          * sqrt(0.4 / variance), numer;
1567          */
1568 }
1569
1570 #if 0
1571 float mspercallsum;
1572 float mspercallsstyle;
1573 float mspercallcount;
1574 #endif
1575 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread)
1576 {
1577         if(missile.owner == world)
1578                 error("Unowned missile");
1579
1580         dir = dir + upDir * (pUpSpeed / pSpeed);
1581         dir_z += pZSpeed / pSpeed;
1582         pSpeed *= vlen(dir);
1583         dir = normalize(dir);
1584
1585 #if 0
1586         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1587         {
1588                 mspercallsum = mspercallcount = 0;
1589                 mspercallsstyle = cvar("g_projectiles_spread_style");
1590         }
1591         mspercallsum -= gettime(GETTIME_HIRES);
1592 #endif
1593         dir = W_CalculateProjectileSpread(dir, spread);
1594 #if 0
1595         mspercallsum += gettime(GETTIME_HIRES);
1596         mspercallcount += 1;
1597         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1598 #endif
1599
1600         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1601 }
1602
1603 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1604 {
1605         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread);
1606 }
1607
1608 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"))
1609 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"))