qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/bot/default/waypoints.qh>
  50 #include <server/campaign.qh>
  51 #include <server/chat.qh>
  52 #include <server/cheats.qh>
  53 #include <server/clientkill.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/common.qh>
  56 #include <server/command/vote.qh>
  57 #include <server/compat/quake3.qh>
  58 #include <server/damage.qh>
  59 #include <server/gamelog.qh>
  60 #include <server/handicap.qh>
  61 #include <server/hook.qh>
  62 #include <server/impulse.qh>
  63 #include <server/intermission.qh>
  64 #include <server/ipban.qh>
  65 #include <server/main.qh>
  66 #include <server/mutators/_mod.qh>
  67 #include <server/player.qh>
  68 #include <server/portals.qh>
  69 #include <server/race.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 142                                         sf |= BIT(4); // show spectators
 143
 144         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 145         WriteByte(MSG_ENTITY, sf);
 146
 147         if (sf & BIT(1))
 148                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 149
 150         if(sf & BIT(4))
 151         {
 152                 float specs = CountSpectators(e, to);
 153                 WriteByte(MSG_ENTITY, specs);
 154                 WriteSpectators(e, to);
 155         }
 156
 157         return true;
 158 }
 159
 160 void ClientData_Attach(entity this)
 161 {
 162         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 163         CS(this).clientdata.drawonlytoclient = this;
 164         CS(this).clientdata.owner = this;
 165 }
 166
 167 void ClientData_Detach(entity this)
 168 {
 169         delete(CS(this).clientdata);
 170         CS(this).clientdata = NULL;
 171 }
 172
 173 void ClientData_Touch(entity e)
 174 {
 175         entity cd = CS(e).clientdata;
 176         if (cd) { cd.SendFlags = 1; }
 177
 178         // make it spectatable
 179         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 180         {
 181                 entity cd = CS(it).clientdata;
 182                 if (cd) { cd.SendFlags = 1; }
 183         });
 184 }
 185
 186
 187 /*
 188 =============
 189 CheckPlayerModel
 190
 191 Checks if the argument string can be a valid playermodel.
 192 Returns a valid one in doubt.
 193 =============
 194 */
 195 string FallbackPlayerModel;
 196 string CheckPlayerModel(string plyermodel) {
 197         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 198         {
 199                 // note: we cannot summon Don Strunzone here, some player may
 200                 // still have the model string set. In case anyone manages how
 201                 // to change a cvar default, we'll have a small leak here.
 202                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 203         }
 204         // only in right path
 205         if(substring(plyermodel, 0, 14) != "models/player/")
 206                 return FallbackPlayerModel;
 207         // only good file extensions
 208         if(substring(plyermodel, -4, 4) != ".iqm"
 209                 && substring(plyermodel, -4, 4) != ".zym"
 210                 && substring(plyermodel, -4, 4) != ".dpm"
 211                 && substring(plyermodel, -4, 4) != ".md3"
 212                 && substring(plyermodel, -4, 4) != ".psk")
 213         {
 214                 return FallbackPlayerModel;
 215         }
 216         // forbid the LOD models
 217         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 218                 return FallbackPlayerModel;
 219         if(plyermodel != strtolower(plyermodel))
 220                 return FallbackPlayerModel;
 221         // also, restrict to server models
 222         if(autocvar_sv_servermodelsonly)
 223         {
 224                 if(!fexists(plyermodel))
 225                         return FallbackPlayerModel;
 226         }
 227         return plyermodel;
 228 }
 229
 230 void setplayermodel(entity e, string modelname)
 231 {
 232         precache_model(modelname);
 233         _setmodel(e, modelname);
 234         player_setupanimsformodel(e);
 235         if(!autocvar_g_debug_globalsounds)
 236                 UpdatePlayerSounds(e);
 237 }
 238
 239 /** putting a client as observer in the server */
 240 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 241 {
 242         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 243         bool recount_ready = false;
 244         PlayerState_detach(this);
 245
 246         if (IS_PLAYER(this))
 247         {
 248                 if(GetResource(this, RES_HEALTH) >= 1)
 249                 {
 250                         // despawn effect
 251                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 252                 }
 253
 254                 // was a player, recount votes and ready status
 255                 if(IS_REAL_CLIENT(this))
 256                 {
 257                         if (vote_called) { VoteCount(false); }
 258                         this.ready = false;
 259                         recount_ready = true;
 260                 }
 261                 entcs_update_players(this);
 262         }
 263
 264         if (use_spawnpoint)
 265         {
 266                 entity spot = SelectSpawnPoint(this, true);
 267                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 268                 this.angles = vec2(spot.angles);
 269                 // offset it so that the spectator spawns higher off the ground, looks better this way
 270                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 271         }
 272         else // change origin to restore previous view origin
 273                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 274         this.fixangle = true;
 275
 276         if (IS_REAL_CLIENT(this))
 277         {
 278                 msg_entity = this;
 279                 WriteByte(MSG_ONE, SVC_SETVIEW);
 280                 WriteEntity(MSG_ONE, this);
 281         }
 282         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 283         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 284         if(!autocvar_g_debug_globalsounds)
 285         {
 286                 // needed for player sounds
 287                 this.model = "";
 288                 FixPlayermodel(this);
 289         }
 290         setmodel(this, MDL_Null);
 291         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 292         this.view_ofs = '0 0 0';
 293
 294         RemoveGrapplingHooks(this);
 295         Portal_ClearAll(this);
 296         Unfreeze(this, false);
 297         SetSpectatee(this, NULL);
 298
 299         if (this.alivetime)
 300         {
 301                 if (!warmup_stage)
 302                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 303                 this.alivetime = 0;
 304         }
 305
 306         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 307
 308         TRANSMUTE(Observer, this);
 309
 310         if(recount_ready) ReadyCount();
 311
 312         WaypointSprite_PlayerDead(this);
 313         accuracy_resend(this);
 314
 315         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 316                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 317
 318         CS(this).spectatortime = time;
 319         if(this.bot_attack)
 320                 IL_REMOVE(g_bot_targets, this);
 321         this.bot_attack = false;
 322         if(this.monster_attack)
 323                 IL_REMOVE(g_monster_targets, this);
 324         this.monster_attack = false;
 325         STAT(HUD, this) = HUD_NORMAL;
 326         this.iscreature = false;
 327         this.teleportable = TELEPORT_SIMPLE;
 328         if(this.damagedbycontents)
 329                 IL_REMOVE(g_damagedbycontents, this);
 330         this.damagedbycontents = false;
 331         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 332         SetSpectatee_status(this, etof(this));
 333         this.takedamage = DAMAGE_NO;
 334         this.solid = SOLID_NOT;
 335         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 336         this.flags = FL_CLIENT | FL_NOTARGET;
 337         this.effects = 0;
 338         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 339         this.pauserotarmor_finished = 0;
 340         this.pauserothealth_finished = 0;
 341         this.pauseregen_finished = 0;
 342         this.damageforcescale = 0;
 343         this.death_time = 0;
 344         this.respawn_flags = 0;
 345         this.respawn_time = 0;
 346         STAT(RESPAWN_TIME, this) = 0;
 347         this.alpha = 0;
 348         this.scale = 0;
 349         this.fade_time = 0;
 350         this.pain_finished = 0;
 351         STAT(AIR_FINISHED, this) = 0;
 352         //this.dphitcontentsmask = 0;
 353         this.dphitcontentsmask = DPCONTENTS_SOLID;
 354         if (autocvar_g_playerclip_collisions)
 355                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 356         this.pushltime = 0;
 357         this.istypefrag = 0;
 358         setthink(this, func_null);
 359         this.nextthink = 0;
 360         this.deadflag = DEAD_NO;
 361         UNSET_DUCKED(this);
 362         STAT(REVIVE_PROGRESS, this) = 0;
 363         this.revival_time = 0;
 364         this.draggable = drag_undraggable;
 365
 366         player_powerups_remove_all(this);
 367         this.items = 0;
 368         STAT(WEAPONS, this) = '0 0 0';
 369         this.drawonlytoclient = this;
 370
 371         this.viewloc = NULL;
 372
 373         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 374
 375         this.weaponmodel = "";
 376         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 377         {
 378                 this.weaponentities[slot] = NULL;
 379         }
 380         this.exteriorweaponentity = NULL;
 381         CS(this).killcount = FRAGS_SPECTATOR;
 382         this.velocity = '0 0 0';
 383         this.avelocity = '0 0 0';
 384         this.punchangle = '0 0 0';
 385         this.punchvector = '0 0 0';
 386         this.oldvelocity = this.velocity;
 387         this.event_damage = func_null;
 388         this.event_heal = func_null;
 389
 390         for(int slot = 0; slot < MAX_AXH; ++slot)
 391         {
 392                 entity axh = this.(AuxiliaryXhair[slot]);
 393                 this.(AuxiliaryXhair[slot]) = NULL;
 394
 395                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 396                         delete(axh);
 397         }
 398
 399         if (mutator_returnvalue)
 400         {
 401                 // mutator prevents resetting teams+score
 402         }
 403         else
 404         {
 405                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 406                 this.frags = FRAGS_SPECTATOR;
 407         }
 408
 409         bot_relinkplayerlist();
 410
 411         if (CS(this).just_joined)
 412                 CS(this).just_joined = false;
 413 }
 414
 415 int player_getspecies(entity this)
 416 {
 417         get_model_parameters(this.model, this.skin);
 418         int s = get_model_parameters_species;
 419         get_model_parameters(string_null, 0);
 420         if (s < 0) return SPECIES_HUMAN;
 421         return s;
 422 }
 423
 424 .float model_randomizer;
 425 void FixPlayermodel(entity player)
 426 {
 427         string defaultmodel = "";
 428         int defaultskin = 0;
 429         if(autocvar_sv_defaultcharacter)
 430         {
 431                 if(teamplay)
 432                 {
 433                         switch(player.team)
 434                         {
 435                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 436                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 437                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 438                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 439                         }
 440                 }
 441
 442                 if(defaultmodel == "")
 443                 {
 444                         defaultmodel = autocvar_sv_defaultplayermodel;
 445                         defaultskin = autocvar_sv_defaultplayerskin;
 446                 }
 447
 448                 int n = tokenize_console(defaultmodel);
 449                 if(n > 0)
 450                 {
 451                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 452                         // However, do NOT randomize if the player-selected model is in the list.
 453                         for (int i = 0; i < n; ++i)
 454                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 455                                         defaultmodel = argv(i);
 456                 }
 457
 458                 int i = strstrofs(defaultmodel, ":", 0);
 459                 if(i >= 0)
 460                 {
 461                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 462                         defaultmodel = substring(defaultmodel, 0, i);
 463                 }
 464         }
 465         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 466         {
 467                 if(teamplay)
 468                 {
 469                         switch(player.team)
 470                         {
 471                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 472                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 473                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 474                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 475                         }
 476                 }
 477
 478                 if(!defaultskin)
 479                         defaultskin = autocvar_sv_defaultplayerskin;
 480         }
 481
 482         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 483         defaultmodel = M_ARGV(0, string);
 484         defaultskin = M_ARGV(1, int);
 485
 486         bool chmdl = false;
 487         int oldskin;
 488         if(defaultmodel != "")
 489         {
 490                 if (defaultmodel != player.model)
 491                 {
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, defaultmodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 oldskin = player.skin;
 500                 player.skin = defaultskin;
 501         } else {
 502                 if (player.playermodel != player.model || player.playermodel == "")
 503                 {
 504                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 505                         vector m1 = player.mins;
 506                         vector m2 = player.maxs;
 507                         setplayermodel (player, player.playermodel);
 508                         setsize (player, m1, m2);
 509                         chmdl = true;
 510                 }
 511
 512                 if(!autocvar_sv_defaultcharacterskin)
 513                 {
 514                         oldskin = player.skin;
 515                         player.skin = stof(player.playerskin);
 516                 }
 517                 else
 518                 {
 519                         oldskin = player.skin;
 520                         player.skin = defaultskin;
 521                 }
 522         }
 523
 524         if(chmdl || oldskin != player.skin) // model or skin has changed
 525         {
 526                 player.species = player_getspecies(player); // update species
 527                 if(!autocvar_g_debug_globalsounds)
 528                         UpdatePlayerSounds(player); // update skin sounds
 529         }
 530
 531         if(!teamplay)
 532                 if(strlen(autocvar_sv_defaultplayercolors))
 533                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 534                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 535 }
 536
 537 void PutPlayerInServer(entity this)
 538 {
 539         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 540
 541         PlayerState_attach(this);
 542         accuracy_resend(this);
 543
 544         if (teamplay && this.bot_forced_team)
 545                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 546
 547         if (this.team < 0)
 548                 TeamBalance_JoinBestTeam(this);
 549
 550         entity spot = SelectSpawnPoint(this, false);
 551         if (!spot) {
 552                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 553                 return; // spawn failed
 554         }
 555
 556         TRANSMUTE(Player, this);
 557
 558         CS(this).wasplayer = true;
 559         this.iscreature = true;
 560         this.teleportable = TELEPORT_NORMAL;
 561         if(!this.damagedbycontents)
 562                 IL_PUSH(g_damagedbycontents, this);
 563         this.damagedbycontents = true;
 564         set_movetype(this, MOVETYPE_WALK);
 565         this.solid = SOLID_SLIDEBOX;
 566         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 567         if (autocvar_g_playerclip_collisions)
 568                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 569         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 570                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 571         this.frags = FRAGS_PLAYER;
 572         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 573         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 574         if (autocvar__notarget)
 575                 this.flags |= FL_NOTARGET;
 576         this.takedamage = DAMAGE_AIM;
 577         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 578
 579         if (warmup_stage) {
 580                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 581                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 582                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 583                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 584                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 585                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 586                 SetResource(this, RES_HEALTH, warmup_start_health);
 587                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 588                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 589         } else {
 590                 SetResource(this, RES_SHELLS, start_ammo_shells);
 591                 SetResource(this, RES_BULLETS, start_ammo_nails);
 592                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 593                 SetResource(this, RES_CELLS, start_ammo_cells);
 594                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 595                 SetResource(this, RES_FUEL, start_ammo_fuel);
 596                 SetResource(this, RES_HEALTH, start_health);
 597                 SetResource(this, RES_ARMOR, start_armorvalue);
 598                 STAT(WEAPONS, this) = start_weapons;
 599                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 600                 {
 601                         GiveRandomWeapons(this, random_start_weapons_count,
 602                                 autocvar_g_random_start_weapons, random_start_ammo);
 603                 }
 604         }
 605         SetSpectatee_status(this, 0);
 606
 607         PS(this).dual_weapons = '0 0 0';
 608
 609         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 610                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 611
 612         this.items = start_items;
 613
 614         float shieldtime = time + autocvar_g_spawnshieldtime;
 615
 616         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 617         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 618         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 619         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 620         if (!sv_ready_restart_after_countdown && time < game_starttime)
 621         {
 622                 float f = game_starttime - time;
 623                 shieldtime += f;
 624                 this.pauserotarmor_finished += f;
 625                 this.pauserothealth_finished += f;
 626                 this.pauseregen_finished += f;
 627         }
 628
 629         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 630
 631         this.damageforcescale = autocvar_g_player_damageforcescale;
 632         this.death_time = 0;
 633         this.respawn_flags = 0;
 634         this.respawn_time = 0;
 635         STAT(RESPAWN_TIME, this) = 0;
 636         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 637         this.fade_time = 0;
 638         this.pain_finished = 0;
 639         this.pushltime = 0;
 640         setthink(this, func_null); // players have no think function
 641         this.nextthink = 0;
 642         this.dmg_team = 0;
 643         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 644
 645         this.deadflag = DEAD_NO;
 646
 647         this.angles = spot.angles;
 648         this.angles_z = 0; // never spawn tilted even if the spot says to
 649         if (IS_BOT_CLIENT(this))
 650         {
 651                 this.v_angle = this.angles;
 652                 bot_aim_reset(this);
 653         }
 654         this.fixangle = true; // turn this way immediately
 655         this.oldvelocity = this.velocity = '0 0 0';
 656         this.avelocity = '0 0 0';
 657         this.punchangle = '0 0 0';
 658         this.punchvector = '0 0 0';
 659
 660         STAT(REVIVE_PROGRESS, this) = 0;
 661         this.revival_time = 0;
 662
 663         STAT(AIR_FINISHED, this) = 0;
 664         this.waterlevel = WATERLEVEL_NONE;
 665         this.watertype = CONTENT_EMPTY;
 666
 667         entity spawnevent = new_pure(spawnevent);
 668         spawnevent.owner = this;
 669         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 670
 671         // Cut off any still running player sounds.
 672         stopsound(this, CH_PLAYER_SINGLE);
 673
 674         this.model = "";
 675         FixPlayermodel(this);
 676         this.drawonlytoclient = NULL;
 677
 678         this.viewloc = NULL;
 679
 680         for(int slot = 0; slot < MAX_AXH; ++slot)
 681         {
 682                 entity axh = this.(AuxiliaryXhair[slot]);
 683                 this.(AuxiliaryXhair[slot]) = NULL;
 684
 685                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 686                         delete(axh);
 687         }
 688
 689         this.spawnpoint_targ = NULL;
 690
 691         UNSET_DUCKED(this);
 692         this.view_ofs = STAT(PL_VIEW_OFS, this);
 693         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 694         this.spawnorigin = spot.origin;
 695         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 696         // don't reset back to last position, even if new position is stuck in solid
 697         this.oldorigin = this.origin;
 698         if(this.conveyor)
 699                 IL_REMOVE(g_conveyed, this);
 700         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 701         if(this.swampslug)
 702                 IL_REMOVE(g_swamped, this);
 703         this.swampslug = NULL;
 704         this.swamp_interval = 0;
 705         if(this.ladder_entity)
 706                 IL_REMOVE(g_ladderents, this);
 707         this.ladder_entity = NULL;
 708         IL_EACH(g_counters, it.realowner == this,
 709         {
 710                 delete(it);
 711         });
 712         STAT(HUD, this) = HUD_NORMAL;
 713
 714         this.event_damage = PlayerDamage;
 715         this.event_heal = PlayerHeal;
 716
 717         this.draggable = func_null;
 718
 719         if(!this.bot_attack)
 720                 IL_PUSH(g_bot_targets, this);
 721         this.bot_attack = true;
 722         if(!this.monster_attack)
 723                 IL_PUSH(g_monster_targets, this);
 724         this.monster_attack = true;
 725         navigation_dynamicgoal_init(this, false);
 726
 727         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 728
 729         // player was spectator
 730         if (CS(this).killcount == FRAGS_SPECTATOR) {
 731                 PlayerScore_Clear(this);
 732                 CS(this).killcount = 0;
 733                 CS(this).startplaytime = time;
 734         }
 735
 736         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 CL_SpawnWeaponentity(this, weaponentity);
 740         }
 741         this.alpha = default_player_alpha;
 742         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 743         this.exteriorweaponentity.alpha = default_weapon_alpha;
 744
 745         this.speedrunning = false;
 746
 747         this.counter_cnt = 0;
 748         this.fragsfilter_cnt = 0;
 749
 750         target_voicescript_clear(this);
 751
 752         // reset fields the weapons may use
 753         FOREACH(Weapons, true, {
 754                 it.wr_resetplayer(it, this);
 755                         // reload all reloadable weapons
 756                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 757                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758                         {
 759                                 .entity weaponentity = weaponentities[slot];
 760                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 761                         }
 762                 }
 763         });
 764
 765         Unfreeze(this, false);
 766
 767         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 768         {
 769                 string s = spot.target;
 770                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 771                         spot.target = string_null;
 772                 SUB_UseTargets(spot, this, NULL);
 773                 if(g_assault || g_race)
 774                         spot.target = s;
 775         }
 776
 777         if (autocvar_spawn_debug)
 778         {
 779                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 780                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 781         }
 782
 783         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 784         {
 785                 .entity weaponentity = weaponentities[slot];
 786                 entity w_ent = this.(weaponentity);
 787                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 788                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 789                 else
 790                         w_ent.m_switchweapon = WEP_Null;
 791                 w_ent.m_weapon = WEP_Null;
 792                 w_ent.weaponname = "";
 793                 w_ent.m_switchingweapon = WEP_Null;
 794                 w_ent.cnt = -1;
 795         }
 796
 797         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 798
 799         if (CS(this).impulse) ImpulseCommands(this);
 800
 801         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 802         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 803         {
 804                 .entity weaponentity = weaponentities[slot];
 805                 W_WeaponFrame(this, weaponentity);
 806         }
 807
 808         if (!warmup_stage && !this.alivetime)
 809                 this.alivetime = time;
 810
 811         antilag_clear(this, CS(this));
 812 }
 813
 814 /** Called when a client spawns in the server */
 815 void PutClientInServer(entity this)
 816 {
 817         if (IS_REAL_CLIENT(this)) {
 818                 msg_entity = this;
 819                 WriteByte(MSG_ONE, SVC_SETVIEW);
 820                 WriteEntity(MSG_ONE, this);
 821         }
 822         if (game_stopped)
 823                 TRANSMUTE(Observer, this);
 824
 825         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 826         SetSpectatee(this, NULL);
 827
 828         // reset player keys
 829         if(PS(this))
 830                 PS(this).itemkeys = 0;
 831
 832         MUTATOR_CALLHOOK(PutClientInServer, this);
 833
 834         if (IS_OBSERVER(this)) {
 835                 PutObserverInServer(this, false, use_spawnpoint);
 836         } else if (IS_PLAYER(this)) {
 837                 PutPlayerInServer(this);
 838         }
 839
 840         bot_relinkplayerlist();
 841 }
 842
 843 // TODO do we need all these fields, or should we stop autodetecting runtime
 844 // changes and just have a console command to update this?
 845 bool ClientInit_SendEntity(entity this, entity to, int sf)
 846 {
 847         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 848         return = true;
 849         msg_entity = to;
 850         // MSG_INIT replacement
 851         // TODO: make easier to use
 852         Registry_send_all();
 853         W_PROP_reload(MSG_ONE, to);
 854         ClientInit_misc(this);
 855         MUTATOR_CALLHOOK(Ent_Init);
 856 }
 857 void ClientInit_misc(entity this)
 858 {
 859         int channel = MSG_ONE;
 860         WriteHeader(channel, ENT_CLIENT_INIT);
 861         WriteByte(channel, g_nexball_meter_period * 32);
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 864         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 865         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 868         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 869         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 870
 871         if(autocvar_sv_foginterval && world.fog != "")
 872                 WriteString(channel, world.fog);
 873         else
 874                 WriteString(channel, "");
 875         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 876         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 877         WriteByte(channel, serverflags);
 878         WriteCoord(channel, autocvar_g_trueaim_minrange);
 879 }
 880
 881 void ClientInit_CheckUpdate(entity this)
 882 {
 883         this.nextthink = time;
 884         if(this.count != autocvar_g_balance_armor_blockpercent)
 885         {
 886                 this.count = autocvar_g_balance_armor_blockpercent;
 887                 this.SendFlags |= 1;
 888         }
 889         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 890         {
 891                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 892                 this.SendFlags |= 1;
 893         }
 894 }
 895
 896 void ClientInit_Spawn()
 897 {
 898         entity e = new_pure(clientinit);
 899         setthink(e, ClientInit_CheckUpdate);
 900         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 901
 902         ClientInit_CheckUpdate(e);
 903 }
 904
 905 /*
 906 =============
 907 SetNewParms
 908 =============
 909 */
 910 void SetNewParms ()
 911 {
 912         // initialize parms for a new player
 913         parm1 = -(86400 * 366);
 914
 915         MUTATOR_CALLHOOK(SetNewParms);
 916 }
 917
 918 /*
 919 =============
 920 SetChangeParms
 921 =============
 922 */
 923 void SetChangeParms (entity this)
 924 {
 925         // save parms for level change
 926         parm1 = CS(this).parm_idlesince - time;
 927
 928         MUTATOR_CALLHOOK(SetChangeParms);
 929 }
 930
 931 /*
 932 =============
 933 DecodeLevelParms
 934 =============
 935 */
 936 void DecodeLevelParms(entity this)
 937 {
 938         // load parms
 939         CS(this).parm_idlesince = parm1;
 940         if (CS(this).parm_idlesince == -(86400 * 366))
 941                 CS(this).parm_idlesince = time;
 942
 943         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 944         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 945
 946         MUTATOR_CALLHOOK(DecodeLevelParms);
 947 }
 948
 949 void FixClientCvars(entity e)
 950 {
 951         // send prediction settings to the client
 952         if(autocvar_g_antilag == 3) // client side hitscan
 953                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 954         if(autocvar_sv_gentle)
 955                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 956
 957         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 958         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 959
 960         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 961
 962         MUTATOR_CALLHOOK(FixClientCvars, e);
 963 }
 964
 965 bool findinlist_abbrev(string tofind, string list)
 966 {
 967         if(list == "" || tofind == "")
 968                 return false; // empty list or search, just return
 969
 970         // this function allows abbreviated strings!
 971         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 972         {
 973                 return true;
 974         });
 975
 976         return false;
 977 }
 978
 979 bool PlayerInIPList(entity p, string iplist)
 980 {
 981         // some safety checks (never allow local?)
 982         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 983                 return false;
 984
 985         return findinlist_abbrev(p.netaddress, iplist);
 986 }
 987
 988 bool PlayerInIDList(entity p, string idlist)
 989 {
 990         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 991         if(!p.crypto_idfp)
 992                 return false;
 993
 994         return findinlist_abbrev(p.crypto_idfp, idlist);
 995 }
 996
 997 bool PlayerInList(entity player, string list)
 998 {
 999         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1000 }
