qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 141                                         sf |= BIT(4); // show spectators
 142
 143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 144         WriteByte(MSG_ENTITY, sf);
 145
 146         if (sf & BIT(1))
 147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 148
 149         if(sf & BIT(4))
 150         {
 151                 float specs = CountSpectators(e, to);
 152                 WriteByte(MSG_ENTITY, specs);
 153                 WriteSpectators(e, to);
 154         }
 155
 156         return true;
 157 }
 158
 159 void ClientData_Attach(entity this)
 160 {
 161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 162         CS(this).clientdata.drawonlytoclient = this;
 163         CS(this).clientdata.owner = this;
 164 }
 165
 166 void ClientData_Detach(entity this)
 167 {
 168         delete(CS(this).clientdata);
 169         CS(this).clientdata = NULL;
 170 }
 171
 172 void ClientData_Touch(entity e)
 173 {
 174         entity cd = CS(e).clientdata;
 175         if (cd) { cd.SendFlags = 1; }
 176
 177         // make it spectatable
 178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 179         {
 180                 entity cd = CS(it).clientdata;
 181                 if (cd) { cd.SendFlags = 1; }
 182         });
 183 }
 184
 185
 186 /*
 187 =============
 188 CheckPlayerModel
 189
 190 Checks if the argument string can be a valid playermodel.
 191 Returns a valid one in doubt.
 192 =============
 193 */
 194 string FallbackPlayerModel;
 195 string CheckPlayerModel(string plyermodel) {
 196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 197         {
 198                 // note: we cannot summon Don Strunzone here, some player may
 199                 // still have the model string set. In case anyone manages how
 200                 // to change a cvar default, we'll have a small leak here.
 201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 202         }
 203         // only in right path
 204         if(substring(plyermodel, 0, 14) != "models/player/")
 205                 return FallbackPlayerModel;
 206         // only good file extensions
 207         if(substring(plyermodel, -4, 4) != ".iqm"
 208                 && substring(plyermodel, -4, 4) != ".zym"
 209                 && substring(plyermodel, -4, 4) != ".dpm"
 210                 && substring(plyermodel, -4, 4) != ".md3"
 211                 && substring(plyermodel, -4, 4) != ".psk")
 212         {
 213                 return FallbackPlayerModel;
 214         }
 215         // forbid the LOD models
 216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 217                 return FallbackPlayerModel;
 218         if(plyermodel != strtolower(plyermodel))
 219                 return FallbackPlayerModel;
 220         // also, restrict to server models
 221         if(autocvar_sv_servermodelsonly)
 222         {
 223                 if(!fexists(plyermodel))
 224                         return FallbackPlayerModel;
 225         }
 226         return plyermodel;
 227 }
 228
 229 void setplayermodel(entity e, string modelname)
 230 {
 231         precache_model(modelname);
 232         _setmodel(e, modelname);
 233         player_setupanimsformodel(e);
 234         if(!autocvar_g_debug_globalsounds)
 235                 UpdatePlayerSounds(e);
 236 }
 237
 238 /** putting a client as observer in the server */
 239 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 240 {
 241         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 242         bool recount_ready = false;
 243         PlayerState_detach(this);
 244
 245         if (IS_PLAYER(this))
 246         {
 247                 if(GetResource(this, RES_HEALTH) >= 1)
 248                 {
 249                         // despawn effect
 250                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 251                 }
 252
 253                 // was a player, recount votes and ready status
 254                 if(IS_REAL_CLIENT(this))
 255                 {
 256                         if (vote_called) { VoteCount(false); }
 257                         this.ready = false;
 258                         recount_ready = true;
 259                 }
 260                 entcs_update_players(this);
 261         }
 262
 263         if (use_spawnpoint)
 264         {
 265                 entity spot = SelectSpawnPoint(this, true);
 266                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 267                 this.angles = vec2(spot.angles);
 268                 // offset it so that the spectator spawns higher off the ground, looks better this way
 269                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 270         }
 271         else // change origin to restore previous view origin
 272                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 273         this.fixangle = true;
 274
 275         if (IS_REAL_CLIENT(this))
 276         {
 277                 msg_entity = this;
 278                 WriteByte(MSG_ONE, SVC_SETVIEW);
 279                 WriteEntity(MSG_ONE, this);
 280         }
 281         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 282         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 283         if(!autocvar_g_debug_globalsounds)
 284         {
 285                 // needed for player sounds
 286                 this.model = "";
 287                 FixPlayermodel(this);
 288         }
 289         setmodel(this, MDL_Null);
 290         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 291         this.view_ofs = '0 0 0';
 292
 293         RemoveGrapplingHooks(this);
 294         Portal_ClearAll(this);
 295         Unfreeze(this, false);
 296         SetSpectatee(this, NULL);
 297
 298         if (this.alivetime)
 299         {
 300                 if (!warmup_stage)
 301                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 302                 this.alivetime = 0;
 303         }
 304
 305         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 306
 307         TRANSMUTE(Observer, this);
 308
 309         if(recount_ready) ReadyCount();
 310
 311         WaypointSprite_PlayerDead(this);
 312         accuracy_resend(this);
 313
 314         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 315                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 316
 317         CS(this).spectatortime = time;
 318         if(this.bot_attack)
 319                 IL_REMOVE(g_bot_targets, this);
 320         this.bot_attack = false;
 321         if(this.monster_attack)
 322                 IL_REMOVE(g_monster_targets, this);
 323         this.monster_attack = false;
 324         STAT(HUD, this) = HUD_NORMAL;
 325         this.iscreature = false;
 326         this.teleportable = TELEPORT_SIMPLE;
 327         if(this.damagedbycontents)
 328                 IL_REMOVE(g_damagedbycontents, this);
 329         this.damagedbycontents = false;
 330         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 331         SetSpectatee_status(this, etof(this));
 332         this.takedamage = DAMAGE_NO;
 333         this.solid = SOLID_NOT;
 334         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 335         this.flags = FL_CLIENT | FL_NOTARGET;
 336         this.effects = 0;
 337         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 338         this.pauserotarmor_finished = 0;
 339         this.pauserothealth_finished = 0;
 340         this.pauseregen_finished = 0;
 341         this.damageforcescale = 0;
 342         this.death_time = 0;
 343         this.respawn_flags = 0;
 344         this.respawn_time = 0;
 345         STAT(RESPAWN_TIME, this) = 0;
 346         this.alpha = 0;
 347         this.scale = 0;
 348         this.fade_time = 0;
 349         this.pain_finished = 0;
 350         STAT(AIR_FINISHED, this) = 0;
 351         //this.dphitcontentsmask = 0;
 352         this.dphitcontentsmask = DPCONTENTS_SOLID;
 353         if (autocvar_g_playerclip_collisions)
 354                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 355         this.pushltime = 0;
 356         this.istypefrag = 0;
 357         setthink(this, func_null);
 358         this.nextthink = 0;
 359         this.deadflag = DEAD_NO;
 360         UNSET_DUCKED(this);
 361         STAT(REVIVE_PROGRESS, this) = 0;
 362         this.revival_time = 0;
 363         this.draggable = drag_undraggable;
 364
 365         player_powerups_remove_all(this);
 366         this.items = 0;
 367         STAT(WEAPONS, this) = '0 0 0';
 368         this.drawonlytoclient = this;
 369
 370         this.viewloc = NULL;
 371
 372         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 373
 374         this.weaponmodel = "";
 375         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 376         {
 377                 this.weaponentities[slot] = NULL;
 378         }
 379         this.exteriorweaponentity = NULL;
 380         CS(this).killcount = FRAGS_SPECTATOR;
 381         this.velocity = '0 0 0';
 382         this.avelocity = '0 0 0';
 383         this.punchangle = '0 0 0';
 384         this.punchvector = '0 0 0';
 385         this.oldvelocity = this.velocity;
 386         this.event_damage = func_null;
 387         this.event_heal = func_null;
 388
 389         for(int slot = 0; slot < MAX_AXH; ++slot)
 390         {
 391                 entity axh = this.(AuxiliaryXhair[slot]);
 392                 this.(AuxiliaryXhair[slot]) = NULL;
 393
 394                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 395                         delete(axh);
 396         }
 397
 398         if (mutator_returnvalue)
 399         {
 400                 // mutator prevents resetting teams+score
 401         }
 402         else
 403         {
 404                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 405                 this.frags = FRAGS_SPECTATOR;
 406         }
 407
 408         bot_relinkplayerlist();
 409
 410         if (CS(this).just_joined)
 411                 CS(this).just_joined = false;
 412 }
 413
 414 int player_getspecies(entity this)
 415 {
 416         get_model_parameters(this.model, this.skin);
 417         int s = get_model_parameters_species;
 418         get_model_parameters(string_null, 0);
 419         if (s < 0) return SPECIES_HUMAN;
 420         return s;
 421 }
 422
 423 .float model_randomizer;
 424 void FixPlayermodel(entity player)
 425 {
 426         string defaultmodel = "";
 427         int defaultskin = 0;
 428         if(autocvar_sv_defaultcharacter)
 429         {
 430                 if(teamplay)
 431                 {
 432                         switch(player.team)
 433                         {
 434                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 435                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 436                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 437                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 438                         }
 439                 }
 440
 441                 if(defaultmodel == "")
 442                 {
 443                         defaultmodel = autocvar_sv_defaultplayermodel;
 444                         defaultskin = autocvar_sv_defaultplayerskin;
 445                 }
 446
 447                 int n = tokenize_console(defaultmodel);
 448                 if(n > 0)
 449                 {
 450                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 451                         // However, do NOT randomize if the player-selected model is in the list.
 452                         for (int i = 0; i < n; ++i)
 453                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 454                                         defaultmodel = argv(i);
 455                 }
 456
 457                 int i = strstrofs(defaultmodel, ":", 0);
 458                 if(i >= 0)
 459                 {
 460                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 461                         defaultmodel = substring(defaultmodel, 0, i);
 462                 }
 463         }
 464         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 465         {
 466                 if(teamplay)
 467                 {
 468                         switch(player.team)
 469                         {
 470                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 471                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 472                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 473                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 474                         }
 475                 }
 476
 477                 if(!defaultskin)
 478                         defaultskin = autocvar_sv_defaultplayerskin;
 479         }
 480
 481         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 482         defaultmodel = M_ARGV(0, string);
 483         defaultskin = M_ARGV(1, int);
 484
 485         bool chmdl = false;
 486         int oldskin;
 487         if(defaultmodel != "")
 488         {
 489                 if (defaultmodel != player.model)
 490                 {
 491                         vector m1 = player.mins;
 492                         vector m2 = player.maxs;
 493                         setplayermodel (player, defaultmodel);
 494                         setsize (player, m1, m2);
 495                         chmdl = true;
 496                 }
 497
 498                 oldskin = player.skin;
 499                 player.skin = defaultskin;
 500         } else {
 501                 if (player.playermodel != player.model || player.playermodel == "")
 502                 {
 503                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 504                         vector m1 = player.mins;
 505                         vector m2 = player.maxs;
 506                         setplayermodel (player, player.playermodel);
 507                         setsize (player, m1, m2);
 508                         chmdl = true;
 509                 }
 510
 511                 if(!autocvar_sv_defaultcharacterskin)
 512                 {
 513                         oldskin = player.skin;
 514                         player.skin = stof(player.playerskin);
 515                 }
 516                 else
 517                 {
 518                         oldskin = player.skin;
 519                         player.skin = defaultskin;
 520                 }
 521         }
 522
 523         if(chmdl || oldskin != player.skin) // model or skin has changed
 524         {
 525                 player.species = player_getspecies(player); // update species
 526                 if(!autocvar_g_debug_globalsounds)
 527                         UpdatePlayerSounds(player); // update skin sounds
 528         }
 529
 530         if(!teamplay)
 531                 if(strlen(autocvar_sv_defaultplayercolors))
 532                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 533                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 534 }
 535
 536 void PutPlayerInServer(entity this)
 537 {
 538         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 539
 540         PlayerState_attach(this);
 541         accuracy_resend(this);
 542
 543         if (IS_BOT_CLIENT(this))
 544         {
 545                 if (teamplay && Team_IsValidIndex(this.bot_forced_team))
 546                         SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 547                 else
 548                         this.bot_forced_team = 0;
 549         }
 550
 551         if (this.team < 0)
 552                 TeamBalance_JoinBestTeam(this);
 553
 554         entity spot = SelectSpawnPoint(this, false);
 555         if (!spot) {
 556                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 557                 return; // spawn failed
 558         }
 559
 560         TRANSMUTE(Player, this);
 561
 562         CS(this).wasplayer = true;
 563         this.iscreature = true;
 564         this.teleportable = TELEPORT_NORMAL;
 565         if(!this.damagedbycontents)
 566                 IL_PUSH(g_damagedbycontents, this);
 567         this.damagedbycontents = true;
 568         set_movetype(this, MOVETYPE_WALK);
 569         this.solid = SOLID_SLIDEBOX;
 570         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 571         if (autocvar_g_playerclip_collisions)
 572                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 573         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 574                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 575         this.frags = FRAGS_PLAYER;
 576         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 577         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 578         if (autocvar__notarget)
 579                 this.flags |= FL_NOTARGET;
 580         this.takedamage = DAMAGE_AIM;
 581         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 582
 583         if (warmup_stage) {
 584                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 585                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 586                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 587                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 588                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 589                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 590                 SetResource(this, RES_HEALTH, warmup_start_health);
 591                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 592                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 593         } else {
 594                 SetResource(this, RES_SHELLS, start_ammo_shells);
 595                 SetResource(this, RES_BULLETS, start_ammo_nails);
 596                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 597                 SetResource(this, RES_CELLS, start_ammo_cells);
 598                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 599                 SetResource(this, RES_FUEL, start_ammo_fuel);
 600                 SetResource(this, RES_HEALTH, start_health);
 601                 SetResource(this, RES_ARMOR, start_armorvalue);
 602                 STAT(WEAPONS, this) = start_weapons;
 603                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 604                 {
 605                         GiveRandomWeapons(this, random_start_weapons_count,
 606                                 autocvar_g_random_start_weapons, random_start_ammo);
 607                 }
 608         }
 609         SetSpectatee_status(this, 0);
 610
 611         PS(this).dual_weapons = '0 0 0';
 612
 613         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 614                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 615
 616         this.items = start_items;
 617
 618         float shieldtime = time + autocvar_g_spawnshieldtime;
 619
 620         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 621         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 622         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 623         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 624         if (!sv_ready_restart_after_countdown && time < game_starttime)
 625         {
 626                 float f = game_starttime - time;
 627                 shieldtime += f;
 628                 this.pauserotarmor_finished += f;
 629                 this.pauserothealth_finished += f;
 630                 this.pauseregen_finished += f;
 631         }
 632
 633         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 634
 635         this.damageforcescale = autocvar_g_player_damageforcescale;
 636         this.death_time = 0;
 637         this.respawn_flags = 0;
 638         this.respawn_time = 0;
 639         STAT(RESPAWN_TIME, this) = 0;
 640         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 641         this.fade_time = 0;
 642         this.pain_finished = 0;
 643         this.pushltime = 0;
 644         setthink(this, func_null); // players have no think function
 645         this.nextthink = 0;
 646         this.dmg_team = 0;
 647         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 648
 649         this.deadflag = DEAD_NO;
 650
 651         this.angles = spot.angles;
 652         this.angles_z = 0; // never spawn tilted even if the spot says to
 653         if (IS_BOT_CLIENT(this))
 654         {
 655                 this.v_angle = this.angles;
 656                 bot_aim_reset(this);
 657         }
 658         this.fixangle = true; // turn this way immediately
 659         this.oldvelocity = this.velocity = '0 0 0';
 660         this.avelocity = '0 0 0';
 661         this.punchangle = '0 0 0';
 662         this.punchvector = '0 0 0';
 663
 664         STAT(REVIVE_PROGRESS, this) = 0;
 665         this.revival_time = 0;
 666
 667         STAT(AIR_FINISHED, this) = 0;
 668         this.waterlevel = WATERLEVEL_NONE;
 669         this.watertype = CONTENT_EMPTY;
 670
 671         entity spawnevent = new_pure(spawnevent);
 672         spawnevent.owner = this;
 673         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 674
 675         // Cut off any still running player sounds.
 676         stopsound(this, CH_PLAYER_SINGLE);
 677
 678         this.model = "";
 679         FixPlayermodel(this);
 680         this.drawonlytoclient = NULL;
 681
 682         this.viewloc = NULL;
 683
 684         for(int slot = 0; slot < MAX_AXH; ++slot)
 685         {
 686                 entity axh = this.(AuxiliaryXhair[slot]);
 687                 this.(AuxiliaryXhair[slot]) = NULL;
 688
 689                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 690                         delete(axh);
 691         }
 692
 693         this.spawnpoint_targ = NULL;
 694
 695         UNSET_DUCKED(this);
 696         this.view_ofs = STAT(PL_VIEW_OFS, this);
 697         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 698         this.spawnorigin = spot.origin;
 699         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 700         // don't reset back to last position, even if new position is stuck in solid
 701         this.oldorigin = this.origin;
 702         if(this.conveyor)
 703                 IL_REMOVE(g_conveyed, this);
 704         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 705         if(this.swampslug)
 706                 IL_REMOVE(g_swamped, this);
 707         this.swampslug = NULL;
 708         this.swamp_interval = 0;
 709         if(this.ladder_entity)
 710                 IL_REMOVE(g_ladderents, this);
 711         this.ladder_entity = NULL;
 712         IL_EACH(g_counters, it.realowner == this,
 713         {
 714                 delete(it);
 715         });
 716         STAT(HUD, this) = HUD_NORMAL;
 717
 718         this.event_damage = PlayerDamage;
 719         this.event_heal = PlayerHeal;
 720
 721         this.draggable = func_null;
 722
 723         if(!this.bot_attack)
 724                 IL_PUSH(g_bot_targets, this);
 725         this.bot_attack = true;
 726         if(!this.monster_attack)
 727                 IL_PUSH(g_monster_targets, this);
 728         this.monster_attack = true;
 729         navigation_dynamicgoal_init(this, false);
 730
 731         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 732
 733         // player was spectator
 734         if (CS(this).killcount == FRAGS_SPECTATOR) {
 735                 PlayerScore_Clear(this);
 736                 CS(this).killcount = 0;
 737                 CS(this).startplaytime = time;
 738         }
 739
 740         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 741         {
 742                 .entity weaponentity = weaponentities[slot];
 743                 CL_SpawnWeaponentity(this, weaponentity);
 744         }
 745         this.alpha = default_player_alpha;
 746         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 747         this.exteriorweaponentity.alpha = default_weapon_alpha;
 748
 749         this.speedrunning = false;
 750
 751         this.counter_cnt = 0;
 752         this.fragsfilter_cnt = 0;
 753
 754         target_voicescript_clear(this);
 755
 756         // reset fields the weapons may use
 757         FOREACH(Weapons, true, {
 758                 it.wr_resetplayer(it, this);
 759                         // reload all reloadable weapons
 760                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 761                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 762                         {
 763                                 .entity weaponentity = weaponentities[slot];
 764                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 765                         }
 766                 }
 767         });
 768
 769         Unfreeze(this, false);
 770
 771         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 772         {
 773                 string s = spot.target;
 774                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 775                         spot.target = string_null;
 776                 SUB_UseTargets(spot, this, NULL);
 777                 if(g_assault || g_race)
 778                         spot.target = s;
 779         }
 780
 781         if (autocvar_spawn_debug)
 782         {
 783                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 784                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 785         }
 786
 787         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 788         {
 789                 .entity weaponentity = weaponentities[slot];
 790                 entity w_ent = this.(weaponentity);
 791                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 792                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 793                 else
 794                         w_ent.m_switchweapon = WEP_Null;
 795                 w_ent.m_weapon = WEP_Null;
 796                 w_ent.weaponname = "";
 797                 w_ent.m_switchingweapon = WEP_Null;
 798                 w_ent.cnt = -1;
 799         }
 800
 801         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 802
 803         if (CS(this).impulse) ImpulseCommands(this);
 804
 805         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 806         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 807         {
 808                 .entity weaponentity = weaponentities[slot];
 809                 W_WeaponFrame(this, weaponentity);
 810         }
 811
 812         if (!warmup_stage && !this.alivetime)
 813                 this.alivetime = time;
 814
 815         antilag_clear(this, CS(this));
 816 }
 817
 818 /** Called when a client spawns in the server */
 819 void PutClientInServer(entity this)
 820 {
 821         if (IS_REAL_CLIENT(this)) {
 822                 msg_entity = this;
 823                 WriteByte(MSG_ONE, SVC_SETVIEW);
 824                 WriteEntity(MSG_ONE, this);
 825         }
 826         if (game_stopped)
 827                 TRANSMUTE(Observer, this);
 828
 829         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 830         SetSpectatee(this, NULL);
 831
 832         // reset player keys
 833         if(PS(this))
 834                 PS(this).itemkeys = 0;
 835
 836         MUTATOR_CALLHOOK(PutClientInServer, this);
 837
 838         if (IS_OBSERVER(this)) {
 839                 PutObserverInServer(this, false, use_spawnpoint);
 840         } else if (IS_PLAYER(this)) {
 841                 PutPlayerInServer(this);
 842         }
 843
 844         bot_relinkplayerlist();
 845 }
 846
 847 // TODO do we need all these fields, or should we stop autodetecting runtime
 848 // changes and just have a console command to update this?
 849 bool ClientInit_SendEntity(entity this, entity to, int sf)
 850 {
 851         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 852         return = true;
 853         msg_entity = to;
 854         // MSG_INIT replacement
 855         // TODO: make easier to use
 856         Registry_send_all();
 857         W_PROP_reload(MSG_ONE, to);
 858         ClientInit_misc(this);
 859         MUTATOR_CALLHOOK(Ent_Init);
 860 }
 861 void ClientInit_misc(entity this)
 862 {
 863         int channel = MSG_ONE;
 864         WriteHeader(channel, ENT_CLIENT_INIT);
 865         WriteByte(channel, g_nexball_meter_period * 32);
 866         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 867         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 868         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 869         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 870         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 871         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 872         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 873         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 874
 875         if(autocvar_sv_foginterval && world.fog != "")
 876                 WriteString(channel, world.fog);
 877         else
 878                 WriteString(channel, "");
 879         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 880         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 881         WriteByte(channel, serverflags);
 882         WriteCoord(channel, autocvar_g_trueaim_minrange);
 883 }
 884
 885 void ClientInit_CheckUpdate(entity this)
 886 {
 887         this.nextthink = time;
 888         if(this.count != autocvar_g_balance_armor_blockpercent)
 889         {
 890                 this.count = autocvar_g_balance_armor_blockpercent;
 891                 this.SendFlags |= 1;
 892         }
 893         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 894         {
 895                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 896                 this.SendFlags |= 1;
 897         }
 898 }
 899
 900 void ClientInit_Spawn()
 901 {
 902         entity e = new_pure(clientinit);
 903         setthink(e, ClientInit_CheckUpdate);
 904         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 905
 906         ClientInit_CheckUpdate(e);
 907 }
 908
 909 /*
 910 =============
 911 SetNewParms
 912 =============
 913 */
 914 void SetNewParms ()
 915 {
 916         // initialize parms for a new player
 917         parm1 = -(86400 * 366);
 918
 919         MUTATOR_CALLHOOK(SetNewParms);
 920 }
 921
 922 /*
 923 =============
 924 SetChangeParms
 925 =============
 926 */
 927 void SetChangeParms (entity this)
 928 {
 929         // save parms for level change
 930         parm1 = CS(this).parm_idlesince - time;
 931
 932         MUTATOR_CALLHOOK(SetChangeParms);
 933 }
 934
 935 /*
 936 =============
 937 DecodeLevelParms
 938 =============
 939 */
 940 void DecodeLevelParms(entity this)
 941 {
 942         // load parms
 943         CS(this).parm_idlesince = parm1;
 944         if (CS(this).parm_idlesince == -(86400 * 366))
 945                 CS(this).parm_idlesince = time;
 946
 947         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 948         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 949
 950         MUTATOR_CALLHOOK(DecodeLevelParms);
 951 }
 952
 953 void FixClientCvars(entity e)
 954 {
 955         // send prediction settings to the client
 956         if(autocvar_g_antilag == 3) // client side hitscan
 957                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 958         if(autocvar_sv_gentle)
 959                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 960
 961         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 962         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 963
 964         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 965
 966         MUTATOR_CALLHOOK(FixClientCvars, e);
 967 }
 968
 969 bool findinlist_abbrev(string tofind, string list)
 970 {
 971         if(list == "" || tofind == "")
 972                 return false; // empty list or search, just return
 973
 974         // this function allows abbreviated strings!
 975         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 976         {
 977                 return true;
 978         });
 979
 980         return false;
 981 }
 982
 983 bool PlayerInIPList(entity p, string iplist)
 984 {
 985         // some safety checks (never allow local?)
 986         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 987                 return false;
 988
 989         return findinlist_abbrev(p.netaddress, iplist);
 990 }
 991
 992 bool PlayerInIDList(entity p, string idlist)
 993 {
 994         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 995         if(!p.crypto_idfp)
 996                 return false;
 997
 998         return findinlist_abbrev(p.crypto_idfp, idlist);
 999 }
