qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         bool recount_ready = false;
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         this.ready = false;
 257                         recount_ready = true;
 258                 }
 259                 entcs_update_players(this);
 260         }
 261
 262         if (use_spawnpoint)
 263         {
 264                 entity spot = SelectSpawnPoint(this, true);
 265                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 266                 this.angles = vec2(spot.angles);
 267                 // offset it so that the spectator spawns higher off the ground, looks better this way
 268                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 269         }
 270         else // change origin to restore previous view origin
 271                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 272         this.fixangle = true;
 273
 274         if (IS_REAL_CLIENT(this))
 275         {
 276                 msg_entity = this;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, this);
 279         }
 280         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 281         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 282         if(!autocvar_g_debug_globalsounds)
 283         {
 284                 // needed for player sounds
 285                 this.model = "";
 286                 FixPlayermodel(this);
 287         }
 288         setmodel(this, MDL_Null);
 289         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 290         this.view_ofs = '0 0 0';
 291
 292         RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         TRANSMUTE(Observer, this);
 307
 308         if(recount_ready) ReadyCount();
 309
 310         WaypointSprite_PlayerDead(this);
 311         accuracy_resend(this);
 312
 313         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 314                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323         STAT(HUD, this) = HUD_NORMAL;
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         player_powerups_remove_all(this);
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406
 407         bot_relinkplayerlist();
 408
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void PutPlayerInServer(entity this)
 536 {
 537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 538
 539         PlayerState_attach(this);
 540         accuracy_resend(this);
 541
 542         if (this.team < 0)
 543                 TeamBalance_JoinBestTeam(this);
 544
 545         entity spot = SelectSpawnPoint(this, false);
 546         if (!spot) {
 547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 548                 return; // spawn failed
 549         }
 550
 551         TRANSMUTE(Player, this);
 552
 553         CS(this).wasplayer = true;
 554         this.iscreature = true;
 555         this.teleportable = TELEPORT_NORMAL;
 556         if(!this.damagedbycontents)
 557                 IL_PUSH(g_damagedbycontents, this);
 558         this.damagedbycontents = true;
 559         set_movetype(this, MOVETYPE_WALK);
 560         this.solid = SOLID_SLIDEBOX;
 561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 562         if (autocvar_g_playerclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 566         this.frags = FRAGS_PLAYER;
 567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 569         if (autocvar__notarget)
 570                 this.flags |= FL_NOTARGET;
 571         this.takedamage = DAMAGE_AIM;
 572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 573
 574         if (warmup_stage) {
 575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, warmup_start_health);
 582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 584         } else {
 585                 SetResource(this, RES_SHELLS, start_ammo_shells);
 586                 SetResource(this, RES_BULLETS, start_ammo_nails);
 587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 588                 SetResource(this, RES_CELLS, start_ammo_cells);
 589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 590                 SetResource(this, RES_FUEL, start_ammo_fuel);
 591                 SetResource(this, RES_HEALTH, start_health);
 592                 SetResource(this, RES_ARMOR, start_armorvalue);
 593                 STAT(WEAPONS, this) = start_weapons;
 594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 595                 {
 596                         GiveRandomWeapons(this, random_start_weapons_count,
 597                                 autocvar_g_random_start_weapons, random_start_ammo);
 598                 }
 599         }
 600         SetSpectatee_status(this, 0);
 601
 602         PS(this).dual_weapons = '0 0 0';
 603
 604         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 605                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 606
 607         this.items = start_items;
 608
 609         float shieldtime = time + autocvar_g_spawnshieldtime;
 610
 611         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 612         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 613         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 614         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 615         if (!sv_ready_restart_after_countdown && time < game_starttime)
 616         {
 617                 float f = game_starttime - time;
 618                 shieldtime += f;
 619                 this.pauserotarmor_finished += f;
 620                 this.pauserothealth_finished += f;
 621                 this.pauseregen_finished += f;
 622         }
 623
 624         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 625
 626         this.damageforcescale = autocvar_g_player_damageforcescale;
 627         this.death_time = 0;
 628         this.respawn_flags = 0;
 629         this.respawn_time = 0;
 630         STAT(RESPAWN_TIME, this) = 0;
 631         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 632         this.fade_time = 0;
 633         this.pain_finished = 0;
 634         this.pushltime = 0;
 635         setthink(this, func_null); // players have no think function
 636         this.nextthink = 0;
 637         this.dmg_team = 0;
 638         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 639
 640         this.deadflag = DEAD_NO;
 641
 642         this.angles = spot.angles;
 643         this.angles_z = 0; // never spawn tilted even if the spot says to
 644         if (IS_BOT_CLIENT(this))
 645         {
 646                 this.v_angle = this.angles;
 647                 bot_aim_reset(this);
 648         }
 649         this.fixangle = true; // turn this way immediately
 650         this.oldvelocity = this.velocity = '0 0 0';
 651         this.avelocity = '0 0 0';
 652         this.punchangle = '0 0 0';
 653         this.punchvector = '0 0 0';
 654
 655         STAT(REVIVE_PROGRESS, this) = 0;
 656         this.revival_time = 0;
 657
 658         STAT(AIR_FINISHED, this) = 0;
 659         this.waterlevel = WATERLEVEL_NONE;
 660         this.watertype = CONTENT_EMPTY;
 661
 662         entity spawnevent = new_pure(spawnevent);
 663         spawnevent.owner = this;
 664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665
 666         // Cut off any still running player sounds.
 667         stopsound(this, CH_PLAYER_SINGLE);
 668
 669         this.model = "";
 670         FixPlayermodel(this);
 671         this.drawonlytoclient = NULL;
 672
 673         this.viewloc = NULL;
 674
 675         for(int slot = 0; slot < MAX_AXH; ++slot)
 676         {
 677                 entity axh = this.(AuxiliaryXhair[slot]);
 678                 this.(AuxiliaryXhair[slot]) = NULL;
 679
 680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 681                         delete(axh);
 682         }
 683
 684         this.spawnpoint_targ = NULL;
 685
 686         UNSET_DUCKED(this);
 687         this.view_ofs = STAT(PL_VIEW_OFS, this);
 688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 689         this.spawnorigin = spot.origin;
 690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 691         // don't reset back to last position, even if new position is stuck in solid
 692         this.oldorigin = this.origin;
 693         if(this.conveyor)
 694                 IL_REMOVE(g_conveyed, this);
 695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 696         if(this.swampslug)
 697                 IL_REMOVE(g_swamped, this);
 698         this.swampslug = NULL;
 699         this.swamp_interval = 0;
 700         if(this.ladder_entity)
 701                 IL_REMOVE(g_ladderents, this);
 702         this.ladder_entity = NULL;
 703         IL_EACH(g_counters, it.realowner == this,
 704         {
 705                 delete(it);
 706         });
 707         STAT(HUD, this) = HUD_NORMAL;
 708
 709         this.event_damage = PlayerDamage;
 710         this.event_heal = PlayerHeal;
 711
 712         this.draggable = func_null;
 713
 714         if(!this.bot_attack)
 715                 IL_PUSH(g_bot_targets, this);
 716         this.bot_attack = true;
 717         if(!this.monster_attack)
 718                 IL_PUSH(g_monster_targets, this);
 719         this.monster_attack = true;
 720         navigation_dynamicgoal_init(this, false);
 721
 722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 723
 724         // player was spectator
 725         if (CS(this).killcount == FRAGS_SPECTATOR) {
 726                 PlayerScore_Clear(this);
 727                 CS(this).killcount = 0;
 728                 CS(this).startplaytime = time;
 729         }
 730
 731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 732         {
 733                 .entity weaponentity = weaponentities[slot];
 734                 CL_SpawnWeaponentity(this, weaponentity);
 735         }
 736         this.alpha = default_player_alpha;
 737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 738         this.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740         this.speedrunning = false;
 741
 742         this.counter_cnt = 0;
 743         this.fragsfilter_cnt = 0;
 744
 745         target_voicescript_clear(this);
 746
 747         // reset fields the weapons may use
 748         FOREACH(Weapons, true, {
 749                 it.wr_resetplayer(it, this);
 750                         // reload all reloadable weapons
 751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753                         {
 754                                 .entity weaponentity = weaponentities[slot];
 755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 756                         }
 757                 }
 758         });
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763
 764         {
 765                 string s = spot.target;
 766                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 767                         spot.target = string_null;
 768                 SUB_UseTargets(spot, this, NULL);
 769                 if(g_assault || g_race)
 770                         spot.target = s;
 771         }
 772
 773         if (autocvar_spawn_debug)
 774         {
 775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 777         }
 778
 779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780         {
 781                 .entity weaponentity = weaponentities[slot];
 782                 entity w_ent = this.(weaponentity);
 783                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 784                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 785                 else
 786                         w_ent.m_switchweapon = WEP_Null;
 787                 w_ent.m_weapon = WEP_Null;
 788                 w_ent.weaponname = "";
 789                 w_ent.m_switchingweapon = WEP_Null;
 790                 w_ent.cnt = -1;
 791         }
 792
 793         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 794
 795         if (CS(this).impulse) ImpulseCommands(this);
 796
 797         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 W_WeaponFrame(this, weaponentity);
 802         }
 803
 804         if (!warmup_stage && !this.alivetime)
 805                 this.alivetime = time;
 806
 807         antilag_clear(this, CS(this));
 808 }
 809
 810 /** Called when a client spawns in the server */
 811 void PutClientInServer(entity this)
 812 {
 813         if (IS_BOT_CLIENT(this)) {
 814                 TRANSMUTE(Player, this);
 815         } else if (IS_REAL_CLIENT(this)) {
 816                 msg_entity = this;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, this);
 819         }
 820         if (game_stopped)
 821                 TRANSMUTE(Observer, this);
 822
 823         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this, false, use_spawnpoint);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837
 838         bot_relinkplayerlist();
 839 }
 840
 841 // TODO do we need all these fields, or should we stop autodetecting runtime
 842 // changes and just have a console command to update this?
 843 bool ClientInit_SendEntity(entity this, entity to, int sf)
 844 {
 845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 846         return = true;
 847         msg_entity = to;
 848         // MSG_INIT replacement
 849         // TODO: make easier to use
 850         Registry_send_all();
 851         W_PROP_reload(MSG_ONE, to);
 852         ClientInit_misc(this);
 853         MUTATOR_CALLHOOK(Ent_Init);
 854 }
 855 void ClientInit_misc(entity this)
 856 {
 857         int channel = MSG_ONE;
 858         WriteHeader(channel, ENT_CLIENT_INIT);
 859         WriteByte(channel, g_nexball_meter_period * 32);
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 868
 869         if(autocvar_sv_foginterval && world.fog != "")
 870                 WriteString(channel, world.fog);
 871         else
 872                 WriteString(channel, "");
 873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 875         WriteByte(channel, serverflags);
 876         WriteCoord(channel, autocvar_g_trueaim_minrange);
 877 }
 878
 879 void ClientInit_CheckUpdate(entity this)
 880 {
 881         this.nextthink = time;
 882         if(this.count != autocvar_g_balance_armor_blockpercent)
 883         {
 884                 this.count = autocvar_g_balance_armor_blockpercent;
 885                 this.SendFlags |= 1;
 886         }
 887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 888         {
 889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 890                 this.SendFlags |= 1;
 891         }
 892 }
 893
 894 void ClientInit_Spawn()
 895 {
 896         entity e = new_pure(clientinit);
 897         setthink(e, ClientInit_CheckUpdate);
 898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 899
 900         ClientInit_CheckUpdate(e);
 901 }
 902
 903 /*
 904 =============
 905 SetNewParms
 906 =============
 907 */
 908 void SetNewParms ()
 909 {
 910         // initialize parms for a new player
 911         parm1 = -(86400 * 366);
 912
 913         MUTATOR_CALLHOOK(SetNewParms);
 914 }
 915
 916 /*
 917 =============
 918 SetChangeParms
 919 =============
 920 */
 921 void SetChangeParms (entity this)
 922 {
 923         // save parms for level change
 924         parm1 = CS(this).parm_idlesince - time;
 925
 926         MUTATOR_CALLHOOK(SetChangeParms);
 927 }
 928
 929 /*
 930 =============
 931 DecodeLevelParms
 932 =============
 933 */
 934 void DecodeLevelParms(entity this)
 935 {
 936         // load parms
 937         CS(this).parm_idlesince = parm1;
 938         if (CS(this).parm_idlesince == -(86400 * 366))
 939                 CS(this).parm_idlesince = time;
 940
 941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 943
 944         MUTATOR_CALLHOOK(DecodeLevelParms);
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 957
 958         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 959
 960         MUTATOR_CALLHOOK(FixClientCvars, e);
 961 }
 962
 963 bool findinlist_abbrev(string tofind, string list)
 964 {
 965         if(list == "" || tofind == "")
 966                 return false; // empty list or search, just return
 967
 968         // this function allows abbreviated strings!
 969         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 970         {
 971                 return true;
 972         });
 973
 974         return false;
 975 }
 976
 977 bool PlayerInIPList(entity p, string iplist)
 978 {
 979         // some safety checks (never allow local?)
 980         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 981                 return false;
 982
 983         return findinlist_abbrev(p.netaddress, iplist);
 984 }
 985
 986 bool PlayerInIDList(entity p, string idlist)
 987 {
 988         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 989         if(!p.crypto_idfp)
 990                 return false;
 991
 992         return findinlist_abbrev(p.crypto_idfp, idlist);
 993 }
 994
 995 bool PlayerInList(entity player, string list)
 996 {
 997         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 998 }
 999
