qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include "compat/quake3.qh"
  36
  37 #include <common/effects/qc/globalsound.qh>
  38
  39 #include "../common/mapobjects/func/conveyor.qh"
  40 #include "../common/mapobjects/teleporters.qh"
  41 #include "../common/mapobjects/target/spawnpoint.qh"
  42 #include <common/mapobjects/trigger/counter.qh>
  43 #include <common/mapobjects/trigger/swamp.qh>
  44
  45 #include "../common/vehicles/all.qh"
  46
  47 #include "weapons/hitplot.qh"
  48 #include "weapons/weaponsystem.qh"
  49
  50 #include "../common/net_notice.qh"
  51 #include "../common/net_linked.qh"
  52 #include "../common/physics/player.qh"
  53
  54 #include <common/vehicles/sv_vehicles.qh>
  55
  56 #include "../common/items/_mod.qh"
  57
  58 #include "../common/mutators/mutator/waypoints/all.qh"
  59 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  60 #include <common/gamemodes/_mod.qh>
  61
  62 #include "../common/mapobjects/subs.qh"
  63 #include "../common/mapobjects/triggers.qh"
  64 #include "../common/mapobjects/trigger/secret.qh"
  65
  66 #include "../common/minigames/sv_minigames.qh"
  67
  68 #include "../common/items/inventory.qh"
  69
  70 #include "../common/monsters/sv_monsters.qh"
  71
  72 #include "../lib/warpzone/server.qh"
  73
  74 #include <common/mutators/mutator/overkill/oknex.qh>
  75
  76 STATIC_METHOD(Client, Add, void(Client this, int _team))
  77 {
  78     ClientConnect(this);
  79     TRANSMUTE(Player, this);
  80     this.frame = 12; // 7
  81     this.team = _team;
  82     PutClientInServer(this);
  83 }
  84
  85 STATIC_METHOD(Client, Remove, void(Client this))
  86 {
  87     TRANSMUTE(Observer, this);
  88     PutClientInServer(this);
  89     ClientDisconnect(this);
  90 }
  91
  92 void send_CSQC_teamnagger() {
  93         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  94 }
  95
  96 int CountSpectators(entity player, entity to)
  97 {
  98         if(!player) { return 0; } // not sure how, but best to be safe
  99
 100         int spec_count = 0;
 101
 102         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 103         {
 104                 spec_count++;
 105         });
 106
 107         return spec_count;
 108 }
 109
 110 void WriteSpectators(entity player, entity to)
 111 {
 112         if(!player) { return; } // not sure how, but best to be safe
 113
 114         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 115         {
 116                 WriteByte(MSG_ENTITY, num_for_edict(it));
 117         });
 118 }
 119
 120 bool ClientData_Send(entity this, entity to, int sf)
 121 {
 122         assert(to == this.owner, return false);
 123
 124         entity e = to;
 125         if (IS_SPEC(e)) e = e.enemy;
 126
 127         sf = 0;
 128         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 129         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 130         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 131         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 132
 133         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 134         WriteByte(MSG_ENTITY, sf);
 135
 136         if (sf & BIT(1))
 137                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 138
 139         if(sf & BIT(4))
 140         {
 141                 float specs = CountSpectators(e, to);
 142                 WriteByte(MSG_ENTITY, specs);
 143                 WriteSpectators(e, to);
 144         }
 145
 146         return true;
 147 }
 148
 149 void ClientData_Attach(entity this)
 150 {
 151         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 152         CS(this).clientdata.drawonlytoclient = this;
 153         CS(this).clientdata.owner = this;
 154 }
 155
 156 void ClientData_Detach(entity this)
 157 {
 158         delete(CS(this).clientdata);
 159         CS(this).clientdata = NULL;
 160 }
 161
 162 void ClientData_Touch(entity e)
 163 {
 164         entity cd = CS(e).clientdata;
 165         if (cd) { cd.SendFlags = 1; }
 166
 167         // make it spectatable
 168         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 169         {
 170                 entity cd = CS(it).clientdata;
 171                 if (cd) { cd.SendFlags = 1; }
 172         });
 173 }
 174
 175
 176 /*
 177 =============
 178 CheckPlayerModel
 179
 180 Checks if the argument string can be a valid playermodel.
 181 Returns a valid one in doubt.
 182 =============
 183 */
 184 string FallbackPlayerModel;
 185 string CheckPlayerModel(string plyermodel) {
 186         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 187         {
 188                 // note: we cannot summon Don Strunzone here, some player may
 189                 // still have the model string set. In case anyone manages how
 190                 // to change a cvar default, we'll have a small leak here.
 191                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 192         }
 193         // only in right path
 194         if( substring(plyermodel,0,14) != "models/player/")
 195                 return FallbackPlayerModel;
 196         // only good file extensions
 197         if(substring(plyermodel,-4,4) != ".zym")
 198         if(substring(plyermodel,-4,4) != ".dpm")
 199         if(substring(plyermodel,-4,4) != ".iqm")
 200         if(substring(plyermodel,-4,4) != ".md3")
 201         if(substring(plyermodel,-4,4) != ".psk")
 202                 return FallbackPlayerModel;
 203         // forbid the LOD models
 204         if(substring(plyermodel, -9,5) == "_lod1")
 205                 return FallbackPlayerModel;
 206         if(substring(plyermodel, -9,5) == "_lod2")
 207                 return FallbackPlayerModel;
 208         if(plyermodel != strtolower(plyermodel))
 209                 return FallbackPlayerModel;
 210         // also, restrict to server models
 211         if(autocvar_sv_servermodelsonly)
 212         {
 213                 if(!fexists(plyermodel))
 214                         return FallbackPlayerModel;
 215         }
 216         return plyermodel;
 217 }
 218
 219 void setplayermodel(entity e, string modelname)
 220 {
 221         precache_model(modelname);
 222         _setmodel(e, modelname);
 223         player_setupanimsformodel(e);
 224         if(!autocvar_g_debug_globalsounds)
 225                 UpdatePlayerSounds(e);
 226 }
 227
 228 /** putting a client as observer in the server */
 229 void PutObserverInServer(entity this)
 230 {
 231     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 232         PlayerState_detach(this);
 233
 234         if (IS_PLAYER(this))
 235         {
 236                 if(GetResource(this, RES_HEALTH) >= 1)
 237                 {
 238                         // despawn effect
 239                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 240                 }
 241
 242                 // was a player, recount votes and ready status
 243                 if(IS_REAL_CLIENT(this))
 244                 {
 245                         if (vote_called) { VoteCount(false); }
 246                         ReadyCount();
 247                 }
 248     }
 249
 250     {
 251         entity spot = SelectSpawnPoint(this, true);
 252         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 253         this.angles = vec2(spot.angles);
 254         this.fixangle = true;
 255         // offset it so that the spectator spawns higher off the ground, looks better this way
 256         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 257         if (IS_REAL_CLIENT(this))
 258         {
 259             msg_entity = this;
 260             WriteByte(MSG_ONE, SVC_SETVIEW);
 261             WriteEntity(MSG_ONE, this);
 262         }
 263         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 264         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 265         if(!autocvar_g_debug_globalsounds)
 266         {
 267                 // needed for player sounds
 268                 this.model = "";
 269                 FixPlayermodel(this);
 270         }
 271         setmodel(this, MDL_Null);
 272         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 273         this.view_ofs = '0 0 0';
 274     }
 275
 276     RemoveGrapplingHooks(this);
 277         Portal_ClearAll(this);
 278         Unfreeze(this, false);
 279         SetSpectatee(this, NULL);
 280
 281         if (this.alivetime)
 282         {
 283                 if (!warmup_stage)
 284                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 285                 this.alivetime = 0;
 286         }
 287
 288         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 289
 290         WaypointSprite_PlayerDead(this);
 291
 292         if (CS(this).killcount != FRAGS_SPECTATOR)
 293         {
 294                 if(!game_stopped)
 295                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 297         }
 298
 299         accuracy_resend(this);
 300
 301         CS(this).spectatortime = time;
 302         if(this.bot_attack)
 303                 IL_REMOVE(g_bot_targets, this);
 304         this.bot_attack = false;
 305         if(this.monster_attack)
 306                 IL_REMOVE(g_monster_targets, this);
 307         this.monster_attack = false;
 308     STAT(HUD, this) = HUD_NORMAL;
 309         TRANSMUTE(Observer, this);
 310         this.iscreature = false;
 311         this.teleportable = TELEPORT_SIMPLE;
 312         if(this.damagedbycontents)
 313                 IL_REMOVE(g_damagedbycontents, this);
 314         this.damagedbycontents = false;
 315         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 316         SetSpectatee_status(this, etof(this));
 317         this.takedamage = DAMAGE_NO;
 318         this.solid = SOLID_NOT;
 319         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 320         this.flags = FL_CLIENT | FL_NOTARGET;
 321         this.effects = 0;
 322         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 323         this.pauserotarmor_finished = 0;
 324         this.pauserothealth_finished = 0;
 325         this.pauseregen_finished = 0;
 326         this.damageforcescale = 0;
 327         this.death_time = 0;
 328         this.respawn_flags = 0;
 329         this.respawn_time = 0;
 330         STAT(RESPAWN_TIME, this) = 0;
 331         this.alpha = 0;
 332         this.scale = 0;
 333         this.fade_time = 0;
 334         this.pain_frame = 0;
 335         this.pain_finished = 0;
 336         this.strength_finished = 0;
 337         this.invincible_finished = 0;
 338         this.superweapons_finished = 0;
 339         //this.dphitcontentsmask = 0;
 340         this.dphitcontentsmask = DPCONTENTS_SOLID;
 341         if (autocvar_g_playerclip_collisions)
 342                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 343         this.pushltime = 0;
 344         this.istypefrag = 0;
 345         setthink(this, func_null);
 346         this.nextthink = 0;
 347         this.deadflag = DEAD_NO;
 348         this.crouch = false;
 349         STAT(REVIVE_PROGRESS, this) = 0;
 350         this.revival_time = 0;
 351         this.draggable = drag_undraggable;
 352
 353         this.items = 0;
 354         STAT(WEAPONS, this) = '0 0 0';
 355         this.drawonlytoclient = this;
 356
 357         this.viewloc = NULL;
 358
 359         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 360
 361         this.weaponmodel = "";
 362         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 363         {
 364                 this.weaponentities[slot] = NULL;
 365         }
 366         this.exteriorweaponentity = NULL;
 367         CS(this).killcount = FRAGS_SPECTATOR;
 368         this.velocity = '0 0 0';
 369         this.avelocity = '0 0 0';
 370         this.punchangle = '0 0 0';
 371         this.punchvector = '0 0 0';
 372         this.oldvelocity = this.velocity;
 373         this.fire_endtime = -1;
 374         this.event_damage = func_null;
 375         this.event_heal = func_null;
 376
 377         for(int slot = 0; slot < MAX_AXH; ++slot)
 378         {
 379                 entity axh = this.(AuxiliaryXhair[slot]);
 380                 this.(AuxiliaryXhair[slot]) = NULL;
 381
 382                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 383                         delete(axh);
 384         }
 385
 386         if (mutator_returnvalue)
 387         {
 388                 // mutator prevents resetting teams+score
 389         }
 390         else
 391         {
 392                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 393                 this.frags = FRAGS_SPECTATOR;
 394         }
 395         if (CS(this).just_joined)
 396                 CS(this).just_joined = false;
 397 }
 398
 399 int player_getspecies(entity this)
 400 {
 401         get_model_parameters(this.model, this.skin);
 402         int s = get_model_parameters_species;
 403         get_model_parameters(string_null, 0);
 404         if (s < 0) return SPECIES_HUMAN;
 405         return s;
 406 }
 407
 408 .float model_randomizer;
 409 void FixPlayermodel(entity player)
 410 {
 411         string defaultmodel = "";
 412         int defaultskin = 0;
 413         if(autocvar_sv_defaultcharacter)
 414         {
 415                 if(teamplay)
 416                 {
 417                         switch(player.team)
 418                         {
 419                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 420                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 421                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 422                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 423                         }
 424                 }
 425
 426                 if(defaultmodel == "")
 427                 {
 428                         defaultmodel = autocvar_sv_defaultplayermodel;
 429                         defaultskin = autocvar_sv_defaultplayerskin;
 430                 }
 431
 432                 int n = tokenize_console(defaultmodel);
 433                 if(n > 0)
 434                 {
 435                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 436                         // However, do NOT randomize if the player-selected model is in the list.
 437                         for (int i = 0; i < n; ++i)
 438                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 439                                         defaultmodel = argv(i);
 440                 }
 441
 442                 int i = strstrofs(defaultmodel, ":", 0);
 443                 if(i >= 0)
 444                 {
 445                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 446                         defaultmodel = substring(defaultmodel, 0, i);
 447                 }
 448         }
 449         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 450         {
 451                 if(teamplay)
 452                 {
 453                         switch(player.team)
 454                         {
 455                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 456                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 457                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 458                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 459                         }
 460                 }
 461
 462                 if(!defaultskin)
 463                         defaultskin = autocvar_sv_defaultplayerskin;
 464         }
 465
 466         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 467         defaultmodel = M_ARGV(0, string);
 468         defaultskin = M_ARGV(1, int);
 469
 470         bool chmdl = false;
 471         int oldskin;
 472         if(defaultmodel != "")
 473         {
 474                 if (defaultmodel != player.model)
 475                 {
 476                         vector m1 = player.mins;
 477                         vector m2 = player.maxs;
 478                         setplayermodel (player, defaultmodel);
 479                         setsize (player, m1, m2);
 480                         chmdl = true;
 481                 }
 482
 483                 oldskin = player.skin;
 484                 player.skin = defaultskin;
 485         } else {
 486                 if (player.playermodel != player.model || player.playermodel == "")
 487                 {
 488                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 489                         vector m1 = player.mins;
 490                         vector m2 = player.maxs;
 491                         setplayermodel (player, player.playermodel);
 492                         setsize (player, m1, m2);
 493                         chmdl = true;
 494                 }
 495
 496                 if(!autocvar_sv_defaultcharacterskin)
 497                 {
 498                         oldskin = player.skin;
 499                         player.skin = stof(player.playerskin);
 500                 }
 501                 else
 502                 {
 503                         oldskin = player.skin;
 504                         player.skin = defaultskin;
 505                 }
 506         }
 507
 508         if(chmdl || oldskin != player.skin) // model or skin has changed
 509         {
 510                 player.species = player_getspecies(player); // update species
 511                 if(!autocvar_g_debug_globalsounds)
 512                         UpdatePlayerSounds(player); // update skin sounds
 513         }
 514
 515         if(!teamplay)
 516                 if(strlen(autocvar_sv_defaultplayercolors))
 517                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 518                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 519 }
 520
 521 void PutPlayerInServer(entity this)
 522 {
 523         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 524
 525         PlayerState_attach(this);
 526         accuracy_resend(this);
 527
 528         if (this.team < 0)
 529                 TeamBalance_JoinBestTeam(this);
 530
 531         entity spot = SelectSpawnPoint(this, false);
 532         if (!spot) {
 533                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 534                 return; // spawn failed
 535         }
 536
 537         TRANSMUTE(Player, this);
 538
 539         CS(this).wasplayer = true;
 540         this.iscreature = true;
 541         this.teleportable = TELEPORT_NORMAL;
 542         if(!this.damagedbycontents)
 543                 IL_PUSH(g_damagedbycontents, this);
 544         this.damagedbycontents = true;
 545         set_movetype(this, MOVETYPE_WALK);
 546         this.solid = SOLID_SLIDEBOX;
 547         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 548         if (autocvar_g_playerclip_collisions)
 549                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 550         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 551                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 552         this.frags = FRAGS_PLAYER;
 553         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 554         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 555         if (autocvar__notarget)
 556                 this.flags |= FL_NOTARGET;
 557         this.takedamage = DAMAGE_AIM;
 558         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 559
 560         if (warmup_stage) {
 561                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 562                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 563                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 564                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 565                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 566                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 567                 SetResource(this, RES_HEALTH, warmup_start_health);
 568                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 569                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 570         } else {
 571                 SetResource(this, RES_SHELLS, start_ammo_shells);
 572                 SetResource(this, RES_BULLETS, start_ammo_nails);
 573                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 574                 SetResource(this, RES_CELLS, start_ammo_cells);
 575                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 576                 SetResource(this, RES_FUEL, start_ammo_fuel);
 577                 SetResource(this, RES_HEALTH, start_health);
 578                 SetResource(this, RES_ARMOR, start_armorvalue);
 579                 STAT(WEAPONS, this) = start_weapons;
 580                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 581                 {
 582                         GiveRandomWeapons(this, random_start_weapons_count,
 583                                 autocvar_g_random_start_weapons, random_start_ammo);
 584                 }
 585         }
 586         SetSpectatee_status(this, 0);
 587
 588         PS(this).dual_weapons = '0 0 0';
 589
 590         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 591
 592         this.items = start_items;
 593
 594         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 595         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 596         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 597         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 598         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 599         if (!sv_ready_restart_after_countdown && time < game_starttime)
 600         {
 601                 float f = game_starttime - time;
 602                 this.spawnshieldtime += f;
 603                 this.pauserotarmor_finished += f;
 604                 this.pauserothealth_finished += f;
 605                 this.pauseregen_finished += f;
 606         }
 607
 608         this.damageforcescale = autocvar_g_player_damageforcescale;
 609         this.death_time = 0;
 610         this.respawn_flags = 0;
 611         this.respawn_time = 0;
 612         STAT(RESPAWN_TIME, this) = 0;
 613         this.scale = autocvar_sv_player_scale;
 614         this.fade_time = 0;
 615         this.pain_frame = 0;
 616         this.pain_finished = 0;
 617         this.pushltime = 0;
 618         setthink(this, func_null); // players have no think function
 619         this.nextthink = 0;
 620         this.dmg_team = 0;
 621         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 622
 623         this.deadflag = DEAD_NO;
 624
 625         this.angles = spot.angles;
 626         this.angles_z = 0; // never spawn tilted even if the spot says to
 627         if (IS_BOT_CLIENT(this))
 628         {
 629                 this.v_angle = this.angles;
 630                 bot_aim_reset(this);
 631         }
 632         this.fixangle = true; // turn this way immediately
 633         this.oldvelocity = this.velocity = '0 0 0';
 634         this.avelocity = '0 0 0';
 635         this.punchangle = '0 0 0';
 636         this.punchvector = '0 0 0';
 637
 638         this.strength_finished = 0;
 639         this.invincible_finished = 0;
 640         this.fire_endtime = -1;
 641         STAT(REVIVE_PROGRESS, this) = 0;
 642         this.revival_time = 0;
 643
 644         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 645         STAT(BUFFS, this) = 0;
 646         STAT(BUFF_TIME, this) = 0;
 647
 648         this.air_finished = time + 12;
 649         this.waterlevel = WATERLEVEL_NONE;
 650         this.watertype = CONTENT_EMPTY;
 651
 652         entity spawnevent = new_pure(spawnevent);
 653         spawnevent.owner = this;
 654         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 655
 656         // Cut off any still running player sounds.
 657         stopsound(this, CH_PLAYER_SINGLE);
 658
 659         this.model = "";
 660         FixPlayermodel(this);
 661         this.drawonlytoclient = NULL;
 662
 663         this.viewloc = NULL;
 664
 665         for(int slot = 0; slot < MAX_AXH; ++slot)
 666         {
 667                 entity axh = this.(AuxiliaryXhair[slot]);
 668                 this.(AuxiliaryXhair[slot]) = NULL;
 669
 670                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 671                         delete(axh);
 672         }
 673
 674         this.spawnpoint_targ = NULL;
 675
 676         this.crouch = false;
 677         this.view_ofs = STAT(PL_VIEW_OFS, this);
 678         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 679         this.spawnorigin = spot.origin;
 680         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 681         // don't reset back to last position, even if new position is stuck in solid
 682         this.oldorigin = this.origin;
 683         if(this.conveyor)
 684                 IL_REMOVE(g_conveyed, this);
 685         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 686         if(this.swampslug)
 687                 delete(this.swampslug);
 688         this.in_swamp = false;
 689         STAT(HUD, this) = HUD_NORMAL;
 690
 691         this.event_damage = PlayerDamage;
 692         this.event_heal = PlayerHeal;
 693
 694         this.draggable = func_null;
 695
 696         if(!this.bot_attack)
 697                 IL_PUSH(g_bot_targets, this);
 698         this.bot_attack = true;
 699         if(!this.monster_attack)
 700                 IL_PUSH(g_monster_targets, this);
 701         this.monster_attack = true;
 702         navigation_dynamicgoal_init(this, false);
 703
 704         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 705
 706         // player was spectator
 707         if (CS(this).killcount == FRAGS_SPECTATOR) {
 708                 PlayerScore_Clear(this);
 709                 CS(this).killcount = 0;
 710                 CS(this).startplaytime = time;
 711         }
 712
 713         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 714         {
 715                 .entity weaponentity = weaponentities[slot];
 716                 entity oldwep = this.(weaponentity);
 717                 CL_SpawnWeaponentity(this, weaponentity);
 718                 if(oldwep && oldwep.owner == this)
 719                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 720         }
 721         this.alpha = default_player_alpha;
 722         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 723         this.exteriorweaponentity.alpha = default_weapon_alpha;
 724
 725         this.speedrunning = false;
 726
 727         this.counter_cnt = 0;
 728         this.fragsfilter_cnt = 0;
 729
 730         target_voicescript_clear(this);
 731
 732         // reset fields the weapons may use
 733         FOREACH(Weapons, true, {
 734                 it.wr_resetplayer(it, this);
 735                         // reload all reloadable weapons
 736                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 737                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 738                         {
 739                                 .entity weaponentity = weaponentities[slot];
 740                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 741                         }
 742                 }
 743         });
 744
 745         {
 746                 string s = spot.target;
 747                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 748                         spot.target = string_null;
 749                 SUB_UseTargets(spot, this, NULL);
 750                 if(g_assault || g_race)
 751                         spot.target = s;
 752         }
 753
 754         Unfreeze(this, false);
 755
 756         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 757
 758         if (autocvar_spawn_debug)
 759         {
 760                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 761                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 762         }
 763
 764         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 765         {
 766                 .entity weaponentity = weaponentities[slot];
 767                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 768                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 769                 else
 770                         this.(weaponentity).m_switchweapon = WEP_Null;
 771                 this.(weaponentity).m_weapon = WEP_Null;
 772                 this.(weaponentity).weaponname = "";
 773                 this.(weaponentity).m_switchingweapon = WEP_Null;
 774                 this.(weaponentity).cnt = -1;
 775         }
 776
 777         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 778
 779         if (CS(this).impulse) ImpulseCommands(this);
 780
 781         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 782         {
 783                 .entity weaponentity = weaponentities[slot];
 784                 W_WeaponFrame(this, weaponentity);
 785         }
 786
 787         if (!warmup_stage && !this.alivetime)
 788                 this.alivetime = time;
 789
 790         antilag_clear(this, CS(this));
 791 }
 792
 793 /** Called when a client spawns in the server */
 794 void PutClientInServer(entity this)
 795 {
 796         if (IS_BOT_CLIENT(this)) {
 797                 TRANSMUTE(Player, this);
 798         } else if (IS_REAL_CLIENT(this)) {
 799                 msg_entity = this;
 800                 WriteByte(MSG_ONE, SVC_SETVIEW);
 801                 WriteEntity(MSG_ONE, this);
 802         }
 803         if (game_stopped)
 804                 TRANSMUTE(Observer, this);
 805
 806         SetSpectatee(this, NULL);
 807
 808         // reset player keys
 809         if(PS(this))
 810                 PS(this).itemkeys = 0;
 811
 812         MUTATOR_CALLHOOK(PutClientInServer, this);
 813
 814         if (IS_OBSERVER(this)) {
 815                 PutObserverInServer(this);
 816         } else if (IS_PLAYER(this)) {
 817                 PutPlayerInServer(this);
 818         }
 819 }
 820
 821 // TODO do we need all these fields, or should we stop autodetecting runtime
 822 // changes and just have a console command to update this?
 823 bool ClientInit_SendEntity(entity this, entity to, int sf)
 824 {
 825         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 826         return = true;
 827         msg_entity = to;
 828         // MSG_INIT replacement
 829         // TODO: make easier to use
 830         Registry_send_all();
 831         W_PROP_reload(MSG_ONE, to);
 832         ClientInit_misc(this);
 833         MUTATOR_CALLHOOK(Ent_Init);
 834 }
 835 void ClientInit_misc(entity this)
 836 {
 837         int channel = MSG_ONE;
 838         WriteHeader(channel, ENT_CLIENT_INIT);
 839         WriteByte(channel, g_nexball_meter_period * 32);
 840         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 841         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 842         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 843         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 844         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 845         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 846         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 847         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 848
 849         if(sv_foginterval && world.fog != "")
 850                 WriteString(channel, world.fog);
 851         else
 852                 WriteString(channel, "");
 853         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 854         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 855         WriteByte(channel, serverflags);
 856         WriteCoord(channel, autocvar_g_trueaim_minrange);
 857 }
 858
 859 void ClientInit_CheckUpdate(entity this)
 860 {
 861         this.nextthink = time;
 862         if(this.count != autocvar_g_balance_armor_blockpercent)
 863         {
 864                 this.count = autocvar_g_balance_armor_blockpercent;
 865                 this.SendFlags |= 1;
 866         }
 867         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 868         {
 869                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 870                 this.SendFlags |= 1;
 871         }
 872 }
 873
 874 void ClientInit_Spawn()
 875 {
 876         entity e = new_pure(clientinit);
 877         setthink(e, ClientInit_CheckUpdate);
 878         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 879
 880         ClientInit_CheckUpdate(e);
 881 }
 882
 883 /*
 884 =============
 885 SetNewParms
 886 =============
 887 */
 888 void SetNewParms ()
 889 {
 890         // initialize parms for a new player
 891         parm1 = -(86400 * 366);
 892
 893         MUTATOR_CALLHOOK(SetNewParms);
 894 }
 895
 896 /*
 897 =============
 898 SetChangeParms
 899 =============
 900 */
 901 void SetChangeParms (entity this)
 902 {
 903         // save parms for level change
 904         parm1 = CS(this).parm_idlesince - time;
 905
 906         MUTATOR_CALLHOOK(SetChangeParms);
 907 }
 908
 909 /*
 910 =============
 911 DecodeLevelParms
 912 =============
 913 */
 914 void DecodeLevelParms(entity this)
 915 {
 916         // load parms
 917         CS(this).parm_idlesince = parm1;
 918         if (CS(this).parm_idlesince == -(86400 * 366))
 919                 CS(this).parm_idlesince = time;
 920
 921         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 922         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 923
 924         MUTATOR_CALLHOOK(DecodeLevelParms);
 925 }
 926
 927 void FixClientCvars(entity e)
 928 {
 929         // send prediction settings to the client
 930         stuffcmd(e, "\nin_bindmap 0 0\n");
 931         if(autocvar_g_antilag == 3) // client side hitscan
 932                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 933         if(autocvar_sv_gentle)
 934                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 935
 936         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 937         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 938
 939         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 940
 941         MUTATOR_CALLHOOK(FixClientCvars, e);
 942 }
 943
 944 bool findinlist_abbrev(string tofind, string list)
 945 {
 946         if(list == "" || tofind == "")
 947                 return false; // empty list or search, just return
 948
 949         // this function allows abbreviated strings!
 950         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 951         {
 952                 return true;
 953         });
 954
 955         return false;
 956 }
 957
 958 bool PlayerInIPList(entity p, string iplist)
 959 {
 960         // some safety checks (never allow local?)
 961         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 962                 return false;
 963
 964         return findinlist_abbrev(p.netaddress, iplist);
 965 }
 966
 967 bool PlayerInIDList(entity p, string idlist)
 968 {
 969         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 970         if(!p.crypto_idfp)
 971                 return false;
 972
 973         return findinlist_abbrev(p.crypto_idfp, idlist);
 974 }
 975
 976 bool PlayerInList(entity player, string list)
 977 {
 978         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 979 }
 980
 981 #ifdef DP_EXT_PRECONNECT
 982 /*
 983 =============
 984 ClientPreConnect
 985
 986 Called once (not at each match start) when a client begins a connection to the server
 987 =============
 988 */
 989 void ClientPreConnect(entity this)
 990 {
 991         if(autocvar_sv_eventlog)
 992         {
 993                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 994                         this.playerid,
 995                         etof(this),
 996                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 997                 ));
 998         }
 999 }
