qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/physics/player.qh"
  41
  42 #include "../common/items/_mod.qh"
  43
  44 #include "../common/mutators/mutator/waypoints/all.qh"
  45
  46 #include "../common/triggers/subs.qh"
  47 #include "../common/triggers/triggers.qh"
  48 #include "../common/triggers/trigger/secret.qh"
  49
  50 #include "../common/minigames/sv_minigames.qh"
  51
  52 #include "../common/items/inventory.qh"
  53
  54 #include "../common/monsters/sv_monsters.qh"
  55
  56 #include "../lib/warpzone/server.qh"
  57
  58 STATIC_METHOD(Client, Add, void(Client this, int _team))
  59 {
  60     ClientConnect(this);
  61     TRANSMUTE(Player, this);
  62     this.frame = 12; // 7
  63     this.team = _team;
  64     PutClientInServer(this);
  65 }
  66
  67 void PutObserverInServer(entity this);
  68
  69 STATIC_METHOD(Client, Remove, void(Client this))
  70 {
  71     TRANSMUTE(Observer, this);
  72     PutClientInServer(this);
  73     ClientDisconnect(this);
  74 }
  75
  76 void send_CSQC_teamnagger() {
  77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  78 }
  79
  80 int CountSpectators(entity player, entity to)
  81 {
  82         if(!player) { return 0; } // not sure how, but best to be safe
  83
  84         int spec_count = 0;
  85
  86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  87         {
  88                 spec_count++;
  89         });
  90
  91         return spec_count;
  92 }
  93
  94 void WriteSpectators(entity player, entity to)
  95 {
  96         if(!player) { return; } // not sure how, but best to be safe
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 WriteByte(MSG_ENTITY, num_for_edict(it));
 101         });
 102 }
 103
 104 bool ClientData_Send(entity this, entity to, int sf)
 105 {
 106         assert(to == this.owner, return false);
 107
 108         entity e = to;
 109         if (IS_SPEC(e)) e = e.enemy;
 110
 111         sf = 0;
 112         if (e.race_completed)       sf |= 1; // forced scoreboard
 113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 114         if (e.zoomstate)            sf |= 4; // zoomed
 115         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124
 125         if(sf & 16)
 126         {
 127                 float specs = CountSpectators(e, to);
 128                 WriteByte(MSG_ENTITY, specs);
 129                 WriteSpectators(e, to);
 130         }
 131
 132         return true;
 133 }
 134
 135 void ClientData_Attach(entity this)
 136 {
 137         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 138         this.clientdata.drawonlytoclient = this;
 139         this.clientdata.owner = this;
 140 }
 141
 142 void ClientData_Detach(entity this)
 143 {
 144         delete(this.clientdata);
 145         this.clientdata = NULL;
 146 }
 147
 148 void ClientData_Touch(entity e)
 149 {
 150         e.clientdata.SendFlags = 1;
 151
 152         // make it spectatable
 153         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 154 }
 155
 156 .string netname_previous;
 157
 158 void SetSpectatee(entity this, entity spectatee);
 159 void SetSpectatee_status(entity this, int spectatee_num);
 160
 161
 162 /*
 163 =============
 164 CheckPlayerModel
 165
 166 Checks if the argument string can be a valid playermodel.
 167 Returns a valid one in doubt.
 168 =============
 169 */
 170 string FallbackPlayerModel;
 171 string CheckPlayerModel(string plyermodel) {
 172         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 173         {
 174                 // note: we cannot summon Don Strunzone here, some player may
 175                 // still have the model string set. In case anyone manages how
 176                 // to change a cvar default, we'll have a small leak here.
 177                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 178         }
 179         // only in right path
 180         if( substring(plyermodel,0,14) != "models/player/")
 181                 return FallbackPlayerModel;
 182         // only good file extensions
 183         if(substring(plyermodel,-4,4) != ".zym")
 184         if(substring(plyermodel,-4,4) != ".dpm")
 185         if(substring(plyermodel,-4,4) != ".iqm")
 186         if(substring(plyermodel,-4,4) != ".md3")
 187         if(substring(plyermodel,-4,4) != ".psk")
 188                 return FallbackPlayerModel;
 189         // forbid the LOD models
 190         if(substring(plyermodel, -9,5) == "_lod1")
 191                 return FallbackPlayerModel;
 192         if(substring(plyermodel, -9,5) == "_lod2")
 193                 return FallbackPlayerModel;
 194         if(plyermodel != strtolower(plyermodel))
 195                 return FallbackPlayerModel;
 196         // also, restrict to server models
 197         if(autocvar_sv_servermodelsonly)
 198         {
 199                 if(!fexists(plyermodel))
 200                         return FallbackPlayerModel;
 201         }
 202         return plyermodel;
 203 }
 204
 205 void setplayermodel(entity e, string modelname)
 206 {
 207         precache_model(modelname);
 208         _setmodel(e, modelname);
 209         player_setupanimsformodel(e);
 210         if(!autocvar_g_debug_globalsounds)
 211                 UpdatePlayerSounds(e);
 212 }
 213
 214 void FixPlayermodel(entity player);
 215 /** putting a client as observer in the server */
 216 void PutObserverInServer(entity this)
 217 {
 218     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 219         PlayerState_detach(this);
 220
 221         if (IS_PLAYER(this) && this.health >= 1) {
 222         // despawn effect
 223                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 224     }
 225
 226     {
 227         entity spot = SelectSpawnPoint(this, true);
 228         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 229         this.angles = spot.angles;
 230         this.angles_z = 0;
 231         this.fixangle = true;
 232         // offset it so that the spectator spawns higher off the ground, looks better this way
 233         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 234         this.prevorigin = this.origin;
 235         if (IS_REAL_CLIENT(this))
 236         {
 237             msg_entity = this;
 238             WriteByte(MSG_ONE, SVC_SETVIEW);
 239             WriteEntity(MSG_ONE, this);
 240         }
 241         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 242         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 243         if(!autocvar_g_debug_globalsounds)
 244         {
 245                 // needed for player sounds
 246                 this.model = "";
 247                 FixPlayermodel(this);
 248         }
 249         setmodel(this, MDL_Null);
 250         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 251         this.view_ofs = '0 0 0';
 252     }
 253
 254     RemoveGrapplingHooks(this);
 255         Portal_ClearAll(this);
 256         Unfreeze(this);
 257         SetSpectatee(this, NULL);
 258
 259         if (this.alivetime)
 260         {
 261                 if (!warmup_stage)
 262                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 263                 this.alivetime = 0;
 264         }
 265
 266         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 267
 268         WaypointSprite_PlayerDead(this);
 269
 270         if (mutator_returnvalue) {
 271             // mutator prevents resetting teams+score
 272         } else {
 273                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 274         this.frags = FRAGS_SPECTATOR;
 275         PlayerScore_Clear(this);  // clear scores when needed
 276     }
 277
 278         if (this.killcount != FRAGS_SPECTATOR)
 279         {
 280                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 281                 if(!intermission_running)
 282                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 283                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 284
 285                 if(this.just_joined == false) {
 286                         LogTeamchange(this.playerid, -1, 4);
 287                 } else
 288                         this.just_joined = false;
 289         }
 290
 291         accuracy_resend(this);
 292
 293         this.spectatortime = time;
 294         if(this.bot_attack)
 295                 IL_REMOVE(g_bot_targets, this);
 296         this.bot_attack = false;
 297     this.hud = HUD_NORMAL;
 298         TRANSMUTE(Observer, this);
 299         this.iscreature = false;
 300         this.teleportable = TELEPORT_SIMPLE;
 301         if(this.damagedbycontents)
 302                 IL_REMOVE(g_damagedbycontents, this);
 303         this.damagedbycontents = false;
 304         this.health = FRAGS_SPECTATOR;
 305         SetSpectatee_status(this, etof(this));
 306         this.takedamage = DAMAGE_NO;
 307         this.solid = SOLID_NOT;
 308         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 309         this.flags = FL_CLIENT | FL_NOTARGET;
 310         this.armorvalue = 666;
 311         this.effects = 0;
 312         this.armorvalue = autocvar_g_balance_armor_start;
 313         this.pauserotarmor_finished = 0;
 314         this.pauserothealth_finished = 0;
 315         this.pauseregen_finished = 0;
 316         this.damageforcescale = 0;
 317         this.death_time = 0;
 318         this.respawn_flags = 0;
 319         this.respawn_time = 0;
 320         this.stat_respawn_time = 0;
 321         this.alpha = 0;
 322         this.scale = 0;
 323         this.fade_time = 0;
 324         this.pain_frame = 0;
 325         this.pain_finished = 0;
 326         this.strength_finished = 0;
 327         this.invincible_finished = 0;
 328         this.superweapons_finished = 0;
 329         this.pushltime = 0;
 330         this.istypefrag = 0;
 331         setthink(this, func_null);
 332         this.nextthink = 0;
 333         this.deadflag = DEAD_NO;
 334         this.crouch = false;
 335         this.revival_time = 0;
 336
 337         this.items = 0;
 338         this.weapons = '0 0 0';
 339         this.drawonlytoclient = this;
 340
 341         this.weaponmodel = "";
 342         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 343         {
 344                 if(!this.weaponentities[slot])
 345                         continue; // first load
 346                 this.weaponentities[slot].hook_time = 0;
 347                 this.weaponentities[slot].weaponname = "";
 348                 this.weaponentities[slot] = NULL;
 349         }
 350         this.exteriorweaponentity = NULL;
 351         this.killcount = FRAGS_SPECTATOR;
 352         this.velocity = '0 0 0';
 353         this.avelocity = '0 0 0';
 354         this.punchangle = '0 0 0';
 355         this.punchvector = '0 0 0';
 356         this.oldvelocity = this.velocity;
 357         this.fire_endtime = -1;
 358         this.event_damage = func_null;
 359 }
 360
 361 int player_getspecies(entity this)
 362 {
 363         get_model_parameters(this.model, this.skin);
 364         int s = get_model_parameters_species;
 365         get_model_parameters(string_null, 0);
 366         if (s < 0) return SPECIES_HUMAN;
 367         return s;
 368 }
 369
 370 .float model_randomizer;
 371 void FixPlayermodel(entity player)
 372 {
 373         string defaultmodel = "";
 374         int defaultskin = 0;
 375         if(autocvar_sv_defaultcharacter)
 376         {
 377                 if(teamplay)
 378                 {
 379                         string s = Static_Team_ColorName_Lower(player.team);
 380                         if (s != "neutral")
 381                         {
 382                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 383                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 384                         }
 385                 }
 386
 387                 if(defaultmodel == "")
 388                 {
 389                         defaultmodel = autocvar_sv_defaultplayermodel;
 390                         defaultskin = autocvar_sv_defaultplayerskin;
 391                 }
 392
 393                 int n = tokenize_console(defaultmodel);
 394                 if(n > 0)
 395                 {
 396                         defaultmodel = argv(floor(n * player.model_randomizer));
 397                         // However, do NOT randomize if the player-selected model is in the list.
 398                         for (int i = 0; i < n; ++i)
 399                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 400                                         defaultmodel = argv(i);
 401                 }
 402
 403                 int i = strstrofs(defaultmodel, ":", 0);
 404                 if(i >= 0)
 405                 {
 406                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 407                         defaultmodel = substring(defaultmodel, 0, i);
 408                 }
 409         }
 410         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 411         {
 412                 if(teamplay)
 413                 {
 414                         string s = Static_Team_ColorName_Lower(player.team);
 415                         if (s != "neutral")
 416                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 417                 }
 418
 419                 if(!defaultskin)
 420                         defaultskin = autocvar_sv_defaultplayerskin;
 421         }
 422
 423         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 424         defaultmodel = M_ARGV(0, string);
 425         defaultskin = M_ARGV(1, int);
 426
 427         bool chmdl = false;
 428         int oldskin;
 429         if(defaultmodel != "")
 430         {
 431                 if (defaultmodel != player.model)
 432                 {
 433                         vector m1 = player.mins;
 434                         vector m2 = player.maxs;
 435                         setplayermodel (player, defaultmodel);
 436                         setsize (player, m1, m2);
 437                         chmdl = true;
 438                 }
 439
 440                 oldskin = player.skin;
 441                 player.skin = defaultskin;
 442         } else {
 443                 if (player.playermodel != player.model || player.playermodel == "")
 444                 {
 445                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 446                         vector m1 = player.mins;
 447                         vector m2 = player.maxs;
 448                         setplayermodel (player, player.playermodel);
 449                         setsize (player, m1, m2);
 450                         chmdl = true;
 451                 }
 452
 453                 if(!autocvar_sv_defaultcharacterskin)
 454                 {
 455                         oldskin = player.skin;
 456                         player.skin = stof(player.playerskin);
 457                 }
 458                 else
 459                 {
 460                         oldskin = player.skin;
 461                         player.skin = defaultskin;
 462                 }
 463         }
 464
 465         if(chmdl || oldskin != player.skin) // model or skin has changed
 466         {
 467                 player.species = player_getspecies(player); // update species
 468                 if(!autocvar_g_debug_globalsounds)
 469                         UpdatePlayerSounds(player); // update skin sounds
 470         }
 471
 472         if(!teamplay)
 473                 if(strlen(autocvar_sv_defaultplayercolors))
 474                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 475                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 476 }
 477
 478
 479 /** Called when a client spawns in the server */
 480 void PutClientInServer(entity this)
 481 {
 482         if (IS_BOT_CLIENT(this)) {
 483                 TRANSMUTE(Player, this);
 484         } else if (IS_REAL_CLIENT(this)) {
 485                 msg_entity = this;
 486                 WriteByte(MSG_ONE, SVC_SETVIEW);
 487                 WriteEntity(MSG_ONE, this);
 488         }
 489         if (gameover) {
 490                 TRANSMUTE(Observer, this);
 491         }
 492
 493         SetSpectatee(this, NULL);
 494
 495         // reset player keys
 496         this.itemkeys = 0;
 497
 498         MUTATOR_CALLHOOK(PutClientInServer, this);
 499
 500         if (IS_OBSERVER(this)) {
 501                 PutObserverInServer(this);
 502         } else if (IS_PLAYER(this)) {
 503                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 504
 505                 PlayerState_attach(this);
 506                 accuracy_resend(this);
 507
 508                 if (this.team < 0)
 509                         JoinBestTeam(this, false, true);
 510
 511                 entity spot = SelectSpawnPoint(this, false);
 512                 if (!spot) {
 513                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 514                         return; // spawn failed
 515                 }
 516
 517                 TRANSMUTE(Player, this);
 518
 519                 this.wasplayer = true;
 520                 this.iscreature = true;
 521                 this.teleportable = TELEPORT_NORMAL;
 522                 if(!this.damagedbycontents)
 523                         IL_PUSH(g_damagedbycontents, this);
 524                 this.damagedbycontents = true;
 525                 set_movetype(this, MOVETYPE_WALK);
 526                 this.solid = SOLID_SLIDEBOX;
 527                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 528                 if (autocvar_g_playerclip_collisions)
 529                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 530                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 531                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 532                 this.frags = FRAGS_PLAYER;
 533                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 534                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 535                 if (autocvar__notarget)
 536                         this.flags |= FL_NOTARGET;
 537                 this.takedamage = DAMAGE_AIM;
 538                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 539                 this.dmg = 2; // WTF
 540
 541                 if (warmup_stage) {
 542                         this.ammo_shells = warmup_start_ammo_shells;
 543                         this.ammo_nails = warmup_start_ammo_nails;
 544                         this.ammo_rockets = warmup_start_ammo_rockets;
 545                         this.ammo_cells = warmup_start_ammo_cells;
 546                         this.ammo_plasma = warmup_start_ammo_plasma;
 547                         this.ammo_fuel = warmup_start_ammo_fuel;
 548                         this.health = warmup_start_health;
 549                         this.armorvalue = warmup_start_armorvalue;
 550                         this.weapons = WARMUP_START_WEAPONS;
 551                 } else {
 552                         this.ammo_shells = start_ammo_shells;
 553                         this.ammo_nails = start_ammo_nails;
 554                         this.ammo_rockets = start_ammo_rockets;
 555                         this.ammo_cells = start_ammo_cells;
 556                         this.ammo_plasma = start_ammo_plasma;
 557                         this.ammo_fuel = start_ammo_fuel;
 558                         this.health = start_health;
 559                         this.armorvalue = start_armorvalue;
 560                         this.weapons = start_weapons;
 561                 }
 562                 SetSpectatee_status(this, 0);
 563
 564                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 565
 566                 this.items = start_items;
 567
 568                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 569                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 570                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 571                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 572                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 573                 // extend the pause of rotting if client was reset at the beginning of the countdown
 574                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 575                         float f = game_starttime - time;
 576                         this.spawnshieldtime += f;
 577                         this.pauserotarmor_finished += f;
 578                         this.pauserothealth_finished += f;
 579                         this.pauseregen_finished += f;
 580                 }
 581                 this.damageforcescale = 2;
 582                 this.death_time = 0;
 583                 this.respawn_flags = 0;
 584                 this.respawn_time = 0;
 585                 this.stat_respawn_time = 0;
 586                 this.scale = autocvar_sv_player_scale;
 587                 this.fade_time = 0;
 588                 this.pain_frame = 0;
 589                 this.pain_finished = 0;
 590                 this.pushltime = 0;
 591                 setthink(this, func_null); // players have no think function
 592                 this.nextthink = 0;
 593                 this.dmg_team = 0;
 594                 this.ballistics_density = autocvar_g_ballistics_density_player;
 595
 596                 this.deadflag = DEAD_NO;
 597
 598                 this.angles = spot.angles;
 599                 this.angles_z = 0; // never spawn tilted even if the spot says to
 600                 if (IS_BOT_CLIENT(this))
 601                         this.v_angle = this.angles;
 602                 this.fixangle = true; // turn this way immediately
 603                 this.oldvelocity = this.velocity = '0 0 0';
 604                 this.avelocity = '0 0 0';
 605                 this.punchangle = '0 0 0';
 606                 this.punchvector = '0 0 0';
 607
 608                 this.strength_finished = 0;
 609                 this.invincible_finished = 0;
 610                 this.fire_endtime = -1;
 611                 this.revival_time = 0;
 612                 this.air_finished = time + 12;
 613
 614                 entity spawnevent = new_pure(spawnevent);
 615                 spawnevent.owner = this;
 616                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 617
 618                 // Cut off any still running player sounds.
 619                 stopsound(this, CH_PLAYER_SINGLE);
 620
 621                 this.model = "";
 622                 FixPlayermodel(this);
 623                 this.drawonlytoclient = NULL;
 624
 625                 this.viewloc = NULL;
 626
 627                 this.crouch = false;
 628                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 629                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 630                 this.spawnorigin = spot.origin;
 631                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 632                 // don't reset back to last position, even if new position is stuck in solid
 633                 this.oldorigin = this.origin;
 634                 this.prevorigin = this.origin;
 635                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 636                 if(this.conveyor)
 637                         IL_REMOVE(g_conveyed, this);
 638                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 639                 this.hud = HUD_NORMAL;
 640
 641                 this.event_damage = PlayerDamage;
 642
 643                 if(!this.bot_attack)
 644                         IL_PUSH(g_bot_targets, this);
 645                 this.bot_attack = true;
 646                 this.monster_attack = true;
 647
 648                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 649
 650                 if (this.killcount == FRAGS_SPECTATOR) {
 651                         PlayerScore_Clear(this);
 652                         this.killcount = 0;
 653                 }
 654
 655                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 656                 {
 657                         .entity weaponentity = weaponentities[slot];
 658                         CL_SpawnWeaponentity(this, weaponentity);
 659                 }
 660                 this.alpha = default_player_alpha;
 661                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 662                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 663
 664                 this.speedrunning = false;
 665
 666                 target_voicescript_clear(this);
 667
 668                 // reset fields the weapons may use
 669                 FOREACH(Weapons, true, LAMBDA(
 670                         it.wr_resetplayer(it, this);
 671                         // reload all reloadable weapons
 672                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 673                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 674                                 {
 675                                         .entity weaponentity = weaponentities[slot];
 676                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 677                                 }
 678                         }
 679                 ));
 680
 681                 {
 682                         string s = spot.target;
 683                         spot.target = string_null;
 684                         SUB_UseTargets(spot, this, NULL);
 685                         spot.target = s;
 686                 }
 687
 688                 Unfreeze(this);
 689
 690                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 691
 692                 if (autocvar_spawn_debug)
 693                 {
 694                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 695                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 696                 }
 697
 698                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 699                 {
 700                         .entity weaponentity = weaponentities[slot];
 701                         if(slot == 0)
 702                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 703                         else
 704                                 this.(weaponentity).m_switchweapon = WEP_Null;
 705                         this.(weaponentity).m_weapon = WEP_Null;
 706                         this.(weaponentity).weaponname = "";
 707                         this.(weaponentity).m_switchingweapon = WEP_Null;
 708                         this.(weaponentity).cnt = -1;
 709                 }
 710
 711                 if (!warmup_stage && !this.alivetime)
 712                         this.alivetime = time;
 713
 714                 antilag_clear(this, CS(this));
 715         }
 716 }
 717
 718 void ClientInit_misc(entity this);
 719
 720 // TODO do we need all these fields, or should we stop autodetecting runtime
 721 // changes and just have a console command to update this?
 722 bool ClientInit_SendEntity(entity this, entity to, int sf)
 723 {
 724         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 725         return = true;
 726         msg_entity = to;
 727         // MSG_INIT replacement
 728         // TODO: make easier to use
 729         Registry_send_all();
 730         W_PROP_reload(MSG_ONE, to);
 731         ClientInit_misc(this);
 732         MUTATOR_CALLHOOK(Ent_Init);
 733 }
 734 void ClientInit_misc(entity this)
 735 {
 736         int channel = MSG_ONE;
 737         WriteHeader(channel, ENT_CLIENT_INIT);
 738         WriteByte(channel, g_nexball_meter_period * 32);
 739         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 740         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 741         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 742         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 743         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 744         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 745         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 746         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 747
 748         if(sv_foginterval && world.fog != "")
 749                 WriteString(channel, world.fog);
 750         else
 751                 WriteString(channel, "");
 752         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 753         WriteByte(channel, serverflags);
 754         WriteCoord(channel, autocvar_g_trueaim_minrange);
 755 }
 756
 757 void ClientInit_CheckUpdate(entity this)
 758 {
 759         this.nextthink = time;
 760         if(this.count != autocvar_g_balance_armor_blockpercent)
 761         {
 762                 this.count = autocvar_g_balance_armor_blockpercent;
 763                 this.SendFlags |= 1;
 764         }
 765 }
 766
 767 void ClientInit_Spawn()
 768 {
 769         entity e = new_pure(clientinit);
 770         setthink(e, ClientInit_CheckUpdate);
 771         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 772
 773         ClientInit_CheckUpdate(e);
 774 }
 775
 776 /*
 777 =============
 778 SetNewParms
 779 =============
 780 */
 781 void SetNewParms ()
 782 {
 783         // initialize parms for a new player
 784         parm1 = -(86400 * 366);
 785
 786         MUTATOR_CALLHOOK(SetNewParms);
 787 }
 788
 789 /*
 790 =============
 791 SetChangeParms
 792 =============
 793 */
 794 void SetChangeParms (entity this)
 795 {
 796         // save parms for level change
 797         parm1 = this.parm_idlesince - time;
 798
 799         MUTATOR_CALLHOOK(SetChangeParms);
 800 }
 801
 802 /*
 803 =============
 804 DecodeLevelParms
 805 =============
 806 */
 807 void DecodeLevelParms(entity this)
 808 {
 809         // load parms
 810         this.parm_idlesince = parm1;
 811         if (this.parm_idlesince == -(86400 * 366))
 812                 this.parm_idlesince = time;
 813
 814         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 815         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 816
 817         MUTATOR_CALLHOOK(DecodeLevelParms);
 818 }
 819
 820 /*
 821 =============
 822 ClientKill
 823
 824 Called when a client types 'kill' in the console
 825 =============
 826 */
 827
 828 .float clientkill_nexttime;
 829 void ClientKill_Now_TeamChange(entity this)
 830 {
 831         if(this.killindicator_teamchange == -1)
 832         {
 833                 JoinBestTeam( this, false, true );
 834         }
 835         else if(this.killindicator_teamchange == -2)
 836         {
 837                 if(blockSpectators)
 838                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 839                 PutObserverInServer(this);
 840         }
 841         else
 842                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 843         this.killindicator_teamchange = 0;
 844 }
 845
 846 void ClientKill_Now(entity this)
 847 {
 848         if(this.vehicle)
 849         {
 850             vehicles_exit(this.vehicle, VHEF_RELEASE);
 851             if(!this.killindicator_teamchange)
 852             {
 853             this.vehicle_health = -1;
 854             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 855             }
 856         }
 857
 858         if(this.killindicator && !wasfreed(this.killindicator))
 859                 delete(this.killindicator);
 860
 861         this.killindicator = NULL;
 862
 863         if(this.killindicator_teamchange)
 864                 ClientKill_Now_TeamChange(this);
 865
 866         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 867                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 868
 869         // now I am sure the player IS dead
 870 }
 871 void KillIndicator_Think(entity this)
 872 {
 873         if (gameover)
 874         {
 875                 this.owner.killindicator = NULL;
 876                 delete(this);
 877                 return;
 878         }
 879
 880         if (this.owner.alpha < 0 && !this.owner.vehicle)
 881         {
 882                 this.owner.killindicator = NULL;
 883                 delete(this);
 884                 return;
 885         }
 886
 887         if(this.cnt <= 0)
 888         {
 889                 ClientKill_Now(this.owner);
 890                 return;
 891         }
 892     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 893     {
 894         this.nextthink = time + 1;
 895         this.cnt -= 1;
 896     }
 897         else
 898         {
 899                 if(this.cnt <= 10)
 900                         setmodel(this, MDL_NUM(this.cnt));
 901                 if(IS_REAL_CLIENT(this.owner))
 902                 {
 903                         if(this.cnt <= 10)
 904                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 905                 }
 906                 this.nextthink = time + 1;
 907                 this.cnt -= 1;
 908         }
 909 }
 910
 911 float clientkilltime;
 912 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 913 {
 914         float killtime;
 915         float starttime;
 916
 917         if (gameover)
 918                 return;
 919
 920         killtime = autocvar_g_balance_kill_delay;
 921
 922         if(g_race_qualifying || g_cts)
 923                 killtime = 0;
 924
 925     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 926         return;
 927
 928         this.killindicator_teamchange = targetteam;
 929
 930     if(!this.killindicator)
 931         {
 932                 if(!IS_DEAD(this))
 933                 {
 934                         killtime = max(killtime, this.clientkill_nexttime - time);
 935                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 936                 }
 937
 938                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 939                 {
 940                         ClientKill_Now(this);
 941                 }
 942                 else
 943                 {
 944                         starttime = max(time, clientkilltime);
 945
 946                         this.killindicator = spawn();
 947                         this.killindicator.owner = this;
 948                         this.killindicator.scale = 0.5;
 949                         setattachment(this.killindicator, this, "");
 950                         setorigin(this.killindicator, '0 0 52');
 951                         setthink(this.killindicator, KillIndicator_Think);
 952                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 953                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 954                         this.killindicator.cnt = ceil(killtime);
 955                         this.killindicator.count = bound(0, ceil(killtime), 10);
 956                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 957
 958                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 959                         {
 960                                 it.killindicator = spawn();
 961                                 it.killindicator.owner = it;
 962                                 it.killindicator.scale = 0.5;
 963                                 setattachment(it.killindicator, it, "");
 964                                 setorigin(it.killindicator, '0 0 52');
 965                                 setthink(it.killindicator, KillIndicator_Think);
 966                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 967                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 968                                 it.killindicator.cnt = ceil(killtime);
 969                         });
 970                         this.lip = 0;
 971                 }
 972         }
 973         if(this.killindicator)
 974         {
 975                 if(targetteam == 0) // just die
 976                 {
 977                         this.killindicator.colormod = '0 0 0';
 978                         if(IS_REAL_CLIENT(this))
 979                         if(this.killindicator.cnt > 0)
 980                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 981                 }
 982                 else if(targetteam == -1) // auto
 983                 {
 984                         this.killindicator.colormod = '0 1 0';
 985                         if(IS_REAL_CLIENT(this))
 986                         if(this.killindicator.cnt > 0)
 987                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 988                 }
 989                 else if(targetteam == -2) // spectate
 990                 {
 991                         this.killindicator.colormod = '0.5 0.5 0.5';
 992                         if(IS_REAL_CLIENT(this))
 993                         if(this.killindicator.cnt > 0)
 994                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 995                 }
 996                 else
 997                 {
 998                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 999                         if(IS_REAL_CLIENT(this))
1000                         if(this.killindicator.cnt > 0)
1001                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1002                 }
1003         }
1004
1005 }
1006
1007 void ClientKill (entity this)
1008 {
1009         if(gameover) return;
1010         if(this.player_blocked) return;
1011         if(STAT(FROZEN, this)) return;
1012
1013         ClientKill_TeamChange(this, 0);
1014 }
1015
1016 void FixClientCvars(entity e)
1017 {
1018         // send prediction settings to the client
1019         stuffcmd(e, "\nin_bindmap 0 0\n");
1020         if(autocvar_g_antilag == 3) // client side hitscan
1021                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1022         if(autocvar_sv_gentle)
1023                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1024
1025         MUTATOR_CALLHOOK(FixClientCvars, e);
1026 }
1027
1028 float PlayerInIDList(entity p, string idlist)
1029 {
1030         float n, i;
1031         string s;
1032
1033         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1034         if (!p.crypto_idfp)
1035                 return 0;
1036
1037         // this function allows abbreviated player IDs too!
1038         n = tokenize_console(idlist);
1039         for(i = 0; i < n; ++i)
1040         {
1041                 s = argv(i);
1042                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1043                         return 1;
1044         }
1045
1046         return 0;
1047 }
1048
1049 #ifdef DP_EXT_PRECONNECT
1050 /*
1051 =============
1052 ClientPreConnect
1053
1054 Called once (not at each match start) when a client begins a connection to the server
1055 =============
1056 */
1057 void ClientPreConnect ()
1058 {ENGINE_EVENT();
1059         if(autocvar_sv_eventlog)
1060         {
1061                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1062                         this.playerid,
1063                         etof(this),
1064                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1065                 ));
1066         }
1067 }
1068 #endif
1069
1070 /**
1071 =============
1072 ClientConnect
1073
1074 Called when a client connects to the server
1075 =============
1076 */
1077 void ClientConnect(entity this)
1078 {
1079         if (Ban_MaybeEnforceBanOnce(this)) return;
1080         assert(!IS_CLIENT(this), return);
1081         this.flags |= FL_CLIENT;
1082         assert(player_count >= 0, player_count = 0);
1083
1084 #ifdef WATERMARK
1085         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1086 #endif
1087         this.version_nagtime = time + 10 + random() * 10;
1088         TRANSMUTE(Client, this);
1089
1090         // identify the right forced team
1091         if (autocvar_g_campaign)
1092         {
1093                 if (IS_REAL_CLIENT(this)) // only players, not bots
1094                 {
1095                         switch (autocvar_g_campaign_forceteam)
1096                         {
1097                                 case 1: this.team_forced = NUM_TEAM_1; break;
1098                                 case 2: this.team_forced = NUM_TEAM_2; break;
1099                                 case 3: this.team_forced = NUM_TEAM_3; break;
1100                                 case 4: this.team_forced = NUM_TEAM_4; break;
1101                                 default: this.team_forced = 0;
1102                         }
1103                 }
1104         }
1105         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1106         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1107         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1108         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1109         else switch (autocvar_g_forced_team_otherwise)
1110         {
1111                 default: this.team_forced = 0; break;
1112                 case "red": this.team_forced = NUM_TEAM_1; break;
1113                 case "blue": this.team_forced = NUM_TEAM_2; break;
1114                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1115                 case "pink": this.team_forced = NUM_TEAM_4; break;
1116                 case "spectate":
1117                 case "spectator":
1118                         this.team_forced = -1;
1119                         break;
1120         }
1121         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1122
1123     {
1124         int id = this.playerid;
1125         this.playerid = 0; // silent
1126             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1127             this.playerid = id;
1128     }
1129
1130         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1131                 TRANSMUTE(Observer, this);
1132         } else {
1133                 if (!teamplay || autocvar_g_balance_teams) {
1134                         TRANSMUTE(Player, this);
1135                         campaign_bots_may_start = true;
1136                 } else {
1137                         TRANSMUTE(Observer, this); // do it anyway
1138                 }
1139         }
1140
1141         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1142
1143         // always track bots, don't ask for cl_allow_uidtracking
1144     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1145
1146         if (autocvar_sv_eventlog)
1147                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1148
1149         LogTeamchange(this.playerid, this.team, 1);
1150
1151         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1152
1153         this.netname_previous = strzone(this.netname);
1154
1155         if(teamplay && IS_PLAYER(this))
1156                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1157         else
1158                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1159
1160         stuffcmd(this, clientstuff, "\n");
1161         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1162
1163         FixClientCvars(this);
1164
1165         // get version info from player
1166         stuffcmd(this, "cmd clientversion $gameversion\n");
1167
1168         // notify about available teams
1169         if (teamplay)
1170         {
1171                 CheckAllowedTeams(this);
1172                 int t = 0;
1173                 if (c1 >= 0) t |= BIT(0);
1174                 if (c2 >= 0) t |= BIT(1);
1175                 if (c3 >= 0) t |= BIT(2);
1176                 if (c4 >= 0) t |= BIT(3);
1177                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1178         }
1179         else
1180         {
1181                 stuffcmd(this, "set _teams_available 0\n");
1182         }
1183
1184         bot_relinkplayerlist();
1185
1186         this.spectatortime = time;
1187         if (blockSpectators)
1188         {
1189                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1190         }
1191
1192         this.jointime = time;
1193         this.allowed_timeouts = autocvar_sv_timeout_number;
1194
1195         if (IS_REAL_CLIENT(this))
1196         {
1197                 if (!autocvar_g_campaign)
1198                 {
1199                         this.motd_actived_time = -1;
1200                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1201                 }
1202
1203                 if (g_weaponarena_weapons == WEPSET(TUBA))
1204                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1205         }
1206
1207         if (!sv_foginterval && world.fog != "")
1208                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1209
1210         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1211                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1212                         send_CSQC_teamnagger();
1213
1214         CSQCMODEL_AUTOINIT(this);
1215
1216         this.model_randomizer = random();
1217
1218         if (IS_REAL_CLIENT(this))
1219                 sv_notice_join(this);
1220
1221         // update physics stats (players can spawn before physics runs)
1222         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1223
1224         IL_EACH(g_initforplayer, it.init_for_player, {
1225                 it.init_for_player(it, this);
1226         });
1227
1228         MUTATOR_CALLHOOK(ClientConnect, this);
1229 }
1230 /*
1231 =============
1232 ClientDisconnect
1233
1234 Called when a client disconnects from the server
1235 =============
1236 */
1237 .entity chatbubbleentity;
1238 void ReadyCount();
1239 void ClientDisconnect(entity this)
1240 {
1241         assert(IS_CLIENT(this), return);
1242
1243         PlayerStats_GameReport_FinalizePlayer(this);
1244         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1245         if (this.active_minigame) part_minigame(this);
1246         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1247
1248         if (autocvar_sv_eventlog)
1249                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1250
1251         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1252
1253         SetSpectatee(this, NULL);
1254
1255     MUTATOR_CALLHOOK(ClientDisconnect, this);
1256
1257         ClientState_detach(this);
1258
1259         Portal_ClearAll(this);
1260
1261         Unfreeze(this);
1262
1263         RemoveGrapplingHooks(this);
1264
1265         // Here, everything has been done that requires this player to be a client.
1266
1267         this.flags &= ~FL_CLIENT;
1268
1269         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1270         if (this.killindicator) delete(this.killindicator);
1271
1272         WaypointSprite_PlayerGone(this);
1273
1274         bot_relinkplayerlist();
1275
1276         if (this.netname_previous) strunzone(this.netname_previous);
1277         if (this.clientstatus) strunzone(this.clientstatus);
1278         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1279         if (this.personal) delete(this.personal);
1280
1281         this.playerid = 0;
1282         ReadyCount();
1283         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1284 }
1285
1286 void ChatBubbleThink(entity this)
1287 {
1288         this.nextthink = time;
1289         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1290         {
1291                 if(this.owner) // but why can that ever be NULL?
1292                         this.owner.chatbubbleentity = NULL;
1293                 delete(this);
1294                 return;
1295         }
1296
1297         this.mdl = "";
1298
1299         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1300         {
1301                 if ( this.owner.active_minigame )
1302                         this.mdl = "models/sprites/minigame_busy.iqm";
1303                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1304                         this.mdl = "models/misc/chatbubble.spr";
1305         }
1306
1307         if ( this.model != this.mdl )
1308                 _setmodel(this, this.mdl);
1309
1310 }
1311
1312 void UpdateChatBubble(entity this)
1313 {
1314         if (this.alpha < 0)
1315                 return;
1316         // spawn a chatbubble entity if needed
1317         if (!this.chatbubbleentity)
1318         {
1319                 this.chatbubbleentity = new(chatbubbleentity);
1320                 this.chatbubbleentity.owner = this;
1321                 this.chatbubbleentity.exteriormodeltoclient = this;
1322                 setthink(this.chatbubbleentity, ChatBubbleThink);
1323                 this.chatbubbleentity.nextthink = time;
1324                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1325                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1326                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1327                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1328                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1329                 //this.chatbubbleentity.model = "";
1330                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1331         }
1332 }
1333
1334
1335 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1336 // added to the model skins
1337 /*void UpdateColorModHack()
1338 {
1339         float c;
1340         c = this.clientcolors & 15;
1341         // LordHavoc: only bothering to support white, green, red, yellow, blue
1342              if (!teamplay) this.colormod = '0 0 0';
1343         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1344         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1345         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1346         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1347         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1348         else this.colormod = '1 1 1';
1349 }*/
1350
1351 void respawn(entity this)
1352 {
1353         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1354         {
1355                 this.solid = SOLID_NOT;
1356                 this.takedamage = DAMAGE_NO;
1357                 set_movetype(this, MOVETYPE_FLY);
1358                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1359                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1360                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1361                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1362                 if(autocvar_g_respawn_ghosts_maxtime)
1363                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1364         }
1365
1366         CopyBody(this, 1);
1367
1368         this.effects |= EF_NODRAW; // prevent another CopyBody
1369         PutClientInServer(this);
1370 }
1371
1372 void play_countdown(entity this, float finished, Sound samp)
1373 {
1374     TC(Sound, samp);
1375         if(IS_REAL_CLIENT(this))
1376                 if(floor(finished - time - frametime) != floor(finished - time))
1377                         if(finished - time < 6)
1378                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1379 }
1380
1381 void player_powerups(entity this)
1382 {
1383         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1384         int items_prev = this.items;
1385
1386         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1387                 this.modelflags |= MF_ROCKET;
1388         else
1389                 this.modelflags &= ~MF_ROCKET;
1390
1391         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1392
1393         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1394                 return;
1395
1396         Fire_ApplyDamage(this);
1397         Fire_ApplyEffect(this);
1398
1399         if (!g_instagib)
1400         {
1401                 if (this.items & ITEM_Strength.m_itemid)
1402                 {
1403                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1404                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1405                         if (time > this.strength_finished)
1406                         {
1407                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1408                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1409                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1410                         }
1411                 }
1412                 else
1413                 {
1414                         if (time < this.strength_finished)
1415                         {
1416                                 this.items = this.items | ITEM_Strength.m_itemid;
1417                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1418                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1419                         }
1420                 }
1421                 if (this.items & ITEM_Shield.m_itemid)
1422                 {
1423                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1424                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1425                         if (time > this.invincible_finished)
1426                         {
1427                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1428                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1429                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1430                         }
1431                 }
1432                 else
1433                 {
1434                         if (time < this.invincible_finished)
1435                         {
1436                                 this.items = this.items | ITEM_Shield.m_itemid;
1437                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1438                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1439                         }
1440                 }
1441                 if (this.items & IT_SUPERWEAPON)
1442                 {
1443                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1444                         {
1445                                 this.superweapons_finished = 0;
1446                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1447                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1448                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1449                         }
1450                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1451                         {
1452                                 // don't let them run out
1453                         }
1454                         else
1455                         {
1456                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1457                                 if (time > this.superweapons_finished)
1458                                 {
1459                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1460                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1461                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1462                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1463                                 }
1464                         }
1465                 }
1466                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1467                 {
1468                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1469                         {
1470                                 this.items = this.items | IT_SUPERWEAPON;
1471                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1472                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1473                         }
1474                         else
1475                         {
1476                                 this.superweapons_finished = 0;
1477                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1478                         }
1479                 }
1480                 else
1481                 {
1482                         this.superweapons_finished = 0;
1483                 }
1484         }
1485
1486         if(autocvar_g_nodepthtestplayers)
1487                 this.effects = this.effects | EF_NODEPTHTEST;
1488
1489         if(autocvar_g_fullbrightplayers)
1490                 this.effects = this.effects | EF_FULLBRIGHT;
1491
1492         if (time >= game_starttime)
1493         if (time < this.spawnshieldtime)
1494                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1495
1496         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1497 }
1498
1499 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1500 {
1501         if(current > stable)
1502                 return current;
1503         else if(current > stable - 0.25) // when close enough, "snap"
1504                 return stable;
1505         else
1506                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1507 }
1508
1509 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1510 {
1511         if(current < stable)
1512                 return current;
1513         else if(current < stable + 0.25) // when close enough, "snap"
1514                 return stable;
1515         else
1516                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1517 }
1518
1519 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1520 {
1521         if(current > rotstable)
1522         {
1523                 if(rotframetime > 0)
1524                 {
1525                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1526                         current = max(rotstable, current - rotlinear * rotframetime);
1527                 }
1528         }
1529         else if(current < regenstable)
1530         {
1531                 if(regenframetime > 0)
1532                 {
1533                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1534                         current = min(regenstable, current + regenlinear * regenframetime);
1535                 }
1536         }
1537
1538         if(current > limit)
1539                 current = limit;
1540
1541         return current;
1542 }
1543
1544 void player_regen(entity this)
1545 {
1546         float max_mod, regen_mod, rot_mod, limit_mod;
1547         max_mod = regen_mod = rot_mod = limit_mod = 1;
1548
1549         float regen_health = autocvar_g_balance_health_regen;
1550         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1551         float regen_health_rot = autocvar_g_balance_health_rot;
1552         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1553         float regen_health_stable = autocvar_g_balance_health_regenstable;
1554         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1555         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1556                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1557         max_mod = M_ARGV(1, float);
1558         regen_mod = M_ARGV(2, float);
1559         rot_mod = M_ARGV(3, float);
1560         limit_mod = M_ARGV(4, float);
1561         regen_health = M_ARGV(5, float);
1562         regen_health_linear = M_ARGV(6, float);
1563         regen_health_rot = M_ARGV(7, float);
1564         regen_health_rotlinear = M_ARGV(8, float);
1565         regen_health_stable = M_ARGV(9, float);
1566         regen_health_rotstable = M_ARGV(10, float);
1567
1568
1569         if(!mutator_returnvalue)
1570         if(!STAT(FROZEN, this))
1571         {
1572                 float mina, maxa, limith, limita;
1573                 maxa = autocvar_g_balance_armor_rotstable;
1574                 mina = autocvar_g_balance_armor_regenstable;
1575                 limith = autocvar_g_balance_health_limit;
1576                 limita = autocvar_g_balance_armor_limit;
1577
1578                 regen_health_rotstable = regen_health_rotstable * max_mod;
1579                 regen_health_stable = regen_health_stable * max_mod;
1580                 limith = limith * limit_mod;
1581                 limita = limita * limit_mod;
1582
1583                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1584                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1585         }
1586
1587         // if player rotted to death...  die!
1588         // check this outside above checks, as player may still be able to rot to death
1589         if(this.health < 1)
1590         {
1591                 if(this.vehicle)
1592                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1593                 if(this.event_damage)
1594                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1595         }
1596
1597         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1598         {
1599                 float minf, maxf, limitf;
1600
1601                 maxf = autocvar_g_balance_fuel_rotstable;
1602                 minf = autocvar_g_balance_fuel_regenstable;
1603                 limitf = autocvar_g_balance_fuel_limit;
1604
1605                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1606         }
1607 }
1608
1609 bool zoomstate_set;
1610 void SetZoomState(entity this, float z)
1611 {
1612         if(z != this.zoomstate)
1613         {
1614                 this.zoomstate = z;
1615                 ClientData_Touch(this);
1616         }
1617         zoomstate_set = true;
1618 }
1619
1620 void GetPressedKeys(entity this)
1621 {
1622         MUTATOR_CALLHOOK(GetPressedKeys, this);
1623         int keys = STAT(PRESSED_KEYS, this);
1624         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1625         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1626         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1627         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1628
1629         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1630         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1631         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1632         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1633         this.pressedkeys = keys; // store for other users
1634
1635         STAT(PRESSED_KEYS, this) = keys;
1636 }
1637
1638 /*
1639 ======================
1640 spectate mode routines
1641 ======================
1642 */
1643
1644 void SpectateCopy(entity this, entity spectatee)
1645 {
1646     TC(Client, this); TC(Client, spectatee);
1647
1648         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1649         PS(this) = PS(spectatee);
1650         this.armortype = spectatee.armortype;
1651         this.armorvalue = spectatee.armorvalue;
1652         this.ammo_cells = spectatee.ammo_cells;
1653         this.ammo_plasma = spectatee.ammo_plasma;
1654         this.ammo_shells = spectatee.ammo_shells;
1655         this.ammo_nails = spectatee.ammo_nails;
1656         this.ammo_rockets = spectatee.ammo_rockets;
1657         this.ammo_fuel = spectatee.ammo_fuel;
1658         this.clip_load = spectatee.clip_load;
1659         this.clip_size = spectatee.clip_size;
1660         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1661         this.health = spectatee.health;
1662         this.impulse = 0;
1663         this.items = spectatee.items;
1664         this.last_pickup = spectatee.last_pickup;
1665         this.hit_time = spectatee.hit_time;
1666         this.strength_finished = spectatee.strength_finished;
1667         this.invincible_finished = spectatee.invincible_finished;
1668         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1669         this.weapons = spectatee.weapons;
1670         this.vortex_charge = spectatee.vortex_charge;
1671         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1672         this.hagar_load = spectatee.hagar_load;
1673         this.arc_heat_percent = spectatee.arc_heat_percent;
1674         this.minelayer_mines = spectatee.minelayer_mines;
1675         this.punchangle = spectatee.punchangle;
1676         this.view_ofs = spectatee.view_ofs;
1677         this.velocity = spectatee.velocity;
1678         this.dmg_take = spectatee.dmg_take;
1679         this.dmg_save = spectatee.dmg_save;
1680         this.dmg_inflictor = spectatee.dmg_inflictor;
1681         this.v_angle = spectatee.v_angle;
1682         this.angles = spectatee.v_angle;
1683         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1684         this.revive_progress = spectatee.revive_progress;
1685         this.viewloc = spectatee.viewloc;
1686         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1687                 this.fixangle = true;
1688         setorigin(this, spectatee.origin);
1689         setsize(this, spectatee.mins, spectatee.maxs);
1690         SetZoomState(this, spectatee.zoomstate);
1691
1692         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1693         {
1694                 .entity weaponentity = weaponentities[slot];
1695                 this.(weaponentity) = spectatee.(weaponentity);
1696         }
1697
1698     anticheat_spectatecopy(this, spectatee);
1699         this.hud = spectatee.hud;
1700         if(spectatee.vehicle)
1701     {
1702         this.angles = spectatee.v_angle;
1703
1704         //this.fixangle = false;
1705         //this.velocity = spectatee.vehicle.velocity;
1706         this.vehicle_health = spectatee.vehicle_health;
1707         this.vehicle_shield = spectatee.vehicle_shield;
1708         this.vehicle_energy = spectatee.vehicle_energy;
1709         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1710         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1711         this.vehicle_reload1 = spectatee.vehicle_reload1;
1712         this.vehicle_reload2 = spectatee.vehicle_reload2;
1713
1714         //msg_entity = this;
1715
1716        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1717             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1718            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1719            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1720
1721         //WriteByte (MSG_ONE, SVC_SETVIEW);
1722         //    WriteEntity(MSG_ONE, this);
1723         //makevectors(spectatee.v_angle);
1724         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1725     }
1726 }
1727
1728 bool SpectateUpdate(entity this)
1729 {
1730         if(!this.enemy)
1731                 return false;
1732
1733         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1734         {
1735                 SetSpectatee(this, NULL);
1736                 return false;
1737         }
1738
1739         SpectateCopy(this, this.enemy);
1740
1741         return true;
1742 }
1743
1744 bool SpectateSet(entity this)
1745 {
1746         if(!IS_PLAYER(this.enemy))
1747                 return false;
1748
1749         ClientData_Touch(this.enemy);
1750
1751         msg_entity = this;
1752         WriteByte(MSG_ONE, SVC_SETVIEW);
1753         WriteEntity(MSG_ONE, this.enemy);
1754         set_movetype(this, MOVETYPE_NONE);
1755         accuracy_resend(this);
1756
1757         if(!SpectateUpdate(this))
1758                 PutObserverInServer(this);
1759
1760         return true;
1761 }
1762
1763 void SetSpectatee_status(entity this, int spectatee_num)
1764 {
1765         int oldspectatee_status = this.spectatee_status;
1766         this.spectatee_status = spectatee_num;
1767
1768         if (this.spectatee_status != oldspectatee_status)
1769         {
1770                 ClientData_Touch(this);
1771                 if (g_race || g_cts) race_InitSpectator();
1772         }
1773 }
1774
1775 void SetSpectatee(entity this, entity spectatee)
1776 {
1777         entity old_spectatee = this.enemy;
1778
1779         this.enemy = spectatee;
1780
1781         // WEAPONTODO
1782         // these are required to fix the spectator bug with arc
1783         if(old_spectatee)
1784         {
1785                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1786                 {
1787                         .entity weaponentity = weaponentities[slot];
1788                         if(old_spectatee.(weaponentity).arc_beam)
1789                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1790                 }
1791         }
1792         if(this.enemy)
1793         {
1794                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1795                 {
1796                         .entity weaponentity = weaponentities[slot];
1797                         if(this.enemy.(weaponentity).arc_beam)
1798                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1799                 }
1800         }
1801
1802         if (this.enemy)
1803                 SetSpectatee_status(this, etof(this.enemy));
1804
1805         // needed to update spectator list
1806         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1807 }
1808
1809 bool Spectate(entity this, entity pl)
1810 {
1811         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1812                 return false;
1813         pl = M_ARGV(1, entity);
1814
1815         SetSpectatee(this, pl);
1816         return SpectateSet(this);
1817 }
1818
1819 bool SpectateNext(entity this)
1820 {
1821         entity ent = find(this.enemy, classname, STR_PLAYER);
1822
1823         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1824                 ent = M_ARGV(1, entity);
1825         else if (!ent)
1826                 ent = find(ent, classname, STR_PLAYER);
1827
1828         if(ent) { SetSpectatee(this, ent); }
1829
1830         return SpectateSet(this);
1831 }
1832
1833 bool SpectatePrev(entity this)
1834 {
1835         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1836         entity ent = findchain(classname, STR_PLAYER);
1837         if (!ent) // no player
1838                 return false;
1839
1840         entity first = ent;
1841         // skip players until current spectated player
1842         if(this.enemy)
1843         while(ent && ent != this.enemy)
1844                 ent = ent.chain;
1845
1846         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1847         {
1848                 case MUT_SPECPREV_FOUND:
1849                     ent = M_ARGV(1, entity);
1850                     break;
1851                 case MUT_SPECPREV_RETURN:
1852                     return true;
1853                 case MUT_SPECPREV_CONTINUE:
1854                 default:
1855                 {
1856                         if(ent.chain)
1857                                 ent = ent.chain;
1858                         else
1859                                 ent = first;
1860                         break;
1861                 }
1862         }
1863
1864         SetSpectatee(this, ent);
1865         return SpectateSet(this);
1866 }
1867
1868 /*
1869 =============
1870 ShowRespawnCountdown()
1871
1872 Update a respawn countdown display.
1873 =============
1874 */
1875 void ShowRespawnCountdown(entity this)
1876 {
1877         float number;
1878         if(!IS_DEAD(this)) // just respawned?
1879                 return;
1880         else
1881         {
1882                 number = ceil(this.respawn_time - time);
1883                 if(number <= 0)
1884                         return;
1885                 if(number <= this.respawn_countdown)
1886                 {
1887                         this.respawn_countdown = number - 1;
1888                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1889                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1890                 }
1891         }
1892 }
1893
1894 .bool team_selected;
1895 bool ShowTeamSelection(entity this)
1896 {
1897         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1898                 return false;
1899         stuffcmd(this, "menu_showteamselect\n");
1900         return true;
1901 }
1902 void Join(entity this)
1903 {
1904         TRANSMUTE(Player, this);
1905
1906         if(!this.team_selected)
1907         if(autocvar_g_campaign || autocvar_g_balance_teams)
1908                 JoinBestTeam(this, false, true);
1909
1910         if(autocvar_g_campaign)
1911                 campaign_bots_may_start = true;
1912
1913         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1914
1915         PutClientInServer(this);
1916
1917         if(teamplay && this.team != -1)
1918                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1919         else
1920                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1921         this.team_selected = false;
1922 }
1923
1924 /**
1925  * Determines whether the player is allowed to join. This depends on cvar
1926  * g_maxplayers, if it isn't used this function always return true, otherwise
1927  * it checks whether the number of currently playing players exceeds g_maxplayers.
1928  * @return int number of free slots for players, 0 if none
1929  */
1930 int nJoinAllowed(entity this, entity ignore)
1931 {
1932         if(!ignore)
1933         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1934         // so report 0 free slots if restricted
1935         {
1936                 if(autocvar_g_forced_team_otherwise == "spectate")
1937                         return 0;
1938                 if(autocvar_g_forced_team_otherwise == "spectator")
1939                         return 0;
1940         }
1941
1942         if(this && this.team_forced < 0)
1943                 return 0; // forced spectators can never join
1944
1945         // TODO simplify this
1946         int totalClients = 0;
1947         int currentlyPlaying = 0;
1948         FOREACH_CLIENT(true, LAMBDA(
1949                 if(it != ignore)
1950                         ++totalClients;
1951                 if(IS_REAL_CLIENT(it))
1952                 if(IS_PLAYER(it) || it.caplayer)
1953                         ++currentlyPlaying;
1954         ));
1955
1956         float free_slots = 0;
1957         if (!autocvar_g_maxplayers)
1958                 free_slots = maxclients - totalClients;
1959         else if(currentlyPlaying < autocvar_g_maxplayers)
1960                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1961
1962         static float join_prevent_msg_time = 0;
1963         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1964         {
1965                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1966                 join_prevent_msg_time = time + 3;
1967         }
1968
1969         return free_slots;
1970 }
1971
1972 /**
1973  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1974  * g_maxplayers_spectator_blocktime seconds
1975  */
1976 void checkSpectatorBlock(entity this)
1977 {
1978         if(IS_SPEC(this) || IS_OBSERVER(this))
1979         if(!this.caplayer)
1980         if(IS_REAL_CLIENT(this))
1981         {
1982                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1983                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1984                         dropclient(this);
1985                 }
1986         }
1987 }
1988
1989 void PrintWelcomeMessage(entity this)
1990 {
1991         if(this.motd_actived_time == 0)
1992         {
1993                 if (autocvar_g_campaign) {
1994                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1995                                 this.motd_actived_time = time;
1996                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1997                         }
1998                 } else {
1999                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2000                                 this.motd_actived_time = time;
2001                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2002                         }
2003                 }
2004         }
2005         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2006         {
2007                 if (autocvar_g_campaign) {
2008                         if (PHYS_INPUT_BUTTON_INFO(this))
2009                                 this.motd_actived_time = time;
2010                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2011                                 this.motd_actived_time = 0;
2012                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2013                         }
2014                 } else {
2015                         if (PHYS_INPUT_BUTTON_INFO(this))
2016                                 this.motd_actived_time = time;
2017                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2018                                 this.motd_actived_time = 0;
2019                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2020                         }
2021                 }
2022         }
2023         else //if(this.motd_actived_time < 0) // just connected, motd is active
2024         {
2025                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2026                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2027                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2028                 {
2029                         // instanctly hide MOTD
2030                         this.motd_actived_time = 0;
2031                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2032                 }
2033         }
2034 }
2035
2036 bool joinAllowed(entity this)
2037 {
2038         if (this.version_mismatch) return false;
2039         if (!nJoinAllowed(this, this)) return false;
2040         if (teamplay && lockteams) return false;
2041         if (ShowTeamSelection(this)) return false;
2042         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2043         return true;
2044 }
2045
2046 void ObserverThink(entity this)
2047 {
2048         if ( this.impulse )
2049         {
2050                 MinigameImpulse(this, this.impulse);
2051                 this.impulse = 0;
2052         }
2053
2054         if (this.flags & FL_JUMPRELEASED) {
2055                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2056                         this.flags &= ~FL_JUMPRELEASED;
2057                         this.flags |= FL_SPAWNING;
2058                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2059                         this.flags &= ~FL_JUMPRELEASED;
2060                         if(SpectateNext(this)) {
2061                                 TRANSMUTE(Spectator, this);
2062                         }
2063                 } else {
2064                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2065                         set_movetype(this, preferred_movetype);
2066                 }
2067         } else {
2068                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2069                         this.flags |= FL_JUMPRELEASED;
2070                         if(this.flags & FL_SPAWNING)
2071                         {
2072                                 this.flags &= ~FL_SPAWNING;
2073                                 Join(this);
2074                                 return;
2075                         }
2076                 }
2077         }
2078 }
2079
2080 void SpectatorThink(entity this)
2081 {
2082         if ( this.impulse )
2083         {
2084                 if(MinigameImpulse(this, this.impulse))
2085                         this.impulse = 0;
2086
2087                 if (this.impulse == IMP_weapon_drop.impulse)
2088                 {
2089                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2090                         this.impulse = 0;
2091                         return;
2092                 }
2093         }
2094
2095         if (this.flags & FL_JUMPRELEASED) {
2096                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2097                         this.flags &= ~FL_JUMPRELEASED;
2098                         this.flags |= FL_SPAWNING;
2099                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2100                         this.flags &= ~FL_JUMPRELEASED;
2101                         if(SpectateNext(this)) {
2102                                 TRANSMUTE(Spectator, this);
2103                         } else {
2104                                 TRANSMUTE(Observer, this);
2105                                 PutClientInServer(this);
2106                         }
2107                         this.impulse = 0;
2108                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2109                         this.flags &= ~FL_JUMPRELEASED;
2110                         if(SpectatePrev(this)) {
2111                                 TRANSMUTE(Spectator, this);
2112                         } else {
2113                                 TRANSMUTE(Observer, this);
2114                                 PutClientInServer(this);
2115                         }
2116                         this.impulse = 0;
2117                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2118                         this.flags &= ~FL_JUMPRELEASED;
2119                         TRANSMUTE(Observer, this);
2120                         PutClientInServer(this);
2121                 } else {
2122                         if(!SpectateUpdate(this))
2123                                 PutObserverInServer(this);
2124                 }
2125         } else {
2126                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2127                         this.flags |= FL_JUMPRELEASED;
2128                         if(this.flags & FL_SPAWNING)
2129                         {
2130                                 this.flags &= ~FL_SPAWNING;
2131                                 Join(this);
2132                                 return;
2133                         }
2134                 }
2135                 if(!SpectateUpdate(this))
2136                         PutObserverInServer(this);
2137         }
2138
2139         this.flags |= FL_CLIENT | FL_NOTARGET;
2140 }
2141
2142 void vehicles_enter (entity pl, entity veh);
2143 void PlayerUseKey(entity this)
2144 {
2145         if (!IS_PLAYER(this))
2146                 return;
2147
2148         if(this.vehicle)
2149         {
2150                 if(!gameover)
2151                 {
2152                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2153                         return;
2154                 }
2155         }
2156         else if(autocvar_g_vehicles_enter)
2157         {
2158                 if(!STAT(FROZEN, this))
2159                 if(!IS_DEAD(this))
2160                 if(!gameover)
2161                 {
2162                         entity head, closest_target = NULL;
2163                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2164
2165                         while(head) // find the closest acceptable target to enter
2166                         {
2167                                 if(IS_VEHICLE(head))
2168                                 if(!IS_DEAD(head))
2169                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2170                                 if(head.takedamage != DAMAGE_NO)
2171                                 {
2172                                         if(closest_target)
2173                                         {
2174                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2175                                                 { closest_target = head; }
2176                                         }
2177                                         else { closest_target = head; }
2178                                 }
2179
2180                                 head = head.chain;
2181                         }
2182
2183                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2184                 }
2185         }
2186
2187         // a use key was pressed; call handlers
2188         MUTATOR_CALLHOOK(PlayerUseKey, this);
2189 }
2190
2191
2192 /*
2193 =============
2194 PlayerPreThink
2195
2196 Called every frame for each client before the physics are run
2197 =============
2198 */
2199 .float usekeypressed;
2200 .float last_vehiclecheck;
2201 .int items_added;
2202 void PlayerPreThink (entity this)
2203 {
2204         WarpZone_PlayerPhysics_FixVAngle(this);
2205
2206     STAT(GAMESTARTTIME, this) = game_starttime;
2207         STAT(ROUNDSTARTTIME, this) = round_starttime;
2208         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2209         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2210
2211         STAT(WEAPONSINMAP, this) = weaponsInMap;
2212
2213         if (frametime) {
2214                 // physics frames: update anticheat stuff
2215                 anticheat_prethink(this);
2216         }
2217
2218         if (blockSpectators && frametime) {
2219                 // WORKAROUND: only use dropclient in server frames (frametime set).
2220                 // Never use it in cl_movement frames (frametime zero).
2221                 checkSpectatorBlock(this);
2222     }
2223
2224         zoomstate_set = false;
2225
2226         // Check for nameless players
2227         if (isInvisibleString(this.netname)) {
2228                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2229                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2230         }
2231         if (this.netname != this.netname_previous) {
2232                 if (autocvar_sv_eventlog) {
2233                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2234         }
2235                 if (this.netname_previous) strunzone(this.netname_previous);
2236                 this.netname_previous = strzone(this.netname);
2237         }
2238
2239         // version nagging
2240         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2241         this.version_nagtime = 0;
2242         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2243             // git client
2244         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2245             // git server
2246             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2247         } else {
2248             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2249             if (r < 0) { // old client
2250                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2251             } else if (r > 0) { // old server
2252                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2253             }
2254         }
2255     }
2256
2257         // GOD MODE info
2258         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2259         {
2260                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2261                 this.max_armorvalue = 0;
2262         }
2263
2264         if (STAT(FROZEN, this) == 2)
2265         {
2266                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2267                 this.health = max(1, this.revive_progress * start_health);
2268                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2269
2270                 if (this.revive_progress >= 1)
2271                         Unfreeze(this);
2272         }
2273         else if (STAT(FROZEN, this) == 3)
2274         {
2275                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2276                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2277
2278                 if (this.health < 1)
2279                 {
2280                         if (this.vehicle)
2281                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2282                         if(this.event_damage)
2283                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2284                 }
2285                 else if (this.revive_progress <= 0)
2286                         Unfreeze(this);
2287         }
2288
2289         MUTATOR_CALLHOOK(PlayerPreThink, this);
2290
2291         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2292         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2293         {
2294                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2295                 {
2296                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2297                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2298                         {
2299                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2300                         }
2301                         else if(!it.owner)
2302                         {
2303                                 if(!it.team || SAME_TEAM(this, it))
2304                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2305                                 else if(autocvar_g_vehicles_steal)
2306                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2307                         }
2308                 });
2309
2310                 this.last_vehiclecheck = time + 1;
2311         }
2312
2313         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2314         {
2315                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2316                         PlayerUseKey(this);
2317                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2318         }
2319
2320         if (IS_REAL_CLIENT(this))
2321                 PrintWelcomeMessage(this);
2322
2323         if (IS_PLAYER(this)) {
2324                 CheckRules_Player(this);
2325
2326                 if (intermission_running) {
2327                         IntermissionThink(this);
2328                         return;
2329                 }
2330
2331                 if (timeout_status == TIMEOUT_ACTIVE) {
2332             // don't allow the player to turn around while game is paused
2333                         // FIXME turn this into CSQC stuff
2334                         this.v_angle = this.lastV_angle;
2335                         this.angles = this.lastV_angle;
2336                         this.fixangle = true;
2337                 }
2338
2339                 if (frametime) player_powerups(this);
2340
2341                 if (IS_DEAD(this)) {
2342                         if (this.personal && g_race_qualifying) {
2343                                 if (time > this.respawn_time) {
2344                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2345                                         respawn(this);
2346                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2347                                 }
2348                         } else {
2349                                 if (frametime) player_anim(this);
2350                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2351
2352                                 switch(this.deadflag)
2353                                 {
2354                                         case DEAD_DYING:
2355                                         {
2356                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2357                                                         this.deadflag = DEAD_RESPAWNING;
2358                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2359                                                         this.deadflag = DEAD_DEAD;
2360                                                 break;
2361                                         }
2362                                         case DEAD_DEAD:
2363                                         {
2364                                                 if (button_pressed)
2365                                                         this.deadflag = DEAD_RESPAWNABLE;
2366                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2367                                                         this.deadflag = DEAD_RESPAWNING;
2368                                                 break;
2369                                         }
2370                                         case DEAD_RESPAWNABLE:
2371                                         {
2372                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2373                                                         this.deadflag = DEAD_RESPAWNING;
2374                                                 break;
2375                                         }
2376                                         case DEAD_RESPAWNING:
2377                                         {
2378                                                 if (time > this.respawn_time)
2379                                                 {
2380                                                         this.respawn_time = time + 1; // only retry once a second
2381                                                         this.respawn_time_max = this.respawn_time;
2382                                                         respawn(this);
2383                                                 }
2384                                                 break;
2385                                         }
2386                                 }
2387
2388                                 ShowRespawnCountdown(this);
2389
2390                                 if (this.respawn_flags & RESPAWN_SILENT)
2391                                         STAT(RESPAWN_TIME, this) = 0;
2392                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2393                                 {
2394                                         if (time < this.respawn_time)
2395                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2396                                         else if (this.deadflag != DEAD_RESPAWNING)
2397                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2398                                 }
2399                                 else
2400                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2401                         }
2402
2403                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2404                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2405                                 STAT(RESPAWN_TIME, this) *= -1;
2406
2407                         return;
2408                 }
2409
2410                 this.prevorigin = this.origin;
2411
2412                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2413                 if (this.hook.state) {
2414                         do_crouch = false;
2415                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2416                         do_crouch = false;
2417                 } else if (this.vehicle) {
2418                         do_crouch = false;
2419                 } else if (STAT(FROZEN, this)) {
2420                         do_crouch = false;
2421         }
2422
2423                 if (do_crouch) {
2424                         if (!this.crouch) {
2425                                 this.crouch = true;
2426                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2427                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2428                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2429                         }
2430                 } else if (this.crouch) {
2431             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2432             if (!trace_startsolid) {
2433                 this.crouch = false;
2434                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2435                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2436             }
2437                 }
2438
2439                 FixPlayermodel(this);
2440
2441                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2442                 //if(frametime)
2443                 {
2444                         this.items &= ~this.items_added;
2445
2446                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2447                         {
2448                                 .entity weaponentity = weaponentities[slot];
2449                                 W_WeaponFrame(this, weaponentity);
2450
2451                                 if(slot == 0)
2452                                 {
2453                                         this.clip_load = this.(weaponentity).clip_load;
2454                                         this.clip_size = this.(weaponentity).clip_size;
2455                                 }
2456                         }
2457
2458                         this.items_added = 0;
2459                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2460                 this.items_added |= IT_FUEL;
2461
2462                         this.items |= this.items_added;
2463                 }
2464
2465                 player_regen(this);
2466
2467                 // WEAPONTODO: Add a weapon request for this
2468                 // rot vortex charge to the charge limit
2469                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2470                 {
2471                         .entity weaponentity = weaponentities[slot];
2472                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2473                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2474                 }
2475
2476                 if (frametime) player_anim(this);
2477
2478                 // secret status
2479                 secrets_setstatus(this);
2480
2481                 // monsters status
2482                 monsters_setstatus(this);
2483
2484                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2485         }
2486         else if (gameover) {
2487                 if (intermission_running) IntermissionThink(this);
2488                 return;
2489         }
2490         else if (IS_OBSERVER(this)) {
2491                 ObserverThink(this);
2492         }
2493         else if (IS_SPEC(this)) {
2494                 SpectatorThink(this);
2495         }
2496
2497         // WEAPONTODO: Add weapon request for this
2498         if (!zoomstate_set) {
2499                 bool wep_zoomed = false;
2500                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2501                 {
2502                         .entity weaponentity = weaponentities[slot];
2503                         Weapon thiswep = this.(weaponentity).m_weapon;
2504                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2505                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2506                 }
2507                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2508     }
2509
2510         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2511         {
2512                 this.teamkill_soundtime = 0;
2513
2514                 entity e = this.teamkill_soundsource;
2515                 entity oldpusher = e.pusher;
2516                 e.pusher = this;
2517                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2518                 e.pusher = oldpusher;
2519         }
2520
2521         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2522                 this.taunt_soundtime = 0;
2523                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2524         }
2525
2526         target_voicescript_next(this);
2527
2528         // WEAPONTODO: Move into weaponsystem somehow
2529         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2530         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2531         {
2532                 .entity weaponentity = weaponentities[slot];
2533                 if(this.(weaponentity).m_weapon == WEP_Null)
2534                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2535         }
2536 }
2537
2538 void DrownPlayer(entity this)
2539 {
2540         if(IS_DEAD(this))
2541                 return;
2542
2543         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2544         {
2545                 if(this.air_finished < time)
2546                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2547                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2548                 this.dmg = 2;
2549         }
2550         else if (this.air_finished < time)
2551         {       // drown!
2552                 if (this.pain_finished < time)
2553                 {
2554                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2555                         this.pain_finished = time + 0.5;
2556                 }
2557         }
2558 }
2559
2560 .bool move_qcphysics;
2561
2562 void Player_Physics(entity this)
2563 {
2564         set_movetype(this, this.move_movetype);
2565
2566         if(!this.move_qcphysics)
2567                 return;
2568
2569         if(!frametime && !this.pm_frametime)
2570                 return;
2571
2572         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2573
2574         this.pm_frametime = 0;
2575 }
2576
2577 /*
2578 =============
2579 PlayerPostThink
2580
2581 Called every frame for each client after the physics are run
2582 =============
2583 */
2584 .float idlekick_lasttimeleft;
2585 void PlayerPostThink (entity this)
2586 {
2587         Player_Physics(this);
2588
2589         if (sv_maxidle > 0)
2590         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2591         if (IS_REAL_CLIENT(this))
2592         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2593         {
2594                 int totalClients = 0;
2595                 if(sv_maxidle_slots > 0)
2596                 {
2597                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2598                         {
2599                                 ++totalClients;
2600                         });
2601                 }
2602
2603                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2604                 { /* do nothing */ }
2605                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2606                 {
2607                         if (this.idlekick_lasttimeleft)
2608                         {
2609                                 this.idlekick_lasttimeleft = 0;
2610                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2611                         }
2612                 }
2613                 else
2614                 {
2615                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2616                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2617                                 if (!this.idlekick_lasttimeleft)
2618                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2619                         }
2620                         if (timeleft <= 0) {
2621                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2622                                 dropclient(this);
2623                                 return;
2624                         }
2625                         else if (timeleft <= 10) {
2626                                 if (timeleft != this.idlekick_lasttimeleft) {
2627                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2628                 }
2629                                 this.idlekick_lasttimeleft = timeleft;
2630                         }
2631                 }
2632         }
2633
2634         CheatFrame(this);
2635
2636         //CheckPlayerJump();
2637
2638         if (IS_PLAYER(this)) {
2639                 DrownPlayer(this);
2640                 CheckRules_Player(this);
2641                 UpdateChatBubble(this);
2642                 if (this.impulse) ImpulseCommands(this);
2643                 if (intermission_running) return; // intermission or finale
2644                 GetPressedKeys(this);
2645         }
2646
2647         if (this.waypointsprite_attachedforcarrier) {
2648             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2649                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2650     }
2651
2652         playerdemo_write(this);
2653
2654         CSQCMODEL_AUTOUPDATE(this);
2655 }