qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!game_stopped)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         this.killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357
 358         for(int slot = 0; slot < MAX_AXH; ++slot)
 359         {
 360                 entity axh = this.(AuxiliaryXhair[slot]);
 361                 this.(AuxiliaryXhair[slot]) = NULL;
 362
 363                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 364                         delete(axh);
 365         }
 366 }
 367
 368 int player_getspecies(entity this)
 369 {
 370         get_model_parameters(this.model, this.skin);
 371         int s = get_model_parameters_species;
 372         get_model_parameters(string_null, 0);
 373         if (s < 0) return SPECIES_HUMAN;
 374         return s;
 375 }
 376
 377 .float model_randomizer;
 378 void FixPlayermodel(entity player)
 379 {
 380         string defaultmodel = "";
 381         int defaultskin = 0;
 382         if(autocvar_sv_defaultcharacter)
 383         {
 384                 if(teamplay)
 385                 {
 386                         switch(player.team)
 387                         {
 388                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 389                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 390                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 391                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 392                         }
 393                 }
 394
 395                 if(defaultmodel == "")
 396                 {
 397                         defaultmodel = autocvar_sv_defaultplayermodel;
 398                         defaultskin = autocvar_sv_defaultplayerskin;
 399                 }
 400
 401                 int n = tokenize_console(defaultmodel);
 402                 if(n > 0)
 403                 {
 404                         defaultmodel = argv(floor(n * player.model_randomizer));
 405                         // However, do NOT randomize if the player-selected model is in the list.
 406                         for (int i = 0; i < n; ++i)
 407                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 408                                         defaultmodel = argv(i);
 409                 }
 410
 411                 int i = strstrofs(defaultmodel, ":", 0);
 412                 if(i >= 0)
 413                 {
 414                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 415                         defaultmodel = substring(defaultmodel, 0, i);
 416                 }
 417         }
 418         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 419         {
 420                 if(teamplay)
 421                 {
 422                         switch(player.team)
 423                         {
 424                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 425                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 426                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 427                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 428                         }
 429                 }
 430
 431                 if(!defaultskin)
 432                         defaultskin = autocvar_sv_defaultplayerskin;
 433         }
 434
 435         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 436         defaultmodel = M_ARGV(0, string);
 437         defaultskin = M_ARGV(1, int);
 438
 439         bool chmdl = false;
 440         int oldskin;
 441         if(defaultmodel != "")
 442         {
 443                 if (defaultmodel != player.model)
 444                 {
 445                         vector m1 = player.mins;
 446                         vector m2 = player.maxs;
 447                         setplayermodel (player, defaultmodel);
 448                         setsize (player, m1, m2);
 449                         chmdl = true;
 450                 }
 451
 452                 oldskin = player.skin;
 453                 player.skin = defaultskin;
 454         } else {
 455                 if (player.playermodel != player.model || player.playermodel == "")
 456                 {
 457                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 458                         vector m1 = player.mins;
 459                         vector m2 = player.maxs;
 460                         setplayermodel (player, player.playermodel);
 461                         setsize (player, m1, m2);
 462                         chmdl = true;
 463                 }
 464
 465                 if(!autocvar_sv_defaultcharacterskin)
 466                 {
 467                         oldskin = player.skin;
 468                         player.skin = stof(player.playerskin);
 469                 }
 470                 else
 471                 {
 472                         oldskin = player.skin;
 473                         player.skin = defaultskin;
 474                 }
 475         }
 476
 477         if(chmdl || oldskin != player.skin) // model or skin has changed
 478         {
 479                 player.species = player_getspecies(player); // update species
 480                 if(!autocvar_g_debug_globalsounds)
 481                         UpdatePlayerSounds(player); // update skin sounds
 482         }
 483
 484         if(!teamplay)
 485                 if(strlen(autocvar_sv_defaultplayercolors))
 486                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 487                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 488 }
 489
 490
 491 /** Called when a client spawns in the server */
 492 void PutClientInServer(entity this)
 493 {
 494         if (IS_BOT_CLIENT(this)) {
 495                 TRANSMUTE(Player, this);
 496         } else if (IS_REAL_CLIENT(this)) {
 497                 msg_entity = this;
 498                 WriteByte(MSG_ONE, SVC_SETVIEW);
 499                 WriteEntity(MSG_ONE, this);
 500         }
 501         if (game_stopped)
 502                 TRANSMUTE(Observer, this);
 503
 504         SetSpectatee(this, NULL);
 505
 506         // reset player keys
 507         this.itemkeys = 0;
 508
 509         MUTATOR_CALLHOOK(PutClientInServer, this);
 510
 511         if (IS_OBSERVER(this)) {
 512                 PutObserverInServer(this);
 513         } else if (IS_PLAYER(this)) {
 514                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 515
 516                 PlayerState_attach(this);
 517                 accuracy_resend(this);
 518
 519                 if (this.team < 0)
 520                         JoinBestTeam(this, false, true);
 521
 522                 entity spot = SelectSpawnPoint(this, false);
 523                 if (!spot) {
 524                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 525                         return; // spawn failed
 526                 }
 527
 528                 TRANSMUTE(Player, this);
 529
 530                 this.wasplayer = true;
 531                 this.iscreature = true;
 532                 this.teleportable = TELEPORT_NORMAL;
 533                 if(!this.damagedbycontents)
 534                         IL_PUSH(g_damagedbycontents, this);
 535                 this.damagedbycontents = true;
 536                 set_movetype(this, MOVETYPE_WALK);
 537                 this.solid = SOLID_SLIDEBOX;
 538                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 539                 if (autocvar_g_playerclip_collisions)
 540                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 541                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 542                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 543                 this.frags = FRAGS_PLAYER;
 544                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 545                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 546                 if (autocvar__notarget)
 547                         this.flags |= FL_NOTARGET;
 548                 this.takedamage = DAMAGE_AIM;
 549                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 550                 this.dmg = 2; // WTF
 551
 552                 if (warmup_stage) {
 553                         this.ammo_shells = warmup_start_ammo_shells;
 554                         this.ammo_nails = warmup_start_ammo_nails;
 555                         this.ammo_rockets = warmup_start_ammo_rockets;
 556                         this.ammo_cells = warmup_start_ammo_cells;
 557                         this.ammo_plasma = warmup_start_ammo_plasma;
 558                         this.ammo_fuel = warmup_start_ammo_fuel;
 559                         this.health = warmup_start_health;
 560                         this.armorvalue = warmup_start_armorvalue;
 561                         this.weapons = WARMUP_START_WEAPONS;
 562                 } else {
 563                         this.ammo_shells = start_ammo_shells;
 564                         this.ammo_nails = start_ammo_nails;
 565                         this.ammo_rockets = start_ammo_rockets;
 566                         this.ammo_cells = start_ammo_cells;
 567                         this.ammo_plasma = start_ammo_plasma;
 568                         this.ammo_fuel = start_ammo_fuel;
 569                         this.health = start_health;
 570                         this.armorvalue = start_armorvalue;
 571                         this.weapons = start_weapons;
 572                 }
 573                 SetSpectatee_status(this, 0);
 574
 575                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 576
 577                 this.items = start_items;
 578
 579                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 580                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 581                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 582                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 583                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 584                 // extend the pause of rotting if client was reset at the beginning of the countdown
 585                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 586                         float f = game_starttime - time;
 587                         this.spawnshieldtime += f;
 588                         this.pauserotarmor_finished += f;
 589                         this.pauserothealth_finished += f;
 590                         this.pauseregen_finished += f;
 591                 }
 592                 this.damageforcescale = 2;
 593                 this.death_time = 0;
 594                 this.respawn_flags = 0;
 595                 this.respawn_time = 0;
 596                 this.stat_respawn_time = 0;
 597                 this.scale = autocvar_sv_player_scale;
 598                 this.fade_time = 0;
 599                 this.pain_frame = 0;
 600                 this.pain_finished = 0;
 601                 this.pushltime = 0;
 602                 setthink(this, func_null); // players have no think function
 603                 this.nextthink = 0;
 604                 this.dmg_team = 0;
 605                 this.ballistics_density = autocvar_g_ballistics_density_player;
 606
 607                 this.deadflag = DEAD_NO;
 608
 609                 this.angles = spot.angles;
 610                 this.angles_z = 0; // never spawn tilted even if the spot says to
 611                 if (IS_BOT_CLIENT(this))
 612                         this.v_angle = this.angles;
 613                 this.fixangle = true; // turn this way immediately
 614                 this.oldvelocity = this.velocity = '0 0 0';
 615                 this.avelocity = '0 0 0';
 616                 this.punchangle = '0 0 0';
 617                 this.punchvector = '0 0 0';
 618
 619                 this.strength_finished = 0;
 620                 this.invincible_finished = 0;
 621                 this.fire_endtime = -1;
 622                 this.revive_progress = 0;
 623                 this.revival_time = 0;
 624                 this.air_finished = time + 12;
 625
 626                 entity spawnevent = new_pure(spawnevent);
 627                 spawnevent.owner = this;
 628                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 629
 630                 // Cut off any still running player sounds.
 631                 stopsound(this, CH_PLAYER_SINGLE);
 632
 633                 this.model = "";
 634                 FixPlayermodel(this);
 635                 this.drawonlytoclient = NULL;
 636
 637                 this.viewloc = NULL;
 638
 639                 this.crouch = false;
 640                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 641                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 642                 this.spawnorigin = spot.origin;
 643                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 644                 // don't reset back to last position, even if new position is stuck in solid
 645                 this.oldorigin = this.origin;
 646                 this.prevorigin = this.origin;
 647                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 648                 if(this.conveyor)
 649                         IL_REMOVE(g_conveyed, this);
 650                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 651                 this.hud = HUD_NORMAL;
 652
 653                 this.event_damage = PlayerDamage;
 654
 655                 if(!this.bot_attack)
 656                         IL_PUSH(g_bot_targets, this);
 657                 this.bot_attack = true;
 658                 this.monster_attack = true;
 659                 navigation_dynamicgoal_init(this, false);
 660
 661                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 662
 663                 if (this.killcount == FRAGS_SPECTATOR) {
 664                         PlayerScore_Clear(this);
 665                         this.killcount = 0;
 666                 }
 667
 668                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 669                 {
 670                         .entity weaponentity = weaponentities[slot];
 671                         entity oldwep = this.(weaponentity);
 672                         CL_SpawnWeaponentity(this, weaponentity);
 673                         if(oldwep && oldwep.owner == this)
 674                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 675                 }
 676                 this.alpha = default_player_alpha;
 677                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 678                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 679
 680                 this.speedrunning = false;
 681
 682                 target_voicescript_clear(this);
 683
 684                 // reset fields the weapons may use
 685                 FOREACH(Weapons, true, LAMBDA(
 686                         it.wr_resetplayer(it, this);
 687                         // reload all reloadable weapons
 688                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 689                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 690                                 {
 691                                         .entity weaponentity = weaponentities[slot];
 692                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 693                                 }
 694                         }
 695                 ));
 696
 697                 {
 698                         string s = spot.target;
 699                         spot.target = string_null;
 700                         SUB_UseTargets(spot, this, NULL);
 701                         spot.target = s;
 702                 }
 703
 704                 Unfreeze(this);
 705
 706                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 707
 708                 if (autocvar_spawn_debug)
 709                 {
 710                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 711                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 712                 }
 713
 714                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 715                 {
 716                         .entity weaponentity = weaponentities[slot];
 717                         if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 718                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 719                         else
 720                                 this.(weaponentity).m_switchweapon = WEP_Null;
 721                         this.(weaponentity).m_weapon = WEP_Null;
 722                         this.(weaponentity).weaponname = "";
 723                         this.(weaponentity).m_switchingweapon = WEP_Null;
 724                         this.(weaponentity).cnt = -1;
 725                 }
 726
 727                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 728
 729                 if (!warmup_stage && !this.alivetime)
 730                         this.alivetime = time;
 731
 732                 antilag_clear(this, CS(this));
 733         }
 734 }
 735
 736 void ClientInit_misc(entity this);
 737
 738 // TODO do we need all these fields, or should we stop autodetecting runtime
 739 // changes and just have a console command to update this?
 740 bool ClientInit_SendEntity(entity this, entity to, int sf)
 741 {
 742         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 743         return = true;
 744         msg_entity = to;
 745         // MSG_INIT replacement
 746         // TODO: make easier to use
 747         Registry_send_all();
 748         W_PROP_reload(MSG_ONE, to);
 749         ClientInit_misc(this);
 750         MUTATOR_CALLHOOK(Ent_Init);
 751 }
 752 void ClientInit_misc(entity this)
 753 {
 754         int channel = MSG_ONE;
 755         WriteHeader(channel, ENT_CLIENT_INIT);
 756         WriteByte(channel, g_nexball_meter_period * 32);
 757         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 758         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 759         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 760         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 761         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 762         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 763         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 764         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 765
 766         if(sv_foginterval && world.fog != "")
 767                 WriteString(channel, world.fog);
 768         else
 769                 WriteString(channel, "");
 770         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 771         WriteByte(channel, serverflags);
 772         WriteCoord(channel, autocvar_g_trueaim_minrange);
 773 }
 774
 775 void ClientInit_CheckUpdate(entity this)
 776 {
 777         this.nextthink = time;
 778         if(this.count != autocvar_g_balance_armor_blockpercent)
 779         {
 780                 this.count = autocvar_g_balance_armor_blockpercent;
 781                 this.SendFlags |= 1;
 782         }
 783 }
 784
 785 void ClientInit_Spawn()
 786 {
 787         entity e = new_pure(clientinit);
 788         setthink(e, ClientInit_CheckUpdate);
 789         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 790
 791         ClientInit_CheckUpdate(e);
 792 }
 793
 794 /*
 795 =============
 796 SetNewParms
 797 =============
 798 */
 799 void SetNewParms ()
 800 {
 801         // initialize parms for a new player
 802         parm1 = -(86400 * 366);
 803
 804         MUTATOR_CALLHOOK(SetNewParms);
 805 }
 806
 807 /*
 808 =============
 809 SetChangeParms
 810 =============
 811 */
 812 void SetChangeParms (entity this)
 813 {
 814         // save parms for level change
 815         parm1 = this.parm_idlesince - time;
 816
 817         MUTATOR_CALLHOOK(SetChangeParms);
 818 }
 819
 820 /*
 821 =============
 822 DecodeLevelParms
 823 =============
 824 */
 825 void DecodeLevelParms(entity this)
 826 {
 827         // load parms
 828         this.parm_idlesince = parm1;
 829         if (this.parm_idlesince == -(86400 * 366))
 830                 this.parm_idlesince = time;
 831
 832         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 833         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 834
 835         MUTATOR_CALLHOOK(DecodeLevelParms);
 836 }
 837
 838 /*
 839 =============
 840 ClientKill
 841
 842 Called when a client types 'kill' in the console
 843 =============
 844 */
 845
 846 .float clientkill_nexttime;
 847 void ClientKill_Now_TeamChange(entity this)
 848 {
 849         if(this.killindicator_teamchange == -1)
 850         {
 851                 JoinBestTeam( this, false, true );
 852         }
 853         else if(this.killindicator_teamchange == -2)
 854         {
 855                 if(blockSpectators)
 856                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 857                 PutObserverInServer(this);
 858         }
 859         else
 860                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 861         this.killindicator_teamchange = 0;
 862 }
 863
 864 void ClientKill_Now(entity this)
 865 {
 866         if(this.vehicle)
 867         {
 868             vehicles_exit(this.vehicle, VHEF_RELEASE);
 869             if(!this.killindicator_teamchange)
 870             {
 871             this.vehicle_health = -1;
 872             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 873             }
 874         }
 875
 876         if(this.killindicator && !wasfreed(this.killindicator))
 877                 delete(this.killindicator);
 878
 879         this.killindicator = NULL;
 880
 881         if(this.killindicator_teamchange)
 882                 ClientKill_Now_TeamChange(this);
 883
 884         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 885                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 886
 887         // now I am sure the player IS dead
 888 }
 889 void KillIndicator_Think(entity this)
 890 {
 891         if (game_stopped)
 892         {
 893                 this.owner.killindicator = NULL;
 894                 delete(this);
 895                 return;
 896         }
 897
 898         if (this.owner.alpha < 0 && !this.owner.vehicle)
 899         {
 900                 this.owner.killindicator = NULL;
 901                 delete(this);
 902                 return;
 903         }
 904
 905         if(this.cnt <= 0)
 906         {
 907                 ClientKill_Now(this.owner);
 908                 return;
 909         }
 910     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 911     {
 912         this.nextthink = time + 1;
 913         this.cnt -= 1;
 914     }
 915         else
 916         {
 917                 if(this.cnt <= 10)
 918                         setmodel(this, MDL_NUM(this.cnt));
 919                 if(IS_REAL_CLIENT(this.owner))
 920                 {
 921                         if(this.cnt <= 10)
 922                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 923                 }
 924                 this.nextthink = time + 1;
 925                 this.cnt -= 1;
 926         }
 927 }
 928
 929 float clientkilltime;
 930 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 931 {
 932         float killtime;
 933         float starttime;
 934
 935         if (game_stopped)
 936                 return;
 937
 938         killtime = autocvar_g_balance_kill_delay;
 939
 940         if(g_race_qualifying || g_cts)
 941                 killtime = 0;
 942
 943     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 944         return;
 945
 946         this.killindicator_teamchange = targetteam;
 947
 948     if(!this.killindicator)
 949         {
 950                 if(!IS_DEAD(this))
 951                 {
 952                         killtime = max(killtime, this.clientkill_nexttime - time);
 953                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 954                 }
 955
 956                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 957                 {
 958                         ClientKill_Now(this);
 959                 }
 960                 else
 961                 {
 962                         starttime = max(time, clientkilltime);
 963
 964                         this.killindicator = spawn();
 965                         this.killindicator.owner = this;
 966                         this.killindicator.scale = 0.5;
 967                         setattachment(this.killindicator, this, "");
 968                         setorigin(this.killindicator, '0 0 52');
 969                         setthink(this.killindicator, KillIndicator_Think);
 970                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 971                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 972                         this.killindicator.cnt = ceil(killtime);
 973                         this.killindicator.count = bound(0, ceil(killtime), 10);
 974                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 975
 976                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 977                         {
 978                                 it.killindicator = spawn();
 979                                 it.killindicator.owner = it;
 980                                 it.killindicator.scale = 0.5;
 981                                 setattachment(it.killindicator, it, "");
 982                                 setorigin(it.killindicator, '0 0 52');
 983                                 setthink(it.killindicator, KillIndicator_Think);
 984                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 985                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 986                                 it.killindicator.cnt = ceil(killtime);
 987                         });
 988                         this.lip = 0;
 989                 }
 990         }
 991         if(this.killindicator)
 992         {
 993                 if(targetteam == 0) // just die
 994                 {
 995                         this.killindicator.colormod = '0 0 0';
 996                         if(IS_REAL_CLIENT(this))
 997                         if(this.killindicator.cnt > 0)
 998                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 999                 }
1000                 else if(targetteam == -1) // auto
1001                 {
1002                         this.killindicator.colormod = '0 1 0';
1003                         if(IS_REAL_CLIENT(this))
1004                         if(this.killindicator.cnt > 0)
1005                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1006                 }
1007                 else if(targetteam == -2) // spectate
1008                 {
1009                         this.killindicator.colormod = '0.5 0.5 0.5';
1010                         if(IS_REAL_CLIENT(this))
1011                         if(this.killindicator.cnt > 0)
1012                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1013                 }
1014                 else
1015                 {
1016                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1017                         if(IS_REAL_CLIENT(this))
1018                         if(this.killindicator.cnt > 0)
1019                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1020                 }
1021         }
1022
1023 }
1024
1025 void ClientKill (entity this)
1026 {
1027         if(game_stopped) return;
1028         if(this.player_blocked) return;
1029         if(STAT(FROZEN, this)) return;
1030
1031         ClientKill_TeamChange(this, 0);
1032 }
1033
1034 void FixClientCvars(entity e)
1035 {
1036         // send prediction settings to the client
1037         stuffcmd(e, "\nin_bindmap 0 0\n");
1038         if(autocvar_g_antilag == 3) // client side hitscan
1039                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1040         if(autocvar_sv_gentle)
1041                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1042
1043         MUTATOR_CALLHOOK(FixClientCvars, e);
1044 }
1045
1046 float PlayerInIDList(entity p, string idlist)
1047 {
1048         float n, i;
1049         string s;
1050
1051         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1052         if (!p.crypto_idfp)
1053                 return 0;
1054
1055         // this function allows abbreviated player IDs too!
1056         n = tokenize_console(idlist);
1057         for(i = 0; i < n; ++i)
1058         {
1059                 s = argv(i);
1060                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1061                         return 1;
1062         }
1063
1064         return 0;
1065 }
1066
1067 #ifdef DP_EXT_PRECONNECT
1068 /*
1069 =============
1070 ClientPreConnect
1071
1072 Called once (not at each match start) when a client begins a connection to the server
1073 =============
1074 */
1075 void ClientPreConnect(entity this)
1076 {
1077         if(autocvar_sv_eventlog)
1078         {
1079                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1080                         this.playerid,
1081                         etof(this),
1082                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1083                 ));
1084         }
1085 }
1086 #endif
1087
1088 /**
1089 =============
1090 ClientConnect
1091
1092 Called when a client connects to the server
1093 =============
1094 */
1095 void ClientConnect(entity this)
1096 {
1097         if (Ban_MaybeEnforceBanOnce(this)) return;
1098         assert(!IS_CLIENT(this), return);
1099         this.flags |= FL_CLIENT;
1100         assert(player_count >= 0, player_count = 0);
1101
1102 #ifdef WATERMARK
1103         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1104 #endif
1105         this.version_nagtime = time + 10 + random() * 10;
1106         TRANSMUTE(Client, this);
1107
1108         // identify the right forced team
1109         if (autocvar_g_campaign)
1110         {
1111                 if (IS_REAL_CLIENT(this)) // only players, not bots
1112                 {
1113                         switch (autocvar_g_campaign_forceteam)
1114                         {
1115                                 case 1: this.team_forced = NUM_TEAM_1; break;
1116                                 case 2: this.team_forced = NUM_TEAM_2; break;
1117                                 case 3: this.team_forced = NUM_TEAM_3; break;
1118                                 case 4: this.team_forced = NUM_TEAM_4; break;
1119                                 default: this.team_forced = 0;
1120                         }
1121                 }
1122         }
1123         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1124         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1125         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1126         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1127         else switch (autocvar_g_forced_team_otherwise)
1128         {
1129                 default: this.team_forced = 0; break;
1130                 case "red": this.team_forced = NUM_TEAM_1; break;
1131                 case "blue": this.team_forced = NUM_TEAM_2; break;
1132                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1133                 case "pink": this.team_forced = NUM_TEAM_4; break;
1134                 case "spectate":
1135                 case "spectator":
1136                         this.team_forced = -1;
1137                         break;
1138         }
1139         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1140
1141     {
1142         int id = this.playerid;
1143         this.playerid = 0; // silent
1144             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1145             this.playerid = id;
1146     }
1147
1148         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1149                 TRANSMUTE(Observer, this);
1150         } else {
1151                 if (!teamplay || autocvar_g_balance_teams) {
1152                         TRANSMUTE(Player, this);
1153                         campaign_bots_may_start = true;
1154                 } else {
1155                         TRANSMUTE(Observer, this); // do it anyway
1156                 }
1157         }
1158
1159         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1160
1161         // always track bots, don't ask for cl_allow_uidtracking
1162     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1163
1164         if (autocvar_sv_eventlog)
1165                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1166
1167         LogTeamchange(this.playerid, this.team, 1);
1168
1169         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1170
1171         this.netname_previous = strzone(this.netname);
1172
1173         if(teamplay && IS_PLAYER(this))
1174                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1175         else
1176                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1177
1178         stuffcmd(this, clientstuff, "\n");
1179         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1180
1181         FixClientCvars(this);
1182
1183         // get version info from player
1184         stuffcmd(this, "cmd clientversion $gameversion\n");
1185
1186         // notify about available teams
1187         if (teamplay)
1188         {
1189                 CheckAllowedTeams(this);
1190                 int t = 0;
1191                 if (c1 >= 0) t |= BIT(0);
1192                 if (c2 >= 0) t |= BIT(1);
1193                 if (c3 >= 0) t |= BIT(2);
1194                 if (c4 >= 0) t |= BIT(3);
1195                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1196         }
1197         else
1198         {
1199                 stuffcmd(this, "set _teams_available 0\n");
1200         }
1201
1202         bot_relinkplayerlist();
1203
1204         this.spectatortime = time;
1205         if (blockSpectators)
1206         {
1207                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1208         }
1209
1210         this.jointime = time;
1211         this.allowed_timeouts = autocvar_sv_timeout_number;
1212
1213         if (IS_REAL_CLIENT(this))
1214         {
1215                 if (g_weaponarena_weapons == WEPSET(TUBA))
1216                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1217         }
1218
1219         if (!sv_foginterval && world.fog != "")
1220                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1221
1222         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1223                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1224                         send_CSQC_teamnagger();
1225
1226         CSQCMODEL_AUTOINIT(this);
1227
1228         this.model_randomizer = random();
1229
1230         if (IS_REAL_CLIENT(this))
1231                 sv_notice_join(this);
1232
1233         // update physics stats (players can spawn before physics runs)
1234         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1235         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1236         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1237
1238         IL_EACH(g_initforplayer, it.init_for_player, {
1239                 it.init_for_player(it, this);
1240         });
1241
1242         MUTATOR_CALLHOOK(ClientConnect, this);
1243
1244         if (IS_REAL_CLIENT(this))
1245         {
1246                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1247                 {
1248                         this.motd_actived_time = -1;
1249                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1250                 }
1251         }
1252 }
1253 /*
1254 =============
1255 ClientDisconnect
1256
1257 Called when a client disconnects from the server
1258 =============
1259 */
1260 .entity chatbubbleentity;
1261 void ReadyCount();
1262 void ClientDisconnect(entity this)
1263 {
1264         assert(IS_CLIENT(this), return);
1265
1266         PlayerStats_GameReport_FinalizePlayer(this);
1267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1268         if (this.active_minigame) part_minigame(this);
1269         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1270
1271         if (autocvar_sv_eventlog)
1272                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1273
1274         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1275
1276         if(IS_SPEC(this))
1277                 SetSpectatee(this, NULL);
1278
1279     MUTATOR_CALLHOOK(ClientDisconnect, this);
1280
1281         ClientState_detach(this);
1282
1283         Portal_ClearAll(this);
1284
1285         Unfreeze(this);
1286
1287         RemoveGrapplingHooks(this);
1288
1289         // Here, everything has been done that requires this player to be a client.
1290
1291         this.flags &= ~FL_CLIENT;
1292
1293         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1294         if (this.killindicator) delete(this.killindicator);
1295
1296         WaypointSprite_PlayerGone(this);
1297
1298         bot_relinkplayerlist();
1299
1300         if (this.netname_previous) strunzone(this.netname_previous);
1301         if (this.clientstatus) strunzone(this.clientstatus);
1302         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1303         if (this.personal) delete(this.personal);
1304
1305         this.playerid = 0;
1306         ReadyCount();
1307         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1308
1309         ONREMOVE(this);
1310 }
1311
1312 void ChatBubbleThink(entity this)
1313 {
1314         this.nextthink = time;
1315         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1316         {
1317                 if(this.owner) // but why can that ever be NULL?
1318                         this.owner.chatbubbleentity = NULL;
1319                 delete(this);
1320                 return;
1321         }
1322
1323         this.mdl = "";
1324
1325         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1326         {
1327                 if ( this.owner.active_minigame )
1328                         this.mdl = "models/sprites/minigame_busy.iqm";
1329                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1330                         this.mdl = "models/misc/chatbubble.spr";
1331         }
1332
1333         if ( this.model != this.mdl )
1334                 _setmodel(this, this.mdl);
1335
1336 }
1337
1338 void UpdateChatBubble(entity this)
1339 {
1340         if (this.alpha < 0)
1341                 return;
1342         // spawn a chatbubble entity if needed
1343         if (!this.chatbubbleentity)
1344         {
1345                 this.chatbubbleentity = new(chatbubbleentity);
1346                 this.chatbubbleentity.owner = this;
1347                 this.chatbubbleentity.exteriormodeltoclient = this;
1348                 setthink(this.chatbubbleentity, ChatBubbleThink);
1349                 this.chatbubbleentity.nextthink = time;
1350                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1351                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1352                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1353                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1354                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1355                 //this.chatbubbleentity.model = "";
1356                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1357         }
1358 }
1359
1360
1361 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1362 // added to the model skins
1363 /*void UpdateColorModHack()
1364 {
1365         float c;
1366         c = this.clientcolors & 15;
1367         // LordHavoc: only bothering to support white, green, red, yellow, blue
1368              if (!teamplay) this.colormod = '0 0 0';
1369         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1370         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1371         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1372         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1373         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1374         else this.colormod = '1 1 1';
1375 }*/
1376
1377 void respawn(entity this)
1378 {
1379         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1380         {
1381                 this.solid = SOLID_NOT;
1382                 this.takedamage = DAMAGE_NO;
1383                 set_movetype(this, MOVETYPE_FLY);
1384                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1385                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1386                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1387                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1388                 if(autocvar_g_respawn_ghosts_maxtime)
1389                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1390         }
1391
1392         CopyBody(this, 1);
1393
1394         this.effects |= EF_NODRAW; // prevent another CopyBody
1395         PutClientInServer(this);
1396 }
1397
1398 void play_countdown(entity this, float finished, Sound samp)
1399 {
1400     TC(Sound, samp);
1401         if(IS_REAL_CLIENT(this))
1402                 if(floor(finished - time - frametime) != floor(finished - time))
1403                         if(finished - time < 6)
1404                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1405 }
1406
1407 void player_powerups(entity this)
1408 {
1409         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1410         int items_prev = this.items;
1411
1412         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1413                 this.modelflags |= MF_ROCKET;
1414         else
1415                 this.modelflags &= ~MF_ROCKET;
1416
1417         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1418
1419         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1420                 return;
1421
1422         Fire_ApplyDamage(this);
1423         Fire_ApplyEffect(this);
1424
1425         if (!g_instagib)
1426         {
1427                 if (this.items & ITEM_Strength.m_itemid)
1428                 {
1429                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1430                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1431                         if (time > this.strength_finished)
1432                         {
1433                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1434                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1435                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1436                         }
1437                 }
1438                 else
1439                 {
1440                         if (time < this.strength_finished)
1441                         {
1442                                 this.items = this.items | ITEM_Strength.m_itemid;
1443                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1444                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1445                         }
1446                 }
1447                 if (this.items & ITEM_Shield.m_itemid)
1448                 {
1449                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1450                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1451                         if (time > this.invincible_finished)
1452                         {
1453                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1454                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1455                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1456                         }
1457                 }
1458                 else
1459                 {
1460                         if (time < this.invincible_finished)
1461                         {
1462                                 this.items = this.items | ITEM_Shield.m_itemid;
1463                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1465                         }
1466                 }
1467                 if (this.items & IT_SUPERWEAPON)
1468                 {
1469                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1470                         {
1471                                 this.superweapons_finished = 0;
1472                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1473                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1474                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1475                         }
1476                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1477                         {
1478                                 // don't let them run out
1479                         }
1480                         else
1481                         {
1482                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1483                                 if (time > this.superweapons_finished)
1484                                 {
1485                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1486                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1487                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1488                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1489                                 }
1490                         }
1491                 }
1492                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1493                 {
1494                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1495                         {
1496                                 this.items = this.items | IT_SUPERWEAPON;
1497                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1498                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1499                         }
1500                         else
1501                         {
1502                                 this.superweapons_finished = 0;
1503                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1504                         }
1505                 }
1506                 else
1507                 {
1508                         this.superweapons_finished = 0;
1509                 }
1510         }
1511
1512         if(autocvar_g_nodepthtestplayers)
1513                 this.effects = this.effects | EF_NODEPTHTEST;
1514
1515         if(autocvar_g_fullbrightplayers)
1516                 this.effects = this.effects | EF_FULLBRIGHT;
1517
1518         if (time >= game_starttime)
1519         if (time < this.spawnshieldtime)
1520                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1521
1522         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1523 }
1524
1525 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1526 {
1527         if(current > stable)
1528                 return current;
1529         else if(current > stable - 0.25) // when close enough, "snap"
1530                 return stable;
1531         else
1532                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1533 }
1534
1535 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1536 {
1537         if(current < stable)
1538                 return current;
1539         else if(current < stable + 0.25) // when close enough, "snap"
1540                 return stable;
1541         else
1542                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1543 }
1544
1545 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1546 {
1547         if(current > rotstable)
1548         {
1549                 if(rotframetime > 0)
1550                 {
1551                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1552                         current = max(rotstable, current - rotlinear * rotframetime);
1553                 }
1554         }
1555         else if(current < regenstable)
1556         {
1557                 if(regenframetime > 0)
1558                 {
1559                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1560                         current = min(regenstable, current + regenlinear * regenframetime);
1561                 }
1562         }
1563
1564         if(current > limit)
1565                 current = limit;
1566
1567         return current;
1568 }
1569
1570 void player_regen(entity this)
1571 {
1572         float max_mod, regen_mod, rot_mod, limit_mod;
1573         max_mod = regen_mod = rot_mod = limit_mod = 1;
1574
1575         float regen_health = autocvar_g_balance_health_regen;
1576         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1577         float regen_health_rot = autocvar_g_balance_health_rot;
1578         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1579         float regen_health_stable = autocvar_g_balance_health_regenstable;
1580         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1581         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1582                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1583         max_mod = M_ARGV(1, float);
1584         regen_mod = M_ARGV(2, float);
1585         rot_mod = M_ARGV(3, float);
1586         limit_mod = M_ARGV(4, float);
1587         regen_health = M_ARGV(5, float);
1588         regen_health_linear = M_ARGV(6, float);
1589         regen_health_rot = M_ARGV(7, float);
1590         regen_health_rotlinear = M_ARGV(8, float);
1591         regen_health_stable = M_ARGV(9, float);
1592         regen_health_rotstable = M_ARGV(10, float);
1593
1594
1595         if(!mutator_returnvalue)
1596         if(!STAT(FROZEN, this))
1597         {
1598                 float mina, maxa, limith, limita;
1599                 maxa = autocvar_g_balance_armor_rotstable;
1600                 mina = autocvar_g_balance_armor_regenstable;
1601                 limith = autocvar_g_balance_health_limit;
1602                 limita = autocvar_g_balance_armor_limit;
1603
1604                 regen_health_rotstable = regen_health_rotstable * max_mod;
1605                 regen_health_stable = regen_health_stable * max_mod;
1606                 limith = limith * limit_mod;
1607                 limita = limita * limit_mod;
1608
1609                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1610                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1611         }
1612
1613         // if player rotted to death...  die!
1614         // check this outside above checks, as player may still be able to rot to death
1615         if(this.health < 1)
1616         {
1617                 if(this.vehicle)
1618                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1619                 if(this.event_damage)
1620                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1621         }
1622
1623         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1624         {
1625                 float minf, maxf, limitf;
1626
1627                 maxf = autocvar_g_balance_fuel_rotstable;
1628                 minf = autocvar_g_balance_fuel_regenstable;
1629                 limitf = autocvar_g_balance_fuel_limit;
1630
1631                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1632         }
1633 }
1634
1635 bool zoomstate_set;
1636 void SetZoomState(entity this, float newzoom)
1637 {
1638         if(newzoom != this.zoomstate)
1639         {
1640                 this.zoomstate = newzoom;
1641                 ClientData_Touch(this);
1642         }
1643         zoomstate_set = true;
1644 }
1645
1646 void GetPressedKeys(entity this)
1647 {
1648         MUTATOR_CALLHOOK(GetPressedKeys, this);
1649         int keys = STAT(PRESSED_KEYS, this);
1650         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1651         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1652         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1653         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1654
1655         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1656         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1657         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1658         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1659         this.pressedkeys = keys; // store for other users
1660
1661         STAT(PRESSED_KEYS, this) = keys;
1662 }
1663
1664 /*
1665 ======================
1666 spectate mode routines
1667 ======================
1668 */
1669
1670 void SpectateCopy(entity this, entity spectatee)
1671 {
1672     TC(Client, this); TC(Client, spectatee);
1673
1674         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1675         PS(this) = PS(spectatee);
1676         this.armortype = spectatee.armortype;
1677         this.armorvalue = spectatee.armorvalue;
1678         this.ammo_cells = spectatee.ammo_cells;
1679         this.ammo_plasma = spectatee.ammo_plasma;
1680         this.ammo_shells = spectatee.ammo_shells;
1681         this.ammo_nails = spectatee.ammo_nails;
1682         this.ammo_rockets = spectatee.ammo_rockets;
1683         this.ammo_fuel = spectatee.ammo_fuel;
1684         this.clip_load = spectatee.clip_load;
1685         this.clip_size = spectatee.clip_size;
1686         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1687         this.health = spectatee.health;
1688         this.impulse = 0;
1689         this.items = spectatee.items;
1690         this.last_pickup = spectatee.last_pickup;
1691         this.hit_time = spectatee.hit_time;
1692         this.strength_finished = spectatee.strength_finished;
1693         this.invincible_finished = spectatee.invincible_finished;
1694         this.superweapons_finished = spectatee.superweapons_finished;
1695         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1696         this.weapons = spectatee.weapons;
1697         this.vortex_charge = spectatee.vortex_charge;
1698         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1699         this.hagar_load = spectatee.hagar_load;
1700         this.arc_heat_percent = spectatee.arc_heat_percent;
1701         this.minelayer_mines = spectatee.minelayer_mines;
1702         this.punchangle = spectatee.punchangle;
1703         this.view_ofs = spectatee.view_ofs;
1704         this.velocity = spectatee.velocity;
1705         this.dmg_take = spectatee.dmg_take;
1706         this.dmg_save = spectatee.dmg_save;
1707         this.dmg_inflictor = spectatee.dmg_inflictor;
1708         this.v_angle = spectatee.v_angle;
1709         this.angles = spectatee.v_angle;
1710         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1711         this.revive_progress = spectatee.revive_progress;
1712         this.viewloc = spectatee.viewloc;
1713         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1714                 this.fixangle = true;
1715         setorigin(this, spectatee.origin);
1716         setsize(this, spectatee.mins, spectatee.maxs);
1717         SetZoomState(this, spectatee.zoomstate);
1718
1719         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1720         {
1721                 .entity weaponentity = weaponentities[slot];
1722                 this.(weaponentity) = spectatee.(weaponentity);
1723         }
1724
1725         for(int slot = 0; slot < MAX_AXH; ++slot)
1726         {
1727                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1728         }
1729
1730     anticheat_spectatecopy(this, spectatee);
1731         this.hud = spectatee.hud;
1732         if(spectatee.vehicle)
1733     {
1734         this.angles = spectatee.v_angle;
1735
1736         //this.fixangle = false;
1737         //this.velocity = spectatee.vehicle.velocity;
1738         this.vehicle_health = spectatee.vehicle_health;
1739         this.vehicle_shield = spectatee.vehicle_shield;
1740         this.vehicle_energy = spectatee.vehicle_energy;
1741         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1742         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1743         this.vehicle_reload1 = spectatee.vehicle_reload1;
1744         this.vehicle_reload2 = spectatee.vehicle_reload2;
1745
1746         //msg_entity = this;
1747
1748        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1749             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1750            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1751            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1752
1753         //WriteByte (MSG_ONE, SVC_SETVIEW);
1754         //    WriteEntity(MSG_ONE, this);
1755         //makevectors(spectatee.v_angle);
1756         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1757     }
1758 }
1759
1760 bool SpectateUpdate(entity this)
1761 {
1762         if(!this.enemy)
1763                 return false;
1764
1765         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1766         {
1767                 SetSpectatee(this, NULL);
1768                 return false;
1769         }
1770
1771         SpectateCopy(this, this.enemy);
1772
1773         return true;
1774 }
1775
1776 bool SpectateSet(entity this)
1777 {
1778         if(!IS_PLAYER(this.enemy))
1779                 return false;
1780
1781         ClientData_Touch(this.enemy);
1782
1783         msg_entity = this;
1784         WriteByte(MSG_ONE, SVC_SETVIEW);
1785         WriteEntity(MSG_ONE, this.enemy);
1786         set_movetype(this, MOVETYPE_NONE);
1787         accuracy_resend(this);
1788
1789         if(!SpectateUpdate(this))
1790                 PutObserverInServer(this);
1791
1792         return true;
1793 }
1794
1795 void SetSpectatee_status(entity this, int spectatee_num)
1796 {
1797         int oldspectatee_status = this.spectatee_status;
1798         this.spectatee_status = spectatee_num;
1799
1800         if (this.spectatee_status != oldspectatee_status)
1801         {
1802                 ClientData_Touch(this);
1803                 if (g_race || g_cts) race_InitSpectator();
1804         }
1805 }
1806
1807 void SetSpectatee(entity this, entity spectatee)
1808 {
1809         entity old_spectatee = this.enemy;
1810
1811         this.enemy = spectatee;
1812
1813         // WEAPONTODO
1814         // these are required to fix the spectator bug with arc
1815         if(old_spectatee)
1816         {
1817                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1818                 {
1819                         .entity weaponentity = weaponentities[slot];
1820                         if(old_spectatee.(weaponentity).arc_beam)
1821                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1822                 }
1823         }
1824         if(this.enemy)
1825         {
1826                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1827                 {
1828                         .entity weaponentity = weaponentities[slot];
1829                         if(this.enemy.(weaponentity).arc_beam)
1830                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1831                 }
1832         }
1833
1834         if (this.enemy)
1835                 SetSpectatee_status(this, etof(this.enemy));
1836
1837         // needed to update spectator list
1838         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1839 }
1840
1841 bool Spectate(entity this, entity pl)
1842 {
1843         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1844                 return false;
1845         pl = M_ARGV(1, entity);
1846
1847         SetSpectatee(this, pl);
1848         return SpectateSet(this);
1849 }
1850
1851 bool SpectateNext(entity this)
1852 {
1853         entity ent = find(this.enemy, classname, STR_PLAYER);
1854
1855         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1856                 ent = M_ARGV(1, entity);
1857         else if (!ent)
1858                 ent = find(ent, classname, STR_PLAYER);
1859
1860         if(ent) { SetSpectatee(this, ent); }
1861
1862         return SpectateSet(this);
1863 }
1864
1865 bool SpectatePrev(entity this)
1866 {
1867         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1868         entity ent = findchain(classname, STR_PLAYER);
1869         if (!ent) // no player
1870                 return false;
1871
1872         entity first = ent;
1873         // skip players until current spectated player
1874         if(this.enemy)
1875         while(ent && ent != this.enemy)
1876                 ent = ent.chain;
1877
1878         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1879         {
1880                 case MUT_SPECPREV_FOUND:
1881                     ent = M_ARGV(1, entity);
1882                     break;
1883                 case MUT_SPECPREV_RETURN:
1884                     return true;
1885                 case MUT_SPECPREV_CONTINUE:
1886                 default:
1887                 {
1888                         if(ent.chain)
1889                                 ent = ent.chain;
1890                         else
1891                                 ent = first;
1892                         break;
1893                 }
1894         }
1895
1896         SetSpectatee(this, ent);
1897         return SpectateSet(this);
1898 }
1899
1900 /*
1901 =============
1902 ShowRespawnCountdown()
1903
1904 Update a respawn countdown display.
1905 =============
1906 */
1907 void ShowRespawnCountdown(entity this)
1908 {
1909         float number;
1910         if(!IS_DEAD(this)) // just respawned?
1911                 return;
1912         else
1913         {
1914                 number = ceil(this.respawn_time - time);
1915                 if(number <= 0)
1916                         return;
1917                 if(number <= this.respawn_countdown)
1918                 {
1919                         this.respawn_countdown = number - 1;
1920                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1921                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1922                 }
1923         }
1924 }
1925
1926 .bool team_selected;
1927 bool ShowTeamSelection(entity this)
1928 {
1929         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1930                 return false;
1931         stuffcmd(this, "menu_showteamselect\n");
1932         return true;
1933 }
1934 void Join(entity this)
1935 {
1936         TRANSMUTE(Player, this);
1937
1938         if(!this.team_selected)
1939         if(autocvar_g_campaign || autocvar_g_balance_teams)
1940                 JoinBestTeam(this, false, true);
1941
1942         if(autocvar_g_campaign)
1943                 campaign_bots_may_start = true;
1944
1945         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1946
1947         PutClientInServer(this);
1948
1949         if(teamplay && this.team != -1)
1950                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1951         else
1952                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1953         this.team_selected = false;
1954 }
1955
1956 /**
1957  * Determines whether the player is allowed to join. This depends on cvar
1958  * g_maxplayers, if it isn't used this function always return true, otherwise
1959  * it checks whether the number of currently playing players exceeds g_maxplayers.
1960  * @return int number of free slots for players, 0 if none
1961  */
1962 int nJoinAllowed(entity this, entity ignore)
1963 {
1964         if(!ignore)
1965         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1966         // so report 0 free slots if restricted
1967         {
1968                 if(autocvar_g_forced_team_otherwise == "spectate")
1969                         return 0;
1970                 if(autocvar_g_forced_team_otherwise == "spectator")
1971                         return 0;
1972         }
1973
1974         if(this && this.team_forced < 0)
1975                 return 0; // forced spectators can never join
1976
1977         // TODO simplify this
1978         int totalClients = 0;
1979         int currentlyPlaying = 0;
1980         FOREACH_CLIENT(true, LAMBDA(
1981                 if(it != ignore)
1982                         ++totalClients;
1983                 if(IS_REAL_CLIENT(it))
1984                 if(IS_PLAYER(it) || it.caplayer)
1985                         ++currentlyPlaying;
1986         ));
1987
1988         float free_slots = 0;
1989         if (!autocvar_g_maxplayers)
1990                 free_slots = maxclients - totalClients;
1991         else if(currentlyPlaying < autocvar_g_maxplayers)
1992                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1993
1994         static float join_prevent_msg_time = 0;
1995         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1996         {
1997                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1998                 join_prevent_msg_time = time + 3;
1999         }
2000
2001         return free_slots;
2002 }
2003
2004 /**
2005  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2006  * g_maxplayers_spectator_blocktime seconds
2007  */
2008 void checkSpectatorBlock(entity this)
2009 {
2010         if(IS_SPEC(this) || IS_OBSERVER(this))
2011         if(!this.caplayer)
2012         if(IS_REAL_CLIENT(this))
2013         {
2014                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2015                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2016                         dropclient(this);
2017                 }
2018         }
2019 }
2020
2021 void PrintWelcomeMessage(entity this)
2022 {
2023         if(this.motd_actived_time == 0)
2024         {
2025                 if (autocvar_g_campaign) {
2026                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2027                                 this.motd_actived_time = time;
2028                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2029                         }
2030                 } else {
2031                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2032                                 this.motd_actived_time = time;
2033                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2034                         }
2035                 }
2036         }
2037         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2038         {
2039                 if (autocvar_g_campaign) {
2040                         if (PHYS_INPUT_BUTTON_INFO(this))
2041                                 this.motd_actived_time = time;
2042                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2043                                 this.motd_actived_time = 0;
2044                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2045                         }
2046                 } else {
2047                         if (PHYS_INPUT_BUTTON_INFO(this))
2048                                 this.motd_actived_time = time;
2049                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2050                                 this.motd_actived_time = 0;
2051                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2052                         }
2053                 }
2054         }
2055         else //if(this.motd_actived_time < 0) // just connected, motd is active
2056         {
2057                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2058                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2059                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2060                 {
2061                         // instanctly hide MOTD
2062                         this.motd_actived_time = 0;
2063                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2064                 }
2065         }
2066 }
2067
2068 bool joinAllowed(entity this)
2069 {
2070         if (this.version_mismatch) return false;
2071         if (!nJoinAllowed(this, this)) return false;
2072         if (teamplay && lockteams) return false;
2073         if (ShowTeamSelection(this)) return false;
2074         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2075         return true;
2076 }
2077
2078 void ObserverThink(entity this)
2079 {
2080         if ( this.impulse )
2081         {
2082                 MinigameImpulse(this, this.impulse);
2083                 this.impulse = 0;
2084         }
2085
2086         if (this.flags & FL_JUMPRELEASED) {
2087                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2088                         this.flags &= ~FL_JUMPRELEASED;
2089                         this.flags |= FL_SPAWNING;
2090                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2091                         this.flags &= ~FL_JUMPRELEASED;
2092                         if(SpectateNext(this)) {
2093                                 TRANSMUTE(Spectator, this);
2094                         }
2095                 } else {
2096                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2097                         set_movetype(this, preferred_movetype);
2098                 }
2099         } else {
2100                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2101                         this.flags |= FL_JUMPRELEASED;
2102                         if(this.flags & FL_SPAWNING)
2103                         {
2104                                 this.flags &= ~FL_SPAWNING;
2105                                 Join(this);
2106                                 return;
2107                         }
2108                 }
2109         }
2110 }
2111
2112 void SpectatorThink(entity this)
2113 {
2114         if ( this.impulse )
2115         {
2116                 if(MinigameImpulse(this, this.impulse))
2117                         this.impulse = 0;
2118
2119                 if (this.impulse == IMP_weapon_drop.impulse)
2120                 {
2121                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2122                         this.impulse = 0;
2123                         return;
2124                 }
2125         }
2126
2127         if (this.flags & FL_JUMPRELEASED) {
2128                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2129                         this.flags &= ~FL_JUMPRELEASED;
2130                         this.flags |= FL_SPAWNING;
2131                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2132                         this.flags &= ~FL_JUMPRELEASED;
2133                         if(SpectateNext(this)) {
2134                                 TRANSMUTE(Spectator, this);
2135                         } else {
2136                                 TRANSMUTE(Observer, this);
2137                                 PutClientInServer(this);
2138                         }
2139                         this.impulse = 0;
2140                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2141                         this.flags &= ~FL_JUMPRELEASED;
2142                         if(SpectatePrev(this)) {
2143                                 TRANSMUTE(Spectator, this);
2144                         } else {
2145                                 TRANSMUTE(Observer, this);
2146                                 PutClientInServer(this);
2147                         }
2148                         this.impulse = 0;
2149                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2150                         this.flags &= ~FL_JUMPRELEASED;
2151                         TRANSMUTE(Observer, this);
2152                         PutClientInServer(this);
2153                 } else {
2154                         if(!SpectateUpdate(this))
2155                                 PutObserverInServer(this);
2156                 }
2157         } else {
2158                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2159                         this.flags |= FL_JUMPRELEASED;
2160                         if(this.flags & FL_SPAWNING)
2161                         {
2162                                 this.flags &= ~FL_SPAWNING;
2163                                 Join(this);
2164                                 return;
2165                         }
2166                 }
2167                 if(!SpectateUpdate(this))
2168                         PutObserverInServer(this);
2169         }
2170
2171         this.flags |= FL_CLIENT | FL_NOTARGET;
2172 }
2173
2174 void vehicles_enter (entity pl, entity veh);
2175 void PlayerUseKey(entity this)
2176 {
2177         if (!IS_PLAYER(this))
2178                 return;
2179
2180         if(this.vehicle)
2181         {
2182                 if(!game_stopped)
2183                 {
2184                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2185                         return;
2186                 }
2187         }
2188         else if(autocvar_g_vehicles_enter)
2189         {
2190                 if(!STAT(FROZEN, this))
2191                 if(!IS_DEAD(this))
2192                 if(!game_stopped)
2193                 {
2194                         entity head, closest_target = NULL;
2195                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2196
2197                         while(head) // find the closest acceptable target to enter
2198                         {
2199                                 if(IS_VEHICLE(head))
2200                                 if(!IS_DEAD(head))
2201                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2202                                 if(head.takedamage != DAMAGE_NO)
2203                                 {
2204                                         if(closest_target)
2205                                         {
2206                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2207                                                 { closest_target = head; }
2208                                         }
2209                                         else { closest_target = head; }
2210                                 }
2211
2212                                 head = head.chain;
2213                         }
2214
2215                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2216                 }
2217         }
2218
2219         // a use key was pressed; call handlers
2220         MUTATOR_CALLHOOK(PlayerUseKey, this);
2221 }
2222
2223
2224 /*
2225 =============
2226 PlayerPreThink
2227
2228 Called every frame for each client before the physics are run
2229 =============
2230 */
2231 .float usekeypressed;
2232 .float last_vehiclecheck;
2233 .int items_added;
2234 void PlayerPreThink (entity this)
2235 {
2236         WarpZone_PlayerPhysics_FixVAngle(this);
2237
2238     STAT(GAMESTARTTIME, this) = game_starttime;
2239         STAT(ROUNDSTARTTIME, this) = round_starttime;
2240         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2241         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2242
2243         STAT(WEAPONSINMAP, this) = weaponsInMap;
2244
2245         if (frametime) {
2246                 // physics frames: update anticheat stuff
2247                 anticheat_prethink(this);
2248         }
2249
2250         if (blockSpectators && frametime) {
2251                 // WORKAROUND: only use dropclient in server frames (frametime set).
2252                 // Never use it in cl_movement frames (frametime zero).
2253                 checkSpectatorBlock(this);
2254     }
2255
2256         zoomstate_set = false;
2257
2258         // Check for nameless players
2259         if (isInvisibleString(this.netname)) {
2260                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2261                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2262         }
2263         if (this.netname != this.netname_previous) {
2264                 if (autocvar_sv_eventlog) {
2265                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2266         }
2267                 if (this.netname_previous) strunzone(this.netname_previous);
2268                 this.netname_previous = strzone(this.netname);
2269         }
2270
2271         // version nagging
2272         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2273         this.version_nagtime = 0;
2274         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2275             // git client
2276         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2277             // git server
2278             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2279         } else {
2280             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2281             if (r < 0) { // old client
2282                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2283             } else if (r > 0) { // old server
2284                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2285             }
2286         }
2287     }
2288
2289         // GOD MODE info
2290         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2291         {
2292                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2293                 this.max_armorvalue = 0;
2294         }
2295
2296         if (STAT(FROZEN, this) == 2)
2297         {
2298                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2299                 this.health = max(1, this.revive_progress * start_health);
2300                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2301
2302                 if (this.revive_progress >= 1)
2303                         Unfreeze(this);
2304         }
2305         else if (STAT(FROZEN, this) == 3)
2306         {
2307                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2308                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2309
2310                 if (this.health < 1)
2311                 {
2312                         if (this.vehicle)
2313                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2314                         if(this.event_damage)
2315                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2316                 }
2317                 else if (this.revive_progress <= 0)
2318                         Unfreeze(this);
2319         }
2320
2321         MUTATOR_CALLHOOK(PlayerPreThink, this);
2322
2323         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2324         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2325         {
2326                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2327                 {
2328                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2329                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2330                         {
2331                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2332                         }
2333                         else if(!it.owner)
2334                         {
2335                                 if(!it.team || SAME_TEAM(this, it))
2336                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2337                                 else if(autocvar_g_vehicles_steal)
2338                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2339                         }
2340                 });
2341
2342                 this.last_vehiclecheck = time + 1;
2343         }
2344
2345         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2346         {
2347                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2348                         PlayerUseKey(this);
2349                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2350         }
2351
2352         if (IS_REAL_CLIENT(this))
2353                 PrintWelcomeMessage(this);
2354
2355         if (IS_PLAYER(this)) {
2356                 CheckRules_Player(this);
2357
2358                 if (game_stopped || intermission_running) {
2359                         this.modelflags &= ~MF_ROCKET;
2360                         if(intermission_running)
2361                                 IntermissionThink(this);
2362                         return;
2363                 }
2364
2365                 if (timeout_status == TIMEOUT_ACTIVE) {
2366             // don't allow the player to turn around while game is paused
2367                         // FIXME turn this into CSQC stuff
2368                         this.v_angle = this.lastV_angle;
2369                         this.angles = this.lastV_angle;
2370                         this.fixangle = true;
2371                 }
2372
2373                 if (frametime) player_powerups(this);
2374
2375                 if (IS_DEAD(this)) {
2376                         if (this.personal && g_race_qualifying) {
2377                                 if (time > this.respawn_time) {
2378                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2379                                         respawn(this);
2380                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2381                                 }
2382                         } else {
2383                                 if (frametime) player_anim(this);
2384
2385                                 if (this.respawn_flags & RESPAWN_DENY)
2386                                 {
2387                                         STAT(RESPAWN_TIME, this) = 0;
2388                                         return;
2389                                 }
2390
2391                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2392
2393                                 switch(this.deadflag)
2394                                 {
2395                                         case DEAD_DYING:
2396                                         {
2397                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2398                                                         this.deadflag = DEAD_RESPAWNING;
2399                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2400                                                         this.deadflag = DEAD_DEAD;
2401                                                 break;
2402                                         }
2403                                         case DEAD_DEAD:
2404                                         {
2405                                                 if (button_pressed)
2406                                                         this.deadflag = DEAD_RESPAWNABLE;
2407                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2408                                                         this.deadflag = DEAD_RESPAWNING;
2409                                                 break;
2410                                         }
2411                                         case DEAD_RESPAWNABLE:
2412                                         {
2413                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2414                                                         this.deadflag = DEAD_RESPAWNING;
2415                                                 break;
2416                                         }
2417                                         case DEAD_RESPAWNING:
2418                                         {
2419                                                 if (time > this.respawn_time)
2420                                                 {
2421                                                         this.respawn_time = time + 1; // only retry once a second
2422                                                         this.respawn_time_max = this.respawn_time;
2423                                                         respawn(this);
2424                                                 }
2425                                                 break;
2426                                         }
2427                                 }
2428
2429                                 ShowRespawnCountdown(this);
2430
2431                                 if (this.respawn_flags & RESPAWN_SILENT)
2432                                         STAT(RESPAWN_TIME, this) = 0;
2433                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2434                                 {
2435                                         if (time < this.respawn_time)
2436                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2437                                         else if (this.deadflag != DEAD_RESPAWNING)
2438                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2439                                 }
2440                                 else
2441                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2442                         }
2443
2444                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2445                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2446                                 STAT(RESPAWN_TIME, this) *= -1;
2447
2448                         return;
2449                 }
2450
2451                 this.prevorigin = this.origin;
2452
2453                 bool have_hook = false;
2454                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2455                 {
2456                         .entity weaponentity = weaponentities[slot];
2457                         if(this.(weaponentity).hook.state)
2458                         {
2459                                 have_hook = true;
2460                                 break;
2461                         }
2462                 }
2463                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2464                 if (have_hook) {
2465                         do_crouch = false;
2466                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2467                         do_crouch = false;
2468                 } else if (this.vehicle) {
2469                         do_crouch = false;
2470                 } else if (STAT(FROZEN, this)) {
2471                         do_crouch = false;
2472         }
2473
2474                 if (do_crouch) {
2475                         if (!this.crouch) {
2476                                 this.crouch = true;
2477                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2478                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2479                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2480                         }
2481                 } else if (this.crouch) {
2482             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2483             if (!trace_startsolid) {
2484                 this.crouch = false;
2485                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2486                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2487             }
2488                 }
2489
2490                 FixPlayermodel(this);
2491
2492                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2493                 //if(frametime)
2494                 {
2495                         this.items &= ~this.items_added;
2496
2497                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2498                         {
2499                                 .entity weaponentity = weaponentities[slot];
2500                                 W_WeaponFrame(this, weaponentity);
2501
2502                                 if(slot == 0)
2503                                 {
2504                                         this.clip_load = this.(weaponentity).clip_load;
2505                                         this.clip_size = this.(weaponentity).clip_size;
2506                                 }
2507                         }
2508
2509                         this.items_added = 0;
2510                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2511                 this.items_added |= IT_FUEL;
2512
2513                         this.items |= this.items_added;
2514                 }
2515
2516                 player_regen(this);
2517
2518                 // WEAPONTODO: Add a weapon request for this
2519                 // rot vortex charge to the charge limit
2520                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2521                 {
2522                         .entity weaponentity = weaponentities[slot];
2523                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2524                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2525                 }
2526
2527                 if (frametime) player_anim(this);
2528
2529                 // secret status
2530                 secrets_setstatus(this);
2531
2532                 // monsters status
2533                 monsters_setstatus(this);
2534
2535                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2536         }
2537         else if (game_stopped || intermission_running) {
2538                 if(intermission_running)
2539                         IntermissionThink(this);
2540                 return;
2541         }
2542         else if (IS_OBSERVER(this)) {
2543                 ObserverThink(this);
2544         }
2545         else if (IS_SPEC(this)) {
2546                 SpectatorThink(this);
2547         }
2548
2549         // WEAPONTODO: Add weapon request for this
2550         if (!zoomstate_set) {
2551                 bool wep_zoomed = false;
2552                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2553                 {
2554                         .entity weaponentity = weaponentities[slot];
2555                         Weapon thiswep = this.(weaponentity).m_weapon;
2556                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2557                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2558                 }
2559                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2560     }
2561
2562         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2563         {
2564                 this.teamkill_soundtime = 0;
2565
2566                 entity e = this.teamkill_soundsource;
2567                 entity oldpusher = e.pusher;
2568                 e.pusher = this;
2569                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2570                 e.pusher = oldpusher;
2571         }
2572
2573         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2574                 this.taunt_soundtime = 0;
2575                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2576         }
2577
2578         target_voicescript_next(this);
2579
2580         // WEAPONTODO: Move into weaponsystem somehow
2581         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2582         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2583         {
2584                 .entity weaponentity = weaponentities[slot];
2585                 if(this.(weaponentity).m_weapon == WEP_Null)
2586                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2587         }
2588 }
2589
2590 void DrownPlayer(entity this)
2591 {
2592         if(IS_DEAD(this))
2593                 return;
2594
2595         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2596         {
2597                 if(this.air_finished < time)
2598                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2599                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2600                 this.dmg = 2;
2601         }
2602         else if (this.air_finished < time)
2603         {       // drown!
2604                 if (this.pain_finished < time)
2605                 {
2606                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2607                         this.pain_finished = time + 0.5;
2608                 }
2609         }
2610 }
2611
2612 .bool move_qcphysics;
2613
2614 void Player_Physics(entity this)
2615 {
2616         set_movetype(this, this.move_movetype);
2617
2618         if(!this.move_qcphysics)
2619                 return;
2620
2621         if(!frametime && !this.pm_frametime)
2622                 return;
2623
2624         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2625
2626         this.pm_frametime = 0;
2627 }
2628
2629 /*
2630 =============
2631 PlayerPostThink
2632
2633 Called every frame for each client after the physics are run
2634 =============
2635 */
2636 .float idlekick_lasttimeleft;
2637 void PlayerPostThink (entity this)
2638 {
2639         Player_Physics(this);
2640
2641         if (sv_maxidle > 0)
2642         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2643         if (IS_REAL_CLIENT(this))
2644         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2645         {
2646                 int totalClients = 0;
2647                 if(sv_maxidle_slots > 0)
2648                 {
2649                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2650                         {
2651                                 ++totalClients;
2652                         });
2653                 }
2654
2655                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2656                 { /* do nothing */ }
2657                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2658                 {
2659                         if (this.idlekick_lasttimeleft)
2660                         {
2661                                 this.idlekick_lasttimeleft = 0;
2662                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2663                         }
2664                 }
2665                 else
2666                 {
2667                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2668                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2669                                 if (!this.idlekick_lasttimeleft)
2670                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2671                         }
2672                         if (timeleft <= 0) {
2673                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2674                                 dropclient(this);
2675                                 return;
2676                         }
2677                         else if (timeleft <= 10) {
2678                                 if (timeleft != this.idlekick_lasttimeleft) {
2679                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2680                 }
2681                                 this.idlekick_lasttimeleft = timeleft;
2682                         }
2683                 }
2684         }
2685
2686         CheatFrame(this);
2687
2688         //CheckPlayerJump();
2689         if (game_stopped)
2690         {
2691                 this.solid = SOLID_NOT;
2692                 this.takedamage = DAMAGE_NO;
2693                 set_movetype(this, MOVETYPE_NONE);
2694         }
2695
2696         if (IS_PLAYER(this)) {
2697                 DrownPlayer(this);
2698                 CheckRules_Player(this);
2699                 UpdateChatBubble(this);
2700                 if (this.impulse) ImpulseCommands(this);
2701                 if (game_stopped)
2702                 {
2703                         CSQCMODEL_AUTOUPDATE(this);
2704                         return;
2705                 }
2706                 GetPressedKeys(this);
2707         }
2708
2709         if (this.waypointsprite_attachedforcarrier) {
2710             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2711                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2712     }
2713
2714         playerdemo_write(this);
2715
2716         CSQCMODEL_AUTOUPDATE(this);
2717 }