c9a5dfc4aa1b9d61236355e94824506004053edb
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / cl_weaponsystem.qc
1 /*
2 ===========================================================================
3
4   CLIENT WEAPONSYSTEM CODE
5   Bring back W_Weaponframe
6
7 ===========================================================================
8 */
9
10 .float weapon_frametime;
11
12 float W_WeaponRateFactor()
13 {
14         float t;
15         t = 1.0 / g_weaponratefactor;
16
17         if(g_runematch)
18         {
19                 if(self.runes & RUNE_SPEED)
20                 {
21                         if(self.runes & CURSE_SLOW)
22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
23                         else
24                                 t = t * cvar("g_balance_rune_speed_atkrate");
25                 }
26                 else if(self.runes & CURSE_SLOW)
27                 {
28                         t = t * cvar("g_balance_curse_slow_atkrate");
29                 }
30         }
31
32         return t;
33 }
34
35 void W_SwitchWeapon_Force(entity e, float w)
36 {
37         e.cnt = e.switchweapon;
38         e.switchweapon = w;
39         e.selectweapon = w;
40 }
41
42 .float antilag_debug;
43
44 // VorteX: static frame globals
45 float WFRAME_DONTCHANGE = -1;
46 float WFRAME_FIRE1 = 0;
47 float WFRAME_FIRE2 = 1;
48 float WFRAME_IDLE = 2;
49 float WFRAME_RELOAD = 3;
50 .float wframe;
51
52 void(float fr, float t, void() func) weapon_thinkf;
53
54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
55 {
56         vector ret;
57         ret_x = screenright * v;
58         ret_y = screenup * v;
59         ret_z = screenforward * v;
60         return ret;
61 }
62
63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
64 {
65         float i, j, k;
66         vector mi, ma, thisv, myv, ret;
67
68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
69
70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
71
72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
73         {
74                 thisv = targ.origin;
75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
79                 if(i || j || k)
80                 {
81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
84                 }
85                 else
86                 {
87                         // first run
88                         mi = ma = thisv;
89                 }
90         }
91
92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
95         ret_z = thisv_z - myv_z;
96         return ret;
97 }
98
99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
100 {
101         vector hitplot;
102         vector org;
103         float lag;
104
105         if(player.hitplotfh >= 0)
106         {
107                 lag = ANTILAG_LATENCY(player);
108                 if(lag < 0.001)
109                         lag = 0;
110                 if(clienttype(player) != CLIENTTYPE_REAL)
111                         lag = 0; // only antilag for clients
112
113                 org = player.origin + player.view_ofs;
114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
115                 if(trace_ent.flags & FL_CLIENT)
116                 {
117                         antilag_takeback(trace_ent, time - lag);
118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
119                         antilag_restore(trace_ent);
120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
122                 }
123         }
124 }
125
126 vector w_shotorg;
127 vector w_shotdir;
128 vector w_shotend;
129
130 // this function calculates w_shotorg and w_shotdir based on the weapon model
131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
132 // make sure you call makevectors first (FIXME?)
133 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage, float range)
134 {
135         float nudge = 1; // added to traceline target and subtracted from result
136         local float oldsolid;
137         vector vecs, dv;
138         oldsolid = ent.dphitcontentsmask;
139         if(ent.weapon == WEP_CAMPINGRIFLE)
140                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
141         else
142                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
143         if(antilag)
144                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
145                 // passing world, because we do NOT want it to touch dphitcontentsmask
146         else
147                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
148         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
149
150         vector vf, vr, vu;
151         vf = v_forward;
152         vr = v_right;
153         vu = v_up;
154         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
155         v_forward = vf;
156         v_right = vr;
157         v_up = vu;
158
159         // track max damage
160         if not(inWarmupStage) {
161                 entity w;
162                 w = get_weaponinfo(ent.weapon);
163                 if(w.spawnflags & WEP_TYPE_SPLASH) {  // splash damage
164                         ent.stats_fired[ent.weapon - 1] += maxdamage;
165                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);
166                 }
167         }
168
169         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
170
171         if(ent.weaponentity.movedir_x > 0)
172                 vecs = ent.weaponentity.movedir;
173         else
174                 vecs = '0 0 0';
175         if(debug_shotorg != '0 0 0')
176                 vecs = debug_shotorg;
177
178         dv = v_right * -vecs_y + v_up * vecs_z;
179         w_shotorg = ent.origin + ent.view_ofs + dv;
180
181         // now move the shotorg forward as much as requested if possible
182         if(antilag)
183         {
184                 if(ent.antilag_debug)
185                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
186                 else
187                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
188         }
189         else
190                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
191         w_shotorg = trace_endpos - v_forward * nudge;
192         // calculate the shotdir from the chosen shotorg
193         w_shotdir = normalize(w_shotend - w_shotorg);
194
195         if (antilag)
196         if (!ent.cvar_cl_noantilag)
197         {
198                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
199                 {
200                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
201                         if (!trace_ent.takedamage)
202                         {
203                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
204                                 if (trace_ent.takedamage && trace_ent.classname == "player")
205                                 {
206                                         entity e;
207                                         e = trace_ent;
208                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
209                                         if(trace_ent == e)
210                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
211                                 }
212                         }
213                 }
214                 else if(cvar("g_antilag") == 3) // client side hitscan
215                 {
216                         // this part MUST use prydon cursor
217                         if (ent.cursor_trace_ent)                 // client was aiming at someone
218                         if (ent.cursor_trace_ent != ent)         // just to make sure
219                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
220                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
221                         {
222                                 // verify that the shot would miss without antilag
223                                 // (avoids an issue where guns would always shoot at their origin)
224                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
225                                 if (!trace_ent.takedamage)
226                                 {
227                                         // verify that the shot would hit if altered
228                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
229                                         if (trace_ent == ent.cursor_trace_ent)
230                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
231                                         else
232                                                 print("antilag fail\n");
233                                 }
234                         }
235                 }
236         }
237
238         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
239
240         if (!g_norecoil)
241                 ent.punchangle_x = recoil * -1;
242
243         if (snd != "")
244         {
245                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
246         }
247
248         if (ent.items & IT_STRENGTH)
249         if (!g_minstagib)
250                 sound (ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
251
252         // nudge w_shotend so a trace to w_shotend hits
253         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
254 };
255
256 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, maxdamage, MAX_SHOT_DISTANCE)
257 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
258 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
259 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
260 #define W_SetupShot_Range(ent,antilag,recoil,snd,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage, range)
261
262 void LaserTarget_Think()
263 {
264         entity e;
265         vector offset;
266         float uselaser;
267         uselaser = 0;
268
269         // list of weapons that will use the laser, and the options that enable it
270         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
271                 uselaser = 1;
272         // example
273         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
274         //      uselaser = 1;
275
276
277
278         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
279         if(!uselaser)
280         {
281                 // rocket launcher isn't selected, so no laser target.
282                 if(self.lasertarget != world)
283                 {
284                         remove(self.lasertarget);
285                         self.lasertarget = world;
286                 }
287                 return;
288         }
289
290         if(!self.lasertarget)
291         {
292                 // we don't have a lasertarget entity, so spawn one
293                 //bprint("create laser target\n");
294                 e = self.lasertarget = spawn();
295                 e.owner = self.owner;                   // Its owner is my owner
296                 e.classname = "laser_target";
297                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
298                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
299                 e.scale = 1.25;                         // make it larger
300                 e.alpha = 0.25;                         // transparency
301                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
302                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
303                 // make it dynamically glow
304                 // you should avoid over-using this, as it can slow down the player's computer.
305                 e.glow_color = 251; // red color
306                 e.glow_size = 12;
307         }
308         else
309                 e = self.lasertarget;
310
311         // move the laser dot to where the player is looking
312
313         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
314         offset = '0 0 26' + v_right*3;
315         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
316         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
317         if(trace_plane_normal != '0 0 0')
318                 e.angles = vectoangles(trace_plane_normal);
319         else
320                 e.angles = vectoangles(v_forward);
321 }
322
323 float CL_Weaponentity_CustomizeEntityForClient()
324 {
325         self.viewmodelforclient = self.owner;
326         if(other.classname == "spectator")
327                 if(other.enemy == self.owner)
328                         self.viewmodelforclient = other;
329         return TRUE;
330 }
331
332 float qcweaponanimation;
333 vector weapon_offset = '0 -10 0';
334 vector weapon_adjust = '10 0 -15';
335 .vector weapon_morph0origin;
336 .vector weapon_morph0angles;
337 .float  weapon_morph0time;
338 .vector weapon_morph1origin;
339 .vector weapon_morph1angles;
340 .float  weapon_morph1time;
341 .vector weapon_morph2origin;
342 .vector weapon_morph2angles;
343 .float  weapon_morph2time;
344 .vector weapon_morph3origin;
345 .vector weapon_morph3angles;
346 .float  weapon_morph3time;
347 .vector weapon_morph4origin;
348 .vector weapon_morph4angles;
349 .float  weapon_morph4time;
350 .string weaponname;
351 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
352
353 /*
354  * supported formats:
355  *
356  * 1. simple animated model, muzzle flash handling on h_ model:
357  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
358  *      tags:
359  *        shot = muzzle end (shot origin, also used for muzzle flashes)
360  *        shell = casings ejection point (must be on the right hand side of the gun)
361  *        weapon = attachment for v_tuba.md3
362  *    v_tuba.md3 - first and third person model
363  *    g_tuba.md3 - pickup model
364  *
365  * 2. simple animated model, muzzle flash handling on v_ model:
366  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
367  *      tags:
368  *        weapon = attachment for v_tuba.md3
369  *    v_tuba.md3 - first and third person model
370  *      tags:
371  *        shot = muzzle end (shot origin, also used for muzzle flashes)
372  *        shell = casings ejection point (must be on the right hand side of the gun)
373  *    g_tuba.md3 - pickup model
374  *
375  * 3. fully animated model, muzzle flash handling on h_ model:
376  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
377  *      tags:
378  *        shot = muzzle end (shot origin, also used for muzzle flashes)
379  *        shell = casings ejection point (must be on the right hand side of the gun)
380  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
381  *    v_tuba.md3 - third person model
382  *    g_tuba.md3 - pickup model
383  *
384  * 4. fully animated model, muzzle flash handling on v_ model:
385  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
386  *      tags:
387  *        shot = muzzle end (shot origin)
388  *        shell = casings ejection point (must be on the right hand side of the gun)
389  *    v_tuba.md3 - third person model
390  *      tags:
391  *        shot = muzzle end (for muzzle flashes)
392  *    g_tuba.md3 - pickup model
393  */
394
395 // writes:
396 //   self.origin, self.angles
397 //   self.weaponentity
398 //   self.movedir, self.view_ofs
399 //   attachment stuff
400 //   anim stuff
401 // to free:
402 //   call again with ""
403 //   remove the ent
404 void CL_WeaponEntity_SetModel(string name)
405 {
406         string animfilename;
407         float animfile;
408         float v_shot_idx;
409         if (name != "")
410         {
411                 // if there is a child entity, hide it until we're sure we use it
412                 if (self.weaponentity)
413                         self.weaponentity.model = "";
414                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
415                 v_shot_idx = gettagindex(self, "shot"); // used later
416                 if(!v_shot_idx)
417                         v_shot_idx = gettagindex(self, "tag_shot");
418
419                 if(qcweaponanimation)
420                 {
421                         self.angles = '0 0 0';
422                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
423                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
424                         self.movedir_x += 32;
425                         self.spawnorigin = self.movedir;
426                         // oldorigin - not calculated here
427                 }
428                 else
429                 {
430                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
431                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
432                         animfile = fopen(animfilename, FILE_READ);
433                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
434                         self.anim_fire1  = '0 1 0.01';
435                         self.anim_fire2  = '1 1 0.01';
436                         self.anim_idle   = '2 1 0.01';
437                         self.anim_reload = '3 1 0.01';
438                         if (animfile >= 0)
439                         {
440                                 animparseerror = FALSE;
441                                 self.anim_fire1  = animparseline(animfile);
442                                 self.anim_fire2  = animparseline(animfile);
443                                 self.anim_idle   = animparseline(animfile);
444                                 self.anim_reload = animparseline(animfile);
445                                 fclose(animfile);
446                                 if (animparseerror)
447                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
448                         }
449
450                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
451                         // if we don't, this is a "real" animated model
452                         if(gettagindex(self, "weapon"))
453                         {
454                                 if (!self.weaponentity)
455                                         self.weaponentity = spawn();
456                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
457                                 setattachment(self.weaponentity, self, "weapon");
458                         }
459                         else if(gettagindex(self, "tag_weapon"))
460                         {
461                                 if (!self.weaponentity)
462                                         self.weaponentity = spawn();
463                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
464                                 setattachment(self.weaponentity, self, "tag_weapon");
465                         }
466                         else
467                         {
468                                 if(self.weaponentity)
469                                         remove(self.weaponentity);
470                                 self.weaponentity = world;
471                         }
472
473                         setorigin(self,'0 0 0');
474                         self.angles = '0 0 0';
475                         self.frame = 0;
476                         self.viewmodelforclient = world;
477
478                         float idx;
479
480                         if(v_shot_idx) // v_ model attached to invisible h_ model
481                         {
482                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
483                         }
484                         else
485                         {
486                                 idx = gettagindex(self, "shot");
487                                 if(!idx)
488                                         idx = gettagindex(self, "tag_shot");
489                                 if(idx)
490                                         self.movedir = gettaginfo(self, idx);
491                                 else
492                                 {
493                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
494                                         self.movedir = '0 0 0';
495                                 }
496                         }
497
498                         if(self.weaponentity) // v_ model attached to invisible h_ model
499                         {
500                                 idx = gettagindex(self.weaponentity, "shell");
501                                 if(!idx)
502                                         idx = gettagindex(self.weaponentity, "tag_shell");
503                                 if(idx)
504                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
505                         }
506                         else
507                                 idx = 0;
508                         if(!idx)
509                         {
510                                 idx = gettagindex(self, "shell");
511                                 if(!idx)
512                                         idx = gettagindex(self, "tag_shell");
513                                 if(idx)
514                                         self.spawnorigin = gettaginfo(self, idx);
515                                 else
516                                 {
517                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
518                                         self.spawnorigin = self.movedir;
519                                 }
520                         }
521
522                         if(v_shot_idx)
523                         {
524                                 self.oldorigin = '0 0 0'; // use regular attachment
525                         }
526                         else
527                         {
528                                 if(self.weaponentity)
529                                 {
530                                         idx = gettagindex(self, "weapon");
531                                         if(!idx)
532                                                 idx = gettagindex(self, "tag_weapon");
533                                 }
534                                 else
535                                 {
536                                         idx = gettagindex(self, "handle");
537                                         if(!idx)
538                                                 idx = gettagindex(self, "tag_handle");
539                                 }
540                                 if(idx)
541                                 {
542                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
543                                 }
544                                 else
545                                 {
546                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
547                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
548                                 }
549                         }
550
551                         self.viewmodelforclient = self.owner;
552                 }
553         }
554         else
555         {
556                 self.model = "";
557                 if(self.weaponentity)
558                         remove(self.weaponentity);
559                 self.weaponentity = world;
560                 self.movedir = '0 0 0';
561                 self.spawnorigin = '0 0 0';
562                 self.oldorigin = '0 0 0';
563                 self.anim_fire1  = '0 1 0.01';
564                 self.anim_fire2  = '0 1 0.01';
565                 self.anim_idle   = '0 1 0.01';
566                 self.anim_reload = '0 1 0.01';
567         }
568
569         self.view_ofs = '0 0 0';
570
571         if(self.movedir_x >= 0)
572         {
573                 vector v0;
574                 v0 = self.movedir;
575                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
576                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
577         }
578         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
579         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
580
581         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
582
583         // check if an instant weapon switch occurred
584         if (qcweaponanimation)
585         {
586                 if (self.state == WS_READY)
587                 {
588                         self.angles = '0 0 0';
589                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
590                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
591                 }
592         }
593         else
594                 setorigin(self, self.view_ofs);
595         // reset animstate now
596         self.wframe = WFRAME_IDLE;
597         self.weapon_morph0time = 0;
598         self.weapon_morph1time = 0;
599         self.weapon_morph2time = 0;
600         self.weapon_morph3time = 0;
601         self.weapon_morph4time = 0;
602         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
603 }
604
605 vector CL_Weapon_GetShotOrg(float wpn)
606 {
607         entity wi, oldself;
608         vector ret;
609         wi = get_weaponinfo(wpn);
610         oldself = self;
611         self = spawn();
612         CL_WeaponEntity_SetModel(wi.mdl);
613         ret = self.movedir;
614         CL_WeaponEntity_SetModel("");
615         remove(self);
616         self = oldself;
617         return ret;
618 }
619
620 void CL_Weaponentity_Think()
621 {
622         float tb;
623         self.nextthink = time;
624         if (intermission_running)
625                 self.frame = self.anim_idle_x;
626         if (self.owner.weaponentity != self)
627         {
628                 if (self.weaponentity)
629                         remove(self.weaponentity);
630                 remove(self);
631                 return;
632         }
633         if (self.owner.deadflag != DEAD_NO)
634         {
635                 self.model = "";
636                 if (self.weaponentity)
637                         self.weaponentity.model = "";
638                 return;
639         }
640         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
641         {
642                 self.cnt = self.owner.weapon;
643                 self.dmg = self.owner.modelindex;
644                 self.deadflag = self.owner.deadflag;
645
646                 CL_WeaponEntity_SetModel(self.owner.weaponname);
647         }
648
649         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
650         self.effects = self.owner.effects & EFMASK_CHEAP;
651         self.effects &~= EF_LOWPRECISION;
652         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
653         self.effects &~= EF_TELEPORT_BIT;
654         self.effects &~= EF_RESTARTANIM_BIT;
655         self.effects |= tb;
656
657         if(self.owner.alpha == default_player_alpha)
658                 self.alpha = default_weapon_alpha;
659         else if(self.owner.alpha != 0)
660                 self.alpha = self.owner.alpha;
661         else
662                 self.alpha = 1;
663
664         self.colormap = self.owner.colormap;
665         if (self.weaponentity)
666         {
667                 self.weaponentity.effects = self.effects;
668                 self.weaponentity.alpha = self.alpha;
669                 self.weaponentity.colormap = self.colormap;
670         }
671
672         self.angles = '0 0 0';
673         local float f;
674         f = 0;
675         if (self.state == WS_RAISE && !intermission_running)
676         {
677                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
678                 self.angles_x = -90 * f * f;
679                 if (qcweaponanimation)
680                 {
681                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
682                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
683                 }
684         }
685         else if (self.state == WS_DROP && !intermission_running)
686         {
687                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
688                 self.angles_x = -90 * f * f;
689                 if (qcweaponanimation)
690                 {
691                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
692                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
693                 }
694         }
695         else if (self.state == WS_CLEAR)
696         {
697                 f = 1;
698                 self.angles_x = -90 * f * f;
699                 if (qcweaponanimation)
700                 {
701                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
702                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
703                 }
704         }
705         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
706         {
707                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
708                 f = 1 - pow(1 - f, 3);
709                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
710                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
711         }
712         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
713         {
714                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
715                 f = 1 - pow(1 - f, 3);
716                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
717                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
718         }
719         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
720         {
721                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
722                 f = 1 - pow(1 - f, 3);
723                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
724                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
725         }
726         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
727         {
728                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
729                 f = 1 - pow(1 - f, 3);
730                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
731                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
732         }
733         else if (qcweaponanimation)
734         {
735                 // begin a new idle morph
736                 self.owner.weapon_morph0time   = time;
737                 self.owner.weapon_morph0angles = self.angles;
738                 self.owner.weapon_morph0origin = self.origin;
739
740                 float r;
741                 float t;
742
743                 r = random();
744                 if (r < 0.1)
745                 {
746                         // turn gun to the left to look at it
747                         t = 2;
748                         self.owner.weapon_morph1time   = time + t * 0.2;
749                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
750                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
751                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
752
753                         self.owner.weapon_morph2time   = time + t * 0.6;
754                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
755                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
756                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
757
758                         self.owner.weapon_morph3time   = time + t;
759                         self.owner.weapon_morph3angles = '0 0 0';
760                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
761                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
762                 }
763                 else if (r < 0.2)
764                 {
765                         // raise the gun a bit
766                         t = 2;
767                         self.owner.weapon_morph1time   = time + t * 0.2;
768                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
769                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
770                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
771
772                         self.owner.weapon_morph2time   = time + t * 0.5;
773                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
774                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
775                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
776
777                         self.owner.weapon_morph3time   = time + t;
778                         self.owner.weapon_morph3angles = '0 0 0';
779                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
780                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
781                 }
782                 else if (r < 0.3)
783                 {
784                         // tweak it a bit
785                         t = 5;
786                         self.owner.weapon_morph1time   = time + t * 0.3;
787                         self.owner.weapon_morph1angles = randomvec() * 6;
788                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
789                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
790
791                         self.owner.weapon_morph2time   = time + t * 0.7;
792                         self.owner.weapon_morph2angles = randomvec() * 6;
793                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
794                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
795
796                         self.owner.weapon_morph3time   = time + t;
797                         self.owner.weapon_morph3angles = '0 0 0';
798                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
799                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
800                 }
801                 else
802                 {
803                         // hold it mostly steady
804                         t = random() * 6 + 4;
805                         self.owner.weapon_morph1time   = time + t * 0.2;
806                         self.owner.weapon_morph1angles = randomvec() * 1;
807                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
808                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
809
810                         self.owner.weapon_morph2time   = time + t * 0.5;
811                         self.owner.weapon_morph2angles = randomvec() * 1;
812                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
813                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
814
815                         self.owner.weapon_morph3time   = time + t * 0.7;
816                         self.owner.weapon_morph3angles = randomvec() * 1;
817                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
818                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
819                 }
820
821                 self.owner.weapon_morph4time   = time + t;
822                 self.owner.weapon_morph4angles = '0 0 0';
823                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
824                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
825
826         }
827
828         // create or update the lasertarget entity
829         LaserTarget_Think();
830 };
831
832 void CL_ExteriorWeaponentity_Think()
833 {
834         float tag_found;
835         vector ang;
836         self.nextthink = time;
837         if (self.owner.exteriorweaponentity != self)
838         {
839                 remove(self);
840                 return;
841         }
842         if (self.owner.deadflag != DEAD_NO)
843         {
844                 self.model = "";
845                 return;
846         }
847         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
848         {
849                 self.cnt = self.owner.weapon;
850                 self.dmg = self.owner.modelindex;
851                 self.deadflag = self.owner.deadflag;
852                 if (self.owner.weaponname != "")
853                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
854                 else
855                         self.model = "";
856
857                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
858                 {
859                         self.tag_index = tag_found;
860                         self.tag_entity = self.owner;
861                 }
862                 else
863                         setattachment(self, self.owner, "bip01 r hand");
864
865                 // if that didn't find a tag, hide the exterior weapon model
866                 if (!self.tag_index)
867                         self.model = "";
868         }
869         self.effects = self.owner.effects;
870         if(sv_pitch_min == sv_pitch_max)
871                 self.effects |= EF_LOWPRECISION;
872         else
873                 self.effects &~= EF_LOWPRECISION;
874         self.effects = self.effects & EFMASK_CHEAP; // eat performance
875         if(self.owner.alpha == default_player_alpha)
876                 self.alpha = default_weapon_alpha;
877         else if(self.owner.alpha != 0)
878                 self.alpha = self.owner.alpha;
879         else
880                 self.alpha = 1;
881
882         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
883         ang_y = 0;
884         ang_z = 0;
885
886         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
887         {
888                 ang_y = self.owner.v_angle_y;
889                 makevectors(ang);
890                 var vector v = v_forward;
891                 var float t = self.tag_entity.frame1time;
892                 var float f = self.tag_entity.frame;
893                 self.tag_entity.frame1time = time;
894                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
895                 gettaginfo(self.tag_entity, self.tag_index);
896                 self.tag_entity.frame1time = t;
897                 self.tag_entity.frame = f;
898                 // untransform v according to this coordinate space
899                 vector w;
900                 w_x = v_forward * v;
901                 w_y = -v_right * v;
902                 w_z = v_up * v;
903                 self.angles = vectoangles(w);
904         }
905         else
906         {
907                 ang_x = -/* don't ask */ang_x;
908                 self.angles = ang;
909         }
910
911         self.colormap = self.owner.colormap;
912 };
913
914 // spawning weaponentity for client
915 void CL_SpawnWeaponentity()
916 {
917         self.weaponentity = spawn();
918         self.weaponentity.classname = "weaponentity";
919         self.weaponentity.solid = SOLID_NOT;
920         self.weaponentity.owner = self;
921         setmodel(self.weaponentity, ""); // precision set when changed
922         setorigin(self.weaponentity, '0 0 0');
923         self.weaponentity.angles = '0 0 0';
924         self.weaponentity.viewmodelforclient = self;
925         self.weaponentity.flags = 0;
926         self.weaponentity.think = CL_Weaponentity_Think;
927         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
928         self.weaponentity.nextthink = time;
929
930         self.exteriorweaponentity = spawn();
931         self.exteriorweaponentity.classname = "exteriorweaponentity";
932         self.exteriorweaponentity.solid = SOLID_NOT;
933         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
934         self.exteriorweaponentity.owner = self;
935         setorigin(self.exteriorweaponentity, '0 0 0');
936         self.exteriorweaponentity.angles = '0 0 0';
937         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
938         self.exteriorweaponentity.nextthink = time;
939 };
940
941 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
942 {
943         msg_entity = e;
944         WriteByte(MSG_ONE, SVC_TEMPENTITY);
945         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
946         WriteByte(MSG_ONE, wpn);
947         WriteString(MSG_ONE, wpnname);
948         WriteByte(MSG_ONE, type);
949 }
950
951 .float hasweapon_complain_spam;
952
953 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
954 {
955         local float weaponbit, f;
956         local entity oldself;
957
958         if(time < self.hasweapon_complain_spam)
959                 complain = 0;
960         if(complain)
961                 self.hasweapon_complain_spam = time + 0.2;
962
963         if (wpn < WEP_FIRST || wpn > WEP_LAST)
964         {
965                 if (complain)
966                         sprint(self, "Invalid weapon\n");
967                 return FALSE;
968         }
969         weaponbit = W_WeaponBit(wpn);
970         if (cl.weapons & weaponbit)
971         {
972                 if (andammo)
973                 {
974                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
975                         {
976                                 f = 1;
977                         }
978                         else
979                         {
980                                 oldself = self;
981                                 self = cl;
982                                 f = weapon_action(wpn, WR_CHECKAMMO1);
983                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
984
985                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
986                                 local entity mine;
987                                 if(wpn == WEP_MINE_LAYER)
988                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
989                                         f = 1;
990
991                                 self = oldself;
992                         }
993                         if (!f)
994                         {
995                                 if (complain)
996                                 if(clienttype(cl) == CLIENTTYPE_REAL)
997                                 {
998                                         play2(cl, "weapons/unavailable.wav");
999                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
1000                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
1001                                 }
1002                                 return FALSE;
1003                         }
1004                 }
1005                 return TRUE;
1006         }
1007         if (complain)
1008         {
1009                 // DRESK - 3/16/07
1010                 // Report Proper Weapon Status / Modified Weapon Ownership Message
1011                 if(weaponsInMap & weaponbit)
1012                 {
1013                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
1014                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
1015
1016                         if(cvar("g_showweaponspawns"))
1017                         {
1018                                 entity e;
1019                                 string s;
1020
1021                                 e = get_weaponinfo(wpn);
1022                                 s = e.model2;
1023
1024                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
1025                                 {
1026                                         if(e.classname == "droppedweapon")
1027                                                 continue;
1028                                         if not(e.flags & FL_ITEM)
1029                                                 continue;
1030                                         WaypointSprite_Spawn(
1031                                                 s,
1032                                                 1, 0,
1033                                                 world, e.origin,
1034                                                 self, 0,
1035                                                 world, enemy,
1036                                                 0
1037                                         );
1038                                 }
1039                         }
1040                 }
1041                 else
1042                 {
1043                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
1044                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
1045                 }
1046
1047                 play2(cl, "weapons/unavailable.wav");
1048         }
1049         return FALSE;
1050 };
1051
1052 // Weapon subs
1053 void w_clear()
1054 {
1055         if (self.weapon != -1)
1056                 self.weapon = 0;
1057         if (self.weaponentity)
1058         {
1059                 self.weaponentity.state = WS_CLEAR;
1060                 self.weaponentity.effects = 0;
1061         }
1062 };
1063
1064 void w_ready()
1065 {
1066         if (self.weaponentity)
1067                 self.weaponentity.state = WS_READY;
1068         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1069 };
1070
1071 // Setup weapon for client (after this raise frame will be launched)
1072 void weapon_setup(float windex)
1073 {
1074         entity e;
1075         qcweaponanimation = cvar("sv_qcweaponanimation");
1076         e = get_weaponinfo(windex);
1077         self.items &~= IT_AMMO;
1078         self.items = self.items | e.items;
1079
1080         // the two weapon entities will notice this has changed and update their models
1081         self.weapon = windex;
1082         self.weaponname = e.mdl;
1083         self.bulletcounter = 0;
1084 };
1085
1086 // perform weapon to attack (weaponstate and attack_finished check is here)
1087 void W_SwitchToOtherWeapon(entity pl)
1088 {
1089         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1090         float w, ww;
1091         w = W_WeaponBit(pl.weapon);
1092         pl.weapons &~= w;
1093         ww = w_getbestweapon(pl);
1094         pl.weapons |= w;
1095         if(ww)
1096                 W_SwitchWeapon_Force(pl, ww);
1097 }
1098 float weapon_prepareattack_checkammo(float secondary)
1099 {
1100         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1101         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1102         {
1103                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1104                 local entity mine;
1105                 if(self.weapon == WEP_MINE_LAYER)
1106                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1107                         return FALSE;
1108
1109                 W_SwitchToOtherWeapon(self);
1110                 return FALSE;
1111         }
1112         return TRUE;
1113 }
1114 .float race_penalty;
1115 float weapon_prepareattack_check(float secondary, float attacktime)
1116 {
1117         if(!weapon_prepareattack_checkammo(secondary))
1118                 return FALSE;
1119
1120         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1121         //if all players readied up and the countdown is running
1122         if(time < game_starttime || time < self.race_penalty) {
1123                 return FALSE;
1124         }
1125
1126         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1127                 return FALSE;
1128
1129         // do not even think about shooting if switching
1130         if(self.switchweapon != self.weapon)
1131                 return FALSE;
1132
1133         if(attacktime >= 0)
1134         {
1135                 // don't fire if previous attack is not finished
1136                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1137                         return FALSE;
1138                 // don't fire while changing weapon
1139                 if (self.weaponentity.state != WS_READY)
1140                         return FALSE;
1141         }
1142
1143         return TRUE;
1144 }
1145 float weapon_prepareattack_do(float secondary, float attacktime)
1146 {
1147         self.weaponentity.state = WS_INUSE;
1148
1149         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1150
1151         // if the weapon hasn't been firing continuously, reset the timer
1152         if(attacktime >= 0)
1153         {
1154                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1155                 {
1156                         ATTACK_FINISHED(self) = time;
1157                         //dprint("resetting attack finished to ", ftos(time), "\n");
1158                 }
1159                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1160         }
1161         self.bulletcounter += 1;
1162         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1163         return TRUE;
1164 }
1165 float weapon_prepareattack(float secondary, float attacktime)
1166 {
1167         if(weapon_prepareattack_check(secondary, attacktime))
1168         {
1169                 weapon_prepareattack_do(secondary, attacktime);
1170                 return TRUE;
1171         }
1172         else
1173                 return FALSE;
1174 }
1175
1176 void weapon_thinkf(float fr, float t, void() func)
1177 {
1178         vector a;
1179         vector of, or, ou;
1180         float restartanim;
1181
1182         if(fr == WFRAME_DONTCHANGE)
1183         {
1184                 fr = self.weaponentity.wframe;
1185                 restartanim = FALSE;
1186         }
1187         else if (fr == WFRAME_IDLE)
1188                 restartanim = FALSE;
1189         else
1190                 restartanim = TRUE;
1191
1192         of = v_forward;
1193         or = v_right;
1194         ou = v_up;
1195
1196         if (self.weaponentity)
1197         {
1198                 self.weaponentity.wframe = fr;
1199                 if (qcweaponanimation)
1200                 {
1201                         if (fr != WFRAME_IDLE)
1202                         {
1203                                 self.weapon_morph0time = time;
1204                                 self.weapon_morph0angles = self.weaponentity.angles;
1205                                 self.weapon_morph0origin = self.weaponentity.origin;
1206
1207                                 self.weapon_morph1angles = '0 0 0';
1208                                 self.weapon_morph1time = time + t;
1209                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1210                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1211
1212                                 self.weapon_morph2angles = '0 0 0';
1213                                 self.weapon_morph2time = time + t;
1214                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1215                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1216
1217                                 self.weapon_morph3angles = '0 0 0';
1218                                 self.weapon_morph3time = time + t;
1219                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1220                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1221
1222                                 self.weapon_morph4angles = '0 0 0';
1223                                 self.weapon_morph4time = time + t;
1224                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1225                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1226
1227                                 if (fr == WFRAME_FIRE1)
1228                                 {
1229                                         self.weapon_morph1angles = '5 0 0';
1230                                         self.weapon_morph1time = time + t * 0.1;
1231                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1232                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1233                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1234                                 }
1235                                 else if (fr == WFRAME_FIRE2)
1236                                 {
1237                                         self.weapon_morph1angles = '10 0 0';
1238                                         self.weapon_morph1time = time + t * 0.1;
1239                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1240                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1241                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1242                                 }
1243                                 else if (fr == WFRAME_RELOAD)
1244                                 {
1245                                         self.weapon_morph1time = time + t * 0.05;
1246                                         self.weapon_morph1angles = '-10 40 0';
1247                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1248                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1249
1250                                         self.weapon_morph2time = time + t * 0.15;
1251                                         self.weapon_morph2angles = '-10 40 5';
1252                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1253                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1254
1255                                         self.weapon_morph3time = time + t * 0.25;
1256                                         self.weapon_morph3angles = '-10 40 0';
1257                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1258                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1259                                 }
1260                         }
1261                 }
1262                 else
1263                 {
1264                         if (fr == WFRAME_IDLE)
1265                                 a = self.weaponentity.anim_idle;
1266                         else if (fr == WFRAME_FIRE1)
1267                                 a = self.weaponentity.anim_fire1;
1268                         else if (fr == WFRAME_FIRE2)
1269                                 a = self.weaponentity.anim_fire2;
1270                         else if (fr == WFRAME_RELOAD)
1271                                 a = self.weaponentity.anim_reload;
1272                         a_z *= g_weaponratefactor;
1273                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1274                 }
1275         }
1276
1277         v_forward = of;
1278         v_right = or;
1279         v_up = ou;
1280
1281         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1282         {
1283                 backtrace("Tried to override initial weapon think function - should this really happen?");
1284         }
1285
1286         t *= W_WeaponRateFactor();
1287
1288         // VorteX: haste can be added here
1289         if (self.weapon_think == w_ready)
1290         {
1291                 self.weapon_nextthink = time;
1292                 //dprint("started firing at ", ftos(time), "\n");
1293         }
1294         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1295         {
1296                 self.weapon_nextthink = time;
1297                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1298         }
1299         self.weapon_nextthink = self.weapon_nextthink + t;
1300         self.weapon_think = func;
1301         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1302
1303         if (restartanim)
1304         if (t)
1305         if (!self.crouch) // shoot anim stands up, this looks bad
1306         {
1307                 local vector anim;
1308                 anim = self.anim_shoot;
1309                 anim_z = anim_y / (t + sys_frametime);
1310                 setanim(self, anim, FALSE, TRUE, TRUE);
1311         }
1312 };
1313
1314 void weapon_boblayer1(float spd, vector org)
1315 {
1316         // VorteX: haste can be added here
1317 };
1318
1319 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1320 {
1321         vector mdirection;
1322         float mspeed;
1323         float outspeed;
1324         float nstyle;
1325         vector outvelocity;
1326
1327         mvelocity = mvelocity * g_weaponspeedfactor;
1328
1329         mdirection = normalize(mvelocity);
1330         mspeed = vlen(mvelocity);
1331
1332         nstyle = cvar("g_projectiles_newton_style");
1333         if(nstyle == 0)
1334         {
1335                 // absolute velocity
1336                 outvelocity = mvelocity;
1337         }
1338         else if(nstyle == 1)
1339         {
1340                 // true Newtonian projectiles
1341                 outvelocity = pvelocity + mvelocity;
1342         }
1343         else if(nstyle == 2)
1344         {
1345                 // true Newtonian projectiles with automatic aim adjustment
1346                 //
1347                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1348                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1349                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1350                 // PLUS SIGN!
1351                 // not defined?
1352                 // then...
1353                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1354                 // velocity without mdirection component > mspeed
1355                 // fire at smallest possible mspeed that works?
1356                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1357
1358                 vector solution;
1359                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1360                 if(solution_z)
1361                         outspeed = solution_y; // the larger one
1362                 else
1363                 {
1364                         //outspeed = 0; // slowest possible shot
1365                         outspeed = solution_x; // the real part (that is, the average!)
1366                         //dprint("impossible shot, adjusting\n");
1367                 }
1368
1369                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1370                 outvelocity = mdirection * outspeed;
1371         }
1372         else if(nstyle == 3)
1373         {
1374                 // pseudo-Newtonian:
1375                 outspeed = mspeed + mdirection * pvelocity;
1376                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1377                 outvelocity = mdirection * outspeed;
1378         }
1379         else if(nstyle == 4)
1380         {
1381                 // tZorkian:
1382                 outspeed = mspeed + vlen(pvelocity);
1383                 outvelocity = mdirection * outspeed;
1384         }
1385         else
1386                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1387
1388         return outvelocity;
1389 }
1390
1391 void W_AttachToShotorg(entity flash, vector offset)
1392 {
1393         entity xflash;
1394         flash.owner = self;
1395         flash.angles_z = random() * 360;
1396         if(qcweaponanimation)
1397         {
1398                 setorigin(flash, w_shotorg + w_shotdir * 50);
1399                 flash.angles = vectoangles(w_shotdir);
1400                 flash.angles_z = random() * 360;
1401         }
1402         else
1403         {
1404                 if(gettagindex(self.weaponentity, "shot"))
1405                         setattachment(flash, self.weaponentity, "shot");
1406                 else
1407                         setattachment(flash, self.weaponentity, "tag_shot");
1408                 setorigin(flash, offset);
1409
1410                 xflash = spawn();
1411                 copyentity(flash, xflash);
1412
1413                 flash.viewmodelforclient = self;
1414
1415                 if(self.weaponentity.oldorigin_x > 0)
1416                 {
1417                         setattachment(xflash, self.exteriorweaponentity, "");
1418                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1419                 }
1420                 else
1421                 {
1422                         if(gettagindex(self.exteriorweaponentity, "shot"))
1423                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1424                         else
1425                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1426                         setorigin(xflash, offset);
1427                 }
1428         }
1429 }
1430
1431 vector cliptoplane(vector v, vector p)
1432 {
1433         return v - (v * p) * p;
1434 }
1435
1436 vector solve_cubic_pq(float p, float q)
1437 {
1438         float D, u, v, a;
1439         D = q*q/4.0 + p*p*p/27.0;
1440         if(D < 0)
1441         {
1442                 // irreducibilis
1443                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1444                 u = sqrt(-4.0/3.0 * p);
1445                 // a in range 0..pi/3
1446                 // cos(a)
1447                 // cos(a + 2pi/3)
1448                 // cos(a + 4pi/3)
1449                 return
1450                         u *
1451                         (
1452                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1453                                 +
1454                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1455                                 +
1456                                 '0 0 1' * cos(a)
1457                         );
1458         }
1459         else if(D == 0)
1460         {
1461                 // simple
1462                 if(p == 0)
1463                         return '0 0 0';
1464                 u = 3*q/p;
1465                 v = -u/2;
1466                 if(u >= v)
1467                         return '1 1 0' * v + '0 0 1' * u;
1468                 else
1469                         return '0 1 1' * v + '1 0 0' * u;
1470         }
1471         else
1472         {
1473                 // cardano
1474                 u = cbrt(-q/2.0 + sqrt(D));
1475                 v = cbrt(-q/2.0 - sqrt(D));
1476                 return '1 1 1' * (u + v);
1477         }
1478 }
1479 vector solve_cubic_abcd(float a, float b, float c, float d)
1480 {
1481         // y = 3*a*x + b
1482         // x = (y - b) / 3a
1483         float p, q;
1484         vector v;
1485         p = (9*a*c - 3*b*b);
1486         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1487         v = solve_cubic_pq(p, q);
1488         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1489         if(a < 0)
1490                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1491         return v;
1492 }
1493
1494 vector findperpendicular(vector v)
1495 {
1496         vector p;
1497         p_x = v_z;
1498         p_y = -v_x;
1499         p_z = v_y;
1500         return normalize(cliptoplane(p, v));
1501 }
1502
1503 vector W_CalculateProjectileSpread(vector forward, float spread)
1504 {
1505         float sigma;
1506         vector v1, v2;
1507         float dx, dy, r;
1508         float sstyle;
1509         spread *= g_weaponspreadfactor;
1510         if(spread <= 0)
1511                 return forward;
1512         sstyle = cvar("g_projectiles_spread_style");
1513         
1514         if(sstyle == 0)
1515         {
1516                 // this is the baseline for the spread value!
1517                 // standard deviation: sqrt(2/5)
1518                 // density function: sqrt(1-r^2)
1519                 return forward + randomvec() * spread;
1520         }
1521         else if(sstyle == 1)
1522         {
1523                 // same thing, basically
1524                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1525         }
1526         else if(sstyle == 2)
1527         {
1528                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1529                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1530                 v1 = findperpendicular(forward);
1531                 v2 = cross(forward, v1);
1532                 // random point on unit circle
1533                 dx = random() * 2 * M_PI;
1534                 dy = sin(dx);
1535                 dx = cos(dx);
1536                 // radius in our dist function
1537                 r = random();
1538                 r = sqrt(r);
1539                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1540         }
1541         else if(sstyle == 3) // gauss 3d
1542         {
1543                 sigma = spread * 0.44721359549996; // match baseline stddev
1544                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1545                 v1 = forward;
1546                 v1_x += gsl_ran_gaussian(sigma);
1547                 v1_y += gsl_ran_gaussian(sigma);
1548                 v1_z += gsl_ran_gaussian(sigma);
1549                 return v1;
1550         }
1551         else if(sstyle == 4) // gauss 2d
1552         {
1553                 sigma = spread * 0.44721359549996; // match baseline stddev
1554                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1555                 v1_x = gsl_ran_gaussian(sigma);
1556                 v1_y = gsl_ran_gaussian(sigma);
1557                 v1_z = gsl_ran_gaussian(sigma);
1558                 return normalize(forward + cliptoplane(v1, forward));
1559         }
1560         else if(sstyle == 5) // 1-r
1561         {
1562                 sigma = spread * 1.154700538379252; // match baseline stddev
1563                 v1 = findperpendicular(forward);
1564                 v2 = cross(forward, v1);
1565                 // random point on unit circle
1566                 dx = random() * 2 * M_PI;
1567                 dy = sin(dx);
1568                 dx = cos(dx);
1569                 // radius in our dist function
1570                 r = random();
1571                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1572                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1573         }
1574         else if(sstyle == 6) // 1-r^2
1575         {
1576                 sigma = spread * 1.095445115010332; // match baseline stddev
1577                 v1 = findperpendicular(forward);
1578                 v2 = cross(forward, v1);
1579                 // random point on unit circle
1580                 dx = random() * 2 * M_PI;
1581                 dy = sin(dx);
1582                 dx = cos(dx);
1583                 // radius in our dist function
1584                 r = random();
1585                 r = sqrt(1 - r);
1586                 r = sqrt(1 - r);
1587                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1588         }
1589         else if(sstyle == 7) // (1-r) (2-r)
1590         {
1591                 sigma = spread * 1.224744871391589; // match baseline stddev
1592                 v1 = findperpendicular(forward);
1593                 v2 = cross(forward, v1);
1594                 // random point on unit circle
1595                 dx = random() * 2 * M_PI;
1596                 dy = sin(dx);
1597                 dx = cos(dx);
1598                 // radius in our dist function
1599                 r = random();
1600                 r = 1 - sqrt(r);
1601                 r = 1 - sqrt(r);
1602                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1603         }
1604         else
1605                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1606         return '0 0 0';
1607         /*
1608          * how to derive falloff functions:
1609          * rho(r) := (2-r) * (1-r);
1610          * a : 0;
1611          * b : 1;
1612          * rhor(r) := r * rho(r);
1613          * cr(t) := integrate(rhor(r), r, a, t);
1614          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1615          * variance : scr(b) / cr(b);
1616          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1617          * sqrt(0.4 / variance), numer;
1618          */
1619 }
1620
1621 #if 0
1622 float mspercallsum;
1623 float mspercallsstyle;
1624 float mspercallcount;
1625 #endif
1626 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread)
1627 {
1628         if(missile.owner == world)
1629                 error("Unowned missile");
1630
1631         dir = dir + upDir * (pUpSpeed / pSpeed);
1632         dir_z += pZSpeed / pSpeed;
1633         pSpeed *= vlen(dir);
1634         dir = normalize(dir);
1635
1636 #if 0
1637         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1638         {
1639                 mspercallsum = mspercallcount = 0;
1640                 mspercallsstyle = cvar("g_projectiles_spread_style");
1641         }
1642         mspercallsum -= gettime(GETTIME_HIRES);
1643 #endif
1644         dir = W_CalculateProjectileSpread(dir, spread);
1645 #if 0
1646         mspercallsum += gettime(GETTIME_HIRES);
1647         mspercallcount += 1;
1648         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1649 #endif
1650
1651         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1652 }
1653
1654 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1655 {
1656         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread);
1657 }
1658
1659 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"))
1660 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"))