qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include "compat/quake3.qh"
  36
  37 #include <common/effects/qc/globalsound.qh>
  38
  39 #include "../common/mapobjects/func/conveyor.qh"
  40 #include "../common/mapobjects/teleporters.qh"
  41 #include "../common/mapobjects/target/spawnpoint.qh"
  42 #include <common/mapobjects/trigger/counter.qh>
  43
  44 #include "../common/vehicles/all.qh"
  45
  46 #include "weapons/hitplot.qh"
  47 #include "weapons/weaponsystem.qh"
  48
  49 #include "../common/net_notice.qh"
  50 #include "../common/net_linked.qh"
  51 #include "../common/physics/player.qh"
  52
  53 #include <common/vehicles/sv_vehicles.qh>
  54
  55 #include "../common/items/_mod.qh"
  56
  57 #include "../common/mutators/mutator/waypoints/all.qh"
  58 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  59 #include <common/gamemodes/_mod.qh>
  60
  61 #include "../common/mapobjects/subs.qh"
  62 #include "../common/mapobjects/triggers.qh"
  63 #include "../common/mapobjects/trigger/secret.qh"
  64
  65 #include "../common/minigames/sv_minigames.qh"
  66
  67 #include "../common/items/inventory.qh"
  68
  69 #include "../common/monsters/sv_monsters.qh"
  70
  71 #include "../lib/warpzone/server.qh"
  72
  73 #include <common/mutators/mutator/overkill/oknex.qh>
  74
  75 STATIC_METHOD(Client, Add, void(Client this, int _team))
  76 {
  77     ClientConnect(this);
  78     TRANSMUTE(Player, this);
  79     this.frame = 12; // 7
  80     this.team = _team;
  81     PutClientInServer(this);
  82 }
  83
  84 STATIC_METHOD(Client, Remove, void(Client this))
  85 {
  86     TRANSMUTE(Observer, this);
  87     PutClientInServer(this);
  88     ClientDisconnect(this);
  89 }
  90
  91 void send_CSQC_teamnagger() {
  92         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  93 }
  94
  95 int CountSpectators(entity player, entity to)
  96 {
  97         if(!player) { return 0; } // not sure how, but best to be safe
  98
  99         int spec_count = 0;
 100
 101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 102         {
 103                 spec_count++;
 104         });
 105
 106         return spec_count;
 107 }
 108
 109 void WriteSpectators(entity player, entity to)
 110 {
 111         if(!player) { return; } // not sure how, but best to be safe
 112
 113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 114         {
 115                 WriteByte(MSG_ENTITY, num_for_edict(it));
 116         });
 117 }
 118
 119 bool ClientData_Send(entity this, entity to, int sf)
 120 {
 121         assert(to == this.owner, return false);
 122
 123         entity e = to;
 124         if (IS_SPEC(e)) e = e.enemy;
 125
 126         sf = 0;
 127         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 128         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 129         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 130         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 131
 132         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 133         WriteByte(MSG_ENTITY, sf);
 134
 135         if (sf & BIT(1))
 136                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 137
 138         if(sf & BIT(4))
 139         {
 140                 float specs = CountSpectators(e, to);
 141                 WriteByte(MSG_ENTITY, specs);
 142                 WriteSpectators(e, to);
 143         }
 144
 145         return true;
 146 }
 147
 148 void ClientData_Attach(entity this)
 149 {
 150         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 151         CS(this).clientdata.drawonlytoclient = this;
 152         CS(this).clientdata.owner = this;
 153 }
 154
 155 void ClientData_Detach(entity this)
 156 {
 157         delete(CS(this).clientdata);
 158         CS(this).clientdata = NULL;
 159 }
 160
 161 void ClientData_Touch(entity e)
 162 {
 163         entity cd = CS(e).clientdata;
 164         if (cd) { cd.SendFlags = 1; }
 165
 166         // make it spectatable
 167         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 168         {
 169                 entity cd = CS(it).clientdata;
 170                 if (cd) { cd.SendFlags = 1; }
 171         });
 172 }
 173
 174
 175 /*
 176 =============
 177 CheckPlayerModel
 178
 179 Checks if the argument string can be a valid playermodel.
 180 Returns a valid one in doubt.
 181 =============
 182 */
 183 string FallbackPlayerModel;
 184 string CheckPlayerModel(string plyermodel) {
 185         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 186         {
 187                 // note: we cannot summon Don Strunzone here, some player may
 188                 // still have the model string set. In case anyone manages how
 189                 // to change a cvar default, we'll have a small leak here.
 190                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 191         }
 192         // only in right path
 193         if( substring(plyermodel,0,14) != "models/player/")
 194                 return FallbackPlayerModel;
 195         // only good file extensions
 196         if(substring(plyermodel,-4,4) != ".zym")
 197         if(substring(plyermodel,-4,4) != ".dpm")
 198         if(substring(plyermodel,-4,4) != ".iqm")
 199         if(substring(plyermodel,-4,4) != ".md3")
 200         if(substring(plyermodel,-4,4) != ".psk")
 201                 return FallbackPlayerModel;
 202         // forbid the LOD models
 203         if(substring(plyermodel, -9,5) == "_lod1")
 204                 return FallbackPlayerModel;
 205         if(substring(plyermodel, -9,5) == "_lod2")
 206                 return FallbackPlayerModel;
 207         if(plyermodel != strtolower(plyermodel))
 208                 return FallbackPlayerModel;
 209         // also, restrict to server models
 210         if(autocvar_sv_servermodelsonly)
 211         {
 212                 if(!fexists(plyermodel))
 213                         return FallbackPlayerModel;
 214         }
 215         return plyermodel;
 216 }
 217
 218 void setplayermodel(entity e, string modelname)
 219 {
 220         precache_model(modelname);
 221         _setmodel(e, modelname);
 222         player_setupanimsformodel(e);
 223         if(!autocvar_g_debug_globalsounds)
 224                 UpdatePlayerSounds(e);
 225 }
 226
 227 /** putting a client as observer in the server */
 228 void PutObserverInServer(entity this)
 229 {
 230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 231         PlayerState_detach(this);
 232
 233         if (IS_PLAYER(this))
 234         {
 235                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 236                 {
 237                         // despawn effect
 238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 239                 }
 240
 241                 // was a player, recount votes and ready status
 242                 if(IS_REAL_CLIENT(this))
 243                 {
 244                         if (vote_called) { VoteCount(false); }
 245                         ReadyCount();
 246                 }
 247     }
 248
 249     {
 250         entity spot = SelectSpawnPoint(this, true);
 251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 252         this.angles = vec2(spot.angles);
 253         this.fixangle = true;
 254         // offset it so that the spectator spawns higher off the ground, looks better this way
 255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 256         if (IS_REAL_CLIENT(this))
 257         {
 258             msg_entity = this;
 259             WriteByte(MSG_ONE, SVC_SETVIEW);
 260             WriteEntity(MSG_ONE, this);
 261         }
 262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 264         if(!autocvar_g_debug_globalsounds)
 265         {
 266                 // needed for player sounds
 267                 this.model = "";
 268                 FixPlayermodel(this);
 269         }
 270         setmodel(this, MDL_Null);
 271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 272         this.view_ofs = '0 0 0';
 273     }
 274
 275     RemoveGrapplingHooks(this);
 276         Portal_ClearAll(this);
 277         Unfreeze(this);
 278         SetSpectatee(this, NULL);
 279
 280         if (this.alivetime)
 281         {
 282                 if (!warmup_stage)
 283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 284                 this.alivetime = 0;
 285         }
 286
 287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 288
 289         WaypointSprite_PlayerDead(this);
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 if(!game_stopped)
 294                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 295                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 296         }
 297
 298         accuracy_resend(this);
 299
 300         CS(this).spectatortime = time;
 301         if(this.bot_attack)
 302                 IL_REMOVE(g_bot_targets, this);
 303         this.bot_attack = false;
 304         if(this.monster_attack)
 305                 IL_REMOVE(g_monster_targets, this);
 306         this.monster_attack = false;
 307     STAT(HUD, this) = HUD_NORMAL;
 308         TRANSMUTE(Observer, this);
 309         this.iscreature = false;
 310         this.teleportable = TELEPORT_SIMPLE;
 311         if(this.damagedbycontents)
 312                 IL_REMOVE(g_damagedbycontents, this);
 313         this.damagedbycontents = false;
 314         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 315         SetSpectatee_status(this, etof(this));
 316         this.takedamage = DAMAGE_NO;
 317         this.solid = SOLID_NOT;
 318         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 319         this.flags = FL_CLIENT | FL_NOTARGET;
 320         this.effects = 0;
 321         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 322         this.pauserotarmor_finished = 0;
 323         this.pauserothealth_finished = 0;
 324         this.pauseregen_finished = 0;
 325         this.damageforcescale = 0;
 326         this.death_time = 0;
 327         this.respawn_flags = 0;
 328         this.respawn_time = 0;
 329         STAT(RESPAWN_TIME, this) = 0;
 330         this.alpha = 0;
 331         this.scale = 0;
 332         this.fade_time = 0;
 333         this.pain_frame = 0;
 334         this.pain_finished = 0;
 335         this.strength_finished = 0;
 336         this.invincible_finished = 0;
 337         this.superweapons_finished = 0;
 338         //this.dphitcontentsmask = 0;
 339         this.dphitcontentsmask = DPCONTENTS_SOLID;
 340         if (autocvar_g_playerclip_collisions)
 341                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         STAT(REVIVE_PROGRESS, this) = 0;
 349         this.revival_time = 0;
 350
 351         this.items = 0;
 352         STAT(WEAPONS, this) = '0 0 0';
 353         this.drawonlytoclient = this;
 354
 355         this.viewloc = NULL;
 356
 357         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 358
 359         this.weaponmodel = "";
 360         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 361         {
 362                 this.weaponentities[slot] = NULL;
 363         }
 364         this.exteriorweaponentity = NULL;
 365         CS(this).killcount = FRAGS_SPECTATOR;
 366         this.velocity = '0 0 0';
 367         this.avelocity = '0 0 0';
 368         this.punchangle = '0 0 0';
 369         this.punchvector = '0 0 0';
 370         this.oldvelocity = this.velocity;
 371         this.fire_endtime = -1;
 372         this.event_damage = func_null;
 373         this.event_heal = func_null;
 374
 375         for(int slot = 0; slot < MAX_AXH; ++slot)
 376         {
 377                 entity axh = this.(AuxiliaryXhair[slot]);
 378                 this.(AuxiliaryXhair[slot]) = NULL;
 379
 380                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 381                         delete(axh);
 382         }
 383
 384         if (mutator_returnvalue)
 385         {
 386                 // mutator prevents resetting teams+score
 387         }
 388         else
 389         {
 390                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 391                 this.frags = FRAGS_SPECTATOR;
 392     }
 393 }
 394
 395 int player_getspecies(entity this)
 396 {
 397         get_model_parameters(this.model, this.skin);
 398         int s = get_model_parameters_species;
 399         get_model_parameters(string_null, 0);
 400         if (s < 0) return SPECIES_HUMAN;
 401         return s;
 402 }
 403
 404 .float model_randomizer;
 405 void FixPlayermodel(entity player)
 406 {
 407         string defaultmodel = "";
 408         int defaultskin = 0;
 409         if(autocvar_sv_defaultcharacter)
 410         {
 411                 if(teamplay)
 412                 {
 413                         switch(player.team)
 414                         {
 415                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 416                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 417                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 418                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 419                         }
 420                 }
 421
 422                 if(defaultmodel == "")
 423                 {
 424                         defaultmodel = autocvar_sv_defaultplayermodel;
 425                         defaultskin = autocvar_sv_defaultplayerskin;
 426                 }
 427
 428                 int n = tokenize_console(defaultmodel);
 429                 if(n > 0)
 430                 {
 431                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 432                         // However, do NOT randomize if the player-selected model is in the list.
 433                         for (int i = 0; i < n; ++i)
 434                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 435                                         defaultmodel = argv(i);
 436                 }
 437
 438                 int i = strstrofs(defaultmodel, ":", 0);
 439                 if(i >= 0)
 440                 {
 441                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 442                         defaultmodel = substring(defaultmodel, 0, i);
 443                 }
 444         }
 445         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 446         {
 447                 if(teamplay)
 448                 {
 449                         switch(player.team)
 450                         {
 451                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 452                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 453                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 454                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 455                         }
 456                 }
 457
 458                 if(!defaultskin)
 459                         defaultskin = autocvar_sv_defaultplayerskin;
 460         }
 461
 462         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 463         defaultmodel = M_ARGV(0, string);
 464         defaultskin = M_ARGV(1, int);
 465
 466         bool chmdl = false;
 467         int oldskin;
 468         if(defaultmodel != "")
 469         {
 470                 if (defaultmodel != player.model)
 471                 {
 472                         vector m1 = player.mins;
 473                         vector m2 = player.maxs;
 474                         setplayermodel (player, defaultmodel);
 475                         setsize (player, m1, m2);
 476                         chmdl = true;
 477                 }
 478
 479                 oldskin = player.skin;
 480                 player.skin = defaultskin;
 481         } else {
 482                 if (player.playermodel != player.model || player.playermodel == "")
 483                 {
 484                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 485                         vector m1 = player.mins;
 486                         vector m2 = player.maxs;
 487                         setplayermodel (player, player.playermodel);
 488                         setsize (player, m1, m2);
 489                         chmdl = true;
 490                 }
 491
 492                 if(!autocvar_sv_defaultcharacterskin)
 493                 {
 494                         oldskin = player.skin;
 495                         player.skin = stof(player.playerskin);
 496                 }
 497                 else
 498                 {
 499                         oldskin = player.skin;
 500                         player.skin = defaultskin;
 501                 }
 502         }
 503
 504         if(chmdl || oldskin != player.skin) // model or skin has changed
 505         {
 506                 player.species = player_getspecies(player); // update species
 507                 if(!autocvar_g_debug_globalsounds)
 508                         UpdatePlayerSounds(player); // update skin sounds
 509         }
 510
 511         if(!teamplay)
 512                 if(strlen(autocvar_sv_defaultplayercolors))
 513                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 514                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 515 }
 516
 517 void PutPlayerInServer(entity this)
 518 {
 519         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 520
 521         PlayerState_attach(this);
 522         accuracy_resend(this);
 523
 524         if (this.team < 0)
 525                 TeamBalance_JoinBestTeam(this);
 526
 527         entity spot = SelectSpawnPoint(this, false);
 528         if (!spot) {
 529                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 530                 return; // spawn failed
 531         }
 532
 533         TRANSMUTE(Player, this);
 534
 535         CS(this).wasplayer = true;
 536         this.iscreature = true;
 537         this.teleportable = TELEPORT_NORMAL;
 538         if(!this.damagedbycontents)
 539                 IL_PUSH(g_damagedbycontents, this);
 540         this.damagedbycontents = true;
 541         set_movetype(this, MOVETYPE_WALK);
 542         this.solid = SOLID_SLIDEBOX;
 543         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 544         if (autocvar_g_playerclip_collisions)
 545                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 546         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 547                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 548         this.frags = FRAGS_PLAYER;
 549         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 550         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 551         if (autocvar__notarget)
 552                 this.flags |= FL_NOTARGET;
 553         this.takedamage = DAMAGE_AIM;
 554         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 555
 556         if (warmup_stage) {
 557                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 558                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 559                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 560                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 561                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 562                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 563                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 564                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 565                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 566         } else {
 567                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 568                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 569                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 570                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 571                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 572                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 573                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 574                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 575                 STAT(WEAPONS, this) = start_weapons;
 576                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 577                 {
 578                         GiveRandomWeapons(this, random_start_weapons_count,
 579                                 autocvar_g_random_start_weapons, random_start_ammo);
 580                 }
 581         }
 582         SetSpectatee_status(this, 0);
 583
 584         PS(this).dual_weapons = '0 0 0';
 585
 586         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 587
 588         this.items = start_items;
 589
 590         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 591         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 592         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 593         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 594         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 595         if (!sv_ready_restart_after_countdown && time < game_starttime)
 596         {
 597                 float f = game_starttime - time;
 598                 this.spawnshieldtime += f;
 599                 this.pauserotarmor_finished += f;
 600                 this.pauserothealth_finished += f;
 601                 this.pauseregen_finished += f;
 602         }
 603
 604         this.damageforcescale = 2;
 605         this.death_time = 0;
 606         this.respawn_flags = 0;
 607         this.respawn_time = 0;
 608         STAT(RESPAWN_TIME, this) = 0;
 609         this.scale = autocvar_sv_player_scale;
 610         this.fade_time = 0;
 611         this.pain_frame = 0;
 612         this.pain_finished = 0;
 613         this.pushltime = 0;
 614         setthink(this, func_null); // players have no think function
 615         this.nextthink = 0;
 616         this.dmg_team = 0;
 617         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 618
 619         this.deadflag = DEAD_NO;
 620
 621         this.angles = spot.angles;
 622         this.angles_z = 0; // never spawn tilted even if the spot says to
 623         if (IS_BOT_CLIENT(this))
 624                 this.v_angle = this.angles;
 625         this.fixangle = true; // turn this way immediately
 626         this.oldvelocity = this.velocity = '0 0 0';
 627         this.avelocity = '0 0 0';
 628         this.punchangle = '0 0 0';
 629         this.punchvector = '0 0 0';
 630
 631         this.strength_finished = 0;
 632         this.invincible_finished = 0;
 633         this.fire_endtime = -1;
 634         STAT(REVIVE_PROGRESS, this) = 0;
 635         this.revival_time = 0;
 636
 637         this.air_finished = time + 12;
 638         this.waterlevel = WATERLEVEL_NONE;
 639         this.watertype = CONTENT_EMPTY;
 640
 641         entity spawnevent = new_pure(spawnevent);
 642         spawnevent.owner = this;
 643         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 644
 645         // Cut off any still running player sounds.
 646         stopsound(this, CH_PLAYER_SINGLE);
 647
 648         this.model = "";
 649         FixPlayermodel(this);
 650         this.drawonlytoclient = NULL;
 651
 652         this.viewloc = NULL;
 653
 654         for(int slot = 0; slot < MAX_AXH; ++slot)
 655         {
 656                 entity axh = this.(AuxiliaryXhair[slot]);
 657                 this.(AuxiliaryXhair[slot]) = NULL;
 658
 659                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 660                         delete(axh);
 661         }
 662
 663         this.spawnpoint_targ = NULL;
 664
 665         this.crouch = false;
 666         this.view_ofs = STAT(PL_VIEW_OFS, this);
 667         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 668         this.spawnorigin = spot.origin;
 669         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 670         // don't reset back to last position, even if new position is stuck in solid
 671         this.oldorigin = this.origin;
 672         if(this.conveyor)
 673                 IL_REMOVE(g_conveyed, this);
 674         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 675         STAT(HUD, this) = HUD_NORMAL;
 676
 677         this.event_damage = PlayerDamage;
 678         this.event_heal = PlayerHeal;
 679
 680         if(!this.bot_attack)
 681                 IL_PUSH(g_bot_targets, this);
 682         this.bot_attack = true;
 683         if(!this.monster_attack)
 684                 IL_PUSH(g_monster_targets, this);
 685         this.monster_attack = true;
 686         navigation_dynamicgoal_init(this, false);
 687
 688         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 689
 690         // player was spectator
 691         if (CS(this).killcount == FRAGS_SPECTATOR) {
 692                 PlayerScore_Clear(this);
 693                 CS(this).killcount = 0;
 694                 CS(this).startplaytime = time;
 695         }
 696
 697         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 698         {
 699                 .entity weaponentity = weaponentities[slot];
 700                 entity oldwep = this.(weaponentity);
 701                 CL_SpawnWeaponentity(this, weaponentity);
 702                 if(oldwep && oldwep.owner == this)
 703                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 704         }
 705         this.alpha = default_player_alpha;
 706         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 707         this.exteriorweaponentity.alpha = default_weapon_alpha;
 708
 709         this.speedrunning = false;
 710
 711         this.counter_cnt = 0;
 712         this.fragsfilter_cnt = 0;
 713
 714         target_voicescript_clear(this);
 715
 716         // reset fields the weapons may use
 717         FOREACH(Weapons, true, {
 718                 it.wr_resetplayer(it, this);
 719                         // reload all reloadable weapons
 720                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 721                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 722                         {
 723                                 .entity weaponentity = weaponentities[slot];
 724                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 725                         }
 726                 }
 727         });
 728
 729         {
 730                 //string s = spot.target;
 731                 //spot.target = string_null;
 732                 SUB_UseTargets(spot, this, NULL);
 733                 //spot.target = s;
 734         }
 735
 736         Unfreeze(this);
 737
 738         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 739
 740         if (autocvar_spawn_debug)
 741         {
 742                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 743                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 744         }
 745
 746         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 747         {
 748                 .entity weaponentity = weaponentities[slot];
 749                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 750                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 751                 else
 752                         this.(weaponentity).m_switchweapon = WEP_Null;
 753                 this.(weaponentity).m_weapon = WEP_Null;
 754                 this.(weaponentity).weaponname = "";
 755                 this.(weaponentity).m_switchingweapon = WEP_Null;
 756                 this.(weaponentity).cnt = -1;
 757         }
 758
 759         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 760
 761         if (CS(this).impulse) ImpulseCommands(this);
 762
 763         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 764         {
 765                 .entity weaponentity = weaponentities[slot];
 766                 W_WeaponFrame(this, weaponentity);
 767         }
 768
 769         if (!warmup_stage && !this.alivetime)
 770                 this.alivetime = time;
 771
 772         antilag_clear(this, CS(this));
 773 }
 774
 775 /** Called when a client spawns in the server */
 776 void PutClientInServer(entity this)
 777 {
 778         if (IS_BOT_CLIENT(this)) {
 779                 TRANSMUTE(Player, this);
 780         } else if (IS_REAL_CLIENT(this)) {
 781                 msg_entity = this;
 782                 WriteByte(MSG_ONE, SVC_SETVIEW);
 783                 WriteEntity(MSG_ONE, this);
 784         }
 785         if (game_stopped)
 786                 TRANSMUTE(Observer, this);
 787
 788         SetSpectatee(this, NULL);
 789
 790         // reset player keys
 791         if(PS(this))
 792                 PS(this).itemkeys = 0;
 793
 794         MUTATOR_CALLHOOK(PutClientInServer, this);
 795
 796         if (IS_OBSERVER(this)) {
 797                 PutObserverInServer(this);
 798         } else if (IS_PLAYER(this)) {
 799                 PutPlayerInServer(this);
 800         }
 801 }
 802
 803 // TODO do we need all these fields, or should we stop autodetecting runtime
 804 // changes and just have a console command to update this?
 805 bool ClientInit_SendEntity(entity this, entity to, int sf)
 806 {
 807         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 808         return = true;
 809         msg_entity = to;
 810         // MSG_INIT replacement
 811         // TODO: make easier to use
 812         Registry_send_all();
 813         W_PROP_reload(MSG_ONE, to);
 814         ClientInit_misc(this);
 815         MUTATOR_CALLHOOK(Ent_Init);
 816 }
 817 void ClientInit_misc(entity this)
 818 {
 819         int channel = MSG_ONE;
 820         WriteHeader(channel, ENT_CLIENT_INIT);
 821         WriteByte(channel, g_nexball_meter_period * 32);
 822         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 823         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 824         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 825         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 826         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 827         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 828         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 829         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 830
 831         if(sv_foginterval && world.fog != "")
 832                 WriteString(channel, world.fog);
 833         else
 834                 WriteString(channel, "");
 835         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 836         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 837         WriteByte(channel, serverflags);
 838         WriteCoord(channel, autocvar_g_trueaim_minrange);
 839 }
 840
 841 void ClientInit_CheckUpdate(entity this)
 842 {
 843         this.nextthink = time;
 844         if(this.count != autocvar_g_balance_armor_blockpercent)
 845         {
 846                 this.count = autocvar_g_balance_armor_blockpercent;
 847                 this.SendFlags |= 1;
 848         }
 849         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 850         {
 851                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 852                 this.SendFlags |= 1;
 853         }
 854 }
 855
 856 void ClientInit_Spawn()
 857 {
 858         entity e = new_pure(clientinit);
 859         setthink(e, ClientInit_CheckUpdate);
 860         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 861
 862         ClientInit_CheckUpdate(e);
 863 }
 864
 865 /*
 866 =============
 867 SetNewParms
 868 =============
 869 */
 870 void SetNewParms ()
 871 {
 872         // initialize parms for a new player
 873         parm1 = -(86400 * 366);
 874
 875         MUTATOR_CALLHOOK(SetNewParms);
 876 }
 877
 878 /*
 879 =============
 880 SetChangeParms
 881 =============
 882 */
 883 void SetChangeParms (entity this)
 884 {
 885         // save parms for level change
 886         parm1 = CS(this).parm_idlesince - time;
 887
 888         MUTATOR_CALLHOOK(SetChangeParms);
 889 }
 890
 891 /*
 892 =============
 893 DecodeLevelParms
 894 =============
 895 */
 896 void DecodeLevelParms(entity this)
 897 {
 898         // load parms
 899         CS(this).parm_idlesince = parm1;
 900         if (CS(this).parm_idlesince == -(86400 * 366))
 901                 CS(this).parm_idlesince = time;
 902
 903         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 904         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 905
 906         MUTATOR_CALLHOOK(DecodeLevelParms);
 907 }
 908
 909 void FixClientCvars(entity e)
 910 {
 911         // send prediction settings to the client
 912         stuffcmd(e, "\nin_bindmap 0 0\n");
 913         if(autocvar_g_antilag == 3) // client side hitscan
 914                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 915         if(autocvar_sv_gentle)
 916                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 917
 918         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 919         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 920
 921         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 922
 923         MUTATOR_CALLHOOK(FixClientCvars, e);
 924 }
 925
 926 bool findinlist_abbrev(string tofind, string list)
 927 {
 928         if(list == "" || tofind == "")
 929                 return false; // empty list or search, just return
 930
 931         // this function allows abbreviated strings!
 932         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 933         {
 934                 return true;
 935         });
 936
 937         return false;
 938 }
 939
 940 bool PlayerInIPList(entity p, string iplist)
 941 {
 942         // some safety checks (never allow local?)
 943         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 944                 return false;
 945
 946         return findinlist_abbrev(p.netaddress, iplist);
 947 }
 948
 949 bool PlayerInIDList(entity p, string idlist)
 950 {
 951         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 952         if(!p.crypto_idfp)
 953                 return false;
 954
 955         return findinlist_abbrev(p.crypto_idfp, idlist);
 956 }
 957
 958 bool PlayerInList(entity player, string list)
 959 {
 960         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 961 }
 962
 963 #ifdef DP_EXT_PRECONNECT
 964 /*
 965 =============
 966 ClientPreConnect
 967
 968 Called once (not at each match start) when a client begins a connection to the server
 969 =============
 970 */
 971 void ClientPreConnect(entity this)
 972 {
 973         if(autocvar_sv_eventlog)
 974         {
 975                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 976                         this.playerid,
 977                         etof(this),
 978                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 979                 ));
 980         }
 981 }
 982 #endif
 983
 984 string GetClientVersionMessage(entity this)
 985 {
 986         if (CS(this).version_mismatch) {
 987                 if(CS(this).version < autocvar_gameversion) {
 988                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 989                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
 990                 } else {
 991                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 992                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
 993                 }
 994         } else {
 995                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
 996         }
 997 }
 998
 999 string getwelcomemessage(entity this)
