Transifex autosync
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <server/defs.qh>
4 #include <server/miscfunctions.qh>
5 #include <common/effects/all.qh>
6 #include "anticheat.qh"
7 #include "impulse.qh"
8 #include "player.qh"
9 #include "ipban.qh"
10 #include "miscfunctions.qh"
11 #include "portals.qh"
12 #include "teamplay.qh"
13 #include "spawnpoints.qh"
14 #include "resources.qh"
15 #include "g_damage.qh"
16 #include "handicap.qh"
17 #include "g_hook.qh"
18 #include "command/common.qh"
19 #include "command/vote.qh"
20 #include "cheats.qh"
21 #include "g_world.qh"
22 #include "race.qh"
23 #include "antilag.qh"
24 #include "campaign.qh"
25 #include "command/common.qh"
26 #include "scores_rules.qh"
27
28 #include "bot/api.qh"
29
30 #include "../common/ent_cs.qh"
31 #include "../common/wepent.qh"
32 #include <common/state.qh>
33
34 #include <common/effects/qc/globalsound.qh>
35
36 #include "../common/mapobjects/func/conveyor.qh"
37 #include "../common/mapobjects/teleporters.qh"
38 #include "../common/mapobjects/target/spawnpoint.qh"
39
40 #include "../common/vehicles/all.qh"
41
42 #include "weapons/hitplot.qh"
43 #include "weapons/weaponsystem.qh"
44
45 #include "../common/net_notice.qh"
46 #include "../common/net_linked.qh"
47 #include "../common/physics/player.qh"
48
49 #include <common/vehicles/sv_vehicles.qh>
50
51 #include "../common/items/_mod.qh"
52
53 #include "../common/mutators/mutator/waypoints/all.qh"
54 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
55 #include <common/gamemodes/_mod.qh>
56
57 #include "../common/mapobjects/subs.qh"
58 #include "../common/mapobjects/triggers.qh"
59 #include "../common/mapobjects/trigger/secret.qh"
60
61 #include "../common/minigames/sv_minigames.qh"
62
63 #include "../common/items/inventory.qh"
64
65 #include "../common/monsters/sv_monsters.qh"
66
67 #include "../lib/warpzone/server.qh"
68
69 #include <common/mutators/mutator/overkill/oknex.qh>
70
71 STATIC_METHOD(Client, Add, void(Client this, int _team))
72 {
73     ClientConnect(this);
74     TRANSMUTE(Player, this);
75     this.frame = 12; // 7
76     this.team = _team;
77     PutClientInServer(this);
78 }
79
80 STATIC_METHOD(Client, Remove, void(Client this))
81 {
82     TRANSMUTE(Observer, this);
83     PutClientInServer(this);
84     ClientDisconnect(this);
85 }
86
87 void send_CSQC_teamnagger() {
88         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
89 }
90
91 int CountSpectators(entity player, entity to)
92 {
93         if(!player) { return 0; } // not sure how, but best to be safe
94
95         int spec_count = 0;
96
97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
98         {
99                 spec_count++;
100         });
101
102         return spec_count;
103 }
104
105 void WriteSpectators(entity player, entity to)
106 {
107         if(!player) { return; } // not sure how, but best to be safe
108
109         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
110         {
111                 WriteByte(MSG_ENTITY, num_for_edict(it));
112         });
113 }
114
115 bool ClientData_Send(entity this, entity to, int sf)
116 {
117         assert(to == this.owner, return false);
118
119         entity e = to;
120         if (IS_SPEC(e)) e = e.enemy;
121
122         sf = 0;
123         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
124         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
125         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
126         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
127
128         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
129         WriteByte(MSG_ENTITY, sf);
130
131         if (sf & BIT(1))
132                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
133
134         if(sf & BIT(4))
135         {
136                 float specs = CountSpectators(e, to);
137                 WriteByte(MSG_ENTITY, specs);
138                 WriteSpectators(e, to);
139         }
140
141         return true;
142 }
143
144 void ClientData_Attach(entity this)
145 {
146         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
147         CS(this).clientdata.drawonlytoclient = this;
148         CS(this).clientdata.owner = this;
149 }
150
151 void ClientData_Detach(entity this)
152 {
153         delete(CS(this).clientdata);
154         CS(this).clientdata = NULL;
155 }
156
157 void ClientData_Touch(entity e)
158 {
159         entity cd = CS(e).clientdata;
160         if (cd) { cd.SendFlags = 1; }
161
162         // make it spectatable
163         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
164         {
165                 entity cd = CS(it).clientdata;
166                 if (cd) { cd.SendFlags = 1; }
167         });
168 }
169
170
171 /*
172 =============
173 CheckPlayerModel
174
175 Checks if the argument string can be a valid playermodel.
176 Returns a valid one in doubt.
177 =============
178 */
179 string FallbackPlayerModel;
180 string CheckPlayerModel(string plyermodel) {
181         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
182         {
183                 // note: we cannot summon Don Strunzone here, some player may
184                 // still have the model string set. In case anyone manages how
185                 // to change a cvar default, we'll have a small leak here.
186                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
187         }
188         // only in right path
189         if( substring(plyermodel,0,14) != "models/player/")
190                 return FallbackPlayerModel;
191         // only good file extensions
192         if(substring(plyermodel,-4,4) != ".zym")
193         if(substring(plyermodel,-4,4) != ".dpm")
194         if(substring(plyermodel,-4,4) != ".iqm")
195         if(substring(plyermodel,-4,4) != ".md3")
196         if(substring(plyermodel,-4,4) != ".psk")
197                 return FallbackPlayerModel;
198         // forbid the LOD models
199         if(substring(plyermodel, -9,5) == "_lod1")
200                 return FallbackPlayerModel;
201         if(substring(plyermodel, -9,5) == "_lod2")
202                 return FallbackPlayerModel;
203         if(plyermodel != strtolower(plyermodel))
204                 return FallbackPlayerModel;
205         // also, restrict to server models
206         if(autocvar_sv_servermodelsonly)
207         {
208                 if(!fexists(plyermodel))
209                         return FallbackPlayerModel;
210         }
211         return plyermodel;
212 }
213
214 void setplayermodel(entity e, string modelname)
215 {
216         precache_model(modelname);
217         _setmodel(e, modelname);
218         player_setupanimsformodel(e);
219         if(!autocvar_g_debug_globalsounds)
220                 UpdatePlayerSounds(e);
221 }
222
223 /** putting a client as observer in the server */
224 void PutObserverInServer(entity this)
225 {
226     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
227         PlayerState_detach(this);
228
229         if (IS_PLAYER(this))
230         {
231                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
232                 {
233                         // despawn effect
234                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
235                 }
236
237                 // was a player, recount votes and ready status
238                 if(IS_REAL_CLIENT(this))
239                 {
240                         if (vote_called) { VoteCount(false); }
241                         ReadyCount();
242                 }
243     }
244
245     {
246         entity spot = SelectSpawnPoint(this, true);
247         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
248         this.angles = vec2(spot.angles);
249         this.fixangle = true;
250         // offset it so that the spectator spawns higher off the ground, looks better this way
251         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
252         if (IS_REAL_CLIENT(this))
253         {
254             msg_entity = this;
255             WriteByte(MSG_ONE, SVC_SETVIEW);
256             WriteEntity(MSG_ONE, this);
257         }
258         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
259         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
260         if(!autocvar_g_debug_globalsounds)
261         {
262                 // needed for player sounds
263                 this.model = "";
264                 FixPlayermodel(this);
265         }
266         setmodel(this, MDL_Null);
267         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
268         this.view_ofs = '0 0 0';
269     }
270
271     RemoveGrapplingHooks(this);
272         Portal_ClearAll(this);
273         Unfreeze(this);
274         SetSpectatee(this, NULL);
275
276         if (this.alivetime)
277         {
278                 if (!warmup_stage)
279                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
280                 this.alivetime = 0;
281         }
282
283         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
284
285         WaypointSprite_PlayerDead(this);
286
287         if (mutator_returnvalue) {
288             // mutator prevents resetting teams+score
289         } else {
290                 int oldteam = this.team;
291                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
292                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
293         this.frags = FRAGS_SPECTATOR;
294         PlayerScore_Clear(this);  // clear scores when needed
295     }
296
297         if (CS(this).killcount != FRAGS_SPECTATOR)
298         {
299                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
300                 if(!game_stopped)
301                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
302                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
303
304                 if(!CS(this).just_joined)
305                         LogTeamchange(this.playerid, -1, 4);
306                 else
307                         CS(this).just_joined = false;
308         }
309
310         accuracy_resend(this);
311
312         CS(this).spectatortime = time;
313         if(this.bot_attack)
314                 IL_REMOVE(g_bot_targets, this);
315         this.bot_attack = false;
316         if(this.monster_attack)
317                 IL_REMOVE(g_monster_targets, this);
318         this.monster_attack = false;
319     STAT(HUD, this) = HUD_NORMAL;
320         TRANSMUTE(Observer, this);
321         this.iscreature = false;
322         this.teleportable = TELEPORT_SIMPLE;
323         if(this.damagedbycontents)
324                 IL_REMOVE(g_damagedbycontents, this);
325         this.damagedbycontents = false;
326         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
327         SetSpectatee_status(this, etof(this));
328         this.takedamage = DAMAGE_NO;
329         this.solid = SOLID_NOT;
330         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
331         this.flags = FL_CLIENT | FL_NOTARGET;
332         this.effects = 0;
333         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
334         this.pauserotarmor_finished = 0;
335         this.pauserothealth_finished = 0;
336         this.pauseregen_finished = 0;
337         this.damageforcescale = 0;
338         this.death_time = 0;
339         this.respawn_flags = 0;
340         this.respawn_time = 0;
341         STAT(RESPAWN_TIME, this) = 0;
342         this.alpha = 0;
343         this.scale = 0;
344         this.fade_time = 0;
345         this.pain_frame = 0;
346         this.pain_finished = 0;
347         this.strength_finished = 0;
348         this.invincible_finished = 0;
349         this.superweapons_finished = 0;
350         this.dphitcontentsmask = 0;
351         this.pushltime = 0;
352         this.istypefrag = 0;
353         setthink(this, func_null);
354         this.nextthink = 0;
355         this.deadflag = DEAD_NO;
356         this.crouch = false;
357         STAT(REVIVE_PROGRESS, this) = 0;
358         this.revival_time = 0;
359
360         this.items = 0;
361         STAT(WEAPONS, this) = '0 0 0';
362         this.drawonlytoclient = this;
363
364         this.viewloc = NULL;
365
366         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
367
368         this.weaponmodel = "";
369         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
370         {
371                 this.weaponentities[slot] = NULL;
372         }
373         this.exteriorweaponentity = NULL;
374         CS(this).killcount = FRAGS_SPECTATOR;
375         this.velocity = '0 0 0';
376         this.avelocity = '0 0 0';
377         this.punchangle = '0 0 0';
378         this.punchvector = '0 0 0';
379         this.oldvelocity = this.velocity;
380         this.fire_endtime = -1;
381         this.event_damage = func_null;
382         this.event_heal = func_null;
383
384         for(int slot = 0; slot < MAX_AXH; ++slot)
385         {
386                 entity axh = this.(AuxiliaryXhair[slot]);
387                 this.(AuxiliaryXhair[slot]) = NULL;
388
389                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
390                         delete(axh);
391         }
392 }
393
394 int player_getspecies(entity this)
395 {
396         get_model_parameters(this.model, this.skin);
397         int s = get_model_parameters_species;
398         get_model_parameters(string_null, 0);
399         if (s < 0) return SPECIES_HUMAN;
400         return s;
401 }
402
403 .float model_randomizer;
404 void FixPlayermodel(entity player)
405 {
406         string defaultmodel = "";
407         int defaultskin = 0;
408         if(autocvar_sv_defaultcharacter)
409         {
410                 if(teamplay)
411                 {
412                         switch(player.team)
413                         {
414                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
415                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
416                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
417                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
418                         }
419                 }
420
421                 if(defaultmodel == "")
422                 {
423                         defaultmodel = autocvar_sv_defaultplayermodel;
424                         defaultskin = autocvar_sv_defaultplayerskin;
425                 }
426
427                 int n = tokenize_console(defaultmodel);
428                 if(n > 0)
429                 {
430                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
431                         // However, do NOT randomize if the player-selected model is in the list.
432                         for (int i = 0; i < n; ++i)
433                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
434                                         defaultmodel = argv(i);
435                 }
436
437                 int i = strstrofs(defaultmodel, ":", 0);
438                 if(i >= 0)
439                 {
440                         defaultskin = stof(substring(defaultmodel, i+1, -1));
441                         defaultmodel = substring(defaultmodel, 0, i);
442                 }
443         }
444         if(autocvar_sv_defaultcharacterskin && !defaultskin)
445         {
446                 if(teamplay)
447                 {
448                         switch(player.team)
449                         {
450                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
451                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
452                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
453                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
454                         }
455                 }
456
457                 if(!defaultskin)
458                         defaultskin = autocvar_sv_defaultplayerskin;
459         }
460
461         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
462         defaultmodel = M_ARGV(0, string);
463         defaultskin = M_ARGV(1, int);
464
465         bool chmdl = false;
466         int oldskin;
467         if(defaultmodel != "")
468         {
469                 if (defaultmodel != player.model)
470                 {
471                         vector m1 = player.mins;
472                         vector m2 = player.maxs;
473                         setplayermodel (player, defaultmodel);
474                         setsize (player, m1, m2);
475                         chmdl = true;
476                 }
477
478                 oldskin = player.skin;
479                 player.skin = defaultskin;
480         } else {
481                 if (player.playermodel != player.model || player.playermodel == "")
482                 {
483                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
484                         vector m1 = player.mins;
485                         vector m2 = player.maxs;
486                         setplayermodel (player, player.playermodel);
487                         setsize (player, m1, m2);
488                         chmdl = true;
489                 }
490
491                 if(!autocvar_sv_defaultcharacterskin)
492                 {
493                         oldskin = player.skin;
494                         player.skin = stof(player.playerskin);
495                 }
496                 else
497                 {
498                         oldskin = player.skin;
499                         player.skin = defaultskin;
500                 }
501         }
502
503         if(chmdl || oldskin != player.skin) // model or skin has changed
504         {
505                 player.species = player_getspecies(player); // update species
506                 if(!autocvar_g_debug_globalsounds)
507                         UpdatePlayerSounds(player); // update skin sounds
508         }
509
510         if(!teamplay)
511                 if(strlen(autocvar_sv_defaultplayercolors))
512                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
513                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
514 }
515
516 void PutPlayerInServer(entity this)
517 {
518         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
519
520         PlayerState_attach(this);
521         accuracy_resend(this);
522
523         if (this.team < 0)
524                 JoinBestTeam(this, true);
525
526         entity spot = SelectSpawnPoint(this, false);
527         if (!spot) {
528                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
529                 return; // spawn failed
530         }
531
532         TRANSMUTE(Player, this);
533
534         CS(this).wasplayer = true;
535         this.iscreature = true;
536         this.teleportable = TELEPORT_NORMAL;
537         if(!this.damagedbycontents)
538                 IL_PUSH(g_damagedbycontents, this);
539         this.damagedbycontents = true;
540         set_movetype(this, MOVETYPE_WALK);
541         this.solid = SOLID_SLIDEBOX;
542         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
543         if (autocvar_g_playerclip_collisions)
544                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
545         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
546                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
547         this.frags = FRAGS_PLAYER;
548         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
549         this.flags = FL_CLIENT | FL_PICKUPITEMS;
550         if (autocvar__notarget)
551                 this.flags |= FL_NOTARGET;
552         this.takedamage = DAMAGE_AIM;
553         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
554
555         if (warmup_stage) {
556                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
557                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
558                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
559                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
560                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
561                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
562                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
563                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
564                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
565         } else {
566                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
567                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
568                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
569                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
570                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
571                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
572                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
573                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
574                 STAT(WEAPONS, this) = start_weapons;
575                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
576                 {
577                         GiveRandomWeapons(this, random_start_weapons_count,
578                                 autocvar_g_random_start_weapons, random_start_ammo);
579                 }
580         }
581         SetSpectatee_status(this, 0);
582
583         PS(this).dual_weapons = '0 0 0';
584
585         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
586
587         this.items = start_items;
588
589         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
590         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
591         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
592         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
593         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
594         if (!sv_ready_restart_after_countdown && time < game_starttime)
595         {
596                 float f = game_starttime - time;
597                 this.spawnshieldtime += f;
598                 this.pauserotarmor_finished += f;
599                 this.pauserothealth_finished += f;
600                 this.pauseregen_finished += f;
601         }
602
603         this.damageforcescale = 2;
604         this.death_time = 0;
605         this.respawn_flags = 0;
606         this.respawn_time = 0;
607         STAT(RESPAWN_TIME, this) = 0;
608         this.scale = autocvar_sv_player_scale;
609         this.fade_time = 0;
610         this.pain_frame = 0;
611         this.pain_finished = 0;
612         this.pushltime = 0;
613         setthink(this, func_null); // players have no think function
614         this.nextthink = 0;
615         this.dmg_team = 0;
616         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
617
618         this.deadflag = DEAD_NO;
619
620         this.angles = spot.angles;
621         this.angles_z = 0; // never spawn tilted even if the spot says to
622         if (IS_BOT_CLIENT(this))
623                 this.v_angle = this.angles;
624         this.fixangle = true; // turn this way immediately
625         this.oldvelocity = this.velocity = '0 0 0';
626         this.avelocity = '0 0 0';
627         this.punchangle = '0 0 0';
628         this.punchvector = '0 0 0';
629
630         this.strength_finished = 0;
631         this.invincible_finished = 0;
632         this.fire_endtime = -1;
633         STAT(REVIVE_PROGRESS, this) = 0;
634         this.revival_time = 0;
635
636         this.air_finished = time + 12;
637         this.waterlevel = WATERLEVEL_NONE;
638         this.watertype = CONTENT_EMPTY;
639
640         entity spawnevent = new_pure(spawnevent);
641         spawnevent.owner = this;
642         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
643
644         // Cut off any still running player sounds.
645         stopsound(this, CH_PLAYER_SINGLE);
646
647         this.model = "";
648         FixPlayermodel(this);
649         this.drawonlytoclient = NULL;
650
651         this.viewloc = NULL;
652
653         for(int slot = 0; slot < MAX_AXH; ++slot)
654         {
655                 entity axh = this.(AuxiliaryXhair[slot]);
656                 this.(AuxiliaryXhair[slot]) = NULL;
657
658                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
659                         delete(axh);
660         }
661
662         this.spawnpoint_targ = NULL;
663
664         this.crouch = false;
665         this.view_ofs = STAT(PL_VIEW_OFS, this);
666         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
667         this.spawnorigin = spot.origin;
668         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
669         // don't reset back to last position, even if new position is stuck in solid
670         this.oldorigin = this.origin;
671         if(this.conveyor)
672                 IL_REMOVE(g_conveyed, this);
673         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
674         STAT(HUD, this) = HUD_NORMAL;
675
676         this.event_damage = PlayerDamage;
677         this.event_heal = PlayerHeal;
678
679         if(!this.bot_attack)
680                 IL_PUSH(g_bot_targets, this);
681         this.bot_attack = true;
682         if(!this.monster_attack)
683                 IL_PUSH(g_monster_targets, this);
684         this.monster_attack = true;
685         navigation_dynamicgoal_init(this, false);
686
687         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
688
689         // player was spectator
690         if (CS(this).killcount == FRAGS_SPECTATOR) {
691                 PlayerScore_Clear(this);
692                 CS(this).killcount = 0;
693                 CS(this).startplaytime = time;
694         }
695
696         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
697         {
698                 .entity weaponentity = weaponentities[slot];
699                 entity oldwep = this.(weaponentity);
700                 CL_SpawnWeaponentity(this, weaponentity);
701                 if(oldwep && oldwep.owner == this)
702                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
703         }
704         this.alpha = default_player_alpha;
705         this.colormod = '1 1 1' * autocvar_g_player_brightness;
706         this.exteriorweaponentity.alpha = default_weapon_alpha;
707
708         this.speedrunning = false;
709
710         target_voicescript_clear(this);
711
712         // reset fields the weapons may use
713         FOREACH(Weapons, true, {
714                 it.wr_resetplayer(it, this);
715                         // reload all reloadable weapons
716                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
717                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
718                         {
719                                 .entity weaponentity = weaponentities[slot];
720                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
721                         }
722                 }
723         });
724
725         {
726                 string s = spot.target;
727                 spot.target = string_null;
728                 SUB_UseTargets(spot, this, NULL);
729                 spot.target = s;
730         }
731
732         Unfreeze(this);
733
734         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
735
736         if (autocvar_spawn_debug)
737         {
738                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
739                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
740         }
741
742         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
743         {
744                 .entity weaponentity = weaponentities[slot];
745                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
746                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
747                 else
748                         this.(weaponentity).m_switchweapon = WEP_Null;
749                 this.(weaponentity).m_weapon = WEP_Null;
750                 this.(weaponentity).weaponname = "";
751                 this.(weaponentity).m_switchingweapon = WEP_Null;
752                 this.(weaponentity).cnt = -1;
753         }
754
755         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
756
757         if (CS(this).impulse) ImpulseCommands(this);
758
759         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
760         {
761                 .entity weaponentity = weaponentities[slot];
762                 W_WeaponFrame(this, weaponentity);
763         }
764
765         if (!warmup_stage && !this.alivetime)
766                 this.alivetime = time;
767
768         antilag_clear(this, CS(this));
769 }
770
771 /** Called when a client spawns in the server */
772 void PutClientInServer(entity this)
773 {
774         if (IS_BOT_CLIENT(this)) {
775                 TRANSMUTE(Player, this);
776         } else if (IS_REAL_CLIENT(this)) {
777                 msg_entity = this;
778                 WriteByte(MSG_ONE, SVC_SETVIEW);
779                 WriteEntity(MSG_ONE, this);
780         }
781         if (game_stopped)
782                 TRANSMUTE(Observer, this);
783
784         SetSpectatee(this, NULL);
785
786         // reset player keys
787         if(PS(this))
788                 PS(this).itemkeys = 0;
789
790         MUTATOR_CALLHOOK(PutClientInServer, this);
791
792         if (IS_OBSERVER(this)) {
793                 PutObserverInServer(this);
794         } else if (IS_PLAYER(this)) {
795                 PutPlayerInServer(this);
796         }
797 }
798
799 // TODO do we need all these fields, or should we stop autodetecting runtime
800 // changes and just have a console command to update this?
801 bool ClientInit_SendEntity(entity this, entity to, int sf)
802 {
803         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
804         return = true;
805         msg_entity = to;
806         // MSG_INIT replacement
807         // TODO: make easier to use
808         Registry_send_all();
809         W_PROP_reload(MSG_ONE, to);
810         ClientInit_misc(this);
811         MUTATOR_CALLHOOK(Ent_Init);
812 }
813 void ClientInit_misc(entity this)
814 {
815         int channel = MSG_ONE;
816         WriteHeader(channel, ENT_CLIENT_INIT);
817         WriteByte(channel, g_nexball_meter_period * 32);
818         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
819         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
820         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
821         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
822         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
823         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
824         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
825         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
826
827         if(sv_foginterval && world.fog != "")
828                 WriteString(channel, world.fog);
829         else
830                 WriteString(channel, "");
831         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
832         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
833         WriteByte(channel, serverflags);
834         WriteCoord(channel, autocvar_g_trueaim_minrange);
835 }
836
837 void ClientInit_CheckUpdate(entity this)
838 {
839         this.nextthink = time;
840         if(this.count != autocvar_g_balance_armor_blockpercent)
841         {
842                 this.count = autocvar_g_balance_armor_blockpercent;
843                 this.SendFlags |= 1;
844         }
845         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
846         {
847                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
848                 this.SendFlags |= 1;
849         }
850 }
851
852 void ClientInit_Spawn()
853 {
854         entity e = new_pure(clientinit);
855         setthink(e, ClientInit_CheckUpdate);
856         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
857
858         ClientInit_CheckUpdate(e);
859 }
860
861 /*
862 =============
863 SetNewParms
864 =============
865 */
866 void SetNewParms ()
867 {
868         // initialize parms for a new player
869         parm1 = -(86400 * 366);
870
871         MUTATOR_CALLHOOK(SetNewParms);
872 }
873
874 /*
875 =============
876 SetChangeParms
877 =============
878 */
879 void SetChangeParms (entity this)
880 {
881         // save parms for level change
882         parm1 = CS(this).parm_idlesince - time;
883
884         MUTATOR_CALLHOOK(SetChangeParms);
885 }
886
887 /*
888 =============
889 DecodeLevelParms
890 =============
891 */
892 void DecodeLevelParms(entity this)
893 {
894         // load parms
895         CS(this).parm_idlesince = parm1;
896         if (CS(this).parm_idlesince == -(86400 * 366))
897                 CS(this).parm_idlesince = time;
898
899         // whatever happens, allow 60 seconds of idling directly after connect for map loading
900         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
901
902         MUTATOR_CALLHOOK(DecodeLevelParms);
903 }
904
905 /*
906 =============
907 ClientKill
908
909 Called when a client types 'kill' in the console
910 =============
911 */
912
913 .float clientkill_nexttime;
914 void ClientKill_Now_TeamChange(entity this)
915 {
916         if(this.killindicator_teamchange == -1)
917         {
918                 JoinBestTeam( this, true );
919         }
920         else if(this.killindicator_teamchange == -2)
921         {
922                 if(blockSpectators)
923                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
924                 PutObserverInServer(this);
925         }
926         else
927                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
928         this.killindicator_teamchange = 0;
929 }
930
931 void ClientKill_Now(entity this)
932 {
933         if(this.vehicle)
934         {
935             vehicles_exit(this.vehicle, VHEF_RELEASE);
936             if(!this.killindicator_teamchange)
937             {
938             this.vehicle_health = -1;
939             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
940             }
941         }
942
943         if(this.killindicator && !wasfreed(this.killindicator))
944                 delete(this.killindicator);
945
946         this.killindicator = NULL;
947
948         if(this.killindicator_teamchange)
949                 ClientKill_Now_TeamChange(this);
950
951         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
952         {
953                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
954         }
955
956         // now I am sure the player IS dead
957 }
958 void KillIndicator_Think(entity this)
959 {
960         if (game_stopped)
961         {
962                 this.owner.killindicator = NULL;
963                 delete(this);
964                 return;
965         }
966
967         if (this.owner.alpha < 0 && !this.owner.vehicle)
968         {
969                 this.owner.killindicator = NULL;
970                 delete(this);
971                 return;
972         }
973
974         if(this.cnt <= 0)
975         {
976                 ClientKill_Now(this.owner);
977                 return;
978         }
979     else if(this.count == 1) // count == 1 means that it's silent
980     {
981         this.nextthink = time + 1;
982         this.cnt -= 1;
983     }
984         else
985         {
986                 if(this.cnt <= 10)
987                         setmodel(this, MDL_NUM(this.cnt));
988                 if(IS_REAL_CLIENT(this.owner))
989                 {
990                         if(this.cnt <= 10)
991                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
992                 }
993                 this.nextthink = time + 1;
994                 this.cnt -= 1;
995         }
996 }
997
998 float clientkilltime;
999 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
1000 {
1001         float killtime;
1002         float starttime;
1003
1004         if (game_stopped)
1005                 return;
1006
1007         killtime = autocvar_g_balance_kill_delay;
1008
1009     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1010         return;
1011     killtime = M_ARGV(1, float);
1012
1013         this.killindicator_teamchange = targetteam;
1014
1015     if(!this.killindicator)
1016         {
1017                 if(!IS_DEAD(this))
1018                 {
1019                         killtime = max(killtime, this.clientkill_nexttime - time);
1020                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1021                 }
1022
1023                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1024                 {
1025                         ClientKill_Now(this);
1026                 }
1027                 else
1028                 {
1029                         starttime = max(time, clientkilltime);
1030
1031                         this.killindicator = spawn();
1032                         this.killindicator.owner = this;
1033                         this.killindicator.scale = 0.5;
1034                         setattachment(this.killindicator, this, "");
1035                         setorigin(this.killindicator, '0 0 52');
1036                         setthink(this.killindicator, KillIndicator_Think);
1037                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1038                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1039                         this.killindicator.cnt = ceil(killtime);
1040                         this.killindicator.count = bound(0, ceil(killtime), 10);
1041                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1042
1043                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1044                         {
1045                                 it.killindicator = spawn();
1046                                 it.killindicator.owner = it;
1047                                 it.killindicator.scale = 0.5;
1048                                 setattachment(it.killindicator, it, "");
1049                                 setorigin(it.killindicator, '0 0 52');
1050                                 setthink(it.killindicator, KillIndicator_Think);
1051                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1052                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1053                                 it.killindicator.cnt = ceil(killtime);
1054                         });
1055                         this.lip = 0;
1056                 }
1057         }
1058         if(this.killindicator)
1059         {
1060                 if(targetteam == 0) // just die
1061                 {
1062                         this.killindicator.colormod = '0 0 0';
1063                         if(IS_REAL_CLIENT(this))
1064                         if(this.killindicator.cnt > 0)
1065                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1066                 }
1067                 else if(targetteam == -1) // auto
1068                 {
1069                         this.killindicator.colormod = '0 1 0';
1070                         if(IS_REAL_CLIENT(this))
1071                         if(this.killindicator.cnt > 0)
1072                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1073                 }
1074                 else if(targetteam == -2) // spectate
1075                 {
1076                         this.killindicator.colormod = '0.5 0.5 0.5';
1077                         if(IS_REAL_CLIENT(this))
1078                         if(this.killindicator.cnt > 0)
1079                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1080                 }
1081                 else
1082                 {
1083                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1084                         if(IS_REAL_CLIENT(this))
1085                         if(this.killindicator.cnt > 0)
1086                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1087                 }
1088         }
1089
1090 }
1091
1092 void ClientKill (entity this)
1093 {
1094         // TODO: once .health is removed, will need to check it here for the "already dead" message!
1095
1096         if(game_stopped) return;
1097         if(this.player_blocked) return;
1098         if(STAT(FROZEN, this)) return;
1099
1100         ClientKill_TeamChange(this, 0);
1101 }
1102
1103 void FixClientCvars(entity e)
1104 {
1105         // send prediction settings to the client
1106         stuffcmd(e, "\nin_bindmap 0 0\n");
1107         if(autocvar_g_antilag == 3) // client side hitscan
1108                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1109         if(autocvar_sv_gentle)
1110                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1111
1112         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1113         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1114
1115         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1116
1117         MUTATOR_CALLHOOK(FixClientCvars, e);
1118 }
1119
1120 bool findinlist_abbrev(string tofind, string list)
1121 {
1122         if(list == "" || tofind == "")
1123                 return false; // empty list or search, just return
1124
1125         // this function allows abbreviated strings!
1126         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1127         {
1128                 return true;
1129         });
1130
1131         return false;
1132 }
1133
1134 bool PlayerInIPList(entity p, string iplist)
1135 {
1136         // some safety checks (never allow local?)
1137         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1138                 return false;
1139
1140         return findinlist_abbrev(p.netaddress, iplist);
1141 }
1142
1143 bool PlayerInIDList(entity p, string idlist)
1144 {
1145         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1146         if(!p.crypto_idfp)
1147                 return false;
1148
1149         return findinlist_abbrev(p.crypto_idfp, idlist);
1150 }
1151
1152 bool PlayerInList(entity player, string list)
1153 {
1154         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1155 }
1156
1157 #ifdef DP_EXT_PRECONNECT
1158 /*
1159 =============
1160 ClientPreConnect
1161
1162 Called once (not at each match start) when a client begins a connection to the server
1163 =============
1164 */
1165 void ClientPreConnect(entity this)
1166 {
1167         if(autocvar_sv_eventlog)
1168         {
1169                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1170                         this.playerid,
1171                         etof(this),
1172                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1173                 ));
1174         }
1175 }
1176 #endif
1177
1178 /**
1179 =============
1180 ClientConnect
1181
1182 Called when a client connects to the server
1183 =============
1184 */
1185 void ClientConnect(entity this)
1186 {
1187         if (Ban_MaybeEnforceBanOnce(this)) return;
1188         assert(!IS_CLIENT(this), return);
1189         this.flags |= FL_CLIENT;
1190         assert(player_count >= 0, player_count = 0);
1191
1192 #ifdef WATERMARK
1193         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1194 #endif
1195         TRANSMUTE(Client, this);
1196         CS(this).version_nagtime = time + 10 + random() * 10;
1197
1198         // identify the right forced team
1199         if (autocvar_g_campaign)
1200         {
1201                 if (IS_REAL_CLIENT(this)) // only players, not bots
1202                 {
1203                         switch (autocvar_g_campaign_forceteam)
1204                         {
1205                                 case 1: this.team_forced = NUM_TEAM_1; break;
1206                                 case 2: this.team_forced = NUM_TEAM_2; break;
1207                                 case 3: this.team_forced = NUM_TEAM_3; break;
1208                                 case 4: this.team_forced = NUM_TEAM_4; break;
1209                                 default: this.team_forced = 0;
1210                         }
1211                 }
1212         }
1213         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1214         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1215         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1216         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1217         else switch (autocvar_g_forced_team_otherwise)
1218         {
1219                 default: this.team_forced = 0; break;
1220                 case "red": this.team_forced = NUM_TEAM_1; break;
1221                 case "blue": this.team_forced = NUM_TEAM_2; break;
1222                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1223                 case "pink": this.team_forced = NUM_TEAM_4; break;
1224                 case "spectate":
1225                 case "spectator":
1226                         this.team_forced = -1;
1227                         break;
1228         }
1229         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1230
1231         int playerid_save = this.playerid;
1232         this.playerid = 0; // silent
1233         JoinBestTeam(this, false); // if the team number is valid, keep it
1234         this.playerid = playerid_save;
1235
1236         TRANSMUTE(Observer, this);
1237
1238         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1239
1240         // always track bots, don't ask for cl_allow_uidtracking
1241         if (IS_BOT_CLIENT(this))
1242                 PlayerStats_GameReport_AddPlayer(this);
1243         else
1244                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1245
1246         if (autocvar_sv_eventlog)
1247                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1248
1249         LogTeamchange(this.playerid, this.team, 1);
1250
1251         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1252
1253         if(teamplay && IS_PLAYER(this))
1254                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1255         else
1256                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1257
1258         stuffcmd(this, clientstuff, "\n");
1259         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1260
1261         FixClientCvars(this);
1262
1263         // get version info from player
1264         stuffcmd(this, "cmd clientversion $gameversion\n");
1265
1266         // notify about available teams
1267         if (teamplay)
1268         {
1269                 CheckAllowedTeams(this);
1270                 int t = 0;
1271                 if (c1 >= 0) t |= BIT(0);
1272                 if (c2 >= 0) t |= BIT(1);
1273                 if (c3 >= 0) t |= BIT(2);
1274                 if (c4 >= 0) t |= BIT(3);
1275                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1276         }
1277         else
1278         {
1279                 stuffcmd(this, "set _teams_available 0\n");
1280         }
1281
1282         bot_relinkplayerlist();
1283
1284         CS(this).spectatortime = time;
1285         if (blockSpectators)
1286         {
1287                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1288         }
1289
1290         CS(this).jointime = time;
1291
1292         if (IS_REAL_CLIENT(this))
1293         {
1294                 if (g_weaponarena_weapons == WEPSET(TUBA))
1295                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1296         }
1297
1298         if (!sv_foginterval && world.fog != "")
1299                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1300
1301         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1302                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1303                         send_CSQC_teamnagger();
1304
1305         CSQCMODEL_AUTOINIT(this);
1306
1307         CS(this).model_randomizer = random();
1308
1309         if (IS_REAL_CLIENT(this))
1310                 sv_notice_join(this);
1311
1312         // update physics stats (players can spawn before physics runs)
1313         Physics_UpdateStats(this);
1314
1315         IL_EACH(g_initforplayer, it.init_for_player, {
1316                 it.init_for_player(it, this);
1317         });
1318
1319         Handicap_Initialize(this);
1320
1321         MUTATOR_CALLHOOK(ClientConnect, this);
1322
1323         if (IS_REAL_CLIENT(this))
1324         {
1325                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1326                 {
1327                         CS(this).motd_actived_time = -1;
1328                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1329                 }
1330         }
1331 }
1332 /*
1333 =============
1334 ClientDisconnect
1335
1336 Called when a client disconnects from the server
1337 =============
1338 */
1339 .entity chatbubbleentity;
1340 void ClientDisconnect(entity this)
1341 {
1342         assert(IS_CLIENT(this), return);
1343
1344         PlayerStats_GameReport_FinalizePlayer(this);
1345         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1346         if (CS(this).active_minigame) part_minigame(this);
1347         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1348
1349         if (autocvar_sv_eventlog)
1350                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1351
1352         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1353
1354         if(IS_SPEC(this))
1355                 SetSpectatee(this, NULL);
1356
1357     MUTATOR_CALLHOOK(ClientDisconnect, this);
1358
1359         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1360         strfree(CS(this).weaponorder_byimpulse);
1361         ClientState_detach(this);
1362
1363         Portal_ClearAll(this);
1364
1365         Unfreeze(this);
1366
1367         RemoveGrapplingHooks(this);
1368
1369         // Here, everything has been done that requires this player to be a client.
1370
1371         this.flags &= ~FL_CLIENT;
1372
1373         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1374         if (this.killindicator) delete(this.killindicator);
1375
1376         WaypointSprite_PlayerGone(this);
1377
1378         bot_relinkplayerlist();
1379
1380         strfree(this.clientstatus);
1381         if (this.personal) delete(this.personal);
1382
1383         this.playerid = 0;
1384         ReadyCount();
1385         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1386
1387         ONREMOVE(this);
1388 }
1389
1390 void ChatBubbleThink(entity this)
1391 {
1392         this.nextthink = time;
1393         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1394         {
1395                 if(this.owner) // but why can that ever be NULL?
1396                         this.owner.chatbubbleentity = NULL;
1397                 delete(this);
1398                 return;
1399         }
1400
1401         this.mdl = "";
1402
1403         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1404         {
1405                 if ( CS(this.owner).active_minigame )
1406                         this.mdl = "models/sprites/minigame_busy.iqm";
1407                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1408                         this.mdl = "models/misc/chatbubble.spr";
1409         }
1410
1411         if ( this.model != this.mdl )
1412                 _setmodel(this, this.mdl);
1413
1414 }
1415
1416 void UpdateChatBubble(entity this)
1417 {
1418         if (this.alpha < 0)
1419                 return;
1420         // spawn a chatbubble entity if needed
1421         if (!this.chatbubbleentity)
1422         {
1423                 this.chatbubbleentity = new(chatbubbleentity);
1424                 this.chatbubbleentity.owner = this;
1425                 this.chatbubbleentity.exteriormodeltoclient = this;
1426                 setthink(this.chatbubbleentity, ChatBubbleThink);
1427                 this.chatbubbleentity.nextthink = time;
1428                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1429                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1430                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1431                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1432                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1433                 //this.chatbubbleentity.model = "";
1434                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1435         }
1436 }
1437
1438
1439 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1440 // added to the model skins
1441 /*void UpdateColorModHack()
1442 {
1443         float c;
1444         c = this.clientcolors & 15;
1445         // LordHavoc: only bothering to support white, green, red, yellow, blue
1446              if (!teamplay) this.colormod = '0 0 0';
1447         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1448         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1449         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1450         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1451         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1452         else this.colormod = '1 1 1';
1453 }*/
1454
1455 void respawn(entity this)
1456 {
1457         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1458         {
1459                 this.solid = SOLID_NOT;
1460                 this.takedamage = DAMAGE_NO;
1461                 set_movetype(this, MOVETYPE_FLY);
1462                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1463                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1464                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1465                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1466                 if(autocvar_g_respawn_ghosts_maxtime)
1467                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1468         }
1469
1470         CopyBody(this, 1);
1471
1472         this.effects |= EF_NODRAW; // prevent another CopyBody
1473         PutClientInServer(this);
1474 }
1475
1476 void PrintToChat(entity client, string text)
1477 {
1478         text = strcat("\{1}^7", text, "\n");
1479         sprint(client, text);
1480 }
1481
1482 void DebugPrintToChat(entity client, string text)
1483 {
1484         if (autocvar_developer)
1485         {
1486                 PrintToChat(client, text);
1487         }
1488 }
1489
1490 void PrintToChatAll(string text)
1491 {
1492         text = strcat("\{1}^7", text, "\n");
1493         bprint(text);
1494 }
1495
1496 void DebugPrintToChatAll(string text)
1497 {
1498         if (autocvar_developer)
1499         {
1500                 PrintToChatAll(text);
1501         }
1502 }
1503
1504 void PrintToChatTeam(int team_num, string text)
1505 {
1506         text = strcat("\{1}^7", text, "\n");
1507         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1508         {
1509                 if (it.team == team_num)
1510                 {
1511                         sprint(it, text);
1512                 }
1513         });
1514 }
1515
1516 void DebugPrintToChatTeam(int team_num, string text)
1517 {
1518         if (autocvar_developer)
1519         {
1520                 PrintToChatTeam(team_num, text);
1521         }
1522 }
1523
1524 void play_countdown(entity this, float finished, Sound samp)
1525 {
1526         TC(Sound, samp);
1527         if(IS_REAL_CLIENT(this))
1528                 if(floor(finished - time - frametime) != floor(finished - time))
1529                         if(finished - time < 6)
1530                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1531 }
1532
1533 void player_powerups(entity this)
1534 {
1535         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1536         int items_prev = this.items;
1537
1538         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1539                 this.modelflags |= MF_ROCKET;
1540         else
1541                 this.modelflags &= ~MF_ROCKET;
1542
1543         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1544
1545         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1546                 return;
1547
1548         Fire_ApplyDamage(this);
1549         Fire_ApplyEffect(this);
1550
1551         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1552         {
1553                 if (this.items & ITEM_Strength.m_itemid)
1554                 {
1555                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1556                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1557                         if (time > this.strength_finished)
1558                         {
1559                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1560                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1561                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1562                         }
1563                 }
1564                 else
1565                 {
1566                         if (time < this.strength_finished)
1567                         {
1568                                 this.items = this.items | ITEM_Strength.m_itemid;
1569                                 if(!g_cts)
1570                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1571                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1572                         }
1573                 }
1574                 if (this.items & ITEM_Shield.m_itemid)
1575                 {
1576                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1577                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1578                         if (time > this.invincible_finished)
1579                         {
1580                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1581                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1582                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1583                         }
1584                 }
1585                 else
1586                 {
1587                         if (time < this.invincible_finished)
1588                         {
1589                                 this.items = this.items | ITEM_Shield.m_itemid;
1590                                 if(!g_cts)
1591                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1592                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1593                         }
1594                 }
1595                 if (this.items & IT_SUPERWEAPON)
1596                 {
1597                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1598                         {
1599                                 this.superweapons_finished = 0;
1600                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1601                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1602                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1603                         }
1604                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1605                         {
1606                                 // don't let them run out
1607                         }
1608                         else
1609                         {
1610                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1611                                 if (time > this.superweapons_finished)
1612                                 {
1613                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1614                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1615                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1616                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1617                                 }
1618                         }
1619                 }
1620                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1621                 {
1622                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1623                         {
1624                                 this.items = this.items | IT_SUPERWEAPON;
1625                                 if(!g_cts)
1626                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1627                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1628                         }
1629                         else
1630                         {
1631                                 this.superweapons_finished = 0;
1632                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1633                         }
1634                 }
1635                 else
1636                 {
1637                         this.superweapons_finished = 0;
1638                 }
1639         }
1640
1641         if(autocvar_g_nodepthtestplayers)
1642                 this.effects = this.effects | EF_NODEPTHTEST;
1643
1644         if(autocvar_g_fullbrightplayers)
1645                 this.effects = this.effects | EF_FULLBRIGHT;
1646
1647         if (time >= game_starttime)
1648         if (time < this.spawnshieldtime)
1649                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1650
1651         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1652 }
1653
1654 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1655 {
1656         if(current > stable)
1657                 return current;
1658         else if(current > stable - 0.25) // when close enough, "snap"
1659                 return stable;
1660         else
1661                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1662 }
1663
1664 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1665 {
1666         if(current < stable)
1667                 return current;
1668         else if(current < stable + 0.25) // when close enough, "snap"
1669                 return stable;
1670         else
1671                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1672 }
1673
1674 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1675 {
1676         if(current > rotstable)
1677         {
1678                 if(rotframetime > 0)
1679                 {
1680                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1681                         current = max(rotstable, current - rotlinear * rotframetime);
1682                 }
1683         }
1684         else if(current < regenstable)
1685         {
1686                 if(regenframetime > 0)
1687                 {
1688                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1689                         current = min(regenstable, current + regenlinear * regenframetime);
1690                 }
1691         }
1692
1693         if(current > limit)
1694                 current = limit;
1695
1696         return current;
1697 }
1698
1699 void player_regen(entity this)
1700 {
1701         float max_mod, regen_mod, rot_mod, limit_mod;
1702         max_mod = regen_mod = rot_mod = limit_mod = 1;
1703
1704         float regen_health = autocvar_g_balance_health_regen;
1705         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1706         float regen_health_rot = autocvar_g_balance_health_rot;
1707         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1708         float regen_health_stable = autocvar_g_balance_health_regenstable;
1709         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1710         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1711                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1712         max_mod = M_ARGV(1, float);
1713         regen_mod = M_ARGV(2, float);
1714         rot_mod = M_ARGV(3, float);
1715         limit_mod = M_ARGV(4, float);
1716         regen_health = M_ARGV(5, float);
1717         regen_health_linear = M_ARGV(6, float);
1718         regen_health_rot = M_ARGV(7, float);
1719         regen_health_rotlinear = M_ARGV(8, float);
1720         regen_health_stable = M_ARGV(9, float);
1721         regen_health_rotstable = M_ARGV(10, float);
1722
1723         if(!mutator_returnvalue)
1724         if(!STAT(FROZEN, this))
1725         {
1726                 float mina, maxa, limith, limita;
1727                 maxa = autocvar_g_balance_armor_rotstable;
1728                 mina = autocvar_g_balance_armor_regenstable;
1729                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1730                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1731
1732                 regen_health_rotstable = regen_health_rotstable * max_mod;
1733                 regen_health_stable = regen_health_stable * max_mod;
1734                 limith = limith * limit_mod;
1735                 limita = limita * limit_mod;
1736
1737                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, 
1738                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1739                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1740                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1741                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1742                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1743         }
1744
1745         // if player rotted to death...  die!
1746         // check this outside above checks, as player may still be able to rot to death
1747         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1748         {
1749                 if(this.vehicle)
1750                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1751                 if(this.event_damage)
1752                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1753         }
1754
1755         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1756         {
1757                 float minf, maxf, limitf;
1758
1759                 maxf = autocvar_g_balance_fuel_rotstable;
1760                 minf = autocvar_g_balance_fuel_regenstable;
1761                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1762
1763                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, 
1764                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1765                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1766         }
1767 }
1768
1769 bool zoomstate_set;
1770 void SetZoomState(entity this, float newzoom)
1771 {
1772         if(newzoom != CS(this).zoomstate)
1773         {
1774                 CS(this).zoomstate = newzoom;
1775                 ClientData_Touch(this);
1776         }
1777         zoomstate_set = true;
1778 }
1779
1780 void GetPressedKeys(entity this)
1781 {
1782         MUTATOR_CALLHOOK(GetPressedKeys, this);
1783         int keys = STAT(PRESSED_KEYS, this);
1784         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1785         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1786         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1787         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1788
1789         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1790         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1791         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1792         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1793         CS(this).pressedkeys = keys; // store for other users
1794
1795         STAT(PRESSED_KEYS, this) = keys;
1796 }
1797
1798 /*
1799 ======================
1800 spectate mode routines
1801 ======================
1802 */
1803
1804 void SpectateCopy(entity this, entity spectatee)
1805 {
1806         TC(Client, this); TC(Client, spectatee);
1807
1808         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1809         PS(this) = PS(spectatee);
1810         this.armortype = spectatee.armortype;
1811         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1812         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1813         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1814         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1815         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1816         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1817         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1818         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1819         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1820         CS(this).impulse = 0;
1821         this.items = spectatee.items;
1822         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1823         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1824         this.strength_finished = spectatee.strength_finished;
1825         this.invincible_finished = spectatee.invincible_finished;
1826         this.superweapons_finished = spectatee.superweapons_finished;
1827         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1828         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1829         this.punchangle = spectatee.punchangle;
1830         this.view_ofs = spectatee.view_ofs;
1831         this.velocity = spectatee.velocity;
1832         this.dmg_take = spectatee.dmg_take;
1833         this.dmg_save = spectatee.dmg_save;
1834         this.dmg_inflictor = spectatee.dmg_inflictor;
1835         this.v_angle = spectatee.v_angle;
1836         this.angles = spectatee.v_angle;
1837         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1838         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1839         this.viewloc = spectatee.viewloc;
1840         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1841                 this.fixangle = true;
1842         setorigin(this, spectatee.origin);
1843         setsize(this, spectatee.mins, spectatee.maxs);
1844         SetZoomState(this, CS(spectatee).zoomstate);
1845
1846     anticheat_spectatecopy(this, spectatee);
1847         STAT(HUD, this) = STAT(HUD, spectatee);
1848         if(spectatee.vehicle)
1849     {
1850         this.angles = spectatee.v_angle;
1851
1852         //this.fixangle = false;
1853         //this.velocity = spectatee.vehicle.velocity;
1854         this.vehicle_health = spectatee.vehicle_health;
1855         this.vehicle_shield = spectatee.vehicle_shield;
1856         this.vehicle_energy = spectatee.vehicle_energy;
1857         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1858         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1859         this.vehicle_reload1 = spectatee.vehicle_reload1;
1860         this.vehicle_reload2 = spectatee.vehicle_reload2;
1861
1862         //msg_entity = this;
1863
1864        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1865             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1866            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1867            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1868
1869         //WriteByte (MSG_ONE, SVC_SETVIEW);
1870         //    WriteEntity(MSG_ONE, this);
1871         //makevectors(spectatee.v_angle);
1872         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1873     }
1874 }
1875
1876 bool SpectateUpdate(entity this)
1877 {
1878         if(!this.enemy)
1879                 return false;
1880
1881         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1882         {
1883                 SetSpectatee(this, NULL);
1884                 return false;
1885         }
1886
1887         SpectateCopy(this, this.enemy);
1888
1889         return true;
1890 }
1891
1892 bool SpectateSet(entity this)
1893 {
1894         if(!IS_PLAYER(this.enemy))
1895                 return false;
1896
1897         ClientData_Touch(this.enemy);
1898
1899         msg_entity = this;
1900         WriteByte(MSG_ONE, SVC_SETVIEW);
1901         WriteEntity(MSG_ONE, this.enemy);
1902         set_movetype(this, MOVETYPE_NONE);
1903         accuracy_resend(this);
1904
1905         if(!SpectateUpdate(this))
1906                 PutObserverInServer(this);
1907
1908         return true;
1909 }
1910
1911 void SetSpectatee_status(entity this, int spectatee_num)
1912 {
1913         int oldspectatee_status = CS(this).spectatee_status;
1914         CS(this).spectatee_status = spectatee_num;
1915
1916         if (CS(this).spectatee_status != oldspectatee_status)
1917         {
1918                 ClientData_Touch(this);
1919                 if (g_race || g_cts) race_InitSpectator();
1920         }
1921 }
1922
1923 void SetSpectatee(entity this, entity spectatee)
1924 {
1925         if(IS_BOT_CLIENT(this))
1926                 return; // bots abuse .enemy, this code is useless to them
1927
1928         entity old_spectatee = this.enemy;
1929
1930         this.enemy = spectatee;
1931
1932         // WEAPONTODO
1933         // these are required to fix the spectator bug with arc
1934         if(old_spectatee)
1935         {
1936                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1937                 {
1938                         .entity weaponentity = weaponentities[slot];
1939                         if(old_spectatee.(weaponentity).arc_beam)
1940                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1941                 }
1942         }
1943         if(this.enemy)
1944         {
1945                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1946                 {
1947                         .entity weaponentity = weaponentities[slot];
1948                         if(this.enemy.(weaponentity).arc_beam)
1949                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1950                 }
1951         }
1952
1953         if (this.enemy)
1954                 SetSpectatee_status(this, etof(this.enemy));
1955
1956         // needed to update spectator list
1957         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1958 }
1959
1960 bool Spectate(entity this, entity pl)
1961 {
1962         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1963                 return false;
1964         pl = M_ARGV(1, entity);
1965
1966         SetSpectatee(this, pl);
1967         return SpectateSet(this);
1968 }
1969
1970 bool SpectateNext(entity this)
1971 {
1972         entity ent = find(this.enemy, classname, STR_PLAYER);
1973
1974         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1975                 ent = M_ARGV(1, entity);
1976         else if (!ent)
1977                 ent = find(ent, classname, STR_PLAYER);
1978
1979         if(ent) { SetSpectatee(this, ent); }
1980
1981         return SpectateSet(this);
1982 }
1983
1984 bool SpectatePrev(entity this)
1985 {
1986         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1987         entity ent = findchain(classname, STR_PLAYER);
1988         if (!ent) // no player
1989                 return false;
1990
1991         entity first = ent;
1992         // skip players until current spectated player
1993         if(this.enemy)
1994         while(ent && ent != this.enemy)
1995                 ent = ent.chain;
1996
1997         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1998         {
1999                 case MUT_SPECPREV_FOUND:
2000                     ent = M_ARGV(1, entity);
2001                     break;
2002                 case MUT_SPECPREV_RETURN:
2003                     return true;
2004                 case MUT_SPECPREV_CONTINUE:
2005                 default:
2006                 {
2007                         if(ent.chain)
2008                                 ent = ent.chain;
2009                         else
2010                                 ent = first;
2011                         break;
2012                 }
2013         }
2014
2015         SetSpectatee(this, ent);
2016         return SpectateSet(this);
2017 }
2018
2019 /*
2020 =============
2021 ShowRespawnCountdown()
2022
2023 Update a respawn countdown display.
2024 =============
2025 */
2026 void ShowRespawnCountdown(entity this)
2027 {
2028         float number;
2029         if(!IS_DEAD(this)) // just respawned?
2030                 return;
2031         else
2032         {
2033                 number = ceil(this.respawn_time - time);
2034                 if(number <= 0)
2035                         return;
2036                 if(number <= this.respawn_countdown)
2037                 {
2038                         this.respawn_countdown = number - 1;
2039                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2040                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2041                 }
2042         }
2043 }
2044
2045 .bool team_selected;
2046 bool ShowTeamSelection(entity this)
2047 {
2048         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2049                 return false;
2050         stuffcmd(this, "menu_showteamselect\n");
2051         return true;
2052 }
2053 void Join(entity this)
2054 {
2055         TRANSMUTE(Player, this);
2056
2057         if(!this.team_selected)
2058         if(autocvar_g_campaign || autocvar_g_balance_teams)
2059                 JoinBestTeam(this, true);
2060
2061         if(autocvar_g_campaign)
2062                 campaign_bots_may_start = true;
2063
2064         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2065
2066         PutClientInServer(this);
2067
2068         if(IS_PLAYER(this))
2069         if(teamplay && this.team != -1)
2070                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2071         else
2072                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2073         this.team_selected = false;
2074 }
2075
2076 /**
2077  * Determines whether the player is allowed to join. This depends on cvar
2078  * g_maxplayers, if it isn't used this function always return true, otherwise
2079  * it checks whether the number of currently playing players exceeds g_maxplayers.
2080  * @return int number of free slots for players, 0 if none
2081  */
2082 int nJoinAllowed(entity this, entity ignore)
2083 {
2084         if(!ignore)
2085         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2086         // so report 0 free slots if restricted
2087         {
2088                 if(autocvar_g_forced_team_otherwise == "spectate")
2089                         return 0;
2090                 if(autocvar_g_forced_team_otherwise == "spectator")
2091                         return 0;
2092         }
2093
2094         if(this && this.team_forced < 0)
2095                 return 0; // forced spectators can never join
2096
2097         // TODO simplify this
2098         int totalClients = 0;
2099         int currentlyPlaying = 0;
2100         FOREACH_CLIENT(true, {
2101                 if(it != ignore)
2102                         ++totalClients;
2103                 if(IS_REAL_CLIENT(it))
2104                 if(IS_PLAYER(it) || it.caplayer)
2105                         ++currentlyPlaying;
2106         });
2107
2108         float free_slots = 0;
2109         if (!autocvar_g_maxplayers)
2110                 free_slots = maxclients - totalClients;
2111         else if(currentlyPlaying < autocvar_g_maxplayers)
2112                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2113
2114         static float join_prevent_msg_time = 0;
2115         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2116         {
2117                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2118                 join_prevent_msg_time = time + 3;
2119         }
2120
2121         return free_slots;
2122 }
2123
2124 /**
2125  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2126  * g_maxplayers_spectator_blocktime seconds
2127  */
2128 void checkSpectatorBlock(entity this)
2129 {
2130         if(IS_SPEC(this) || IS_OBSERVER(this))
2131         if(!this.caplayer)
2132         if(IS_REAL_CLIENT(this))
2133         {
2134                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2135                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2136                         dropclient(this);
2137                 }
2138         }
2139 }
2140
2141 void PrintWelcomeMessage(entity this)
2142 {
2143         if(CS(this).motd_actived_time == 0)
2144         {
2145                 if (autocvar_g_campaign) {
2146                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2147                                 CS(this).motd_actived_time = time;
2148                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2149                         }
2150                 } else {
2151                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2152                                 CS(this).motd_actived_time = time;
2153                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2154                         }
2155                 }
2156         }
2157         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2158         {
2159                 if (autocvar_g_campaign) {
2160                         if (PHYS_INPUT_BUTTON_INFO(this))
2161                                 CS(this).motd_actived_time = time;
2162                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2163                                 CS(this).motd_actived_time = 0;
2164                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2165                         }
2166                 } else {
2167                         if (PHYS_INPUT_BUTTON_INFO(this))
2168                                 CS(this).motd_actived_time = time;
2169                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2170                                 CS(this).motd_actived_time = 0;
2171                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2172                         }
2173                 }
2174         }
2175         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2176         {
2177                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2178                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2179                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2180                 {
2181                         // instanctly hide MOTD
2182                         CS(this).motd_actived_time = 0;
2183                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2184                 }
2185         }
2186 }
2187
2188 const int MIN_SPEC_TIME = 1;
2189 bool joinAllowed(entity this)
2190 {
2191         if (CS(this).version_mismatch) return false;
2192         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2193         if (!nJoinAllowed(this, this)) return false;
2194         if (teamplay && lockteams) return false;
2195         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2196         if (ShowTeamSelection(this)) return false;
2197         return true;
2198 }
2199
2200 .int items_added;
2201 .string shootfromfixedorigin;
2202 bool PlayerThink(entity this)
2203 {
2204         if (game_stopped || intermission_running) {
2205                 this.modelflags &= ~MF_ROCKET;
2206                 if(intermission_running)
2207                         IntermissionThink(this);
2208                 return false;
2209         }
2210
2211         if (timeout_status == TIMEOUT_ACTIVE) {
2212         // don't allow the player to turn around while game is paused
2213                 // FIXME turn this into CSQC stuff
2214                 this.v_angle = this.lastV_angle;
2215                 this.angles = this.lastV_angle;
2216                 this.fixangle = true;
2217         }
2218
2219         if (frametime) player_powerups(this);
2220
2221         if (IS_DEAD(this)) {
2222                 if (this.personal && g_race_qualifying) {
2223                         if (time > this.respawn_time) {
2224                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2225                                 respawn(this);
2226                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2227                         }
2228                 } else {
2229                         if (frametime) player_anim(this);
2230
2231                         if (this.respawn_flags & RESPAWN_DENY)
2232                         {
2233                                 STAT(RESPAWN_TIME, this) = 0;
2234                                 return false;
2235                         }
2236
2237                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2238
2239                         switch(this.deadflag)
2240                         {
2241                                 case DEAD_DYING:
2242                                 {
2243                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2244                                                 this.deadflag = DEAD_RESPAWNING;
2245                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2246                                                 this.deadflag = DEAD_DEAD;
2247                                         break;
2248                                 }
2249                                 case DEAD_DEAD:
2250                                 {
2251                                         if (button_pressed)
2252                                                 this.deadflag = DEAD_RESPAWNABLE;
2253                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2254                                                 this.deadflag = DEAD_RESPAWNING;
2255                                         break;
2256                                 }
2257                                 case DEAD_RESPAWNABLE:
2258                                 {
2259                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2260                                                 this.deadflag = DEAD_RESPAWNING;
2261                                         break;
2262                                 }
2263                                 case DEAD_RESPAWNING:
2264                                 {
2265                                         if (time > this.respawn_time)
2266                                         {
2267                                                 this.respawn_time = time + 1; // only retry once a second
2268                                                 this.respawn_time_max = this.respawn_time;
2269                                                 respawn(this);
2270                                         }
2271                                         break;
2272                                 }
2273                         }
2274
2275                         ShowRespawnCountdown(this);
2276
2277                         if (this.respawn_flags & RESPAWN_SILENT)
2278                                 STAT(RESPAWN_TIME, this) = 0;
2279                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2280                         {
2281                                 if (time < this.respawn_time)
2282                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2283                                 else if (this.deadflag != DEAD_RESPAWNING)
2284                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2285                         }
2286                         else
2287                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2288                 }
2289
2290                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2291                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2292                         STAT(RESPAWN_TIME, this) *= -1;
2293
2294                 return false;
2295         }
2296
2297         FixPlayermodel(this);
2298
2299         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2300                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2301                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2302         }
2303
2304         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2305         //if(frametime)
2306         {
2307                 this.items &= ~this.items_added;
2308
2309                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2310                 {
2311                         .entity weaponentity = weaponentities[slot];
2312                         W_WeaponFrame(this, weaponentity);
2313                 }
2314
2315                 this.items_added = 0;
2316                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2317             this.items_added |= IT_FUEL;
2318
2319                 this.items |= this.items_added;
2320         }
2321
2322         player_regen(this);
2323
2324         // WEAPONTODO: Add a weapon request for this
2325         // rot vortex charge to the charge limit
2326         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2327         {
2328                 .entity weaponentity = weaponentities[slot];
2329                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2330                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2331         }
2332
2333         if (frametime) player_anim(this);
2334
2335         // secret status
2336         secrets_setstatus(this);
2337
2338         // monsters status
2339         monsters_setstatus(this);
2340
2341         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2342
2343         return true;
2344 }
2345
2346 .bool would_spectate;
2347 void ObserverThink(entity this)
2348 {
2349         if ( CS(this).impulse )
2350         {
2351                 MinigameImpulse(this, CS(this).impulse);
2352                 CS(this).impulse = 0;
2353         }
2354
2355         if (this.flags & FL_JUMPRELEASED) {
2356                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2357                         this.flags &= ~FL_JUMPRELEASED;
2358                         this.flags |= FL_SPAWNING;
2359                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2360                         this.flags &= ~FL_JUMPRELEASED;
2361                         if(SpectateNext(this)) {
2362                                 TRANSMUTE(Spectator, this);
2363                         }
2364                 } else {
2365                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2366                         set_movetype(this, preferred_movetype);
2367                 }
2368         } else {
2369                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2370                         this.flags |= FL_JUMPRELEASED;
2371                         if(this.flags & FL_SPAWNING)
2372                         {
2373                                 this.flags &= ~FL_SPAWNING;
2374                                 Join(this);
2375                                 return;
2376                         }
2377                 }
2378         }
2379 }
2380
2381 void SpectatorThink(entity this)
2382 {
2383         if ( CS(this).impulse )
2384         {
2385                 if(MinigameImpulse(this, CS(this).impulse))
2386                         CS(this).impulse = 0;
2387
2388                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2389                 {
2390                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2391                         CS(this).impulse = 0;
2392                         return;
2393                 }
2394         }
2395
2396         if (this.flags & FL_JUMPRELEASED) {
2397                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2398                         this.flags &= ~FL_JUMPRELEASED;
2399                         this.flags |= FL_SPAWNING;
2400                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2401                         this.flags &= ~FL_JUMPRELEASED;
2402                         if(SpectateNext(this)) {
2403                                 TRANSMUTE(Spectator, this);
2404                         } else {
2405                                 TRANSMUTE(Observer, this);
2406                                 PutClientInServer(this);
2407                         }
2408                         CS(this).impulse = 0;
2409                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2410                         this.flags &= ~FL_JUMPRELEASED;
2411                         if(SpectatePrev(this)) {
2412                                 TRANSMUTE(Spectator, this);
2413                         } else {
2414                                 TRANSMUTE(Observer, this);
2415                                 PutClientInServer(this);
2416                         }
2417                         CS(this).impulse = 0;
2418                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2419                         this.would_spectate = false;
2420                         this.flags &= ~FL_JUMPRELEASED;
2421                         TRANSMUTE(Observer, this);
2422                         PutClientInServer(this);
2423                 } else {
2424                         if(!SpectateUpdate(this))
2425                         {
2426                                 if(!SpectateNext(this))
2427                                 {
2428                                         PutObserverInServer(this);
2429                                         this.would_spectate = true;
2430                                 }
2431                         }
2432                 }
2433         } else {
2434                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2435                         this.flags |= FL_JUMPRELEASED;
2436                         if(this.flags & FL_SPAWNING)
2437                         {
2438                                 this.flags &= ~FL_SPAWNING;
2439                                 Join(this);
2440                                 return;
2441                         }
2442                 }
2443                 if(!SpectateUpdate(this))
2444                         PutObserverInServer(this);
2445         }
2446
2447         this.flags |= FL_CLIENT | FL_NOTARGET;
2448 }
2449
2450 void PlayerUseKey(entity this)
2451 {
2452         if (!IS_PLAYER(this))
2453                 return;
2454
2455         if(this.vehicle)
2456         {
2457                 if(!game_stopped)
2458                 {
2459                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2460                         return;
2461                 }
2462         }
2463         else if(autocvar_g_vehicles_enter)
2464         {
2465                 if(!STAT(FROZEN, this))
2466                 if(!IS_DEAD(this))
2467                 if(!game_stopped)
2468                 {
2469                         entity head, closest_target = NULL;
2470                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2471
2472                         while(head) // find the closest acceptable target to enter
2473                         {
2474                                 if(IS_VEHICLE(head))
2475                                 if(!IS_DEAD(head))
2476                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2477                                 if(head.takedamage != DAMAGE_NO)
2478                                 {
2479                                         if(closest_target)
2480                                         {
2481                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2482                                                 { closest_target = head; }
2483                                         }
2484                                         else { closest_target = head; }
2485                                 }
2486
2487                                 head = head.chain;
2488                         }
2489
2490                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2491                 }
2492         }
2493
2494         // a use key was pressed; call handlers
2495         MUTATOR_CALLHOOK(PlayerUseKey, this);
2496 }
2497
2498
2499 /*
2500 =============
2501 PlayerPreThink
2502
2503 Called every frame for each client before the physics are run
2504 =============
2505 */
2506 .float last_vehiclecheck;
2507 void PlayerPreThink (entity this)
2508 {
2509         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2510         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2511
2512         WarpZone_PlayerPhysics_FixVAngle(this);
2513
2514         if (frametime) {
2515                 // physics frames: update anticheat stuff
2516                 anticheat_prethink(this);
2517         }
2518
2519         if (blockSpectators && frametime) {
2520                 // WORKAROUND: only use dropclient in server frames (frametime set).
2521                 // Never use it in cl_movement frames (frametime zero).
2522                 checkSpectatorBlock(this);
2523         }
2524
2525         zoomstate_set = false;
2526
2527         // Check for nameless players
2528         if (this.netname == "" || this.netname != CS(this).netname_previous)
2529         {
2530                 bool assume_unchanged = (CS(this).netname_previous == "");
2531                 if (isInvisibleString(this.netname))
2532                 {
2533                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2534                         assume_unchanged = false;
2535                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2536                 }
2537                 if (!assume_unchanged && autocvar_sv_eventlog)
2538                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2539                 strcpy(CS(this).netname_previous, this.netname);
2540         }
2541
2542         // version nagging
2543         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2544         CS(this).version_nagtime = 0;
2545         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2546             // git client
2547         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2548             // git server
2549             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2550         } else {
2551             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2552             if (r < 0) { // old client
2553                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2554             } else if (r > 0) { // old server
2555                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2556             }
2557         }
2558     }
2559
2560         // GOD MODE info
2561         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2562         {
2563                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2564                 this.max_armorvalue = 0;
2565         }
2566
2567         if(IS_PLAYER(this))
2568         {
2569                 if (STAT(FROZEN, this) == 2)
2570                 {
2571                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2572                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2573                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2574
2575                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2576                                 Unfreeze(this);
2577                 }
2578                 else if (STAT(FROZEN, this) == 3)
2579                 {
2580                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2581                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2582
2583                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2584                         {
2585                                 if (this.vehicle)
2586                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2587                                 if(this.event_damage)
2588                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2589                         }
2590                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2591                                 Unfreeze(this);
2592                 }
2593         }
2594
2595         MUTATOR_CALLHOOK(PlayerPreThink, this);
2596
2597         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2598         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2599         {
2600                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2601                 {
2602                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2603                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2604                         {
2605                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2606                         }
2607                         else if(!it.owner)
2608                         {
2609                                 if(!it.team || SAME_TEAM(this, it))
2610                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2611                                 else if(autocvar_g_vehicles_steal)
2612                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2613                         }
2614                 });
2615
2616                 this.last_vehiclecheck = time + 1;
2617         }
2618
2619         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2620         {
2621                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2622                         PlayerUseKey(this);
2623                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2624         }
2625
2626         if (IS_REAL_CLIENT(this))
2627                 PrintWelcomeMessage(this);
2628
2629         if (IS_PLAYER(this)) {
2630                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2631                         error("Client can't be spawned as player on connection!");
2632                 if(!PlayerThink(this))
2633                         return;
2634         }
2635         else if (game_stopped || intermission_running) {
2636                 if(intermission_running)
2637                         IntermissionThink(this);
2638                 return;
2639         }
2640         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2641         {
2642                 CS(this).autojoin_checked = true;
2643                 // don't do this in ClientConnect
2644                 // many things can go wrong if a client is spawned as player on connection
2645                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2646                         || (!(autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0)
2647                                 && (!teamplay || autocvar_g_balance_teams)))
2648                 {
2649                         campaign_bots_may_start = true;
2650                         Join(this);
2651                         return;
2652                 }
2653         }
2654         else if (IS_OBSERVER(this)) {
2655                 ObserverThink(this);
2656         }
2657         else if (IS_SPEC(this)) {
2658                 SpectatorThink(this);
2659         }
2660
2661         // WEAPONTODO: Add weapon request for this
2662         if (!zoomstate_set) {
2663                 bool wep_zoomed = false;
2664                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2665                 {
2666                         .entity weaponentity = weaponentities[slot];
2667                         Weapon thiswep = this.(weaponentity).m_weapon;
2668                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2669                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2670                 }
2671                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2672     }
2673
2674         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2675         {
2676                 CS(this).teamkill_soundtime = 0;
2677
2678                 entity e = CS(this).teamkill_soundsource;
2679                 entity oldpusher = e.pusher;
2680                 e.pusher = this;
2681                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2682                 e.pusher = oldpusher;
2683         }
2684
2685         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2686                 CS(this).taunt_soundtime = 0;
2687                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2688         }
2689
2690         target_voicescript_next(this);
2691
2692         // WEAPONTODO: Move into weaponsystem somehow
2693         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2694         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2695         {
2696                 .entity weaponentity = weaponentities[slot];
2697                 if(this.(weaponentity).m_weapon == WEP_Null)
2698                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2699         }
2700 }
2701
2702 void DrownPlayer(entity this)
2703 {
2704         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2705                 return;
2706
2707         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2708         {
2709                 if(this.air_finished < time)
2710                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2711                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2712         }
2713         else if (this.air_finished < time)
2714         {       // drown!
2715                 if (this.pain_finished < time)
2716                 {
2717                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2718                         this.pain_finished = time + 0.5;
2719                 }
2720         }
2721 }
2722
2723 .bool move_qcphysics;
2724
2725 void Player_Physics(entity this)
2726 {
2727         set_movetype(this, this.move_movetype);
2728
2729         if(!this.move_qcphysics)
2730                 return;
2731
2732         if(!frametime && !CS(this).pm_frametime)
2733                 return;
2734
2735         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2736
2737         CS(this).pm_frametime = 0;
2738 }
2739
2740 /*
2741 =============
2742 PlayerPostThink
2743
2744 Called every frame for each client after the physics are run
2745 =============
2746 */
2747 void PlayerPostThink (entity this)
2748 {
2749         Player_Physics(this);
2750
2751         if (sv_maxidle > 0)
2752         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2753         if (IS_REAL_CLIENT(this))
2754         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2755         {
2756                 int totalClients = 0;
2757                 if(sv_maxidle_slots > 0)
2758                 {
2759                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2760                         {
2761                                 ++totalClients;
2762                         });
2763                 }
2764
2765                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2766                 { /* do nothing */ }
2767                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2768                 {
2769                         if (CS(this).idlekick_lasttimeleft)
2770                         {
2771                                 CS(this).idlekick_lasttimeleft = 0;
2772                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2773                         }
2774                 }
2775                 else
2776                 {
2777                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2778                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2779                                 if (!CS(this).idlekick_lasttimeleft)
2780                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2781                         }
2782                         if (timeleft <= 0) {
2783                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2784                                 dropclient(this);
2785                                 return;
2786                         }
2787                         else if (timeleft <= 10) {
2788                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2789                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2790                 }
2791                                 CS(this).idlekick_lasttimeleft = timeleft;
2792                         }
2793                 }
2794         }
2795
2796         CheatFrame(this);
2797
2798         if (game_stopped)
2799         {
2800                 this.solid = SOLID_NOT;
2801                 this.takedamage = DAMAGE_NO;
2802                 set_movetype(this, MOVETYPE_NONE);
2803         }
2804
2805         if (IS_PLAYER(this)) {
2806                 if(this.death_time == time && IS_DEAD(this))
2807                 {
2808                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2809                         // once all the damage events of this frame have been processed with normal size
2810                         this.maxs.z = 5;
2811                         setsize(this, this.mins, this.maxs);
2812                 }
2813                 DrownPlayer(this);
2814                 UpdateChatBubble(this);
2815                 if (CS(this).impulse) ImpulseCommands(this);
2816                 if (game_stopped)
2817                 {
2818                         CSQCMODEL_AUTOUPDATE(this);
2819                         return;
2820                 }
2821                 GetPressedKeys(this);
2822         }
2823
2824         if (this.waypointsprite_attachedforcarrier) {
2825             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2826                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2827     }
2828
2829         CSQCMODEL_AUTOUPDATE(this);
2830 }
2831
2832 // hack to copy the button fields from the client entity to the Client State
2833 void PM_UpdateButtons(entity this, entity store)
2834 {
2835         if(this.impulse)
2836                 store.impulse = this.impulse;
2837         this.impulse = 0;
2838
2839         bool typing = this.buttonchat;
2840
2841         store.button0 = (typing) ? 0 : this.button0;
2842         //button1?!
2843         store.button2 = (typing) ? 0 : this.button2;
2844         store.button3 = (typing) ? 0 : this.button3;
2845         store.button4 = this.button4;
2846         store.button5 = (typing) ? 0 : this.button5;
2847         store.button6 = this.button6;
2848         store.button7 = this.button7;
2849         store.button8 = this.button8;
2850         store.button9 = this.button9;
2851         store.button10 = this.button10;
2852         store.button11 = this.button11;
2853         store.button12 = this.button12;
2854         store.button13 = this.button13;
2855         store.button14 = this.button14;
2856         store.button15 = this.button15;
2857         store.button16 = this.button16;
2858         store.buttonuse = this.buttonuse;
2859         store.buttonchat = this.buttonchat;
2860
2861         store.cursor_active = this.cursor_active;
2862         store.cursor_screen = this.cursor_screen;
2863         store.cursor_trace_start = this.cursor_trace_start;
2864         store.cursor_trace_endpos = this.cursor_trace_endpos;
2865         store.cursor_trace_ent = this.cursor_trace_ent;
2866
2867         store.ping = this.ping;
2868         store.ping_packetloss = this.ping_packetloss;
2869         store.ping_movementloss = this.ping_movementloss;
2870
2871         store.v_angle = this.v_angle;
2872         store.movement = (typing) ? '0 0 0' : this.movement;
2873 }
2874
2875 NET_HANDLE(fpsreport, bool)
2876 {
2877         int fps = ReadShort();
2878         PlayerScore_Set(sender, SP_FPS, fps);
2879         return true;
2880 }