qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         bool recount_ready = false;
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         this.ready = false;
 257                         recount_ready = true;
 258                 }
 259                 entcs_update_players(this);
 260         }
 261
 262         if (use_spawnpoint)
 263         {
 264                 entity spot = SelectSpawnPoint(this, true);
 265                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 266                 this.angles = vec2(spot.angles);
 267                 // offset it so that the spectator spawns higher off the ground, looks better this way
 268                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 269         }
 270         else // change origin to restore previous view origin
 271                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 272         this.fixangle = true;
 273
 274         if (IS_REAL_CLIENT(this))
 275         {
 276                 msg_entity = this;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, this);
 279         }
 280         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 281         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 282         if(!autocvar_g_debug_globalsounds)
 283         {
 284                 // needed for player sounds
 285                 this.model = "";
 286                 FixPlayermodel(this);
 287         }
 288         setmodel(this, MDL_Null);
 289         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 290         this.view_ofs = '0 0 0';
 291
 292         RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         TRANSMUTE(Observer, this);
 307
 308         if(recount_ready) ReadyCount();
 309
 310         WaypointSprite_PlayerDead(this);
 311         accuracy_resend(this);
 312
 313         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 314                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323         STAT(HUD, this) = HUD_NORMAL;
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         player_powerups_remove_all(this);
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406
 407         bot_relinkplayerlist();
 408
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void PutPlayerInServer(entity this)
 536 {
 537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 538
 539         PlayerState_attach(this);
 540         accuracy_resend(this);
 541
 542         if (this.team < 0)
 543                 TeamBalance_JoinBestTeam(this);
 544
 545         entity spot = SelectSpawnPoint(this, false);
 546         if (!spot) {
 547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 548                 return; // spawn failed
 549         }
 550
 551         TRANSMUTE(Player, this);
 552
 553         CS(this).wasplayer = true;
 554         this.iscreature = true;
 555         this.teleportable = TELEPORT_NORMAL;
 556         if(!this.damagedbycontents)
 557                 IL_PUSH(g_damagedbycontents, this);
 558         this.damagedbycontents = true;
 559         set_movetype(this, MOVETYPE_WALK);
 560         this.solid = SOLID_SLIDEBOX;
 561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 562         if (autocvar_g_playerclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 566         this.frags = FRAGS_PLAYER;
 567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 569         if (autocvar__notarget)
 570                 this.flags |= FL_NOTARGET;
 571         this.takedamage = DAMAGE_AIM;
 572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 573
 574         if (warmup_stage) {
 575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, warmup_start_health);
 582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 584         } else {
 585                 SetResource(this, RES_SHELLS, start_ammo_shells);
 586                 SetResource(this, RES_BULLETS, start_ammo_nails);
 587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 588                 SetResource(this, RES_CELLS, start_ammo_cells);
 589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 590                 SetResource(this, RES_FUEL, start_ammo_fuel);
 591                 SetResource(this, RES_HEALTH, start_health);
 592                 SetResource(this, RES_ARMOR, start_armorvalue);
 593                 STAT(WEAPONS, this) = start_weapons;
 594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 595                 {
 596                         GiveRandomWeapons(this, random_start_weapons_count,
 597                                 autocvar_g_random_start_weapons, random_start_ammo);
 598                 }
 599         }
 600         SetSpectatee_status(this, 0);
 601
 602         PS(this).dual_weapons = '0 0 0';
 603
 604         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 605                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 606
 607         this.items = start_items;
 608
 609         float shieldtime = time + autocvar_g_spawnshieldtime;
 610
 611         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 612         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 613         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 614         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 615         if (!sv_ready_restart_after_countdown && time < game_starttime)
 616         {
 617                 float f = game_starttime - time;
 618                 shieldtime += f;
 619                 this.pauserotarmor_finished += f;
 620                 this.pauserothealth_finished += f;
 621                 this.pauseregen_finished += f;
 622         }
 623
 624         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 625
 626         this.damageforcescale = autocvar_g_player_damageforcescale;
 627         this.death_time = 0;
 628         this.respawn_flags = 0;
 629         this.respawn_time = 0;
 630         STAT(RESPAWN_TIME, this) = 0;
 631         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 632         this.fade_time = 0;
 633         this.pain_finished = 0;
 634         this.pushltime = 0;
 635         setthink(this, func_null); // players have no think function
 636         this.nextthink = 0;
 637         this.dmg_team = 0;
 638         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 639
 640         this.deadflag = DEAD_NO;
 641
 642         this.angles = spot.angles;
 643         this.angles_z = 0; // never spawn tilted even if the spot says to
 644         if (IS_BOT_CLIENT(this))
 645         {
 646                 this.v_angle = this.angles;
 647                 bot_aim_reset(this);
 648         }
 649         this.fixangle = true; // turn this way immediately
 650         this.oldvelocity = this.velocity = '0 0 0';
 651         this.avelocity = '0 0 0';
 652         this.punchangle = '0 0 0';
 653         this.punchvector = '0 0 0';
 654
 655         STAT(REVIVE_PROGRESS, this) = 0;
 656         this.revival_time = 0;
 657
 658         STAT(AIR_FINISHED, this) = 0;
 659         this.waterlevel = WATERLEVEL_NONE;
 660         this.watertype = CONTENT_EMPTY;
 661
 662         entity spawnevent = new_pure(spawnevent);
 663         spawnevent.owner = this;
 664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665
 666         // Cut off any still running player sounds.
 667         stopsound(this, CH_PLAYER_SINGLE);
 668
 669         this.model = "";
 670         FixPlayermodel(this);
 671         this.drawonlytoclient = NULL;
 672
 673         this.viewloc = NULL;
 674
 675         for(int slot = 0; slot < MAX_AXH; ++slot)
 676         {
 677                 entity axh = this.(AuxiliaryXhair[slot]);
 678                 this.(AuxiliaryXhair[slot]) = NULL;
 679
 680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 681                         delete(axh);
 682         }
 683
 684         this.spawnpoint_targ = NULL;
 685
 686         UNSET_DUCKED(this);
 687         this.view_ofs = STAT(PL_VIEW_OFS, this);
 688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 689         this.spawnorigin = spot.origin;
 690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 691         // don't reset back to last position, even if new position is stuck in solid
 692         this.oldorigin = this.origin;
 693         if(this.conveyor)
 694                 IL_REMOVE(g_conveyed, this);
 695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 696         if(this.swampslug)
 697                 IL_REMOVE(g_swamped, this);
 698         this.swampslug = NULL;
 699         this.swamp_interval = 0;
 700         if(this.ladder_entity)
 701                 IL_REMOVE(g_ladderents, this);
 702         this.ladder_entity = NULL;
 703         IL_EACH(g_counters, it.realowner == this,
 704         {
 705                 delete(it);
 706         });
 707         STAT(HUD, this) = HUD_NORMAL;
 708
 709         this.event_damage = PlayerDamage;
 710         this.event_heal = PlayerHeal;
 711
 712         this.draggable = func_null;
 713
 714         if(!this.bot_attack)
 715                 IL_PUSH(g_bot_targets, this);
 716         this.bot_attack = true;
 717         if(!this.monster_attack)
 718                 IL_PUSH(g_monster_targets, this);
 719         this.monster_attack = true;
 720         navigation_dynamicgoal_init(this, false);
 721
 722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 723
 724         // player was spectator
 725         if (CS(this).killcount == FRAGS_SPECTATOR) {
 726                 PlayerScore_Clear(this);
 727                 CS(this).killcount = 0;
 728                 CS(this).startplaytime = time;
 729         }
 730
 731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 732         {
 733                 .entity weaponentity = weaponentities[slot];
 734                 CL_SpawnWeaponentity(this, weaponentity);
 735         }
 736         this.alpha = default_player_alpha;
 737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 738         this.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740         this.speedrunning = false;
 741
 742         this.counter_cnt = 0;
 743         this.fragsfilter_cnt = 0;
 744
 745         target_voicescript_clear(this);
 746
 747         // reset fields the weapons may use
 748         FOREACH(Weapons, true, {
 749                 it.wr_resetplayer(it, this);
 750                         // reload all reloadable weapons
 751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753                         {
 754                                 .entity weaponentity = weaponentities[slot];
 755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 756                         }
 757                 }
 758         });
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763
 764         {
 765                 string s = spot.target;
 766                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 767                         spot.target = string_null;
 768                 SUB_UseTargets(spot, this, NULL);
 769                 if(g_assault || g_race)
 770                         spot.target = s;
 771         }
 772
 773         if (autocvar_spawn_debug)
 774         {
 775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 777         }
 778
 779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780         {
 781                 .entity weaponentity = weaponentities[slot];
 782                 entity w_ent = this.(weaponentity);
 783                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 784                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 785                 else
 786                         w_ent.m_switchweapon = WEP_Null;
 787                 w_ent.m_weapon = WEP_Null;
 788                 w_ent.weaponname = "";
 789                 w_ent.m_switchingweapon = WEP_Null;
 790                 w_ent.cnt = -1;
 791         }
 792
 793         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 794
 795         if (CS(this).impulse) ImpulseCommands(this);
 796
 797         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 W_WeaponFrame(this, weaponentity);
 802         }
 803
 804         if (!warmup_stage && !this.alivetime)
 805                 this.alivetime = time;
 806
 807         antilag_clear(this, CS(this));
 808 }
 809
 810 /** Called when a client spawns in the server */
 811 void PutClientInServer(entity this)
 812 {
 813         if (IS_BOT_CLIENT(this)) {
 814                 TRANSMUTE(Player, this);
 815         } else if (IS_REAL_CLIENT(this)) {
 816                 msg_entity = this;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, this);
 819         }
 820         if (game_stopped)
 821                 TRANSMUTE(Observer, this);
 822
 823         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this, false, use_spawnpoint);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837
 838         bot_relinkplayerlist();
 839 }
 840
 841 // TODO do we need all these fields, or should we stop autodetecting runtime
 842 // changes and just have a console command to update this?
 843 bool ClientInit_SendEntity(entity this, entity to, int sf)
 844 {
 845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 846         return = true;
 847         msg_entity = to;
 848         // MSG_INIT replacement
 849         // TODO: make easier to use
 850         Registry_send_all();
 851         W_PROP_reload(MSG_ONE, to);
 852         ClientInit_misc(this);
 853         MUTATOR_CALLHOOK(Ent_Init);
 854 }
 855 void ClientInit_misc(entity this)
 856 {
 857         int channel = MSG_ONE;
 858         WriteHeader(channel, ENT_CLIENT_INIT);
 859         WriteByte(channel, g_nexball_meter_period * 32);
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 868
 869         if(autocvar_sv_foginterval && world.fog != "")
 870                 WriteString(channel, world.fog);
 871         else
 872                 WriteString(channel, "");
 873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 875         WriteByte(channel, serverflags);
 876         WriteCoord(channel, autocvar_g_trueaim_minrange);
 877 }
 878
 879 void ClientInit_CheckUpdate(entity this)
 880 {
 881         this.nextthink = time;
 882         if(this.count != autocvar_g_balance_armor_blockpercent)
 883         {
 884                 this.count = autocvar_g_balance_armor_blockpercent;
 885                 this.SendFlags |= 1;
 886         }
 887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 888         {
 889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 890                 this.SendFlags |= 1;
 891         }
 892 }
 893
 894 void ClientInit_Spawn()
 895 {
 896         entity e = new_pure(clientinit);
 897         setthink(e, ClientInit_CheckUpdate);
 898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 899
 900         ClientInit_CheckUpdate(e);
 901 }
 902
 903 /*
 904 =============
 905 SetNewParms
 906 =============
 907 */
 908 void SetNewParms ()
 909 {
 910         // initialize parms for a new player
 911         parm1 = -(86400 * 366);
 912
 913         MUTATOR_CALLHOOK(SetNewParms);
 914 }
 915
 916 /*
 917 =============
 918 SetChangeParms
 919 =============
 920 */
 921 void SetChangeParms (entity this)
 922 {
 923         // save parms for level change
 924         parm1 = CS(this).parm_idlesince - time;
 925
 926         MUTATOR_CALLHOOK(SetChangeParms);
 927 }
 928
 929 /*
 930 =============
 931 DecodeLevelParms
 932 =============
 933 */
 934 void DecodeLevelParms(entity this)
 935 {
 936         // load parms
 937         CS(this).parm_idlesince = parm1;
 938         if (CS(this).parm_idlesince == -(86400 * 366))
 939                 CS(this).parm_idlesince = time;
 940
 941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 943
 944         MUTATOR_CALLHOOK(DecodeLevelParms);
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 957
 958         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 959
 960         MUTATOR_CALLHOOK(FixClientCvars, e);
 961 }
 962
 963 bool findinlist_abbrev(string tofind, string list)
 964 {
 965         if(list == "" || tofind == "")
 966                 return false; // empty list or search, just return
 967
 968         // this function allows abbreviated strings!
 969         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 970         {
 971                 return true;
 972         });
 973
 974         return false;
 975 }
 976
 977 bool PlayerInIPList(entity p, string iplist)
 978 {
 979         // some safety checks (never allow local?)
 980         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 981                 return false;
 982
 983         return findinlist_abbrev(p.netaddress, iplist);
 984 }
 985
 986 bool PlayerInIDList(entity p, string idlist)
 987 {
 988         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 989         if(!p.crypto_idfp)
 990                 return false;
 991
 992         return findinlist_abbrev(p.crypto_idfp, idlist);
 993 }
 994
 995 bool PlayerInList(entity player, string list)
 996 {
 997         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 998 }
 999