1000 #endif
1001
1002 string GetClientVersionMessage(entity this)
1003 {
1004         if (CS(this).version_mismatch) {
1005                 if(CS(this).version < autocvar_gameversion) {
1006                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1007                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1008                 } else {
1009                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1010                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1011                 }
1012         } else {
1013                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1014         }
1015 }
1016
1017 string getwelcomemessage(entity this)
1018 {
1019         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1020         string modifications = M_ARGV(0, string);
1021
1022         if(g_weaponarena)
1023         {
1024                 if(g_weaponarena_random)
1025                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1026                 else
1027                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1028         }
1029         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1030                 modifications = strcat(modifications, ", No start weapons");
1031         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1032                 modifications = strcat(modifications, ", Low gravity");
1033         if(g_weapon_stay && !g_cts)
1034                 modifications = strcat(modifications, ", Weapons stay");
1035         if(g_jetpack)
1036                 modifications = strcat(modifications, ", Jet pack");
1037         if(autocvar_g_powerups == 0)
1038                 modifications = strcat(modifications, ", No powerups");
1039         if(autocvar_g_powerups > 0)
1040                 modifications = strcat(modifications, ", Powerups");
1041         modifications = substring(modifications, 2, strlen(modifications) - 2);
1042
1043         string versionmessage = GetClientVersionMessage(this);
1044         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1045
1046         if(modifications != "")
1047                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1048
1049         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1050         {
1051                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1052                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1053         }
1054
1055         if (cache_mutatormsg != "") {
1056                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1057         }
1058
1059         string mutator_msg = "";
1060         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1061         mutator_msg = M_ARGV(0, string);
1062
1063         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1064
1065         string motd = autocvar_sv_motd;
1066         if (motd != "") {
1067                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1068         }
1069         return s;
1070 }
1071
1072 bool autocvar_sv_qcphysics = false; // TODO this is for testing - remove when qcphysics work
1073
1074 /**
1075 =============
1076 ClientConnect
1077
1078 Called when a client connects to the server
1079 =============
1080 */
1081 void ClientConnect(entity this)
1082 {
1083         if (Ban_MaybeEnforceBanOnce(this)) return;
1084         assert(!IS_CLIENT(this), return);
1085         this.flags |= FL_CLIENT;
1086         assert(player_count >= 0, player_count = 0);
1087
1088 #ifdef WATERMARK
1089         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1090 #endif
1091         TRANSMUTE(Client, this);
1092         CS(this).version_nagtime = time + 10 + random() * 10;
1093
1094         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1095
1096         bot_clientconnect(this);
1097
1098         Player_DetermineForcedTeam(this);
1099
1100         TRANSMUTE(Observer, this);
1101
1102         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1103
1104         // always track bots, don't ask for cl_allow_uidtracking
1105         if (IS_BOT_CLIENT(this))
1106                 PlayerStats_GameReport_AddPlayer(this);
1107         else
1108                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1109
1110         if (autocvar_sv_eventlog)
1111                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1112
1113         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1114
1115         stuffcmd(this, clientstuff, "\n");
1116         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1117
1118         FixClientCvars(this);
1119
1120         // get version info from player
1121         stuffcmd(this, "cmd clientversion $gameversion\n");
1122
1123         // notify about available teams
1124         if (teamplay)
1125         {
1126                 entity balance = TeamBalance_CheckAllowedTeams(this);
1127                 int t = TeamBalance_GetAllowedTeams(balance);
1128                 TeamBalance_Destroy(balance);
1129                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1130         }
1131         else
1132         {
1133                 stuffcmd(this, "set _teams_available 0\n");
1134         }
1135
1136         bot_relinkplayerlist();
1137
1138         CS(this).spectatortime = time;
1139         if (blockSpectators)
1140         {
1141                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1142         }
1143
1144         CS(this).jointime = time;
1145
1146         if (IS_REAL_CLIENT(this))
1147         {
1148                 if (g_weaponarena_weapons == WEPSET(TUBA))
1149                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1150         }
1151
1152         if (!sv_foginterval && world.fog != "")
1153                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1154
1155         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1156                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1157                         send_CSQC_teamnagger();
1158
1159         CSQCMODEL_AUTOINIT(this);
1160
1161         CS(this).model_randomizer = random();
1162
1163         if (IS_REAL_CLIENT(this))
1164                 sv_notice_join(this);
1165
1166         this.move_qcphysics = autocvar_sv_qcphysics;
1167
1168         // update physics stats (players can spawn before physics runs)
1169         Physics_UpdateStats(this);
1170
1171         IL_EACH(g_initforplayer, it.init_for_player, {
1172                 it.init_for_player(it, this);
1173         });
1174
1175         Handicap_Initialize(this);
1176
1177         MUTATOR_CALLHOOK(ClientConnect, this);
1178
1179         if (IS_REAL_CLIENT(this))
1180         {
1181                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1182                 {
1183                         CS(this).motd_actived_time = -1;
1184                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1185                 }
1186         }
1187 }
1188 /*
1189 =============
1190 ClientDisconnect
1191
1192 Called when a client disconnects from the server
1193 =============
1194 */
1195 .entity chatbubbleentity;
1196 void ClientDisconnect(entity this)
1197 {
1198         assert(IS_CLIENT(this), return);
1199
1200         PlayerStats_GameReport_FinalizePlayer(this);
1201         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1202         if (CS(this).active_minigame) part_minigame(this);
1203         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1204
1205         if (autocvar_sv_eventlog)
1206                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1207
1208         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1209
1210         if(IS_SPEC(this))
1211                 SetSpectatee(this, NULL);
1212
1213     MUTATOR_CALLHOOK(ClientDisconnect, this);
1214
1215         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1216         strfree(CS(this).weaponorder_byimpulse);
1217         ClientState_detach(this);
1218
1219         Portal_ClearAll(this);
1220
1221         Unfreeze(this, false);
1222
1223         RemoveGrapplingHooks(this);
1224
1225         // Here, everything has been done that requires this player to be a client.
1226
1227         this.flags &= ~FL_CLIENT;
1228
1229         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1230         if (this.killindicator) delete(this.killindicator);
1231
1232         WaypointSprite_PlayerGone(this);
1233
1234         bot_relinkplayerlist();
1235
1236         strfree(this.clientstatus);
1237         if (this.personal) delete(this.personal);
1238
1239         this.playerid = 0;
1240         ReadyCount();
1241         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1242
1243         ONREMOVE(this);
1244 }
1245
1246 void ChatBubbleThink(entity this)
1247 {
1248         this.nextthink = time;
1249         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1250         {
1251                 if(this.owner) // but why can that ever be NULL?
1252                         this.owner.chatbubbleentity = NULL;
1253                 delete(this);
1254                 return;
1255         }
1256
1257         this.mdl = "";
1258
1259         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1260         {
1261                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1262                         this.mdl = "models/sprites/minigame_busy.iqm";
1263                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1264                         this.mdl = "models/misc/chatbubble.spr";
1265         }
1266
1267         if ( this.model != this.mdl )
1268                 _setmodel(this, this.mdl);
1269
1270 }
1271
1272 void UpdateChatBubble(entity this)
1273 {
1274         if (this.alpha < 0)
1275                 return;
1276         // spawn a chatbubble entity if needed
1277         if (!this.chatbubbleentity)
1278         {
1279                 this.chatbubbleentity = new(chatbubbleentity);
1280                 this.chatbubbleentity.owner = this;
1281                 this.chatbubbleentity.exteriormodeltoclient = this;
1282                 setthink(this.chatbubbleentity, ChatBubbleThink);
1283                 this.chatbubbleentity.nextthink = time;
1284                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1285                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1286                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1287                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1288                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1289                 //this.chatbubbleentity.model = "";
1290                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1291         }
1292 }
1293
1294
1295 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1296 // added to the model skins
1297 /*void UpdateColorModHack()
1298 {
1299         float c;
1300         c = this.clientcolors & 15;
1301         // LordHavoc: only bothering to support white, green, red, yellow, blue
1302              if (!teamplay) this.colormod = '0 0 0';
1303         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1304         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1305         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1306         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1307         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1308         else this.colormod = '1 1 1';
1309 }*/
1310
1311 void respawn(entity this)
1312 {
1313         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1314         {
1315                 this.solid = SOLID_NOT;
1316                 this.takedamage = DAMAGE_NO;
1317                 set_movetype(this, MOVETYPE_FLY);
1318                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1319                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1320                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1321                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1322                 if(autocvar_g_respawn_ghosts_maxtime)
1323                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1324         }
1325
1326         CopyBody(this, 1);
1327
1328         this.effects |= EF_NODRAW; // prevent another CopyBody
1329         PutClientInServer(this);
1330 }
1331
1332 ERASEABLE
1333 void PrintToChat(entity client, string text)
1334 {
1335         text = strcat("\{1}^7", text, "\n");
1336         sprint(client, text);
1337 }
1338
1339 ERASEABLE
1340 void DebugPrintToChat(entity client, string text)
1341 {
1342         if (autocvar_developer > 0)
1343         {
1344                 PrintToChat(client, text);
1345         }
1346 }
1347
1348 ERASEABLE
1349 void PrintToChatAll(string text)
1350 {
1351         text = strcat("\{1}^7", text, "\n");
1352         bprint(text);
1353 }
1354
1355 ERASEABLE
1356 void DebugPrintToChatAll(string text)
1357 {
1358         if (autocvar_developer > 0)
1359         {
1360                 PrintToChatAll(text);
1361         }
1362 }
1363
1364 ERASEABLE
1365 void PrintToChatTeam(int team_num, string text)
1366 {
1367         text = strcat("\{1}^7", text, "\n");
1368         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1369         {
1370                 if (it.team == team_num)
1371                 {
1372                         sprint(it, text);
1373                 }
1374         });
1375 }
1376
1377 ERASEABLE
1378 void DebugPrintToChatTeam(int team_num, string text)
1379 {
1380         if (autocvar_developer > 0)
1381         {
1382                 PrintToChatTeam(team_num, text);
1383         }
1384 }
1385
1386 void play_countdown(entity this, float finished, Sound samp)
1387 {
1388         TC(Sound, samp);
1389         if(IS_REAL_CLIENT(this))
1390                 if(floor(finished - time - frametime) != floor(finished - time))
1391                         if(finished - time < 6)
1392                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1393 }
1394
1395 void player_powerups(entity this)
1396 {
1397         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1398         int items_prev = this.items;
1399
1400         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1401                 this.modelflags |= MF_ROCKET;
1402         else
1403                 this.modelflags &= ~MF_ROCKET;
1404
1405         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1406
1407         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1408                 return;
1409
1410         Fire_ApplyDamage(this);
1411         Fire_ApplyEffect(this);
1412
1413         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1414         {
1415                 if (this.items & ITEM_Strength.m_itemid)
1416                 {
1417                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1418                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1419                         if (time > this.strength_finished)
1420                         {
1421                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1422                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1423                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1424                         }
1425                 }
1426                 else
1427                 {
1428                         if (time < this.strength_finished)
1429                         {
1430                                 this.items = this.items | ITEM_Strength.m_itemid;
1431                                 if(!g_cts)
1432                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1433                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1434                         }
1435                 }
1436                 if (this.items & ITEM_Shield.m_itemid)
1437                 {
1438                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1439                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1440                         if (time > this.invincible_finished)
1441                         {
1442                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1443                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1444                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1445                         }
1446                 }
1447                 else
1448                 {
1449                         if (time < this.invincible_finished)
1450                         {
1451                                 this.items = this.items | ITEM_Shield.m_itemid;
1452                                 if(!g_cts)
1453                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1454                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1455                         }
1456                 }
1457                 if (this.items & IT_SUPERWEAPON)
1458                 {
1459                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1460                         {
1461                                 this.superweapons_finished = 0;
1462                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1463                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1465                         }
1466                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1467                         {
1468                                 // don't let them run out
1469                         }
1470                         else
1471                         {
1472                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1473                                 if (time > this.superweapons_finished)
1474                                 {
1475                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1476                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1477                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1478                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1479                                 }
1480                         }
1481                 }
1482                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1483                 {
1484                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1485                         {
1486                                 this.items = this.items | IT_SUPERWEAPON;
1487                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1488                                 {
1489                                         if(!g_cts)
1490                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1491                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1492                                 }
1493                         }
1494                         else
1495                         {
1496                                 this.superweapons_finished = 0;
1497                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1498                         }
1499                 }
1500                 else
1501                 {
1502                         this.superweapons_finished = 0;
1503                 }
1504         }
1505
1506         if(autocvar_g_nodepthtestplayers)
1507                 this.effects = this.effects | EF_NODEPTHTEST;
1508
1509         if(autocvar_g_fullbrightplayers)
1510                 this.effects = this.effects | EF_FULLBRIGHT;
1511
1512         if (time >= game_starttime)
1513         if (time < this.spawnshieldtime)
1514                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1515
1516         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1517 }
1518
1519 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1520 {
1521         if(current > stable)
1522                 return current;
1523         else if(current > stable - 0.25) // when close enough, "snap"
1524                 return stable;
1525         else
1526                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1527 }
1528
1529 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1530 {
1531         if(current < stable)
1532                 return current;
1533         else if(current < stable + 0.25) // when close enough, "snap"
1534                 return stable;
1535         else
1536                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1537 }
1538
1539 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1540 {
1541         if(current > rotstable)
1542         {
1543                 if(rotframetime > 0)
1544                 {
1545                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1546                         current = max(rotstable, current - rotlinear * rotframetime);
1547                 }
1548         }
1549         else if(current < regenstable)
1550         {
1551                 if(regenframetime > 0)
1552                 {
1553                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1554                         current = min(regenstable, current + regenlinear * regenframetime);
1555                 }
1556         }
1557
1558         if(current > limit)
1559                 current = limit;
1560
1561         return current;
1562 }
1563
1564 void player_regen(entity this)
1565 {
1566         float max_mod, regen_mod, rot_mod, limit_mod;
1567         max_mod = regen_mod = rot_mod = limit_mod = 1;
1568
1569         float regen_health = autocvar_g_balance_health_regen;
1570         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1571         float regen_health_rot = autocvar_g_balance_health_rot;
1572         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1573         float regen_health_stable = autocvar_g_balance_health_regenstable;
1574         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1575         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1576                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1577         max_mod = M_ARGV(1, float);
1578         regen_mod = M_ARGV(2, float);
1579         rot_mod = M_ARGV(3, float);
1580         limit_mod = M_ARGV(4, float);
1581         regen_health = M_ARGV(5, float);
1582         regen_health_linear = M_ARGV(6, float);
1583         regen_health_rot = M_ARGV(7, float);
1584         regen_health_rotlinear = M_ARGV(8, float);
1585         regen_health_stable = M_ARGV(9, float);
1586         regen_health_rotstable = M_ARGV(10, float);
1587
1588         if(!mutator_returnvalue)
1589         if(!STAT(FROZEN, this))
1590         {
1591                 float mina, maxa, limith, limita;
1592                 maxa = autocvar_g_balance_armor_rotstable;
1593                 mina = autocvar_g_balance_armor_regenstable;
1594                 limith = GetResourceLimit(this, RES_HEALTH);
1595                 limita = GetResourceLimit(this, RES_ARMOR);
1596
1597                 regen_health_rotstable = regen_health_rotstable * max_mod;
1598                 regen_health_stable = regen_health_stable * max_mod;
1599                 limith = limith * limit_mod;
1600                 limita = limita * limit_mod;
1601
1602                 SetResource(this, RES_ARMOR, CalcRotRegen(GetResource(this, RES_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1603                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1604                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1605                 SetResource(this, RES_HEALTH, CalcRotRegen(GetResource(this, RES_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1606                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1607                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1608         }
1609
1610         // if player rotted to death...  die!
1611         // check this outside above checks, as player may still be able to rot to death
1612         if(GetResource(this, RES_HEALTH) < 1)
1613         {
1614                 if(this.vehicle)
1615                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1616                 if(this.event_damage)
1617                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1618         }
1619
1620         if (!(this.items & IT_UNLIMITED_AMMO))
1621         {
1622                 float minf, maxf, limitf;
1623
1624                 maxf = autocvar_g_balance_fuel_rotstable;
1625                 minf = autocvar_g_balance_fuel_regenstable;
1626                 limitf = GetResourceLimit(this, RES_FUEL);
1627
1628                 SetResource(this, RES_FUEL, CalcRotRegen(GetResource(this, RES_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1629                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1630                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1631         }
1632 }
1633
1634 bool zoomstate_set;
1635 void SetZoomState(entity this, float newzoom)
1636 {
1637         if(newzoom != CS(this).zoomstate)
1638         {
1639                 CS(this).zoomstate = newzoom;
1640                 ClientData_Touch(this);
1641         }
1642         zoomstate_set = true;
1643 }
1644
1645 void GetPressedKeys(entity this)
1646 {
1647         MUTATOR_CALLHOOK(GetPressedKeys, this);
1648         int keys = STAT(PRESSED_KEYS, this);
1649         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1650         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1651         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1652         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1653
1654         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1655         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1656         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1657         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1658         CS(this).pressedkeys = keys; // store for other users
1659
1660         STAT(PRESSED_KEYS, this) = keys;
1661 }
1662
1663 /*
1664 ======================
1665 spectate mode routines
1666 ======================
1667 */
1668
1669 void SpectateCopy(entity this, entity spectatee)
1670 {
1671         TC(Client, this); TC(Client, spectatee);
1672
1673         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1674         PS(this) = PS(spectatee);
1675         this.armortype = spectatee.armortype;
1676         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1677         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1678         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1679         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1680         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1681         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1682         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1683         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1684         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1685         CS(this).impulse = 0;
1686         this.disableclientprediction = 1; // no need to run prediction on a spectator
1687         this.items = spectatee.items;
1688         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1689         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1690         this.strength_finished = spectatee.strength_finished;
1691         this.invincible_finished = spectatee.invincible_finished;
1692         this.superweapons_finished = spectatee.superweapons_finished;
1693         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1694         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1695         this.punchangle = spectatee.punchangle;
1696         this.view_ofs = spectatee.view_ofs;
1697         this.velocity = spectatee.velocity;
1698         this.dmg_take = spectatee.dmg_take;
1699         this.dmg_save = spectatee.dmg_save;
1700         this.dmg_inflictor = spectatee.dmg_inflictor;
1701         this.v_angle = spectatee.v_angle;
1702         this.angles = spectatee.v_angle;
1703         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1704         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1705         this.viewloc = spectatee.viewloc;
1706         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1707                 this.fixangle = true;
1708         setorigin(this, spectatee.origin);
1709         setsize(this, spectatee.mins, spectatee.maxs);
1710         SetZoomState(this, CS(spectatee).zoomstate);
1711
1712     anticheat_spectatecopy(this, spectatee);
1713         STAT(HUD, this) = STAT(HUD, spectatee);
1714         if(spectatee.vehicle)
1715     {
1716         this.angles = spectatee.v_angle;
1717
1718         //this.fixangle = false;
1719         //this.velocity = spectatee.vehicle.velocity;
1720         this.vehicle_health = spectatee.vehicle_health;
1721         this.vehicle_shield = spectatee.vehicle_shield;
1722         this.vehicle_energy = spectatee.vehicle_energy;
1723         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1724         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1725         this.vehicle_reload1 = spectatee.vehicle_reload1;
1726         this.vehicle_reload2 = spectatee.vehicle_reload2;
1727
1728         //msg_entity = this;
1729
1730        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1731             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1732            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1733            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1734
1735         //WriteByte (MSG_ONE, SVC_SETVIEW);
1736         //    WriteEntity(MSG_ONE, this);
1737         //makevectors(spectatee.v_angle);
1738         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1739     }
1740 }
1741
1742 bool SpectateUpdate(entity this)
1743 {
1744         if(!this.enemy)
1745                 return false;
1746
1747         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1748         {
1749                 SetSpectatee(this, NULL);
1750                 return false;
1751         }
1752
1753         SpectateCopy(this, this.enemy);
1754
1755         return true;
1756 }
1757
1758 bool SpectateSet(entity this)
1759 {
1760         if(!IS_PLAYER(this.enemy))
1761                 return false;
1762
1763         ClientData_Touch(this.enemy);
1764
1765         msg_entity = this;
1766         WriteByte(MSG_ONE, SVC_SETVIEW);
1767         WriteEntity(MSG_ONE, this.enemy);
1768         set_movetype(this, MOVETYPE_NONE);
1769         accuracy_resend(this);
1770
1771         if(!SpectateUpdate(this))
1772                 PutObserverInServer(this);
1773
1774         return true;
1775 }
1776
1777 void SetSpectatee_status(entity this, int spectatee_num)
1778 {
1779         int oldspectatee_status = CS(this).spectatee_status;
1780         CS(this).spectatee_status = spectatee_num;
1781
1782         if (CS(this).spectatee_status != oldspectatee_status)
1783         {
1784                 ClientData_Touch(this);
1785                 if (g_race || g_cts) race_InitSpectator();
1786         }
1787 }
1788
1789 void SetSpectatee(entity this, entity spectatee)
1790 {
1791         if(IS_BOT_CLIENT(this))
1792                 return; // bots abuse .enemy, this code is useless to them
1793
1794         entity old_spectatee = this.enemy;
1795
1796         this.enemy = spectatee;
1797
1798         // WEAPONTODO
1799         // these are required to fix the spectator bug with arc
1800         if(old_spectatee)
1801         {
1802                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1803                 {
1804                         .entity weaponentity = weaponentities[slot];
1805                         if(old_spectatee.(weaponentity).arc_beam)
1806                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1807                 }
1808         }
1809         if(this.enemy)
1810         {
1811                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1812                 {
1813                         .entity weaponentity = weaponentities[slot];
1814                         if(this.enemy.(weaponentity).arc_beam)
1815                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1816                 }
1817         }
1818
1819         if (this.enemy)
1820                 SetSpectatee_status(this, etof(this.enemy));
1821
1822         // needed to update spectator list
1823         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1824 }
1825
1826 bool Spectate(entity this, entity pl)
1827 {
1828         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1829                 return false;
1830         pl = M_ARGV(1, entity);
1831
1832         SetSpectatee(this, pl);
1833         return SpectateSet(this);
1834 }
1835
1836 bool SpectateNext(entity this)
1837 {
1838         entity ent = find(this.enemy, classname, STR_PLAYER);
1839
1840         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1841                 ent = M_ARGV(1, entity);
1842         else if (!ent)
1843                 ent = find(ent, classname, STR_PLAYER);
1844
1845         if(ent) { SetSpectatee(this, ent); }
1846
1847         return SpectateSet(this);
1848 }
1849
1850 bool SpectatePrev(entity this)
1851 {
1852         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1853         entity ent = findchain(classname, STR_PLAYER);
1854         if (!ent) // no player
1855                 return false;
1856
1857         entity first = ent;
1858         // skip players until current spectated player
1859         if(this.enemy)
1860         while(ent && ent != this.enemy)
1861                 ent = ent.chain;
1862
1863         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1864         {
1865                 case MUT_SPECPREV_FOUND:
1866                     ent = M_ARGV(1, entity);
1867                     break;
1868                 case MUT_SPECPREV_RETURN:
1869                     return true;
1870                 case MUT_SPECPREV_CONTINUE:
1871                 default:
1872                 {
1873                         if(ent.chain)
1874                                 ent = ent.chain;
1875                         else
1876                                 ent = first;
1877                         break;
1878                 }
1879         }
1880
1881         SetSpectatee(this, ent);
1882         return SpectateSet(this);
1883 }
1884
1885 /*
1886 =============
1887 ShowRespawnCountdown()
1888
1889 Update a respawn countdown display.
1890 =============
1891 */
1892 void ShowRespawnCountdown(entity this)
1893 {
1894         float number;
1895         if(!IS_DEAD(this)) // just respawned?
1896                 return;
1897         else
1898         {
1899                 number = ceil(this.respawn_time - time);
1900                 if(number <= 0)
1901                         return;
1902                 if(number <= this.respawn_countdown)
1903                 {
1904                         this.respawn_countdown = number - 1;
1905                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1906                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1907                 }
1908         }
1909 }
1910
1911 .bool team_selected;
1912 bool ShowTeamSelection(entity this)
1913 {
1914         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1915                 return false;
1916         stuffcmd(this, "menu_showteamselect\n");
1917         return true;
1918 }
1919 void Join(entity this)
1920 {
1921         TRANSMUTE(Player, this);
1922
1923         if(!this.team_selected)
1924         if(autocvar_g_campaign || autocvar_g_balance_teams)
1925                 TeamBalance_JoinBestTeam(this);
1926
1927         if(autocvar_g_campaign)
1928                 campaign_bots_may_start = true;
1929
1930         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1931
1932         PutClientInServer(this);
1933
1934         if(IS_PLAYER(this))
1935         if(teamplay && this.team != -1)
1936         {
1937         }
1938         else
1939                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1940         this.team_selected = false;
1941 }
1942
1943 int GetPlayerLimit()
1944 {
1945         int player_limit = autocvar_g_maxplayers;
1946         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1947         player_limit = M_ARGV(0, int);
1948         return player_limit;
1949 }
1950
1951 /**
1952  * Determines whether the player is allowed to join. This depends on cvar
1953  * g_maxplayers, if it isn't used this function always return true, otherwise
1954  * it checks whether the number of currently playing players exceeds g_maxplayers.
1955  * @return int number of free slots for players, 0 if none
1956  */
1957 int nJoinAllowed(entity this, entity ignore)
1958 {
1959         if(!ignore)
1960         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1961         // so report 0 free slots if restricted
1962         {
1963                 if(autocvar_g_forced_team_otherwise == "spectate")
1964                         return 0;
1965                 if(autocvar_g_forced_team_otherwise == "spectator")
1966                         return 0;
1967         }
1968
1969         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1970                 return 0; // forced spectators can never join
1971
1972         // TODO simplify this
1973         int totalClients = 0;
1974         int currentlyPlaying = 0;
1975         FOREACH_CLIENT(true, {
1976                 if(it != ignore)
1977                         ++totalClients;
1978                 if(IS_REAL_CLIENT(it))
1979                 if(IS_PLAYER(it) || it.caplayer)
1980                         ++currentlyPlaying;
1981         });
1982
1983         int player_limit = GetPlayerLimit();
1984
1985         float free_slots = 0;
1986         if (!player_limit)
1987                 free_slots = maxclients - totalClients;
1988         else if(currentlyPlaying < player_limit)
1989                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
1990
1991         static float join_prevent_msg_time = 0;
1992         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1993         {
1994                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1995                 join_prevent_msg_time = time + 3;
1996         }
1997
1998         return free_slots;
1999 }
2000
2001 /**
2002  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2003  * g_maxplayers_spectator_blocktime seconds
2004  */
2005 void checkSpectatorBlock(entity this)
2006 {
2007         if(IS_SPEC(this) || IS_OBSERVER(this))
2008         if(!this.caplayer)
2009         if(IS_REAL_CLIENT(this))
2010         {
2011                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2012                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2013                         dropclient(this);
2014                 }
2015         }
2016 }
2017
2018 void PrintWelcomeMessage(entity this)
2019 {
2020         if(CS(this).motd_actived_time == 0)
2021         {
2022                 if (autocvar_g_campaign) {
2023                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2024                                 CS(this).motd_actived_time = time;
2025                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2026                         }
2027                 } else {
2028                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2029                                 CS(this).motd_actived_time = time;
2030                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2031                         }
2032                 }
2033         }
2034         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2035         {
2036                 if (autocvar_g_campaign) {
2037                         if (PHYS_INPUT_BUTTON_INFO(this))
2038                                 CS(this).motd_actived_time = time;
2039                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2040                                 CS(this).motd_actived_time = 0;
2041                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2042                         }
2043                 } else {
2044                         if (PHYS_INPUT_BUTTON_INFO(this))
2045                                 CS(this).motd_actived_time = time;
2046                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2047                                 CS(this).motd_actived_time = 0;
2048                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2049                         }
2050                 }
2051         }
2052         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2053         {
2054                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2055                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2056                 else if (CS(this).motd_actived_time == -2)
2057                 {
2058                         // instantly hide MOTD
2059                         CS(this).motd_actived_time = 0;
2060                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2061                 }
2062                 else if (IS_PLAYER(this) || IS_SPEC(this))
2063                 {
2064                         // FIXME occasionally for some reason MOTD never goes away
2065                         // delay MOTD removal a little bit in the hope it fixes this bug
2066                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2067                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2068                         else //if (CS(this).motd_actived_time < -2)
2069                                 CS(this).motd_actived_time++;
2070                 }
2071         }
2072 }
2073
2074 const int MIN_SPEC_TIME = 1;
2075 bool joinAllowed(entity this)
2076 {
2077         if (CS(this).version_mismatch) return false;
2078         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2079         if (!nJoinAllowed(this, this)) return false;
2080         if (teamplay && lockteams) return false;
2081         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2082         if (ShowTeamSelection(this)) return false;
2083         return true;
2084 }
2085
2086 .int items_added;
2087 .string shootfromfixedorigin;
2088 bool PlayerThink(entity this)
2089 {
2090         if (game_stopped || intermission_running) {
2091                 this.modelflags &= ~MF_ROCKET;
2092                 if(intermission_running)
2093                         IntermissionThink(this);
2094                 return false;
2095         }
2096
2097         if (timeout_status == TIMEOUT_ACTIVE) {
2098         // don't allow the player to turn around while game is paused
2099                 // FIXME turn this into CSQC stuff
2100                 this.v_angle = this.lastV_angle;
2101                 this.angles = this.lastV_angle;
2102                 this.fixangle = true;
2103         }
2104
2105         if (frametime) player_powerups(this);
2106
2107         if (IS_DEAD(this)) {
2108                 if (this.personal && g_race_qualifying) {
2109                         if (time > this.respawn_time) {
2110                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2111                                 respawn(this);
2112                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2113                         }
2114                 } else {
2115                         if (frametime) player_anim(this);
2116
2117                         if (this.respawn_flags & RESPAWN_DENY)
2118                         {
2119                                 STAT(RESPAWN_TIME, this) = 0;
2120                                 return false;
2121                         }
2122
2123                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2124
2125                         switch(this.deadflag)
2126                         {
2127                                 case DEAD_DYING:
2128                                 {
2129                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2130                                                 this.deadflag = DEAD_RESPAWNING;
2131                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2132                                                 this.deadflag = DEAD_DEAD;
2133                                         break;
2134                                 }
2135                                 case DEAD_DEAD:
2136                                 {
2137                                         if (button_pressed)
2138                                                 this.deadflag = DEAD_RESPAWNABLE;
2139                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2140                                                 this.deadflag = DEAD_RESPAWNING;
2141                                         break;
2142                                 }
2143                                 case DEAD_RESPAWNABLE:
2144                                 {
2145                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2146                                                 this.deadflag = DEAD_RESPAWNING;
2147                                         break;
2148                                 }
2149                                 case DEAD_RESPAWNING:
2150                                 {
2151                                         if (time > this.respawn_time)
2152                                         {
2153                                                 this.respawn_time = time + 1; // only retry once a second
2154                                                 this.respawn_time_max = this.respawn_time;
2155                                                 respawn(this);
2156                                         }
2157                                         break;
2158                                 }
2159                         }
2160
2161                         ShowRespawnCountdown(this);
2162
2163                         if (this.respawn_flags & RESPAWN_SILENT)
2164                                 STAT(RESPAWN_TIME, this) = 0;
2165                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2166                         {
2167                                 if (time < this.respawn_time)
2168                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2169                                 else if (this.deadflag != DEAD_RESPAWNING)
2170                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2171                         }
2172                         else
2173                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2174                 }
2175
2176                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2177                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2178                         STAT(RESPAWN_TIME, this) *= -1;
2179
2180                 return false;
2181         }
2182
2183         FixPlayermodel(this);
2184
2185         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2186                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2187                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2188         }
2189
2190         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2191         //if(frametime)
2192         {
2193                 this.items &= ~this.items_added;
2194
2195                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2196                 {
2197                         .entity weaponentity = weaponentities[slot];
2198                         if(WEP_CVAR(vortex, charge_always))
2199                                 W_Vortex_Charge(this, weaponentity, frametime);
2200                         W_WeaponFrame(this, weaponentity);
2201                 }
2202
2203                 this.items_added = 0;
2204                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResource(this, RES_FUEL) >= 0.01))
2205             this.items_added |= IT_FUEL;
2206
2207                 this.items |= this.items_added;
2208         }
2209
2210         // WEAPONTODO: Add a weapon request for this
2211         // rot vortex charge to the charge limit
2212         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2213         {
2214                 .entity weaponentity = weaponentities[slot];
2215                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2216                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2217         }
2218
2219         if (frametime)
2220         {
2221                 player_regen(this);
2222                 player_anim(this);
2223                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2224         }
2225
2226         secrets_setstatus(this);
2227         monsters_setstatus(this);
2228
2229         return true;
2230 }
2231
2232 .bool would_spectate;
2233 void ObserverThink(entity this)
2234 {
2235         if ( CS(this).impulse )
2236         {
2237                 MinigameImpulse(this, CS(this).impulse);
2238                 CS(this).impulse = 0;
2239         }
2240
2241         if (this.flags & FL_JUMPRELEASED) {
2242                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2243                         this.flags &= ~FL_JUMPRELEASED;
2244                         this.flags |= FL_SPAWNING;
2245                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2246                         this.flags &= ~FL_JUMPRELEASED;
2247                         if(SpectateNext(this)) {
2248                                 TRANSMUTE(Spectator, this);
2249                         }
2250                 } else {
2251                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2252                         set_movetype(this, preferred_movetype);
2253                 }
2254         } else {
2255                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2256                         this.flags |= FL_JUMPRELEASED;
2257                         if(this.flags & FL_SPAWNING)
2258                         {
2259                                 this.flags &= ~FL_SPAWNING;
2260                                 Join(this);
2261                                 return;
2262                         }
2263                 }
2264         }
2265 }
2266
2267 void SpectatorThink(entity this)
2268 {
2269         if ( CS(this).impulse )
2270         {
2271                 if(MinigameImpulse(this, CS(this).impulse))
2272                         CS(this).impulse = 0;
2273
2274                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2275                 {
2276                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2277                         CS(this).impulse = 0;
2278                         return;
2279                 }
2280         }
2281
2282         if (this.flags & FL_JUMPRELEASED) {
2283                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2284                         this.flags &= ~FL_JUMPRELEASED;
2285                         this.flags |= FL_SPAWNING;
2286                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2287                         this.flags &= ~FL_JUMPRELEASED;
2288                         if(SpectateNext(this)) {
2289                                 TRANSMUTE(Spectator, this);
2290                         } else {
2291                                 TRANSMUTE(Observer, this);
2292                                 PutClientInServer(this);
2293                         }
2294                         CS(this).impulse = 0;
2295                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2296                         this.flags &= ~FL_JUMPRELEASED;
2297                         if(SpectatePrev(this)) {
2298                                 TRANSMUTE(Spectator, this);
2299                         } else {
2300                                 TRANSMUTE(Observer, this);
2301                                 PutClientInServer(this);
2302                         }
2303                         CS(this).impulse = 0;
2304                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2305                         this.would_spectate = false;
2306                         this.flags &= ~FL_JUMPRELEASED;
2307                         TRANSMUTE(Observer, this);
2308                         PutClientInServer(this);
2309                 } else {
2310                         if(!SpectateUpdate(this))
2311                         {
2312                                 if(!SpectateNext(this))
2313                                 {
2314                                         PutObserverInServer(this);
2315                                         this.would_spectate = true;
2316                                 }
2317                         }
2318                 }
2319         } else {
2320                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2321                         this.flags |= FL_JUMPRELEASED;
2322                         if(this.flags & FL_SPAWNING)
2323                         {
2324                                 this.flags &= ~FL_SPAWNING;
2325                                 Join(this);
2326                                 return;
2327                         }
2328                 }
2329                 if(!SpectateUpdate(this))
2330                         PutObserverInServer(this);
2331         }
2332
2333         this.flags |= FL_CLIENT | FL_NOTARGET;
2334 }
2335
2336 void PlayerUseKey(entity this)
2337 {
2338         if (!IS_PLAYER(this))
2339                 return;
2340
2341         if(this.vehicle)
2342         {
2343                 if(!game_stopped)
2344                 {
2345                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2346                         return;
2347                 }
2348         }
2349         else if(autocvar_g_vehicles_enter)
2350         {
2351                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2352                 {
2353                         entity head, closest_target = NULL;
2354                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2355
2356                         while(head) // find the closest acceptable target to enter
2357                         {
2358                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2359                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2360                                 {
2361                                         if(closest_target)
2362                                         {
2363                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2364                                                 { closest_target = head; }
2365                                         }
2366                                         else { closest_target = head; }
2367                                 }
2368
2369                                 head = head.chain;
2370                         }
2371
2372                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2373                 }
2374         }
2375
2376         // a use key was pressed; call handlers
2377         MUTATOR_CALLHOOK(PlayerUseKey, this);
2378 }
2379
2380
2381 /*
2382 =============
2383 PlayerPreThink
2384
2385 Called every frame for each client before the physics are run
2386 =============
2387 */
2388 .float last_vehiclecheck;
2389 void PlayerPreThink (entity this)
2390 {
2391         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2392         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2393
2394         WarpZone_PlayerPhysics_FixVAngle(this);
2395
2396         if (frametime) {
2397                 // physics frames: update anticheat stuff
2398                 anticheat_prethink(this);
2399         }
2400
2401         if (blockSpectators && frametime) {
2402                 // WORKAROUND: only use dropclient in server frames (frametime set).
2403                 // Never use it in cl_movement frames (frametime zero).
2404                 checkSpectatorBlock(this);
2405         }
2406
2407         zoomstate_set = false;
2408
2409         // Check for nameless players
2410         if (this.netname == "" || this.netname != CS(this).netname_previous)
2411         {
2412                 bool assume_unchanged = (CS(this).netname_previous == "");
2413                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2414                 {
2415                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2416                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2417                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2418                         assume_unchanged = false;
2419                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2420                 }
2421                 if (isInvisibleString(this.netname))
2422                 {
2423                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2424                         sprint(this, "Warning: invisible names are not allowed.\n");
2425                         assume_unchanged = false;
2426                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2427                 }
2428                 if (!assume_unchanged && autocvar_sv_eventlog)
2429                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2430                 strcpy(CS(this).netname_previous, this.netname);
2431         }
2432
2433         // version nagging
2434         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2435         CS(this).version_nagtime = 0;
2436         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2437             // git client
2438         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2439             // git server
2440             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2441         } else {
2442             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2443             if (r < 0) { // old client
2444                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2445             } else if (r > 0) { // old server
2446                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2447             }
2448         }
2449     }
2450
2451         // GOD MODE info
2452         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2453         {
2454                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2455                 this.max_armorvalue = 0;
2456         }
2457
2458         if (frametime && IS_PLAYER(this))
2459         {
2460                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2461                 {
2462                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2463                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2464                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2465
2466                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2467                                 Unfreeze(this, false);
2468                 }
2469                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2470                 {
2471                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2472                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2473
2474                         if (GetResource(this, RES_HEALTH) < 1)
2475                         {
2476                                 if (this.vehicle)
2477                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2478                                 if(this.event_damage)
2479                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2480                         }
2481                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2482                                 Unfreeze(this, false);
2483                 }
2484         }
2485
2486         MUTATOR_CALLHOOK(PlayerPreThink, this);
2487
2488         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2489         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2490         {
2491                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2492                 {
2493                         if(!it.owner)
2494                         {
2495                                 if(!it.team || SAME_TEAM(this, it))
2496                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2497                                 else if(autocvar_g_vehicles_steal)
2498                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2499                         }
2500                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2501                         {
2502                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2503                         }
2504                 });
2505
2506                 this.last_vehiclecheck = time + 1;
2507         }
2508
2509         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2510         {
2511                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2512                         PlayerUseKey(this);
2513                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2514         }
2515
2516         if (IS_REAL_CLIENT(this))
2517                 PrintWelcomeMessage(this);
2518
2519         if (IS_PLAYER(this)) {
2520                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2521                         error("Client can't be spawned as player on connection!");
2522                 if(!PlayerThink(this))
2523                         return;
2524         }
2525         else if (game_stopped || intermission_running) {
2526                 if(intermission_running)
2527                         IntermissionThink(this);
2528                 return;
2529         }
2530         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2531         {
2532                 CS(this).autojoin_checked = true;
2533                 // don't do this in ClientConnect
2534                 // many things can go wrong if a client is spawned as player on connection
2535                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2536                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2537                                 && (!teamplay || autocvar_g_balance_teams)))
2538                 {
2539                         campaign_bots_may_start = true;
2540                         Join(this);
2541                         return;
2542                 }
2543         }
2544         else if (IS_OBSERVER(this)) {
2545                 ObserverThink(this);
2546         }
2547         else if (IS_SPEC(this)) {
2548                 SpectatorThink(this);
2549         }
2550
2551         // WEAPONTODO: Add weapon request for this
2552         if (!zoomstate_set) {
2553                 bool wep_zoomed = false;
2554                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2555                 {
2556                         .entity weaponentity = weaponentities[slot];
2557                         Weapon thiswep = this.(weaponentity).m_weapon;
2558                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2559                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2560                 }
2561                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2562     }
2563
2564         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2565         {
2566                 CS(this).teamkill_soundtime = 0;
2567
2568                 entity e = CS(this).teamkill_soundsource;
2569                 entity oldpusher = e.pusher;
2570                 e.pusher = this;
2571                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2572                 e.pusher = oldpusher;
2573         }
2574
2575         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2576                 CS(this).taunt_soundtime = 0;
2577                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2578         }
2579
2580         target_voicescript_next(this);
2581
2582         // WEAPONTODO: Move into weaponsystem somehow
2583         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2584         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2585         {
2586                 .entity weaponentity = weaponentities[slot];
2587                 if(this.(weaponentity).m_weapon == WEP_Null)
2588                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2589         }
2590 }
2591
2592 void DrownPlayer(entity this)
2593 {
2594         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2595                 return;
2596
2597         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2598         {
2599                 if(this.air_finished < time)
2600                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2601                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2602         }
2603         else if (this.air_finished < time)
2604         {       // drown!
2605                 if (this.pain_finished < time)
2606                 {
2607                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2608                         this.pain_finished = time + 0.5;
2609                 }
2610         }
2611 }
2612
2613 .bool move_qcphysics;
2614
2615 void Player_Physics(entity this)
2616 {
2617         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2618
2619         if(!this.move_qcphysics)
2620                 return;
2621
2622         if(!frametime && !CS(this).pm_frametime)
2623                 return;
2624
2625         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2626
2627         CS(this).pm_frametime = 0;
2628 }
2629
2630 /*
2631 =============
2632 PlayerPostThink
2633
2634 Called every frame for each client after the physics are run
2635 =============
2636 */
2637 void PlayerPostThink (entity this)
2638 {
2639         Player_Physics(this);
2640
2641         if (sv_maxidle > 0)
2642         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2643         if (IS_REAL_CLIENT(this))
2644         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2645         {
2646                 int totalClients = 0;
2647                 if(sv_maxidle_slots > 0)
2648                 {
2649                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2650                         {
2651                                 ++totalClients;
2652                         });
2653                 }
2654
2655                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2656                 { /* do nothing */ }
2657                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2658                 {
2659                         if (CS(this).idlekick_lasttimeleft)
2660                         {
2661                                 CS(this).idlekick_lasttimeleft = 0;
2662                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2663                         }
2664                 }
2665                 else
2666                 {
2667                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2668                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2669                                 if (!CS(this).idlekick_lasttimeleft)
2670                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2671                         }
2672                         if (timeleft <= 0) {
2673                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2674                                 dropclient(this);
2675                                 return;
2676                         }
2677                         else if (timeleft <= 10) {
2678                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2679                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2680                 }
2681                                 CS(this).idlekick_lasttimeleft = timeleft;
2682                         }
2683                 }
2684         }
2685
2686         CheatFrame(this);
2687
2688         if (game_stopped)
2689         {
2690                 this.solid = SOLID_NOT;
2691                 this.takedamage = DAMAGE_NO;
2692                 set_movetype(this, MOVETYPE_NONE);
2693         }
2694
2695         if (IS_PLAYER(this)) {
2696                 if(this.death_time == time && IS_DEAD(this))
2697                 {
2698                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2699                         // once all the damage events of this frame have been processed with normal size
2700                         this.maxs.z = 5;
2701                         setsize(this, this.mins, this.maxs);
2702                 }
2703                 DrownPlayer(this);
2704                 UpdateChatBubble(this);
2705                 if (CS(this).impulse) ImpulseCommands(this);
2706                 if (game_stopped)
2707                 {
2708                         CSQCMODEL_AUTOUPDATE(this);
2709                         return;
2710                 }
2711                 GetPressedKeys(this);
2712         }
2713
2714         if (this.waypointsprite_attachedforcarrier) {
2715                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2716                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2717         }
2718
2719         CSQCMODEL_AUTOUPDATE(this);
2720 }
2721
2722 /**
2723  * message "": do not say, just test flood control
2724  * return value:
2725  *   1 = accept
2726  *   0 = reject
2727  *  -1 = fake accept
2728  */
2729 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2730 {
2731         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2732                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2733
2734         if (source)
2735                 msgin = formatmessage(source, msgin);
2736
2737         string colorstr;
2738         if (!(IS_PLAYER(source) || source.caplayer))
2739                 colorstr = "^0"; // black for spectators
2740         else if(teamplay)
2741                 colorstr = Team_ColorCode(source.team);
2742         else
2743         {
2744                 colorstr = "";
2745                 teamsay = false;
2746         }
2747
2748         if (!source) {
2749                 colorstr = "";
2750                 teamsay = false;
2751         }
2752
2753         if(msgin != "")
2754                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2755
2756         /*
2757          * using bprint solves this... me stupid
2758         // how can we prevent the message from appearing in a listen server?
2759         // for now, just give "say" back and only handle say_team
2760         if(!teamsay)
2761         {
2762                 clientcommand(source, strcat("say ", msgin));
2763                 return;
2764         }
2765         */
2766
2767         string namestr = "";
2768         if (source)
2769                 namestr = playername(source, autocvar_g_chat_teamcolors);
2770
2771         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2772
2773         string msgstr = "", cmsgstr = "";
2774         string privatemsgprefix = string_null;
2775         int privatemsgprefixlen = 0;
2776         if (msgin != "")
2777         {
2778                 bool found_me = false;
2779                 if(strstrofs(msgin, "/me", 0) >= 0)
2780                 {
2781                         string newmsgin = "";
2782                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2783                         FOREACH_WORD(msgin, true,
2784                         {
2785                                 if(strdecolorize(it) == "/me")
2786                                 {
2787                                         found_me = true;
2788                                         newmsgin = cons(newmsgin, newnamestr);
2789                                 }
2790                                 else
2791                                         newmsgin = cons(newmsgin, it);
2792                         });
2793                         msgin = newmsgin;
2794                 }
2795
2796                 if(privatesay)
2797                 {
2798                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2799                         privatemsgprefixlen = strlen(msgstr);
2800                         msgstr = strcat(msgstr, msgin);
2801                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2802                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2803                 }
2804                 else if(teamsay)
2805                 {
2806                         if(found_me)
2807                         {
2808                                 //msgin = strreplace("/me", "", msgin);
2809                                 //msgin = substring(msgin, 3, strlen(msgin));
2810                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2811                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2812                         }
2813                         else
2814                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2815                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2816                 }
2817                 else
2818                 {
2819                         if(found_me)
2820                         {
2821                                 //msgin = strreplace("/me", "", msgin);
2822                                 //msgin = substring(msgin, 3, strlen(msgin));
2823                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2824                                 msgstr = strcat("\{1}^4* ^7", msgin);
2825                         }
2826                         else {
2827                                 msgstr = "\{1}";
2828                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2829                                 msgstr = strcat(msgstr, msgin);
2830                         }
2831                         cmsgstr = "";
2832                 }
2833                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2834         }
2835
2836         string fullmsgstr = msgstr;
2837         string fullcmsgstr = cmsgstr;
2838
2839         // FLOOD CONTROL
2840         int flood = 0;
2841         var .float flood_field = floodcontrol_chat;
2842         if(floodcontrol && source)
2843         {
2844                 float flood_spl;
2845                 float flood_burst;
2846                 float flood_lmax;
2847                 float lines;
2848                 if(privatesay)
2849                 {
2850                         flood_spl = autocvar_g_chat_flood_spl_tell;
2851                         flood_burst = autocvar_g_chat_flood_burst_tell;
2852                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2853                         flood_field = floodcontrol_chattell;
2854                 }
2855                 else if(teamsay)
2856                 {
2857                         flood_spl = autocvar_g_chat_flood_spl_team;
2858                         flood_burst = autocvar_g_chat_flood_burst_team;
2859                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2860                         flood_field = floodcontrol_chatteam;
2861                 }
2862                 else
2863                 {
2864                         flood_spl = autocvar_g_chat_flood_spl;
2865                         flood_burst = autocvar_g_chat_flood_burst;
2866                         flood_lmax = autocvar_g_chat_flood_lmax;
2867                         flood_field = floodcontrol_chat;
2868                 }
2869                 flood_burst = max(0, flood_burst - 1);
2870                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2871
2872                 // do flood control for the default line size
2873                 if(msgstr != "")
2874                 {
2875                         getWrappedLine_remaining = msgstr;
2876                         msgstr = "";
2877                         lines = 0;
2878                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
2879                         {
2880                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
2881                                 ++lines;
2882                         }
2883                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2884
2885                         if(getWrappedLine_remaining != "")
2886                         {
2887                                 msgstr = strcat(msgstr, "\n");
2888                                 flood = 2;
2889                         }
2890
2891                         if (time >= source.(flood_field))
2892                         {
2893                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
2894                         }
2895                         else
2896                         {
2897                                 flood = 1;
2898                                 msgstr = fullmsgstr;
2899                         }
2900                 }
2901                 else
2902                 {
2903                         if (time >= source.(flood_field))
2904                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
2905                         else
2906                                 flood = 1;
2907                 }
2908
2909                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
2910                         source.(flood_field) = flood = 0;
2911         }
2912
2913         string sourcemsgstr, sourcecmsgstr;
2914         if(flood == 2) // cannot happen for empty msgstr
2915         {
2916                 if(autocvar_g_chat_flood_notify_flooder)
2917                 {
2918                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
2919                         sourcecmsgstr = "";
2920                 }
2921                 else
2922                 {
2923                         sourcemsgstr = fullmsgstr;
2924                         sourcecmsgstr = fullcmsgstr;
2925                 }
2926                 cmsgstr = "";
2927         }
2928         else
2929         {
2930                 sourcemsgstr = msgstr;
2931                 sourcecmsgstr = cmsgstr;
2932         }
2933
2934         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2935         {
2936                 if (!game_stopped)
2937                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
2938                         teamsay = -1; // spectators
2939         }
2940
2941         if(flood)
2942                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
2943
2944         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
2945         if(privatesay)
2946                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
2947
2948         int ret;
2949         if(source && CS(source).muted)
2950         {
2951                 // always fake the message
2952                 ret = -1;
2953         }
2954         else if(flood == 1)
2955         {
2956                 if (autocvar_g_chat_flood_notify_flooder)
2957                 {
2958                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
2959                         ret = 0;
2960                 }
2961                 else
2962                         ret = -1;
2963         }
2964         else
2965         {
2966                 ret = 1;
2967         }
2968
2969         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
2970         {
2971                 if (!game_stopped)
2972                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
2973                         ret = -1; // just hide the message completely
2974         }
2975
2976         MUTATOR_CALLHOOK(ChatMessage, source, ret);
2977         ret = M_ARGV(1, int);
2978
2979         string event_log_msg = "";
2980
2981         if(sourcemsgstr != "" && ret != 0)
2982         {
2983                 if(ret < 0) // faked message, because the player is muted
2984                 {
2985                         sprint(source, sourcemsgstr);
2986                         if(sourcecmsgstr != "" && !privatesay)
2987                                 centerprint(source, sourcecmsgstr);
2988                 }
2989                 else if(privatesay) // private message, between 2 people only
2990                 {
2991                         sprint(source, sourcemsgstr);
2992                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
2993                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
2994                         {
2995                                 sprint(privatesay, msgstr);
2996                                 if(cmsgstr != "")
2997                                         centerprint(privatesay, cmsgstr);
2998                         }
2999                 }
3000                 else if ( teamsay && CS(source).active_minigame )
3001                 {
3002                         sprint(source, sourcemsgstr);
3003                         dedicated_print(msgstr); // send to server console too
3004                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3005                                 sprint(it, msgstr);
3006                         });
3007                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3008
3009                 }
3010                 else if(teamsay > 0) // team message, only sent to team mates
3011                 {
3012                         sprint(source, sourcemsgstr);
3013                         dedicated_print(msgstr); // send to server console too
3014                         if(sourcecmsgstr != "")
3015                                 centerprint(source, sourcecmsgstr);
3016                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3017                                 sprint(it, msgstr);
3018                                 if(cmsgstr != "")
3019                                         centerprint(it, cmsgstr);
3020                         });
3021                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3022                 }
3023                 else if(teamsay < 0) // spectator message, only sent to spectators
3024                 {
3025                         sprint(source, sourcemsgstr);
3026                         dedicated_print(msgstr); // send to server console too
3027                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3028                                 sprint(it, msgstr);
3029                         });
3030                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3031                 }
3032                 else
3033                 {
3034                         if (source) {
3035                                 sprint(source, sourcemsgstr);
3036                                 dedicated_print(msgstr); // send to server console too
3037                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3038                         }
3039                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3040                                 sprint(it, msgstr);
3041                         });
3042                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3043                 }
3044         }
3045
3046         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3047                 GameLogEcho(event_log_msg);
3048         }
3049
3050         return ret;
3051 }
3052
3053 // hack to copy the button fields from the client entity to the Client State
3054 void PM_UpdateButtons(entity this, entity store)
3055 {
3056         if(this.impulse)
3057                 store.impulse = this.impulse;
3058         this.impulse = 0;
3059
3060         bool typing = this.buttonchat || this.button12;
3061
3062         store.button0 = (typing) ? 0 : this.button0;
3063         //button1?!
3064         store.button2 = (typing) ? 0 : this.button2;
3065         store.button3 = (typing) ? 0 : this.button3;
3066         store.button4 = this.button4;
3067         store.button5 = (typing) ? 0 : this.button5;
3068         store.button6 = this.button6;
3069         store.button7 = this.button7;
3070         store.button8 = this.button8;
3071         store.button9 = this.button9;
3072         store.button10 = this.button10;
3073         store.button11 = this.button11;
3074         store.button12 = this.button12;
3075         store.button13 = this.button13;
3076         store.button14 = this.button14;
3077         store.button15 = this.button15;
3078         store.button16 = this.button16;
3079         store.buttonuse = this.buttonuse;
3080         store.buttonchat = this.buttonchat;
3081
3082         store.cursor_active = this.cursor_active;
3083         store.cursor_screen = this.cursor_screen;
3084         store.cursor_trace_start = this.cursor_trace_start;
3085         store.cursor_trace_endpos = this.cursor_trace_endpos;
3086         store.cursor_trace_ent = this.cursor_trace_ent;
3087
3088         store.ping = this.ping;
3089         store.ping_packetloss = this.ping_packetloss;
3090         store.ping_movementloss = this.ping_movementloss;
3091
3092         store.v_angle = this.v_angle;
3093         store.movement = (typing) ? '0 0 0' : this.movement;
3094 }
3095
3096 NET_HANDLE(fpsreport, bool)
3097 {
3098         int fps = ReadShort();
3099         PlayerScore_Set(sender, SP_FPS, fps);
3100         return true;
3101 }