qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/overkill/oknex.qh>
  25 #include <common/mutators/mutator/waypoints/all.qh>
  26 #include <common/net_linked.qh>
  27 #include <common/net_notice.qh>
  28 #include <common/notifications/all.qh>
  29 #include <common/physics/player.qh>
  30 #include <common/playerstats.qh>
  31 #include <common/state.qh>
  32 #include <common/stats.qh>
  33 #include <common/vehicles/all.qh>
  34 #include <common/vehicles/sv_vehicles.qh>
  35 #include <common/viewloc.qh>
  36 #include <common/weapons/_all.qh>
  37 #include <common/weapons/weapon/vortex.qh>
  38 #include <common/wepent.qh>
  39 #include <lib/csqcmodel/sv_model.qh>
  40 #include <lib/warpzone/common.qh>
  41 #include <lib/warpzone/server.qh>
  42 #include <server/anticheat.qh>
  43 #include <server/antilag.qh>
  44 #include <server/bot/api.qh>
  45 #include <server/campaign.qh>
  46 #include <server/chat.qh>
  47 #include <server/cheats.qh>
  48 #include <server/clientkill.qh>
  49 #include <server/command/common.qh>
  50 #include <server/command/common.qh>
  51 #include <server/command/vote.qh>
  52 #include <server/compat/quake3.qh>
  53 #include <server/damage.qh>
  54 #include <server/gamelog.qh>
  55 #include <server/handicap.qh>
  56 #include <server/hook.qh>
  57 #include <server/impulse.qh>
  58 #include <server/intermission.qh>
  59 #include <server/ipban.qh>
  60 #include <server/main.qh>
  61 #include <server/mutators/_mod.qh>
  62 #include <server/player.qh>
  63 #include <server/portals.qh>
  64 #include <server/race.qh>
  65 #include <server/resources.qh>
  66 #include <server/scores.qh>
  67 #include <server/scores_rules.qh>
  68 #include <server/spawnpoints.qh>
  69 #include <server/teamplay.qh>
  70 #include <server/weapons/accuracy.qh>
  71 #include <server/weapons/common.qh>
  72 #include <server/weapons/hitplot.qh>
  73 #include <server/weapons/selection.qh>
  74 #include <server/weapons/weaponsystem.qh>
  75 #include <server/world.qh>
  76
  77 STATIC_METHOD(Client, Add, void(Client this, int _team))
  78 {
  79     ClientConnect(this);
  80     TRANSMUTE(Player, this);
  81     this.frame = 12; // 7
  82     this.team = _team;
  83     PutClientInServer(this);
  84 }
  85
  86 STATIC_METHOD(Client, Remove, void(Client this))
  87 {
  88     TRANSMUTE(Observer, this);
  89     PutClientInServer(this);
  90     ClientDisconnect(this);
  91 }
  92
  93 void send_CSQC_teamnagger() {
  94         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  95 }
  96
  97 int CountSpectators(entity player, entity to)
  98 {
  99         if(!player) { return 0; } // not sure how, but best to be safe
 100
 101         int spec_count = 0;
 102
 103         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 104         {
 105                 spec_count++;
 106         });
 107
 108         return spec_count;
 109 }
 110
 111 void WriteSpectators(entity player, entity to)
 112 {
 113         if(!player) { return; } // not sure how, but best to be safe
 114
 115         int spec_count = 0;
 116         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 117         {
 118                 if(spec_count >= MAX_SPECTATORS)
 119                         break;
 120                 WriteByte(MSG_ENTITY, num_for_edict(it));
 121                 ++spec_count;
 122         });
 123 }
 124
 125 bool ClientData_Send(entity this, entity to, int sf)
 126 {
 127         assert(to == this.owner, return false);
 128
 129         entity e = to;
 130         if (IS_SPEC(e)) e = e.enemy;
 131
 132         sf = 0;
 133         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 134         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 135         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 136         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 137
 138         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 139         WriteByte(MSG_ENTITY, sf);
 140
 141         if (sf & BIT(1))
 142                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 143
 144         if(sf & BIT(4))
 145         {
 146                 float specs = CountSpectators(e, to);
 147                 WriteByte(MSG_ENTITY, specs);
 148                 WriteSpectators(e, to);
 149         }
 150
 151         return true;
 152 }
 153
 154 void ClientData_Attach(entity this)
 155 {
 156         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 157         CS(this).clientdata.drawonlytoclient = this;
 158         CS(this).clientdata.owner = this;
 159 }
 160
 161 void ClientData_Detach(entity this)
 162 {
 163         delete(CS(this).clientdata);
 164         CS(this).clientdata = NULL;
 165 }
 166
 167 void ClientData_Touch(entity e)
 168 {
 169         entity cd = CS(e).clientdata;
 170         if (cd) { cd.SendFlags = 1; }
 171
 172         // make it spectatable
 173         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 174         {
 175                 entity cd = CS(it).clientdata;
 176                 if (cd) { cd.SendFlags = 1; }
 177         });
 178 }
 179
 180
 181 /*
 182 =============
 183 CheckPlayerModel
 184
 185 Checks if the argument string can be a valid playermodel.
 186 Returns a valid one in doubt.
 187 =============
 188 */
 189 string FallbackPlayerModel;
 190 string CheckPlayerModel(string plyermodel) {
 191         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 192         {
 193                 // note: we cannot summon Don Strunzone here, some player may
 194                 // still have the model string set. In case anyone manages how
 195                 // to change a cvar default, we'll have a small leak here.
 196                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 197         }
 198         // only in right path
 199         if( substring(plyermodel,0,14) != "models/player/")
 200                 return FallbackPlayerModel;
 201         // only good file extensions
 202         if(substring(plyermodel,-4,4) != ".zym")
 203         if(substring(plyermodel,-4,4) != ".dpm")
 204         if(substring(plyermodel,-4,4) != ".iqm")
 205         if(substring(plyermodel,-4,4) != ".md3")
 206         if(substring(plyermodel,-4,4) != ".psk")
 207                 return FallbackPlayerModel;
 208         // forbid the LOD models
 209         if(substring(plyermodel, -9,5) == "_lod1")
 210                 return FallbackPlayerModel;
 211         if(substring(plyermodel, -9,5) == "_lod2")
 212                 return FallbackPlayerModel;
 213         if(plyermodel != strtolower(plyermodel))
 214                 return FallbackPlayerModel;
 215         // also, restrict to server models
 216         if(autocvar_sv_servermodelsonly)
 217         {
 218                 if(!fexists(plyermodel))
 219                         return FallbackPlayerModel;
 220         }
 221         return plyermodel;
 222 }
 223
 224 void setplayermodel(entity e, string modelname)
 225 {
 226         precache_model(modelname);
 227         _setmodel(e, modelname);
 228         player_setupanimsformodel(e);
 229         if(!autocvar_g_debug_globalsounds)
 230                 UpdatePlayerSounds(e);
 231 }
 232
 233 /** putting a client as observer in the server */
 234 void PutObserverInServer(entity this)
 235 {
 236         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 237         PlayerState_detach(this);
 238
 239         if (IS_PLAYER(this))
 240         {
 241                 if(GetResource(this, RES_HEALTH) >= 1)
 242                 {
 243                         // despawn effect
 244                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 245                 }
 246
 247                 // was a player, recount votes and ready status
 248                 if(IS_REAL_CLIENT(this))
 249                 {
 250                         if (vote_called) { VoteCount(false); }
 251                         ReadyCount();
 252                 }
 253         }
 254
 255         entity spot = SelectSpawnPoint(this, true);
 256         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 257         this.angles = vec2(spot.angles);
 258         this.fixangle = true;
 259         // offset it so that the spectator spawns higher off the ground, looks better this way
 260         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 261         if (IS_REAL_CLIENT(this))
 262         {
 263                 msg_entity = this;
 264                 WriteByte(MSG_ONE, SVC_SETVIEW);
 265                 WriteEntity(MSG_ONE, this);
 266         }
 267         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 268         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 269         if(!autocvar_g_debug_globalsounds)
 270         {
 271                 // needed for player sounds
 272                 this.model = "";
 273                 FixPlayermodel(this);
 274         }
 275         setmodel(this, MDL_Null);
 276         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 277         this.view_ofs = '0 0 0';
 278
 279         RemoveGrapplingHooks(this);
 280         Portal_ClearAll(this);
 281         Unfreeze(this, false);
 282         SetSpectatee(this, NULL);
 283
 284         if (this.alivetime)
 285         {
 286                 if (!warmup_stage)
 287                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 288                 this.alivetime = 0;
 289         }
 290
 291         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 292
 293         WaypointSprite_PlayerDead(this);
 294
 295         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 296                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 297
 298         accuracy_resend(this);
 299
 300         CS(this).spectatortime = time;
 301         if(this.bot_attack)
 302                 IL_REMOVE(g_bot_targets, this);
 303         this.bot_attack = false;
 304         if(this.monster_attack)
 305                 IL_REMOVE(g_monster_targets, this);
 306         this.monster_attack = false;
 307         STAT(HUD, this) = HUD_NORMAL;
 308         TRANSMUTE(Observer, this);
 309         this.iscreature = false;
 310         this.teleportable = TELEPORT_SIMPLE;
 311         if(this.damagedbycontents)
 312                 IL_REMOVE(g_damagedbycontents, this);
 313         this.damagedbycontents = false;
 314         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 315         SetSpectatee_status(this, etof(this));
 316         this.takedamage = DAMAGE_NO;
 317         this.solid = SOLID_NOT;
 318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 319         this.flags = FL_CLIENT | FL_NOTARGET;
 320         this.effects = 0;
 321         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 322         this.pauserotarmor_finished = 0;
 323         this.pauserothealth_finished = 0;
 324         this.pauseregen_finished = 0;
 325         this.damageforcescale = 0;
 326         this.death_time = 0;
 327         this.respawn_flags = 0;
 328         this.respawn_time = 0;
 329         STAT(RESPAWN_TIME, this) = 0;
 330         this.alpha = 0;
 331         this.scale = 0;
 332         this.fade_time = 0;
 333         this.pain_finished = 0;
 334         STAT(STRENGTH_FINISHED, this) = 0;
 335         STAT(INVINCIBLE_FINISHED, this) = 0;
 336         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 337         STAT(AIR_FINISHED, this) = 0;
 338         //this.dphitcontentsmask = 0;
 339         this.dphitcontentsmask = DPCONTENTS_SOLID;
 340         if (autocvar_g_playerclip_collisions)
 341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         UNSET_DUCKED(this);
 348         STAT(REVIVE_PROGRESS, this) = 0;
 349         this.revival_time = 0;
 350         this.draggable = drag_undraggable;
 351
 352         this.items = 0;
 353         STAT(WEAPONS, this) = '0 0 0';
 354         this.drawonlytoclient = this;
 355
 356         this.viewloc = NULL;
 357
 358         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 359
 360         this.weaponmodel = "";
 361         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 362         {
 363                 this.weaponentities[slot] = NULL;
 364         }
 365         this.exteriorweaponentity = NULL;
 366         CS(this).killcount = FRAGS_SPECTATOR;
 367         this.velocity = '0 0 0';
 368         this.avelocity = '0 0 0';
 369         this.punchangle = '0 0 0';
 370         this.punchvector = '0 0 0';
 371         this.oldvelocity = this.velocity;
 372         this.fire_endtime = -1;
 373         this.event_damage = func_null;
 374         this.event_heal = func_null;
 375
 376         for(int slot = 0; slot < MAX_AXH; ++slot)
 377         {
 378                 entity axh = this.(AuxiliaryXhair[slot]);
 379                 this.(AuxiliaryXhair[slot]) = NULL;
 380
 381                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 382                         delete(axh);
 383         }
 384
 385         if (mutator_returnvalue)
 386         {
 387                 // mutator prevents resetting teams+score
 388         }
 389         else
 390         {
 391                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 392                 this.frags = FRAGS_SPECTATOR;
 393         }
 394         if (CS(this).just_joined)
 395                 CS(this).just_joined = false;
 396 }
 397
 398 int player_getspecies(entity this)
 399 {
 400         get_model_parameters(this.model, this.skin);
 401         int s = get_model_parameters_species;
 402         get_model_parameters(string_null, 0);
 403         if (s < 0) return SPECIES_HUMAN;
 404         return s;
 405 }
 406
 407 .float model_randomizer;
 408 void FixPlayermodel(entity player)
 409 {
 410         string defaultmodel = "";
 411         int defaultskin = 0;
 412         if(autocvar_sv_defaultcharacter)
 413         {
 414                 if(teamplay)
 415                 {
 416                         switch(player.team)
 417                         {
 418                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 419                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 420                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 421                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 422                         }
 423                 }
 424
 425                 if(defaultmodel == "")
 426                 {
 427                         defaultmodel = autocvar_sv_defaultplayermodel;
 428                         defaultskin = autocvar_sv_defaultplayerskin;
 429                 }
 430
 431                 int n = tokenize_console(defaultmodel);
 432                 if(n > 0)
 433                 {
 434                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 435                         // However, do NOT randomize if the player-selected model is in the list.
 436                         for (int i = 0; i < n; ++i)
 437                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 438                                         defaultmodel = argv(i);
 439                 }
 440
 441                 int i = strstrofs(defaultmodel, ":", 0);
 442                 if(i >= 0)
 443                 {
 444                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 445                         defaultmodel = substring(defaultmodel, 0, i);
 446                 }
 447         }
 448         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 449         {
 450                 if(teamplay)
 451                 {
 452                         switch(player.team)
 453                         {
 454                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 455                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 456                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 457                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 458                         }
 459                 }
 460
 461                 if(!defaultskin)
 462                         defaultskin = autocvar_sv_defaultplayerskin;
 463         }
 464
 465         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 466         defaultmodel = M_ARGV(0, string);
 467         defaultskin = M_ARGV(1, int);
 468
 469         bool chmdl = false;
 470         int oldskin;
 471         if(defaultmodel != "")
 472         {
 473                 if (defaultmodel != player.model)
 474                 {
 475                         vector m1 = player.mins;
 476                         vector m2 = player.maxs;
 477                         setplayermodel (player, defaultmodel);
 478                         setsize (player, m1, m2);
 479                         chmdl = true;
 480                 }
 481
 482                 oldskin = player.skin;
 483                 player.skin = defaultskin;
 484         } else {
 485                 if (player.playermodel != player.model || player.playermodel == "")
 486                 {
 487                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 488                         vector m1 = player.mins;
 489                         vector m2 = player.maxs;
 490                         setplayermodel (player, player.playermodel);
 491                         setsize (player, m1, m2);
 492                         chmdl = true;
 493                 }
 494
 495                 if(!autocvar_sv_defaultcharacterskin)
 496                 {
 497                         oldskin = player.skin;
 498                         player.skin = stof(player.playerskin);
 499                 }
 500                 else
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = defaultskin;
 504                 }
 505         }
 506
 507         if(chmdl || oldskin != player.skin) // model or skin has changed
 508         {
 509                 player.species = player_getspecies(player); // update species
 510                 if(!autocvar_g_debug_globalsounds)
 511                         UpdatePlayerSounds(player); // update skin sounds
 512         }
 513
 514         if(!teamplay)
 515                 if(strlen(autocvar_sv_defaultplayercolors))
 516                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 517                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 518 }
 519
 520 void PutPlayerInServer(entity this)
 521 {
 522         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 523
 524         PlayerState_attach(this);
 525         accuracy_resend(this);
 526
 527         if (this.team < 0)
 528                 TeamBalance_JoinBestTeam(this);
 529
 530         entity spot = SelectSpawnPoint(this, false);
 531         if (!spot) {
 532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 533                 return; // spawn failed
 534         }
 535
 536         TRANSMUTE(Player, this);
 537
 538         CS(this).wasplayer = true;
 539         this.iscreature = true;
 540         this.teleportable = TELEPORT_NORMAL;
 541         if(!this.damagedbycontents)
 542                 IL_PUSH(g_damagedbycontents, this);
 543         this.damagedbycontents = true;
 544         set_movetype(this, MOVETYPE_WALK);
 545         this.solid = SOLID_SLIDEBOX;
 546         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 547         if (autocvar_g_playerclip_collisions)
 548                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 549         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 550                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 551         this.frags = FRAGS_PLAYER;
 552         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 553         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 554         if (autocvar__notarget)
 555                 this.flags |= FL_NOTARGET;
 556         this.takedamage = DAMAGE_AIM;
 557         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 558
 559         if (warmup_stage) {
 560                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 561                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 562                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 563                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 564                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 565                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 566                 SetResource(this, RES_HEALTH, warmup_start_health);
 567                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 568                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 569         } else {
 570                 SetResource(this, RES_SHELLS, start_ammo_shells);
 571                 SetResource(this, RES_BULLETS, start_ammo_nails);
 572                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 573                 SetResource(this, RES_CELLS, start_ammo_cells);
 574                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 575                 SetResource(this, RES_FUEL, start_ammo_fuel);
 576                 SetResource(this, RES_HEALTH, start_health);
 577                 SetResource(this, RES_ARMOR, start_armorvalue);
 578                 STAT(WEAPONS, this) = start_weapons;
 579                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 580                 {
 581                         GiveRandomWeapons(this, random_start_weapons_count,
 582                                 autocvar_g_random_start_weapons, random_start_ammo);
 583                 }
 584         }
 585         SetSpectatee_status(this, 0);
 586
 587         PS(this).dual_weapons = '0 0 0';
 588
 589         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 590
 591         this.items = start_items;
 592
 593         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 594         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 595         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 596         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 597         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 598         if (!sv_ready_restart_after_countdown && time < game_starttime)
 599         {
 600                 float f = game_starttime - time;
 601                 this.spawnshieldtime += f;
 602                 this.pauserotarmor_finished += f;
 603                 this.pauserothealth_finished += f;
 604                 this.pauseregen_finished += f;
 605         }
 606
 607         this.damageforcescale = autocvar_g_player_damageforcescale;
 608         this.death_time = 0;
 609         this.respawn_flags = 0;
 610         this.respawn_time = 0;
 611         STAT(RESPAWN_TIME, this) = 0;
 612         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 613         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 614         this.fade_time = 0;
 615         this.pain_finished = 0;
 616         this.pushltime = 0;
 617         setthink(this, func_null); // players have no think function
 618         this.nextthink = 0;
 619         this.dmg_team = 0;
 620         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 621
 622         this.deadflag = DEAD_NO;
 623
 624         this.angles = spot.angles;
 625         this.angles_z = 0; // never spawn tilted even if the spot says to
 626         if (IS_BOT_CLIENT(this))
 627         {
 628                 this.v_angle = this.angles;
 629                 bot_aim_reset(this);
 630         }
 631         this.fixangle = true; // turn this way immediately
 632         this.oldvelocity = this.velocity = '0 0 0';
 633         this.avelocity = '0 0 0';
 634         this.punchangle = '0 0 0';
 635         this.punchvector = '0 0 0';
 636
 637         STAT(STRENGTH_FINISHED, this) = 0;
 638         STAT(INVINCIBLE_FINISHED, this) = 0;
 639         this.fire_endtime = -1;
 640         STAT(REVIVE_PROGRESS, this) = 0;
 641         this.revival_time = 0;
 642
 643         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 644         STAT(BUFFS, this) = 0;
 645         STAT(BUFF_TIME, this) = 0;
 646
 647         STAT(AIR_FINISHED, this) = 0;
 648         this.waterlevel = WATERLEVEL_NONE;
 649         this.watertype = CONTENT_EMPTY;
 650
 651         entity spawnevent = new_pure(spawnevent);
 652         spawnevent.owner = this;
 653         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 654
 655         // Cut off any still running player sounds.
 656         stopsound(this, CH_PLAYER_SINGLE);
 657
 658         this.model = "";
 659         FixPlayermodel(this);
 660         this.drawonlytoclient = NULL;
 661
 662         this.viewloc = NULL;
 663
 664         for(int slot = 0; slot < MAX_AXH; ++slot)
 665         {
 666                 entity axh = this.(AuxiliaryXhair[slot]);
 667                 this.(AuxiliaryXhair[slot]) = NULL;
 668
 669                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 670                         delete(axh);
 671         }
 672
 673         this.spawnpoint_targ = NULL;
 674
 675         UNSET_DUCKED(this);
 676         this.view_ofs = STAT(PL_VIEW_OFS, this);
 677         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 678         this.spawnorigin = spot.origin;
 679         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 680         // don't reset back to last position, even if new position is stuck in solid
 681         this.oldorigin = this.origin;
 682         if(this.conveyor)
 683                 IL_REMOVE(g_conveyed, this);
 684         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 685         if(this.swampslug)
 686                 IL_REMOVE(g_swamped, this);
 687         this.swampslug = NULL;
 688         this.swamp_interval = 0;
 689         if(this.ladder_entity)
 690                 IL_REMOVE(g_ladderents, this);
 691         this.ladder_entity = NULL;
 692         IL_EACH(g_counters, it.realowner == this,
 693         {
 694                 delete(it);
 695         });
 696         STAT(HUD, this) = HUD_NORMAL;
 697
 698         this.event_damage = PlayerDamage;
 699         this.event_heal = PlayerHeal;
 700
 701         this.draggable = func_null;
 702
 703         if(!this.bot_attack)
 704                 IL_PUSH(g_bot_targets, this);
 705         this.bot_attack = true;
 706         if(!this.monster_attack)
 707                 IL_PUSH(g_monster_targets, this);
 708         this.monster_attack = true;
 709         navigation_dynamicgoal_init(this, false);
 710
 711         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 712
 713         // player was spectator
 714         if (CS(this).killcount == FRAGS_SPECTATOR) {
 715                 PlayerScore_Clear(this);
 716                 CS(this).killcount = 0;
 717                 CS(this).startplaytime = time;
 718         }
 719
 720         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 721         {
 722                 .entity weaponentity = weaponentities[slot];
 723                 CL_SpawnWeaponentity(this, weaponentity);
 724         }
 725         this.alpha = default_player_alpha;
 726         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 727         this.exteriorweaponentity.alpha = default_weapon_alpha;
 728
 729         this.speedrunning = false;
 730
 731         this.counter_cnt = 0;
 732         this.fragsfilter_cnt = 0;
 733
 734         target_voicescript_clear(this);
 735
 736         // reset fields the weapons may use
 737         FOREACH(Weapons, true, {
 738                 it.wr_resetplayer(it, this);
 739                         // reload all reloadable weapons
 740                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 741                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 742                         {
 743                                 .entity weaponentity = weaponentities[slot];
 744                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 745                         }
 746                 }
 747         });
 748
 749         {
 750                 string s = spot.target;
 751                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 752                         spot.target = string_null;
 753                 SUB_UseTargets(spot, this, NULL);
 754                 if(g_assault || g_race)
 755                         spot.target = s;
 756         }
 757
 758         Unfreeze(this, false);
 759
 760         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 761
 762         if (autocvar_spawn_debug)
 763         {
 764                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 765                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 766         }
 767
 768         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 769         {
 770                 .entity weaponentity = weaponentities[slot];
 771                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 772                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 773                 else
 774                         this.(weaponentity).m_switchweapon = WEP_Null;
 775                 this.(weaponentity).m_weapon = WEP_Null;
 776                 this.(weaponentity).weaponname = "";
 777                 this.(weaponentity).m_switchingweapon = WEP_Null;
 778                 this.(weaponentity).cnt = -1;
 779         }
 780
 781         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 782
 783         if (CS(this).impulse) ImpulseCommands(this);
 784
 785         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 786         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 787         {
 788                 .entity weaponentity = weaponentities[slot];
 789                 W_WeaponFrame(this, weaponentity);
 790         }
 791
 792         if (!warmup_stage && !this.alivetime)
 793                 this.alivetime = time;
 794
 795         antilag_clear(this, CS(this));
 796 }
 797
 798 /** Called when a client spawns in the server */
 799 void PutClientInServer(entity this)
 800 {
 801         if (IS_BOT_CLIENT(this)) {
 802                 TRANSMUTE(Player, this);
 803         } else if (IS_REAL_CLIENT(this)) {
 804                 msg_entity = this;
 805                 WriteByte(MSG_ONE, SVC_SETVIEW);
 806                 WriteEntity(MSG_ONE, this);
 807         }
 808         if (game_stopped)
 809                 TRANSMUTE(Observer, this);
 810
 811         SetSpectatee(this, NULL);
 812
 813         // reset player keys
 814         if(PS(this))
 815                 PS(this).itemkeys = 0;
 816
 817         MUTATOR_CALLHOOK(PutClientInServer, this);
 818
 819         if (IS_OBSERVER(this)) {
 820                 PutObserverInServer(this);
 821         } else if (IS_PLAYER(this)) {
 822                 PutPlayerInServer(this);
 823         }
 824 }
 825
 826 // TODO do we need all these fields, or should we stop autodetecting runtime
 827 // changes and just have a console command to update this?
 828 bool ClientInit_SendEntity(entity this, entity to, int sf)
 829 {
 830         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 831         return = true;
 832         msg_entity = to;
 833         // MSG_INIT replacement
 834         // TODO: make easier to use
 835         Registry_send_all();
 836         W_PROP_reload(MSG_ONE, to);
 837         ClientInit_misc(this);
 838         MUTATOR_CALLHOOK(Ent_Init);
 839 }
 840 void ClientInit_misc(entity this)
 841 {
 842         int channel = MSG_ONE;
 843         WriteHeader(channel, ENT_CLIENT_INIT);
 844         WriteByte(channel, g_nexball_meter_period * 32);
 845         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 846         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 847         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 848         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 849         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 850         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 851         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 852         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 853
 854         if(autocvar_sv_foginterval && world.fog != "")
 855                 WriteString(channel, world.fog);
 856         else
 857                 WriteString(channel, "");
 858         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 859         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 860         WriteByte(channel, serverflags);
 861         WriteCoord(channel, autocvar_g_trueaim_minrange);
 862 }
 863
 864 void ClientInit_CheckUpdate(entity this)
 865 {
 866         this.nextthink = time;
 867         if(this.count != autocvar_g_balance_armor_blockpercent)
 868         {
 869                 this.count = autocvar_g_balance_armor_blockpercent;
 870                 this.SendFlags |= 1;
 871         }
 872         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 873         {
 874                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 875                 this.SendFlags |= 1;
 876         }
 877 }
 878
 879 void ClientInit_Spawn()
 880 {
 881         entity e = new_pure(clientinit);
 882         setthink(e, ClientInit_CheckUpdate);
 883         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 884
 885         ClientInit_CheckUpdate(e);
 886 }
 887
 888 /*
 889 =============
 890 SetNewParms
 891 =============
 892 */
 893 void SetNewParms ()
 894 {
 895         // initialize parms for a new player
 896         parm1 = -(86400 * 366);
 897
 898         MUTATOR_CALLHOOK(SetNewParms);
 899 }
 900
 901 /*
 902 =============
 903 SetChangeParms
 904 =============
 905 */
 906 void SetChangeParms (entity this)
 907 {
 908         // save parms for level change
 909         parm1 = CS(this).parm_idlesince - time;
 910
 911         MUTATOR_CALLHOOK(SetChangeParms);
 912 }
 913
 914 /*
 915 =============
 916 DecodeLevelParms
 917 =============
 918 */
 919 void DecodeLevelParms(entity this)
 920 {
 921         // load parms
 922         CS(this).parm_idlesince = parm1;
 923         if (CS(this).parm_idlesince == -(86400 * 366))
 924                 CS(this).parm_idlesince = time;
 925
 926         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 927         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 928
 929         MUTATOR_CALLHOOK(DecodeLevelParms);
 930 }
 931
 932 void FixClientCvars(entity e)
 933 {
 934         // send prediction settings to the client
 935         stuffcmd(e, "\nin_bindmap 0 0\n");
 936         if(autocvar_g_antilag == 3) // client side hitscan
 937                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 938         if(autocvar_sv_gentle)
 939                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 940
 941         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 942         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 943
 944         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 945
 946         MUTATOR_CALLHOOK(FixClientCvars, e);
 947 }
 948
 949 bool findinlist_abbrev(string tofind, string list)
 950 {
 951         if(list == "" || tofind == "")
 952                 return false; // empty list or search, just return
 953
 954         // this function allows abbreviated strings!
 955         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 956         {
 957                 return true;
 958         });
 959
 960         return false;
 961 }
 962
 963 bool PlayerInIPList(entity p, string iplist)
 964 {
 965         // some safety checks (never allow local?)
 966         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 967                 return false;
 968
 969         return findinlist_abbrev(p.netaddress, iplist);
 970 }
 971
 972 bool PlayerInIDList(entity p, string idlist)
 973 {
 974         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 975         if(!p.crypto_idfp)
 976                 return false;
 977
 978         return findinlist_abbrev(p.crypto_idfp, idlist);
 979 }
 980
 981 bool PlayerInList(entity player, string list)
 982 {
 983         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 984 }
 985
 986 #ifdef DP_EXT_PRECONNECT
 987 /*
 988 =============
 989 ClientPreConnect
 990
 991 Called once (not at each match start) when a client begins a connection to the server
 992 =============
 993 */
 994 void ClientPreConnect(entity this)
 995 {
 996         if(autocvar_sv_eventlog)
 997         {
 998                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 999                         this.playerid,
1000                         etof(this),
1001                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1002                 ));
1003         }
1004 }
1005 #endif
1006
1007 string GetClientVersionMessage(entity this)
1008 {
1009         if (CS(this).version_mismatch) {
1010                 if(CS(this).version < autocvar_gameversion) {
1011                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1012                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1013                 } else {
1014                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1015                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1016                 }
1017         } else {
1018                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1019         }
1020 }
1021
1022 string getwelcomemessage(entity this)
1023 {
1024         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1025         string modifications = M_ARGV(0, string);
1026
1027         if(g_weaponarena)
1028         {
1029                 if(g_weaponarena_random)
1030                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1031                 else
1032                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1033         }
1034         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1035                 modifications = strcat(modifications, ", No start weapons");
1036         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1037                 modifications = strcat(modifications, ", Low gravity");
1038         if(g_weapon_stay && !g_cts)
1039                 modifications = strcat(modifications, ", Weapons stay");
1040         if(autocvar_g_jetpack)
1041                 modifications = strcat(modifications, ", Jet pack");
1042         if(autocvar_g_powerups == 0)
1043                 modifications = strcat(modifications, ", No powerups");
1044         if(autocvar_g_powerups > 0)
1045                 modifications = strcat(modifications, ", Powerups");
1046         modifications = substring(modifications, 2, strlen(modifications) - 2);
1047
1048         string versionmessage = GetClientVersionMessage(this);
1049         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1050
1051         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1052
1053         if(modifications != "")
1054                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1055
1056         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1057         {
1058                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1059                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1060         }
1061
1062         if (cache_mutatormsg != "") {
1063                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1064         }
1065
1066         string mutator_msg = "";
1067         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1068         mutator_msg = M_ARGV(0, string);
1069
1070         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1071
1072         string motd = autocvar_sv_motd;
1073         if (motd != "") {
1074                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1075         }
1076         return s;
1077 }
1078
1079 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1080
1081 /**
1082 =============
1083 ClientConnect
1084
1085 Called when a client connects to the server
1086 =============
1087 */
1088 void ClientConnect(entity this)
1089 {
1090         if (Ban_MaybeEnforceBanOnce(this)) return;
1091         assert(!IS_CLIENT(this), return);
1092         this.flags |= FL_CLIENT;
1093         assert(player_count >= 0, player_count = 0);
1094
1095         TRANSMUTE(Client, this);
1096         CS(this).version_nagtime = time + 10 + random() * 10;
1097
1098         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1099
1100         bot_clientconnect(this);
1101
1102         Player_DetermineForcedTeam(this);
1103
1104         TRANSMUTE(Observer, this);
1105
1106         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1107
1108         // always track bots, don't ask for cl_allow_uidtracking
1109         if (IS_BOT_CLIENT(this))
1110                 PlayerStats_GameReport_AddPlayer(this);
1111         else
1112                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1113
1114         if (autocvar_sv_eventlog)
1115                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1116
1117         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1118
1119         stuffcmd(this, clientstuff, "\n");
1120         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1121
1122         FixClientCvars(this);
1123
1124         // get version info from player
1125         stuffcmd(this, "cmd clientversion $gameversion\n");
1126
1127         // notify about available teams
1128         if (teamplay)
1129         {
1130                 entity balance = TeamBalance_CheckAllowedTeams(this);
1131                 int t = TeamBalance_GetAllowedTeams(balance);
1132                 TeamBalance_Destroy(balance);
1133                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1134         }
1135         else
1136         {
1137                 stuffcmd(this, "set _teams_available 0\n");
1138         }
1139
1140         bot_relinkplayerlist();
1141
1142         CS(this).spectatortime = time;
1143         if (blockSpectators)
1144         {
1145                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1146         }
1147
1148         CS(this).jointime = time;
1149
1150         if (IS_REAL_CLIENT(this))
1151         {
1152                 if (g_weaponarena_weapons == WEPSET(TUBA))
1153                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1154         }
1155
1156         if (!autocvar_sv_foginterval && world.fog != "")
1157                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1158
1159         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1160                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1161                         send_CSQC_teamnagger();
1162
1163         CSQCMODEL_AUTOINIT(this);
1164
1165         CS(this).model_randomizer = random();
1166
1167         if (IS_REAL_CLIENT(this))
1168                 sv_notice_join(this);
1169
1170         this.move_qcphysics = autocvar_sv_qcphysics;
1171
1172         // update physics stats (players can spawn before physics runs)
1173         Physics_UpdateStats(this);
1174
1175         IL_EACH(g_initforplayer, it.init_for_player, {
1176                 it.init_for_player(it, this);
1177         });
1178
1179         Handicap_Initialize(this);
1180
1181         MUTATOR_CALLHOOK(ClientConnect, this);
1182
1183         if (IS_REAL_CLIENT(this))
1184         {
1185                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1186                 {
1187                         CS(this).motd_actived_time = -1;
1188                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1189                 }
1190         }
1191 }
1192 /*
1193 =============
1194 ClientDisconnect
1195
1196 Called when a client disconnects from the server
1197 =============
1198 */
1199 .entity chatbubbleentity;
1200 void ClientDisconnect(entity this)
1201 {
1202         assert(IS_CLIENT(this), return);
1203
1204         PlayerStats_GameReport_FinalizePlayer(this);
1205         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1206         if (CS(this).active_minigame) part_minigame(this);
1207         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1208
1209         if (autocvar_sv_eventlog)
1210                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1211
1212         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1213
1214         if(IS_SPEC(this))
1215                 SetSpectatee(this, NULL);
1216
1217         MUTATOR_CALLHOOK(ClientDisconnect, this);
1218
1219         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1220         strfree(CS(this).weaponorder_byimpulse);
1221         ClientState_detach(this);
1222
1223         Portal_ClearAll(this);
1224
1225         Unfreeze(this, false);
1226
1227         RemoveGrapplingHooks(this);
1228
1229         // Here, everything has been done that requires this player to be a client.
1230
1231         this.flags &= ~FL_CLIENT;
1232
1233         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1234         if (this.killindicator) delete(this.killindicator);
1235
1236         IL_EACH(g_counters, it.realowner == this,
1237         {
1238                 delete(it);
1239         });
1240
1241         WaypointSprite_PlayerGone(this);
1242
1243         bot_relinkplayerlist();
1244
1245         strfree(this.clientstatus);
1246         if (this.personal) delete(this.personal);
1247
1248         this.playerid = 0;
1249         ReadyCount();
1250         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1251
1252         ONREMOVE(this);
1253 }
1254
1255 void ChatBubbleThink(entity this)
1256 {
1257         this.nextthink = time;
1258         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1259         {
1260                 if(this.owner) // but why can that ever be NULL?
1261                         this.owner.chatbubbleentity = NULL;
1262                 delete(this);
1263                 return;
1264         }
1265
1266         this.mdl = "";
1267
1268         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1269         {
1270                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1271                         this.mdl = "models/sprites/minigame_busy.iqm";
1272                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1273                         this.mdl = "models/misc/chatbubble.spr";
1274         }
1275
1276         if ( this.model != this.mdl )
1277                 _setmodel(this, this.mdl);
1278
1279 }
1280
1281 void UpdateChatBubble(entity this)
1282 {
1283         if (this.alpha < 0)
1284                 return;
1285         // spawn a chatbubble entity if needed
1286         if (!this.chatbubbleentity)
1287         {
1288                 this.chatbubbleentity = new(chatbubbleentity);
1289                 this.chatbubbleentity.owner = this;
1290                 this.chatbubbleentity.exteriormodeltoclient = this;
1291                 setthink(this.chatbubbleentity, ChatBubbleThink);
1292                 this.chatbubbleentity.nextthink = time;
1293                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1294                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1295                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1296                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1297                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1298                 //this.chatbubbleentity.model = "";
1299                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1300         }
1301 }
1302
1303 void calculate_player_respawn_time(entity this)
1304 {
1305         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1306                 return;
1307
1308         float gametype_setting_tmp;
1309         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1310         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1311         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1312         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1313         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1314         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1315
1316         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1317         if (teamplay)
1318         {
1319                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1320                         if(it.team == this.team)
1321                                 ++pcount;
1322                 });
1323                 if (sdelay_small_count == 0)
1324                         sdelay_small_count = 1;
1325                 if (sdelay_large_count == 0)
1326                         sdelay_large_count = 1;
1327         }
1328         else
1329         {
1330                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1331                         ++pcount;
1332                 });
1333                 if (sdelay_small_count == 0)
1334                 {
1335                         if (IS_INDEPENDENT_PLAYER(this))
1336                         {
1337                                 // Players play independently. No point in requiring enemies.
1338                                 sdelay_small_count = 1;
1339                         }
1340                         else
1341                         {
1342                                 // Players play AGAINST each other. Enemies required.
1343                                 sdelay_small_count = 2;
1344                         }
1345                 }
1346                 if (sdelay_large_count == 0)
1347                 {
1348                         if (IS_INDEPENDENT_PLAYER(this))
1349                         {
1350                                 // Players play independently. No point in requiring enemies.
1351                                 sdelay_large_count = 1;
1352                         }
1353                         else
1354                         {
1355                                 // Players play AGAINST each other. Enemies required.
1356                                 sdelay_large_count = 2;
1357                         }
1358                 }
1359         }
1360
1361         float sdelay;
1362
1363         if (pcount <= sdelay_small_count)
1364                 sdelay = sdelay_small;
1365         else if (pcount >= sdelay_large_count)
1366                 sdelay = sdelay_large;
1367         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1368                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1369
1370         if(waves)
1371                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1372         else
1373                 this.respawn_time = time + sdelay;
1374
1375         if(sdelay < sdelay_max)
1376                 this.respawn_time_max = time + sdelay_max;
1377         else
1378                 this.respawn_time_max = this.respawn_time;
1379
1380         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1381                 this.respawn_countdown = 10; // first number to count down from is 10
1382         else
1383                 this.respawn_countdown = -1; // do not count down
1384
1385         if(autocvar_g_forced_respawn)
1386                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1387 }
1388
1389 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1390 // added to the model skins
1391 /*void UpdateColorModHack()
1392 {
1393         float c;
1394         c = this.clientcolors & 15;
1395         // LordHavoc: only bothering to support white, green, red, yellow, blue
1396              if (!teamplay) this.colormod = '0 0 0';
1397         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1398         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1399         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1400         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1401         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1402         else this.colormod = '1 1 1';
1403 }*/
1404
1405 void respawn(entity this)
1406 {
1407         bool damagedbycontents_prev = this.damagedbycontents;
1408         if(this.alpha >= 0)
1409         {
1410                 if(autocvar_g_respawn_ghosts)
1411                 {
1412                         this.solid = SOLID_NOT;
1413                         this.takedamage = DAMAGE_NO;
1414                         this.damagedbycontents = false;
1415                         set_movetype(this, MOVETYPE_FLY);
1416                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1417                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1418                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1419                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1420                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1421                         if(autocvar_g_respawn_ghosts_time > 0)
1422                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1423                 }
1424                 else
1425                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1426         }
1427
1428         CopyBody(this, 1);
1429         this.damagedbycontents = damagedbycontents_prev;
1430
1431         this.effects |= EF_NODRAW; // prevent another CopyBody
1432         PutClientInServer(this);
1433 }
1434
1435 void play_countdown(entity this, float finished, Sound samp)
1436 {
1437         TC(Sound, samp);
1438         if(IS_REAL_CLIENT(this))
1439                 if(floor(finished - time - frametime) != floor(finished - time))
1440                         if(finished - time < 6)
1441                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1442 }
1443
1444 void player_powerups(entity this)
1445 {
1446         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1447                 this.modelflags |= MF_ROCKET;
1448         else
1449                 this.modelflags &= ~MF_ROCKET;
1450
1451         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1452
1453         if (IS_DEAD(this))
1454         {
1455                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1456                 {
1457                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1458                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1459                         this.items &= ~ITEM_Strength.m_itemid;
1460                         this.items &= ~ITEM_Shield.m_itemid;
1461                         this.items -= (this.items & IT_SUPERWEAPON);
1462                 }
1463         }
1464
1465         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1466                 return;
1467
1468         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1469         int items_prev = this.items;
1470
1471         Fire_ApplyDamage(this);
1472         Fire_ApplyEffect(this);
1473
1474         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1475         {
1476                 if (this.items & ITEM_Strength.m_itemid)
1477                 {
1478                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1479                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1480                         if (time > STAT(STRENGTH_FINISHED, this))
1481                         {
1482                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1483                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1484                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1485                         }
1486                 }
1487                 else
1488                 {
1489                         if (time < STAT(STRENGTH_FINISHED, this))
1490                         {
1491                                 this.items = this.items | ITEM_Strength.m_itemid;
1492                                 if(!g_cts)
1493                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1494                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1495                         }
1496                 }
1497                 if (this.items & ITEM_Shield.m_itemid)
1498                 {
1499                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1500                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1501                         if (time > STAT(INVINCIBLE_FINISHED, this))
1502                         {
1503                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1504                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1505                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1506                         }
1507                 }
1508                 else
1509                 {
1510                         if (time < STAT(INVINCIBLE_FINISHED, this))
1511                         {
1512                                 this.items = this.items | ITEM_Shield.m_itemid;
1513                                 if(!g_cts)
1514                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1515                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1516                         }
1517                 }
1518                 if (this.items & IT_SUPERWEAPON)
1519                 {
1520                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1521                         {
1522                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1523                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1524                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1525                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1526                         }
1527                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1528                         {
1529                                 // don't let them run out
1530                         }
1531                         else
1532                         {
1533                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1534                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1535                                 {
1536                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1537                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1538                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1539                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1540                                 }
1541                         }
1542                 }
1543                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1544                 {
1545                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1546                         {
1547                                 this.items = this.items | IT_SUPERWEAPON;
1548                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1549                                 {
1550                                         if(!g_cts)
1551                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1552                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1553                                 }
1554                         }
1555                         else
1556                         {
1557                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1558                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1559                         }
1560                 }
1561                 else
1562                 {
1563                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1564                 }
1565         }
1566
1567         if(autocvar_g_nodepthtestplayers)
1568                 this.effects = this.effects | EF_NODEPTHTEST;
1569
1570         if(autocvar_g_fullbrightplayers)
1571                 this.effects = this.effects | EF_FULLBRIGHT;
1572
1573         if (time >= game_starttime)
1574         if (time < this.spawnshieldtime)
1575                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1576
1577         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1578 }
1579
1580 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1581 {
1582         if(current > stable)
1583                 return current;
1584         else if(current > stable - 0.25) // when close enough, "snap"
1585                 return stable;
1586         else
1587                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1588 }
1589
1590 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1591 {
1592         if(current < stable)
1593                 return current;
1594         else if(current < stable + 0.25) // when close enough, "snap"
1595                 return stable;
1596         else
1597                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1598 }
1599
1600 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1601 {
1602         float old = GetResource(this, res);
1603         float current = old;
1604         if(current > rotstable)
1605         {
1606                 if(rotframetime > 0)
1607                 {
1608                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1609                         current = max(rotstable, current - rotlinear * rotframetime);
1610                 }
1611         }
1612         else if(current < regenstable)
1613         {
1614                 if(regenframetime > 0)
1615                 {
1616                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1617                         current = min(regenstable, current + regenlinear * regenframetime);
1618                 }
1619         }
1620
1621         float limit = GetResourceLimit(this, res) * limit_mod;
1622         if(current > limit)
1623                 current = limit;
1624
1625         if (current != old)
1626                 SetResource(this, res, current);
1627 }
1628
1629 void player_regen(entity this)
1630 {
1631         float max_mod, regen_mod, rot_mod, limit_mod;
1632         max_mod = regen_mod = rot_mod = limit_mod = 1;
1633
1634         float regen_health = autocvar_g_balance_health_regen;
1635         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1636         float regen_health_rot = autocvar_g_balance_health_rot;
1637         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1638         float regen_health_stable = autocvar_g_balance_health_regenstable;
1639         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1640         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1641                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1642         max_mod = M_ARGV(1, float);
1643         regen_mod = M_ARGV(2, float);
1644         rot_mod = M_ARGV(3, float);
1645         limit_mod = M_ARGV(4, float);
1646         regen_health = M_ARGV(5, float);
1647         regen_health_linear = M_ARGV(6, float);
1648         regen_health_rot = M_ARGV(7, float);
1649         regen_health_rotlinear = M_ARGV(8, float);
1650         regen_health_stable = M_ARGV(9, float);
1651         regen_health_rotstable = M_ARGV(10, float);
1652
1653         if(!mutator_returnvalue)
1654         if(!STAT(FROZEN, this))
1655         {
1656                 float maxa = autocvar_g_balance_armor_rotstable;
1657                 float mina = autocvar_g_balance_armor_regenstable;
1658
1659                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1660                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1661                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1662
1663                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1664                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1665                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1666         }
1667
1668         // if player rotted to death...  die!
1669         // check this outside above checks, as player may still be able to rot to death
1670         if(GetResource(this, RES_HEALTH) < 1)
1671         {
1672                 if(this.vehicle)
1673                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1674                 if(this.event_damage)
1675                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1676         }
1677
1678         if (!(this.items & IT_UNLIMITED_AMMO))
1679         {
1680                 float maxf = autocvar_g_balance_fuel_rotstable;
1681                 float minf = autocvar_g_balance_fuel_regenstable;
1682
1683                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1684                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1685                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1686         }
1687 }
1688
1689 bool zoomstate_set;
1690 void SetZoomState(entity this, float newzoom)
1691 {
1692         if(newzoom != CS(this).zoomstate)
1693         {
1694                 CS(this).zoomstate = newzoom;
1695                 ClientData_Touch(this);
1696         }
1697         zoomstate_set = true;
1698 }
1699
1700 void GetPressedKeys(entity this)
1701 {
1702         MUTATOR_CALLHOOK(GetPressedKeys, this);
1703         int keys = STAT(PRESSED_KEYS, this);
1704         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1705         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1706         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1707         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1708
1709         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1710         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1711         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1712         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1713         CS(this).pressedkeys = keys; // store for other users
1714
1715         STAT(PRESSED_KEYS, this) = keys;
1716 }
1717
1718 /*
1719 ======================
1720 spectate mode routines
1721 ======================
1722 */
1723
1724 void SpectateCopy(entity this, entity spectatee)
1725 {
1726         TC(Client, this); TC(Client, spectatee);
1727
1728         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1729         PS(this) = PS(spectatee);
1730         this.armortype = spectatee.armortype;
1731         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1732         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1733         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1734         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1735         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1736         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1737         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1738         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1739         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1740         CS(this).impulse = 0;
1741         this.disableclientprediction = 1; // no need to run prediction on a spectator
1742         this.items = spectatee.items;
1743         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1744         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1745         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1746         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1747         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1748         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1749         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1750         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1751         this.punchangle = spectatee.punchangle;
1752         this.view_ofs = spectatee.view_ofs;
1753         this.velocity = spectatee.velocity;
1754         this.dmg_take = spectatee.dmg_take;
1755         this.dmg_save = spectatee.dmg_save;
1756         this.dmg_inflictor = spectatee.dmg_inflictor;
1757         this.v_angle = spectatee.v_angle;
1758         this.angles = spectatee.v_angle;
1759         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1760         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1761         this.viewloc = spectatee.viewloc;
1762         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1763                 this.fixangle = true;
1764         setorigin(this, spectatee.origin);
1765         setsize(this, spectatee.mins, spectatee.maxs);
1766         SetZoomState(this, CS(spectatee).zoomstate);
1767
1768     anticheat_spectatecopy(this, spectatee);
1769         STAT(HUD, this) = STAT(HUD, spectatee);
1770         if(spectatee.vehicle)
1771     {
1772         this.angles = spectatee.v_angle;
1773
1774         //this.fixangle = false;
1775         //this.velocity = spectatee.vehicle.velocity;
1776         this.vehicle_health = spectatee.vehicle_health;
1777         this.vehicle_shield = spectatee.vehicle_shield;
1778         this.vehicle_energy = spectatee.vehicle_energy;
1779         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1780         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1781         this.vehicle_reload1 = spectatee.vehicle_reload1;
1782         this.vehicle_reload2 = spectatee.vehicle_reload2;
1783
1784         //msg_entity = this;
1785
1786        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1787             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1788            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1789            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1790
1791         //WriteByte (MSG_ONE, SVC_SETVIEW);
1792         //    WriteEntity(MSG_ONE, this);
1793         //makevectors(spectatee.v_angle);
1794         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1795     }
1796 }
1797
1798 bool SpectateUpdate(entity this)
1799 {
1800         if(!this.enemy)
1801                 return false;
1802
1803         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1804         {
1805                 SetSpectatee(this, NULL);
1806                 return false;
1807         }
1808
1809         SpectateCopy(this, this.enemy);
1810
1811         return true;
1812 }
1813
1814 bool SpectateSet(entity this)
1815 {
1816         if(!IS_PLAYER(this.enemy))
1817                 return false;
1818
1819         ClientData_Touch(this.enemy);
1820
1821         msg_entity = this;
1822         WriteByte(MSG_ONE, SVC_SETVIEW);
1823         WriteEntity(MSG_ONE, this.enemy);
1824         set_movetype(this, MOVETYPE_NONE);
1825         accuracy_resend(this);
1826
1827         if(!SpectateUpdate(this))
1828                 PutObserverInServer(this);
1829
1830         return true;
1831 }
1832
1833 void SetSpectatee_status(entity this, int spectatee_num)
1834 {
1835         int oldspectatee_status = CS(this).spectatee_status;
1836         CS(this).spectatee_status = spectatee_num;
1837
1838         if (CS(this).spectatee_status != oldspectatee_status)
1839         {
1840                 if (STAT(PRESSED_KEYS, this))
1841                 {
1842                         CS(this).pressedkeys = 0;
1843                         STAT(PRESSED_KEYS, this) = 0;
1844                 }
1845                 ClientData_Touch(this);
1846                 if (g_race || g_cts) race_InitSpectator();
1847         }
1848 }
1849
1850 void SetSpectatee(entity this, entity spectatee)
1851 {
1852         if(IS_BOT_CLIENT(this))
1853                 return; // bots abuse .enemy, this code is useless to them
1854
1855         entity old_spectatee = this.enemy;
1856
1857         this.enemy = spectatee;
1858
1859         // WEAPONTODO
1860         // these are required to fix the spectator bug with arc
1861         if(old_spectatee)
1862         {
1863                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1864                 {
1865                         .entity weaponentity = weaponentities[slot];
1866                         if(old_spectatee.(weaponentity).arc_beam)
1867                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1868                 }
1869         }
1870         if(this.enemy)
1871         {
1872                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1873                 {
1874                         .entity weaponentity = weaponentities[slot];
1875                         if(this.enemy.(weaponentity).arc_beam)
1876                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1877                 }
1878         }
1879
1880         if (this.enemy)
1881                 SetSpectatee_status(this, etof(this.enemy));
1882
1883         // needed to update spectator list
1884         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1885 }
1886
1887 bool Spectate(entity this, entity pl)
1888 {
1889         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1890                 return false;
1891         pl = M_ARGV(1, entity);
1892
1893         SetSpectatee(this, pl);
1894         return SpectateSet(this);
1895 }
1896
1897 bool SpectateNext(entity this)
1898 {
1899         entity ent = find(this.enemy, classname, STR_PLAYER);
1900
1901         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1902                 ent = M_ARGV(1, entity);
1903         else if (!ent)
1904                 ent = find(ent, classname, STR_PLAYER);
1905
1906         if(ent) { SetSpectatee(this, ent); }
1907
1908         return SpectateSet(this);
1909 }
1910
1911 bool SpectatePrev(entity this)
1912 {
1913         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1914         entity ent = findchain(classname, STR_PLAYER);
1915         if (!ent) // no player
1916                 return false;
1917
1918         entity first = ent;
1919         // skip players until current spectated player
1920         if(this.enemy)
1921         while(ent && ent != this.enemy)
1922                 ent = ent.chain;
1923
1924         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1925         {
1926                 case MUT_SPECPREV_FOUND:
1927                         ent = M_ARGV(1, entity);
1928                         break;
1929                 case MUT_SPECPREV_RETURN:
1930                         return true;
1931                 case MUT_SPECPREV_CONTINUE:
1932                 default:
1933                 {
1934                         if(ent.chain)
1935                                 ent = ent.chain;
1936                         else
1937                                 ent = first;
1938                         break;
1939                 }
1940         }
1941
1942         SetSpectatee(this, ent);
1943         return SpectateSet(this);
1944 }
1945
1946 /*
1947 =============
1948 ShowRespawnCountdown()
1949
1950 Update a respawn countdown display.
1951 =============
1952 */
1953 void ShowRespawnCountdown(entity this)
1954 {
1955         float number;
1956         if(!IS_DEAD(this)) // just respawned?
1957                 return;
1958         else
1959         {
1960                 number = ceil(this.respawn_time - time);
1961                 if(number <= 0)
1962                         return;
1963                 if(number <= this.respawn_countdown)
1964                 {
1965                         this.respawn_countdown = number - 1;
1966                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1967                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1968                 }
1969         }
1970 }
1971
1972 .bool team_selected;
1973 bool ShowTeamSelection(entity this)
1974 {
1975         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1976                 return false;
1977         stuffcmd(this, "menu_showteamselect\n");
1978         return true;
1979 }
1980 void Join(entity this)
1981 {
1982         TRANSMUTE(Player, this);
1983
1984         if(!this.team_selected)
1985         if(autocvar_g_campaign || autocvar_g_balance_teams)
1986                 TeamBalance_JoinBestTeam(this);
1987
1988         if(autocvar_g_campaign)
1989                 campaign_bots_may_start = true;
1990
1991         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1992
1993         PutClientInServer(this);
1994
1995         if(IS_PLAYER(this))
1996         if(teamplay && this.team != -1)
1997         {
1998         }
1999         else
2000                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2001         this.team_selected = false;
2002 }
2003
2004 int GetPlayerLimit()
2005 {
2006         if(g_duel)
2007                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2008         int player_limit = autocvar_g_maxplayers;
2009         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2010         player_limit = M_ARGV(0, int);
2011         return player_limit;
2012 }
2013
2014 /**
2015  * Determines whether the player is allowed to join. This depends on cvar
2016  * g_maxplayers, if it isn't used this function always return true, otherwise
2017  * it checks whether the number of currently playing players exceeds g_maxplayers.
2018  * @return int number of free slots for players, 0 if none
2019  */
2020 int nJoinAllowed(entity this, entity ignore)
2021 {
2022         if(!ignore)
2023         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2024         // so report 0 free slots if restricted
2025         {
2026                 if(autocvar_g_forced_team_otherwise == "spectate")
2027                         return 0;
2028                 if(autocvar_g_forced_team_otherwise == "spectator")
2029                         return 0;
2030         }
2031
2032         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2033                 return 0; // forced spectators can never join
2034
2035         // TODO simplify this
2036         int totalClients = 0;
2037         int currentlyPlaying = 0;
2038         FOREACH_CLIENT(true, {
2039                 if(it != ignore)
2040                         ++totalClients;
2041                 if(IS_REAL_CLIENT(it))
2042                 if(IS_PLAYER(it) || it.caplayer)
2043                         ++currentlyPlaying;
2044         });
2045
2046         int player_limit = GetPlayerLimit();
2047
2048         int free_slots = 0;
2049         if (!player_limit)
2050                 free_slots = maxclients - totalClients;
2051         else if(player_limit > 0 && currentlyPlaying < player_limit)
2052                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2053
2054         static float msg_time = 0;
2055         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2056         {
2057                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2058                 msg_time = time + 0.5;
2059         }
2060
2061         return free_slots;
2062 }
2063
2064 /**
2065  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2066  * g_maxplayers_spectator_blocktime seconds
2067  */
2068 void checkSpectatorBlock(entity this)
2069 {
2070         if(IS_SPEC(this) || IS_OBSERVER(this))
2071         if(!this.caplayer)
2072         if(IS_REAL_CLIENT(this))
2073         {
2074                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2075                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2076                         dropclient(this);
2077                 }
2078         }
2079 }
2080
2081 void PrintWelcomeMessage(entity this)
2082 {
2083         if(CS(this).motd_actived_time == 0)
2084         {
2085                 if (autocvar_g_campaign) {
2086                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2087                                 CS(this).motd_actived_time = time;
2088                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2089                         }
2090                 } else {
2091                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2092                                 CS(this).motd_actived_time = time;
2093                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2094                         }
2095                 }
2096         }
2097         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2098         {
2099                 if (autocvar_g_campaign) {
2100                         if (PHYS_INPUT_BUTTON_INFO(this))
2101                                 CS(this).motd_actived_time = time;
2102                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2103                                 CS(this).motd_actived_time = 0;
2104                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2105                         }
2106                 } else {
2107                         if (PHYS_INPUT_BUTTON_INFO(this))
2108                                 CS(this).motd_actived_time = time;
2109                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2110                                 CS(this).motd_actived_time = 0;
2111                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2112                         }
2113                 }
2114         }
2115         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2116         {
2117                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2118                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2119                 else if (CS(this).motd_actived_time == -2)
2120                 {
2121                         // instantly hide MOTD
2122                         CS(this).motd_actived_time = 0;
2123                         if (autocvar_g_campaign)
2124                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2125                         else
2126                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2127                 }
2128                 else if (IS_PLAYER(this) || IS_SPEC(this))
2129                 {
2130                         // FIXME occasionally for some reason MOTD never goes away
2131                         // delay MOTD removal a little bit in the hope it fixes this bug
2132                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2133                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2134                         else //if (CS(this).motd_actived_time < -2)
2135                                 CS(this).motd_actived_time++;
2136                 }
2137         }
2138 }
2139
2140 bool joinAllowed(entity this)
2141 {
2142         if (CS(this).version_mismatch) return false;
2143         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2144         if (!nJoinAllowed(this, this)) return false;
2145         if (teamplay && lockteams) return false;
2146         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2147         if (ShowTeamSelection(this)) return false;
2148         return true;
2149 }
2150
2151 .string shootfromfixedorigin;
2152 .bool dualwielding_prev;
2153 bool PlayerThink(entity this)
2154 {
2155         if (game_stopped || intermission_running) {
2156                 this.modelflags &= ~MF_ROCKET;
2157                 if(intermission_running)
2158                         IntermissionThink(this);
2159                 return false;
2160         }
2161
2162         if (timeout_status == TIMEOUT_ACTIVE) {
2163                 // don't allow the player to turn around while game is paused
2164                 // FIXME turn this into CSQC stuff
2165                 this.v_angle = this.lastV_angle;
2166                 this.angles = this.lastV_angle;
2167                 this.fixangle = true;
2168         }
2169
2170         if (frametime) player_powerups(this);
2171
2172         if (IS_DEAD(this)) {
2173                 if (this.personal && g_race_qualifying) {
2174                         if (time > this.respawn_time) {
2175                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2176                                 respawn(this);
2177                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2178                         }
2179                 } else {
2180                         if (frametime) player_anim(this);
2181
2182                         if (this.respawn_flags & RESPAWN_DENY)
2183                         {
2184                                 STAT(RESPAWN_TIME, this) = 0;
2185                                 return false;
2186                         }
2187
2188                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2189
2190                         switch(this.deadflag)
2191                         {
2192                                 case DEAD_DYING:
2193                                 {
2194                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2195                                                 this.deadflag = DEAD_RESPAWNING;
2196                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2197                                                 this.deadflag = DEAD_DEAD;
2198                                         break;
2199                                 }
2200                                 case DEAD_DEAD:
2201                                 {
2202                                         if (button_pressed)
2203                                                 this.deadflag = DEAD_RESPAWNABLE;
2204                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2205                                                 this.deadflag = DEAD_RESPAWNING;
2206                                         break;
2207                                 }
2208                                 case DEAD_RESPAWNABLE:
2209                                 {
2210                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2211                                                 this.deadflag = DEAD_RESPAWNING;
2212                                         break;
2213                                 }
2214                                 case DEAD_RESPAWNING:
2215                                 {
2216                                         if (time > this.respawn_time)
2217                                         {
2218                                                 this.respawn_time = time + 1; // only retry once a second
2219                                                 this.respawn_time_max = this.respawn_time;
2220                                                 respawn(this);
2221                                         }
2222                                         break;
2223                                 }
2224                         }
2225
2226                         ShowRespawnCountdown(this);
2227
2228                         if (this.respawn_flags & RESPAWN_SILENT)
2229                                 STAT(RESPAWN_TIME, this) = 0;
2230                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2231                         {
2232                                 if (time < this.respawn_time)
2233                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2234                                 else if (this.deadflag != DEAD_RESPAWNING)
2235                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2236                         }
2237                         else
2238                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2239                 }
2240
2241                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2242                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2243                         STAT(RESPAWN_TIME, this) *= -1;
2244
2245                 return false;
2246         }
2247
2248         FixPlayermodel(this);
2249
2250         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2251                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2252                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2253         }
2254
2255         // reset gun alignment when dual wielding status changes
2256         // to ensure guns are always aligned right and left
2257         bool dualwielding = W_DualWielding(this);
2258         if(this.dualwielding_prev != dualwielding)
2259         {
2260                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2261                 this.dualwielding_prev = dualwielding;
2262         }
2263
2264         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2265         //if(frametime)
2266         {
2267                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2268                 {
2269                         .entity weaponentity = weaponentities[slot];
2270                         if(WEP_CVAR(vortex, charge_always))
2271                                 W_Vortex_Charge(this, weaponentity, frametime);
2272                         W_WeaponFrame(this, weaponentity);
2273                 }
2274         }
2275
2276         if (frametime)
2277         {
2278                 // WEAPONTODO: Add a weapon request for this
2279                 // rot vortex charge to the charge limit
2280                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2281                 {
2282                         .entity weaponentity = weaponentities[slot];
2283                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2284                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2285                 }
2286
2287                 player_regen(this);
2288                 player_anim(this);
2289                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2290         }
2291
2292         monsters_setstatus(this);
2293
2294         return true;
2295 }
2296
2297 .bool would_spectate;
2298 void ObserverOrSpectatorThink(entity this)
2299 {
2300         bool is_spec = IS_SPEC(this);
2301         if ( CS(this).impulse )
2302         {
2303                 int r = MinigameImpulse(this, CS(this).impulse);
2304                 if (!is_spec || r)
2305                         CS(this).impulse = 0;
2306
2307                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2308                 {
2309                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2310                         CS(this).impulse = 0;
2311                         return;
2312                 }
2313         }
2314
2315         if (this.flags & FL_JUMPRELEASED) {
2316                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2317                         this.flags &= ~FL_JUMPRELEASED;
2318                         this.flags |= FL_SPAWNING;
2319                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2320                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2321                         this.flags &= ~FL_JUMPRELEASED;
2322                         if(SpectateNext(this)) {
2323                                 TRANSMUTE(Spectator, this);
2324                         } else if (is_spec) {
2325                                 TRANSMUTE(Observer, this);
2326                                 PutClientInServer(this);
2327                         }
2328                         if (is_spec)
2329                                 CS(this).impulse = 0;
2330                 } else if (is_spec) {
2331                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2332                                 this.flags &= ~FL_JUMPRELEASED;
2333                                 if(SpectatePrev(this)) {
2334                                         TRANSMUTE(Spectator, this);
2335                                 } else {
2336                                         TRANSMUTE(Observer, this);
2337                                         PutClientInServer(this);
2338                                 }
2339                                 CS(this).impulse = 0;
2340                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2341                                 this.would_spectate = false;
2342                                 this.flags &= ~FL_JUMPRELEASED;
2343                                 TRANSMUTE(Observer, this);
2344                                 PutClientInServer(this);
2345                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2346                                 PutObserverInServer(this);
2347                                 this.would_spectate = true;
2348                         }
2349                 }
2350                 else {
2351                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2352                         set_movetype(this, preferred_movetype);
2353                 }
2354         } else {
2355                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2356                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2357                         this.flags |= FL_JUMPRELEASED;
2358                         if(this.flags & FL_SPAWNING)
2359                         {
2360                                 this.flags &= ~FL_SPAWNING;
2361                                 if(joinAllowed(this))
2362                                         Join(this);
2363                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2364                                         CS(this).autojoin_checked = -1;
2365                                 return;
2366                         }
2367                 }
2368                 if(is_spec && !SpectateUpdate(this))
2369                         PutObserverInServer(this);
2370         }
2371         if (is_spec)
2372                 this.flags |= FL_CLIENT | FL_NOTARGET;
2373 }
2374
2375 void PlayerUseKey(entity this)
2376 {
2377         if (!IS_PLAYER(this))
2378                 return;
2379
2380         if(this.vehicle)
2381         {
2382                 if(!game_stopped)
2383                 {
2384                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2385                         return;
2386                 }
2387         }
2388         else if(autocvar_g_vehicles_enter)
2389         {
2390                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2391                 {
2392                         entity head, closest_target = NULL;
2393                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2394
2395                         while(head) // find the closest acceptable target to enter
2396                         {
2397                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2398                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2399                                 {
2400                                         if(closest_target)
2401                                         {
2402                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2403                                                 { closest_target = head; }
2404                                         }
2405                                         else { closest_target = head; }
2406                                 }
2407
2408                                 head = head.chain;
2409                         }
2410
2411                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2412                 }
2413         }
2414
2415         // a use key was pressed; call handlers
2416         MUTATOR_CALLHOOK(PlayerUseKey, this);
2417 }
2418
2419
2420 /*
2421 =============
2422 PlayerPreThink
2423
2424 Called every frame for each client before the physics are run
2425 =============
2426 */
2427 .float last_vehiclecheck;
2428 void PlayerPreThink (entity this)
2429 {
2430         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2431         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2432
2433         WarpZone_PlayerPhysics_FixVAngle(this);
2434
2435         if (frametime) {
2436                 // physics frames: update anticheat stuff
2437                 anticheat_prethink(this);
2438         }
2439
2440         if (blockSpectators && frametime) {
2441                 // WORKAROUND: only use dropclient in server frames (frametime set).
2442                 // Never use it in cl_movement frames (frametime zero).
2443                 checkSpectatorBlock(this);
2444         }
2445
2446         zoomstate_set = false;
2447
2448         // Check for nameless players
2449         if (this.netname == "" || this.netname != CS(this).netname_previous)
2450         {
2451                 bool assume_unchanged = (CS(this).netname_previous == "");
2452                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2453                 {
2454                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2455                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2456                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2457                         assume_unchanged = false;
2458                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2459                 }
2460                 if (isInvisibleString(this.netname))
2461                 {
2462                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2463                         sprint(this, "Warning: invisible names are not allowed.\n");
2464                         assume_unchanged = false;
2465                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2466                 }
2467                 if (!assume_unchanged && autocvar_sv_eventlog)
2468                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2469                 strcpy(CS(this).netname_previous, this.netname);
2470         }
2471
2472         // version nagging
2473         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2474         CS(this).version_nagtime = 0;
2475         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2476             // git client
2477         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2478             // git server
2479             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2480         } else {
2481             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2482             if (r < 0) { // old client
2483                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2484             } else if (r > 0) { // old server
2485                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2486             }
2487         }
2488     }
2489
2490         // GOD MODE info
2491         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2492         {
2493                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2494                 this.max_armorvalue = 0;
2495         }
2496
2497         if (frametime && IS_PLAYER(this))
2498         {
2499                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2500                 {
2501                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2502                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2503                         if (this.iceblock)
2504                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2505
2506                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2507                                 Unfreeze(this, false);
2508                 }
2509                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2510                 {
2511                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2512                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2513
2514                         if (GetResource(this, RES_HEALTH) < 1)
2515                         {
2516                                 if (this.vehicle)
2517                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2518                                 if(this.event_damage)
2519                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2520                         }
2521                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2522                                 Unfreeze(this, false);
2523                 }
2524         }
2525
2526         MUTATOR_CALLHOOK(PlayerPreThink, this);
2527
2528         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2529         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2530         {
2531                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2532                 {
2533                         if(!it.owner)
2534                         {
2535                                 if(!it.team || SAME_TEAM(this, it))
2536                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2537                                 else if(autocvar_g_vehicles_steal)
2538                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2539                         }
2540                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2541                         {
2542                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2543                         }
2544                 });
2545
2546                 this.last_vehiclecheck = time + 1;
2547         }
2548
2549         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2550         {
2551                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2552                         PlayerUseKey(this);
2553                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2554         }
2555
2556         if (IS_REAL_CLIENT(this))
2557                 PrintWelcomeMessage(this);
2558
2559         if (IS_PLAYER(this)) {
2560                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2561                         error("Client can't be spawned as player on connection!");
2562                 if(!PlayerThink(this))
2563                         return;
2564         }
2565         else if (game_stopped || intermission_running) {
2566                 if(intermission_running)
2567                         IntermissionThink(this);
2568                 return;
2569         }
2570         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2571         {
2572                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2573                 CS(this).autojoin_checked = 1;
2574                 // don't do this in ClientConnect
2575                 // many things can go wrong if a client is spawned as player on connection
2576                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2577                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2578                                 && (!teamplay || autocvar_g_balance_teams)))
2579                 {
2580                         campaign_bots_may_start = true;
2581                         if(joinAllowed(this))
2582                                 Join(this);
2583                         return;
2584                 }
2585         }
2586         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2587                 ObserverOrSpectatorThink(this);
2588         }
2589
2590         // WEAPONTODO: Add weapon request for this
2591         if (!zoomstate_set) {
2592                 bool wep_zoomed = false;
2593                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2594                 {
2595                         .entity weaponentity = weaponentities[slot];
2596                         Weapon thiswep = this.(weaponentity).m_weapon;
2597                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2598                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2599                 }
2600                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2601         }
2602
2603         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2604         {
2605                 CS(this).teamkill_soundtime = 0;
2606
2607                 entity e = CS(this).teamkill_soundsource;
2608                 entity oldpusher = e.pusher;
2609                 e.pusher = this;
2610                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2611                 e.pusher = oldpusher;
2612         }
2613
2614         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2615                 CS(this).taunt_soundtime = 0;
2616                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2617         }
2618
2619         target_voicescript_next(this);
2620
2621         // WEAPONTODO: Move into weaponsystem somehow
2622         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2623         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2624         {
2625                 .entity weaponentity = weaponentities[slot];
2626                 if(this.(weaponentity).m_weapon == WEP_Null)
2627                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2628         }
2629 }
2630
2631 void DrownPlayer(entity this)
2632 {
2633         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2634                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2635         {
2636                 STAT(AIR_FINISHED, this) = 0;
2637                 return;
2638         }
2639
2640         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2641         {
2642                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2643                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2644                 STAT(AIR_FINISHED, this) = 0;
2645         }
2646         else
2647         {
2648                 if (!STAT(AIR_FINISHED, this))
2649                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2650                 if (STAT(AIR_FINISHED, this) < time)
2651                 {       // drown!
2652                         if (this.pain_finished < time)
2653                         {
2654                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2655                                 this.pain_finished = time + 0.5;
2656                         }
2657                 }
2658         }
2659 }
2660
2661 .bool move_qcphysics;
2662
2663 void Player_Physics(entity this)
2664 {
2665         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2666
2667         if(!this.move_qcphysics)
2668                 return;
2669
2670         if(!frametime && !CS(this).pm_frametime)
2671                 return;
2672
2673         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2674
2675         CS(this).pm_frametime = 0;
2676 }
2677
2678 /*
2679 =============
2680 PlayerPostThink
2681
2682 Called every frame for each client after the physics are run
2683 =============
2684 */
2685 void PlayerPostThink (entity this)
2686 {
2687         Player_Physics(this);
2688
2689         if (autocvar_sv_maxidle > 0)
2690         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2691         if (IS_REAL_CLIENT(this))
2692         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2693         {
2694                 int totalClients = 0;
2695                 if(autocvar_sv_maxidle_slots > 0)
2696                 {
2697                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2698                         {
2699                                 ++totalClients;
2700                         });
2701                 }
2702
2703                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2704                 { /* do nothing */ }
2705                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2706                 {
2707                         if (CS(this).idlekick_lasttimeleft)
2708                         {
2709                                 CS(this).idlekick_lasttimeleft = 0;
2710                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2711                         }
2712                 }
2713                 else
2714                 {
2715                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2716                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2717                                 if (!CS(this).idlekick_lasttimeleft)
2718                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2719                         }
2720                         if (timeleft <= 0) {
2721                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2722                                 dropclient(this);
2723                                 return;
2724                         }
2725                         else if (timeleft <= 10) {
2726                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2727                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2728                                 CS(this).idlekick_lasttimeleft = timeleft;
2729                         }
2730                 }
2731         }
2732
2733         CheatFrame(this);
2734
2735         if (game_stopped)
2736         {
2737                 this.solid = SOLID_NOT;
2738                 this.takedamage = DAMAGE_NO;
2739                 set_movetype(this, MOVETYPE_NONE);
2740                 CS(this).teamkill_complain = 0;
2741                 CS(this).teamkill_soundtime = 0;
2742                 CS(this).teamkill_soundsource = NULL;
2743         }
2744
2745         if (IS_PLAYER(this)) {
2746                 if(this.death_time == time && IS_DEAD(this))
2747                 {
2748                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2749                         // once all the damage events of this frame have been processed with normal size
2750                         this.maxs.z = 5;
2751                         setsize(this, this.mins, this.maxs);
2752                 }
2753                 DrownPlayer(this);
2754                 UpdateChatBubble(this);
2755                 if (CS(this).impulse) ImpulseCommands(this);
2756                 if (game_stopped)
2757                 {
2758                         CSQCMODEL_AUTOUPDATE(this);
2759                         return;
2760                 }
2761                 GetPressedKeys(this);
2762         }
2763         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2764         {
2765                 CS(this).pressedkeys = 0;
2766                 STAT(PRESSED_KEYS, this) = 0;
2767         }
2768
2769         if (this.waypointsprite_attachedforcarrier) {
2770                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2771                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2772         }
2773
2774         CSQCMODEL_AUTOUPDATE(this);
2775 }
2776
2777 // hack to copy the button fields from the client entity to the Client State
2778 void PM_UpdateButtons(entity this, entity store)
2779 {
2780         if(this.impulse)
2781                 store.impulse = this.impulse;
2782         this.impulse = 0;
2783
2784         bool typing = this.buttonchat || this.button12;
2785
2786         store.button0 = (typing) ? 0 : this.button0;
2787         //button1?!
2788         store.button2 = (typing) ? 0 : this.button2;
2789         store.button3 = (typing) ? 0 : this.button3;
2790         store.button4 = this.button4;
2791         store.button5 = (typing) ? 0 : this.button5;
2792         store.button6 = this.button6;
2793         store.button7 = this.button7;
2794         store.button8 = this.button8;
2795         store.button9 = this.button9;
2796         store.button10 = this.button10;
2797         store.button11 = this.button11;
2798         store.button12 = this.button12;
2799         store.button13 = this.button13;
2800         store.button14 = this.button14;
2801         store.button15 = this.button15;
2802         store.button16 = this.button16;
2803         store.buttonuse = this.buttonuse;
2804         store.buttonchat = this.buttonchat;
2805
2806         store.cursor_active = this.cursor_active;
2807         store.cursor_screen = this.cursor_screen;
2808         store.cursor_trace_start = this.cursor_trace_start;
2809         store.cursor_trace_endpos = this.cursor_trace_endpos;
2810         store.cursor_trace_ent = this.cursor_trace_ent;
2811
2812         store.ping = this.ping;
2813         store.ping_packetloss = this.ping_packetloss;
2814         store.ping_movementloss = this.ping_movementloss;
2815
2816         store.v_angle = this.v_angle;
2817         store.movement = this.movement;
2818 }
2819
2820 NET_HANDLE(fpsreport, bool)
2821 {
2822         int fps = ReadShort();
2823         PlayerScore_Set(sender, SP_FPS, fps);
2824         return true;
2825 }