Merge remote branch 'refs/remotes/origin/fruitiex/racefixes'
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 .float weapon_frametime;
11
12 float W_WeaponRateFactor()
13 {
14         float t;
15         t = 1.0 / g_weaponratefactor;
16
17         if(g_runematch)
18         {
19                 if(self.runes & RUNE_SPEED)
20                 {
21                         if(self.runes & CURSE_SLOW)
22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
23                         else
24                                 t = t * cvar("g_balance_rune_speed_atkrate");
25                 }
26                 else if(self.runes & CURSE_SLOW)
27                 {
28                         t = t * cvar("g_balance_curse_slow_atkrate");
29                 }
30         }
31
32         return t;
33 }
34
35 void W_SwitchWeapon_Force(entity e, float w)
36 {
37         e.cnt = e.switchweapon;
38         e.switchweapon = w;
39         e.selectweapon = w;
40 }
41
42 .float antilag_debug;
43
44 // VorteX: static frame globals
45 float WFRAME_DONTCHANGE = -1;
46 float WFRAME_FIRE1 = 0;
47 float WFRAME_FIRE2 = 1;
48 float WFRAME_IDLE = 2;
49 float WFRAME_RELOAD = 3;
50 .float wframe;
51
52 void(float fr, float t, void() func) weapon_thinkf;
53
54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
55 {
56         vector ret;
57         ret_x = screenright * v;
58         ret_y = screenup * v;
59         ret_z = screenforward * v;
60         return ret;
61 }
62
63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
64 {
65         float i, j, k;
66         vector mi, ma, thisv, myv, ret;
67
68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
69
70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
71
72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
73         {
74                 thisv = targ.origin;
75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
79                 if(i || j || k)
80                 {
81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
84                 }
85                 else
86                 {
87                         // first run
88                         mi = ma = thisv;
89                 }
90         }
91
92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
95         ret_z = thisv_z - myv_z;
96         return ret;
97 }
98
99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
100 {
101         vector hitplot;
102         vector org;
103         float lag;
104
105         if(player.hitplotfh >= 0)
106         {
107                 lag = ANTILAG_LATENCY(player);
108                 if(lag < 0.001)
109                         lag = 0;
110                 if(clienttype(player) != CLIENTTYPE_REAL)
111                         lag = 0; // only antilag for clients
112
113                 org = player.origin + player.view_ofs;
114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
115                 if(trace_ent.flags & FL_CLIENT)
116                 {
117                         antilag_takeback(trace_ent, time - lag);
118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
119                         antilag_restore(trace_ent);
120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
122                 }
123         }
124 }
125
126 vector w_shotorg;
127 vector w_shotdir;
128 vector w_shotend;
129
130 // this function calculates w_shotorg and w_shotdir based on the weapon model
131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
132 // make sure you call makevectors first (FIXME?)
133 .float prevstrengthsound;
134 .float prevstrengthsoundattempt;
135 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage, float range)
136 {
137         float nudge = 1; // added to traceline target and subtracted from result
138         local float oldsolid;
139         vector vecs, dv;
140         oldsolid = ent.dphitcontentsmask;
141         if(ent.weapon == WEP_CAMPINGRIFLE)
142                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
143         else
144                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
145         if(antilag)
146                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
147                 // passing world, because we do NOT want it to touch dphitcontentsmask
148         else
149                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
150         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
151
152         vector vf, vr, vu;
153         vf = v_forward;
154         vr = v_right;
155         vu = v_up;
156         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
157         v_forward = vf;
158         v_right = vr;
159         v_up = vu;
160
161         // track max damage
162         if not(inWarmupStage) {
163                 entity w;
164                 w = get_weaponinfo(ent.weapon);
165                 if(w.spawnflags & WEP_TYPE_SPLASH) {  // splash damage
166                         ent.stats_fired[ent.weapon - 1] += maxdamage;
167                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);
168                 }
169         }
170
171         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
172
173         if(ent.weaponentity.movedir_x > 0)
174                 vecs = ent.weaponentity.movedir;
175         else
176                 vecs = '0 0 0';
177         if(debug_shotorg != '0 0 0')
178                 vecs = debug_shotorg;
179
180         dv = v_right * -vecs_y + v_up * vecs_z;
181         w_shotorg = ent.origin + ent.view_ofs + dv;
182
183         // now move the shotorg forward as much as requested if possible
184         if(antilag)
185         {
186                 if(ent.antilag_debug)
187                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
188                 else
189                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
190         }
191         else
192                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
193         w_shotorg = trace_endpos - v_forward * nudge;
194         // calculate the shotdir from the chosen shotorg
195         w_shotdir = normalize(w_shotend - w_shotorg);
196
197         if (antilag)
198         if (!ent.cvar_cl_noantilag)
199         {
200                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
201                 {
202                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
203                         if (!trace_ent.takedamage)
204                         {
205                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
206                                 if (trace_ent.takedamage && trace_ent.classname == "player")
207                                 {
208                                         entity e;
209                                         e = trace_ent;
210                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
211                                         if(trace_ent == e)
212                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
213                                 }
214                         }
215                 }
216                 else if(cvar("g_antilag") == 3) // client side hitscan
217                 {
218                         // this part MUST use prydon cursor
219                         if (ent.cursor_trace_ent)                 // client was aiming at someone
220                         if (ent.cursor_trace_ent != ent)         // just to make sure
221                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
222                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
223                         {
224                                 // verify that the shot would miss without antilag
225                                 // (avoids an issue where guns would always shoot at their origin)
226                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
227                                 if (!trace_ent.takedamage)
228                                 {
229                                         // verify that the shot would hit if altered
230                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
231                                         if (trace_ent == ent.cursor_trace_ent)
232                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
233                                         else
234                                                 print("antilag fail\n");
235                                 }
236                         }
237                 }
238         }
239
240         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
241
242         if (!g_norecoil)
243                 ent.punchangle_x = recoil * -1;
244
245         if (snd != "")
246         {
247                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
248         }
249
250         if(ent.items & IT_STRENGTH)
251         if(!g_minstagib)
252         if(
253                 (time > ent.prevstrengthsound + cvar("sv_strengthsound_antispam_time"))
254                 ||
255                 (time > ent.prevstrengthsoundattempt + cvar("sv_strengthsound_antispam_refire_threshold"))
256         ) // prevent insane sound spam
257         {
258                 sound(ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
259                 ent.prevstrengthsound = time;
260         }
261         ent.prevstrengthsoundattempt = time;
262
263         // nudge w_shotend so a trace to w_shotend hits
264         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
265 };
266
267 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, maxdamage, MAX_SHOT_DISTANCE)
268 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
269 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
270 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
271 #define W_SetupShot_Range(ent,antilag,recoil,snd,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage, range)
272
273 void LaserTarget_Think()
274 {
275         entity e;
276         vector offset;
277         float uselaser;
278         uselaser = 0;
279
280         // list of weapons that will use the laser, and the options that enable it
281         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
282                 uselaser = 1;
283         // example
284         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
285         //      uselaser = 1;
286
287
288
289         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
290         if(!uselaser)
291         {
292                 // rocket launcher isn't selected, so no laser target.
293                 if(self.lasertarget != world)
294                 {
295                         remove(self.lasertarget);
296                         self.lasertarget = world;
297                 }
298                 return;
299         }
300
301         if(!self.lasertarget)
302         {
303                 // we don't have a lasertarget entity, so spawn one
304                 //bprint("create laser target\n");
305                 e = self.lasertarget = spawn();
306                 e.owner = self.owner;                   // Its owner is my owner
307                 e.classname = "laser_target";
308                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
309                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
310                 e.scale = 1.25;                         // make it larger
311                 e.alpha = 0.25;                         // transparency
312                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
313                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
314                 // make it dynamically glow
315                 // you should avoid over-using this, as it can slow down the player's computer.
316                 e.glow_color = 251; // red color
317                 e.glow_size = 12;
318         }
319         else
320                 e = self.lasertarget;
321
322         // move the laser dot to where the player is looking
323
324         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
325         offset = '0 0 26' + v_right*3;
326         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
327         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
328         if(trace_plane_normal != '0 0 0')
329                 e.angles = vectoangles(trace_plane_normal);
330         else
331                 e.angles = vectoangles(v_forward);
332 }
333
334 float CL_Weaponentity_CustomizeEntityForClient()
335 {
336         self.viewmodelforclient = self.owner;
337         if(other.classname == "spectator")
338                 if(other.enemy == self.owner)
339                         self.viewmodelforclient = other;
340         return TRUE;
341 }
342
343 float qcweaponanimation;
344 vector weapon_offset = '0 -10 0';
345 vector weapon_adjust = '10 0 -15';
346 .vector weapon_morph0origin;
347 .vector weapon_morph0angles;
348 .float  weapon_morph0time;
349 .vector weapon_morph1origin;
350 .vector weapon_morph1angles;
351 .float  weapon_morph1time;
352 .vector weapon_morph2origin;
353 .vector weapon_morph2angles;
354 .float  weapon_morph2time;
355 .vector weapon_morph3origin;
356 .vector weapon_morph3angles;
357 .float  weapon_morph3time;
358 .vector weapon_morph4origin;
359 .vector weapon_morph4angles;
360 .float  weapon_morph4time;
361 .string weaponname;
362 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
363
364 /*
365  * supported formats:
366  *
367  * 1. simple animated model, muzzle flash handling on h_ model:
368  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
369  *      tags:
370  *        shot = muzzle end (shot origin, also used for muzzle flashes)
371  *        shell = casings ejection point (must be on the right hand side of the gun)
372  *        weapon = attachment for v_tuba.md3
373  *    v_tuba.md3 - first and third person model
374  *    g_tuba.md3 - pickup model
375  *
376  * 2. simple animated model, muzzle flash handling on v_ model:
377  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
378  *      tags:
379  *        weapon = attachment for v_tuba.md3
380  *    v_tuba.md3 - first and third person model
381  *      tags:
382  *        shot = muzzle end (shot origin, also used for muzzle flashes)
383  *        shell = casings ejection point (must be on the right hand side of the gun)
384  *    g_tuba.md3 - pickup model
385  *
386  * 3. fully animated model, muzzle flash handling on h_ model:
387  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
388  *      tags:
389  *        shot = muzzle end (shot origin, also used for muzzle flashes)
390  *        shell = casings ejection point (must be on the right hand side of the gun)
391  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
392  *    v_tuba.md3 - third person model
393  *    g_tuba.md3 - pickup model
394  *
395  * 4. fully animated model, muzzle flash handling on v_ model:
396  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
397  *      tags:
398  *        shot = muzzle end (shot origin)
399  *        shell = casings ejection point (must be on the right hand side of the gun)
400  *    v_tuba.md3 - third person model
401  *      tags:
402  *        shot = muzzle end (for muzzle flashes)
403  *    g_tuba.md3 - pickup model
404  */
405
406 // writes:
407 //   self.origin, self.angles
408 //   self.weaponentity
409 //   self.movedir, self.view_ofs
410 //   attachment stuff
411 //   anim stuff
412 // to free:
413 //   call again with ""
414 //   remove the ent
415 void CL_WeaponEntity_SetModel(string name)
416 {
417         string animfilename;
418         float animfile;
419         float v_shot_idx;
420         if (name != "")
421         {
422                 // if there is a child entity, hide it until we're sure we use it
423                 if (self.weaponentity)
424                         self.weaponentity.model = "";
425                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
426                 v_shot_idx = gettagindex(self, "shot"); // used later
427                 if(!v_shot_idx)
428                         v_shot_idx = gettagindex(self, "tag_shot");
429
430                 if(qcweaponanimation)
431                 {
432                         self.angles = '0 0 0';
433                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
434                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
435                         self.movedir_x += 32;
436                         self.spawnorigin = self.movedir;
437                         // oldorigin - not calculated here
438                 }
439                 else
440                 {
441                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
442                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
443                         animfile = fopen(animfilename, FILE_READ);
444                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
445                         self.anim_fire1  = '0 1 0.01';
446                         self.anim_fire2  = '1 1 0.01';
447                         self.anim_idle   = '2 1 0.01';
448                         self.anim_reload = '3 1 0.01';
449                         if (animfile >= 0)
450                         {
451                                 animparseerror = FALSE;
452                                 self.anim_fire1  = animparseline(animfile);
453                                 self.anim_fire2  = animparseline(animfile);
454                                 self.anim_idle   = animparseline(animfile);
455                                 self.anim_reload = animparseline(animfile);
456                                 fclose(animfile);
457                                 if (animparseerror)
458                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
459                         }
460
461                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
462                         // if we don't, this is a "real" animated model
463                         if(gettagindex(self, "weapon"))
464                         {
465                                 if (!self.weaponentity)
466                                         self.weaponentity = spawn();
467                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
468                                 setattachment(self.weaponentity, self, "weapon");
469                         }
470                         else if(gettagindex(self, "tag_weapon"))
471                         {
472                                 if (!self.weaponentity)
473                                         self.weaponentity = spawn();
474                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
475                                 setattachment(self.weaponentity, self, "tag_weapon");
476                         }
477                         else
478                         {
479                                 if(self.weaponentity)
480                                         remove(self.weaponentity);
481                                 self.weaponentity = world;
482                         }
483
484                         setorigin(self,'0 0 0');
485                         self.angles = '0 0 0';
486                         self.frame = 0;
487                         self.viewmodelforclient = world;
488
489                         float idx;
490
491                         if(v_shot_idx) // v_ model attached to invisible h_ model
492                         {
493                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
494                         }
495                         else
496                         {
497                                 idx = gettagindex(self, "shot");
498                                 if(!idx)
499                                         idx = gettagindex(self, "tag_shot");
500                                 if(idx)
501                                         self.movedir = gettaginfo(self, idx);
502                                 else
503                                 {
504                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
505                                         self.movedir = '0 0 0';
506                                 }
507                         }
508
509                         if(self.weaponentity) // v_ model attached to invisible h_ model
510                         {
511                                 idx = gettagindex(self.weaponentity, "shell");
512                                 if(!idx)
513                                         idx = gettagindex(self.weaponentity, "tag_shell");
514                                 if(idx)
515                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
516                         }
517                         else
518                                 idx = 0;
519                         if(!idx)
520                         {
521                                 idx = gettagindex(self, "shell");
522                                 if(!idx)
523                                         idx = gettagindex(self, "tag_shell");
524                                 if(idx)
525                                         self.spawnorigin = gettaginfo(self, idx);
526                                 else
527                                 {
528                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
529                                         self.spawnorigin = self.movedir;
530                                 }
531                         }
532
533                         if(v_shot_idx)
534                         {
535                                 self.oldorigin = '0 0 0'; // use regular attachment
536                         }
537                         else
538                         {
539                                 if(self.weaponentity)
540                                 {
541                                         idx = gettagindex(self, "weapon");
542                                         if(!idx)
543                                                 idx = gettagindex(self, "tag_weapon");
544                                 }
545                                 else
546                                 {
547                                         idx = gettagindex(self, "handle");
548                                         if(!idx)
549                                                 idx = gettagindex(self, "tag_handle");
550                                 }
551                                 if(idx)
552                                 {
553                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
554                                 }
555                                 else
556                                 {
557                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
558                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
559                                 }
560                         }
561
562                         self.viewmodelforclient = self.owner;
563                 }
564         }
565         else
566         {
567                 self.model = "";
568                 if(self.weaponentity)
569                         remove(self.weaponentity);
570                 self.weaponentity = world;
571                 self.movedir = '0 0 0';
572                 self.spawnorigin = '0 0 0';
573                 self.oldorigin = '0 0 0';
574                 self.anim_fire1  = '0 1 0.01';
575                 self.anim_fire2  = '0 1 0.01';
576                 self.anim_idle   = '0 1 0.01';
577                 self.anim_reload = '0 1 0.01';
578         }
579
580         self.view_ofs = '0 0 0';
581
582         if(self.movedir_x >= 0)
583         {
584                 vector v0;
585                 v0 = self.movedir;
586                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
587                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
588         }
589         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
590         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
591
592         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
593
594         // check if an instant weapon switch occurred
595         if (qcweaponanimation)
596         {
597                 if (self.state == WS_READY)
598                 {
599                         self.angles = '0 0 0';
600                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
601                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
602                 }
603         }
604         else
605                 setorigin(self, self.view_ofs);
606         // reset animstate now
607         self.wframe = WFRAME_IDLE;
608         self.weapon_morph0time = 0;
609         self.weapon_morph1time = 0;
610         self.weapon_morph2time = 0;
611         self.weapon_morph3time = 0;
612         self.weapon_morph4time = 0;
613         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
614 }
615
616 vector CL_Weapon_GetShotOrg(float wpn)
617 {
618         entity wi, oldself;
619         vector ret;
620         wi = get_weaponinfo(wpn);
621         oldself = self;
622         self = spawn();
623         CL_WeaponEntity_SetModel(wi.mdl);
624         ret = self.movedir;
625         CL_WeaponEntity_SetModel("");
626         remove(self);
627         self = oldself;
628         return ret;
629 }
630
631 void CL_Weaponentity_Think()
632 {
633         float tb;
634         self.nextthink = time;
635         if (intermission_running)
636                 self.frame = self.anim_idle_x;
637         if (self.owner.weaponentity != self)
638         {
639                 if (self.weaponentity)
640                         remove(self.weaponentity);
641                 remove(self);
642                 return;
643         }
644         if (self.owner.deadflag != DEAD_NO)
645         {
646                 self.model = "";
647                 if (self.weaponentity)
648                         self.weaponentity.model = "";
649                 return;
650         }
651         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
652         {
653                 self.cnt = self.owner.weapon;
654                 self.dmg = self.owner.modelindex;
655                 self.deadflag = self.owner.deadflag;
656
657                 CL_WeaponEntity_SetModel(self.owner.weaponname);
658         }
659
660         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
661         self.effects = self.owner.effects & EFMASK_CHEAP;
662         self.effects &~= EF_LOWPRECISION;
663         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
664         self.effects &~= EF_TELEPORT_BIT;
665         self.effects &~= EF_RESTARTANIM_BIT;
666         self.effects |= tb;
667
668         if(self.owner.alpha == default_player_alpha)
669                 self.alpha = default_weapon_alpha;
670         else if(self.owner.alpha != 0)
671                 self.alpha = self.owner.alpha;
672         else
673                 self.alpha = 1;
674
675         self.colormap = self.owner.colormap;
676         if (self.weaponentity)
677         {
678                 self.weaponentity.effects = self.effects;
679                 self.weaponentity.alpha = self.alpha;
680                 self.weaponentity.colormap = self.colormap;
681         }
682
683         self.angles = '0 0 0';
684         local float f;
685         f = 0;
686         if (self.state == WS_RAISE && !intermission_running)
687         {
688                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
689                 self.angles_x = -90 * f * f;
690                 if (qcweaponanimation)
691                 {
692                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
693                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
694                 }
695         }
696         else if (self.state == WS_DROP && !intermission_running)
697         {
698                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
699                 self.angles_x = -90 * f * f;
700                 if (qcweaponanimation)
701                 {
702                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
703                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
704                 }
705         }
706         else if (self.state == WS_CLEAR)
707         {
708                 f = 1;
709                 self.angles_x = -90 * f * f;
710                 if (qcweaponanimation)
711                 {
712                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
713                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
714                 }
715         }
716         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
717         {
718                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
719                 f = 1 - pow(1 - f, 3);
720                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
721                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
722         }
723         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
724         {
725                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
726                 f = 1 - pow(1 - f, 3);
727                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
728                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
729         }
730         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
731         {
732                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
733                 f = 1 - pow(1 - f, 3);
734                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
735                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
736         }
737         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
738         {
739                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
740                 f = 1 - pow(1 - f, 3);
741                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
742                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
743         }
744         else if (qcweaponanimation)
745         {
746                 // begin a new idle morph
747                 self.owner.weapon_morph0time   = time;
748                 self.owner.weapon_morph0angles = self.angles;
749                 self.owner.weapon_morph0origin = self.origin;
750
751                 float r;
752                 float t;
753
754                 r = random();
755                 if (r < 0.1)
756                 {
757                         // turn gun to the left to look at it
758                         t = 2;
759                         self.owner.weapon_morph1time   = time + t * 0.2;
760                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
761                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
762                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
763
764                         self.owner.weapon_morph2time   = time + t * 0.6;
765                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
766                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
767                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
768
769                         self.owner.weapon_morph3time   = time + t;
770                         self.owner.weapon_morph3angles = '0 0 0';
771                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
772                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
773                 }
774                 else if (r < 0.2)
775                 {
776                         // raise the gun a bit
777                         t = 2;
778                         self.owner.weapon_morph1time   = time + t * 0.2;
779                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
780                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
781                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
782
783                         self.owner.weapon_morph2time   = time + t * 0.5;
784                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
785                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
786                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
787
788                         self.owner.weapon_morph3time   = time + t;
789                         self.owner.weapon_morph3angles = '0 0 0';
790                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
791                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
792                 }
793                 else if (r < 0.3)
794                 {
795                         // tweak it a bit
796                         t = 5;
797                         self.owner.weapon_morph1time   = time + t * 0.3;
798                         self.owner.weapon_morph1angles = randomvec() * 6;
799                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
800                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
801
802                         self.owner.weapon_morph2time   = time + t * 0.7;
803                         self.owner.weapon_morph2angles = randomvec() * 6;
804                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
805                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
806
807                         self.owner.weapon_morph3time   = time + t;
808                         self.owner.weapon_morph3angles = '0 0 0';
809                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
810                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
811                 }
812                 else
813                 {
814                         // hold it mostly steady
815                         t = random() * 6 + 4;
816                         self.owner.weapon_morph1time   = time + t * 0.2;
817                         self.owner.weapon_morph1angles = randomvec() * 1;
818                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
819                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
820
821                         self.owner.weapon_morph2time   = time + t * 0.5;
822                         self.owner.weapon_morph2angles = randomvec() * 1;
823                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
824                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
825
826                         self.owner.weapon_morph3time   = time + t * 0.7;
827                         self.owner.weapon_morph3angles = randomvec() * 1;
828                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
829                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
830                 }
831
832                 self.owner.weapon_morph4time   = time + t;
833                 self.owner.weapon_morph4angles = '0 0 0';
834                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
835                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
836
837         }
838
839         // create or update the lasertarget entity
840         LaserTarget_Think();
841 };
842
843 void CL_ExteriorWeaponentity_Think()
844 {
845         float tag_found;
846         vector ang;
847         self.nextthink = time;
848         if (self.owner.exteriorweaponentity != self)
849         {
850                 remove(self);
851                 return;
852         }
853         if (self.owner.deadflag != DEAD_NO)
854         {
855                 self.model = "";
856                 return;
857         }
858         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
859         {
860                 self.cnt = self.owner.weapon;
861                 self.dmg = self.owner.modelindex;
862                 self.deadflag = self.owner.deadflag;
863                 if (self.owner.weaponname != "")
864                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
865                 else
866                         self.model = "";
867
868                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
869                 {
870                         self.tag_index = tag_found;
871                         self.tag_entity = self.owner;
872                 }
873                 else
874                         setattachment(self, self.owner, "bip01 r hand");
875
876                 // if that didn't find a tag, hide the exterior weapon model
877                 if (!self.tag_index)
878                         self.model = "";
879         }
880         self.effects = self.owner.effects;
881         if(sv_pitch_min == sv_pitch_max)
882                 self.effects |= EF_LOWPRECISION;
883         else
884                 self.effects &~= EF_LOWPRECISION;
885         self.effects = self.effects & EFMASK_CHEAP; // eat performance
886         if(self.owner.alpha == default_player_alpha)
887                 self.alpha = default_weapon_alpha;
888         else if(self.owner.alpha != 0)
889                 self.alpha = self.owner.alpha;
890         else
891                 self.alpha = 1;
892
893         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
894         ang_y = 0;
895         ang_z = 0;
896
897         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
898         {
899                 ang_y = self.owner.v_angle_y;
900                 makevectors(ang);
901                 var vector v = v_forward;
902                 var float t = self.tag_entity.frame1time;
903                 var float f = self.tag_entity.frame;
904                 self.tag_entity.frame1time = time;
905                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
906                 gettaginfo(self.tag_entity, self.tag_index);
907                 self.tag_entity.frame1time = t;
908                 self.tag_entity.frame = f;
909                 // untransform v according to this coordinate space
910                 vector w;
911                 w_x = v_forward * v;
912                 w_y = -v_right * v;
913                 w_z = v_up * v;
914                 self.angles = vectoangles(w);
915         }
916         else
917         {
918                 ang_x = -/* don't ask */ang_x;
919                 self.angles = ang;
920         }
921
922         self.colormap = self.owner.colormap;
923 };
924
925 // spawning weaponentity for client
926 void CL_SpawnWeaponentity()
927 {
928         self.weaponentity = spawn();
929         self.weaponentity.classname = "weaponentity";
930         self.weaponentity.solid = SOLID_NOT;
931         self.weaponentity.owner = self;
932         setmodel(self.weaponentity, ""); // precision set when changed
933         setorigin(self.weaponentity, '0 0 0');
934         self.weaponentity.angles = '0 0 0';
935         self.weaponentity.viewmodelforclient = self;
936         self.weaponentity.flags = 0;
937         self.weaponentity.think = CL_Weaponentity_Think;
938         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
939         self.weaponentity.nextthink = time;
940
941         self.exteriorweaponentity = spawn();
942         self.exteriorweaponentity.classname = "exteriorweaponentity";
943         self.exteriorweaponentity.solid = SOLID_NOT;
944         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
945         self.exteriorweaponentity.owner = self;
946         setorigin(self.exteriorweaponentity, '0 0 0');
947         self.exteriorweaponentity.angles = '0 0 0';
948         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
949         self.exteriorweaponentity.nextthink = time;
950 };
951
952 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
953 {
954         msg_entity = e;
955         WriteByte(MSG_ONE, SVC_TEMPENTITY);
956         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
957         WriteByte(MSG_ONE, wpn);
958         WriteString(MSG_ONE, wpnname);
959         WriteByte(MSG_ONE, type);
960 }
961
962 .float hasweapon_complain_spam;
963
964 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
965 {
966         local float weaponbit, f;
967         local entity oldself;
968
969         if(time < self.hasweapon_complain_spam)
970                 complain = 0;
971         if(complain)
972                 self.hasweapon_complain_spam = time + 0.2;
973
974         if (wpn < WEP_FIRST || wpn > WEP_LAST)
975         {
976                 if (complain)
977                         sprint(self, "Invalid weapon\n");
978                 return FALSE;
979         }
980         weaponbit = W_WeaponBit(wpn);
981         if (cl.weapons & weaponbit)
982         {
983                 if (andammo)
984                 {
985                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
986                         {
987                                 f = 1;
988                         }
989                         else
990                         {
991                                 oldself = self;
992                                 self = cl;
993                                 f = weapon_action(wpn, WR_CHECKAMMO1);
994                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
995
996                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
997                                 local entity mine;
998                                 if(wpn == WEP_MINE_LAYER)
999                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1000                                         f = 1;
1001
1002                                 self = oldself;
1003                         }
1004                         if (!f)
1005                         {
1006                                 if (complain)
1007                                 if(clienttype(cl) == CLIENTTYPE_REAL)
1008                                 {
1009                                         play2(cl, "weapons/unavailable.wav");
1010                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
1011                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
1012                                 }
1013                                 return FALSE;
1014                         }
1015                 }
1016                 return TRUE;
1017         }
1018         if (complain)
1019         {
1020                 // DRESK - 3/16/07
1021                 // Report Proper Weapon Status / Modified Weapon Ownership Message
1022                 if(weaponsInMap & weaponbit)
1023                 {
1024                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
1025                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
1026
1027                         if(cvar("g_showweaponspawns"))
1028                         {
1029                                 entity e;
1030                                 string s;
1031
1032                                 e = get_weaponinfo(wpn);
1033                                 s = e.model2;
1034
1035                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
1036                                 {
1037                                         if(e.classname == "droppedweapon")
1038                                                 continue;
1039                                         if not(e.flags & FL_ITEM)
1040                                                 continue;
1041                                         WaypointSprite_Spawn(
1042                                                 s,
1043                                                 1, 0,
1044                                                 world, e.origin,
1045                                                 self, 0,
1046                                                 world, enemy,
1047                                                 0
1048                                         );
1049                                 }
1050                         }
1051                 }
1052                 else
1053                 {
1054                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
1055                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
1056                 }
1057
1058                 play2(cl, "weapons/unavailable.wav");
1059         }
1060         return FALSE;
1061 };
1062
1063 // Weapon subs
1064 void w_clear()
1065 {
1066         if (self.weapon != -1)
1067                 self.weapon = 0;
1068         if (self.weaponentity)
1069         {
1070                 self.weaponentity.state = WS_CLEAR;
1071                 self.weaponentity.effects = 0;
1072         }
1073 };
1074
1075 void w_ready()
1076 {
1077         if (self.weaponentity)
1078                 self.weaponentity.state = WS_READY;
1079         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1080 };
1081
1082 // Setup weapon for client (after this raise frame will be launched)
1083 void weapon_setup(float windex)
1084 {
1085         entity e;
1086         qcweaponanimation = cvar("sv_qcweaponanimation");
1087         e = get_weaponinfo(windex);
1088         self.items &~= IT_AMMO;
1089         self.items = self.items | e.items;
1090
1091         // the two weapon entities will notice this has changed and update their models
1092         self.weapon = windex;
1093         self.weaponname = e.mdl;
1094         self.bulletcounter = 0;
1095 };
1096
1097 // perform weapon to attack (weaponstate and attack_finished check is here)
1098 void W_SwitchToOtherWeapon(entity pl)
1099 {
1100         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1101         float w, ww;
1102         w = W_WeaponBit(pl.weapon);
1103         pl.weapons &~= w;
1104         ww = w_getbestweapon(pl);
1105         pl.weapons |= w;
1106         if(ww)
1107                 W_SwitchWeapon_Force(pl, ww);
1108 }
1109 float weapon_prepareattack_checkammo(float secondary)
1110 {
1111         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1112         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1113         {
1114                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1115                 local entity mine;
1116                 if(self.weapon == WEP_MINE_LAYER)
1117                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1118                         return FALSE;
1119
1120                 if(self.weapon == self.switchweapon) // only play once BEFORE starting to switch weapons
1121                         sound (self, CHAN_AUTO, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1122
1123                 W_SwitchToOtherWeapon(self);
1124                 return FALSE;
1125         }
1126         return TRUE;
1127 }
1128 .float race_penalty;
1129 float weapon_prepareattack_check(float secondary, float attacktime)
1130 {
1131         if(!weapon_prepareattack_checkammo(secondary))
1132                 return FALSE;
1133
1134         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1135         //if all players readied up and the countdown is running
1136         if(time < game_starttime || time < self.race_penalty) {
1137                 return FALSE;
1138         }
1139
1140         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1141                 return FALSE;
1142
1143         // do not even think about shooting if switching
1144         if(self.switchweapon != self.weapon)
1145                 return FALSE;
1146
1147         if(attacktime >= 0)
1148         {
1149                 // don't fire if previous attack is not finished
1150                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1151                         return FALSE;
1152                 // don't fire while changing weapon
1153                 if (self.weaponentity.state != WS_READY)
1154                         return FALSE;
1155         }
1156
1157         return TRUE;
1158 }
1159 float weapon_prepareattack_do(float secondary, float attacktime)
1160 {
1161         self.weaponentity.state = WS_INUSE;
1162
1163         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1164
1165         // if the weapon hasn't been firing continuously, reset the timer
1166         if(attacktime >= 0)
1167         {
1168                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1169                 {
1170                         ATTACK_FINISHED(self) = time;
1171                         //dprint("resetting attack finished to ", ftos(time), "\n");
1172                 }
1173                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1174         }
1175         self.bulletcounter += 1;
1176         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1177         return TRUE;
1178 }
1179 float weapon_prepareattack(float secondary, float attacktime)
1180 {
1181         if(weapon_prepareattack_check(secondary, attacktime))
1182         {
1183                 weapon_prepareattack_do(secondary, attacktime);
1184                 return TRUE;
1185         }
1186         else
1187                 return FALSE;
1188 }
1189
1190 void weapon_thinkf(float fr, float t, void() func)
1191 {
1192         vector a;
1193         vector of, or, ou;
1194         float restartanim;
1195
1196         if(fr == WFRAME_DONTCHANGE)
1197         {
1198                 fr = self.weaponentity.wframe;
1199                 restartanim = FALSE;
1200         }
1201         else if (fr == WFRAME_IDLE)
1202                 restartanim = FALSE;
1203         else
1204                 restartanim = TRUE;
1205
1206         of = v_forward;
1207         or = v_right;
1208         ou = v_up;
1209
1210         if (self.weaponentity)
1211         {
1212                 self.weaponentity.wframe = fr;
1213                 if (qcweaponanimation)
1214                 {
1215                         if (fr != WFRAME_IDLE)
1216                         {
1217                                 self.weapon_morph0time = time;
1218                                 self.weapon_morph0angles = self.weaponentity.angles;
1219                                 self.weapon_morph0origin = self.weaponentity.origin;
1220
1221                                 self.weapon_morph1angles = '0 0 0';
1222                                 self.weapon_morph1time = time + t;
1223                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1224                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1225
1226                                 self.weapon_morph2angles = '0 0 0';
1227                                 self.weapon_morph2time = time + t;
1228                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1229                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1230
1231                                 self.weapon_morph3angles = '0 0 0';
1232                                 self.weapon_morph3time = time + t;
1233                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1234                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1235
1236                                 self.weapon_morph4angles = '0 0 0';
1237                                 self.weapon_morph4time = time + t;
1238                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1239                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1240
1241                                 if (fr == WFRAME_FIRE1)
1242                                 {
1243                                         self.weapon_morph1angles = '5 0 0';
1244                                         self.weapon_morph1time = time + t * 0.1;
1245                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1246                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1247                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1248                                 }
1249                                 else if (fr == WFRAME_FIRE2)
1250                                 {
1251                                         self.weapon_morph1angles = '10 0 0';
1252                                         self.weapon_morph1time = time + t * 0.1;
1253                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1254                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1255                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1256                                 }
1257                                 else if (fr == WFRAME_RELOAD)
1258                                 {
1259                                         self.weapon_morph1time = time + t * 0.05;
1260                                         self.weapon_morph1angles = '-10 40 0';
1261                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1262                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1263
1264                                         self.weapon_morph2time = time + t * 0.15;
1265                                         self.weapon_morph2angles = '-10 40 5';
1266                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1267                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1268
1269                                         self.weapon_morph3time = time + t * 0.25;
1270                                         self.weapon_morph3angles = '-10 40 0';
1271                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1272                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1273                                 }
1274                         }
1275                 }
1276                 else
1277                 {
1278                         if (fr == WFRAME_IDLE)
1279                                 a = self.weaponentity.anim_idle;
1280                         else if (fr == WFRAME_FIRE1)
1281                                 a = self.weaponentity.anim_fire1;
1282                         else if (fr == WFRAME_FIRE2)
1283                                 a = self.weaponentity.anim_fire2;
1284                         else if (fr == WFRAME_RELOAD)
1285                                 a = self.weaponentity.anim_reload;
1286                         a_z *= g_weaponratefactor;
1287                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1288                 }
1289         }
1290
1291         v_forward = of;
1292         v_right = or;
1293         v_up = ou;
1294
1295         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1296         {
1297                 backtrace("Tried to override initial weapon think function - should this really happen?");
1298         }
1299
1300         t *= W_WeaponRateFactor();
1301
1302         // VorteX: haste can be added here
1303         if (self.weapon_think == w_ready)
1304         {
1305                 self.weapon_nextthink = time;
1306                 //dprint("started firing at ", ftos(time), "\n");
1307         }
1308         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1309         {
1310                 self.weapon_nextthink = time;
1311                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1312         }
1313         self.weapon_nextthink = self.weapon_nextthink + t;
1314         self.weapon_think = func;
1315         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1316
1317         if (restartanim)
1318         if (t)
1319         if (!self.crouch) // shoot anim stands up, this looks bad
1320         {
1321                 local vector anim;
1322                 anim = self.anim_shoot;
1323                 anim_z = anim_y / (t + sys_frametime);
1324                 setanim(self, anim, FALSE, TRUE, TRUE);
1325         }
1326 };
1327
1328 void weapon_boblayer1(float spd, vector org)
1329 {
1330         // VorteX: haste can be added here
1331 };
1332
1333 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1334 {
1335         vector mdirection;
1336         float mspeed;
1337         float outspeed;
1338         float nstyle;
1339         vector outvelocity;
1340
1341         mvelocity = mvelocity * g_weaponspeedfactor;
1342
1343         mdirection = normalize(mvelocity);
1344         mspeed = vlen(mvelocity);
1345
1346         nstyle = cvar("g_projectiles_newton_style");
1347         if(nstyle == 0)
1348         {
1349                 // absolute velocity
1350                 outvelocity = mvelocity;
1351         }
1352         else if(nstyle == 1)
1353         {
1354                 // true Newtonian projectiles
1355                 outvelocity = pvelocity + mvelocity;
1356         }
1357         else if(nstyle == 2)
1358         {
1359                 // true Newtonian projectiles with automatic aim adjustment
1360                 //
1361                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1362                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1363                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1364                 // PLUS SIGN!
1365                 // not defined?
1366                 // then...
1367                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1368                 // velocity without mdirection component > mspeed
1369                 // fire at smallest possible mspeed that works?
1370                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1371
1372                 vector solution;
1373                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1374                 if(solution_z)
1375                         outspeed = solution_y; // the larger one
1376                 else
1377                 {
1378                         //outspeed = 0; // slowest possible shot
1379                         outspeed = solution_x; // the real part (that is, the average!)
1380                         //dprint("impossible shot, adjusting\n");
1381                 }
1382
1383                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1384                 outvelocity = mdirection * outspeed;
1385         }
1386         else if(nstyle == 3)
1387         {
1388                 // pseudo-Newtonian:
1389                 outspeed = mspeed + mdirection * pvelocity;
1390                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1391                 outvelocity = mdirection * outspeed;
1392         }
1393         else if(nstyle == 4)
1394         {
1395                 // tZorkian:
1396                 outspeed = mspeed + vlen(pvelocity);
1397                 outvelocity = mdirection * outspeed;
1398         }
1399         else
1400                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1401
1402         return outvelocity;
1403 }
1404
1405 void W_AttachToShotorg(entity flash, vector offset)
1406 {
1407         entity xflash;
1408         flash.owner = self;
1409         flash.angles_z = random() * 360;
1410         if(qcweaponanimation)
1411         {
1412                 setorigin(flash, w_shotorg + w_shotdir * 50);
1413                 flash.angles = vectoangles(w_shotdir);
1414                 flash.angles_z = random() * 360;
1415         }
1416         else
1417         {
1418                 if(gettagindex(self.weaponentity, "shot"))
1419                         setattachment(flash, self.weaponentity, "shot");
1420                 else
1421                         setattachment(flash, self.weaponentity, "tag_shot");
1422                 setorigin(flash, offset);
1423
1424                 xflash = spawn();
1425                 copyentity(flash, xflash);
1426
1427                 flash.viewmodelforclient = self;
1428
1429                 if(self.weaponentity.oldorigin_x > 0)
1430                 {
1431                         setattachment(xflash, self.exteriorweaponentity, "");
1432                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1433                 }
1434                 else
1435                 {
1436                         if(gettagindex(self.exteriorweaponentity, "shot"))
1437                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1438                         else
1439                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1440                         setorigin(xflash, offset);
1441                 }
1442         }
1443 }
1444
1445 vector cliptoplane(vector v, vector p)
1446 {
1447         return v - (v * p) * p;
1448 }
1449
1450 vector solve_cubic_pq(float p, float q)
1451 {
1452         float D, u, v, a;
1453         D = q*q/4.0 + p*p*p/27.0;
1454         if(D < 0)
1455         {
1456                 // irreducibilis
1457                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1458                 u = sqrt(-4.0/3.0 * p);
1459                 // a in range 0..pi/3
1460                 // cos(a)
1461                 // cos(a + 2pi/3)
1462                 // cos(a + 4pi/3)
1463                 return
1464                         u *
1465                         (
1466                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1467                                 +
1468                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1469                                 +
1470                                 '0 0 1' * cos(a)
1471                         );
1472         }
1473         else if(D == 0)
1474         {
1475                 // simple
1476                 if(p == 0)
1477                         return '0 0 0';
1478                 u = 3*q/p;
1479                 v = -u/2;
1480                 if(u >= v)
1481                         return '1 1 0' * v + '0 0 1' * u;
1482                 else
1483                         return '0 1 1' * v + '1 0 0' * u;
1484         }
1485         else
1486         {
1487                 // cardano
1488                 u = cbrt(-q/2.0 + sqrt(D));
1489                 v = cbrt(-q/2.0 - sqrt(D));
1490                 return '1 1 1' * (u + v);
1491         }
1492 }
1493 vector solve_cubic_abcd(float a, float b, float c, float d)
1494 {
1495         // y = 3*a*x + b
1496         // x = (y - b) / 3a
1497         float p, q;
1498         vector v;
1499         p = (9*a*c - 3*b*b);
1500         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1501         v = solve_cubic_pq(p, q);
1502         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1503         if(a < 0)
1504                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1505         return v;
1506 }
1507
1508 vector findperpendicular(vector v)
1509 {
1510         vector p;
1511         p_x = v_z;
1512         p_y = -v_x;
1513         p_z = v_y;
1514         return normalize(cliptoplane(p, v));
1515 }
1516
1517 vector W_CalculateProjectileSpread(vector forward, float spread)
1518 {
1519         float sigma;
1520         vector v1, v2;
1521         float dx, dy, r;
1522         float sstyle;
1523         spread *= g_weaponspreadfactor;
1524         if(spread <= 0)
1525                 return forward;
1526         sstyle = cvar("g_projectiles_spread_style");
1527         
1528         if(sstyle == 0)
1529         {
1530                 // this is the baseline for the spread value!
1531                 // standard deviation: sqrt(2/5)
1532                 // density function: sqrt(1-r^2)
1533                 return forward + randomvec() * spread;
1534         }
1535         else if(sstyle == 1)
1536         {
1537                 // same thing, basically
1538                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1539         }
1540         else if(sstyle == 2)
1541         {
1542                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1543                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1544                 v1 = findperpendicular(forward);
1545                 v2 = cross(forward, v1);
1546                 // random point on unit circle
1547                 dx = random() * 2 * M_PI;
1548                 dy = sin(dx);
1549                 dx = cos(dx);
1550                 // radius in our dist function
1551                 r = random();
1552                 r = sqrt(r);
1553                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1554         }
1555         else if(sstyle == 3) // gauss 3d
1556         {
1557                 sigma = spread * 0.44721359549996; // match baseline stddev
1558                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1559                 v1 = forward;
1560                 v1_x += gsl_ran_gaussian(sigma);
1561                 v1_y += gsl_ran_gaussian(sigma);
1562                 v1_z += gsl_ran_gaussian(sigma);
1563                 return v1;
1564         }
1565         else if(sstyle == 4) // gauss 2d
1566         {
1567                 sigma = spread * 0.44721359549996; // match baseline stddev
1568                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1569                 v1_x = gsl_ran_gaussian(sigma);
1570                 v1_y = gsl_ran_gaussian(sigma);
1571                 v1_z = gsl_ran_gaussian(sigma);
1572                 return normalize(forward + cliptoplane(v1, forward));
1573         }
1574         else if(sstyle == 5) // 1-r
1575         {
1576                 sigma = spread * 1.154700538379252; // match baseline stddev
1577                 v1 = findperpendicular(forward);
1578                 v2 = cross(forward, v1);
1579                 // random point on unit circle
1580                 dx = random() * 2 * M_PI;
1581                 dy = sin(dx);
1582                 dx = cos(dx);
1583                 // radius in our dist function
1584                 r = random();
1585                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1586                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1587         }
1588         else if(sstyle == 6) // 1-r^2
1589         {
1590                 sigma = spread * 1.095445115010332; // match baseline stddev
1591                 v1 = findperpendicular(forward);
1592                 v2 = cross(forward, v1);
1593                 // random point on unit circle
1594                 dx = random() * 2 * M_PI;
1595                 dy = sin(dx);
1596                 dx = cos(dx);
1597                 // radius in our dist function
1598                 r = random();
1599                 r = sqrt(1 - r);
1600                 r = sqrt(1 - r);
1601                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1602         }
1603         else if(sstyle == 7) // (1-r) (2-r)
1604         {
1605                 sigma = spread * 1.224744871391589; // match baseline stddev
1606                 v1 = findperpendicular(forward);
1607                 v2 = cross(forward, v1);
1608                 // random point on unit circle
1609                 dx = random() * 2 * M_PI;
1610                 dy = sin(dx);
1611                 dx = cos(dx);
1612                 // radius in our dist function
1613                 r = random();
1614                 r = 1 - sqrt(r);
1615                 r = 1 - sqrt(r);
1616                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1617         }
1618         else
1619                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1620         return '0 0 0';
1621         /*
1622          * how to derive falloff functions:
1623          * rho(r) := (2-r) * (1-r);
1624          * a : 0;
1625          * b : 1;
1626          * rhor(r) := r * rho(r);
1627          * cr(t) := integrate(rhor(r), r, a, t);
1628          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1629          * variance : scr(b) / cr(b);
1630          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1631          * sqrt(0.4 / variance), numer;
1632          */
1633 }
1634
1635 #if 0
1636 float mspercallsum;
1637 float mspercallsstyle;
1638 float mspercallcount;
1639 #endif
1640 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread)
1641 {
1642         if(missile.owner == world)
1643                 error("Unowned missile");
1644
1645         dir = dir + upDir * (pUpSpeed / pSpeed);
1646         dir_z += pZSpeed / pSpeed;
1647         pSpeed *= vlen(dir);
1648         dir = normalize(dir);
1649
1650 #if 0
1651         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1652         {
1653                 mspercallsum = mspercallcount = 0;
1654                 mspercallsstyle = cvar("g_projectiles_spread_style");
1655         }
1656         mspercallsum -= gettime(GETTIME_HIRES);
1657 #endif
1658         dir = W_CalculateProjectileSpread(dir, spread);
1659 #if 0
1660         mspercallsum += gettime(GETTIME_HIRES);
1661         mspercallcount += 1;
1662         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1663 #endif
1664
1665         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1666 }
1667
1668 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1669 {
1670         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread);
1671 }
1672
1673 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"))
1674 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"))