qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         bool recount_ready = false;
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         this.ready = false;
 257                         recount_ready = true;
 258                 }
 259                 entcs_update_players(this);
 260         }
 261
 262         if (use_spawnpoint)
 263         {
 264                 entity spot = SelectSpawnPoint(this, true);
 265                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 266                 this.angles = vec2(spot.angles);
 267                 // offset it so that the spectator spawns higher off the ground, looks better this way
 268                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 269         }
 270         else // change origin to restore previous view origin
 271                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 272         this.fixangle = true;
 273
 274         if (IS_REAL_CLIENT(this))
 275         {
 276                 msg_entity = this;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, this);
 279         }
 280         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 281         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 282         if(!autocvar_g_debug_globalsounds)
 283         {
 284                 // needed for player sounds
 285                 this.model = "";
 286                 FixPlayermodel(this);
 287         }
 288         setmodel(this, MDL_Null);
 289         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 290         this.view_ofs = '0 0 0';
 291
 292         RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         TRANSMUTE(Observer, this);
 307
 308         if(recount_ready) ReadyCount();
 309
 310         WaypointSprite_PlayerDead(this);
 311         accuracy_resend(this);
 312
 313         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 314                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323         STAT(HUD, this) = HUD_NORMAL;
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         player_powerups_remove_all(this);
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406
 407         bot_relinkplayerlist();
 408
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void PutPlayerInServer(entity this)
 536 {
 537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 538
 539         PlayerState_attach(this);
 540         accuracy_resend(this);
 541
 542         if (this.team < 0)
 543                 TeamBalance_JoinBestTeam(this);
 544
 545         entity spot = SelectSpawnPoint(this, false);
 546         if (!spot) {
 547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 548                 return; // spawn failed
 549         }
 550
 551         TRANSMUTE(Player, this);
 552
 553         CS(this).wasplayer = true;
 554         this.iscreature = true;
 555         this.teleportable = TELEPORT_NORMAL;
 556         if(!this.damagedbycontents)
 557                 IL_PUSH(g_damagedbycontents, this);
 558         this.damagedbycontents = true;
 559         set_movetype(this, MOVETYPE_WALK);
 560         this.solid = SOLID_SLIDEBOX;
 561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 562         if (autocvar_g_playerclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 566         this.frags = FRAGS_PLAYER;
 567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 569         if (autocvar__notarget)
 570                 this.flags |= FL_NOTARGET;
 571         this.takedamage = DAMAGE_AIM;
 572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 573
 574         if (warmup_stage) {
 575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, warmup_start_health);
 582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 584         } else {
 585                 SetResource(this, RES_SHELLS, start_ammo_shells);
 586                 SetResource(this, RES_BULLETS, start_ammo_nails);
 587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 588                 SetResource(this, RES_CELLS, start_ammo_cells);
 589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 590                 SetResource(this, RES_FUEL, start_ammo_fuel);
 591                 SetResource(this, RES_HEALTH, start_health);
 592                 SetResource(this, RES_ARMOR, start_armorvalue);
 593                 STAT(WEAPONS, this) = start_weapons;
 594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 595                 {
 596                         GiveRandomWeapons(this, random_start_weapons_count,
 597                                 autocvar_g_random_start_weapons, random_start_ammo);
 598                 }
 599         }
 600         SetSpectatee_status(this, 0);
 601
 602         PS(this).dual_weapons = '0 0 0';
 603
 604         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 605                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 606
 607         this.items = start_items;
 608
 609         float shieldtime = time + autocvar_g_spawnshieldtime;
 610
 611         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 612         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 613         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 614         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 615         if (!sv_ready_restart_after_countdown && time < game_starttime)
 616         {
 617                 float f = game_starttime - time;
 618                 shieldtime += f;
 619                 this.pauserotarmor_finished += f;
 620                 this.pauserothealth_finished += f;
 621                 this.pauseregen_finished += f;
 622         }
 623
 624         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 625
 626         this.damageforcescale = autocvar_g_player_damageforcescale;
 627         this.death_time = 0;
 628         this.respawn_flags = 0;
 629         this.respawn_time = 0;
 630         STAT(RESPAWN_TIME, this) = 0;
 631         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 632         this.fade_time = 0;
 633         this.pain_finished = 0;
 634         this.pushltime = 0;
 635         setthink(this, func_null); // players have no think function
 636         this.nextthink = 0;
 637         this.dmg_team = 0;
 638         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 639
 640         this.deadflag = DEAD_NO;
 641
 642         this.angles = spot.angles;
 643         this.angles_z = 0; // never spawn tilted even if the spot says to
 644         if (IS_BOT_CLIENT(this))
 645         {
 646                 this.v_angle = this.angles;
 647                 bot_aim_reset(this);
 648         }
 649         this.fixangle = true; // turn this way immediately
 650         this.oldvelocity = this.velocity = '0 0 0';
 651         this.avelocity = '0 0 0';
 652         this.punchangle = '0 0 0';
 653         this.punchvector = '0 0 0';
 654
 655         STAT(REVIVE_PROGRESS, this) = 0;
 656         this.revival_time = 0;
 657
 658         STAT(AIR_FINISHED, this) = 0;
 659         this.waterlevel = WATERLEVEL_NONE;
 660         this.watertype = CONTENT_EMPTY;
 661
 662         entity spawnevent = new_pure(spawnevent);
 663         spawnevent.owner = this;
 664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665
 666         // Cut off any still running player sounds.
 667         stopsound(this, CH_PLAYER_SINGLE);
 668
 669         this.model = "";
 670         FixPlayermodel(this);
 671         this.drawonlytoclient = NULL;
 672
 673         this.viewloc = NULL;
 674
 675         for(int slot = 0; slot < MAX_AXH; ++slot)
 676         {
 677                 entity axh = this.(AuxiliaryXhair[slot]);
 678                 this.(AuxiliaryXhair[slot]) = NULL;
 679
 680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 681                         delete(axh);
 682         }
 683
 684         this.spawnpoint_targ = NULL;
 685
 686         UNSET_DUCKED(this);
 687         this.view_ofs = STAT(PL_VIEW_OFS, this);
 688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 689         this.spawnorigin = spot.origin;
 690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 691         // don't reset back to last position, even if new position is stuck in solid
 692         this.oldorigin = this.origin;
 693         if(this.conveyor)
 694                 IL_REMOVE(g_conveyed, this);
 695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 696         if(this.swampslug)
 697                 IL_REMOVE(g_swamped, this);
 698         this.swampslug = NULL;
 699         this.swamp_interval = 0;
 700         if(this.ladder_entity)
 701                 IL_REMOVE(g_ladderents, this);
 702         this.ladder_entity = NULL;
 703         IL_EACH(g_counters, it.realowner == this,
 704         {
 705                 delete(it);
 706         });
 707         STAT(HUD, this) = HUD_NORMAL;
 708
 709         this.event_damage = PlayerDamage;
 710         this.event_heal = PlayerHeal;
 711
 712         this.draggable = func_null;
 713
 714         if(!this.bot_attack)
 715                 IL_PUSH(g_bot_targets, this);
 716         this.bot_attack = true;
 717         if(!this.monster_attack)
 718                 IL_PUSH(g_monster_targets, this);
 719         this.monster_attack = true;
 720         navigation_dynamicgoal_init(this, false);
 721
 722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 723
 724         // player was spectator
 725         if (CS(this).killcount == FRAGS_SPECTATOR) {
 726                 PlayerScore_Clear(this);
 727                 CS(this).killcount = 0;
 728                 CS(this).startplaytime = time;
 729         }
 730
 731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 732         {
 733                 .entity weaponentity = weaponentities[slot];
 734                 CL_SpawnWeaponentity(this, weaponentity);
 735         }
 736         this.alpha = default_player_alpha;
 737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 738         this.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740         this.speedrunning = false;
 741
 742         this.counter_cnt = 0;
 743         this.fragsfilter_cnt = 0;
 744
 745         target_voicescript_clear(this);
 746
 747         // reset fields the weapons may use
 748         FOREACH(Weapons, true, {
 749                 it.wr_resetplayer(it, this);
 750                         // reload all reloadable weapons
 751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753                         {
 754                                 .entity weaponentity = weaponentities[slot];
 755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 756                         }
 757                 }
 758         });
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763
 764         {
 765                 string s = spot.target;
 766                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 767                         spot.target = string_null;
 768                 SUB_UseTargets(spot, this, NULL);
 769                 if(g_assault || g_race)
 770                         spot.target = s;
 771         }
 772
 773         if (autocvar_spawn_debug)
 774         {
 775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 777         }
 778
 779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780         {
 781                 .entity weaponentity = weaponentities[slot];
 782                 entity w_ent = this.(weaponentity);
 783                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 784                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 785                 else
 786                         w_ent.m_switchweapon = WEP_Null;
 787                 w_ent.m_weapon = WEP_Null;
 788                 w_ent.weaponname = "";
 789                 w_ent.m_switchingweapon = WEP_Null;
 790                 w_ent.cnt = -1;
 791         }
 792
 793         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 794
 795         if (CS(this).impulse) ImpulseCommands(this);
 796
 797         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 W_WeaponFrame(this, weaponentity);
 802         }
 803
 804         if (!warmup_stage && !this.alivetime)
 805                 this.alivetime = time;
 806
 807         antilag_clear(this, CS(this));
 808 }
 809
 810 /** Called when a client spawns in the server */
 811 void PutClientInServer(entity this)
 812 {
 813         if (IS_BOT_CLIENT(this)) {
 814                 TRANSMUTE(Player, this);
 815         } else if (IS_REAL_CLIENT(this)) {
 816                 msg_entity = this;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, this);
 819         }
 820         if (game_stopped)
 821                 TRANSMUTE(Observer, this);
 822
 823         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this, false, use_spawnpoint);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837
 838         bot_relinkplayerlist();
 839 }
 840
 841 // TODO do we need all these fields, or should we stop autodetecting runtime
 842 // changes and just have a console command to update this?
 843 bool ClientInit_SendEntity(entity this, entity to, int sf)
 844 {
 845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 846         return = true;
 847         msg_entity = to;
 848         // MSG_INIT replacement
 849         // TODO: make easier to use
 850         Registry_send_all();
 851         W_PROP_reload(MSG_ONE, to);
 852         ClientInit_misc(this);
 853         MUTATOR_CALLHOOK(Ent_Init);
 854 }
 855 void ClientInit_misc(entity this)
 856 {
 857         int channel = MSG_ONE;
 858         WriteHeader(channel, ENT_CLIENT_INIT);
 859         WriteByte(channel, g_nexball_meter_period * 32);
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 868
 869         if(autocvar_sv_foginterval && world.fog != "")
 870                 WriteString(channel, world.fog);
 871         else
 872                 WriteString(channel, "");
 873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 875         WriteByte(channel, serverflags);
 876         WriteCoord(channel, autocvar_g_trueaim_minrange);
 877 }
 878
 879 void ClientInit_CheckUpdate(entity this)
 880 {
 881         this.nextthink = time;
 882         if(this.count != autocvar_g_balance_armor_blockpercent)
 883         {
 884                 this.count = autocvar_g_balance_armor_blockpercent;
 885                 this.SendFlags |= 1;
 886         }
 887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 888         {
 889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 890                 this.SendFlags |= 1;
 891         }
 892 }
 893
 894 void ClientInit_Spawn()
 895 {
 896         entity e = new_pure(clientinit);
 897         setthink(e, ClientInit_CheckUpdate);
 898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 899
 900         ClientInit_CheckUpdate(e);
 901 }
 902
 903 /*
 904 =============
 905 SetNewParms
 906 =============
 907 */
 908 void SetNewParms ()
 909 {
 910         // initialize parms for a new player
 911         parm1 = -(86400 * 366);
 912
 913         MUTATOR_CALLHOOK(SetNewParms);
 914 }
 915
 916 /*
 917 =============
 918 SetChangeParms
 919 =============
 920 */
 921 void SetChangeParms (entity this)
 922 {
 923         // save parms for level change
 924         parm1 = CS(this).parm_idlesince - time;
 925
 926         MUTATOR_CALLHOOK(SetChangeParms);
 927 }
 928
 929 /*
 930 =============
 931 DecodeLevelParms
 932 =============
 933 */
 934 void DecodeLevelParms(entity this)
 935 {
 936         // load parms
 937         CS(this).parm_idlesince = parm1;
 938         if (CS(this).parm_idlesince == -(86400 * 366))
 939                 CS(this).parm_idlesince = time;
 940
 941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 943
 944         MUTATOR_CALLHOOK(DecodeLevelParms);
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 957
 958         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 959
 960         MUTATOR_CALLHOOK(FixClientCvars, e);
 961 }
 962
 963 bool findinlist_abbrev(string tofind, string list)
 964 {
 965         if(list == "" || tofind == "")
 966                 return false; // empty list or search, just return
 967
 968         // this function allows abbreviated strings!
 969         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 970         {
 971                 return true;
 972         });
 973
 974         return false;
 975 }
 976
 977 bool PlayerInIPList(entity p, string iplist)
 978 {
 979         // some safety checks (never allow local?)
 980         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 981                 return false;
 982
 983         return findinlist_abbrev(p.netaddress, iplist);
 984 }
 985
 986 bool PlayerInIDList(entity p, string idlist)
 987 {
 988         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 989         if(!p.crypto_idfp)
 990                 return false;
 991
 992         return findinlist_abbrev(p.crypto_idfp, idlist);
 993 }
 994
 995 bool PlayerInList(entity player, string list)
 996 {
 997         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 998 }
 999
