qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38
  39 #include "../common/vehicles/all.qh"
  40
  41 #include "weapons/hitplot.qh"
  42 #include "weapons/weaponsystem.qh"
  43
  44 #include "../common/net_notice.qh"
  45 #include "../common/net_linked.qh"
  46 #include "../common/physics/player.qh"
  47
  48 #include "../common/items/_mod.qh"
  49
  50 #include "../common/mutators/mutator/waypoints/all.qh"
  51
  52 #include "../common/triggers/subs.qh"
  53 #include "../common/triggers/triggers.qh"
  54 #include "../common/triggers/trigger/secret.qh"
  55
  56 #include "../common/minigames/sv_minigames.qh"
  57
  58 #include "../common/items/inventory.qh"
  59
  60 #include "../common/monsters/sv_monsters.qh"
  61
  62 #include "../lib/warpzone/server.qh"
  63
  64 STATIC_METHOD(Client, Add, void(Client this, int _team))
  65 {
  66     ClientConnect(this);
  67     TRANSMUTE(Player, this);
  68     this.frame = 12; // 7
  69     this.team = _team;
  70     PutClientInServer(this);
  71 }
  72
  73 void PutObserverInServer(entity this);
  74
  75 STATIC_METHOD(Client, Remove, void(Client this))
  76 {
  77     TRANSMUTE(Observer, this);
  78     PutClientInServer(this);
  79     ClientDisconnect(this);
  80 }
  81
  82 void send_CSQC_teamnagger() {
  83         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  84 }
  85
  86 int CountSpectators(entity player, entity to)
  87 {
  88         if(!player) { return 0; } // not sure how, but best to be safe
  89
  90         int spec_count = 0;
  91
  92         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  93         {
  94                 spec_count++;
  95         });
  96
  97         return spec_count;
  98 }
  99
 100 void WriteSpectators(entity player, entity to)
 101 {
 102         if(!player) { return; } // not sure how, but best to be safe
 103
 104         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 105         {
 106                 WriteByte(MSG_ENTITY, num_for_edict(it));
 107         });
 108 }
 109
 110 bool ClientData_Send(entity this, entity to, int sf)
 111 {
 112         assert(to == this.owner, return false);
 113
 114         entity e = to;
 115         if (IS_SPEC(e)) e = e.enemy;
 116
 117         sf = 0;
 118         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 119         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 120         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 121         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 122
 123         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 124         WriteByte(MSG_ENTITY, sf);
 125
 126         if (sf & BIT(1))
 127                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 128
 129         if(sf & BIT(4))
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         CS(this).clientdata.drawonlytoclient = this;
 143         CS(this).clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(CS(this).clientdata);
 149         CS(this).clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         CS(e).clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 158 }
 159
 160 void SetSpectatee(entity this, entity spectatee);
 161 void SetSpectatee_status(entity this, int spectatee_num);
 162
 163
 164 /*
 165 =============
 166 CheckPlayerModel
 167
 168 Checks if the argument string can be a valid playermodel.
 169 Returns a valid one in doubt.
 170 =============
 171 */
 172 string FallbackPlayerModel;
 173 string CheckPlayerModel(string plyermodel) {
 174         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 175         {
 176                 // note: we cannot summon Don Strunzone here, some player may
 177                 // still have the model string set. In case anyone manages how
 178                 // to change a cvar default, we'll have a small leak here.
 179                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 180         }
 181         // only in right path
 182         if( substring(plyermodel,0,14) != "models/player/")
 183                 return FallbackPlayerModel;
 184         // only good file extensions
 185         if(substring(plyermodel,-4,4) != ".zym")
 186         if(substring(plyermodel,-4,4) != ".dpm")
 187         if(substring(plyermodel,-4,4) != ".iqm")
 188         if(substring(plyermodel,-4,4) != ".md3")
 189         if(substring(plyermodel,-4,4) != ".psk")
 190                 return FallbackPlayerModel;
 191         // forbid the LOD models
 192         if(substring(plyermodel, -9,5) == "_lod1")
 193                 return FallbackPlayerModel;
 194         if(substring(plyermodel, -9,5) == "_lod2")
 195                 return FallbackPlayerModel;
 196         if(plyermodel != strtolower(plyermodel))
 197                 return FallbackPlayerModel;
 198         // also, restrict to server models
 199         if(autocvar_sv_servermodelsonly)
 200         {
 201                 if(!fexists(plyermodel))
 202                         return FallbackPlayerModel;
 203         }
 204         return plyermodel;
 205 }
 206
 207 void setplayermodel(entity e, string modelname)
 208 {
 209         precache_model(modelname);
 210         _setmodel(e, modelname);
 211         player_setupanimsformodel(e);
 212         if(!autocvar_g_debug_globalsounds)
 213                 UpdatePlayerSounds(e);
 214 }
 215
 216 void FixPlayermodel(entity player);
 217 /** putting a client as observer in the server */
 218 void PutObserverInServer(entity this)
 219 {
 220     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 221         PlayerState_detach(this);
 222
 223         if (IS_PLAYER(this))
 224         {
 225                 if(this.health >= 1)
 226                 {
 227                         // despawn effect
 228                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 229                 }
 230
 231                 // was a player, recount votes and ready status
 232                 if(IS_REAL_CLIENT(this))
 233                 {
 234                         if (vote_called) { VoteCount(false); }
 235                         ReadyCount();
 236                 }
 237     }
 238
 239     {
 240         entity spot = SelectSpawnPoint(this, true);
 241         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 242         this.angles = vec2(spot.angles);
 243         this.fixangle = true;
 244         // offset it so that the spectator spawns higher off the ground, looks better this way
 245         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 246         if (IS_REAL_CLIENT(this))
 247         {
 248             msg_entity = this;
 249             WriteByte(MSG_ONE, SVC_SETVIEW);
 250             WriteEntity(MSG_ONE, this);
 251         }
 252         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254         if(!autocvar_g_debug_globalsounds)
 255         {
 256                 // needed for player sounds
 257                 this.model = "";
 258                 FixPlayermodel(this);
 259         }
 260         setmodel(this, MDL_Null);
 261         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 262         this.view_ofs = '0 0 0';
 263     }
 264
 265     RemoveGrapplingHooks(this);
 266         Portal_ClearAll(this);
 267         Unfreeze(this);
 268         SetSpectatee(this, NULL);
 269
 270         if (this.alivetime)
 271         {
 272                 if (!warmup_stage)
 273                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 274                 this.alivetime = 0;
 275         }
 276
 277         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 278
 279         WaypointSprite_PlayerDead(this);
 280
 281         if (mutator_returnvalue) {
 282             // mutator prevents resetting teams+score
 283         } else {
 284                 int oldteam = this.team;
 285                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 286                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 287         this.frags = FRAGS_SPECTATOR;
 288         PlayerScore_Clear(this);  // clear scores when needed
 289     }
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 294                 if(!game_stopped)
 295                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 297
 298                 if(!CS(this).just_joined)
 299                         LogTeamchange(this.playerid, -1, 4);
 300                 else
 301                         CS(this).just_joined = false;
 302         }
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310     this.hud = HUD_NORMAL;
 311         TRANSMUTE(Observer, this);
 312         this.iscreature = false;
 313         this.teleportable = TELEPORT_SIMPLE;
 314         if(this.damagedbycontents)
 315                 IL_REMOVE(g_damagedbycontents, this);
 316         this.damagedbycontents = false;
 317         this.health = FRAGS_SPECTATOR;
 318         SetSpectatee_status(this, etof(this));
 319         this.takedamage = DAMAGE_NO;
 320         this.solid = SOLID_NOT;
 321         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 322         this.flags = FL_CLIENT | FL_NOTARGET;
 323         this.armorvalue = 666;
 324         this.effects = 0;
 325         this.armorvalue = autocvar_g_balance_armor_start;
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         this.stat_respawn_time = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_frame = 0;
 338         this.pain_finished = 0;
 339         this.strength_finished = 0;
 340         this.invincible_finished = 0;
 341         this.superweapons_finished = 0;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         this.revive_progress = 0;
 349         this.revival_time = 0;
 350
 351         this.items = 0;
 352         this.weapons = '0 0 0';
 353         this.drawonlytoclient = this;
 354
 355         this.weaponmodel = "";
 356         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 357         {
 358                 this.weaponentities[slot] = NULL;
 359         }
 360         this.exteriorweaponentity = NULL;
 361         CS(this).killcount = FRAGS_SPECTATOR;
 362         this.velocity = '0 0 0';
 363         this.avelocity = '0 0 0';
 364         this.punchangle = '0 0 0';
 365         this.punchvector = '0 0 0';
 366         this.oldvelocity = this.velocity;
 367         this.fire_endtime = -1;
 368         this.event_damage = func_null;
 369
 370         for(int slot = 0; slot < MAX_AXH; ++slot)
 371         {
 372                 entity axh = this.(AuxiliaryXhair[slot]);
 373                 this.(AuxiliaryXhair[slot]) = NULL;
 374
 375                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 376                         delete(axh);
 377         }
 378 }
 379
 380 int player_getspecies(entity this)
 381 {
 382         get_model_parameters(this.model, this.skin);
 383         int s = get_model_parameters_species;
 384         get_model_parameters(string_null, 0);
 385         if (s < 0) return SPECIES_HUMAN;
 386         return s;
 387 }
 388
 389 .float model_randomizer;
 390 void FixPlayermodel(entity player)
 391 {
 392         string defaultmodel = "";
 393         int defaultskin = 0;
 394         if(autocvar_sv_defaultcharacter)
 395         {
 396                 if(teamplay)
 397                 {
 398                         switch(player.team)
 399                         {
 400                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 401                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 402                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 403                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 404                         }
 405                 }
 406
 407                 if(defaultmodel == "")
 408                 {
 409                         defaultmodel = autocvar_sv_defaultplayermodel;
 410                         defaultskin = autocvar_sv_defaultplayerskin;
 411                 }
 412
 413                 int n = tokenize_console(defaultmodel);
 414                 if(n > 0)
 415                 {
 416                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 417                         // However, do NOT randomize if the player-selected model is in the list.
 418                         for (int i = 0; i < n; ++i)
 419                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 420                                         defaultmodel = argv(i);
 421                 }
 422
 423                 int i = strstrofs(defaultmodel, ":", 0);
 424                 if(i >= 0)
 425                 {
 426                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 427                         defaultmodel = substring(defaultmodel, 0, i);
 428                 }
 429         }
 430         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 431         {
 432                 if(teamplay)
 433                 {
 434                         switch(player.team)
 435                         {
 436                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 437                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 438                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 439                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 440                         }
 441                 }
 442
 443                 if(!defaultskin)
 444                         defaultskin = autocvar_sv_defaultplayerskin;
 445         }
 446
 447         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 448         defaultmodel = M_ARGV(0, string);
 449         defaultskin = M_ARGV(1, int);
 450
 451         bool chmdl = false;
 452         int oldskin;
 453         if(defaultmodel != "")
 454         {
 455                 if (defaultmodel != player.model)
 456                 {
 457                         vector m1 = player.mins;
 458                         vector m2 = player.maxs;
 459                         setplayermodel (player, defaultmodel);
 460                         setsize (player, m1, m2);
 461                         chmdl = true;
 462                 }
 463
 464                 oldskin = player.skin;
 465                 player.skin = defaultskin;
 466         } else {
 467                 if (player.playermodel != player.model || player.playermodel == "")
 468                 {
 469                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 470                         vector m1 = player.mins;
 471                         vector m2 = player.maxs;
 472                         setplayermodel (player, player.playermodel);
 473                         setsize (player, m1, m2);
 474                         chmdl = true;
 475                 }
 476
 477                 if(!autocvar_sv_defaultcharacterskin)
 478                 {
 479                         oldskin = player.skin;
 480                         player.skin = stof(player.playerskin);
 481                 }
 482                 else
 483                 {
 484                         oldskin = player.skin;
 485                         player.skin = defaultskin;
 486                 }
 487         }
 488
 489         if(chmdl || oldskin != player.skin) // model or skin has changed
 490         {
 491                 player.species = player_getspecies(player); // update species
 492                 if(!autocvar_g_debug_globalsounds)
 493                         UpdatePlayerSounds(player); // update skin sounds
 494         }
 495
 496         if(!teamplay)
 497                 if(strlen(autocvar_sv_defaultplayercolors))
 498                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 499                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 500 }
 501
 502 void PutPlayerInServer(entity this)
 503 {
 504         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 505
 506         PlayerState_attach(this);
 507         accuracy_resend(this);
 508
 509         if (this.team < 0)
 510                 JoinBestTeam(this, true);
 511
 512         entity spot = SelectSpawnPoint(this, false);
 513         if (!spot) {
 514                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 515                 return; // spawn failed
 516         }
 517
 518         TRANSMUTE(Player, this);
 519
 520         CS(this).wasplayer = true;
 521         this.iscreature = true;
 522         this.teleportable = TELEPORT_NORMAL;
 523         if(!this.damagedbycontents)
 524                 IL_PUSH(g_damagedbycontents, this);
 525         this.damagedbycontents = true;
 526         set_movetype(this, MOVETYPE_WALK);
 527         this.solid = SOLID_SLIDEBOX;
 528         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 529         if (autocvar_g_playerclip_collisions)
 530                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 531         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 532                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 533         this.frags = FRAGS_PLAYER;
 534         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 535         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 536         if (autocvar__notarget)
 537                 this.flags |= FL_NOTARGET;
 538         this.takedamage = DAMAGE_AIM;
 539         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 540
 541         if (warmup_stage) {
 542                 this.ammo_shells = warmup_start_ammo_shells;
 543                 this.ammo_nails = warmup_start_ammo_nails;
 544                 this.ammo_rockets = warmup_start_ammo_rockets;
 545                 this.ammo_cells = warmup_start_ammo_cells;
 546                 this.ammo_plasma = warmup_start_ammo_plasma;
 547                 this.ammo_fuel = warmup_start_ammo_fuel;
 548                 this.health = warmup_start_health;
 549                 this.armorvalue = warmup_start_armorvalue;
 550                 this.weapons = WARMUP_START_WEAPONS;
 551         } else {
 552                 this.ammo_shells = start_ammo_shells;
 553                 this.ammo_nails = start_ammo_nails;
 554                 this.ammo_rockets = start_ammo_rockets;
 555                 this.ammo_cells = start_ammo_cells;
 556                 this.ammo_plasma = start_ammo_plasma;
 557                 this.ammo_fuel = start_ammo_fuel;
 558                 this.health = start_health;
 559                 this.armorvalue = start_armorvalue;
 560                 this.weapons = start_weapons;
 561                 if (MUTATOR_CALLHOOK(ShouldGiveRandomStartWeapons, this) == false)
 562                 {
 563                         GiveRandomWeapons(this, random_start_weapons_count,
 564                                 autocvar_g_random_start_weapons, random_start_ammo);
 565                 }
 566         }
 567         SetSpectatee_status(this, 0);
 568
 569         PS(this).dual_weapons = '0 0 0';
 570
 571         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 572
 573         this.items = start_items;
 574
 575         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 576         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 577         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 578         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 579         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 580         // extend the pause of rotting if client was reset at the beginning of the countdown
 581         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 582                 float f = game_starttime - time;
 583                 this.spawnshieldtime += f;
 584                 this.pauserotarmor_finished += f;
 585                 this.pauserothealth_finished += f;
 586                 this.pauseregen_finished += f;
 587         }
 588         this.damageforcescale = 2;
 589         this.death_time = 0;
 590         this.respawn_flags = 0;
 591         this.respawn_time = 0;
 592         this.stat_respawn_time = 0;
 593         this.scale = autocvar_sv_player_scale;
 594         this.fade_time = 0;
 595         this.pain_frame = 0;
 596         this.pain_finished = 0;
 597         this.pushltime = 0;
 598         setthink(this, func_null); // players have no think function
 599         this.nextthink = 0;
 600         this.dmg_team = 0;
 601         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 602
 603         this.deadflag = DEAD_NO;
 604
 605         this.angles = spot.angles;
 606         this.angles_z = 0; // never spawn tilted even if the spot says to
 607         if (IS_BOT_CLIENT(this))
 608                 this.v_angle = this.angles;
 609         this.fixangle = true; // turn this way immediately
 610         this.oldvelocity = this.velocity = '0 0 0';
 611         this.avelocity = '0 0 0';
 612         this.punchangle = '0 0 0';
 613         this.punchvector = '0 0 0';
 614
 615         this.strength_finished = 0;
 616         this.invincible_finished = 0;
 617         this.fire_endtime = -1;
 618         this.revive_progress = 0;
 619         this.revival_time = 0;
 620         this.air_finished = time + 12;
 621
 622         entity spawnevent = new_pure(spawnevent);
 623         spawnevent.owner = this;
 624         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 625
 626         // Cut off any still running player sounds.
 627         stopsound(this, CH_PLAYER_SINGLE);
 628
 629         this.model = "";
 630         FixPlayermodel(this);
 631         this.drawonlytoclient = NULL;
 632
 633         this.viewloc = NULL;
 634
 635         this.crouch = false;
 636         this.view_ofs = STAT(PL_VIEW_OFS, this);
 637         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 638         this.spawnorigin = spot.origin;
 639         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 640         // don't reset back to last position, even if new position is stuck in solid
 641         this.oldorigin = this.origin;
 642         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 643         if(this.conveyor)
 644                 IL_REMOVE(g_conveyed, this);
 645         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 646         this.hud = HUD_NORMAL;
 647
 648         this.event_damage = PlayerDamage;
 649
 650         if(!this.bot_attack)
 651                 IL_PUSH(g_bot_targets, this);
 652         this.bot_attack = true;
 653         if(!this.monster_attack)
 654                 IL_PUSH(g_monster_targets, this);
 655         this.monster_attack = true;
 656         navigation_dynamicgoal_init(this, false);
 657
 658         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 659
 660         // player was spectator
 661         if (CS(this).killcount == FRAGS_SPECTATOR) {
 662                 PlayerScore_Clear(this);
 663                 CS(this).killcount = 0;
 664                 CS(this).startplaytime = time;
 665         }
 666
 667         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 668         {
 669                 .entity weaponentity = weaponentities[slot];
 670                 entity oldwep = this.(weaponentity);
 671                 CL_SpawnWeaponentity(this, weaponentity);
 672                 if(oldwep && oldwep.owner == this)
 673                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 674         }
 675         this.alpha = default_player_alpha;
 676         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 677         this.exteriorweaponentity.alpha = default_weapon_alpha;
 678
 679         this.speedrunning = false;
 680
 681         target_voicescript_clear(this);
 682
 683         // reset fields the weapons may use
 684         FOREACH(Weapons, true, {
 685                 it.wr_resetplayer(it, this);
 686                         // reload all reloadable weapons
 687                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 688                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 689                         {
 690                                 .entity weaponentity = weaponentities[slot];
 691                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 692                         }
 693                 }
 694         });
 695
 696         {
 697                 string s = spot.target;
 698                 spot.target = string_null;
 699                 SUB_UseTargets(spot, this, NULL);
 700                 spot.target = s;
 701         }
 702
 703         Unfreeze(this);
 704
 705         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 706
 707         if (autocvar_spawn_debug)
 708         {
 709                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 710                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 711         }
 712
 713         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 714         {
 715                 .entity weaponentity = weaponentities[slot];
 716                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 717                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 718                 else
 719                         this.(weaponentity).m_switchweapon = WEP_Null;
 720                 this.(weaponentity).m_weapon = WEP_Null;
 721                 this.(weaponentity).weaponname = "";
 722                 this.(weaponentity).m_switchingweapon = WEP_Null;
 723                 this.(weaponentity).cnt = -1;
 724         }
 725
 726         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 727
 728         if (!warmup_stage && !this.alivetime)
 729                 this.alivetime = time;
 730
 731         antilag_clear(this, CS(this));
 732 }
 733
 734 /** Called when a client spawns in the server */
 735 void PutClientInServer(entity this)
 736 {
 737         if (IS_BOT_CLIENT(this)) {
 738                 TRANSMUTE(Player, this);
 739         } else if (IS_REAL_CLIENT(this)) {
 740                 msg_entity = this;
 741                 WriteByte(MSG_ONE, SVC_SETVIEW);
 742                 WriteEntity(MSG_ONE, this);
 743         }
 744         if (game_stopped)
 745                 TRANSMUTE(Observer, this);
 746
 747         SetSpectatee(this, NULL);
 748
 749         // reset player keys
 750         if(PS(this))
 751                 PS(this).itemkeys = 0;
 752
 753         MUTATOR_CALLHOOK(PutClientInServer, this);
 754
 755         if (IS_OBSERVER(this)) {
 756                 PutObserverInServer(this);
 757         } else if (IS_PLAYER(this)) {
 758                 PutPlayerInServer(this);
 759         }
 760 }
 761
 762 void ClientInit_misc(entity this);
 763
 764 // TODO do we need all these fields, or should we stop autodetecting runtime
 765 // changes and just have a console command to update this?
 766 bool ClientInit_SendEntity(entity this, entity to, int sf)
 767 {
 768         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 769         return = true;
 770         msg_entity = to;
 771         // MSG_INIT replacement
 772         // TODO: make easier to use
 773         Registry_send_all();
 774         W_PROP_reload(MSG_ONE, to);
 775         ClientInit_misc(this);
 776         MUTATOR_CALLHOOK(Ent_Init);
 777 }
 778 void ClientInit_misc(entity this)
 779 {
 780         int channel = MSG_ONE;
 781         WriteHeader(channel, ENT_CLIENT_INIT);
 782         WriteByte(channel, g_nexball_meter_period * 32);
 783         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 784         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 785         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 786         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 787         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 788         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 789         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 790         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 791
 792         if(sv_foginterval && world.fog != "")
 793                 WriteString(channel, world.fog);
 794         else
 795                 WriteString(channel, "");
 796         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 797         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 798         WriteByte(channel, serverflags);
 799         WriteCoord(channel, autocvar_g_trueaim_minrange);
 800 }
 801
 802 void ClientInit_CheckUpdate(entity this)
 803 {
 804         this.nextthink = time;
 805         if(this.count != autocvar_g_balance_armor_blockpercent)
 806         {
 807                 this.count = autocvar_g_balance_armor_blockpercent;
 808                 this.SendFlags |= 1;
 809         }
 810         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 811         {
 812                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 813                 this.SendFlags |= 1;
 814         }
 815 }
 816
 817 void ClientInit_Spawn()
 818 {
 819         entity e = new_pure(clientinit);
 820         setthink(e, ClientInit_CheckUpdate);
 821         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 822
 823         ClientInit_CheckUpdate(e);
 824 }
 825
 826 /*
 827 =============
 828 SetNewParms
 829 =============
 830 */
 831 void SetNewParms ()
 832 {
 833         // initialize parms for a new player
 834         parm1 = -(86400 * 366);
 835
 836         MUTATOR_CALLHOOK(SetNewParms);
 837 }
 838
 839 /*
 840 =============
 841 SetChangeParms
 842 =============
 843 */
 844 void SetChangeParms (entity this)
 845 {
 846         // save parms for level change
 847         parm1 = CS(this).parm_idlesince - time;
 848
 849         MUTATOR_CALLHOOK(SetChangeParms);
 850 }
 851
 852 /*
 853 =============
 854 DecodeLevelParms
 855 =============
 856 */
 857 void DecodeLevelParms(entity this)
 858 {
 859         // load parms
 860         CS(this).parm_idlesince = parm1;
 861         if (CS(this).parm_idlesince == -(86400 * 366))
 862                 CS(this).parm_idlesince = time;
 863
 864         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 865         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 866
 867         MUTATOR_CALLHOOK(DecodeLevelParms);
 868 }
 869
 870 /*
 871 =============
 872 ClientKill
 873
 874 Called when a client types 'kill' in the console
 875 =============
 876 */
 877
 878 .float clientkill_nexttime;
 879 void ClientKill_Now_TeamChange(entity this)
 880 {
 881         if(this.killindicator_teamchange == -1)
 882         {
 883                 JoinBestTeam( this, true );
 884         }
 885         else if(this.killindicator_teamchange == -2)
 886         {
 887                 if(blockSpectators)
 888                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 889                 PutObserverInServer(this);
 890         }
 891         else
 892                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 893         this.killindicator_teamchange = 0;
 894 }
 895
 896 void ClientKill_Now(entity this)
 897 {
 898         if(this.vehicle)
 899         {
 900             vehicles_exit(this.vehicle, VHEF_RELEASE);
 901             if(!this.killindicator_teamchange)
 902             {
 903             this.vehicle_health = -1;
 904             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 905             }
 906         }
 907
 908         if(this.killindicator && !wasfreed(this.killindicator))
 909                 delete(this.killindicator);
 910
 911         this.killindicator = NULL;
 912
 913         if(this.killindicator_teamchange)
 914                 ClientKill_Now_TeamChange(this);
 915
 916         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 917         {
 918                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 919         }
 920
 921         // now I am sure the player IS dead
 922 }
 923 void KillIndicator_Think(entity this)
 924 {
 925         if (game_stopped)
 926         {
 927                 this.owner.killindicator = NULL;
 928                 delete(this);
 929                 return;
 930         }
 931
 932         if (this.owner.alpha < 0 && !this.owner.vehicle)
 933         {
 934                 this.owner.killindicator = NULL;
 935                 delete(this);
 936                 return;
 937         }
 938
 939         if(this.cnt <= 0)
 940         {
 941                 ClientKill_Now(this.owner);
 942                 return;
 943         }
 944     else if(this.health == 1) // health == 1 means that it's silent
 945     {
 946         this.nextthink = time + 1;
 947         this.cnt -= 1;
 948     }
 949         else
 950         {
 951                 if(this.cnt <= 10)
 952                         setmodel(this, MDL_NUM(this.cnt));
 953                 if(IS_REAL_CLIENT(this.owner))
 954                 {
 955                         if(this.cnt <= 10)
 956                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 957                 }
 958                 this.nextthink = time + 1;
 959                 this.cnt -= 1;
 960         }
 961 }
 962
 963 float clientkilltime;
 964 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 965 {
 966         float killtime;
 967         float starttime;
 968
 969         if (game_stopped)
 970                 return;
 971
 972         killtime = autocvar_g_balance_kill_delay;
 973
 974     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 975         return;
 976     killtime = M_ARGV(1, float);
 977
 978         this.killindicator_teamchange = targetteam;
 979
 980     if(!this.killindicator)
 981         {
 982                 if(!IS_DEAD(this))
 983                 {
 984                         killtime = max(killtime, this.clientkill_nexttime - time);
 985                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 986                 }
 987
 988                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 989                 {
 990                         ClientKill_Now(this);
 991                 }
 992                 else
 993                 {
 994                         starttime = max(time, clientkilltime);
 995
 996                         this.killindicator = spawn();
 997                         this.killindicator.owner = this;
 998                         this.killindicator.scale = 0.5;
 999                         setattachment(this.killindicator, this, "");
1000                         setorigin(this.killindicator, '0 0 52');
1001                         setthink(this.killindicator, KillIndicator_Think);
1002                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1003                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1004                         this.killindicator.cnt = ceil(killtime);
1005                         this.killindicator.count = bound(0, ceil(killtime), 10);
1006                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1007
1008                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1009                         {
1010                                 it.killindicator = spawn();
1011                                 it.killindicator.owner = it;
1012                                 it.killindicator.scale = 0.5;
1013                                 setattachment(it.killindicator, it, "");
1014                                 setorigin(it.killindicator, '0 0 52');
1015                                 setthink(it.killindicator, KillIndicator_Think);
1016                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1017                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1018                                 it.killindicator.cnt = ceil(killtime);
1019                         });
1020                         this.lip = 0;
1021                 }
1022         }
1023         if(this.killindicator)
1024         {
1025                 if(targetteam == 0) // just die
1026                 {
1027                         this.killindicator.colormod = '0 0 0';
1028                         if(IS_REAL_CLIENT(this))
1029                         if(this.killindicator.cnt > 0)
1030                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1031                 }
1032                 else if(targetteam == -1) // auto
1033                 {
1034                         this.killindicator.colormod = '0 1 0';
1035                         if(IS_REAL_CLIENT(this))
1036                         if(this.killindicator.cnt > 0)
1037                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1038                 }
1039                 else if(targetteam == -2) // spectate
1040                 {
1041                         this.killindicator.colormod = '0.5 0.5 0.5';
1042                         if(IS_REAL_CLIENT(this))
1043                         if(this.killindicator.cnt > 0)
1044                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1045                 }
1046                 else
1047                 {
1048                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1049                         if(IS_REAL_CLIENT(this))
1050                         if(this.killindicator.cnt > 0)
1051                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1052                 }
1053         }
1054
1055 }
1056
1057 void ClientKill (entity this)
1058 {
1059         if(game_stopped) return;
1060         if(this.player_blocked) return;
1061         if(STAT(FROZEN, this)) return;
1062
1063         ClientKill_TeamChange(this, 0);
1064 }
1065
1066 void FixClientCvars(entity e)
1067 {
1068         // send prediction settings to the client
1069         stuffcmd(e, "\nin_bindmap 0 0\n");
1070         if(autocvar_g_antilag == 3) // client side hitscan
1071                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1072         if(autocvar_sv_gentle)
1073                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1074
1075         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1076         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1077
1078         MUTATOR_CALLHOOK(FixClientCvars, e);
1079 }
1080
1081 bool findinlist_abbrev(string tofind, string list)
1082 {
1083         if(list == "" || tofind == "")
1084                 return false; // empty list or search, just return
1085
1086         // this function allows abbreviated strings!
1087         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1088         {
1089                 return true;
1090         });
1091
1092         return false;
1093 }
1094
1095 bool PlayerInIPList(entity p, string iplist)
1096 {
1097         // some safety checks (never allow local?)
1098         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1099                 return false;
1100
1101         return findinlist_abbrev(p.netaddress, iplist);
1102 }
1103
1104 bool PlayerInIDList(entity p, string idlist)
1105 {
1106         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1107         if(!p.crypto_idfp)
1108                 return false;
1109
1110         return findinlist_abbrev(p.crypto_idfp, idlist);
1111 }
1112
1113 bool PlayerInList(entity player, string list)
1114 {
1115         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1116 }
1117
1118 #ifdef DP_EXT_PRECONNECT
1119 /*
1120 =============
1121 ClientPreConnect
1122
1123 Called once (not at each match start) when a client begins a connection to the server
1124 =============
1125 */
1126 void ClientPreConnect(entity this)
1127 {
1128         if(autocvar_sv_eventlog)
1129         {
1130                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1131                         this.playerid,
1132                         etof(this),
1133                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1134                 ));
1135         }
1136 }
1137 #endif
1138
1139 /**
1140 =============
1141 ClientConnect
1142
1143 Called when a client connects to the server
1144 =============
1145 */
1146 void ClientConnect(entity this)
1147 {
1148         if (Ban_MaybeEnforceBanOnce(this)) return;
1149         assert(!IS_CLIENT(this), return);
1150         this.flags |= FL_CLIENT;
1151         assert(player_count >= 0, player_count = 0);
1152
1153 #ifdef WATERMARK
1154         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1155 #endif
1156         TRANSMUTE(Client, this);
1157         CS(this).version_nagtime = time + 10 + random() * 10;
1158
1159         // identify the right forced team
1160         if (autocvar_g_campaign)
1161         {
1162                 if (IS_REAL_CLIENT(this)) // only players, not bots
1163                 {
1164                         switch (autocvar_g_campaign_forceteam)
1165                         {
1166                                 case 1: this.team_forced = NUM_TEAM_1; break;
1167                                 case 2: this.team_forced = NUM_TEAM_2; break;
1168                                 case 3: this.team_forced = NUM_TEAM_3; break;
1169                                 case 4: this.team_forced = NUM_TEAM_4; break;
1170                                 default: this.team_forced = 0;
1171                         }
1172                 }
1173         }
1174         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1175         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1176         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1177         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1178         else switch (autocvar_g_forced_team_otherwise)
1179         {
1180                 default: this.team_forced = 0; break;
1181                 case "red": this.team_forced = NUM_TEAM_1; break;
1182                 case "blue": this.team_forced = NUM_TEAM_2; break;
1183                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1184                 case "pink": this.team_forced = NUM_TEAM_4; break;
1185                 case "spectate":
1186                 case "spectator":
1187                         this.team_forced = -1;
1188                         break;
1189         }
1190         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1191
1192     {
1193         int id = this.playerid;
1194         this.playerid = 0; // silent
1195             JoinBestTeam(this, false); // if the team number is valid, keep it
1196             this.playerid = id;
1197     }
1198
1199         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1200                 TRANSMUTE(Observer, this);
1201         } else {
1202                 if (!teamplay || autocvar_g_balance_teams) {
1203                         TRANSMUTE(Player, this);
1204                         campaign_bots_may_start = true;
1205                 } else {
1206                         TRANSMUTE(Observer, this); // do it anyway
1207                 }
1208         }
1209
1210         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1211
1212         // always track bots, don't ask for cl_allow_uidtracking
1213         if (IS_BOT_CLIENT(this))
1214                 PlayerStats_GameReport_AddPlayer(this);
1215         else
1216                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1217
1218         if (autocvar_sv_eventlog)
1219                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1220
1221         LogTeamchange(this.playerid, this.team, 1);
1222
1223         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1224
1225         if(teamplay && IS_PLAYER(this))
1226                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1227         else
1228                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1229
1230         stuffcmd(this, clientstuff, "\n");
1231         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1232
1233         FixClientCvars(this);
1234
1235         // get version info from player
1236         stuffcmd(this, "cmd clientversion $gameversion\n");
1237
1238         // notify about available teams
1239         if (teamplay)
1240         {
1241                 CheckAllowedTeams(this);
1242                 int t = 0;
1243                 if (c1 >= 0) t |= BIT(0);
1244                 if (c2 >= 0) t |= BIT(1);
1245                 if (c3 >= 0) t |= BIT(2);
1246                 if (c4 >= 0) t |= BIT(3);
1247                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1248         }
1249         else
1250         {
1251                 stuffcmd(this, "set _teams_available 0\n");
1252         }
1253
1254         bot_relinkplayerlist();
1255
1256         CS(this).spectatortime = time;
1257         if (blockSpectators)
1258         {
1259                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1260         }
1261
1262         CS(this).jointime = time;
1263
1264         if (IS_REAL_CLIENT(this))
1265         {
1266                 if (g_weaponarena_weapons == WEPSET(TUBA))
1267                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1268         }
1269
1270         if (!sv_foginterval && world.fog != "")
1271                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1272
1273         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1274                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1275                         send_CSQC_teamnagger();
1276
1277         CSQCMODEL_AUTOINIT(this);
1278
1279         CS(this).model_randomizer = random();
1280
1281         if (IS_REAL_CLIENT(this))
1282                 sv_notice_join(this);
1283
1284         // update physics stats (players can spawn before physics runs)
1285         Physics_UpdateStats(this);
1286
1287         IL_EACH(g_initforplayer, it.init_for_player, {
1288                 it.init_for_player(it, this);
1289         });
1290
1291         Handicap_Initialize(this);
1292
1293         MUTATOR_CALLHOOK(ClientConnect, this);
1294
1295         if (IS_REAL_CLIENT(this))
1296         {
1297                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1298                 {
1299                         CS(this).motd_actived_time = -1;
1300                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1301                 }
1302         }
1303 }
1304 /*
1305 =============
1306 ClientDisconnect
1307
1308 Called when a client disconnects from the server
1309 =============
1310 */
1311 .entity chatbubbleentity;
1312 void ReadyCount();
1313 void ClientDisconnect(entity this)
1314 {
1315         assert(IS_CLIENT(this), return);
1316
1317         PlayerStats_GameReport_FinalizePlayer(this);
1318         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1319         if (CS(this).active_minigame) part_minigame(this);
1320         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1321
1322         if (autocvar_sv_eventlog)
1323                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1324
1325         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1326
1327         if(IS_SPEC(this))
1328                 SetSpectatee(this, NULL);
1329
1330     MUTATOR_CALLHOOK(ClientDisconnect, this);
1331
1332         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1333         ClientState_detach(this);
1334
1335         Portal_ClearAll(this);
1336
1337         Unfreeze(this);
1338
1339         RemoveGrapplingHooks(this);
1340
1341         // Here, everything has been done that requires this player to be a client.
1342
1343         this.flags &= ~FL_CLIENT;
1344
1345         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1346         if (this.killindicator) delete(this.killindicator);
1347
1348         WaypointSprite_PlayerGone(this);
1349
1350         bot_relinkplayerlist();
1351
1352         if (this.clientstatus) strunzone(this.clientstatus);
1353         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1354         if (this.personal) delete(this.personal);
1355
1356         this.playerid = 0;
1357         ReadyCount();
1358         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1359
1360         ONREMOVE(this);
1361 }
1362
1363 void ChatBubbleThink(entity this)
1364 {
1365         this.nextthink = time;
1366         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1367         {
1368                 if(this.owner) // but why can that ever be NULL?
1369                         this.owner.chatbubbleentity = NULL;
1370                 delete(this);
1371                 return;
1372         }
1373
1374         this.mdl = "";
1375
1376         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1377         {
1378                 if ( CS(this.owner).active_minigame )
1379                         this.mdl = "models/sprites/minigame_busy.iqm";
1380                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1381                         this.mdl = "models/misc/chatbubble.spr";
1382         }
1383
1384         if ( this.model != this.mdl )
1385                 _setmodel(this, this.mdl);
1386
1387 }
1388
1389 void UpdateChatBubble(entity this)
1390 {
1391         if (this.alpha < 0)
1392                 return;
1393         // spawn a chatbubble entity if needed
1394         if (!this.chatbubbleentity)
1395         {
1396                 this.chatbubbleentity = new(chatbubbleentity);
1397                 this.chatbubbleentity.owner = this;
1398                 this.chatbubbleentity.exteriormodeltoclient = this;
1399                 setthink(this.chatbubbleentity, ChatBubbleThink);
1400                 this.chatbubbleentity.nextthink = time;
1401                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1402                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1403                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1404                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1405                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1406                 //this.chatbubbleentity.model = "";
1407                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1408         }
1409 }
1410
1411
1412 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1413 // added to the model skins
1414 /*void UpdateColorModHack()
1415 {
1416         float c;
1417         c = this.clientcolors & 15;
1418         // LordHavoc: only bothering to support white, green, red, yellow, blue
1419              if (!teamplay) this.colormod = '0 0 0';
1420         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1421         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1422         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1423         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1424         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1425         else this.colormod = '1 1 1';
1426 }*/
1427
1428 void respawn(entity this)
1429 {
1430         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1431         {
1432                 this.solid = SOLID_NOT;
1433                 this.takedamage = DAMAGE_NO;
1434                 set_movetype(this, MOVETYPE_FLY);
1435                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1436                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1437                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1438                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1439                 if(autocvar_g_respawn_ghosts_maxtime)
1440                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1441         }
1442
1443         CopyBody(this, 1);
1444
1445         this.effects |= EF_NODRAW; // prevent another CopyBody
1446         PutClientInServer(this);
1447 }
1448
1449 void play_countdown(entity this, float finished, Sound samp)
1450 {
1451     TC(Sound, samp);
1452         if(IS_REAL_CLIENT(this))
1453                 if(floor(finished - time - frametime) != floor(finished - time))
1454                         if(finished - time < 6)
1455                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1456 }
1457
1458 void player_powerups(entity this)
1459 {
1460         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1461         int items_prev = this.items;
1462
1463         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1464                 this.modelflags |= MF_ROCKET;
1465         else
1466                 this.modelflags &= ~MF_ROCKET;
1467
1468         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1469
1470         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1471                 return;
1472
1473         Fire_ApplyDamage(this);
1474         Fire_ApplyEffect(this);
1475
1476         if (!g_instagib)
1477         {
1478                 if (this.items & ITEM_Strength.m_itemid)
1479                 {
1480                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1481                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1482                         if (time > this.strength_finished)
1483                         {
1484                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1485                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1486                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1487                         }
1488                 }
1489                 else
1490                 {
1491                         if (time < this.strength_finished)
1492                         {
1493                                 this.items = this.items | ITEM_Strength.m_itemid;
1494                                 if(!g_cts)
1495                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1496                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1497                         }
1498                 }
1499                 if (this.items & ITEM_Shield.m_itemid)
1500                 {
1501                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1502                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1503                         if (time > this.invincible_finished)
1504                         {
1505                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1506                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1507                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1508                         }
1509                 }
1510                 else
1511                 {
1512                         if (time < this.invincible_finished)
1513                         {
1514                                 this.items = this.items | ITEM_Shield.m_itemid;
1515                                 if(!g_cts)
1516                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1517                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1518                         }
1519                 }
1520                 if (this.items & IT_SUPERWEAPON)
1521                 {
1522                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1523                         {
1524                                 this.superweapons_finished = 0;
1525                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1526                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1527                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1528                         }
1529                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1530                         {
1531                                 // don't let them run out
1532                         }
1533                         else
1534                         {
1535                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1536                                 if (time > this.superweapons_finished)
1537                                 {
1538                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1539                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1540                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1541                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1542                                 }
1543                         }
1544                 }
1545                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1546                 {
1547                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1548                         {
1549                                 this.items = this.items | IT_SUPERWEAPON;
1550                                 if(!g_cts)
1551                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1552                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1553                         }
1554                         else
1555                         {
1556                                 this.superweapons_finished = 0;
1557                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1558                         }
1559                 }
1560                 else
1561                 {
1562                         this.superweapons_finished = 0;
1563                 }
1564         }
1565
1566         if(autocvar_g_nodepthtestplayers)
1567                 this.effects = this.effects | EF_NODEPTHTEST;
1568
1569         if(autocvar_g_fullbrightplayers)
1570                 this.effects = this.effects | EF_FULLBRIGHT;
1571
1572         if (time >= game_starttime)
1573         if (time < this.spawnshieldtime)
1574                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1575
1576         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1577 }
1578
1579 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1580 {
1581         if(current > stable)
1582                 return current;
1583         else if(current > stable - 0.25) // when close enough, "snap"
1584                 return stable;
1585         else
1586                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1587 }
1588
1589 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1590 {
1591         if(current < stable)
1592                 return current;
1593         else if(current < stable + 0.25) // when close enough, "snap"
1594                 return stable;
1595         else
1596                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1597 }
1598
1599 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1600 {
1601         if(current > rotstable)
1602         {
1603                 if(rotframetime > 0)
1604                 {
1605                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1606                         current = max(rotstable, current - rotlinear * rotframetime);
1607                 }
1608         }
1609         else if(current < regenstable)
1610         {
1611                 if(regenframetime > 0)
1612                 {
1613                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1614                         current = min(regenstable, current + regenlinear * regenframetime);
1615                 }
1616         }
1617
1618         if(current > limit)
1619                 current = limit;
1620
1621         return current;
1622 }
1623
1624 void player_regen(entity this)
1625 {
1626         float max_mod, regen_mod, rot_mod, limit_mod;
1627         max_mod = regen_mod = rot_mod = limit_mod = 1;
1628
1629         float regen_health = autocvar_g_balance_health_regen;
1630         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1631         float regen_health_rot = autocvar_g_balance_health_rot;
1632         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1633         float regen_health_stable = autocvar_g_balance_health_regenstable;
1634         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1635         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1636                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1637         max_mod = M_ARGV(1, float);
1638         regen_mod = M_ARGV(2, float);
1639         rot_mod = M_ARGV(3, float);
1640         limit_mod = M_ARGV(4, float);
1641         regen_health = M_ARGV(5, float);
1642         regen_health_linear = M_ARGV(6, float);
1643         regen_health_rot = M_ARGV(7, float);
1644         regen_health_rotlinear = M_ARGV(8, float);
1645         regen_health_stable = M_ARGV(9, float);
1646         regen_health_rotstable = M_ARGV(10, float);
1647
1648         if(!mutator_returnvalue)
1649         if(!STAT(FROZEN, this))
1650         {
1651                 float mina, maxa, limith, limita;
1652                 maxa = autocvar_g_balance_armor_rotstable;
1653                 mina = autocvar_g_balance_armor_regenstable;
1654                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1655                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1656
1657                 regen_health_rotstable = regen_health_rotstable * max_mod;
1658                 regen_health_stable = regen_health_stable * max_mod;
1659                 limith = limith * limit_mod;
1660                 limita = limita * limit_mod;
1661
1662                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1663                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1664         }
1665
1666         // if player rotted to death...  die!
1667         // check this outside above checks, as player may still be able to rot to death
1668         if(this.health < 1)
1669         {
1670                 if(this.vehicle)
1671                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1672                 if(this.event_damage)
1673                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1674         }
1675
1676         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1677         {
1678                 float minf, maxf, limitf;
1679
1680                 maxf = autocvar_g_balance_fuel_rotstable;
1681                 minf = autocvar_g_balance_fuel_regenstable;
1682                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1683
1684                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1685         }
1686         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1687         // TODO: Remove this hack when all code uses GivePlayerHealth and
1688         // GivePlayerArmor.
1689         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1690         {
1691                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1692         }
1693         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1694         {
1695                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1696         }
1697         // End hack.
1698 }
1699
1700 bool zoomstate_set;
1701 void SetZoomState(entity this, float newzoom)
1702 {
1703         if(newzoom != CS(this).zoomstate)
1704         {
1705                 CS(this).zoomstate = newzoom;
1706                 ClientData_Touch(this);
1707         }
1708         zoomstate_set = true;
1709 }
1710
1711 void GetPressedKeys(entity this)
1712 {
1713         MUTATOR_CALLHOOK(GetPressedKeys, this);
1714         int keys = STAT(PRESSED_KEYS, this);
1715         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1716         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1717         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1718         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1719
1720         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1721         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1722         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1723         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1724         CS(this).pressedkeys = keys; // store for other users
1725
1726         STAT(PRESSED_KEYS, this) = keys;
1727 }
1728
1729 /*
1730 ======================
1731 spectate mode routines
1732 ======================
1733 */
1734
1735 void SpectateCopy(entity this, entity spectatee)
1736 {
1737     TC(Client, this); TC(Client, spectatee);
1738
1739         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1740         PS(this) = PS(spectatee);
1741         this.armortype = spectatee.armortype;
1742         this.armorvalue = spectatee.armorvalue;
1743         this.ammo_cells = spectatee.ammo_cells;
1744         this.ammo_plasma = spectatee.ammo_plasma;
1745         this.ammo_shells = spectatee.ammo_shells;
1746         this.ammo_nails = spectatee.ammo_nails;
1747         this.ammo_rockets = spectatee.ammo_rockets;
1748         this.ammo_fuel = spectatee.ammo_fuel;
1749         this.clip_load = spectatee.clip_load;
1750         this.clip_size = spectatee.clip_size;
1751         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1752         this.health = spectatee.health;
1753         CS(this).impulse = 0;
1754         this.items = spectatee.items;
1755         this.last_pickup = spectatee.last_pickup;
1756         this.hit_time = spectatee.hit_time;
1757         this.strength_finished = spectatee.strength_finished;
1758         this.invincible_finished = spectatee.invincible_finished;
1759         this.superweapons_finished = spectatee.superweapons_finished;
1760         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1761         this.weapons = spectatee.weapons;
1762         this.vortex_charge = spectatee.vortex_charge;
1763         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1764         this.hagar_load = spectatee.hagar_load;
1765         this.arc_heat_percent = spectatee.arc_heat_percent;
1766         this.minelayer_mines = spectatee.minelayer_mines;
1767         this.punchangle = spectatee.punchangle;
1768         this.view_ofs = spectatee.view_ofs;
1769         this.velocity = spectatee.velocity;
1770         this.dmg_take = spectatee.dmg_take;
1771         this.dmg_save = spectatee.dmg_save;
1772         this.dmg_inflictor = spectatee.dmg_inflictor;
1773         this.v_angle = spectatee.v_angle;
1774         this.angles = spectatee.v_angle;
1775         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1776         this.revive_progress = spectatee.revive_progress;
1777         this.viewloc = spectatee.viewloc;
1778         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1779                 this.fixangle = true;
1780         setorigin(this, spectatee.origin);
1781         setsize(this, spectatee.mins, spectatee.maxs);
1782         SetZoomState(this, CS(spectatee).zoomstate);
1783
1784         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1785         {
1786                 .entity weaponentity = weaponentities[slot];
1787                 this.(weaponentity) = spectatee.(weaponentity);
1788         }
1789
1790         for(int slot = 0; slot < MAX_AXH; ++slot)
1791         {
1792                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1793         }
1794
1795     anticheat_spectatecopy(this, spectatee);
1796         this.hud = spectatee.hud;
1797         if(spectatee.vehicle)
1798     {
1799         this.angles = spectatee.v_angle;
1800
1801         //this.fixangle = false;
1802         //this.velocity = spectatee.vehicle.velocity;
1803         this.vehicle_health = spectatee.vehicle_health;
1804         this.vehicle_shield = spectatee.vehicle_shield;
1805         this.vehicle_energy = spectatee.vehicle_energy;
1806         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1807         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1808         this.vehicle_reload1 = spectatee.vehicle_reload1;
1809         this.vehicle_reload2 = spectatee.vehicle_reload2;
1810
1811         //msg_entity = this;
1812
1813        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1814             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1815            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1816            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1817
1818         //WriteByte (MSG_ONE, SVC_SETVIEW);
1819         //    WriteEntity(MSG_ONE, this);
1820         //makevectors(spectatee.v_angle);
1821         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1822     }
1823 }
1824
1825 bool SpectateUpdate(entity this)
1826 {
1827         if(!this.enemy)
1828                 return false;
1829
1830         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1831         {
1832                 SetSpectatee(this, NULL);
1833                 return false;
1834         }
1835
1836         SpectateCopy(this, this.enemy);
1837
1838         return true;
1839 }
1840
1841 bool SpectateSet(entity this)
1842 {
1843         if(!IS_PLAYER(this.enemy))
1844                 return false;
1845
1846         ClientData_Touch(this.enemy);
1847
1848         msg_entity = this;
1849         WriteByte(MSG_ONE, SVC_SETVIEW);
1850         WriteEntity(MSG_ONE, this.enemy);
1851         set_movetype(this, MOVETYPE_NONE);
1852         accuracy_resend(this);
1853
1854         if(!SpectateUpdate(this))
1855                 PutObserverInServer(this);
1856
1857         return true;
1858 }
1859
1860 void SetSpectatee_status(entity this, int spectatee_num)
1861 {
1862         int oldspectatee_status = CS(this).spectatee_status;
1863         CS(this).spectatee_status = spectatee_num;
1864
1865         if (CS(this).spectatee_status != oldspectatee_status)
1866         {
1867                 ClientData_Touch(this);
1868                 if (g_race || g_cts) race_InitSpectator();
1869         }
1870 }
1871
1872 void SetSpectatee(entity this, entity spectatee)
1873 {
1874         if(IS_BOT_CLIENT(this))
1875                 return; // bots abuse .enemy, this code is useless to them
1876
1877         entity old_spectatee = this.enemy;
1878
1879         this.enemy = spectatee;
1880
1881         // WEAPONTODO
1882         // these are required to fix the spectator bug with arc
1883         if(old_spectatee)
1884         {
1885                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1886                 {
1887                         .entity weaponentity = weaponentities[slot];
1888                         if(old_spectatee.(weaponentity).arc_beam)
1889                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1890                 }
1891         }
1892         if(this.enemy)
1893         {
1894                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1895                 {
1896                         .entity weaponentity = weaponentities[slot];
1897                         if(this.enemy.(weaponentity).arc_beam)
1898                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1899                 }
1900         }
1901
1902         if (this.enemy)
1903                 SetSpectatee_status(this, etof(this.enemy));
1904
1905         // needed to update spectator list
1906         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1907 }
1908
1909 bool Spectate(entity this, entity pl)
1910 {
1911         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1912                 return false;
1913         pl = M_ARGV(1, entity);
1914
1915         SetSpectatee(this, pl);
1916         return SpectateSet(this);
1917 }
1918
1919 bool SpectateNext(entity this)
1920 {
1921         entity ent = find(this.enemy, classname, STR_PLAYER);
1922
1923         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1924                 ent = M_ARGV(1, entity);
1925         else if (!ent)
1926                 ent = find(ent, classname, STR_PLAYER);
1927
1928         if(ent) { SetSpectatee(this, ent); }
1929
1930         return SpectateSet(this);
1931 }
1932
1933 bool SpectatePrev(entity this)
1934 {
1935         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1936         entity ent = findchain(classname, STR_PLAYER);
1937         if (!ent) // no player
1938                 return false;
1939
1940         entity first = ent;
1941         // skip players until current spectated player
1942         if(this.enemy)
1943         while(ent && ent != this.enemy)
1944                 ent = ent.chain;
1945
1946         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1947         {
1948                 case MUT_SPECPREV_FOUND:
1949                     ent = M_ARGV(1, entity);
1950                     break;
1951                 case MUT_SPECPREV_RETURN:
1952                     return true;
1953                 case MUT_SPECPREV_CONTINUE:
1954                 default:
1955                 {
1956                         if(ent.chain)
1957                                 ent = ent.chain;
1958                         else
1959                                 ent = first;
1960                         break;
1961                 }
1962         }
1963
1964         SetSpectatee(this, ent);
1965         return SpectateSet(this);
1966 }
1967
1968 /*
1969 =============
1970 ShowRespawnCountdown()
1971
1972 Update a respawn countdown display.
1973 =============
1974 */
1975 void ShowRespawnCountdown(entity this)
1976 {
1977         float number;
1978         if(!IS_DEAD(this)) // just respawned?
1979                 return;
1980         else
1981         {
1982                 number = ceil(this.respawn_time - time);
1983                 if(number <= 0)
1984                         return;
1985                 if(number <= this.respawn_countdown)
1986                 {
1987                         this.respawn_countdown = number - 1;
1988                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1989                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1990                 }
1991         }
1992 }
1993
1994 .bool team_selected;
1995 bool ShowTeamSelection(entity this)
1996 {
1997         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1998                 return false;
1999         stuffcmd(this, "menu_showteamselect\n");
2000         return true;
2001 }
2002 void Join(entity this)
2003 {
2004         TRANSMUTE(Player, this);
2005
2006         if(!this.team_selected)
2007         if(autocvar_g_campaign || autocvar_g_balance_teams)
2008                 JoinBestTeam(this, true);
2009
2010         if(autocvar_g_campaign)
2011                 campaign_bots_may_start = true;
2012
2013         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2014
2015         PutClientInServer(this);
2016
2017         if(IS_PLAYER(this))
2018         if(teamplay && this.team != -1)
2019                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2020         else
2021                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2022         this.team_selected = false;
2023 }
2024
2025 /**
2026  * Determines whether the player is allowed to join. This depends on cvar
2027  * g_maxplayers, if it isn't used this function always return true, otherwise
2028  * it checks whether the number of currently playing players exceeds g_maxplayers.
2029  * @return int number of free slots for players, 0 if none
2030  */
2031 int nJoinAllowed(entity this, entity ignore)
2032 {
2033         if(!ignore)
2034         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2035         // so report 0 free slots if restricted
2036         {
2037                 if(autocvar_g_forced_team_otherwise == "spectate")
2038                         return 0;
2039                 if(autocvar_g_forced_team_otherwise == "spectator")
2040                         return 0;
2041         }
2042
2043         if(this && this.team_forced < 0)
2044                 return 0; // forced spectators can never join
2045
2046         // TODO simplify this
2047         int totalClients = 0;
2048         int currentlyPlaying = 0;
2049         FOREACH_CLIENT(true, {
2050                 if(it != ignore)
2051                         ++totalClients;
2052                 if(IS_REAL_CLIENT(it))
2053                 if(IS_PLAYER(it) || it.caplayer)
2054                         ++currentlyPlaying;
2055         });
2056
2057         float free_slots = 0;
2058         if (!autocvar_g_maxplayers)
2059                 free_slots = maxclients - totalClients;
2060         else if(currentlyPlaying < autocvar_g_maxplayers)
2061                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2062
2063         static float join_prevent_msg_time = 0;
2064         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2065         {
2066                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2067                 join_prevent_msg_time = time + 3;
2068         }
2069
2070         return free_slots;
2071 }
2072
2073 /**
2074  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2075  * g_maxplayers_spectator_blocktime seconds
2076  */
2077 void checkSpectatorBlock(entity this)
2078 {
2079         if(IS_SPEC(this) || IS_OBSERVER(this))
2080         if(!this.caplayer)
2081         if(IS_REAL_CLIENT(this))
2082         {
2083                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2084                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2085                         dropclient(this);
2086                 }
2087         }
2088 }
2089
2090 void PrintWelcomeMessage(entity this)
2091 {
2092         if(CS(this).motd_actived_time == 0)
2093         {
2094                 if (autocvar_g_campaign) {
2095                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2096                                 CS(this).motd_actived_time = time;
2097                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2098                         }
2099                 } else {
2100                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2101                                 CS(this).motd_actived_time = time;
2102                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2103                         }
2104                 }
2105         }
2106         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2107         {
2108                 if (autocvar_g_campaign) {
2109                         if (PHYS_INPUT_BUTTON_INFO(this))
2110                                 CS(this).motd_actived_time = time;
2111                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2112                                 CS(this).motd_actived_time = 0;
2113                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2114                         }
2115                 } else {
2116                         if (PHYS_INPUT_BUTTON_INFO(this))
2117                                 CS(this).motd_actived_time = time;
2118                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2119                                 CS(this).motd_actived_time = 0;
2120                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2121                         }
2122                 }
2123         }
2124         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2125         {
2126                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2127                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2128                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2129                 {
2130                         // instanctly hide MOTD
2131                         CS(this).motd_actived_time = 0;
2132                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2133                 }
2134         }
2135 }
2136
2137 bool joinAllowed(entity this)
2138 {
2139         if (CS(this).version_mismatch) return false;
2140         if (!nJoinAllowed(this, this)) return false;
2141         if (teamplay && lockteams) return false;
2142         if (ShowTeamSelection(this)) return false;
2143         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2144         return true;
2145 }
2146
2147 .int items_added;
2148 bool PlayerThink(entity this)
2149 {
2150         if (game_stopped || intermission_running) {
2151                 this.modelflags &= ~MF_ROCKET;
2152                 if(intermission_running)
2153                         IntermissionThink(this);
2154                 return false;
2155         }
2156
2157         if (timeout_status == TIMEOUT_ACTIVE) {
2158         // don't allow the player to turn around while game is paused
2159                 // FIXME turn this into CSQC stuff
2160                 this.v_angle = this.lastV_angle;
2161                 this.angles = this.lastV_angle;
2162                 this.fixangle = true;
2163         }
2164
2165         if (frametime) player_powerups(this);
2166
2167         if (IS_DEAD(this)) {
2168                 if (this.personal && g_race_qualifying) {
2169                         if (time > this.respawn_time) {
2170                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2171                                 respawn(this);
2172                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2173                         }
2174                 } else {
2175                         if (frametime) player_anim(this);
2176
2177                         if (this.respawn_flags & RESPAWN_DENY)
2178                         {
2179                                 STAT(RESPAWN_TIME, this) = 0;
2180                                 return false;
2181                         }
2182
2183                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2184
2185                         switch(this.deadflag)
2186                         {
2187                                 case DEAD_DYING:
2188                                 {
2189                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2190                                                 this.deadflag = DEAD_RESPAWNING;
2191                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2192                                                 this.deadflag = DEAD_DEAD;
2193                                         break;
2194                                 }
2195                                 case DEAD_DEAD:
2196                                 {
2197                                         if (button_pressed)
2198                                                 this.deadflag = DEAD_RESPAWNABLE;
2199                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2200                                                 this.deadflag = DEAD_RESPAWNING;
2201                                         break;
2202                                 }
2203                                 case DEAD_RESPAWNABLE:
2204                                 {
2205                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2206                                                 this.deadflag = DEAD_RESPAWNING;
2207                                         break;
2208                                 }
2209                                 case DEAD_RESPAWNING:
2210                                 {
2211                                         if (time > this.respawn_time)
2212                                         {
2213                                                 this.respawn_time = time + 1; // only retry once a second
2214                                                 this.respawn_time_max = this.respawn_time;
2215                                                 respawn(this);
2216                                         }
2217                                         break;
2218                                 }
2219                         }
2220
2221                         ShowRespawnCountdown(this);
2222
2223                         if (this.respawn_flags & RESPAWN_SILENT)
2224                                 STAT(RESPAWN_TIME, this) = 0;
2225                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2226                         {
2227                                 if (time < this.respawn_time)
2228                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2229                                 else if (this.deadflag != DEAD_RESPAWNING)
2230                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2231                         }
2232                         else
2233                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2234                 }
2235
2236                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2237                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2238                         STAT(RESPAWN_TIME, this) *= -1;
2239
2240                 return false;
2241         }
2242
2243         bool have_hook = false;
2244         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2245         {
2246                 .entity weaponentity = weaponentities[slot];
2247                 if(this.(weaponentity).hook.state)
2248                 {
2249                         have_hook = true;
2250                         break;
2251                 }
2252         }
2253         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2254         if (have_hook) {
2255                 do_crouch = false;
2256         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2257                 do_crouch = false;
2258         } else if (this.vehicle) {
2259                 do_crouch = false;
2260         } else if (STAT(FROZEN, this)) {
2261                 do_crouch = false;
2262     }
2263
2264         if (do_crouch) {
2265                 if (!this.crouch) {
2266                         this.crouch = true;
2267                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2268                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2269                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2270                 }
2271         } else if (this.crouch) {
2272         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2273         if (!trace_startsolid) {
2274             this.crouch = false;
2275             this.view_ofs = STAT(PL_VIEW_OFS, this);
2276             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2277         }
2278         }
2279
2280         FixPlayermodel(this);
2281
2282         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2283         //if(frametime)
2284         {
2285                 this.items &= ~this.items_added;
2286
2287                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2288                 {
2289                         .entity weaponentity = weaponentities[slot];
2290                         W_WeaponFrame(this, weaponentity);
2291
2292                         if(slot == 0)
2293                         {
2294                                 this.clip_load = this.(weaponentity).clip_load;
2295                                 this.clip_size = this.(weaponentity).clip_size;
2296                         }
2297                 }
2298
2299                 this.items_added = 0;
2300                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2301             this.items_added |= IT_FUEL;
2302
2303                 this.items |= this.items_added;
2304         }
2305
2306         player_regen(this);
2307
2308         // WEAPONTODO: Add a weapon request for this
2309         // rot vortex charge to the charge limit
2310         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2311         {
2312                 .entity weaponentity = weaponentities[slot];
2313                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2314                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2315         }
2316
2317         if (frametime) player_anim(this);
2318
2319         // secret status
2320         secrets_setstatus(this);
2321
2322         // monsters status
2323         monsters_setstatus(this);
2324
2325         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2326
2327         return true;
2328 }
2329
2330 void ObserverThink(entity this)
2331 {
2332         if ( CS(this).impulse )
2333         {
2334                 MinigameImpulse(this, CS(this).impulse);
2335                 CS(this).impulse = 0;
2336         }
2337
2338         if (this.flags & FL_JUMPRELEASED) {
2339                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2340                         this.flags &= ~FL_JUMPRELEASED;
2341                         this.flags |= FL_SPAWNING;
2342                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2343                         this.flags &= ~FL_JUMPRELEASED;
2344                         if(SpectateNext(this)) {
2345                                 TRANSMUTE(Spectator, this);
2346                         }
2347                 } else {
2348                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2349                         set_movetype(this, preferred_movetype);
2350                 }
2351         } else {
2352                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2353                         this.flags |= FL_JUMPRELEASED;
2354                         if(this.flags & FL_SPAWNING)
2355                         {
2356                                 this.flags &= ~FL_SPAWNING;
2357                                 Join(this);
2358                                 return;
2359                         }
2360                 }
2361         }
2362 }
2363
2364 void SpectatorThink(entity this)
2365 {
2366         if ( CS(this).impulse )
2367         {
2368                 if(MinigameImpulse(this, CS(this).impulse))
2369                         CS(this).impulse = 0;
2370
2371                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2372                 {
2373                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2374                         CS(this).impulse = 0;
2375                         return;
2376                 }
2377         }
2378
2379         if (this.flags & FL_JUMPRELEASED) {
2380                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2381                         this.flags &= ~FL_JUMPRELEASED;
2382                         this.flags |= FL_SPAWNING;
2383                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2384                         this.flags &= ~FL_JUMPRELEASED;
2385                         if(SpectateNext(this)) {
2386                                 TRANSMUTE(Spectator, this);
2387                         } else {
2388                                 TRANSMUTE(Observer, this);
2389                                 PutClientInServer(this);
2390                         }
2391                         CS(this).impulse = 0;
2392                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2393                         this.flags &= ~FL_JUMPRELEASED;
2394                         if(SpectatePrev(this)) {
2395                                 TRANSMUTE(Spectator, this);
2396                         } else {
2397                                 TRANSMUTE(Observer, this);
2398                                 PutClientInServer(this);
2399                         }
2400                         CS(this).impulse = 0;
2401                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2402                         this.flags &= ~FL_JUMPRELEASED;
2403                         TRANSMUTE(Observer, this);
2404                         PutClientInServer(this);
2405                 } else {
2406                         if(!SpectateUpdate(this))
2407                                 PutObserverInServer(this);
2408                 }
2409         } else {
2410                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2411                         this.flags |= FL_JUMPRELEASED;
2412                         if(this.flags & FL_SPAWNING)
2413                         {
2414                                 this.flags &= ~FL_SPAWNING;
2415                                 Join(this);
2416                                 return;
2417                         }
2418                 }
2419                 if(!SpectateUpdate(this))
2420                         PutObserverInServer(this);
2421         }
2422
2423         this.flags |= FL_CLIENT | FL_NOTARGET;
2424 }
2425
2426 void vehicles_enter (entity pl, entity veh);
2427 void PlayerUseKey(entity this)
2428 {
2429         if (!IS_PLAYER(this))
2430                 return;
2431
2432         if(this.vehicle)
2433         {
2434                 if(!game_stopped)
2435                 {
2436                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2437                         return;
2438                 }
2439         }
2440         else if(autocvar_g_vehicles_enter)
2441         {
2442                 if(!STAT(FROZEN, this))
2443                 if(!IS_DEAD(this))
2444                 if(!game_stopped)
2445                 {
2446                         entity head, closest_target = NULL;
2447                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2448
2449                         while(head) // find the closest acceptable target to enter
2450                         {
2451                                 if(IS_VEHICLE(head))
2452                                 if(!IS_DEAD(head))
2453                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2454                                 if(head.takedamage != DAMAGE_NO)
2455                                 {
2456                                         if(closest_target)
2457                                         {
2458                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2459                                                 { closest_target = head; }
2460                                         }
2461                                         else { closest_target = head; }
2462                                 }
2463
2464                                 head = head.chain;
2465                         }
2466
2467                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2468                 }
2469         }
2470
2471         // a use key was pressed; call handlers
2472         MUTATOR_CALLHOOK(PlayerUseKey, this);
2473 }
2474
2475
2476 /*
2477 =============
2478 PlayerPreThink
2479
2480 Called every frame for each client before the physics are run
2481 =============
2482 */
2483 .float last_vehiclecheck;
2484 void PlayerPreThink (entity this)
2485 {
2486         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2487         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2488
2489         WarpZone_PlayerPhysics_FixVAngle(this);
2490
2491         if (frametime) {
2492                 // physics frames: update anticheat stuff
2493                 anticheat_prethink(this);
2494         }
2495
2496         if (blockSpectators && frametime) {
2497                 // WORKAROUND: only use dropclient in server frames (frametime set).
2498                 // Never use it in cl_movement frames (frametime zero).
2499                 checkSpectatorBlock(this);
2500         }
2501
2502         zoomstate_set = false;
2503
2504         // Check for nameless players
2505         if (this.netname == "" || this.netname != CS(this).netname_previous)
2506         {
2507                 bool assume_unchanged = (CS(this).netname_previous == "");
2508                 if (isInvisibleString(this.netname))
2509                 {
2510                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2511                         assume_unchanged = false;
2512                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2513                 }
2514                 if (!assume_unchanged && autocvar_sv_eventlog)
2515                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2516                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2517                 CS(this).netname_previous = strzone(this.netname);
2518         }
2519
2520         // version nagging
2521         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2522         CS(this).version_nagtime = 0;
2523         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2524             // git client
2525         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2526             // git server
2527             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2528         } else {
2529             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2530             if (r < 0) { // old client
2531                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2532             } else if (r > 0) { // old server
2533                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2534             }
2535         }
2536     }
2537
2538         // GOD MODE info
2539         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2540         {
2541                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2542                 this.max_armorvalue = 0;
2543         }
2544
2545         if(IS_PLAYER(this))
2546         {
2547                 if (STAT(FROZEN, this) == 2)
2548                 {
2549                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2550                         this.health = max(1, this.revive_progress * start_health);
2551                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2552
2553                         if (this.revive_progress >= 1)
2554                                 Unfreeze(this);
2555                 }
2556                 else if (STAT(FROZEN, this) == 3)
2557                 {
2558                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2559                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2560
2561                         if (this.health < 1)
2562                         {
2563                                 if (this.vehicle)
2564                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2565                                 if(this.event_damage)
2566                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2567                         }
2568                         else if (this.revive_progress <= 0)
2569                                 Unfreeze(this);
2570                 }
2571         }
2572
2573         MUTATOR_CALLHOOK(PlayerPreThink, this);
2574
2575         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2576         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2577         {
2578                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2579                 {
2580                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2581                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2582                         {
2583                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2584                         }
2585                         else if(!it.owner)
2586                         {
2587                                 if(!it.team || SAME_TEAM(this, it))
2588                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2589                                 else if(autocvar_g_vehicles_steal)
2590                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2591                         }
2592                 });
2593
2594                 this.last_vehiclecheck = time + 1;
2595         }
2596
2597         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2598         {
2599                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2600                         PlayerUseKey(this);
2601                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2602         }
2603
2604         if (IS_REAL_CLIENT(this))
2605                 PrintWelcomeMessage(this);
2606
2607         if (IS_PLAYER(this)) {
2608                 if(!PlayerThink(this))
2609                         return;
2610         }
2611         else if (game_stopped || intermission_running) {
2612                 if(intermission_running)
2613                         IntermissionThink(this);
2614                 return;
2615         }
2616         else if (IS_OBSERVER(this)) {
2617                 ObserverThink(this);
2618         }
2619         else if (IS_SPEC(this)) {
2620                 SpectatorThink(this);
2621         }
2622
2623         // WEAPONTODO: Add weapon request for this
2624         if (!zoomstate_set) {
2625                 bool wep_zoomed = false;
2626                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2627                 {
2628                         .entity weaponentity = weaponentities[slot];
2629                         Weapon thiswep = this.(weaponentity).m_weapon;
2630                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2631                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2632                 }
2633                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2634     }
2635
2636         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2637         {
2638                 CS(this).teamkill_soundtime = 0;
2639
2640                 entity e = CS(this).teamkill_soundsource;
2641                 entity oldpusher = e.pusher;
2642                 e.pusher = this;
2643                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2644                 e.pusher = oldpusher;
2645         }
2646
2647         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2648                 CS(this).taunt_soundtime = 0;
2649                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2650         }
2651
2652         target_voicescript_next(this);
2653
2654         // WEAPONTODO: Move into weaponsystem somehow
2655         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2656         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2657         {
2658                 .entity weaponentity = weaponentities[slot];
2659                 if(this.(weaponentity).m_weapon == WEP_Null)
2660                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2661         }
2662 }
2663
2664 void DrownPlayer(entity this)
2665 {
2666         if(IS_DEAD(this))
2667                 return;
2668
2669         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2670         {
2671                 if(this.air_finished < time)
2672                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2673                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2674         }
2675         else if (this.air_finished < time)
2676         {       // drown!
2677                 if (this.pain_finished < time)
2678                 {
2679                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2680                         this.pain_finished = time + 0.5;
2681                 }
2682         }
2683 }
2684
2685 .bool move_qcphysics;
2686
2687 void Player_Physics(entity this)
2688 {
2689         set_movetype(this, this.move_movetype);
2690
2691         if(!this.move_qcphysics)
2692                 return;
2693
2694         if(!frametime && !CS(this).pm_frametime)
2695                 return;
2696
2697         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2698
2699         CS(this).pm_frametime = 0;
2700 }
2701
2702 /*
2703 =============
2704 PlayerPostThink
2705
2706 Called every frame for each client after the physics are run
2707 =============
2708 */
2709 void PlayerPostThink (entity this)
2710 {
2711         Player_Physics(this);
2712
2713         if (sv_maxidle > 0)
2714         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2715         if (IS_REAL_CLIENT(this))
2716         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2717         {
2718                 int totalClients = 0;
2719                 if(sv_maxidle_slots > 0)
2720                 {
2721                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2722                         {
2723                                 ++totalClients;
2724                         });
2725                 }
2726
2727                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2728                 { /* do nothing */ }
2729                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2730                 {
2731                         if (CS(this).idlekick_lasttimeleft)
2732                         {
2733                                 CS(this).idlekick_lasttimeleft = 0;
2734                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2735                         }
2736                 }
2737                 else
2738                 {
2739                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2740                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2741                                 if (!CS(this).idlekick_lasttimeleft)
2742                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2743                         }
2744                         if (timeleft <= 0) {
2745                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2746                                 dropclient(this);
2747                                 return;
2748                         }
2749                         else if (timeleft <= 10) {
2750                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2751                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2752                 }
2753                                 CS(this).idlekick_lasttimeleft = timeleft;
2754                         }
2755                 }
2756         }
2757
2758         CheatFrame(this);
2759
2760         if (game_stopped)
2761         {
2762                 this.solid = SOLID_NOT;
2763                 this.takedamage = DAMAGE_NO;
2764                 set_movetype(this, MOVETYPE_NONE);
2765         }
2766
2767         if (IS_PLAYER(this)) {
2768                 DrownPlayer(this);
2769                 UpdateChatBubble(this);
2770                 if (CS(this).impulse) ImpulseCommands(this);
2771                 if (game_stopped)
2772                 {
2773                         CSQCMODEL_AUTOUPDATE(this);
2774                         return;
2775                 }
2776                 GetPressedKeys(this);
2777         }
2778
2779         if (this.waypointsprite_attachedforcarrier) {
2780             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2781                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2782     }
2783
2784         playerdemo_write(this);
2785
2786         CSQCMODEL_AUTOUPDATE(this);
2787 }
2788
2789 // hack to copy the button fields from the client entity to the Client State
2790 void PM_UpdateButtons(entity this, entity store)
2791 {
2792         if(this.impulse)
2793                 store.impulse = this.impulse;
2794         this.impulse = 0;
2795
2796         store.button0 = this.button0;
2797         store.button2 = this.button2;
2798         store.button3 = this.button3;
2799         store.button4 = this.button4;
2800         store.button5 = this.button5;
2801         store.button6 = this.button6;
2802         store.button7 = this.button7;
2803         store.button8 = this.button8;
2804         store.button9 = this.button9;
2805         store.button10 = this.button10;
2806         store.button11 = this.button11;
2807         store.button12 = this.button12;
2808         store.button13 = this.button13;
2809         store.button14 = this.button14;
2810         store.button15 = this.button15;
2811         store.button16 = this.button16;
2812         store.buttonuse = this.buttonuse;
2813         store.buttonchat = this.buttonchat;
2814
2815         store.cursor_active = this.cursor_active;
2816         store.cursor_screen = this.cursor_screen;
2817         store.cursor_trace_start = this.cursor_trace_start;
2818         store.cursor_trace_endpos = this.cursor_trace_endpos;
2819         store.cursor_trace_ent = this.cursor_trace_ent;
2820
2821         store.ping = this.ping;
2822         store.ping_packetloss = this.ping_packetloss;
2823         store.ping_movementloss = this.ping_movementloss;
2824
2825         store.v_angle = this.v_angle;
2826         store.movement = this.movement;
2827 }