0c6f66a2cc2cbc23347298bf54582a29d827ecdb
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include "anticheat.qh"
4 #include "impulse.qh"
5 #include "player.qh"
6 #include "ipban.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "playerdemo.qh"
11 #include "spawnpoints.qh"
12 #include "g_damage.qh"
13 #include "g_hook.qh"
14 #include "command/common.qh"
15 #include "cheats.qh"
16 #include "g_world.qh"
17 #include "race.qh"
18 #include "antilag.qh"
19 #include "campaign.qh"
20 #include "command/common.qh"
21 #include "scores_rules.qh"
22
23 #include "bot/api.qh"
24
25 #include "../common/ent_cs.qh"
26 #include <common/state.qh>
27
28 #include <common/effects/qc/globalsound.qh>
29
30 #include "../common/triggers/teleporters.qh"
31
32 #include "../common/vehicles/all.qh"
33
34 #include "weapons/hitplot.qh"
35 #include "weapons/weaponsystem.qh"
36
37 #include "../common/net_notice.qh"
38 #include "../common/physics/player.qh"
39
40 #include "../common/items/_mod.qh"
41
42 #include "../common/mutators/mutator/waypoints/all.qh"
43
44 #include "../common/triggers/subs.qh"
45 #include "../common/triggers/triggers.qh"
46 #include "../common/triggers/trigger/secret.qh"
47
48 #include "../common/minigames/sv_minigames.qh"
49
50 #include "../common/items/inventory.qh"
51
52 #include "../common/monsters/sv_monsters.qh"
53
54 #include "../lib/warpzone/server.qh"
55
56 STATIC_METHOD(Client, Add, void(Client this, int _team))
57 {
58     ClientConnect(this);
59     TRANSMUTE(Player, this);
60     this.frame = 12; // 7
61     this.team = _team;
62     PutClientInServer(this);
63 }
64
65 void PutObserverInServer(entity this);
66
67 STATIC_METHOD(Client, Remove, void(Client this))
68 {
69     TRANSMUTE(Observer, this);
70     PutClientInServer(this);
71     ClientDisconnect(this);
72 }
73
74 void send_CSQC_teamnagger() {
75         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
76 }
77
78 int CountSpectators(entity player, entity to)
79 {
80         if(!player) { return 0; } // not sure how, but best to be safe
81
82         int spec_count = 0;
83
84         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
85         {
86                 spec_count++;
87         });
88
89         return spec_count;
90 }
91
92 void WriteSpectators(entity player, entity to)
93 {
94         if(!player) { return; } // not sure how, but best to be safe
95
96         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
97         {
98                 WriteByte(MSG_ENTITY, num_for_edict(it));
99         });
100 }
101
102 bool ClientData_Send(entity this, entity to, int sf)
103 {
104         assert(to == this.owner, return false);
105
106         entity e = to;
107         if (IS_SPEC(e)) e = e.enemy;
108
109         sf = 0;
110         if (e.race_completed)       sf |= 1; // forced scoreboard
111         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
112         if (e.zoomstate)            sf |= 4; // zoomed
113         if (e.porto_v_angle_held)   sf |= 8; // angles held
114         if (autocvar_sv_showspectators) sf |= 16; // show spectators
115
116         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
117         WriteByte(MSG_ENTITY, sf);
118
119         if (sf & 2)
120         {
121                 WriteByte(MSG_ENTITY, to.spectatee_status);
122         }
123         if (sf & 8)
124         {
125                 WriteAngle(MSG_ENTITY, e.v_angle.x);
126                 WriteAngle(MSG_ENTITY, e.v_angle.y);
127         }
128
129         if(sf & 16)
130         {
131                 float specs = CountSpectators(e, to);
132                 WriteByte(MSG_ENTITY, specs);
133                 WriteSpectators(e, to);
134         }
135
136         return true;
137 }
138
139 void ClientData_Attach(entity this)
140 {
141         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
142         this.clientdata.drawonlytoclient = this;
143         this.clientdata.owner = this;
144 }
145
146 void ClientData_Detach(entity this)
147 {
148         delete(this.clientdata);
149         this.clientdata = NULL;
150 }
151
152 void ClientData_Touch(entity e)
153 {
154         e.clientdata.SendFlags = 1;
155
156         // make it spectatable
157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
158 }
159
160 .string netname_previous;
161
162 void SetSpectatee(entity player, entity spectatee);
163
164
165 /*
166 =============
167 CheckPlayerModel
168
169 Checks if the argument string can be a valid playermodel.
170 Returns a valid one in doubt.
171 =============
172 */
173 string FallbackPlayerModel;
174 string CheckPlayerModel(string plyermodel) {
175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
176         {
177                 // note: we cannot summon Don Strunzone here, some player may
178                 // still have the model string set. In case anyone manages how
179                 // to change a cvar default, we'll have a small leak here.
180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
181         }
182         // only in right path
183         if( substring(plyermodel,0,14) != "models/player/")
184                 return FallbackPlayerModel;
185         // only good file extensions
186         if(substring(plyermodel,-4,4) != ".zym")
187         if(substring(plyermodel,-4,4) != ".dpm")
188         if(substring(plyermodel,-4,4) != ".iqm")
189         if(substring(plyermodel,-4,4) != ".md3")
190         if(substring(plyermodel,-4,4) != ".psk")
191                 return FallbackPlayerModel;
192         // forbid the LOD models
193         if(substring(plyermodel, -9,5) == "_lod1")
194                 return FallbackPlayerModel;
195         if(substring(plyermodel, -9,5) == "_lod2")
196                 return FallbackPlayerModel;
197         if(plyermodel != strtolower(plyermodel))
198                 return FallbackPlayerModel;
199         // also, restrict to server models
200         if(autocvar_sv_servermodelsonly)
201         {
202                 if(!fexists(plyermodel))
203                         return FallbackPlayerModel;
204         }
205         return plyermodel;
206 }
207
208 void setplayermodel(entity e, string modelname)
209 {
210         precache_model(modelname);
211         _setmodel(e, modelname);
212         player_setupanimsformodel(e);
213         if(!autocvar_g_debug_globalsounds)
214                 UpdatePlayerSounds(e);
215 }
216
217 void FixPlayermodel(entity player);
218 /** putting a client as observer in the server */
219 void PutObserverInServer(entity this)
220 {
221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
222         PlayerState_detach(this);
223
224         if (IS_PLAYER(this) && this.health >= 1) {
225         // despawn effect
226                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
227     }
228
229     {
230         entity spot = SelectSpawnPoint(this, true);
231         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
232         this.angles = spot.angles;
233         this.angles_z = 0;
234         this.fixangle = true;
235         // offset it so that the spectator spawns higher off the ground, looks better this way
236         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
237         this.prevorigin = this.origin;
238         if (IS_REAL_CLIENT(this))
239         {
240             msg_entity = this;
241             WriteByte(MSG_ONE, SVC_SETVIEW);
242             WriteEntity(MSG_ONE, this);
243         }
244         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
245         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
246         if(!autocvar_g_debug_globalsounds)
247         {
248                 // needed for player sounds
249                 this.model = "";
250                 FixPlayermodel(this);
251         }
252         setmodel(this, MDL_Null);
253         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
254         this.view_ofs = '0 0 0';
255     }
256
257     RemoveGrapplingHook(this);
258         Portal_ClearAll(this);
259         Unfreeze(this);
260         SetSpectatee(this, NULL);
261
262         if (this.alivetime)
263         {
264                 if (!warmup_stage)
265                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
266                 this.alivetime = 0;
267         }
268
269         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
270
271         WaypointSprite_PlayerDead(this);
272
273         if (mutator_returnvalue) {
274             // mutator prevents resetting teams+score
275         } else {
276                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
277         this.frags = FRAGS_SPECTATOR;
278         PlayerScore_Clear(this);  // clear scores when needed
279     }
280
281         if (this.killcount != FRAGS_SPECTATOR)
282         {
283                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
284                 if(!intermission_running)
285                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
286                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
287
288                 if(this.just_joined == false) {
289                         LogTeamchange(this.playerid, -1, 4);
290                 } else
291                         this.just_joined = false;
292         }
293
294         accuracy_resend(this);
295
296         this.spectatortime = time;
297         this.bot_attack = false;
298     this.hud = HUD_NORMAL;
299         TRANSMUTE(Observer, this);
300         this.iscreature = false;
301         this.teleportable = TELEPORT_SIMPLE;
302         this.damagedbycontents = false;
303         this.health = FRAGS_SPECTATOR;
304         this.takedamage = DAMAGE_NO;
305         this.solid = SOLID_NOT;
306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
307         this.flags = FL_CLIENT | FL_NOTARGET;
308         this.armorvalue = 666;
309         this.effects = 0;
310         this.armorvalue = autocvar_g_balance_armor_start;
311         this.pauserotarmor_finished = 0;
312         this.pauserothealth_finished = 0;
313         this.pauseregen_finished = 0;
314         this.damageforcescale = 0;
315         this.death_time = 0;
316         this.respawn_flags = 0;
317         this.respawn_time = 0;
318         this.stat_respawn_time = 0;
319         this.alpha = 0;
320         this.scale = 0;
321         this.fade_time = 0;
322         this.pain_frame = 0;
323         this.pain_finished = 0;
324         this.strength_finished = 0;
325         this.invincible_finished = 0;
326         this.superweapons_finished = 0;
327         this.pushltime = 0;
328         this.istypefrag = 0;
329         setthink(this, func_null);
330         this.nextthink = 0;
331         this.hook_time = 0;
332         this.deadflag = DEAD_NO;
333         this.crouch = false;
334         this.revival_time = 0;
335
336         this.items = 0;
337         this.weapons = '0 0 0';
338         this.drawonlytoclient = this;
339
340         this.weaponname = "";
341         this.weaponmodel = "";
342         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
343         {
344                 this.weaponentities[slot] = NULL;
345         }
346         this.exteriorweaponentity = NULL;
347         this.killcount = FRAGS_SPECTATOR;
348         this.velocity = '0 0 0';
349         this.avelocity = '0 0 0';
350         this.punchangle = '0 0 0';
351         this.punchvector = '0 0 0';
352         this.oldvelocity = this.velocity;
353         this.fire_endtime = -1;
354         this.event_damage = func_null;
355
356         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
357         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
358         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
359 }
360
361 int player_getspecies(entity this)
362 {
363         get_model_parameters(this.model, this.skin);
364         int s = get_model_parameters_species;
365         get_model_parameters(string_null, 0);
366         if (s < 0) return SPECIES_HUMAN;
367         return s;
368 }
369
370 .float model_randomizer;
371 void FixPlayermodel(entity player)
372 {
373         string defaultmodel = "";
374         int defaultskin = 0;
375         if(autocvar_sv_defaultcharacter)
376         {
377                 if(teamplay)
378                 {
379                         string s = Static_Team_ColorName_Lower(player.team);
380                         if (s != "neutral")
381                         {
382                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
383                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
384                         }
385                 }
386
387                 if(defaultmodel == "")
388                 {
389                         defaultmodel = autocvar_sv_defaultplayermodel;
390                         defaultskin = autocvar_sv_defaultplayerskin;
391                 }
392
393                 int n = tokenize_console(defaultmodel);
394                 if(n > 0)
395                 {
396                         defaultmodel = argv(floor(n * player.model_randomizer));
397                         // However, do NOT randomize if the player-selected model is in the list.
398                         for (int i = 0; i < n; ++i)
399                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
400                                         defaultmodel = argv(i);
401                 }
402
403                 int i = strstrofs(defaultmodel, ":", 0);
404                 if(i >= 0)
405                 {
406                         defaultskin = stof(substring(defaultmodel, i+1, -1));
407                         defaultmodel = substring(defaultmodel, 0, i);
408                 }
409         }
410         if(autocvar_sv_defaultcharacterskin && !defaultskin)
411         {
412                 if(teamplay)
413                 {
414                         string s = Static_Team_ColorName_Lower(player.team);
415                         if (s != "neutral")
416                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
417                 }
418
419                 if(!defaultskin)
420                         defaultskin = autocvar_sv_defaultplayerskin;
421         }
422
423         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
424         defaultmodel = M_ARGV(0, string);
425         defaultskin = M_ARGV(1, int);
426
427         bool chmdl = false;
428         int oldskin;
429         if(defaultmodel != "")
430         {
431                 if (defaultmodel != player.model)
432                 {
433                         vector m1 = player.mins;
434                         vector m2 = player.maxs;
435                         setplayermodel (player, defaultmodel);
436                         setsize (player, m1, m2);
437                         chmdl = true;
438                 }
439
440                 oldskin = player.skin;
441                 player.skin = defaultskin;
442         } else {
443                 if (player.playermodel != player.model || player.playermodel == "")
444                 {
445                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
446                         vector m1 = player.mins;
447                         vector m2 = player.maxs;
448                         setplayermodel (player, player.playermodel);
449                         setsize (player, m1, m2);
450                         chmdl = true;
451                 }
452
453                 if(!autocvar_sv_defaultcharacterskin)
454                 {
455                         oldskin = player.skin;
456                         player.skin = stof(player.playerskin);
457                 }
458                 else
459                 {
460                         oldskin = player.skin;
461                         player.skin = defaultskin;
462                 }
463         }
464
465         if(chmdl || oldskin != player.skin) // model or skin has changed
466         {
467                 player.species = player_getspecies(player); // update species
468                 if(!autocvar_g_debug_globalsounds)
469                         UpdatePlayerSounds(player); // update skin sounds
470         }
471
472         if(!teamplay)
473                 if(strlen(autocvar_sv_defaultplayercolors))
474                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
475                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
476 }
477
478
479 /** Called when a client spawns in the server */
480 void PutClientInServer(entity this)
481 {
482         if (IS_BOT_CLIENT(this)) {
483                 TRANSMUTE(Player, this);
484         } else if (IS_REAL_CLIENT(this)) {
485                 msg_entity = this;
486                 WriteByte(MSG_ONE, SVC_SETVIEW);
487                 WriteEntity(MSG_ONE, this);
488         }
489         if (gameover) {
490                 TRANSMUTE(Observer, this);
491         }
492
493         SetSpectatee(this, NULL);
494
495         // reset player keys
496         this.itemkeys = 0;
497
498         MUTATOR_CALLHOOK(PutClientInServer, this);
499
500         if (IS_OBSERVER(this)) {
501                 PutObserverInServer(this);
502         } else if (IS_PLAYER(this)) {
503                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
504
505                 PlayerState_attach(this);
506                 accuracy_resend(this);
507
508                 if (this.team < 0)
509                         JoinBestTeam(this, false, true);
510
511                 entity spot = SelectSpawnPoint(this, false);
512                 if (!spot) {
513                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
514                         return; // spawn failed
515                 }
516
517                 TRANSMUTE(Player, this);
518                 this.wasplayer = true;
519                 this.iscreature = true;
520                 this.teleportable = TELEPORT_NORMAL;
521                 this.damagedbycontents = true;
522                 set_movetype(this, MOVETYPE_WALK);
523                 this.solid = SOLID_SLIDEBOX;
524                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
525                 if (autocvar_g_playerclip_collisions)
526                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
527                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
528                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
529                 this.frags = FRAGS_PLAYER;
530                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
531                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
532                 if (autocvar__notarget)
533                         this.flags |= FL_NOTARGET;
534                 this.takedamage = DAMAGE_AIM;
535                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
536                 this.dmg = 2; // WTF
537
538                 if (warmup_stage) {
539                         this.ammo_shells = warmup_start_ammo_shells;
540                         this.ammo_nails = warmup_start_ammo_nails;
541                         this.ammo_rockets = warmup_start_ammo_rockets;
542                         this.ammo_cells = warmup_start_ammo_cells;
543                         this.ammo_plasma = warmup_start_ammo_plasma;
544                         this.ammo_fuel = warmup_start_ammo_fuel;
545                         this.health = warmup_start_health;
546                         this.armorvalue = warmup_start_armorvalue;
547                         this.weapons = WARMUP_START_WEAPONS;
548                 } else {
549                         this.ammo_shells = start_ammo_shells;
550                         this.ammo_nails = start_ammo_nails;
551                         this.ammo_rockets = start_ammo_rockets;
552                         this.ammo_cells = start_ammo_cells;
553                         this.ammo_plasma = start_ammo_plasma;
554                         this.ammo_fuel = start_ammo_fuel;
555                         this.health = start_health;
556                         this.armorvalue = start_armorvalue;
557                         this.weapons = start_weapons;
558                 }
559
560                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
561
562                 this.items = start_items;
563
564                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
565                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
566                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
567                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
568                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
569                 // extend the pause of rotting if client was reset at the beginning of the countdown
570                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
571                         float f = game_starttime - time;
572                         this.spawnshieldtime += f;
573                         this.pauserotarmor_finished += f;
574                         this.pauserothealth_finished += f;
575                         this.pauseregen_finished += f;
576                 }
577                 this.damageforcescale = 2;
578                 this.death_time = 0;
579                 this.respawn_flags = 0;
580                 this.respawn_time = 0;
581                 this.stat_respawn_time = 0;
582                 this.scale = autocvar_sv_player_scale;
583                 this.fade_time = 0;
584                 this.pain_frame = 0;
585                 this.pain_finished = 0;
586                 this.pushltime = 0;
587                 setthink(this, func_null); // players have no think function
588                 this.nextthink = 0;
589                 this.dmg_team = 0;
590                 this.ballistics_density = autocvar_g_ballistics_density_player;
591
592                 this.deadflag = DEAD_NO;
593
594                 this.angles = spot.angles;
595                 this.angles_z = 0; // never spawn tilted even if the spot says to
596                 if (IS_BOT_CLIENT(this))
597                         this.v_angle = this.angles;
598                 this.fixangle = true; // turn this way immediately
599                 this.oldvelocity = this.velocity = '0 0 0';
600                 this.avelocity = '0 0 0';
601                 this.punchangle = '0 0 0';
602                 this.punchvector = '0 0 0';
603
604                 this.strength_finished = 0;
605                 this.invincible_finished = 0;
606                 this.fire_endtime = -1;
607                 this.revival_time = 0;
608                 this.air_finished = time + 12;
609
610                 entity spawnevent = new_pure(spawnevent);
611                 spawnevent.owner = this;
612                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
613
614                 // Cut off any still running player sounds.
615                 stopsound(this, CH_PLAYER_SINGLE);
616
617                 this.model = "";
618                 FixPlayermodel(this);
619                 this.drawonlytoclient = NULL;
620
621                 this.crouch = false;
622                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
623                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
624                 this.spawnorigin = spot.origin;
625                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
626                 // don't reset back to last position, even if new position is stuck in solid
627                 this.oldorigin = this.origin;
628                 this.prevorigin = this.origin;
629                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
630                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
631                 this.hud = HUD_NORMAL;
632
633                 this.event_damage = PlayerDamage;
634
635                 this.bot_attack = true;
636                 this.monster_attack = true;
637
638                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
639
640                 if (this.killcount == FRAGS_SPECTATOR) {
641                         PlayerScore_Clear(this);
642                         this.killcount = 0;
643                 }
644
645                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
646                 {
647                         CL_SpawnWeaponentity(this, weaponentities[slot]);
648                 }
649                 this.alpha = default_player_alpha;
650                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
651                 this.exteriorweaponentity.alpha = default_weapon_alpha;
652
653                 this.speedrunning = false;
654
655                 target_voicescript_clear(this);
656
657                 // reset fields the weapons may use
658                 FOREACH(Weapons, true, LAMBDA(
659                         it.wr_resetplayer(it, this);
660                         // reload all reloadable weapons
661                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
662                                 this.weapon_load[it.m_id] = it.reloading_ammo;
663                         }
664                 ));
665
666                 {
667                         string s = spot.target;
668                         spot.target = string_null;
669                         SUB_UseTargets(spot, this, NULL);
670                         spot.target = s;
671                 }
672
673                 Unfreeze(this);
674
675                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
676
677                 if (autocvar_spawn_debug)
678                 {
679                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
680                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
681                 }
682
683                 PS(this).m_switchweapon = w_getbestweapon(this);
684                 this.cnt = -1; // W_LastWeapon will not complain
685                 PS(this).m_weapon = WEP_Null;
686                 this.weaponname = "";
687                 PS(this).m_switchingweapon = WEP_Null;
688
689                 if (!warmup_stage && !this.alivetime)
690                         this.alivetime = time;
691
692                 antilag_clear(this, CS(this));
693         }
694 }
695
696 void ClientInit_misc(entity this);
697
698 .float ebouncefactor, ebouncestop; // electro's values
699 // TODO do we need all these fields, or should we stop autodetecting runtime
700 // changes and just have a console command to update this?
701 bool ClientInit_SendEntity(entity this, entity to, int sf)
702 {
703         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
704         return = true;
705         msg_entity = to;
706         // MSG_INIT replacement
707         // TODO: make easier to use
708         Registry_send_all();
709         W_PROP_reload(MSG_ONE, to);
710         ClientInit_misc(this);
711         MUTATOR_CALLHOOK(Ent_Init);
712 }
713 void ClientInit_misc(entity this)
714 {
715         int channel = MSG_ONE;
716         WriteHeader(channel, ENT_CLIENT_INIT);
717         WriteByte(channel, g_nexball_meter_period * 32);
718         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
719         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
720         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
721         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
722         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
723         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
724         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
725         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
726
727         if(sv_foginterval && world.fog != "")
728                 WriteString(channel, world.fog);
729         else
730                 WriteString(channel, "");
731         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
732         WriteByte(channel, serverflags); // client has to know if it should zoom or not
733         WriteCoord(channel, autocvar_g_trueaim_minrange);
734 }
735
736 void ClientInit_CheckUpdate(entity this)
737 {
738         this.nextthink = time;
739         if(this.count != autocvar_g_balance_armor_blockpercent)
740         {
741                 this.count = autocvar_g_balance_armor_blockpercent;
742                 this.SendFlags |= 1;
743         }
744 }
745
746 void ClientInit_Spawn()
747 {
748         entity e = new_pure(clientinit);
749         setthink(e, ClientInit_CheckUpdate);
750         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
751
752         ClientInit_CheckUpdate(e);
753 }
754
755 /*
756 =============
757 SetNewParms
758 =============
759 */
760 void SetNewParms ()
761 {
762         // initialize parms for a new player
763         parm1 = -(86400 * 366);
764
765         MUTATOR_CALLHOOK(SetNewParms);
766 }
767
768 /*
769 =============
770 SetChangeParms
771 =============
772 */
773 void SetChangeParms (entity this)
774 {
775         // save parms for level change
776         parm1 = this.parm_idlesince - time;
777
778         MUTATOR_CALLHOOK(SetChangeParms);
779 }
780
781 /*
782 =============
783 DecodeLevelParms
784 =============
785 */
786 void DecodeLevelParms(entity this)
787 {
788         // load parms
789         this.parm_idlesince = parm1;
790         if (this.parm_idlesince == -(86400 * 366))
791                 this.parm_idlesince = time;
792
793         // whatever happens, allow 60 seconds of idling directly after connect for map loading
794         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
795
796         MUTATOR_CALLHOOK(DecodeLevelParms);
797 }
798
799 /*
800 =============
801 ClientKill
802
803 Called when a client types 'kill' in the console
804 =============
805 */
806
807 .float clientkill_nexttime;
808 void ClientKill_Now_TeamChange(entity this)
809 {
810         if(this.killindicator_teamchange == -1)
811         {
812                 JoinBestTeam( this, false, true );
813         }
814         else if(this.killindicator_teamchange == -2)
815         {
816                 if(blockSpectators)
817                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
818                 PutObserverInServer(this);
819         }
820         else
821                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
822         this.killindicator_teamchange = 0;
823 }
824
825 void ClientKill_Now(entity this)
826 {
827         if(this.vehicle)
828         {
829             vehicles_exit(this.vehicle, VHEF_RELEASE);
830             if(!this.killindicator_teamchange)
831             {
832             this.vehicle_health = -1;
833             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
834             }
835         }
836
837         if(this.killindicator && !wasfreed(this.killindicator))
838                 delete(this.killindicator);
839
840         this.killindicator = NULL;
841
842         if(this.killindicator_teamchange)
843                 ClientKill_Now_TeamChange(this);
844
845         if(!IS_SPEC(this) && !IS_OBSERVER(this))
846                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
847
848         // now I am sure the player IS dead
849 }
850 void KillIndicator_Think(entity this)
851 {
852         if (gameover)
853         {
854                 this.owner.killindicator = NULL;
855                 delete(this);
856                 return;
857         }
858
859         if (this.owner.alpha < 0 && !this.owner.vehicle)
860         {
861                 this.owner.killindicator = NULL;
862                 delete(this);
863                 return;
864         }
865
866         if(this.cnt <= 0)
867         {
868                 ClientKill_Now(this.owner);
869                 return;
870         }
871     else if(g_cts && this.health == 1) // health == 1 means that it's silent
872     {
873         this.nextthink = time + 1;
874         this.cnt -= 1;
875     }
876         else
877         {
878                 if(this.cnt <= 10)
879                         setmodel(this, MDL_NUM(this.cnt));
880                 if(IS_REAL_CLIENT(this.owner))
881                 {
882                         if(this.cnt <= 10)
883                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
884                 }
885                 this.nextthink = time + 1;
886                 this.cnt -= 1;
887         }
888 }
889
890 float clientkilltime;
891 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
892 {
893         float killtime;
894         float starttime;
895
896         if (gameover)
897                 return;
898
899         killtime = autocvar_g_balance_kill_delay;
900
901         if(g_race_qualifying || g_cts)
902                 killtime = 0;
903
904     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
905         return;
906
907         this.killindicator_teamchange = targetteam;
908
909     if(!this.killindicator)
910         {
911                 if(!IS_DEAD(this))
912                 {
913                         killtime = max(killtime, this.clientkill_nexttime - time);
914                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
915                 }
916
917                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
918                 {
919                         ClientKill_Now(this);
920                 }
921                 else
922                 {
923                         starttime = max(time, clientkilltime);
924
925                         this.killindicator = spawn();
926                         this.killindicator.owner = this;
927                         this.killindicator.scale = 0.5;
928                         setattachment(this.killindicator, this, "");
929                         setorigin(this.killindicator, '0 0 52');
930                         setthink(this.killindicator, KillIndicator_Think);
931                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
932                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
933                         this.killindicator.cnt = ceil(killtime);
934                         this.killindicator.count = bound(0, ceil(killtime), 10);
935                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
936
937                         FOREACH_ENTITY_ENT(enemy, this,
938                         {
939                                 if(it.classname != "body")
940                                         continue;
941                                 it.killindicator = spawn();
942                                 it.killindicator.owner = it;
943                                 it.killindicator.scale = 0.5;
944                                 setattachment(it.killindicator, it, "");
945                                 setorigin(it.killindicator, '0 0 52');
946                                 setthink(it.killindicator, KillIndicator_Think);
947                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
948                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
949                                 it.killindicator.cnt = ceil(killtime);
950                         });
951                         this.lip = 0;
952                 }
953         }
954         if(this.killindicator)
955         {
956                 if(targetteam == 0) // just die
957                 {
958                         this.killindicator.colormod = '0 0 0';
959                         if(IS_REAL_CLIENT(this))
960                         if(this.killindicator.cnt > 0)
961                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
962                 }
963                 else if(targetteam == -1) // auto
964                 {
965                         this.killindicator.colormod = '0 1 0';
966                         if(IS_REAL_CLIENT(this))
967                         if(this.killindicator.cnt > 0)
968                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
969                 }
970                 else if(targetteam == -2) // spectate
971                 {
972                         this.killindicator.colormod = '0.5 0.5 0.5';
973                         if(IS_REAL_CLIENT(this))
974                         if(this.killindicator.cnt > 0)
975                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
976                 }
977                 else
978                 {
979                         this.killindicator.colormod = Team_ColorRGB(targetteam);
980                         if(IS_REAL_CLIENT(this))
981                         if(this.killindicator.cnt > 0)
982                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
983                 }
984         }
985
986 }
987
988 void ClientKill (entity this)
989 {
990         if(gameover) return;
991         if(this.player_blocked) return;
992         if(STAT(FROZEN, this)) return;
993
994         ClientKill_TeamChange(this, 0);
995 }
996
997 void FixClientCvars(entity e)
998 {
999         // send prediction settings to the client
1000         stuffcmd(e, "\nin_bindmap 0 0\n");
1001         if(autocvar_g_antilag == 3) // client side hitscan
1002                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1003         if(autocvar_sv_gentle)
1004                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1005
1006         MUTATOR_CALLHOOK(FixClientCvars, e);
1007 }
1008
1009 float PlayerInIDList(entity p, string idlist)
1010 {
1011         float n, i;
1012         string s;
1013
1014         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1015         if (!p.crypto_idfp)
1016                 return 0;
1017
1018         // this function allows abbreviated player IDs too!
1019         n = tokenize_console(idlist);
1020         for(i = 0; i < n; ++i)
1021         {
1022                 s = argv(i);
1023                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1024                         return 1;
1025         }
1026
1027         return 0;
1028 }
1029
1030 #ifdef DP_EXT_PRECONNECT
1031 /*
1032 =============
1033 ClientPreConnect
1034
1035 Called once (not at each match start) when a client begins a connection to the server
1036 =============
1037 */
1038 void ClientPreConnect ()
1039 {ENGINE_EVENT();
1040         if(autocvar_sv_eventlog)
1041         {
1042                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1043                         this.playerid,
1044                         etof(this),
1045                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1046                 ));
1047         }
1048 }
1049 #endif
1050
1051 /**
1052 =============
1053 ClientConnect
1054
1055 Called when a client connects to the server
1056 =============
1057 */
1058 void ClientConnect(entity this)
1059 {
1060         if (Ban_MaybeEnforceBanOnce(this)) return;
1061         assert(!IS_CLIENT(this), return);
1062         this.flags |= FL_CLIENT;
1063         assert(player_count >= 0, player_count = 0);
1064
1065 #ifdef WATERMARK
1066         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1067 #endif
1068         this.version_nagtime = time + 10 + random() * 10;
1069         TRANSMUTE(Client, this);
1070
1071         // identify the right forced team
1072         if (autocvar_g_campaign)
1073         {
1074                 if (IS_REAL_CLIENT(this)) // only players, not bots
1075                 {
1076                         switch (autocvar_g_campaign_forceteam)
1077                         {
1078                                 case 1: this.team_forced = NUM_TEAM_1; break;
1079                                 case 2: this.team_forced = NUM_TEAM_2; break;
1080                                 case 3: this.team_forced = NUM_TEAM_3; break;
1081                                 case 4: this.team_forced = NUM_TEAM_4; break;
1082                                 default: this.team_forced = 0;
1083                         }
1084                 }
1085         }
1086         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1087         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1088         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1089         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1090         else switch (autocvar_g_forced_team_otherwise)
1091         {
1092                 default: this.team_forced = 0; break;
1093                 case "red": this.team_forced = NUM_TEAM_1; break;
1094                 case "blue": this.team_forced = NUM_TEAM_2; break;
1095                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1096                 case "pink": this.team_forced = NUM_TEAM_4; break;
1097                 case "spectate":
1098                 case "spectator":
1099                         this.team_forced = -1;
1100                         break;
1101         }
1102         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1103
1104     {
1105         int id = this.playerid;
1106         this.playerid = 0; // silent
1107             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1108             this.playerid = id;
1109     }
1110
1111         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1112                 TRANSMUTE(Observer, this);
1113         } else {
1114                 if (!teamplay || autocvar_g_balance_teams) {
1115                         TRANSMUTE(Player, this);
1116                         campaign_bots_may_start = true;
1117                 } else {
1118                         TRANSMUTE(Observer, this); // do it anyway
1119                 }
1120         }
1121
1122         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1123
1124         // always track bots, don't ask for cl_allow_uidtracking
1125     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1126
1127         if (autocvar_sv_eventlog)
1128                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1129
1130         LogTeamchange(this.playerid, this.team, 1);
1131
1132         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1133
1134         this.netname_previous = strzone(this.netname);
1135
1136         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1137
1138         stuffcmd(this, clientstuff, "\n");
1139         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1140
1141         FixClientCvars(this);
1142
1143         // get version info from player
1144         stuffcmd(this, "cmd clientversion $gameversion\n");
1145
1146         // notify about available teams
1147         if (teamplay)
1148         {
1149                 CheckAllowedTeams(this);
1150                 int t = 0;
1151                 if (c1 >= 0) t |= BIT(0);
1152                 if (c2 >= 0) t |= BIT(1);
1153                 if (c3 >= 0) t |= BIT(2);
1154                 if (c4 >= 0) t |= BIT(3);
1155                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1156         }
1157         else
1158         {
1159                 stuffcmd(this, "set _teams_available 0\n");
1160         }
1161
1162         bot_relinkplayerlist();
1163
1164         this.spectatortime = time;
1165         if (blockSpectators)
1166         {
1167                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1168         }
1169
1170         this.jointime = time;
1171         this.allowed_timeouts = autocvar_sv_timeout_number;
1172
1173         if (IS_REAL_CLIENT(this))
1174         {
1175                 if (!autocvar_g_campaign)
1176                 {
1177                         this.motd_actived_time = -1;
1178                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1179                 }
1180
1181                 if (g_weaponarena_weapons == WEPSET(TUBA))
1182                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1183         }
1184
1185         if (!sv_foginterval && world.fog != "")
1186                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1187
1188         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1189                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1190                         send_CSQC_teamnagger();
1191
1192         CSQCMODEL_AUTOINIT(this);
1193
1194         this.model_randomizer = random();
1195
1196         if (IS_REAL_CLIENT(this))
1197                 sv_notice_join(this);
1198
1199         FOREACH_ENTITY_FLOAT(init_for_player_needed, true, {
1200                 it.init_for_player(it, this);
1201         });
1202
1203         MUTATOR_CALLHOOK(ClientConnect, this);
1204 }
1205 /*
1206 =============
1207 ClientDisconnect
1208
1209 Called when a client disconnects from the server
1210 =============
1211 */
1212 .entity chatbubbleentity;
1213 void ReadyCount();
1214 void ClientDisconnect(entity this)
1215 {
1216         assert(IS_CLIENT(this), return);
1217
1218         PlayerStats_GameReport_FinalizePlayer(this);
1219         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1220         if (this.active_minigame) part_minigame(this);
1221         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1222
1223         if (autocvar_sv_eventlog)
1224                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1225
1226         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1227
1228         SetSpectatee(this, NULL);
1229
1230     MUTATOR_CALLHOOK(ClientDisconnect, this);
1231
1232         ClientState_detach(this);
1233
1234         Portal_ClearAll(this);
1235
1236         Unfreeze(this);
1237
1238         RemoveGrapplingHook(this);
1239
1240         // Here, everything has been done that requires this player to be a client.
1241
1242         this.flags &= ~FL_CLIENT;
1243
1244         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1245         if (this.killindicator) delete(this.killindicator);
1246
1247         WaypointSprite_PlayerGone(this);
1248
1249         bot_relinkplayerlist();
1250
1251         if (this.netname_previous) strunzone(this.netname_previous);
1252         if (this.clientstatus) strunzone(this.clientstatus);
1253         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1254         if (this.personal) delete(this.personal);
1255
1256         this.playerid = 0;
1257         ReadyCount();
1258         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1259 }
1260
1261 void ChatBubbleThink(entity this)
1262 {
1263         this.nextthink = time;
1264         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1265         {
1266                 if(this.owner) // but why can that ever be NULL?
1267                         this.owner.chatbubbleentity = NULL;
1268                 delete(this);
1269                 return;
1270         }
1271
1272         this.mdl = "";
1273
1274         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1275         {
1276                 if ( this.owner.active_minigame )
1277                         this.mdl = "models/sprites/minigame_busy.iqm";
1278                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1279                         this.mdl = "models/misc/chatbubble.spr";
1280         }
1281
1282         if ( this.model != this.mdl )
1283                 _setmodel(this, this.mdl);
1284
1285 }
1286
1287 void UpdateChatBubble(entity this)
1288 {
1289         if (this.alpha < 0)
1290                 return;
1291         // spawn a chatbubble entity if needed
1292         if (!this.chatbubbleentity)
1293         {
1294                 this.chatbubbleentity = new(chatbubbleentity);
1295                 this.chatbubbleentity.owner = this;
1296                 this.chatbubbleentity.exteriormodeltoclient = this;
1297                 setthink(this.chatbubbleentity, ChatBubbleThink);
1298                 this.chatbubbleentity.nextthink = time;
1299                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1300                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1301                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1302                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1303                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1304                 //this.chatbubbleentity.model = "";
1305                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1306         }
1307 }
1308
1309
1310 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1311 // added to the model skins
1312 /*void UpdateColorModHack()
1313 {
1314         float c;
1315         c = this.clientcolors & 15;
1316         // LordHavoc: only bothering to support white, green, red, yellow, blue
1317              if (!teamplay) this.colormod = '0 0 0';
1318         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1319         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1320         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1321         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1322         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1323         else this.colormod = '1 1 1';
1324 }*/
1325
1326 void respawn(entity this)
1327 {
1328         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1329         {
1330                 this.solid = SOLID_NOT;
1331                 this.takedamage = DAMAGE_NO;
1332                 set_movetype(this, MOVETYPE_FLY);
1333                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1334                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1335                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1336                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1337                 if(autocvar_g_respawn_ghosts_maxtime)
1338                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1339         }
1340
1341         CopyBody(this, 1);
1342
1343         this.effects |= EF_NODRAW; // prevent another CopyBody
1344         PutClientInServer(this);
1345 }
1346
1347 void play_countdown(entity this, float finished, Sound samp)
1348 {
1349     TC(Sound, samp);
1350         if(IS_REAL_CLIENT(this))
1351                 if(floor(finished - time - frametime) != floor(finished - time))
1352                         if(finished - time < 6)
1353                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1354 }
1355
1356 void player_powerups(entity this)
1357 {
1358         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1359         int items_prev = this.items;
1360
1361         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1362                 this.modelflags |= MF_ROCKET;
1363         else
1364                 this.modelflags &= ~MF_ROCKET;
1365
1366         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1367
1368         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1369                 return;
1370
1371         Fire_ApplyDamage(this);
1372         Fire_ApplyEffect(this);
1373
1374         if (!g_instagib)
1375         {
1376                 if (this.items & ITEM_Strength.m_itemid)
1377                 {
1378                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1379                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1380                         if (time > this.strength_finished)
1381                         {
1382                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1383                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1384                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1385                         }
1386                 }
1387                 else
1388                 {
1389                         if (time < this.strength_finished)
1390                         {
1391                                 this.items = this.items | ITEM_Strength.m_itemid;
1392                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1393                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1394                         }
1395                 }
1396                 if (this.items & ITEM_Shield.m_itemid)
1397                 {
1398                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1399                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1400                         if (time > this.invincible_finished)
1401                         {
1402                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1403                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1404                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1405                         }
1406                 }
1407                 else
1408                 {
1409                         if (time < this.invincible_finished)
1410                         {
1411                                 this.items = this.items | ITEM_Shield.m_itemid;
1412                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1413                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1414                         }
1415                 }
1416                 if (this.items & IT_SUPERWEAPON)
1417                 {
1418                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1419                         {
1420                                 this.superweapons_finished = 0;
1421                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1422                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1423                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1424                         }
1425                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1426                         {
1427                                 // don't let them run out
1428                         }
1429                         else
1430                         {
1431                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1432                                 if (time > this.superweapons_finished)
1433                                 {
1434                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1435                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1436                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1437                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1438                                 }
1439                         }
1440                 }
1441                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1442                 {
1443                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1444                         {
1445                                 this.items = this.items | IT_SUPERWEAPON;
1446                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1447                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1448                         }
1449                         else
1450                         {
1451                                 this.superweapons_finished = 0;
1452                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1453                         }
1454                 }
1455                 else
1456                 {
1457                         this.superweapons_finished = 0;
1458                 }
1459         }
1460
1461         if(autocvar_g_nodepthtestplayers)
1462                 this.effects = this.effects | EF_NODEPTHTEST;
1463
1464         if(autocvar_g_fullbrightplayers)
1465                 this.effects = this.effects | EF_FULLBRIGHT;
1466
1467         if (time >= game_starttime)
1468         if (time < this.spawnshieldtime)
1469                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1470
1471         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1472 }
1473
1474 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1475 {
1476         if(current > stable)
1477                 return current;
1478         else if(current > stable - 0.25) // when close enough, "snap"
1479                 return stable;
1480         else
1481                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1482 }
1483
1484 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1485 {
1486         if(current < stable)
1487                 return current;
1488         else if(current < stable + 0.25) // when close enough, "snap"
1489                 return stable;
1490         else
1491                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1492 }
1493
1494 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1495 {
1496         if(current > rotstable)
1497         {
1498                 if(rotframetime > 0)
1499                 {
1500                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1501                         current = max(rotstable, current - rotlinear * rotframetime);
1502                 }
1503         }
1504         else if(current < regenstable)
1505         {
1506                 if(regenframetime > 0)
1507                 {
1508                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1509                         current = min(regenstable, current + regenlinear * regenframetime);
1510                 }
1511         }
1512
1513         if(current > limit)
1514                 current = limit;
1515
1516         return current;
1517 }
1518
1519 void player_regen(entity this)
1520 {
1521         float max_mod, regen_mod, rot_mod, limit_mod;
1522         max_mod = regen_mod = rot_mod = limit_mod = 1;
1523
1524         float regen_health = autocvar_g_balance_health_regen;
1525         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1526         float regen_health_rot = autocvar_g_balance_health_rot;
1527         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1528         float regen_health_stable = autocvar_g_balance_health_regenstable;
1529         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1530         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1531                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1532         max_mod = M_ARGV(1, float);
1533         regen_mod = M_ARGV(2, float);
1534         rot_mod = M_ARGV(3, float);
1535         limit_mod = M_ARGV(4, float);
1536         regen_health = M_ARGV(5, float);
1537         regen_health_linear = M_ARGV(6, float);
1538         regen_health_rot = M_ARGV(7, float);
1539         regen_health_rotlinear = M_ARGV(8, float);
1540         regen_health_stable = M_ARGV(9, float);
1541         regen_health_rotstable = M_ARGV(10, float);
1542
1543
1544         if(!mutator_returnvalue)
1545         if(!STAT(FROZEN, this))
1546         {
1547                 float mina, maxa, limith, limita;
1548                 maxa = autocvar_g_balance_armor_rotstable;
1549                 mina = autocvar_g_balance_armor_regenstable;
1550                 limith = autocvar_g_balance_health_limit;
1551                 limita = autocvar_g_balance_armor_limit;
1552
1553                 regen_health_rotstable = regen_health_rotstable * max_mod;
1554                 regen_health_stable = regen_health_stable * max_mod;
1555                 limith = limith * limit_mod;
1556                 limita = limita * limit_mod;
1557
1558                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1559                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1560         }
1561
1562         // if player rotted to death...  die!
1563         // check this outside above checks, as player may still be able to rot to death
1564         if(this.health < 1)
1565         {
1566                 if(this.vehicle)
1567                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1568                 if(this.event_damage)
1569                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1570         }
1571
1572         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1573         {
1574                 float minf, maxf, limitf;
1575
1576                 maxf = autocvar_g_balance_fuel_rotstable;
1577                 minf = autocvar_g_balance_fuel_regenstable;
1578                 limitf = autocvar_g_balance_fuel_limit;
1579
1580                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1581         }
1582 }
1583
1584 bool zoomstate_set;
1585 void SetZoomState(entity this, float z)
1586 {
1587         if(z != this.zoomstate)
1588         {
1589                 this.zoomstate = z;
1590                 ClientData_Touch(this);
1591         }
1592         zoomstate_set = true;
1593 }
1594
1595 void GetPressedKeys(entity this)
1596 {
1597         MUTATOR_CALLHOOK(GetPressedKeys, this);
1598         int keys = this.pressedkeys;
1599         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1600         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1601         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1602         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1603
1604         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1605         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1606         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1607         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1608         this.pressedkeys = keys;
1609 }
1610
1611 /*
1612 ======================
1613 spectate mode routines
1614 ======================
1615 */
1616
1617 void SpectateCopy(entity this, entity spectatee)
1618 {
1619     TC(Client, this); TC(Client, spectatee);
1620
1621         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1622         PS(this) = PS(spectatee);
1623         this.armortype = spectatee.armortype;
1624         this.armorvalue = spectatee.armorvalue;
1625         this.ammo_cells = spectatee.ammo_cells;
1626         this.ammo_plasma = spectatee.ammo_plasma;
1627         this.ammo_shells = spectatee.ammo_shells;
1628         this.ammo_nails = spectatee.ammo_nails;
1629         this.ammo_rockets = spectatee.ammo_rockets;
1630         this.ammo_fuel = spectatee.ammo_fuel;
1631         this.clip_load = spectatee.clip_load;
1632         this.clip_size = spectatee.clip_size;
1633         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1634         this.health = spectatee.health;
1635         this.impulse = 0;
1636         this.items = spectatee.items;
1637         this.last_pickup = spectatee.last_pickup;
1638         this.hit_time = spectatee.hit_time;
1639         this.strength_finished = spectatee.strength_finished;
1640         this.invincible_finished = spectatee.invincible_finished;
1641         this.pressedkeys = spectatee.pressedkeys;
1642         this.weapons = spectatee.weapons;
1643         this.vortex_charge = spectatee.vortex_charge;
1644         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1645         this.hagar_load = spectatee.hagar_load;
1646         this.arc_heat_percent = spectatee.arc_heat_percent;
1647         this.minelayer_mines = spectatee.minelayer_mines;
1648         this.punchangle = spectatee.punchangle;
1649         this.view_ofs = spectatee.view_ofs;
1650         this.velocity = spectatee.velocity;
1651         this.dmg_take = spectatee.dmg_take;
1652         this.dmg_save = spectatee.dmg_save;
1653         this.dmg_inflictor = spectatee.dmg_inflictor;
1654         this.v_angle = spectatee.v_angle;
1655         this.angles = spectatee.v_angle;
1656         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1657         this.revive_progress = spectatee.revive_progress;
1658         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1659                 this.fixangle = true;
1660         setorigin(this, spectatee.origin);
1661         setsize(this, spectatee.mins, spectatee.maxs);
1662         SetZoomState(this, spectatee.zoomstate);
1663
1664     anticheat_spectatecopy(this, spectatee);
1665         this.hud = spectatee.hud;
1666         if(spectatee.vehicle)
1667     {
1668         this.angles = spectatee.v_angle;
1669
1670         //this.fixangle = false;
1671         //this.velocity = spectatee.vehicle.velocity;
1672         this.vehicle_health = spectatee.vehicle_health;
1673         this.vehicle_shield = spectatee.vehicle_shield;
1674         this.vehicle_energy = spectatee.vehicle_energy;
1675         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1676         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1677         this.vehicle_reload1 = spectatee.vehicle_reload1;
1678         this.vehicle_reload2 = spectatee.vehicle_reload2;
1679
1680         //msg_entity = this;
1681
1682        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1683             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1684            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1685            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1686
1687         //WriteByte (MSG_ONE, SVC_SETVIEW);
1688         //    WriteEntity(MSG_ONE, this);
1689         //makevectors(spectatee.v_angle);
1690         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1691     }
1692 }
1693
1694 bool SpectateUpdate(entity this)
1695 {
1696         if(!this.enemy)
1697             return false;
1698
1699         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1700         {
1701                 SetSpectatee(this, NULL);
1702                 return false;
1703         }
1704
1705         SpectateCopy(this, this.enemy);
1706
1707         return true;
1708 }
1709
1710 bool SpectateSet(entity this)
1711 {
1712         if(!IS_PLAYER(this.enemy))
1713                 return false;
1714
1715         ClientData_Touch(this.enemy);
1716
1717         msg_entity = this;
1718         WriteByte(MSG_ONE, SVC_SETVIEW);
1719         WriteEntity(MSG_ONE, this.enemy);
1720         set_movetype(this, MOVETYPE_NONE);
1721         accuracy_resend(this);
1722
1723         if(!SpectateUpdate(this))
1724                 PutObserverInServer(this);
1725
1726         return true;
1727 }
1728
1729 void SetSpectatee(entity this, entity spectatee)
1730 {
1731         entity old_spectatee = this.enemy;
1732
1733         this.enemy = spectatee;
1734
1735         // WEAPONTODO
1736         // these are required to fix the spectator bug with arc
1737         if(old_spectatee)
1738         {
1739                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1740                 {
1741                         .entity weaponentity = weaponentities[slot];
1742                         if(old_spectatee.(weaponentity).arc_beam)
1743                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1744                 }
1745         }
1746         if(this.enemy)
1747         {
1748                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1749                 {
1750                         .entity weaponentity = weaponentities[slot];
1751                         if(this.enemy.(weaponentity).arc_beam)
1752                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1753                 }
1754         }
1755
1756         // needed to update spectator list
1757         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1758 }
1759
1760 bool Spectate(entity this, entity pl)
1761 {
1762         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1763                 return false;
1764         pl = M_ARGV(1, entity);
1765
1766         SetSpectatee(this, pl);
1767         return SpectateSet(this);
1768 }
1769
1770 bool SpectateNext(entity this)
1771 {
1772         entity ent = find(this.enemy, classname, STR_PLAYER);
1773
1774         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1775                 ent = M_ARGV(1, entity);
1776         else if (!ent)
1777                 ent = find(ent, classname, STR_PLAYER);
1778
1779         if(ent) { SetSpectatee(this, ent); }
1780
1781         return SpectateSet(this);
1782 }
1783
1784 bool SpectatePrev(entity this)
1785 {
1786         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1787         entity ent = findchain(classname, STR_PLAYER);
1788         if (!ent) // no player
1789                 return false;
1790
1791         entity first = ent;
1792         // skip players until current spectated player
1793         if(this.enemy)
1794         while(ent && ent != this.enemy)
1795                 ent = ent.chain;
1796
1797         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1798         {
1799                 case MUT_SPECPREV_FOUND:
1800                     ent = M_ARGV(1, entity);
1801                     break;
1802                 case MUT_SPECPREV_RETURN:
1803                     return true;
1804                 case MUT_SPECPREV_CONTINUE:
1805                 default:
1806                 {
1807                         if(ent.chain)
1808                                 ent = ent.chain;
1809                         else
1810                                 ent = first;
1811                         break;
1812                 }
1813         }
1814
1815         SetSpectatee(this, ent);
1816         return SpectateSet(this);
1817 }
1818
1819 /*
1820 =============
1821 ShowRespawnCountdown()
1822
1823 Update a respawn countdown display.
1824 =============
1825 */
1826 void ShowRespawnCountdown(entity this)
1827 {
1828         float number;
1829         if(!IS_DEAD(this)) // just respawned?
1830                 return;
1831         else
1832         {
1833                 number = ceil(this.respawn_time - time);
1834                 if(number <= 0)
1835                         return;
1836                 if(number <= this.respawn_countdown)
1837                 {
1838                         this.respawn_countdown = number - 1;
1839                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1840                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1841                 }
1842         }
1843 }
1844
1845 .float caplayer;
1846
1847 void LeaveSpectatorMode(entity this)
1848 {
1849         if(this.caplayer)
1850                 return;
1851         if(nJoinAllowed(this, this))
1852         {
1853                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1854                 {
1855                         TRANSMUTE(Player, this);
1856
1857                         SetSpectatee(this, NULL);
1858
1859                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1860                                 { JoinBestTeam(this, false, true); }
1861
1862                         if(autocvar_g_campaign)
1863                                 { campaign_bots_may_start = true; }
1864
1865                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1866
1867                         PutClientInServer(this);
1868
1869                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1870                 }
1871                 else
1872                         stuffcmd(this, "menu_showteamselect\n");
1873         }
1874         else
1875         {
1876                 // Player may not join because g_maxplayers is set
1877                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1878         }
1879 }
1880
1881 /**
1882  * Determines whether the player is allowed to join. This depends on cvar
1883  * g_maxplayers, if it isn't used this function always return true, otherwise
1884  * it checks whether the number of currently playing players exceeds g_maxplayers.
1885  * @return int number of free slots for players, 0 if none
1886  */
1887 bool nJoinAllowed(entity this, entity ignore)
1888 {
1889         if(!ignore)
1890         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1891         // so report 0 free slots if restricted
1892         {
1893                 if(autocvar_g_forced_team_otherwise == "spectate")
1894                         return false;
1895                 if(autocvar_g_forced_team_otherwise == "spectator")
1896                         return false;
1897         }
1898
1899         if(this.team_forced < 0)
1900                 return false; // forced spectators can never join
1901
1902         // TODO simplify this
1903         int totalClients = 0;
1904         int currentlyPlaying = 0;
1905         FOREACH_CLIENT(true, LAMBDA(
1906                 if(it != ignore)
1907                         ++totalClients;
1908                 if(IS_REAL_CLIENT(it))
1909                 if(IS_PLAYER(it) || it.caplayer)
1910                         ++currentlyPlaying;
1911         ));
1912
1913         if (!autocvar_g_maxplayers)
1914                 return maxclients - totalClients;
1915
1916         if(currentlyPlaying < autocvar_g_maxplayers)
1917                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1918
1919         return false;
1920 }
1921
1922 /**
1923  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1924  * g_maxplayers_spectator_blocktime seconds
1925  */
1926 void checkSpectatorBlock(entity this)
1927 {
1928         if(IS_SPEC(this) || IS_OBSERVER(this))
1929         if(!this.caplayer)
1930         if(IS_REAL_CLIENT(this))
1931         {
1932                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1933                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1934                         dropclient(this);
1935                 }
1936         }
1937 }
1938
1939 void PrintWelcomeMessage(entity this)
1940 {
1941         if(this.motd_actived_time == 0)
1942         {
1943                 if (autocvar_g_campaign) {
1944                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1945                                 this.motd_actived_time = time;
1946                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1947                         }
1948                 } else {
1949                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1950                                 this.motd_actived_time = time;
1951                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1952                         }
1953                 }
1954         }
1955         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1956         {
1957                 if (autocvar_g_campaign) {
1958                         if (PHYS_INPUT_BUTTON_INFO(this))
1959                                 this.motd_actived_time = time;
1960                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1961                                 this.motd_actived_time = 0;
1962                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1963                         }
1964                 } else {
1965                         if (PHYS_INPUT_BUTTON_INFO(this))
1966                                 this.motd_actived_time = time;
1967                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1968                                 this.motd_actived_time = 0;
1969                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1970                         }
1971                 }
1972         }
1973         else //if(this.motd_actived_time < 0) // just connected, motd is active
1974         {
1975                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1976                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1977                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
1978                 {
1979                         // instanctly hide MOTD
1980                         this.motd_actived_time = 0;
1981                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1982                 }
1983         }
1984 }
1985
1986 void ObserverThink(entity this)
1987 {
1988         if ( this.impulse )
1989         {
1990                 MinigameImpulse(this, this.impulse);
1991                 this.impulse = 0;
1992         }
1993         if (this.flags & FL_JUMPRELEASED) {
1994                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
1995                         this.flags &= ~FL_JUMPRELEASED;
1996                         this.flags |= FL_SPAWNING;
1997                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
1998                         this.flags &= ~FL_JUMPRELEASED;
1999                         if(SpectateNext(this)) {
2000                                 TRANSMUTE(Spectator, this);
2001                         }
2002                 } else {
2003                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2004                         set_movetype(this, preferred_movetype);
2005                 }
2006         } else {
2007                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2008                         this.flags |= FL_JUMPRELEASED;
2009                         if(this.flags & FL_SPAWNING)
2010                         {
2011                                 this.flags &= ~FL_SPAWNING;
2012                                 LeaveSpectatorMode(this);
2013                                 return;
2014                         }
2015                 }
2016         }
2017 }
2018
2019 void SpectatorThink(entity this)
2020 {
2021         if ( this.impulse )
2022         {
2023                 if(MinigameImpulse(this, this.impulse))
2024                         this.impulse = 0;
2025
2026                 if (this.impulse == IMP_weapon_drop.impulse)
2027                 {
2028                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2029                         this.impulse = 0;
2030                         return;
2031                 }
2032         }
2033         if (this.flags & FL_JUMPRELEASED) {
2034                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2035                         this.flags &= ~FL_JUMPRELEASED;
2036                         this.flags |= FL_SPAWNING;
2037                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2038                         this.flags &= ~FL_JUMPRELEASED;
2039                         if(SpectateNext(this)) {
2040                                 TRANSMUTE(Spectator, this);
2041                         } else {
2042                                 TRANSMUTE(Observer, this);
2043                                 PutClientInServer(this);
2044                         }
2045                         this.impulse = 0;
2046                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2047                         this.flags &= ~FL_JUMPRELEASED;
2048                         if(SpectatePrev(this)) {
2049                                 TRANSMUTE(Spectator, this);
2050                         } else {
2051                                 TRANSMUTE(Observer, this);
2052                                 PutClientInServer(this);
2053                         }
2054                         this.impulse = 0;
2055                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2056                         this.flags &= ~FL_JUMPRELEASED;
2057                         TRANSMUTE(Observer, this);
2058                         PutClientInServer(this);
2059                 } else {
2060                         if(!SpectateUpdate(this))
2061                                 PutObserverInServer(this);
2062                 }
2063         } else {
2064                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2065                         this.flags |= FL_JUMPRELEASED;
2066                         if(this.flags & FL_SPAWNING)
2067                         {
2068                                 this.flags &= ~FL_SPAWNING;
2069                                 LeaveSpectatorMode(this);
2070                                 return;
2071                         }
2072                 }
2073                 if(!SpectateUpdate(this))
2074                         PutObserverInServer(this);
2075         }
2076
2077         this.flags |= FL_CLIENT | FL_NOTARGET;
2078 }
2079
2080 void vehicles_enter (entity pl, entity veh);
2081 void PlayerUseKey(entity this)
2082 {
2083         if (!IS_PLAYER(this))
2084                 return;
2085
2086         if(this.vehicle)
2087         {
2088                 if(!gameover)
2089                 {
2090                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2091                         return;
2092                 }
2093         }
2094         else if(autocvar_g_vehicles_enter)
2095         {
2096                 if(!STAT(FROZEN, this))
2097                 if(!IS_DEAD(this))
2098                 if(!gameover)
2099                 {
2100                         entity head, closest_target = NULL;
2101                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2102
2103                         while(head) // find the closest acceptable target to enter
2104                         {
2105                                 if(IS_VEHICLE(head))
2106                                 if(!IS_DEAD(head))
2107                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2108                                 if(head.takedamage != DAMAGE_NO)
2109                                 {
2110                                         if(closest_target)
2111                                         {
2112                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2113                                                 { closest_target = head; }
2114                                         }
2115                                         else { closest_target = head; }
2116                                 }
2117
2118                                 head = head.chain;
2119                         }
2120
2121                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2122                 }
2123         }
2124
2125         // a use key was pressed; call handlers
2126         MUTATOR_CALLHOOK(PlayerUseKey, this);
2127 }
2128
2129
2130 /*
2131 =============
2132 PlayerPreThink
2133
2134 Called every frame for each client before the physics are run
2135 =============
2136 */
2137 .float usekeypressed;
2138 .float last_vehiclecheck;
2139 .int items_added;
2140 void PlayerPreThink (entity this)
2141 {
2142         WarpZone_PlayerPhysics_FixVAngle(this);
2143
2144     STAT(GAMESTARTTIME, this) = game_starttime;
2145         STAT(ROUNDSTARTTIME, this) = round_starttime;
2146         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2147         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2148
2149         STAT(WEAPONSINMAP, this) = weaponsInMap;
2150
2151         if (frametime) {
2152                 // physics frames: update anticheat stuff
2153                 anticheat_prethink(this);
2154         }
2155
2156         if (blockSpectators && frametime) {
2157                 // WORKAROUND: only use dropclient in server frames (frametime set).
2158                 // Never use it in cl_movement frames (frametime zero).
2159                 checkSpectatorBlock(this);
2160     }
2161
2162         zoomstate_set = false;
2163
2164         // Check for nameless players
2165         if (isInvisibleString(this.netname)) {
2166                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2167                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2168         }
2169         if (this.netname != this.netname_previous) {
2170                 if (autocvar_sv_eventlog) {
2171                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2172         }
2173                 if (this.netname_previous) strunzone(this.netname_previous);
2174                 this.netname_previous = strzone(this.netname);
2175         }
2176
2177         // version nagging
2178         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2179         this.version_nagtime = 0;
2180         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2181             // git client
2182         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2183             // git server
2184             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2185         } else {
2186             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2187             if (r < 0) { // old client
2188                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2189             } else if (r > 0) { // old server
2190                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2191             }
2192         }
2193     }
2194
2195         // GOD MODE info
2196         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2197         {
2198                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2199                 this.max_armorvalue = 0;
2200         }
2201
2202         if (STAT(FROZEN, this) == 2)
2203         {
2204                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2205                 this.health = max(1, this.revive_progress * start_health);
2206                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2207
2208                 if (this.revive_progress >= 1)
2209                         Unfreeze(this);
2210         }
2211         else if (STAT(FROZEN, this) == 3)
2212         {
2213                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2214                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2215
2216                 if (this.health < 1)
2217                 {
2218                         if (this.vehicle)
2219                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2220                         if(this.event_damage)
2221                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2222                 }
2223                 else if (this.revive_progress <= 0)
2224                         Unfreeze(this);
2225         }
2226
2227         MUTATOR_CALLHOOK(PlayerPreThink, this);
2228
2229         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2230         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2231         {
2232                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2233                 {
2234                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2235                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2236                         {
2237                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2238                         }
2239                         else if(!it.owner)
2240                         {
2241                                 if(!it.team || SAME_TEAM(this, it))
2242                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2243                                 else if(autocvar_g_vehicles_steal)
2244                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2245                         }
2246                 });
2247
2248                 this.last_vehiclecheck = time + 1;
2249         }
2250
2251         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2252         {
2253                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2254                         PlayerUseKey(this);
2255                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2256         }
2257
2258         if (IS_REAL_CLIENT(this))
2259                 PrintWelcomeMessage(this);
2260
2261         if (IS_PLAYER(this)) {
2262                 CheckRules_Player(this);
2263
2264                 if (intermission_running) {
2265                         IntermissionThink(this);
2266                         return;
2267                 }
2268
2269                 if (timeout_status == TIMEOUT_ACTIVE) {
2270             // don't allow the player to turn around while game is paused
2271                         // FIXME turn this into CSQC stuff
2272                         this.v_angle = this.lastV_angle;
2273                         this.angles = this.lastV_angle;
2274                         this.fixangle = true;
2275                 }
2276
2277                 if (frametime) player_powerups(this);
2278
2279                 if (IS_DEAD(this)) {
2280                         if (this.personal && g_race_qualifying) {
2281                                 if (time > this.respawn_time) {
2282                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2283                                         respawn(this);
2284                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2285                                 }
2286                         } else {
2287                                 if (frametime) player_anim(this);
2288                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2289
2290                                 switch(this.deadflag)
2291                                 {
2292                                         case DEAD_DYING:
2293                                         {
2294                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2295                                                         this.deadflag = DEAD_RESPAWNING;
2296                                                 else if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2297                                                         this.deadflag = DEAD_DEAD;
2298                                                 break;
2299                                         }
2300                                         case DEAD_DEAD:
2301                                         {
2302                                                 if (button_pressed)
2303                                                         this.deadflag = DEAD_RESPAWNABLE;
2304                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2305                                                         this.deadflag = DEAD_RESPAWNING;
2306                                                 break;
2307                                         }
2308                                         case DEAD_RESPAWNABLE:
2309                                         {
2310                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2311                                                         this.deadflag = DEAD_RESPAWNING;
2312                                                 break;
2313                                         }
2314                                         case DEAD_RESPAWNING:
2315                                         {
2316                                                 if (time > this.respawn_time)
2317                                                 {
2318                                                         this.respawn_time = time + 1; // only retry once a second
2319                                                         this.respawn_time_max = this.respawn_time;
2320                                                         respawn(this);
2321                                                 }
2322                                                 break;
2323                                         }
2324                                 }
2325
2326                                 ShowRespawnCountdown(this);
2327
2328                                 if (this.respawn_flags & RESPAWN_SILENT)
2329                                         STAT(RESPAWN_TIME, this) = 0;
2330                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2331                                 {
2332                                         if (time < this.respawn_time)
2333                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2334                                         else if (this.deadflag != DEAD_RESPAWNING)
2335                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2336                                 }
2337                                 else
2338                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2339                         }
2340
2341                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2342                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2343                                 STAT(RESPAWN_TIME, this) *= -1;
2344
2345                         return;
2346                 }
2347
2348                 this.prevorigin = this.origin;
2349
2350                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2351                 if (this.hook.state) {
2352                         do_crouch = false;
2353                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2354                         do_crouch = false;
2355                 } else if (this.vehicle) {
2356                         do_crouch = false;
2357                 } else if (STAT(FROZEN, this)) {
2358                         do_crouch = false;
2359         }
2360
2361                 if (do_crouch) {
2362                         if (!this.crouch) {
2363                                 this.crouch = true;
2364                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2365                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2366                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2367                         }
2368                 } else if (this.crouch) {
2369             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2370             if (!trace_startsolid) {
2371                 this.crouch = false;
2372                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2373                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2374             }
2375                 }
2376
2377                 FixPlayermodel(this);
2378
2379                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2380                 //if(frametime)
2381                 {
2382                         this.items &= ~this.items_added;
2383
2384                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2385                         //{
2386                                 //.entity weaponentity = weaponentities[slot];
2387                                 //W_WeaponFrame(this, weaponentity);
2388                         //}
2389                         .entity weaponentity = weaponentities[0]; // TODO
2390                         W_WeaponFrame(this, weaponentity);
2391
2392                         this.items_added = 0;
2393                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2394                 this.items_added |= IT_FUEL;
2395
2396                         this.items |= this.items_added;
2397                 }
2398
2399                 player_regen(this);
2400
2401                 // WEAPONTODO: Add a weapon request for this
2402                 // rot vortex charge to the charge limit
2403                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2404                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2405
2406                 if (frametime) player_anim(this);
2407
2408                 // secret status
2409                 secrets_setstatus(this);
2410
2411                 // monsters status
2412                 monsters_setstatus(this);
2413
2414                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2415         }
2416         else if (gameover) {
2417                 if (intermission_running) IntermissionThink(this);
2418                 return;
2419         }
2420         else if (IS_OBSERVER(this)) {
2421                 ObserverThink(this);
2422         }
2423         else if (IS_SPEC(this)) {
2424                 SpectatorThink(this);
2425         }
2426
2427         // WEAPONTODO: Add weapon request for this
2428         if (!zoomstate_set) {
2429                 SetZoomState(this,
2430                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2431                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2432                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2433                 );
2434     }
2435
2436         int oldspectatee_status = this.spectatee_status;
2437         if (IS_SPEC(this)) {
2438                 this.spectatee_status = etof(this.enemy);
2439         } else if (IS_OBSERVER(this)) {
2440                 this.spectatee_status = etof(this);
2441         } else {
2442                 this.spectatee_status = 0;
2443     }
2444         if (this.spectatee_status != oldspectatee_status) {
2445                 ClientData_Touch(this);
2446                 if (g_race || g_cts) race_InitSpectator();
2447         }
2448
2449         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2450         {
2451                 this.teamkill_soundtime = 0;
2452
2453                 entity e = this.teamkill_soundsource;
2454                 entity oldpusher = e.pusher;
2455                 e.pusher = this;
2456                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2457                 e.pusher = oldpusher;
2458         }
2459
2460         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2461                 this.taunt_soundtime = 0;
2462                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2463         }
2464
2465         target_voicescript_next(this);
2466
2467         // WEAPONTODO: Move into weaponsystem somehow
2468         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2469         if (PS(this).m_weapon == WEP_Null)
2470                 this.clip_load = this.clip_size = 0;
2471 }
2472
2473 void DrownPlayer(entity this)
2474 {
2475         if(IS_DEAD(this))
2476                 return;
2477
2478         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2479         {
2480                 if(this.air_finished < time)
2481                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2482                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2483                 this.dmg = 2;
2484         }
2485         else if (this.air_finished < time)
2486         {       // drown!
2487                 if (this.pain_finished < time)
2488                 {
2489                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2490                         this.pain_finished = time + 0.5;
2491                 }
2492         }
2493 }
2494
2495 .bool move_qcphysics;
2496
2497 void Player_Physics(entity this)
2498 {
2499         set_movetype(this, ((this.move_qcphysics) ? MOVETYPE_NONE : this.move_movetype));
2500
2501         if(!this.move_qcphysics)
2502                 return;
2503
2504         int mt = this.move_movetype;
2505
2506         if(mt == MOVETYPE_PUSH || mt == MOVETYPE_FAKEPUSH || mt == MOVETYPE_PHYSICS)
2507         {
2508                 this.move_qcphysics = false;
2509                 set_movetype(this, mt);
2510                 return;
2511         }
2512
2513         if(!frametime && !this.pm_frametime)
2514                 return;
2515
2516         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2517
2518         this.pm_frametime = 0;
2519 }
2520
2521 /*
2522 =============
2523 PlayerPostThink
2524
2525 Called every frame for each client after the physics are run
2526 =============
2527 */
2528 .float idlekick_lasttimeleft;
2529 void PlayerPostThink (entity this)
2530 {
2531         Player_Physics(this);
2532
2533         if (sv_maxidle > 0)
2534         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2535         if (IS_REAL_CLIENT(this))
2536         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2537         {
2538                 int totalClients = 0;
2539                 if(sv_maxidle_slots > 0)
2540                 {
2541                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2542                         {
2543                                 ++totalClients;
2544                         });
2545                 }
2546
2547                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2548                 { /* do nothing */ }
2549                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2550                 {
2551                         if (this.idlekick_lasttimeleft)
2552                         {
2553                                 this.idlekick_lasttimeleft = 0;
2554                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2555                         }
2556                 }
2557                 else
2558                 {
2559                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2560                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2561                                 if (!this.idlekick_lasttimeleft)
2562                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2563                         }
2564                         if (timeleft <= 0) {
2565                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2566                                 dropclient(this);
2567                                 return;
2568                         }
2569                         else if (timeleft <= 10) {
2570                                 if (timeleft != this.idlekick_lasttimeleft) {
2571                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2572                 }
2573                                 this.idlekick_lasttimeleft = timeleft;
2574                         }
2575                 }
2576         }
2577
2578         CheatFrame(this);
2579
2580         //CheckPlayerJump();
2581
2582         if (IS_PLAYER(this)) {
2583                 DrownPlayer(this);
2584                 CheckRules_Player(this);
2585                 UpdateChatBubble(this);
2586                 if (this.impulse) ImpulseCommands(this);
2587                 if (intermission_running) return; // intermission or finale
2588                 GetPressedKeys(this);
2589         }
2590
2591         if (this.waypointsprite_attachedforcarrier) {
2592             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2593                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2594     }
2595
2596         playerdemo_write(this);
2597
2598         CSQCMODEL_AUTOUPDATE(this);
2599 }