qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!gameover)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 if(!this.weaponentities[slot])
 347                         continue; // first load
 348                 this.weaponentities[slot].hook_time = 0;
 349                 this.weaponentities[slot].weaponname = "";
 350                 this.weaponentities[slot] = NULL;
 351         }
 352         this.exteriorweaponentity = NULL;
 353         this.killcount = FRAGS_SPECTATOR;
 354         this.velocity = '0 0 0';
 355         this.avelocity = '0 0 0';
 356         this.punchangle = '0 0 0';
 357         this.punchvector = '0 0 0';
 358         this.oldvelocity = this.velocity;
 359         this.fire_endtime = -1;
 360         this.event_damage = func_null;
 361 }
 362
 363 int player_getspecies(entity this)
 364 {
 365         get_model_parameters(this.model, this.skin);
 366         int s = get_model_parameters_species;
 367         get_model_parameters(string_null, 0);
 368         if (s < 0) return SPECIES_HUMAN;
 369         return s;
 370 }
 371
 372 .float model_randomizer;
 373 void FixPlayermodel(entity player)
 374 {
 375         string defaultmodel = "";
 376         int defaultskin = 0;
 377         if(autocvar_sv_defaultcharacter)
 378         {
 379                 if(teamplay)
 380                 {
 381                         string s = Static_Team_ColorName_Lower(player.team);
 382                         if (s != "neutral")
 383                         {
 384                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 385                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 386                         }
 387                 }
 388
 389                 if(defaultmodel == "")
 390                 {
 391                         defaultmodel = autocvar_sv_defaultplayermodel;
 392                         defaultskin = autocvar_sv_defaultplayerskin;
 393                 }
 394
 395                 int n = tokenize_console(defaultmodel);
 396                 if(n > 0)
 397                 {
 398                         defaultmodel = argv(floor(n * player.model_randomizer));
 399                         // However, do NOT randomize if the player-selected model is in the list.
 400                         for (int i = 0; i < n; ++i)
 401                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 402                                         defaultmodel = argv(i);
 403                 }
 404
 405                 int i = strstrofs(defaultmodel, ":", 0);
 406                 if(i >= 0)
 407                 {
 408                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 409                         defaultmodel = substring(defaultmodel, 0, i);
 410                 }
 411         }
 412         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 413         {
 414                 if(teamplay)
 415                 {
 416                         string s = Static_Team_ColorName_Lower(player.team);
 417                         if (s != "neutral")
 418                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 419                 }
 420
 421                 if(!defaultskin)
 422                         defaultskin = autocvar_sv_defaultplayerskin;
 423         }
 424
 425         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 426         defaultmodel = M_ARGV(0, string);
 427         defaultskin = M_ARGV(1, int);
 428
 429         bool chmdl = false;
 430         int oldskin;
 431         if(defaultmodel != "")
 432         {
 433                 if (defaultmodel != player.model)
 434                 {
 435                         vector m1 = player.mins;
 436                         vector m2 = player.maxs;
 437                         setplayermodel (player, defaultmodel);
 438                         setsize (player, m1, m2);
 439                         chmdl = true;
 440                 }
 441
 442                 oldskin = player.skin;
 443                 player.skin = defaultskin;
 444         } else {
 445                 if (player.playermodel != player.model || player.playermodel == "")
 446                 {
 447                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 448                         vector m1 = player.mins;
 449                         vector m2 = player.maxs;
 450                         setplayermodel (player, player.playermodel);
 451                         setsize (player, m1, m2);
 452                         chmdl = true;
 453                 }
 454
 455                 if(!autocvar_sv_defaultcharacterskin)
 456                 {
 457                         oldskin = player.skin;
 458                         player.skin = stof(player.playerskin);
 459                 }
 460                 else
 461                 {
 462                         oldskin = player.skin;
 463                         player.skin = defaultskin;
 464                 }
 465         }
 466
 467         if(chmdl || oldskin != player.skin) // model or skin has changed
 468         {
 469                 player.species = player_getspecies(player); // update species
 470                 if(!autocvar_g_debug_globalsounds)
 471                         UpdatePlayerSounds(player); // update skin sounds
 472         }
 473
 474         if(!teamplay)
 475                 if(strlen(autocvar_sv_defaultplayercolors))
 476                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 477                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 478 }
 479
 480
 481 /** Called when a client spawns in the server */
 482 void PutClientInServer(entity this)
 483 {
 484         if (IS_BOT_CLIENT(this)) {
 485                 TRANSMUTE(Player, this);
 486         } else if (IS_REAL_CLIENT(this)) {
 487                 msg_entity = this;
 488                 WriteByte(MSG_ONE, SVC_SETVIEW);
 489                 WriteEntity(MSG_ONE, this);
 490         }
 491         if (gameover) {
 492                 TRANSMUTE(Observer, this);
 493         }
 494
 495         SetSpectatee(this, NULL);
 496
 497         // reset player keys
 498         this.itemkeys = 0;
 499
 500         MUTATOR_CALLHOOK(PutClientInServer, this);
 501
 502         if (IS_OBSERVER(this)) {
 503                 PutObserverInServer(this);
 504         } else if (IS_PLAYER(this)) {
 505                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 506
 507                 PlayerState_attach(this);
 508                 accuracy_resend(this);
 509
 510                 if (this.team < 0)
 511                         JoinBestTeam(this, false, true);
 512
 513                 entity spot = SelectSpawnPoint(this, false);
 514                 if (!spot) {
 515                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 516                         return; // spawn failed
 517                 }
 518
 519                 TRANSMUTE(Player, this);
 520
 521                 this.wasplayer = true;
 522                 this.iscreature = true;
 523                 this.teleportable = TELEPORT_NORMAL;
 524                 if(!this.damagedbycontents)
 525                         IL_PUSH(g_damagedbycontents, this);
 526                 this.damagedbycontents = true;
 527                 set_movetype(this, MOVETYPE_WALK);
 528                 this.solid = SOLID_SLIDEBOX;
 529                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 530                 if (autocvar_g_playerclip_collisions)
 531                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 532                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 533                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 534                 this.frags = FRAGS_PLAYER;
 535                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 536                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 537                 if (autocvar__notarget)
 538                         this.flags |= FL_NOTARGET;
 539                 this.takedamage = DAMAGE_AIM;
 540                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 541                 this.dmg = 2; // WTF
 542
 543                 if (warmup_stage) {
 544                         this.ammo_shells = warmup_start_ammo_shells;
 545                         this.ammo_nails = warmup_start_ammo_nails;
 546                         this.ammo_rockets = warmup_start_ammo_rockets;
 547                         this.ammo_cells = warmup_start_ammo_cells;
 548                         this.ammo_plasma = warmup_start_ammo_plasma;
 549                         this.ammo_fuel = warmup_start_ammo_fuel;
 550                         this.health = warmup_start_health;
 551                         this.armorvalue = warmup_start_armorvalue;
 552                         this.weapons = WARMUP_START_WEAPONS;
 553                 } else {
 554                         this.ammo_shells = start_ammo_shells;
 555                         this.ammo_nails = start_ammo_nails;
 556                         this.ammo_rockets = start_ammo_rockets;
 557                         this.ammo_cells = start_ammo_cells;
 558                         this.ammo_plasma = start_ammo_plasma;
 559                         this.ammo_fuel = start_ammo_fuel;
 560                         this.health = start_health;
 561                         this.armorvalue = start_armorvalue;
 562                         this.weapons = start_weapons;
 563                 }
 564                 SetSpectatee_status(this, 0);
 565
 566                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 567
 568                 this.items = start_items;
 569
 570                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 571                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 572                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 573                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 574                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 575                 // extend the pause of rotting if client was reset at the beginning of the countdown
 576                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 577                         float f = game_starttime - time;
 578                         this.spawnshieldtime += f;
 579                         this.pauserotarmor_finished += f;
 580                         this.pauserothealth_finished += f;
 581                         this.pauseregen_finished += f;
 582                 }
 583                 this.damageforcescale = 2;
 584                 this.death_time = 0;
 585                 this.respawn_flags = 0;
 586                 this.respawn_time = 0;
 587                 this.stat_respawn_time = 0;
 588                 this.scale = autocvar_sv_player_scale;
 589                 this.fade_time = 0;
 590                 this.pain_frame = 0;
 591                 this.pain_finished = 0;
 592                 this.pushltime = 0;
 593                 setthink(this, func_null); // players have no think function
 594                 this.nextthink = 0;
 595                 this.dmg_team = 0;
 596                 this.ballistics_density = autocvar_g_ballistics_density_player;
 597
 598                 this.deadflag = DEAD_NO;
 599
 600                 this.angles = spot.angles;
 601                 this.angles_z = 0; // never spawn tilted even if the spot says to
 602                 if (IS_BOT_CLIENT(this))
 603                         this.v_angle = this.angles;
 604                 this.fixangle = true; // turn this way immediately
 605                 this.oldvelocity = this.velocity = '0 0 0';
 606                 this.avelocity = '0 0 0';
 607                 this.punchangle = '0 0 0';
 608                 this.punchvector = '0 0 0';
 609
 610                 this.strength_finished = 0;
 611                 this.invincible_finished = 0;
 612                 this.fire_endtime = -1;
 613                 this.revive_progress = 0;
 614                 this.revival_time = 0;
 615                 this.air_finished = time + 12;
 616
 617                 entity spawnevent = new_pure(spawnevent);
 618                 spawnevent.owner = this;
 619                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 620
 621                 // Cut off any still running player sounds.
 622                 stopsound(this, CH_PLAYER_SINGLE);
 623
 624                 this.model = "";
 625                 FixPlayermodel(this);
 626                 this.drawonlytoclient = NULL;
 627
 628                 this.viewloc = NULL;
 629
 630                 this.crouch = false;
 631                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 632                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 633                 this.spawnorigin = spot.origin;
 634                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 635                 // don't reset back to last position, even if new position is stuck in solid
 636                 this.oldorigin = this.origin;
 637                 this.prevorigin = this.origin;
 638                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 639                 if(this.conveyor)
 640                         IL_REMOVE(g_conveyed, this);
 641                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 642                 this.hud = HUD_NORMAL;
 643
 644                 this.event_damage = PlayerDamage;
 645
 646                 if(!this.bot_attack)
 647                         IL_PUSH(g_bot_targets, this);
 648                 this.bot_attack = true;
 649                 this.monster_attack = true;
 650
 651                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 652
 653                 if (this.killcount == FRAGS_SPECTATOR) {
 654                         PlayerScore_Clear(this);
 655                         this.killcount = 0;
 656                 }
 657
 658                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 659                 {
 660                         .entity weaponentity = weaponentities[slot];
 661                         CL_SpawnWeaponentity(this, weaponentity);
 662                 }
 663                 this.alpha = default_player_alpha;
 664                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 665                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 666
 667                 this.speedrunning = false;
 668
 669                 target_voicescript_clear(this);
 670
 671                 // reset fields the weapons may use
 672                 FOREACH(Weapons, true, LAMBDA(
 673                         it.wr_resetplayer(it, this);
 674                         // reload all reloadable weapons
 675                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 676                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 677                                 {
 678                                         .entity weaponentity = weaponentities[slot];
 679                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 680                                 }
 681                         }
 682                 ));
 683
 684                 {
 685                         string s = spot.target;
 686                         spot.target = string_null;
 687                         SUB_UseTargets(spot, this, NULL);
 688                         spot.target = s;
 689                 }
 690
 691                 Unfreeze(this);
 692
 693                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 694
 695                 if (autocvar_spawn_debug)
 696                 {
 697                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 698                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 699                 }
 700
 701                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 702                 {
 703                         .entity weaponentity = weaponentities[slot];
 704                         if(slot == 0)
 705                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 706                         else
 707                                 this.(weaponentity).m_switchweapon = WEP_Null;
 708                         this.(weaponentity).m_weapon = WEP_Null;
 709                         this.(weaponentity).weaponname = "";
 710                         this.(weaponentity).m_switchingweapon = WEP_Null;
 711                         this.(weaponentity).cnt = -1;
 712                 }
 713
 714                 if (!warmup_stage && !this.alivetime)
 715                         this.alivetime = time;
 716
 717                 antilag_clear(this, CS(this));
 718         }
 719 }
 720
 721 void ClientInit_misc(entity this);
 722
 723 // TODO do we need all these fields, or should we stop autodetecting runtime
 724 // changes and just have a console command to update this?
 725 bool ClientInit_SendEntity(entity this, entity to, int sf)
 726 {
 727         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 728         return = true;
 729         msg_entity = to;
 730         // MSG_INIT replacement
 731         // TODO: make easier to use
 732         Registry_send_all();
 733         W_PROP_reload(MSG_ONE, to);
 734         ClientInit_misc(this);
 735         MUTATOR_CALLHOOK(Ent_Init);
 736 }
 737 void ClientInit_misc(entity this)
 738 {
 739         int channel = MSG_ONE;
 740         WriteHeader(channel, ENT_CLIENT_INIT);
 741         WriteByte(channel, g_nexball_meter_period * 32);
 742         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 743         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 744         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 745         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 746         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 747         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 748         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 749         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 750
 751         if(sv_foginterval && world.fog != "")
 752                 WriteString(channel, world.fog);
 753         else
 754                 WriteString(channel, "");
 755         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 756         WriteByte(channel, serverflags);
 757         WriteCoord(channel, autocvar_g_trueaim_minrange);
 758 }
 759
 760 void ClientInit_CheckUpdate(entity this)
 761 {
 762         this.nextthink = time;
 763         if(this.count != autocvar_g_balance_armor_blockpercent)
 764         {
 765                 this.count = autocvar_g_balance_armor_blockpercent;
 766                 this.SendFlags |= 1;
 767         }
 768 }
 769
 770 void ClientInit_Spawn()
 771 {
 772         entity e = new_pure(clientinit);
 773         setthink(e, ClientInit_CheckUpdate);
 774         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 775
 776         ClientInit_CheckUpdate(e);
 777 }
 778
 779 /*
 780 =============
 781 SetNewParms
 782 =============
 783 */
 784 void SetNewParms ()
 785 {
 786         // initialize parms for a new player
 787         parm1 = -(86400 * 366);
 788
 789         MUTATOR_CALLHOOK(SetNewParms);
 790 }
 791
 792 /*
 793 =============
 794 SetChangeParms
 795 =============
 796 */
 797 void SetChangeParms (entity this)
 798 {
 799         // save parms for level change
 800         parm1 = this.parm_idlesince - time;
 801
 802         MUTATOR_CALLHOOK(SetChangeParms);
 803 }
 804
 805 /*
 806 =============
 807 DecodeLevelParms
 808 =============
 809 */
 810 void DecodeLevelParms(entity this)
 811 {
 812         // load parms
 813         this.parm_idlesince = parm1;
 814         if (this.parm_idlesince == -(86400 * 366))
 815                 this.parm_idlesince = time;
 816
 817         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 818         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 819
 820         MUTATOR_CALLHOOK(DecodeLevelParms);
 821 }
 822
 823 /*
 824 =============
 825 ClientKill
 826
 827 Called when a client types 'kill' in the console
 828 =============
 829 */
 830
 831 .float clientkill_nexttime;
 832 void ClientKill_Now_TeamChange(entity this)
 833 {
 834         if(this.killindicator_teamchange == -1)
 835         {
 836                 JoinBestTeam( this, false, true );
 837         }
 838         else if(this.killindicator_teamchange == -2)
 839         {
 840                 if(blockSpectators)
 841                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 842                 PutObserverInServer(this);
 843         }
 844         else
 845                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 846         this.killindicator_teamchange = 0;
 847 }
 848
 849 void ClientKill_Now(entity this)
 850 {
 851         if(this.vehicle)
 852         {
 853             vehicles_exit(this.vehicle, VHEF_RELEASE);
 854             if(!this.killindicator_teamchange)
 855             {
 856             this.vehicle_health = -1;
 857             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 858             }
 859         }
 860
 861         if(this.killindicator && !wasfreed(this.killindicator))
 862                 delete(this.killindicator);
 863
 864         this.killindicator = NULL;
 865
 866         if(this.killindicator_teamchange)
 867                 ClientKill_Now_TeamChange(this);
 868
 869         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 870                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 871
 872         // now I am sure the player IS dead
 873 }
 874 void KillIndicator_Think(entity this)
 875 {
 876         if (gameover)
 877         {
 878                 this.owner.killindicator = NULL;
 879                 delete(this);
 880                 return;
 881         }
 882
 883         if (this.owner.alpha < 0 && !this.owner.vehicle)
 884         {
 885                 this.owner.killindicator = NULL;
 886                 delete(this);
 887                 return;
 888         }
 889
 890         if(this.cnt <= 0)
 891         {
 892                 ClientKill_Now(this.owner);
 893                 return;
 894         }
 895     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 896     {
 897         this.nextthink = time + 1;
 898         this.cnt -= 1;
 899     }
 900         else
 901         {
 902                 if(this.cnt <= 10)
 903                         setmodel(this, MDL_NUM(this.cnt));
 904                 if(IS_REAL_CLIENT(this.owner))
 905                 {
 906                         if(this.cnt <= 10)
 907                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 908                 }
 909                 this.nextthink = time + 1;
 910                 this.cnt -= 1;
 911         }
 912 }
 913
 914 float clientkilltime;
 915 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 916 {
 917         float killtime;
 918         float starttime;
 919
 920         if (gameover)
 921                 return;
 922
 923         killtime = autocvar_g_balance_kill_delay;
 924
 925         if(g_race_qualifying || g_cts)
 926                 killtime = 0;
 927
 928     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 929         return;
 930
 931         this.killindicator_teamchange = targetteam;
 932
 933     if(!this.killindicator)
 934         {
 935                 if(!IS_DEAD(this))
 936                 {
 937                         killtime = max(killtime, this.clientkill_nexttime - time);
 938                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 939                 }
 940
 941                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 942                 {
 943                         ClientKill_Now(this);
 944                 }
 945                 else
 946                 {
 947                         starttime = max(time, clientkilltime);
 948
 949                         this.killindicator = spawn();
 950                         this.killindicator.owner = this;
 951                         this.killindicator.scale = 0.5;
 952                         setattachment(this.killindicator, this, "");
 953                         setorigin(this.killindicator, '0 0 52');
 954                         setthink(this.killindicator, KillIndicator_Think);
 955                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 956                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 957                         this.killindicator.cnt = ceil(killtime);
 958                         this.killindicator.count = bound(0, ceil(killtime), 10);
 959                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 960
 961                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 962                         {
 963                                 it.killindicator = spawn();
 964                                 it.killindicator.owner = it;
 965                                 it.killindicator.scale = 0.5;
 966                                 setattachment(it.killindicator, it, "");
 967                                 setorigin(it.killindicator, '0 0 52');
 968                                 setthink(it.killindicator, KillIndicator_Think);
 969                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 970                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 971                                 it.killindicator.cnt = ceil(killtime);
 972                         });
 973                         this.lip = 0;
 974                 }
 975         }
 976         if(this.killindicator)
 977         {
 978                 if(targetteam == 0) // just die
 979                 {
 980                         this.killindicator.colormod = '0 0 0';
 981                         if(IS_REAL_CLIENT(this))
 982                         if(this.killindicator.cnt > 0)
 983                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 984                 }
 985                 else if(targetteam == -1) // auto
 986                 {
 987                         this.killindicator.colormod = '0 1 0';
 988                         if(IS_REAL_CLIENT(this))
 989                         if(this.killindicator.cnt > 0)
 990                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 991                 }
 992                 else if(targetteam == -2) // spectate
 993                 {
 994                         this.killindicator.colormod = '0.5 0.5 0.5';
 995                         if(IS_REAL_CLIENT(this))
 996                         if(this.killindicator.cnt > 0)
 997                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 998                 }
 999                 else
1000                 {
1001                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1002                         if(IS_REAL_CLIENT(this))
1003                         if(this.killindicator.cnt > 0)
1004                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1005                 }
1006         }
1007
1008 }
1009
1010 void ClientKill (entity this)
1011 {
1012         if(gameover) return;
1013         if(this.player_blocked) return;
1014         if(STAT(FROZEN, this)) return;
1015
1016         ClientKill_TeamChange(this, 0);
1017 }
1018
1019 void FixClientCvars(entity e)
1020 {
1021         // send prediction settings to the client
1022         stuffcmd(e, "\nin_bindmap 0 0\n");
1023         if(autocvar_g_antilag == 3) // client side hitscan
1024                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1025         if(autocvar_sv_gentle)
1026                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1027
1028         MUTATOR_CALLHOOK(FixClientCvars, e);
1029 }
1030
1031 float PlayerInIDList(entity p, string idlist)
1032 {
1033         float n, i;
1034         string s;
1035
1036         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1037         if (!p.crypto_idfp)
1038                 return 0;
1039
1040         // this function allows abbreviated player IDs too!
1041         n = tokenize_console(idlist);
1042         for(i = 0; i < n; ++i)
1043         {
1044                 s = argv(i);
1045                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1046                         return 1;
1047         }
1048
1049         return 0;
1050 }
1051
1052 #ifdef DP_EXT_PRECONNECT
1053 /*
1054 =============
1055 ClientPreConnect
1056
1057 Called once (not at each match start) when a client begins a connection to the server
1058 =============
1059 */
1060 void ClientPreConnect(entity this)
1061 {
1062         if(autocvar_sv_eventlog)
1063         {
1064                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1065                         this.playerid,
1066                         etof(this),
1067                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1068                 ));
1069         }
1070 }
1071 #endif
1072
1073 /**
1074 =============
1075 ClientConnect
1076
1077 Called when a client connects to the server
1078 =============
1079 */
1080 void ClientConnect(entity this)
1081 {
1082         if (Ban_MaybeEnforceBanOnce(this)) return;
1083         assert(!IS_CLIENT(this), return);
1084         this.flags |= FL_CLIENT;
1085         assert(player_count >= 0, player_count = 0);
1086
1087 #ifdef WATERMARK
1088         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1089 #endif
1090         this.version_nagtime = time + 10 + random() * 10;
1091         TRANSMUTE(Client, this);
1092
1093         // identify the right forced team
1094         if (autocvar_g_campaign)
1095         {
1096                 if (IS_REAL_CLIENT(this)) // only players, not bots
1097                 {
1098                         switch (autocvar_g_campaign_forceteam)
1099                         {
1100                                 case 1: this.team_forced = NUM_TEAM_1; break;
1101                                 case 2: this.team_forced = NUM_TEAM_2; break;
1102                                 case 3: this.team_forced = NUM_TEAM_3; break;
1103                                 case 4: this.team_forced = NUM_TEAM_4; break;
1104                                 default: this.team_forced = 0;
1105                         }
1106                 }
1107         }
1108         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1109         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1110         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1111         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1112         else switch (autocvar_g_forced_team_otherwise)
1113         {
1114                 default: this.team_forced = 0; break;
1115                 case "red": this.team_forced = NUM_TEAM_1; break;
1116                 case "blue": this.team_forced = NUM_TEAM_2; break;
1117                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1118                 case "pink": this.team_forced = NUM_TEAM_4; break;
1119                 case "spectate":
1120                 case "spectator":
1121                         this.team_forced = -1;
1122                         break;
1123         }
1124         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1125
1126     {
1127         int id = this.playerid;
1128         this.playerid = 0; // silent
1129             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1130             this.playerid = id;
1131     }
1132
1133         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1134                 TRANSMUTE(Observer, this);
1135         } else {
1136                 if (!teamplay || autocvar_g_balance_teams) {
1137                         TRANSMUTE(Player, this);
1138                         campaign_bots_may_start = true;
1139                 } else {
1140                         TRANSMUTE(Observer, this); // do it anyway
1141                 }
1142         }
1143
1144         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1145
1146         // always track bots, don't ask for cl_allow_uidtracking
1147     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1148
1149         if (autocvar_sv_eventlog)
1150                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1151
1152         LogTeamchange(this.playerid, this.team, 1);
1153
1154         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1155
1156         this.netname_previous = strzone(this.netname);
1157
1158         if(teamplay && IS_PLAYER(this))
1159                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1160         else
1161                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1162
1163         stuffcmd(this, clientstuff, "\n");
1164         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1165
1166         FixClientCvars(this);
1167
1168         // get version info from player
1169         stuffcmd(this, "cmd clientversion $gameversion\n");
1170
1171         // notify about available teams
1172         if (teamplay)
1173         {
1174                 CheckAllowedTeams(this);
1175                 int t = 0;
1176                 if (c1 >= 0) t |= BIT(0);
1177                 if (c2 >= 0) t |= BIT(1);
1178                 if (c3 >= 0) t |= BIT(2);
1179                 if (c4 >= 0) t |= BIT(3);
1180                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1181         }
1182         else
1183         {
1184                 stuffcmd(this, "set _teams_available 0\n");
1185         }
1186
1187         bot_relinkplayerlist();
1188
1189         this.spectatortime = time;
1190         if (blockSpectators)
1191         {
1192                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1193         }
1194
1195         this.jointime = time;
1196         this.allowed_timeouts = autocvar_sv_timeout_number;
1197
1198         if (IS_REAL_CLIENT(this))
1199         {
1200                 if (g_weaponarena_weapons == WEPSET(TUBA))
1201                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1202         }
1203
1204         if (!sv_foginterval && world.fog != "")
1205                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1206
1207         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1208                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1209                         send_CSQC_teamnagger();
1210
1211         CSQCMODEL_AUTOINIT(this);
1212
1213         this.model_randomizer = random();
1214
1215         if (IS_REAL_CLIENT(this))
1216                 sv_notice_join(this);
1217
1218         // update physics stats (players can spawn before physics runs)
1219         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1220
1221         IL_EACH(g_initforplayer, it.init_for_player, {
1222                 it.init_for_player(it, this);
1223         });
1224
1225         MUTATOR_CALLHOOK(ClientConnect, this);
1226
1227         if (IS_REAL_CLIENT(this))
1228         {
1229                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1230                 {
1231                         this.motd_actived_time = -1;
1232                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1233                 }
1234         }
1235 }
1236 /*
1237 =============
1238 ClientDisconnect
1239
1240 Called when a client disconnects from the server
1241 =============
1242 */
1243 .entity chatbubbleentity;
1244 void ReadyCount();
1245 void ClientDisconnect(entity this)
1246 {
1247         assert(IS_CLIENT(this), return);
1248
1249         PlayerStats_GameReport_FinalizePlayer(this);
1250         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1251         if (this.active_minigame) part_minigame(this);
1252         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1253
1254         if (autocvar_sv_eventlog)
1255                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1256
1257         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1258
1259         SetSpectatee(this, NULL);
1260
1261     MUTATOR_CALLHOOK(ClientDisconnect, this);
1262
1263         ClientState_detach(this);
1264
1265         Portal_ClearAll(this);
1266
1267         Unfreeze(this);
1268
1269         RemoveGrapplingHooks(this);
1270
1271         // Here, everything has been done that requires this player to be a client.
1272
1273         this.flags &= ~FL_CLIENT;
1274
1275         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1276         if (this.killindicator) delete(this.killindicator);
1277
1278         WaypointSprite_PlayerGone(this);
1279
1280         bot_relinkplayerlist();
1281
1282         if (this.netname_previous) strunzone(this.netname_previous);
1283         if (this.clientstatus) strunzone(this.clientstatus);
1284         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1285         if (this.personal) delete(this.personal);
1286
1287         this.playerid = 0;
1288         ReadyCount();
1289         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1290
1291         ONREMOVE(this);
1292 }
1293
1294 void ChatBubbleThink(entity this)
1295 {
1296         this.nextthink = time;
1297         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1298         {
1299                 if(this.owner) // but why can that ever be NULL?
1300                         this.owner.chatbubbleentity = NULL;
1301                 delete(this);
1302                 return;
1303         }
1304
1305         this.mdl = "";
1306
1307         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1308         {
1309                 if ( this.owner.active_minigame )
1310                         this.mdl = "models/sprites/minigame_busy.iqm";
1311                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1312                         this.mdl = "models/misc/chatbubble.spr";
1313         }
1314
1315         if ( this.model != this.mdl )
1316                 _setmodel(this, this.mdl);
1317
1318 }
1319
1320 void UpdateChatBubble(entity this)
1321 {
1322         if (this.alpha < 0)
1323                 return;
1324         // spawn a chatbubble entity if needed
1325         if (!this.chatbubbleentity)
1326         {
1327                 this.chatbubbleentity = new(chatbubbleentity);
1328                 this.chatbubbleentity.owner = this;
1329                 this.chatbubbleentity.exteriormodeltoclient = this;
1330                 setthink(this.chatbubbleentity, ChatBubbleThink);
1331                 this.chatbubbleentity.nextthink = time;
1332                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1333                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1334                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1335                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1336                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1337                 //this.chatbubbleentity.model = "";
1338                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1339         }
1340 }
1341
1342
1343 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1344 // added to the model skins
1345 /*void UpdateColorModHack()
1346 {
1347         float c;
1348         c = this.clientcolors & 15;
1349         // LordHavoc: only bothering to support white, green, red, yellow, blue
1350              if (!teamplay) this.colormod = '0 0 0';
1351         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1352         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1353         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1354         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1355         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1356         else this.colormod = '1 1 1';
1357 }*/
1358
1359 void respawn(entity this)
1360 {
1361         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1362         {
1363                 this.solid = SOLID_NOT;
1364                 this.takedamage = DAMAGE_NO;
1365                 set_movetype(this, MOVETYPE_FLY);
1366                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1367                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1368                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1369                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1370                 if(autocvar_g_respawn_ghosts_maxtime)
1371                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1372         }
1373
1374         CopyBody(this, 1);
1375
1376         this.effects |= EF_NODRAW; // prevent another CopyBody
1377         PutClientInServer(this);
1378 }
1379
1380 void play_countdown(entity this, float finished, Sound samp)
1381 {
1382     TC(Sound, samp);
1383         if(IS_REAL_CLIENT(this))
1384                 if(floor(finished - time - frametime) != floor(finished - time))
1385                         if(finished - time < 6)
1386                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1387 }
1388
1389 void player_powerups(entity this)
1390 {
1391         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1392         int items_prev = this.items;
1393
1394         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1395                 this.modelflags |= MF_ROCKET;
1396         else
1397                 this.modelflags &= ~MF_ROCKET;
1398
1399         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1400
1401         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1402                 return;
1403
1404         Fire_ApplyDamage(this);
1405         Fire_ApplyEffect(this);
1406
1407         if (!g_instagib)
1408         {
1409                 if (this.items & ITEM_Strength.m_itemid)
1410                 {
1411                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1412                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1413                         if (time > this.strength_finished)
1414                         {
1415                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1416                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1417                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1418                         }
1419                 }
1420                 else
1421                 {
1422                         if (time < this.strength_finished)
1423                         {
1424                                 this.items = this.items | ITEM_Strength.m_itemid;
1425                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1426                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1427                         }
1428                 }
1429                 if (this.items & ITEM_Shield.m_itemid)
1430                 {
1431                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1432                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1433                         if (time > this.invincible_finished)
1434                         {
1435                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1436                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1437                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1438                         }
1439                 }
1440                 else
1441                 {
1442                         if (time < this.invincible_finished)
1443                         {
1444                                 this.items = this.items | ITEM_Shield.m_itemid;
1445                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1446                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1447                         }
1448                 }
1449                 if (this.items & IT_SUPERWEAPON)
1450                 {
1451                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1452                         {
1453                                 this.superweapons_finished = 0;
1454                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1455                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1456                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1457                         }
1458                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1459                         {
1460                                 // don't let them run out
1461                         }
1462                         else
1463                         {
1464                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1465                                 if (time > this.superweapons_finished)
1466                                 {
1467                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1468                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1469                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1470                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1471                                 }
1472                         }
1473                 }
1474                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1475                 {
1476                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1477                         {
1478                                 this.items = this.items | IT_SUPERWEAPON;
1479                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1480                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1481                         }
1482                         else
1483                         {
1484                                 this.superweapons_finished = 0;
1485                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1486                         }
1487                 }
1488                 else
1489                 {
1490                         this.superweapons_finished = 0;
1491                 }
1492         }
1493
1494         if(autocvar_g_nodepthtestplayers)
1495                 this.effects = this.effects | EF_NODEPTHTEST;
1496
1497         if(autocvar_g_fullbrightplayers)
1498                 this.effects = this.effects | EF_FULLBRIGHT;
1499
1500         if (time >= game_starttime)
1501         if (time < this.spawnshieldtime)
1502                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1503
1504         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1505 }
1506
1507 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1508 {
1509         if(current > stable)
1510                 return current;
1511         else if(current > stable - 0.25) // when close enough, "snap"
1512                 return stable;
1513         else
1514                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1515 }
1516
1517 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1518 {
1519         if(current < stable)
1520                 return current;
1521         else if(current < stable + 0.25) // when close enough, "snap"
1522                 return stable;
1523         else
1524                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1525 }
1526
1527 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1528 {
1529         if(current > rotstable)
1530         {
1531                 if(rotframetime > 0)
1532                 {
1533                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1534                         current = max(rotstable, current - rotlinear * rotframetime);
1535                 }
1536         }
1537         else if(current < regenstable)
1538         {
1539                 if(regenframetime > 0)
1540                 {
1541                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1542                         current = min(regenstable, current + regenlinear * regenframetime);
1543                 }
1544         }
1545
1546         if(current > limit)
1547                 current = limit;
1548
1549         return current;
1550 }
1551
1552 void player_regen(entity this)
1553 {
1554         float max_mod, regen_mod, rot_mod, limit_mod;
1555         max_mod = regen_mod = rot_mod = limit_mod = 1;
1556
1557         float regen_health = autocvar_g_balance_health_regen;
1558         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1559         float regen_health_rot = autocvar_g_balance_health_rot;
1560         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1561         float regen_health_stable = autocvar_g_balance_health_regenstable;
1562         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1563         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1564                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1565         max_mod = M_ARGV(1, float);
1566         regen_mod = M_ARGV(2, float);
1567         rot_mod = M_ARGV(3, float);
1568         limit_mod = M_ARGV(4, float);
1569         regen_health = M_ARGV(5, float);
1570         regen_health_linear = M_ARGV(6, float);
1571         regen_health_rot = M_ARGV(7, float);
1572         regen_health_rotlinear = M_ARGV(8, float);
1573         regen_health_stable = M_ARGV(9, float);
1574         regen_health_rotstable = M_ARGV(10, float);
1575
1576
1577         if(!mutator_returnvalue)
1578         if(!STAT(FROZEN, this))
1579         {
1580                 float mina, maxa, limith, limita;
1581                 maxa = autocvar_g_balance_armor_rotstable;
1582                 mina = autocvar_g_balance_armor_regenstable;
1583                 limith = autocvar_g_balance_health_limit;
1584                 limita = autocvar_g_balance_armor_limit;
1585
1586                 regen_health_rotstable = regen_health_rotstable * max_mod;
1587                 regen_health_stable = regen_health_stable * max_mod;
1588                 limith = limith * limit_mod;
1589                 limita = limita * limit_mod;
1590
1591                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1592                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1593         }
1594
1595         // if player rotted to death...  die!
1596         // check this outside above checks, as player may still be able to rot to death
1597         if(this.health < 1)
1598         {
1599                 if(this.vehicle)
1600                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1601                 if(this.event_damage)
1602                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1603         }
1604
1605         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1606         {
1607                 float minf, maxf, limitf;
1608
1609                 maxf = autocvar_g_balance_fuel_rotstable;
1610                 minf = autocvar_g_balance_fuel_regenstable;
1611                 limitf = autocvar_g_balance_fuel_limit;
1612
1613                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1614         }
1615 }
1616
1617 bool zoomstate_set;
1618 void SetZoomState(entity this, float newzoom)
1619 {
1620         if(newzoom != this.zoomstate)
1621         {
1622                 this.zoomstate = newzoom;
1623                 ClientData_Touch(this);
1624         }
1625         zoomstate_set = true;
1626 }
1627
1628 void GetPressedKeys(entity this)
1629 {
1630         MUTATOR_CALLHOOK(GetPressedKeys, this);
1631         int keys = STAT(PRESSED_KEYS, this);
1632         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1633         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1634         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1635         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1636
1637         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1638         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1639         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1640         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1641         this.pressedkeys = keys; // store for other users
1642
1643         STAT(PRESSED_KEYS, this) = keys;
1644 }
1645
1646 /*
1647 ======================
1648 spectate mode routines
1649 ======================
1650 */
1651
1652 void SpectateCopy(entity this, entity spectatee)
1653 {
1654     TC(Client, this); TC(Client, spectatee);
1655
1656         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1657         PS(this) = PS(spectatee);
1658         this.armortype = spectatee.armortype;
1659         this.armorvalue = spectatee.armorvalue;
1660         this.ammo_cells = spectatee.ammo_cells;
1661         this.ammo_plasma = spectatee.ammo_plasma;
1662         this.ammo_shells = spectatee.ammo_shells;
1663         this.ammo_nails = spectatee.ammo_nails;
1664         this.ammo_rockets = spectatee.ammo_rockets;
1665         this.ammo_fuel = spectatee.ammo_fuel;
1666         this.clip_load = spectatee.clip_load;
1667         this.clip_size = spectatee.clip_size;
1668         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1669         this.health = spectatee.health;
1670         this.impulse = 0;
1671         this.items = spectatee.items;
1672         this.last_pickup = spectatee.last_pickup;
1673         this.hit_time = spectatee.hit_time;
1674         this.strength_finished = spectatee.strength_finished;
1675         this.invincible_finished = spectatee.invincible_finished;
1676         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1677         this.weapons = spectatee.weapons;
1678         this.vortex_charge = spectatee.vortex_charge;
1679         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1680         this.hagar_load = spectatee.hagar_load;
1681         this.arc_heat_percent = spectatee.arc_heat_percent;
1682         this.minelayer_mines = spectatee.minelayer_mines;
1683         this.punchangle = spectatee.punchangle;
1684         this.view_ofs = spectatee.view_ofs;
1685         this.velocity = spectatee.velocity;
1686         this.dmg_take = spectatee.dmg_take;
1687         this.dmg_save = spectatee.dmg_save;
1688         this.dmg_inflictor = spectatee.dmg_inflictor;
1689         this.v_angle = spectatee.v_angle;
1690         this.angles = spectatee.v_angle;
1691         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1692         this.revive_progress = spectatee.revive_progress;
1693         this.viewloc = spectatee.viewloc;
1694         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1695                 this.fixangle = true;
1696         setorigin(this, spectatee.origin);
1697         setsize(this, spectatee.mins, spectatee.maxs);
1698         SetZoomState(this, spectatee.zoomstate);
1699
1700         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1701         {
1702                 .entity weaponentity = weaponentities[slot];
1703                 this.(weaponentity) = spectatee.(weaponentity);
1704         }
1705
1706     anticheat_spectatecopy(this, spectatee);
1707         this.hud = spectatee.hud;
1708         if(spectatee.vehicle)
1709     {
1710         this.angles = spectatee.v_angle;
1711
1712         //this.fixangle = false;
1713         //this.velocity = spectatee.vehicle.velocity;
1714         this.vehicle_health = spectatee.vehicle_health;
1715         this.vehicle_shield = spectatee.vehicle_shield;
1716         this.vehicle_energy = spectatee.vehicle_energy;
1717         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1718         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1719         this.vehicle_reload1 = spectatee.vehicle_reload1;
1720         this.vehicle_reload2 = spectatee.vehicle_reload2;
1721
1722         //msg_entity = this;
1723
1724        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1725             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1726            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1727            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1728
1729         //WriteByte (MSG_ONE, SVC_SETVIEW);
1730         //    WriteEntity(MSG_ONE, this);
1731         //makevectors(spectatee.v_angle);
1732         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1733     }
1734 }
1735
1736 bool SpectateUpdate(entity this)
1737 {
1738         if(!this.enemy)
1739                 return false;
1740
1741         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1742         {
1743                 SetSpectatee(this, NULL);
1744                 return false;
1745         }
1746
1747         SpectateCopy(this, this.enemy);
1748
1749         return true;
1750 }
1751
1752 bool SpectateSet(entity this)
1753 {
1754         if(!IS_PLAYER(this.enemy))
1755                 return false;
1756
1757         ClientData_Touch(this.enemy);
1758
1759         msg_entity = this;
1760         WriteByte(MSG_ONE, SVC_SETVIEW);
1761         WriteEntity(MSG_ONE, this.enemy);
1762         set_movetype(this, MOVETYPE_NONE);
1763         accuracy_resend(this);
1764
1765         if(!SpectateUpdate(this))
1766                 PutObserverInServer(this);
1767
1768         return true;
1769 }
1770
1771 void SetSpectatee_status(entity this, int spectatee_num)
1772 {
1773         int oldspectatee_status = this.spectatee_status;
1774         this.spectatee_status = spectatee_num;
1775
1776         if (this.spectatee_status != oldspectatee_status)
1777         {
1778                 ClientData_Touch(this);
1779                 if (g_race || g_cts) race_InitSpectator();
1780         }
1781 }
1782
1783 void SetSpectatee(entity this, entity spectatee)
1784 {
1785         entity old_spectatee = this.enemy;
1786
1787         this.enemy = spectatee;
1788
1789         // WEAPONTODO
1790         // these are required to fix the spectator bug with arc
1791         if(old_spectatee)
1792         {
1793                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1794                 {
1795                         .entity weaponentity = weaponentities[slot];
1796                         if(old_spectatee.(weaponentity).arc_beam)
1797                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1798                 }
1799         }
1800         if(this.enemy)
1801         {
1802                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1803                 {
1804                         .entity weaponentity = weaponentities[slot];
1805                         if(this.enemy.(weaponentity).arc_beam)
1806                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1807                 }
1808         }
1809
1810         if (this.enemy)
1811                 SetSpectatee_status(this, etof(this.enemy));
1812
1813         // needed to update spectator list
1814         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1815 }
1816
1817 bool Spectate(entity this, entity pl)
1818 {
1819         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1820                 return false;
1821         pl = M_ARGV(1, entity);
1822
1823         SetSpectatee(this, pl);
1824         return SpectateSet(this);
1825 }
1826
1827 bool SpectateNext(entity this)
1828 {
1829         entity ent = find(this.enemy, classname, STR_PLAYER);
1830
1831         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1832                 ent = M_ARGV(1, entity);
1833         else if (!ent)
1834                 ent = find(ent, classname, STR_PLAYER);
1835
1836         if(ent) { SetSpectatee(this, ent); }
1837
1838         return SpectateSet(this);
1839 }
1840
1841 bool SpectatePrev(entity this)
1842 {
1843         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1844         entity ent = findchain(classname, STR_PLAYER);
1845         if (!ent) // no player
1846                 return false;
1847
1848         entity first = ent;
1849         // skip players until current spectated player
1850         if(this.enemy)
1851         while(ent && ent != this.enemy)
1852                 ent = ent.chain;
1853
1854         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1855         {
1856                 case MUT_SPECPREV_FOUND:
1857                     ent = M_ARGV(1, entity);
1858                     break;
1859                 case MUT_SPECPREV_RETURN:
1860                     return true;
1861                 case MUT_SPECPREV_CONTINUE:
1862                 default:
1863                 {
1864                         if(ent.chain)
1865                                 ent = ent.chain;
1866                         else
1867                                 ent = first;
1868                         break;
1869                 }
1870         }
1871
1872         SetSpectatee(this, ent);
1873         return SpectateSet(this);
1874 }
1875
1876 /*
1877 =============
1878 ShowRespawnCountdown()
1879
1880 Update a respawn countdown display.
1881 =============
1882 */
1883 void ShowRespawnCountdown(entity this)
1884 {
1885         float number;
1886         if(!IS_DEAD(this)) // just respawned?
1887                 return;
1888         else
1889         {
1890                 number = ceil(this.respawn_time - time);
1891                 if(number <= 0)
1892                         return;
1893                 if(number <= this.respawn_countdown)
1894                 {
1895                         this.respawn_countdown = number - 1;
1896                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1897                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1898                 }
1899         }
1900 }
1901
1902 .bool team_selected;
1903 bool ShowTeamSelection(entity this)
1904 {
1905         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1906                 return false;
1907         stuffcmd(this, "menu_showteamselect\n");
1908         return true;
1909 }
1910 void Join(entity this)
1911 {
1912         TRANSMUTE(Player, this);
1913
1914         if(!this.team_selected)
1915         if(autocvar_g_campaign || autocvar_g_balance_teams)
1916                 JoinBestTeam(this, false, true);
1917
1918         if(autocvar_g_campaign)
1919                 campaign_bots_may_start = true;
1920
1921         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1922
1923         PutClientInServer(this);
1924
1925         if(teamplay && this.team != -1)
1926                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1927         else
1928                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1929         this.team_selected = false;
1930 }
1931
1932 /**
1933  * Determines whether the player is allowed to join. This depends on cvar
1934  * g_maxplayers, if it isn't used this function always return true, otherwise
1935  * it checks whether the number of currently playing players exceeds g_maxplayers.
1936  * @return int number of free slots for players, 0 if none
1937  */
1938 int nJoinAllowed(entity this, entity ignore)
1939 {
1940         if(!ignore)
1941         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1942         // so report 0 free slots if restricted
1943         {
1944                 if(autocvar_g_forced_team_otherwise == "spectate")
1945                         return 0;
1946                 if(autocvar_g_forced_team_otherwise == "spectator")
1947                         return 0;
1948         }
1949
1950         if(this && this.team_forced < 0)
1951                 return 0; // forced spectators can never join
1952
1953         // TODO simplify this
1954         int totalClients = 0;
1955         int currentlyPlaying = 0;
1956         FOREACH_CLIENT(true, LAMBDA(
1957                 if(it != ignore)
1958                         ++totalClients;
1959                 if(IS_REAL_CLIENT(it))
1960                 if(IS_PLAYER(it) || it.caplayer)
1961                         ++currentlyPlaying;
1962         ));
1963
1964         float free_slots = 0;
1965         if (!autocvar_g_maxplayers)
1966                 free_slots = maxclients - totalClients;
1967         else if(currentlyPlaying < autocvar_g_maxplayers)
1968                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1969
1970         static float join_prevent_msg_time = 0;
1971         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1972         {
1973                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1974                 join_prevent_msg_time = time + 3;
1975         }
1976
1977         return free_slots;
1978 }
1979
1980 /**
1981  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1982  * g_maxplayers_spectator_blocktime seconds
1983  */
1984 void checkSpectatorBlock(entity this)
1985 {
1986         if(IS_SPEC(this) || IS_OBSERVER(this))
1987         if(!this.caplayer)
1988         if(IS_REAL_CLIENT(this))
1989         {
1990                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1991                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1992                         dropclient(this);
1993                 }
1994         }
1995 }
1996
1997 void PrintWelcomeMessage(entity this)
1998 {
1999         if(this.motd_actived_time == 0)
2000         {
2001                 if (autocvar_g_campaign) {
2002                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2003                                 this.motd_actived_time = time;
2004                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2005                         }
2006                 } else {
2007                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2008                                 this.motd_actived_time = time;
2009                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2010                         }
2011                 }
2012         }
2013         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2014         {
2015                 if (autocvar_g_campaign) {
2016                         if (PHYS_INPUT_BUTTON_INFO(this))
2017                                 this.motd_actived_time = time;
2018                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2019                                 this.motd_actived_time = 0;
2020                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2021                         }
2022                 } else {
2023                         if (PHYS_INPUT_BUTTON_INFO(this))
2024                                 this.motd_actived_time = time;
2025                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2026                                 this.motd_actived_time = 0;
2027                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2028                         }
2029                 }
2030         }
2031         else //if(this.motd_actived_time < 0) // just connected, motd is active
2032         {
2033                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2034                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2035                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2036                 {
2037                         // instanctly hide MOTD
2038                         this.motd_actived_time = 0;
2039                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2040                 }
2041         }
2042 }
2043
2044 bool joinAllowed(entity this)
2045 {
2046         if (this.version_mismatch) return false;
2047         if (!nJoinAllowed(this, this)) return false;
2048         if (teamplay && lockteams) return false;
2049         if (ShowTeamSelection(this)) return false;
2050         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2051         return true;
2052 }
2053
2054 void ObserverThink(entity this)
2055 {
2056         if ( this.impulse )
2057         {
2058                 MinigameImpulse(this, this.impulse);
2059                 this.impulse = 0;
2060         }
2061
2062         if (this.flags & FL_JUMPRELEASED) {
2063                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2064                         this.flags &= ~FL_JUMPRELEASED;
2065                         this.flags |= FL_SPAWNING;
2066                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2067                         this.flags &= ~FL_JUMPRELEASED;
2068                         if(SpectateNext(this)) {
2069                                 TRANSMUTE(Spectator, this);
2070                         }
2071                 } else {
2072                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2073                         set_movetype(this, preferred_movetype);
2074                 }
2075         } else {
2076                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2077                         this.flags |= FL_JUMPRELEASED;
2078                         if(this.flags & FL_SPAWNING)
2079                         {
2080                                 this.flags &= ~FL_SPAWNING;
2081                                 Join(this);
2082                                 return;
2083                         }
2084                 }
2085         }
2086 }
2087
2088 void SpectatorThink(entity this)
2089 {
2090         if ( this.impulse )
2091         {
2092                 if(MinigameImpulse(this, this.impulse))
2093                         this.impulse = 0;
2094
2095                 if (this.impulse == IMP_weapon_drop.impulse)
2096                 {
2097                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2098                         this.impulse = 0;
2099                         return;
2100                 }
2101         }
2102
2103         if (this.flags & FL_JUMPRELEASED) {
2104                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2105                         this.flags &= ~FL_JUMPRELEASED;
2106                         this.flags |= FL_SPAWNING;
2107                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2108                         this.flags &= ~FL_JUMPRELEASED;
2109                         if(SpectateNext(this)) {
2110                                 TRANSMUTE(Spectator, this);
2111                         } else {
2112                                 TRANSMUTE(Observer, this);
2113                                 PutClientInServer(this);
2114                         }
2115                         this.impulse = 0;
2116                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2117                         this.flags &= ~FL_JUMPRELEASED;
2118                         if(SpectatePrev(this)) {
2119                                 TRANSMUTE(Spectator, this);
2120                         } else {
2121                                 TRANSMUTE(Observer, this);
2122                                 PutClientInServer(this);
2123                         }
2124                         this.impulse = 0;
2125                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2126                         this.flags &= ~FL_JUMPRELEASED;
2127                         TRANSMUTE(Observer, this);
2128                         PutClientInServer(this);
2129                 } else {
2130                         if(!SpectateUpdate(this))
2131                                 PutObserverInServer(this);
2132                 }
2133         } else {
2134                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2135                         this.flags |= FL_JUMPRELEASED;
2136                         if(this.flags & FL_SPAWNING)
2137                         {
2138                                 this.flags &= ~FL_SPAWNING;
2139                                 Join(this);
2140                                 return;
2141                         }
2142                 }
2143                 if(!SpectateUpdate(this))
2144                         PutObserverInServer(this);
2145         }
2146
2147         this.flags |= FL_CLIENT | FL_NOTARGET;
2148 }
2149
2150 void vehicles_enter (entity pl, entity veh);
2151 void PlayerUseKey(entity this)
2152 {
2153         if (!IS_PLAYER(this))
2154                 return;
2155
2156         if(this.vehicle)
2157         {
2158                 if(!gameover)
2159                 {
2160                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2161                         return;
2162                 }
2163         }
2164         else if(autocvar_g_vehicles_enter)
2165         {
2166                 if(!STAT(FROZEN, this))
2167                 if(!IS_DEAD(this))
2168                 if(!gameover)
2169                 {
2170                         entity head, closest_target = NULL;
2171                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2172
2173                         while(head) // find the closest acceptable target to enter
2174                         {
2175                                 if(IS_VEHICLE(head))
2176                                 if(!IS_DEAD(head))
2177                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2178                                 if(head.takedamage != DAMAGE_NO)
2179                                 {
2180                                         if(closest_target)
2181                                         {
2182                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2183                                                 { closest_target = head; }
2184                                         }
2185                                         else { closest_target = head; }
2186                                 }
2187
2188                                 head = head.chain;
2189                         }
2190
2191                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2192                 }
2193         }
2194
2195         // a use key was pressed; call handlers
2196         MUTATOR_CALLHOOK(PlayerUseKey, this);
2197 }
2198
2199
2200 /*
2201 =============
2202 PlayerPreThink
2203
2204 Called every frame for each client before the physics are run
2205 =============
2206 */
2207 .float usekeypressed;
2208 .float last_vehiclecheck;
2209 .int items_added;
2210 void PlayerPreThink (entity this)
2211 {
2212         WarpZone_PlayerPhysics_FixVAngle(this);
2213
2214     STAT(GAMESTARTTIME, this) = game_starttime;
2215         STAT(ROUNDSTARTTIME, this) = round_starttime;
2216         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2217         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2218
2219         STAT(WEAPONSINMAP, this) = weaponsInMap;
2220
2221         if (frametime) {
2222                 // physics frames: update anticheat stuff
2223                 anticheat_prethink(this);
2224         }
2225
2226         if (blockSpectators && frametime) {
2227                 // WORKAROUND: only use dropclient in server frames (frametime set).
2228                 // Never use it in cl_movement frames (frametime zero).
2229                 checkSpectatorBlock(this);
2230     }
2231
2232         zoomstate_set = false;
2233
2234         // Check for nameless players
2235         if (isInvisibleString(this.netname)) {
2236                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2237                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2238         }
2239         if (this.netname != this.netname_previous) {
2240                 if (autocvar_sv_eventlog) {
2241                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2242         }
2243                 if (this.netname_previous) strunzone(this.netname_previous);
2244                 this.netname_previous = strzone(this.netname);
2245         }
2246
2247         // version nagging
2248         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2249         this.version_nagtime = 0;
2250         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2251             // git client
2252         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2253             // git server
2254             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2255         } else {
2256             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2257             if (r < 0) { // old client
2258                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2259             } else if (r > 0) { // old server
2260                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2261             }
2262         }
2263     }
2264
2265         // GOD MODE info
2266         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2267         {
2268                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2269                 this.max_armorvalue = 0;
2270         }
2271
2272         if (STAT(FROZEN, this) == 2)
2273         {
2274                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2275                 this.health = max(1, this.revive_progress * start_health);
2276                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2277
2278                 if (this.revive_progress >= 1)
2279                         Unfreeze(this);
2280         }
2281         else if (STAT(FROZEN, this) == 3)
2282         {
2283                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2284                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2285
2286                 if (this.health < 1)
2287                 {
2288                         if (this.vehicle)
2289                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2290                         if(this.event_damage)
2291                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2292                 }
2293                 else if (this.revive_progress <= 0)
2294                         Unfreeze(this);
2295         }
2296
2297         MUTATOR_CALLHOOK(PlayerPreThink, this);
2298
2299         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2300         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2301         {
2302                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2303                 {
2304                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2305                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2306                         {
2307                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2308                         }
2309                         else if(!it.owner)
2310                         {
2311                                 if(!it.team || SAME_TEAM(this, it))
2312                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2313                                 else if(autocvar_g_vehicles_steal)
2314                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2315                         }
2316                 });
2317
2318                 this.last_vehiclecheck = time + 1;
2319         }
2320
2321         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2322         {
2323                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2324                         PlayerUseKey(this);
2325                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2326         }
2327
2328         if (IS_REAL_CLIENT(this))
2329                 PrintWelcomeMessage(this);
2330
2331         if (IS_PLAYER(this)) {
2332                 CheckRules_Player(this);
2333
2334                 if (gameover || intermission_running) {
2335                         if(intermission_running)
2336                                 IntermissionThink(this);
2337                         return;
2338                 }
2339
2340                 if (timeout_status == TIMEOUT_ACTIVE) {
2341             // don't allow the player to turn around while game is paused
2342                         // FIXME turn this into CSQC stuff
2343                         this.v_angle = this.lastV_angle;
2344                         this.angles = this.lastV_angle;
2345                         this.fixangle = true;
2346                 }
2347
2348                 if (frametime) player_powerups(this);
2349
2350                 if (IS_DEAD(this)) {
2351                         if (this.personal && g_race_qualifying) {
2352                                 if (time > this.respawn_time) {
2353                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2354                                         respawn(this);
2355                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2356                                 }
2357                         } else {
2358                                 if (frametime) player_anim(this);
2359                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2360
2361                                 switch(this.deadflag)
2362                                 {
2363                                         case DEAD_DYING:
2364                                         {
2365                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2366                                                         this.deadflag = DEAD_RESPAWNING;
2367                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2368                                                         this.deadflag = DEAD_DEAD;
2369                                                 break;
2370                                         }
2371                                         case DEAD_DEAD:
2372                                         {
2373                                                 if (button_pressed)
2374                                                         this.deadflag = DEAD_RESPAWNABLE;
2375                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2376                                                         this.deadflag = DEAD_RESPAWNING;
2377                                                 break;
2378                                         }
2379                                         case DEAD_RESPAWNABLE:
2380                                         {
2381                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2382                                                         this.deadflag = DEAD_RESPAWNING;
2383                                                 break;
2384                                         }
2385                                         case DEAD_RESPAWNING:
2386                                         {
2387                                                 if (time > this.respawn_time)
2388                                                 {
2389                                                         this.respawn_time = time + 1; // only retry once a second
2390                                                         this.respawn_time_max = this.respawn_time;
2391                                                         respawn(this);
2392                                                 }
2393                                                 break;
2394                                         }
2395                                 }
2396
2397                                 ShowRespawnCountdown(this);
2398
2399                                 if (this.respawn_flags & RESPAWN_SILENT)
2400                                         STAT(RESPAWN_TIME, this) = 0;
2401                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2402                                 {
2403                                         if (time < this.respawn_time)
2404                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2405                                         else if (this.deadflag != DEAD_RESPAWNING)
2406                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2407                                 }
2408                                 else
2409                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2410                         }
2411
2412                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2413                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2414                                 STAT(RESPAWN_TIME, this) *= -1;
2415
2416                         return;
2417                 }
2418
2419                 this.prevorigin = this.origin;
2420
2421                 bool have_hook = false;
2422                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2423                 {
2424                         .entity weaponentity = weaponentities[slot];
2425                         if(this.(weaponentity).hook.state)
2426                         {
2427                                 have_hook = true;
2428                                 break;
2429                         }
2430                 }
2431                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2432                 if (have_hook) {
2433                         do_crouch = false;
2434                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2435                         do_crouch = false;
2436                 } else if (this.vehicle) {
2437                         do_crouch = false;
2438                 } else if (STAT(FROZEN, this)) {
2439                         do_crouch = false;
2440         }
2441
2442                 if (do_crouch) {
2443                         if (!this.crouch) {
2444                                 this.crouch = true;
2445                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2446                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2447                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2448                         }
2449                 } else if (this.crouch) {
2450             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2451             if (!trace_startsolid) {
2452                 this.crouch = false;
2453                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2454                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2455             }
2456                 }
2457
2458                 FixPlayermodel(this);
2459
2460                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2461                 //if(frametime)
2462                 {
2463                         this.items &= ~this.items_added;
2464
2465                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2466                         {
2467                                 .entity weaponentity = weaponentities[slot];
2468                                 W_WeaponFrame(this, weaponentity);
2469
2470                                 if(slot == 0)
2471                                 {
2472                                         this.clip_load = this.(weaponentity).clip_load;
2473                                         this.clip_size = this.(weaponentity).clip_size;
2474                                 }
2475                         }
2476
2477                         this.items_added = 0;
2478                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2479                 this.items_added |= IT_FUEL;
2480
2481                         this.items |= this.items_added;
2482                 }
2483
2484                 player_regen(this);
2485
2486                 // WEAPONTODO: Add a weapon request for this
2487                 // rot vortex charge to the charge limit
2488                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2489                 {
2490                         .entity weaponentity = weaponentities[slot];
2491                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2492                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2493                 }
2494
2495                 if (frametime) player_anim(this);
2496
2497                 // secret status
2498                 secrets_setstatus(this);
2499
2500                 // monsters status
2501                 monsters_setstatus(this);
2502
2503                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2504         }
2505         else if (gameover || intermission_running) {
2506                 if(intermission_running)
2507                         IntermissionThink(this);
2508                 return;
2509         }
2510         else if (IS_OBSERVER(this)) {
2511                 ObserverThink(this);
2512         }
2513         else if (IS_SPEC(this)) {
2514                 SpectatorThink(this);
2515         }
2516
2517         // WEAPONTODO: Add weapon request for this
2518         if (!zoomstate_set) {
2519                 bool wep_zoomed = false;
2520                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2521                 {
2522                         .entity weaponentity = weaponentities[slot];
2523                         Weapon thiswep = this.(weaponentity).m_weapon;
2524                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2525                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2526                 }
2527                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2528     }
2529
2530         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2531         {
2532                 this.teamkill_soundtime = 0;
2533
2534                 entity e = this.teamkill_soundsource;
2535                 entity oldpusher = e.pusher;
2536                 e.pusher = this;
2537                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2538                 e.pusher = oldpusher;
2539         }
2540
2541         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2542                 this.taunt_soundtime = 0;
2543                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2544         }
2545
2546         target_voicescript_next(this);
2547
2548         // WEAPONTODO: Move into weaponsystem somehow
2549         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2550         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2551         {
2552                 .entity weaponentity = weaponentities[slot];
2553                 if(this.(weaponentity).m_weapon == WEP_Null)
2554                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2555         }
2556 }
2557
2558 void DrownPlayer(entity this)
2559 {
2560         if(IS_DEAD(this))
2561                 return;
2562
2563         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2564         {
2565                 if(this.air_finished < time)
2566                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2567                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2568                 this.dmg = 2;
2569         }
2570         else if (this.air_finished < time)
2571         {       // drown!
2572                 if (this.pain_finished < time)
2573                 {
2574                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2575                         this.pain_finished = time + 0.5;
2576                 }
2577         }
2578 }
2579
2580 .bool move_qcphysics;
2581
2582 void Player_Physics(entity this)
2583 {
2584         set_movetype(this, this.move_movetype);
2585
2586         if(!this.move_qcphysics)
2587                 return;
2588
2589         if(!frametime && !this.pm_frametime)
2590                 return;
2591
2592         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2593
2594         this.pm_frametime = 0;
2595 }
2596
2597 /*
2598 =============
2599 PlayerPostThink
2600
2601 Called every frame for each client after the physics are run
2602 =============
2603 */
2604 .float idlekick_lasttimeleft;
2605 void PlayerPostThink (entity this)
2606 {
2607         Player_Physics(this);
2608
2609         if (sv_maxidle > 0)
2610         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2611         if (IS_REAL_CLIENT(this))
2612         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2613         {
2614                 int totalClients = 0;
2615                 if(sv_maxidle_slots > 0)
2616                 {
2617                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2618                         {
2619                                 ++totalClients;
2620                         });
2621                 }
2622
2623                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2624                 { /* do nothing */ }
2625                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2626                 {
2627                         if (this.idlekick_lasttimeleft)
2628                         {
2629                                 this.idlekick_lasttimeleft = 0;
2630                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2631                         }
2632                 }
2633                 else
2634                 {
2635                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2636                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2637                                 if (!this.idlekick_lasttimeleft)
2638                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2639                         }
2640                         if (timeleft <= 0) {
2641                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2642                                 dropclient(this);
2643                                 return;
2644                         }
2645                         else if (timeleft <= 10) {
2646                                 if (timeleft != this.idlekick_lasttimeleft) {
2647                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2648                 }
2649                                 this.idlekick_lasttimeleft = timeleft;
2650                         }
2651                 }
2652         }
2653
2654         CheatFrame(this);
2655
2656         //CheckPlayerJump();
2657         if (gameover)
2658         {
2659                 this.solid = SOLID_NOT;
2660                 this.takedamage = DAMAGE_NO;
2661                 set_movetype(this, MOVETYPE_NONE);
2662         }
2663
2664         if (IS_PLAYER(this)) {
2665                 DrownPlayer(this);
2666                 CheckRules_Player(this);
2667                 UpdateChatBubble(this);
2668                 if (this.impulse) ImpulseCommands(this);
2669                 if (gameover)
2670                 {
2671                         CSQCMODEL_AUTOUPDATE(this);
2672                         return;
2673                 }
2674                 GetPressedKeys(this);
2675         }
2676
2677         if (this.waypointsprite_attachedforcarrier) {
2678             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2679                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2680     }
2681
2682         playerdemo_write(this);
2683
2684         CSQCMODEL_AUTOUPDATE(this);
2685 }