1000 {
1001         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1002         string modifications = M_ARGV(0, string);
1003
1004         if(g_weaponarena)
1005         {
1006                 if(g_weaponarena_random)
1007                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1008                 else
1009                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1010         }
1011         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1012                 modifications = strcat(modifications, ", No start weapons");
1013         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1014                 modifications = strcat(modifications, ", Low gravity");
1015         if(g_weapon_stay && !g_cts)
1016                 modifications = strcat(modifications, ", Weapons stay");
1017         if(g_jetpack)
1018                 modifications = strcat(modifications, ", Jet pack");
1019         if(autocvar_g_powerups == 0)
1020                 modifications = strcat(modifications, ", No powerups");
1021         if(autocvar_g_powerups > 0)
1022                 modifications = strcat(modifications, ", Powerups");
1023         modifications = substring(modifications, 2, strlen(modifications) - 2);
1024
1025         string versionmessage = GetClientVersionMessage(this);
1026         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1027
1028         if(modifications != "")
1029                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1030
1031         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1032         {
1033                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1034                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1035         }
1036
1037         if (cache_mutatormsg != "") {
1038                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1039         }
1040
1041         string mutator_msg = "";
1042         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1043         mutator_msg = M_ARGV(0, string);
1044
1045         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1046
1047         string motd = autocvar_sv_motd;
1048         if (motd != "") {
1049                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1050         }
1051         return s;
1052 }
1053
1054 /**
1055 =============
1056 ClientConnect
1057
1058 Called when a client connects to the server
1059 =============
1060 */
1061 void ClientConnect(entity this)
1062 {
1063         if (Ban_MaybeEnforceBanOnce(this)) return;
1064         assert(!IS_CLIENT(this), return);
1065         this.flags |= FL_CLIENT;
1066         assert(player_count >= 0, player_count = 0);
1067
1068 #ifdef WATERMARK
1069         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1070 #endif
1071         TRANSMUTE(Client, this);
1072         CS(this).version_nagtime = time + 10 + random() * 10;
1073
1074         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1075
1076         bot_clientconnect(this);
1077
1078         Player_DetermineForcedTeam(this);
1079
1080         TRANSMUTE(Observer, this);
1081
1082         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1083
1084         // always track bots, don't ask for cl_allow_uidtracking
1085         if (IS_BOT_CLIENT(this))
1086                 PlayerStats_GameReport_AddPlayer(this);
1087         else
1088                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1089
1090         if (autocvar_sv_eventlog)
1091                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1092
1093         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1094
1095         stuffcmd(this, clientstuff, "\n");
1096         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1097
1098         FixClientCvars(this);
1099
1100         // get version info from player
1101         stuffcmd(this, "cmd clientversion $gameversion\n");
1102
1103         // notify about available teams
1104         if (teamplay)
1105         {
1106                 entity balance = TeamBalance_CheckAllowedTeams(this);
1107                 int t = TeamBalance_GetAllowedTeams(balance);
1108                 TeamBalance_Destroy(balance);
1109                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1110         }
1111         else
1112         {
1113                 stuffcmd(this, "set _teams_available 0\n");
1114         }
1115
1116         bot_relinkplayerlist();
1117
1118         CS(this).spectatortime = time;
1119         if (blockSpectators)
1120         {
1121                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1122         }
1123
1124         CS(this).jointime = time;
1125
1126         if (IS_REAL_CLIENT(this))
1127         {
1128                 if (g_weaponarena_weapons == WEPSET(TUBA))
1129                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1130         }
1131
1132         if (!sv_foginterval && world.fog != "")
1133                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1134
1135         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1136                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1137                         send_CSQC_teamnagger();
1138
1139         CSQCMODEL_AUTOINIT(this);
1140
1141         CS(this).model_randomizer = random();
1142
1143         if (IS_REAL_CLIENT(this))
1144                 sv_notice_join(this);
1145
1146         // update physics stats (players can spawn before physics runs)
1147         Physics_UpdateStats(this);
1148
1149         IL_EACH(g_initforplayer, it.init_for_player, {
1150                 it.init_for_player(it, this);
1151         });
1152
1153         Handicap_Initialize(this);
1154
1155         MUTATOR_CALLHOOK(ClientConnect, this);
1156
1157         if (IS_REAL_CLIENT(this))
1158         {
1159                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1160                 {
1161                         CS(this).motd_actived_time = -1;
1162                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1163                 }
1164         }
1165 }
1166 /*
1167 =============
1168 ClientDisconnect
1169
1170 Called when a client disconnects from the server
1171 =============
1172 */
1173 .entity chatbubbleentity;
1174 void ClientDisconnect(entity this)
1175 {
1176         assert(IS_CLIENT(this), return);
1177
1178         PlayerStats_GameReport_FinalizePlayer(this);
1179         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1180         if (CS(this).active_minigame) part_minigame(this);
1181         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1182
1183         if (autocvar_sv_eventlog)
1184                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1185
1186         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1187
1188         if(IS_SPEC(this))
1189                 SetSpectatee(this, NULL);
1190
1191     MUTATOR_CALLHOOK(ClientDisconnect, this);
1192
1193         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1194         strfree(CS(this).weaponorder_byimpulse);
1195         ClientState_detach(this);
1196
1197         Portal_ClearAll(this);
1198
1199         Unfreeze(this);
1200
1201         RemoveGrapplingHooks(this);
1202
1203         // Here, everything has been done that requires this player to be a client.
1204
1205         this.flags &= ~FL_CLIENT;
1206
1207         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1208         if (this.killindicator) delete(this.killindicator);
1209
1210         WaypointSprite_PlayerGone(this);
1211
1212         bot_relinkplayerlist();
1213
1214         strfree(this.clientstatus);
1215         if (this.personal) delete(this.personal);
1216
1217         this.playerid = 0;
1218         ReadyCount();
1219         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1220
1221         ONREMOVE(this);
1222 }
1223
1224 void ChatBubbleThink(entity this)
1225 {
1226         this.nextthink = time;
1227         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1228         {
1229                 if(this.owner) // but why can that ever be NULL?
1230                         this.owner.chatbubbleentity = NULL;
1231                 delete(this);
1232                 return;
1233         }
1234
1235         this.mdl = "";
1236
1237         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1238         {
1239                 if ( CS(this.owner).active_minigame )
1240                         this.mdl = "models/sprites/minigame_busy.iqm";
1241                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1242                         this.mdl = "models/misc/chatbubble.spr";
1243         }
1244
1245         if ( this.model != this.mdl )
1246                 _setmodel(this, this.mdl);
1247
1248 }
1249
1250 void UpdateChatBubble(entity this)
1251 {
1252         if (this.alpha < 0)
1253                 return;
1254         // spawn a chatbubble entity if needed
1255         if (!this.chatbubbleentity)
1256         {
1257                 this.chatbubbleentity = new(chatbubbleentity);
1258                 this.chatbubbleentity.owner = this;
1259                 this.chatbubbleentity.exteriormodeltoclient = this;
1260                 setthink(this.chatbubbleentity, ChatBubbleThink);
1261                 this.chatbubbleentity.nextthink = time;
1262                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1263                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1264                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1265                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1266                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1267                 //this.chatbubbleentity.model = "";
1268                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1269         }
1270 }
1271
1272
1273 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1274 // added to the model skins
1275 /*void UpdateColorModHack()
1276 {
1277         float c;
1278         c = this.clientcolors & 15;
1279         // LordHavoc: only bothering to support white, green, red, yellow, blue
1280              if (!teamplay) this.colormod = '0 0 0';
1281         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1282         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1283         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1284         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1285         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1286         else this.colormod = '1 1 1';
1287 }*/
1288
1289 void respawn(entity this)
1290 {
1291         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1292         {
1293                 this.solid = SOLID_NOT;
1294                 this.takedamage = DAMAGE_NO;
1295                 set_movetype(this, MOVETYPE_FLY);
1296                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1297                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1298                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1299                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1300                 if(autocvar_g_respawn_ghosts_maxtime)
1301                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1302         }
1303
1304         CopyBody(this, 1);
1305
1306         this.effects |= EF_NODRAW; // prevent another CopyBody
1307         PutClientInServer(this);
1308 }
1309
1310 void PrintToChat(entity client, string text)
1311 {
1312         text = strcat("\{1}^7", text, "\n");
1313         sprint(client, text);
1314 }
1315
1316 void DebugPrintToChat(entity client, string text)
1317 {
1318         if (autocvar_developer)
1319         {
1320                 PrintToChat(client, text);
1321         }
1322 }
1323
1324 void PrintToChatAll(string text)
1325 {
1326         text = strcat("\{1}^7", text, "\n");
1327         bprint(text);
1328 }
1329
1330 void DebugPrintToChatAll(string text)
1331 {
1332         if (autocvar_developer)
1333         {
1334                 PrintToChatAll(text);
1335         }
1336 }
1337
1338 void PrintToChatTeam(int team_num, string text)
1339 {
1340         text = strcat("\{1}^7", text, "\n");
1341         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1342         {
1343                 if (it.team == team_num)
1344                 {
1345                         sprint(it, text);
1346                 }
1347         });
1348 }
1349
1350 void DebugPrintToChatTeam(int team_num, string text)
1351 {
1352         if (autocvar_developer)
1353         {
1354                 PrintToChatTeam(team_num, text);
1355         }
1356 }
1357
1358 void play_countdown(entity this, float finished, Sound samp)
1359 {
1360         TC(Sound, samp);
1361         if(IS_REAL_CLIENT(this))
1362                 if(floor(finished - time - frametime) != floor(finished - time))
1363                         if(finished - time < 6)
1364                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1365 }
1366
1367 void player_powerups(entity this)
1368 {
1369         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1370         int items_prev = this.items;
1371
1372         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1373                 this.modelflags |= MF_ROCKET;
1374         else
1375                 this.modelflags &= ~MF_ROCKET;
1376
1377         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1378
1379         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1380                 return;
1381
1382         Fire_ApplyDamage(this);
1383         Fire_ApplyEffect(this);
1384
1385         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1386         {
1387                 if (this.items & ITEM_Strength.m_itemid)
1388                 {
1389                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1390                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1391                         if (time > this.strength_finished)
1392                         {
1393                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1394                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1395                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1396                         }
1397                 }
1398                 else
1399                 {
1400                         if (time < this.strength_finished)
1401                         {
1402                                 this.items = this.items | ITEM_Strength.m_itemid;
1403                                 if(!g_cts)
1404                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1405                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1406                         }
1407                 }
1408                 if (this.items & ITEM_Shield.m_itemid)
1409                 {
1410                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1411                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1412                         if (time > this.invincible_finished)
1413                         {
1414                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1415                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1416                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1417                         }
1418                 }
1419                 else
1420                 {
1421                         if (time < this.invincible_finished)
1422                         {
1423                                 this.items = this.items | ITEM_Shield.m_itemid;
1424                                 if(!g_cts)
1425                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1426                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1427                         }
1428                 }
1429                 if (this.items & IT_SUPERWEAPON)
1430                 {
1431                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1432                         {
1433                                 this.superweapons_finished = 0;
1434                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1435                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1437                         }
1438                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1439                         {
1440                                 // don't let them run out
1441                         }
1442                         else
1443                         {
1444                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1445                                 if (time > this.superweapons_finished)
1446                                 {
1447                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1448                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1449                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1450                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1451                                 }
1452                         }
1453                 }
1454                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1455                 {
1456                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1457                         {
1458                                 this.items = this.items | IT_SUPERWEAPON;
1459                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1460                                 {
1461                                         if(!g_cts)
1462                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1463                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1464                                 }
1465                         }
1466                         else
1467                         {
1468                                 this.superweapons_finished = 0;
1469                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1470                         }
1471                 }
1472                 else
1473                 {
1474                         this.superweapons_finished = 0;
1475                 }
1476         }
1477
1478         if(autocvar_g_nodepthtestplayers)
1479                 this.effects = this.effects | EF_NODEPTHTEST;
1480
1481         if(autocvar_g_fullbrightplayers)
1482                 this.effects = this.effects | EF_FULLBRIGHT;
1483
1484         if (time >= game_starttime)
1485         if (time < this.spawnshieldtime)
1486                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1487
1488         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1489 }
1490
1491 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1492 {
1493         if(current > stable)
1494                 return current;
1495         else if(current > stable - 0.25) // when close enough, "snap"
1496                 return stable;
1497         else
1498                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1499 }
1500
1501 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1502 {
1503         if(current < stable)
1504                 return current;
1505         else if(current < stable + 0.25) // when close enough, "snap"
1506                 return stable;
1507         else
1508                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1509 }
1510
1511 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1512 {
1513         if(current > rotstable)
1514         {
1515                 if(rotframetime > 0)
1516                 {
1517                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1518                         current = max(rotstable, current - rotlinear * rotframetime);
1519                 }
1520         }
1521         else if(current < regenstable)
1522         {
1523                 if(regenframetime > 0)
1524                 {
1525                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1526                         current = min(regenstable, current + regenlinear * regenframetime);
1527                 }
1528         }
1529
1530         if(current > limit)
1531                 current = limit;
1532
1533         return current;
1534 }
1535
1536 void player_regen(entity this)
1537 {
1538         float max_mod, regen_mod, rot_mod, limit_mod;
1539         max_mod = regen_mod = rot_mod = limit_mod = 1;
1540
1541         float regen_health = autocvar_g_balance_health_regen;
1542         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1543         float regen_health_rot = autocvar_g_balance_health_rot;
1544         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1545         float regen_health_stable = autocvar_g_balance_health_regenstable;
1546         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1547         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1548                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1549         max_mod = M_ARGV(1, float);
1550         regen_mod = M_ARGV(2, float);
1551         rot_mod = M_ARGV(3, float);
1552         limit_mod = M_ARGV(4, float);
1553         regen_health = M_ARGV(5, float);
1554         regen_health_linear = M_ARGV(6, float);
1555         regen_health_rot = M_ARGV(7, float);
1556         regen_health_rotlinear = M_ARGV(8, float);
1557         regen_health_stable = M_ARGV(9, float);
1558         regen_health_rotstable = M_ARGV(10, float);
1559
1560         if(!mutator_returnvalue)
1561         if(!STAT(FROZEN, this))
1562         {
1563                 float mina, maxa, limith, limita;
1564                 maxa = autocvar_g_balance_armor_rotstable;
1565                 mina = autocvar_g_balance_armor_regenstable;
1566                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1567                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1568
1569                 regen_health_rotstable = regen_health_rotstable * max_mod;
1570                 regen_health_stable = regen_health_stable * max_mod;
1571                 limith = limith * limit_mod;
1572                 limita = limita * limit_mod;
1573
1574                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1575                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1576                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1577                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1578                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1579                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1580         }
1581
1582         // if player rotted to death...  die!
1583         // check this outside above checks, as player may still be able to rot to death
1584         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1585         {
1586                 if(this.vehicle)
1587                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1588                 if(this.event_damage)
1589                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1590         }
1591
1592         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1593         {
1594                 float minf, maxf, limitf;
1595
1596                 maxf = autocvar_g_balance_fuel_rotstable;
1597                 minf = autocvar_g_balance_fuel_regenstable;
1598                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1599
1600                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1601                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1602                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1603         }
1604 }
1605
1606 bool zoomstate_set;
1607 void SetZoomState(entity this, float newzoom)
1608 {
1609         if(newzoom != CS(this).zoomstate)
1610         {
1611                 CS(this).zoomstate = newzoom;
1612                 ClientData_Touch(this);
1613         }
1614         zoomstate_set = true;
1615 }
1616
1617 void GetPressedKeys(entity this)
1618 {
1619         MUTATOR_CALLHOOK(GetPressedKeys, this);
1620         int keys = STAT(PRESSED_KEYS, this);
1621         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1622         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1623         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1624         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1625
1626         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1627         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1628         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1629         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1630         CS(this).pressedkeys = keys; // store for other users
1631
1632         STAT(PRESSED_KEYS, this) = keys;
1633 }
1634
1635 /*
1636 ======================
1637 spectate mode routines
1638 ======================
1639 */
1640
1641 void SpectateCopy(entity this, entity spectatee)
1642 {
1643         TC(Client, this); TC(Client, spectatee);
1644
1645         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1646         PS(this) = PS(spectatee);
1647         this.armortype = spectatee.armortype;
1648         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1649         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1650         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1651         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1652         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1653         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1654         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1655         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1656         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1657         CS(this).impulse = 0;
1658         this.items = spectatee.items;
1659         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1660         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1661         this.strength_finished = spectatee.strength_finished;
1662         this.invincible_finished = spectatee.invincible_finished;
1663         this.superweapons_finished = spectatee.superweapons_finished;
1664         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1665         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1666         this.punchangle = spectatee.punchangle;
1667         this.view_ofs = spectatee.view_ofs;
1668         this.velocity = spectatee.velocity;
1669         this.dmg_take = spectatee.dmg_take;
1670         this.dmg_save = spectatee.dmg_save;
1671         this.dmg_inflictor = spectatee.dmg_inflictor;
1672         this.v_angle = spectatee.v_angle;
1673         this.angles = spectatee.v_angle;
1674         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1675         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1676         this.viewloc = spectatee.viewloc;
1677         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1678                 this.fixangle = true;
1679         setorigin(this, spectatee.origin);
1680         setsize(this, spectatee.mins, spectatee.maxs);
1681         SetZoomState(this, CS(spectatee).zoomstate);
1682
1683     anticheat_spectatecopy(this, spectatee);
1684         STAT(HUD, this) = STAT(HUD, spectatee);
1685         if(spectatee.vehicle)
1686     {
1687         this.angles = spectatee.v_angle;
1688
1689         //this.fixangle = false;
1690         //this.velocity = spectatee.vehicle.velocity;
1691         this.vehicle_health = spectatee.vehicle_health;
1692         this.vehicle_shield = spectatee.vehicle_shield;
1693         this.vehicle_energy = spectatee.vehicle_energy;
1694         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1695         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1696         this.vehicle_reload1 = spectatee.vehicle_reload1;
1697         this.vehicle_reload2 = spectatee.vehicle_reload2;
1698
1699         //msg_entity = this;
1700
1701        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1702             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1703            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1704            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1705
1706         //WriteByte (MSG_ONE, SVC_SETVIEW);
1707         //    WriteEntity(MSG_ONE, this);
1708         //makevectors(spectatee.v_angle);
1709         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1710     }
1711 }
1712
1713 bool SpectateUpdate(entity this)
1714 {
1715         if(!this.enemy)
1716                 return false;
1717
1718         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1719         {
1720                 SetSpectatee(this, NULL);
1721                 return false;
1722         }
1723
1724         SpectateCopy(this, this.enemy);
1725
1726         return true;
1727 }
1728
1729 bool SpectateSet(entity this)
1730 {
1731         if(!IS_PLAYER(this.enemy))
1732                 return false;
1733
1734         ClientData_Touch(this.enemy);
1735
1736         msg_entity = this;
1737         WriteByte(MSG_ONE, SVC_SETVIEW);
1738         WriteEntity(MSG_ONE, this.enemy);
1739         set_movetype(this, MOVETYPE_NONE);
1740         accuracy_resend(this);
1741
1742         if(!SpectateUpdate(this))
1743                 PutObserverInServer(this);
1744
1745         return true;
1746 }
1747
1748 void SetSpectatee_status(entity this, int spectatee_num)
1749 {
1750         int oldspectatee_status = CS(this).spectatee_status;
1751         CS(this).spectatee_status = spectatee_num;
1752
1753         if (CS(this).spectatee_status != oldspectatee_status)
1754         {
1755                 ClientData_Touch(this);
1756                 if (g_race || g_cts) race_InitSpectator();
1757         }
1758 }
1759
1760 void SetSpectatee(entity this, entity spectatee)
1761 {
1762         if(IS_BOT_CLIENT(this))
1763                 return; // bots abuse .enemy, this code is useless to them
1764
1765         entity old_spectatee = this.enemy;
1766
1767         this.enemy = spectatee;
1768
1769         // WEAPONTODO
1770         // these are required to fix the spectator bug with arc
1771         if(old_spectatee)
1772         {
1773                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1774                 {
1775                         .entity weaponentity = weaponentities[slot];
1776                         if(old_spectatee.(weaponentity).arc_beam)
1777                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1778                 }
1779         }
1780         if(this.enemy)
1781         {
1782                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1783                 {
1784                         .entity weaponentity = weaponentities[slot];
1785                         if(this.enemy.(weaponentity).arc_beam)
1786                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1787                 }
1788         }
1789
1790         if (this.enemy)
1791                 SetSpectatee_status(this, etof(this.enemy));
1792
1793         // needed to update spectator list
1794         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1795 }
1796
1797 bool Spectate(entity this, entity pl)
1798 {
1799         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1800                 return false;
1801         pl = M_ARGV(1, entity);
1802
1803         SetSpectatee(this, pl);
1804         return SpectateSet(this);
1805 }
1806
1807 bool SpectateNext(entity this)
1808 {
1809         entity ent = find(this.enemy, classname, STR_PLAYER);
1810
1811         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1812                 ent = M_ARGV(1, entity);
1813         else if (!ent)
1814                 ent = find(ent, classname, STR_PLAYER);
1815
1816         if(ent) { SetSpectatee(this, ent); }
1817
1818         return SpectateSet(this);
1819 }
1820
1821 bool SpectatePrev(entity this)
1822 {
1823         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1824         entity ent = findchain(classname, STR_PLAYER);
1825         if (!ent) // no player
1826                 return false;
1827
1828         entity first = ent;
1829         // skip players until current spectated player
1830         if(this.enemy)
1831         while(ent && ent != this.enemy)
1832                 ent = ent.chain;
1833
1834         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1835         {
1836                 case MUT_SPECPREV_FOUND:
1837                     ent = M_ARGV(1, entity);
1838                     break;
1839                 case MUT_SPECPREV_RETURN:
1840                     return true;
1841                 case MUT_SPECPREV_CONTINUE:
1842                 default:
1843                 {
1844                         if(ent.chain)
1845                                 ent = ent.chain;
1846                         else
1847                                 ent = first;
1848                         break;
1849                 }
1850         }
1851
1852         SetSpectatee(this, ent);
1853         return SpectateSet(this);
1854 }
1855
1856 /*
1857 =============
1858 ShowRespawnCountdown()
1859
1860 Update a respawn countdown display.
1861 =============
1862 */
1863 void ShowRespawnCountdown(entity this)
1864 {
1865         float number;
1866         if(!IS_DEAD(this)) // just respawned?
1867                 return;
1868         else
1869         {
1870                 number = ceil(this.respawn_time - time);
1871                 if(number <= 0)
1872                         return;
1873                 if(number <= this.respawn_countdown)
1874                 {
1875                         this.respawn_countdown = number - 1;
1876                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1877                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1878                 }
1879         }
1880 }
1881
1882 .bool team_selected;
1883 bool ShowTeamSelection(entity this)
1884 {
1885         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1886                 return false;
1887         stuffcmd(this, "menu_showteamselect\n");
1888         return true;
1889 }
1890 void Join(entity this)
1891 {
1892         TRANSMUTE(Player, this);
1893
1894         if(!this.team_selected)
1895         if(autocvar_g_campaign || autocvar_g_balance_teams)
1896                 TeamBalance_JoinBestTeam(this);
1897
1898         if(autocvar_g_campaign)
1899                 campaign_bots_may_start = true;
1900
1901         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1902
1903         PutClientInServer(this);
1904
1905         if(IS_PLAYER(this))
1906         if(teamplay && this.team != -1)
1907         {
1908         }
1909         else
1910                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1911         this.team_selected = false;
1912 }
1913
1914 /**
1915  * Determines whether the player is allowed to join. This depends on cvar
1916  * g_maxplayers, if it isn't used this function always return true, otherwise
1917  * it checks whether the number of currently playing players exceeds g_maxplayers.
1918  * @return int number of free slots for players, 0 if none
1919  */
1920 int nJoinAllowed(entity this, entity ignore)
1921 {
1922         if(!ignore)
1923         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1924         // so report 0 free slots if restricted
1925         {
1926                 if(autocvar_g_forced_team_otherwise == "spectate")
1927                         return 0;
1928                 if(autocvar_g_forced_team_otherwise == "spectator")
1929                         return 0;
1930         }
1931
1932         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1933                 return 0; // forced spectators can never join
1934
1935         // TODO simplify this
1936         int totalClients = 0;
1937         int currentlyPlaying = 0;
1938         FOREACH_CLIENT(true, {
1939                 if(it != ignore)
1940                         ++totalClients;
1941                 if(IS_REAL_CLIENT(it))
1942                 if(IS_PLAYER(it) || it.caplayer)
1943                         ++currentlyPlaying;
1944         });
1945
1946         float free_slots = 0;
1947         if (!autocvar_g_maxplayers)
1948                 free_slots = maxclients - totalClients;
1949         else if(currentlyPlaying < autocvar_g_maxplayers)
1950                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1951
1952         static float join_prevent_msg_time = 0;
1953         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1954         {
1955                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1956                 join_prevent_msg_time = time + 3;
1957         }
1958
1959         return free_slots;
1960 }
1961
1962 /**
1963  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1964  * g_maxplayers_spectator_blocktime seconds
1965  */
1966 void checkSpectatorBlock(entity this)
1967 {
1968         if(IS_SPEC(this) || IS_OBSERVER(this))
1969         if(!this.caplayer)
1970         if(IS_REAL_CLIENT(this))
1971         {
1972                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1973                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1974                         dropclient(this);
1975                 }
1976         }
1977 }
1978
1979 void PrintWelcomeMessage(entity this)
1980 {
1981         if(CS(this).motd_actived_time == 0)
1982         {
1983                 if (autocvar_g_campaign) {
1984                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1985                                 CS(this).motd_actived_time = time;
1986                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1987                         }
1988                 } else {
1989                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1990                                 CS(this).motd_actived_time = time;
1991                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1992                         }
1993                 }
1994         }
1995         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
1996         {
1997                 if (autocvar_g_campaign) {
1998                         if (PHYS_INPUT_BUTTON_INFO(this))
1999                                 CS(this).motd_actived_time = time;
2000                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2001                                 CS(this).motd_actived_time = 0;
2002                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2003                         }
2004                 } else {
2005                         if (PHYS_INPUT_BUTTON_INFO(this))
2006                                 CS(this).motd_actived_time = time;
2007                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2008                                 CS(this).motd_actived_time = 0;
2009                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2010                         }
2011                 }
2012         }
2013         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2014         {
2015                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2016                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2017                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2018                 {
2019                         // instanctly hide MOTD
2020                         CS(this).motd_actived_time = 0;
2021                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2022                 }
2023         }
2024 }
2025
2026 const int MIN_SPEC_TIME = 1;
2027 bool joinAllowed(entity this)
2028 {
2029         if (CS(this).version_mismatch) return false;
2030         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2031         if (!nJoinAllowed(this, this)) return false;
2032         if (teamplay && lockteams) return false;
2033         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2034         if (ShowTeamSelection(this)) return false;
2035         return true;
2036 }
2037
2038 .int items_added;
2039 .string shootfromfixedorigin;
2040 bool PlayerThink(entity this)
2041 {
2042         if (game_stopped || intermission_running) {
2043                 this.modelflags &= ~MF_ROCKET;
2044                 if(intermission_running)
2045                         IntermissionThink(this);
2046                 return false;
2047         }
2048
2049         if (timeout_status == TIMEOUT_ACTIVE) {
2050         // don't allow the player to turn around while game is paused
2051                 // FIXME turn this into CSQC stuff
2052                 this.v_angle = this.lastV_angle;
2053                 this.angles = this.lastV_angle;
2054                 this.fixangle = true;
2055         }
2056
2057         if (frametime) player_powerups(this);
2058
2059         if (IS_DEAD(this)) {
2060                 if (this.personal && g_race_qualifying) {
2061                         if (time > this.respawn_time) {
2062                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2063                                 respawn(this);
2064                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2065                         }
2066                 } else {
2067                         if (frametime) player_anim(this);
2068
2069                         if (this.respawn_flags & RESPAWN_DENY)
2070                         {
2071                                 STAT(RESPAWN_TIME, this) = 0;
2072                                 return false;
2073                         }
2074
2075                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2076
2077                         switch(this.deadflag)
2078                         {
2079                                 case DEAD_DYING:
2080                                 {
2081                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2082                                                 this.deadflag = DEAD_RESPAWNING;
2083                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2084                                                 this.deadflag = DEAD_DEAD;
2085                                         break;
2086                                 }
2087                                 case DEAD_DEAD:
2088                                 {
2089                                         if (button_pressed)
2090                                                 this.deadflag = DEAD_RESPAWNABLE;
2091                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2092                                                 this.deadflag = DEAD_RESPAWNING;
2093                                         break;
2094                                 }
2095                                 case DEAD_RESPAWNABLE:
2096                                 {
2097                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2098                                                 this.deadflag = DEAD_RESPAWNING;
2099                                         break;
2100                                 }
2101                                 case DEAD_RESPAWNING:
2102                                 {
2103                                         if (time > this.respawn_time)
2104                                         {
2105                                                 this.respawn_time = time + 1; // only retry once a second
2106                                                 this.respawn_time_max = this.respawn_time;
2107                                                 respawn(this);
2108                                         }
2109                                         break;
2110                                 }
2111                         }
2112
2113                         ShowRespawnCountdown(this);
2114
2115                         if (this.respawn_flags & RESPAWN_SILENT)
2116                                 STAT(RESPAWN_TIME, this) = 0;
2117                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2118                         {
2119                                 if (time < this.respawn_time)
2120                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2121                                 else if (this.deadflag != DEAD_RESPAWNING)
2122                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2123                         }
2124                         else
2125                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2126                 }
2127
2128                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2129                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2130                         STAT(RESPAWN_TIME, this) *= -1;
2131
2132                 return false;
2133         }
2134
2135         FixPlayermodel(this);
2136
2137         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2138                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2139                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2140         }
2141
2142         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2143         //if(frametime)
2144         {
2145                 this.items &= ~this.items_added;
2146
2147                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2148                 {
2149                         .entity weaponentity = weaponentities[slot];
2150                         W_WeaponFrame(this, weaponentity);
2151                 }
2152
2153                 this.items_added = 0;
2154                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2155             this.items_added |= IT_FUEL;
2156
2157                 this.items |= this.items_added;
2158         }
2159
2160         player_regen(this);
2161
2162         // WEAPONTODO: Add a weapon request for this
2163         // rot vortex charge to the charge limit
2164         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2165         {
2166                 .entity weaponentity = weaponentities[slot];
2167                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2168                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2169         }
2170
2171         if (frametime) player_anim(this);
2172
2173         // secret status
2174         secrets_setstatus(this);
2175
2176         // monsters status
2177         monsters_setstatus(this);
2178
2179         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2180
2181         return true;
2182 }
2183
2184 .bool would_spectate;
2185 void ObserverThink(entity this)
2186 {
2187         if ( CS(this).impulse )
2188         {
2189                 MinigameImpulse(this, CS(this).impulse);
2190                 CS(this).impulse = 0;
2191         }
2192
2193         if (this.flags & FL_JUMPRELEASED) {
2194                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2195                         this.flags &= ~FL_JUMPRELEASED;
2196                         this.flags |= FL_SPAWNING;
2197                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2198                         this.flags &= ~FL_JUMPRELEASED;
2199                         if(SpectateNext(this)) {
2200                                 TRANSMUTE(Spectator, this);
2201                         }
2202                 } else {
2203                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2204                         set_movetype(this, preferred_movetype);
2205                 }
2206         } else {
2207                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2208                         this.flags |= FL_JUMPRELEASED;
2209                         if(this.flags & FL_SPAWNING)
2210                         {
2211                                 this.flags &= ~FL_SPAWNING;
2212                                 Join(this);
2213                                 return;
2214                         }
2215                 }
2216         }
2217 }
2218
2219 void SpectatorThink(entity this)
2220 {
2221         if ( CS(this).impulse )
2222         {
2223                 if(MinigameImpulse(this, CS(this).impulse))
2224                         CS(this).impulse = 0;
2225
2226                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2227                 {
2228                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2229                         CS(this).impulse = 0;
2230                         return;
2231                 }
2232         }
2233
2234         if (this.flags & FL_JUMPRELEASED) {
2235                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2236                         this.flags &= ~FL_JUMPRELEASED;
2237                         this.flags |= FL_SPAWNING;
2238                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2239                         this.flags &= ~FL_JUMPRELEASED;
2240                         if(SpectateNext(this)) {
2241                                 TRANSMUTE(Spectator, this);
2242                         } else {
2243                                 TRANSMUTE(Observer, this);
2244                                 PutClientInServer(this);
2245                         }
2246                         CS(this).impulse = 0;
2247                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2248                         this.flags &= ~FL_JUMPRELEASED;
2249                         if(SpectatePrev(this)) {
2250                                 TRANSMUTE(Spectator, this);
2251                         } else {
2252                                 TRANSMUTE(Observer, this);
2253                                 PutClientInServer(this);
2254                         }
2255                         CS(this).impulse = 0;
2256                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2257                         this.would_spectate = false;
2258                         this.flags &= ~FL_JUMPRELEASED;
2259                         TRANSMUTE(Observer, this);
2260                         PutClientInServer(this);
2261                 } else {
2262                         if(!SpectateUpdate(this))
2263                         {
2264                                 if(!SpectateNext(this))
2265                                 {
2266                                         PutObserverInServer(this);
2267                                         this.would_spectate = true;
2268                                 }
2269                         }
2270                 }
2271         } else {
2272                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2273                         this.flags |= FL_JUMPRELEASED;
2274                         if(this.flags & FL_SPAWNING)
2275                         {
2276                                 this.flags &= ~FL_SPAWNING;
2277                                 Join(this);
2278                                 return;
2279                         }
2280                 }
2281                 if(!SpectateUpdate(this))
2282                         PutObserverInServer(this);
2283         }
2284
2285         this.flags |= FL_CLIENT | FL_NOTARGET;
2286 }
2287
2288 void PlayerUseKey(entity this)
2289 {
2290         if (!IS_PLAYER(this))
2291                 return;
2292
2293         if(this.vehicle)
2294         {
2295                 if(!game_stopped)
2296                 {
2297                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2298                         return;
2299                 }
2300         }
2301         else if(autocvar_g_vehicles_enter)
2302         {
2303                 if(!STAT(FROZEN, this))
2304                 if(!IS_DEAD(this))
2305                 if(!game_stopped)
2306                 {
2307                         entity head, closest_target = NULL;
2308                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2309
2310                         while(head) // find the closest acceptable target to enter
2311                         {
2312                                 if(IS_VEHICLE(head))
2313                                 if(!IS_DEAD(head))
2314                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2315                                 if(head.takedamage != DAMAGE_NO)
2316                                 {
2317                                         if(closest_target)
2318                                         {
2319                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2320                                                 { closest_target = head; }
2321                                         }
2322                                         else { closest_target = head; }
2323                                 }
2324
2325                                 head = head.chain;
2326                         }
2327
2328                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2329                 }
2330         }
2331
2332         // a use key was pressed; call handlers
2333         MUTATOR_CALLHOOK(PlayerUseKey, this);
2334 }
2335
2336
2337 /*
2338 =============
2339 PlayerPreThink
2340
2341 Called every frame for each client before the physics are run
2342 =============
2343 */
2344 .float last_vehiclecheck;
2345 void PlayerPreThink (entity this)
2346 {
2347         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2348         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2349
2350         WarpZone_PlayerPhysics_FixVAngle(this);
2351
2352         if (frametime) {
2353                 // physics frames: update anticheat stuff
2354                 anticheat_prethink(this);
2355         }
2356
2357         if (blockSpectators && frametime) {
2358                 // WORKAROUND: only use dropclient in server frames (frametime set).
2359                 // Never use it in cl_movement frames (frametime zero).
2360                 checkSpectatorBlock(this);
2361         }
2362
2363         zoomstate_set = false;
2364
2365         // Check for nameless players
2366         if (this.netname == "" || this.netname != CS(this).netname_previous)
2367         {
2368                 bool assume_unchanged = (CS(this).netname_previous == "");
2369                 if (isInvisibleString(this.netname))
2370                 {
2371                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2372                         assume_unchanged = false;
2373                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2374                 }
2375                 if (!assume_unchanged && autocvar_sv_eventlog)
2376                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2377                 strcpy(CS(this).netname_previous, this.netname);
2378         }
2379
2380         // version nagging
2381         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2382         CS(this).version_nagtime = 0;
2383         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2384             // git client
2385         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2386             // git server
2387             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2388         } else {
2389             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2390             if (r < 0) { // old client
2391                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2392             } else if (r > 0) { // old server
2393                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2394             }
2395         }
2396     }
2397
2398         // GOD MODE info
2399         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2400         {
2401                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2402                 this.max_armorvalue = 0;
2403         }
2404
2405         if(IS_PLAYER(this))
2406         {
2407                 if (STAT(FROZEN, this) == 2)
2408                 {
2409                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2410                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2411                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2412
2413                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2414                                 Unfreeze(this);
2415                 }
2416                 else if (STAT(FROZEN, this) == 3)
2417                 {
2418                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2419                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2420
2421                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2422                         {
2423                                 if (this.vehicle)
2424                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2425                                 if(this.event_damage)
2426                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2427                         }
2428                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2429                                 Unfreeze(this);
2430                 }
2431         }
2432
2433         MUTATOR_CALLHOOK(PlayerPreThink, this);
2434
2435         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2436         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2437         {
2438                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2439                 {
2440                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2441                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2442                         {
2443                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2444                         }
2445                         else if(!it.owner)
2446                         {
2447                                 if(!it.team || SAME_TEAM(this, it))
2448                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2449                                 else if(autocvar_g_vehicles_steal)
2450                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2451                         }
2452                 });
2453
2454                 this.last_vehiclecheck = time + 1;
2455         }
2456
2457         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2458         {
2459                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2460                         PlayerUseKey(this);
2461                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2462         }
2463
2464         if (IS_REAL_CLIENT(this))
2465                 PrintWelcomeMessage(this);
2466
2467         if (IS_PLAYER(this)) {
2468                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2469                         error("Client can't be spawned as player on connection!");
2470                 if(!PlayerThink(this))
2471                         return;
2472         }
2473         else if (game_stopped || intermission_running) {
2474                 if(intermission_running)
2475                         IntermissionThink(this);
2476                 return;
2477         }
2478         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2479         {
2480                 CS(this).autojoin_checked = true;
2481                 // don't do this in ClientConnect
2482                 // many things can go wrong if a client is spawned as player on connection
2483                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2484                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2485                                 && (!teamplay || autocvar_g_balance_teams)))
2486                 {
2487                         campaign_bots_may_start = true;
2488                         Join(this);
2489                         return;
2490                 }
2491         }
2492         else if (IS_OBSERVER(this)) {
2493                 ObserverThink(this);
2494         }
2495         else if (IS_SPEC(this)) {
2496                 SpectatorThink(this);
2497         }
2498
2499         // WEAPONTODO: Add weapon request for this
2500         if (!zoomstate_set) {
2501                 bool wep_zoomed = false;
2502                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2503                 {
2504                         .entity weaponentity = weaponentities[slot];
2505                         Weapon thiswep = this.(weaponentity).m_weapon;
2506                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2507                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2508                 }
2509                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2510     }
2511
2512         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2513         {
2514                 CS(this).teamkill_soundtime = 0;
2515
2516                 entity e = CS(this).teamkill_soundsource;
2517                 entity oldpusher = e.pusher;
2518                 e.pusher = this;
2519                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2520                 e.pusher = oldpusher;
2521         }
2522
2523         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2524                 CS(this).taunt_soundtime = 0;
2525                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2526         }
2527
2528         target_voicescript_next(this);
2529
2530         // WEAPONTODO: Move into weaponsystem somehow
2531         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2532         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2533         {
2534                 .entity weaponentity = weaponentities[slot];
2535                 if(this.(weaponentity).m_weapon == WEP_Null)
2536                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2537         }
2538 }
2539
2540 void DrownPlayer(entity this)
2541 {
2542         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2543                 return;
2544
2545         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2546         {
2547                 if(this.air_finished < time)
2548                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2549                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2550         }
2551         else if (this.air_finished < time)
2552         {       // drown!
2553                 if (this.pain_finished < time)
2554                 {
2555                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2556                         this.pain_finished = time + 0.5;
2557                 }
2558         }
2559 }
2560
2561 .bool move_qcphysics;
2562
2563 void Player_Physics(entity this)
2564 {
2565         set_movetype(this, this.move_movetype);
2566
2567         if(!this.move_qcphysics)
2568                 return;
2569
2570         if(!frametime && !CS(this).pm_frametime)
2571                 return;
2572
2573         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2574
2575         CS(this).pm_frametime = 0;
2576 }
2577
2578 /*
2579 =============
2580 PlayerPostThink
2581
2582 Called every frame for each client after the physics are run
2583 =============
2584 */
2585 void PlayerPostThink (entity this)
2586 {
2587         Player_Physics(this);
2588
2589         if (sv_maxidle > 0)
2590         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2591         if (IS_REAL_CLIENT(this))
2592         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2593         {
2594                 int totalClients = 0;
2595                 if(sv_maxidle_slots > 0)
2596                 {
2597                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2598                         {
2599                                 ++totalClients;
2600                         });
2601                 }
2602
2603                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2604                 { /* do nothing */ }
2605                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2606                 {
2607                         if (CS(this).idlekick_lasttimeleft)
2608                         {
2609                                 CS(this).idlekick_lasttimeleft = 0;
2610                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2611                         }
2612                 }
2613                 else
2614                 {
2615                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2616                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2617                                 if (!CS(this).idlekick_lasttimeleft)
2618                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2619                         }
2620                         if (timeleft <= 0) {
2621                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2622                                 dropclient(this);
2623                                 return;
2624                         }
2625                         else if (timeleft <= 10) {
2626                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2627                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2628                 }
2629                                 CS(this).idlekick_lasttimeleft = timeleft;
2630                         }
2631                 }
2632         }
2633
2634         CheatFrame(this);
2635
2636         if (game_stopped)
2637         {
2638                 this.solid = SOLID_NOT;
2639                 this.takedamage = DAMAGE_NO;
2640                 set_movetype(this, MOVETYPE_NONE);
2641         }
2642
2643         if (IS_PLAYER(this)) {
2644                 if(this.death_time == time && IS_DEAD(this))
2645                 {
2646                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2647                         // once all the damage events of this frame have been processed with normal size
2648                         this.maxs.z = 5;
2649                         setsize(this, this.mins, this.maxs);
2650                 }
2651                 DrownPlayer(this);
2652                 UpdateChatBubble(this);
2653                 if (CS(this).impulse) ImpulseCommands(this);
2654                 if (game_stopped)
2655                 {
2656                         CSQCMODEL_AUTOUPDATE(this);
2657                         return;
2658                 }
2659                 GetPressedKeys(this);
2660         }
2661
2662         if (this.waypointsprite_attachedforcarrier) {
2663             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2664                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2665     }
2666
2667         CSQCMODEL_AUTOUPDATE(this);
2668 }
2669
2670 // hack to copy the button fields from the client entity to the Client State
2671 void PM_UpdateButtons(entity this, entity store)
2672 {
2673         if(this.impulse)
2674                 store.impulse = this.impulse;
2675         this.impulse = 0;
2676
2677         bool typing = this.buttonchat;
2678
2679         store.button0 = (typing) ? 0 : this.button0;
2680         //button1?!
2681         store.button2 = (typing) ? 0 : this.button2;
2682         store.button3 = (typing) ? 0 : this.button3;
2683         store.button4 = this.button4;
2684         store.button5 = (typing) ? 0 : this.button5;
2685         store.button6 = this.button6;
2686         store.button7 = this.button7;
2687         store.button8 = this.button8;
2688         store.button9 = this.button9;
2689         store.button10 = this.button10;
2690         store.button11 = this.button11;
2691         store.button12 = this.button12;
2692         store.button13 = this.button13;
2693         store.button14 = this.button14;
2694         store.button15 = this.button15;
2695         store.button16 = this.button16;
2696         store.buttonuse = this.buttonuse;
2697         store.buttonchat = this.buttonchat;
2698
2699         store.cursor_active = this.cursor_active;
2700         store.cursor_screen = this.cursor_screen;
2701         store.cursor_trace_start = this.cursor_trace_start;
2702         store.cursor_trace_endpos = this.cursor_trace_endpos;
2703         store.cursor_trace_ent = this.cursor_trace_ent;
2704
2705         store.ping = this.ping;
2706         store.ping_packetloss = this.ping_packetloss;
2707         store.ping_movementloss = this.ping_movementloss;
2708
2709         store.v_angle = this.v_angle;
2710         store.movement = (typing) ? '0 0 0' : this.movement;
2711 }
2712
2713 NET_HANDLE(fpsreport, bool)
2714 {
2715         int fps = ReadShort();
2716         PlayerScore_Set(sender, SP_FPS, fps);
2717         return true;
2718 }