1001
1002 #ifdef DP_EXT_PRECONNECT
1003 /*
1004 =============
1005 ClientPreConnect
1006
1007 Called once (not at each match start) when a client begins a connection to the server
1008 =============
1009 */
1010 void ClientPreConnect(entity this)
1011 {
1012         if(autocvar_sv_eventlog)
1013         {
1014                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1015                         this.playerid,
1016                         etof(this),
1017                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1018                 ));
1019         }
1020 }
1021 #endif
1022
1023 // NOTE csqc uses the active mutators list sent by this function
1024 // to understand which mutators are enabled
1025 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1026 void SendWelcomeMessage(entity this, int msg_type)
1027 {
1028         WriteByte(msg_type, boolean(autocvar_g_campaign));
1029         if (boolean(autocvar_g_campaign))
1030         {
1031                 WriteString(msg_type, Campaign_GetTitle());
1032                 WriteByte(msg_type, Campaign_GetLevelNum());
1033                 WriteString(msg_type, Campaign_GetMessage());
1034                 return;
1035         }
1036         WriteString(msg_type, autocvar_hostname);
1037         WriteString(msg_type, autocvar_g_xonoticversion);
1038         WriteByte(msg_type, CS(this).version_mismatch);
1039         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1040
1041         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1042         string modifications = M_ARGV(0, string);
1043
1044         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1045                 modifications = strcat(modifications, ", No start weapons");
1046         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1047                 modifications = strcat(modifications, ", Low gravity");
1048         if(g_weapon_stay && !g_cts)
1049                 modifications = strcat(modifications, ", Weapons stay");
1050         if(autocvar_g_jetpack)
1051                 modifications = strcat(modifications, ", Jetpack");
1052         modifications = substring(modifications, 2, strlen(modifications) - 2);
1053
1054         WriteString(msg_type, modifications);
1055
1056         WriteString(msg_type, g_weaponarena_list);
1057
1058         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1059         {
1060                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1061                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1062         }
1063
1064         WriteString(msg_type, cache_mutatormsg);
1065
1066         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1067 }
1068
1069 /**
1070 =============
1071 ClientConnect
1072
1073 Called when a client connects to the server
1074 =============
1075 */
1076 void ClientConnect(entity this)
1077 {
1078         if (Ban_MaybeEnforceBanOnce(this)) return;
1079         assert(!IS_CLIENT(this), return);
1080         this.flags |= FL_CLIENT;
1081         assert(player_count >= 0, player_count = 0);
1082
1083         TRANSMUTE(Client, this);
1084         CS(this).version_nagtime = time + 10 + random() * 10;
1085
1086         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1087
1088         bot_clientconnect(this);
1089
1090         Player_DetermineForcedTeam(this);
1091
1092         TRANSMUTE(Observer, this);
1093
1094         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1095
1096         // always track bots, don't ask for cl_allow_uidtracking
1097         if (IS_BOT_CLIENT(this))
1098                 PlayerStats_GameReport_AddPlayer(this);
1099         else
1100                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1101
1102         if (autocvar_sv_eventlog)
1103                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1104
1105         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1106
1107         stuffcmd(this, clientstuff, "\n");
1108         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1109
1110         FixClientCvars(this);
1111
1112         // get version info from player
1113         stuffcmd(this, "cmd clientversion $gameversion\n");
1114
1115         // notify about available teams
1116         if (teamplay)
1117         {
1118                 entity balance = TeamBalance_CheckAllowedTeams(this);
1119                 int t = TeamBalance_GetAllowedTeams(balance);
1120                 TeamBalance_Destroy(balance);
1121                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1122         }
1123         else
1124         {
1125                 stuffcmd(this, "set _teams_available 0\n");
1126         }
1127
1128         bot_relinkplayerlist();
1129
1130         CS(this).spectatortime = time;
1131         if (blockSpectators)
1132         {
1133                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1134         }
1135
1136         CS(this).jointime = time;
1137
1138         if (IS_REAL_CLIENT(this))
1139         {
1140                 if (g_weaponarena_weapons == WEPSET(TUBA))
1141                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1142                 // quickmenu file must be put in a subfolder with an unique name
1143                 // to reduce chances of overriding custom client quickmenus
1144                 if (waypointeditor_enabled)
1145                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1146                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1147                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1148         }
1149
1150         if (!autocvar_sv_foginterval && world.fog != "")
1151                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1152
1153         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1154                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1155                         send_CSQC_teamnagger();
1156
1157         CSQCMODEL_AUTOINIT(this);
1158
1159         CS(this).model_randomizer = random();
1160
1161         if (IS_REAL_CLIENT(this))
1162                 sv_notice_join(this);
1163
1164         this.move_qcphysics = autocvar_sv_qcphysics;
1165
1166         // update physics stats (players can spawn before physics runs)
1167         Physics_UpdateStats(this);
1168
1169         IL_EACH(g_initforplayer, it.init_for_player, {
1170                 it.init_for_player(it, this);
1171         });
1172
1173         Handicap_Initialize(this);
1174
1175         MUTATOR_CALLHOOK(ClientConnect, this);
1176
1177         if (player_count == 1)
1178                 localcmd("\nsv_hook_firstjoin\n");
1179 }
1180 /*
1181 =============
1182 ClientDisconnect
1183
1184 Called when a client disconnects from the server
1185 =============
1186 */
1187 .entity chatbubbleentity;
1188 void player_powerups_remove_all(entity this);
1189
1190 void ClientDisconnect(entity this)
1191 {
1192         assert(IS_CLIENT(this), return);
1193
1194         PlayerStats_GameReport_FinalizePlayer(this);
1195         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1196         if (CS(this).active_minigame) part_minigame(this);
1197         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1198
1199         if (autocvar_sv_eventlog)
1200                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1201
1202         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1203
1204         if(IS_SPEC(this))
1205                 SetSpectatee(this, NULL);
1206
1207         MUTATOR_CALLHOOK(ClientDisconnect, this);
1208
1209         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1210         strfree(CS_CVAR(this).weaponorder_byimpulse);
1211         ClientState_detach(this);
1212
1213         Portal_ClearAll(this);
1214
1215         Unfreeze(this, false);
1216
1217         RemoveGrapplingHooks(this);
1218
1219         // Here, everything has been done that requires this player to be a client.
1220
1221         this.flags &= ~FL_CLIENT;
1222
1223         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1224         if (this.killindicator) delete(this.killindicator);
1225
1226         IL_EACH(g_counters, it.realowner == this,
1227         {
1228                 delete(it);
1229         });
1230
1231         WaypointSprite_PlayerGone(this);
1232
1233         bot_relinkplayerlist();
1234
1235         strfree(this.clientstatus);
1236         if (this.personal) delete(this.personal);
1237
1238         this.playerid = 0;
1239         ReadyCount();
1240         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1241
1242         player_powerups_remove_all(this); // stop powerup sound
1243
1244         ONREMOVE(this);
1245
1246         if (player_count == 0)
1247                 localcmd("\nsv_hook_lastleave\n");
1248 }
1249
1250 void ChatBubbleThink(entity this)
1251 {
1252         this.nextthink = time;
1253         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1254         {
1255                 if(this.owner) // but why can that ever be NULL?
1256                         this.owner.chatbubbleentity = NULL;
1257                 delete(this);
1258                 return;
1259         }
1260
1261         this.mdl = "";
1262
1263         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1264         {
1265                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1266                         this.mdl = "models/sprites/minigame_busy.iqm";
1267                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1268                         this.mdl = "models/misc/chatbubble.spr";
1269         }
1270
1271         if ( this.model != this.mdl )
1272                 _setmodel(this, this.mdl);
1273
1274 }
1275
1276 void UpdateChatBubble(entity this)
1277 {
1278         if (this.alpha < 0)
1279                 return;
1280         // spawn a chatbubble entity if needed
1281         if (!this.chatbubbleentity)
1282         {
1283                 this.chatbubbleentity = new(chatbubbleentity);
1284                 this.chatbubbleentity.owner = this;
1285                 this.chatbubbleentity.exteriormodeltoclient = this;
1286                 setthink(this.chatbubbleentity, ChatBubbleThink);
1287                 this.chatbubbleentity.nextthink = time;
1288                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1289                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1290                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1291                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1292                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1293                 //this.chatbubbleentity.model = "";
1294                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1295         }
1296 }
1297
1298 void calculate_player_respawn_time(entity this)
1299 {
1300         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1301                 return;
1302
1303         float gametype_setting_tmp;
1304         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1305         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1306         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1307         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1308         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1309         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1310
1311         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1312         if (teamplay)
1313         {
1314                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1315                         if(it.team == this.team)
1316                                 ++pcount;
1317                 });
1318                 if (sdelay_small_count == 0)
1319                         sdelay_small_count = 1;
1320                 if (sdelay_large_count == 0)
1321                         sdelay_large_count = 1;
1322         }
1323         else
1324         {
1325                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1326                         ++pcount;
1327                 });
1328                 if (sdelay_small_count == 0)
1329                 {
1330                         if (IS_INDEPENDENT_PLAYER(this))
1331                         {
1332                                 // Players play independently. No point in requiring enemies.
1333                                 sdelay_small_count = 1;
1334                         }
1335                         else
1336                         {
1337                                 // Players play AGAINST each other. Enemies required.
1338                                 sdelay_small_count = 2;
1339                         }
1340                 }
1341                 if (sdelay_large_count == 0)
1342                 {
1343                         if (IS_INDEPENDENT_PLAYER(this))
1344                         {
1345                                 // Players play independently. No point in requiring enemies.
1346                                 sdelay_large_count = 1;
1347                         }
1348                         else
1349                         {
1350                                 // Players play AGAINST each other. Enemies required.
1351                                 sdelay_large_count = 2;
1352                         }
1353                 }
1354         }
1355
1356         float sdelay;
1357
1358         if (pcount <= sdelay_small_count)
1359                 sdelay = sdelay_small;
1360         else if (pcount >= sdelay_large_count)
1361                 sdelay = sdelay_large;
1362         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1363                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1364
1365         if(waves)
1366                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1367         else
1368                 this.respawn_time = time + sdelay;
1369
1370         if(sdelay < sdelay_max)
1371                 this.respawn_time_max = time + sdelay_max;
1372         else
1373                 this.respawn_time_max = this.respawn_time;
1374
1375         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1376                 this.respawn_countdown = 10; // first number to count down from is 10
1377         else
1378                 this.respawn_countdown = -1; // do not count down
1379
1380         if(autocvar_g_forced_respawn)
1381                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1382 }
1383
1384 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1385 // added to the model skins
1386 /*void UpdateColorModHack()
1387 {
1388         float c;
1389         c = this.clientcolors & 15;
1390         // LordHavoc: only bothering to support white, green, red, yellow, blue
1391              if (!teamplay) this.colormod = '0 0 0';
1392         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1393         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1394         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1395         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1396         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1397         else this.colormod = '1 1 1';
1398 }*/
1399
1400 void respawn(entity this)
1401 {
1402         bool damagedbycontents_prev = this.damagedbycontents;
1403         if(this.alpha >= 0)
1404         {
1405                 if(autocvar_g_respawn_ghosts)
1406                 {
1407                         this.solid = SOLID_NOT;
1408                         this.takedamage = DAMAGE_NO;
1409                         this.damagedbycontents = false;
1410                         set_movetype(this, MOVETYPE_FLY);
1411                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1412                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1413                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1414                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1415                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1416                         if(autocvar_g_respawn_ghosts_time > 0)
1417                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1418                 }
1419                 else
1420                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1421         }
1422
1423         CopyBody(this, 1);
1424         this.damagedbycontents = damagedbycontents_prev;
1425
1426         this.effects |= EF_NODRAW; // prevent another CopyBody
1427         PutClientInServer(this);
1428 }
1429
1430 void play_countdown(entity this, float finished, Sound samp)
1431 {
1432         TC(Sound, samp);
1433         float time_left = finished - time;
1434         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1435                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1436 }
1437
1438 // it removes special powerups not handled by StatusEffects
1439 void player_powerups_remove_all(entity this)
1440 {
1441         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1442         {
1443                 // don't play the poweroff sound when the game restarts or the player disconnects
1444                 if (time > game_starttime + 1 && IS_CLIENT(this)
1445                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1446                 {
1447                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1448                 }
1449                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1450                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1451                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1452         }
1453 }
1454
1455 void player_powerups(entity this)
1456 {
1457         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1458                 this.modelflags |= MF_ROCKET;
1459         else
1460                 this.modelflags &= ~MF_ROCKET;
1461
1462         this.effects &= ~EF_NODEPTHTEST;
1463
1464         if (IS_DEAD(this))
1465                 player_powerups_remove_all(this);
1466
1467         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1468                 return;
1469
1470         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1471         int items_prev = this.items;
1472
1473         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1474         {
1475                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1476                 if (this.items & IT_SUPERWEAPON)
1477                 {
1478                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1479                         {
1480                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1481                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1482                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1483                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1484                         }
1485                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1486                         {
1487                                 // don't let them run out
1488                         }
1489                         else
1490                         {
1491                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1492                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1493                                 {
1494                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1495                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1496                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1497                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1498                                 }
1499                         }
1500                 }
1501                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1502                 {
1503                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1504                         {
1505                                 this.items = this.items | IT_SUPERWEAPON;
1506                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1507                                 {
1508                                         if(!g_cts)
1509                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1510                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1511                                 }
1512                         }
1513                         else
1514                         {
1515                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1516                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1517                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1518                         }
1519                 }
1520                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1521                 {
1522                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1523                 }
1524         }
1525
1526         if(autocvar_g_nodepthtestplayers)
1527                 this.effects = this.effects | EF_NODEPTHTEST;
1528
1529         if(autocvar_g_fullbrightplayers)
1530                 this.effects = this.effects | EF_FULLBRIGHT;
1531
1532         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1533 }
1534
1535 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1536 {
1537         if(current > stable)
1538                 return current;
1539         else if(current > stable - 0.25) // when close enough, "snap"
1540                 return stable;
1541         else
1542                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1543 }
1544
1545 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1546 {
1547         if(current < stable)
1548                 return current;
1549         else if(current < stable + 0.25) // when close enough, "snap"
1550                 return stable;
1551         else
1552                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1553 }
1554
1555 void RotRegen(entity this, Resource res, float limit_mod,
1556         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1557         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1558 {
1559         float old = GetResource(this, res);
1560         float current = old;
1561         if(current > rotstable)
1562         {
1563                 if(rotframetime > 0)
1564                 {
1565                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1566                         current = max(rotstable, current - rotlinear * rotframetime);
1567                 }
1568         }
1569         else if(current < regenstable)
1570         {
1571                 if(regenframetime > 0)
1572                 {
1573                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1574                         current = min(regenstable, current + regenlinear * regenframetime);
1575                 }
1576         }
1577
1578         float limit = GetResourceLimit(this, res) * limit_mod;
1579         if(current > limit)
1580                 current = limit;
1581
1582         if (current != old)
1583                 SetResource(this, res, current);
1584 }
1585
1586 void player_regen(entity this)
1587 {
1588         float max_mod, regen_mod, rot_mod, limit_mod;
1589         max_mod = regen_mod = rot_mod = limit_mod = 1;
1590
1591         float regen_health = autocvar_g_balance_health_regen;
1592         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1593         float regen_health_rot = autocvar_g_balance_health_rot;
1594         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1595         float regen_health_stable = autocvar_g_balance_health_regenstable;
1596         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1597         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1598                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1599         max_mod = M_ARGV(1, float);
1600         regen_mod = M_ARGV(2, float);
1601         rot_mod = M_ARGV(3, float);
1602         limit_mod = M_ARGV(4, float);
1603         regen_health = M_ARGV(5, float);
1604         regen_health_linear = M_ARGV(6, float);
1605         regen_health_rot = M_ARGV(7, float);
1606         regen_health_rotlinear = M_ARGV(8, float);
1607         regen_health_stable = M_ARGV(9, float);
1608         regen_health_rotstable = M_ARGV(10, float);
1609
1610         float rotstable, regenstable, rotframetime, regenframetime;
1611
1612         if(!mutator_returnvalue)
1613         if(!STAT(FROZEN, this))
1614         {
1615                 regenstable = autocvar_g_balance_armor_regenstable;
1616                 rotstable = autocvar_g_balance_armor_rotstable;
1617                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1618                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1619                 RotRegen(this, RES_ARMOR, limit_mod,
1620                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1621                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1622
1623                 // NOTE: max_mod is only applied to health
1624                 regenstable = regen_health_stable * max_mod;
1625                 rotstable = regen_health_rotstable * max_mod;
1626                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1627                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1628                 RotRegen(this, RES_HEALTH, limit_mod,
1629                         regenstable, regen_health, regen_health_linear, regenframetime,
1630                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1631         }
1632
1633         // if player rotted to death...  die!
1634         // check this outside above checks, as player may still be able to rot to death
1635         if(GetResource(this, RES_HEALTH) < 1)
1636         {
1637                 if(this.vehicle)
1638                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1639                 if(this.event_damage)
1640                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1641         }
1642
1643         if (!(this.items & IT_UNLIMITED_AMMO))
1644         {
1645                 regenstable = autocvar_g_balance_fuel_regenstable;
1646                 rotstable = autocvar_g_balance_fuel_rotstable;
1647                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1648                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1649                 RotRegen(this, RES_FUEL, 1,
1650                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1651                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1652         }
1653 }
1654
1655 bool zoomstate_set;
1656 void SetZoomState(entity this, float newzoom)
1657 {
1658         if(newzoom != CS(this).zoomstate)
1659         {
1660                 CS(this).zoomstate = newzoom;
1661                 ClientData_Touch(this);
1662         }
1663         zoomstate_set = true;
1664 }
1665
1666 void GetPressedKeys(entity this)
1667 {
1668         MUTATOR_CALLHOOK(GetPressedKeys, this);
1669         if (game_stopped)
1670         {
1671                 CS(this).pressedkeys = 0;
1672                 STAT(PRESSED_KEYS, this) = 0;
1673                 return;
1674         }
1675
1676         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1677         int keys = STAT(PRESSED_KEYS, this);
1678         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1679         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1680         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1681         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1682
1683         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1684         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1685         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1686         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1687         CS(this).pressedkeys = keys; // store for other users
1688
1689         STAT(PRESSED_KEYS, this) = keys;
1690 }
1691
1692 /*
1693 ======================
1694 spectate mode routines
1695 ======================
1696 */
1697
1698 void SpectateCopy(entity this, entity spectatee)
1699 {
1700         TC(Client, this); TC(Client, spectatee);
1701
1702         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1703         PS(this) = PS(spectatee);
1704         this.armortype = spectatee.armortype;
1705         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1706         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1707         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1708         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1709         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1710         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1711         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1712         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1713         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1714         CS(this).impulse = 0;
1715         this.disableclientprediction = 1; // no need to run prediction on a spectator
1716         this.items = spectatee.items;
1717         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1718         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1719         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1720         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1721         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1722         this.punchangle = spectatee.punchangle;
1723         this.view_ofs = spectatee.view_ofs;
1724         this.velocity = spectatee.velocity;
1725         this.dmg_take = spectatee.dmg_take;
1726         this.dmg_save = spectatee.dmg_save;
1727         this.dmg_inflictor = spectatee.dmg_inflictor;
1728         this.v_angle = spectatee.v_angle;
1729         this.angles = spectatee.v_angle;
1730         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1731         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1732         this.viewloc = spectatee.viewloc;
1733         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1734                 this.fixangle = true;
1735         setorigin(this, spectatee.origin);
1736         setsize(this, spectatee.mins, spectatee.maxs);
1737         SetZoomState(this, CS(spectatee).zoomstate);
1738
1739     anticheat_spectatecopy(this, spectatee);
1740         STAT(HUD, this) = STAT(HUD, spectatee);
1741         if(spectatee.vehicle)
1742     {
1743         this.angles = spectatee.v_angle;
1744
1745         //this.fixangle = false;
1746         //this.velocity = spectatee.vehicle.velocity;
1747         this.vehicle_health = spectatee.vehicle_health;
1748         this.vehicle_shield = spectatee.vehicle_shield;
1749         this.vehicle_energy = spectatee.vehicle_energy;
1750         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1751         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1752         this.vehicle_reload1 = spectatee.vehicle_reload1;
1753         this.vehicle_reload2 = spectatee.vehicle_reload2;
1754
1755         //msg_entity = this;
1756
1757        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1758             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1759            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1760            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1761
1762         //WriteByte (MSG_ONE, SVC_SETVIEW);
1763         //    WriteEntity(MSG_ONE, this);
1764         //makevectors(spectatee.v_angle);
1765         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1766     }
1767 }
1768
1769 bool SpectateUpdate(entity this)
1770 {
1771         if(!this.enemy)
1772                 return false;
1773
1774         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1775         {
1776                 SetSpectatee(this, NULL);
1777                 return false;
1778         }
1779
1780         SpectateCopy(this, this.enemy);
1781
1782         return true;
1783 }
1784
1785 bool SpectateSet(entity this)
1786 {
1787         if(!IS_PLAYER(this.enemy))
1788                 return false;
1789
1790         ClientData_Touch(this.enemy);
1791
1792         msg_entity = this;
1793         WriteByte(MSG_ONE, SVC_SETVIEW);
1794         WriteEntity(MSG_ONE, this.enemy);
1795         set_movetype(this, MOVETYPE_NONE);
1796         accuracy_resend(this);
1797
1798         if(!SpectateUpdate(this))
1799                 PutObserverInServer(this, false, true);
1800
1801         return true;
1802 }
1803
1804 void SetSpectatee_status(entity this, int spectatee_num)
1805 {
1806         int oldspectatee_status = CS(this).spectatee_status;
1807         CS(this).spectatee_status = spectatee_num;
1808
1809         if (CS(this).spectatee_status != oldspectatee_status)
1810         {
1811                 if (STAT(PRESSED_KEYS, this))
1812                 {
1813                         CS(this).pressedkeys = 0;
1814                         STAT(PRESSED_KEYS, this) = 0;
1815                 }
1816                 ClientData_Touch(this);
1817                 if (g_race || g_cts) race_InitSpectator();
1818         }
1819 }
1820
1821 void SetSpectatee(entity this, entity spectatee)
1822 {
1823         if(IS_BOT_CLIENT(this))
1824                 return; // bots abuse .enemy, this code is useless to them
1825
1826         entity old_spectatee = this.enemy;
1827
1828         this.enemy = spectatee;
1829
1830         // WEAPONTODO
1831         // these are required to fix the spectator bug with arc
1832         if(old_spectatee)
1833         {
1834                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1835                 {
1836                         .entity weaponentity = weaponentities[slot];
1837                         if(old_spectatee.(weaponentity).arc_beam)
1838                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1839                 }
1840         }
1841         if(spectatee)
1842         {
1843                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1844                 {
1845                         .entity weaponentity = weaponentities[slot];
1846                         if(spectatee.(weaponentity).arc_beam)
1847                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1848                 }
1849         }
1850
1851         if (spectatee)
1852                 SetSpectatee_status(this, etof(spectatee));
1853
1854         // needed to update spectator list
1855         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1856 }
1857
1858 bool Spectate(entity this, entity pl)
1859 {
1860         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1861                 return false;
1862         pl = M_ARGV(1, entity);
1863
1864         SetSpectatee(this, pl);
1865         return SpectateSet(this);
1866 }
1867
1868 bool SpectateNext(entity this)
1869 {
1870         entity ent = find(this.enemy, classname, STR_PLAYER);
1871
1872         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1873                 ent = M_ARGV(1, entity);
1874         else if (!ent)
1875                 ent = find(ent, classname, STR_PLAYER);
1876
1877         if(ent) { SetSpectatee(this, ent); }
1878
1879         return SpectateSet(this);
1880 }
1881
1882 bool SpectatePrev(entity this)
1883 {
1884         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1885         entity ent = findchain(classname, STR_PLAYER);
1886         if (!ent) // no player
1887                 return false;
1888
1889         entity first = ent;
1890         // skip players until current spectated player
1891         if(this.enemy)
1892         while(ent && ent != this.enemy)
1893                 ent = ent.chain;
1894
1895         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1896         {
1897                 case MUT_SPECPREV_FOUND:
1898                         ent = M_ARGV(1, entity);
1899                         break;
1900                 case MUT_SPECPREV_RETURN:
1901                         return true;
1902                 case MUT_SPECPREV_CONTINUE:
1903                 default:
1904                 {
1905                         if(ent.chain)
1906                                 ent = ent.chain;
1907                         else
1908                                 ent = first;
1909                         break;
1910                 }
1911         }
1912
1913         SetSpectatee(this, ent);
1914         return SpectateSet(this);
1915 }
1916
1917 /*
1918 =============
1919 ShowRespawnCountdown()
1920
1921 Update a respawn countdown display.
1922 =============
1923 */
1924 void ShowRespawnCountdown(entity this)
1925 {
1926         float number;
1927         if(!IS_DEAD(this)) // just respawned?
1928                 return;
1929         else
1930         {
1931                 number = ceil(this.respawn_time - time);
1932                 if(number <= 0)
1933                         return;
1934                 if(number <= this.respawn_countdown)
1935                 {
1936                         this.respawn_countdown = number - 1;
1937                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1938                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1939                 }
1940         }
1941 }
1942
1943 .bool team_selected;
1944 bool ShowTeamSelection(entity this)
1945 {
1946         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1947                 return false;
1948         if (frametime) // once per frame is more than enough
1949                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1950         return true;
1951 }
1952 void Join(entity this)
1953 {
1954         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1955                 ReadyRestart(true);
1956
1957         TRANSMUTE(Player, this);
1958
1959         if(!this.team_selected)
1960         if(autocvar_g_campaign || autocvar_g_balance_teams)
1961                 TeamBalance_JoinBestTeam(this);
1962
1963         if(autocvar_g_campaign)
1964                 campaign_bots_may_start = true;
1965
1966         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1967
1968         PutClientInServer(this);
1969
1970         if(IS_PLAYER(this))
1971         if(teamplay && this.team != -1)
1972         {
1973         }
1974         else
1975                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1976         this.team_selected = false;
1977 }
1978
1979 int GetPlayerLimit()
1980 {
1981         if(g_duel)
1982                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1983         int player_limit = autocvar_g_maxplayers;
1984         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1985         player_limit = M_ARGV(0, int);
1986         return player_limit;
1987 }
1988
1989 /**
1990  * Determines whether the player is allowed to join. This depends on cvar
1991  * g_maxplayers, if it isn't used this function always return true, otherwise
1992  * it checks whether the number of currently playing players exceeds g_maxplayers.
1993  * @return int number of free slots for players, 0 if none
1994  */
1995 int nJoinAllowed(entity this, entity ignore)
1996 {
1997         if(!ignore)
1998         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1999         // so report 0 free slots if restricted
2000         {
2001                 if(autocvar_g_forced_team_otherwise == "spectate")
2002                         return 0;
2003                 if(autocvar_g_forced_team_otherwise == "spectator")
2004                         return 0;
2005         }
2006
2007         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2008                 return 0; // forced spectators can never join
2009
2010         // TODO simplify this
2011         int totalClients = 0;
2012         int currentlyPlaying = 0;
2013         FOREACH_CLIENT(true, {
2014                 if(it != ignore)
2015                         ++totalClients;
2016                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2017                         ++currentlyPlaying;
2018         });
2019
2020         int player_limit = GetPlayerLimit();
2021
2022         int free_slots = 0;
2023         if (!player_limit)
2024                 free_slots = maxclients - totalClients;
2025         else if(player_limit > 0 && currentlyPlaying < player_limit)
2026                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2027
2028         static float msg_time = 0;
2029         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2030         {
2031                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2032                 msg_time = time + 0.5;
2033         }
2034
2035         return free_slots;
2036 }
2037
2038 bool joinAllowed(entity this)
2039 {
2040         if (CS(this).version_mismatch) return false;
2041         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2042         if (!nJoinAllowed(this, this)) return false;
2043         if (teamplay && lockteams) return false;
2044         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2045         if (ShowTeamSelection(this)) return false;
2046         return true;
2047 }
2048
2049 .string shootfromfixedorigin;
2050 .bool dualwielding_prev;
2051 bool PlayerThink(entity this)
2052 {
2053         if (game_stopped || intermission_running) {
2054                 this.modelflags &= ~MF_ROCKET;
2055                 if(intermission_running)
2056                         IntermissionThink(this);
2057                 return false;
2058         }
2059
2060         if (timeout_status == TIMEOUT_ACTIVE) {
2061                 // don't allow the player to turn around while game is paused
2062                 // FIXME turn this into CSQC stuff
2063                 this.v_angle = this.lastV_angle;
2064                 this.angles = this.lastV_angle;
2065                 this.fixangle = true;
2066         }
2067
2068         if (frametime) player_powerups(this);
2069
2070         if (IS_DEAD(this)) {
2071                 if (this.personal && g_race_qualifying) {
2072                         if (time > this.respawn_time) {
2073                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2074                                 respawn(this);
2075                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2076                         }
2077                 } else {
2078                         if (frametime) player_anim(this);
2079
2080                         if (this.respawn_flags & RESPAWN_DENY)
2081                         {
2082                                 STAT(RESPAWN_TIME, this) = 0;
2083                                 return false;
2084                         }
2085
2086                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2087
2088                         switch(this.deadflag)
2089                         {
2090                                 case DEAD_DYING:
2091                                 {
2092                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2093                                                 this.deadflag = DEAD_RESPAWNING;
2094                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2095                                                 this.deadflag = DEAD_DEAD;
2096                                         break;
2097                                 }
2098                                 case DEAD_DEAD:
2099                                 {
2100                                         if (button_pressed)
2101                                                 this.deadflag = DEAD_RESPAWNABLE;
2102                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2103                                                 this.deadflag = DEAD_RESPAWNING;
2104                                         break;
2105                                 }
2106                                 case DEAD_RESPAWNABLE:
2107                                 {
2108                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2109                                                 this.deadflag = DEAD_RESPAWNING;
2110                                         break;
2111                                 }
2112                                 case DEAD_RESPAWNING:
2113                                 {
2114                                         if (time > this.respawn_time)
2115                                         {
2116                                                 this.respawn_time = time + 1; // only retry once a second
2117                                                 this.respawn_time_max = this.respawn_time;
2118                                                 respawn(this);
2119                                         }
2120                                         break;
2121                                 }
2122                         }
2123
2124                         ShowRespawnCountdown(this);
2125
2126                         if (this.respawn_flags & RESPAWN_SILENT)
2127                                 STAT(RESPAWN_TIME, this) = 0;
2128                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2129                         {
2130                                 if (time < this.respawn_time)
2131                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2132                                 else if (this.deadflag != DEAD_RESPAWNING)
2133                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2134                         }
2135                         else
2136                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2137                 }
2138
2139                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2140                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2141                         STAT(RESPAWN_TIME, this) *= -1;
2142
2143                 return false;
2144         }
2145
2146         FixPlayermodel(this);
2147
2148         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2149                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2150                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2151         }
2152
2153         // reset gun alignment when dual wielding status changes
2154         // to ensure guns are always aligned right and left
2155         bool dualwielding = W_DualWielding(this);
2156         if(this.dualwielding_prev != dualwielding)
2157         {
2158                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2159                 this.dualwielding_prev = dualwielding;
2160         }
2161
2162         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2163         //if(frametime)
2164         {
2165                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2166                 {
2167                         .entity weaponentity = weaponentities[slot];
2168                         if(WEP_CVAR(vortex, charge_always))
2169                                 W_Vortex_Charge(this, weaponentity, frametime);
2170                         W_WeaponFrame(this, weaponentity);
2171                 }
2172         }
2173
2174         if (frametime)
2175         {
2176                 // WEAPONTODO: Add a weapon request for this
2177                 // rot vortex charge to the charge limit
2178                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2179                 {
2180                         .entity weaponentity = weaponentities[slot];
2181                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2182                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2183                 }
2184
2185                 player_regen(this);
2186                 player_anim(this);
2187                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2188         }
2189
2190         monsters_setstatus(this);
2191
2192         return true;
2193 }
2194
2195 .bool would_spectate;
2196 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2197 void ObserverOrSpectatorThink(entity this)
2198 {
2199         bool is_spec = IS_SPEC(this);
2200         if ( CS(this).impulse )
2201         {
2202                 int r = MinigameImpulse(this, CS(this).impulse);
2203                 if (!is_spec || r)
2204                         CS(this).impulse = 0;
2205
2206                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2207                 {
2208                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2209                         CS(this).impulse = 0;
2210                         return;
2211                 }
2212         }
2213
2214         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2215         {
2216                 CS(this).autojoin_checked = true;
2217                 TRANSMUTE(Player, this);
2218                 PutClientInServer(this);
2219                 return;
2220         }
2221
2222         if (this.flags & FL_JUMPRELEASED) {
2223                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2224                         this.flags &= ~FL_JUMPRELEASED;
2225                         this.flags |= FL_SPAWNING;
2226                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2227                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2228                         this.flags &= ~FL_JUMPRELEASED;
2229                         if(SpectateNext(this)) {
2230                                 TRANSMUTE(Spectator, this);
2231                         } else if (is_spec) {
2232                                 TRANSMUTE(Observer, this);
2233                                 PutClientInServer(this);
2234                         }
2235                         else
2236                                 this.would_spectate = false; // unable to spectate anyone
2237                         if (is_spec)
2238                                 CS(this).impulse = 0;
2239                 } else if (is_spec) {
2240                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2241                                 this.flags &= ~FL_JUMPRELEASED;
2242                                 if(SpectatePrev(this)) {
2243                                         TRANSMUTE(Spectator, this);
2244                                 } else {
2245                                         TRANSMUTE(Observer, this);
2246                                         PutClientInServer(this);
2247                                 }
2248                                 CS(this).impulse = 0;
2249                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2250                                 this.would_spectate = false;
2251                                 this.flags &= ~FL_JUMPRELEASED;
2252                                 TRANSMUTE(Observer, this);
2253                                 PutClientInServer(this);
2254                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2255                                 PutObserverInServer(this, false, true);
2256                                 this.would_spectate = true;
2257                         }
2258                 }
2259                 else {
2260                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2261                         if (PHYS_INPUT_BUTTON_USE(this))
2262                                 wouldclip = !wouldclip;
2263                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2264                         set_movetype(this, preferred_movetype);
2265                 }
2266         } else { // jump pressed
2267                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2268                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2269                         this.flags |= FL_JUMPRELEASED;
2270                         if(this.flags & FL_SPAWNING)
2271                         {
2272                                 this.flags &= ~FL_SPAWNING;
2273                                 if(joinAllowed(this))
2274                                         Join(this);
2275                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2276                                         CS(this).autojoin_checked = -1;
2277                                 return;
2278                         }
2279                 }
2280                 if(is_spec && !SpectateUpdate(this))
2281                         PutObserverInServer(this, false, true);
2282         }
2283         if (is_spec)
2284                 this.flags |= FL_CLIENT | FL_NOTARGET;
2285 }
2286
2287 void PlayerUseKey(entity this)
2288 {
2289         if (!IS_PLAYER(this))
2290                 return;
2291
2292         if(this.vehicle)
2293         {
2294                 if(!game_stopped)
2295                 {
2296                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2297                         return;
2298                 }
2299         }
2300         else if(autocvar_g_vehicles_enter)
2301         {
2302                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2303                 {
2304                         entity head, closest_target = NULL;
2305                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2306
2307                         while(head) // find the closest acceptable target to enter
2308                         {
2309                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2310                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2311                                 {
2312                                         if(closest_target)
2313                                         {
2314                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2315                                                 { closest_target = head; }
2316                                         }
2317                                         else { closest_target = head; }
2318                                 }
2319
2320                                 head = head.chain;
2321                         }
2322
2323                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2324                 }
2325         }
2326
2327         // a use key was pressed; call handlers
2328         MUTATOR_CALLHOOK(PlayerUseKey, this);
2329 }
2330
2331
2332 /*
2333 =============
2334 PlayerPreThink
2335
2336 Called every frame for each client before the physics are run
2337 =============
2338 */
2339 .float last_vehiclecheck;
2340 void PlayerPreThink (entity this)
2341 {
2342         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2343         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2344
2345         WarpZone_PlayerPhysics_FixVAngle(this);
2346
2347         if (frametime) {
2348                 // physics frames: update anticheat stuff
2349                 anticheat_prethink(this);
2350
2351                 // WORKAROUND: only use dropclient in server frames (frametime set).
2352                 // Never use it in cl_movement frames (frametime zero).
2353                 if (blockSpectators && IS_REAL_CLIENT(this)
2354                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2355                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2356                 {
2357                         if (dropclient_schedule(this))
2358                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2359                 }
2360         }
2361
2362         zoomstate_set = false;
2363
2364         // Check for nameless players
2365         if (this.netname == "" || this.netname != CS(this).netname_previous)
2366         {
2367                 bool assume_unchanged = (CS(this).netname_previous == "");
2368                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2369                 {
2370                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2371                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2372                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2373                         assume_unchanged = false;
2374                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2375                 }
2376                 if (isInvisibleString(this.netname))
2377                 {
2378                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2379                         sprint(this, "Warning: invisible names are not allowed.\n");
2380                         assume_unchanged = false;
2381                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2382                 }
2383                 if (!assume_unchanged && autocvar_sv_eventlog)
2384                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2385                 strcpy(CS(this).netname_previous, this.netname);
2386         }
2387
2388         // version nagging
2389         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2390         CS(this).version_nagtime = 0;
2391         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2392             // git client
2393         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2394             // git server
2395             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2396         } else {
2397             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2398             if (r < 0) { // old client
2399                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2400             } else if (r > 0) { // old server
2401                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2402             }
2403         }
2404     }
2405
2406         // GOD MODE info
2407         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2408         {
2409                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2410                 this.max_armorvalue = 0;
2411         }
2412
2413         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2414         {
2415                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2416                 {
2417                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2418                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2419                         if (this.iceblock)
2420                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2421
2422                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2423                                 Unfreeze(this, false);
2424                 }
2425                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2426                 {
2427                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2428                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2429
2430                         if (GetResource(this, RES_HEALTH) < 1)
2431                         {
2432                                 if (this.vehicle)
2433                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2434                                 if(this.event_damage)
2435                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2436                         }
2437                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2438                                 Unfreeze(this, false);
2439                 }
2440         }
2441
2442         MUTATOR_CALLHOOK(PlayerPreThink, this);
2443
2444         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2445         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2446         {
2447                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2448                 {
2449                         if(!it.owner)
2450                         {
2451                                 if(!it.team || SAME_TEAM(this, it))
2452                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2453                                 else if(autocvar_g_vehicles_steal)
2454                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2455                         }
2456                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2457                         {
2458                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2459                         }
2460                 });
2461
2462                 this.last_vehiclecheck = time + 1;
2463         }
2464
2465         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2466                 PlayerUseKey(this);
2467         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2468
2469         if (IS_PLAYER(this)) {
2470                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2471                         error("Client can't be spawned as player on connection!");
2472                 if(!PlayerThink(this))
2473                         return;
2474         }
2475         else if (game_stopped || intermission_running) {
2476                 if(intermission_running)
2477                         IntermissionThink(this);
2478                 return;
2479         }
2480         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2481         {
2482                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2483                 CS(this).autojoin_checked = 1;
2484                 // don't do this in ClientConnect
2485                 // many things can go wrong if a client is spawned as player on connection
2486                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2487                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2488                                 && (!teamplay || autocvar_g_balance_teams)))
2489                 {
2490                         if(joinAllowed(this))
2491                                 Join(this);
2492                         return;
2493                 }
2494         }
2495         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2496                 ObserverOrSpectatorThink(this);
2497         }
2498
2499         // WEAPONTODO: Add weapon request for this
2500         if (!zoomstate_set) {
2501                 bool wep_zoomed = false;
2502                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2503                 {
2504                         .entity weaponentity = weaponentities[slot];
2505                         Weapon thiswep = this.(weaponentity).m_weapon;
2506                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2507                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2508                 }
2509                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2510         }
2511
2512         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2513         {
2514                 CS(this).teamkill_soundtime = 0;
2515
2516                 entity e = CS(this).teamkill_soundsource;
2517                 entity oldpusher = e.pusher;
2518                 e.pusher = this;
2519                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2520                 e.pusher = oldpusher;
2521         }
2522
2523         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2524                 CS(this).taunt_soundtime = 0;
2525                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2526         }
2527
2528         target_voicescript_next(this);
2529 }
2530
2531 void DrownPlayer(entity this)
2532 {
2533         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2534                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2535         {
2536                 STAT(AIR_FINISHED, this) = 0;
2537                 return;
2538         }
2539
2540         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2541         {
2542                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2543                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2544                 STAT(AIR_FINISHED, this) = 0;
2545         }
2546         else
2547         {
2548                 if (!STAT(AIR_FINISHED, this))
2549                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2550                 if (STAT(AIR_FINISHED, this) < time)
2551                 {       // drown!
2552                         if (this.pain_finished < time)
2553                         {
2554                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2555                                 this.pain_finished = time + 0.5;
2556                         }
2557                 }
2558         }
2559 }
2560
2561 .bool move_qcphysics;
2562
2563 void Player_Physics(entity this)
2564 {
2565         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2566
2567         if(!this.move_qcphysics)
2568                 return;
2569
2570         if(!frametime && !CS(this).pm_frametime)
2571                 return;
2572
2573         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2574
2575         CS(this).pm_frametime = 0;
2576 }
2577
2578 /*
2579 =============
2580 PlayerPostThink
2581
2582 Called every frame for each client after the physics are run
2583 =============
2584 */
2585 void PlayerPostThink (entity this)
2586 {
2587         Player_Physics(this);
2588
2589         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2590         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2591         if (IS_REAL_CLIENT(this))
2592         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2593         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2594         {
2595                 int totalClients = 0;
2596                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2597                 {
2598                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2599                         if (server_is_dedicated)
2600                         {
2601                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2602                                 {
2603                                         ++totalClients;
2604                                 });
2605                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2606                                         totalClients = 0;
2607                         }
2608                 }
2609                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2610                 {
2611                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2612                         {
2613                                 ++totalClients;
2614                         });
2615                 }
2616
2617                 if (totalClients < autocvar_sv_maxidle_minplayers)
2618                 {
2619                         // idle kick disabled
2620                         CS(this).parm_idlesince = time;
2621                 }
2622                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2623                 {
2624                         if (CS(this).idlekick_lasttimeleft)
2625                         {
2626                                 CS(this).idlekick_lasttimeleft = 0;
2627                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2628                         }
2629                 }
2630                 else
2631                 {
2632                         float maxidle_time = autocvar_sv_maxidle;
2633                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2634                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2635                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2636                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2637                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2638                         {
2639                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2640                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2641                                 else
2642                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2643                         }
2644                         if (timeleft <= 0) {
2645                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2646                                 {
2647                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2648                                         PutObserverInServer(this, true, true);
2649                                 }
2650                                 else
2651                                 {
2652                                         if (dropclient_schedule(this))
2653                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2654                                 }
2655                                 return;
2656                         }
2657                         else if (timeleft <= countdown_time) {
2658                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2659                                         play2(this, SND(TALK2));
2660                                 CS(this).idlekick_lasttimeleft = timeleft;
2661                         }
2662                 }
2663         }
2664
2665         CheatFrame(this);
2666
2667         if (game_stopped)
2668         {
2669                 this.solid = SOLID_NOT;
2670                 this.takedamage = DAMAGE_NO;
2671                 set_movetype(this, MOVETYPE_NONE);
2672                 CS(this).teamkill_complain = 0;
2673                 CS(this).teamkill_soundtime = 0;
2674                 CS(this).teamkill_soundsource = NULL;
2675         }
2676
2677         if (IS_PLAYER(this)) {
2678                 if(this.death_time == time && IS_DEAD(this))
2679                 {
2680                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2681                         // once all the damage events of this frame have been processed with normal size
2682                         this.maxs.z = 5;
2683                         setsize(this, this.mins, this.maxs);
2684                 }
2685                 DrownPlayer(this);
2686                 UpdateChatBubble(this);
2687                 if (CS(this).impulse) ImpulseCommands(this);
2688                 GetPressedKeys(this);
2689                 if (game_stopped)
2690                 {
2691                         CSQCMODEL_AUTOUPDATE(this);
2692                         return;
2693                 }
2694         }
2695         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2696         {
2697                 CS(this).pressedkeys = 0;
2698                 STAT(PRESSED_KEYS, this) = 0;
2699         }
2700
2701         if (this.waypointsprite_attachedforcarrier) {
2702                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2703                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2704         }
2705
2706         CSQCMODEL_AUTOUPDATE(this);
2707 }
2708
2709 // hack to copy the button fields from the client entity to the Client State
2710 void PM_UpdateButtons(entity this, entity store)
2711 {
2712         if(this.impulse)
2713                 store.impulse = this.impulse;
2714         this.impulse = 0;
2715
2716         bool typing = this.buttonchat || this.button12;
2717
2718         store.button0 = (typing) ? 0 : this.button0;
2719         //button1?!
2720         store.button2 = (typing) ? 0 : this.button2;
2721         store.button3 = (typing) ? 0 : this.button3;
2722         store.button4 = this.button4;
2723         store.button5 = (typing) ? 0 : this.button5;
2724         store.button6 = this.button6;
2725         store.button7 = this.button7;
2726         store.button8 = this.button8;
2727         store.button9 = this.button9;
2728         store.button10 = this.button10;
2729         store.button11 = this.button11;
2730         store.button12 = this.button12;
2731         store.button13 = this.button13;
2732         store.button14 = this.button14;
2733         store.button15 = this.button15;
2734         store.button16 = this.button16;
2735         store.buttonuse = this.buttonuse;
2736         store.buttonchat = this.buttonchat;
2737
2738         store.cursor_active = this.cursor_active;
2739         store.cursor_screen = this.cursor_screen;
2740         store.cursor_trace_start = this.cursor_trace_start;
2741         store.cursor_trace_endpos = this.cursor_trace_endpos;
2742         store.cursor_trace_ent = this.cursor_trace_ent;
2743
2744         store.ping = this.ping;
2745         store.ping_packetloss = this.ping_packetloss;
2746         store.ping_movementloss = this.ping_movementloss;
2747
2748         store.v_angle = this.v_angle;
2749         store.movement = this.movement;
2750 }
2751
2752 NET_HANDLE(fpsreport, bool)
2753 {
2754         int fps = ReadShort();
2755         PlayerScore_Set(sender, SP_FPS, fps);
2756         return true;
2757 }