Don't bother checking for CTS specifically if the re-spawn is intended to be silent
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include "anticheat.qh"
4 #include "impulse.qh"
5 #include "player.qh"
6 #include "ipban.qh"
7 #include "miscfunctions.qh"
8 #include "portals.qh"
9 #include "teamplay.qh"
10 #include "playerdemo.qh"
11 #include "spawnpoints.qh"
12 #include "g_damage.qh"
13 #include "g_hook.qh"
14 #include "command/common.qh"
15 #include "cheats.qh"
16 #include "g_world.qh"
17 #include "race.qh"
18 #include "antilag.qh"
19 #include "campaign.qh"
20 #include "command/common.qh"
21 #include "scores_rules.qh"
22
23 #include "bot/api.qh"
24
25 #include "../common/ent_cs.qh"
26 #include "../common/wepent.qh"
27 #include <common/state.qh>
28
29 #include <common/effects/qc/globalsound.qh>
30
31 #include "../common/triggers/func/conveyor.qh"
32 #include "../common/triggers/teleporters.qh"
33
34 #include "../common/vehicles/all.qh"
35
36 #include "weapons/hitplot.qh"
37 #include "weapons/weaponsystem.qh"
38
39 #include "../common/net_notice.qh"
40 #include "../common/net_linked.qh"
41 #include "../common/physics/player.qh"
42
43 #include "../common/items/_mod.qh"
44
45 #include "../common/mutators/mutator/waypoints/all.qh"
46
47 #include "../common/triggers/subs.qh"
48 #include "../common/triggers/triggers.qh"
49 #include "../common/triggers/trigger/secret.qh"
50
51 #include "../common/minigames/sv_minigames.qh"
52
53 #include "../common/items/inventory.qh"
54
55 #include "../common/monsters/sv_monsters.qh"
56
57 #include "../lib/warpzone/server.qh"
58
59 STATIC_METHOD(Client, Add, void(Client this, int _team))
60 {
61     ClientConnect(this);
62     TRANSMUTE(Player, this);
63     this.frame = 12; // 7
64     this.team = _team;
65     PutClientInServer(this);
66 }
67
68 void PutObserverInServer(entity this);
69
70 STATIC_METHOD(Client, Remove, void(Client this))
71 {
72     TRANSMUTE(Observer, this);
73     PutClientInServer(this);
74     ClientDisconnect(this);
75 }
76
77 void send_CSQC_teamnagger() {
78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
79 }
80
81 int CountSpectators(entity player, entity to)
82 {
83         if(!player) { return 0; } // not sure how, but best to be safe
84
85         int spec_count = 0;
86
87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
88         {
89                 spec_count++;
90         });
91
92         return spec_count;
93 }
94
95 void WriteSpectators(entity player, entity to)
96 {
97         if(!player) { return; } // not sure how, but best to be safe
98
99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
100         {
101                 WriteByte(MSG_ENTITY, num_for_edict(it));
102         });
103 }
104
105 bool ClientData_Send(entity this, entity to, int sf)
106 {
107         assert(to == this.owner, return false);
108
109         entity e = to;
110         if (IS_SPEC(e)) e = e.enemy;
111
112         sf = 0;
113         if (e.race_completed)       sf |= 1; // forced scoreboard
114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
115         if (e.zoomstate)            sf |= 4; // zoomed
116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
117
118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
119         WriteByte(MSG_ENTITY, sf);
120
121         if (sf & 2)
122         {
123                 WriteByte(MSG_ENTITY, to.spectatee_status);
124         }
125
126         if(sf & 16)
127         {
128                 float specs = CountSpectators(e, to);
129                 WriteByte(MSG_ENTITY, specs);
130                 WriteSpectators(e, to);
131         }
132
133         return true;
134 }
135
136 void ClientData_Attach(entity this)
137 {
138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
139         this.clientdata.drawonlytoclient = this;
140         this.clientdata.owner = this;
141 }
142
143 void ClientData_Detach(entity this)
144 {
145         delete(this.clientdata);
146         this.clientdata = NULL;
147 }
148
149 void ClientData_Touch(entity e)
150 {
151         e.clientdata.SendFlags = 1;
152
153         // make it spectatable
154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
155 }
156
157 .string netname_previous;
158
159 void SetSpectatee(entity this, entity spectatee);
160 void SetSpectatee_status(entity this, int spectatee_num);
161
162
163 /*
164 =============
165 CheckPlayerModel
166
167 Checks if the argument string can be a valid playermodel.
168 Returns a valid one in doubt.
169 =============
170 */
171 string FallbackPlayerModel;
172 string CheckPlayerModel(string plyermodel) {
173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
174         {
175                 // note: we cannot summon Don Strunzone here, some player may
176                 // still have the model string set. In case anyone manages how
177                 // to change a cvar default, we'll have a small leak here.
178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
179         }
180         // only in right path
181         if( substring(plyermodel,0,14) != "models/player/")
182                 return FallbackPlayerModel;
183         // only good file extensions
184         if(substring(plyermodel,-4,4) != ".zym")
185         if(substring(plyermodel,-4,4) != ".dpm")
186         if(substring(plyermodel,-4,4) != ".iqm")
187         if(substring(plyermodel,-4,4) != ".md3")
188         if(substring(plyermodel,-4,4) != ".psk")
189                 return FallbackPlayerModel;
190         // forbid the LOD models
191         if(substring(plyermodel, -9,5) == "_lod1")
192                 return FallbackPlayerModel;
193         if(substring(plyermodel, -9,5) == "_lod2")
194                 return FallbackPlayerModel;
195         if(plyermodel != strtolower(plyermodel))
196                 return FallbackPlayerModel;
197         // also, restrict to server models
198         if(autocvar_sv_servermodelsonly)
199         {
200                 if(!fexists(plyermodel))
201                         return FallbackPlayerModel;
202         }
203         return plyermodel;
204 }
205
206 void setplayermodel(entity e, string modelname)
207 {
208         precache_model(modelname);
209         _setmodel(e, modelname);
210         player_setupanimsformodel(e);
211         if(!autocvar_g_debug_globalsounds)
212                 UpdatePlayerSounds(e);
213 }
214
215 void FixPlayermodel(entity player);
216 /** putting a client as observer in the server */
217 void PutObserverInServer(entity this)
218 {
219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
220         PlayerState_detach(this);
221
222         if (IS_PLAYER(this) && this.health >= 1) {
223         // despawn effect
224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
225     }
226
227     {
228         entity spot = SelectSpawnPoint(this, true);
229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
230         this.angles = spot.angles;
231         this.angles_z = 0;
232         this.fixangle = true;
233         // offset it so that the spectator spawns higher off the ground, looks better this way
234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
235         this.prevorigin = this.origin;
236         if (IS_REAL_CLIENT(this))
237         {
238             msg_entity = this;
239             WriteByte(MSG_ONE, SVC_SETVIEW);
240             WriteEntity(MSG_ONE, this);
241         }
242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
244         if(!autocvar_g_debug_globalsounds)
245         {
246                 // needed for player sounds
247                 this.model = "";
248                 FixPlayermodel(this);
249         }
250         setmodel(this, MDL_Null);
251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
252         this.view_ofs = '0 0 0';
253     }
254
255     RemoveGrapplingHooks(this);
256         Portal_ClearAll(this);
257         Unfreeze(this);
258         SetSpectatee(this, NULL);
259
260         if (this.alivetime)
261         {
262                 if (!warmup_stage)
263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
264                 this.alivetime = 0;
265         }
266
267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
268
269         WaypointSprite_PlayerDead(this);
270
271         if (mutator_returnvalue) {
272             // mutator prevents resetting teams+score
273         } else {
274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
275         this.frags = FRAGS_SPECTATOR;
276         PlayerScore_Clear(this);  // clear scores when needed
277     }
278
279         if (this.killcount != FRAGS_SPECTATOR)
280         {
281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
282                 if(!game_stopped)
283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
285
286                 if(this.just_joined == false) {
287                         LogTeamchange(this.playerid, -1, 4);
288                 } else
289                         this.just_joined = false;
290         }
291
292         accuracy_resend(this);
293
294         this.spectatortime = time;
295         if(this.bot_attack)
296                 IL_REMOVE(g_bot_targets, this);
297         this.bot_attack = false;
298     this.hud = HUD_NORMAL;
299         TRANSMUTE(Observer, this);
300         this.iscreature = false;
301         this.teleportable = TELEPORT_SIMPLE;
302         if(this.damagedbycontents)
303                 IL_REMOVE(g_damagedbycontents, this);
304         this.damagedbycontents = false;
305         this.health = FRAGS_SPECTATOR;
306         SetSpectatee_status(this, etof(this));
307         this.takedamage = DAMAGE_NO;
308         this.solid = SOLID_NOT;
309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
310         this.flags = FL_CLIENT | FL_NOTARGET;
311         this.armorvalue = 666;
312         this.effects = 0;
313         this.armorvalue = autocvar_g_balance_armor_start;
314         this.pauserotarmor_finished = 0;
315         this.pauserothealth_finished = 0;
316         this.pauseregen_finished = 0;
317         this.damageforcescale = 0;
318         this.death_time = 0;
319         this.respawn_flags = 0;
320         this.respawn_time = 0;
321         this.stat_respawn_time = 0;
322         this.alpha = 0;
323         this.scale = 0;
324         this.fade_time = 0;
325         this.pain_frame = 0;
326         this.pain_finished = 0;
327         this.strength_finished = 0;
328         this.invincible_finished = 0;
329         this.superweapons_finished = 0;
330         this.pushltime = 0;
331         this.istypefrag = 0;
332         setthink(this, func_null);
333         this.nextthink = 0;
334         this.deadflag = DEAD_NO;
335         this.crouch = false;
336         this.revive_progress = 0;
337         this.revival_time = 0;
338
339         this.items = 0;
340         this.weapons = '0 0 0';
341         this.drawonlytoclient = this;
342
343         this.weaponmodel = "";
344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
345         {
346                 this.weaponentities[slot] = NULL;
347         }
348         this.exteriorweaponentity = NULL;
349         this.killcount = FRAGS_SPECTATOR;
350         this.velocity = '0 0 0';
351         this.avelocity = '0 0 0';
352         this.punchangle = '0 0 0';
353         this.punchvector = '0 0 0';
354         this.oldvelocity = this.velocity;
355         this.fire_endtime = -1;
356         this.event_damage = func_null;
357
358         for(int slot = 0; slot < MAX_AXH; ++slot)
359         {
360                 entity axh = this.(AuxiliaryXhair[slot]);
361                 this.(AuxiliaryXhair[slot]) = NULL;
362
363                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
364                         delete(axh);
365         }
366 }
367
368 int player_getspecies(entity this)
369 {
370         get_model_parameters(this.model, this.skin);
371         int s = get_model_parameters_species;
372         get_model_parameters(string_null, 0);
373         if (s < 0) return SPECIES_HUMAN;
374         return s;
375 }
376
377 .float model_randomizer;
378 void FixPlayermodel(entity player)
379 {
380         string defaultmodel = "";
381         int defaultskin = 0;
382         if(autocvar_sv_defaultcharacter)
383         {
384                 if(teamplay)
385                 {
386                         string s = Static_Team_ColorName_Lower(player.team);
387                         if (s != "neutral")
388                         {
389                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
390                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
391                         }
392                 }
393
394                 if(defaultmodel == "")
395                 {
396                         defaultmodel = autocvar_sv_defaultplayermodel;
397                         defaultskin = autocvar_sv_defaultplayerskin;
398                 }
399
400                 int n = tokenize_console(defaultmodel);
401                 if(n > 0)
402                 {
403                         defaultmodel = argv(floor(n * player.model_randomizer));
404                         // However, do NOT randomize if the player-selected model is in the list.
405                         for (int i = 0; i < n; ++i)
406                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
407                                         defaultmodel = argv(i);
408                 }
409
410                 int i = strstrofs(defaultmodel, ":", 0);
411                 if(i >= 0)
412                 {
413                         defaultskin = stof(substring(defaultmodel, i+1, -1));
414                         defaultmodel = substring(defaultmodel, 0, i);
415                 }
416         }
417         if(autocvar_sv_defaultcharacterskin && !defaultskin)
418         {
419                 if(teamplay)
420                 {
421                         string s = Static_Team_ColorName_Lower(player.team);
422                         if (s != "neutral")
423                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
424                 }
425
426                 if(!defaultskin)
427                         defaultskin = autocvar_sv_defaultplayerskin;
428         }
429
430         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
431         defaultmodel = M_ARGV(0, string);
432         defaultskin = M_ARGV(1, int);
433
434         bool chmdl = false;
435         int oldskin;
436         if(defaultmodel != "")
437         {
438                 if (defaultmodel != player.model)
439                 {
440                         vector m1 = player.mins;
441                         vector m2 = player.maxs;
442                         setplayermodel (player, defaultmodel);
443                         setsize (player, m1, m2);
444                         chmdl = true;
445                 }
446
447                 oldskin = player.skin;
448                 player.skin = defaultskin;
449         } else {
450                 if (player.playermodel != player.model || player.playermodel == "")
451                 {
452                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
453                         vector m1 = player.mins;
454                         vector m2 = player.maxs;
455                         setplayermodel (player, player.playermodel);
456                         setsize (player, m1, m2);
457                         chmdl = true;
458                 }
459
460                 if(!autocvar_sv_defaultcharacterskin)
461                 {
462                         oldskin = player.skin;
463                         player.skin = stof(player.playerskin);
464                 }
465                 else
466                 {
467                         oldskin = player.skin;
468                         player.skin = defaultskin;
469                 }
470         }
471
472         if(chmdl || oldskin != player.skin) // model or skin has changed
473         {
474                 player.species = player_getspecies(player); // update species
475                 if(!autocvar_g_debug_globalsounds)
476                         UpdatePlayerSounds(player); // update skin sounds
477         }
478
479         if(!teamplay)
480                 if(strlen(autocvar_sv_defaultplayercolors))
481                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
482                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
483 }
484
485
486 /** Called when a client spawns in the server */
487 void PutClientInServer(entity this)
488 {
489         if (IS_BOT_CLIENT(this)) {
490                 TRANSMUTE(Player, this);
491         } else if (IS_REAL_CLIENT(this)) {
492                 msg_entity = this;
493                 WriteByte(MSG_ONE, SVC_SETVIEW);
494                 WriteEntity(MSG_ONE, this);
495         }
496         if (game_stopped)
497                 TRANSMUTE(Observer, this);
498
499         SetSpectatee(this, NULL);
500
501         // reset player keys
502         this.itemkeys = 0;
503
504         MUTATOR_CALLHOOK(PutClientInServer, this);
505
506         if (IS_OBSERVER(this)) {
507                 PutObserverInServer(this);
508         } else if (IS_PLAYER(this)) {
509                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
510
511                 PlayerState_attach(this);
512                 accuracy_resend(this);
513
514                 if (this.team < 0)
515                         JoinBestTeam(this, false, true);
516
517                 entity spot = SelectSpawnPoint(this, false);
518                 if (!spot) {
519                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
520                         return; // spawn failed
521                 }
522
523                 TRANSMUTE(Player, this);
524
525                 this.wasplayer = true;
526                 this.iscreature = true;
527                 this.teleportable = TELEPORT_NORMAL;
528                 if(!this.damagedbycontents)
529                         IL_PUSH(g_damagedbycontents, this);
530                 this.damagedbycontents = true;
531                 set_movetype(this, MOVETYPE_WALK);
532                 this.solid = SOLID_SLIDEBOX;
533                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
534                 if (autocvar_g_playerclip_collisions)
535                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
536                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
537                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
538                 this.frags = FRAGS_PLAYER;
539                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
540                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
541                 if (autocvar__notarget)
542                         this.flags |= FL_NOTARGET;
543                 this.takedamage = DAMAGE_AIM;
544                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
545                 this.dmg = 2; // WTF
546
547                 if (warmup_stage) {
548                         this.ammo_shells = warmup_start_ammo_shells;
549                         this.ammo_nails = warmup_start_ammo_nails;
550                         this.ammo_rockets = warmup_start_ammo_rockets;
551                         this.ammo_cells = warmup_start_ammo_cells;
552                         this.ammo_plasma = warmup_start_ammo_plasma;
553                         this.ammo_fuel = warmup_start_ammo_fuel;
554                         this.health = warmup_start_health;
555                         this.armorvalue = warmup_start_armorvalue;
556                         this.weapons = WARMUP_START_WEAPONS;
557                 } else {
558                         this.ammo_shells = start_ammo_shells;
559                         this.ammo_nails = start_ammo_nails;
560                         this.ammo_rockets = start_ammo_rockets;
561                         this.ammo_cells = start_ammo_cells;
562                         this.ammo_plasma = start_ammo_plasma;
563                         this.ammo_fuel = start_ammo_fuel;
564                         this.health = start_health;
565                         this.armorvalue = start_armorvalue;
566                         this.weapons = start_weapons;
567                 }
568                 SetSpectatee_status(this, 0);
569
570                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
571
572                 this.items = start_items;
573
574                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
575                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
576                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
577                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
578                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
579                 // extend the pause of rotting if client was reset at the beginning of the countdown
580                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
581                         float f = game_starttime - time;
582                         this.spawnshieldtime += f;
583                         this.pauserotarmor_finished += f;
584                         this.pauserothealth_finished += f;
585                         this.pauseregen_finished += f;
586                 }
587                 this.damageforcescale = 2;
588                 this.death_time = 0;
589                 this.respawn_flags = 0;
590                 this.respawn_time = 0;
591                 this.stat_respawn_time = 0;
592                 this.scale = autocvar_sv_player_scale;
593                 this.fade_time = 0;
594                 this.pain_frame = 0;
595                 this.pain_finished = 0;
596                 this.pushltime = 0;
597                 setthink(this, func_null); // players have no think function
598                 this.nextthink = 0;
599                 this.dmg_team = 0;
600                 this.ballistics_density = autocvar_g_ballistics_density_player;
601
602                 this.deadflag = DEAD_NO;
603
604                 this.angles = spot.angles;
605                 this.angles_z = 0; // never spawn tilted even if the spot says to
606                 if (IS_BOT_CLIENT(this))
607                         this.v_angle = this.angles;
608                 this.fixangle = true; // turn this way immediately
609                 this.oldvelocity = this.velocity = '0 0 0';
610                 this.avelocity = '0 0 0';
611                 this.punchangle = '0 0 0';
612                 this.punchvector = '0 0 0';
613
614                 this.strength_finished = 0;
615                 this.invincible_finished = 0;
616                 this.fire_endtime = -1;
617                 this.revive_progress = 0;
618                 this.revival_time = 0;
619                 this.air_finished = time + 12;
620
621                 entity spawnevent = new_pure(spawnevent);
622                 spawnevent.owner = this;
623                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
624
625                 // Cut off any still running player sounds.
626                 stopsound(this, CH_PLAYER_SINGLE);
627
628                 this.model = "";
629                 FixPlayermodel(this);
630                 this.drawonlytoclient = NULL;
631
632                 this.viewloc = NULL;
633
634                 this.crouch = false;
635                 this.view_ofs = STAT(PL_VIEW_OFS, this);
636                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
637                 this.spawnorigin = spot.origin;
638                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
639                 // don't reset back to last position, even if new position is stuck in solid
640                 this.oldorigin = this.origin;
641                 this.prevorigin = this.origin;
642                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
643                 if(this.conveyor)
644                         IL_REMOVE(g_conveyed, this);
645                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
646                 this.hud = HUD_NORMAL;
647
648                 this.event_damage = PlayerDamage;
649
650                 if(!this.bot_attack)
651                         IL_PUSH(g_bot_targets, this);
652                 this.bot_attack = true;
653                 this.monster_attack = true;
654
655                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
656
657                 if (this.killcount == FRAGS_SPECTATOR) {
658                         PlayerScore_Clear(this);
659                         this.killcount = 0;
660                 }
661
662                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
663                 {
664                         .entity weaponentity = weaponentities[slot];
665                         entity oldwep = this.(weaponentity);
666                         CL_SpawnWeaponentity(this, weaponentity);
667                         if(oldwep && oldwep.owner == this)
668                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
669                 }
670                 this.alpha = default_player_alpha;
671                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
672                 this.exteriorweaponentity.alpha = default_weapon_alpha;
673
674                 this.speedrunning = false;
675
676                 target_voicescript_clear(this);
677
678                 // reset fields the weapons may use
679                 FOREACH(Weapons, true, LAMBDA(
680                         it.wr_resetplayer(it, this);
681                         // reload all reloadable weapons
682                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
683                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
684                                 {
685                                         .entity weaponentity = weaponentities[slot];
686                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
687                                 }
688                         }
689                 ));
690
691                 {
692                         string s = spot.target;
693                         spot.target = string_null;
694                         SUB_UseTargets(spot, this, NULL);
695                         spot.target = s;
696                 }
697
698                 Unfreeze(this);
699
700                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
701
702                 if (autocvar_spawn_debug)
703                 {
704                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
705                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
706                 }
707
708                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
709                 {
710                         .entity weaponentity = weaponentities[slot];
711                         if(slot == 0)
712                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
713                         else
714                                 this.(weaponentity).m_switchweapon = WEP_Null;
715                         this.(weaponentity).m_weapon = WEP_Null;
716                         this.(weaponentity).weaponname = "";
717                         this.(weaponentity).m_switchingweapon = WEP_Null;
718                         this.(weaponentity).cnt = -1;
719                 }
720
721                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
722
723                 if (!warmup_stage && !this.alivetime)
724                         this.alivetime = time;
725
726                 antilag_clear(this, CS(this));
727         }
728 }
729
730 void ClientInit_misc(entity this);
731
732 // TODO do we need all these fields, or should we stop autodetecting runtime
733 // changes and just have a console command to update this?
734 bool ClientInit_SendEntity(entity this, entity to, int sf)
735 {
736         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
737         return = true;
738         msg_entity = to;
739         // MSG_INIT replacement
740         // TODO: make easier to use
741         Registry_send_all();
742         W_PROP_reload(MSG_ONE, to);
743         ClientInit_misc(this);
744         MUTATOR_CALLHOOK(Ent_Init);
745 }
746 void ClientInit_misc(entity this)
747 {
748         int channel = MSG_ONE;
749         WriteHeader(channel, ENT_CLIENT_INIT);
750         WriteByte(channel, g_nexball_meter_period * 32);
751         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
752         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
753         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
754         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
755         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
756         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
757         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
758         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
759
760         if(sv_foginterval && world.fog != "")
761                 WriteString(channel, world.fog);
762         else
763                 WriteString(channel, "");
764         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
765         WriteByte(channel, serverflags);
766         WriteCoord(channel, autocvar_g_trueaim_minrange);
767 }
768
769 void ClientInit_CheckUpdate(entity this)
770 {
771         this.nextthink = time;
772         if(this.count != autocvar_g_balance_armor_blockpercent)
773         {
774                 this.count = autocvar_g_balance_armor_blockpercent;
775                 this.SendFlags |= 1;
776         }
777 }
778
779 void ClientInit_Spawn()
780 {
781         entity e = new_pure(clientinit);
782         setthink(e, ClientInit_CheckUpdate);
783         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
784
785         ClientInit_CheckUpdate(e);
786 }
787
788 /*
789 =============
790 SetNewParms
791 =============
792 */
793 void SetNewParms ()
794 {
795         // initialize parms for a new player
796         parm1 = -(86400 * 366);
797
798         MUTATOR_CALLHOOK(SetNewParms);
799 }
800
801 /*
802 =============
803 SetChangeParms
804 =============
805 */
806 void SetChangeParms (entity this)
807 {
808         // save parms for level change
809         parm1 = this.parm_idlesince - time;
810
811         MUTATOR_CALLHOOK(SetChangeParms);
812 }
813
814 /*
815 =============
816 DecodeLevelParms
817 =============
818 */
819 void DecodeLevelParms(entity this)
820 {
821         // load parms
822         this.parm_idlesince = parm1;
823         if (this.parm_idlesince == -(86400 * 366))
824                 this.parm_idlesince = time;
825
826         // whatever happens, allow 60 seconds of idling directly after connect for map loading
827         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
828
829         MUTATOR_CALLHOOK(DecodeLevelParms);
830 }
831
832 /*
833 =============
834 ClientKill
835
836 Called when a client types 'kill' in the console
837 =============
838 */
839
840 .float clientkill_nexttime;
841 void ClientKill_Now_TeamChange(entity this)
842 {
843         if(this.killindicator_teamchange == -1)
844         {
845                 JoinBestTeam( this, false, true );
846         }
847         else if(this.killindicator_teamchange == -2)
848         {
849                 if(blockSpectators)
850                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
851                 PutObserverInServer(this);
852         }
853         else
854                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
855         this.killindicator_teamchange = 0;
856 }
857
858 void ClientKill_Now(entity this)
859 {
860         if(this.vehicle)
861         {
862             vehicles_exit(this.vehicle, VHEF_RELEASE);
863             if(!this.killindicator_teamchange)
864             {
865             this.vehicle_health = -1;
866             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
867             }
868         }
869
870         if(this.killindicator && !wasfreed(this.killindicator))
871                 delete(this.killindicator);
872
873         this.killindicator = NULL;
874
875         if(this.killindicator_teamchange)
876                 ClientKill_Now_TeamChange(this);
877
878         if(!IS_SPEC(this) && !IS_OBSERVER(this))
879                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
880
881         // now I am sure the player IS dead
882 }
883 void KillIndicator_Think(entity this)
884 {
885         if (game_stopped)
886         {
887                 this.owner.killindicator = NULL;
888                 delete(this);
889                 return;
890         }
891
892         if (this.owner.alpha < 0 && !this.owner.vehicle)
893         {
894                 this.owner.killindicator = NULL;
895                 delete(this);
896                 return;
897         }
898
899         if(this.cnt <= 0)
900         {
901                 ClientKill_Now(this.owner);
902                 return;
903         }
904     else if(this.health == 1) // health == 1 means that it's silent
905     {
906         this.nextthink = time + 1;
907         this.cnt -= 1;
908     }
909         else
910         {
911                 if(this.cnt <= 10)
912                         setmodel(this, MDL_NUM(this.cnt));
913                 if(IS_REAL_CLIENT(this.owner))
914                 {
915                         if(this.cnt <= 10)
916                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
917                 }
918                 this.nextthink = time + 1;
919                 this.cnt -= 1;
920         }
921 }
922
923 float clientkilltime;
924 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
925 {
926         float killtime;
927         float starttime;
928
929         if (game_stopped)
930                 return;
931
932         killtime = autocvar_g_balance_kill_delay;
933
934     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
935         return;
936     killtime = M_ARGV(1, float);
937
938         this.killindicator_teamchange = targetteam;
939
940     if(!this.killindicator)
941         {
942                 if(!IS_DEAD(this))
943                 {
944                         killtime = max(killtime, this.clientkill_nexttime - time);
945                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
946                 }
947
948                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
949                 {
950                         ClientKill_Now(this);
951                 }
952                 else
953                 {
954                         starttime = max(time, clientkilltime);
955
956                         this.killindicator = spawn();
957                         this.killindicator.owner = this;
958                         this.killindicator.scale = 0.5;
959                         setattachment(this.killindicator, this, "");
960                         setorigin(this.killindicator, '0 0 52');
961                         setthink(this.killindicator, KillIndicator_Think);
962                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
963                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
964                         this.killindicator.cnt = ceil(killtime);
965                         this.killindicator.count = bound(0, ceil(killtime), 10);
966                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
967
968                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
969                         {
970                                 it.killindicator = spawn();
971                                 it.killindicator.owner = it;
972                                 it.killindicator.scale = 0.5;
973                                 setattachment(it.killindicator, it, "");
974                                 setorigin(it.killindicator, '0 0 52');
975                                 setthink(it.killindicator, KillIndicator_Think);
976                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
977                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
978                                 it.killindicator.cnt = ceil(killtime);
979                         });
980                         this.lip = 0;
981                 }
982         }
983         if(this.killindicator)
984         {
985                 if(targetteam == 0) // just die
986                 {
987                         this.killindicator.colormod = '0 0 0';
988                         if(IS_REAL_CLIENT(this))
989                         if(this.killindicator.cnt > 0)
990                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
991                 }
992                 else if(targetteam == -1) // auto
993                 {
994                         this.killindicator.colormod = '0 1 0';
995                         if(IS_REAL_CLIENT(this))
996                         if(this.killindicator.cnt > 0)
997                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
998                 }
999                 else if(targetteam == -2) // spectate
1000                 {
1001                         this.killindicator.colormod = '0.5 0.5 0.5';
1002                         if(IS_REAL_CLIENT(this))
1003                         if(this.killindicator.cnt > 0)
1004                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1005                 }
1006                 else
1007                 {
1008                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1009                         if(IS_REAL_CLIENT(this))
1010                         if(this.killindicator.cnt > 0)
1011                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1012                 }
1013         }
1014
1015 }
1016
1017 void ClientKill (entity this)
1018 {
1019         if(game_stopped) return;
1020         if(this.player_blocked) return;
1021         if(STAT(FROZEN, this)) return;
1022
1023         ClientKill_TeamChange(this, 0);
1024 }
1025
1026 void FixClientCvars(entity e)
1027 {
1028         // send prediction settings to the client
1029         stuffcmd(e, "\nin_bindmap 0 0\n");
1030         if(autocvar_g_antilag == 3) // client side hitscan
1031                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1032         if(autocvar_sv_gentle)
1033                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1034
1035         MUTATOR_CALLHOOK(FixClientCvars, e);
1036 }
1037
1038 float PlayerInIDList(entity p, string idlist)
1039 {
1040         float n, i;
1041         string s;
1042
1043         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1044         if (!p.crypto_idfp)
1045                 return 0;
1046
1047         // this function allows abbreviated player IDs too!
1048         n = tokenize_console(idlist);
1049         for(i = 0; i < n; ++i)
1050         {
1051                 s = argv(i);
1052                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1053                         return 1;
1054         }
1055
1056         return 0;
1057 }
1058
1059 #ifdef DP_EXT_PRECONNECT
1060 /*
1061 =============
1062 ClientPreConnect
1063
1064 Called once (not at each match start) when a client begins a connection to the server
1065 =============
1066 */
1067 void ClientPreConnect(entity this)
1068 {
1069         if(autocvar_sv_eventlog)
1070         {
1071                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1072                         this.playerid,
1073                         etof(this),
1074                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1075                 ));
1076         }
1077 }
1078 #endif
1079
1080 /**
1081 =============
1082 ClientConnect
1083
1084 Called when a client connects to the server
1085 =============
1086 */
1087 void ClientConnect(entity this)
1088 {
1089         if (Ban_MaybeEnforceBanOnce(this)) return;
1090         assert(!IS_CLIENT(this), return);
1091         this.flags |= FL_CLIENT;
1092         assert(player_count >= 0, player_count = 0);
1093
1094 #ifdef WATERMARK
1095         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1096 #endif
1097         this.version_nagtime = time + 10 + random() * 10;
1098         TRANSMUTE(Client, this);
1099
1100         // identify the right forced team
1101         if (autocvar_g_campaign)
1102         {
1103                 if (IS_REAL_CLIENT(this)) // only players, not bots
1104                 {
1105                         switch (autocvar_g_campaign_forceteam)
1106                         {
1107                                 case 1: this.team_forced = NUM_TEAM_1; break;
1108                                 case 2: this.team_forced = NUM_TEAM_2; break;
1109                                 case 3: this.team_forced = NUM_TEAM_3; break;
1110                                 case 4: this.team_forced = NUM_TEAM_4; break;
1111                                 default: this.team_forced = 0;
1112                         }
1113                 }
1114         }
1115         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1116         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1117         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1118         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1119         else switch (autocvar_g_forced_team_otherwise)
1120         {
1121                 default: this.team_forced = 0; break;
1122                 case "red": this.team_forced = NUM_TEAM_1; break;
1123                 case "blue": this.team_forced = NUM_TEAM_2; break;
1124                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1125                 case "pink": this.team_forced = NUM_TEAM_4; break;
1126                 case "spectate":
1127                 case "spectator":
1128                         this.team_forced = -1;
1129                         break;
1130         }
1131         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1132
1133     {
1134         int id = this.playerid;
1135         this.playerid = 0; // silent
1136             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1137             this.playerid = id;
1138     }
1139
1140         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1141                 TRANSMUTE(Observer, this);
1142         } else {
1143                 if (!teamplay || autocvar_g_balance_teams) {
1144                         TRANSMUTE(Player, this);
1145                         campaign_bots_may_start = true;
1146                 } else {
1147                         TRANSMUTE(Observer, this); // do it anyway
1148                 }
1149         }
1150
1151         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1152
1153         // always track bots, don't ask for cl_allow_uidtracking
1154     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1155
1156         if (autocvar_sv_eventlog)
1157                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1158
1159         LogTeamchange(this.playerid, this.team, 1);
1160
1161         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1162
1163         this.netname_previous = strzone(this.netname);
1164
1165         if(teamplay && IS_PLAYER(this))
1166                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1167         else
1168                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1169
1170         stuffcmd(this, clientstuff, "\n");
1171         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1172
1173         FixClientCvars(this);
1174
1175         // get version info from player
1176         stuffcmd(this, "cmd clientversion $gameversion\n");
1177
1178         // notify about available teams
1179         if (teamplay)
1180         {
1181                 CheckAllowedTeams(this);
1182                 int t = 0;
1183                 if (c1 >= 0) t |= BIT(0);
1184                 if (c2 >= 0) t |= BIT(1);
1185                 if (c3 >= 0) t |= BIT(2);
1186                 if (c4 >= 0) t |= BIT(3);
1187                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1188         }
1189         else
1190         {
1191                 stuffcmd(this, "set _teams_available 0\n");
1192         }
1193
1194         bot_relinkplayerlist();
1195
1196         this.spectatortime = time;
1197         if (blockSpectators)
1198         {
1199                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1200         }
1201
1202         this.jointime = time;
1203         this.allowed_timeouts = autocvar_sv_timeout_number;
1204
1205         if (IS_REAL_CLIENT(this))
1206         {
1207                 if (g_weaponarena_weapons == WEPSET(TUBA))
1208                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1209         }
1210
1211         if (!sv_foginterval && world.fog != "")
1212                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1213
1214         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1215                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1216                         send_CSQC_teamnagger();
1217
1218         CSQCMODEL_AUTOINIT(this);
1219
1220         this.model_randomizer = random();
1221
1222         if (IS_REAL_CLIENT(this))
1223                 sv_notice_join(this);
1224
1225         // update physics stats (players can spawn before physics runs)
1226         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1227
1228         IL_EACH(g_initforplayer, it.init_for_player, {
1229                 it.init_for_player(it, this);
1230         });
1231
1232         MUTATOR_CALLHOOK(ClientConnect, this);
1233
1234         if (IS_REAL_CLIENT(this))
1235         {
1236                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1237                 {
1238                         this.motd_actived_time = -1;
1239                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1240                 }
1241         }
1242 }
1243 /*
1244 =============
1245 ClientDisconnect
1246
1247 Called when a client disconnects from the server
1248 =============
1249 */
1250 .entity chatbubbleentity;
1251 void ReadyCount();
1252 void ClientDisconnect(entity this)
1253 {
1254         assert(IS_CLIENT(this), return);
1255
1256         PlayerStats_GameReport_FinalizePlayer(this);
1257         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1258         if (this.active_minigame) part_minigame(this);
1259         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1260
1261         if (autocvar_sv_eventlog)
1262                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1263
1264         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1265
1266         if(IS_SPEC(this))
1267                 SetSpectatee(this, NULL);
1268
1269     MUTATOR_CALLHOOK(ClientDisconnect, this);
1270
1271         ClientState_detach(this);
1272
1273         Portal_ClearAll(this);
1274
1275         Unfreeze(this);
1276
1277         RemoveGrapplingHooks(this);
1278
1279         // Here, everything has been done that requires this player to be a client.
1280
1281         this.flags &= ~FL_CLIENT;
1282
1283         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1284         if (this.killindicator) delete(this.killindicator);
1285
1286         WaypointSprite_PlayerGone(this);
1287
1288         bot_relinkplayerlist();
1289
1290         if (this.netname_previous) strunzone(this.netname_previous);
1291         if (this.clientstatus) strunzone(this.clientstatus);
1292         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1293         if (this.personal) delete(this.personal);
1294
1295         this.playerid = 0;
1296         ReadyCount();
1297         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1298
1299         ONREMOVE(this);
1300 }
1301
1302 void ChatBubbleThink(entity this)
1303 {
1304         this.nextthink = time;
1305         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1306         {
1307                 if(this.owner) // but why can that ever be NULL?
1308                         this.owner.chatbubbleentity = NULL;
1309                 delete(this);
1310                 return;
1311         }
1312
1313         this.mdl = "";
1314
1315         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1316         {
1317                 if ( this.owner.active_minigame )
1318                         this.mdl = "models/sprites/minigame_busy.iqm";
1319                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1320                         this.mdl = "models/misc/chatbubble.spr";
1321         }
1322
1323         if ( this.model != this.mdl )
1324                 _setmodel(this, this.mdl);
1325
1326 }
1327
1328 void UpdateChatBubble(entity this)
1329 {
1330         if (this.alpha < 0)
1331                 return;
1332         // spawn a chatbubble entity if needed
1333         if (!this.chatbubbleentity)
1334         {
1335                 this.chatbubbleentity = new(chatbubbleentity);
1336                 this.chatbubbleentity.owner = this;
1337                 this.chatbubbleentity.exteriormodeltoclient = this;
1338                 setthink(this.chatbubbleentity, ChatBubbleThink);
1339                 this.chatbubbleentity.nextthink = time;
1340                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1341                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1342                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1343                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1344                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1345                 //this.chatbubbleentity.model = "";
1346                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1347         }
1348 }
1349
1350
1351 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1352 // added to the model skins
1353 /*void UpdateColorModHack()
1354 {
1355         float c;
1356         c = this.clientcolors & 15;
1357         // LordHavoc: only bothering to support white, green, red, yellow, blue
1358              if (!teamplay) this.colormod = '0 0 0';
1359         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1360         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1361         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1362         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1363         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1364         else this.colormod = '1 1 1';
1365 }*/
1366
1367 void respawn(entity this)
1368 {
1369         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1370         {
1371                 this.solid = SOLID_NOT;
1372                 this.takedamage = DAMAGE_NO;
1373                 set_movetype(this, MOVETYPE_FLY);
1374                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1375                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1376                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1377                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1378                 if(autocvar_g_respawn_ghosts_maxtime)
1379                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1380         }
1381
1382         CopyBody(this, 1);
1383
1384         this.effects |= EF_NODRAW; // prevent another CopyBody
1385         PutClientInServer(this);
1386 }
1387
1388 void play_countdown(entity this, float finished, Sound samp)
1389 {
1390     TC(Sound, samp);
1391         if(IS_REAL_CLIENT(this))
1392                 if(floor(finished - time - frametime) != floor(finished - time))
1393                         if(finished - time < 6)
1394                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1395 }
1396
1397 void player_powerups(entity this)
1398 {
1399         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1400         int items_prev = this.items;
1401
1402         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1403                 this.modelflags |= MF_ROCKET;
1404         else
1405                 this.modelflags &= ~MF_ROCKET;
1406
1407         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1408
1409         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1410                 return;
1411
1412         Fire_ApplyDamage(this);
1413         Fire_ApplyEffect(this);
1414
1415         if (!g_instagib)
1416         {
1417                 if (this.items & ITEM_Strength.m_itemid)
1418                 {
1419                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1420                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1421                         if (time > this.strength_finished)
1422                         {
1423                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1424                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1425                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1426                         }
1427                 }
1428                 else
1429                 {
1430                         if (time < this.strength_finished)
1431                         {
1432                                 this.items = this.items | ITEM_Strength.m_itemid;
1433                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1434                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1435                         }
1436                 }
1437                 if (this.items & ITEM_Shield.m_itemid)
1438                 {
1439                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1440                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1441                         if (time > this.invincible_finished)
1442                         {
1443                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1444                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1445                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1446                         }
1447                 }
1448                 else
1449                 {
1450                         if (time < this.invincible_finished)
1451                         {
1452                                 this.items = this.items | ITEM_Shield.m_itemid;
1453                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1454                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1455                         }
1456                 }
1457                 if (this.items & IT_SUPERWEAPON)
1458                 {
1459                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1460                         {
1461                                 this.superweapons_finished = 0;
1462                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1463                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1465                         }
1466                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1467                         {
1468                                 // don't let them run out
1469                         }
1470                         else
1471                         {
1472                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1473                                 if (time > this.superweapons_finished)
1474                                 {
1475                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1476                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1477                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1478                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1479                                 }
1480                         }
1481                 }
1482                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1483                 {
1484                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1485                         {
1486                                 this.items = this.items | IT_SUPERWEAPON;
1487                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1488                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1489                         }
1490                         else
1491                         {
1492                                 this.superweapons_finished = 0;
1493                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1494                         }
1495                 }
1496                 else
1497                 {
1498                         this.superweapons_finished = 0;
1499                 }
1500         }
1501
1502         if(autocvar_g_nodepthtestplayers)
1503                 this.effects = this.effects | EF_NODEPTHTEST;
1504
1505         if(autocvar_g_fullbrightplayers)
1506                 this.effects = this.effects | EF_FULLBRIGHT;
1507
1508         if (time >= game_starttime)
1509         if (time < this.spawnshieldtime)
1510                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1511
1512         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1513 }
1514
1515 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1516 {
1517         if(current > stable)
1518                 return current;
1519         else if(current > stable - 0.25) // when close enough, "snap"
1520                 return stable;
1521         else
1522                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1523 }
1524
1525 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1526 {
1527         if(current < stable)
1528                 return current;
1529         else if(current < stable + 0.25) // when close enough, "snap"
1530                 return stable;
1531         else
1532                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1533 }
1534
1535 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1536 {
1537         if(current > rotstable)
1538         {
1539                 if(rotframetime > 0)
1540                 {
1541                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1542                         current = max(rotstable, current - rotlinear * rotframetime);
1543                 }
1544         }
1545         else if(current < regenstable)
1546         {
1547                 if(regenframetime > 0)
1548                 {
1549                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1550                         current = min(regenstable, current + regenlinear * regenframetime);
1551                 }
1552         }
1553
1554         if(current > limit)
1555                 current = limit;
1556
1557         return current;
1558 }
1559
1560 void player_regen(entity this)
1561 {
1562         float max_mod, regen_mod, rot_mod, limit_mod;
1563         max_mod = regen_mod = rot_mod = limit_mod = 1;
1564
1565         float regen_health = autocvar_g_balance_health_regen;
1566         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1567         float regen_health_rot = autocvar_g_balance_health_rot;
1568         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1569         float regen_health_stable = autocvar_g_balance_health_regenstable;
1570         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1571         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1572                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1573         max_mod = M_ARGV(1, float);
1574         regen_mod = M_ARGV(2, float);
1575         rot_mod = M_ARGV(3, float);
1576         limit_mod = M_ARGV(4, float);
1577         regen_health = M_ARGV(5, float);
1578         regen_health_linear = M_ARGV(6, float);
1579         regen_health_rot = M_ARGV(7, float);
1580         regen_health_rotlinear = M_ARGV(8, float);
1581         regen_health_stable = M_ARGV(9, float);
1582         regen_health_rotstable = M_ARGV(10, float);
1583
1584
1585         if(!mutator_returnvalue)
1586         if(!STAT(FROZEN, this))
1587         {
1588                 float mina, maxa, limith, limita;
1589                 maxa = autocvar_g_balance_armor_rotstable;
1590                 mina = autocvar_g_balance_armor_regenstable;
1591                 limith = autocvar_g_balance_health_limit;
1592                 limita = autocvar_g_balance_armor_limit;
1593
1594                 regen_health_rotstable = regen_health_rotstable * max_mod;
1595                 regen_health_stable = regen_health_stable * max_mod;
1596                 limith = limith * limit_mod;
1597                 limita = limita * limit_mod;
1598
1599                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1600                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1601         }
1602
1603         // if player rotted to death...  die!
1604         // check this outside above checks, as player may still be able to rot to death
1605         if(this.health < 1)
1606         {
1607                 if(this.vehicle)
1608                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1609                 if(this.event_damage)
1610                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1611         }
1612
1613         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1614         {
1615                 float minf, maxf, limitf;
1616
1617                 maxf = autocvar_g_balance_fuel_rotstable;
1618                 minf = autocvar_g_balance_fuel_regenstable;
1619                 limitf = autocvar_g_balance_fuel_limit;
1620
1621                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1622         }
1623 }
1624
1625 bool zoomstate_set;
1626 void SetZoomState(entity this, float newzoom)
1627 {
1628         if(newzoom != this.zoomstate)
1629         {
1630                 this.zoomstate = newzoom;
1631                 ClientData_Touch(this);
1632         }
1633         zoomstate_set = true;
1634 }
1635
1636 void GetPressedKeys(entity this)
1637 {
1638         MUTATOR_CALLHOOK(GetPressedKeys, this);
1639         int keys = STAT(PRESSED_KEYS, this);
1640         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1641         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1642         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1643         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1644
1645         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1646         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1647         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1648         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1649         this.pressedkeys = keys; // store for other users
1650
1651         STAT(PRESSED_KEYS, this) = keys;
1652 }
1653
1654 /*
1655 ======================
1656 spectate mode routines
1657 ======================
1658 */
1659
1660 void SpectateCopy(entity this, entity spectatee)
1661 {
1662     TC(Client, this); TC(Client, spectatee);
1663
1664         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1665         PS(this) = PS(spectatee);
1666         this.armortype = spectatee.armortype;
1667         this.armorvalue = spectatee.armorvalue;
1668         this.ammo_cells = spectatee.ammo_cells;
1669         this.ammo_plasma = spectatee.ammo_plasma;
1670         this.ammo_shells = spectatee.ammo_shells;
1671         this.ammo_nails = spectatee.ammo_nails;
1672         this.ammo_rockets = spectatee.ammo_rockets;
1673         this.ammo_fuel = spectatee.ammo_fuel;
1674         this.clip_load = spectatee.clip_load;
1675         this.clip_size = spectatee.clip_size;
1676         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1677         this.health = spectatee.health;
1678         this.impulse = 0;
1679         this.items = spectatee.items;
1680         this.last_pickup = spectatee.last_pickup;
1681         this.hit_time = spectatee.hit_time;
1682         this.strength_finished = spectatee.strength_finished;
1683         this.invincible_finished = spectatee.invincible_finished;
1684         this.superweapons_finished = spectatee.superweapons_finished;
1685         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1686         this.weapons = spectatee.weapons;
1687         this.vortex_charge = spectatee.vortex_charge;
1688         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1689         this.hagar_load = spectatee.hagar_load;
1690         this.arc_heat_percent = spectatee.arc_heat_percent;
1691         this.minelayer_mines = spectatee.minelayer_mines;
1692         this.punchangle = spectatee.punchangle;
1693         this.view_ofs = spectatee.view_ofs;
1694         this.velocity = spectatee.velocity;
1695         this.dmg_take = spectatee.dmg_take;
1696         this.dmg_save = spectatee.dmg_save;
1697         this.dmg_inflictor = spectatee.dmg_inflictor;
1698         this.v_angle = spectatee.v_angle;
1699         this.angles = spectatee.v_angle;
1700         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1701         this.revive_progress = spectatee.revive_progress;
1702         this.viewloc = spectatee.viewloc;
1703         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1704                 this.fixangle = true;
1705         setorigin(this, spectatee.origin);
1706         setsize(this, spectatee.mins, spectatee.maxs);
1707         SetZoomState(this, spectatee.zoomstate);
1708
1709         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1710         {
1711                 .entity weaponentity = weaponentities[slot];
1712                 this.(weaponentity) = spectatee.(weaponentity);
1713         }
1714
1715         for(int slot = 0; slot < MAX_AXH; ++slot)
1716         {
1717                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1718         }
1719
1720     anticheat_spectatecopy(this, spectatee);
1721         this.hud = spectatee.hud;
1722         if(spectatee.vehicle)
1723     {
1724         this.angles = spectatee.v_angle;
1725
1726         //this.fixangle = false;
1727         //this.velocity = spectatee.vehicle.velocity;
1728         this.vehicle_health = spectatee.vehicle_health;
1729         this.vehicle_shield = spectatee.vehicle_shield;
1730         this.vehicle_energy = spectatee.vehicle_energy;
1731         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1732         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1733         this.vehicle_reload1 = spectatee.vehicle_reload1;
1734         this.vehicle_reload2 = spectatee.vehicle_reload2;
1735
1736         //msg_entity = this;
1737
1738        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1739             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1740            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1741            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1742
1743         //WriteByte (MSG_ONE, SVC_SETVIEW);
1744         //    WriteEntity(MSG_ONE, this);
1745         //makevectors(spectatee.v_angle);
1746         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1747     }
1748 }
1749
1750 bool SpectateUpdate(entity this)
1751 {
1752         if(!this.enemy)
1753                 return false;
1754
1755         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1756         {
1757                 SetSpectatee(this, NULL);
1758                 return false;
1759         }
1760
1761         SpectateCopy(this, this.enemy);
1762
1763         return true;
1764 }
1765
1766 bool SpectateSet(entity this)
1767 {
1768         if(!IS_PLAYER(this.enemy))
1769                 return false;
1770
1771         ClientData_Touch(this.enemy);
1772
1773         msg_entity = this;
1774         WriteByte(MSG_ONE, SVC_SETVIEW);
1775         WriteEntity(MSG_ONE, this.enemy);
1776         set_movetype(this, MOVETYPE_NONE);
1777         accuracy_resend(this);
1778
1779         if(!SpectateUpdate(this))
1780                 PutObserverInServer(this);
1781
1782         return true;
1783 }
1784
1785 void SetSpectatee_status(entity this, int spectatee_num)
1786 {
1787         int oldspectatee_status = this.spectatee_status;
1788         this.spectatee_status = spectatee_num;
1789
1790         if (this.spectatee_status != oldspectatee_status)
1791         {
1792                 ClientData_Touch(this);
1793                 if (g_race || g_cts) race_InitSpectator();
1794         }
1795 }
1796
1797 void SetSpectatee(entity this, entity spectatee)
1798 {
1799         entity old_spectatee = this.enemy;
1800
1801         this.enemy = spectatee;
1802
1803         // WEAPONTODO
1804         // these are required to fix the spectator bug with arc
1805         if(old_spectatee)
1806         {
1807                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1808                 {
1809                         .entity weaponentity = weaponentities[slot];
1810                         if(old_spectatee.(weaponentity).arc_beam)
1811                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1812                 }
1813         }
1814         if(this.enemy)
1815         {
1816                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1817                 {
1818                         .entity weaponentity = weaponentities[slot];
1819                         if(this.enemy.(weaponentity).arc_beam)
1820                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1821                 }
1822         }
1823
1824         if (this.enemy)
1825                 SetSpectatee_status(this, etof(this.enemy));
1826
1827         // needed to update spectator list
1828         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1829 }
1830
1831 bool Spectate(entity this, entity pl)
1832 {
1833         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1834                 return false;
1835         pl = M_ARGV(1, entity);
1836
1837         SetSpectatee(this, pl);
1838         return SpectateSet(this);
1839 }
1840
1841 bool SpectateNext(entity this)
1842 {
1843         entity ent = find(this.enemy, classname, STR_PLAYER);
1844
1845         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1846                 ent = M_ARGV(1, entity);
1847         else if (!ent)
1848                 ent = find(ent, classname, STR_PLAYER);
1849
1850         if(ent) { SetSpectatee(this, ent); }
1851
1852         return SpectateSet(this);
1853 }
1854
1855 bool SpectatePrev(entity this)
1856 {
1857         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1858         entity ent = findchain(classname, STR_PLAYER);
1859         if (!ent) // no player
1860                 return false;
1861
1862         entity first = ent;
1863         // skip players until current spectated player
1864         if(this.enemy)
1865         while(ent && ent != this.enemy)
1866                 ent = ent.chain;
1867
1868         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1869         {
1870                 case MUT_SPECPREV_FOUND:
1871                     ent = M_ARGV(1, entity);
1872                     break;
1873                 case MUT_SPECPREV_RETURN:
1874                     return true;
1875                 case MUT_SPECPREV_CONTINUE:
1876                 default:
1877                 {
1878                         if(ent.chain)
1879                                 ent = ent.chain;
1880                         else
1881                                 ent = first;
1882                         break;
1883                 }
1884         }
1885
1886         SetSpectatee(this, ent);
1887         return SpectateSet(this);
1888 }
1889
1890 /*
1891 =============
1892 ShowRespawnCountdown()
1893
1894 Update a respawn countdown display.
1895 =============
1896 */
1897 void ShowRespawnCountdown(entity this)
1898 {
1899         float number;
1900         if(!IS_DEAD(this)) // just respawned?
1901                 return;
1902         else
1903         {
1904                 number = ceil(this.respawn_time - time);
1905                 if(number <= 0)
1906                         return;
1907                 if(number <= this.respawn_countdown)
1908                 {
1909                         this.respawn_countdown = number - 1;
1910                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1911                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1912                 }
1913         }
1914 }
1915
1916 .bool team_selected;
1917 bool ShowTeamSelection(entity this)
1918 {
1919         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1920                 return false;
1921         stuffcmd(this, "menu_showteamselect\n");
1922         return true;
1923 }
1924 void Join(entity this)
1925 {
1926         TRANSMUTE(Player, this);
1927
1928         if(!this.team_selected)
1929         if(autocvar_g_campaign || autocvar_g_balance_teams)
1930                 JoinBestTeam(this, false, true);
1931
1932         if(autocvar_g_campaign)
1933                 campaign_bots_may_start = true;
1934
1935         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1936
1937         PutClientInServer(this);
1938
1939         if(teamplay && this.team != -1)
1940                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1941         else
1942                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1943         this.team_selected = false;
1944 }
1945
1946 /**
1947  * Determines whether the player is allowed to join. This depends on cvar
1948  * g_maxplayers, if it isn't used this function always return true, otherwise
1949  * it checks whether the number of currently playing players exceeds g_maxplayers.
1950  * @return int number of free slots for players, 0 if none
1951  */
1952 int nJoinAllowed(entity this, entity ignore)
1953 {
1954         if(!ignore)
1955         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1956         // so report 0 free slots if restricted
1957         {
1958                 if(autocvar_g_forced_team_otherwise == "spectate")
1959                         return 0;
1960                 if(autocvar_g_forced_team_otherwise == "spectator")
1961                         return 0;
1962         }
1963
1964         if(this && this.team_forced < 0)
1965                 return 0; // forced spectators can never join
1966
1967         // TODO simplify this
1968         int totalClients = 0;
1969         int currentlyPlaying = 0;
1970         FOREACH_CLIENT(true, LAMBDA(
1971                 if(it != ignore)
1972                         ++totalClients;
1973                 if(IS_REAL_CLIENT(it))
1974                 if(IS_PLAYER(it) || it.caplayer)
1975                         ++currentlyPlaying;
1976         ));
1977
1978         float free_slots = 0;
1979         if (!autocvar_g_maxplayers)
1980                 free_slots = maxclients - totalClients;
1981         else if(currentlyPlaying < autocvar_g_maxplayers)
1982                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1983
1984         static float join_prevent_msg_time = 0;
1985         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1986         {
1987                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1988                 join_prevent_msg_time = time + 3;
1989         }
1990
1991         return free_slots;
1992 }
1993
1994 /**
1995  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1996  * g_maxplayers_spectator_blocktime seconds
1997  */
1998 void checkSpectatorBlock(entity this)
1999 {
2000         if(IS_SPEC(this) || IS_OBSERVER(this))
2001         if(!this.caplayer)
2002         if(IS_REAL_CLIENT(this))
2003         {
2004                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2005                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2006                         dropclient(this);
2007                 }
2008         }
2009 }
2010
2011 void PrintWelcomeMessage(entity this)
2012 {
2013         if(this.motd_actived_time == 0)
2014         {
2015                 if (autocvar_g_campaign) {
2016                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2017                                 this.motd_actived_time = time;
2018                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2019                         }
2020                 } else {
2021                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2022                                 this.motd_actived_time = time;
2023                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2024                         }
2025                 }
2026         }
2027         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2028         {
2029                 if (autocvar_g_campaign) {
2030                         if (PHYS_INPUT_BUTTON_INFO(this))
2031                                 this.motd_actived_time = time;
2032                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2033                                 this.motd_actived_time = 0;
2034                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2035                         }
2036                 } else {
2037                         if (PHYS_INPUT_BUTTON_INFO(this))
2038                                 this.motd_actived_time = time;
2039                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2040                                 this.motd_actived_time = 0;
2041                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2042                         }
2043                 }
2044         }
2045         else //if(this.motd_actived_time < 0) // just connected, motd is active
2046         {
2047                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2048                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2049                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2050                 {
2051                         // instanctly hide MOTD
2052                         this.motd_actived_time = 0;
2053                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2054                 }
2055         }
2056 }
2057
2058 bool joinAllowed(entity this)
2059 {
2060         if (this.version_mismatch) return false;
2061         if (!nJoinAllowed(this, this)) return false;
2062         if (teamplay && lockteams) return false;
2063         if (ShowTeamSelection(this)) return false;
2064         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2065         return true;
2066 }
2067
2068 void ObserverThink(entity this)
2069 {
2070         if ( this.impulse )
2071         {
2072                 MinigameImpulse(this, this.impulse);
2073                 this.impulse = 0;
2074         }
2075
2076         if (this.flags & FL_JUMPRELEASED) {
2077                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2078                         this.flags &= ~FL_JUMPRELEASED;
2079                         this.flags |= FL_SPAWNING;
2080                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2081                         this.flags &= ~FL_JUMPRELEASED;
2082                         if(SpectateNext(this)) {
2083                                 TRANSMUTE(Spectator, this);
2084                         }
2085                 } else {
2086                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2087                         set_movetype(this, preferred_movetype);
2088                 }
2089         } else {
2090                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2091                         this.flags |= FL_JUMPRELEASED;
2092                         if(this.flags & FL_SPAWNING)
2093                         {
2094                                 this.flags &= ~FL_SPAWNING;
2095                                 Join(this);
2096                                 return;
2097                         }
2098                 }
2099         }
2100 }
2101
2102 void SpectatorThink(entity this)
2103 {
2104         if ( this.impulse )
2105         {
2106                 if(MinigameImpulse(this, this.impulse))
2107                         this.impulse = 0;
2108
2109                 if (this.impulse == IMP_weapon_drop.impulse)
2110                 {
2111                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2112                         this.impulse = 0;
2113                         return;
2114                 }
2115         }
2116
2117         if (this.flags & FL_JUMPRELEASED) {
2118                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2119                         this.flags &= ~FL_JUMPRELEASED;
2120                         this.flags |= FL_SPAWNING;
2121                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2122                         this.flags &= ~FL_JUMPRELEASED;
2123                         if(SpectateNext(this)) {
2124                                 TRANSMUTE(Spectator, this);
2125                         } else {
2126                                 TRANSMUTE(Observer, this);
2127                                 PutClientInServer(this);
2128                         }
2129                         this.impulse = 0;
2130                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2131                         this.flags &= ~FL_JUMPRELEASED;
2132                         if(SpectatePrev(this)) {
2133                                 TRANSMUTE(Spectator, this);
2134                         } else {
2135                                 TRANSMUTE(Observer, this);
2136                                 PutClientInServer(this);
2137                         }
2138                         this.impulse = 0;
2139                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2140                         this.flags &= ~FL_JUMPRELEASED;
2141                         TRANSMUTE(Observer, this);
2142                         PutClientInServer(this);
2143                 } else {
2144                         if(!SpectateUpdate(this))
2145                                 PutObserverInServer(this);
2146                 }
2147         } else {
2148                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2149                         this.flags |= FL_JUMPRELEASED;
2150                         if(this.flags & FL_SPAWNING)
2151                         {
2152                                 this.flags &= ~FL_SPAWNING;
2153                                 Join(this);
2154                                 return;
2155                         }
2156                 }
2157                 if(!SpectateUpdate(this))
2158                         PutObserverInServer(this);
2159         }
2160
2161         this.flags |= FL_CLIENT | FL_NOTARGET;
2162 }
2163
2164 void vehicles_enter (entity pl, entity veh);
2165 void PlayerUseKey(entity this)
2166 {
2167         if (!IS_PLAYER(this))
2168                 return;
2169
2170         if(this.vehicle)
2171         {
2172                 if(!game_stopped)
2173                 {
2174                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2175                         return;
2176                 }
2177         }
2178         else if(autocvar_g_vehicles_enter)
2179         {
2180                 if(!STAT(FROZEN, this))
2181                 if(!IS_DEAD(this))
2182                 if(!game_stopped)
2183                 {
2184                         entity head, closest_target = NULL;
2185                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2186
2187                         while(head) // find the closest acceptable target to enter
2188                         {
2189                                 if(IS_VEHICLE(head))
2190                                 if(!IS_DEAD(head))
2191                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2192                                 if(head.takedamage != DAMAGE_NO)
2193                                 {
2194                                         if(closest_target)
2195                                         {
2196                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2197                                                 { closest_target = head; }
2198                                         }
2199                                         else { closest_target = head; }
2200                                 }
2201
2202                                 head = head.chain;
2203                         }
2204
2205                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2206                 }
2207         }
2208
2209         // a use key was pressed; call handlers
2210         MUTATOR_CALLHOOK(PlayerUseKey, this);
2211 }
2212
2213
2214 /*
2215 =============
2216 PlayerPreThink
2217
2218 Called every frame for each client before the physics are run
2219 =============
2220 */
2221 .float usekeypressed;
2222 .float last_vehiclecheck;
2223 .int items_added;
2224 void PlayerPreThink (entity this)
2225 {
2226         WarpZone_PlayerPhysics_FixVAngle(this);
2227
2228     STAT(GAMESTARTTIME, this) = game_starttime;
2229         STAT(ROUNDSTARTTIME, this) = round_starttime;
2230         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2231         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2232
2233         STAT(WEAPONSINMAP, this) = weaponsInMap;
2234
2235         if (frametime) {
2236                 // physics frames: update anticheat stuff
2237                 anticheat_prethink(this);
2238         }
2239
2240         if (blockSpectators && frametime) {
2241                 // WORKAROUND: only use dropclient in server frames (frametime set).
2242                 // Never use it in cl_movement frames (frametime zero).
2243                 checkSpectatorBlock(this);
2244     }
2245
2246         zoomstate_set = false;
2247
2248         // Check for nameless players
2249         if (isInvisibleString(this.netname)) {
2250                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2251                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2252         }
2253         if (this.netname != this.netname_previous) {
2254                 if (autocvar_sv_eventlog) {
2255                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2256         }
2257                 if (this.netname_previous) strunzone(this.netname_previous);
2258                 this.netname_previous = strzone(this.netname);
2259         }
2260
2261         // version nagging
2262         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2263         this.version_nagtime = 0;
2264         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2265             // git client
2266         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2267             // git server
2268             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2269         } else {
2270             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2271             if (r < 0) { // old client
2272                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2273             } else if (r > 0) { // old server
2274                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2275             }
2276         }
2277     }
2278
2279         // GOD MODE info
2280         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2281         {
2282                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2283                 this.max_armorvalue = 0;
2284         }
2285
2286         if (STAT(FROZEN, this) == 2)
2287         {
2288                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2289                 this.health = max(1, this.revive_progress * start_health);
2290                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2291
2292                 if (this.revive_progress >= 1)
2293                         Unfreeze(this);
2294         }
2295         else if (STAT(FROZEN, this) == 3)
2296         {
2297                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2298                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2299
2300                 if (this.health < 1)
2301                 {
2302                         if (this.vehicle)
2303                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2304                         if(this.event_damage)
2305                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2306                 }
2307                 else if (this.revive_progress <= 0)
2308                         Unfreeze(this);
2309         }
2310
2311         MUTATOR_CALLHOOK(PlayerPreThink, this);
2312
2313         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2314         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2315         {
2316                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2317                 {
2318                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2319                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2320                         {
2321                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2322                         }
2323                         else if(!it.owner)
2324                         {
2325                                 if(!it.team || SAME_TEAM(this, it))
2326                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2327                                 else if(autocvar_g_vehicles_steal)
2328                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2329                         }
2330                 });
2331
2332                 this.last_vehiclecheck = time + 1;
2333         }
2334
2335         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2336         {
2337                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2338                         PlayerUseKey(this);
2339                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2340         }
2341
2342         if (IS_REAL_CLIENT(this))
2343                 PrintWelcomeMessage(this);
2344
2345         if (IS_PLAYER(this)) {
2346                 CheckRules_Player(this);
2347
2348                 if (game_stopped || intermission_running) {
2349                         this.modelflags &= ~MF_ROCKET;
2350                         if(intermission_running)
2351                                 IntermissionThink(this);
2352                         return;
2353                 }
2354
2355                 if (timeout_status == TIMEOUT_ACTIVE) {
2356             // don't allow the player to turn around while game is paused
2357                         // FIXME turn this into CSQC stuff
2358                         this.v_angle = this.lastV_angle;
2359                         this.angles = this.lastV_angle;
2360                         this.fixangle = true;
2361                 }
2362
2363                 if (frametime) player_powerups(this);
2364
2365                 if (IS_DEAD(this)) {
2366                         if (this.personal && g_race_qualifying) {
2367                                 if (time > this.respawn_time) {
2368                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2369                                         respawn(this);
2370                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2371                                 }
2372                         } else {
2373                                 if (frametime) player_anim(this);
2374                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2375
2376                                 switch(this.deadflag)
2377                                 {
2378                                         case DEAD_DYING:
2379                                         {
2380                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2381                                                         this.deadflag = DEAD_RESPAWNING;
2382                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2383                                                         this.deadflag = DEAD_DEAD;
2384                                                 break;
2385                                         }
2386                                         case DEAD_DEAD:
2387                                         {
2388                                                 if (button_pressed)
2389                                                         this.deadflag = DEAD_RESPAWNABLE;
2390                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2391                                                         this.deadflag = DEAD_RESPAWNING;
2392                                                 break;
2393                                         }
2394                                         case DEAD_RESPAWNABLE:
2395                                         {
2396                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2397                                                         this.deadflag = DEAD_RESPAWNING;
2398                                                 break;
2399                                         }
2400                                         case DEAD_RESPAWNING:
2401                                         {
2402                                                 if (time > this.respawn_time)
2403                                                 {
2404                                                         this.respawn_time = time + 1; // only retry once a second
2405                                                         this.respawn_time_max = this.respawn_time;
2406                                                         respawn(this);
2407                                                 }
2408                                                 break;
2409                                         }
2410                                 }
2411
2412                                 ShowRespawnCountdown(this);
2413
2414                                 if (this.respawn_flags & RESPAWN_SILENT)
2415                                         STAT(RESPAWN_TIME, this) = 0;
2416                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2417                                 {
2418                                         if (time < this.respawn_time)
2419                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2420                                         else if (this.deadflag != DEAD_RESPAWNING)
2421                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2422                                 }
2423                                 else
2424                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2425                         }
2426
2427                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2428                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2429                                 STAT(RESPAWN_TIME, this) *= -1;
2430
2431                         return;
2432                 }
2433
2434                 this.prevorigin = this.origin;
2435
2436                 bool have_hook = false;
2437                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2438                 {
2439                         .entity weaponentity = weaponentities[slot];
2440                         if(this.(weaponentity).hook.state)
2441                         {
2442                                 have_hook = true;
2443                                 break;
2444                         }
2445                 }
2446                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2447                 if (have_hook) {
2448                         do_crouch = false;
2449                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2450                         do_crouch = false;
2451                 } else if (this.vehicle) {
2452                         do_crouch = false;
2453                 } else if (STAT(FROZEN, this)) {
2454                         do_crouch = false;
2455         }
2456
2457                 if (do_crouch) {
2458                         if (!this.crouch) {
2459                                 this.crouch = true;
2460                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2461                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2462                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2463                         }
2464                 } else if (this.crouch) {
2465             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2466             if (!trace_startsolid) {
2467                 this.crouch = false;
2468                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2469                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2470             }
2471                 }
2472
2473                 FixPlayermodel(this);
2474
2475                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2476                 //if(frametime)
2477                 {
2478                         this.items &= ~this.items_added;
2479
2480                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2481                         {
2482                                 .entity weaponentity = weaponentities[slot];
2483                                 W_WeaponFrame(this, weaponentity);
2484
2485                                 if(slot == 0)
2486                                 {
2487                                         this.clip_load = this.(weaponentity).clip_load;
2488                                         this.clip_size = this.(weaponentity).clip_size;
2489                                 }
2490                         }
2491
2492                         this.items_added = 0;
2493                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2494                 this.items_added |= IT_FUEL;
2495
2496                         this.items |= this.items_added;
2497                 }
2498
2499                 player_regen(this);
2500
2501                 // WEAPONTODO: Add a weapon request for this
2502                 // rot vortex charge to the charge limit
2503                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2504                 {
2505                         .entity weaponentity = weaponentities[slot];
2506                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2507                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2508                 }
2509
2510                 if (frametime) player_anim(this);
2511
2512                 // secret status
2513                 secrets_setstatus(this);
2514
2515                 // monsters status
2516                 monsters_setstatus(this);
2517
2518                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2519         }
2520         else if (game_stopped || intermission_running) {
2521                 if(intermission_running)
2522                         IntermissionThink(this);
2523                 return;
2524         }
2525         else if (IS_OBSERVER(this)) {
2526                 ObserverThink(this);
2527         }
2528         else if (IS_SPEC(this)) {
2529                 SpectatorThink(this);
2530         }
2531
2532         // WEAPONTODO: Add weapon request for this
2533         if (!zoomstate_set) {
2534                 bool wep_zoomed = false;
2535                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2536                 {
2537                         .entity weaponentity = weaponentities[slot];
2538                         Weapon thiswep = this.(weaponentity).m_weapon;
2539                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2540                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2541                 }
2542                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2543     }
2544
2545         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2546         {
2547                 this.teamkill_soundtime = 0;
2548
2549                 entity e = this.teamkill_soundsource;
2550                 entity oldpusher = e.pusher;
2551                 e.pusher = this;
2552                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2553                 e.pusher = oldpusher;
2554         }
2555
2556         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2557                 this.taunt_soundtime = 0;
2558                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2559         }
2560
2561         target_voicescript_next(this);
2562
2563         // WEAPONTODO: Move into weaponsystem somehow
2564         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2565         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2566         {
2567                 .entity weaponentity = weaponentities[slot];
2568                 if(this.(weaponentity).m_weapon == WEP_Null)
2569                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2570         }
2571 }
2572
2573 void DrownPlayer(entity this)
2574 {
2575         if(IS_DEAD(this))
2576                 return;
2577
2578         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2579         {
2580                 if(this.air_finished < time)
2581                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2582                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2583                 this.dmg = 2;
2584         }
2585         else if (this.air_finished < time)
2586         {       // drown!
2587                 if (this.pain_finished < time)
2588                 {
2589                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2590                         this.pain_finished = time + 0.5;
2591                 }
2592         }
2593 }
2594
2595 .bool move_qcphysics;
2596
2597 void Player_Physics(entity this)
2598 {
2599         set_movetype(this, this.move_movetype);
2600
2601         if(!this.move_qcphysics)
2602                 return;
2603
2604         if(!frametime && !this.pm_frametime)
2605                 return;
2606
2607         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2608
2609         this.pm_frametime = 0;
2610 }
2611
2612 /*
2613 =============
2614 PlayerPostThink
2615
2616 Called every frame for each client after the physics are run
2617 =============
2618 */
2619 .float idlekick_lasttimeleft;
2620 void PlayerPostThink (entity this)
2621 {
2622         Player_Physics(this);
2623
2624         if (sv_maxidle > 0)
2625         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2626         if (IS_REAL_CLIENT(this))
2627         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2628         {
2629                 int totalClients = 0;
2630                 if(sv_maxidle_slots > 0)
2631                 {
2632                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2633                         {
2634                                 ++totalClients;
2635                         });
2636                 }
2637
2638                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2639                 { /* do nothing */ }
2640                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2641                 {
2642                         if (this.idlekick_lasttimeleft)
2643                         {
2644                                 this.idlekick_lasttimeleft = 0;
2645                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2646                         }
2647                 }
2648                 else
2649                 {
2650                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2651                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2652                                 if (!this.idlekick_lasttimeleft)
2653                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2654                         }
2655                         if (timeleft <= 0) {
2656                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2657                                 dropclient(this);
2658                                 return;
2659                         }
2660                         else if (timeleft <= 10) {
2661                                 if (timeleft != this.idlekick_lasttimeleft) {
2662                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2663                 }
2664                                 this.idlekick_lasttimeleft = timeleft;
2665                         }
2666                 }
2667         }
2668
2669         CheatFrame(this);
2670
2671         //CheckPlayerJump();
2672         if (game_stopped)
2673         {
2674                 this.solid = SOLID_NOT;
2675                 this.takedamage = DAMAGE_NO;
2676                 set_movetype(this, MOVETYPE_NONE);
2677         }
2678
2679         if (IS_PLAYER(this)) {
2680                 DrownPlayer(this);
2681                 CheckRules_Player(this);
2682                 UpdateChatBubble(this);
2683                 if (this.impulse) ImpulseCommands(this);
2684                 if (game_stopped)
2685                 {
2686                         CSQCMODEL_AUTOUPDATE(this);
2687                         return;
2688                 }
2689                 GetPressedKeys(this);
2690         }
2691
2692         if (this.waypointsprite_attachedforcarrier) {
2693             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2694                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2695     }
2696
2697         playerdemo_write(this);
2698
2699         CSQCMODEL_AUTOUPDATE(this);
2700 }