qcsrc/server/cl_weaponsystem.qc

   1 /*
   2 ===========================================================================
   3
   4   CLIENT WEAPONSYSTEM CODE
   5   Bring back W_Weaponframe
   6
   7 ===========================================================================
   8 */
   9
  10 .float weapon_frametime;
  11
  12 float W_WeaponRateFactor()
  13 {
  14         float t;
  15         t = 1.0 / g_weaponratefactor;
  16
  17         if(g_runematch)
  18         {
  19                 if(self.runes & RUNE_SPEED)
  20                 {
  21                         if(self.runes & CURSE_SLOW)
  22                                 t = t * autocvar_g_balance_rune_speed_combo_atkrate;
  23                         else
  24                                 t = t * autocvar_g_balance_rune_speed_atkrate;
  25                 }
  26                 else if(self.runes & CURSE_SLOW)
  27                 {
  28                         t = t * autocvar_g_balance_curse_slow_atkrate;
  29                 }
  30         }
  31
  32         return t;
  33 }
  34
  35 void W_SwitchWeapon_Force(entity e, float w)
  36 {
  37         e.cnt = e.switchweapon;
  38         e.switchweapon = w;
  39         e.selectweapon = w;
  40 }
  41
  42 .float antilag_debug;
  43
  44 // VorteX: static frame globals
  45 float WFRAME_DONTCHANGE = -1;
  46 float WFRAME_FIRE1 = 0;
  47 float WFRAME_FIRE2 = 1;
  48 float WFRAME_IDLE = 2;
  49 float WFRAME_RELOAD = 3;
  50 .float wframe;
  51
  52 void(float fr, float t, void() func) weapon_thinkf;
  53
  54 vector W_HitPlotUnnormalizedUntransform(vector screenforward, vector screenright, vector screenup, vector v)
  55 {
  56         vector ret;
  57         ret_x = screenright * v;
  58         ret_y = screenup * v;
  59         ret_z = screenforward * v;
  60         return ret;
  61 }
  62
  63 vector W_HitPlotNormalizedUntransform(vector org, entity targ, vector screenforward, vector screenright, vector screenup, vector v)
  64 {
  65         float i, j, k;
  66         vector mi, ma, thisv, myv, ret;
  67
  68         myv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, org);
  69
  70         // x = 0..1 relative to hitbox; y = 0..1 relative to hitbox; z = distance
  71
  72         for(i = 0; i < 2; ++i) for(j = 0; j < 2; ++j) for(k = 0; k < 2; ++k)
  73         {
  74                 thisv = targ.origin;
  75                 if(i) thisv_x += targ.maxs_x; else thisv_x += targ.mins_x;
  76                 if(j) thisv_y += targ.maxs_y; else thisv_y += targ.mins_y;
  77                 if(k) thisv_z += targ.maxs_z; else thisv_z += targ.mins_z;
  78                 thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, thisv);
  79                 if(i || j || k)
  80                 {
  81                         if(mi_x > thisv_x) mi_x = thisv_x; if(ma_x < thisv_x) ma_x = thisv_x;
  82                         if(mi_y > thisv_y) mi_y = thisv_y; if(ma_y < thisv_y) ma_y = thisv_y;
  83                         //if(mi_z > thisv_z) mi_z = thisv_z; if(ma_z < thisv_z) ma_y = thisv_z;
  84                 }
  85                 else
  86                 {
  87                         // first run
  88                         mi = ma = thisv;
  89                 }
  90         }
  91
  92         thisv = W_HitPlotUnnormalizedUntransform(screenforward, screenright, screenup, v);
  93         ret_x = (thisv_x - mi_x) / (ma_x - mi_x);
  94         ret_y = (thisv_y - mi_y) / (ma_y - mi_y);
  95         ret_z = thisv_z - myv_z;
  96         return ret;
  97 }
  98
  99 void W_HitPlotAnalysis(entity player, vector screenforward, vector screenright, vector screenup)
 100 {
 101         vector hitplot;
 102         vector org;
 103         float lag;
 104
 105         if(player.hitplotfh >= 0)
 106         {
 107                 lag = ANTILAG_LATENCY(player);
 108                 if(lag < 0.001)
 109                         lag = 0;
 110                 if(clienttype(player) != CLIENTTYPE_REAL)
 111                         lag = 0; // only antilag for clients
 112
 113                 org = player.origin + player.view_ofs;
 114                 traceline_antilag_force(player, org, org + screenforward * MAX_SHOT_DISTANCE, MOVE_NORMAL, player, lag);
 115                 if(trace_ent.flags & FL_CLIENT)
 116                 {
 117                         antilag_takeback(trace_ent, time - lag);
 118                         hitplot = W_HitPlotNormalizedUntransform(org, trace_ent, screenforward, screenright, screenup, trace_endpos);
 119                         antilag_restore(trace_ent);
 120                         fputs(player.hitplotfh, strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), " ", ftos(player.switchweapon), "\n"));
 121                         //print(strcat(ftos(hitplot_x), " ", ftos(hitplot_y), " ", ftos(hitplot_z), "\n"));
 122                 }
 123         }
 124 }
 125
 126 vector w_shotorg;
 127 vector w_shotdir;
 128 vector w_shotend;
 129
 130 // this function calculates w_shotorg and w_shotdir based on the weapon model
 131 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
 132 // make sure you call makevectors first (FIXME?)
 133 .float prevstrengthsound;
 134 .float prevstrengthsoundattempt;
 135 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
 136 {
 137         float nudge = 1; // added to traceline target and subtracted from result
 138         local float oldsolid;
 139         vector vecs, dv;
 140         oldsolid = ent.dphitcontentsmask;
 141         if(ent.weapon == WEP_RIFLE)
 142                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 143         else
 144                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 145         if(antilag)
 146                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 147                 // passing world, because we do NOT want it to touch dphitcontentsmask
 148         else
 149                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
 150         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 151
 152         vector vf, vr, vu;
 153         vf = v_forward;
 154         vr = v_right;
 155         vu = v_up;
 156         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
 157         v_forward = vf;
 158         v_right = vr;
 159         v_up = vu;
 160
 161         // un-adjust trueaim if shotend is too close
 162         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
 163                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
 164
 165         // track max damage
 166         if(accuracy_canbegooddamage(ent))
 167                 accuracy_add(ent, ent.weapon, maxdamage, 0);
 168
 169         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
 170
 171         if(ent.weaponentity.movedir_x > 0)
 172                 vecs = ent.weaponentity.movedir;
 173         else
 174                 vecs = '0 0 0';
 175         if(debug_shotorg != '0 0 0')
 176                 vecs = debug_shotorg;
 177
 178         dv = v_right * -vecs_y + v_up * vecs_z;
 179         w_shotorg = ent.origin + ent.view_ofs + dv;
 180
 181         // now move the shotorg forward as much as requested if possible
 182         if(antilag)
 183         {
 184                 if(ent.antilag_debug)
 185                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
 186                 else
 187                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 188         }
 189         else
 190                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
 191         w_shotorg = trace_endpos - v_forward * nudge;
 192         // calculate the shotdir from the chosen shotorg
 193         w_shotdir = normalize(w_shotend - w_shotorg);
 194
 195         if (antilag)
 196         if (!ent.cvar_cl_noantilag)
 197         {
 198                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 199                 {
 200                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 201                         if (!trace_ent.takedamage)
 202                         {
 203                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 204                                 if (trace_ent.takedamage && trace_ent.classname == "player")
 205                                 {
 206                                         entity e;
 207                                         e = trace_ent;
 208                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 209                                         if(trace_ent == e)
 210                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 211                                 }
 212                         }
 213                 }
 214                 else if(autocvar_g_antilag == 3) // client side hitscan
 215                 {
 216                         // this part MUST use prydon cursor
 217                         if (ent.cursor_trace_ent)                 // client was aiming at someone
 218                         if (ent.cursor_trace_ent != ent)         // just to make sure
 219                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
 220                         if (ent.cursor_trace_ent.classname == "player") // and actually a player
 221                         {
 222                                 // verify that the shot would miss without antilag
 223                                 // (avoids an issue where guns would always shoot at their origin)
 224                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 225                                 if (!trace_ent.takedamage)
 226                                 {
 227                                         // verify that the shot would hit if altered
 228                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
 229                                         if (trace_ent == ent.cursor_trace_ent)
 230                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
 231                                         else
 232                                                 print("antilag fail\n");
 233                                 }
 234                         }
 235                 }
 236         }
 237
 238         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 239
 240         if (!g_norecoil)
 241                 ent.punchangle_x = recoil * -1;
 242
 243         if (snd != "")
 244                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 245
 246         if(ent.items & IT_STRENGTH)
 247         if(!g_minstagib)
 248         if(
 249                 (time > ent.prevstrengthsound + autocvar_sv_strengthsound_antispam_time)
 250                 ||
 251                 (time > ent.prevstrengthsoundattempt + autocvar_sv_strengthsound_antispam_refire_threshold)
 252         ) // prevent insane sound spam
 253         {
 254                 sound(ent, CH_TRIGGER, "weapons/strength_fire.wav", VOL_BASE, ATTN_NORM);
 255                 ent.prevstrengthsound = time;
 256         }
 257         ent.prevstrengthsoundattempt = time;
 258
 259         // nudge w_shotend so a trace to w_shotend hits
 260         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 261 };
 262
 263 #define W_SetupShot_Dir_ProjectileSize(ent,s_forward,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize_Range(ent, s_forward, mi, ma, antilag, recoil, snd, chan, maxdamage, MAX_SHOT_DISTANCE)
 264 #define W_SetupShot_ProjectileSize(ent,mi,ma,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, v_forward, mi, ma, antilag, recoil, snd, chan, maxdamage)
 265 #define W_SetupShot_Dir(ent,s_forward,antilag,recoil,snd,chan,maxdamage) W_SetupShot_Dir_ProjectileSize(ent, s_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 266 #define W_SetupShot(ent,antilag,recoil,snd,chan,maxdamage) W_SetupShot_ProjectileSize(ent, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage)
 267 #define W_SetupShot_Range(ent,antilag,recoil,snd,chan,maxdamage,range) W_SetupShot_Dir_ProjectileSize_Range(ent, v_forward, '0 0 0', '0 0 0', antilag, recoil, snd, chan, maxdamage, range)
 268
 269 float CL_Weaponentity_CustomizeEntityForClient()
 270 {
 271         self.viewmodelforclient = self.owner;
 272         if(other.classname == "spectator")
 273                 if(other.enemy == self.owner)
 274                         self.viewmodelforclient = other;
 275         return TRUE;
 276 }
 277
 278 float qcweaponanimation;
 279 vector weapon_offset = '0 -10 0';
 280 vector weapon_adjust = '10 0 -15';
 281 .vector weapon_morph0origin;
 282 .vector weapon_morph0angles;
 283 .float  weapon_morph0time;
 284 .vector weapon_morph1origin;
 285 .vector weapon_morph1angles;
 286 .float  weapon_morph1time;
 287 .vector weapon_morph2origin;
 288 .vector weapon_morph2angles;
 289 .float  weapon_morph2time;
 290 .vector weapon_morph3origin;
 291 .vector weapon_morph3angles;
 292 .float  weapon_morph3time;
 293 .vector weapon_morph4origin;
 294 .vector weapon_morph4angles;
 295 .float  weapon_morph4time;
 296 .string weaponname;
 297 #define QCWEAPONANIMATION_ORIGIN(e) ((weapon_offset_x + e.view_ofs_x) * v_forward - (weapon_offset_y + e.view_ofs_y) * v_right + (weapon_offset_z + e.view_ofs_z) * v_up + weapon_adjust)
 298
 299 /*
 300  * supported formats:
 301  *
 302  * 1. simple animated model, muzzle flash handling on h_ model:
 303  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 304  *      tags:
 305  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 306  *        shell = casings ejection point (must be on the right hand side of the gun)
 307  *        weapon = attachment for v_tuba.md3
 308  *    v_tuba.md3 - first and third person model
 309  *    g_tuba.md3 - pickup model
 310  *
 311  * 2. simple animated model, muzzle flash handling on v_ model:
 312  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 313  *      tags:
 314  *        weapon = attachment for v_tuba.md3
 315  *    v_tuba.md3 - first and third person model
 316  *      tags:
 317  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 318  *        shell = casings ejection point (must be on the right hand side of the gun)
 319  *    g_tuba.md3 - pickup model
 320  *
 321  * 3. fully animated model, muzzle flash handling on h_ model:
 322  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 323  *      tags:
 324  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 325  *        shell = casings ejection point (must be on the right hand side of the gun)
 326  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 327  *    v_tuba.md3 - third person model
 328  *    g_tuba.md3 - pickup model
 329  *
 330  * 4. fully animated model, muzzle flash handling on v_ model:
 331  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 332  *      tags:
 333  *        shot = muzzle end (shot origin)
 334  *        shell = casings ejection point (must be on the right hand side of the gun)
 335  *    v_tuba.md3 - third person model
 336  *      tags:
 337  *        shot = muzzle end (for muzzle flashes)
 338  *    g_tuba.md3 - pickup model
 339  */
 340
 341 // writes:
 342 //   self.origin, self.angles
 343 //   self.weaponentity
 344 //   self.movedir, self.view_ofs
 345 //   attachment stuff
 346 //   anim stuff
 347 // to free:
 348 //   call again with ""
 349 //   remove the ent
 350 void CL_WeaponEntity_SetModel(string name)
 351 {
 352         string animfilename;
 353         float animfile;
 354         float v_shot_idx;
 355         if (name != "")
 356         {
 357                 // if there is a child entity, hide it until we're sure we use it
 358                 if (self.weaponentity)
 359                         self.weaponentity.model = "";
 360                 setmodel(self, strcat("models/weapons/v_", name, ".md3")); // precision set below
 361                 v_shot_idx = gettagindex(self, "shot"); // used later
 362                 if(!v_shot_idx)
 363                         v_shot_idx = gettagindex(self, "tag_shot");
 364
 365                 if(qcweaponanimation)
 366                 {
 367                         self.angles = '0 0 0';
 368                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 369                         self.movedir = weapon_offset_x * v_forward - weapon_offset_y * v_right + weapon_offset_z * v_up + weapon_adjust;
 370                         self.movedir_x += 32;
 371                         self.spawnorigin = self.movedir;
 372                         // oldorigin - not calculated here
 373                 }
 374                 else
 375                 {
 376                         setmodel(self, strcat("models/weapons/h_", name, ".iqm")); // precision set below
 377                         animfilename = strcat("models/weapons/h_", name, ".iqm.animinfo");
 378                         animfile = fopen(animfilename, FILE_READ);
 379                         // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 380                         self.anim_fire1  = '0 1 0.01';
 381                         self.anim_fire2  = '1 1 0.01';
 382                         self.anim_idle   = '2 1 0.01';
 383                         self.anim_reload = '3 1 0.01';
 384                         if (animfile >= 0)
 385                         {
 386                                 animparseerror = FALSE;
 387                                 self.anim_fire1  = animparseline(animfile);
 388                                 self.anim_fire2  = animparseline(animfile);
 389                                 self.anim_idle   = animparseline(animfile);
 390                                 self.anim_reload = animparseline(animfile);
 391                                 fclose(animfile);
 392                                 if (animparseerror)
 393                                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 394                         }
 395
 396                         // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 397                         // if we don't, this is a "real" animated model
 398                         if(gettagindex(self, "weapon"))
 399                         {
 400                                 if (!self.weaponentity)
 401                                         self.weaponentity = spawn();
 402                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 403                                 setattachment(self.weaponentity, self, "weapon");
 404                         }
 405                         else if(gettagindex(self, "tag_weapon"))
 406                         {
 407                                 if (!self.weaponentity)
 408                                         self.weaponentity = spawn();
 409                                 setmodel(self.weaponentity, strcat("models/weapons/v_", name, ".md3")); // precision does not matter
 410                                 setattachment(self.weaponentity, self, "tag_weapon");
 411                         }
 412                         else
 413                         {
 414                                 if(self.weaponentity)
 415                                         remove(self.weaponentity);
 416                                 self.weaponentity = world;
 417                         }
 418
 419                         setorigin(self,'0 0 0');
 420                         self.angles = '0 0 0';
 421                         self.frame = 0;
 422                         self.viewmodelforclient = world;
 423
 424                         float idx;
 425
 426                         if(v_shot_idx) // v_ model attached to invisible h_ model
 427                         {
 428                                 self.movedir = gettaginfo(self.weaponentity, v_shot_idx);
 429                         }
 430                         else
 431                         {
 432                                 idx = gettagindex(self, "shot");
 433                                 if(!idx)
 434                                         idx = gettagindex(self, "tag_shot");
 435                                 if(idx)
 436                                         self.movedir = gettaginfo(self, idx);
 437                                 else
 438                                 {
 439                                         print("WARNING: weapon model ", self.model, " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 440                                         self.movedir = '0 0 0';
 441                                 }
 442                         }
 443
 444                         if(self.weaponentity) // v_ model attached to invisible h_ model
 445                         {
 446                                 idx = gettagindex(self.weaponentity, "shell");
 447                                 if(!idx)
 448                                         idx = gettagindex(self.weaponentity, "tag_shell");
 449                                 if(idx)
 450                                         self.spawnorigin = gettaginfo(self.weaponentity, idx);
 451                         }
 452                         else
 453                                 idx = 0;
 454                         if(!idx)
 455                         {
 456                                 idx = gettagindex(self, "shell");
 457                                 if(!idx)
 458                                         idx = gettagindex(self, "tag_shell");
 459                                 if(idx)
 460                                         self.spawnorigin = gettaginfo(self, idx);
 461                                 else
 462                                 {
 463                                         print("WARNING: weapon model ", self.model, " does not support the 'shell' tag, will display casings wrong\n");
 464                                         self.spawnorigin = self.movedir;
 465                                 }
 466                         }
 467
 468                         if(v_shot_idx)
 469                         {
 470                                 self.oldorigin = '0 0 0'; // use regular attachment
 471                         }
 472                         else
 473                         {
 474                                 if(self.weaponentity)
 475                                 {
 476                                         idx = gettagindex(self, "weapon");
 477                                         if(!idx)
 478                                                 idx = gettagindex(self, "tag_weapon");
 479                                 }
 480                                 else
 481                                 {
 482                                         idx = gettagindex(self, "handle");
 483                                         if(!idx)
 484                                                 idx = gettagindex(self, "tag_handle");
 485                                 }
 486                                 if(idx)
 487                                 {
 488                                         self.oldorigin = self.movedir - gettaginfo(self, idx);
 489                                 }
 490                                 else
 491                                 {
 492                                         print("WARNING: weapon model ", self.model, " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 493                                         self.oldorigin = '0 0 0'; // there is no way to recover from this
 494                                 }
 495                         }
 496
 497                         self.viewmodelforclient = self.owner;
 498                 }
 499         }
 500         else
 501         {
 502                 self.model = "";
 503                 if(self.weaponentity)
 504                         remove(self.weaponentity);
 505                 self.weaponentity = world;
 506                 self.movedir = '0 0 0';
 507                 self.spawnorigin = '0 0 0';
 508                 self.oldorigin = '0 0 0';
 509                 self.anim_fire1  = '0 1 0.01';
 510                 self.anim_fire2  = '0 1 0.01';
 511                 self.anim_idle   = '0 1 0.01';
 512                 self.anim_reload = '0 1 0.01';
 513         }
 514
 515         self.view_ofs = '0 0 0';
 516
 517         if(self.movedir_x >= 0)
 518         {
 519                 vector v0;
 520                 v0 = self.movedir;
 521                 self.movedir = shotorg_adjust(v0, FALSE, FALSE);
 522                 self.view_ofs = shotorg_adjust(v0, FALSE, TRUE) - v0;
 523         }
 524         self.owner.stat_shotorg = compressShotOrigin(self.movedir);
 525         self.movedir = decompressShotOrigin(self.owner.stat_shotorg); // make them match perfectly
 526
 527         self.spawnorigin += self.view_ofs; // offset the casings origin by the same amount
 528
 529         // check if an instant weapon switch occurred
 530         if (qcweaponanimation)
 531         {
 532                 if (self.state == WS_READY)
 533                 {
 534                         self.angles = '0 0 0';
 535                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 536                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 537                 }
 538         }
 539         else
 540                 setorigin(self, self.view_ofs);
 541         // reset animstate now
 542         self.wframe = WFRAME_IDLE;
 543         self.weapon_morph0time = 0;
 544         self.weapon_morph1time = 0;
 545         self.weapon_morph2time = 0;
 546         self.weapon_morph3time = 0;
 547         self.weapon_morph4time = 0;
 548         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 549 }
 550
 551 vector CL_Weapon_GetShotOrg(float wpn)
 552 {
 553         entity wi, oldself;
 554         vector ret;
 555         wi = get_weaponinfo(wpn);
 556         oldself = self;
 557         self = spawn();
 558         CL_WeaponEntity_SetModel(wi.mdl);
 559         ret = self.movedir;
 560         CL_WeaponEntity_SetModel("");
 561         remove(self);
 562         self = oldself;
 563         return ret;
 564 }
 565
 566 void CL_Weaponentity_Think()
 567 {
 568         float tb;
 569         self.nextthink = time;
 570         if (intermission_running)
 571                 self.frame = self.anim_idle_x;
 572         if (self.owner.weaponentity != self)
 573         {
 574                 if (self.weaponentity)
 575                         remove(self.weaponentity);
 576                 remove(self);
 577                 return;
 578         }
 579         if (self.owner.deadflag != DEAD_NO)
 580         {
 581                 self.model = "";
 582                 if (self.weaponentity)
 583                         self.weaponentity.model = "";
 584                 return;
 585         }
 586         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 587         {
 588                 self.cnt = self.owner.weapon;
 589                 self.dmg = self.owner.modelindex;
 590                 self.deadflag = self.owner.deadflag;
 591
 592                 CL_WeaponEntity_SetModel(self.owner.weaponname);
 593         }
 594
 595         tb = (self.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 596         self.effects = self.owner.effects & EFMASK_CHEAP;
 597         self.effects &~= EF_LOWPRECISION;
 598         self.effects &~= EF_FULLBRIGHT; // can mask team color, so get rid of it
 599         self.effects &~= EF_TELEPORT_BIT;
 600         self.effects &~= EF_RESTARTANIM_BIT;
 601         self.effects |= tb;
 602
 603         if(self.owner.alpha == default_player_alpha)
 604                 self.alpha = default_weapon_alpha;
 605         else if(self.owner.alpha != 0)
 606                 self.alpha = self.owner.alpha;
 607         else
 608                 self.alpha = 1;
 609
 610         self.glowmod = self.owner.weaponentity_glowmod;
 611         self.colormap = self.owner.colormap;
 612         if (self.weaponentity)
 613         {
 614                 self.weaponentity.effects = self.effects;
 615                 self.weaponentity.alpha = self.alpha;
 616                 self.weaponentity.colormap = self.colormap;
 617                 self.weaponentity.glowmod = self.glowmod;
 618         }
 619
 620         self.angles = '0 0 0';
 621         local float f;
 622         f = 0;
 623         if (self.state == WS_RAISE && !intermission_running)
 624         {
 625                 f = (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 626                 self.angles_x = -90 * f * f;
 627                 if (qcweaponanimation)
 628                 {
 629                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 630                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 631                 }
 632         }
 633         else if (self.state == WS_DROP && !intermission_running)
 634         {
 635                 f = 1 - (self.owner.weapon_nextthink - time) * g_weaponratefactor / autocvar_g_balance_weaponswitchdelay;
 636                 self.angles_x = -90 * f * f;
 637                 if (qcweaponanimation)
 638                 {
 639                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 640                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 641                 }
 642         }
 643         else if (self.state == WS_CLEAR)
 644         {
 645                 f = 1;
 646                 self.angles_x = -90 * f * f;
 647                 if (qcweaponanimation)
 648                 {
 649                         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0' + self.angles_z * '0 0 1');
 650                         setorigin(self, QCWEAPONANIMATION_ORIGIN(self));
 651                 }
 652         }
 653         else if (qcweaponanimation && time < self.owner.weapon_morph1time)
 654         {
 655                 f = (time - self.owner.weapon_morph0time) / (self.owner.weapon_morph1time - self.owner.weapon_morph0time);
 656                 f = 1 - pow(1 - f, 3);
 657                 self.angles = self.owner.weapon_morph0angles * (1 - f) + self.owner.weapon_morph1angles * f;
 658                 setorigin(self, self.owner.weapon_morph0origin * (1 - f) + self.owner.weapon_morph1origin * f);
 659         }
 660         else if (qcweaponanimation && time < self.owner.weapon_morph2time)
 661         {
 662                 f = (time - self.owner.weapon_morph1time) / (self.owner.weapon_morph2time - self.owner.weapon_morph1time);
 663                 f = 1 - pow(1 - f, 3);
 664                 self.angles = self.owner.weapon_morph1angles * (1 - f) + self.owner.weapon_morph2angles * f;
 665                 setorigin(self, self.owner.weapon_morph1origin * (1 - f) + self.owner.weapon_morph2origin * f);
 666         }
 667         else if (qcweaponanimation && time < self.owner.weapon_morph3time)
 668         {
 669                 f = (time - self.owner.weapon_morph2time) / (self.owner.weapon_morph3time - self.owner.weapon_morph2time);
 670                 f = 1 - pow(1 - f, 3);
 671                 self.angles = self.owner.weapon_morph2angles * (1 - f) + self.owner.weapon_morph3angles * f;
 672                 setorigin(self, self.owner.weapon_morph2origin * (1 - f) + self.owner.weapon_morph3origin * f);
 673         }
 674         else if (qcweaponanimation && time < self.owner.weapon_morph4time)
 675         {
 676                 f = (time - self.owner.weapon_morph3time) / (self.owner.weapon_morph4time - self.owner.weapon_morph3time);
 677                 f = 1 - pow(1 - f, 3);
 678                 self.angles = self.owner.weapon_morph3angles * (1 - f) + self.owner.weapon_morph4angles * f;
 679                 setorigin(self, self.owner.weapon_morph3origin * (1 - f) + self.owner.weapon_morph4origin * f);
 680         }
 681         else if (qcweaponanimation)
 682         {
 683                 // begin a new idle morph
 684                 self.owner.weapon_morph0time   = time;
 685                 self.owner.weapon_morph0angles = self.angles;
 686                 self.owner.weapon_morph0origin = self.origin;
 687
 688                 float r;
 689                 float t;
 690
 691                 r = random();
 692                 if (r < 0.1)
 693                 {
 694                         // turn gun to the left to look at it
 695                         t = 2;
 696                         self.owner.weapon_morph1time   = time + t * 0.2;
 697                         self.owner.weapon_morph1angles = randomvec() * 3 + '-5 30 0';
 698                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 699                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 700
 701                         self.owner.weapon_morph2time   = time + t * 0.6;
 702                         self.owner.weapon_morph2angles = randomvec() * 3 + '-5 30 0';
 703                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 704                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 705
 706                         self.owner.weapon_morph3time   = time + t;
 707                         self.owner.weapon_morph3angles = '0 0 0';
 708                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 709                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 710                 }
 711                 else if (r < 0.2)
 712                 {
 713                         // raise the gun a bit
 714                         t = 2;
 715                         self.owner.weapon_morph1time   = time + t * 0.2;
 716                         self.owner.weapon_morph1angles = randomvec() * 3 + '30 -10 0';
 717                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 718                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 719
 720                         self.owner.weapon_morph2time   = time + t * 0.5;
 721                         self.owner.weapon_morph2angles = randomvec() * 3 + '30 -10 5';
 722                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 723                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 724
 725                         self.owner.weapon_morph3time   = time + t;
 726                         self.owner.weapon_morph3angles = '0 0 0';
 727                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 728                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 729                 }
 730                 else if (r < 0.3)
 731                 {
 732                         // tweak it a bit
 733                         t = 5;
 734                         self.owner.weapon_morph1time   = time + t * 0.3;
 735                         self.owner.weapon_morph1angles = randomvec() * 6;
 736                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 737                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 738
 739                         self.owner.weapon_morph2time   = time + t * 0.7;
 740                         self.owner.weapon_morph2angles = randomvec() * 6;
 741                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 742                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 743
 744                         self.owner.weapon_morph3time   = time + t;
 745                         self.owner.weapon_morph3angles = '0 0 0';
 746                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 747                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 748                 }
 749                 else
 750                 {
 751                         // hold it mostly steady
 752                         t = random() * 6 + 4;
 753                         self.owner.weapon_morph1time   = time + t * 0.2;
 754                         self.owner.weapon_morph1angles = randomvec() * 1;
 755                         makevectors(self.owner.weapon_morph1angles_x * '-1 0 0' + self.owner.weapon_morph1angles_y * '0 1 0' + self.owner.weapon_morph1angles_z * '0 0 1');
 756                         self.owner.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self);
 757
 758                         self.owner.weapon_morph2time   = time + t * 0.5;
 759                         self.owner.weapon_morph2angles = randomvec() * 1;
 760                         makevectors(self.owner.weapon_morph2angles_x * '-1 0 0' + self.owner.weapon_morph2angles_y * '0 1 0' + self.owner.weapon_morph2angles_z * '0 0 1');
 761                         self.owner.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self);
 762
 763                         self.owner.weapon_morph3time   = time + t * 0.7;
 764                         self.owner.weapon_morph3angles = randomvec() * 1;
 765                         makevectors(self.owner.weapon_morph3angles_x * '-1 0 0' + self.owner.weapon_morph3angles_y * '0 1 0' + self.owner.weapon_morph3angles_z * '0 0 1');
 766                         self.owner.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self);
 767                 }
 768
 769                 self.owner.weapon_morph4time   = time + t;
 770                 self.owner.weapon_morph4angles = '0 0 0';
 771                 makevectors(self.owner.weapon_morph4angles_x * '-1 0 0' + self.owner.weapon_morph4angles_y * '0 1 0' + self.owner.weapon_morph4angles_z * '0 0 1');
 772                 self.owner.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self);
 773
 774         }
 775 };
 776
 777 void CL_ExteriorWeaponentity_Think()
 778 {
 779         float tag_found;
 780         vector ang;
 781         self.nextthink = time;
 782         if (self.owner.exteriorweaponentity != self)
 783         {
 784                 remove(self);
 785                 return;
 786         }
 787         if (self.owner.deadflag != DEAD_NO)
 788         {
 789                 self.model = "";
 790                 return;
 791         }
 792         if (self.cnt != self.owner.weapon || self.dmg != self.owner.modelindex || self.deadflag != self.owner.deadflag)
 793         {
 794                 self.cnt = self.owner.weapon;
 795                 self.dmg = self.owner.modelindex;
 796                 self.deadflag = self.owner.deadflag;
 797                 if (self.owner.weaponname != "")
 798                         setmodel(self, strcat("models/weapons/v_", self.owner.weaponname, ".md3")); // precision set below
 799                 else
 800                         self.model = "";
 801
 802                 if((tag_found = gettagindex(self.owner, "tag_weapon")))
 803                 {
 804                         self.tag_index = tag_found;
 805                         self.tag_entity = self.owner;
 806                 }
 807                 else
 808                         setattachment(self, self.owner, "bip01 r hand");
 809
 810                 // if that didn't find a tag, hide the exterior weapon model
 811                 if (!self.tag_index)
 812                         self.model = "";
 813         }
 814         self.effects = self.owner.effects;
 815         if(sv_pitch_min == sv_pitch_max)
 816                 self.effects |= EF_LOWPRECISION;
 817         else
 818                 self.effects &~= EF_LOWPRECISION;
 819         self.effects = self.effects & EFMASK_CHEAP; // eat performance
 820         if(self.owner.alpha == default_player_alpha)
 821                 self.alpha = default_weapon_alpha;
 822         else if(self.owner.alpha != 0)
 823                 self.alpha = self.owner.alpha;
 824         else
 825                 self.alpha = 1;
 826
 827         if (!intermission_running)
 828         {
 829                 ang_x = bound(sv_pitch_min, self.owner.v_angle_x, sv_pitch_max);
 830                 ang_y = 0;
 831                 ang_z = 0;
 832
 833                 if(sv_pitch_fixyaw) // workaround for stupid player models that don't aim forward
 834                 {
 835                         ang_y = self.owner.v_angle_y;
 836                         makevectors(ang);
 837                         var vector v = v_forward;
 838                         var float t = self.tag_entity.frame1time;
 839                         var float f = self.tag_entity.frame;
 840                         self.tag_entity.frame1time = time;
 841                         self.tag_entity.frame = self.tag_entity.anim_idle_x;
 842                         gettaginfo(self.tag_entity, self.tag_index);
 843                         self.tag_entity.frame1time = t;
 844                         self.tag_entity.frame = f;
 845                         // untransform v according to this coordinate space
 846                         vector w;
 847                         w_x = v_forward * v;
 848                         w_y = -v_right * v;
 849                         w_z = v_up * v;
 850                         self.angles = vectoangles(w);
 851                 }
 852                 else
 853                 {
 854                         ang_x = -/* don't ask */ang_x;
 855                         self.angles = ang;
 856                 }
 857         }
 858
 859         self.glowmod = self.owner.weaponentity_glowmod;
 860         self.colormap = self.owner.colormap;
 861 };
 862
 863 // spawning weaponentity for client
 864 void CL_SpawnWeaponentity()
 865 {
 866         self.weaponentity = spawn();
 867         self.weaponentity.classname = "weaponentity";
 868         self.weaponentity.solid = SOLID_NOT;
 869         self.weaponentity.owner = self;
 870         setmodel(self.weaponentity, ""); // precision set when changed
 871         setorigin(self.weaponentity, '0 0 0');
 872         self.weaponentity.angles = '0 0 0';
 873         self.weaponentity.viewmodelforclient = self;
 874         self.weaponentity.flags = 0;
 875         self.weaponentity.think = CL_Weaponentity_Think;
 876         self.weaponentity.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 877         self.weaponentity.nextthink = time;
 878
 879         self.exteriorweaponentity = spawn();
 880         self.exteriorweaponentity.classname = "exteriorweaponentity";
 881         self.exteriorweaponentity.solid = SOLID_NOT;
 882         self.exteriorweaponentity.exteriorweaponentity = self.exteriorweaponentity;
 883         self.exteriorweaponentity.owner = self;
 884         setorigin(self.exteriorweaponentity, '0 0 0');
 885         self.exteriorweaponentity.angles = '0 0 0';
 886         self.exteriorweaponentity.think = CL_ExteriorWeaponentity_Think;
 887         self.exteriorweaponentity.nextthink = time;
 888 };
 889
 890 void Send_WeaponComplain (entity e, float wpn, string wpnname, float type)
 891 {
 892         msg_entity = e;
 893         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 894         WriteByte(MSG_ONE, TE_CSQC_WEAPONCOMPLAIN);
 895         WriteByte(MSG_ONE, wpn);
 896         WriteString(MSG_ONE, wpnname);
 897         WriteByte(MSG_ONE, type);
 898 }
 899
 900 .float hasweapon_complain_spam;
 901
 902 float client_hasweapon(entity cl, float wpn, float andammo, float complain)
 903 {
 904         local float weaponbit, f;
 905         local entity oldself;
 906
 907         if(time < self.hasweapon_complain_spam)
 908                 complain = 0;
 909         if(complain)
 910                 self.hasweapon_complain_spam = time + 0.2;
 911
 912         if (wpn < WEP_FIRST || wpn > WEP_LAST)
 913         {
 914                 if (complain)
 915                         sprint(self, "Invalid weapon\n");
 916                 return FALSE;
 917         }
 918         weaponbit = W_WeaponBit(wpn);
 919         if (cl.weapons & weaponbit)
 920         {
 921                 if (andammo)
 922                 {
 923                         if(cl.items & IT_UNLIMITED_WEAPON_AMMO)
 924                         {
 925                                 f = 1;
 926                         }
 927                         else
 928                         {
 929                                 oldself = self;
 930                                 self = cl;
 931                                 f = weapon_action(wpn, WR_CHECKAMMO1);
 932                                 f = f + weapon_action(wpn, WR_CHECKAMMO2);
 933
 934                                 // always allow selecting the Mine Layer if we placed mines, so that we can detonate them
 935                                 local entity mine;
 936                                 if(wpn == WEP_MINE_LAYER)
 937                                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 938                                         f = 1;
 939
 940                                 self = oldself;
 941                         }
 942                         if (!f)
 943                         {
 944                                 if (complain)
 945                                 if(clienttype(cl) == CLIENTTYPE_REAL)
 946                                 {
 947                                         play2(cl, "weapons/unavailable.wav");
 948                                         sprint(cl, strcat("You don't have any ammo for the ^2", W_Name(wpn), "\n"));
 949                                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 0);
 950                                 }
 951                                 return FALSE;
 952                         }
 953                 }
 954                 return TRUE;
 955         }
 956         if (complain)
 957         {
 958                 // DRESK - 3/16/07
 959                 // Report Proper Weapon Status / Modified Weapon Ownership Message
 960                 if(weaponsInMap & weaponbit)
 961                 {
 962                         sprint(cl, strcat("You do not have the ^2", W_Name(wpn), "\n") );
 963                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 1);
 964
 965                         if(autocvar_g_showweaponspawns)
 966                         {
 967                                 entity e;
 968                                 string s;
 969
 970                                 e = get_weaponinfo(wpn);
 971                                 s = e.model2;
 972
 973                                 for(e = world; (e = findfloat(e, weapons, weaponbit)); )
 974                                 {
 975                                         if(e.classname == "droppedweapon")
 976                                                 continue;
 977                                         if not(e.flags & FL_ITEM)
 978                                                 continue;
 979                                         WaypointSprite_Spawn(
 980                                                 s,
 981                                                 1, 0,
 982                                                 world, e.origin,
 983                                                 self, 0,
 984                                                 world, enemy,
 985                                                 0,
 986                                                 RADARICON_NONE, '0 0 0'
 987                                         );
 988                                 }
 989                         }
 990                 }
 991                 else
 992                 {
 993                         Send_WeaponComplain (cl, wpn, W_Name(wpn), 2);
 994                         sprint(cl, strcat("The ^2", W_Name(wpn), "^7 is ^1NOT AVAILABLE^7 in this map\n") );
 995                 }
 996
 997                 play2(cl, "weapons/unavailable.wav");
 998         }
 999         return FALSE;
