qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * cvar("g_balance_rune_speed_combo_atkrate");
  23                         else
  24                                 t = t * cvar("g_balance_rune_speed_atkrate");
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * cvar("g_balance_curse_slow_atkrate");
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128
 129 // this function calculates w_shotorg and w_shotdir based on the weapon model
 130 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 131 // make sure you call makevectors first (FIXME?)
 132 void W_SetupShot_Dir_ProjectileSize(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float maxdamage)
 133 {
 134         float nudge = 1; // added to traceline target and subtracted from result
 135         local vector trueaimpoint;
 136         local float oldsolid;
 137         vector vecs, dv;
 138         oldsolid = ent.dphitcontentsmask;
 139         if(ent.weapon == WEP_CAMPINGRIFLE)
 140                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 141         else
 142                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         if(antilag)
 144                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 145                 // passing world, because we do NOT want it to touch dphitcontentsmask
 146         else
 147                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * MAX_SHOT_DISTANCE, MOVE_NOMONSTERS, ent);
 148         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 149
 150         vector vf, vr, vu;
 151         vf = v_forward;
 152         vr = v_right;
 153         vu = v_up;
 154         trueaimpoint = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 155         v_forward = vf;
 156         v_right = vr;
 157         v_up = vu;
 158
 159         // track max damage
 160         if not(inWarmupStage) {
 161                 entity w;
 162                 w = get_weaponinfo(ent.weapon);
 163                 if(w.spawnflags & WEP_TYPE_SPLASH) {  // splash damage
 164                         ent.stats_fired[ent.weapon - 1] += maxdamage;
 165                         ent.stat_fired = ent.weapon + 64 * floor(ent.stats_fired[ent.weapon - 1]);
 166                 }
 167         }
 168
 169         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 170
 171         if(ent.weaponentity.movedir_x > 0)
 172         {
 173                 vecs = ent.weaponentity.movedir;
 174                 vecs_y = -vecs_y;
 175         }
 176         else
 177                 vecs = '0 0 0';
 178
 179         if(debug_shotorg != '0 0 0')
 180                 vecs = debug_shotorg;
 181
 182         dv = v_right * vecs_y + v_up * vecs_z;
 183         w_shotorg = ent.origin + ent.view_ofs + dv;
 184
 185         // now move the shotorg forward as much as requested if possible
 186         if(antilag)
 187         {
 188                 if(ent.antilag_debug)
 189                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 190                 else
 191                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 192         }
 193         else
 194                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 195         w_shotorg = trace_endpos - v_forward * nudge;
 196         // calculate the shotdir from the chosen shotorg
 197         w_shotdir = normalize(trueaimpoint - w_shotorg);
 198
 199         if (antilag)
 200         if (!ent.cvar_cl_noantilag)
 201         {
 202                 if (cvar("g_antilag") == 1) // switch to "ghost" if not hitting original
 203                 {
 204                         traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 205                         if (!trace_ent.takedamage)
 206                         {
 207                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 208                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 209                                 {
 210                                         entity e;
 211                                         e = trace_ent;
 212                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 213                                         if(trace_ent == e)
 214                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 215                                 }
 216                         }
 217                 }
 218                 else if(cvar("g_antilag") == 3) // client side hitscan
 219                 {
 220                         // this part MUST use prydon cursor
 221                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 222                         if (ent.cursor_trace_ent != ent)         // just to make sure
 223                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 224                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 225                         {
 226                                 // verify that the shot would miss without antilag
 227                                 // (avoids an issue where guns would always shoot at their origin)
 228                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, ent);
 229                                 if (!trace_ent.takedamage)
 230                                 {
 231                                         // verify that the shot would hit if altered
 232                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 233                                         if (trace_ent == ent.cursor_trace_ent)
 234                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 235                                         else
 236                                                 print("antilag fail\n");
 237                                 }
 238                         }
 239                 }
 240         }
 241
 242         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 243
 244         if (!g_norecoil)
 245                 ent.punchangle_x = recoil * -1;
 246
 247         if (snd != "")
 248         {
 249                 sound (ent, CHAN_WEAPON, snd, VOL_BASE, ATTN_NORM);
 250         }
 251
 252         if (ent.items & IT_STRENGTH)
 253         if (!g_minstagib)
 254                 sound (ent, CHAN_AUTO, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 255 };
 256
 257 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, maxdamage)
 258 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 259 #define W_SetupShot(ent,antilag,recoil,snd,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, maxdamage)
 260
 261 void LaserTarget_Think()
 262 {
 263         entity e;
 264         vector offset;
 265         float uselaser;
 266         uselaser = 0;
 267
 268         // list of weapons that will use the laser, and the options that enable it
 269         if(self.owner.laser_on && self.owner.weapon == WEP_ROCKET_LAUNCHER && g_laserguided_missile)
 270                 uselaser = 1;
 271         // example
 272         //if(self.owner.weapon == WEP_ELECTRO && cvar("g_laserguided_electro"))
 273         //      uselaser = 1;
 274
 275
 276
 277         // if a laser-enabled weapon isn't selected, delete any existing laser and quit
 278         if(!uselaser)
 279         {
 280                 // rocket launcher isn't selected, so no laser target.
 281                 if(self.lasertarget != world)
 282                 {
 283                         remove(self.lasertarget);
 284                         self.lasertarget = world;
 285                 }
 286                 return;
 287         }
 288
 289         if(!self.lasertarget)
 290         {
 291                 // we don't have a lasertarget entity, so spawn one
 292                 //bprint("create laser target\n");
 293                 e = self.lasertarget = spawn();
 294                 e.owner = self.owner;                   // Its owner is my owner
 295                 e.classname = "laser_target";
 296                 e.movetype = MOVETYPE_NOCLIP;   // don't touch things
 297                 setmodel(e, "models/laser_dot.mdl");    // what it looks like, precision set below
 298                 e.scale = 1.25;                         // make it larger
 299                 e.alpha = 0.25;                         // transparency
 300                 e.colormod = '255 0 0' * (1/255) * 8;   // change colors
 301                 e.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
 302                 // make it dynamically glow
 303                 // you should avoid over-using this, as it can slow down the player's computer.
 304                 e.glow_color = 251; // red color
 305                 e.glow_size = 12;
 306         }
 307         else
 308                 e = self.lasertarget;
 309
 310         // move the laser dot to where the player is looking
 311
 312         makevectors(self.owner.v_angle); // set v_forward etc to the direction the player is looking
 313         offset = '0 0 26' + v_right*3;
 314         traceline(self.owner.origin + offset, self.owner.origin + offset + v_forward * MAX_SHOT_DISTANCE, FALSE, self); // trace forward until you hit something, like a player or wall
 315         setorigin(e, trace_endpos + v_forward*8); // move me to where the traceline ended
 316         if(trace_plane_normal != '0 0 0')
 317                 e.angles = vectoangles(trace_plane_normal);
 318         else
 319                 e.angles = vectoangles(v_forward);
 320 }
 321
 322 float CL_Weaponentity_CustomizeEntityForClient()
 323 {
 324         self.viewmodelforclient = self.owner;
 325         if(other.classname == "spectator")
 326                 if(other.enemy == self.owner)
 327                         self.viewmodelforclient = other;
 328         return TRUE;
 329 }
 330
 331 float qcweaponanimation;
 332 vector weapon_offset = '0 -10 0';
 333 vector weapon_adjust = '10 0 -15';
 334 .vector weapon_morph0origin;
 335 .vector weapon_morph0angles;
 336 .float  weapon_morph0time;
 337 .vector weapon_morph1origin;
 338 .vector weapon_morph1angles;
 339 .float  weapon_morph1time;
 340 .vector weapon_morph2origin;
 341 .vector weapon_morph2angles;
 342 .float  weapon_morph2time;
 343 .vector weapon_morph3origin;
 344 .vector weapon_morph3angles;
 345 .float  weapon_morph3time;
 346 .vector weapon_morph4origin;
 347 .vector weapon_morph4angles;
 348 .float  weapon_morph4time;
 349 .string weaponname;
 350 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 351
 352 /*
 353  * supported formats:
 354  *
 355  * 1. simple animated model, muzzle flash handling on h_ model:
 356  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 357  *      tags:
 358  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 359  *        shell = casings ejection point (must be on the right hand side of the gun)
 360  *        weapon = attachment for v_tuba.md3
 361  *    v_tuba.md3 - first and third person model
 362  *    g_tuba.md3 - pickup model
 363  *
 364  * 2. simple animated model, muzzle flash handling on v_ model:
 365  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 366  *      tags:
 367  *        weapon = attachment for v_tuba.md3
 368  *    v_tuba.md3 - first and third person model
 369  *      tags:
 370  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 371  *        shell = casings ejection point (must be on the right hand side of the gun)
 372  *    g_tuba.md3 - pickup model
 373  *
 374  * 3. fully animated model, muzzle flash handling on h_ model:
 375  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 376  *      tags:
 377  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 378  *        shell = casings ejection point (must be on the right hand side of the gun)
 379  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 380  *    v_tuba.md3 - third person model
 381  *    g_tuba.md3 - pickup model
 382  *
 383  * 4. fully animated model, muzzle flash handling on v_ model:
 384  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 385  *      tags:
 386  *        shot = muzzle end (shot origin)
 387  *        shell = casings ejection point (must be on the right hand side of the gun)
 388  *    v_tuba.md3 - third person model
 389  *      tags:
 390  *        shot = muzzle end (for muzzle flashes)
 391  *    g_tuba.md3 - pickup model
 392  */
 393
 394 // writes:
 395 //   self.origin, self.angles
 396 //   self.weaponentity
 397 //   self.movedir, self.view_ofs
 398 //   attachment stuff
 399 //   anim stuff
 400 // to free:
 401 //   call again with ""
 402 //   remove the ent
 403 void CL_WeaponEntity_SetModel(string name)
 404 {
 405         string animfilename;
 406         float animfile;
 407         float v_shot_idx;
 408         if (name != "")
 409         {
 410                 // if there is a child entity, hide it until we're sure we use it
 411                 if (self.weaponentity)
 412                         self.weaponentity.model = "";
 413                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 414                 v_shot_idx = gettagindex(self, "shot"); // used later
 415                 if(!v_shot_idx)
 416                         v_shot_idx = gettagindex(self, "tag_shot");
 417
 418                 if(qcweaponanimation)
 419                 {
 420                         self.angles = '0 0 0';
 421                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 422                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 423                         self.movedir_x += 32;
 424                         self.spawnorigin = self.movedir;
 425                         // oldorigin - not calculated here
 426                 }
 427                 else
 428                 {
 429                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 430                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
 431                         animfile = fopen(animfilename, FILE_READ);
 432                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 433                         self.anim_fire1  = '0 1 0.01';
 434                         self.anim_fire2  = '1 1 0.01';
 435                         self.anim_idle   = '2 1 0.01';
 436                         self.anim_reload = '3 1 0.01';
 437                         if (animfile >= 0)
 438                         {
 439                                 animparseerror = FALSE;
 440                                 self.anim_fire1  = animparseline(animfile);
 441                                 self.anim_fire2  = animparseline(animfile);
 442                                 self.anim_idle   = animparseline(animfile);
 443                                 self.anim_reload = animparseline(animfile);
 444                                 fclose(animfile);
 445                                 if (animparseerror)
 446                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 447                         }
 448
 449                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 450                         // if we don't, this is a "real" animated model
 451                         if(gettagindex(self, "weapon"))
 452                         {
 453                                 if (!self.weaponentity)
 454                                         self.weaponentity = spawn();
 455                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 456                                 setattachment(self.weaponentity, self, "weapon");
 457                         }
 458                         else if(gettagindex(self, "tag_weapon"))
 459                         {
 460                                 if (!self.weaponentity)
 461                                         self.weaponentity = spawn();
 462                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 463                                 setattachment(self.weaponentity, self, "tag_weapon");
 464                         }
 465                         else
 466                         {
 467                                 if(self.weaponentity)
 468                                         remove(self.weaponentity);
 469                                 self.weaponentity = world;
 470                         }
 471
 472                         setorigin(self,'0 0 0');
 473                         self.angles = '0 0 0';
 474                         self.frame = 0;
 475                         self.viewmodelforclient = world;
 476
 477                         float idx;
 478
 479                         if(v_shot_idx) // v_ model attached to invisible h_ model
 480                         {
 481                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 482                         }
 483                         else
 484                         {
 485                                 idx = gettagindex(self, "shot");
 486                                 if(!idx)
 487                                         idx = gettagindex(self, "tag_shot");
 488                                 if(idx)
 489                                         self.movedir = gettaginfo(self, idx);
 490                                 else
 491                                 {
 492                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 493                                         self.movedir = '0 0 0';
 494                                 }
 495                         }
 496
 497                         if(self.weaponentity) // v_ model attached to invisible h_ model
 498                         {
 499                                 idx = gettagindex(self.weaponentity, "shell");
 500                                 if(!idx)
 501                                         idx = gettagindex(self.weaponentity, "tag_shell");
 502                                 if(idx)
 503                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
 504                         }
 505                         else
 506                                 idx = 0;
 507                         if(!idx)
 508                         {
 509                                 idx = gettagindex(self, "shell");
 510                                 if(!idx)
 511                                         idx = gettagindex(self, "tag_shell");
 512                                 if(idx)
 513                                         self.spawnorigin = gettaginfo(self, idx);
 514                                 else
 515                                 {
 516                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 517                                         self.spawnorigin = self.movedir;
 518                                 }
 519                         }
 520
 521                         if(v_shot_idx)
 522                         {
 523                                 self.oldorigin = '0 0 0'; // use regular attachment
 524                         }
 525                         else
 526                         {
 527                                 if(self.weaponentity)
 528                                 {
 529                                         idx = gettagindex(self, "weapon");
 530                                         if(!idx)
 531                                                 idx = gettagindex(self, "tag_weapon");
 532                                 }
 533                                 else
 534                                 {
 535                                         idx = gettagindex(self, "handle");
 536                                         if(!idx)
 537                                                 idx = gettagindex(self, "tag_handle");
 538                                 }
 539                                 if(idx)
 540                                 {
 541                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
 542                                 }
 543                                 else
 544                                 {
 545                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 546                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
 547                                 }
 548                         }
 549
 550                         self.viewmodelforclient = self.owner;
 551                 }
 552         }
 553         else
 554         {
 555                 self.model = "";
 556                 if(self.weaponentity)
 557                         remove(self.weaponentity);
 558                 self.weaponentity = world;
 559                 self.movedir = '0 0 0';
 560                 self.spawnorigin = '0 0 0';
 561                 self.oldorigin = '0 0 0';
 562                 self.anim_fire1  = '0 1 0.01';
 563                 self.anim_fire2  = '0 1 0.01';
 564                 self.anim_idle   = '0 1 0.01';
 565                 self.anim_reload = '0 1 0.01';
 566         }
 567
 568         self.view_ofs = '0 0 0';
 569
 570         if(self.movedir_x >= 0)
 571         {
 572                 vector v0;
 573                 v0 = self.movedir;
 574                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 575                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 576         }
 577         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 578         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 579
 580         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 581
 582         // check if an instant weapon switch occurred
 583         if (qcweaponanimation)
 584         {
 585                 if (self.state == WS_READY)
 586                 {
 587                         self.angles = '0 0 0';
 588                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 589                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 590                 }
 591         }
 592         else
 593                 setorigin(self, self.view_ofs);
 594         // reset animstate now
 595         self.wframe = WFRAME_IDLE;
 596         self.weapon_morph0time = 0;
 597         self.weapon_morph1time = 0;
 598         self.weapon_morph2time = 0;
 599         self.weapon_morph3time = 0;
 600         self.weapon_morph4time = 0;
 601         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 602 }
 603
 604 vector CL_Weapon_GetShotOrg(float wpn)
 605 {
 606         entity wi, oldself;
 607         vector ret;
 608         wi = get_weaponinfo(wpn);
 609         oldself = self;
 610         self = spawn();
 611         CL_WeaponEntity_SetModel(wi.mdl);
 612         ret = self.movedir;
 613         CL_WeaponEntity_SetModel("");
 614         remove(self);
 615         self = oldself;
 616         return ret;
 617 }
 618
 619 void CL_Weaponentity_Think()
 620 {
 621         float tb;
 622         self.nextthink = time;
 623         if (intermission_running)
 624                 self.frame = self.anim_idle_x;
 625         if (self.owner.weaponentity != self)
 626         {
 627                 if (self.weaponentity)
 628                         remove(self.weaponentity);
 629                 remove(self);
 630                 return;
 631         }
 632         if (self.owner.deadflag != DEAD_NO)
 633         {
 634                 self.model = "";
 635                 if (self.weaponentity)
 636                         self.weaponentity.model = "";
 637                 return;
 638         }
 639         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 640         {
 641                 self.cnt = self.owner.weapon;
 642                 self.dmg = self.owner.modelindex;
 643                 self.deadflag = self.owner.deadflag;
 644
 645                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 646         }
 647
 648         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 649         self.effects = self.owner.effects & EFMASK_CHEAP;
 650         self.effects &~= EF_LOWPRECISION;
 651         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 652         self.effects &~= EF_TELEPORT_BIT;
 653         self.effects &~= EF_RESTARTANIM_BIT;
 654         self.effects |= tb;
 655
 656         if(self.owner.alpha == default_player_alpha)
 657                 self.alpha = default_weapon_alpha;
 658         else if(self.owner.alpha != 0)
 659                 self.alpha = self.owner.alpha;
 660         else
 661                 self.alpha = 1;
 662
 663         self.colormap = self.owner.colormap;
 664         if (self.weaponentity)
 665         {
 666                 self.weaponentity.effects = self.effects;
 667                 self.weaponentity.alpha = self.alpha;
 668                 self.weaponentity.colormap = self.colormap;
 669         }
 670
 671         self.angles = '0 0 0';
 672         local float f;
 673         f = 0;
 674         if (self.state == WS_RAISE && !intermission_running)
 675         {
 676                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 677                 self.angles_x = -90 * f * f;
 678                 if (qcweaponanimation)
 679                 {
 680                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 681                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 682                 }
 683         }
 684         else if (self.state == WS_DROP && !intermission_running)
 685         {
 686                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / cvar("g_balance_weaponswitchdelay");
 687                 self.angles_x = -90 * f * f;
 688                 if (qcweaponanimation)
 689                 {
 690                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 691                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 692                 }
 693         }
 694         else if (self.state == WS_CLEAR)
 695         {
 696                 f = 1;
 697                 self.angles_x = -90 * f * f;
 698                 if (qcweaponanimation)
 699                 {
 700                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 701                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 702                 }
 703         }
 704         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 705         {
 706                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 707                 f = 1 - pow(1 - f, 3);
 708                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 709                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 710         }
 711         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 712         {
 713                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 714                 f = 1 - pow(1 - f, 3);
 715                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 716                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 717         }
 718         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 719         {
 720                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 721                 f = 1 - pow(1 - f, 3);
 722                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 723                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 724         }
 725         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 726         {
 727                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 728                 f = 1 - pow(1 - f, 3);
 729                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 730                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 731         }
 732         else if (qcweaponanimation)
 733         {
 734                 // begin a new idle morph
 735                 self.owner.weapon_morph0time   = time;
 736                 self.owner.weapon_morph0angles = self.angles;
 737                 self.owner.weapon_morph0origin = self.origin;
 738
 739                 float r;
 740                 float t;
 741
 742                 r = random();
 743                 if (r < 0.1)
 744                 {
 745                         // turn gun to the left to look at it
 746                         t = 2;
 747                         self.owner.weapon_morph1time   = time + t * 0.2;
 748                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 749                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 750                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 751
 752                         self.owner.weapon_morph2time   = time + t * 0.6;
 753                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 754                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 755                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 756
 757                         self.owner.weapon_morph3time   = time + t;
 758                         self.owner.weapon_morph3angles = '0 0 0';
 759                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 760                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 761                 }
 762                 else if (r < 0.2)
 763                 {
 764                         // raise the gun a bit
 765                         t = 2;
 766                         self.owner.weapon_morph1time   = time + t * 0.2;
 767                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 768                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 769                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 770
 771                         self.owner.weapon_morph2time   = time + t * 0.5;
 772                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 773                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 774                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 775
 776                         self.owner.weapon_morph3time   = time + t;
 777                         self.owner.weapon_morph3angles = '0 0 0';
 778                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 779                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 780                 }
 781                 else if (r < 0.3)
 782                 {
 783                         // tweak it a bit
 784                         t = 5;
 785                         self.owner.weapon_morph1time   = time + t * 0.3;
 786                         self.owner.weapon_morph1angles = randomvec() * 6;
 787                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 788                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 789
 790                         self.owner.weapon_morph2time   = time + t * 0.7;
 791                         self.owner.weapon_morph2angles = randomvec() * 6;
 792                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 793                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 794
 795                         self.owner.weapon_morph3time   = time + t;
 796                         self.owner.weapon_morph3angles = '0 0 0';
 797                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 798                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 799                 }
 800                 else
 801                 {
 802                         // hold it mostly steady
 803                         t = random() * 6 + 4;
 804                         self.owner.weapon_morph1time   = time + t * 0.2;
 805                         self.owner.weapon_morph1angles = randomvec() * 1;
 806                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 807                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 808
 809                         self.owner.weapon_morph2time   = time + t * 0.5;
 810                         self.owner.weapon_morph2angles = randomvec() * 1;
 811                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 812                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 813
 814                         self.owner.weapon_morph3time   = time + t * 0.7;
 815                         self.owner.weapon_morph3angles = randomvec() * 1;
 816                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 817                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 818                 }
 819
 820                 self.owner.weapon_morph4time   = time + t;
 821                 self.owner.weapon_morph4angles = '0 0 0';
 822                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 823                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 824
 825         }
 826
 827         // create or update the lasertarget entity
 828         LaserTarget_Think();
 829 };
 830
 831 void CL_ExteriorWeaponentity_Think()
 832 {
 833         float tag_found;
 834         vector ang;
 835         self.nextthink = time;
 836         if (self.owner.exteriorweaponentity != self)
 837         {
 838                 remove(self);
 839                 return;
 840         }
 841         if (self.owner.deadflag != DEAD_NO)
 842         {
 843                 self.model = "";
 844                 return;
 845         }
 846         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 847         {
 848                 self.cnt = self.owner.weapon;
 849                 self.dmg = self.owner.modelindex;
 850                 self.deadflag = self.owner.deadflag;
 851                 if (self.owner.weaponname != "")
 852                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 853                 else
 854                         self.model = "";
 855
 856                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 857                 {
 858                         self.tag_index = tag_found;
 859                         self.tag_entity = self.owner;
 860                 }
 861                 else
 862                         setattachment(self, self.owner, "bip01 r hand");
 863
 864                 // if that didn't find a tag, hide the exterior weapon model
 865                 if (!self.tag_index)
 866                         self.model = "";
 867         }
 868         self.effects = self.owner.effects;
 869         if(sv_pitch_min == sv_pitch_max)
 870                 self.effects |= EF_LOWPRECISION;
 871         else
 872                 self.effects &~= EF_LOWPRECISION;
 873         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 874         if(self.owner.alpha == default_player_alpha)
 875                 self.alpha = default_weapon_alpha;
 876         else if(self.owner.alpha != 0)
 877                 self.alpha = self.owner.alpha;
 878         else
 879                 self.alpha = 1;
 880
 881         ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 882         ang_y = 0;
 883         ang_z = 0;
 884
 885         if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 886         {
 887                 ang_y = self.owner.v_angle_y;
 888                 makevectors(ang);
 889                 var vector v = v_forward;
 890                 var float t = self.tag_entity.frame1time;
 891                 var float f = self.tag_entity.frame;
 892                 self.tag_entity.frame1time = time;
 893                 self.tag_entity.frame = self.tag_entity.anim_idle_x;
 894                 gettaginfo(self.tag_entity, self.tag_index);
 895                 self.tag_entity.frame1time = t;
 896                 self.tag_entity.frame = f;
 897                 // untransform v according to this coordinate space
 898                 vector w;
 899                 w_x = v_forward * v;
 900                 w_y = -v_right * v;
 901                 w_z = v_up * v;
 902                 self.angles = vectoangles(w);
 903         }
 904         else
 905         {
 906                 ang_x = -/* don't ask */ang_x;
 907                 self.angles = ang;
 908         }
 909
 910         self.colormap = self.owner.colormap;
 911 };
 912
 913 // spawning weaponentity for client
 914 void CL_SpawnWeaponentity()
 915 {
 916         self.weaponentity = spawn();
 917         self.weaponentity.classname = "weaponentity";
 918         self.weaponentity.solid = SOLID_NOT;
 919         self.weaponentity.owner = self;
 920         setmodel(self.weaponentity, ""); // precision set when changed
 921         setorigin(self.weaponentity, '0 0 0');
 922         self.weaponentity.angles = '0 0 0';
 923         self.weaponentity.viewmodelforclient = self;
 924         self.weaponentity.flags = 0;
 925         self.weaponentity.think = CL_Weaponentity_Think;
 926         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 927         self.weaponentity.nextthink = time;
 928
 929         self.exteriorweaponentity = spawn();
 930         self.exteriorweaponentity.classname = "exteriorweaponentity";
 931         self.exteriorweaponentity.solid = SOLID_NOT;
 932         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 933         self.exteriorweaponentity.owner = self;
 934         setorigin(self.exteriorweaponentity, '0 0 0');
 935         self.exteriorweaponentity.angles = '0 0 0';
 936         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 937         self.exteriorweaponentity.nextthink = time;
 938 };
 939
 940 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 941 {
 942         msg_entity = e;
 943         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 944         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 945         WriteByte(MSG_ONE, wpn);
 946         WriteString(MSG_ONE, wpnname);
 947         WriteByte(MSG_ONE, type);
 948 }
 949
 950 .float hasweapon_complain_spam;
 951
 952 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 953 {
 954         local float weaponbit, f;
 955         local entity oldself;
 956
 957         if(time < self.hasweapon_complain_spam)
 958                 complain = 0;
 959         if(complain)
 960                 self.hasweapon_complain_spam = time + 0.2;
 961
 962         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 963         {
 964                 if (complain)
 965                         sprint(self, "Invalid weapon\n");
 966                 return FALSE;
 967         }
 968         weaponbit = W_WeaponBit(wpn);
 969         if (cl.weapons & weaponbit)
 970         {
 971                 if (andammo)
 972                 {
 973                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 974                         {
 975                                 f = 1;
 976                         }
 977                         else
 978                         {
 979                                 oldself = self;
 980                                 self = cl;
 981                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 982                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 983                                 self = oldself;
 984                         }
 985                         if (!f)
 986                         {
 987                                 if (complain)
 988                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 989                                 {
 990                                         play2(cl, "weapons/unavailable.wav");
 991                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 992                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 993                                 }
 994                                 return FALSE;
 995                         }
 996                 }
 997                 return TRUE;
 998         }
 999         if (complain)
1000         {
1001                 // DRESK - 3/16/07
1002                 // Report Proper Weapon Status / Modified Weapon Ownership Message
1003                 if(weaponsInMap & weaponbit)
1004                 {
1005                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
1006                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
1007
1008                         if(cvar("g_showweaponspawns"))
1009                         {
1010                                 entity e;
1011                                 string s;
1012
1013                                 e = get_weaponinfo(wpn);
1014                                 s = e.model2;
1015
1016                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
1017                                 {
1018                                         if(e.classname == "droppedweapon")
1019                                                 continue;
1020                                         if not(e.flags & FL_ITEM)
1021                                                 continue;
1022                                         WaypointSprite_Spawn(
1023                                                 s,
1024                                                 1, 0,
1025                                                 world, e.origin,
1026                                                 self, 0,
1027                                                 world, enemy,
1028                                                 0
1029                                         );
1030                                 }
1031                         }
1032                 }
1033                 else
1034                 {
1035                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
1036                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
1037                 }
1038
1039                 play2(cl, "weapons/unavailable.wav");
1040         }
1041         return FALSE;
1042 };
1043
1044 // Weapon subs
1045 void w_clear()
1046 {
1047         if (self.weapon != -1)
1048                 self.weapon = 0;
1049         if (self.weaponentity)
1050         {
1051                 self.weaponentity.state = WS_CLEAR;
1052                 self.weaponentity.effects = 0;
1053         }
1054 };
1055
1056 void w_ready()
1057 {
1058         if (self.weaponentity)
1059                 self.weaponentity.state = WS_READY;
1060         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1061 };
1062
1063 // Setup weapon for client (after this raise frame will be launched)
1064 void weapon_setup(float windex)
1065 {
1066         entity e;
1067         qcweaponanimation = cvar("sv_qcweaponanimation");
1068         e = get_weaponinfo(windex);
1069         self.items &~= IT_AMMO;
1070         self.items = self.items | e.items;
1071
1072         // the two weapon entities will notice this has changed and update their models
1073         self.weapon = windex;
1074         self.weaponname = e.mdl;
1075         self.bulletcounter = 0;
1076 };
1077
1078 // perform weapon to attack (weaponstate and attack_finished check is here)
1079 void W_SwitchToOtherWeapon(entity pl)
1080 {
1081         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1082         float w, ww;
1083         w = W_WeaponBit(pl.weapon);
1084         pl.weapons &~= w;
1085         ww = w_getbestweapon(pl);
1086         pl.weapons |= w;
1087         if(ww)
1088                 W_SwitchWeapon_Force(pl, ww);
1089 }
1090 float weapon_prepareattack_checkammo(float secondary)
1091 {
1092         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1093         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1094         {
1095                 W_SwitchToOtherWeapon(self);
1096                 return FALSE;
1097         }
1098         return TRUE;
1099 }
1100 .float race_penalty;
1101 float weapon_prepareattack_check(float secondary, float attacktime)
1102 {
1103         if(!weapon_prepareattack_checkammo(secondary))
1104                 return FALSE;
1105
1106         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1107         //if all players readied up and the countdown is running
1108         if(time < game_starttime || time < self.race_penalty) {
1109                 return FALSE;
1110         }
1111
1112         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1113                 return FALSE;
1114
1115         // do not even think about shooting if switching
1116         if(self.switchweapon != self.weapon)
1117                 return FALSE;
1118
1119         if(attacktime >= 0)
1120         {
1121                 // don't fire if previous attack is not finished
1122                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1123                         return FALSE;
1124                 // don't fire while changing weapon
1125                 if (self.weaponentity.state != WS_READY)
1126                         return FALSE;
1127         }
1128
1129         return TRUE;
1130 }
1131 float weapon_prepareattack_do(float secondary, float attacktime)
1132 {
1133         self.weaponentity.state = WS_INUSE;
1134
1135         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1136
1137         // if the weapon hasn't been firing continuously, reset the timer
1138         if(attacktime >= 0)
1139         {
1140                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1141                 {
1142                         ATTACK_FINISHED(self) = time;
1143                         //dprint("resetting attack finished to ", ftos(time), "\n");
1144                 }
1145                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1146         }
1147         self.bulletcounter += 1;
1148         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1149         return TRUE;
1150 }
1151 float weapon_prepareattack(float secondary, float attacktime)
1152 {
1153         if(weapon_prepareattack_check(secondary, attacktime))
1154         {
1155                 weapon_prepareattack_do(secondary, attacktime);
1156                 return TRUE;
1157         }
1158         else
1159                 return FALSE;
1160 }
1161
1162 void weapon_thinkf(float fr, float t, void() func)
1163 {
1164         vector a;
1165         vector of, or, ou;
1166         float restartanim;
1167
1168         if(fr == WFRAME_DONTCHANGE)
1169         {
1170                 fr = self.weaponentity.wframe;
1171                 restartanim = FALSE;
1172         }
1173         else if (fr == WFRAME_IDLE)
1174                 restartanim = FALSE;
1175         else
1176                 restartanim = TRUE;
1177
1178         of = v_forward;
1179         or = v_right;
1180         ou = v_up;
1181
1182         if (self.weaponentity)
1183         {
1184                 self.weaponentity.wframe = fr;
1185                 if (qcweaponanimation)
1186                 {
1187                         if (fr != WFRAME_IDLE)
1188                         {
1189                                 self.weapon_morph0time = time;
1190                                 self.weapon_morph0angles = self.weaponentity.angles;
1191                                 self.weapon_morph0origin = self.weaponentity.origin;
1192
1193                                 self.weapon_morph1angles = '0 0 0';
1194                                 self.weapon_morph1time = time + t;
1195                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1196                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1197
1198                                 self.weapon_morph2angles = '0 0 0';
1199                                 self.weapon_morph2time = time + t;
1200                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1201                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1202
1203                                 self.weapon_morph3angles = '0 0 0';
1204                                 self.weapon_morph3time = time + t;
1205                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1206                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1207
1208                                 self.weapon_morph4angles = '0 0 0';
1209                                 self.weapon_morph4time = time + t;
1210                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1211                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1212
1213                                 if (fr == WFRAME_FIRE1)
1214                                 {
1215                                         self.weapon_morph1angles = '5 0 0';
1216                                         self.weapon_morph1time = time + t * 0.1;
1217                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1218                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1219                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1220                                 }
1221                                 else if (fr == WFRAME_FIRE2)
1222                                 {
1223                                         self.weapon_morph1angles = '10 0 0';
1224                                         self.weapon_morph1time = time + t * 0.1;
1225                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1226                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1227                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1228                                 }
1229                                 else if (fr == WFRAME_RELOAD)
1230                                 {
1231                                         self.weapon_morph1time = time + t * 0.05;
1232                                         self.weapon_morph1angles = '-10 40 0';
1233                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1234                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1235
1236                                         self.weapon_morph2time = time + t * 0.15;
1237                                         self.weapon_morph2angles = '-10 40 5';
1238                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1239                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1240
1241                                         self.weapon_morph3time = time + t * 0.25;
1242                                         self.weapon_morph3angles = '-10 40 0';
1243                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1244                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1245                                 }
1246                         }
1247                 }
1248                 else
1249                 {
1250                         if (fr == WFRAME_IDLE)
1251                                 a = self.weaponentity.anim_idle;
1252                         else if (fr == WFRAME_FIRE1)
1253                                 a = self.weaponentity.anim_fire1;
1254                         else if (fr == WFRAME_FIRE2)
1255                                 a = self.weaponentity.anim_fire2;
1256                         else if (fr == WFRAME_RELOAD)
1257                                 a = self.weaponentity.anim_reload;
1258                         a_z *= g_weaponratefactor;
1259                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1260                 }
1261         }
1262
1263         v_forward = of;
1264         v_right = or;
1265         v_up = ou;
1266
1267         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1268         {
1269                 backtrace("Tried to override initial weapon think function - should this really happen?");
1270         }
1271
1272         t *= W_WeaponRateFactor();
1273
1274         // VorteX: haste can be added here
1275         if (self.weapon_think == w_ready)
1276         {
1277                 self.weapon_nextthink = time;
1278                 //dprint("started firing at ", ftos(time), "\n");
1279         }
1280         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1281         {
1282                 self.weapon_nextthink = time;
1283                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1284         }
1285         self.weapon_nextthink = self.weapon_nextthink + t;
1286         self.weapon_think = func;
1287         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1288
1289         if (restartanim)
1290         if (t)
1291         if (!self.crouch) // shoot anim stands up, this looks bad
1292         {
1293                 local vector anim;
1294                 anim = self.anim_shoot;
1295                 anim_z = anim_y / (t + sys_frametime);
1296                 setanim(self, anim, FALSE, TRUE, TRUE);
1297         }
1298 };
1299
1300 void weapon_boblayer1(float spd, vector org)
1301 {
1302         // VorteX: haste can be added here
1303 };
1304
1305 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity)
1306 {
1307         vector mdirection;
1308         float mspeed;
1309         float outspeed;
1310         float nstyle;
1311         vector outvelocity;
1312
1313         mvelocity = mvelocity * g_weaponspeedfactor;
1314
1315         mdirection = normalize(mvelocity);
1316         mspeed = vlen(mvelocity);
1317
1318         nstyle = cvar("g_projectiles_newton_style");
1319         if(nstyle == 0)
1320         {
1321                 // absolute velocity
1322                 outvelocity = mvelocity;
1323         }
1324         else if(nstyle == 1)
1325         {
1326                 // true Newtonian projectiles
1327                 outvelocity = pvelocity + mvelocity;
1328         }
1329         else if(nstyle == 2)
1330         {
1331                 // true Newtonian projectiles with automatic aim adjustment
1332                 //
1333                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1334                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1335                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1336                 // PLUS SIGN!
1337                 // not defined?
1338                 // then...
1339                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1340                 // velocity without mdirection component > mspeed
1341                 // fire at smallest possible mspeed that works?
1342                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1343
1344                 vector solution;
1345                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1346                 if(solution_z)
1347                         outspeed = solution_y; // the larger one
1348                 else
1349                 {
1350                         //outspeed = 0; // slowest possible shot
1351                         outspeed = solution_x; // the real part (that is, the average!)
1352                         //dprint("impossible shot, adjusting\n");
1353                 }
1354
1355                 outspeed = bound(mspeed * cvar("g_projectiles_newton_style_2_minfactor"), outspeed, mspeed * cvar("g_projectiles_newton_style_2_maxfactor"));
1356                 outvelocity = mdirection * outspeed;
1357         }
1358         else if(nstyle == 3)
1359         {
1360                 // pseudo-Newtonian:
1361                 outspeed = mspeed + mdirection * pvelocity;
1362                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1363                 outvelocity = mdirection * outspeed;
1364         }
1365         else if(nstyle == 4)
1366         {
1367                 // tZorkian:
1368                 outspeed = mspeed + vlen(pvelocity);
1369                 outvelocity = mdirection * outspeed;
1370         }
1371         else
1372                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1373
1374         return outvelocity;
1375 }
1376
1377 void W_AttachToShotorg(entity flash, vector offset)
1378 {
1379         entity xflash;
1380         flash.owner = self;
1381         flash.angles_z = random() * 360;
1382         if(qcweaponanimation)
1383         {
1384                 setorigin(flash, w_shotorg + w_shotdir * 50);
1385                 flash.angles = vectoangles(w_shotdir);
1386                 flash.angles_z = random() * 360;
1387         }
1388         else
1389         {
1390                 if(gettagindex(self.weaponentity, "shot"))
1391                         setattachment(flash, self.weaponentity, "shot");
1392                 else
1393                         setattachment(flash, self.weaponentity, "tag_shot");
1394                 setorigin(flash, offset);
1395
1396                 xflash = spawn();
1397                 copyentity(flash, xflash);
1398
1399                 flash.viewmodelforclient = self;
1400
1401                 if(self.weaponentity.oldorigin_x > 0)
1402                 {
1403                         setattachment(xflash, self.exteriorweaponentity, "");
1404                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1405                 }
1406                 else
1407                 {
1408                         if(gettagindex(self.exteriorweaponentity, "shot"))
1409                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1410                         else
1411                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1412                         setorigin(xflash, offset);
1413                 }
1414         }
1415 }
1416
1417 vector cliptoplane(vector v, vector p)
1418 {
1419         return v - (v * p) * p;
1420 }
1421
1422 vector solve_cubic_pq(float p, float q)
1423 {
1424         float D, u, v, a;
1425         D = q*q/4.0 + p*p*p/27.0;
1426         if(D < 0)
1427         {
1428                 // irreducibilis
1429                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1430                 u = sqrt(-4.0/3.0 * p);
1431                 // a in range 0..pi/3
1432                 // cos(a)
1433                 // cos(a + 2pi/3)
1434                 // cos(a + 4pi/3)
1435                 return
1436                         u *
1437                         (
1438                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1439                                 +
1440                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1441                                 +
1442                                 '0 0 1' * cos(a)
1443                         );
1444         }
1445         else if(D == 0)
1446         {
1447                 // simple
1448                 if(p == 0)
1449                         return '0 0 0';
1450                 u = 3*q/p;
1451                 v = -u/2;
1452                 if(u >= v)
1453                         return '1 1 0' * v + '0 0 1' * u;
1454                 else
1455                         return '0 1 1' * v + '1 0 0' * u;
1456         }
1457         else
1458         {
1459                 // cardano
1460                 u = cbrt(-q/2.0 + sqrt(D));
1461                 v = cbrt(-q/2.0 - sqrt(D));
1462                 return '1 1 1' * (u + v);
1463         }
1464 }
1465 vector solve_cubic_abcd(float a, float b, float c, float d)
1466 {
1467         // y = 3*a*x + b
1468         // x = (y - b) / 3a
1469         float p, q;
1470         vector v;
1471         p = (9*a*c - 3*b*b);
1472         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1473         v = solve_cubic_pq(p, q);
1474         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1475         if(a < 0)
1476                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1477         return v;
1478 }
1479
1480 vector findperpendicular(vector v)
1481 {
1482         vector p;
1483         p_x = v_z;
1484         p_y = -v_x;
1485         p_z = v_y;
1486         return normalize(cliptoplane(p, v));
1487 }
1488
1489 vector W_CalculateProjectileSpread(vector forward, float spread)
1490 {
1491         float sigma;
1492         vector v1, v2;
1493         float dx, dy, r;
1494         float sstyle;
1495         spread *= g_weaponspreadfactor;
1496         if(spread <= 0)
1497                 return forward;
1498         sstyle = cvar("g_projectiles_spread_style");
1499
1500         if(sstyle == 0)
1501         {
1502                 // this is the baseline for the spread value!
1503                 // standard deviation: sqrt(2/5)
1504                 // density function: sqrt(1-r^2)
1505                 return forward + randomvec() * spread;
1506         }
1507         else if(sstyle == 1)
1508         {
1509                 // same thing, basically
1510                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1511         }
1512         else if(sstyle == 2)
1513         {
1514                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1515                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1516                 v1 = findperpendicular(forward);
1517                 v2 = cross(forward, v1);
1518                 // random point on unit circle
1519                 dx = random() * 2 * M_PI;
1520                 dy = sin(dx);
1521                 dx = cos(dx);
1522                 // radius in our dist function
1523                 r = random();
1524                 r = sqrt(r);
1525                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1526         }
1527         else if(sstyle == 3) // gauss 3d
1528         {
1529                 sigma = spread * 0.44721359549996; // match baseline stddev
1530                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1531                 v1 = forward;
1532                 v1_x += gsl_ran_gaussian(sigma);
1533                 v1_y += gsl_ran_gaussian(sigma);
1534                 v1_z += gsl_ran_gaussian(sigma);
1535                 return v1;
1536         }
1537         else if(sstyle == 4) // gauss 2d
1538         {
1539                 sigma = spread * 0.44721359549996; // match baseline stddev
1540                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1541                 v1_x = gsl_ran_gaussian(sigma);
1542                 v1_y = gsl_ran_gaussian(sigma);
1543                 v1_z = gsl_ran_gaussian(sigma);
1544                 return normalize(forward + cliptoplane(v1, forward));
1545         }
1546         else if(sstyle == 5) // 1-r
1547         {
1548                 sigma = spread * 1.154700538379252; // match baseline stddev
1549                 v1 = findperpendicular(forward);
1550                 v2 = cross(forward, v1);
1551                 // random point on unit circle
1552                 dx = random() * 2 * M_PI;
1553                 dy = sin(dx);
1554                 dx = cos(dx);
1555                 // radius in our dist function
1556                 r = random();
1557                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1558                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1559         }
1560         else if(sstyle == 6) // 1-r^2
1561         {
1562                 sigma = spread * 1.095445115010332; // match baseline stddev
1563                 v1 = findperpendicular(forward);
1564                 v2 = cross(forward, v1);
1565                 // random point on unit circle
1566                 dx = random() * 2 * M_PI;
1567                 dy = sin(dx);
1568                 dx = cos(dx);
1569                 // radius in our dist function
1570                 r = random();
1571                 r = sqrt(1 - r);
1572                 r = sqrt(1 - r);
1573                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1574         }
1575         else if(sstyle == 7) // (1-r) (2-r)
1576         {
1577                 sigma = spread * 1.224744871391589; // match baseline stddev
1578                 v1 = findperpendicular(forward);
1579                 v2 = cross(forward, v1);
1580                 // random point on unit circle
1581                 dx = random() * 2 * M_PI;
1582                 dy = sin(dx);
1583                 dx = cos(dx);
1584                 // radius in our dist function
1585                 r = random();
1586                 r = 1 - sqrt(r);
1587                 r = 1 - sqrt(r);
1588                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1589         }
1590         else
1591                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1592         return '0 0 0';
1593         /*
1594          * how to derive falloff functions:
1595          * rho(r) := (2-r) * (1-r);
1596          * a : 0;
1597          * b : 1;
1598          * rhor(r) := r * rho(r);
1599          * cr(t) := integrate(rhor(r), r, a, t);
1600          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1601          * variance : scr(b) / cr(b);
1602          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1603          * sqrt(0.4 / variance), numer;
1604          */
1605 }
1606
1607 #if 0
1608 float mspercallsum;
1609 float mspercallsstyle;
1610 float mspercallcount;
1611 #endif
1612 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread)
1613 {
1614         if(missile.owner == world)
1615                 error("Unowned missile");
1616
1617         dir = dir + upDir * (pUpSpeed / pSpeed);
1618         dir_z += pZSpeed / pSpeed;
1619         pSpeed *= vlen(dir);
1620         dir = normalize(dir);
1621
1622 #if 0
1623         if(cvar("g_projectiles_spread_style") != mspercallsstyle)
1624         {
1625                 mspercallsum = mspercallcount = 0;
1626                 mspercallsstyle = cvar("g_projectiles_spread_style");
1627         }
1628         mspercallsum -= gettime(GETTIME_HIRES);
1629 #endif
1630         dir = W_CalculateProjectileSpread(dir, spread);
1631 #if 0
1632         mspercallsum += gettime(GETTIME_HIRES);
1633         mspercallcount += 1;
1634         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1635 #endif
1636
1637         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir);
1638 }
1639
1640 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1641 {
1642         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread);
1643 }
1644
1645 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"))
1646 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"))