95f28752714a9c322ebfb08ba67cf0ffbcb930e6
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include "anticheat.qh"
4 #include "impulse.qh"
5 #include "player.qh"
6 #include "ipban.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "playerdemo.qh"
11 #include "spawnpoints.qh"
12 #include "g_damage.qh"
13 #include "g_hook.qh"
14 #include "command/common.qh"
15 #include "cheats.qh"
16 #include "g_world.qh"
17 #include "race.qh"
18 #include "antilag.qh"
19 #include "campaign.qh"
20 #include "command/common.qh"
21 #include "scores_rules.qh"
22
23 #include "bot/api.qh"
24
25 #include "../common/ent_cs.qh"
26 #include "../common/wepent.qh"
27 #include <common/state.qh>
28
29 #include <common/effects/qc/globalsound.qh>
30
31 #include "../common/triggers/func/conveyor.qh"
32 #include "../common/triggers/teleporters.qh"
33
34 #include "../common/vehicles/all.qh"
35
36 #include "weapons/hitplot.qh"
37 #include "weapons/weaponsystem.qh"
38
39 #include "../common/net_notice.qh"
40 #include "../common/net_linked.qh"
41 #include "../common/physics/player.qh"
42
43 #include "../common/items/_mod.qh"
44
45 #include "../common/mutators/mutator/waypoints/all.qh"
46
47 #include "../common/triggers/subs.qh"
48 #include "../common/triggers/triggers.qh"
49 #include "../common/triggers/trigger/secret.qh"
50
51 #include "../common/minigames/sv_minigames.qh"
52
53 #include "../common/items/inventory.qh"
54
55 #include "../common/monsters/sv_monsters.qh"
56
57 #include "../lib/warpzone/server.qh"
58
59 STATIC_METHOD(Client, Add, void(Client this, int _team))
60 {
61     ClientConnect(this);
62     TRANSMUTE(Player, this);
63     this.frame = 12; // 7
64     this.team = _team;
65     PutClientInServer(this);
66 }
67
68 void PutObserverInServer(entity this);
69
70 STATIC_METHOD(Client, Remove, void(Client this))
71 {
72     TRANSMUTE(Observer, this);
73     PutClientInServer(this);
74     ClientDisconnect(this);
75 }
76
77 void send_CSQC_teamnagger() {
78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
79 }
80
81 int CountSpectators(entity player, entity to)
82 {
83         if(!player) { return 0; } // not sure how, but best to be safe
84
85         int spec_count = 0;
86
87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
88         {
89                 spec_count++;
90         });
91
92         return spec_count;
93 }
94
95 void WriteSpectators(entity player, entity to)
96 {
97         if(!player) { return; } // not sure how, but best to be safe
98
99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
100         {
101                 WriteByte(MSG_ENTITY, num_for_edict(it));
102         });
103 }
104
105 bool ClientData_Send(entity this, entity to, int sf)
106 {
107         assert(to == this.owner, return false);
108
109         entity e = to;
110         if (IS_SPEC(e)) e = e.enemy;
111
112         sf = 0;
113         if (e.race_completed)       sf |= 1; // forced scoreboard
114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
115         if (e.zoomstate)            sf |= 4; // zoomed
116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
117
118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
119         WriteByte(MSG_ENTITY, sf);
120
121         if (sf & 2)
122         {
123                 WriteByte(MSG_ENTITY, to.spectatee_status);
124         }
125
126         if(sf & 16)
127         {
128                 float specs = CountSpectators(e, to);
129                 WriteByte(MSG_ENTITY, specs);
130                 WriteSpectators(e, to);
131         }
132
133         return true;
134 }
135
136 void ClientData_Attach(entity this)
137 {
138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
139         this.clientdata.drawonlytoclient = this;
140         this.clientdata.owner = this;
141 }
142
143 void ClientData_Detach(entity this)
144 {
145         delete(this.clientdata);
146         this.clientdata = NULL;
147 }
148
149 void ClientData_Touch(entity e)
150 {
151         e.clientdata.SendFlags = 1;
152
153         // make it spectatable
154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
155 }
156
157 .string netname_previous;
158
159 void SetSpectatee(entity this, entity spectatee);
160 void SetSpectatee_status(entity this, int spectatee_num);
161
162
163 /*
164 =============
165 CheckPlayerModel
166
167 Checks if the argument string can be a valid playermodel.
168 Returns a valid one in doubt.
169 =============
170 */
171 string FallbackPlayerModel;
172 string CheckPlayerModel(string plyermodel) {
173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
174         {
175                 // note: we cannot summon Don Strunzone here, some player may
176                 // still have the model string set. In case anyone manages how
177                 // to change a cvar default, we'll have a small leak here.
178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
179         }
180         // only in right path
181         if( substring(plyermodel,0,14) != "models/player/")
182                 return FallbackPlayerModel;
183         // only good file extensions
184         if(substring(plyermodel,-4,4) != ".zym")
185         if(substring(plyermodel,-4,4) != ".dpm")
186         if(substring(plyermodel,-4,4) != ".iqm")
187         if(substring(plyermodel,-4,4) != ".md3")
188         if(substring(plyermodel,-4,4) != ".psk")
189                 return FallbackPlayerModel;
190         // forbid the LOD models
191         if(substring(plyermodel, -9,5) == "_lod1")
192                 return FallbackPlayerModel;
193         if(substring(plyermodel, -9,5) == "_lod2")
194                 return FallbackPlayerModel;
195         if(plyermodel != strtolower(plyermodel))
196                 return FallbackPlayerModel;
197         // also, restrict to server models
198         if(autocvar_sv_servermodelsonly)
199         {
200                 if(!fexists(plyermodel))
201                         return FallbackPlayerModel;
202         }
203         return plyermodel;
204 }
205
206 void setplayermodel(entity e, string modelname)
207 {
208         precache_model(modelname);
209         _setmodel(e, modelname);
210         player_setupanimsformodel(e);
211         if(!autocvar_g_debug_globalsounds)
212                 UpdatePlayerSounds(e);
213 }
214
215 void FixPlayermodel(entity player);
216 /** putting a client as observer in the server */
217 void PutObserverInServer(entity this)
218 {
219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
220         PlayerState_detach(this);
221
222         if (IS_PLAYER(this) && this.health >= 1) {
223         // despawn effect
224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
225     }
226
227     {
228         entity spot = SelectSpawnPoint(this, true);
229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
230         this.angles = spot.angles;
231         this.angles_z = 0;
232         this.fixangle = true;
233         // offset it so that the spectator spawns higher off the ground, looks better this way
234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
235         this.prevorigin = this.origin;
236         if (IS_REAL_CLIENT(this))
237         {
238             msg_entity = this;
239             WriteByte(MSG_ONE, SVC_SETVIEW);
240             WriteEntity(MSG_ONE, this);
241         }
242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
244         if(!autocvar_g_debug_globalsounds)
245         {
246                 // needed for player sounds
247                 this.model = "";
248                 FixPlayermodel(this);
249         }
250         setmodel(this, MDL_Null);
251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
252         this.view_ofs = '0 0 0';
253     }
254
255     RemoveGrapplingHooks(this);
256         Portal_ClearAll(this);
257         Unfreeze(this);
258         SetSpectatee(this, NULL);
259
260         if (this.alivetime)
261         {
262                 if (!warmup_stage)
263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
264                 this.alivetime = 0;
265         }
266
267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
268
269         WaypointSprite_PlayerDead(this);
270
271         if (mutator_returnvalue) {
272             // mutator prevents resetting teams+score
273         } else {
274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
275         this.frags = FRAGS_SPECTATOR;
276         PlayerScore_Clear(this);  // clear scores when needed
277     }
278
279         if (this.killcount != FRAGS_SPECTATOR)
280         {
281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
282                 if(!game_stopped)
283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
285
286                 if(this.just_joined == false) {
287                         LogTeamchange(this.playerid, -1, 4);
288                 } else
289                         this.just_joined = false;
290         }
291
292         accuracy_resend(this);
293
294         this.spectatortime = time;
295         if(this.bot_attack)
296                 IL_REMOVE(g_bot_targets, this);
297         this.bot_attack = false;
298     this.hud = HUD_NORMAL;
299         TRANSMUTE(Observer, this);
300         this.iscreature = false;
301         this.teleportable = TELEPORT_SIMPLE;
302         if(this.damagedbycontents)
303                 IL_REMOVE(g_damagedbycontents, this);
304         this.damagedbycontents = false;
305         this.health = FRAGS_SPECTATOR;
306         SetSpectatee_status(this, etof(this));
307         this.takedamage = DAMAGE_NO;
308         this.solid = SOLID_NOT;
309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
310         this.flags = FL_CLIENT | FL_NOTARGET;
311         this.armorvalue = 666;
312         this.effects = 0;
313         this.armorvalue = autocvar_g_balance_armor_start;
314         this.pauserotarmor_finished = 0;
315         this.pauserothealth_finished = 0;
316         this.pauseregen_finished = 0;
317         this.damageforcescale = 0;
318         this.death_time = 0;
319         this.respawn_flags = 0;
320         this.respawn_time = 0;
321         this.stat_respawn_time = 0;
322         this.alpha = 0;
323         this.scale = 0;
324         this.fade_time = 0;
325         this.pain_frame = 0;
326         this.pain_finished = 0;
327         this.strength_finished = 0;
328         this.invincible_finished = 0;
329         this.superweapons_finished = 0;
330         this.pushltime = 0;
331         this.istypefrag = 0;
332         setthink(this, func_null);
333         this.nextthink = 0;
334         this.deadflag = DEAD_NO;
335         this.crouch = false;
336         this.revive_progress = 0;
337         this.revival_time = 0;
338
339         this.items = 0;
340         this.weapons = '0 0 0';
341         this.dual_weapons = '0 0 0';
342         this.drawonlytoclient = this;
343
344         this.weaponmodel = "";
345         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
346         {
347                 this.weaponentities[slot] = NULL;
348         }
349         this.exteriorweaponentity = NULL;
350         this.killcount = FRAGS_SPECTATOR;
351         this.velocity = '0 0 0';
352         this.avelocity = '0 0 0';
353         this.punchangle = '0 0 0';
354         this.punchvector = '0 0 0';
355         this.oldvelocity = this.velocity;
356         this.fire_endtime = -1;
357         this.event_damage = func_null;
358
359         for(int slot = 0; slot < MAX_AXH; ++slot)
360         {
361                 entity axh = this.(AuxiliaryXhair[slot]);
362                 this.(AuxiliaryXhair[slot]) = NULL;
363
364                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
365                         delete(axh);
366         }
367 }
368
369 int player_getspecies(entity this)
370 {
371         get_model_parameters(this.model, this.skin);
372         int s = get_model_parameters_species;
373         get_model_parameters(string_null, 0);
374         if (s < 0) return SPECIES_HUMAN;
375         return s;
376 }
377
378 .float model_randomizer;
379 void FixPlayermodel(entity player)
380 {
381         string defaultmodel = "";
382         int defaultskin = 0;
383         if(autocvar_sv_defaultcharacter)
384         {
385                 if(teamplay)
386                 {
387                         switch(player.team)
388                         {
389                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
390                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
391                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
392                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
393                         }
394                 }
395
396                 if(defaultmodel == "")
397                 {
398                         defaultmodel = autocvar_sv_defaultplayermodel;
399                         defaultskin = autocvar_sv_defaultplayerskin;
400                 }
401
402                 int n = tokenize_console(defaultmodel);
403                 if(n > 0)
404                 {
405                         defaultmodel = argv(floor(n * player.model_randomizer));
406                         // However, do NOT randomize if the player-selected model is in the list.
407                         for (int i = 0; i < n; ++i)
408                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
409                                         defaultmodel = argv(i);
410                 }
411
412                 int i = strstrofs(defaultmodel, ":", 0);
413                 if(i >= 0)
414                 {
415                         defaultskin = stof(substring(defaultmodel, i+1, -1));
416                         defaultmodel = substring(defaultmodel, 0, i);
417                 }
418         }
419         if(autocvar_sv_defaultcharacterskin && !defaultskin)
420         {
421                 if(teamplay)
422                 {
423                         switch(player.team)
424                         {
425                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
426                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
427                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
428                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
429                         }
430                 }
431
432                 if(!defaultskin)
433                         defaultskin = autocvar_sv_defaultplayerskin;
434         }
435
436         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
437         defaultmodel = M_ARGV(0, string);
438         defaultskin = M_ARGV(1, int);
439
440         bool chmdl = false;
441         int oldskin;
442         if(defaultmodel != "")
443         {
444                 if (defaultmodel != player.model)
445                 {
446                         vector m1 = player.mins;
447                         vector m2 = player.maxs;
448                         setplayermodel (player, defaultmodel);
449                         setsize (player, m1, m2);
450                         chmdl = true;
451                 }
452
453                 oldskin = player.skin;
454                 player.skin = defaultskin;
455         } else {
456                 if (player.playermodel != player.model || player.playermodel == "")
457                 {
458                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
459                         vector m1 = player.mins;
460                         vector m2 = player.maxs;
461                         setplayermodel (player, player.playermodel);
462                         setsize (player, m1, m2);
463                         chmdl = true;
464                 }
465
466                 if(!autocvar_sv_defaultcharacterskin)
467                 {
468                         oldskin = player.skin;
469                         player.skin = stof(player.playerskin);
470                 }
471                 else
472                 {
473                         oldskin = player.skin;
474                         player.skin = defaultskin;
475                 }
476         }
477
478         if(chmdl || oldskin != player.skin) // model or skin has changed
479         {
480                 player.species = player_getspecies(player); // update species
481                 if(!autocvar_g_debug_globalsounds)
482                         UpdatePlayerSounds(player); // update skin sounds
483         }
484
485         if(!teamplay)
486                 if(strlen(autocvar_sv_defaultplayercolors))
487                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
488                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
489 }
490
491
492 /** Called when a client spawns in the server */
493 void PutClientInServer(entity this)
494 {
495         if (IS_BOT_CLIENT(this)) {
496                 TRANSMUTE(Player, this);
497         } else if (IS_REAL_CLIENT(this)) {
498                 msg_entity = this;
499                 WriteByte(MSG_ONE, SVC_SETVIEW);
500                 WriteEntity(MSG_ONE, this);
501         }
502         if (game_stopped)
503                 TRANSMUTE(Observer, this);
504
505         SetSpectatee(this, NULL);
506
507         // reset player keys
508         this.itemkeys = 0;
509
510         MUTATOR_CALLHOOK(PutClientInServer, this);
511
512         if (IS_OBSERVER(this)) {
513                 PutObserverInServer(this);
514         } else if (IS_PLAYER(this)) {
515                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
516
517                 PlayerState_attach(this);
518                 accuracy_resend(this);
519
520                 if (this.team < 0)
521                         JoinBestTeam(this, false, true);
522
523                 entity spot = SelectSpawnPoint(this, false);
524                 if (!spot) {
525                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
526                         return; // spawn failed
527                 }
528
529                 TRANSMUTE(Player, this);
530
531                 this.wasplayer = true;
532                 this.iscreature = true;
533                 this.teleportable = TELEPORT_NORMAL;
534                 if(!this.damagedbycontents)
535                         IL_PUSH(g_damagedbycontents, this);
536                 this.damagedbycontents = true;
537                 set_movetype(this, MOVETYPE_WALK);
538                 this.solid = SOLID_SLIDEBOX;
539                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
540                 if (autocvar_g_playerclip_collisions)
541                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
542                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
543                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
544                 this.frags = FRAGS_PLAYER;
545                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
546                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
547                 if (autocvar__notarget)
548                         this.flags |= FL_NOTARGET;
549                 this.takedamage = DAMAGE_AIM;
550                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
551                 this.dmg = 2; // WTF
552
553                 if (warmup_stage) {
554                         this.ammo_shells = warmup_start_ammo_shells;
555                         this.ammo_nails = warmup_start_ammo_nails;
556                         this.ammo_rockets = warmup_start_ammo_rockets;
557                         this.ammo_cells = warmup_start_ammo_cells;
558                         this.ammo_plasma = warmup_start_ammo_plasma;
559                         this.ammo_fuel = warmup_start_ammo_fuel;
560                         this.health = warmup_start_health;
561                         this.armorvalue = warmup_start_armorvalue;
562                         this.weapons = WARMUP_START_WEAPONS;
563                 } else {
564                         this.ammo_shells = start_ammo_shells;
565                         this.ammo_nails = start_ammo_nails;
566                         this.ammo_rockets = start_ammo_rockets;
567                         this.ammo_cells = start_ammo_cells;
568                         this.ammo_plasma = start_ammo_plasma;
569                         this.ammo_fuel = start_ammo_fuel;
570                         this.health = start_health;
571                         this.armorvalue = start_armorvalue;
572                         this.weapons = start_weapons;
573                 }
574                 SetSpectatee_status(this, 0);
575
576                 this.dual_weapons = '0 0 0';
577
578                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
579
580                 this.items = start_items;
581
582                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
583                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
584                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
585                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
586                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
587                 // extend the pause of rotting if client was reset at the beginning of the countdown
588                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
589                         float f = game_starttime - time;
590                         this.spawnshieldtime += f;
591                         this.pauserotarmor_finished += f;
592                         this.pauserothealth_finished += f;
593                         this.pauseregen_finished += f;
594                 }
595                 this.damageforcescale = 2;
596                 this.death_time = 0;
597                 this.respawn_flags = 0;
598                 this.respawn_time = 0;
599                 this.stat_respawn_time = 0;
600                 this.scale = autocvar_sv_player_scale;
601                 this.fade_time = 0;
602                 this.pain_frame = 0;
603                 this.pain_finished = 0;
604                 this.pushltime = 0;
605                 setthink(this, func_null); // players have no think function
606                 this.nextthink = 0;
607                 this.dmg_team = 0;
608                 this.ballistics_density = autocvar_g_ballistics_density_player;
609
610                 this.deadflag = DEAD_NO;
611
612                 this.angles = spot.angles;
613                 this.angles_z = 0; // never spawn tilted even if the spot says to
614                 if (IS_BOT_CLIENT(this))
615                         this.v_angle = this.angles;
616                 this.fixangle = true; // turn this way immediately
617                 this.oldvelocity = this.velocity = '0 0 0';
618                 this.avelocity = '0 0 0';
619                 this.punchangle = '0 0 0';
620                 this.punchvector = '0 0 0';
621
622                 this.strength_finished = 0;
623                 this.invincible_finished = 0;
624                 this.fire_endtime = -1;
625                 this.revive_progress = 0;
626                 this.revival_time = 0;
627                 this.air_finished = time + 12;
628
629                 entity spawnevent = new_pure(spawnevent);
630                 spawnevent.owner = this;
631                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
632
633                 // Cut off any still running player sounds.
634                 stopsound(this, CH_PLAYER_SINGLE);
635
636                 this.model = "";
637                 FixPlayermodel(this);
638                 this.drawonlytoclient = NULL;
639
640                 this.viewloc = NULL;
641
642                 this.crouch = false;
643                 this.view_ofs = STAT(PL_VIEW_OFS, this);
644                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
645                 this.spawnorigin = spot.origin;
646                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
647                 // don't reset back to last position, even if new position is stuck in solid
648                 this.oldorigin = this.origin;
649                 this.prevorigin = this.origin;
650                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
651                 if(this.conveyor)
652                         IL_REMOVE(g_conveyed, this);
653                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
654                 this.hud = HUD_NORMAL;
655
656                 this.event_damage = PlayerDamage;
657
658                 if(!this.bot_attack)
659                         IL_PUSH(g_bot_targets, this);
660                 this.bot_attack = true;
661                 this.monster_attack = true;
662                 navigation_dynamicgoal_init(this, false);
663
664                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
665
666                 if (this.killcount == FRAGS_SPECTATOR) {
667                         PlayerScore_Clear(this);
668                         this.killcount = 0;
669                 }
670
671                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
672                 {
673                         .entity weaponentity = weaponentities[slot];
674                         entity oldwep = this.(weaponentity);
675                         CL_SpawnWeaponentity(this, weaponentity);
676                         if(oldwep && oldwep.owner == this)
677                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
678                 }
679                 this.alpha = default_player_alpha;
680                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
681                 this.exteriorweaponentity.alpha = default_weapon_alpha;
682
683                 this.speedrunning = false;
684
685                 target_voicescript_clear(this);
686
687                 // reset fields the weapons may use
688                 FOREACH(Weapons, true, LAMBDA(
689                         it.wr_resetplayer(it, this);
690                         // reload all reloadable weapons
691                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
692                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
693                                 {
694                                         .entity weaponentity = weaponentities[slot];
695                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
696                                 }
697                         }
698                 ));
699
700                 {
701                         string s = spot.target;
702                         spot.target = string_null;
703                         SUB_UseTargets(spot, this, NULL);
704                         spot.target = s;
705                 }
706
707                 Unfreeze(this);
708
709                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
710
711                 if (autocvar_spawn_debug)
712                 {
713                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
714                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
715                 }
716
717                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
718                 {
719                         .entity weaponentity = weaponentities[slot];
720                         if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
721                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
722                         else
723                                 this.(weaponentity).m_switchweapon = WEP_Null;
724                         this.(weaponentity).m_weapon = WEP_Null;
725                         this.(weaponentity).weaponname = "";
726                         this.(weaponentity).m_switchingweapon = WEP_Null;
727                         this.(weaponentity).cnt = -1;
728                 }
729
730                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
731
732                 if (!warmup_stage && !this.alivetime)
733                         this.alivetime = time;
734
735                 antilag_clear(this, CS(this));
736         }
737 }
738
739 void ClientInit_misc(entity this);
740
741 // TODO do we need all these fields, or should we stop autodetecting runtime
742 // changes and just have a console command to update this?
743 bool ClientInit_SendEntity(entity this, entity to, int sf)
744 {
745         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
746         return = true;
747         msg_entity = to;
748         // MSG_INIT replacement
749         // TODO: make easier to use
750         Registry_send_all();
751         W_PROP_reload(MSG_ONE, to);
752         ClientInit_misc(this);
753         MUTATOR_CALLHOOK(Ent_Init);
754 }
755 void ClientInit_misc(entity this)
756 {
757         int channel = MSG_ONE;
758         WriteHeader(channel, ENT_CLIENT_INIT);
759         WriteByte(channel, g_nexball_meter_period * 32);
760         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
761         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
764         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
765         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
768
769         if(sv_foginterval && world.fog != "")
770                 WriteString(channel, world.fog);
771         else
772                 WriteString(channel, "");
773         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
774         WriteByte(channel, serverflags);
775         WriteCoord(channel, autocvar_g_trueaim_minrange);
776 }
777
778 void ClientInit_CheckUpdate(entity this)
779 {
780         this.nextthink = time;
781         if(this.count != autocvar_g_balance_armor_blockpercent)
782         {
783                 this.count = autocvar_g_balance_armor_blockpercent;
784                 this.SendFlags |= 1;
785         }
786 }
787
788 void ClientInit_Spawn()
789 {
790         entity e = new_pure(clientinit);
791         setthink(e, ClientInit_CheckUpdate);
792         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
793
794         ClientInit_CheckUpdate(e);
795 }
796
797 /*
798 =============
799 SetNewParms
800 =============
801 */
802 void SetNewParms ()
803 {
804         // initialize parms for a new player
805         parm1 = -(86400 * 366);
806
807         MUTATOR_CALLHOOK(SetNewParms);
808 }
809
810 /*
811 =============
812 SetChangeParms
813 =============
814 */
815 void SetChangeParms (entity this)
816 {
817         // save parms for level change
818         parm1 = this.parm_idlesince - time;
819
820         MUTATOR_CALLHOOK(SetChangeParms);
821 }
822
823 /*
824 =============
825 DecodeLevelParms
826 =============
827 */
828 void DecodeLevelParms(entity this)
829 {
830         // load parms
831         this.parm_idlesince = parm1;
832         if (this.parm_idlesince == -(86400 * 366))
833                 this.parm_idlesince = time;
834
835         // whatever happens, allow 60 seconds of idling directly after connect for map loading
836         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
837
838         MUTATOR_CALLHOOK(DecodeLevelParms);
839 }
840
841 /*
842 =============
843 ClientKill
844
845 Called when a client types 'kill' in the console
846 =============
847 */
848
849 .float clientkill_nexttime;
850 void ClientKill_Now_TeamChange(entity this)
851 {
852         if(this.killindicator_teamchange == -1)
853         {
854                 JoinBestTeam( this, false, true );
855         }
856         else if(this.killindicator_teamchange == -2)
857         {
858                 if(blockSpectators)
859                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
860                 PutObserverInServer(this);
861         }
862         else
863                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
864         this.killindicator_teamchange = 0;
865 }
866
867 void ClientKill_Now(entity this)
868 {
869         if(this.vehicle)
870         {
871             vehicles_exit(this.vehicle, VHEF_RELEASE);
872             if(!this.killindicator_teamchange)
873             {
874             this.vehicle_health = -1;
875             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
876             }
877         }
878
879         if(this.killindicator && !wasfreed(this.killindicator))
880                 delete(this.killindicator);
881
882         this.killindicator = NULL;
883
884         if(this.killindicator_teamchange)
885                 ClientKill_Now_TeamChange(this);
886
887         if(!IS_SPEC(this) && !IS_OBSERVER(this))
888                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
889
890         // now I am sure the player IS dead
891 }
892 void KillIndicator_Think(entity this)
893 {
894         if (game_stopped)
895         {
896                 this.owner.killindicator = NULL;
897                 delete(this);
898                 return;
899         }
900
901         if (this.owner.alpha < 0 && !this.owner.vehicle)
902         {
903                 this.owner.killindicator = NULL;
904                 delete(this);
905                 return;
906         }
907
908         if(this.cnt <= 0)
909         {
910                 ClientKill_Now(this.owner);
911                 return;
912         }
913     else if(g_cts && this.health == 1) // health == 1 means that it's silent
914     {
915         this.nextthink = time + 1;
916         this.cnt -= 1;
917     }
918         else
919         {
920                 if(this.cnt <= 10)
921                         setmodel(this, MDL_NUM(this.cnt));
922                 if(IS_REAL_CLIENT(this.owner))
923                 {
924                         if(this.cnt <= 10)
925                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
926                 }
927                 this.nextthink = time + 1;
928                 this.cnt -= 1;
929         }
930 }
931
932 float clientkilltime;
933 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
934 {
935         float killtime;
936         float starttime;
937
938         if (game_stopped)
939                 return;
940
941         killtime = autocvar_g_balance_kill_delay;
942
943         if(g_race_qualifying || g_cts)
944                 killtime = 0;
945
946     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
947         return;
948
949         this.killindicator_teamchange = targetteam;
950
951     if(!this.killindicator)
952         {
953                 if(!IS_DEAD(this))
954                 {
955                         killtime = max(killtime, this.clientkill_nexttime - time);
956                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
957                 }
958
959                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
960                 {
961                         ClientKill_Now(this);
962                 }
963                 else
964                 {
965                         starttime = max(time, clientkilltime);
966
967                         this.killindicator = spawn();
968                         this.killindicator.owner = this;
969                         this.killindicator.scale = 0.5;
970                         setattachment(this.killindicator, this, "");
971                         setorigin(this.killindicator, '0 0 52');
972                         setthink(this.killindicator, KillIndicator_Think);
973                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
974                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
975                         this.killindicator.cnt = ceil(killtime);
976                         this.killindicator.count = bound(0, ceil(killtime), 10);
977                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
978
979                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
980                         {
981                                 it.killindicator = spawn();
982                                 it.killindicator.owner = it;
983                                 it.killindicator.scale = 0.5;
984                                 setattachment(it.killindicator, it, "");
985                                 setorigin(it.killindicator, '0 0 52');
986                                 setthink(it.killindicator, KillIndicator_Think);
987                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
988                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
989                                 it.killindicator.cnt = ceil(killtime);
990                         });
991                         this.lip = 0;
992                 }
993         }
994         if(this.killindicator)
995         {
996                 if(targetteam == 0) // just die
997                 {
998                         this.killindicator.colormod = '0 0 0';
999                         if(IS_REAL_CLIENT(this))
1000                         if(this.killindicator.cnt > 0)
1001                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1002                 }
1003                 else if(targetteam == -1) // auto
1004                 {
1005                         this.killindicator.colormod = '0 1 0';
1006                         if(IS_REAL_CLIENT(this))
1007                         if(this.killindicator.cnt > 0)
1008                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1009                 }
1010                 else if(targetteam == -2) // spectate
1011                 {
1012                         this.killindicator.colormod = '0.5 0.5 0.5';
1013                         if(IS_REAL_CLIENT(this))
1014                         if(this.killindicator.cnt > 0)
1015                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1016                 }
1017                 else
1018                 {
1019                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1020                         if(IS_REAL_CLIENT(this))
1021                         if(this.killindicator.cnt > 0)
1022                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1023                 }
1024         }
1025
1026 }
1027
1028 void ClientKill (entity this)
1029 {
1030         if(game_stopped) return;
1031         if(this.player_blocked) return;
1032         if(STAT(FROZEN, this)) return;
1033
1034         ClientKill_TeamChange(this, 0);
1035 }
1036
1037 void FixClientCvars(entity e)
1038 {
1039         // send prediction settings to the client
1040         stuffcmd(e, "\nin_bindmap 0 0\n");
1041         if(autocvar_g_antilag == 3) // client side hitscan
1042                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1043         if(autocvar_sv_gentle)
1044                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1045
1046         MUTATOR_CALLHOOK(FixClientCvars, e);
1047 }
1048
1049 float PlayerInIDList(entity p, string idlist)
1050 {
1051         float n, i;
1052         string s;
1053
1054         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1055         if (!p.crypto_idfp)
1056                 return 0;
1057
1058         // this function allows abbreviated player IDs too!
1059         n = tokenize_console(idlist);
1060         for(i = 0; i < n; ++i)
1061         {
1062                 s = argv(i);
1063                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1064                         return 1;
1065         }
1066
1067         return 0;
1068 }
1069
1070 #ifdef DP_EXT_PRECONNECT
1071 /*
1072 =============
1073 ClientPreConnect
1074
1075 Called once (not at each match start) when a client begins a connection to the server
1076 =============
1077 */
1078 void ClientPreConnect(entity this)
1079 {
1080         if(autocvar_sv_eventlog)
1081         {
1082                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1083                         this.playerid,
1084                         etof(this),
1085                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1086                 ));
1087         }
1088 }
1089 #endif
1090
1091 /**
1092 =============
1093 ClientConnect
1094
1095 Called when a client connects to the server
1096 =============
1097 */
1098 void ClientConnect(entity this)
1099 {
1100         if (Ban_MaybeEnforceBanOnce(this)) return;
1101         assert(!IS_CLIENT(this), return);
1102         this.flags |= FL_CLIENT;
1103         assert(player_count >= 0, player_count = 0);
1104
1105 #ifdef WATERMARK
1106         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1107 #endif
1108         this.version_nagtime = time + 10 + random() * 10;
1109         TRANSMUTE(Client, this);
1110
1111         // identify the right forced team
1112         if (autocvar_g_campaign)
1113         {
1114                 if (IS_REAL_CLIENT(this)) // only players, not bots
1115                 {
1116                         switch (autocvar_g_campaign_forceteam)
1117                         {
1118                                 case 1: this.team_forced = NUM_TEAM_1; break;
1119                                 case 2: this.team_forced = NUM_TEAM_2; break;
1120                                 case 3: this.team_forced = NUM_TEAM_3; break;
1121                                 case 4: this.team_forced = NUM_TEAM_4; break;
1122                                 default: this.team_forced = 0;
1123                         }
1124                 }
1125         }
1126         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1127         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1128         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1129         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1130         else switch (autocvar_g_forced_team_otherwise)
1131         {
1132                 default: this.team_forced = 0; break;
1133                 case "red": this.team_forced = NUM_TEAM_1; break;
1134                 case "blue": this.team_forced = NUM_TEAM_2; break;
1135                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1136                 case "pink": this.team_forced = NUM_TEAM_4; break;
1137                 case "spectate":
1138                 case "spectator":
1139                         this.team_forced = -1;
1140                         break;
1141         }
1142         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1143
1144     {
1145         int id = this.playerid;
1146         this.playerid = 0; // silent
1147             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1148             this.playerid = id;
1149     }
1150
1151         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1152                 TRANSMUTE(Observer, this);
1153         } else {
1154                 if (!teamplay || autocvar_g_balance_teams) {
1155                         TRANSMUTE(Player, this);
1156                         campaign_bots_may_start = true;
1157                 } else {
1158                         TRANSMUTE(Observer, this); // do it anyway
1159                 }
1160         }
1161
1162         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1163
1164         // always track bots, don't ask for cl_allow_uidtracking
1165     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1166
1167         if (autocvar_sv_eventlog)
1168                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1169
1170         LogTeamchange(this.playerid, this.team, 1);
1171
1172         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1173
1174         this.netname_previous = strzone(this.netname);
1175
1176         if(teamplay && IS_PLAYER(this))
1177                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1178         else
1179                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1180
1181         stuffcmd(this, clientstuff, "\n");
1182         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1183
1184         FixClientCvars(this);
1185
1186         // get version info from player
1187         stuffcmd(this, "cmd clientversion $gameversion\n");
1188
1189         // notify about available teams
1190         if (teamplay)
1191         {
1192                 CheckAllowedTeams(this);
1193                 int t = 0;
1194                 if (c1 >= 0) t |= BIT(0);
1195                 if (c2 >= 0) t |= BIT(1);
1196                 if (c3 >= 0) t |= BIT(2);
1197                 if (c4 >= 0) t |= BIT(3);
1198                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1199         }
1200         else
1201         {
1202                 stuffcmd(this, "set _teams_available 0\n");
1203         }
1204
1205         bot_relinkplayerlist();
1206
1207         this.spectatortime = time;
1208         if (blockSpectators)
1209         {
1210                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1211         }
1212
1213         this.jointime = time;
1214         this.allowed_timeouts = autocvar_sv_timeout_number;
1215
1216         if (IS_REAL_CLIENT(this))
1217         {
1218                 if (g_weaponarena_weapons == WEPSET(TUBA))
1219                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1220         }
1221
1222         if (!sv_foginterval && world.fog != "")
1223                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1224
1225         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1226                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1227                         send_CSQC_teamnagger();
1228
1229         CSQCMODEL_AUTOINIT(this);
1230
1231         this.model_randomizer = random();
1232
1233         if (IS_REAL_CLIENT(this))
1234                 sv_notice_join(this);
1235
1236         // update physics stats (players can spawn before physics runs)
1237         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1238         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1239         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1240
1241         IL_EACH(g_initforplayer, it.init_for_player, {
1242                 it.init_for_player(it, this);
1243         });
1244
1245         MUTATOR_CALLHOOK(ClientConnect, this);
1246
1247         if (IS_REAL_CLIENT(this))
1248         {
1249                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1250                 {
1251                         this.motd_actived_time = -1;
1252                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1253                 }
1254         }
1255 }
1256 /*
1257 =============
1258 ClientDisconnect
1259
1260 Called when a client disconnects from the server
1261 =============
1262 */
1263 .entity chatbubbleentity;
1264 void ReadyCount();
1265 void ClientDisconnect(entity this)
1266 {
1267         assert(IS_CLIENT(this), return);
1268
1269         PlayerStats_GameReport_FinalizePlayer(this);
1270         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1271         if (this.active_minigame) part_minigame(this);
1272         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1273
1274         if (autocvar_sv_eventlog)
1275                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1276
1277         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1278
1279         if(IS_SPEC(this))
1280                 SetSpectatee(this, NULL);
1281
1282     MUTATOR_CALLHOOK(ClientDisconnect, this);
1283
1284         ClientState_detach(this);
1285
1286         Portal_ClearAll(this);
1287
1288         Unfreeze(this);
1289
1290         RemoveGrapplingHooks(this);
1291
1292         // Here, everything has been done that requires this player to be a client.
1293
1294         this.flags &= ~FL_CLIENT;
1295
1296         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1297         if (this.killindicator) delete(this.killindicator);
1298
1299         WaypointSprite_PlayerGone(this);
1300
1301         bot_relinkplayerlist();
1302
1303         if (this.netname_previous) strunzone(this.netname_previous);
1304         if (this.clientstatus) strunzone(this.clientstatus);
1305         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1306         if (this.personal) delete(this.personal);
1307
1308         this.playerid = 0;
1309         ReadyCount();
1310         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1311
1312         ONREMOVE(this);
1313 }
1314
1315 void ChatBubbleThink(entity this)
1316 {
1317         this.nextthink = time;
1318         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1319         {
1320                 if(this.owner) // but why can that ever be NULL?
1321                         this.owner.chatbubbleentity = NULL;
1322                 delete(this);
1323                 return;
1324         }
1325
1326         this.mdl = "";
1327
1328         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1329         {
1330                 if ( this.owner.active_minigame )
1331                         this.mdl = "models/sprites/minigame_busy.iqm";
1332                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1333                         this.mdl = "models/misc/chatbubble.spr";
1334         }
1335
1336         if ( this.model != this.mdl )
1337                 _setmodel(this, this.mdl);
1338
1339 }
1340
1341 void UpdateChatBubble(entity this)
1342 {
1343         if (this.alpha < 0)
1344                 return;
1345         // spawn a chatbubble entity if needed
1346         if (!this.chatbubbleentity)
1347         {
1348                 this.chatbubbleentity = new(chatbubbleentity);
1349                 this.chatbubbleentity.owner = this;
1350                 this.chatbubbleentity.exteriormodeltoclient = this;
1351                 setthink(this.chatbubbleentity, ChatBubbleThink);
1352                 this.chatbubbleentity.nextthink = time;
1353                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1354                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1355                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1356                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1357                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1358                 //this.chatbubbleentity.model = "";
1359                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1360         }
1361 }
1362
1363
1364 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1365 // added to the model skins
1366 /*void UpdateColorModHack()
1367 {
1368         float c;
1369         c = this.clientcolors & 15;
1370         // LordHavoc: only bothering to support white, green, red, yellow, blue
1371              if (!teamplay) this.colormod = '0 0 0';
1372         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1373         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1374         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1375         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1376         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1377         else this.colormod = '1 1 1';
1378 }*/
1379
1380 void respawn(entity this)
1381 {
1382         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1383         {
1384                 this.solid = SOLID_NOT;
1385                 this.takedamage = DAMAGE_NO;
1386                 set_movetype(this, MOVETYPE_FLY);
1387                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1388                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1389                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1390                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1391                 if(autocvar_g_respawn_ghosts_maxtime)
1392                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1393         }
1394
1395         CopyBody(this, 1);
1396
1397         this.effects |= EF_NODRAW; // prevent another CopyBody
1398         PutClientInServer(this);
1399 }
1400
1401 void play_countdown(entity this, float finished, Sound samp)
1402 {
1403     TC(Sound, samp);
1404         if(IS_REAL_CLIENT(this))
1405                 if(floor(finished - time - frametime) != floor(finished - time))
1406                         if(finished - time < 6)
1407                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1408 }
1409
1410 void player_powerups(entity this)
1411 {
1412         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1413         int items_prev = this.items;
1414
1415         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1416                 this.modelflags |= MF_ROCKET;
1417         else
1418                 this.modelflags &= ~MF_ROCKET;
1419
1420         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1421
1422         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1423                 return;
1424
1425         Fire_ApplyDamage(this);
1426         Fire_ApplyEffect(this);
1427
1428         if (!g_instagib)
1429         {
1430                 if (this.items & ITEM_Strength.m_itemid)
1431                 {
1432                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1433                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1434                         if (time > this.strength_finished)
1435                         {
1436                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1437                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1438                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1439                         }
1440                 }
1441                 else
1442                 {
1443                         if (time < this.strength_finished)
1444                         {
1445                                 this.items = this.items | ITEM_Strength.m_itemid;
1446                                 if(!g_cts)
1447                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1448                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1449                         }
1450                 }
1451                 if (this.items & ITEM_Shield.m_itemid)
1452                 {
1453                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1454                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1455                         if (time > this.invincible_finished)
1456                         {
1457                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1458                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1459                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1460                         }
1461                 }
1462                 else
1463                 {
1464                         if (time < this.invincible_finished)
1465                         {
1466                                 this.items = this.items | ITEM_Shield.m_itemid;
1467                                 if(!g_cts)
1468                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1469                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1470                         }
1471                 }
1472                 if (this.items & IT_SUPERWEAPON)
1473                 {
1474                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1475                         {
1476                                 this.superweapons_finished = 0;
1477                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1478                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1479                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1480                         }
1481                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1482                         {
1483                                 // don't let them run out
1484                         }
1485                         else
1486                         {
1487                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1488                                 if (time > this.superweapons_finished)
1489                                 {
1490                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1491                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1492                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1493                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1494                                 }
1495                         }
1496                 }
1497                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1498                 {
1499                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1500                         {
1501                                 this.items = this.items | IT_SUPERWEAPON;
1502                                 if(!g_cts)
1503                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1504                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1505                         }
1506                         else
1507                         {
1508                                 this.superweapons_finished = 0;
1509                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1510                         }
1511                 }
1512                 else
1513                 {
1514                         this.superweapons_finished = 0;
1515                 }
1516         }
1517
1518         if(autocvar_g_nodepthtestplayers)
1519                 this.effects = this.effects | EF_NODEPTHTEST;
1520
1521         if(autocvar_g_fullbrightplayers)
1522                 this.effects = this.effects | EF_FULLBRIGHT;
1523
1524         if (time >= game_starttime)
1525         if (time < this.spawnshieldtime)
1526                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1527
1528         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1529 }
1530
1531 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1532 {
1533         if(current > stable)
1534                 return current;
1535         else if(current > stable - 0.25) // when close enough, "snap"
1536                 return stable;
1537         else
1538                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1539 }
1540
1541 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1542 {
1543         if(current < stable)
1544                 return current;
1545         else if(current < stable + 0.25) // when close enough, "snap"
1546                 return stable;
1547         else
1548                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1549 }
1550
1551 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1552 {
1553         if(current > rotstable)
1554         {
1555                 if(rotframetime > 0)
1556                 {
1557                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1558                         current = max(rotstable, current - rotlinear * rotframetime);
1559                 }
1560         }
1561         else if(current < regenstable)
1562         {
1563                 if(regenframetime > 0)
1564                 {
1565                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1566                         current = min(regenstable, current + regenlinear * regenframetime);
1567                 }
1568         }
1569
1570         if(current > limit)
1571                 current = limit;
1572
1573         return current;
1574 }
1575
1576 void player_regen(entity this)
1577 {
1578         float max_mod, regen_mod, rot_mod, limit_mod;
1579         max_mod = regen_mod = rot_mod = limit_mod = 1;
1580
1581         float regen_health = autocvar_g_balance_health_regen;
1582         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1583         float regen_health_rot = autocvar_g_balance_health_rot;
1584         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1585         float regen_health_stable = autocvar_g_balance_health_regenstable;
1586         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1587         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1588                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1589         max_mod = M_ARGV(1, float);
1590         regen_mod = M_ARGV(2, float);
1591         rot_mod = M_ARGV(3, float);
1592         limit_mod = M_ARGV(4, float);
1593         regen_health = M_ARGV(5, float);
1594         regen_health_linear = M_ARGV(6, float);
1595         regen_health_rot = M_ARGV(7, float);
1596         regen_health_rotlinear = M_ARGV(8, float);
1597         regen_health_stable = M_ARGV(9, float);
1598         regen_health_rotstable = M_ARGV(10, float);
1599
1600
1601         if(!mutator_returnvalue)
1602         if(!STAT(FROZEN, this))
1603         {
1604                 float mina, maxa, limith, limita;
1605                 maxa = autocvar_g_balance_armor_rotstable;
1606                 mina = autocvar_g_balance_armor_regenstable;
1607                 limith = autocvar_g_balance_health_limit;
1608                 limita = autocvar_g_balance_armor_limit;
1609
1610                 regen_health_rotstable = regen_health_rotstable * max_mod;
1611                 regen_health_stable = regen_health_stable * max_mod;
1612                 limith = limith * limit_mod;
1613                 limita = limita * limit_mod;
1614
1615                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1616                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1617         }
1618
1619         // if player rotted to death...  die!
1620         // check this outside above checks, as player may still be able to rot to death
1621         if(this.health < 1)
1622         {
1623                 if(this.vehicle)
1624                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1625                 if(this.event_damage)
1626                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1627         }
1628
1629         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1630         {
1631                 float minf, maxf, limitf;
1632
1633                 maxf = autocvar_g_balance_fuel_rotstable;
1634                 minf = autocvar_g_balance_fuel_regenstable;
1635                 limitf = autocvar_g_balance_fuel_limit;
1636
1637                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1638         }
1639 }
1640
1641 bool zoomstate_set;
1642 void SetZoomState(entity this, float newzoom)
1643 {
1644         if(newzoom != this.zoomstate)
1645         {
1646                 this.zoomstate = newzoom;
1647                 ClientData_Touch(this);
1648         }
1649         zoomstate_set = true;
1650 }
1651
1652 void GetPressedKeys(entity this)
1653 {
1654         MUTATOR_CALLHOOK(GetPressedKeys, this);
1655         int keys = STAT(PRESSED_KEYS, this);
1656         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1657         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1658         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1659         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1660
1661         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1662         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1663         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1664         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1665         this.pressedkeys = keys; // store for other users
1666
1667         STAT(PRESSED_KEYS, this) = keys;
1668 }
1669
1670 /*
1671 ======================
1672 spectate mode routines
1673 ======================
1674 */
1675
1676 void SpectateCopy(entity this, entity spectatee)
1677 {
1678     TC(Client, this); TC(Client, spectatee);
1679
1680         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1681         PS(this) = PS(spectatee);
1682         this.armortype = spectatee.armortype;
1683         this.armorvalue = spectatee.armorvalue;
1684         this.ammo_cells = spectatee.ammo_cells;
1685         this.ammo_plasma = spectatee.ammo_plasma;
1686         this.ammo_shells = spectatee.ammo_shells;
1687         this.ammo_nails = spectatee.ammo_nails;
1688         this.ammo_rockets = spectatee.ammo_rockets;
1689         this.ammo_fuel = spectatee.ammo_fuel;
1690         this.clip_load = spectatee.clip_load;
1691         this.clip_size = spectatee.clip_size;
1692         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1693         this.health = spectatee.health;
1694         this.impulse = 0;
1695         this.items = spectatee.items;
1696         this.last_pickup = spectatee.last_pickup;
1697         this.hit_time = spectatee.hit_time;
1698         this.strength_finished = spectatee.strength_finished;
1699         this.invincible_finished = spectatee.invincible_finished;
1700         this.superweapons_finished = spectatee.superweapons_finished;
1701         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1702         this.weapons = spectatee.weapons;
1703         this.dual_weapons = spectatee.dual_weapons;
1704         this.vortex_charge = spectatee.vortex_charge;
1705         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1706         this.hagar_load = spectatee.hagar_load;
1707         this.arc_heat_percent = spectatee.arc_heat_percent;
1708         this.minelayer_mines = spectatee.minelayer_mines;
1709         this.punchangle = spectatee.punchangle;
1710         this.view_ofs = spectatee.view_ofs;
1711         this.velocity = spectatee.velocity;
1712         this.dmg_take = spectatee.dmg_take;
1713         this.dmg_save = spectatee.dmg_save;
1714         this.dmg_inflictor = spectatee.dmg_inflictor;
1715         this.v_angle = spectatee.v_angle;
1716         this.angles = spectatee.v_angle;
1717         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1718         this.revive_progress = spectatee.revive_progress;
1719         this.viewloc = spectatee.viewloc;
1720         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1721                 this.fixangle = true;
1722         setorigin(this, spectatee.origin);
1723         setsize(this, spectatee.mins, spectatee.maxs);
1724         SetZoomState(this, spectatee.zoomstate);
1725
1726         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1727         {
1728                 .entity weaponentity = weaponentities[slot];
1729                 this.(weaponentity) = spectatee.(weaponentity);
1730         }
1731
1732         for(int slot = 0; slot < MAX_AXH; ++slot)
1733         {
1734                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1735         }
1736
1737     anticheat_spectatecopy(this, spectatee);
1738         this.hud = spectatee.hud;
1739         if(spectatee.vehicle)
1740     {
1741         this.angles = spectatee.v_angle;
1742
1743         //this.fixangle = false;
1744         //this.velocity = spectatee.vehicle.velocity;
1745         this.vehicle_health = spectatee.vehicle_health;
1746         this.vehicle_shield = spectatee.vehicle_shield;
1747         this.vehicle_energy = spectatee.vehicle_energy;
1748         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1749         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1750         this.vehicle_reload1 = spectatee.vehicle_reload1;
1751         this.vehicle_reload2 = spectatee.vehicle_reload2;
1752
1753         //msg_entity = this;
1754
1755        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1756             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1757            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1758            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1759
1760         //WriteByte (MSG_ONE, SVC_SETVIEW);
1761         //    WriteEntity(MSG_ONE, this);
1762         //makevectors(spectatee.v_angle);
1763         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1764     }
1765 }
1766
1767 bool SpectateUpdate(entity this)
1768 {
1769         if(!this.enemy)
1770                 return false;
1771
1772         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1773         {
1774                 SetSpectatee(this, NULL);
1775                 return false;
1776         }
1777
1778         SpectateCopy(this, this.enemy);
1779
1780         return true;
1781 }
1782
1783 bool SpectateSet(entity this)
1784 {
1785         if(!IS_PLAYER(this.enemy))
1786                 return false;
1787
1788         ClientData_Touch(this.enemy);
1789
1790         msg_entity = this;
1791         WriteByte(MSG_ONE, SVC_SETVIEW);
1792         WriteEntity(MSG_ONE, this.enemy);
1793         set_movetype(this, MOVETYPE_NONE);
1794         accuracy_resend(this);
1795
1796         if(!SpectateUpdate(this))
1797                 PutObserverInServer(this);
1798
1799         return true;
1800 }
1801
1802 void SetSpectatee_status(entity this, int spectatee_num)
1803 {
1804         int oldspectatee_status = this.spectatee_status;
1805         this.spectatee_status = spectatee_num;
1806
1807         if (this.spectatee_status != oldspectatee_status)
1808         {
1809                 ClientData_Touch(this);
1810                 if (g_race || g_cts) race_InitSpectator();
1811         }
1812 }
1813
1814 void SetSpectatee(entity this, entity spectatee)
1815 {
1816         if(IS_BOT_CLIENT(this))
1817                 return; // bots abuse .enemy, this code is useless to them
1818
1819         entity old_spectatee = this.enemy;
1820
1821         this.enemy = spectatee;
1822
1823         // WEAPONTODO
1824         // these are required to fix the spectator bug with arc
1825         if(old_spectatee)
1826         {
1827                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1828                 {
1829                         .entity weaponentity = weaponentities[slot];
1830                         if(old_spectatee.(weaponentity).arc_beam)
1831                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1832                 }
1833         }
1834         if(this.enemy)
1835         {
1836                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1837                 {
1838                         .entity weaponentity = weaponentities[slot];
1839                         if(this.enemy.(weaponentity).arc_beam)
1840                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1841                 }
1842         }
1843
1844         if (this.enemy)
1845                 SetSpectatee_status(this, etof(this.enemy));
1846
1847         // needed to update spectator list
1848         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1849 }
1850
1851 bool Spectate(entity this, entity pl)
1852 {
1853         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1854                 return false;
1855         pl = M_ARGV(1, entity);
1856
1857         SetSpectatee(this, pl);
1858         return SpectateSet(this);
1859 }
1860
1861 bool SpectateNext(entity this)
1862 {
1863         entity ent = find(this.enemy, classname, STR_PLAYER);
1864
1865         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1866                 ent = M_ARGV(1, entity);
1867         else if (!ent)
1868                 ent = find(ent, classname, STR_PLAYER);
1869
1870         if(ent) { SetSpectatee(this, ent); }
1871
1872         return SpectateSet(this);
1873 }
1874
1875 bool SpectatePrev(entity this)
1876 {
1877         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1878         entity ent = findchain(classname, STR_PLAYER);
1879         if (!ent) // no player
1880                 return false;
1881
1882         entity first = ent;
1883         // skip players until current spectated player
1884         if(this.enemy)
1885         while(ent && ent != this.enemy)
1886                 ent = ent.chain;
1887
1888         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1889         {
1890                 case MUT_SPECPREV_FOUND:
1891                     ent = M_ARGV(1, entity);
1892                     break;
1893                 case MUT_SPECPREV_RETURN:
1894                     return true;
1895                 case MUT_SPECPREV_CONTINUE:
1896                 default:
1897                 {
1898                         if(ent.chain)
1899                                 ent = ent.chain;
1900                         else
1901                                 ent = first;
1902                         break;
1903                 }
1904         }
1905
1906         SetSpectatee(this, ent);
1907         return SpectateSet(this);
1908 }
1909
1910 /*
1911 =============
1912 ShowRespawnCountdown()
1913
1914 Update a respawn countdown display.
1915 =============
1916 */
1917 void ShowRespawnCountdown(entity this)
1918 {
1919         float number;
1920         if(!IS_DEAD(this)) // just respawned?
1921                 return;
1922         else
1923         {
1924                 number = ceil(this.respawn_time - time);
1925                 if(number <= 0)
1926                         return;
1927                 if(number <= this.respawn_countdown)
1928                 {
1929                         this.respawn_countdown = number - 1;
1930                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1931                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1932                 }
1933         }
1934 }
1935
1936 .bool team_selected;
1937 bool ShowTeamSelection(entity this)
1938 {
1939         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1940                 return false;
1941         stuffcmd(this, "menu_showteamselect\n");
1942         return true;
1943 }
1944 void Join(entity this)
1945 {
1946         TRANSMUTE(Player, this);
1947
1948         if(!this.team_selected)
1949         if(autocvar_g_campaign || autocvar_g_balance_teams)
1950                 JoinBestTeam(this, false, true);
1951
1952         if(autocvar_g_campaign)
1953                 campaign_bots_may_start = true;
1954
1955         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1956
1957         PutClientInServer(this);
1958
1959         if(IS_PLAYER(this))
1960         if(teamplay && this.team != -1)
1961                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1962         else
1963                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1964         this.team_selected = false;
1965 }
1966
1967 /**
1968  * Determines whether the player is allowed to join. This depends on cvar
1969  * g_maxplayers, if it isn't used this function always return true, otherwise
1970  * it checks whether the number of currently playing players exceeds g_maxplayers.
1971  * @return int number of free slots for players, 0 if none
1972  */
1973 int nJoinAllowed(entity this, entity ignore)
1974 {
1975         if(!ignore)
1976         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1977         // so report 0 free slots if restricted
1978         {
1979                 if(autocvar_g_forced_team_otherwise == "spectate")
1980                         return 0;
1981                 if(autocvar_g_forced_team_otherwise == "spectator")
1982                         return 0;
1983         }
1984
1985         if(this && this.team_forced < 0)
1986                 return 0; // forced spectators can never join
1987
1988         // TODO simplify this
1989         int totalClients = 0;
1990         int currentlyPlaying = 0;
1991         FOREACH_CLIENT(true, LAMBDA(
1992                 if(it != ignore)
1993                         ++totalClients;
1994                 if(IS_REAL_CLIENT(it))
1995                 if(IS_PLAYER(it) || it.caplayer)
1996                         ++currentlyPlaying;
1997         ));
1998
1999         float free_slots = 0;
2000         if (!autocvar_g_maxplayers)
2001                 free_slots = maxclients - totalClients;
2002         else if(currentlyPlaying < autocvar_g_maxplayers)
2003                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2004
2005         static float join_prevent_msg_time = 0;
2006         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2007         {
2008                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2009                 join_prevent_msg_time = time + 3;
2010         }
2011
2012         return free_slots;
2013 }
2014
2015 /**
2016  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2017  * g_maxplayers_spectator_blocktime seconds
2018  */
2019 void checkSpectatorBlock(entity this)
2020 {
2021         if(IS_SPEC(this) || IS_OBSERVER(this))
2022         if(!this.caplayer)
2023         if(IS_REAL_CLIENT(this))
2024         {
2025                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2026                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2027                         dropclient(this);
2028                 }
2029         }
2030 }
2031
2032 void PrintWelcomeMessage(entity this)
2033 {
2034         if(this.motd_actived_time == 0)
2035         {
2036                 if (autocvar_g_campaign) {
2037                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2038                                 this.motd_actived_time = time;
2039                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2040                         }
2041                 } else {
2042                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2043                                 this.motd_actived_time = time;
2044                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2045                         }
2046                 }
2047         }
2048         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2049         {
2050                 if (autocvar_g_campaign) {
2051                         if (PHYS_INPUT_BUTTON_INFO(this))
2052                                 this.motd_actived_time = time;
2053                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2054                                 this.motd_actived_time = 0;
2055                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2056                         }
2057                 } else {
2058                         if (PHYS_INPUT_BUTTON_INFO(this))
2059                                 this.motd_actived_time = time;
2060                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2061                                 this.motd_actived_time = 0;
2062                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2063                         }
2064                 }
2065         }
2066         else //if(this.motd_actived_time < 0) // just connected, motd is active
2067         {
2068                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2069                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2070                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2071                 {
2072                         // instanctly hide MOTD
2073                         this.motd_actived_time = 0;
2074                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2075                 }
2076         }
2077 }
2078
2079 bool joinAllowed(entity this)
2080 {
2081         if (this.version_mismatch) return false;
2082         if (!nJoinAllowed(this, this)) return false;
2083         if (teamplay && lockteams) return false;
2084         if (ShowTeamSelection(this)) return false;
2085         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2086         return true;
2087 }
2088
2089 void ObserverThink(entity this)
2090 {
2091         if ( this.impulse )
2092         {
2093                 MinigameImpulse(this, this.impulse);
2094                 this.impulse = 0;
2095         }
2096
2097         if (this.flags & FL_JUMPRELEASED) {
2098                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2099                         this.flags &= ~FL_JUMPRELEASED;
2100                         this.flags |= FL_SPAWNING;
2101                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2102                         this.flags &= ~FL_JUMPRELEASED;
2103                         if(SpectateNext(this)) {
2104                                 TRANSMUTE(Spectator, this);
2105                         }
2106                 } else {
2107                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2108                         set_movetype(this, preferred_movetype);
2109                 }
2110         } else {
2111                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2112                         this.flags |= FL_JUMPRELEASED;
2113                         if(this.flags & FL_SPAWNING)
2114                         {
2115                                 this.flags &= ~FL_SPAWNING;
2116                                 Join(this);
2117                                 return;
2118                         }
2119                 }
2120         }
2121 }
2122
2123 void SpectatorThink(entity this)
2124 {
2125         if ( this.impulse )
2126         {
2127                 if(MinigameImpulse(this, this.impulse))
2128                         this.impulse = 0;
2129
2130                 if (this.impulse == IMP_weapon_drop.impulse)
2131                 {
2132                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2133                         this.impulse = 0;
2134                         return;
2135                 }
2136         }
2137
2138         if (this.flags & FL_JUMPRELEASED) {
2139                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2140                         this.flags &= ~FL_JUMPRELEASED;
2141                         this.flags |= FL_SPAWNING;
2142                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2143                         this.flags &= ~FL_JUMPRELEASED;
2144                         if(SpectateNext(this)) {
2145                                 TRANSMUTE(Spectator, this);
2146                         } else {
2147                                 TRANSMUTE(Observer, this);
2148                                 PutClientInServer(this);
2149                         }
2150                         this.impulse = 0;
2151                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2152                         this.flags &= ~FL_JUMPRELEASED;
2153                         if(SpectatePrev(this)) {
2154                                 TRANSMUTE(Spectator, this);
2155                         } else {
2156                                 TRANSMUTE(Observer, this);
2157                                 PutClientInServer(this);
2158                         }
2159                         this.impulse = 0;
2160                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2161                         this.flags &= ~FL_JUMPRELEASED;
2162                         TRANSMUTE(Observer, this);
2163                         PutClientInServer(this);
2164                 } else {
2165                         if(!SpectateUpdate(this))
2166                                 PutObserverInServer(this);
2167                 }
2168         } else {
2169                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2170                         this.flags |= FL_JUMPRELEASED;
2171                         if(this.flags & FL_SPAWNING)
2172                         {
2173                                 this.flags &= ~FL_SPAWNING;
2174                                 Join(this);
2175                                 return;
2176                         }
2177                 }
2178                 if(!SpectateUpdate(this))
2179                         PutObserverInServer(this);
2180         }
2181
2182         this.flags |= FL_CLIENT | FL_NOTARGET;
2183 }
2184
2185 void vehicles_enter (entity pl, entity veh);
2186 void PlayerUseKey(entity this)
2187 {
2188         if (!IS_PLAYER(this))
2189                 return;
2190
2191         if(this.vehicle)
2192         {
2193                 if(!game_stopped)
2194                 {
2195                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2196                         return;
2197                 }
2198         }
2199         else if(autocvar_g_vehicles_enter)
2200         {
2201                 if(!STAT(FROZEN, this))
2202                 if(!IS_DEAD(this))
2203                 if(!game_stopped)
2204                 {
2205                         entity head, closest_target = NULL;
2206                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2207
2208                         while(head) // find the closest acceptable target to enter
2209                         {
2210                                 if(IS_VEHICLE(head))
2211                                 if(!IS_DEAD(head))
2212                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2213                                 if(head.takedamage != DAMAGE_NO)
2214                                 {
2215                                         if(closest_target)
2216                                         {
2217                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2218                                                 { closest_target = head; }
2219                                         }
2220                                         else { closest_target = head; }
2221                                 }
2222
2223                                 head = head.chain;
2224                         }
2225
2226                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2227                 }
2228         }
2229
2230         // a use key was pressed; call handlers
2231         MUTATOR_CALLHOOK(PlayerUseKey, this);
2232 }
2233
2234
2235 /*
2236 =============
2237 PlayerPreThink
2238
2239 Called every frame for each client before the physics are run
2240 =============
2241 */
2242 .float usekeypressed;
2243 .float last_vehiclecheck;
2244 .int items_added;
2245 void PlayerPreThink (entity this)
2246 {
2247         WarpZone_PlayerPhysics_FixVAngle(this);
2248
2249     STAT(GAMESTARTTIME, this) = game_starttime;
2250         STAT(ROUNDSTARTTIME, this) = round_starttime;
2251         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2252         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2253
2254         STAT(WEAPONSINMAP, this) = weaponsInMap;
2255
2256         if (frametime) {
2257                 // physics frames: update anticheat stuff
2258                 anticheat_prethink(this);
2259         }
2260
2261         if (blockSpectators && frametime) {
2262                 // WORKAROUND: only use dropclient in server frames (frametime set).
2263                 // Never use it in cl_movement frames (frametime zero).
2264                 checkSpectatorBlock(this);
2265     }
2266
2267         zoomstate_set = false;
2268
2269         // Check for nameless players
2270         if (isInvisibleString(this.netname)) {
2271                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2272                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2273         }
2274         if (this.netname != this.netname_previous) {
2275                 if (autocvar_sv_eventlog) {
2276                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2277         }
2278                 if (this.netname_previous) strunzone(this.netname_previous);
2279                 this.netname_previous = strzone(this.netname);
2280         }
2281
2282         // version nagging
2283         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2284         this.version_nagtime = 0;
2285         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2286             // git client
2287         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2288             // git server
2289             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2290         } else {
2291             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2292             if (r < 0) { // old client
2293                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2294             } else if (r > 0) { // old server
2295                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2296             }
2297         }
2298     }
2299
2300         // GOD MODE info
2301         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2302         {
2303                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2304                 this.max_armorvalue = 0;
2305         }
2306
2307         if (STAT(FROZEN, this) == 2)
2308         {
2309                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2310                 this.health = max(1, this.revive_progress * start_health);
2311                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2312
2313                 if (this.revive_progress >= 1)
2314                         Unfreeze(this);
2315         }
2316         else if (STAT(FROZEN, this) == 3)
2317         {
2318                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2319                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2320
2321                 if (this.health < 1)
2322                 {
2323                         if (this.vehicle)
2324                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2325                         if(this.event_damage)
2326                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2327                 }
2328                 else if (this.revive_progress <= 0)
2329                         Unfreeze(this);
2330         }
2331
2332         MUTATOR_CALLHOOK(PlayerPreThink, this);
2333
2334         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2335         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2336         {
2337                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2338                 {
2339                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2340                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2341                         {
2342                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2343                         }
2344                         else if(!it.owner)
2345                         {
2346                                 if(!it.team || SAME_TEAM(this, it))
2347                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2348                                 else if(autocvar_g_vehicles_steal)
2349                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2350                         }
2351                 });
2352
2353                 this.last_vehiclecheck = time + 1;
2354         }
2355
2356         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2357         {
2358                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2359                         PlayerUseKey(this);
2360                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2361         }
2362
2363         if (IS_REAL_CLIENT(this))
2364                 PrintWelcomeMessage(this);
2365
2366         if (IS_PLAYER(this)) {
2367                 CheckRules_Player(this);
2368
2369                 if (game_stopped || intermission_running) {
2370                         this.modelflags &= ~MF_ROCKET;
2371                         if(intermission_running)
2372                                 IntermissionThink(this);
2373                         return;
2374                 }
2375
2376                 if (timeout_status == TIMEOUT_ACTIVE) {
2377             // don't allow the player to turn around while game is paused
2378                         // FIXME turn this into CSQC stuff
2379                         this.v_angle = this.lastV_angle;
2380                         this.angles = this.lastV_angle;
2381                         this.fixangle = true;
2382                 }
2383
2384                 if (frametime) player_powerups(this);
2385
2386                 if (IS_DEAD(this)) {
2387                         if (this.personal && g_race_qualifying) {
2388                                 if (time > this.respawn_time) {
2389                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2390                                         respawn(this);
2391                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2392                                 }
2393                         } else {
2394                                 if (frametime) player_anim(this);
2395
2396                                 if (this.respawn_flags & RESPAWN_DENY)
2397                                 {
2398                                         STAT(RESPAWN_TIME, this) = 0;
2399                                         return;
2400                                 }
2401
2402                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2403
2404                                 switch(this.deadflag)
2405                                 {
2406                                         case DEAD_DYING:
2407                                         {
2408                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2409                                                         this.deadflag = DEAD_RESPAWNING;
2410                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2411                                                         this.deadflag = DEAD_DEAD;
2412                                                 break;
2413                                         }
2414                                         case DEAD_DEAD:
2415                                         {
2416                                                 if (button_pressed)
2417                                                         this.deadflag = DEAD_RESPAWNABLE;
2418                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2419                                                         this.deadflag = DEAD_RESPAWNING;
2420                                                 break;
2421                                         }
2422                                         case DEAD_RESPAWNABLE:
2423                                         {
2424                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2425                                                         this.deadflag = DEAD_RESPAWNING;
2426                                                 break;
2427                                         }
2428                                         case DEAD_RESPAWNING:
2429                                         {
2430                                                 if (time > this.respawn_time)
2431                                                 {
2432                                                         this.respawn_time = time + 1; // only retry once a second
2433                                                         this.respawn_time_max = this.respawn_time;
2434                                                         respawn(this);
2435                                                 }
2436                                                 break;
2437                                         }
2438                                 }
2439
2440                                 ShowRespawnCountdown(this);
2441
2442                                 if (this.respawn_flags & RESPAWN_SILENT)
2443                                         STAT(RESPAWN_TIME, this) = 0;
2444                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2445                                 {
2446                                         if (time < this.respawn_time)
2447                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2448                                         else if (this.deadflag != DEAD_RESPAWNING)
2449                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2450                                 }
2451                                 else
2452                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2453                         }
2454
2455                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2456                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2457                                 STAT(RESPAWN_TIME, this) *= -1;
2458
2459                         return;
2460                 }
2461
2462                 this.prevorigin = this.origin;
2463
2464                 bool have_hook = false;
2465                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2466                 {
2467                         .entity weaponentity = weaponentities[slot];
2468                         if(this.(weaponentity).hook.state)
2469                         {
2470                                 have_hook = true;
2471                                 break;
2472                         }
2473                 }
2474                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2475                 if (have_hook) {
2476                         do_crouch = false;
2477                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2478                         do_crouch = false;
2479                 } else if (this.vehicle) {
2480                         do_crouch = false;
2481                 } else if (STAT(FROZEN, this)) {
2482                         do_crouch = false;
2483         }
2484
2485                 if (do_crouch) {
2486                         if (!this.crouch) {
2487                                 this.crouch = true;
2488                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2489                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2490                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2491                         }
2492                 } else if (this.crouch) {
2493             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2494             if (!trace_startsolid) {
2495                 this.crouch = false;
2496                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2497                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2498             }
2499                 }
2500
2501                 FixPlayermodel(this);
2502
2503                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2504                 //if(frametime)
2505                 {
2506                         this.items &= ~this.items_added;
2507
2508                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2509                         {
2510                                 .entity weaponentity = weaponentities[slot];
2511                                 W_WeaponFrame(this, weaponentity);
2512
2513                                 if(slot == 0)
2514                                 {
2515                                         this.clip_load = this.(weaponentity).clip_load;
2516                                         this.clip_size = this.(weaponentity).clip_size;
2517                                 }
2518                         }
2519
2520                         this.items_added = 0;
2521                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2522                 this.items_added |= IT_FUEL;
2523
2524                         this.items |= this.items_added;
2525                 }
2526
2527                 player_regen(this);
2528
2529                 // WEAPONTODO: Add a weapon request for this
2530                 // rot vortex charge to the charge limit
2531                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2532                 {
2533                         .entity weaponentity = weaponentities[slot];
2534                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2535                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2536                 }
2537
2538                 if (frametime) player_anim(this);
2539
2540                 // secret status
2541                 secrets_setstatus(this);
2542
2543                 // monsters status
2544                 monsters_setstatus(this);
2545
2546                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2547         }
2548         else if (game_stopped || intermission_running) {
2549                 if(intermission_running)
2550                         IntermissionThink(this);
2551                 return;
2552         }
2553         else if (IS_OBSERVER(this)) {
2554                 ObserverThink(this);
2555         }
2556         else if (IS_SPEC(this)) {
2557                 SpectatorThink(this);
2558         }
2559
2560         // WEAPONTODO: Add weapon request for this
2561         if (!zoomstate_set) {
2562                 bool wep_zoomed = false;
2563                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2564                 {
2565                         .entity weaponentity = weaponentities[slot];
2566                         Weapon thiswep = this.(weaponentity).m_weapon;
2567                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2568                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2569                 }
2570                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2571     }
2572
2573         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2574         {
2575                 this.teamkill_soundtime = 0;
2576
2577                 entity e = this.teamkill_soundsource;
2578                 entity oldpusher = e.pusher;
2579                 e.pusher = this;
2580                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2581                 e.pusher = oldpusher;
2582         }
2583
2584         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2585                 this.taunt_soundtime = 0;
2586                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2587         }
2588
2589         target_voicescript_next(this);
2590
2591         // WEAPONTODO: Move into weaponsystem somehow
2592         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2593         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2594         {
2595                 .entity weaponentity = weaponentities[slot];
2596                 if(this.(weaponentity).m_weapon == WEP_Null)
2597                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2598         }
2599 }
2600
2601 void DrownPlayer(entity this)
2602 {
2603         if(IS_DEAD(this))
2604                 return;
2605
2606         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2607         {
2608                 if(this.air_finished < time)
2609                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2610                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2611                 this.dmg = 2;
2612         }
2613         else if (this.air_finished < time)
2614         {       // drown!
2615                 if (this.pain_finished < time)
2616                 {
2617                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2618                         this.pain_finished = time + 0.5;
2619                 }
2620         }
2621 }
2622
2623 .bool move_qcphysics;
2624
2625 void Player_Physics(entity this)
2626 {
2627         set_movetype(this, this.move_movetype);
2628
2629         if(!this.move_qcphysics)
2630                 return;
2631
2632         if(!frametime && !this.pm_frametime)
2633                 return;
2634
2635         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2636
2637         this.pm_frametime = 0;
2638 }
2639
2640 /*
2641 =============
2642 PlayerPostThink
2643
2644 Called every frame for each client after the physics are run
2645 =============
2646 */
2647 .float idlekick_lasttimeleft;
2648 void PlayerPostThink (entity this)
2649 {
2650         Player_Physics(this);
2651
2652         if (sv_maxidle > 0)
2653         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2654         if (IS_REAL_CLIENT(this))
2655         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2656         {
2657                 int totalClients = 0;
2658                 if(sv_maxidle_slots > 0)
2659                 {
2660                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2661                         {
2662                                 ++totalClients;
2663                         });
2664                 }
2665
2666                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2667                 { /* do nothing */ }
2668                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2669                 {
2670                         if (this.idlekick_lasttimeleft)
2671                         {
2672                                 this.idlekick_lasttimeleft = 0;
2673                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2674                         }
2675                 }
2676                 else
2677                 {
2678                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2679                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2680                                 if (!this.idlekick_lasttimeleft)
2681                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2682                         }
2683                         if (timeleft <= 0) {
2684                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2685                                 dropclient(this);
2686                                 return;
2687                         }
2688                         else if (timeleft <= 10) {
2689                                 if (timeleft != this.idlekick_lasttimeleft) {
2690                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2691                 }
2692                                 this.idlekick_lasttimeleft = timeleft;
2693                         }
2694                 }
2695         }
2696
2697         CheatFrame(this);
2698
2699         //CheckPlayerJump();
2700         if (game_stopped)
2701         {
2702                 this.solid = SOLID_NOT;
2703                 this.takedamage = DAMAGE_NO;
2704                 set_movetype(this, MOVETYPE_NONE);
2705         }
2706
2707         if (IS_PLAYER(this)) {
2708                 DrownPlayer(this);
2709                 CheckRules_Player(this);
2710                 UpdateChatBubble(this);
2711                 if (this.impulse) ImpulseCommands(this);
2712                 if (game_stopped)
2713                 {
2714                         CSQCMODEL_AUTOUPDATE(this);
2715                         return;
2716                 }
2717                 GetPressedKeys(this);
2718         }
2719
2720         if (this.waypointsprite_attachedforcarrier) {
2721             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2722                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2723     }
2724
2725         playerdemo_write(this);
2726
2727         CSQCMODEL_AUTOUPDATE(this);
2728 }