qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         bool recount_ready = false;
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         this.ready = false;
 257                         recount_ready = true;
 258                 }
 259                 entcs_update_players(this);
 260         }
 261
 262         if (use_spawnpoint)
 263         {
 264                 entity spot = SelectSpawnPoint(this, true);
 265                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 266                 this.angles = vec2(spot.angles);
 267                 // offset it so that the spectator spawns higher off the ground, looks better this way
 268                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 269         }
 270         else // change origin to restore previous view origin
 271                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 272         this.fixangle = true;
 273
 274         if (IS_REAL_CLIENT(this))
 275         {
 276                 msg_entity = this;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, this);
 279         }
 280         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 281         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 282         if(!autocvar_g_debug_globalsounds)
 283         {
 284                 // needed for player sounds
 285                 this.model = "";
 286                 FixPlayermodel(this);
 287         }
 288         setmodel(this, MDL_Null);
 289         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 290         this.view_ofs = '0 0 0';
 291
 292         RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         TRANSMUTE(Observer, this);
 307
 308         if(recount_ready) ReadyCount();
 309
 310         WaypointSprite_PlayerDead(this);
 311         accuracy_resend(this);
 312
 313         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 314                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323         STAT(HUD, this) = HUD_NORMAL;
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         player_powerups_remove_all(this);
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406
 407         bot_relinkplayerlist();
 408
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void PutPlayerInServer(entity this)
 536 {
 537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 538
 539         PlayerState_attach(this);
 540         accuracy_resend(this);
 541
 542         if (this.team < 0)
 543                 TeamBalance_JoinBestTeam(this);
 544
 545         entity spot = SelectSpawnPoint(this, false);
 546         if (!spot) {
 547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 548                 return; // spawn failed
 549         }
 550
 551         TRANSMUTE(Player, this);
 552
 553         CS(this).wasplayer = true;
 554         this.iscreature = true;
 555         this.teleportable = TELEPORT_NORMAL;
 556         if(!this.damagedbycontents)
 557                 IL_PUSH(g_damagedbycontents, this);
 558         this.damagedbycontents = true;
 559         set_movetype(this, MOVETYPE_WALK);
 560         this.solid = SOLID_SLIDEBOX;
 561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 562         if (autocvar_g_playerclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 566         this.frags = FRAGS_PLAYER;
 567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 569         if (autocvar__notarget)
 570                 this.flags |= FL_NOTARGET;
 571         this.takedamage = DAMAGE_AIM;
 572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 573
 574         if (warmup_stage) {
 575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, warmup_start_health);
 582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 584         } else {
 585                 SetResource(this, RES_SHELLS, start_ammo_shells);
 586                 SetResource(this, RES_BULLETS, start_ammo_nails);
 587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 588                 SetResource(this, RES_CELLS, start_ammo_cells);
 589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 590                 SetResource(this, RES_FUEL, start_ammo_fuel);
 591                 SetResource(this, RES_HEALTH, start_health);
 592                 SetResource(this, RES_ARMOR, start_armorvalue);
 593                 STAT(WEAPONS, this) = start_weapons;
 594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 595                 {
 596                         GiveRandomWeapons(this, random_start_weapons_count,
 597                                 autocvar_g_random_start_weapons, random_start_ammo);
 598                 }
 599         }
 600         SetSpectatee_status(this, 0);
 601
 602         PS(this).dual_weapons = '0 0 0';
 603
 604         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 605                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 606
 607         this.items = start_items;
 608
 609         float shieldtime = time + autocvar_g_spawnshieldtime;
 610
 611         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 612         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 613         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 614         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 615         if (!sv_ready_restart_after_countdown && time < game_starttime)
 616         {
 617                 float f = game_starttime - time;
 618                 shieldtime += f;
 619                 this.pauserotarmor_finished += f;
 620                 this.pauserothealth_finished += f;
 621                 this.pauseregen_finished += f;
 622         }
 623
 624         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 625
 626         this.damageforcescale = autocvar_g_player_damageforcescale;
 627         this.death_time = 0;
 628         this.respawn_flags = 0;
 629         this.respawn_time = 0;
 630         STAT(RESPAWN_TIME, this) = 0;
 631         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 632         this.fade_time = 0;
 633         this.pain_finished = 0;
 634         this.pushltime = 0;
 635         setthink(this, func_null); // players have no think function
 636         this.nextthink = 0;
 637         this.dmg_team = 0;
 638         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 639
 640         this.deadflag = DEAD_NO;
 641
 642         this.angles = spot.angles;
 643         this.angles_z = 0; // never spawn tilted even if the spot says to
 644         if (IS_BOT_CLIENT(this))
 645         {
 646                 this.v_angle = this.angles;
 647                 bot_aim_reset(this);
 648         }
 649         this.fixangle = true; // turn this way immediately
 650         this.oldvelocity = this.velocity = '0 0 0';
 651         this.avelocity = '0 0 0';
 652         this.punchangle = '0 0 0';
 653         this.punchvector = '0 0 0';
 654
 655         STAT(REVIVE_PROGRESS, this) = 0;
 656         this.revival_time = 0;
 657
 658         STAT(AIR_FINISHED, this) = 0;
 659         this.waterlevel = WATERLEVEL_NONE;
 660         this.watertype = CONTENT_EMPTY;
 661
 662         entity spawnevent = new_pure(spawnevent);
 663         spawnevent.owner = this;
 664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665
 666         // Cut off any still running player sounds.
 667         stopsound(this, CH_PLAYER_SINGLE);
 668
 669         this.model = "";
 670         FixPlayermodel(this);
 671         this.drawonlytoclient = NULL;
 672
 673         this.viewloc = NULL;
 674
 675         for(int slot = 0; slot < MAX_AXH; ++slot)
 676         {
 677                 entity axh = this.(AuxiliaryXhair[slot]);
 678                 this.(AuxiliaryXhair[slot]) = NULL;
 679
 680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 681                         delete(axh);
 682         }
 683
 684         this.spawnpoint_targ = NULL;
 685
 686         UNSET_DUCKED(this);
 687         this.view_ofs = STAT(PL_VIEW_OFS, this);
 688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 689         this.spawnorigin = spot.origin;
 690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 691         // don't reset back to last position, even if new position is stuck in solid
 692         this.oldorigin = this.origin;
 693         if(this.conveyor)
 694                 IL_REMOVE(g_conveyed, this);
 695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 696         if(this.swampslug)
 697                 IL_REMOVE(g_swamped, this);
 698         this.swampslug = NULL;
 699         this.swamp_interval = 0;
 700         if(this.ladder_entity)
 701                 IL_REMOVE(g_ladderents, this);
 702         this.ladder_entity = NULL;
 703         IL_EACH(g_counters, it.realowner == this,
 704         {
 705                 delete(it);
 706         });
 707         STAT(HUD, this) = HUD_NORMAL;
 708
 709         this.event_damage = PlayerDamage;
 710         this.event_heal = PlayerHeal;
 711
 712         this.draggable = func_null;
 713
 714         if(!this.bot_attack)
 715                 IL_PUSH(g_bot_targets, this);
 716         this.bot_attack = true;
 717         if(!this.monster_attack)
 718                 IL_PUSH(g_monster_targets, this);
 719         this.monster_attack = true;
 720         navigation_dynamicgoal_init(this, false);
 721
 722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 723
 724         // player was spectator
 725         if (CS(this).killcount == FRAGS_SPECTATOR) {
 726                 PlayerScore_Clear(this);
 727                 CS(this).killcount = 0;
 728                 CS(this).startplaytime = time;
 729         }
 730
 731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 732         {
 733                 .entity weaponentity = weaponentities[slot];
 734                 CL_SpawnWeaponentity(this, weaponentity);
 735         }
 736         this.alpha = default_player_alpha;
 737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 738         this.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740         this.speedrunning = false;
 741
 742         this.counter_cnt = 0;
 743         this.fragsfilter_cnt = 0;
 744
 745         target_voicescript_clear(this);
 746
 747         // reset fields the weapons may use
 748         FOREACH(Weapons, true, {
 749                 it.wr_resetplayer(it, this);
 750                         // reload all reloadable weapons
 751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753                         {
 754                                 .entity weaponentity = weaponentities[slot];
 755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 756                         }
 757                 }
 758         });
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763         {
 764                 string s = spot.target;
 765                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 766                         spot.target = string_null;
 767                 SUB_UseTargets(spot, this, NULL);
 768                 if(g_assault || g_race)
 769                         spot.target = s;
 770         }
 771
 772         if (autocvar_spawn_debug)
 773         {
 774                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 775                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 776         }
 777
 778         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 779         {
 780                 .entity weaponentity = weaponentities[slot];
 781                 entity w_ent = this.(weaponentity);
 782                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 783                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 784                 else
 785                         w_ent.m_switchweapon = WEP_Null;
 786                 w_ent.m_weapon = WEP_Null;
 787                 w_ent.weaponname = "";
 788                 w_ent.m_switchingweapon = WEP_Null;
 789                 w_ent.cnt = -1;
 790         }
 791
 792         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 793
 794         if (CS(this).impulse) ImpulseCommands(this);
 795
 796         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 797         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 798         {
 799                 .entity weaponentity = weaponentities[slot];
 800                 W_WeaponFrame(this, weaponentity);
 801         }
 802
 803         if (!warmup_stage && !this.alivetime)
 804                 this.alivetime = time;
 805
 806         antilag_clear(this, CS(this));
 807 }
 808
 809 /** Called when a client spawns in the server */
 810 void PutClientInServer(entity this)
 811 {
 812         if (IS_BOT_CLIENT(this)) {
 813                 TRANSMUTE(Player, this);
 814         } else if (IS_REAL_CLIENT(this)) {
 815                 msg_entity = this;
 816                 WriteByte(MSG_ONE, SVC_SETVIEW);
 817                 WriteEntity(MSG_ONE, this);
 818         }
 819         if (game_stopped)
 820                 TRANSMUTE(Observer, this);
 821
 822         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 823         SetSpectatee(this, NULL);
 824
 825         // reset player keys
 826         if(PS(this))
 827                 PS(this).itemkeys = 0;
 828
 829         MUTATOR_CALLHOOK(PutClientInServer, this);
 830
 831         if (IS_OBSERVER(this)) {
 832                 PutObserverInServer(this, false, use_spawnpoint);
 833         } else if (IS_PLAYER(this)) {
 834                 PutPlayerInServer(this);
 835         }
 836
 837         bot_relinkplayerlist();
 838 }
 839
 840 // TODO do we need all these fields, or should we stop autodetecting runtime
 841 // changes and just have a console command to update this?
 842 bool ClientInit_SendEntity(entity this, entity to, int sf)
 843 {
 844         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 845         return = true;
 846         msg_entity = to;
 847         // MSG_INIT replacement
 848         // TODO: make easier to use
 849         Registry_send_all();
 850         W_PROP_reload(MSG_ONE, to);
 851         ClientInit_misc(this);
 852         MUTATOR_CALLHOOK(Ent_Init);
 853 }
 854 void ClientInit_misc(entity this)
 855 {
 856         int channel = MSG_ONE;
 857         WriteHeader(channel, ENT_CLIENT_INIT);
 858         WriteByte(channel, g_nexball_meter_period * 32);
 859         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 863         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 867
 868         if(autocvar_sv_foginterval && world.fog != "")
 869                 WriteString(channel, world.fog);
 870         else
 871                 WriteString(channel, "");
 872         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 873         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 874         WriteByte(channel, serverflags);
 875         WriteCoord(channel, autocvar_g_trueaim_minrange);
 876 }
 877
 878 void ClientInit_CheckUpdate(entity this)
 879 {
 880         this.nextthink = time;
 881         if(this.count != autocvar_g_balance_armor_blockpercent)
 882         {
 883                 this.count = autocvar_g_balance_armor_blockpercent;
 884                 this.SendFlags |= 1;
 885         }
 886         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 887         {
 888                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 889                 this.SendFlags |= 1;
 890         }
 891 }
 892
 893 void ClientInit_Spawn()
 894 {
 895         entity e = new_pure(clientinit);
 896         setthink(e, ClientInit_CheckUpdate);
 897         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 898
 899         ClientInit_CheckUpdate(e);
 900 }
 901
 902 /*
 903 =============
 904 SetNewParms
 905 =============
 906 */
 907 void SetNewParms ()
 908 {
 909         // initialize parms for a new player
 910         parm1 = -(86400 * 366);
 911
 912         MUTATOR_CALLHOOK(SetNewParms);
 913 }
 914
 915 /*
 916 =============
 917 SetChangeParms
 918 =============
 919 */
 920 void SetChangeParms (entity this)
 921 {
 922         // save parms for level change
 923         parm1 = CS(this).parm_idlesince - time;
 924
 925         MUTATOR_CALLHOOK(SetChangeParms);
 926 }
 927
 928 /*
 929 =============
 930 DecodeLevelParms
 931 =============
 932 */
 933 void DecodeLevelParms(entity this)
 934 {
 935         // load parms
 936         CS(this).parm_idlesince = parm1;
 937         if (CS(this).parm_idlesince == -(86400 * 366))
 938                 CS(this).parm_idlesince = time;
 939
 940         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 941         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 942
 943         MUTATOR_CALLHOOK(DecodeLevelParms);
 944 }
 945
 946 void FixClientCvars(entity e)
 947 {
 948         // send prediction settings to the client
 949         if(autocvar_g_antilag == 3) // client side hitscan
 950                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 951         if(autocvar_sv_gentle)
 952                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 953
 954         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 956
 957         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 958
 959         MUTATOR_CALLHOOK(FixClientCvars, e);
 960 }
 961
 962 bool findinlist_abbrev(string tofind, string list)
 963 {
 964         if(list == "" || tofind == "")
 965                 return false; // empty list or search, just return
 966
 967         // this function allows abbreviated strings!
 968         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 969         {
 970                 return true;
 971         });
 972
 973         return false;
 974 }
 975
 976 bool PlayerInIPList(entity p, string iplist)
 977 {
 978         // some safety checks (never allow local?)
 979         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 980                 return false;
 981
 982         return findinlist_abbrev(p.netaddress, iplist);
 983 }
 984
 985 bool PlayerInIDList(entity p, string idlist)
 986 {
 987         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 988         if(!p.crypto_idfp)
 989                 return false;
 990
 991         return findinlist_abbrev(p.crypto_idfp, idlist);
 992 }
 993
 994 bool PlayerInList(entity player, string list)
 995 {
 996         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 997 }
 998
 999 #ifdef DP_EXT_PRECONNECT