1000 #ifdef DP_EXT_PRECONNECT
1001 /*
1002 =============
1003 ClientPreConnect
1004
1005 Called once (not at each match start) when a client begins a connection to the server
1006 =============
1007 */
1008 void ClientPreConnect(entity this)
1009 {
1010         if(autocvar_sv_eventlog)
1011         {
1012                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1013                         this.playerid,
1014                         etof(this),
1015                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1016                 ));
1017         }
1018 }
1019 #endif
1020
1021 void SendWelcomemessage(entity this, bool force_centerprint)
1022 {
1023         msg_entity = this;
1024         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1025         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1026 }
1027
1028 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1029 {
1030         WriteByte(msg_type, boolean(autocvar_g_campaign));
1031         if (boolean(autocvar_g_campaign))
1032         {
1033                 WriteString(msg_type, Campaign_GetTitle());
1034                 WriteByte(msg_type, Campaign_GetLevelNum());
1035                 WriteString(msg_type, Campaign_GetMessage());
1036                 return;
1037         }
1038         WriteByte(msg_type, force_centerprint);
1039         WriteString(msg_type, autocvar_hostname);
1040         WriteString(msg_type, autocvar_g_xonoticversion);
1041         WriteByte(msg_type, CS(this).version_mismatch);
1042         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1043
1044         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1045         string modifications = M_ARGV(0, string);
1046
1047         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1048                 modifications = strcat(modifications, ", No start weapons");
1049         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1050                 modifications = strcat(modifications, ", Low gravity");
1051         if(g_weapon_stay && !g_cts)
1052                 modifications = strcat(modifications, ", Weapons stay");
1053         if(autocvar_g_jetpack)
1054                 modifications = strcat(modifications, ", Jetpack");
1055         modifications = substring(modifications, 2, strlen(modifications) - 2);
1056
1057         WriteString(msg_type, modifications);
1058
1059         WriteString(msg_type, g_weaponarena_list);
1060
1061         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1062         {
1063                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1064                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1065         }
1066
1067         WriteString(msg_type, cache_mutatormsg);
1068
1069         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1070 }
1071
1072 /**
1073 =============
1074 ClientConnect
1075
1076 Called when a client connects to the server
1077 =============
1078 */
1079 void ClientConnect(entity this)
1080 {
1081         if (Ban_MaybeEnforceBanOnce(this)) return;
1082         assert(!IS_CLIENT(this), return);
1083         this.flags |= FL_CLIENT;
1084         assert(player_count >= 0, player_count = 0);
1085
1086         TRANSMUTE(Client, this);
1087         CS(this).version_nagtime = time + 10 + random() * 10;
1088
1089         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1090
1091         bot_clientconnect(this);
1092
1093         Player_DetermineForcedTeam(this);
1094
1095         TRANSMUTE(Observer, this);
1096
1097         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1098
1099         // always track bots, don't ask for cl_allow_uidtracking
1100         if (IS_BOT_CLIENT(this))
1101                 PlayerStats_GameReport_AddPlayer(this);
1102         else
1103                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1104
1105         if (autocvar_sv_eventlog)
1106                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1107
1108         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1109
1110         stuffcmd(this, clientstuff, "\n");
1111         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1112
1113         FixClientCvars(this);
1114
1115         // get version info from player
1116         stuffcmd(this, "cmd clientversion $gameversion\n");
1117
1118         // notify about available teams
1119         if (teamplay)
1120         {
1121                 entity balance = TeamBalance_CheckAllowedTeams(this);
1122                 int t = TeamBalance_GetAllowedTeams(balance);
1123                 TeamBalance_Destroy(balance);
1124                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1125         }
1126         else
1127         {
1128                 stuffcmd(this, "set _teams_available 0\n");
1129         }
1130
1131         bot_relinkplayerlist();
1132
1133         CS(this).spectatortime = time;
1134         if (blockSpectators)
1135         {
1136                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1137         }
1138
1139         CS(this).jointime = time;
1140
1141         if (IS_REAL_CLIENT(this))
1142         {
1143                 if (g_weaponarena_weapons == WEPSET(TUBA))
1144                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1145         }
1146
1147         if (!autocvar_sv_foginterval && world.fog != "")
1148                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1149
1150         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1151                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1152                         send_CSQC_teamnagger();
1153
1154         CSQCMODEL_AUTOINIT(this);
1155
1156         CS(this).model_randomizer = random();
1157
1158         if (IS_REAL_CLIENT(this))
1159                 sv_notice_join(this);
1160
1161         this.move_qcphysics = autocvar_sv_qcphysics;
1162
1163         // update physics stats (players can spawn before physics runs)
1164         Physics_UpdateStats(this);
1165
1166         IL_EACH(g_initforplayer, it.init_for_player, {
1167                 it.init_for_player(it, this);
1168         });
1169
1170         Handicap_Initialize(this);
1171
1172         MUTATOR_CALLHOOK(ClientConnect, this);
1173
1174         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1175                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1176 }
1177 /*
1178 =============
1179 ClientDisconnect
1180
1181 Called when a client disconnects from the server
1182 =============
1183 */
1184 .entity chatbubbleentity;
1185 void player_powerups_remove_all(entity this);
1186
1187 void ClientDisconnect(entity this)
1188 {
1189         assert(IS_CLIENT(this), return);
1190
1191         PlayerStats_GameReport_FinalizePlayer(this);
1192         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1193         if (CS(this).active_minigame) part_minigame(this);
1194         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1195
1196         if (autocvar_sv_eventlog)
1197                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1198
1199         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1200
1201         if(IS_SPEC(this))
1202                 SetSpectatee(this, NULL);
1203
1204         MUTATOR_CALLHOOK(ClientDisconnect, this);
1205
1206         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1207         strfree(CS_CVAR(this).weaponorder_byimpulse);
1208         ClientState_detach(this);
1209
1210         Portal_ClearAll(this);
1211
1212         Unfreeze(this, false);
1213
1214         RemoveGrapplingHooks(this);
1215
1216         // Here, everything has been done that requires this player to be a client.
1217
1218         this.flags &= ~FL_CLIENT;
1219
1220         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1221         if (this.killindicator) delete(this.killindicator);
1222
1223         IL_EACH(g_counters, it.realowner == this,
1224         {
1225                 delete(it);
1226         });
1227
1228         WaypointSprite_PlayerGone(this);
1229
1230         bot_relinkplayerlist();
1231
1232         strfree(this.clientstatus);
1233         if (this.personal) delete(this.personal);
1234
1235         this.playerid = 0;
1236         ReadyCount();
1237         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1238
1239         player_powerups_remove_all(this); // stop powerup sound
1240
1241         ONREMOVE(this);
1242 }
1243
1244 void ChatBubbleThink(entity this)
1245 {
1246         this.nextthink = time;
1247         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1248         {
1249                 if(this.owner) // but why can that ever be NULL?
1250                         this.owner.chatbubbleentity = NULL;
1251                 delete(this);
1252                 return;
1253         }
1254
1255         this.mdl = "";
1256
1257         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1258         {
1259                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1260                         this.mdl = "models/sprites/minigame_busy.iqm";
1261                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1262                         this.mdl = "models/misc/chatbubble.spr";
1263         }
1264
1265         if ( this.model != this.mdl )
1266                 _setmodel(this, this.mdl);
1267
1268 }
1269
1270 void UpdateChatBubble(entity this)
1271 {
1272         if (this.alpha < 0)
1273                 return;
1274         // spawn a chatbubble entity if needed
1275         if (!this.chatbubbleentity)
1276         {
1277                 this.chatbubbleentity = new(chatbubbleentity);
1278                 this.chatbubbleentity.owner = this;
1279                 this.chatbubbleentity.exteriormodeltoclient = this;
1280                 setthink(this.chatbubbleentity, ChatBubbleThink);
1281                 this.chatbubbleentity.nextthink = time;
1282                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1283                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1284                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1285                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1286                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1287                 //this.chatbubbleentity.model = "";
1288                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1289         }
1290 }
1291
1292 void calculate_player_respawn_time(entity this)
1293 {
1294         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1295                 return;
1296
1297         float gametype_setting_tmp;
1298         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1299         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1300         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1301         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1302         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1303         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1304
1305         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1306         if (teamplay)
1307         {
1308                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1309                         if(it.team == this.team)
1310                                 ++pcount;
1311                 });
1312                 if (sdelay_small_count == 0)
1313                         sdelay_small_count = 1;
1314                 if (sdelay_large_count == 0)
1315                         sdelay_large_count = 1;
1316         }
1317         else
1318         {
1319                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1320                         ++pcount;
1321                 });
1322                 if (sdelay_small_count == 0)
1323                 {
1324                         if (IS_INDEPENDENT_PLAYER(this))
1325                         {
1326                                 // Players play independently. No point in requiring enemies.
1327                                 sdelay_small_count = 1;
1328                         }
1329                         else
1330                         {
1331                                 // Players play AGAINST each other. Enemies required.
1332                                 sdelay_small_count = 2;
1333                         }
1334                 }
1335                 if (sdelay_large_count == 0)
1336                 {
1337                         if (IS_INDEPENDENT_PLAYER(this))
1338                         {
1339                                 // Players play independently. No point in requiring enemies.
1340                                 sdelay_large_count = 1;
1341                         }
1342                         else
1343                         {
1344                                 // Players play AGAINST each other. Enemies required.
1345                                 sdelay_large_count = 2;
1346                         }
1347                 }
1348         }
1349
1350         float sdelay;
1351
1352         if (pcount <= sdelay_small_count)
1353                 sdelay = sdelay_small;
1354         else if (pcount >= sdelay_large_count)
1355                 sdelay = sdelay_large;
1356         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1357                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1358
1359         if(waves)
1360                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1361         else
1362                 this.respawn_time = time + sdelay;
1363
1364         if(sdelay < sdelay_max)
1365                 this.respawn_time_max = time + sdelay_max;
1366         else
1367                 this.respawn_time_max = this.respawn_time;
1368
1369         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1370                 this.respawn_countdown = 10; // first number to count down from is 10
1371         else
1372                 this.respawn_countdown = -1; // do not count down
1373
1374         if(autocvar_g_forced_respawn)
1375                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1376 }
1377
1378 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1379 // added to the model skins
1380 /*void UpdateColorModHack()
1381 {
1382         float c;
1383         c = this.clientcolors & 15;
1384         // LordHavoc: only bothering to support white, green, red, yellow, blue
1385              if (!teamplay) this.colormod = '0 0 0';
1386         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1387         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1388         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1389         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1390         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1391         else this.colormod = '1 1 1';
1392 }*/
1393
1394 void respawn(entity this)
1395 {
1396         bool damagedbycontents_prev = this.damagedbycontents;
1397         if(this.alpha >= 0)
1398         {
1399                 if(autocvar_g_respawn_ghosts)
1400                 {
1401                         this.solid = SOLID_NOT;
1402                         this.takedamage = DAMAGE_NO;
1403                         this.damagedbycontents = false;
1404                         set_movetype(this, MOVETYPE_FLY);
1405                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1406                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1407                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1408                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1409                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1410                         if(autocvar_g_respawn_ghosts_time > 0)
1411                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1412                 }
1413                 else
1414                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1415         }
1416
1417         CopyBody(this, 1);
1418         this.damagedbycontents = damagedbycontents_prev;
1419
1420         this.effects |= EF_NODRAW; // prevent another CopyBody
1421         PutClientInServer(this);
1422 }
1423
1424 void play_countdown(entity this, float finished, Sound samp)
1425 {
1426         TC(Sound, samp);
1427         float time_left = finished - time;
1428         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1429                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1430 }
1431
1432 // it removes special powerups not handled by StatusEffects
1433 void player_powerups_remove_all(entity this)
1434 {
1435         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1436         {
1437                 // don't play the poweroff sound when the game restarts or the player disconnects
1438                 if (time > game_starttime + 1 && IS_CLIENT(this)
1439                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1440                 {
1441                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1442                 }
1443                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1444                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1445                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1446         }
1447 }
1448
1449 void player_powerups(entity this)
1450 {
1451         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1452                 this.modelflags |= MF_ROCKET;
1453         else
1454                 this.modelflags &= ~MF_ROCKET;
1455
1456         this.effects &= ~EF_NODEPTHTEST;
1457
1458         if (IS_DEAD(this))
1459                 player_powerups_remove_all(this);
1460
1461         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1462                 return;
1463
1464         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1465         int items_prev = this.items;
1466
1467         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1468         {
1469                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1470                 if (this.items & IT_SUPERWEAPON)
1471                 {
1472                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1473                         {
1474                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1475                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1476                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1477                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1478                         }
1479                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1480                         {
1481                                 // don't let them run out
1482                         }
1483                         else
1484                         {
1485                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1486                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1487                                 {
1488                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1489                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1490                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1491                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1492                                 }
1493                         }
1494                 }
1495                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1496                 {
1497                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1498                         {
1499                                 this.items = this.items | IT_SUPERWEAPON;
1500                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1501                                 {
1502                                         if(!g_cts)
1503                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1504                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1505                                 }
1506                         }
1507                         else
1508                         {
1509                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1510                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1511                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1512                         }
1513                 }
1514                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1515                 {
1516                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1517                 }
1518         }
1519
1520         if(autocvar_g_nodepthtestplayers)
1521                 this.effects = this.effects | EF_NODEPTHTEST;
1522
1523         if(autocvar_g_fullbrightplayers)
1524                 this.effects = this.effects | EF_FULLBRIGHT;
1525
1526         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1527 }
1528
1529 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1530 {
1531         if(current > stable)
1532                 return current;
1533         else if(current > stable - 0.25) // when close enough, "snap"
1534                 return stable;
1535         else
1536                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1537 }
1538
1539 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1540 {
1541         if(current < stable)
1542                 return current;
1543         else if(current < stable + 0.25) // when close enough, "snap"
1544                 return stable;
1545         else
1546                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1547 }
1548
1549 void RotRegen(entity this, Resource res, float limit_mod,
1550         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1551         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1552 {
1553         float old = GetResource(this, res);
1554         float current = old;
1555         if(current > rotstable)
1556         {
1557                 if(rotframetime > 0)
1558                 {
1559                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1560                         current = max(rotstable, current - rotlinear * rotframetime);
1561                 }
1562         }
1563         else if(current < regenstable)
1564         {
1565                 if(regenframetime > 0)
1566                 {
1567                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1568                         current = min(regenstable, current + regenlinear * regenframetime);
1569                 }
1570         }
1571
1572         float limit = GetResourceLimit(this, res) * limit_mod;
1573         if(current > limit)
1574                 current = limit;
1575
1576         if (current != old)
1577                 SetResource(this, res, current);
1578 }
1579
1580 void player_regen(entity this)
1581 {
1582         float max_mod, regen_mod, rot_mod, limit_mod;
1583         max_mod = regen_mod = rot_mod = limit_mod = 1;
1584
1585         float regen_health = autocvar_g_balance_health_regen;
1586         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1587         float regen_health_rot = autocvar_g_balance_health_rot;
1588         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1589         float regen_health_stable = autocvar_g_balance_health_regenstable;
1590         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1591         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1592                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1593         max_mod = M_ARGV(1, float);
1594         regen_mod = M_ARGV(2, float);
1595         rot_mod = M_ARGV(3, float);
1596         limit_mod = M_ARGV(4, float);
1597         regen_health = M_ARGV(5, float);
1598         regen_health_linear = M_ARGV(6, float);
1599         regen_health_rot = M_ARGV(7, float);
1600         regen_health_rotlinear = M_ARGV(8, float);
1601         regen_health_stable = M_ARGV(9, float);
1602         regen_health_rotstable = M_ARGV(10, float);
1603
1604         float rotstable, regenstable, rotframetime, regenframetime;
1605
1606         if(!mutator_returnvalue)
1607         if(!STAT(FROZEN, this))
1608         {
1609                 regenstable = autocvar_g_balance_armor_regenstable;
1610                 rotstable = autocvar_g_balance_armor_rotstable;
1611                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1612                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1613                 RotRegen(this, RES_ARMOR, limit_mod,
1614                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1615                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1616
1617                 // NOTE: max_mod is only applied to health
1618                 regenstable = regen_health_stable * max_mod;
1619                 rotstable = regen_health_rotstable * max_mod;
1620                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1621                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1622                 RotRegen(this, RES_HEALTH, limit_mod,
1623                         regenstable, regen_health, regen_health_linear, regenframetime,
1624                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1625         }
1626
1627         // if player rotted to death...  die!
1628         // check this outside above checks, as player may still be able to rot to death
1629         if(GetResource(this, RES_HEALTH) < 1)
1630         {
1631                 if(this.vehicle)
1632                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1633                 if(this.event_damage)
1634                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1635         }
1636
1637         if (!(this.items & IT_UNLIMITED_AMMO))
1638         {
1639                 regenstable = autocvar_g_balance_fuel_regenstable;
1640                 rotstable = autocvar_g_balance_fuel_rotstable;
1641                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1642                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1643                 RotRegen(this, RES_FUEL, 1,
1644                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1645                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1646         }
1647 }
1648
1649 bool zoomstate_set;
1650 void SetZoomState(entity this, float newzoom)
1651 {
1652         if(newzoom != CS(this).zoomstate)
1653         {
1654                 CS(this).zoomstate = newzoom;
1655                 ClientData_Touch(this);
1656         }
1657         zoomstate_set = true;
1658 }
1659
1660 void GetPressedKeys(entity this)
1661 {
1662         MUTATOR_CALLHOOK(GetPressedKeys, this);
1663         if (game_stopped)
1664         {
1665                 CS(this).pressedkeys = 0;
1666                 STAT(PRESSED_KEYS, this) = 0;
1667                 return;
1668         }
1669
1670         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1671         int keys = STAT(PRESSED_KEYS, this);
1672         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1673         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1674         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1675         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1676
1677         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1678         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1679         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1680         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1681         CS(this).pressedkeys = keys; // store for other users
1682
1683         STAT(PRESSED_KEYS, this) = keys;
1684 }
1685
1686 /*
1687 ======================
1688 spectate mode routines
1689 ======================
1690 */
1691
1692 void SpectateCopy(entity this, entity spectatee)
1693 {
1694         TC(Client, this); TC(Client, spectatee);
1695
1696         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1697         PS(this) = PS(spectatee);
1698         this.armortype = spectatee.armortype;
1699         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1700         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1701         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1702         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1703         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1704         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1705         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1706         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1707         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1708         CS(this).impulse = 0;
1709         this.disableclientprediction = 1; // no need to run prediction on a spectator
1710         this.items = spectatee.items;
1711         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1712         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1713         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1714         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1715         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1716         this.punchangle = spectatee.punchangle;
1717         this.view_ofs = spectatee.view_ofs;
1718         this.velocity = spectatee.velocity;
1719         this.dmg_take = spectatee.dmg_take;
1720         this.dmg_save = spectatee.dmg_save;
1721         this.dmg_inflictor = spectatee.dmg_inflictor;
1722         this.v_angle = spectatee.v_angle;
1723         this.angles = spectatee.v_angle;
1724         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1725         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1726         this.viewloc = spectatee.viewloc;
1727         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1728                 this.fixangle = true;
1729         setorigin(this, spectatee.origin);
1730         setsize(this, spectatee.mins, spectatee.maxs);
1731         SetZoomState(this, CS(spectatee).zoomstate);
1732
1733     anticheat_spectatecopy(this, spectatee);
1734         STAT(HUD, this) = STAT(HUD, spectatee);
1735         if(spectatee.vehicle)
1736     {
1737         this.angles = spectatee.v_angle;
1738
1739         //this.fixangle = false;
1740         //this.velocity = spectatee.vehicle.velocity;
1741         this.vehicle_health = spectatee.vehicle_health;
1742         this.vehicle_shield = spectatee.vehicle_shield;
1743         this.vehicle_energy = spectatee.vehicle_energy;
1744         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1745         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1746         this.vehicle_reload1 = spectatee.vehicle_reload1;
1747         this.vehicle_reload2 = spectatee.vehicle_reload2;
1748
1749         //msg_entity = this;
1750
1751        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1752             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1753            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1754            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1755
1756         //WriteByte (MSG_ONE, SVC_SETVIEW);
1757         //    WriteEntity(MSG_ONE, this);
1758         //makevectors(spectatee.v_angle);
1759         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1760     }
1761 }
1762
1763 bool SpectateUpdate(entity this)
1764 {
1765         if(!this.enemy)
1766                 return false;
1767
1768         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1769         {
1770                 SetSpectatee(this, NULL);
1771                 return false;
1772         }
1773
1774         SpectateCopy(this, this.enemy);
1775
1776         return true;
1777 }
1778
1779 bool SpectateSet(entity this)
1780 {
1781         if(!IS_PLAYER(this.enemy))
1782                 return false;
1783
1784         ClientData_Touch(this.enemy);
1785
1786         msg_entity = this;
1787         WriteByte(MSG_ONE, SVC_SETVIEW);
1788         WriteEntity(MSG_ONE, this.enemy);
1789         set_movetype(this, MOVETYPE_NONE);
1790         accuracy_resend(this);
1791
1792         if(!SpectateUpdate(this))
1793                 PutObserverInServer(this, false, true);
1794
1795         return true;
1796 }
1797
1798 void SetSpectatee_status(entity this, int spectatee_num)
1799 {
1800         int oldspectatee_status = CS(this).spectatee_status;
1801         CS(this).spectatee_status = spectatee_num;
1802
1803         if (CS(this).spectatee_status != oldspectatee_status)
1804         {
1805                 if (STAT(PRESSED_KEYS, this))
1806                 {
1807                         CS(this).pressedkeys = 0;
1808                         STAT(PRESSED_KEYS, this) = 0;
1809                 }
1810                 ClientData_Touch(this);
1811                 if (g_race || g_cts) race_InitSpectator();
1812         }
1813 }
1814
1815 void SetSpectatee(entity this, entity spectatee)
1816 {
1817         if(IS_BOT_CLIENT(this))
1818                 return; // bots abuse .enemy, this code is useless to them
1819
1820         entity old_spectatee = this.enemy;
1821
1822         this.enemy = spectatee;
1823
1824         // WEAPONTODO
1825         // these are required to fix the spectator bug with arc
1826         if(old_spectatee)
1827         {
1828                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1829                 {
1830                         .entity weaponentity = weaponentities[slot];
1831                         if(old_spectatee.(weaponentity).arc_beam)
1832                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1833                 }
1834         }
1835         if(spectatee)
1836         {
1837                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1838                 {
1839                         .entity weaponentity = weaponentities[slot];
1840                         if(spectatee.(weaponentity).arc_beam)
1841                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1842                 }
1843         }
1844
1845         if (spectatee)
1846                 SetSpectatee_status(this, etof(spectatee));
1847
1848         // needed to update spectator list
1849         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1850 }
1851
1852 bool Spectate(entity this, entity pl)
1853 {
1854         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1855                 return false;
1856         pl = M_ARGV(1, entity);
1857
1858         SetSpectatee(this, pl);
1859         return SpectateSet(this);
1860 }
1861
1862 bool SpectateNext(entity this)
1863 {
1864         entity ent = find(this.enemy, classname, STR_PLAYER);
1865
1866         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1867                 ent = M_ARGV(1, entity);
1868         else if (!ent)
1869                 ent = find(ent, classname, STR_PLAYER);
1870
1871         if(ent) { SetSpectatee(this, ent); }
1872
1873         return SpectateSet(this);
1874 }
1875
1876 bool SpectatePrev(entity this)
1877 {
1878         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1879         entity ent = findchain(classname, STR_PLAYER);
1880         if (!ent) // no player
1881                 return false;
1882
1883         entity first = ent;
1884         // skip players until current spectated player
1885         if(this.enemy)
1886         while(ent && ent != this.enemy)
1887                 ent = ent.chain;
1888
1889         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1890         {
1891                 case MUT_SPECPREV_FOUND:
1892                         ent = M_ARGV(1, entity);
1893                         break;
1894                 case MUT_SPECPREV_RETURN:
1895                         return true;
1896                 case MUT_SPECPREV_CONTINUE:
1897                 default:
1898                 {
1899                         if(ent.chain)
1900                                 ent = ent.chain;
1901                         else
1902                                 ent = first;
1903                         break;
1904                 }
1905         }
1906
1907         SetSpectatee(this, ent);
1908         return SpectateSet(this);
1909 }
1910
1911 /*
1912 =============
1913 ShowRespawnCountdown()
1914
1915 Update a respawn countdown display.
1916 =============
1917 */
1918 void ShowRespawnCountdown(entity this)
1919 {
1920         float number;
1921         if(!IS_DEAD(this)) // just respawned?
1922                 return;
1923         else
1924         {
1925                 number = ceil(this.respawn_time - time);
1926                 if(number <= 0)
1927                         return;
1928                 if(number <= this.respawn_countdown)
1929                 {
1930                         this.respawn_countdown = number - 1;
1931                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1932                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1933                 }
1934         }
1935 }
1936
1937 .bool team_selected;
1938 bool ShowTeamSelection(entity this)
1939 {
1940         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1941                 return false;
1942         stuffcmd(this, "menu_showteamselect\n");
1943         return true;
1944 }
1945 void Join(entity this)
1946 {
1947         TRANSMUTE(Player, this);
1948
1949         if(!this.team_selected)
1950         if(autocvar_g_campaign || autocvar_g_balance_teams)
1951                 TeamBalance_JoinBestTeam(this);
1952
1953         if(autocvar_g_campaign)
1954                 campaign_bots_may_start = true;
1955
1956         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1957
1958         PutClientInServer(this);
1959
1960         if(IS_PLAYER(this))
1961         if(teamplay && this.team != -1)
1962         {
1963         }
1964         else
1965                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1966         this.team_selected = false;
1967 }
1968
1969 int GetPlayerLimit()
1970 {
1971         if(g_duel)
1972                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1973         int player_limit = autocvar_g_maxplayers;
1974         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1975         player_limit = M_ARGV(0, int);
1976         return player_limit;
1977 }
1978
1979 /**
1980  * Determines whether the player is allowed to join. This depends on cvar
1981  * g_maxplayers, if it isn't used this function always return true, otherwise
1982  * it checks whether the number of currently playing players exceeds g_maxplayers.
1983  * @return int number of free slots for players, 0 if none
1984  */
1985 int nJoinAllowed(entity this, entity ignore)
1986 {
1987         if(!ignore)
1988         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1989         // so report 0 free slots if restricted
1990         {
1991                 if(autocvar_g_forced_team_otherwise == "spectate")
1992                         return 0;
1993                 if(autocvar_g_forced_team_otherwise == "spectator")
1994                         return 0;
1995         }
1996
1997         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1998                 return 0; // forced spectators can never join
1999
2000         // TODO simplify this
2001         int totalClients = 0;
2002         int currentlyPlaying = 0;
2003         FOREACH_CLIENT(true, {
2004                 if(it != ignore)
2005                         ++totalClients;
2006                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2007                         ++currentlyPlaying;
2008         });
2009
2010         int player_limit = GetPlayerLimit();
2011
2012         int free_slots = 0;
2013         if (!player_limit)
2014                 free_slots = maxclients - totalClients;
2015         else if(player_limit > 0 && currentlyPlaying < player_limit)
2016                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2017
2018         static float msg_time = 0;
2019         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2020         {
2021                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2022                 msg_time = time + 0.5;
2023         }
2024
2025         return free_slots;
2026 }
2027
2028 void PrintWelcomeMessage(entity this)
2029 {
2030         if(CS(this).motd_actived_time == 0)
2031         {
2032                 if (autocvar_g_campaign) {
2033                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2034                                 CS(this).motd_actived_time = time;
2035                                 SendWelcomemessage(this, false);
2036                         }
2037                 } else {
2038                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2039                                 CS(this).motd_actived_time = time;
2040                                 SendWelcomemessage(this, true);
2041                         }
2042                 }
2043         }
2044         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2045         {
2046                 if (autocvar_g_campaign) {
2047                         if (PHYS_INPUT_BUTTON_INFO(this))
2048                                 CS(this).motd_actived_time = time;
2049                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2050                                 CS(this).motd_actived_time = 0;
2051                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2052                         }
2053                 } else {
2054                         if (PHYS_INPUT_BUTTON_INFO(this))
2055                                 CS(this).motd_actived_time = time;
2056                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2057                                 CS(this).motd_actived_time = 0;
2058                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2059                         }
2060                 }
2061         }
2062         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2063         {
2064                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2065                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2066                 else if (CS(this).motd_actived_time == -2)
2067                 {
2068                         // instantly hide MOTD
2069                         CS(this).motd_actived_time = 0;
2070                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2071                 }
2072                 else if (IS_PLAYER(this) || IS_SPEC(this))
2073                 {
2074                         // FIXME occasionally for some reason MOTD never goes away
2075                         // delay MOTD removal a little bit in the hope it fixes this bug
2076                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2077                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2078                         else //if (CS(this).motd_actived_time < -2)
2079                                 CS(this).motd_actived_time++;
2080                 }
2081         }
2082 }
2083
2084 bool joinAllowed(entity this)
2085 {
2086         if (CS(this).version_mismatch) return false;
2087         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2088         if (!nJoinAllowed(this, this)) return false;
2089         if (teamplay && lockteams) return false;
2090         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2091         if (ShowTeamSelection(this)) return false;
2092         return true;
2093 }
2094
2095 .string shootfromfixedorigin;
2096 .bool dualwielding_prev;
2097 bool PlayerThink(entity this)
2098 {
2099         if (game_stopped || intermission_running) {
2100                 this.modelflags &= ~MF_ROCKET;
2101                 if(intermission_running)
2102                         IntermissionThink(this);
2103                 return false;
2104         }
2105
2106         if (timeout_status == TIMEOUT_ACTIVE) {
2107                 // don't allow the player to turn around while game is paused
2108                 // FIXME turn this into CSQC stuff
2109                 this.v_angle = this.lastV_angle;
2110                 this.angles = this.lastV_angle;
2111                 this.fixangle = true;
2112         }
2113
2114         if (frametime) player_powerups(this);
2115
2116         if (IS_DEAD(this)) {
2117                 if (this.personal && g_race_qualifying) {
2118                         if (time > this.respawn_time) {
2119                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2120                                 respawn(this);
2121                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2122                         }
2123                 } else {
2124                         if (frametime) player_anim(this);
2125
2126                         if (this.respawn_flags & RESPAWN_DENY)
2127                         {
2128                                 STAT(RESPAWN_TIME, this) = 0;
2129                                 return false;
2130                         }
2131
2132                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2133
2134                         switch(this.deadflag)
2135                         {
2136                                 case DEAD_DYING:
2137                                 {
2138                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2139                                                 this.deadflag = DEAD_RESPAWNING;
2140                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2141                                                 this.deadflag = DEAD_DEAD;
2142                                         break;
2143                                 }
2144                                 case DEAD_DEAD:
2145                                 {
2146                                         if (button_pressed)
2147                                                 this.deadflag = DEAD_RESPAWNABLE;
2148                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2149                                                 this.deadflag = DEAD_RESPAWNING;
2150                                         break;
2151                                 }
2152                                 case DEAD_RESPAWNABLE:
2153                                 {
2154                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2155                                                 this.deadflag = DEAD_RESPAWNING;
2156                                         break;
2157                                 }
2158                                 case DEAD_RESPAWNING:
2159                                 {
2160                                         if (time > this.respawn_time)
2161                                         {
2162                                                 this.respawn_time = time + 1; // only retry once a second
2163                                                 this.respawn_time_max = this.respawn_time;
2164                                                 respawn(this);
2165                                         }
2166                                         break;
2167                                 }
2168                         }
2169
2170                         ShowRespawnCountdown(this);
2171
2172                         if (this.respawn_flags & RESPAWN_SILENT)
2173                                 STAT(RESPAWN_TIME, this) = 0;
2174                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2175                         {
2176                                 if (time < this.respawn_time)
2177                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2178                                 else if (this.deadflag != DEAD_RESPAWNING)
2179                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2180                         }
2181                         else
2182                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2183                 }
2184
2185                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2186                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2187                         STAT(RESPAWN_TIME, this) *= -1;
2188
2189                 return false;
2190         }
2191
2192         FixPlayermodel(this);
2193
2194         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2195                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2196                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2197         }
2198
2199         // reset gun alignment when dual wielding status changes
2200         // to ensure guns are always aligned right and left
2201         bool dualwielding = W_DualWielding(this);
2202         if(this.dualwielding_prev != dualwielding)
2203         {
2204                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2205                 this.dualwielding_prev = dualwielding;
2206         }
2207
2208         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2209         //if(frametime)
2210         {
2211                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2212                 {
2213                         .entity weaponentity = weaponentities[slot];
2214                         if(WEP_CVAR(vortex, charge_always))
2215                                 W_Vortex_Charge(this, weaponentity, frametime);
2216                         W_WeaponFrame(this, weaponentity);
2217                 }
2218         }
2219
2220         if (frametime)
2221         {
2222                 // WEAPONTODO: Add a weapon request for this
2223                 // rot vortex charge to the charge limit
2224                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2225                 {
2226                         .entity weaponentity = weaponentities[slot];
2227                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2228                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2229                 }
2230
2231                 player_regen(this);
2232                 player_anim(this);
2233                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2234         }
2235
2236         monsters_setstatus(this);
2237
2238         return true;
2239 }
2240
2241 .bool would_spectate;
2242 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2243 void ObserverOrSpectatorThink(entity this)
2244 {
2245         bool is_spec = IS_SPEC(this);
2246         if ( CS(this).impulse )
2247         {
2248                 int r = MinigameImpulse(this, CS(this).impulse);
2249                 if (!is_spec || r)
2250                         CS(this).impulse = 0;
2251
2252                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2253                 {
2254                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2255                         CS(this).impulse = 0;
2256                         return;
2257                 }
2258         }
2259
2260         if (this.flags & FL_JUMPRELEASED) {
2261                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2262                         this.flags &= ~FL_JUMPRELEASED;
2263                         this.flags |= FL_SPAWNING;
2264                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2265                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2266                         this.flags &= ~FL_JUMPRELEASED;
2267                         if(SpectateNext(this)) {
2268                                 TRANSMUTE(Spectator, this);
2269                         } else if (is_spec) {
2270                                 TRANSMUTE(Observer, this);
2271                                 PutClientInServer(this);
2272                         }
2273                         else
2274                                 this.would_spectate = false; // unable to spectate anyone
2275                         if (is_spec)
2276                                 CS(this).impulse = 0;
2277                 } else if (is_spec) {
2278                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2279                                 this.flags &= ~FL_JUMPRELEASED;
2280                                 if(SpectatePrev(this)) {
2281                                         TRANSMUTE(Spectator, this);
2282                                 } else {
2283                                         TRANSMUTE(Observer, this);
2284                                         PutClientInServer(this);
2285                                 }
2286                                 CS(this).impulse = 0;
2287                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2288                                 this.would_spectate = false;
2289                                 this.flags &= ~FL_JUMPRELEASED;
2290                                 TRANSMUTE(Observer, this);
2291                                 PutClientInServer(this);
2292                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2293                                 PutObserverInServer(this, false, true);
2294                                 this.would_spectate = true;
2295                         }
2296                 }
2297                 else {
2298                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2299                         if (PHYS_INPUT_BUTTON_USE(this))
2300                                 wouldclip = !wouldclip;
2301                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2302                         set_movetype(this, preferred_movetype);
2303                 }
2304         } else { // jump pressed
2305                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2306                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2307                         this.flags |= FL_JUMPRELEASED;
2308                         if(this.flags & FL_SPAWNING)
2309                         {
2310                                 this.flags &= ~FL_SPAWNING;
2311                                 if(joinAllowed(this))
2312                                         Join(this);
2313                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2314                                         CS(this).autojoin_checked = -1;
2315                                 return;
2316                         }
2317                 }
2318                 if(is_spec && !SpectateUpdate(this))
2319                         PutObserverInServer(this, false, true);
2320         }
2321         if (is_spec)
2322                 this.flags |= FL_CLIENT | FL_NOTARGET;
2323 }
2324
2325 void PlayerUseKey(entity this)
2326 {
2327         if (!IS_PLAYER(this))
2328                 return;
2329
2330         if(this.vehicle)
2331         {
2332                 if(!game_stopped)
2333                 {
2334                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2335                         return;
2336                 }
2337         }
2338         else if(autocvar_g_vehicles_enter)
2339         {
2340                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2341                 {
2342                         entity head, closest_target = NULL;
2343                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2344
2345                         while(head) // find the closest acceptable target to enter
2346                         {
2347                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2348                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2349                                 {
2350                                         if(closest_target)
2351                                         {
2352                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2353                                                 { closest_target = head; }
2354                                         }
2355                                         else { closest_target = head; }
2356                                 }
2357
2358                                 head = head.chain;
2359                         }
2360
2361                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2362                 }
2363         }
2364
2365         // a use key was pressed; call handlers
2366         MUTATOR_CALLHOOK(PlayerUseKey, this);
2367 }
2368
2369
2370 /*
2371 =============
2372 PlayerPreThink
2373
2374 Called every frame for each client before the physics are run
2375 =============
2376 */
2377 .float last_vehiclecheck;
2378 void PlayerPreThink (entity this)
2379 {
2380         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2381         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2382
2383         WarpZone_PlayerPhysics_FixVAngle(this);
2384
2385         if (frametime) {
2386                 // physics frames: update anticheat stuff
2387                 anticheat_prethink(this);
2388
2389                 // WORKAROUND: only use dropclient in server frames (frametime set).
2390                 // Never use it in cl_movement frames (frametime zero).
2391                 if (blockSpectators && IS_REAL_CLIENT(this)
2392                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2393                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2394                 {
2395                         if (dropclient_schedule(this))
2396                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2397                 }
2398         }
2399
2400         zoomstate_set = false;
2401
2402         // Check for nameless players
2403         if (this.netname == "" || this.netname != CS(this).netname_previous)
2404         {
2405                 bool assume_unchanged = (CS(this).netname_previous == "");
2406                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2407                 {
2408                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2409                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2410                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2411                         assume_unchanged = false;
2412                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2413                 }
2414                 if (isInvisibleString(this.netname))
2415                 {
2416                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2417                         sprint(this, "Warning: invisible names are not allowed.\n");
2418                         assume_unchanged = false;
2419                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2420                 }
2421                 if (!assume_unchanged && autocvar_sv_eventlog)
2422                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2423                 strcpy(CS(this).netname_previous, this.netname);
2424         }
2425
2426         // version nagging
2427         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2428         CS(this).version_nagtime = 0;
2429         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2430             // git client
2431         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2432             // git server
2433             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2434         } else {
2435             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2436             if (r < 0) { // old client
2437                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2438             } else if (r > 0) { // old server
2439                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2440             }
2441         }
2442     }
2443
2444         // GOD MODE info
2445         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2446         {
2447                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2448                 this.max_armorvalue = 0;
2449         }
2450
2451         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2452         {
2453                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2454                 {
2455                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2456                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2457                         if (this.iceblock)
2458                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2459
2460                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2461                                 Unfreeze(this, false);
2462                 }
2463                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2464                 {
2465                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2466                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2467
2468                         if (GetResource(this, RES_HEALTH) < 1)
2469                         {
2470                                 if (this.vehicle)
2471                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2472                                 if(this.event_damage)
2473                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2474                         }
2475                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2476                                 Unfreeze(this, false);
2477                 }
2478         }
2479
2480         MUTATOR_CALLHOOK(PlayerPreThink, this);
2481
2482         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2483         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2484         {
2485                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2486                 {
2487                         if(!it.owner)
2488                         {
2489                                 if(!it.team || SAME_TEAM(this, it))
2490                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2491                                 else if(autocvar_g_vehicles_steal)
2492                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2493                         }
2494                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2495                         {
2496                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2497                         }
2498                 });
2499
2500                 this.last_vehiclecheck = time + 1;
2501         }
2502
2503         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2504                 PlayerUseKey(this);
2505         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2506
2507         if (IS_REAL_CLIENT(this))
2508                 PrintWelcomeMessage(this);
2509
2510         if (IS_PLAYER(this)) {
2511                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2512                         error("Client can't be spawned as player on connection!");
2513                 if(!PlayerThink(this))
2514                         return;
2515         }
2516         else if (game_stopped || intermission_running) {
2517                 if(intermission_running)
2518                         IntermissionThink(this);
2519                 return;
2520         }
2521         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2522         {
2523                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2524                 CS(this).autojoin_checked = 1;
2525                 // don't do this in ClientConnect
2526                 // many things can go wrong if a client is spawned as player on connection
2527                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2528                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2529                                 && (!teamplay || autocvar_g_balance_teams)))
2530                 {
2531                         campaign_bots_may_start = true;
2532                         if(joinAllowed(this))
2533                                 Join(this);
2534                         return;
2535                 }
2536         }
2537         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2538                 ObserverOrSpectatorThink(this);
2539         }
2540
2541         // WEAPONTODO: Add weapon request for this
2542         if (!zoomstate_set) {
2543                 bool wep_zoomed = false;
2544                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2545                 {
2546                         .entity weaponentity = weaponentities[slot];
2547                         Weapon thiswep = this.(weaponentity).m_weapon;
2548                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2549                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2550                 }
2551                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2552         }
2553
2554         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2555         {
2556                 CS(this).teamkill_soundtime = 0;
2557
2558                 entity e = CS(this).teamkill_soundsource;
2559                 entity oldpusher = e.pusher;
2560                 e.pusher = this;
2561                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2562                 e.pusher = oldpusher;
2563         }
2564
2565         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2566                 CS(this).taunt_soundtime = 0;
2567                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2568         }
2569
2570         target_voicescript_next(this);
2571 }
2572
2573 void DrownPlayer(entity this)
2574 {
2575         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2576                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2577         {
2578                 STAT(AIR_FINISHED, this) = 0;
2579                 return;
2580         }
2581
2582         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2583         {
2584                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2585                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2586                 STAT(AIR_FINISHED, this) = 0;
2587         }
2588         else
2589         {
2590                 if (!STAT(AIR_FINISHED, this))
2591                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2592                 if (STAT(AIR_FINISHED, this) < time)
2593                 {       // drown!
2594                         if (this.pain_finished < time)
2595                         {
2596                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2597                                 this.pain_finished = time + 0.5;
2598                         }
2599                 }
2600         }
2601 }
2602
2603 .bool move_qcphysics;
2604
2605 void Player_Physics(entity this)
2606 {
2607         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2608
2609         if(!this.move_qcphysics)
2610                 return;
2611
2612         if(!frametime && !CS(this).pm_frametime)
2613                 return;
2614
2615         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2616
2617         CS(this).pm_frametime = 0;
2618 }
2619
2620 /*
2621 =============
2622 PlayerPostThink
2623
2624 Called every frame for each client after the physics are run
2625 =============
2626 */
2627 void PlayerPostThink (entity this)
2628 {
2629         Player_Physics(this);
2630
2631         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2632         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2633         if (IS_REAL_CLIENT(this))
2634         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2635         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2636         {
2637                 int totalClients = 0;
2638                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2639                 {
2640                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2641                         if (server_is_dedicated)
2642                         {
2643                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2644                                 {
2645                                         ++totalClients;
2646                                 });
2647                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2648                                         totalClients = 0;
2649                         }
2650                 }
2651                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2652                 {
2653                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2654                         {
2655                                 ++totalClients;
2656                         });
2657                 }
2658
2659                 if (totalClients < autocvar_sv_maxidle_minplayers)
2660                 {
2661                         // idle kick disabled
2662                         CS(this).parm_idlesince = time;
2663                 }
2664                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2665                 {
2666                         if (CS(this).idlekick_lasttimeleft)
2667                         {
2668                                 CS(this).idlekick_lasttimeleft = 0;
2669                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2670                         }
2671                 }
2672                 else
2673                 {
2674                         float maxidle_time = autocvar_sv_maxidle;
2675                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2676                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2677                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2678                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2679                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2680                         {
2681                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2682                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2683                                 else
2684                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2685                         }
2686                         if (timeleft <= 0) {
2687                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2688                                 {
2689                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2690                                         PutObserverInServer(this, true, true);
2691                                 }
2692                                 else
2693                                 {
2694                                         if (dropclient_schedule(this))
2695                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2696                                 }
2697                                 return;
2698                         }
2699                         else if (timeleft <= countdown_time) {
2700                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2701                                         play2(this, SND(TALK2));
2702                                 CS(this).idlekick_lasttimeleft = timeleft;
2703                         }
2704                 }
2705         }
2706
2707         CheatFrame(this);
2708
2709         if (game_stopped)
2710         {
2711                 this.solid = SOLID_NOT;
2712                 this.takedamage = DAMAGE_NO;
2713                 set_movetype(this, MOVETYPE_NONE);
2714                 CS(this).teamkill_complain = 0;
2715                 CS(this).teamkill_soundtime = 0;
2716                 CS(this).teamkill_soundsource = NULL;
2717         }
2718
2719         if (IS_PLAYER(this)) {
2720                 if(this.death_time == time && IS_DEAD(this))
2721                 {
2722                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2723                         // once all the damage events of this frame have been processed with normal size
2724                         this.maxs.z = 5;
2725                         setsize(this, this.mins, this.maxs);
2726                 }
2727                 DrownPlayer(this);
2728                 UpdateChatBubble(this);
2729                 if (CS(this).impulse) ImpulseCommands(this);
2730                 GetPressedKeys(this);
2731                 if (game_stopped)
2732                 {
2733                         CSQCMODEL_AUTOUPDATE(this);
2734                         return;
2735                 }
2736         }
2737         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2738         {
2739                 CS(this).pressedkeys = 0;
2740                 STAT(PRESSED_KEYS, this) = 0;
2741         }
2742
2743         if (this.waypointsprite_attachedforcarrier) {
2744                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2745                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2746         }
2747
2748         CSQCMODEL_AUTOUPDATE(this);
2749 }
2750
2751 // hack to copy the button fields from the client entity to the Client State
2752 void PM_UpdateButtons(entity this, entity store)
2753 {
2754         if(this.impulse)
2755                 store.impulse = this.impulse;
2756         this.impulse = 0;
2757
2758         bool typing = this.buttonchat || this.button12;
2759
2760         store.button0 = (typing) ? 0 : this.button0;
2761         //button1?!
2762         store.button2 = (typing) ? 0 : this.button2;
2763         store.button3 = (typing) ? 0 : this.button3;
2764         store.button4 = this.button4;
2765         store.button5 = (typing) ? 0 : this.button5;
2766         store.button6 = this.button6;
2767         store.button7 = this.button7;
2768         store.button8 = this.button8;
2769         store.button9 = this.button9;
2770         store.button10 = this.button10;
2771         store.button11 = this.button11;
2772         store.button12 = this.button12;
2773         store.button13 = this.button13;
2774         store.button14 = this.button14;
2775         store.button15 = this.button15;
2776         store.button16 = this.button16;
2777         store.buttonuse = this.buttonuse;
2778         store.buttonchat = this.buttonchat;
2779
2780         store.cursor_active = this.cursor_active;
2781         store.cursor_screen = this.cursor_screen;
2782         store.cursor_trace_start = this.cursor_trace_start;
2783         store.cursor_trace_endpos = this.cursor_trace_endpos;
2784         store.cursor_trace_ent = this.cursor_trace_ent;
2785
2786         store.ping = this.ping;
2787         store.ping_packetloss = this.ping_packetloss;
2788         store.ping_movementloss = this.ping_movementloss;
2789
2790         store.v_angle = this.v_angle;
2791         store.movement = this.movement;
2792 }
2793
2794 NET_HANDLE(fpsreport, bool)
2795 {
2796         int fps = ReadShort();
2797         PlayerScore_Set(sender, SP_FPS, fps);
2798         return true;
2799 }