1000 #ifdef DP_EXT_PRECONNECT
1001 /*
1002 =============
1003 ClientPreConnect
1004
1005 Called once (not at each match start) when a client begins a connection to the server
1006 =============
1007 */
1008 void ClientPreConnect(entity this)
1009 {
1010         if(autocvar_sv_eventlog)
1011         {
1012                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1013                         this.playerid,
1014                         etof(this),
1015                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1016                 ));
1017         }
1018 }
1019 #endif
1020
1021 string GetClientVersionMessage(entity this)
1022 {
1023         if (CS(this).version_mismatch) {
1024                 if(CS(this).version < autocvar_gameversion) {
1025                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1026                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1027                 } else {
1028                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1029                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1030                 }
1031         } else {
1032                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1033         }
1034 }
1035
1036 void SendWelcomemessage(entity this, bool force_centerprint)
1037 {
1038         msg_entity = this;
1039         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1040         WriteByte(MSG_ONE, boolean(autocvar_g_campaign));
1041         if (boolean(autocvar_g_campaign))
1042         {
1043                 WriteString(MSG_ONE, Campaign_GetTitle());
1044                 WriteByte(MSG_ONE, Campaign_GetLevelNum());
1045                 WriteString(MSG_ONE, Campaign_GetMessage());
1046                 return;
1047         }
1048         WriteByte(MSG_ONE, force_centerprint);
1049         WriteString(MSG_ONE, autocvar_hostname);
1050         WriteString(MSG_ONE, GetClientVersionMessage(this));
1051
1052         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1053         string modifications = M_ARGV(0, string);
1054
1055         if(g_weaponarena)
1056         {
1057                 if(g_weaponarena_random)
1058                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1059                 else
1060                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1061         }
1062         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1063                 modifications = strcat(modifications, ", No start weapons");
1064         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1065                 modifications = strcat(modifications, ", Low gravity");
1066         if(g_weapon_stay && !g_cts)
1067                 modifications = strcat(modifications, ", Weapons stay");
1068         if(autocvar_g_jetpack)
1069                 modifications = strcat(modifications, ", Jet pack");
1070         modifications = substring(modifications, 2, strlen(modifications) - 2);
1071
1072         WriteString(MSG_ONE, modifications);
1073
1074         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1075         {
1076                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1077                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1078         }
1079
1080         WriteString(MSG_ONE, cache_mutatormsg);
1081
1082         string mutator_msg = "";
1083         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1084         mutator_msg = M_ARGV(0, string);
1085
1086         WriteString(MSG_ONE, mutator_msg); // trust that the mutator will do proper formatting
1087         WriteString(MSG_ONE, strreplace("\\n", "\n", autocvar_sv_motd));
1088 }
1089
1090 void SendWelcomemessage_onConnection_think(entity this)
1091 {
1092         SendWelcomemessage(this, false);
1093 }
1094
1095 void SendWelcomemessage_onConnection(entity this)
1096 {
1097         // give the client time to sent its version
1098         defer(this, 0.5, SendWelcomemessage_onConnection_think);
1099 }
1100
1101 /**
1102 =============
1103 ClientConnect
1104
1105 Called when a client connects to the server
1106 =============
1107 */
1108 void ClientConnect(entity this)
1109 {
1110         if (Ban_MaybeEnforceBanOnce(this)) return;
1111         assert(!IS_CLIENT(this), return);
1112         this.flags |= FL_CLIENT;
1113         assert(player_count >= 0, player_count = 0);
1114
1115         TRANSMUTE(Client, this);
1116         CS(this).version_nagtime = time + 10 + random() * 10;
1117
1118         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1119
1120         bot_clientconnect(this);
1121
1122         Player_DetermineForcedTeam(this);
1123
1124         TRANSMUTE(Observer, this);
1125
1126         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1127
1128         // always track bots, don't ask for cl_allow_uidtracking
1129         if (IS_BOT_CLIENT(this))
1130                 PlayerStats_GameReport_AddPlayer(this);
1131         else
1132                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1133
1134         if (autocvar_sv_eventlog)
1135                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1136
1137         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1138
1139         stuffcmd(this, clientstuff, "\n");
1140         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1141
1142         FixClientCvars(this);
1143
1144         // get version info from player
1145         stuffcmd(this, "cmd clientversion $gameversion\n");
1146
1147         // notify about available teams
1148         if (teamplay)
1149         {
1150                 entity balance = TeamBalance_CheckAllowedTeams(this);
1151                 int t = TeamBalance_GetAllowedTeams(balance);
1152                 TeamBalance_Destroy(balance);
1153                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1154         }
1155         else
1156         {
1157                 stuffcmd(this, "set _teams_available 0\n");
1158         }
1159
1160         bot_relinkplayerlist();
1161
1162         CS(this).spectatortime = time;
1163         if (blockSpectators)
1164         {
1165                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1166         }
1167
1168         CS(this).jointime = time;
1169
1170         if (IS_REAL_CLIENT(this))
1171         {
1172                 if (g_weaponarena_weapons == WEPSET(TUBA))
1173                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1174         }
1175
1176         if (!autocvar_sv_foginterval && world.fog != "")
1177                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1178
1179         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1180                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1181                         send_CSQC_teamnagger();
1182
1183         CSQCMODEL_AUTOINIT(this);
1184
1185         CS(this).model_randomizer = random();
1186
1187         if (IS_REAL_CLIENT(this))
1188         {
1189                 if (!autocvar_g_campaign)
1190                         SendWelcomemessage_onConnection(this);
1191                 sv_notice_join(this);
1192         }
1193
1194         this.move_qcphysics = autocvar_sv_qcphysics;
1195
1196         // update physics stats (players can spawn before physics runs)
1197         Physics_UpdateStats(this);
1198
1199         IL_EACH(g_initforplayer, it.init_for_player, {
1200                 it.init_for_player(it, this);
1201         });
1202
1203         Handicap_Initialize(this);
1204
1205         MUTATOR_CALLHOOK(ClientConnect, this);
1206
1207         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1208                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1209 }
1210 /*
1211 =============
1212 ClientDisconnect
1213
1214 Called when a client disconnects from the server
1215 =============
1216 */
1217 .entity chatbubbleentity;
1218 void player_powerups_remove_all(entity this);
1219
1220 void ClientDisconnect(entity this)
1221 {
1222         assert(IS_CLIENT(this), return);
1223
1224         PlayerStats_GameReport_FinalizePlayer(this);
1225         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1226         if (CS(this).active_minigame) part_minigame(this);
1227         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1228
1229         if (autocvar_sv_eventlog)
1230                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1231
1232         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1233
1234         if(IS_SPEC(this))
1235                 SetSpectatee(this, NULL);
1236
1237         MUTATOR_CALLHOOK(ClientDisconnect, this);
1238
1239         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1240         strfree(CS_CVAR(this).weaponorder_byimpulse);
1241         ClientState_detach(this);
1242
1243         Portal_ClearAll(this);
1244
1245         Unfreeze(this, false);
1246
1247         RemoveGrapplingHooks(this);
1248
1249         // Here, everything has been done that requires this player to be a client.
1250
1251         this.flags &= ~FL_CLIENT;
1252
1253         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1254         if (this.killindicator) delete(this.killindicator);
1255
1256         IL_EACH(g_counters, it.realowner == this,
1257         {
1258                 delete(it);
1259         });
1260
1261         WaypointSprite_PlayerGone(this);
1262
1263         bot_relinkplayerlist();
1264
1265         strfree(this.clientstatus);
1266         if (this.personal) delete(this.personal);
1267
1268         this.playerid = 0;
1269         ReadyCount();
1270         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1271
1272         player_powerups_remove_all(this); // stop powerup sound
1273
1274         ONREMOVE(this);
1275 }
1276
1277 void ChatBubbleThink(entity this)
1278 {
1279         this.nextthink = time;
1280         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1281         {
1282                 if(this.owner) // but why can that ever be NULL?
1283                         this.owner.chatbubbleentity = NULL;
1284                 delete(this);
1285                 return;
1286         }
1287
1288         this.mdl = "";
1289
1290         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1291         {
1292                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1293                         this.mdl = "models/sprites/minigame_busy.iqm";
1294                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1295                         this.mdl = "models/misc/chatbubble.spr";
1296         }
1297
1298         if ( this.model != this.mdl )
1299                 _setmodel(this, this.mdl);
1300
1301 }
1302
1303 void UpdateChatBubble(entity this)
1304 {
1305         if (this.alpha < 0)
1306                 return;
1307         // spawn a chatbubble entity if needed
1308         if (!this.chatbubbleentity)
1309         {
1310                 this.chatbubbleentity = new(chatbubbleentity);
1311                 this.chatbubbleentity.owner = this;
1312                 this.chatbubbleentity.exteriormodeltoclient = this;
1313                 setthink(this.chatbubbleentity, ChatBubbleThink);
1314                 this.chatbubbleentity.nextthink = time;
1315                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1316                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1317                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1318                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1319                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1320                 //this.chatbubbleentity.model = "";
1321                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1322         }
1323 }
1324
1325 void calculate_player_respawn_time(entity this)
1326 {
1327         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1328                 return;
1329
1330         float gametype_setting_tmp;
1331         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1332         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1333         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1334         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1335         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1336         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1337
1338         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1339         if (teamplay)
1340         {
1341                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1342                         if(it.team == this.team)
1343                                 ++pcount;
1344                 });
1345                 if (sdelay_small_count == 0)
1346                         sdelay_small_count = 1;
1347                 if (sdelay_large_count == 0)
1348                         sdelay_large_count = 1;
1349         }
1350         else
1351         {
1352                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1353                         ++pcount;
1354                 });
1355                 if (sdelay_small_count == 0)
1356                 {
1357                         if (IS_INDEPENDENT_PLAYER(this))
1358                         {
1359                                 // Players play independently. No point in requiring enemies.
1360                                 sdelay_small_count = 1;
1361                         }
1362                         else
1363                         {
1364                                 // Players play AGAINST each other. Enemies required.
1365                                 sdelay_small_count = 2;
1366                         }
1367                 }
1368                 if (sdelay_large_count == 0)
1369                 {
1370                         if (IS_INDEPENDENT_PLAYER(this))
1371                         {
1372                                 // Players play independently. No point in requiring enemies.
1373                                 sdelay_large_count = 1;
1374                         }
1375                         else
1376                         {
1377                                 // Players play AGAINST each other. Enemies required.
1378                                 sdelay_large_count = 2;
1379                         }
1380                 }
1381         }
1382
1383         float sdelay;
1384
1385         if (pcount <= sdelay_small_count)
1386                 sdelay = sdelay_small;
1387         else if (pcount >= sdelay_large_count)
1388                 sdelay = sdelay_large;
1389         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1390                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1391
1392         if(waves)
1393                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1394         else
1395                 this.respawn_time = time + sdelay;
1396
1397         if(sdelay < sdelay_max)
1398                 this.respawn_time_max = time + sdelay_max;
1399         else
1400                 this.respawn_time_max = this.respawn_time;
1401
1402         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1403                 this.respawn_countdown = 10; // first number to count down from is 10
1404         else
1405                 this.respawn_countdown = -1; // do not count down
1406
1407         if(autocvar_g_forced_respawn)
1408                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1409 }
1410
1411 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1412 // added to the model skins
1413 /*void UpdateColorModHack()
1414 {
1415         float c;
1416         c = this.clientcolors & 15;
1417         // LordHavoc: only bothering to support white, green, red, yellow, blue
1418              if (!teamplay) this.colormod = '0 0 0';
1419         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1420         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1421         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1422         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1423         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1424         else this.colormod = '1 1 1';
1425 }*/
1426
1427 void respawn(entity this)
1428 {
1429         bool damagedbycontents_prev = this.damagedbycontents;
1430         if(this.alpha >= 0)
1431         {
1432                 if(autocvar_g_respawn_ghosts)
1433                 {
1434                         this.solid = SOLID_NOT;
1435                         this.takedamage = DAMAGE_NO;
1436                         this.damagedbycontents = false;
1437                         set_movetype(this, MOVETYPE_FLY);
1438                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1439                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1440                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1441                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1442                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1443                         if(autocvar_g_respawn_ghosts_time > 0)
1444                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1445                 }
1446                 else
1447                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1448         }
1449
1450         CopyBody(this, 1);
1451         this.damagedbycontents = damagedbycontents_prev;
1452
1453         this.effects |= EF_NODRAW; // prevent another CopyBody
1454         PutClientInServer(this);
1455 }
1456
1457 void play_countdown(entity this, float finished, Sound samp)
1458 {
1459         TC(Sound, samp);
1460         float time_left = finished - time;
1461         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1462                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1463 }
1464
1465 // it removes special powerups not handled by StatusEffects
1466 void player_powerups_remove_all(entity this)
1467 {
1468         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1469         {
1470                 // don't play the poweroff sound when the game restarts or the player disconnects
1471                 if (time > game_starttime + 1 && IS_CLIENT(this)
1472                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1473                 {
1474                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1475                 }
1476                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1477                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1478                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1479         }
1480 }
1481
1482 void player_powerups(entity this)
1483 {
1484         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1485                 this.modelflags |= MF_ROCKET;
1486         else
1487                 this.modelflags &= ~MF_ROCKET;
1488
1489         this.effects &= ~EF_NODEPTHTEST;
1490
1491         if (IS_DEAD(this))
1492                 player_powerups_remove_all(this);
1493
1494         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1495                 return;
1496
1497         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1498         int items_prev = this.items;
1499
1500         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1501         {
1502                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1503                 if (this.items & IT_SUPERWEAPON)
1504                 {
1505                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1506                         {
1507                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1508                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1509                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1510                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1511                         }
1512                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1513                         {
1514                                 // don't let them run out
1515                         }
1516                         else
1517                         {
1518                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1519                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1520                                 {
1521                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1522                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1523                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1524                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1525                                 }
1526                         }
1527                 }
1528                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1529                 {
1530                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1531                         {
1532                                 this.items = this.items | IT_SUPERWEAPON;
1533                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1534                                 {
1535                                         if(!g_cts)
1536                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1537                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1538                                 }
1539                         }
1540                         else
1541                         {
1542                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1543                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1544                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1545                         }
1546                 }
1547                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1548                 {
1549                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1550                 }
1551         }
1552
1553         if(autocvar_g_nodepthtestplayers)
1554                 this.effects = this.effects | EF_NODEPTHTEST;
1555
1556         if(autocvar_g_fullbrightplayers)
1557                 this.effects = this.effects | EF_FULLBRIGHT;
1558
1559         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1560 }
1561
1562 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1563 {
1564         if(current > stable)
1565                 return current;
1566         else if(current > stable - 0.25) // when close enough, "snap"
1567                 return stable;
1568         else
1569                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1570 }
1571
1572 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1573 {
1574         if(current < stable)
1575                 return current;
1576         else if(current < stable + 0.25) // when close enough, "snap"
1577                 return stable;
1578         else
1579                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1580 }
1581
1582 void RotRegen(entity this, Resource res, float limit_mod,
1583         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1584         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1585 {
1586         float old = GetResource(this, res);
1587         float current = old;
1588         if(current > rotstable)
1589         {
1590                 if(rotframetime > 0)
1591                 {
1592                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1593                         current = max(rotstable, current - rotlinear * rotframetime);
1594                 }
1595         }
1596         else if(current < regenstable)
1597         {
1598                 if(regenframetime > 0)
1599                 {
1600                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1601                         current = min(regenstable, current + regenlinear * regenframetime);
1602                 }
1603         }
1604
1605         float limit = GetResourceLimit(this, res) * limit_mod;
1606         if(current > limit)
1607                 current = limit;
1608
1609         if (current != old)
1610                 SetResource(this, res, current);
1611 }
1612
1613 void player_regen(entity this)
1614 {
1615         float max_mod, regen_mod, rot_mod, limit_mod;
1616         max_mod = regen_mod = rot_mod = limit_mod = 1;
1617
1618         float regen_health = autocvar_g_balance_health_regen;
1619         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1620         float regen_health_rot = autocvar_g_balance_health_rot;
1621         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1622         float regen_health_stable = autocvar_g_balance_health_regenstable;
1623         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1624         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1625                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1626         max_mod = M_ARGV(1, float);
1627         regen_mod = M_ARGV(2, float);
1628         rot_mod = M_ARGV(3, float);
1629         limit_mod = M_ARGV(4, float);
1630         regen_health = M_ARGV(5, float);
1631         regen_health_linear = M_ARGV(6, float);
1632         regen_health_rot = M_ARGV(7, float);
1633         regen_health_rotlinear = M_ARGV(8, float);
1634         regen_health_stable = M_ARGV(9, float);
1635         regen_health_rotstable = M_ARGV(10, float);
1636
1637         float rotstable, regenstable, rotframetime, regenframetime;
1638
1639         if(!mutator_returnvalue)
1640         if(!STAT(FROZEN, this))
1641         {
1642                 regenstable = autocvar_g_balance_armor_regenstable;
1643                 rotstable = autocvar_g_balance_armor_rotstable;
1644                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1645                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1646                 RotRegen(this, RES_ARMOR, limit_mod,
1647                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1648                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1649
1650                 // NOTE: max_mod is only applied to health
1651                 regenstable = regen_health_stable * max_mod;
1652                 rotstable = regen_health_rotstable * max_mod;
1653                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1654                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1655                 RotRegen(this, RES_HEALTH, limit_mod,
1656                         regenstable, regen_health, regen_health_linear, regenframetime,
1657                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1658         }
1659
1660         // if player rotted to death...  die!
1661         // check this outside above checks, as player may still be able to rot to death
1662         if(GetResource(this, RES_HEALTH) < 1)
1663         {
1664                 if(this.vehicle)
1665                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1666                 if(this.event_damage)
1667                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1668         }
1669
1670         if (!(this.items & IT_UNLIMITED_AMMO))
1671         {
1672                 regenstable = autocvar_g_balance_fuel_regenstable;
1673                 rotstable = autocvar_g_balance_fuel_rotstable;
1674                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1675                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1676                 RotRegen(this, RES_FUEL, 1,
1677                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1678                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1679         }
1680 }
1681
1682 bool zoomstate_set;
1683 void SetZoomState(entity this, float newzoom)
1684 {
1685         if(newzoom != CS(this).zoomstate)
1686         {
1687                 CS(this).zoomstate = newzoom;
1688                 ClientData_Touch(this);
1689         }
1690         zoomstate_set = true;
1691 }
1692
1693 void GetPressedKeys(entity this)
1694 {
1695         MUTATOR_CALLHOOK(GetPressedKeys, this);
1696         if (game_stopped)
1697         {
1698                 CS(this).pressedkeys = 0;
1699                 STAT(PRESSED_KEYS, this) = 0;
1700                 return;
1701         }
1702
1703         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1704         int keys = STAT(PRESSED_KEYS, this);
1705         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1706         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1707         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1708         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1709
1710         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1711         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1712         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1713         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1714         CS(this).pressedkeys = keys; // store for other users
1715
1716         STAT(PRESSED_KEYS, this) = keys;
1717 }
1718
1719 /*
1720 ======================
1721 spectate mode routines
1722 ======================
1723 */
1724
1725 void SpectateCopy(entity this, entity spectatee)
1726 {
1727         TC(Client, this); TC(Client, spectatee);
1728
1729         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1730         PS(this) = PS(spectatee);
1731         this.armortype = spectatee.armortype;
1732         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1733         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1734         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1735         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1736         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1737         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1738         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1739         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1740         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1741         CS(this).impulse = 0;
1742         this.disableclientprediction = 1; // no need to run prediction on a spectator
1743         this.items = spectatee.items;
1744         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1745         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1746         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1747         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1748         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1749         this.punchangle = spectatee.punchangle;
1750         this.view_ofs = spectatee.view_ofs;
1751         this.velocity = spectatee.velocity;
1752         this.dmg_take = spectatee.dmg_take;
1753         this.dmg_save = spectatee.dmg_save;
1754         this.dmg_inflictor = spectatee.dmg_inflictor;
1755         this.v_angle = spectatee.v_angle;
1756         this.angles = spectatee.v_angle;
1757         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1758         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1759         this.viewloc = spectatee.viewloc;
1760         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1761                 this.fixangle = true;
1762         setorigin(this, spectatee.origin);
1763         setsize(this, spectatee.mins, spectatee.maxs);
1764         SetZoomState(this, CS(spectatee).zoomstate);
1765
1766     anticheat_spectatecopy(this, spectatee);
1767         STAT(HUD, this) = STAT(HUD, spectatee);
1768         if(spectatee.vehicle)
1769     {
1770         this.angles = spectatee.v_angle;
1771
1772         //this.fixangle = false;
1773         //this.velocity = spectatee.vehicle.velocity;
1774         this.vehicle_health = spectatee.vehicle_health;
1775         this.vehicle_shield = spectatee.vehicle_shield;
1776         this.vehicle_energy = spectatee.vehicle_energy;
1777         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1778         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1779         this.vehicle_reload1 = spectatee.vehicle_reload1;
1780         this.vehicle_reload2 = spectatee.vehicle_reload2;
1781
1782         //msg_entity = this;
1783
1784        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1785             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1786            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1787            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1788
1789         //WriteByte (MSG_ONE, SVC_SETVIEW);
1790         //    WriteEntity(MSG_ONE, this);
1791         //makevectors(spectatee.v_angle);
1792         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1793     }
1794 }
1795
1796 bool SpectateUpdate(entity this)
1797 {
1798         if(!this.enemy)
1799                 return false;
1800
1801         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1802         {
1803                 SetSpectatee(this, NULL);
1804                 return false;
1805         }
1806
1807         SpectateCopy(this, this.enemy);
1808
1809         return true;
1810 }
1811
1812 bool SpectateSet(entity this)
1813 {
1814         if(!IS_PLAYER(this.enemy))
1815                 return false;
1816
1817         ClientData_Touch(this.enemy);
1818
1819         msg_entity = this;
1820         WriteByte(MSG_ONE, SVC_SETVIEW);
1821         WriteEntity(MSG_ONE, this.enemy);
1822         set_movetype(this, MOVETYPE_NONE);
1823         accuracy_resend(this);
1824
1825         if(!SpectateUpdate(this))
1826                 PutObserverInServer(this, false, true);
1827
1828         return true;
1829 }
1830
1831 void SetSpectatee_status(entity this, int spectatee_num)
1832 {
1833         int oldspectatee_status = CS(this).spectatee_status;
1834         CS(this).spectatee_status = spectatee_num;
1835
1836         if (CS(this).spectatee_status != oldspectatee_status)
1837         {
1838                 if (STAT(PRESSED_KEYS, this))
1839                 {
1840                         CS(this).pressedkeys = 0;
1841                         STAT(PRESSED_KEYS, this) = 0;
1842                 }
1843                 ClientData_Touch(this);
1844                 if (g_race || g_cts) race_InitSpectator();
1845         }
1846 }
1847
1848 void SetSpectatee(entity this, entity spectatee)
1849 {
1850         if(IS_BOT_CLIENT(this))
1851                 return; // bots abuse .enemy, this code is useless to them
1852
1853         entity old_spectatee = this.enemy;
1854
1855         this.enemy = spectatee;
1856
1857         // WEAPONTODO
1858         // these are required to fix the spectator bug with arc
1859         if(old_spectatee)
1860         {
1861                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1862                 {
1863                         .entity weaponentity = weaponentities[slot];
1864                         if(old_spectatee.(weaponentity).arc_beam)
1865                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1866                 }
1867         }
1868         if(spectatee)
1869         {
1870                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1871                 {
1872                         .entity weaponentity = weaponentities[slot];
1873                         if(spectatee.(weaponentity).arc_beam)
1874                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1875                 }
1876         }
1877
1878         if (spectatee)
1879                 SetSpectatee_status(this, etof(spectatee));
1880
1881         // needed to update spectator list
1882         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1883 }
1884
1885 bool Spectate(entity this, entity pl)
1886 {
1887         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1888                 return false;
1889         pl = M_ARGV(1, entity);
1890
1891         SetSpectatee(this, pl);
1892         return SpectateSet(this);
1893 }
1894
1895 bool SpectateNext(entity this)
1896 {
1897         entity ent = find(this.enemy, classname, STR_PLAYER);
1898
1899         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1900                 ent = M_ARGV(1, entity);
1901         else if (!ent)
1902                 ent = find(ent, classname, STR_PLAYER);
1903
1904         if(ent) { SetSpectatee(this, ent); }
1905
1906         return SpectateSet(this);
1907 }
1908
1909 bool SpectatePrev(entity this)
1910 {
1911         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1912         entity ent = findchain(classname, STR_PLAYER);
1913         if (!ent) // no player
1914                 return false;
1915
1916         entity first = ent;
1917         // skip players until current spectated player
1918         if(this.enemy)
1919         while(ent && ent != this.enemy)
1920                 ent = ent.chain;
1921
1922         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1923         {
1924                 case MUT_SPECPREV_FOUND:
1925                         ent = M_ARGV(1, entity);
1926                         break;
1927                 case MUT_SPECPREV_RETURN:
1928                         return true;
1929                 case MUT_SPECPREV_CONTINUE:
1930                 default:
1931                 {
1932                         if(ent.chain)
1933                                 ent = ent.chain;
1934                         else
1935                                 ent = first;
1936                         break;
1937                 }
1938         }
1939
1940         SetSpectatee(this, ent);
1941         return SpectateSet(this);
1942 }
1943
1944 /*
1945 =============
1946 ShowRespawnCountdown()
1947
1948 Update a respawn countdown display.
1949 =============
1950 */
1951 void ShowRespawnCountdown(entity this)
1952 {
1953         float number;
1954         if(!IS_DEAD(this)) // just respawned?
1955                 return;
1956         else
1957         {
1958                 number = ceil(this.respawn_time - time);
1959                 if(number <= 0)
1960                         return;
1961                 if(number <= this.respawn_countdown)
1962                 {
1963                         this.respawn_countdown = number - 1;
1964                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1965                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1966                 }
1967         }
1968 }
1969
1970 .bool team_selected;
1971 bool ShowTeamSelection(entity this)
1972 {
1973         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1974                 return false;
1975         stuffcmd(this, "menu_showteamselect\n");
1976         return true;
1977 }
1978 void Join(entity this)
1979 {
1980         TRANSMUTE(Player, this);
1981
1982         if(!this.team_selected)
1983         if(autocvar_g_campaign || autocvar_g_balance_teams)
1984                 TeamBalance_JoinBestTeam(this);
1985
1986         if(autocvar_g_campaign)
1987                 campaign_bots_may_start = true;
1988
1989         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1990
1991         PutClientInServer(this);
1992
1993         if(IS_PLAYER(this))
1994         if(teamplay && this.team != -1)
1995         {
1996         }
1997         else
1998                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1999         this.team_selected = false;
2000 }
2001
2002 int GetPlayerLimit()
2003 {
2004         if(g_duel)
2005                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2006         int player_limit = autocvar_g_maxplayers;
2007         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2008         player_limit = M_ARGV(0, int);
2009         return player_limit;
2010 }
2011
2012 /**
2013  * Determines whether the player is allowed to join. This depends on cvar
2014  * g_maxplayers, if it isn't used this function always return true, otherwise
2015  * it checks whether the number of currently playing players exceeds g_maxplayers.
2016  * @return int number of free slots for players, 0 if none
2017  */
2018 int nJoinAllowed(entity this, entity ignore)
2019 {
2020         if(!ignore)
2021         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2022         // so report 0 free slots if restricted
2023         {
2024                 if(autocvar_g_forced_team_otherwise == "spectate")
2025                         return 0;
2026                 if(autocvar_g_forced_team_otherwise == "spectator")
2027                         return 0;
2028         }
2029
2030         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2031                 return 0; // forced spectators can never join
2032
2033         // TODO simplify this
2034         int totalClients = 0;
2035         int currentlyPlaying = 0;
2036         FOREACH_CLIENT(true, {
2037                 if(it != ignore)
2038                         ++totalClients;
2039                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2040                         ++currentlyPlaying;
2041         });
2042
2043         int player_limit = GetPlayerLimit();
2044
2045         int free_slots = 0;
2046         if (!player_limit)
2047                 free_slots = maxclients - totalClients;
2048         else if(player_limit > 0 && currentlyPlaying < player_limit)
2049                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2050
2051         static float msg_time = 0;
2052         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2053         {
2054                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2055                 msg_time = time + 0.5;
2056         }
2057
2058         return free_slots;
2059 }
2060
2061 void PrintWelcomeMessage(entity this)
2062 {
2063         if(CS(this).motd_actived_time == 0)
2064         {
2065                 if (autocvar_g_campaign) {
2066                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2067                                 CS(this).motd_actived_time = time;
2068                                 SendWelcomemessage(this, false);
2069                         }
2070                 } else {
2071                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2072                                 CS(this).motd_actived_time = time;
2073                                 SendWelcomemessage(this, true);
2074                         }
2075                 }
2076         }
2077         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2078         {
2079                 if (autocvar_g_campaign) {
2080                         if (PHYS_INPUT_BUTTON_INFO(this))
2081                                 CS(this).motd_actived_time = time;
2082                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2083                                 CS(this).motd_actived_time = 0;
2084                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2085                         }
2086                 } else {
2087                         if (PHYS_INPUT_BUTTON_INFO(this))
2088                                 CS(this).motd_actived_time = time;
2089                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2090                                 CS(this).motd_actived_time = 0;
2091                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2092                         }
2093                 }
2094         }
2095         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2096         {
2097                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2098                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2099                 else if (CS(this).motd_actived_time == -2)
2100                 {
2101                         // instantly hide MOTD
2102                         CS(this).motd_actived_time = 0;
2103                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2104                 }
2105                 else if (IS_PLAYER(this) || IS_SPEC(this))
2106                 {
2107                         // FIXME occasionally for some reason MOTD never goes away
2108                         // delay MOTD removal a little bit in the hope it fixes this bug
2109                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2110                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2111                         else //if (CS(this).motd_actived_time < -2)
2112                                 CS(this).motd_actived_time++;
2113                 }
2114         }
2115 }
2116
2117 bool joinAllowed(entity this)
2118 {
2119         if (CS(this).version_mismatch) return false;
2120         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2121         if (!nJoinAllowed(this, this)) return false;
2122         if (teamplay && lockteams) return false;
2123         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2124         if (ShowTeamSelection(this)) return false;
2125         return true;
2126 }
2127
2128 .string shootfromfixedorigin;
2129 .bool dualwielding_prev;
2130 bool PlayerThink(entity this)
2131 {
2132         if (game_stopped || intermission_running) {
2133                 this.modelflags &= ~MF_ROCKET;
2134                 if(intermission_running)
2135                         IntermissionThink(this);
2136                 return false;
2137         }
2138
2139         if (timeout_status == TIMEOUT_ACTIVE) {
2140                 // don't allow the player to turn around while game is paused
2141                 // FIXME turn this into CSQC stuff
2142                 this.v_angle = this.lastV_angle;
2143                 this.angles = this.lastV_angle;
2144                 this.fixangle = true;
2145         }
2146
2147         if (frametime) player_powerups(this);
2148
2149         if (IS_DEAD(this)) {
2150                 if (this.personal && g_race_qualifying) {
2151                         if (time > this.respawn_time) {
2152                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2153                                 respawn(this);
2154                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2155                         }
2156                 } else {
2157                         if (frametime) player_anim(this);
2158
2159                         if (this.respawn_flags & RESPAWN_DENY)
2160                         {
2161                                 STAT(RESPAWN_TIME, this) = 0;
2162                                 return false;
2163                         }
2164
2165                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2166
2167                         switch(this.deadflag)
2168                         {
2169                                 case DEAD_DYING:
2170                                 {
2171                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2172                                                 this.deadflag = DEAD_RESPAWNING;
2173                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2174                                                 this.deadflag = DEAD_DEAD;
2175                                         break;
2176                                 }
2177                                 case DEAD_DEAD:
2178                                 {
2179                                         if (button_pressed)
2180                                                 this.deadflag = DEAD_RESPAWNABLE;
2181                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2182                                                 this.deadflag = DEAD_RESPAWNING;
2183                                         break;
2184                                 }
2185                                 case DEAD_RESPAWNABLE:
2186                                 {
2187                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2188                                                 this.deadflag = DEAD_RESPAWNING;
2189                                         break;
2190                                 }
2191                                 case DEAD_RESPAWNING:
2192                                 {
2193                                         if (time > this.respawn_time)
2194                                         {
2195                                                 this.respawn_time = time + 1; // only retry once a second
2196                                                 this.respawn_time_max = this.respawn_time;
2197                                                 respawn(this);
2198                                         }
2199                                         break;
2200                                 }
2201                         }
2202
2203                         ShowRespawnCountdown(this);
2204
2205                         if (this.respawn_flags & RESPAWN_SILENT)
2206                                 STAT(RESPAWN_TIME, this) = 0;
2207                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2208                         {
2209                                 if (time < this.respawn_time)
2210                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2211                                 else if (this.deadflag != DEAD_RESPAWNING)
2212                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2213                         }
2214                         else
2215                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2216                 }
2217
2218                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2219                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2220                         STAT(RESPAWN_TIME, this) *= -1;
2221
2222                 return false;
2223         }
2224
2225         FixPlayermodel(this);
2226
2227         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2228                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2229                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2230         }
2231
2232         // reset gun alignment when dual wielding status changes
2233         // to ensure guns are always aligned right and left
2234         bool dualwielding = W_DualWielding(this);
2235         if(this.dualwielding_prev != dualwielding)
2236         {
2237                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2238                 this.dualwielding_prev = dualwielding;
2239         }
2240
2241         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2242         //if(frametime)
2243         {
2244                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2245                 {
2246                         .entity weaponentity = weaponentities[slot];
2247                         if(WEP_CVAR(vortex, charge_always))
2248                                 W_Vortex_Charge(this, weaponentity, frametime);
2249                         W_WeaponFrame(this, weaponentity);
2250                 }
2251         }
2252
2253         if (frametime)
2254         {
2255                 // WEAPONTODO: Add a weapon request for this
2256                 // rot vortex charge to the charge limit
2257                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2258                 {
2259                         .entity weaponentity = weaponentities[slot];
2260                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2261                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2262                 }
2263
2264                 player_regen(this);
2265                 player_anim(this);
2266                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2267         }
2268
2269         monsters_setstatus(this);
2270
2271         return true;
2272 }
2273
2274 .bool would_spectate;
2275 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2276 void ObserverOrSpectatorThink(entity this)
2277 {
2278         bool is_spec = IS_SPEC(this);
2279         if ( CS(this).impulse )
2280         {
2281                 int r = MinigameImpulse(this, CS(this).impulse);
2282                 if (!is_spec || r)
2283                         CS(this).impulse = 0;
2284
2285                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2286                 {
2287                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2288                         CS(this).impulse = 0;
2289                         return;
2290                 }
2291         }
2292
2293         if (this.flags & FL_JUMPRELEASED) {
2294                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2295                         this.flags &= ~FL_JUMPRELEASED;
2296                         this.flags |= FL_SPAWNING;
2297                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2298                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2299                         this.flags &= ~FL_JUMPRELEASED;
2300                         if(SpectateNext(this)) {
2301                                 TRANSMUTE(Spectator, this);
2302                         } else if (is_spec) {
2303                                 TRANSMUTE(Observer, this);
2304                                 PutClientInServer(this);
2305                         }
2306                         else
2307                                 this.would_spectate = false; // unable to spectate anyone
2308                         if (is_spec)
2309                                 CS(this).impulse = 0;
2310                 } else if (is_spec) {
2311                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2312                                 this.flags &= ~FL_JUMPRELEASED;
2313                                 if(SpectatePrev(this)) {
2314                                         TRANSMUTE(Spectator, this);
2315                                 } else {
2316                                         TRANSMUTE(Observer, this);
2317                                         PutClientInServer(this);
2318                                 }
2319                                 CS(this).impulse = 0;
2320                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2321                                 this.would_spectate = false;
2322                                 this.flags &= ~FL_JUMPRELEASED;
2323                                 TRANSMUTE(Observer, this);
2324                                 PutClientInServer(this);
2325                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2326                                 PutObserverInServer(this, false, true);
2327                                 this.would_spectate = true;
2328                         }
2329                 }
2330                 else {
2331                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2332                         if (PHYS_INPUT_BUTTON_USE(this))
2333                                 wouldclip = !wouldclip;
2334                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2335                         set_movetype(this, preferred_movetype);
2336                 }
2337         } else { // jump pressed
2338                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2339                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2340                         this.flags |= FL_JUMPRELEASED;
2341                         if(this.flags & FL_SPAWNING)
2342                         {
2343                                 this.flags &= ~FL_SPAWNING;
2344                                 if(joinAllowed(this))
2345                                         Join(this);
2346                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2347                                         CS(this).autojoin_checked = -1;
2348                                 return;
2349                         }
2350                 }
2351                 if(is_spec && !SpectateUpdate(this))
2352                         PutObserverInServer(this, false, true);
2353         }
2354         if (is_spec)
2355                 this.flags |= FL_CLIENT | FL_NOTARGET;
2356 }
2357
2358 void PlayerUseKey(entity this)
2359 {
2360         if (!IS_PLAYER(this))
2361                 return;
2362
2363         if(this.vehicle)
2364         {
2365                 if(!game_stopped)
2366                 {
2367                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2368                         return;
2369                 }
2370         }
2371         else if(autocvar_g_vehicles_enter)
2372         {
2373                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2374                 {
2375                         entity head, closest_target = NULL;
2376                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2377
2378                         while(head) // find the closest acceptable target to enter
2379                         {
2380                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2381                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2382                                 {
2383                                         if(closest_target)
2384                                         {
2385                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2386                                                 { closest_target = head; }
2387                                         }
2388                                         else { closest_target = head; }
2389                                 }
2390
2391                                 head = head.chain;
2392                         }
2393
2394                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2395                 }
2396         }
2397
2398         // a use key was pressed; call handlers
2399         MUTATOR_CALLHOOK(PlayerUseKey, this);
2400 }
2401
2402
2403 /*
2404 =============
2405 PlayerPreThink
2406
2407 Called every frame for each client before the physics are run
2408 =============
2409 */
2410 .float last_vehiclecheck;
2411 void PlayerPreThink (entity this)
2412 {
2413         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2414         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2415
2416         WarpZone_PlayerPhysics_FixVAngle(this);
2417
2418         if (frametime) {
2419                 // physics frames: update anticheat stuff
2420                 anticheat_prethink(this);
2421
2422                 // WORKAROUND: only use dropclient in server frames (frametime set).
2423                 // Never use it in cl_movement frames (frametime zero).
2424                 if (blockSpectators && IS_REAL_CLIENT(this)
2425                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2426                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2427                 {
2428                         if (dropclient_schedule(this))
2429                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2430                 }
2431         }
2432
2433         zoomstate_set = false;
2434
2435         // Check for nameless players
2436         if (this.netname == "" || this.netname != CS(this).netname_previous)
2437         {
2438                 bool assume_unchanged = (CS(this).netname_previous == "");
2439                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2440                 {
2441                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2442                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2443                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2444                         assume_unchanged = false;
2445                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2446                 }
2447                 if (isInvisibleString(this.netname))
2448                 {
2449                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2450                         sprint(this, "Warning: invisible names are not allowed.\n");
2451                         assume_unchanged = false;
2452                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2453                 }
2454                 if (!assume_unchanged && autocvar_sv_eventlog)
2455                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2456                 strcpy(CS(this).netname_previous, this.netname);
2457         }
2458
2459         // version nagging
2460         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2461         CS(this).version_nagtime = 0;
2462         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2463             // git client
2464         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2465             // git server
2466             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2467         } else {
2468             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2469             if (r < 0) { // old client
2470                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2471             } else if (r > 0) { // old server
2472                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2473             }
2474         }
2475     }
2476
2477         // GOD MODE info
2478         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2479         {
2480                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2481                 this.max_armorvalue = 0;
2482         }
2483
2484         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2485         {
2486                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2487                 {
2488                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2489                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2490                         if (this.iceblock)
2491                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2492
2493                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2494                                 Unfreeze(this, false);
2495                 }
2496                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2497                 {
2498                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2499                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2500
2501                         if (GetResource(this, RES_HEALTH) < 1)
2502                         {
2503                                 if (this.vehicle)
2504                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2505                                 if(this.event_damage)
2506                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2507                         }
2508                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2509                                 Unfreeze(this, false);
2510                 }
2511         }
2512
2513         MUTATOR_CALLHOOK(PlayerPreThink, this);
2514
2515         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2516         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2517         {
2518                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2519                 {
2520                         if(!it.owner)
2521                         {
2522                                 if(!it.team || SAME_TEAM(this, it))
2523                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2524                                 else if(autocvar_g_vehicles_steal)
2525                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2526                         }
2527                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2528                         {
2529                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2530                         }
2531                 });
2532
2533                 this.last_vehiclecheck = time + 1;
2534         }
2535
2536         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2537                 PlayerUseKey(this);
2538         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2539
2540         if (IS_REAL_CLIENT(this))
2541                 PrintWelcomeMessage(this);
2542
2543         if (IS_PLAYER(this)) {
2544                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2545                         error("Client can't be spawned as player on connection!");
2546                 if(!PlayerThink(this))
2547                         return;
2548         }
2549         else if (game_stopped || intermission_running) {
2550                 if(intermission_running)
2551                         IntermissionThink(this);
2552                 return;
2553         }
2554         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2555         {
2556                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2557                 CS(this).autojoin_checked = 1;
2558                 // don't do this in ClientConnect
2559                 // many things can go wrong if a client is spawned as player on connection
2560                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2561                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2562                                 && (!teamplay || autocvar_g_balance_teams)))
2563                 {
2564                         campaign_bots_may_start = true;
2565                         if(joinAllowed(this))
2566                                 Join(this);
2567                         return;
2568                 }
2569         }
2570         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2571                 ObserverOrSpectatorThink(this);
2572         }
2573
2574         // WEAPONTODO: Add weapon request for this
2575         if (!zoomstate_set) {
2576                 bool wep_zoomed = false;
2577                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2578                 {
2579                         .entity weaponentity = weaponentities[slot];
2580                         Weapon thiswep = this.(weaponentity).m_weapon;
2581                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2582                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2583                 }
2584                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2585         }
2586
2587         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2588         {
2589                 CS(this).teamkill_soundtime = 0;
2590
2591                 entity e = CS(this).teamkill_soundsource;
2592                 entity oldpusher = e.pusher;
2593                 e.pusher = this;
2594                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2595                 e.pusher = oldpusher;
2596         }
2597
2598         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2599                 CS(this).taunt_soundtime = 0;
2600                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2601         }
2602
2603         target_voicescript_next(this);
2604 }
2605
2606 void DrownPlayer(entity this)
2607 {
2608         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2609                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2610         {
2611                 STAT(AIR_FINISHED, this) = 0;
2612                 return;
2613         }
2614
2615         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2616         {
2617                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2618                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2619                 STAT(AIR_FINISHED, this) = 0;
2620         }
2621         else
2622         {
2623                 if (!STAT(AIR_FINISHED, this))
2624                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2625                 if (STAT(AIR_FINISHED, this) < time)
2626                 {       // drown!
2627                         if (this.pain_finished < time)
2628                         {
2629                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2630                                 this.pain_finished = time + 0.5;
2631                         }
2632                 }
2633         }
2634 }
2635
2636 .bool move_qcphysics;
2637
2638 void Player_Physics(entity this)
2639 {
2640         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2641
2642         if(!this.move_qcphysics)
2643                 return;
2644
2645         if(!frametime && !CS(this).pm_frametime)
2646                 return;
2647
2648         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2649
2650         CS(this).pm_frametime = 0;
2651 }
2652
2653 /*
2654 =============
2655 PlayerPostThink
2656
2657 Called every frame for each client after the physics are run
2658 =============
2659 */
2660 void PlayerPostThink (entity this)
2661 {
2662         Player_Physics(this);
2663
2664         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2665         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2666         if (IS_REAL_CLIENT(this))
2667         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2668         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2669         {
2670                 int totalClients = 0;
2671                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2672                 {
2673                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2674                         if (server_is_dedicated)
2675                         {
2676                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2677                                 {
2678                                         ++totalClients;
2679                                 });
2680                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2681                                         totalClients = 0;
2682                         }
2683                 }
2684                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2685                 {
2686                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2687                         {
2688                                 ++totalClients;
2689                         });
2690                 }
2691
2692                 if (totalClients < autocvar_sv_maxidle_minplayers)
2693                 {
2694                         // idle kick disabled
2695                         CS(this).parm_idlesince = time;
2696                 }
2697                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2698                 {
2699                         if (CS(this).idlekick_lasttimeleft)
2700                         {
2701                                 CS(this).idlekick_lasttimeleft = 0;
2702                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2703                         }
2704                 }
2705                 else
2706                 {
2707                         float maxidle_time = autocvar_sv_maxidle;
2708                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2709                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2710                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2711                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2712                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2713                         {
2714                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2715                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2716                                 else
2717                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2718                         }
2719                         if (timeleft <= 0) {
2720                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2721                                 {
2722                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2723                                         PutObserverInServer(this, true, true);
2724                                 }
2725                                 else
2726                                 {
2727                                         if (dropclient_schedule(this))
2728                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2729                                 }
2730                                 return;
2731                         }
2732                         else if (timeleft <= countdown_time) {
2733                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2734                                         play2(this, SND(TALK2));
2735                                 CS(this).idlekick_lasttimeleft = timeleft;
2736                         }
2737                 }
2738         }
2739
2740         CheatFrame(this);
2741
2742         if (game_stopped)
2743         {
2744                 this.solid = SOLID_NOT;
2745                 this.takedamage = DAMAGE_NO;
2746                 set_movetype(this, MOVETYPE_NONE);
2747                 CS(this).teamkill_complain = 0;
2748                 CS(this).teamkill_soundtime = 0;
2749                 CS(this).teamkill_soundsource = NULL;
2750         }
2751
2752         if (IS_PLAYER(this)) {
2753                 if(this.death_time == time && IS_DEAD(this))
2754                 {
2755                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2756                         // once all the damage events of this frame have been processed with normal size
2757                         this.maxs.z = 5;
2758                         setsize(this, this.mins, this.maxs);
2759                 }
2760                 DrownPlayer(this);
2761                 UpdateChatBubble(this);
2762                 if (CS(this).impulse) ImpulseCommands(this);
2763                 GetPressedKeys(this);
2764                 if (game_stopped)
2765                 {
2766                         CSQCMODEL_AUTOUPDATE(this);
2767                         return;
2768                 }
2769         }
2770         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2771         {
2772                 CS(this).pressedkeys = 0;
2773                 STAT(PRESSED_KEYS, this) = 0;
2774         }
2775
2776         if (this.waypointsprite_attachedforcarrier) {
2777                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2778                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2779         }
2780
2781         CSQCMODEL_AUTOUPDATE(this);
2782 }
2783
2784 // hack to copy the button fields from the client entity to the Client State
2785 void PM_UpdateButtons(entity this, entity store)
2786 {
2787         if(this.impulse)
2788                 store.impulse = this.impulse;
2789         this.impulse = 0;
2790
2791         bool typing = this.buttonchat || this.button12;
2792
2793         store.button0 = (typing) ? 0 : this.button0;
2794         //button1?!
2795         store.button2 = (typing) ? 0 : this.button2;
2796         store.button3 = (typing) ? 0 : this.button3;
2797         store.button4 = this.button4;
2798         store.button5 = (typing) ? 0 : this.button5;
2799         store.button6 = this.button6;
2800         store.button7 = this.button7;
2801         store.button8 = this.button8;
2802         store.button9 = this.button9;
2803         store.button10 = this.button10;
2804         store.button11 = this.button11;
2805         store.button12 = this.button12;
2806         store.button13 = this.button13;
2807         store.button14 = this.button14;
2808         store.button15 = this.button15;
2809         store.button16 = this.button16;
2810         store.buttonuse = this.buttonuse;
2811         store.buttonchat = this.buttonchat;
2812
2813         store.cursor_active = this.cursor_active;
2814         store.cursor_screen = this.cursor_screen;
2815         store.cursor_trace_start = this.cursor_trace_start;
2816         store.cursor_trace_endpos = this.cursor_trace_endpos;
2817         store.cursor_trace_ent = this.cursor_trace_ent;
2818
2819         store.ping = this.ping;
2820         store.ping_packetloss = this.ping_packetloss;
2821         store.ping_movementloss = this.ping_movementloss;
2822
2823         store.v_angle = this.v_angle;
2824         store.movement = this.movement;
2825 }
2826
2827 NET_HANDLE(fpsreport, bool)
2828 {
2829         int fps = ReadShort();
2830         PlayerScore_Set(sender, SP_FPS, fps);
2831         return true;
2832 }