1000
1001 bool PlayerInList(entity player, string list)
1002 {
1003         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1004 }
1005
1006 #ifdef DP_EXT_PRECONNECT
1007 /*
1008 =============
1009 ClientPreConnect
1010
1011 Called once (not at each match start) when a client begins a connection to the server
1012 =============
1013 */
1014 void ClientPreConnect(entity this)
1015 {
1016         if(autocvar_sv_eventlog)
1017         {
1018                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1019                         this.playerid,
1020                         etof(this),
1021                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1022                 ));
1023         }
1024 }
1025 #endif
1026
1027 void SendWelcomemessage(entity this, bool force_centerprint)
1028 {
1029         msg_entity = this;
1030         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1031         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1032 }
1033
1034 // NOTE csqc uses the active mutators list sent by this function
1035 // to understand which mutators are enabled
1036 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1037 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1038 {
1039         WriteByte(msg_type, boolean(autocvar_g_campaign));
1040         if (boolean(autocvar_g_campaign))
1041         {
1042                 WriteString(msg_type, Campaign_GetTitle());
1043                 WriteByte(msg_type, Campaign_GetLevelNum());
1044                 WriteString(msg_type, Campaign_GetMessage());
1045                 return;
1046         }
1047         WriteByte(msg_type, force_centerprint);
1048         WriteString(msg_type, autocvar_hostname);
1049         WriteString(msg_type, autocvar_g_xonoticversion);
1050         WriteByte(msg_type, CS(this).version_mismatch);
1051         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1052
1053         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1054         string modifications = M_ARGV(0, string);
1055
1056         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1057                 modifications = strcat(modifications, ", No start weapons");
1058         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1059                 modifications = strcat(modifications, ", Low gravity");
1060         if(g_weapon_stay && !g_cts)
1061                 modifications = strcat(modifications, ", Weapons stay");
1062         if(autocvar_g_jetpack)
1063                 modifications = strcat(modifications, ", Jetpack");
1064         modifications = substring(modifications, 2, strlen(modifications) - 2);
1065
1066         WriteString(msg_type, modifications);
1067
1068         WriteString(msg_type, g_weaponarena_list);
1069
1070         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1071         {
1072                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1073                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1074         }
1075
1076         WriteString(msg_type, cache_mutatormsg);
1077
1078         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1079 }
1080
1081 /**
1082 =============
1083 ClientConnect
1084
1085 Called when a client connects to the server
1086 =============
1087 */
1088 void ClientConnect(entity this)
1089 {
1090         if (Ban_MaybeEnforceBanOnce(this)) return;
1091         assert(!IS_CLIENT(this), return);
1092         this.flags |= FL_CLIENT;
1093         assert(player_count >= 0, player_count = 0);
1094
1095         TRANSMUTE(Client, this);
1096         CS(this).version_nagtime = time + 10 + random() * 10;
1097
1098         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1099
1100         bot_clientconnect(this);
1101
1102         Player_DetermineForcedTeam(this);
1103
1104         TRANSMUTE(Observer, this);
1105
1106         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1107
1108         // always track bots, don't ask for cl_allow_uidtracking
1109         if (IS_BOT_CLIENT(this))
1110                 PlayerStats_GameReport_AddPlayer(this);
1111         else
1112                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1113
1114         if (autocvar_sv_eventlog)
1115                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1116
1117         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1118
1119         stuffcmd(this, clientstuff, "\n");
1120         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1121
1122         FixClientCvars(this);
1123
1124         // get version info from player
1125         stuffcmd(this, "cmd clientversion $gameversion\n");
1126
1127         // notify about available teams
1128         if (teamplay)
1129         {
1130                 entity balance = TeamBalance_CheckAllowedTeams(this);
1131                 int t = TeamBalance_GetAllowedTeams(balance);
1132                 TeamBalance_Destroy(balance);
1133                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1134         }
1135         else
1136         {
1137                 stuffcmd(this, "set _teams_available 0\n");
1138         }
1139
1140         bot_relinkplayerlist();
1141
1142         CS(this).spectatortime = time;
1143         if (blockSpectators)
1144         {
1145                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1146         }
1147
1148         CS(this).jointime = time;
1149
1150         if (IS_REAL_CLIENT(this))
1151         {
1152                 if (g_weaponarena_weapons == WEPSET(TUBA))
1153                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1154         }
1155
1156         if (!autocvar_sv_foginterval && world.fog != "")
1157                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1158
1159         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1160                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1161                         send_CSQC_teamnagger();
1162
1163         CSQCMODEL_AUTOINIT(this);
1164
1165         CS(this).model_randomizer = random();
1166
1167         if (IS_REAL_CLIENT(this))
1168                 sv_notice_join(this);
1169
1170         this.move_qcphysics = autocvar_sv_qcphysics;
1171
1172         // update physics stats (players can spawn before physics runs)
1173         Physics_UpdateStats(this);
1174
1175         IL_EACH(g_initforplayer, it.init_for_player, {
1176                 it.init_for_player(it, this);
1177         });
1178
1179         Handicap_Initialize(this);
1180
1181         MUTATOR_CALLHOOK(ClientConnect, this);
1182
1183         if (player_count == 1)
1184                 localcmd("\nsv_hook_firstjoin\n");
1185
1186         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1187                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1188 }
1189 /*
1190 =============
1191 ClientDisconnect
1192
1193 Called when a client disconnects from the server
1194 =============
1195 */
1196 .entity chatbubbleentity;
1197 void player_powerups_remove_all(entity this);
1198
1199 void ClientDisconnect(entity this)
1200 {
1201         assert(IS_CLIENT(this), return);
1202
1203         PlayerStats_GameReport_FinalizePlayer(this);
1204         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1205         if (CS(this).active_minigame) part_minigame(this);
1206         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1207
1208         if (autocvar_sv_eventlog)
1209                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1210
1211         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1212
1213         if(IS_SPEC(this))
1214                 SetSpectatee(this, NULL);
1215
1216         MUTATOR_CALLHOOK(ClientDisconnect, this);
1217
1218         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1219         strfree(CS_CVAR(this).weaponorder_byimpulse);
1220         ClientState_detach(this);
1221
1222         Portal_ClearAll(this);
1223
1224         Unfreeze(this, false);
1225
1226         RemoveGrapplingHooks(this);
1227
1228         // Here, everything has been done that requires this player to be a client.
1229
1230         this.flags &= ~FL_CLIENT;
1231
1232         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1233         if (this.killindicator) delete(this.killindicator);
1234
1235         IL_EACH(g_counters, it.realowner == this,
1236         {
1237                 delete(it);
1238         });
1239
1240         WaypointSprite_PlayerGone(this);
1241
1242         bot_relinkplayerlist();
1243
1244         strfree(this.clientstatus);
1245         if (this.personal) delete(this.personal);
1246
1247         this.playerid = 0;
1248         ReadyCount();
1249         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1250
1251         player_powerups_remove_all(this); // stop powerup sound
1252
1253         ONREMOVE(this);
1254
1255         if (player_count == 0)
1256                 localcmd("\nsv_hook_lastleave\n");
1257 }
1258
1259 void ChatBubbleThink(entity this)
1260 {
1261         this.nextthink = time;
1262         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1263         {
1264                 if(this.owner) // but why can that ever be NULL?
1265                         this.owner.chatbubbleentity = NULL;
1266                 delete(this);
1267                 return;
1268         }
1269
1270         this.mdl = "";
1271
1272         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1273         {
1274                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1275                         this.mdl = "models/sprites/minigame_busy.iqm";
1276                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1277                         this.mdl = "models/misc/chatbubble.spr";
1278         }
1279
1280         if ( this.model != this.mdl )
1281                 _setmodel(this, this.mdl);
1282
1283 }
1284
1285 void UpdateChatBubble(entity this)
1286 {
1287         if (this.alpha < 0)
1288                 return;
1289         // spawn a chatbubble entity if needed
1290         if (!this.chatbubbleentity)
1291         {
1292                 this.chatbubbleentity = new(chatbubbleentity);
1293                 this.chatbubbleentity.owner = this;
1294                 this.chatbubbleentity.exteriormodeltoclient = this;
1295                 setthink(this.chatbubbleentity, ChatBubbleThink);
1296                 this.chatbubbleentity.nextthink = time;
1297                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1298                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1299                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1300                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1301                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1302                 //this.chatbubbleentity.model = "";
1303                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1304         }
1305 }
1306
1307 void calculate_player_respawn_time(entity this)
1308 {
1309         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1310                 return;
1311
1312         float gametype_setting_tmp;
1313         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1314         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1315         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1316         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1317         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1318         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1319
1320         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1321         if (teamplay)
1322         {
1323                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1324                         if(it.team == this.team)
1325                                 ++pcount;
1326                 });
1327                 if (sdelay_small_count == 0)
1328                         sdelay_small_count = 1;
1329                 if (sdelay_large_count == 0)
1330                         sdelay_large_count = 1;
1331         }
1332         else
1333         {
1334                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1335                         ++pcount;
1336                 });
1337                 if (sdelay_small_count == 0)
1338                 {
1339                         if (IS_INDEPENDENT_PLAYER(this))
1340                         {
1341                                 // Players play independently. No point in requiring enemies.
1342                                 sdelay_small_count = 1;
1343                         }
1344                         else
1345                         {
1346                                 // Players play AGAINST each other. Enemies required.
1347                                 sdelay_small_count = 2;
1348                         }
1349                 }
1350                 if (sdelay_large_count == 0)
1351                 {
1352                         if (IS_INDEPENDENT_PLAYER(this))
1353                         {
1354                                 // Players play independently. No point in requiring enemies.
1355                                 sdelay_large_count = 1;
1356                         }
1357                         else
1358                         {
1359                                 // Players play AGAINST each other. Enemies required.
1360                                 sdelay_large_count = 2;
1361                         }
1362                 }
1363         }
1364
1365         float sdelay;
1366
1367         if (pcount <= sdelay_small_count)
1368                 sdelay = sdelay_small;
1369         else if (pcount >= sdelay_large_count)
1370                 sdelay = sdelay_large;
1371         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1372                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1373
1374         if(waves)
1375                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1376         else
1377                 this.respawn_time = time + sdelay;
1378
1379         if(sdelay < sdelay_max)
1380                 this.respawn_time_max = time + sdelay_max;
1381         else
1382                 this.respawn_time_max = this.respawn_time;
1383
1384         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1385                 this.respawn_countdown = 10; // first number to count down from is 10
1386         else
1387                 this.respawn_countdown = -1; // do not count down
1388
1389         if(autocvar_g_forced_respawn)
1390                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1391 }
1392
1393 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1394 // added to the model skins
1395 /*void UpdateColorModHack()
1396 {
1397         float c;
1398         c = this.clientcolors & 15;
1399         // LordHavoc: only bothering to support white, green, red, yellow, blue
1400              if (!teamplay) this.colormod = '0 0 0';
1401         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1402         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1403         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1404         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1405         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1406         else this.colormod = '1 1 1';
1407 }*/
1408
1409 void respawn(entity this)
1410 {
1411         bool damagedbycontents_prev = this.damagedbycontents;
1412         if(this.alpha >= 0)
1413         {
1414                 if(autocvar_g_respawn_ghosts)
1415                 {
1416                         this.solid = SOLID_NOT;
1417                         this.takedamage = DAMAGE_NO;
1418                         this.damagedbycontents = false;
1419                         set_movetype(this, MOVETYPE_FLY);
1420                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1421                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1422                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1423                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1424                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1425                         if(autocvar_g_respawn_ghosts_time > 0)
1426                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1427                 }
1428                 else
1429                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1430         }
1431
1432         CopyBody(this, 1);
1433         this.damagedbycontents = damagedbycontents_prev;
1434
1435         this.effects |= EF_NODRAW; // prevent another CopyBody
1436         PutClientInServer(this);
1437 }
1438
1439 void play_countdown(entity this, float finished, Sound samp)
1440 {
1441         TC(Sound, samp);
1442         float time_left = finished - time;
1443         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1444                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1445 }
1446
1447 // it removes special powerups not handled by StatusEffects
1448 void player_powerups_remove_all(entity this)
1449 {
1450         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1451         {
1452                 // don't play the poweroff sound when the game restarts or the player disconnects
1453                 if (time > game_starttime + 1 && IS_CLIENT(this)
1454                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1455                 {
1456                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1457                 }
1458                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1459                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1460                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1461         }
1462 }
1463
1464 void player_powerups(entity this)
1465 {
1466         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1467                 this.modelflags |= MF_ROCKET;
1468         else
1469                 this.modelflags &= ~MF_ROCKET;
1470
1471         this.effects &= ~EF_NODEPTHTEST;
1472
1473         if (IS_DEAD(this))
1474                 player_powerups_remove_all(this);
1475
1476         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1477                 return;
1478
1479         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1480         int items_prev = this.items;
1481
1482         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1483         {
1484                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1485                 if (this.items & IT_SUPERWEAPON)
1486                 {
1487                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1488                         {
1489                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1490                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1491                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1492                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1493                         }
1494                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1495                         {
1496                                 // don't let them run out
1497                         }
1498                         else
1499                         {
1500                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1501                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1502                                 {
1503                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1504                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1505                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1506                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1507                                 }
1508                         }
1509                 }
1510                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1511                 {
1512                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1513                         {
1514                                 this.items = this.items | IT_SUPERWEAPON;
1515                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1516                                 {
1517                                         if(!g_cts)
1518                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1519                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1520                                 }
1521                         }
1522                         else
1523                         {
1524                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1525                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1526                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1527                         }
1528                 }
1529                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1530                 {
1531                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1532                 }
1533         }
1534
1535         if(autocvar_g_nodepthtestplayers)
1536                 this.effects = this.effects | EF_NODEPTHTEST;
1537
1538         if(autocvar_g_fullbrightplayers)
1539                 this.effects = this.effects | EF_FULLBRIGHT;
1540
1541         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1542 }
1543
1544 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1545 {
1546         if(current > stable)
1547                 return current;
1548         else if(current > stable - 0.25) // when close enough, "snap"
1549                 return stable;
1550         else
1551                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1552 }
1553
1554 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1555 {
1556         if(current < stable)
1557                 return current;
1558         else if(current < stable + 0.25) // when close enough, "snap"
1559                 return stable;
1560         else
1561                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1562 }
1563
1564 void RotRegen(entity this, Resource res, float limit_mod,
1565         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1566         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1567 {
1568         float old = GetResource(this, res);
1569         float current = old;
1570         if(current > rotstable)
1571         {
1572                 if(rotframetime > 0)
1573                 {
1574                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1575                         current = max(rotstable, current - rotlinear * rotframetime);
1576                 }
1577         }
1578         else if(current < regenstable)
1579         {
1580                 if(regenframetime > 0)
1581                 {
1582                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1583                         current = min(regenstable, current + regenlinear * regenframetime);
1584                 }
1585         }
1586
1587         float limit = GetResourceLimit(this, res) * limit_mod;
1588         if(current > limit)
1589                 current = limit;
1590
1591         if (current != old)
1592                 SetResource(this, res, current);
1593 }
1594
1595 void player_regen(entity this)
1596 {
1597         float max_mod, regen_mod, rot_mod, limit_mod;
1598         max_mod = regen_mod = rot_mod = limit_mod = 1;
1599
1600         float regen_health = autocvar_g_balance_health_regen;
1601         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1602         float regen_health_rot = autocvar_g_balance_health_rot;
1603         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1604         float regen_health_stable = autocvar_g_balance_health_regenstable;
1605         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1606         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1607                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1608         max_mod = M_ARGV(1, float);
1609         regen_mod = M_ARGV(2, float);
1610         rot_mod = M_ARGV(3, float);
1611         limit_mod = M_ARGV(4, float);
1612         regen_health = M_ARGV(5, float);
1613         regen_health_linear = M_ARGV(6, float);
1614         regen_health_rot = M_ARGV(7, float);
1615         regen_health_rotlinear = M_ARGV(8, float);
1616         regen_health_stable = M_ARGV(9, float);
1617         regen_health_rotstable = M_ARGV(10, float);
1618
1619         float rotstable, regenstable, rotframetime, regenframetime;
1620
1621         if(!mutator_returnvalue)
1622         if(!STAT(FROZEN, this))
1623         {
1624                 regenstable = autocvar_g_balance_armor_regenstable;
1625                 rotstable = autocvar_g_balance_armor_rotstable;
1626                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1627                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1628                 RotRegen(this, RES_ARMOR, limit_mod,
1629                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1630                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1631
1632                 // NOTE: max_mod is only applied to health
1633                 regenstable = regen_health_stable * max_mod;
1634                 rotstable = regen_health_rotstable * max_mod;
1635                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1636                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1637                 RotRegen(this, RES_HEALTH, limit_mod,
1638                         regenstable, regen_health, regen_health_linear, regenframetime,
1639                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1640         }
1641
1642         // if player rotted to death...  die!
1643         // check this outside above checks, as player may still be able to rot to death
1644         if(GetResource(this, RES_HEALTH) < 1)
1645         {
1646                 if(this.vehicle)
1647                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1648                 if(this.event_damage)
1649                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1650         }
1651
1652         if (!(this.items & IT_UNLIMITED_AMMO))
1653         {
1654                 regenstable = autocvar_g_balance_fuel_regenstable;
1655                 rotstable = autocvar_g_balance_fuel_rotstable;
1656                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1657                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1658                 RotRegen(this, RES_FUEL, 1,
1659                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1660                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1661         }
1662 }
1663
1664 bool zoomstate_set;
1665 void SetZoomState(entity this, float newzoom)
1666 {
1667         if(newzoom != CS(this).zoomstate)
1668         {
1669                 CS(this).zoomstate = newzoom;
1670                 ClientData_Touch(this);
1671         }
1672         zoomstate_set = true;
1673 }
1674
1675 void GetPressedKeys(entity this)
1676 {
1677         MUTATOR_CALLHOOK(GetPressedKeys, this);
1678         if (game_stopped)
1679         {
1680                 CS(this).pressedkeys = 0;
1681                 STAT(PRESSED_KEYS, this) = 0;
1682                 return;
1683         }
1684
1685         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1686         int keys = STAT(PRESSED_KEYS, this);
1687         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1688         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1689         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1690         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1691
1692         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1693         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1694         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1695         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1696         CS(this).pressedkeys = keys; // store for other users
1697
1698         STAT(PRESSED_KEYS, this) = keys;
1699 }
1700
1701 /*
1702 ======================
1703 spectate mode routines
1704 ======================
1705 */
1706
1707 void SpectateCopy(entity this, entity spectatee)
1708 {
1709         TC(Client, this); TC(Client, spectatee);
1710
1711         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1712         PS(this) = PS(spectatee);
1713         this.armortype = spectatee.armortype;
1714         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1715         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1716         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1717         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1718         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1719         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1720         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1721         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1722         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1723         CS(this).impulse = 0;
1724         this.disableclientprediction = 1; // no need to run prediction on a spectator
1725         this.items = spectatee.items;
1726         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1727         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1728         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1729         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1730         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1731         this.punchangle = spectatee.punchangle;
1732         this.view_ofs = spectatee.view_ofs;
1733         this.velocity = spectatee.velocity;
1734         this.dmg_take = spectatee.dmg_take;
1735         this.dmg_save = spectatee.dmg_save;
1736         this.dmg_inflictor = spectatee.dmg_inflictor;
1737         this.v_angle = spectatee.v_angle;
1738         this.angles = spectatee.v_angle;
1739         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1740         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1741         this.viewloc = spectatee.viewloc;
1742         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1743                 this.fixangle = true;
1744         setorigin(this, spectatee.origin);
1745         setsize(this, spectatee.mins, spectatee.maxs);
1746         SetZoomState(this, CS(spectatee).zoomstate);
1747
1748     anticheat_spectatecopy(this, spectatee);
1749         STAT(HUD, this) = STAT(HUD, spectatee);
1750         if(spectatee.vehicle)
1751     {
1752         this.angles = spectatee.v_angle;
1753
1754         //this.fixangle = false;
1755         //this.velocity = spectatee.vehicle.velocity;
1756         this.vehicle_health = spectatee.vehicle_health;
1757         this.vehicle_shield = spectatee.vehicle_shield;
1758         this.vehicle_energy = spectatee.vehicle_energy;
1759         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1760         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1761         this.vehicle_reload1 = spectatee.vehicle_reload1;
1762         this.vehicle_reload2 = spectatee.vehicle_reload2;
1763
1764         //msg_entity = this;
1765
1766        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1767             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1768            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1769            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1770
1771         //WriteByte (MSG_ONE, SVC_SETVIEW);
1772         //    WriteEntity(MSG_ONE, this);
1773         //makevectors(spectatee.v_angle);
1774         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1775     }
1776 }
1777
1778 bool SpectateUpdate(entity this)
1779 {
1780         if(!this.enemy)
1781                 return false;
1782
1783         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1784         {
1785                 SetSpectatee(this, NULL);
1786                 return false;
1787         }
1788
1789         SpectateCopy(this, this.enemy);
1790
1791         return true;
1792 }
1793
1794 bool SpectateSet(entity this)
1795 {
1796         if(!IS_PLAYER(this.enemy))
1797                 return false;
1798
1799         ClientData_Touch(this.enemy);
1800
1801         msg_entity = this;
1802         WriteByte(MSG_ONE, SVC_SETVIEW);
1803         WriteEntity(MSG_ONE, this.enemy);
1804         set_movetype(this, MOVETYPE_NONE);
1805         accuracy_resend(this);
1806
1807         if(!SpectateUpdate(this))
1808                 PutObserverInServer(this, false, true);
1809
1810         return true;
1811 }
1812
1813 void SetSpectatee_status(entity this, int spectatee_num)
1814 {
1815         int oldspectatee_status = CS(this).spectatee_status;
1816         CS(this).spectatee_status = spectatee_num;
1817
1818         if (CS(this).spectatee_status != oldspectatee_status)
1819         {
1820                 if (STAT(PRESSED_KEYS, this))
1821                 {
1822                         CS(this).pressedkeys = 0;
1823                         STAT(PRESSED_KEYS, this) = 0;
1824                 }
1825                 ClientData_Touch(this);
1826                 if (g_race || g_cts) race_InitSpectator();
1827         }
1828 }
1829
1830 void SetSpectatee(entity this, entity spectatee)
1831 {
1832         if(IS_BOT_CLIENT(this))
1833                 return; // bots abuse .enemy, this code is useless to them
1834
1835         entity old_spectatee = this.enemy;
1836
1837         this.enemy = spectatee;
1838
1839         // WEAPONTODO
1840         // these are required to fix the spectator bug with arc
1841         if(old_spectatee)
1842         {
1843                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1844                 {
1845                         .entity weaponentity = weaponentities[slot];
1846                         if(old_spectatee.(weaponentity).arc_beam)
1847                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1848                 }
1849         }
1850         if(spectatee)
1851         {
1852                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1853                 {
1854                         .entity weaponentity = weaponentities[slot];
1855                         if(spectatee.(weaponentity).arc_beam)
1856                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1857                 }
1858         }
1859
1860         if (spectatee)
1861                 SetSpectatee_status(this, etof(spectatee));
1862
1863         // needed to update spectator list
1864         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1865 }
1866
1867 bool Spectate(entity this, entity pl)
1868 {
1869         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1870                 return false;
1871         pl = M_ARGV(1, entity);
1872
1873         SetSpectatee(this, pl);
1874         return SpectateSet(this);
1875 }
1876
1877 bool SpectateNext(entity this)
1878 {
1879         entity ent = find(this.enemy, classname, STR_PLAYER);
1880
1881         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1882                 ent = M_ARGV(1, entity);
1883         else if (!ent)
1884                 ent = find(ent, classname, STR_PLAYER);
1885
1886         if(ent) { SetSpectatee(this, ent); }
1887
1888         return SpectateSet(this);
1889 }
1890
1891 bool SpectatePrev(entity this)
1892 {
1893         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1894         entity ent = findchain(classname, STR_PLAYER);
1895         if (!ent) // no player
1896                 return false;
1897
1898         entity first = ent;
1899         // skip players until current spectated player
1900         if(this.enemy)
1901         while(ent && ent != this.enemy)
1902                 ent = ent.chain;
1903
1904         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1905         {
1906                 case MUT_SPECPREV_FOUND:
1907                         ent = M_ARGV(1, entity);
1908                         break;
1909                 case MUT_SPECPREV_RETURN:
1910                         return true;
1911                 case MUT_SPECPREV_CONTINUE:
1912                 default:
1913                 {
1914                         if(ent.chain)
1915                                 ent = ent.chain;
1916                         else
1917                                 ent = first;
1918                         break;
1919                 }
1920         }
1921
1922         SetSpectatee(this, ent);
1923         return SpectateSet(this);
1924 }
1925
1926 /*
1927 =============
1928 ShowRespawnCountdown()
1929
1930 Update a respawn countdown display.
1931 =============
1932 */
1933 void ShowRespawnCountdown(entity this)
1934 {
1935         float number;
1936         if(!IS_DEAD(this)) // just respawned?
1937                 return;
1938         else
1939         {
1940                 number = ceil(this.respawn_time - time);
1941                 if(number <= 0)
1942                         return;
1943                 if(number <= this.respawn_countdown)
1944                 {
1945                         this.respawn_countdown = number - 1;
1946                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1947                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1948                 }
1949         }
1950 }
1951
1952 .bool team_selected;
1953 bool ShowTeamSelection(entity this)
1954 {
1955         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1956                 return false;
1957         stuffcmd(this, "menu_showteamselect\n");
1958         return true;
1959 }
1960 void Join(entity this)
1961 {
1962         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1963                 ReadyRestart(true);
1964
1965         TRANSMUTE(Player, this);
1966
1967         if(!this.team_selected)
1968         if(autocvar_g_campaign || autocvar_g_balance_teams)
1969                 TeamBalance_JoinBestTeam(this);
1970
1971         if(autocvar_g_campaign)
1972                 campaign_bots_may_start = true;
1973
1974         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1975
1976         PutClientInServer(this);
1977
1978         if(IS_PLAYER(this))
1979         if(teamplay && this.team != -1)
1980         {
1981         }
1982         else
1983                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1984         this.team_selected = false;
1985 }
1986
1987 int GetPlayerLimit()
1988 {
1989         if(g_duel)
1990                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1991         int player_limit = autocvar_g_maxplayers;
1992         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1993         player_limit = M_ARGV(0, int);
1994         return player_limit;
1995 }
1996
1997 /**
1998  * Determines whether the player is allowed to join. This depends on cvar
1999  * g_maxplayers, if it isn't used this function always return true, otherwise
2000  * it checks whether the number of currently playing players exceeds g_maxplayers.
2001  * @return int number of free slots for players, 0 if none
2002  */
2003 int nJoinAllowed(entity this, entity ignore)
2004 {
2005         if(!ignore)
2006         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2007         // so report 0 free slots if restricted
2008         {
2009                 if(autocvar_g_forced_team_otherwise == "spectate")
2010                         return 0;
2011                 if(autocvar_g_forced_team_otherwise == "spectator")
2012                         return 0;
2013         }
2014
2015         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2016                 return 0; // forced spectators can never join
2017
2018         // TODO simplify this
2019         int totalClients = 0;
2020         int currentlyPlaying = 0;
2021         FOREACH_CLIENT(true, {
2022                 if(it != ignore)
2023                         ++totalClients;
2024                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2025                         ++currentlyPlaying;
2026         });
2027
2028         int player_limit = GetPlayerLimit();
2029
2030         int free_slots = 0;
2031         if (!player_limit)
2032                 free_slots = maxclients - totalClients;
2033         else if(player_limit > 0 && currentlyPlaying < player_limit)
2034                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2035
2036         static float msg_time = 0;
2037         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2038         {
2039                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2040                 msg_time = time + 0.5;
2041         }
2042
2043         return free_slots;
2044 }
2045
2046 void PrintWelcomeMessage(entity this)
2047 {
2048         if(CS(this).motd_actived_time == 0)
2049         {
2050                 if (autocvar_g_campaign) {
2051                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2052                                 CS(this).motd_actived_time = time;
2053                                 SendWelcomemessage(this, false);
2054                         }
2055                 } else {
2056                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2057                                 CS(this).motd_actived_time = time;
2058                                 SendWelcomemessage(this, true);
2059                         }
2060                 }
2061         }
2062         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2063         {
2064                 if (autocvar_g_campaign) {
2065                         if (PHYS_INPUT_BUTTON_INFO(this))
2066                                 CS(this).motd_actived_time = time;
2067                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2068                                 CS(this).motd_actived_time = 0;
2069                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2070                         }
2071                 } else {
2072                         if (PHYS_INPUT_BUTTON_INFO(this))
2073                                 CS(this).motd_actived_time = time;
2074                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2075                                 CS(this).motd_actived_time = 0;
2076                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2077                         }
2078                 }
2079         }
2080         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2081         {
2082                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2083                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2084                 else if (CS(this).motd_actived_time == -2)
2085                 {
2086                         // instantly hide MOTD
2087                         CS(this).motd_actived_time = 0;
2088                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2089                 }
2090                 else if (IS_PLAYER(this) || IS_SPEC(this))
2091                 {
2092                         // FIXME occasionally for some reason MOTD never goes away
2093                         // delay MOTD removal a little bit in the hope it fixes this bug
2094                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2095                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2096                         else //if (CS(this).motd_actived_time < -2)
2097                                 CS(this).motd_actived_time++;
2098                 }
2099         }
2100 }
2101
2102 bool joinAllowed(entity this)
2103 {
2104         if (CS(this).version_mismatch) return false;
2105         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2106         if (!nJoinAllowed(this, this)) return false;
2107         if (teamplay && lockteams) return false;
2108         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2109         if (ShowTeamSelection(this)) return false;
2110         return true;
2111 }
2112
2113 .string shootfromfixedorigin;
2114 .bool dualwielding_prev;
2115 bool PlayerThink(entity this)
2116 {
2117         if (game_stopped || intermission_running) {
2118                 this.modelflags &= ~MF_ROCKET;
2119                 if(intermission_running)
2120                         IntermissionThink(this);
2121                 return false;
2122         }
2123
2124         if (timeout_status == TIMEOUT_ACTIVE) {
2125                 // don't allow the player to turn around while game is paused
2126                 // FIXME turn this into CSQC stuff
2127                 this.v_angle = this.lastV_angle;
2128                 this.angles = this.lastV_angle;
2129                 this.fixangle = true;
2130         }
2131
2132         if (frametime) player_powerups(this);
2133
2134         if (IS_DEAD(this)) {
2135                 if (this.personal && g_race_qualifying) {
2136                         if (time > this.respawn_time) {
2137                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2138                                 respawn(this);
2139                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2140                         }
2141                 } else {
2142                         if (frametime) player_anim(this);
2143
2144                         if (this.respawn_flags & RESPAWN_DENY)
2145                         {
2146                                 STAT(RESPAWN_TIME, this) = 0;
2147                                 return false;
2148                         }
2149
2150                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2151
2152                         switch(this.deadflag)
2153                         {
2154                                 case DEAD_DYING:
2155                                 {
2156                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2157                                                 this.deadflag = DEAD_RESPAWNING;
2158                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2159                                                 this.deadflag = DEAD_DEAD;
2160                                         break;
2161                                 }
2162                                 case DEAD_DEAD:
2163                                 {
2164                                         if (button_pressed)
2165                                                 this.deadflag = DEAD_RESPAWNABLE;
2166                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2167                                                 this.deadflag = DEAD_RESPAWNING;
2168                                         break;
2169                                 }
2170                                 case DEAD_RESPAWNABLE:
2171                                 {
2172                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2173                                                 this.deadflag = DEAD_RESPAWNING;
2174                                         break;
2175                                 }
2176                                 case DEAD_RESPAWNING:
2177                                 {
2178                                         if (time > this.respawn_time)
2179                                         {
2180                                                 this.respawn_time = time + 1; // only retry once a second
2181                                                 this.respawn_time_max = this.respawn_time;
2182                                                 respawn(this);
2183                                         }
2184                                         break;
2185                                 }
2186                         }
2187
2188                         ShowRespawnCountdown(this);
2189
2190                         if (this.respawn_flags & RESPAWN_SILENT)
2191                                 STAT(RESPAWN_TIME, this) = 0;
2192                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2193                         {
2194                                 if (time < this.respawn_time)
2195                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2196                                 else if (this.deadflag != DEAD_RESPAWNING)
2197                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2198                         }
2199                         else
2200                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2201                 }
2202
2203                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2204                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2205                         STAT(RESPAWN_TIME, this) *= -1;
2206
2207                 return false;
2208         }
2209
2210         FixPlayermodel(this);
2211
2212         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2213                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2214                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2215         }
2216
2217         // reset gun alignment when dual wielding status changes
2218         // to ensure guns are always aligned right and left
2219         bool dualwielding = W_DualWielding(this);
2220         if(this.dualwielding_prev != dualwielding)
2221         {
2222                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2223                 this.dualwielding_prev = dualwielding;
2224         }
2225
2226         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2227         //if(frametime)
2228         {
2229                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2230                 {
2231                         .entity weaponentity = weaponentities[slot];
2232                         if(WEP_CVAR(vortex, charge_always))
2233                                 W_Vortex_Charge(this, weaponentity, frametime);
2234                         W_WeaponFrame(this, weaponentity);
2235                 }
2236         }
2237
2238         if (frametime)
2239         {
2240                 // WEAPONTODO: Add a weapon request for this
2241                 // rot vortex charge to the charge limit
2242                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2243                 {
2244                         .entity weaponentity = weaponentities[slot];
2245                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2246                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2247                 }
2248
2249                 player_regen(this);
2250                 player_anim(this);
2251                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2252         }
2253
2254         monsters_setstatus(this);
2255
2256         return true;
2257 }
2258
2259 .bool would_spectate;
2260 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2261 void ObserverOrSpectatorThink(entity this)
2262 {
2263         bool is_spec = IS_SPEC(this);
2264         if ( CS(this).impulse )
2265         {
2266                 int r = MinigameImpulse(this, CS(this).impulse);
2267                 if (!is_spec || r)
2268                         CS(this).impulse = 0;
2269
2270                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2271                 {
2272                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2273                         CS(this).impulse = 0;
2274                         return;
2275                 }
2276         }
2277
2278         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2279         {
2280                 CS(this).autojoin_checked = true;
2281                 TRANSMUTE(Player, this);
2282                 PutClientInServer(this);
2283                 return;
2284         }
2285
2286         if (this.flags & FL_JUMPRELEASED) {
2287                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2288                         this.flags &= ~FL_JUMPRELEASED;
2289                         this.flags |= FL_SPAWNING;
2290                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2291                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2292                         this.flags &= ~FL_JUMPRELEASED;
2293                         if(SpectateNext(this)) {
2294                                 TRANSMUTE(Spectator, this);
2295                         } else if (is_spec) {
2296                                 TRANSMUTE(Observer, this);
2297                                 PutClientInServer(this);
2298                         }
2299                         else
2300                                 this.would_spectate = false; // unable to spectate anyone
2301                         if (is_spec)
2302                                 CS(this).impulse = 0;
2303                 } else if (is_spec) {
2304                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2305                                 this.flags &= ~FL_JUMPRELEASED;
2306                                 if(SpectatePrev(this)) {
2307                                         TRANSMUTE(Spectator, this);
2308                                 } else {
2309                                         TRANSMUTE(Observer, this);
2310                                         PutClientInServer(this);
2311                                 }
2312                                 CS(this).impulse = 0;
2313                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2314                                 this.would_spectate = false;
2315                                 this.flags &= ~FL_JUMPRELEASED;
2316                                 TRANSMUTE(Observer, this);
2317                                 PutClientInServer(this);
2318                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2319                                 PutObserverInServer(this, false, true);
2320                                 this.would_spectate = true;
2321                         }
2322                 }
2323                 else {
2324                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2325                         if (PHYS_INPUT_BUTTON_USE(this))
2326                                 wouldclip = !wouldclip;
2327                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2328                         set_movetype(this, preferred_movetype);
2329                 }
2330         } else { // jump pressed
2331                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2332                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2333                         this.flags |= FL_JUMPRELEASED;
2334                         if(this.flags & FL_SPAWNING)
2335                         {
2336                                 this.flags &= ~FL_SPAWNING;
2337                                 if(joinAllowed(this))
2338                                         Join(this);
2339                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2340                                         CS(this).autojoin_checked = -1;
2341                                 return;
2342                         }
2343                 }
2344                 if(is_spec && !SpectateUpdate(this))
2345                         PutObserverInServer(this, false, true);
2346         }
2347         if (is_spec)
2348                 this.flags |= FL_CLIENT | FL_NOTARGET;
2349 }
2350
2351 void PlayerUseKey(entity this)
2352 {
2353         if (!IS_PLAYER(this))
2354                 return;
2355
2356         if(this.vehicle)
2357         {
2358                 if(!game_stopped)
2359                 {
2360                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2361                         return;
2362                 }
2363         }
2364         else if(autocvar_g_vehicles_enter)
2365         {
2366                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2367                 {
2368                         entity head, closest_target = NULL;
2369                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2370
2371                         while(head) // find the closest acceptable target to enter
2372                         {
2373                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2374                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2375                                 {
2376                                         if(closest_target)
2377                                         {
2378                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2379                                                 { closest_target = head; }
2380                                         }
2381                                         else { closest_target = head; }
2382                                 }
2383
2384                                 head = head.chain;
2385                         }
2386
2387                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2388                 }
2389         }
2390
2391         // a use key was pressed; call handlers
2392         MUTATOR_CALLHOOK(PlayerUseKey, this);
2393 }
2394
2395
2396 /*
2397 =============
2398 PlayerPreThink
2399
2400 Called every frame for each client before the physics are run
2401 =============
2402 */
2403 .float last_vehiclecheck;
2404 void PlayerPreThink (entity this)
2405 {
2406         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2407         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2408
2409         WarpZone_PlayerPhysics_FixVAngle(this);
2410
2411         if (frametime) {
2412                 // physics frames: update anticheat stuff
2413                 anticheat_prethink(this);
2414
2415                 // WORKAROUND: only use dropclient in server frames (frametime set).
2416                 // Never use it in cl_movement frames (frametime zero).
2417                 if (blockSpectators && IS_REAL_CLIENT(this)
2418                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2419                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2420                 {
2421                         if (dropclient_schedule(this))
2422                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2423                 }
2424         }
2425
2426         zoomstate_set = false;
2427
2428         // Check for nameless players
2429         if (this.netname == "" || this.netname != CS(this).netname_previous)
2430         {
2431                 bool assume_unchanged = (CS(this).netname_previous == "");
2432                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2433                 {
2434                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2435                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2436                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2437                         assume_unchanged = false;
2438                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2439                 }
2440                 if (isInvisibleString(this.netname))
2441                 {
2442                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2443                         sprint(this, "Warning: invisible names are not allowed.\n");
2444                         assume_unchanged = false;
2445                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2446                 }
2447                 if (!assume_unchanged && autocvar_sv_eventlog)
2448                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2449                 strcpy(CS(this).netname_previous, this.netname);
2450         }
2451
2452         // version nagging
2453         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2454         CS(this).version_nagtime = 0;
2455         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2456             // git client
2457         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2458             // git server
2459             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2460         } else {
2461             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2462             if (r < 0) { // old client
2463                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2464             } else if (r > 0) { // old server
2465                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2466             }
2467         }
2468     }
2469
2470         // GOD MODE info
2471         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2472         {
2473                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2474                 this.max_armorvalue = 0;
2475         }
2476
2477         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2478         {
2479                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2480                 {
2481                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2482                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2483                         if (this.iceblock)
2484                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2485
2486                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2487                                 Unfreeze(this, false);
2488                 }
2489                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2490                 {
2491                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2492                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2493
2494                         if (GetResource(this, RES_HEALTH) < 1)
2495                         {
2496                                 if (this.vehicle)
2497                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2498                                 if(this.event_damage)
2499                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2500                         }
2501                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2502                                 Unfreeze(this, false);
2503                 }
2504         }
2505
2506         MUTATOR_CALLHOOK(PlayerPreThink, this);
2507
2508         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2509         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2510         {
2511                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2512                 {
2513                         if(!it.owner)
2514                         {
2515                                 if(!it.team || SAME_TEAM(this, it))
2516                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2517                                 else if(autocvar_g_vehicles_steal)
2518                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2519                         }
2520                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2521                         {
2522                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2523                         }
2524                 });
2525
2526                 this.last_vehiclecheck = time + 1;
2527         }
2528
2529         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2530                 PlayerUseKey(this);
2531         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2532
2533         if (IS_REAL_CLIENT(this))
2534                 PrintWelcomeMessage(this);
2535
2536         if (IS_PLAYER(this)) {
2537                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2538                         error("Client can't be spawned as player on connection!");
2539                 if(!PlayerThink(this))
2540                         return;
2541         }
2542         else if (game_stopped || intermission_running) {
2543                 if(intermission_running)
2544                         IntermissionThink(this);
2545                 return;
2546         }
2547         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2548         {
2549                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2550                 CS(this).autojoin_checked = 1;
2551                 // don't do this in ClientConnect
2552                 // many things can go wrong if a client is spawned as player on connection
2553                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2554                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2555                                 && (!teamplay || autocvar_g_balance_teams)))
2556                 {
2557                         if(joinAllowed(this))
2558                                 Join(this);
2559                         return;
2560                 }
2561         }
2562         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2563                 ObserverOrSpectatorThink(this);
2564         }
2565
2566         // WEAPONTODO: Add weapon request for this
2567         if (!zoomstate_set) {
2568                 bool wep_zoomed = false;
2569                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2570                 {
2571                         .entity weaponentity = weaponentities[slot];
2572                         Weapon thiswep = this.(weaponentity).m_weapon;
2573                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2574                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2575                 }
2576                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2577         }
2578
2579         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2580         {
2581                 CS(this).teamkill_soundtime = 0;
2582
2583                 entity e = CS(this).teamkill_soundsource;
2584                 entity oldpusher = e.pusher;
2585                 e.pusher = this;
2586                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2587                 e.pusher = oldpusher;
2588         }
2589
2590         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2591                 CS(this).taunt_soundtime = 0;
2592                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2593         }
2594
2595         target_voicescript_next(this);
2596 }
2597
2598 void DrownPlayer(entity this)
2599 {
2600         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2601                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2602         {
2603                 STAT(AIR_FINISHED, this) = 0;
2604                 return;
2605         }
2606
2607         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2608         {
2609                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2610                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2611                 STAT(AIR_FINISHED, this) = 0;
2612         }
2613         else
2614         {
2615                 if (!STAT(AIR_FINISHED, this))
2616                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2617                 if (STAT(AIR_FINISHED, this) < time)
2618                 {       // drown!
2619                         if (this.pain_finished < time)
2620                         {
2621                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2622                                 this.pain_finished = time + 0.5;
2623                         }
2624                 }
2625         }
2626 }
2627
2628 .bool move_qcphysics;
2629
2630 void Player_Physics(entity this)
2631 {
2632         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2633
2634         if(!this.move_qcphysics)
2635                 return;
2636
2637         if(!frametime && !CS(this).pm_frametime)
2638                 return;
2639
2640         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2641
2642         CS(this).pm_frametime = 0;
2643 }
2644
2645 /*
2646 =============
2647 PlayerPostThink
2648
2649 Called every frame for each client after the physics are run
2650 =============
2651 */
2652 void PlayerPostThink (entity this)
2653 {
2654         Player_Physics(this);
2655
2656         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2657         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2658         if (IS_REAL_CLIENT(this))
2659         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2660         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2661         {
2662                 int totalClients = 0;
2663                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2664                 {
2665                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2666                         if (server_is_dedicated)
2667                         {
2668                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2669                                 {
2670                                         ++totalClients;
2671                                 });
2672                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2673                                         totalClients = 0;
2674                         }
2675                 }
2676                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2677                 {
2678                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2679                         {
2680                                 ++totalClients;
2681                         });
2682                 }
2683
2684                 if (totalClients < autocvar_sv_maxidle_minplayers)
2685                 {
2686                         // idle kick disabled
2687                         CS(this).parm_idlesince = time;
2688                 }
2689                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2690                 {
2691                         if (CS(this).idlekick_lasttimeleft)
2692                         {
2693                                 CS(this).idlekick_lasttimeleft = 0;
2694                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2695                         }
2696                 }
2697                 else
2698                 {
2699                         float maxidle_time = autocvar_sv_maxidle;
2700                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2701                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2702                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2703                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2704                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2705                         {
2706                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2707                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2708                                 else
2709                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2710                         }
2711                         if (timeleft <= 0) {
2712                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2713                                 {
2714                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2715                                         PutObserverInServer(this, true, true);
2716                                 }
2717                                 else
2718                                 {
2719                                         if (dropclient_schedule(this))
2720                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2721                                 }
2722                                 return;
2723                         }
2724                         else if (timeleft <= countdown_time) {
2725                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2726                                         play2(this, SND(TALK2));
2727                                 CS(this).idlekick_lasttimeleft = timeleft;
2728                         }
2729                 }
2730         }
2731
2732         CheatFrame(this);
2733
2734         if (game_stopped)
2735         {
2736                 this.solid = SOLID_NOT;
2737                 this.takedamage = DAMAGE_NO;
2738                 set_movetype(this, MOVETYPE_NONE);
2739                 CS(this).teamkill_complain = 0;
2740                 CS(this).teamkill_soundtime = 0;
2741                 CS(this).teamkill_soundsource = NULL;
2742         }
2743
2744         if (IS_PLAYER(this)) {
2745                 if(this.death_time == time && IS_DEAD(this))
2746                 {
2747                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2748                         // once all the damage events of this frame have been processed with normal size
2749                         this.maxs.z = 5;
2750                         setsize(this, this.mins, this.maxs);
2751                 }
2752                 DrownPlayer(this);
2753                 UpdateChatBubble(this);
2754                 if (CS(this).impulse) ImpulseCommands(this);
2755                 GetPressedKeys(this);
2756                 if (game_stopped)
2757                 {
2758                         CSQCMODEL_AUTOUPDATE(this);
2759                         return;
2760                 }
2761         }
2762         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2763         {
2764                 CS(this).pressedkeys = 0;
2765                 STAT(PRESSED_KEYS, this) = 0;
2766         }
2767
2768         if (this.waypointsprite_attachedforcarrier) {
2769                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2770                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2771         }
2772
2773         CSQCMODEL_AUTOUPDATE(this);
2774 }
2775
2776 // hack to copy the button fields from the client entity to the Client State
2777 void PM_UpdateButtons(entity this, entity store)
2778 {
2779         if(this.impulse)
2780                 store.impulse = this.impulse;
2781         this.impulse = 0;
2782
2783         bool typing = this.buttonchat || this.button12;
2784
2785         store.button0 = (typing) ? 0 : this.button0;
2786         //button1?!
2787         store.button2 = (typing) ? 0 : this.button2;
2788         store.button3 = (typing) ? 0 : this.button3;
2789         store.button4 = this.button4;
2790         store.button5 = (typing) ? 0 : this.button5;
2791         store.button6 = this.button6;
2792         store.button7 = this.button7;
2793         store.button8 = this.button8;
2794         store.button9 = this.button9;
2795         store.button10 = this.button10;
2796         store.button11 = this.button11;
2797         store.button12 = this.button12;
2798         store.button13 = this.button13;
2799         store.button14 = this.button14;
2800         store.button15 = this.button15;
2801         store.button16 = this.button16;
2802         store.buttonuse = this.buttonuse;
2803         store.buttonchat = this.buttonchat;
2804
2805         store.cursor_active = this.cursor_active;
2806         store.cursor_screen = this.cursor_screen;
2807         store.cursor_trace_start = this.cursor_trace_start;
2808         store.cursor_trace_endpos = this.cursor_trace_endpos;
2809         store.cursor_trace_ent = this.cursor_trace_ent;
2810
2811         store.ping = this.ping;
2812         store.ping_packetloss = this.ping_packetloss;
2813         store.ping_movementloss = this.ping_movementloss;
2814
2815         store.v_angle = this.v_angle;
2816         store.movement = this.movement;
2817 }
2818
2819 NET_HANDLE(fpsreport, bool)
2820 {
2821         int fps = ReadShort();
2822         PlayerScore_Set(sender, SP_FPS, fps);
2823         return true;
2824 }