1000 /*
1001 =============
1002 ClientPreConnect
1003
1004 Called once (not at each match start) when a client begins a connection to the server
1005 =============
1006 */
1007 void ClientPreConnect(entity this)
1008 {
1009         if(autocvar_sv_eventlog)
1010         {
1011                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1012                         this.playerid,
1013                         etof(this),
1014                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1015                 ));
1016         }
1017 }
1018 #endif
1019
1020 void SendWelcomemessage(entity this, bool force_centerprint)
1021 {
1022         msg_entity = this;
1023         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1024         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1025 }
1026
1027 // NOTE csqc uses the active mutators list sent by this function
1028 // to understand which mutators are enabled
1029 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1030 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1031 {
1032         WriteByte(msg_type, boolean(autocvar_g_campaign));
1033         if (boolean(autocvar_g_campaign))
1034         {
1035                 WriteString(msg_type, Campaign_GetTitle());
1036                 WriteByte(msg_type, Campaign_GetLevelNum());
1037                 WriteString(msg_type, Campaign_GetMessage());
1038                 return;
1039         }
1040         WriteByte(msg_type, force_centerprint);
1041         WriteString(msg_type, autocvar_hostname);
1042         WriteString(msg_type, autocvar_g_xonoticversion);
1043         WriteByte(msg_type, CS(this).version_mismatch);
1044         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1045
1046         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1047         string modifications = M_ARGV(0, string);
1048
1049         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1050                 modifications = strcat(modifications, ", No start weapons");
1051         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1052                 modifications = strcat(modifications, ", Low gravity");
1053         if(g_weapon_stay && !g_cts)
1054                 modifications = strcat(modifications, ", Weapons stay");
1055         if(autocvar_g_jetpack)
1056                 modifications = strcat(modifications, ", Jetpack");
1057         modifications = substring(modifications, 2, strlen(modifications) - 2);
1058
1059         WriteString(msg_type, modifications);
1060
1061         WriteString(msg_type, g_weaponarena_list);
1062
1063         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1064         {
1065                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1066                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1067         }
1068
1069         WriteString(msg_type, cache_mutatormsg);
1070
1071         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1072 }
1073
1074 /**
1075 =============
1076 ClientConnect
1077
1078 Called when a client connects to the server
1079 =============
1080 */
1081 void ClientConnect(entity this)
1082 {
1083         if (Ban_MaybeEnforceBanOnce(this)) return;
1084         assert(!IS_CLIENT(this), return);
1085         this.flags |= FL_CLIENT;
1086         assert(player_count >= 0, player_count = 0);
1087
1088         TRANSMUTE(Client, this);
1089         CS(this).version_nagtime = time + 10 + random() * 10;
1090
1091         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1092
1093         bot_clientconnect(this);
1094
1095         Player_DetermineForcedTeam(this);
1096
1097         TRANSMUTE(Observer, this);
1098
1099         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1100
1101         // always track bots, don't ask for cl_allow_uidtracking
1102         if (IS_BOT_CLIENT(this))
1103                 PlayerStats_GameReport_AddPlayer(this);
1104         else
1105                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1106
1107         if (autocvar_sv_eventlog)
1108                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1109
1110         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1111
1112         stuffcmd(this, clientstuff, "\n");
1113         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1114
1115         FixClientCvars(this);
1116
1117         // get version info from player
1118         stuffcmd(this, "cmd clientversion $gameversion\n");
1119
1120         // notify about available teams
1121         if (teamplay)
1122         {
1123                 entity balance = TeamBalance_CheckAllowedTeams(this);
1124                 int t = TeamBalance_GetAllowedTeams(balance);
1125                 TeamBalance_Destroy(balance);
1126                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1127         }
1128         else
1129         {
1130                 stuffcmd(this, "set _teams_available 0\n");
1131         }
1132
1133         bot_relinkplayerlist();
1134
1135         CS(this).spectatortime = time;
1136         if (blockSpectators)
1137         {
1138                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1139         }
1140
1141         CS(this).jointime = time;
1142
1143         if (IS_REAL_CLIENT(this))
1144         {
1145                 if (g_weaponarena_weapons == WEPSET(TUBA))
1146                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1147         }
1148
1149         if (!autocvar_sv_foginterval && world.fog != "")
1150                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1151
1152         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1153                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1154                         send_CSQC_teamnagger();
1155
1156         CSQCMODEL_AUTOINIT(this);
1157
1158         CS(this).model_randomizer = random();
1159
1160         if (IS_REAL_CLIENT(this))
1161                 sv_notice_join(this);
1162
1163         this.move_qcphysics = autocvar_sv_qcphysics;
1164
1165         // update physics stats (players can spawn before physics runs)
1166         Physics_UpdateStats(this);
1167
1168         IL_EACH(g_initforplayer, it.init_for_player, {
1169                 it.init_for_player(it, this);
1170         });
1171
1172         Handicap_Initialize(this);
1173
1174         MUTATOR_CALLHOOK(ClientConnect, this);
1175
1176         if (player_count == 1)
1177                 localcmd("\nsv_hook_firstjoin\n");
1178
1179         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1180                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1181 }
1182 /*
1183 =============
1184 ClientDisconnect
1185
1186 Called when a client disconnects from the server
1187 =============
1188 */
1189 .entity chatbubbleentity;
1190 void player_powerups_remove_all(entity this);
1191
1192 void ClientDisconnect(entity this)
1193 {
1194         assert(IS_CLIENT(this), return);
1195
1196         PlayerStats_GameReport_FinalizePlayer(this);
1197         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1198         if (CS(this).active_minigame) part_minigame(this);
1199         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1200
1201         if (autocvar_sv_eventlog)
1202                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1203
1204         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1205
1206         if(IS_SPEC(this))
1207                 SetSpectatee(this, NULL);
1208
1209         MUTATOR_CALLHOOK(ClientDisconnect, this);
1210
1211         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1212         strfree(CS_CVAR(this).weaponorder_byimpulse);
1213         ClientState_detach(this);
1214
1215         Portal_ClearAll(this);
1216
1217         Unfreeze(this, false);
1218
1219         RemoveGrapplingHooks(this);
1220
1221         // Here, everything has been done that requires this player to be a client.
1222
1223         this.flags &= ~FL_CLIENT;
1224
1225         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1226         if (this.killindicator) delete(this.killindicator);
1227
1228         IL_EACH(g_counters, it.realowner == this,
1229         {
1230                 delete(it);
1231         });
1232
1233         WaypointSprite_PlayerGone(this);
1234
1235         bot_relinkplayerlist();
1236
1237         strfree(this.clientstatus);
1238         if (this.personal) delete(this.personal);
1239
1240         this.playerid = 0;
1241         ReadyCount();
1242         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1243
1244         player_powerups_remove_all(this); // stop powerup sound
1245
1246         ONREMOVE(this);
1247
1248         if (player_count == 0)
1249                 localcmd("\nsv_hook_lastleave\n");
1250 }
1251
1252 void ChatBubbleThink(entity this)
1253 {
1254         this.nextthink = time;
1255         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1256         {
1257                 if(this.owner) // but why can that ever be NULL?
1258                         this.owner.chatbubbleentity = NULL;
1259                 delete(this);
1260                 return;
1261         }
1262
1263         this.mdl = "";
1264
1265         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1266         {
1267                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1268                         this.mdl = "models/sprites/minigame_busy.iqm";
1269                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1270                         this.mdl = "models/misc/chatbubble.spr";
1271         }
1272
1273         if ( this.model != this.mdl )
1274                 _setmodel(this, this.mdl);
1275
1276 }
1277
1278 void UpdateChatBubble(entity this)
1279 {
1280         if (this.alpha < 0)
1281                 return;
1282         // spawn a chatbubble entity if needed
1283         if (!this.chatbubbleentity)
1284         {
1285                 this.chatbubbleentity = new(chatbubbleentity);
1286                 this.chatbubbleentity.owner = this;
1287                 this.chatbubbleentity.exteriormodeltoclient = this;
1288                 setthink(this.chatbubbleentity, ChatBubbleThink);
1289                 this.chatbubbleentity.nextthink = time;
1290                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1291                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1292                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1293                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1294                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1295                 //this.chatbubbleentity.model = "";
1296                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1297         }
1298 }
1299
1300 void calculate_player_respawn_time(entity this)
1301 {
1302         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1303                 return;
1304
1305         float gametype_setting_tmp;
1306         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1307         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1308         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1309         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1310         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1311         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1312
1313         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1314         if (teamplay)
1315         {
1316                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1317                         if(it.team == this.team)
1318                                 ++pcount;
1319                 });
1320                 if (sdelay_small_count == 0)
1321                         sdelay_small_count = 1;
1322                 if (sdelay_large_count == 0)
1323                         sdelay_large_count = 1;
1324         }
1325         else
1326         {
1327                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1328                         ++pcount;
1329                 });
1330                 if (sdelay_small_count == 0)
1331                 {
1332                         if (IS_INDEPENDENT_PLAYER(this))
1333                         {
1334                                 // Players play independently. No point in requiring enemies.
1335                                 sdelay_small_count = 1;
1336                         }
1337                         else
1338                         {
1339                                 // Players play AGAINST each other. Enemies required.
1340                                 sdelay_small_count = 2;
1341                         }
1342                 }
1343                 if (sdelay_large_count == 0)
1344                 {
1345                         if (IS_INDEPENDENT_PLAYER(this))
1346                         {
1347                                 // Players play independently. No point in requiring enemies.
1348                                 sdelay_large_count = 1;
1349                         }
1350                         else
1351                         {
1352                                 // Players play AGAINST each other. Enemies required.
1353                                 sdelay_large_count = 2;
1354                         }
1355                 }
1356         }
1357
1358         float sdelay;
1359
1360         if (pcount <= sdelay_small_count)
1361                 sdelay = sdelay_small;
1362         else if (pcount >= sdelay_large_count)
1363                 sdelay = sdelay_large;
1364         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1365                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1366
1367         if(waves)
1368                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1369         else
1370                 this.respawn_time = time + sdelay;
1371
1372         if(sdelay < sdelay_max)
1373                 this.respawn_time_max = time + sdelay_max;
1374         else
1375                 this.respawn_time_max = this.respawn_time;
1376
1377         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1378                 this.respawn_countdown = 10; // first number to count down from is 10
1379         else
1380                 this.respawn_countdown = -1; // do not count down
1381
1382         if(autocvar_g_forced_respawn)
1383                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1384 }
1385
1386 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1387 // added to the model skins
1388 /*void UpdateColorModHack()
1389 {
1390         float c;
1391         c = this.clientcolors & 15;
1392         // LordHavoc: only bothering to support white, green, red, yellow, blue
1393              if (!teamplay) this.colormod = '0 0 0';
1394         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1395         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1396         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1397         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1398         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1399         else this.colormod = '1 1 1';
1400 }*/
1401
1402 void respawn(entity this)
1403 {
1404         bool damagedbycontents_prev = this.damagedbycontents;
1405         if(this.alpha >= 0)
1406         {
1407                 if(autocvar_g_respawn_ghosts)
1408                 {
1409                         this.solid = SOLID_NOT;
1410                         this.takedamage = DAMAGE_NO;
1411                         this.damagedbycontents = false;
1412                         set_movetype(this, MOVETYPE_FLY);
1413                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1414                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1415                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1416                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1417                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1418                         if(autocvar_g_respawn_ghosts_time > 0)
1419                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1420                 }
1421                 else
1422                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1423         }
1424
1425         CopyBody(this, 1);
1426         this.damagedbycontents = damagedbycontents_prev;
1427
1428         this.effects |= EF_NODRAW; // prevent another CopyBody
1429         PutClientInServer(this);
1430 }
1431
1432 void play_countdown(entity this, float finished, Sound samp)
1433 {
1434         TC(Sound, samp);
1435         float time_left = finished - time;
1436         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1437                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1438 }
1439
1440 // it removes special powerups not handled by StatusEffects
1441 void player_powerups_remove_all(entity this)
1442 {
1443         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1444         {
1445                 // don't play the poweroff sound when the game restarts or the player disconnects
1446                 if (time > game_starttime + 1 && IS_CLIENT(this)
1447                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1448                 {
1449                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1450                 }
1451                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1452                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1453                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1454         }
1455 }
1456
1457 void player_powerups(entity this)
1458 {
1459         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1460                 this.modelflags |= MF_ROCKET;
1461         else
1462                 this.modelflags &= ~MF_ROCKET;
1463
1464         this.effects &= ~EF_NODEPTHTEST;
1465
1466         if (IS_DEAD(this))
1467                 player_powerups_remove_all(this);
1468
1469         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1470                 return;
1471
1472         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1473         int items_prev = this.items;
1474
1475         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1476         {
1477                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1478                 if (this.items & IT_SUPERWEAPON)
1479                 {
1480                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1481                         {
1482                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1483                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1484                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1485                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1486                         }
1487                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1488                         {
1489                                 // don't let them run out
1490                         }
1491                         else
1492                         {
1493                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1494                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1495                                 {
1496                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1497                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1498                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1499                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1500                                 }
1501                         }
1502                 }
1503                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1504                 {
1505                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1506                         {
1507                                 this.items = this.items | IT_SUPERWEAPON;
1508                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1509                                 {
1510                                         if(!g_cts)
1511                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1512                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1513                                 }
1514                         }
1515                         else
1516                         {
1517                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1518                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1519                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1520                         }
1521                 }
1522                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1523                 {
1524                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1525                 }
1526         }
1527
1528         if(autocvar_g_nodepthtestplayers)
1529                 this.effects = this.effects | EF_NODEPTHTEST;
1530
1531         if(autocvar_g_fullbrightplayers)
1532                 this.effects = this.effects | EF_FULLBRIGHT;
1533
1534         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1535 }
1536
1537 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1538 {
1539         if(current > stable)
1540                 return current;
1541         else if(current > stable - 0.25) // when close enough, "snap"
1542                 return stable;
1543         else
1544                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1545 }
1546
1547 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1548 {
1549         if(current < stable)
1550                 return current;
1551         else if(current < stable + 0.25) // when close enough, "snap"
1552                 return stable;
1553         else
1554                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1555 }
1556
1557 void RotRegen(entity this, Resource res, float limit_mod,
1558         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1559         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1560 {
1561         float old = GetResource(this, res);
1562         float current = old;
1563         if(current > rotstable)
1564         {
1565                 if(rotframetime > 0)
1566                 {
1567                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1568                         current = max(rotstable, current - rotlinear * rotframetime);
1569                 }
1570         }
1571         else if(current < regenstable)
1572         {
1573                 if(regenframetime > 0)
1574                 {
1575                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1576                         current = min(regenstable, current + regenlinear * regenframetime);
1577                 }
1578         }
1579
1580         float limit = GetResourceLimit(this, res) * limit_mod;
1581         if(current > limit)
1582                 current = limit;
1583
1584         if (current != old)
1585                 SetResource(this, res, current);
1586 }
1587
1588 void player_regen(entity this)
1589 {
1590         float max_mod, regen_mod, rot_mod, limit_mod;
1591         max_mod = regen_mod = rot_mod = limit_mod = 1;
1592
1593         float regen_health = autocvar_g_balance_health_regen;
1594         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1595         float regen_health_rot = autocvar_g_balance_health_rot;
1596         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1597         float regen_health_stable = autocvar_g_balance_health_regenstable;
1598         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1599         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1600                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1601         max_mod = M_ARGV(1, float);
1602         regen_mod = M_ARGV(2, float);
1603         rot_mod = M_ARGV(3, float);
1604         limit_mod = M_ARGV(4, float);
1605         regen_health = M_ARGV(5, float);
1606         regen_health_linear = M_ARGV(6, float);
1607         regen_health_rot = M_ARGV(7, float);
1608         regen_health_rotlinear = M_ARGV(8, float);
1609         regen_health_stable = M_ARGV(9, float);
1610         regen_health_rotstable = M_ARGV(10, float);
1611
1612         float rotstable, regenstable, rotframetime, regenframetime;
1613
1614         if(!mutator_returnvalue)
1615         if(!STAT(FROZEN, this))
1616         {
1617                 regenstable = autocvar_g_balance_armor_regenstable;
1618                 rotstable = autocvar_g_balance_armor_rotstable;
1619                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1620                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1621                 RotRegen(this, RES_ARMOR, limit_mod,
1622                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1623                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1624
1625                 // NOTE: max_mod is only applied to health
1626                 regenstable = regen_health_stable * max_mod;
1627                 rotstable = regen_health_rotstable * max_mod;
1628                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1629                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1630                 RotRegen(this, RES_HEALTH, limit_mod,
1631                         regenstable, regen_health, regen_health_linear, regenframetime,
1632                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1633         }
1634
1635         // if player rotted to death...  die!
1636         // check this outside above checks, as player may still be able to rot to death
1637         if(GetResource(this, RES_HEALTH) < 1)
1638         {
1639                 if(this.vehicle)
1640                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1641                 if(this.event_damage)
1642                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1643         }
1644
1645         if (!(this.items & IT_UNLIMITED_AMMO))
1646         {
1647                 regenstable = autocvar_g_balance_fuel_regenstable;
1648                 rotstable = autocvar_g_balance_fuel_rotstable;
1649                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1650                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1651                 RotRegen(this, RES_FUEL, 1,
1652                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1653                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1654         }
1655 }
1656
1657 bool zoomstate_set;
1658 void SetZoomState(entity this, float newzoom)
1659 {
1660         if(newzoom != CS(this).zoomstate)
1661         {
1662                 CS(this).zoomstate = newzoom;
1663                 ClientData_Touch(this);
1664         }
1665         zoomstate_set = true;
1666 }
1667
1668 void GetPressedKeys(entity this)
1669 {
1670         MUTATOR_CALLHOOK(GetPressedKeys, this);
1671         if (game_stopped)
1672         {
1673                 CS(this).pressedkeys = 0;
1674                 STAT(PRESSED_KEYS, this) = 0;
1675                 return;
1676         }
1677
1678         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1679         int keys = STAT(PRESSED_KEYS, this);
1680         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1681         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1682         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1683         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1684
1685         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1686         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1687         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1688         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1689         CS(this).pressedkeys = keys; // store for other users
1690
1691         STAT(PRESSED_KEYS, this) = keys;
1692 }
1693
1694 /*
1695 ======================
1696 spectate mode routines
1697 ======================
1698 */
1699
1700 void SpectateCopy(entity this, entity spectatee)
1701 {
1702         TC(Client, this); TC(Client, spectatee);
1703
1704         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1705         PS(this) = PS(spectatee);
1706         this.armortype = spectatee.armortype;
1707         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1708         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1709         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1710         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1711         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1712         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1713         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1714         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1715         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1716         CS(this).impulse = 0;
1717         this.disableclientprediction = 1; // no need to run prediction on a spectator
1718         this.items = spectatee.items;
1719         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1720         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1721         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1722         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1723         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1724         this.punchangle = spectatee.punchangle;
1725         this.view_ofs = spectatee.view_ofs;
1726         this.velocity = spectatee.velocity;
1727         this.dmg_take = spectatee.dmg_take;
1728         this.dmg_save = spectatee.dmg_save;
1729         this.dmg_inflictor = spectatee.dmg_inflictor;
1730         this.v_angle = spectatee.v_angle;
1731         this.angles = spectatee.v_angle;
1732         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1733         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1734         this.viewloc = spectatee.viewloc;
1735         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1736                 this.fixangle = true;
1737         setorigin(this, spectatee.origin);
1738         setsize(this, spectatee.mins, spectatee.maxs);
1739         SetZoomState(this, CS(spectatee).zoomstate);
1740
1741     anticheat_spectatecopy(this, spectatee);
1742         STAT(HUD, this) = STAT(HUD, spectatee);
1743         if(spectatee.vehicle)
1744     {
1745         this.angles = spectatee.v_angle;
1746
1747         //this.fixangle = false;
1748         //this.velocity = spectatee.vehicle.velocity;
1749         this.vehicle_health = spectatee.vehicle_health;
1750         this.vehicle_shield = spectatee.vehicle_shield;
1751         this.vehicle_energy = spectatee.vehicle_energy;
1752         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1753         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1754         this.vehicle_reload1 = spectatee.vehicle_reload1;
1755         this.vehicle_reload2 = spectatee.vehicle_reload2;
1756
1757         //msg_entity = this;
1758
1759        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1760             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1761            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1762            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1763
1764         //WriteByte (MSG_ONE, SVC_SETVIEW);
1765         //    WriteEntity(MSG_ONE, this);
1766         //makevectors(spectatee.v_angle);
1767         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1768     }
1769 }
1770
1771 bool SpectateUpdate(entity this)
1772 {
1773         if(!this.enemy)
1774                 return false;
1775
1776         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1777         {
1778                 SetSpectatee(this, NULL);
1779                 return false;
1780         }
1781
1782         SpectateCopy(this, this.enemy);
1783
1784         return true;
1785 }
1786
1787 bool SpectateSet(entity this)
1788 {
1789         if(!IS_PLAYER(this.enemy))
1790                 return false;
1791
1792         ClientData_Touch(this.enemy);
1793
1794         msg_entity = this;
1795         WriteByte(MSG_ONE, SVC_SETVIEW);
1796         WriteEntity(MSG_ONE, this.enemy);
1797         set_movetype(this, MOVETYPE_NONE);
1798         accuracy_resend(this);
1799
1800         if(!SpectateUpdate(this))
1801                 PutObserverInServer(this, false, true);
1802
1803         return true;
1804 }
1805
1806 void SetSpectatee_status(entity this, int spectatee_num)
1807 {
1808         int oldspectatee_status = CS(this).spectatee_status;
1809         CS(this).spectatee_status = spectatee_num;
1810
1811         if (CS(this).spectatee_status != oldspectatee_status)
1812         {
1813                 if (STAT(PRESSED_KEYS, this))
1814                 {
1815                         CS(this).pressedkeys = 0;
1816                         STAT(PRESSED_KEYS, this) = 0;
1817                 }
1818                 ClientData_Touch(this);
1819                 if (g_race || g_cts) race_InitSpectator();
1820         }
1821 }
1822
1823 void SetSpectatee(entity this, entity spectatee)
1824 {
1825         if(IS_BOT_CLIENT(this))
1826                 return; // bots abuse .enemy, this code is useless to them
1827
1828         entity old_spectatee = this.enemy;
1829
1830         this.enemy = spectatee;
1831
1832         // WEAPONTODO
1833         // these are required to fix the spectator bug with arc
1834         if(old_spectatee)
1835         {
1836                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1837                 {
1838                         .entity weaponentity = weaponentities[slot];
1839                         if(old_spectatee.(weaponentity).arc_beam)
1840                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1841                 }
1842         }
1843         if(spectatee)
1844         {
1845                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1846                 {
1847                         .entity weaponentity = weaponentities[slot];
1848                         if(spectatee.(weaponentity).arc_beam)
1849                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1850                 }
1851         }
1852
1853         if (spectatee)
1854                 SetSpectatee_status(this, etof(spectatee));
1855
1856         // needed to update spectator list
1857         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1858 }
1859
1860 bool Spectate(entity this, entity pl)
1861 {
1862         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1863                 return false;
1864         pl = M_ARGV(1, entity);
1865
1866         SetSpectatee(this, pl);
1867         return SpectateSet(this);
1868 }
1869
1870 bool SpectateNext(entity this)
1871 {
1872         entity ent = find(this.enemy, classname, STR_PLAYER);
1873
1874         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1875                 ent = M_ARGV(1, entity);
1876         else if (!ent)
1877                 ent = find(ent, classname, STR_PLAYER);
1878
1879         if(ent) { SetSpectatee(this, ent); }
1880
1881         return SpectateSet(this);
1882 }
1883
1884 bool SpectatePrev(entity this)
1885 {
1886         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1887         entity ent = findchain(classname, STR_PLAYER);
1888         if (!ent) // no player
1889                 return false;
1890
1891         entity first = ent;
1892         // skip players until current spectated player
1893         if(this.enemy)
1894         while(ent && ent != this.enemy)
1895                 ent = ent.chain;
1896
1897         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1898         {
1899                 case MUT_SPECPREV_FOUND:
1900                         ent = M_ARGV(1, entity);
1901                         break;
1902                 case MUT_SPECPREV_RETURN:
1903                         return true;
1904                 case MUT_SPECPREV_CONTINUE:
1905                 default:
1906                 {
1907                         if(ent.chain)
1908                                 ent = ent.chain;
1909                         else
1910                                 ent = first;
1911                         break;
1912                 }
1913         }
1914
1915         SetSpectatee(this, ent);
1916         return SpectateSet(this);
1917 }
1918
1919 /*
1920 =============
1921 ShowRespawnCountdown()
1922
1923 Update a respawn countdown display.
1924 =============
1925 */
1926 void ShowRespawnCountdown(entity this)
1927 {
1928         float number;
1929         if(!IS_DEAD(this)) // just respawned?
1930                 return;
1931         else
1932         {
1933                 number = ceil(this.respawn_time - time);
1934                 if(number <= 0)
1935                         return;
1936                 if(number <= this.respawn_countdown)
1937                 {
1938                         this.respawn_countdown = number - 1;
1939                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1940                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1941                 }
1942         }
1943 }
1944
1945 .bool team_selected;
1946 bool ShowTeamSelection(entity this)
1947 {
1948         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1949                 return false;
1950         stuffcmd(this, "menu_showteamselect\n");
1951         return true;
1952 }
1953 void Join(entity this)
1954 {
1955         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1956                 ReadyRestart(true);
1957
1958         TRANSMUTE(Player, this);
1959
1960         if(!this.team_selected)
1961         if(autocvar_g_campaign || autocvar_g_balance_teams)
1962                 TeamBalance_JoinBestTeam(this);
1963
1964         if(autocvar_g_campaign)
1965                 campaign_bots_may_start = true;
1966
1967         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1968
1969         PutClientInServer(this);
1970
1971         if(IS_PLAYER(this))
1972         if(teamplay && this.team != -1)
1973         {
1974         }
1975         else
1976                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1977         this.team_selected = false;
1978 }
1979
1980 int GetPlayerLimit()
1981 {
1982         if(g_duel)
1983                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1984         int player_limit = autocvar_g_maxplayers;
1985         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1986         player_limit = M_ARGV(0, int);
1987         return player_limit;
1988 }
1989
1990 /**
1991  * Determines whether the player is allowed to join. This depends on cvar
1992  * g_maxplayers, if it isn't used this function always return true, otherwise
1993  * it checks whether the number of currently playing players exceeds g_maxplayers.
1994  * @return int number of free slots for players, 0 if none
1995  */
1996 int nJoinAllowed(entity this, entity ignore)
1997 {
1998         if(!ignore)
1999         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2000         // so report 0 free slots if restricted
2001         {
2002                 if(autocvar_g_forced_team_otherwise == "spectate")
2003                         return 0;
2004                 if(autocvar_g_forced_team_otherwise == "spectator")
2005                         return 0;
2006         }
2007
2008         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2009                 return 0; // forced spectators can never join
2010
2011         // TODO simplify this
2012         int totalClients = 0;
2013         int currentlyPlaying = 0;
2014         FOREACH_CLIENT(true, {
2015                 if(it != ignore)
2016                         ++totalClients;
2017                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2018                         ++currentlyPlaying;
2019         });
2020
2021         int player_limit = GetPlayerLimit();
2022
2023         int free_slots = 0;
2024         if (!player_limit)
2025                 free_slots = maxclients - totalClients;
2026         else if(player_limit > 0 && currentlyPlaying < player_limit)
2027                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2028
2029         static float msg_time = 0;
2030         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2031         {
2032                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2033                 msg_time = time + 0.5;
2034         }
2035
2036         return free_slots;
2037 }
2038
2039 void PrintWelcomeMessage(entity this)
2040 {
2041         if(CS(this).motd_actived_time == 0)
2042         {
2043                 if (autocvar_g_campaign) {
2044                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2045                                 CS(this).motd_actived_time = time;
2046                                 SendWelcomemessage(this, false);
2047                         }
2048                 } else {
2049                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2050                                 CS(this).motd_actived_time = time;
2051                                 SendWelcomemessage(this, true);
2052                         }
2053                 }
2054         }
2055         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2056         {
2057                 if (autocvar_g_campaign) {
2058                         if (PHYS_INPUT_BUTTON_INFO(this))
2059                                 CS(this).motd_actived_time = time;
2060                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2061                                 CS(this).motd_actived_time = 0;
2062                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2063                         }
2064                 } else {
2065                         if (PHYS_INPUT_BUTTON_INFO(this))
2066                                 CS(this).motd_actived_time = time;
2067                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2068                                 CS(this).motd_actived_time = 0;
2069                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2070                         }
2071                 }
2072         }
2073         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2074         {
2075                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2076                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2077                 else if (CS(this).motd_actived_time == -2)
2078                 {
2079                         // instantly hide MOTD
2080                         CS(this).motd_actived_time = 0;
2081                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2082                 }
2083                 else if (IS_PLAYER(this) || IS_SPEC(this))
2084                 {
2085                         // FIXME occasionally for some reason MOTD never goes away
2086                         // delay MOTD removal a little bit in the hope it fixes this bug
2087                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2088                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2089                         else //if (CS(this).motd_actived_time < -2)
2090                                 CS(this).motd_actived_time++;
2091                 }
2092         }
2093 }
2094
2095 bool joinAllowed(entity this)
2096 {
2097         if (CS(this).version_mismatch) return false;
2098         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2099         if (!nJoinAllowed(this, this)) return false;
2100         if (teamplay && lockteams) return false;
2101         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2102         if (ShowTeamSelection(this)) return false;
2103         return true;
2104 }
2105
2106 .string shootfromfixedorigin;
2107 .bool dualwielding_prev;
2108 bool PlayerThink(entity this)
2109 {
2110         if (game_stopped || intermission_running) {
2111                 this.modelflags &= ~MF_ROCKET;
2112                 if(intermission_running)
2113                         IntermissionThink(this);
2114                 return false;
2115         }
2116
2117         if (timeout_status == TIMEOUT_ACTIVE) {
2118                 // don't allow the player to turn around while game is paused
2119                 // FIXME turn this into CSQC stuff
2120                 this.v_angle = this.lastV_angle;
2121                 this.angles = this.lastV_angle;
2122                 this.fixangle = true;
2123         }
2124
2125         if (frametime) player_powerups(this);
2126
2127         if (IS_DEAD(this)) {
2128                 if (this.personal && g_race_qualifying) {
2129                         if (time > this.respawn_time) {
2130                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2131                                 respawn(this);
2132                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2133                         }
2134                 } else {
2135                         if (frametime) player_anim(this);
2136
2137                         if (this.respawn_flags & RESPAWN_DENY)
2138                         {
2139                                 STAT(RESPAWN_TIME, this) = 0;
2140                                 return false;
2141                         }
2142
2143                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2144
2145                         switch(this.deadflag)
2146                         {
2147                                 case DEAD_DYING:
2148                                 {
2149                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2150                                                 this.deadflag = DEAD_RESPAWNING;
2151                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2152                                                 this.deadflag = DEAD_DEAD;
2153                                         break;
2154                                 }
2155                                 case DEAD_DEAD:
2156                                 {
2157                                         if (button_pressed)
2158                                                 this.deadflag = DEAD_RESPAWNABLE;
2159                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2160                                                 this.deadflag = DEAD_RESPAWNING;
2161                                         break;
2162                                 }
2163                                 case DEAD_RESPAWNABLE:
2164                                 {
2165                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2166                                                 this.deadflag = DEAD_RESPAWNING;
2167                                         break;
2168                                 }
2169                                 case DEAD_RESPAWNING:
2170                                 {
2171                                         if (time > this.respawn_time)
2172                                         {
2173                                                 this.respawn_time = time + 1; // only retry once a second
2174                                                 this.respawn_time_max = this.respawn_time;
2175                                                 respawn(this);
2176                                         }
2177                                         break;
2178                                 }
2179                         }
2180
2181                         ShowRespawnCountdown(this);
2182
2183                         if (this.respawn_flags & RESPAWN_SILENT)
2184                                 STAT(RESPAWN_TIME, this) = 0;
2185                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2186                         {
2187                                 if (time < this.respawn_time)
2188                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2189                                 else if (this.deadflag != DEAD_RESPAWNING)
2190                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2191                         }
2192                         else
2193                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2194                 }
2195
2196                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2197                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2198                         STAT(RESPAWN_TIME, this) *= -1;
2199
2200                 return false;
2201         }
2202
2203         FixPlayermodel(this);
2204
2205         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2206                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2207                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2208         }
2209
2210         // reset gun alignment when dual wielding status changes
2211         // to ensure guns are always aligned right and left
2212         bool dualwielding = W_DualWielding(this);
2213         if(this.dualwielding_prev != dualwielding)
2214         {
2215                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2216                 this.dualwielding_prev = dualwielding;
2217         }
2218
2219         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2220         //if(frametime)
2221         {
2222                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2223                 {
2224                         .entity weaponentity = weaponentities[slot];
2225                         if(WEP_CVAR(vortex, charge_always))
2226                                 W_Vortex_Charge(this, weaponentity, frametime);
2227                         W_WeaponFrame(this, weaponentity);
2228                 }
2229         }
2230
2231         if (frametime)
2232         {
2233                 // WEAPONTODO: Add a weapon request for this
2234                 // rot vortex charge to the charge limit
2235                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2236                 {
2237                         .entity weaponentity = weaponentities[slot];
2238                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2239                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2240                 }
2241
2242                 player_regen(this);
2243                 player_anim(this);
2244                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2245         }
2246
2247         monsters_setstatus(this);
2248
2249         return true;
2250 }
2251
2252 .bool would_spectate;
2253 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2254 void ObserverOrSpectatorThink(entity this)
2255 {
2256         bool is_spec = IS_SPEC(this);
2257         if ( CS(this).impulse )
2258         {
2259                 int r = MinigameImpulse(this, CS(this).impulse);
2260                 if (!is_spec || r)
2261                         CS(this).impulse = 0;
2262
2263                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2264                 {
2265                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2266                         CS(this).impulse = 0;
2267                         return;
2268                 }
2269         }
2270
2271         if (this.flags & FL_JUMPRELEASED) {
2272                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2273                         this.flags &= ~FL_JUMPRELEASED;
2274                         this.flags |= FL_SPAWNING;
2275                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2276                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2277                         this.flags &= ~FL_JUMPRELEASED;
2278                         if(SpectateNext(this)) {
2279                                 TRANSMUTE(Spectator, this);
2280                         } else if (is_spec) {
2281                                 TRANSMUTE(Observer, this);
2282                                 PutClientInServer(this);
2283                         }
2284                         else
2285                                 this.would_spectate = false; // unable to spectate anyone
2286                         if (is_spec)
2287                                 CS(this).impulse = 0;
2288                 } else if (is_spec) {
2289                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2290                                 this.flags &= ~FL_JUMPRELEASED;
2291                                 if(SpectatePrev(this)) {
2292                                         TRANSMUTE(Spectator, this);
2293                                 } else {
2294                                         TRANSMUTE(Observer, this);
2295                                         PutClientInServer(this);
2296                                 }
2297                                 CS(this).impulse = 0;
2298                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2299                                 this.would_spectate = false;
2300                                 this.flags &= ~FL_JUMPRELEASED;
2301                                 TRANSMUTE(Observer, this);
2302                                 PutClientInServer(this);
2303                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2304                                 PutObserverInServer(this, false, true);
2305                                 this.would_spectate = true;
2306                         }
2307                 }
2308                 else {
2309                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2310                         if (PHYS_INPUT_BUTTON_USE(this))
2311                                 wouldclip = !wouldclip;
2312                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2313                         set_movetype(this, preferred_movetype);
2314                 }
2315         } else { // jump pressed
2316                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2317                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2318                         this.flags |= FL_JUMPRELEASED;
2319                         if(this.flags & FL_SPAWNING)
2320                         {
2321                                 this.flags &= ~FL_SPAWNING;
2322                                 if(joinAllowed(this))
2323                                         Join(this);
2324                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2325                                         CS(this).autojoin_checked = -1;
2326                                 return;
2327                         }
2328                 }
2329                 if(is_spec && !SpectateUpdate(this))
2330                         PutObserverInServer(this, false, true);
2331         }
2332         if (is_spec)
2333                 this.flags |= FL_CLIENT | FL_NOTARGET;
2334 }
2335
2336 void PlayerUseKey(entity this)
2337 {
2338         if (!IS_PLAYER(this))
2339                 return;
2340
2341         if(this.vehicle)
2342         {
2343                 if(!game_stopped)
2344                 {
2345                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2346                         return;
2347                 }
2348         }
2349         else if(autocvar_g_vehicles_enter)
2350         {
2351                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2352                 {
2353                         entity head, closest_target = NULL;
2354                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2355
2356                         while(head) // find the closest acceptable target to enter
2357                         {
2358                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2359                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2360                                 {
2361                                         if(closest_target)
2362                                         {
2363                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2364                                                 { closest_target = head; }
2365                                         }
2366                                         else { closest_target = head; }
2367                                 }
2368
2369                                 head = head.chain;
2370                         }
2371
2372                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2373                 }
2374         }
2375
2376         // a use key was pressed; call handlers
2377         MUTATOR_CALLHOOK(PlayerUseKey, this);
2378 }
2379
2380
2381 /*
2382 =============
2383 PlayerPreThink
2384
2385 Called every frame for each client before the physics are run
2386 =============
2387 */
2388 .float last_vehiclecheck;
2389 void PlayerPreThink (entity this)
2390 {
2391         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2392         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2393
2394         WarpZone_PlayerPhysics_FixVAngle(this);
2395
2396         if (frametime) {
2397                 // physics frames: update anticheat stuff
2398                 anticheat_prethink(this);
2399
2400                 // WORKAROUND: only use dropclient in server frames (frametime set).
2401                 // Never use it in cl_movement frames (frametime zero).
2402                 if (blockSpectators && IS_REAL_CLIENT(this)
2403                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2404                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2405                 {
2406                         if (dropclient_schedule(this))
2407                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2408                 }
2409         }
2410
2411         zoomstate_set = false;
2412
2413         // Check for nameless players
2414         if (this.netname == "" || this.netname != CS(this).netname_previous)
2415         {
2416                 bool assume_unchanged = (CS(this).netname_previous == "");
2417                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2418                 {
2419                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2420                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2421                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2422                         assume_unchanged = false;
2423                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2424                 }
2425                 if (isInvisibleString(this.netname))
2426                 {
2427                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2428                         sprint(this, "Warning: invisible names are not allowed.\n");
2429                         assume_unchanged = false;
2430                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2431                 }
2432                 if (!assume_unchanged && autocvar_sv_eventlog)
2433                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2434                 strcpy(CS(this).netname_previous, this.netname);
2435         }
2436
2437         // version nagging
2438         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2439         CS(this).version_nagtime = 0;
2440         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2441             // git client
2442         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2443             // git server
2444             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2445         } else {
2446             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2447             if (r < 0) { // old client
2448                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2449             } else if (r > 0) { // old server
2450                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2451             }
2452         }
2453     }
2454
2455         // GOD MODE info
2456         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2457         {
2458                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2459                 this.max_armorvalue = 0;
2460         }
2461
2462         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2463         {
2464                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2465                 {
2466                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2467                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2468                         if (this.iceblock)
2469                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2470
2471                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2472                                 Unfreeze(this, false);
2473                 }
2474                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2475                 {
2476                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2477                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2478
2479                         if (GetResource(this, RES_HEALTH) < 1)
2480                         {
2481                                 if (this.vehicle)
2482                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2483                                 if(this.event_damage)
2484                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2485                         }
2486                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2487                                 Unfreeze(this, false);
2488                 }
2489         }
2490
2491         MUTATOR_CALLHOOK(PlayerPreThink, this);
2492
2493         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2494         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2495         {
2496                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2497                 {
2498                         if(!it.owner)
2499                         {
2500                                 if(!it.team || SAME_TEAM(this, it))
2501                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2502                                 else if(autocvar_g_vehicles_steal)
2503                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2504                         }
2505                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2506                         {
2507                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2508                         }
2509                 });
2510
2511                 this.last_vehiclecheck = time + 1;
2512         }
2513
2514         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2515                 PlayerUseKey(this);
2516         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2517
2518         if (IS_REAL_CLIENT(this))
2519                 PrintWelcomeMessage(this);
2520
2521         if (IS_PLAYER(this)) {
2522                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2523                         error("Client can't be spawned as player on connection!");
2524                 if(!PlayerThink(this))
2525                         return;
2526         }
2527         else if (game_stopped || intermission_running) {
2528                 if(intermission_running)
2529                         IntermissionThink(this);
2530                 return;
2531         }
2532         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2533         {
2534                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2535                 CS(this).autojoin_checked = 1;
2536                 // don't do this in ClientConnect
2537                 // many things can go wrong if a client is spawned as player on connection
2538                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2539                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2540                                 && (!teamplay || autocvar_g_balance_teams)))
2541                 {
2542                         if(joinAllowed(this))
2543                                 Join(this);
2544                         return;
2545                 }
2546         }
2547         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2548                 ObserverOrSpectatorThink(this);
2549         }
2550
2551         // WEAPONTODO: Add weapon request for this
2552         if (!zoomstate_set) {
2553                 bool wep_zoomed = false;
2554                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2555                 {
2556                         .entity weaponentity = weaponentities[slot];
2557                         Weapon thiswep = this.(weaponentity).m_weapon;
2558                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2559                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2560                 }
2561                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2562         }
2563
2564         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2565         {
2566                 CS(this).teamkill_soundtime = 0;
2567
2568                 entity e = CS(this).teamkill_soundsource;
2569                 entity oldpusher = e.pusher;
2570                 e.pusher = this;
2571                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2572                 e.pusher = oldpusher;
2573         }
2574
2575         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2576                 CS(this).taunt_soundtime = 0;
2577                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2578         }
2579
2580         target_voicescript_next(this);
2581 }
2582
2583 void DrownPlayer(entity this)
2584 {
2585         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2586                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2587         {
2588                 STAT(AIR_FINISHED, this) = 0;
2589                 return;
2590         }
2591
2592         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2593         {
2594                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2595                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2596                 STAT(AIR_FINISHED, this) = 0;
2597         }
2598         else
2599         {
2600                 if (!STAT(AIR_FINISHED, this))
2601                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2602                 if (STAT(AIR_FINISHED, this) < time)
2603                 {       // drown!
2604                         if (this.pain_finished < time)
2605                         {
2606                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2607                                 this.pain_finished = time + 0.5;
2608                         }
2609                 }
2610         }
2611 }
2612
2613 .bool move_qcphysics;
2614
2615 void Player_Physics(entity this)
2616 {
2617         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2618
2619         if(!this.move_qcphysics)
2620                 return;
2621
2622         if(!frametime && !CS(this).pm_frametime)
2623                 return;
2624
2625         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2626
2627         CS(this).pm_frametime = 0;
2628 }
2629
2630 /*
2631 =============
2632 PlayerPostThink
2633
2634 Called every frame for each client after the physics are run
2635 =============
2636 */
2637 void PlayerPostThink (entity this)
2638 {
2639         Player_Physics(this);
2640
2641         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2642         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2643         if (IS_REAL_CLIENT(this))
2644         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2645         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2646         {
2647                 int totalClients = 0;
2648                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2649                 {
2650                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2651                         if (server_is_dedicated)
2652                         {
2653                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2654                                 {
2655                                         ++totalClients;
2656                                 });
2657                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2658                                         totalClients = 0;
2659                         }
2660                 }
2661                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2662                 {
2663                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2664                         {
2665                                 ++totalClients;
2666                         });
2667                 }
2668
2669                 if (totalClients < autocvar_sv_maxidle_minplayers)
2670                 {
2671                         // idle kick disabled
2672                         CS(this).parm_idlesince = time;
2673                 }
2674                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2675                 {
2676                         if (CS(this).idlekick_lasttimeleft)
2677                         {
2678                                 CS(this).idlekick_lasttimeleft = 0;
2679                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2680                         }
2681                 }
2682                 else
2683                 {
2684                         float maxidle_time = autocvar_sv_maxidle;
2685                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2686                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2687                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2688                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2689                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2690                         {
2691                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2692                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2693                                 else
2694                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2695                         }
2696                         if (timeleft <= 0) {
2697                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2698                                 {
2699                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2700                                         PutObserverInServer(this, true, true);
2701                                 }
2702                                 else
2703                                 {
2704                                         if (dropclient_schedule(this))
2705                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2706                                 }
2707                                 return;
2708                         }
2709                         else if (timeleft <= countdown_time) {
2710                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2711                                         play2(this, SND(TALK2));
2712                                 CS(this).idlekick_lasttimeleft = timeleft;
2713                         }
2714                 }
2715         }
2716
2717         CheatFrame(this);
2718
2719         if (game_stopped)
2720         {
2721                 this.solid = SOLID_NOT;
2722                 this.takedamage = DAMAGE_NO;
2723                 set_movetype(this, MOVETYPE_NONE);
2724                 CS(this).teamkill_complain = 0;
2725                 CS(this).teamkill_soundtime = 0;
2726                 CS(this).teamkill_soundsource = NULL;
2727         }
2728
2729         if (IS_PLAYER(this)) {
2730                 if(this.death_time == time && IS_DEAD(this))
2731                 {
2732                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2733                         // once all the damage events of this frame have been processed with normal size
2734                         this.maxs.z = 5;
2735                         setsize(this, this.mins, this.maxs);
2736                 }
2737                 DrownPlayer(this);
2738                 UpdateChatBubble(this);
2739                 if (CS(this).impulse) ImpulseCommands(this);
2740                 GetPressedKeys(this);
2741                 if (game_stopped)
2742                 {
2743                         CSQCMODEL_AUTOUPDATE(this);
2744                         return;
2745                 }
2746         }
2747         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2748         {
2749                 CS(this).pressedkeys = 0;
2750                 STAT(PRESSED_KEYS, this) = 0;
2751         }
2752
2753         if (this.waypointsprite_attachedforcarrier) {
2754                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2755                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2756         }
2757
2758         CSQCMODEL_AUTOUPDATE(this);
2759 }
2760
2761 // hack to copy the button fields from the client entity to the Client State
2762 void PM_UpdateButtons(entity this, entity store)
2763 {
2764         if(this.impulse)
2765                 store.impulse = this.impulse;
2766         this.impulse = 0;
2767
2768         bool typing = this.buttonchat || this.button12;
2769
2770         store.button0 = (typing) ? 0 : this.button0;
2771         //button1?!
2772         store.button2 = (typing) ? 0 : this.button2;
2773         store.button3 = (typing) ? 0 : this.button3;
2774         store.button4 = this.button4;
2775         store.button5 = (typing) ? 0 : this.button5;
2776         store.button6 = this.button6;
2777         store.button7 = this.button7;
2778         store.button8 = this.button8;
2779         store.button9 = this.button9;
2780         store.button10 = this.button10;
2781         store.button11 = this.button11;
2782         store.button12 = this.button12;
2783         store.button13 = this.button13;
2784         store.button14 = this.button14;
2785         store.button15 = this.button15;
2786         store.button16 = this.button16;
2787         store.buttonuse = this.buttonuse;
2788         store.buttonchat = this.buttonchat;
2789
2790         store.cursor_active = this.cursor_active;
2791         store.cursor_screen = this.cursor_screen;
2792         store.cursor_trace_start = this.cursor_trace_start;
2793         store.cursor_trace_endpos = this.cursor_trace_endpos;
2794         store.cursor_trace_ent = this.cursor_trace_ent;
2795
2796         store.ping = this.ping;
2797         store.ping_packetloss = this.ping_packetloss;
2798         store.ping_movementloss = this.ping_movementloss;
2799
2800         store.v_angle = this.v_angle;
2801         store.movement = this.movement;
2802 }
2803
2804 NET_HANDLE(fpsreport, bool)
2805 {
2806         int fps = ReadShort();
2807         PlayerScore_Set(sender, SP_FPS, fps);
2808         return true;
2809 }