qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/physics/player.qh"
  41
  42 #include "../common/items/_mod.qh"
  43
  44 #include "../common/mutators/mutator/waypoints/all.qh"
  45
  46 #include "../common/triggers/subs.qh"
  47 #include "../common/triggers/triggers.qh"
  48 #include "../common/triggers/trigger/secret.qh"
  49
  50 #include "../common/minigames/sv_minigames.qh"
  51
  52 #include "../common/items/inventory.qh"
  53
  54 #include "../common/monsters/sv_monsters.qh"
  55
  56 #include "../lib/warpzone/server.qh"
  57
  58 STATIC_METHOD(Client, Add, void(Client this, int _team))
  59 {
  60     ClientConnect(this);
  61     TRANSMUTE(Player, this);
  62     this.frame = 12; // 7
  63     this.team = _team;
  64     PutClientInServer(this);
  65 }
  66
  67 void PutObserverInServer(entity this);
  68
  69 STATIC_METHOD(Client, Remove, void(Client this))
  70 {
  71     TRANSMUTE(Observer, this);
  72     PutClientInServer(this);
  73     ClientDisconnect(this);
  74 }
  75
  76 void send_CSQC_teamnagger() {
  77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  78 }
  79
  80 int CountSpectators(entity player, entity to)
  81 {
  82         if(!player) { return 0; } // not sure how, but best to be safe
  83
  84         int spec_count = 0;
  85
  86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  87         {
  88                 spec_count++;
  89         });
  90
  91         return spec_count;
  92 }
  93
  94 void WriteSpectators(entity player, entity to)
  95 {
  96         if(!player) { return; } // not sure how, but best to be safe
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 WriteByte(MSG_ENTITY, num_for_edict(it));
 101         });
 102 }
 103
 104 bool ClientData_Send(entity this, entity to, int sf)
 105 {
 106         assert(to == this.owner, return false);
 107
 108         entity e = to;
 109         if (IS_SPEC(e)) e = e.enemy;
 110
 111         sf = 0;
 112         if (e.race_completed)       sf |= 1; // forced scoreboard
 113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 114         if (e.zoomstate)            sf |= 4; // zoomed
 115         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124
 125         if(sf & 16)
 126         {
 127                 float specs = CountSpectators(e, to);
 128                 WriteByte(MSG_ENTITY, specs);
 129                 WriteSpectators(e, to);
 130         }
 131
 132         return true;
 133 }
 134
 135 void ClientData_Attach(entity this)
 136 {
 137         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 138         this.clientdata.drawonlytoclient = this;
 139         this.clientdata.owner = this;
 140 }
 141
 142 void ClientData_Detach(entity this)
 143 {
 144         delete(this.clientdata);
 145         this.clientdata = NULL;
 146 }
 147
 148 void ClientData_Touch(entity e)
 149 {
 150         e.clientdata.SendFlags = 1;
 151
 152         // make it spectatable
 153         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 154 }
 155
 156 .string netname_previous;
 157
 158 void SetSpectatee(entity this, entity spectatee);
 159 void SetSpectatee_status(entity this, int spectatee_num);
 160
 161
 162 /*
 163 =============
 164 CheckPlayerModel
 165
 166 Checks if the argument string can be a valid playermodel.
 167 Returns a valid one in doubt.
 168 =============
 169 */
 170 string FallbackPlayerModel;
 171 string CheckPlayerModel(string plyermodel) {
 172         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 173         {
 174                 // note: we cannot summon Don Strunzone here, some player may
 175                 // still have the model string set. In case anyone manages how
 176                 // to change a cvar default, we'll have a small leak here.
 177                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 178         }
 179         // only in right path
 180         if( substring(plyermodel,0,14) != "models/player/")
 181                 return FallbackPlayerModel;
 182         // only good file extensions
 183         if(substring(plyermodel,-4,4) != ".zym")
 184         if(substring(plyermodel,-4,4) != ".dpm")
 185         if(substring(plyermodel,-4,4) != ".iqm")
 186         if(substring(plyermodel,-4,4) != ".md3")
 187         if(substring(plyermodel,-4,4) != ".psk")
 188                 return FallbackPlayerModel;
 189         // forbid the LOD models
 190         if(substring(plyermodel, -9,5) == "_lod1")
 191                 return FallbackPlayerModel;
 192         if(substring(plyermodel, -9,5) == "_lod2")
 193                 return FallbackPlayerModel;
 194         if(plyermodel != strtolower(plyermodel))
 195                 return FallbackPlayerModel;
 196         // also, restrict to server models
 197         if(autocvar_sv_servermodelsonly)
 198         {
 199                 if(!fexists(plyermodel))
 200                         return FallbackPlayerModel;
 201         }
 202         return plyermodel;
 203 }
 204
 205 void setplayermodel(entity e, string modelname)
 206 {
 207         precache_model(modelname);
 208         _setmodel(e, modelname);
 209         player_setupanimsformodel(e);
 210         if(!autocvar_g_debug_globalsounds)
 211                 UpdatePlayerSounds(e);
 212 }
 213
 214 void FixPlayermodel(entity player);
 215 /** putting a client as observer in the server */
 216 void PutObserverInServer(entity this)
 217 {
 218     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 219         PlayerState_detach(this);
 220
 221         if (IS_PLAYER(this) && this.health >= 1) {
 222         // despawn effect
 223                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 224     }
 225
 226     {
 227         entity spot = SelectSpawnPoint(this, true);
 228         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 229         this.angles = spot.angles;
 230         this.angles_z = 0;
 231         this.fixangle = true;
 232         // offset it so that the spectator spawns higher off the ground, looks better this way
 233         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 234         this.prevorigin = this.origin;
 235         if (IS_REAL_CLIENT(this))
 236         {
 237             msg_entity = this;
 238             WriteByte(MSG_ONE, SVC_SETVIEW);
 239             WriteEntity(MSG_ONE, this);
 240         }
 241         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 242         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 243         if(!autocvar_g_debug_globalsounds)
 244         {
 245                 // needed for player sounds
 246                 this.model = "";
 247                 FixPlayermodel(this);
 248         }
 249         setmodel(this, MDL_Null);
 250         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 251         this.view_ofs = '0 0 0';
 252     }
 253
 254     RemoveGrapplingHooks(this);
 255         Portal_ClearAll(this);
 256         Unfreeze(this);
 257         SetSpectatee(this, NULL);
 258
 259         if (this.alivetime)
 260         {
 261                 if (!warmup_stage)
 262                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 263                 this.alivetime = 0;
 264         }
 265
 266         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 267
 268         WaypointSprite_PlayerDead(this);
 269
 270         if (mutator_returnvalue) {
 271             // mutator prevents resetting teams+score
 272         } else {
 273                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 274         this.frags = FRAGS_SPECTATOR;
 275         PlayerScore_Clear(this);  // clear scores when needed
 276     }
 277
 278         if (this.killcount != FRAGS_SPECTATOR)
 279         {
 280                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 281                 if(!intermission_running)
 282                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 283                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 284
 285                 if(this.just_joined == false) {
 286                         LogTeamchange(this.playerid, -1, 4);
 287                 } else
 288                         this.just_joined = false;
 289         }
 290
 291         accuracy_resend(this);
 292
 293         this.spectatortime = time;
 294         if(this.bot_attack)
 295                 IL_REMOVE(g_bot_targets, this);
 296         this.bot_attack = false;
 297     this.hud = HUD_NORMAL;
 298         TRANSMUTE(Observer, this);
 299         this.iscreature = false;
 300         this.teleportable = TELEPORT_SIMPLE;
 301         this.damagedbycontents = false;
 302         this.health = FRAGS_SPECTATOR;
 303         SetSpectatee_status(this, etof(this));
 304         this.takedamage = DAMAGE_NO;
 305         this.solid = SOLID_NOT;
 306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 307         this.flags = FL_CLIENT | FL_NOTARGET;
 308         this.armorvalue = 666;
 309         this.effects = 0;
 310         this.armorvalue = autocvar_g_balance_armor_start;
 311         this.pauserotarmor_finished = 0;
 312         this.pauserothealth_finished = 0;
 313         this.pauseregen_finished = 0;
 314         this.damageforcescale = 0;
 315         this.death_time = 0;
 316         this.respawn_flags = 0;
 317         this.respawn_time = 0;
 318         this.stat_respawn_time = 0;
 319         this.alpha = 0;
 320         this.scale = 0;
 321         this.fade_time = 0;
 322         this.pain_frame = 0;
 323         this.pain_finished = 0;
 324         this.strength_finished = 0;
 325         this.invincible_finished = 0;
 326         this.superweapons_finished = 0;
 327         this.pushltime = 0;
 328         this.istypefrag = 0;
 329         setthink(this, func_null);
 330         this.nextthink = 0;
 331         this.deadflag = DEAD_NO;
 332         this.crouch = false;
 333         this.revival_time = 0;
 334
 335         this.items = 0;
 336         this.weapons = '0 0 0';
 337         this.drawonlytoclient = this;
 338
 339         this.weaponmodel = "";
 340         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 341         {
 342                 if(!this.weaponentities[slot])
 343                         continue; // first load
 344                 this.weaponentities[slot].hook_time = 0;
 345                 this.weaponentities[slot].weaponname = "";
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         this.killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357 }
 358
 359 int player_getspecies(entity this)
 360 {
 361         get_model_parameters(this.model, this.skin);
 362         int s = get_model_parameters_species;
 363         get_model_parameters(string_null, 0);
 364         if (s < 0) return SPECIES_HUMAN;
 365         return s;
 366 }
 367
 368 .float model_randomizer;
 369 void FixPlayermodel(entity player)
 370 {
 371         string defaultmodel = "";
 372         int defaultskin = 0;
 373         if(autocvar_sv_defaultcharacter)
 374         {
 375                 if(teamplay)
 376                 {
 377                         string s = Static_Team_ColorName_Lower(player.team);
 378                         if (s != "neutral")
 379                         {
 380                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 381                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 382                         }
 383                 }
 384
 385                 if(defaultmodel == "")
 386                 {
 387                         defaultmodel = autocvar_sv_defaultplayermodel;
 388                         defaultskin = autocvar_sv_defaultplayerskin;
 389                 }
 390
 391                 int n = tokenize_console(defaultmodel);
 392                 if(n > 0)
 393                 {
 394                         defaultmodel = argv(floor(n * player.model_randomizer));
 395                         // However, do NOT randomize if the player-selected model is in the list.
 396                         for (int i = 0; i < n; ++i)
 397                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 398                                         defaultmodel = argv(i);
 399                 }
 400
 401                 int i = strstrofs(defaultmodel, ":", 0);
 402                 if(i >= 0)
 403                 {
 404                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 405                         defaultmodel = substring(defaultmodel, 0, i);
 406                 }
 407         }
 408         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 409         {
 410                 if(teamplay)
 411                 {
 412                         string s = Static_Team_ColorName_Lower(player.team);
 413                         if (s != "neutral")
 414                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 415                 }
 416
 417                 if(!defaultskin)
 418                         defaultskin = autocvar_sv_defaultplayerskin;
 419         }
 420
 421         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 422         defaultmodel = M_ARGV(0, string);
 423         defaultskin = M_ARGV(1, int);
 424
 425         bool chmdl = false;
 426         int oldskin;
 427         if(defaultmodel != "")
 428         {
 429                 if (defaultmodel != player.model)
 430                 {
 431                         vector m1 = player.mins;
 432                         vector m2 = player.maxs;
 433                         setplayermodel (player, defaultmodel);
 434                         setsize (player, m1, m2);
 435                         chmdl = true;
 436                 }
 437
 438                 oldskin = player.skin;
 439                 player.skin = defaultskin;
 440         } else {
 441                 if (player.playermodel != player.model || player.playermodel == "")
 442                 {
 443                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 444                         vector m1 = player.mins;
 445                         vector m2 = player.maxs;
 446                         setplayermodel (player, player.playermodel);
 447                         setsize (player, m1, m2);
 448                         chmdl = true;
 449                 }
 450
 451                 if(!autocvar_sv_defaultcharacterskin)
 452                 {
 453                         oldskin = player.skin;
 454                         player.skin = stof(player.playerskin);
 455                 }
 456                 else
 457                 {
 458                         oldskin = player.skin;
 459                         player.skin = defaultskin;
 460                 }
 461         }
 462
 463         if(chmdl || oldskin != player.skin) // model or skin has changed
 464         {
 465                 player.species = player_getspecies(player); // update species
 466                 if(!autocvar_g_debug_globalsounds)
 467                         UpdatePlayerSounds(player); // update skin sounds
 468         }
 469
 470         if(!teamplay)
 471                 if(strlen(autocvar_sv_defaultplayercolors))
 472                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 473                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 474 }
 475
 476
 477 /** Called when a client spawns in the server */
 478 void PutClientInServer(entity this)
 479 {
 480         if (IS_BOT_CLIENT(this)) {
 481                 TRANSMUTE(Player, this);
 482         } else if (IS_REAL_CLIENT(this)) {
 483                 msg_entity = this;
 484                 WriteByte(MSG_ONE, SVC_SETVIEW);
 485                 WriteEntity(MSG_ONE, this);
 486         }
 487         if (gameover) {
 488                 TRANSMUTE(Observer, this);
 489         }
 490
 491         SetSpectatee(this, NULL);
 492
 493         // reset player keys
 494         this.itemkeys = 0;
 495
 496         MUTATOR_CALLHOOK(PutClientInServer, this);
 497
 498         if (IS_OBSERVER(this)) {
 499                 PutObserverInServer(this);
 500         } else if (IS_PLAYER(this)) {
 501                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 502
 503                 PlayerState_attach(this);
 504                 accuracy_resend(this);
 505
 506                 if (this.team < 0)
 507                         JoinBestTeam(this, false, true);
 508
 509                 entity spot = SelectSpawnPoint(this, false);
 510                 if (!spot) {
 511                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 512                         return; // spawn failed
 513                 }
 514
 515                 TRANSMUTE(Player, this);
 516
 517                 this.wasplayer = true;
 518                 this.iscreature = true;
 519                 this.teleportable = TELEPORT_NORMAL;
 520                 this.damagedbycontents = true;
 521                 set_movetype(this, MOVETYPE_WALK);
 522                 this.solid = SOLID_SLIDEBOX;
 523                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 524                 if (autocvar_g_playerclip_collisions)
 525                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 526                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 527                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 528                 this.frags = FRAGS_PLAYER;
 529                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 530                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 531                 if (autocvar__notarget)
 532                         this.flags |= FL_NOTARGET;
 533                 this.takedamage = DAMAGE_AIM;
 534                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 535                 this.dmg = 2; // WTF
 536
 537                 if (warmup_stage) {
 538                         this.ammo_shells = warmup_start_ammo_shells;
 539                         this.ammo_nails = warmup_start_ammo_nails;
 540                         this.ammo_rockets = warmup_start_ammo_rockets;
 541                         this.ammo_cells = warmup_start_ammo_cells;
 542                         this.ammo_plasma = warmup_start_ammo_plasma;
 543                         this.ammo_fuel = warmup_start_ammo_fuel;
 544                         this.health = warmup_start_health;
 545                         this.armorvalue = warmup_start_armorvalue;
 546                         this.weapons = WARMUP_START_WEAPONS;
 547                 } else {
 548                         this.ammo_shells = start_ammo_shells;
 549                         this.ammo_nails = start_ammo_nails;
 550                         this.ammo_rockets = start_ammo_rockets;
 551                         this.ammo_cells = start_ammo_cells;
 552                         this.ammo_plasma = start_ammo_plasma;
 553                         this.ammo_fuel = start_ammo_fuel;
 554                         this.health = start_health;
 555                         this.armorvalue = start_armorvalue;
 556                         this.weapons = start_weapons;
 557                 }
 558                 SetSpectatee_status(this, 0);
 559
 560                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 561
 562                 this.items = start_items;
 563
 564                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 565                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 566                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 567                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 568                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 569                 // extend the pause of rotting if client was reset at the beginning of the countdown
 570                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 571                         float f = game_starttime - time;
 572                         this.spawnshieldtime += f;
 573                         this.pauserotarmor_finished += f;
 574                         this.pauserothealth_finished += f;
 575                         this.pauseregen_finished += f;
 576                 }
 577                 this.damageforcescale = 2;
 578                 this.death_time = 0;
 579                 this.respawn_flags = 0;
 580                 this.respawn_time = 0;
 581                 this.stat_respawn_time = 0;
 582                 this.scale = autocvar_sv_player_scale;
 583                 this.fade_time = 0;
 584                 this.pain_frame = 0;
 585                 this.pain_finished = 0;
 586                 this.pushltime = 0;
 587                 setthink(this, func_null); // players have no think function
 588                 this.nextthink = 0;
 589                 this.dmg_team = 0;
 590                 this.ballistics_density = autocvar_g_ballistics_density_player;
 591
 592                 this.deadflag = DEAD_NO;
 593
 594                 this.angles = spot.angles;
 595                 this.angles_z = 0; // never spawn tilted even if the spot says to
 596                 if (IS_BOT_CLIENT(this))
 597                         this.v_angle = this.angles;
 598                 this.fixangle = true; // turn this way immediately
 599                 this.oldvelocity = this.velocity = '0 0 0';
 600                 this.avelocity = '0 0 0';
 601                 this.punchangle = '0 0 0';
 602                 this.punchvector = '0 0 0';
 603
 604                 this.strength_finished = 0;
 605                 this.invincible_finished = 0;
 606                 this.fire_endtime = -1;
 607                 this.revival_time = 0;
 608                 this.air_finished = time + 12;
 609
 610                 entity spawnevent = new_pure(spawnevent);
 611                 spawnevent.owner = this;
 612                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 613
 614                 // Cut off any still running player sounds.
 615                 stopsound(this, CH_PLAYER_SINGLE);
 616
 617                 this.model = "";
 618                 FixPlayermodel(this);
 619                 this.drawonlytoclient = NULL;
 620
 621                 this.viewloc = NULL;
 622
 623                 this.crouch = false;
 624                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 625                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 626                 this.spawnorigin = spot.origin;
 627                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 628                 // don't reset back to last position, even if new position is stuck in solid
 629                 this.oldorigin = this.origin;
 630                 this.prevorigin = this.origin;
 631                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 632                 if(this.conveyor)
 633                         IL_REMOVE(g_conveyed, this);
 634                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 635                 this.hud = HUD_NORMAL;
 636
 637                 this.event_damage = PlayerDamage;
 638
 639                 if(!this.bot_attack)
 640                         IL_PUSH(g_bot_targets, this);
 641                 this.bot_attack = true;
 642                 this.monster_attack = true;
 643
 644                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 645
 646                 if (this.killcount == FRAGS_SPECTATOR) {
 647                         PlayerScore_Clear(this);
 648                         this.killcount = 0;
 649                 }
 650
 651                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 652                 {
 653                         .entity weaponentity = weaponentities[slot];
 654                         CL_SpawnWeaponentity(this, weaponentity);
 655                 }
 656                 this.alpha = default_player_alpha;
 657                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 658                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 659
 660                 this.speedrunning = false;
 661
 662                 target_voicescript_clear(this);
 663
 664                 // reset fields the weapons may use
 665                 FOREACH(Weapons, true, LAMBDA(
 666                         it.wr_resetplayer(it, this);
 667                         // reload all reloadable weapons
 668                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 669                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 670                                 {
 671                                         .entity weaponentity = weaponentities[slot];
 672                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 673                                 }
 674                         }
 675                 ));
 676
 677                 {
 678                         string s = spot.target;
 679                         spot.target = string_null;
 680                         SUB_UseTargets(spot, this, NULL);
 681                         spot.target = s;
 682                 }
 683
 684                 Unfreeze(this);
 685
 686                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 687
 688                 if (autocvar_spawn_debug)
 689                 {
 690                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 691                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 692                 }
 693
 694                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 695                 {
 696                         .entity weaponentity = weaponentities[slot];
 697                         if(slot == 0)
 698                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 699                         else
 700                                 this.(weaponentity).m_switchweapon = WEP_Null;
 701                         this.(weaponentity).m_weapon = WEP_Null;
 702                         this.(weaponentity).weaponname = "";
 703                         this.(weaponentity).m_switchingweapon = WEP_Null;
 704                         this.(weaponentity).cnt = -1;
 705                 }
 706
 707                 if (!warmup_stage && !this.alivetime)
 708                         this.alivetime = time;
 709
 710                 antilag_clear(this, CS(this));
 711         }
 712 }
 713
 714 void ClientInit_misc(entity this);
 715
 716 .float ebouncefactor, ebouncestop; // electro's values
 717 // TODO do we need all these fields, or should we stop autodetecting runtime
 718 // changes and just have a console command to update this?
 719 bool ClientInit_SendEntity(entity this, entity to, int sf)
 720 {
 721         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 722         return = true;
 723         msg_entity = to;
 724         // MSG_INIT replacement
 725         // TODO: make easier to use
 726         Registry_send_all();
 727         W_PROP_reload(MSG_ONE, to);
 728         ClientInit_misc(this);
 729         MUTATOR_CALLHOOK(Ent_Init);
 730 }
 731 void ClientInit_misc(entity this)
 732 {
 733         int channel = MSG_ONE;
 734         WriteHeader(channel, ENT_CLIENT_INIT);
 735         WriteByte(channel, g_nexball_meter_period * 32);
 736         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 737         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 738         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 739         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 740         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 741         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 742         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 743         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 744
 745         if(sv_foginterval && world.fog != "")
 746                 WriteString(channel, world.fog);
 747         else
 748                 WriteString(channel, "");
 749         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 750         WriteByte(channel, serverflags);
 751         WriteCoord(channel, autocvar_g_trueaim_minrange);
 752 }
 753
 754 void ClientInit_CheckUpdate(entity this)
 755 {
 756         this.nextthink = time;
 757         if(this.count != autocvar_g_balance_armor_blockpercent)
 758         {
 759                 this.count = autocvar_g_balance_armor_blockpercent;
 760                 this.SendFlags |= 1;
 761         }
 762 }
 763
 764 void ClientInit_Spawn()
 765 {
 766         entity e = new_pure(clientinit);
 767         setthink(e, ClientInit_CheckUpdate);
 768         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 769
 770         ClientInit_CheckUpdate(e);
 771 }
 772
 773 /*
 774 =============
 775 SetNewParms
 776 =============
 777 */
 778 void SetNewParms ()
 779 {
 780         // initialize parms for a new player
 781         parm1 = -(86400 * 366);
 782
 783         MUTATOR_CALLHOOK(SetNewParms);
 784 }
 785
 786 /*
 787 =============
 788 SetChangeParms
 789 =============
 790 */
 791 void SetChangeParms (entity this)
 792 {
 793         // save parms for level change
 794         parm1 = this.parm_idlesince - time;
 795
 796         MUTATOR_CALLHOOK(SetChangeParms);
 797 }
 798
 799 /*
 800 =============
 801 DecodeLevelParms
 802 =============
 803 */
 804 void DecodeLevelParms(entity this)
 805 {
 806         // load parms
 807         this.parm_idlesince = parm1;
 808         if (this.parm_idlesince == -(86400 * 366))
 809                 this.parm_idlesince = time;
 810
 811         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 812         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 813
 814         MUTATOR_CALLHOOK(DecodeLevelParms);
 815 }
 816
 817 /*
 818 =============
 819 ClientKill
 820
 821 Called when a client types 'kill' in the console
 822 =============
 823 */
 824
 825 .float clientkill_nexttime;
 826 void ClientKill_Now_TeamChange(entity this)
 827 {
 828         if(this.killindicator_teamchange == -1)
 829         {
 830                 JoinBestTeam( this, false, true );
 831         }
 832         else if(this.killindicator_teamchange == -2)
 833         {
 834                 if(blockSpectators)
 835                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 836                 PutObserverInServer(this);
 837         }
 838         else
 839                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 840         this.killindicator_teamchange = 0;
 841 }
 842
 843 void ClientKill_Now(entity this)
 844 {
 845         if(this.vehicle)
 846         {
 847             vehicles_exit(this.vehicle, VHEF_RELEASE);
 848             if(!this.killindicator_teamchange)
 849             {
 850             this.vehicle_health = -1;
 851             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 852             }
 853         }
 854
 855         if(this.killindicator && !wasfreed(this.killindicator))
 856                 delete(this.killindicator);
 857
 858         this.killindicator = NULL;
 859
 860         if(this.killindicator_teamchange)
 861                 ClientKill_Now_TeamChange(this);
 862
 863         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 864                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 865
 866         // now I am sure the player IS dead
 867 }
 868 void KillIndicator_Think(entity this)
 869 {
 870         if (gameover)
 871         {
 872                 this.owner.killindicator = NULL;
 873                 delete(this);
 874                 return;
 875         }
 876
 877         if (this.owner.alpha < 0 && !this.owner.vehicle)
 878         {
 879                 this.owner.killindicator = NULL;
 880                 delete(this);
 881                 return;
 882         }
 883
 884         if(this.cnt <= 0)
 885         {
 886                 ClientKill_Now(this.owner);
 887                 return;
 888         }
 889     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 890     {
 891         this.nextthink = time + 1;
 892         this.cnt -= 1;
 893     }
 894         else
 895         {
 896                 if(this.cnt <= 10)
 897                         setmodel(this, MDL_NUM(this.cnt));
 898                 if(IS_REAL_CLIENT(this.owner))
 899                 {
 900                         if(this.cnt <= 10)
 901                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 902                 }
 903                 this.nextthink = time + 1;
 904                 this.cnt -= 1;
 905         }
 906 }
 907
 908 float clientkilltime;
 909 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 910 {
 911         float killtime;
 912         float starttime;
 913
 914         if (gameover)
 915                 return;
 916
 917         killtime = autocvar_g_balance_kill_delay;
 918
 919         if(g_race_qualifying || g_cts)
 920                 killtime = 0;
 921
 922     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 923         return;
 924
 925         this.killindicator_teamchange = targetteam;
 926
 927     if(!this.killindicator)
 928         {
 929                 if(!IS_DEAD(this))
 930                 {
 931                         killtime = max(killtime, this.clientkill_nexttime - time);
 932                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 933                 }
 934
 935                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 936                 {
 937                         ClientKill_Now(this);
 938                 }
 939                 else
 940                 {
 941                         starttime = max(time, clientkilltime);
 942
 943                         this.killindicator = spawn();
 944                         this.killindicator.owner = this;
 945                         this.killindicator.scale = 0.5;
 946                         setattachment(this.killindicator, this, "");
 947                         setorigin(this.killindicator, '0 0 52');
 948                         setthink(this.killindicator, KillIndicator_Think);
 949                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 950                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 951                         this.killindicator.cnt = ceil(killtime);
 952                         this.killindicator.count = bound(0, ceil(killtime), 10);
 953                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 954
 955                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 956                         {
 957                                 it.killindicator = spawn();
 958                                 it.killindicator.owner = it;
 959                                 it.killindicator.scale = 0.5;
 960                                 setattachment(it.killindicator, it, "");
 961                                 setorigin(it.killindicator, '0 0 52');
 962                                 setthink(it.killindicator, KillIndicator_Think);
 963                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 964                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 965                                 it.killindicator.cnt = ceil(killtime);
 966                         });
 967                         this.lip = 0;
 968                 }
 969         }
 970         if(this.killindicator)
 971         {
 972                 if(targetteam == 0) // just die
 973                 {
 974                         this.killindicator.colormod = '0 0 0';
 975                         if(IS_REAL_CLIENT(this))
 976                         if(this.killindicator.cnt > 0)
 977                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 978                 }
 979                 else if(targetteam == -1) // auto
 980                 {
 981                         this.killindicator.colormod = '0 1 0';
 982                         if(IS_REAL_CLIENT(this))
 983                         if(this.killindicator.cnt > 0)
 984                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 985                 }
 986                 else if(targetteam == -2) // spectate
 987                 {
 988                         this.killindicator.colormod = '0.5 0.5 0.5';
 989                         if(IS_REAL_CLIENT(this))
 990                         if(this.killindicator.cnt > 0)
 991                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 992                 }
 993                 else
 994                 {
 995                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 996                         if(IS_REAL_CLIENT(this))
 997                         if(this.killindicator.cnt > 0)
 998                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 999                 }
1000         }
1001
1002 }
1003
1004 void ClientKill (entity this)
1005 {
1006         if(gameover) return;
1007         if(this.player_blocked) return;
1008         if(STAT(FROZEN, this)) return;
1009
1010         ClientKill_TeamChange(this, 0);
1011 }
1012
1013 void FixClientCvars(entity e)
1014 {
1015         // send prediction settings to the client
1016         stuffcmd(e, "\nin_bindmap 0 0\n");
1017         if(autocvar_g_antilag == 3) // client side hitscan
1018                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1019         if(autocvar_sv_gentle)
1020                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1021
1022         MUTATOR_CALLHOOK(FixClientCvars, e);
1023 }
1024
1025 float PlayerInIDList(entity p, string idlist)
1026 {
1027         float n, i;
1028         string s;
1029
1030         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1031         if (!p.crypto_idfp)
1032                 return 0;
1033
1034         // this function allows abbreviated player IDs too!
1035         n = tokenize_console(idlist);
1036         for(i = 0; i < n; ++i)
1037         {
1038                 s = argv(i);
1039                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1040                         return 1;
1041         }
1042
1043         return 0;
1044 }
1045
1046 #ifdef DP_EXT_PRECONNECT
1047 /*
1048 =============
1049 ClientPreConnect
1050
1051 Called once (not at each match start) when a client begins a connection to the server
1052 =============
1053 */
1054 void ClientPreConnect ()
1055 {ENGINE_EVENT();
1056         if(autocvar_sv_eventlog)
1057         {
1058                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1059                         this.playerid,
1060                         etof(this),
1061                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1062                 ));
1063         }
1064 }
1065 #endif
1066
1067 /**
1068 =============
1069 ClientConnect
1070
1071 Called when a client connects to the server
1072 =============
1073 */
1074 void ClientConnect(entity this)
1075 {
1076         if (Ban_MaybeEnforceBanOnce(this)) return;
1077         assert(!IS_CLIENT(this), return);
1078         this.flags |= FL_CLIENT;
1079         assert(player_count >= 0, player_count = 0);
1080
1081 #ifdef WATERMARK
1082         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1083 #endif
1084         this.version_nagtime = time + 10 + random() * 10;
1085         TRANSMUTE(Client, this);
1086
1087         // identify the right forced team
1088         if (autocvar_g_campaign)
1089         {
1090                 if (IS_REAL_CLIENT(this)) // only players, not bots
1091                 {
1092                         switch (autocvar_g_campaign_forceteam)
1093                         {
1094                                 case 1: this.team_forced = NUM_TEAM_1; break;
1095                                 case 2: this.team_forced = NUM_TEAM_2; break;
1096                                 case 3: this.team_forced = NUM_TEAM_3; break;
1097                                 case 4: this.team_forced = NUM_TEAM_4; break;
1098                                 default: this.team_forced = 0;
1099                         }
1100                 }
1101         }
1102         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1103         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1104         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1105         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1106         else switch (autocvar_g_forced_team_otherwise)
1107         {
1108                 default: this.team_forced = 0; break;
1109                 case "red": this.team_forced = NUM_TEAM_1; break;
1110                 case "blue": this.team_forced = NUM_TEAM_2; break;
1111                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1112                 case "pink": this.team_forced = NUM_TEAM_4; break;
1113                 case "spectate":
1114                 case "spectator":
1115                         this.team_forced = -1;
1116                         break;
1117         }
1118         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1119
1120     {
1121         int id = this.playerid;
1122         this.playerid = 0; // silent
1123             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1124             this.playerid = id;
1125     }
1126
1127         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1128                 TRANSMUTE(Observer, this);
1129         } else {
1130                 if (!teamplay || autocvar_g_balance_teams) {
1131                         TRANSMUTE(Player, this);
1132                         campaign_bots_may_start = true;
1133                 } else {
1134                         TRANSMUTE(Observer, this); // do it anyway
1135                 }
1136         }
1137
1138         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1139
1140         // always track bots, don't ask for cl_allow_uidtracking
1141     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1142
1143         if (autocvar_sv_eventlog)
1144                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1145
1146         LogTeamchange(this.playerid, this.team, 1);
1147
1148         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1149
1150         this.netname_previous = strzone(this.netname);
1151
1152         if(teamplay && IS_PLAYER(this))
1153                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1154         else
1155                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1156
1157         stuffcmd(this, clientstuff, "\n");
1158         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1159
1160         FixClientCvars(this);
1161
1162         // get version info from player
1163         stuffcmd(this, "cmd clientversion $gameversion\n");
1164
1165         // notify about available teams
1166         if (teamplay)
1167         {
1168                 CheckAllowedTeams(this);
1169                 int t = 0;
1170                 if (c1 >= 0) t |= BIT(0);
1171                 if (c2 >= 0) t |= BIT(1);
1172                 if (c3 >= 0) t |= BIT(2);
1173                 if (c4 >= 0) t |= BIT(3);
1174                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1175         }
1176         else
1177         {
1178                 stuffcmd(this, "set _teams_available 0\n");
1179         }
1180
1181         bot_relinkplayerlist();
1182
1183         this.spectatortime = time;
1184         if (blockSpectators)
1185         {
1186                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1187         }
1188
1189         this.jointime = time;
1190         this.allowed_timeouts = autocvar_sv_timeout_number;
1191
1192         if (IS_REAL_CLIENT(this))
1193         {
1194                 if (!autocvar_g_campaign)
1195                 {
1196                         this.motd_actived_time = -1;
1197                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1198                 }
1199
1200                 if (g_weaponarena_weapons == WEPSET(TUBA))
1201                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1202         }
1203
1204         if (!sv_foginterval && world.fog != "")
1205                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1206
1207         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1208                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1209                         send_CSQC_teamnagger();
1210
1211         CSQCMODEL_AUTOINIT(this);
1212
1213         this.model_randomizer = random();
1214
1215         if (IS_REAL_CLIENT(this))
1216                 sv_notice_join(this);
1217
1218         // update physics stats (players can spawn before physics runs)
1219         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1220
1221         IL_EACH(g_initforplayer, it.init_for_player, {
1222                 it.init_for_player(it, this);
1223         });
1224
1225         MUTATOR_CALLHOOK(ClientConnect, this);
1226 }
1227 /*
1228 =============
1229 ClientDisconnect
1230
1231 Called when a client disconnects from the server
1232 =============
1233 */
1234 .entity chatbubbleentity;
1235 void ReadyCount();
1236 void ClientDisconnect(entity this)
1237 {
1238         assert(IS_CLIENT(this), return);
1239
1240         PlayerStats_GameReport_FinalizePlayer(this);
1241         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1242         if (this.active_minigame) part_minigame(this);
1243         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1244
1245         if (autocvar_sv_eventlog)
1246                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1247
1248         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1249
1250         SetSpectatee(this, NULL);
1251
1252     MUTATOR_CALLHOOK(ClientDisconnect, this);
1253
1254         ClientState_detach(this);
1255
1256         Portal_ClearAll(this);
1257
1258         Unfreeze(this);
1259
1260         RemoveGrapplingHooks(this);
1261
1262         // Here, everything has been done that requires this player to be a client.
1263
1264         this.flags &= ~FL_CLIENT;
1265
1266         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1267         if (this.killindicator) delete(this.killindicator);
1268
1269         WaypointSprite_PlayerGone(this);
1270
1271         bot_relinkplayerlist();
1272
1273         if (this.netname_previous) strunzone(this.netname_previous);
1274         if (this.clientstatus) strunzone(this.clientstatus);
1275         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1276         if (this.personal) delete(this.personal);
1277
1278         this.playerid = 0;
1279         ReadyCount();
1280         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1281 }
1282
1283 void ChatBubbleThink(entity this)
1284 {
1285         this.nextthink = time;
1286         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1287         {
1288                 if(this.owner) // but why can that ever be NULL?
1289                         this.owner.chatbubbleentity = NULL;
1290                 delete(this);
1291                 return;
1292         }
1293
1294         this.mdl = "";
1295
1296         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1297         {
1298                 if ( this.owner.active_minigame )
1299                         this.mdl = "models/sprites/minigame_busy.iqm";
1300                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1301                         this.mdl = "models/misc/chatbubble.spr";
1302         }
1303
1304         if ( this.model != this.mdl )
1305                 _setmodel(this, this.mdl);
1306
1307 }
1308
1309 void UpdateChatBubble(entity this)
1310 {
1311         if (this.alpha < 0)
1312                 return;
1313         // spawn a chatbubble entity if needed
1314         if (!this.chatbubbleentity)
1315         {
1316                 this.chatbubbleentity = new(chatbubbleentity);
1317                 this.chatbubbleentity.owner = this;
1318                 this.chatbubbleentity.exteriormodeltoclient = this;
1319                 setthink(this.chatbubbleentity, ChatBubbleThink);
1320                 this.chatbubbleentity.nextthink = time;
1321                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1322                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1323                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1324                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1325                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1326                 //this.chatbubbleentity.model = "";
1327                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1328         }
1329 }
1330
1331
1332 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1333 // added to the model skins
1334 /*void UpdateColorModHack()
1335 {
1336         float c;
1337         c = this.clientcolors & 15;
1338         // LordHavoc: only bothering to support white, green, red, yellow, blue
1339              if (!teamplay) this.colormod = '0 0 0';
1340         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1341         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1342         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1343         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1344         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1345         else this.colormod = '1 1 1';
1346 }*/
1347
1348 void respawn(entity this)
1349 {
1350         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1351         {
1352                 this.solid = SOLID_NOT;
1353                 this.takedamage = DAMAGE_NO;
1354                 set_movetype(this, MOVETYPE_FLY);
1355                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1356                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1357                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1358                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1359                 if(autocvar_g_respawn_ghosts_maxtime)
1360                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1361         }
1362
1363         CopyBody(this, 1);
1364
1365         this.effects |= EF_NODRAW; // prevent another CopyBody
1366         PutClientInServer(this);
1367 }
1368
1369 void play_countdown(entity this, float finished, Sound samp)
1370 {
1371     TC(Sound, samp);
1372         if(IS_REAL_CLIENT(this))
1373                 if(floor(finished - time - frametime) != floor(finished - time))
1374                         if(finished - time < 6)
1375                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1376 }
1377
1378 void player_powerups(entity this)
1379 {
1380         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1381         int items_prev = this.items;
1382
1383         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1384                 this.modelflags |= MF_ROCKET;
1385         else
1386                 this.modelflags &= ~MF_ROCKET;
1387
1388         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1389
1390         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1391                 return;
1392
1393         Fire_ApplyDamage(this);
1394         Fire_ApplyEffect(this);
1395
1396         if (!g_instagib)
1397         {
1398                 if (this.items & ITEM_Strength.m_itemid)
1399                 {
1400                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1401                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1402                         if (time > this.strength_finished)
1403                         {
1404                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1405                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1406                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1407                         }
1408                 }
1409                 else
1410                 {
1411                         if (time < this.strength_finished)
1412                         {
1413                                 this.items = this.items | ITEM_Strength.m_itemid;
1414                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1415                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1416                         }
1417                 }
1418                 if (this.items & ITEM_Shield.m_itemid)
1419                 {
1420                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1421                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1422                         if (time > this.invincible_finished)
1423                         {
1424                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1425                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1426                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1427                         }
1428                 }
1429                 else
1430                 {
1431                         if (time < this.invincible_finished)
1432                         {
1433                                 this.items = this.items | ITEM_Shield.m_itemid;
1434                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1435                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1436                         }
1437                 }
1438                 if (this.items & IT_SUPERWEAPON)
1439                 {
1440                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1441                         {
1442                                 this.superweapons_finished = 0;
1443                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1444                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1445                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1446                         }
1447                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1448                         {
1449                                 // don't let them run out
1450                         }
1451                         else
1452                         {
1453                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1454                                 if (time > this.superweapons_finished)
1455                                 {
1456                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1457                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1458                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1459                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1460                                 }
1461                         }
1462                 }
1463                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1464                 {
1465                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1466                         {
1467                                 this.items = this.items | IT_SUPERWEAPON;
1468                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1469                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1470                         }
1471                         else
1472                         {
1473                                 this.superweapons_finished = 0;
1474                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1475                         }
1476                 }
1477                 else
1478                 {
1479                         this.superweapons_finished = 0;
1480                 }
1481         }
1482
1483         if(autocvar_g_nodepthtestplayers)
1484                 this.effects = this.effects | EF_NODEPTHTEST;
1485
1486         if(autocvar_g_fullbrightplayers)
1487                 this.effects = this.effects | EF_FULLBRIGHT;
1488
1489         if (time >= game_starttime)
1490         if (time < this.spawnshieldtime)
1491                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1492
1493         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1494 }
1495
1496 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1497 {
1498         if(current > stable)
1499                 return current;
1500         else if(current > stable - 0.25) // when close enough, "snap"
1501                 return stable;
1502         else
1503                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1504 }
1505
1506 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1507 {
1508         if(current < stable)
1509                 return current;
1510         else if(current < stable + 0.25) // when close enough, "snap"
1511                 return stable;
1512         else
1513                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1514 }
1515
1516 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1517 {
1518         if(current > rotstable)
1519         {
1520                 if(rotframetime > 0)
1521                 {
1522                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1523                         current = max(rotstable, current - rotlinear * rotframetime);
1524                 }
1525         }
1526         else if(current < regenstable)
1527         {
1528                 if(regenframetime > 0)
1529                 {
1530                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1531                         current = min(regenstable, current + regenlinear * regenframetime);
1532                 }
1533         }
1534
1535         if(current > limit)
1536                 current = limit;
1537
1538         return current;
1539 }
1540
1541 void player_regen(entity this)
1542 {
1543         float max_mod, regen_mod, rot_mod, limit_mod;
1544         max_mod = regen_mod = rot_mod = limit_mod = 1;
1545
1546         float regen_health = autocvar_g_balance_health_regen;
1547         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1548         float regen_health_rot = autocvar_g_balance_health_rot;
1549         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1550         float regen_health_stable = autocvar_g_balance_health_regenstable;
1551         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1552         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1553                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1554         max_mod = M_ARGV(1, float);
1555         regen_mod = M_ARGV(2, float);
1556         rot_mod = M_ARGV(3, float);
1557         limit_mod = M_ARGV(4, float);
1558         regen_health = M_ARGV(5, float);
1559         regen_health_linear = M_ARGV(6, float);
1560         regen_health_rot = M_ARGV(7, float);
1561         regen_health_rotlinear = M_ARGV(8, float);
1562         regen_health_stable = M_ARGV(9, float);
1563         regen_health_rotstable = M_ARGV(10, float);
1564
1565
1566         if(!mutator_returnvalue)
1567         if(!STAT(FROZEN, this))
1568         {
1569                 float mina, maxa, limith, limita;
1570                 maxa = autocvar_g_balance_armor_rotstable;
1571                 mina = autocvar_g_balance_armor_regenstable;
1572                 limith = autocvar_g_balance_health_limit;
1573                 limita = autocvar_g_balance_armor_limit;
1574
1575                 regen_health_rotstable = regen_health_rotstable * max_mod;
1576                 regen_health_stable = regen_health_stable * max_mod;
1577                 limith = limith * limit_mod;
1578                 limita = limita * limit_mod;
1579
1580                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1581                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1582         }
1583
1584         // if player rotted to death...  die!
1585         // check this outside above checks, as player may still be able to rot to death
1586         if(this.health < 1)
1587         {
1588                 if(this.vehicle)
1589                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1590                 if(this.event_damage)
1591                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1592         }
1593
1594         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1595         {
1596                 float minf, maxf, limitf;
1597
1598                 maxf = autocvar_g_balance_fuel_rotstable;
1599                 minf = autocvar_g_balance_fuel_regenstable;
1600                 limitf = autocvar_g_balance_fuel_limit;
1601
1602                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1603         }
1604 }
1605
1606 bool zoomstate_set;
1607 void SetZoomState(entity this, float z)
1608 {
1609         if(z != this.zoomstate)
1610         {
1611                 this.zoomstate = z;
1612                 ClientData_Touch(this);
1613         }
1614         zoomstate_set = true;
1615 }
1616
1617 void GetPressedKeys(entity this)
1618 {
1619         MUTATOR_CALLHOOK(GetPressedKeys, this);
1620         int keys = STAT(PRESSED_KEYS, this);
1621         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1622         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1623         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1624         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1625
1626         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1627         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1628         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1629         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1630         this.pressedkeys = keys; // store for other users
1631
1632         STAT(PRESSED_KEYS, this) = keys;
1633 }
1634
1635 /*
1636 ======================
1637 spectate mode routines
1638 ======================
1639 */
1640
1641 void SpectateCopy(entity this, entity spectatee)
1642 {
1643     TC(Client, this); TC(Client, spectatee);
1644
1645         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1646         PS(this) = PS(spectatee);
1647         this.armortype = spectatee.armortype;
1648         this.armorvalue = spectatee.armorvalue;
1649         this.ammo_cells = spectatee.ammo_cells;
1650         this.ammo_plasma = spectatee.ammo_plasma;
1651         this.ammo_shells = spectatee.ammo_shells;
1652         this.ammo_nails = spectatee.ammo_nails;
1653         this.ammo_rockets = spectatee.ammo_rockets;
1654         this.ammo_fuel = spectatee.ammo_fuel;
1655         this.clip_load = spectatee.clip_load;
1656         this.clip_size = spectatee.clip_size;
1657         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1658         this.health = spectatee.health;
1659         this.impulse = 0;
1660         this.items = spectatee.items;
1661         this.last_pickup = spectatee.last_pickup;
1662         this.hit_time = spectatee.hit_time;
1663         this.strength_finished = spectatee.strength_finished;
1664         this.invincible_finished = spectatee.invincible_finished;
1665         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1666         this.weapons = spectatee.weapons;
1667         this.vortex_charge = spectatee.vortex_charge;
1668         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1669         this.hagar_load = spectatee.hagar_load;
1670         this.arc_heat_percent = spectatee.arc_heat_percent;
1671         this.minelayer_mines = spectatee.minelayer_mines;
1672         this.punchangle = spectatee.punchangle;
1673         this.view_ofs = spectatee.view_ofs;
1674         this.velocity = spectatee.velocity;
1675         this.dmg_take = spectatee.dmg_take;
1676         this.dmg_save = spectatee.dmg_save;
1677         this.dmg_inflictor = spectatee.dmg_inflictor;
1678         this.v_angle = spectatee.v_angle;
1679         this.angles = spectatee.v_angle;
1680         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1681         this.revive_progress = spectatee.revive_progress;
1682         this.viewloc = spectatee.viewloc;
1683         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1684                 this.fixangle = true;
1685         setorigin(this, spectatee.origin);
1686         setsize(this, spectatee.mins, spectatee.maxs);
1687         SetZoomState(this, spectatee.zoomstate);
1688
1689     anticheat_spectatecopy(this, spectatee);
1690         this.hud = spectatee.hud;
1691         if(spectatee.vehicle)
1692     {
1693         this.angles = spectatee.v_angle;
1694
1695         //this.fixangle = false;
1696         //this.velocity = spectatee.vehicle.velocity;
1697         this.vehicle_health = spectatee.vehicle_health;
1698         this.vehicle_shield = spectatee.vehicle_shield;
1699         this.vehicle_energy = spectatee.vehicle_energy;
1700         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1701         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1702         this.vehicle_reload1 = spectatee.vehicle_reload1;
1703         this.vehicle_reload2 = spectatee.vehicle_reload2;
1704
1705         //msg_entity = this;
1706
1707        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1708             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1709            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1710            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1711
1712         //WriteByte (MSG_ONE, SVC_SETVIEW);
1713         //    WriteEntity(MSG_ONE, this);
1714         //makevectors(spectatee.v_angle);
1715         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1716     }
1717 }
1718
1719 bool SpectateUpdate(entity this)
1720 {
1721         if(!this.enemy)
1722                 return false;
1723
1724         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1725         {
1726                 SetSpectatee(this, NULL);
1727                 return false;
1728         }
1729
1730         SpectateCopy(this, this.enemy);
1731
1732         return true;
1733 }
1734
1735 bool SpectateSet(entity this)
1736 {
1737         if(!IS_PLAYER(this.enemy))
1738                 return false;
1739
1740         ClientData_Touch(this.enemy);
1741
1742         msg_entity = this;
1743         WriteByte(MSG_ONE, SVC_SETVIEW);
1744         WriteEntity(MSG_ONE, this.enemy);
1745         set_movetype(this, MOVETYPE_NONE);
1746         accuracy_resend(this);
1747
1748         if(!SpectateUpdate(this))
1749                 PutObserverInServer(this);
1750
1751         return true;
1752 }
1753
1754 void SetSpectatee_status(entity this, int spectatee_num)
1755 {
1756         int oldspectatee_status = this.spectatee_status;
1757         this.spectatee_status = spectatee_num;
1758
1759         if (this.spectatee_status != oldspectatee_status)
1760         {
1761                 ClientData_Touch(this);
1762                 if (g_race || g_cts) race_InitSpectator();
1763         }
1764 }
1765
1766 void SetSpectatee(entity this, entity spectatee)
1767 {
1768         entity old_spectatee = this.enemy;
1769
1770         this.enemy = spectatee;
1771
1772         // WEAPONTODO
1773         // these are required to fix the spectator bug with arc
1774         if(old_spectatee)
1775         {
1776                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1777                 {
1778                         .entity weaponentity = weaponentities[slot];
1779                         if(old_spectatee.(weaponentity).arc_beam)
1780                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1781                 }
1782         }
1783         if(this.enemy)
1784         {
1785                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1786                 {
1787                         .entity weaponentity = weaponentities[slot];
1788                         if(this.enemy.(weaponentity).arc_beam)
1789                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1790                 }
1791         }
1792
1793         if (this.enemy)
1794                 SetSpectatee_status(this, etof(this.enemy));
1795
1796         // needed to update spectator list
1797         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1798 }
1799
1800 bool Spectate(entity this, entity pl)
1801 {
1802         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1803                 return false;
1804         pl = M_ARGV(1, entity);
1805
1806         SetSpectatee(this, pl);
1807         return SpectateSet(this);
1808 }
1809
1810 bool SpectateNext(entity this)
1811 {
1812         entity ent = find(this.enemy, classname, STR_PLAYER);
1813
1814         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1815                 ent = M_ARGV(1, entity);
1816         else if (!ent)
1817                 ent = find(ent, classname, STR_PLAYER);
1818
1819         if(ent) { SetSpectatee(this, ent); }
1820
1821         return SpectateSet(this);
1822 }
1823
1824 bool SpectatePrev(entity this)
1825 {
1826         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1827         entity ent = findchain(classname, STR_PLAYER);
1828         if (!ent) // no player
1829                 return false;
1830
1831         entity first = ent;
1832         // skip players until current spectated player
1833         if(this.enemy)
1834         while(ent && ent != this.enemy)
1835                 ent = ent.chain;
1836
1837         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1838         {
1839                 case MUT_SPECPREV_FOUND:
1840                     ent = M_ARGV(1, entity);
1841                     break;
1842                 case MUT_SPECPREV_RETURN:
1843                     return true;
1844                 case MUT_SPECPREV_CONTINUE:
1845                 default:
1846                 {
1847                         if(ent.chain)
1848                                 ent = ent.chain;
1849                         else
1850                                 ent = first;
1851                         break;
1852                 }
1853         }
1854
1855         SetSpectatee(this, ent);
1856         return SpectateSet(this);
1857 }
1858
1859 /*
1860 =============
1861 ShowRespawnCountdown()
1862
1863 Update a respawn countdown display.
1864 =============
1865 */
1866 void ShowRespawnCountdown(entity this)
1867 {
1868         float number;
1869         if(!IS_DEAD(this)) // just respawned?
1870                 return;
1871         else
1872         {
1873                 number = ceil(this.respawn_time - time);
1874                 if(number <= 0)
1875                         return;
1876                 if(number <= this.respawn_countdown)
1877                 {
1878                         this.respawn_countdown = number - 1;
1879                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1880                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1881                 }
1882         }
1883 }
1884
1885 .bool team_selected;
1886 bool ShowTeamSelection(entity this)
1887 {
1888         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1889                 return false;
1890         stuffcmd(this, "menu_showteamselect\n");
1891         return true;
1892 }
1893 void Join(entity this)
1894 {
1895         TRANSMUTE(Player, this);
1896
1897         if(!this.team_selected)
1898         if(autocvar_g_campaign || autocvar_g_balance_teams)
1899                 JoinBestTeam(this, false, true);
1900
1901         if(autocvar_g_campaign)
1902                 campaign_bots_may_start = true;
1903
1904         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1905
1906         PutClientInServer(this);
1907
1908         if(teamplay && this.team != -1)
1909                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1910         else
1911                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1912         this.team_selected = false;
1913 }
1914
1915 /**
1916  * Determines whether the player is allowed to join. This depends on cvar
1917  * g_maxplayers, if it isn't used this function always return true, otherwise
1918  * it checks whether the number of currently playing players exceeds g_maxplayers.
1919  * @return int number of free slots for players, 0 if none
1920  */
1921 int nJoinAllowed(entity this, entity ignore)
1922 {
1923         if(!ignore)
1924         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1925         // so report 0 free slots if restricted
1926         {
1927                 if(autocvar_g_forced_team_otherwise == "spectate")
1928                         return 0;
1929                 if(autocvar_g_forced_team_otherwise == "spectator")
1930                         return 0;
1931         }
1932
1933         if(this && this.team_forced < 0)
1934                 return 0; // forced spectators can never join
1935
1936         // TODO simplify this
1937         int totalClients = 0;
1938         int currentlyPlaying = 0;
1939         FOREACH_CLIENT(true, LAMBDA(
1940                 if(it != ignore)
1941                         ++totalClients;
1942                 if(IS_REAL_CLIENT(it))
1943                 if(IS_PLAYER(it) || it.caplayer)
1944                         ++currentlyPlaying;
1945         ));
1946
1947         float free_slots = 0;
1948         if (!autocvar_g_maxplayers)
1949                 free_slots = maxclients - totalClients;
1950         else if(currentlyPlaying < autocvar_g_maxplayers)
1951                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1952
1953         static float join_prevent_msg_time = 0;
1954         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1955         {
1956                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1957                 join_prevent_msg_time = time + 3;
1958         }
1959
1960         return free_slots;
1961 }
1962
1963 /**
1964  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1965  * g_maxplayers_spectator_blocktime seconds
1966  */
1967 void checkSpectatorBlock(entity this)
1968 {
1969         if(IS_SPEC(this) || IS_OBSERVER(this))
1970         if(!this.caplayer)
1971         if(IS_REAL_CLIENT(this))
1972         {
1973                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1974                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1975                         dropclient(this);
1976                 }
1977         }
1978 }
1979
1980 void PrintWelcomeMessage(entity this)
1981 {
1982         if(this.motd_actived_time == 0)
1983         {
1984                 if (autocvar_g_campaign) {
1985                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1986                                 this.motd_actived_time = time;
1987                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1988                         }
1989                 } else {
1990                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1991                                 this.motd_actived_time = time;
1992                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1993                         }
1994                 }
1995         }
1996         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1997         {
1998                 if (autocvar_g_campaign) {
1999                         if (PHYS_INPUT_BUTTON_INFO(this))
2000                                 this.motd_actived_time = time;
2001                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2002                                 this.motd_actived_time = 0;
2003                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2004                         }
2005                 } else {
2006                         if (PHYS_INPUT_BUTTON_INFO(this))
2007                                 this.motd_actived_time = time;
2008                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2009                                 this.motd_actived_time = 0;
2010                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2011                         }
2012                 }
2013         }
2014         else //if(this.motd_actived_time < 0) // just connected, motd is active
2015         {
2016                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2017                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2018                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2019                 {
2020                         // instanctly hide MOTD
2021                         this.motd_actived_time = 0;
2022                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2023                 }
2024         }
2025 }
2026
2027 bool joinAllowed(entity this)
2028 {
2029         if (this.version_mismatch) return false;
2030         if (!nJoinAllowed(this, this)) return false;
2031         if (teamplay && lockteams) return false;
2032         if (ShowTeamSelection(this)) return false;
2033         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2034         return true;
2035 }
2036
2037 void ObserverThink(entity this)
2038 {
2039         if ( this.impulse )
2040         {
2041                 MinigameImpulse(this, this.impulse);
2042                 this.impulse = 0;
2043         }
2044
2045         if (this.flags & FL_JUMPRELEASED) {
2046                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2047                         this.flags &= ~FL_JUMPRELEASED;
2048                         this.flags |= FL_SPAWNING;
2049                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2050                         this.flags &= ~FL_JUMPRELEASED;
2051                         if(SpectateNext(this)) {
2052                                 TRANSMUTE(Spectator, this);
2053                         }
2054                 } else {
2055                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2056                         set_movetype(this, preferred_movetype);
2057                 }
2058         } else {
2059                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2060                         this.flags |= FL_JUMPRELEASED;
2061                         if(this.flags & FL_SPAWNING)
2062                         {
2063                                 this.flags &= ~FL_SPAWNING;
2064                                 Join(this);
2065                                 return;
2066                         }
2067                 }
2068         }
2069 }
2070
2071 void SpectatorThink(entity this)
2072 {
2073         if ( this.impulse )
2074         {
2075                 if(MinigameImpulse(this, this.impulse))
2076                         this.impulse = 0;
2077
2078                 if (this.impulse == IMP_weapon_drop.impulse)
2079                 {
2080                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2081                         this.impulse = 0;
2082                         return;
2083                 }
2084         }
2085
2086         if (this.flags & FL_JUMPRELEASED) {
2087                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2088                         this.flags &= ~FL_JUMPRELEASED;
2089                         this.flags |= FL_SPAWNING;
2090                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2091                         this.flags &= ~FL_JUMPRELEASED;
2092                         if(SpectateNext(this)) {
2093                                 TRANSMUTE(Spectator, this);
2094                         } else {
2095                                 TRANSMUTE(Observer, this);
2096                                 PutClientInServer(this);
2097                         }
2098                         this.impulse = 0;
2099                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2100                         this.flags &= ~FL_JUMPRELEASED;
2101                         if(SpectatePrev(this)) {
2102                                 TRANSMUTE(Spectator, this);
2103                         } else {
2104                                 TRANSMUTE(Observer, this);
2105                                 PutClientInServer(this);
2106                         }
2107                         this.impulse = 0;
2108                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2109                         this.flags &= ~FL_JUMPRELEASED;
2110                         TRANSMUTE(Observer, this);
2111                         PutClientInServer(this);
2112                 } else {
2113                         if(!SpectateUpdate(this))
2114                                 PutObserverInServer(this);
2115                 }
2116         } else {
2117                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2118                         this.flags |= FL_JUMPRELEASED;
2119                         if(this.flags & FL_SPAWNING)
2120                         {
2121                                 this.flags &= ~FL_SPAWNING;
2122                                 Join(this);
2123                                 return;
2124                         }
2125                 }
2126                 if(!SpectateUpdate(this))
2127                         PutObserverInServer(this);
2128         }
2129
2130         this.flags |= FL_CLIENT | FL_NOTARGET;
2131 }
2132
2133 void vehicles_enter (entity pl, entity veh);
2134 void PlayerUseKey(entity this)
2135 {
2136         if (!IS_PLAYER(this))
2137                 return;
2138
2139         if(this.vehicle)
2140         {
2141                 if(!gameover)
2142                 {
2143                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2144                         return;
2145                 }
2146         }
2147         else if(autocvar_g_vehicles_enter)
2148         {
2149                 if(!STAT(FROZEN, this))
2150                 if(!IS_DEAD(this))
2151                 if(!gameover)
2152                 {
2153                         entity head, closest_target = NULL;
2154                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2155
2156                         while(head) // find the closest acceptable target to enter
2157                         {
2158                                 if(IS_VEHICLE(head))
2159                                 if(!IS_DEAD(head))
2160                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2161                                 if(head.takedamage != DAMAGE_NO)
2162                                 {
2163                                         if(closest_target)
2164                                         {
2165                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2166                                                 { closest_target = head; }
2167                                         }
2168                                         else { closest_target = head; }
2169                                 }
2170
2171                                 head = head.chain;
2172                         }
2173
2174                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2175                 }
2176         }
2177
2178         // a use key was pressed; call handlers
2179         MUTATOR_CALLHOOK(PlayerUseKey, this);
2180 }
2181
2182
2183 /*
2184 =============
2185 PlayerPreThink
2186
2187 Called every frame for each client before the physics are run
2188 =============
2189 */
2190 .float usekeypressed;
2191 .float last_vehiclecheck;
2192 .int items_added;
2193 void PlayerPreThink (entity this)
2194 {
2195         WarpZone_PlayerPhysics_FixVAngle(this);
2196
2197     STAT(GAMESTARTTIME, this) = game_starttime;
2198         STAT(ROUNDSTARTTIME, this) = round_starttime;
2199         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2200         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2201
2202         STAT(WEAPONSINMAP, this) = weaponsInMap;
2203
2204         if (frametime) {
2205                 // physics frames: update anticheat stuff
2206                 anticheat_prethink(this);
2207         }
2208
2209         if (blockSpectators && frametime) {
2210                 // WORKAROUND: only use dropclient in server frames (frametime set).
2211                 // Never use it in cl_movement frames (frametime zero).
2212                 checkSpectatorBlock(this);
2213     }
2214
2215         zoomstate_set = false;
2216
2217         // Check for nameless players
2218         if (isInvisibleString(this.netname)) {
2219                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2220                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2221         }
2222         if (this.netname != this.netname_previous) {
2223                 if (autocvar_sv_eventlog) {
2224                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2225         }
2226                 if (this.netname_previous) strunzone(this.netname_previous);
2227                 this.netname_previous = strzone(this.netname);
2228         }
2229
2230         // version nagging
2231         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2232         this.version_nagtime = 0;
2233         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2234             // git client
2235         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2236             // git server
2237             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2238         } else {
2239             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2240             if (r < 0) { // old client
2241                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2242             } else if (r > 0) { // old server
2243                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2244             }
2245         }
2246     }
2247
2248         // GOD MODE info
2249         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2250         {
2251                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2252                 this.max_armorvalue = 0;
2253         }
2254
2255         if (STAT(FROZEN, this) == 2)
2256         {
2257                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2258                 this.health = max(1, this.revive_progress * start_health);
2259                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2260
2261                 if (this.revive_progress >= 1)
2262                         Unfreeze(this);
2263         }
2264         else if (STAT(FROZEN, this) == 3)
2265         {
2266                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2267                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2268
2269                 if (this.health < 1)
2270                 {
2271                         if (this.vehicle)
2272                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2273                         if(this.event_damage)
2274                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2275                 }
2276                 else if (this.revive_progress <= 0)
2277                         Unfreeze(this);
2278         }
2279
2280         MUTATOR_CALLHOOK(PlayerPreThink, this);
2281
2282         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2283         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2284         {
2285                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2286                 {
2287                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2288                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2289                         {
2290                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2291                         }
2292                         else if(!it.owner)
2293                         {
2294                                 if(!it.team || SAME_TEAM(this, it))
2295                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2296                                 else if(autocvar_g_vehicles_steal)
2297                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2298                         }
2299                 });
2300
2301                 this.last_vehiclecheck = time + 1;
2302         }
2303
2304         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2305         {
2306                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2307                         PlayerUseKey(this);
2308                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2309         }
2310
2311         if (IS_REAL_CLIENT(this))
2312                 PrintWelcomeMessage(this);
2313
2314         if (IS_PLAYER(this)) {
2315                 CheckRules_Player(this);
2316
2317                 if (intermission_running) {
2318                         IntermissionThink(this);
2319                         return;
2320                 }
2321
2322                 if (timeout_status == TIMEOUT_ACTIVE) {
2323             // don't allow the player to turn around while game is paused
2324                         // FIXME turn this into CSQC stuff
2325                         this.v_angle = this.lastV_angle;
2326                         this.angles = this.lastV_angle;
2327                         this.fixangle = true;
2328                 }
2329
2330                 if (frametime) player_powerups(this);
2331
2332                 if (IS_DEAD(this)) {
2333                         if (this.personal && g_race_qualifying) {
2334                                 if (time > this.respawn_time) {
2335                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2336                                         respawn(this);
2337                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2338                                 }
2339                         } else {
2340                                 if (frametime) player_anim(this);
2341                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2342
2343                                 switch(this.deadflag)
2344                                 {
2345                                         case DEAD_DYING:
2346                                         {
2347                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2348                                                         this.deadflag = DEAD_RESPAWNING;
2349                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2350                                                         this.deadflag = DEAD_DEAD;
2351                                                 break;
2352                                         }
2353                                         case DEAD_DEAD:
2354                                         {
2355                                                 if (button_pressed)
2356                                                         this.deadflag = DEAD_RESPAWNABLE;
2357                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2358                                                         this.deadflag = DEAD_RESPAWNING;
2359                                                 break;
2360                                         }
2361                                         case DEAD_RESPAWNABLE:
2362                                         {
2363                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2364                                                         this.deadflag = DEAD_RESPAWNING;
2365                                                 break;
2366                                         }
2367                                         case DEAD_RESPAWNING:
2368                                         {
2369                                                 if (time > this.respawn_time)
2370                                                 {
2371                                                         this.respawn_time = time + 1; // only retry once a second
2372                                                         this.respawn_time_max = this.respawn_time;
2373                                                         respawn(this);
2374                                                 }
2375                                                 break;
2376                                         }
2377                                 }
2378
2379                                 ShowRespawnCountdown(this);
2380
2381                                 if (this.respawn_flags & RESPAWN_SILENT)
2382                                         STAT(RESPAWN_TIME, this) = 0;
2383                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2384                                 {
2385                                         if (time < this.respawn_time)
2386                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2387                                         else if (this.deadflag != DEAD_RESPAWNING)
2388                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2389                                 }
2390                                 else
2391                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2392                         }
2393
2394                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2395                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2396                                 STAT(RESPAWN_TIME, this) *= -1;
2397
2398                         return;
2399                 }
2400
2401                 this.prevorigin = this.origin;
2402
2403                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2404                 if (this.hook.state) {
2405                         do_crouch = false;
2406                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2407                         do_crouch = false;
2408                 } else if (this.vehicle) {
2409                         do_crouch = false;
2410                 } else if (STAT(FROZEN, this)) {
2411                         do_crouch = false;
2412         }
2413
2414                 if (do_crouch) {
2415                         if (!this.crouch) {
2416                                 this.crouch = true;
2417                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2418                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2419                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2420                         }
2421                 } else if (this.crouch) {
2422             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2423             if (!trace_startsolid) {
2424                 this.crouch = false;
2425                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2426                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2427             }
2428                 }
2429
2430                 FixPlayermodel(this);
2431
2432                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2433                 //if(frametime)
2434                 {
2435                         this.items &= ~this.items_added;
2436
2437                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2438                         {
2439                                 .entity weaponentity = weaponentities[slot];
2440                                 W_WeaponFrame(this, weaponentity);
2441
2442                                 if(slot == 0)
2443                                 {
2444                                         this.clip_load = this.(weaponentity).clip_load;
2445                                         this.clip_size = this.(weaponentity).clip_size;
2446                                 }
2447                         }
2448
2449                         this.items_added = 0;
2450                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2451                 this.items_added |= IT_FUEL;
2452
2453                         this.items |= this.items_added;
2454                 }
2455
2456                 player_regen(this);
2457
2458                 // WEAPONTODO: Add a weapon request for this
2459                 // rot vortex charge to the charge limit
2460                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2461                 {
2462                         .entity weaponentity = weaponentities[slot];
2463                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2464                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2465                 }
2466
2467                 if (frametime) player_anim(this);
2468
2469                 // secret status
2470                 secrets_setstatus(this);
2471
2472                 // monsters status
2473                 monsters_setstatus(this);
2474
2475                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2476         }
2477         else if (gameover) {
2478                 if (intermission_running) IntermissionThink(this);
2479                 return;
2480         }
2481         else if (IS_OBSERVER(this)) {
2482                 ObserverThink(this);
2483         }
2484         else if (IS_SPEC(this)) {
2485                 SpectatorThink(this);
2486         }
2487
2488         // WEAPONTODO: Add weapon request for this
2489         if (!zoomstate_set) {
2490                 bool wep_zoomed = false;
2491                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2492                 {
2493                         .entity weaponentity = weaponentities[slot];
2494                         Weapon thiswep = this.(weaponentity).m_weapon;
2495                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2496                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2497                 }
2498                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2499     }
2500
2501         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2502         {
2503                 this.teamkill_soundtime = 0;
2504
2505                 entity e = this.teamkill_soundsource;
2506                 entity oldpusher = e.pusher;
2507                 e.pusher = this;
2508                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2509                 e.pusher = oldpusher;
2510         }
2511
2512         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2513                 this.taunt_soundtime = 0;
2514                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2515         }
2516
2517         target_voicescript_next(this);
2518
2519         // WEAPONTODO: Move into weaponsystem somehow
2520         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2521         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2522         {
2523                 .entity weaponentity = weaponentities[slot];
2524                 if(this.(weaponentity).m_weapon == WEP_Null)
2525                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2526         }
2527 }
2528
2529 void DrownPlayer(entity this)
2530 {
2531         if(IS_DEAD(this))
2532                 return;
2533
2534         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2535         {
2536                 if(this.air_finished < time)
2537                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2538                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2539                 this.dmg = 2;
2540         }
2541         else if (this.air_finished < time)
2542         {       // drown!
2543                 if (this.pain_finished < time)
2544                 {
2545                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2546                         this.pain_finished = time + 0.5;
2547                 }
2548         }
2549 }
2550
2551 .bool move_qcphysics;
2552
2553 void Player_Physics(entity this)
2554 {
2555         set_movetype(this, this.move_movetype);
2556
2557         if(!this.move_qcphysics)
2558                 return;
2559
2560         if(!frametime && !this.pm_frametime)
2561                 return;
2562
2563         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2564
2565         this.pm_frametime = 0;
2566 }
2567
2568 /*
2569 =============
2570 PlayerPostThink
2571
2572 Called every frame for each client after the physics are run
2573 =============
2574 */
2575 .float idlekick_lasttimeleft;
2576 void PlayerPostThink (entity this)
2577 {
2578         Player_Physics(this);
2579
2580         if (sv_maxidle > 0)
2581         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2582         if (IS_REAL_CLIENT(this))
2583         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2584         {
2585                 int totalClients = 0;
2586                 if(sv_maxidle_slots > 0)
2587                 {
2588                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2589                         {
2590                                 ++totalClients;
2591                         });
2592                 }
2593
2594                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2595                 { /* do nothing */ }
2596                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2597                 {
2598                         if (this.idlekick_lasttimeleft)
2599                         {
2600                                 this.idlekick_lasttimeleft = 0;
2601                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2602                         }
2603                 }
2604                 else
2605                 {
2606                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2607                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2608                                 if (!this.idlekick_lasttimeleft)
2609                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2610                         }
2611                         if (timeleft <= 0) {
2612                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2613                                 dropclient(this);
2614                                 return;
2615                         }
2616                         else if (timeleft <= 10) {
2617                                 if (timeleft != this.idlekick_lasttimeleft) {
2618                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2619                 }
2620                                 this.idlekick_lasttimeleft = timeleft;
2621                         }
2622                 }
2623         }
2624
2625         CheatFrame(this);
2626
2627         //CheckPlayerJump();
2628
2629         if (IS_PLAYER(this)) {
2630                 DrownPlayer(this);
2631                 CheckRules_Player(this);
2632                 UpdateChatBubble(this);
2633                 if (this.impulse) ImpulseCommands(this);
2634                 if (intermission_running) return; // intermission or finale
2635                 GetPressedKeys(this);
2636         }
2637
2638         if (this.waypointsprite_attachedforcarrier) {
2639             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2640                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2641     }
2642
2643         playerdemo_write(this);
2644
2645         CSQCMODEL_AUTOUPDATE(this);
2646 }