1000 };
1001
1002 // Weapon subs
1003 void w_clear()
1004 {
1005         if (self.weapon != -1)
1006                 self.weapon = 0;
1007         if (self.weaponentity)
1008         {
1009                 self.weaponentity.state = WS_CLEAR;
1010                 self.weaponentity.effects = 0;
1011         }
1012 };
1013
1014 void w_ready()
1015 {
1016         if (self.weaponentity)
1017                 self.weaponentity.state = WS_READY;
1018         weapon_thinkf(WFRAME_IDLE, 1000000, w_ready);
1019 };
1020
1021 // Setup weapon for client (after this raise frame will be launched)
1022 void weapon_setup(float windex)
1023 {
1024         entity e;
1025         qcweaponanimation = autocvar_sv_qcweaponanimation;
1026         e = get_weaponinfo(windex);
1027         self.items &~= IT_AMMO;
1028         self.items = self.items | e.items;
1029
1030         // the two weapon entities will notice this has changed and update their models
1031         self.weapon = windex;
1032         self.weaponname = e.mdl;
1033         self.bulletcounter = 0;
1034 };
1035
1036 // perform weapon to attack (weaponstate and attack_finished check is here)
1037 void W_SwitchToOtherWeapon(entity pl)
1038 {
1039         // hack to ensure it switches to an OTHER weapon (in case the other fire mode still has ammo, we want that anyway)
1040         float w, ww;
1041         w = W_WeaponBit(pl.weapon);
1042         pl.weapons &~= w;
1043         ww = w_getbestweapon(pl);
1044         pl.weapons |= w;
1045         if(ww)
1046                 W_SwitchWeapon_Force(pl, ww);
1047 }
1048 .float prevdryfire;
1049 float weapon_prepareattack_checkammo(float secondary)
1050 {
1051         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1052         if (!weapon_action(self.weapon, WR_CHECKAMMO1 + secondary))
1053         {
1054                 // always keep the Mine Layer if we placed mines, so that we can detonate them
1055                 local entity mine;
1056                 if(self.weapon == WEP_MINE_LAYER)
1057                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
1058                         return FALSE;
1059
1060                 if(self.weapon == self.switchweapon && time - self.prevdryfire > 1) // only play once BEFORE starting to switch weapons
1061                 {
1062                         sound (self, CH_WEAPON_A, "weapons/dryfire.wav", VOL_BASE, ATTN_NORM);
1063                         self.prevdryfire = time;
1064                 }
1065
1066                 W_SwitchToOtherWeapon(self);
1067                 return FALSE;
1068         }
1069         return TRUE;
1070 }
1071 .float race_penalty;
1072 float weapon_prepareattack_check(float secondary, float attacktime)
1073 {
1074         if(!weapon_prepareattack_checkammo(secondary))
1075                 return FALSE;
1076
1077         //if sv_ready_restart_after_countdown is set, don't allow the player to shoot
1078         //if all players readied up and the countdown is running
1079         if(time < game_starttime || time < self.race_penalty) {
1080                 return FALSE;
1081         }
1082
1083         if (timeoutStatus == 2) //don't allow the player to shoot while game is paused
1084                 return FALSE;
1085
1086         // do not even think about shooting if switching
1087         if(self.switchweapon != self.weapon)
1088                 return FALSE;
1089
1090         if(attacktime >= 0)
1091         {
1092                 // don't fire if previous attack is not finished
1093                 if (ATTACK_FINISHED(self) > time + self.weapon_frametime * 0.5)
1094                         return FALSE;
1095                 // don't fire while changing weapon
1096                 if (self.weaponentity.state != WS_READY)
1097                         return FALSE;
1098         }
1099
1100         return TRUE;
1101 }
1102 float weapon_prepareattack_do(float secondary, float attacktime)
1103 {
1104         self.weaponentity.state = WS_INUSE;
1105
1106         self.spawnshieldtime = min(self.spawnshieldtime, time); // kill spawn shield when you fire
1107
1108         // if the weapon hasn't been firing continuously, reset the timer
1109         if(attacktime >= 0)
1110         {
1111                 if (ATTACK_FINISHED(self) < time - self.weapon_frametime * 1.5)
1112                 {
1113                         ATTACK_FINISHED(self) = time;
1114                         //dprint("resetting attack finished to ", ftos(time), "\n");
1115                 }
1116                 ATTACK_FINISHED(self) = ATTACK_FINISHED(self) + attacktime * W_WeaponRateFactor();
1117         }
1118         self.bulletcounter += 1;
1119         //dprint("attack finished ", ftos(ATTACK_FINISHED(self)), "\n");
1120         return TRUE;
1121 }
1122 float weapon_prepareattack(float secondary, float attacktime)
1123 {
1124         if(weapon_prepareattack_check(secondary, attacktime))
1125         {
1126                 weapon_prepareattack_do(secondary, attacktime);
1127                 return TRUE;
1128         }
1129         else
1130                 return FALSE;
1131 }
1132
1133 void weapon_thinkf(float fr, float t, void() func)
1134 {
1135         vector a;
1136         vector of, or, ou;
1137         float restartanim;
1138
1139         if(fr == WFRAME_DONTCHANGE)
1140         {
1141                 fr = self.weaponentity.wframe;
1142                 restartanim = FALSE;
1143         }
1144         else if (fr == WFRAME_IDLE)
1145                 restartanim = FALSE;
1146         else
1147                 restartanim = TRUE;
1148
1149         of = v_forward;
1150         or = v_right;
1151         ou = v_up;
1152
1153         if (self.weaponentity)
1154         {
1155                 self.weaponentity.wframe = fr;
1156                 if (qcweaponanimation)
1157                 {
1158                         if (fr != WFRAME_IDLE)
1159                         {
1160                                 self.weapon_morph0time = time;
1161                                 self.weapon_morph0angles = self.weaponentity.angles;
1162                                 self.weapon_morph0origin = self.weaponentity.origin;
1163
1164                                 self.weapon_morph1angles = '0 0 0';
1165                                 self.weapon_morph1time = time + t;
1166                                 makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1167                                 self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1168
1169                                 self.weapon_morph2angles = '0 0 0';
1170                                 self.weapon_morph2time = time + t;
1171                                 makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1172                                 self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1173
1174                                 self.weapon_morph3angles = '0 0 0';
1175                                 self.weapon_morph3time = time + t;
1176                                 makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1177                                 self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1178
1179                                 self.weapon_morph4angles = '0 0 0';
1180                                 self.weapon_morph4time = time + t;
1181                                 makevectors(self.weapon_morph4angles_x * '-1 0 0' + self.weapon_morph4angles_y * '0 1 0' + self.weapon_morph4angles_z * '0 0 1');
1182                                 self.weapon_morph4origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1183
1184                                 if (fr == WFRAME_FIRE1)
1185                                 {
1186                                         self.weapon_morph1angles = '5 0 0';
1187                                         self.weapon_morph1time = time + t * 0.1;
1188                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1189                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1190                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1191                                 }
1192                                 else if (fr == WFRAME_FIRE2)
1193                                 {
1194                                         self.weapon_morph1angles = '10 0 0';
1195                                         self.weapon_morph1time = time + t * 0.1;
1196                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1197                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1198                                         self.weapon_morph4time = time + t + 1; // delay idle effect
1199                                 }
1200                                 else if (fr == WFRAME_RELOAD)
1201                                 {
1202                                         self.weapon_morph1time = time + t * 0.05;
1203                                         self.weapon_morph1angles = '-10 40 0';
1204                                         makevectors(self.weapon_morph1angles_x * '-1 0 0' + self.weapon_morph1angles_y * '0 1 0' + self.weapon_morph1angles_z * '0 0 1');
1205                                         self.weapon_morph1origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1206
1207                                         self.weapon_morph2time = time + t * 0.15;
1208                                         self.weapon_morph2angles = '-10 40 5';
1209                                         makevectors(self.weapon_morph2angles_x * '-1 0 0' + self.weapon_morph2angles_y * '0 1 0' + self.weapon_morph2angles_z * '0 0 1');
1210                                         self.weapon_morph2origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1211
1212                                         self.weapon_morph3time = time + t * 0.25;
1213                                         self.weapon_morph3angles = '-10 40 0';
1214                                         makevectors(self.weapon_morph3angles_x * '-1 0 0' + self.weapon_morph3angles_y * '0 1 0' + self.weapon_morph3angles_z * '0 0 1');
1215                                         self.weapon_morph3origin = QCWEAPONANIMATION_ORIGIN(self.weaponentity);
1216                                 }
1217                         }
1218                 }
1219                 else
1220                 {
1221                         if (fr == WFRAME_IDLE)
1222                                 a = self.weaponentity.anim_idle;
1223                         else if (fr == WFRAME_FIRE1)
1224                                 a = self.weaponentity.anim_fire1;
1225                         else if (fr == WFRAME_FIRE2)
1226                                 a = self.weaponentity.anim_fire2;
1227                         else if (fr == WFRAME_RELOAD)
1228                                 a = self.weaponentity.anim_reload;
1229                         a_z *= g_weaponratefactor;
1230                         setanim(self.weaponentity, a, restartanim == FALSE, restartanim, restartanim);
1231                 }
1232         }
1233
1234         v_forward = of;
1235         v_right = or;
1236         v_up = ou;
1237
1238         if(self.weapon_think == w_ready && func != w_ready && self.weaponentity.state == WS_RAISE)
1239         {
1240                 backtrace("Tried to override initial weapon think function - should this really happen?");
1241         }
1242
1243         t *= W_WeaponRateFactor();
1244
1245         // VorteX: haste can be added here
1246         if (self.weapon_think == w_ready)
1247         {
1248                 self.weapon_nextthink = time;
1249                 //dprint("started firing at ", ftos(time), "\n");
1250         }
1251         if (self.weapon_nextthink < time - self.weapon_frametime * 1.5 || self.weapon_nextthink > time + self.weapon_frametime * 1.5)
1252         {
1253                 self.weapon_nextthink = time;
1254                 //dprint("reset weapon animation timer at ", ftos(time), "\n");
1255         }
1256         self.weapon_nextthink = self.weapon_nextthink + t;
1257         self.weapon_think = func;
1258         //dprint("next ", ftos(self.weapon_nextthink), "\n");
1259
1260         // The shoot animation looks TERRIBLE without animation blending! Yay for moonwalking while shooting!
1261         //anim = self.anim_shoot;
1262         if (restartanim)
1263         if (t)
1264         if (!self.crouch) // shoot anim stands up, this looks bad
1265         {
1266                 vector anim;
1267                 if(self.weapon == WEP_SHOTGUN && self.BUTTON_ATCK2)
1268                 {
1269                         anim = self.anim_melee;
1270                         anim_z = anim_y / (t + sys_frametime);
1271                         setanim(self, anim, FALSE, TRUE, TRUE);
1272                 }
1273         }
1274 };
1275
1276 void weapon_boblayer1(float spd, vector org)
1277 {
1278         // VorteX: haste can be added here
1279 };
1280
1281 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
1282 {
1283         vector mdirection;
1284         float mspeed;
1285         float outspeed;
1286         float nstyle;
1287         vector outvelocity;
1288
1289         mvelocity = mvelocity * g_weaponspeedfactor;
1290
1291         mdirection = normalize(mvelocity);
1292         mspeed = vlen(mvelocity);
1293
1294         nstyle = autocvar_g_projectiles_newton_style;
1295         if(nstyle == 0 || forceAbsolute)
1296         {
1297                 // absolute velocity
1298                 outvelocity = mvelocity;
1299         }
1300         else if(nstyle == 1)
1301         {
1302                 // true Newtonian projectiles
1303                 outvelocity = pvelocity + mvelocity;
1304         }
1305         else if(nstyle == 2)
1306         {
1307                 // true Newtonian projectiles with automatic aim adjustment
1308                 //
1309                 // solve: |outspeed * mdirection - pvelocity| = mspeed
1310                 // outspeed^2 - 2 * outspeed * (mdirection * pvelocity) + pvelocity^2 - mspeed^2 = 0
1311                 // outspeed = (mdirection * pvelocity) +- sqrt((mdirection * pvelocity)^2 - pvelocity^2 + mspeed^2)
1312                 // PLUS SIGN!
1313                 // not defined?
1314                 // then...
1315                 // pvelocity^2 - (mdirection * pvelocity)^2 > mspeed^2
1316                 // velocity without mdirection component > mspeed
1317                 // fire at smallest possible mspeed that works?
1318                 // |(mdirection * pvelocity) * pvelocity - pvelocity| = mspeed
1319
1320                 vector solution;
1321                 solution = solve_quadratic(1, -2 * (mdirection * pvelocity), pvelocity * pvelocity - mspeed * mspeed);
1322                 if(solution_z)
1323                         outspeed = solution_y; // the larger one
1324                 else
1325                 {
1326                         //outspeed = 0; // slowest possible shot
1327                         outspeed = solution_x; // the real part (that is, the average!)
1328                         //dprint("impossible shot, adjusting\n");
1329                 }
1330
1331                 outspeed = bound(mspeed * autocvar_g_projectiles_newton_style_2_minfactor, outspeed, mspeed * autocvar_g_projectiles_newton_style_2_maxfactor);
1332                 outvelocity = mdirection * outspeed;
1333         }
1334         else if(nstyle == 3)
1335         {
1336                 // pseudo-Newtonian:
1337                 outspeed = mspeed + mdirection * pvelocity;
1338                 outspeed = bound(mspeed * 0.7, outspeed, mspeed * 5.0);
1339                 outvelocity = mdirection * outspeed;
1340         }
1341         else if(nstyle == 4)
1342         {
1343                 // tZorkian:
1344                 outspeed = mspeed + vlen(pvelocity);
1345                 outvelocity = mdirection * outspeed;
1346         }
1347         else
1348                 error("g_projectiles_newton_style must be 0 (absolute), 1 (Newtonian), 2 (Newtonian + aimfix), 3 (pseudo Newtonian) or 4 (tZorkian)!");
1349
1350         return outvelocity;
1351 }
1352
1353 void W_AttachToShotorg(entity flash, vector offset)
1354 {
1355         entity xflash;
1356         flash.owner = self;
1357         flash.angles_z = random() * 360;
1358         if(qcweaponanimation)
1359         {
1360                 setorigin(flash, w_shotorg + w_shotdir * 50);
1361                 flash.angles = vectoangles(w_shotdir);
1362                 flash.angles_z = random() * 360;
1363         }
1364         else
1365         {
1366                 if(gettagindex(self.weaponentity, "shot"))
1367                         setattachment(flash, self.weaponentity, "shot");
1368                 else
1369                         setattachment(flash, self.weaponentity, "tag_shot");
1370                 setorigin(flash, offset);
1371
1372                 xflash = spawn();
1373                 copyentity(flash, xflash);
1374
1375                 flash.viewmodelforclient = self;
1376
1377                 if(self.weaponentity.oldorigin_x > 0)
1378                 {
1379                         setattachment(xflash, self.exteriorweaponentity, "");
1380                         setorigin(xflash, self.weaponentity.oldorigin + offset);
1381                 }
1382                 else
1383                 {
1384                         if(gettagindex(self.exteriorweaponentity, "shot"))
1385                                 setattachment(xflash, self.exteriorweaponentity, "shot");
1386                         else
1387                                 setattachment(xflash, self.exteriorweaponentity, "tag_shot");
1388                         setorigin(xflash, offset);
1389                 }
1390         }
1391 }
1392
1393 vector cliptoplane(vector v, vector p)
1394 {
1395         return v - (v * p) * p;
1396 }
1397
1398 vector solve_cubic_pq(float p, float q)
1399 {
1400         float D, u, v, a;
1401         D = q*q/4.0 + p*p*p/27.0;
1402         if(D < 0)
1403         {
1404                 // irreducibilis
1405                 a = 1.0/3.0 * acos(-q/2.0 * sqrt(-27.0/(p*p*p)));
1406                 u = sqrt(-4.0/3.0 * p);
1407                 // a in range 0..pi/3
1408                 // cos(a)
1409                 // cos(a + 2pi/3)
1410                 // cos(a + 4pi/3)
1411                 return
1412                         u *
1413                         (
1414                                 '1 0 0' * cos(a + 2.0/3.0*M_PI)
1415                                 +
1416                                 '0 1 0' * cos(a + 4.0/3.0*M_PI)
1417                                 +
1418                                 '0 0 1' * cos(a)
1419                         );
1420         }
1421         else if(D == 0)
1422         {
1423                 // simple
1424                 if(p == 0)
1425                         return '0 0 0';
1426                 u = 3*q/p;
1427                 v = -u/2;
1428                 if(u >= v)
1429                         return '1 1 0' * v + '0 0 1' * u;
1430                 else
1431                         return '0 1 1' * v + '1 0 0' * u;
1432         }
1433         else
1434         {
1435                 // cardano
1436                 u = cbrt(-q/2.0 + sqrt(D));
1437                 v = cbrt(-q/2.0 - sqrt(D));
1438                 return '1 1 1' * (u + v);
1439         }
1440 }
1441 vector solve_cubic_abcd(float a, float b, float c, float d)
1442 {
1443         // y = 3*a*x + b
1444         // x = (y - b) / 3a
1445         float p, q;
1446         vector v;
1447         p = (9*a*c - 3*b*b);
1448         q = (27*a*a*d - 9*a*b*c + 2*b*b*b);
1449         v = solve_cubic_pq(p, q);
1450         v = (v -  b * '1 1 1') * (1.0 / (3.0 * a));
1451         if(a < 0)
1452                 v += '1 0 -1' * (v_z - v_x); // swap x, z
1453         return v;
1454 }
1455
1456 vector findperpendicular(vector v)
1457 {
1458         vector p;
1459         p_x = v_z;
1460         p_y = -v_x;
1461         p_z = v_y;
1462         return normalize(cliptoplane(p, v));
1463 }
1464
1465 vector W_CalculateProjectileSpread(vector forward, float spread)
1466 {
1467         float sigma;
1468         vector v1, v2;
1469         float dx, dy, r;
1470         float sstyle;
1471         spread *= g_weaponspreadfactor;
1472         if(spread <= 0)
1473                 return forward;
1474         sstyle = autocvar_g_projectiles_spread_style;
1475
1476         if(sstyle == 0)
1477         {
1478                 // this is the baseline for the spread value!
1479                 // standard deviation: sqrt(2/5)
1480                 // density function: sqrt(1-r^2)
1481                 return forward + randomvec() * spread;
1482         }
1483         else if(sstyle == 1)
1484         {
1485                 // same thing, basically
1486                 return normalize(forward + cliptoplane(randomvec() * spread, forward));
1487         }
1488         else if(sstyle == 2)
1489         {
1490                 // circle spread... has at sigma=1 a standard deviation of sqrt(1/2)
1491                 sigma = spread * 0.89442719099991587855; // match baseline stddev
1492                 v1 = findperpendicular(forward);
1493                 v2 = cross(forward, v1);
1494                 // random point on unit circle
1495                 dx = random() * 2 * M_PI;
1496                 dy = sin(dx);
1497                 dx = cos(dx);
1498                 // radius in our dist function
1499                 r = random();
1500                 r = sqrt(r);
1501                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1502         }
1503         else if(sstyle == 3) // gauss 3d
1504         {
1505                 sigma = spread * 0.44721359549996; // match baseline stddev
1506                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1507                 v1 = forward;
1508                 v1_x += gsl_ran_gaussian(sigma);
1509                 v1_y += gsl_ran_gaussian(sigma);
1510                 v1_z += gsl_ran_gaussian(sigma);
1511                 return v1;
1512         }
1513         else if(sstyle == 4) // gauss 2d
1514         {
1515                 sigma = spread * 0.44721359549996; // match baseline stddev
1516                 // note: 2D gaussian has sqrt(2) times the stddev of 1D, so this factor is right
1517                 v1_x = gsl_ran_gaussian(sigma);
1518                 v1_y = gsl_ran_gaussian(sigma);
1519                 v1_z = gsl_ran_gaussian(sigma);
1520                 return normalize(forward + cliptoplane(v1, forward));
1521         }
1522         else if(sstyle == 5) // 1-r
1523         {
1524                 sigma = spread * 1.154700538379252; // match baseline stddev
1525                 v1 = findperpendicular(forward);
1526                 v2 = cross(forward, v1);
1527                 // random point on unit circle
1528                 dx = random() * 2 * M_PI;
1529                 dy = sin(dx);
1530                 dx = cos(dx);
1531                 // radius in our dist function
1532                 r = random();
1533                 r = solve_cubic_abcd(-2, 3, 0, -r) * '0 1 0';
1534                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1535         }
1536         else if(sstyle == 6) // 1-r^2
1537         {
1538                 sigma = spread * 1.095445115010332; // match baseline stddev
1539                 v1 = findperpendicular(forward);
1540                 v2 = cross(forward, v1);
1541                 // random point on unit circle
1542                 dx = random() * 2 * M_PI;
1543                 dy = sin(dx);
1544                 dx = cos(dx);
1545                 // radius in our dist function
1546                 r = random();
1547                 r = sqrt(1 - r);
1548                 r = sqrt(1 - r);
1549                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1550         }
1551         else if(sstyle == 7) // (1-r) (2-r)
1552         {
1553                 sigma = spread * 1.224744871391589; // match baseline stddev
1554                 v1 = findperpendicular(forward);
1555                 v2 = cross(forward, v1);
1556                 // random point on unit circle
1557                 dx = random() * 2 * M_PI;
1558                 dy = sin(dx);
1559                 dx = cos(dx);
1560                 // radius in our dist function
1561                 r = random();
1562                 r = 1 - sqrt(r);
1563                 r = 1 - sqrt(r);
1564                 return normalize(forward + (v1 * dx + v2 * dy) * r * sigma);
1565         }
1566         else
1567                 error("g_projectiles_spread_style must be 0 (sphere), 1 (flattened sphere), 2 (circle), 3 (gauss 3D), 4 (gauss plane), 5 (linear falloff), 6 (quadratic falloff), 7 (stronger falloff)!");
1568         return '0 0 0';
1569         /*
1570          * how to derive falloff functions:
1571          * rho(r) := (2-r) * (1-r);
1572          * a : 0;
1573          * b : 1;
1574          * rhor(r) := r * rho(r);
1575          * cr(t) := integrate(rhor(r), r, a, t);
1576          * scr(t) := integrate(rhor(r) * r^2, r, a, t);
1577          * variance : scr(b) / cr(b);
1578          * solve(cr(r) = rand * cr(b), r), programmmode:false;
1579          * sqrt(0.4 / variance), numer;
1580          */
1581 }
1582
1583 #if 0
1584 float mspercallsum;
1585 float mspercallsstyle;
1586 float mspercallcount;
1587 #endif
1588 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
1589 {
1590         if(missile.owner == world)
1591                 error("Unowned missile");
1592
1593         dir = dir + upDir * (pUpSpeed / pSpeed);
1594         dir_z += pZSpeed / pSpeed;
1595         pSpeed *= vlen(dir);
1596         dir = normalize(dir);
1597
1598 #if 0
1599         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
1600         {
1601                 mspercallsum = mspercallcount = 0;
1602                 mspercallsstyle = autocvar_g_projectiles_spread_style;
1603         }
1604         mspercallsum -= gettime(GETTIME_HIRES);
1605 #endif
1606         dir = W_CalculateProjectileSpread(dir, spread);
1607 #if 0
1608         mspercallsum += gettime(GETTIME_HIRES);
1609         mspercallcount += 1;
1610         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
1611 #endif
1612
1613         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
1614 }
1615
1616 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread)
1617 {
1618         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
1619 }
1620
1621 #define W_SETUPPROJECTILEVELOCITY_UP(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), cvar(#s "_speed_up"), cvar(#s "_speed_z"), cvar(#s "_spread"), FALSE)
1622 #define W_SETUPPROJECTILEVELOCITY(m,s) W_SetupProjectileVelocityEx(m, w_shotdir, v_up, cvar(#s "_speed"), 0, 0, cvar(#s "_spread"), FALSE)
1623
1624 void W_DecreaseAmmo(.float ammo_type, float ammo_use, float ammo_reload)
1625 {
1626         if((self.items & IT_UNLIMITED_WEAPON_AMMO) && !ammo_reload)
1627                 return;
1628
1629         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
1630         if(ammo_reload)
1631         {
1632                 self.clip_load -= ammo_use;
1633                 self.weapon_load[self.weapon] = self.clip_load;
1634         }
1635         else
1636                 self.(self.current_ammo) -= ammo_use;
1637 }
1638
1639 // weapon reloading code
1640
1641 .float reload_ammo_amount, reload_ammo_min, reload_time;
1642 .float reload_complain;
1643 .string reload_sound;
1644
1645 void W_ReloadedAndReady()
1646 {
1647         // finish the reloading process, and do the ammo transfer
1648
1649         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
1650
1651         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
1652         if(!self.reload_ammo_min || self.items & IT_UNLIMITED_WEAPON_AMMO)
1653                 self.clip_load = self.reload_ammo_amount;
1654         else
1655         {
1656                 while(self.clip_load < self.reload_ammo_amount && self.(self.current_ammo)) // make sure we don't add more ammo than we have
1657                 {
1658                         self.clip_load += 1;
1659                         self.(self.current_ammo) -= 1;
1660                 }
1661         }
1662         self.weapon_load[self.weapon] = self.clip_load;
1663
1664         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1665         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1666         // so your weapon is disabled for a few seconds without reason
1667
1668         //ATTACK_FINISHED(self) -= self.reload_time - 1;
1669
1670         w_ready();
1671 }
1672
1673 void W_Reload(float sent_ammo_min, float sent_ammo_amount, float sent_time, string sent_sound)
1674 {
1675         // set global values to work with
1676
1677         self.reload_ammo_min = sent_ammo_min;
1678         self.reload_ammo_amount = sent_ammo_amount;
1679         self.reload_time = sent_time;
1680         self.reload_sound = sent_sound;
1681
1682         // check if we meet the necessary conditions to reload
1683
1684         entity e;
1685         e = get_weaponinfo(self.weapon);
1686
1687         // don't reload weapons that don't have the RELOADABLE flag
1688         if not(e.spawnflags & WEP_FLAG_RELOADABLE)
1689         {
1690                 dprint("Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
1691                 return;
1692         }
1693
1694         // return if reloading is disabled for this weapon
1695         if(!self.reload_ammo_amount)
1696                 return;
1697
1698         // our weapon is fully loaded, no need to reload
1699         if (self.clip_load >= self.reload_ammo_amount)
1700                 return;
1701
1702         // no ammo, so nothing to load
1703         if(!self.(self.current_ammo) && self.reload_ammo_min)
1704         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1705         {
1706                 if(clienttype(self) == CLIENTTYPE_REAL && self.reload_complain < time)
1707                 {
1708                         play2(self, "weapons/unavailable.wav");
1709                         sprint(self, strcat("You don't have enough ammo to reload the ^2", W_Name(self.weapon), "\n"));
1710                         self.reload_complain = time + 1;
1711                 }
1712                 // switch away if the amount of ammo is not enough to keep using this weapon
1713                 if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
1714                 {
1715                         self.clip_load = -1; // reload later
1716                         W_SwitchToOtherWeapon(self);
1717                 }
1718                 return;
1719         }
1720
1721         if (self.weaponentity)
1722         {
1723                 if (self.weaponentity.wframe == WFRAME_RELOAD)
1724                         return;
1725
1726                 // allow switching away while reloading, but this will cause a new reload!
1727                 self.weaponentity.state = WS_READY;
1728         }
1729
1730         // now begin the reloading process
1731
1732         sound (self, CH_WEAPON_B, self.reload_sound, VOL_BASE, ATTN_NORM);
1733
1734         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1735         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1736         // so your weapon is disabled for a few seconds without reason
1737
1738         //ATTACK_FINISHED(self) = max(time, ATTACK_FINISHED(self)) + self.reload_time + 1;
1739
1740         weapon_thinkf(WFRAME_RELOAD, self.reload_time, W_ReloadedAndReady);
1741
1742         if(self.clip_load < 0)
1743                 self.clip_load = 0;
1744         self.old_clip_load = self.clip_load;
1745         self.clip_load = self.weapon_load[self.weapon] = -1;
1746 }