1000 #ifdef DP_EXT_PRECONNECT
1001 /*
1002 =============
1003 ClientPreConnect
1004
1005 Called once (not at each match start) when a client begins a connection to the server
1006 =============
1007 */
1008 void ClientPreConnect(entity this)
1009 {
1010         if(autocvar_sv_eventlog)
1011         {
1012                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1013                         this.playerid,
1014                         etof(this),
1015                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1016                 ));
1017         }
1018 }
1019 #endif
1020
1021 void SendWelcomemessage(entity this, bool force_centerprint)
1022 {
1023         msg_entity = this;
1024         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1025         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1026 }
1027
1028 // NOTE csqc uses the active mutators list sent by this function
1029 // to understand which mutators are enabled
1030 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1031 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1032 {
1033         WriteByte(msg_type, boolean(autocvar_g_campaign));
1034         if (boolean(autocvar_g_campaign))
1035         {
1036                 WriteString(msg_type, Campaign_GetTitle());
1037                 WriteByte(msg_type, Campaign_GetLevelNum());
1038                 WriteString(msg_type, Campaign_GetMessage());
1039                 return;
1040         }
1041         WriteByte(msg_type, force_centerprint);
1042         WriteString(msg_type, autocvar_hostname);
1043         WriteString(msg_type, autocvar_g_xonoticversion);
1044         WriteByte(msg_type, CS(this).version_mismatch);
1045         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1046
1047         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1048         string modifications = M_ARGV(0, string);
1049
1050         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1051                 modifications = strcat(modifications, ", No start weapons");
1052         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1053                 modifications = strcat(modifications, ", Low gravity");
1054         if(g_weapon_stay && !g_cts)
1055                 modifications = strcat(modifications, ", Weapons stay");
1056         if(autocvar_g_jetpack)
1057                 modifications = strcat(modifications, ", Jetpack");
1058         modifications = substring(modifications, 2, strlen(modifications) - 2);
1059
1060         WriteString(msg_type, modifications);
1061
1062         WriteString(msg_type, g_weaponarena_list);
1063
1064         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1065         {
1066                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1067                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1068         }
1069
1070         WriteString(msg_type, cache_mutatormsg);
1071
1072         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1073 }
1074
1075 /**
1076 =============
1077 ClientConnect
1078
1079 Called when a client connects to the server
1080 =============
1081 */
1082 void ClientConnect(entity this)
1083 {
1084         if (Ban_MaybeEnforceBanOnce(this)) return;
1085         assert(!IS_CLIENT(this), return);
1086         this.flags |= FL_CLIENT;
1087         assert(player_count >= 0, player_count = 0);
1088
1089         TRANSMUTE(Client, this);
1090         CS(this).version_nagtime = time + 10 + random() * 10;
1091
1092         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1093
1094         bot_clientconnect(this);
1095
1096         Player_DetermineForcedTeam(this);
1097
1098         TRANSMUTE(Observer, this);
1099
1100         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1101
1102         // always track bots, don't ask for cl_allow_uidtracking
1103         if (IS_BOT_CLIENT(this))
1104                 PlayerStats_GameReport_AddPlayer(this);
1105         else
1106                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1107
1108         if (autocvar_sv_eventlog)
1109                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1110
1111         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1112
1113         stuffcmd(this, clientstuff, "\n");
1114         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1115
1116         FixClientCvars(this);
1117
1118         // get version info from player
1119         stuffcmd(this, "cmd clientversion $gameversion\n");
1120
1121         // notify about available teams
1122         if (teamplay)
1123         {
1124                 entity balance = TeamBalance_CheckAllowedTeams(this);
1125                 int t = TeamBalance_GetAllowedTeams(balance);
1126                 TeamBalance_Destroy(balance);
1127                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1128         }
1129         else
1130         {
1131                 stuffcmd(this, "set _teams_available 0\n");
1132         }
1133
1134         bot_relinkplayerlist();
1135
1136         CS(this).spectatortime = time;
1137         if (blockSpectators)
1138         {
1139                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1140         }
1141
1142         CS(this).jointime = time;
1143
1144         if (IS_REAL_CLIENT(this))
1145         {
1146                 if (g_weaponarena_weapons == WEPSET(TUBA))
1147                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1148         }
1149
1150         if (!autocvar_sv_foginterval && world.fog != "")
1151                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1152
1153         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1154                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1155                         send_CSQC_teamnagger();
1156
1157         CSQCMODEL_AUTOINIT(this);
1158
1159         CS(this).model_randomizer = random();
1160
1161         if (IS_REAL_CLIENT(this))
1162                 sv_notice_join(this);
1163
1164         this.move_qcphysics = autocvar_sv_qcphysics;
1165
1166         // update physics stats (players can spawn before physics runs)
1167         Physics_UpdateStats(this);
1168
1169         IL_EACH(g_initforplayer, it.init_for_player, {
1170                 it.init_for_player(it, this);
1171         });
1172
1173         Handicap_Initialize(this);
1174
1175         MUTATOR_CALLHOOK(ClientConnect, this);
1176
1177         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1178                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1179 }
1180 /*
1181 =============
1182 ClientDisconnect
1183
1184 Called when a client disconnects from the server
1185 =============
1186 */
1187 .entity chatbubbleentity;
1188 void player_powerups_remove_all(entity this);
1189
1190 void ClientDisconnect(entity this)
1191 {
1192         assert(IS_CLIENT(this), return);
1193
1194         PlayerStats_GameReport_FinalizePlayer(this);
1195         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1196         if (CS(this).active_minigame) part_minigame(this);
1197         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1198
1199         if (autocvar_sv_eventlog)
1200                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1201
1202         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1203
1204         if(IS_SPEC(this))
1205                 SetSpectatee(this, NULL);
1206
1207         MUTATOR_CALLHOOK(ClientDisconnect, this);
1208
1209         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1210         strfree(CS_CVAR(this).weaponorder_byimpulse);
1211         ClientState_detach(this);
1212
1213         Portal_ClearAll(this);
1214
1215         Unfreeze(this, false);
1216
1217         RemoveGrapplingHooks(this);
1218
1219         // Here, everything has been done that requires this player to be a client.
1220
1221         this.flags &= ~FL_CLIENT;
1222
1223         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1224         if (this.killindicator) delete(this.killindicator);
1225
1226         IL_EACH(g_counters, it.realowner == this,
1227         {
1228                 delete(it);
1229         });
1230
1231         WaypointSprite_PlayerGone(this);
1232
1233         bot_relinkplayerlist();
1234
1235         strfree(this.clientstatus);
1236         if (this.personal) delete(this.personal);
1237
1238         this.playerid = 0;
1239         ReadyCount();
1240         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1241
1242         player_powerups_remove_all(this); // stop powerup sound
1243
1244         ONREMOVE(this);
1245 }
1246
1247 void ChatBubbleThink(entity this)
1248 {
1249         this.nextthink = time;
1250         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1251         {
1252                 if(this.owner) // but why can that ever be NULL?
1253                         this.owner.chatbubbleentity = NULL;
1254                 delete(this);
1255                 return;
1256         }
1257
1258         this.mdl = "";
1259
1260         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1261         {
1262                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1263                         this.mdl = "models/sprites/minigame_busy.iqm";
1264                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1265                         this.mdl = "models/misc/chatbubble.spr";
1266         }
1267
1268         if ( this.model != this.mdl )
1269                 _setmodel(this, this.mdl);
1270
1271 }
1272
1273 void UpdateChatBubble(entity this)
1274 {
1275         if (this.alpha < 0)
1276                 return;
1277         // spawn a chatbubble entity if needed
1278         if (!this.chatbubbleentity)
1279         {
1280                 this.chatbubbleentity = new(chatbubbleentity);
1281                 this.chatbubbleentity.owner = this;
1282                 this.chatbubbleentity.exteriormodeltoclient = this;
1283                 setthink(this.chatbubbleentity, ChatBubbleThink);
1284                 this.chatbubbleentity.nextthink = time;
1285                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1286                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1287                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1288                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1289                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1290                 //this.chatbubbleentity.model = "";
1291                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1292         }
1293 }
1294
1295 void calculate_player_respawn_time(entity this)
1296 {
1297         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1298                 return;
1299
1300         float gametype_setting_tmp;
1301         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1302         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1303         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1304         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1305         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1306         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1307
1308         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1309         if (teamplay)
1310         {
1311                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1312                         if(it.team == this.team)
1313                                 ++pcount;
1314                 });
1315                 if (sdelay_small_count == 0)
1316                         sdelay_small_count = 1;
1317                 if (sdelay_large_count == 0)
1318                         sdelay_large_count = 1;
1319         }
1320         else
1321         {
1322                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1323                         ++pcount;
1324                 });
1325                 if (sdelay_small_count == 0)
1326                 {
1327                         if (IS_INDEPENDENT_PLAYER(this))
1328                         {
1329                                 // Players play independently. No point in requiring enemies.
1330                                 sdelay_small_count = 1;
1331                         }
1332                         else
1333                         {
1334                                 // Players play AGAINST each other. Enemies required.
1335                                 sdelay_small_count = 2;
1336                         }
1337                 }
1338                 if (sdelay_large_count == 0)
1339                 {
1340                         if (IS_INDEPENDENT_PLAYER(this))
1341                         {
1342                                 // Players play independently. No point in requiring enemies.
1343                                 sdelay_large_count = 1;
1344                         }
1345                         else
1346                         {
1347                                 // Players play AGAINST each other. Enemies required.
1348                                 sdelay_large_count = 2;
1349                         }
1350                 }
1351         }
1352
1353         float sdelay;
1354
1355         if (pcount <= sdelay_small_count)
1356                 sdelay = sdelay_small;
1357         else if (pcount >= sdelay_large_count)
1358                 sdelay = sdelay_large;
1359         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1360                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1361
1362         if(waves)
1363                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1364         else
1365                 this.respawn_time = time + sdelay;
1366
1367         if(sdelay < sdelay_max)
1368                 this.respawn_time_max = time + sdelay_max;
1369         else
1370                 this.respawn_time_max = this.respawn_time;
1371
1372         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1373                 this.respawn_countdown = 10; // first number to count down from is 10
1374         else
1375                 this.respawn_countdown = -1; // do not count down
1376
1377         if(autocvar_g_forced_respawn)
1378                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1379 }
1380
1381 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1382 // added to the model skins
1383 /*void UpdateColorModHack()
1384 {
1385         float c;
1386         c = this.clientcolors & 15;
1387         // LordHavoc: only bothering to support white, green, red, yellow, blue
1388              if (!teamplay) this.colormod = '0 0 0';
1389         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1390         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1391         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1392         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1393         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1394         else this.colormod = '1 1 1';
1395 }*/
1396
1397 void respawn(entity this)
1398 {
1399         bool damagedbycontents_prev = this.damagedbycontents;
1400         if(this.alpha >= 0)
1401         {
1402                 if(autocvar_g_respawn_ghosts)
1403                 {
1404                         this.solid = SOLID_NOT;
1405                         this.takedamage = DAMAGE_NO;
1406                         this.damagedbycontents = false;
1407                         set_movetype(this, MOVETYPE_FLY);
1408                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1409                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1410                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1411                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1412                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1413                         if(autocvar_g_respawn_ghosts_time > 0)
1414                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1415                 }
1416                 else
1417                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1418         }
1419
1420         CopyBody(this, 1);
1421         this.damagedbycontents = damagedbycontents_prev;
1422
1423         this.effects |= EF_NODRAW; // prevent another CopyBody
1424         PutClientInServer(this);
1425 }
1426
1427 void play_countdown(entity this, float finished, Sound samp)
1428 {
1429         TC(Sound, samp);
1430         float time_left = finished - time;
1431         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1432                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1433 }
1434
1435 // it removes special powerups not handled by StatusEffects
1436 void player_powerups_remove_all(entity this)
1437 {
1438         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1439         {
1440                 // don't play the poweroff sound when the game restarts or the player disconnects
1441                 if (time > game_starttime + 1 && IS_CLIENT(this)
1442                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1443                 {
1444                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1445                 }
1446                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1447                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1448                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1449         }
1450 }
1451
1452 void player_powerups(entity this)
1453 {
1454         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1455                 this.modelflags |= MF_ROCKET;
1456         else
1457                 this.modelflags &= ~MF_ROCKET;
1458
1459         this.effects &= ~EF_NODEPTHTEST;
1460
1461         if (IS_DEAD(this))
1462                 player_powerups_remove_all(this);
1463
1464         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1465                 return;
1466
1467         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1468         int items_prev = this.items;
1469
1470         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1471         {
1472                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1473                 if (this.items & IT_SUPERWEAPON)
1474                 {
1475                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1476                         {
1477                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1478                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1479                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1480                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1481                         }
1482                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1483                         {
1484                                 // don't let them run out
1485                         }
1486                         else
1487                         {
1488                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1489                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1490                                 {
1491                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1492                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1493                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1494                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1495                                 }
1496                         }
1497                 }
1498                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1499                 {
1500                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1501                         {
1502                                 this.items = this.items | IT_SUPERWEAPON;
1503                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1504                                 {
1505                                         if(!g_cts)
1506                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1507                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1508                                 }
1509                         }
1510                         else
1511                         {
1512                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1513                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1514                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1515                         }
1516                 }
1517                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1518                 {
1519                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1520                 }
1521         }
1522
1523         if(autocvar_g_nodepthtestplayers)
1524                 this.effects = this.effects | EF_NODEPTHTEST;
1525
1526         if(autocvar_g_fullbrightplayers)
1527                 this.effects = this.effects | EF_FULLBRIGHT;
1528
1529         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1530 }
1531
1532 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1533 {
1534         if(current > stable)
1535                 return current;
1536         else if(current > stable - 0.25) // when close enough, "snap"
1537                 return stable;
1538         else
1539                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1540 }
1541
1542 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1543 {
1544         if(current < stable)
1545                 return current;
1546         else if(current < stable + 0.25) // when close enough, "snap"
1547                 return stable;
1548         else
1549                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1550 }
1551
1552 void RotRegen(entity this, Resource res, float limit_mod,
1553         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1554         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1555 {
1556         float old = GetResource(this, res);
1557         float current = old;
1558         if(current > rotstable)
1559         {
1560                 if(rotframetime > 0)
1561                 {
1562                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1563                         current = max(rotstable, current - rotlinear * rotframetime);
1564                 }
1565         }
1566         else if(current < regenstable)
1567         {
1568                 if(regenframetime > 0)
1569                 {
1570                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1571                         current = min(regenstable, current + regenlinear * regenframetime);
1572                 }
1573         }
1574
1575         float limit = GetResourceLimit(this, res) * limit_mod;
1576         if(current > limit)
1577                 current = limit;
1578
1579         if (current != old)
1580                 SetResource(this, res, current);
1581 }
1582
1583 void player_regen(entity this)
1584 {
1585         float max_mod, regen_mod, rot_mod, limit_mod;
1586         max_mod = regen_mod = rot_mod = limit_mod = 1;
1587
1588         float regen_health = autocvar_g_balance_health_regen;
1589         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1590         float regen_health_rot = autocvar_g_balance_health_rot;
1591         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1592         float regen_health_stable = autocvar_g_balance_health_regenstable;
1593         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1594         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1595                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1596         max_mod = M_ARGV(1, float);
1597         regen_mod = M_ARGV(2, float);
1598         rot_mod = M_ARGV(3, float);
1599         limit_mod = M_ARGV(4, float);
1600         regen_health = M_ARGV(5, float);
1601         regen_health_linear = M_ARGV(6, float);
1602         regen_health_rot = M_ARGV(7, float);
1603         regen_health_rotlinear = M_ARGV(8, float);
1604         regen_health_stable = M_ARGV(9, float);
1605         regen_health_rotstable = M_ARGV(10, float);
1606
1607         float rotstable, regenstable, rotframetime, regenframetime;
1608
1609         if(!mutator_returnvalue)
1610         if(!STAT(FROZEN, this))
1611         {
1612                 regenstable = autocvar_g_balance_armor_regenstable;
1613                 rotstable = autocvar_g_balance_armor_rotstable;
1614                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1615                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1616                 RotRegen(this, RES_ARMOR, limit_mod,
1617                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1618                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1619
1620                 // NOTE: max_mod is only applied to health
1621                 regenstable = regen_health_stable * max_mod;
1622                 rotstable = regen_health_rotstable * max_mod;
1623                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1624                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1625                 RotRegen(this, RES_HEALTH, limit_mod,
1626                         regenstable, regen_health, regen_health_linear, regenframetime,
1627                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1628         }
1629
1630         // if player rotted to death...  die!
1631         // check this outside above checks, as player may still be able to rot to death
1632         if(GetResource(this, RES_HEALTH) < 1)
1633         {
1634                 if(this.vehicle)
1635                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1636                 if(this.event_damage)
1637                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1638         }
1639
1640         if (!(this.items & IT_UNLIMITED_AMMO))
1641         {
1642                 regenstable = autocvar_g_balance_fuel_regenstable;
1643                 rotstable = autocvar_g_balance_fuel_rotstable;
1644                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1645                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1646                 RotRegen(this, RES_FUEL, 1,
1647                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1648                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1649         }
1650 }
1651
1652 bool zoomstate_set;
1653 void SetZoomState(entity this, float newzoom)
1654 {
1655         if(newzoom != CS(this).zoomstate)
1656         {
1657                 CS(this).zoomstate = newzoom;
1658                 ClientData_Touch(this);
1659         }
1660         zoomstate_set = true;
1661 }
1662
1663 void GetPressedKeys(entity this)
1664 {
1665         MUTATOR_CALLHOOK(GetPressedKeys, this);
1666         if (game_stopped)
1667         {
1668                 CS(this).pressedkeys = 0;
1669                 STAT(PRESSED_KEYS, this) = 0;
1670                 return;
1671         }
1672
1673         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1674         int keys = STAT(PRESSED_KEYS, this);
1675         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1676         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1677         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1678         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1679
1680         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1681         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1682         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1683         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1684         CS(this).pressedkeys = keys; // store for other users
1685
1686         STAT(PRESSED_KEYS, this) = keys;
1687 }
1688
1689 /*
1690 ======================
1691 spectate mode routines
1692 ======================
1693 */
1694
1695 void SpectateCopy(entity this, entity spectatee)
1696 {
1697         TC(Client, this); TC(Client, spectatee);
1698
1699         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1700         PS(this) = PS(spectatee);
1701         this.armortype = spectatee.armortype;
1702         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1703         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1704         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1705         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1706         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1707         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1708         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1709         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1710         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1711         CS(this).impulse = 0;
1712         this.disableclientprediction = 1; // no need to run prediction on a spectator
1713         this.items = spectatee.items;
1714         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1715         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1716         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1717         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1718         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1719         this.punchangle = spectatee.punchangle;
1720         this.view_ofs = spectatee.view_ofs;
1721         this.velocity = spectatee.velocity;
1722         this.dmg_take = spectatee.dmg_take;
1723         this.dmg_save = spectatee.dmg_save;
1724         this.dmg_inflictor = spectatee.dmg_inflictor;
1725         this.v_angle = spectatee.v_angle;
1726         this.angles = spectatee.v_angle;
1727         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1728         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1729         this.viewloc = spectatee.viewloc;
1730         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1731                 this.fixangle = true;
1732         setorigin(this, spectatee.origin);
1733         setsize(this, spectatee.mins, spectatee.maxs);
1734         SetZoomState(this, CS(spectatee).zoomstate);
1735
1736     anticheat_spectatecopy(this, spectatee);
1737         STAT(HUD, this) = STAT(HUD, spectatee);
1738         if(spectatee.vehicle)
1739     {
1740         this.angles = spectatee.v_angle;
1741
1742         //this.fixangle = false;
1743         //this.velocity = spectatee.vehicle.velocity;
1744         this.vehicle_health = spectatee.vehicle_health;
1745         this.vehicle_shield = spectatee.vehicle_shield;
1746         this.vehicle_energy = spectatee.vehicle_energy;
1747         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1748         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1749         this.vehicle_reload1 = spectatee.vehicle_reload1;
1750         this.vehicle_reload2 = spectatee.vehicle_reload2;
1751
1752         //msg_entity = this;
1753
1754        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1755             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1756            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1757            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1758
1759         //WriteByte (MSG_ONE, SVC_SETVIEW);
1760         //    WriteEntity(MSG_ONE, this);
1761         //makevectors(spectatee.v_angle);
1762         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1763     }
1764 }
1765
1766 bool SpectateUpdate(entity this)
1767 {
1768         if(!this.enemy)
1769                 return false;
1770
1771         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1772         {
1773                 SetSpectatee(this, NULL);
1774                 return false;
1775         }
1776
1777         SpectateCopy(this, this.enemy);
1778
1779         return true;
1780 }
1781
1782 bool SpectateSet(entity this)
1783 {
1784         if(!IS_PLAYER(this.enemy))
1785                 return false;
1786
1787         ClientData_Touch(this.enemy);
1788
1789         msg_entity = this;
1790         WriteByte(MSG_ONE, SVC_SETVIEW);
1791         WriteEntity(MSG_ONE, this.enemy);
1792         set_movetype(this, MOVETYPE_NONE);
1793         accuracy_resend(this);
1794
1795         if(!SpectateUpdate(this))
1796                 PutObserverInServer(this, false, true);
1797
1798         return true;
1799 }
1800
1801 void SetSpectatee_status(entity this, int spectatee_num)
1802 {
1803         int oldspectatee_status = CS(this).spectatee_status;
1804         CS(this).spectatee_status = spectatee_num;
1805
1806         if (CS(this).spectatee_status != oldspectatee_status)
1807         {
1808                 if (STAT(PRESSED_KEYS, this))
1809                 {
1810                         CS(this).pressedkeys = 0;
1811                         STAT(PRESSED_KEYS, this) = 0;
1812                 }
1813                 ClientData_Touch(this);
1814                 if (g_race || g_cts) race_InitSpectator();
1815         }
1816 }
1817
1818 void SetSpectatee(entity this, entity spectatee)
1819 {
1820         if(IS_BOT_CLIENT(this))
1821                 return; // bots abuse .enemy, this code is useless to them
1822
1823         entity old_spectatee = this.enemy;
1824
1825         this.enemy = spectatee;
1826
1827         // WEAPONTODO
1828         // these are required to fix the spectator bug with arc
1829         if(old_spectatee)
1830         {
1831                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1832                 {
1833                         .entity weaponentity = weaponentities[slot];
1834                         if(old_spectatee.(weaponentity).arc_beam)
1835                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1836                 }
1837         }
1838         if(spectatee)
1839         {
1840                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1841                 {
1842                         .entity weaponentity = weaponentities[slot];
1843                         if(spectatee.(weaponentity).arc_beam)
1844                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1845                 }
1846         }
1847
1848         if (spectatee)
1849                 SetSpectatee_status(this, etof(spectatee));
1850
1851         // needed to update spectator list
1852         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1853 }
1854
1855 bool Spectate(entity this, entity pl)
1856 {
1857         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1858                 return false;
1859         pl = M_ARGV(1, entity);
1860
1861         SetSpectatee(this, pl);
1862         return SpectateSet(this);
1863 }
1864
1865 bool SpectateNext(entity this)
1866 {
1867         entity ent = find(this.enemy, classname, STR_PLAYER);
1868
1869         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1870                 ent = M_ARGV(1, entity);
1871         else if (!ent)
1872                 ent = find(ent, classname, STR_PLAYER);
1873
1874         if(ent) { SetSpectatee(this, ent); }
1875
1876         return SpectateSet(this);
1877 }
1878
1879 bool SpectatePrev(entity this)
1880 {
1881         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1882         entity ent = findchain(classname, STR_PLAYER);
1883         if (!ent) // no player
1884                 return false;
1885
1886         entity first = ent;
1887         // skip players until current spectated player
1888         if(this.enemy)
1889         while(ent && ent != this.enemy)
1890                 ent = ent.chain;
1891
1892         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1893         {
1894                 case MUT_SPECPREV_FOUND:
1895                         ent = M_ARGV(1, entity);
1896                         break;
1897                 case MUT_SPECPREV_RETURN:
1898                         return true;
1899                 case MUT_SPECPREV_CONTINUE:
1900                 default:
1901                 {
1902                         if(ent.chain)
1903                                 ent = ent.chain;
1904                         else
1905                                 ent = first;
1906                         break;
1907                 }
1908         }
1909
1910         SetSpectatee(this, ent);
1911         return SpectateSet(this);
1912 }
1913
1914 /*
1915 =============
1916 ShowRespawnCountdown()
1917
1918 Update a respawn countdown display.
1919 =============
1920 */
1921 void ShowRespawnCountdown(entity this)
1922 {
1923         float number;
1924         if(!IS_DEAD(this)) // just respawned?
1925                 return;
1926         else
1927         {
1928                 number = ceil(this.respawn_time - time);
1929                 if(number <= 0)
1930                         return;
1931                 if(number <= this.respawn_countdown)
1932                 {
1933                         this.respawn_countdown = number - 1;
1934                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1935                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1936                 }
1937         }
1938 }
1939
1940 .bool team_selected;
1941 bool ShowTeamSelection(entity this)
1942 {
1943         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1944                 return false;
1945         stuffcmd(this, "menu_showteamselect\n");
1946         return true;
1947 }
1948 void Join(entity this)
1949 {
1950         TRANSMUTE(Player, this);
1951
1952         if(!this.team_selected)
1953         if(autocvar_g_campaign || autocvar_g_balance_teams)
1954                 TeamBalance_JoinBestTeam(this);
1955
1956         if(autocvar_g_campaign)
1957                 campaign_bots_may_start = true;
1958
1959         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1960
1961         PutClientInServer(this);
1962
1963         if(IS_PLAYER(this))
1964         if(teamplay && this.team != -1)
1965         {
1966         }
1967         else
1968                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1969         this.team_selected = false;
1970 }
1971
1972 int GetPlayerLimit()
1973 {
1974         if(g_duel)
1975                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1976         int player_limit = autocvar_g_maxplayers;
1977         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1978         player_limit = M_ARGV(0, int);
1979         return player_limit;
1980 }
1981
1982 /**
1983  * Determines whether the player is allowed to join. This depends on cvar
1984  * g_maxplayers, if it isn't used this function always return true, otherwise
1985  * it checks whether the number of currently playing players exceeds g_maxplayers.
1986  * @return int number of free slots for players, 0 if none
1987  */
1988 int nJoinAllowed(entity this, entity ignore)
1989 {
1990         if(!ignore)
1991         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1992         // so report 0 free slots if restricted
1993         {
1994                 if(autocvar_g_forced_team_otherwise == "spectate")
1995                         return 0;
1996                 if(autocvar_g_forced_team_otherwise == "spectator")
1997                         return 0;
1998         }
1999
2000         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2001                 return 0; // forced spectators can never join
2002
2003         // TODO simplify this
2004         int totalClients = 0;
2005         int currentlyPlaying = 0;
2006         FOREACH_CLIENT(true, {
2007                 if(it != ignore)
2008                         ++totalClients;
2009                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2010                         ++currentlyPlaying;
2011         });
2012
2013         int player_limit = GetPlayerLimit();
2014
2015         int free_slots = 0;
2016         if (!player_limit)
2017                 free_slots = maxclients - totalClients;
2018         else if(player_limit > 0 && currentlyPlaying < player_limit)
2019                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2020
2021         static float msg_time = 0;
2022         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2023         {
2024                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2025                 msg_time = time + 0.5;
2026         }
2027
2028         return free_slots;
2029 }
2030
2031 void PrintWelcomeMessage(entity this)
2032 {
2033         if(CS(this).motd_actived_time == 0)
2034         {
2035                 if (autocvar_g_campaign) {
2036                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2037                                 CS(this).motd_actived_time = time;
2038                                 SendWelcomemessage(this, false);
2039                         }
2040                 } else {
2041                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2042                                 CS(this).motd_actived_time = time;
2043                                 SendWelcomemessage(this, true);
2044                         }
2045                 }
2046         }
2047         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2048         {
2049                 if (autocvar_g_campaign) {
2050                         if (PHYS_INPUT_BUTTON_INFO(this))
2051                                 CS(this).motd_actived_time = time;
2052                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2053                                 CS(this).motd_actived_time = 0;
2054                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2055                         }
2056                 } else {
2057                         if (PHYS_INPUT_BUTTON_INFO(this))
2058                                 CS(this).motd_actived_time = time;
2059                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2060                                 CS(this).motd_actived_time = 0;
2061                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2062                         }
2063                 }
2064         }
2065         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2066         {
2067                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2068                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2069                 else if (CS(this).motd_actived_time == -2)
2070                 {
2071                         // instantly hide MOTD
2072                         CS(this).motd_actived_time = 0;
2073                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2074                 }
2075                 else if (IS_PLAYER(this) || IS_SPEC(this))
2076                 {
2077                         // FIXME occasionally for some reason MOTD never goes away
2078                         // delay MOTD removal a little bit in the hope it fixes this bug
2079                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2080                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2081                         else //if (CS(this).motd_actived_time < -2)
2082                                 CS(this).motd_actived_time++;
2083                 }
2084         }
2085 }
2086
2087 bool joinAllowed(entity this)
2088 {
2089         if (CS(this).version_mismatch) return false;
2090         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2091         if (!nJoinAllowed(this, this)) return false;
2092         if (teamplay && lockteams) return false;
2093         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2094         if (ShowTeamSelection(this)) return false;
2095         return true;
2096 }
2097
2098 .string shootfromfixedorigin;
2099 .bool dualwielding_prev;
2100 bool PlayerThink(entity this)
2101 {
2102         if (game_stopped || intermission_running) {
2103                 this.modelflags &= ~MF_ROCKET;
2104                 if(intermission_running)
2105                         IntermissionThink(this);
2106                 return false;
2107         }
2108
2109         if (timeout_status == TIMEOUT_ACTIVE) {
2110                 // don't allow the player to turn around while game is paused
2111                 // FIXME turn this into CSQC stuff
2112                 this.v_angle = this.lastV_angle;
2113                 this.angles = this.lastV_angle;
2114                 this.fixangle = true;
2115         }
2116
2117         if (frametime) player_powerups(this);
2118
2119         if (IS_DEAD(this)) {
2120                 if (this.personal && g_race_qualifying) {
2121                         if (time > this.respawn_time) {
2122                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2123                                 respawn(this);
2124                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2125                         }
2126                 } else {
2127                         if (frametime) player_anim(this);
2128
2129                         if (this.respawn_flags & RESPAWN_DENY)
2130                         {
2131                                 STAT(RESPAWN_TIME, this) = 0;
2132                                 return false;
2133                         }
2134
2135                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2136
2137                         switch(this.deadflag)
2138                         {
2139                                 case DEAD_DYING:
2140                                 {
2141                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2142                                                 this.deadflag = DEAD_RESPAWNING;
2143                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2144                                                 this.deadflag = DEAD_DEAD;
2145                                         break;
2146                                 }
2147                                 case DEAD_DEAD:
2148                                 {
2149                                         if (button_pressed)
2150                                                 this.deadflag = DEAD_RESPAWNABLE;
2151                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2152                                                 this.deadflag = DEAD_RESPAWNING;
2153                                         break;
2154                                 }
2155                                 case DEAD_RESPAWNABLE:
2156                                 {
2157                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2158                                                 this.deadflag = DEAD_RESPAWNING;
2159                                         break;
2160                                 }
2161                                 case DEAD_RESPAWNING:
2162                                 {
2163                                         if (time > this.respawn_time)
2164                                         {
2165                                                 this.respawn_time = time + 1; // only retry once a second
2166                                                 this.respawn_time_max = this.respawn_time;
2167                                                 respawn(this);
2168                                         }
2169                                         break;
2170                                 }
2171                         }
2172
2173                         ShowRespawnCountdown(this);
2174
2175                         if (this.respawn_flags & RESPAWN_SILENT)
2176                                 STAT(RESPAWN_TIME, this) = 0;
2177                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2178                         {
2179                                 if (time < this.respawn_time)
2180                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2181                                 else if (this.deadflag != DEAD_RESPAWNING)
2182                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2183                         }
2184                         else
2185                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2186                 }
2187
2188                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2189                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2190                         STAT(RESPAWN_TIME, this) *= -1;
2191
2192                 return false;
2193         }
2194
2195         FixPlayermodel(this);
2196
2197         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2198                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2199                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2200         }
2201
2202         // reset gun alignment when dual wielding status changes
2203         // to ensure guns are always aligned right and left
2204         bool dualwielding = W_DualWielding(this);
2205         if(this.dualwielding_prev != dualwielding)
2206         {
2207                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2208                 this.dualwielding_prev = dualwielding;
2209         }
2210
2211         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2212         //if(frametime)
2213         {
2214                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2215                 {
2216                         .entity weaponentity = weaponentities[slot];
2217                         if(WEP_CVAR(vortex, charge_always))
2218                                 W_Vortex_Charge(this, weaponentity, frametime);
2219                         W_WeaponFrame(this, weaponentity);
2220                 }
2221         }
2222
2223         if (frametime)
2224         {
2225                 // WEAPONTODO: Add a weapon request for this
2226                 // rot vortex charge to the charge limit
2227                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2228                 {
2229                         .entity weaponentity = weaponentities[slot];
2230                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2231                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2232                 }
2233
2234                 player_regen(this);
2235                 player_anim(this);
2236                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2237         }
2238
2239         monsters_setstatus(this);
2240
2241         return true;
2242 }
2243
2244 .bool would_spectate;
2245 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2246 void ObserverOrSpectatorThink(entity this)
2247 {
2248         bool is_spec = IS_SPEC(this);
2249         if ( CS(this).impulse )
2250         {
2251                 int r = MinigameImpulse(this, CS(this).impulse);
2252                 if (!is_spec || r)
2253                         CS(this).impulse = 0;
2254
2255                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2256                 {
2257                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2258                         CS(this).impulse = 0;
2259                         return;
2260                 }
2261         }
2262
2263         if (this.flags & FL_JUMPRELEASED) {
2264                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2265                         this.flags &= ~FL_JUMPRELEASED;
2266                         this.flags |= FL_SPAWNING;
2267                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2268                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2269                         this.flags &= ~FL_JUMPRELEASED;
2270                         if(SpectateNext(this)) {
2271                                 TRANSMUTE(Spectator, this);
2272                         } else if (is_spec) {
2273                                 TRANSMUTE(Observer, this);
2274                                 PutClientInServer(this);
2275                         }
2276                         else
2277                                 this.would_spectate = false; // unable to spectate anyone
2278                         if (is_spec)
2279                                 CS(this).impulse = 0;
2280                 } else if (is_spec) {
2281                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2282                                 this.flags &= ~FL_JUMPRELEASED;
2283                                 if(SpectatePrev(this)) {
2284                                         TRANSMUTE(Spectator, this);
2285                                 } else {
2286                                         TRANSMUTE(Observer, this);
2287                                         PutClientInServer(this);
2288                                 }
2289                                 CS(this).impulse = 0;
2290                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2291                                 this.would_spectate = false;
2292                                 this.flags &= ~FL_JUMPRELEASED;
2293                                 TRANSMUTE(Observer, this);
2294                                 PutClientInServer(this);
2295                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2296                                 PutObserverInServer(this, false, true);
2297                                 this.would_spectate = true;
2298                         }
2299                 }
2300                 else {
2301                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2302                         if (PHYS_INPUT_BUTTON_USE(this))
2303                                 wouldclip = !wouldclip;
2304                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2305                         set_movetype(this, preferred_movetype);
2306                 }
2307         } else { // jump pressed
2308                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2309                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2310                         this.flags |= FL_JUMPRELEASED;
2311                         if(this.flags & FL_SPAWNING)
2312                         {
2313                                 this.flags &= ~FL_SPAWNING;
2314                                 if(joinAllowed(this))
2315                                         Join(this);
2316                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2317                                         CS(this).autojoin_checked = -1;
2318                                 return;
2319                         }
2320                 }
2321                 if(is_spec && !SpectateUpdate(this))
2322                         PutObserverInServer(this, false, true);
2323         }
2324         if (is_spec)
2325                 this.flags |= FL_CLIENT | FL_NOTARGET;
2326 }
2327
2328 void PlayerUseKey(entity this)
2329 {
2330         if (!IS_PLAYER(this))
2331                 return;
2332
2333         if(this.vehicle)
2334         {
2335                 if(!game_stopped)
2336                 {
2337                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2338                         return;
2339                 }
2340         }
2341         else if(autocvar_g_vehicles_enter)
2342         {
2343                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2344                 {
2345                         entity head, closest_target = NULL;
2346                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2347
2348                         while(head) // find the closest acceptable target to enter
2349                         {
2350                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2351                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2352                                 {
2353                                         if(closest_target)
2354                                         {
2355                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2356                                                 { closest_target = head; }
2357                                         }
2358                                         else { closest_target = head; }
2359                                 }
2360
2361                                 head = head.chain;
2362                         }
2363
2364                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2365                 }
2366         }
2367
2368         // a use key was pressed; call handlers
2369         MUTATOR_CALLHOOK(PlayerUseKey, this);
2370 }
2371
2372
2373 /*
2374 =============
2375 PlayerPreThink
2376
2377 Called every frame for each client before the physics are run
2378 =============
2379 */
2380 .float last_vehiclecheck;
2381 void PlayerPreThink (entity this)
2382 {
2383         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2384         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2385
2386         WarpZone_PlayerPhysics_FixVAngle(this);
2387
2388         if (frametime) {
2389                 // physics frames: update anticheat stuff
2390                 anticheat_prethink(this);
2391
2392                 // WORKAROUND: only use dropclient in server frames (frametime set).
2393                 // Never use it in cl_movement frames (frametime zero).
2394                 if (blockSpectators && IS_REAL_CLIENT(this)
2395                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2396                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2397                 {
2398                         if (dropclient_schedule(this))
2399                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2400                 }
2401         }
2402
2403         zoomstate_set = false;
2404
2405         // Check for nameless players
2406         if (this.netname == "" || this.netname != CS(this).netname_previous)
2407         {
2408                 bool assume_unchanged = (CS(this).netname_previous == "");
2409                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2410                 {
2411                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2412                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2413                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2414                         assume_unchanged = false;
2415                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2416                 }
2417                 if (isInvisibleString(this.netname))
2418                 {
2419                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2420                         sprint(this, "Warning: invisible names are not allowed.\n");
2421                         assume_unchanged = false;
2422                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2423                 }
2424                 if (!assume_unchanged && autocvar_sv_eventlog)
2425                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2426                 strcpy(CS(this).netname_previous, this.netname);
2427         }
2428
2429         // version nagging
2430         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2431         CS(this).version_nagtime = 0;
2432         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2433             // git client
2434         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2435             // git server
2436             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2437         } else {
2438             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2439             if (r < 0) { // old client
2440                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2441             } else if (r > 0) { // old server
2442                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2443             }
2444         }
2445     }
2446
2447         // GOD MODE info
2448         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2449         {
2450                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2451                 this.max_armorvalue = 0;
2452         }
2453
2454         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2455         {
2456                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2457                 {
2458                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2459                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2460                         if (this.iceblock)
2461                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2462
2463                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2464                                 Unfreeze(this, false);
2465                 }
2466                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2467                 {
2468                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2469                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2470
2471                         if (GetResource(this, RES_HEALTH) < 1)
2472                         {
2473                                 if (this.vehicle)
2474                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2475                                 if(this.event_damage)
2476                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2477                         }
2478                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2479                                 Unfreeze(this, false);
2480                 }
2481         }
2482
2483         MUTATOR_CALLHOOK(PlayerPreThink, this);
2484
2485         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2486         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2487         {
2488                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2489                 {
2490                         if(!it.owner)
2491                         {
2492                                 if(!it.team || SAME_TEAM(this, it))
2493                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2494                                 else if(autocvar_g_vehicles_steal)
2495                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2496                         }
2497                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2498                         {
2499                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2500                         }
2501                 });
2502
2503                 this.last_vehiclecheck = time + 1;
2504         }
2505
2506         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2507                 PlayerUseKey(this);
2508         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2509
2510         if (IS_REAL_CLIENT(this))
2511                 PrintWelcomeMessage(this);
2512
2513         if (IS_PLAYER(this)) {
2514                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2515                         error("Client can't be spawned as player on connection!");
2516                 if(!PlayerThink(this))
2517                         return;
2518         }
2519         else if (game_stopped || intermission_running) {
2520                 if(intermission_running)
2521                         IntermissionThink(this);
2522                 return;
2523         }
2524         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2525         {
2526                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2527                 CS(this).autojoin_checked = 1;
2528                 // don't do this in ClientConnect
2529                 // many things can go wrong if a client is spawned as player on connection
2530                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2531                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2532                                 && (!teamplay || autocvar_g_balance_teams)))
2533                 {
2534                         campaign_bots_may_start = true;
2535                         if(joinAllowed(this))
2536                                 Join(this);
2537                         return;
2538                 }
2539         }
2540         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2541                 ObserverOrSpectatorThink(this);
2542         }
2543
2544         // WEAPONTODO: Add weapon request for this
2545         if (!zoomstate_set) {
2546                 bool wep_zoomed = false;
2547                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2548                 {
2549                         .entity weaponentity = weaponentities[slot];
2550                         Weapon thiswep = this.(weaponentity).m_weapon;
2551                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2552                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2553                 }
2554                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2555         }
2556
2557         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2558         {
2559                 CS(this).teamkill_soundtime = 0;
2560
2561                 entity e = CS(this).teamkill_soundsource;
2562                 entity oldpusher = e.pusher;
2563                 e.pusher = this;
2564                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2565                 e.pusher = oldpusher;
2566         }
2567
2568         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2569                 CS(this).taunt_soundtime = 0;
2570                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2571         }
2572
2573         target_voicescript_next(this);
2574 }
2575
2576 void DrownPlayer(entity this)
2577 {
2578         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2579                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2580         {
2581                 STAT(AIR_FINISHED, this) = 0;
2582                 return;
2583         }
2584
2585         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2586         {
2587                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2588                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2589                 STAT(AIR_FINISHED, this) = 0;
2590         }
2591         else
2592         {
2593                 if (!STAT(AIR_FINISHED, this))
2594                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2595                 if (STAT(AIR_FINISHED, this) < time)
2596                 {       // drown!
2597                         if (this.pain_finished < time)
2598                         {
2599                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2600                                 this.pain_finished = time + 0.5;
2601                         }
2602                 }
2603         }
2604 }
2605
2606 .bool move_qcphysics;
2607
2608 void Player_Physics(entity this)
2609 {
2610         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2611
2612         if(!this.move_qcphysics)
2613                 return;
2614
2615         if(!frametime && !CS(this).pm_frametime)
2616                 return;
2617
2618         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2619
2620         CS(this).pm_frametime = 0;
2621 }
2622
2623 /*
2624 =============
2625 PlayerPostThink
2626
2627 Called every frame for each client after the physics are run
2628 =============
2629 */
2630 void PlayerPostThink (entity this)
2631 {
2632         Player_Physics(this);
2633
2634         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2635         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2636         if (IS_REAL_CLIENT(this))
2637         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2638         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2639         {
2640                 int totalClients = 0;
2641                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2642                 {
2643                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2644                         if (server_is_dedicated)
2645                         {
2646                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2647                                 {
2648                                         ++totalClients;
2649                                 });
2650                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2651                                         totalClients = 0;
2652                         }
2653                 }
2654                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2655                 {
2656                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2657                         {
2658                                 ++totalClients;
2659                         });
2660                 }
2661
2662                 if (totalClients < autocvar_sv_maxidle_minplayers)
2663                 {
2664                         // idle kick disabled
2665                         CS(this).parm_idlesince = time;
2666                 }
2667                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2668                 {
2669                         if (CS(this).idlekick_lasttimeleft)
2670                         {
2671                                 CS(this).idlekick_lasttimeleft = 0;
2672                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2673                         }
2674                 }
2675                 else
2676                 {
2677                         float maxidle_time = autocvar_sv_maxidle;
2678                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2679                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2680                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2681                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2682                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2683                         {
2684                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2685                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2686                                 else
2687                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2688                         }
2689                         if (timeleft <= 0) {
2690                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2691                                 {
2692                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2693                                         PutObserverInServer(this, true, true);
2694                                 }
2695                                 else
2696                                 {
2697                                         if (dropclient_schedule(this))
2698                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2699                                 }
2700                                 return;
2701                         }
2702                         else if (timeleft <= countdown_time) {
2703                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2704                                         play2(this, SND(TALK2));
2705                                 CS(this).idlekick_lasttimeleft = timeleft;
2706                         }
2707                 }
2708         }
2709
2710         CheatFrame(this);
2711
2712         if (game_stopped)
2713         {
2714                 this.solid = SOLID_NOT;
2715                 this.takedamage = DAMAGE_NO;
2716                 set_movetype(this, MOVETYPE_NONE);
2717                 CS(this).teamkill_complain = 0;
2718                 CS(this).teamkill_soundtime = 0;
2719                 CS(this).teamkill_soundsource = NULL;
2720         }
2721
2722         if (IS_PLAYER(this)) {
2723                 if(this.death_time == time && IS_DEAD(this))
2724                 {
2725                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2726                         // once all the damage events of this frame have been processed with normal size
2727                         this.maxs.z = 5;
2728                         setsize(this, this.mins, this.maxs);
2729                 }
2730                 DrownPlayer(this);
2731                 UpdateChatBubble(this);
2732                 if (CS(this).impulse) ImpulseCommands(this);
2733                 GetPressedKeys(this);
2734                 if (game_stopped)
2735                 {
2736                         CSQCMODEL_AUTOUPDATE(this);
2737                         return;
2738                 }
2739         }
2740         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2741         {
2742                 CS(this).pressedkeys = 0;
2743                 STAT(PRESSED_KEYS, this) = 0;
2744         }
2745
2746         if (this.waypointsprite_attachedforcarrier) {
2747                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2748                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2749         }
2750
2751         CSQCMODEL_AUTOUPDATE(this);
2752 }
2753
2754 // hack to copy the button fields from the client entity to the Client State
2755 void PM_UpdateButtons(entity this, entity store)
2756 {
2757         if(this.impulse)
2758                 store.impulse = this.impulse;
2759         this.impulse = 0;
2760
2761         bool typing = this.buttonchat || this.button12;
2762
2763         store.button0 = (typing) ? 0 : this.button0;
2764         //button1?!
2765         store.button2 = (typing) ? 0 : this.button2;
2766         store.button3 = (typing) ? 0 : this.button3;
2767         store.button4 = this.button4;
2768         store.button5 = (typing) ? 0 : this.button5;
2769         store.button6 = this.button6;
2770         store.button7 = this.button7;
2771         store.button8 = this.button8;
2772         store.button9 = this.button9;
2773         store.button10 = this.button10;
2774         store.button11 = this.button11;
2775         store.button12 = this.button12;
2776         store.button13 = this.button13;
2777         store.button14 = this.button14;
2778         store.button15 = this.button15;
2779         store.button16 = this.button16;
2780         store.buttonuse = this.buttonuse;
2781         store.buttonchat = this.buttonchat;
2782
2783         store.cursor_active = this.cursor_active;
2784         store.cursor_screen = this.cursor_screen;
2785         store.cursor_trace_start = this.cursor_trace_start;
2786         store.cursor_trace_endpos = this.cursor_trace_endpos;
2787         store.cursor_trace_ent = this.cursor_trace_ent;
2788
2789         store.ping = this.ping;
2790         store.ping_packetloss = this.ping_packetloss;
2791         store.ping_movementloss = this.ping_movementloss;
2792
2793         store.v_angle = this.v_angle;
2794         store.movement = this.movement;
2795 }
2796
2797 NET_HANDLE(fpsreport, bool)
2798 {
2799         int fps = ReadShort();
2800         PlayerScore_Set(sender, SP_FPS, fps);
2801         return true;
2802 }