qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!game_stopped)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         this.killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357
 358         for(int slot = 0; slot < MAX_AXH; ++slot)
 359         {
 360                 entity axh = this.(AuxiliaryXhair[slot]);
 361                 this.(AuxiliaryXhair[slot]) = NULL;
 362
 363                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 364                         delete(axh);
 365         }
 366 }
 367
 368 int player_getspecies(entity this)
 369 {
 370         get_model_parameters(this.model, this.skin);
 371         int s = get_model_parameters_species;
 372         get_model_parameters(string_null, 0);
 373         if (s < 0) return SPECIES_HUMAN;
 374         return s;
 375 }
 376
 377 .float model_randomizer;
 378 void FixPlayermodel(entity player)
 379 {
 380         string defaultmodel = "";
 381         int defaultskin = 0;
 382         if(autocvar_sv_defaultcharacter)
 383         {
 384                 if(teamplay)
 385                 {
 386                         string s = Static_Team_ColorName_Lower(player.team);
 387                         if (s != "neutral")
 388                         {
 389                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 390                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 391                         }
 392                 }
 393
 394                 if(defaultmodel == "")
 395                 {
 396                         defaultmodel = autocvar_sv_defaultplayermodel;
 397                         defaultskin = autocvar_sv_defaultplayerskin;
 398                 }
 399
 400                 int n = tokenize_console(defaultmodel);
 401                 if(n > 0)
 402                 {
 403                         defaultmodel = argv(floor(n * player.model_randomizer));
 404                         // However, do NOT randomize if the player-selected model is in the list.
 405                         for (int i = 0; i < n; ++i)
 406                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 407                                         defaultmodel = argv(i);
 408                 }
 409
 410                 int i = strstrofs(defaultmodel, ":", 0);
 411                 if(i >= 0)
 412                 {
 413                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 414                         defaultmodel = substring(defaultmodel, 0, i);
 415                 }
 416         }
 417         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 418         {
 419                 if(teamplay)
 420                 {
 421                         string s = Static_Team_ColorName_Lower(player.team);
 422                         if (s != "neutral")
 423                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 424                 }
 425
 426                 if(!defaultskin)
 427                         defaultskin = autocvar_sv_defaultplayerskin;
 428         }
 429
 430         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 431         defaultmodel = M_ARGV(0, string);
 432         defaultskin = M_ARGV(1, int);
 433
 434         bool chmdl = false;
 435         int oldskin;
 436         if(defaultmodel != "")
 437         {
 438                 if (defaultmodel != player.model)
 439                 {
 440                         vector m1 = player.mins;
 441                         vector m2 = player.maxs;
 442                         setplayermodel (player, defaultmodel);
 443                         setsize (player, m1, m2);
 444                         chmdl = true;
 445                 }
 446
 447                 oldskin = player.skin;
 448                 player.skin = defaultskin;
 449         } else {
 450                 if (player.playermodel != player.model || player.playermodel == "")
 451                 {
 452                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 453                         vector m1 = player.mins;
 454                         vector m2 = player.maxs;
 455                         setplayermodel (player, player.playermodel);
 456                         setsize (player, m1, m2);
 457                         chmdl = true;
 458                 }
 459
 460                 if(!autocvar_sv_defaultcharacterskin)
 461                 {
 462                         oldskin = player.skin;
 463                         player.skin = stof(player.playerskin);
 464                 }
 465                 else
 466                 {
 467                         oldskin = player.skin;
 468                         player.skin = defaultskin;
 469                 }
 470         }
 471
 472         if(chmdl || oldskin != player.skin) // model or skin has changed
 473         {
 474                 player.species = player_getspecies(player); // update species
 475                 if(!autocvar_g_debug_globalsounds)
 476                         UpdatePlayerSounds(player); // update skin sounds
 477         }
 478
 479         if(!teamplay)
 480                 if(strlen(autocvar_sv_defaultplayercolors))
 481                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 482                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 483 }
 484
 485
 486 /** Called when a client spawns in the server */
 487 void PutClientInServer(entity this)
 488 {
 489         if (IS_BOT_CLIENT(this)) {
 490                 TRANSMUTE(Player, this);
 491         } else if (IS_REAL_CLIENT(this)) {
 492                 msg_entity = this;
 493                 WriteByte(MSG_ONE, SVC_SETVIEW);
 494                 WriteEntity(MSG_ONE, this);
 495         }
 496         if (game_stopped)
 497                 TRANSMUTE(Observer, this);
 498
 499         SetSpectatee(this, NULL);
 500
 501         // reset player keys
 502         this.itemkeys = 0;
 503
 504         MUTATOR_CALLHOOK(PutClientInServer, this);
 505
 506         if (IS_OBSERVER(this)) {
 507                 PutObserverInServer(this);
 508         } else if (IS_PLAYER(this)) {
 509                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 510
 511                 PlayerState_attach(this);
 512                 accuracy_resend(this);
 513
 514                 if (this.team < 0)
 515                         JoinBestTeam(this, false, true);
 516
 517                 entity spot = SelectSpawnPoint(this, false);
 518                 if (!spot) {
 519                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 520                         return; // spawn failed
 521                 }
 522
 523                 TRANSMUTE(Player, this);
 524
 525                 this.wasplayer = true;
 526                 this.iscreature = true;
 527                 this.teleportable = TELEPORT_NORMAL;
 528                 if(!this.damagedbycontents)
 529                         IL_PUSH(g_damagedbycontents, this);
 530                 this.damagedbycontents = true;
 531                 set_movetype(this, MOVETYPE_WALK);
 532                 this.solid = SOLID_SLIDEBOX;
 533                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 534                 if (autocvar_g_playerclip_collisions)
 535                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 536                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 537                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 538                 this.frags = FRAGS_PLAYER;
 539                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 540                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 541                 if (autocvar__notarget)
 542                         this.flags |= FL_NOTARGET;
 543                 this.takedamage = DAMAGE_AIM;
 544                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 545                 this.dmg = 2; // WTF
 546
 547                 if (warmup_stage) {
 548                         this.ammo_shells = warmup_start_ammo_shells;
 549                         this.ammo_nails = warmup_start_ammo_nails;
 550                         this.ammo_rockets = warmup_start_ammo_rockets;
 551                         this.ammo_cells = warmup_start_ammo_cells;
 552                         this.ammo_plasma = warmup_start_ammo_plasma;
 553                         this.ammo_fuel = warmup_start_ammo_fuel;
 554                         this.health = warmup_start_health;
 555                         this.armorvalue = warmup_start_armorvalue;
 556                         this.weapons = WARMUP_START_WEAPONS;
 557                 } else {
 558                         this.ammo_shells = start_ammo_shells;
 559                         this.ammo_nails = start_ammo_nails;
 560                         this.ammo_rockets = start_ammo_rockets;
 561                         this.ammo_cells = start_ammo_cells;
 562                         this.ammo_plasma = start_ammo_plasma;
 563                         this.ammo_fuel = start_ammo_fuel;
 564                         this.health = start_health;
 565                         this.armorvalue = start_armorvalue;
 566                         this.weapons = start_weapons;
 567                 }
 568                 SetSpectatee_status(this, 0);
 569
 570                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 571
 572                 this.items = start_items;
 573
 574                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 575                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 576                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 577                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 578                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 579                 // extend the pause of rotting if client was reset at the beginning of the countdown
 580                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 581                         float f = game_starttime - time;
 582                         this.spawnshieldtime += f;
 583                         this.pauserotarmor_finished += f;
 584                         this.pauserothealth_finished += f;
 585                         this.pauseregen_finished += f;
 586                 }
 587                 this.damageforcescale = 2;
 588                 this.death_time = 0;
 589                 this.respawn_flags = 0;
 590                 this.respawn_time = 0;
 591                 this.stat_respawn_time = 0;
 592                 this.scale = autocvar_sv_player_scale;
 593                 this.fade_time = 0;
 594                 this.pain_frame = 0;
 595                 this.pain_finished = 0;
 596                 this.pushltime = 0;
 597                 setthink(this, func_null); // players have no think function
 598                 this.nextthink = 0;
 599                 this.dmg_team = 0;
 600                 this.ballistics_density = autocvar_g_ballistics_density_player;
 601
 602                 this.deadflag = DEAD_NO;
 603
 604                 this.angles = spot.angles;
 605                 this.angles_z = 0; // never spawn tilted even if the spot says to
 606                 if (IS_BOT_CLIENT(this))
 607                         this.v_angle = this.angles;
 608                 this.fixangle = true; // turn this way immediately
 609                 this.oldvelocity = this.velocity = '0 0 0';
 610                 this.avelocity = '0 0 0';
 611                 this.punchangle = '0 0 0';
 612                 this.punchvector = '0 0 0';
 613
 614                 this.strength_finished = 0;
 615                 this.invincible_finished = 0;
 616                 this.fire_endtime = -1;
 617                 this.revive_progress = 0;
 618                 this.revival_time = 0;
 619                 this.air_finished = time + 12;
 620
 621                 entity spawnevent = new_pure(spawnevent);
 622                 spawnevent.owner = this;
 623                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 624
 625                 // Cut off any still running player sounds.
 626                 stopsound(this, CH_PLAYER_SINGLE);
 627
 628                 this.model = "";
 629                 FixPlayermodel(this);
 630                 this.drawonlytoclient = NULL;
 631
 632                 this.viewloc = NULL;
 633
 634                 this.crouch = false;
 635                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 636                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 637                 this.spawnorigin = spot.origin;
 638                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 639                 // don't reset back to last position, even if new position is stuck in solid
 640                 this.oldorigin = this.origin;
 641                 this.prevorigin = this.origin;
 642                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 643                 if(this.conveyor)
 644                         IL_REMOVE(g_conveyed, this);
 645                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 646                 this.hud = HUD_NORMAL;
 647
 648                 this.event_damage = PlayerDamage;
 649
 650                 if(!this.bot_attack)
 651                         IL_PUSH(g_bot_targets, this);
 652                 this.bot_attack = true;
 653                 this.monster_attack = true;
 654
 655                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 656
 657                 if (this.killcount == FRAGS_SPECTATOR) {
 658                         PlayerScore_Clear(this);
 659                         this.killcount = 0;
 660                 }
 661
 662                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 663                 {
 664                         .entity weaponentity = weaponentities[slot];
 665                         entity oldwep = this.(weaponentity);
 666                         CL_SpawnWeaponentity(this, weaponentity);
 667                         if(oldwep && oldwep.owner == this)
 668                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 669                 }
 670                 this.alpha = default_player_alpha;
 671                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 672                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 673
 674                 this.speedrunning = false;
 675
 676                 target_voicescript_clear(this);
 677
 678                 // reset fields the weapons may use
 679                 FOREACH(Weapons, true, LAMBDA(
 680                         it.wr_resetplayer(it, this);
 681                         // reload all reloadable weapons
 682                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 683                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 684                                 {
 685                                         .entity weaponentity = weaponentities[slot];
 686                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 687                                 }
 688                         }
 689                 ));
 690
 691                 {
 692                         string s = spot.target;
 693                         spot.target = string_null;
 694                         SUB_UseTargets(spot, this, NULL);
 695                         spot.target = s;
 696                 }
 697
 698                 Unfreeze(this);
 699
 700                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 701
 702                 if (autocvar_spawn_debug)
 703                 {
 704                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 705                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 706                 }
 707
 708                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 709                 {
 710                         .entity weaponentity = weaponentities[slot];
 711                         if(slot == 0)
 712                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 713                         else
 714                                 this.(weaponentity).m_switchweapon = WEP_Null;
 715                         this.(weaponentity).m_weapon = WEP_Null;
 716                         this.(weaponentity).weaponname = "";
 717                         this.(weaponentity).m_switchingweapon = WEP_Null;
 718                         this.(weaponentity).cnt = -1;
 719                 }
 720
 721                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 722
 723                 if (!warmup_stage && !this.alivetime)
 724                         this.alivetime = time;
 725
 726                 antilag_clear(this, CS(this));
 727         }
 728 }
 729
 730 void ClientInit_misc(entity this);
 731
 732 // TODO do we need all these fields, or should we stop autodetecting runtime
 733 // changes and just have a console command to update this?
 734 bool ClientInit_SendEntity(entity this, entity to, int sf)
 735 {
 736         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 737         return = true;
 738         msg_entity = to;
 739         // MSG_INIT replacement
 740         // TODO: make easier to use
 741         Registry_send_all();
 742         W_PROP_reload(MSG_ONE, to);
 743         ClientInit_misc(this);
 744         MUTATOR_CALLHOOK(Ent_Init);
 745 }
 746 void ClientInit_misc(entity this)
 747 {
 748         int channel = MSG_ONE;
 749         WriteHeader(channel, ENT_CLIENT_INIT);
 750         WriteByte(channel, g_nexball_meter_period * 32);
 751         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 752         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 753         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 754         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 755         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 756         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 757         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 758         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 759
 760         if(sv_foginterval && world.fog != "")
 761                 WriteString(channel, world.fog);
 762         else
 763                 WriteString(channel, "");
 764         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 765         WriteByte(channel, serverflags);
 766         WriteCoord(channel, autocvar_g_trueaim_minrange);
 767 }
 768
 769 void ClientInit_CheckUpdate(entity this)
 770 {
 771         this.nextthink = time;
 772         if(this.count != autocvar_g_balance_armor_blockpercent)
 773         {
 774                 this.count = autocvar_g_balance_armor_blockpercent;
 775                 this.SendFlags |= 1;
 776         }
 777 }
 778
 779 void ClientInit_Spawn()
 780 {
 781         entity e = new_pure(clientinit);
 782         setthink(e, ClientInit_CheckUpdate);
 783         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 784
 785         ClientInit_CheckUpdate(e);
 786 }
 787
 788 /*
 789 =============
 790 SetNewParms
 791 =============
 792 */
 793 void SetNewParms ()
 794 {
 795         // initialize parms for a new player
 796         parm1 = -(86400 * 366);
 797
 798         MUTATOR_CALLHOOK(SetNewParms);
 799 }
 800
 801 /*
 802 =============
 803 SetChangeParms
 804 =============
 805 */
 806 void SetChangeParms (entity this)
 807 {
 808         // save parms for level change
 809         parm1 = this.parm_idlesince - time;
 810
 811         MUTATOR_CALLHOOK(SetChangeParms);
 812 }
 813
 814 /*
 815 =============
 816 DecodeLevelParms
 817 =============
 818 */
 819 void DecodeLevelParms(entity this)
 820 {
 821         // load parms
 822         this.parm_idlesince = parm1;
 823         if (this.parm_idlesince == -(86400 * 366))
 824                 this.parm_idlesince = time;
 825
 826         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 827         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 828
 829         MUTATOR_CALLHOOK(DecodeLevelParms);
 830 }
 831
 832 /*
 833 =============
 834 ClientKill
 835
 836 Called when a client types 'kill' in the console
 837 =============
 838 */
 839
 840 .float clientkill_nexttime;
 841 void ClientKill_Now_TeamChange(entity this)
 842 {
 843         if(this.killindicator_teamchange == -1)
 844         {
 845                 JoinBestTeam( this, false, true );
 846         }
 847         else if(this.killindicator_teamchange == -2)
 848         {
 849                 if(blockSpectators)
 850                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 851                 PutObserverInServer(this);
 852         }
 853         else
 854                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 855         this.killindicator_teamchange = 0;
 856 }
 857
 858 void ClientKill_Now(entity this)
 859 {
 860         if(this.vehicle)
 861         {
 862             vehicles_exit(this.vehicle, VHEF_RELEASE);
 863             if(!this.killindicator_teamchange)
 864             {
 865             this.vehicle_health = -1;
 866             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 867             }
 868         }
 869
 870         if(this.killindicator && !wasfreed(this.killindicator))
 871                 delete(this.killindicator);
 872
 873         this.killindicator = NULL;
 874
 875         if(this.killindicator_teamchange)
 876                 ClientKill_Now_TeamChange(this);
 877
 878         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 879                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 880
 881         // now I am sure the player IS dead
 882 }
 883 void KillIndicator_Think(entity this)
 884 {
 885         if (game_stopped)
 886         {
 887                 this.owner.killindicator = NULL;
 888                 delete(this);
 889                 return;
 890         }
 891
 892         if (this.owner.alpha < 0 && !this.owner.vehicle)
 893         {
 894                 this.owner.killindicator = NULL;
 895                 delete(this);
 896                 return;
 897         }
 898
 899         if(this.cnt <= 0)
 900         {
 901                 ClientKill_Now(this.owner);
 902                 return;
 903         }
 904     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 905     {
 906         this.nextthink = time + 1;
 907         this.cnt -= 1;
 908     }
 909         else
 910         {
 911                 if(this.cnt <= 10)
 912                         setmodel(this, MDL_NUM(this.cnt));
 913                 if(IS_REAL_CLIENT(this.owner))
 914                 {
 915                         if(this.cnt <= 10)
 916                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 917                 }
 918                 this.nextthink = time + 1;
 919                 this.cnt -= 1;
 920         }
 921 }
 922
 923 float clientkilltime;
 924 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 925 {
 926         float killtime;
 927         float starttime;
 928
 929         if (game_stopped)
 930                 return;
 931
 932         killtime = autocvar_g_balance_kill_delay;
 933
 934         if(g_race_qualifying || g_cts)
 935                 killtime = 0;
 936
 937     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 938         return;
 939
 940         this.killindicator_teamchange = targetteam;
 941
 942     if(!this.killindicator)
 943         {
 944                 if(!IS_DEAD(this))
 945                 {
 946                         killtime = max(killtime, this.clientkill_nexttime - time);
 947                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 948                 }
 949
 950                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 951                 {
 952                         ClientKill_Now(this);
 953                 }
 954                 else
 955                 {
 956                         starttime = max(time, clientkilltime);
 957
 958                         this.killindicator = spawn();
 959                         this.killindicator.owner = this;
 960                         this.killindicator.scale = 0.5;
 961                         setattachment(this.killindicator, this, "");
 962                         setorigin(this.killindicator, '0 0 52');
 963                         setthink(this.killindicator, KillIndicator_Think);
 964                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 965                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 966                         this.killindicator.cnt = ceil(killtime);
 967                         this.killindicator.count = bound(0, ceil(killtime), 10);
 968                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 969
 970                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 971                         {
 972                                 it.killindicator = spawn();
 973                                 it.killindicator.owner = it;
 974                                 it.killindicator.scale = 0.5;
 975                                 setattachment(it.killindicator, it, "");
 976                                 setorigin(it.killindicator, '0 0 52');
 977                                 setthink(it.killindicator, KillIndicator_Think);
 978                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 979                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 980                                 it.killindicator.cnt = ceil(killtime);
 981                         });
 982                         this.lip = 0;
 983                 }
 984         }
 985         if(this.killindicator)
 986         {
 987                 if(targetteam == 0) // just die
 988                 {
 989                         this.killindicator.colormod = '0 0 0';
 990                         if(IS_REAL_CLIENT(this))
 991                         if(this.killindicator.cnt > 0)
 992                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 993                 }
 994                 else if(targetteam == -1) // auto
 995                 {
 996                         this.killindicator.colormod = '0 1 0';
 997                         if(IS_REAL_CLIENT(this))
 998                         if(this.killindicator.cnt > 0)
 999                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1000                 }
1001                 else if(targetteam == -2) // spectate
1002                 {
1003                         this.killindicator.colormod = '0.5 0.5 0.5';
1004                         if(IS_REAL_CLIENT(this))
1005                         if(this.killindicator.cnt > 0)
1006                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1007                 }
1008                 else
1009                 {
1010                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1011                         if(IS_REAL_CLIENT(this))
1012                         if(this.killindicator.cnt > 0)
1013                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1014                 }
1015         }
1016
1017 }
1018
1019 void ClientKill (entity this)
1020 {
1021         if(game_stopped) return;
1022         if(this.player_blocked) return;
1023         if(STAT(FROZEN, this)) return;
1024
1025         ClientKill_TeamChange(this, 0);
1026 }
1027
1028 void FixClientCvars(entity e)
1029 {
1030         // send prediction settings to the client
1031         stuffcmd(e, "\nin_bindmap 0 0\n");
1032         if(autocvar_g_antilag == 3) // client side hitscan
1033                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1034         if(autocvar_sv_gentle)
1035                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1036
1037         MUTATOR_CALLHOOK(FixClientCvars, e);
1038 }
1039
1040 float PlayerInIDList(entity p, string idlist)
1041 {
1042         float n, i;
1043         string s;
1044
1045         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1046         if (!p.crypto_idfp)
1047                 return 0;
1048
1049         // this function allows abbreviated player IDs too!
1050         n = tokenize_console(idlist);
1051         for(i = 0; i < n; ++i)
1052         {
1053                 s = argv(i);
1054                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1055                         return 1;
1056         }
1057
1058         return 0;
1059 }
1060
1061 #ifdef DP_EXT_PRECONNECT
1062 /*
1063 =============
1064 ClientPreConnect
1065
1066 Called once (not at each match start) when a client begins a connection to the server
1067 =============
1068 */
1069 void ClientPreConnect(entity this)
1070 {
1071         if(autocvar_sv_eventlog)
1072         {
1073                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1074                         this.playerid,
1075                         etof(this),
1076                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1077                 ));
1078         }
1079 }
1080 #endif
1081
1082 /**
1083 =============
1084 ClientConnect
1085
1086 Called when a client connects to the server
1087 =============
1088 */
1089 void ClientConnect(entity this)
1090 {
1091         if (Ban_MaybeEnforceBanOnce(this)) return;
1092         assert(!IS_CLIENT(this), return);
1093         this.flags |= FL_CLIENT;
1094         assert(player_count >= 0, player_count = 0);
1095
1096 #ifdef WATERMARK
1097         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1098 #endif
1099         this.version_nagtime = time + 10 + random() * 10;
1100         TRANSMUTE(Client, this);
1101
1102         // identify the right forced team
1103         if (autocvar_g_campaign)
1104         {
1105                 if (IS_REAL_CLIENT(this)) // only players, not bots
1106                 {
1107                         switch (autocvar_g_campaign_forceteam)
1108                         {
1109                                 case 1: this.team_forced = NUM_TEAM_1; break;
1110                                 case 2: this.team_forced = NUM_TEAM_2; break;
1111                                 case 3: this.team_forced = NUM_TEAM_3; break;
1112                                 case 4: this.team_forced = NUM_TEAM_4; break;
1113                                 default: this.team_forced = 0;
1114                         }
1115                 }
1116         }
1117         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1118         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1119         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1120         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1121         else switch (autocvar_g_forced_team_otherwise)
1122         {
1123                 default: this.team_forced = 0; break;
1124                 case "red": this.team_forced = NUM_TEAM_1; break;
1125                 case "blue": this.team_forced = NUM_TEAM_2; break;
1126                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1127                 case "pink": this.team_forced = NUM_TEAM_4; break;
1128                 case "spectate":
1129                 case "spectator":
1130                         this.team_forced = -1;
1131                         break;
1132         }
1133         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1134
1135     {
1136         int id = this.playerid;
1137         this.playerid = 0; // silent
1138             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1139             this.playerid = id;
1140     }
1141
1142         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1143                 TRANSMUTE(Observer, this);
1144         } else {
1145                 if (!teamplay || autocvar_g_balance_teams) {
1146                         TRANSMUTE(Player, this);
1147                         campaign_bots_may_start = true;
1148                 } else {
1149                         TRANSMUTE(Observer, this); // do it anyway
1150                 }
1151         }
1152
1153         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1154
1155         // always track bots, don't ask for cl_allow_uidtracking
1156     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1157
1158         if (autocvar_sv_eventlog)
1159                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1160
1161         LogTeamchange(this.playerid, this.team, 1);
1162
1163         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1164
1165         this.netname_previous = strzone(this.netname);
1166
1167         if(teamplay && IS_PLAYER(this))
1168                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1169         else
1170                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1171
1172         stuffcmd(this, clientstuff, "\n");
1173         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1174
1175         FixClientCvars(this);
1176
1177         // get version info from player
1178         stuffcmd(this, "cmd clientversion $gameversion\n");
1179
1180         // notify about available teams
1181         if (teamplay)
1182         {
1183                 CheckAllowedTeams(this);
1184                 int t = 0;
1185                 if (c1 >= 0) t |= BIT(0);
1186                 if (c2 >= 0) t |= BIT(1);
1187                 if (c3 >= 0) t |= BIT(2);
1188                 if (c4 >= 0) t |= BIT(3);
1189                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1190         }
1191         else
1192         {
1193                 stuffcmd(this, "set _teams_available 0\n");
1194         }
1195
1196         bot_relinkplayerlist();
1197
1198         this.spectatortime = time;
1199         if (blockSpectators)
1200         {
1201                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1202         }
1203
1204         this.jointime = time;
1205         this.allowed_timeouts = autocvar_sv_timeout_number;
1206
1207         if (IS_REAL_CLIENT(this))
1208         {
1209                 if (g_weaponarena_weapons == WEPSET(TUBA))
1210                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1211         }
1212
1213         if (!sv_foginterval && world.fog != "")
1214                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1215
1216         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1217                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1218                         send_CSQC_teamnagger();
1219
1220         CSQCMODEL_AUTOINIT(this);
1221
1222         this.model_randomizer = random();
1223
1224         if (IS_REAL_CLIENT(this))
1225                 sv_notice_join(this);
1226
1227         // update physics stats (players can spawn before physics runs)
1228         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1229
1230         IL_EACH(g_initforplayer, it.init_for_player, {
1231                 it.init_for_player(it, this);
1232         });
1233
1234         MUTATOR_CALLHOOK(ClientConnect, this);
1235
1236         if (IS_REAL_CLIENT(this))
1237         {
1238                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1239                 {
1240                         this.motd_actived_time = -1;
1241                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1242                 }
1243         }
1244 }
1245 /*
1246 =============
1247 ClientDisconnect
1248
1249 Called when a client disconnects from the server
1250 =============
1251 */
1252 .entity chatbubbleentity;
1253 void ReadyCount();
1254 void ClientDisconnect(entity this)
1255 {
1256         assert(IS_CLIENT(this), return);
1257
1258         PlayerStats_GameReport_FinalizePlayer(this);
1259         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1260         if (this.active_minigame) part_minigame(this);
1261         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1262
1263         if (autocvar_sv_eventlog)
1264                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1265
1266         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1267
1268         if(IS_SPEC(this))
1269                 SetSpectatee(this, NULL);
1270
1271     MUTATOR_CALLHOOK(ClientDisconnect, this);
1272
1273         ClientState_detach(this);
1274
1275         Portal_ClearAll(this);
1276
1277         Unfreeze(this);
1278
1279         RemoveGrapplingHooks(this);
1280
1281         // Here, everything has been done that requires this player to be a client.
1282
1283         this.flags &= ~FL_CLIENT;
1284
1285         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1286         if (this.killindicator) delete(this.killindicator);
1287
1288         WaypointSprite_PlayerGone(this);
1289
1290         bot_relinkplayerlist();
1291
1292         if (this.netname_previous) strunzone(this.netname_previous);
1293         if (this.clientstatus) strunzone(this.clientstatus);
1294         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1295         if (this.personal) delete(this.personal);
1296
1297         this.playerid = 0;
1298         ReadyCount();
1299         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1300
1301         ONREMOVE(this);
1302 }
1303
1304 void ChatBubbleThink(entity this)
1305 {
1306         this.nextthink = time;
1307         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1308         {
1309                 if(this.owner) // but why can that ever be NULL?
1310                         this.owner.chatbubbleentity = NULL;
1311                 delete(this);
1312                 return;
1313         }
1314
1315         this.mdl = "";
1316
1317         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1318         {
1319                 if ( this.owner.active_minigame )
1320                         this.mdl = "models/sprites/minigame_busy.iqm";
1321                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1322                         this.mdl = "models/misc/chatbubble.spr";
1323         }
1324
1325         if ( this.model != this.mdl )
1326                 _setmodel(this, this.mdl);
1327
1328 }
1329
1330 void UpdateChatBubble(entity this)
1331 {
1332         if (this.alpha < 0)
1333                 return;
1334         // spawn a chatbubble entity if needed
1335         if (!this.chatbubbleentity)
1336         {
1337                 this.chatbubbleentity = new(chatbubbleentity);
1338                 this.chatbubbleentity.owner = this;
1339                 this.chatbubbleentity.exteriormodeltoclient = this;
1340                 setthink(this.chatbubbleentity, ChatBubbleThink);
1341                 this.chatbubbleentity.nextthink = time;
1342                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1343                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1344                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1345                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1346                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1347                 //this.chatbubbleentity.model = "";
1348                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1349         }
1350 }
1351
1352
1353 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1354 // added to the model skins
1355 /*void UpdateColorModHack()
1356 {
1357         float c;
1358         c = this.clientcolors & 15;
1359         // LordHavoc: only bothering to support white, green, red, yellow, blue
1360              if (!teamplay) this.colormod = '0 0 0';
1361         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1362         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1363         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1364         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1365         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1366         else this.colormod = '1 1 1';
1367 }*/
1368
1369 void respawn(entity this)
1370 {
1371         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1372         {
1373                 this.solid = SOLID_NOT;
1374                 this.takedamage = DAMAGE_NO;
1375                 set_movetype(this, MOVETYPE_FLY);
1376                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1377                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1378                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1379                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1380                 if(autocvar_g_respawn_ghosts_maxtime)
1381                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1382         }
1383
1384         CopyBody(this, 1);
1385
1386         this.effects |= EF_NODRAW; // prevent another CopyBody
1387         PutClientInServer(this);
1388 }
1389
1390 void play_countdown(entity this, float finished, Sound samp)
1391 {
1392     TC(Sound, samp);
1393         if(IS_REAL_CLIENT(this))
1394                 if(floor(finished - time - frametime) != floor(finished - time))
1395                         if(finished - time < 6)
1396                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1397 }
1398
1399 void player_powerups(entity this)
1400 {
1401         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1402         int items_prev = this.items;
1403
1404         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1405                 this.modelflags |= MF_ROCKET;
1406         else
1407                 this.modelflags &= ~MF_ROCKET;
1408
1409         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1410
1411         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1412                 return;
1413
1414         Fire_ApplyDamage(this);
1415         Fire_ApplyEffect(this);
1416
1417         if (!g_instagib)
1418         {
1419                 if (this.items & ITEM_Strength.m_itemid)
1420                 {
1421                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1422                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1423                         if (time > this.strength_finished)
1424                         {
1425                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1426                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1427                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1428                         }
1429                 }
1430                 else
1431                 {
1432                         if (time < this.strength_finished)
1433                         {
1434                                 this.items = this.items | ITEM_Strength.m_itemid;
1435                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1436                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1437                         }
1438                 }
1439                 if (this.items & ITEM_Shield.m_itemid)
1440                 {
1441                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1442                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1443                         if (time > this.invincible_finished)
1444                         {
1445                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1446                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1447                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1448                         }
1449                 }
1450                 else
1451                 {
1452                         if (time < this.invincible_finished)
1453                         {
1454                                 this.items = this.items | ITEM_Shield.m_itemid;
1455                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1456                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1457                         }
1458                 }
1459                 if (this.items & IT_SUPERWEAPON)
1460                 {
1461                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1462                         {
1463                                 this.superweapons_finished = 0;
1464                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1465                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1466                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1467                         }
1468                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1469                         {
1470                                 // don't let them run out
1471                         }
1472                         else
1473                         {
1474                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1475                                 if (time > this.superweapons_finished)
1476                                 {
1477                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1478                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1479                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1480                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1481                                 }
1482                         }
1483                 }
1484                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1485                 {
1486                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1487                         {
1488                                 this.items = this.items | IT_SUPERWEAPON;
1489                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1490                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1491                         }
1492                         else
1493                         {
1494                                 this.superweapons_finished = 0;
1495                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1496                         }
1497                 }
1498                 else
1499                 {
1500                         this.superweapons_finished = 0;
1501                 }
1502         }
1503
1504         if(autocvar_g_nodepthtestplayers)
1505                 this.effects = this.effects | EF_NODEPTHTEST;
1506
1507         if(autocvar_g_fullbrightplayers)
1508                 this.effects = this.effects | EF_FULLBRIGHT;
1509
1510         if (time >= game_starttime)
1511         if (time < this.spawnshieldtime)
1512                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1513
1514         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1515 }
1516
1517 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1518 {
1519         if(current > stable)
1520                 return current;
1521         else if(current > stable - 0.25) // when close enough, "snap"
1522                 return stable;
1523         else
1524                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1525 }
1526
1527 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1528 {
1529         if(current < stable)
1530                 return current;
1531         else if(current < stable + 0.25) // when close enough, "snap"
1532                 return stable;
1533         else
1534                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1535 }
1536
1537 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1538 {
1539         if(current > rotstable)
1540         {
1541                 if(rotframetime > 0)
1542                 {
1543                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1544                         current = max(rotstable, current - rotlinear * rotframetime);
1545                 }
1546         }
1547         else if(current < regenstable)
1548         {
1549                 if(regenframetime > 0)
1550                 {
1551                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1552                         current = min(regenstable, current + regenlinear * regenframetime);
1553                 }
1554         }
1555
1556         if(current > limit)
1557                 current = limit;
1558
1559         return current;
1560 }
1561
1562 void player_regen(entity this)
1563 {
1564         float max_mod, regen_mod, rot_mod, limit_mod;
1565         max_mod = regen_mod = rot_mod = limit_mod = 1;
1566
1567         float regen_health = autocvar_g_balance_health_regen;
1568         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1569         float regen_health_rot = autocvar_g_balance_health_rot;
1570         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1571         float regen_health_stable = autocvar_g_balance_health_regenstable;
1572         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1573         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1574                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1575         max_mod = M_ARGV(1, float);
1576         regen_mod = M_ARGV(2, float);
1577         rot_mod = M_ARGV(3, float);
1578         limit_mod = M_ARGV(4, float);
1579         regen_health = M_ARGV(5, float);
1580         regen_health_linear = M_ARGV(6, float);
1581         regen_health_rot = M_ARGV(7, float);
1582         regen_health_rotlinear = M_ARGV(8, float);
1583         regen_health_stable = M_ARGV(9, float);
1584         regen_health_rotstable = M_ARGV(10, float);
1585
1586
1587         if(!mutator_returnvalue)
1588         if(!STAT(FROZEN, this))
1589         {
1590                 float mina, maxa, limith, limita;
1591                 maxa = autocvar_g_balance_armor_rotstable;
1592                 mina = autocvar_g_balance_armor_regenstable;
1593                 limith = autocvar_g_balance_health_limit;
1594                 limita = autocvar_g_balance_armor_limit;
1595
1596                 regen_health_rotstable = regen_health_rotstable * max_mod;
1597                 regen_health_stable = regen_health_stable * max_mod;
1598                 limith = limith * limit_mod;
1599                 limita = limita * limit_mod;
1600
1601                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1602                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1603         }
1604
1605         // if player rotted to death...  die!
1606         // check this outside above checks, as player may still be able to rot to death
1607         if(this.health < 1)
1608         {
1609                 if(this.vehicle)
1610                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1611                 if(this.event_damage)
1612                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1613         }
1614
1615         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1616         {
1617                 float minf, maxf, limitf;
1618
1619                 maxf = autocvar_g_balance_fuel_rotstable;
1620                 minf = autocvar_g_balance_fuel_regenstable;
1621                 limitf = autocvar_g_balance_fuel_limit;
1622
1623                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1624         }
1625 }
1626
1627 bool zoomstate_set;
1628 void SetZoomState(entity this, float newzoom)
1629 {
1630         if(newzoom != this.zoomstate)
1631         {
1632                 this.zoomstate = newzoom;
1633                 ClientData_Touch(this);
1634         }
1635         zoomstate_set = true;
1636 }
1637
1638 void GetPressedKeys(entity this)
1639 {
1640         MUTATOR_CALLHOOK(GetPressedKeys, this);
1641         int keys = STAT(PRESSED_KEYS, this);
1642         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1643         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1644         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1645         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1646
1647         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1648         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1649         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1650         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1651         this.pressedkeys = keys; // store for other users
1652
1653         STAT(PRESSED_KEYS, this) = keys;
1654 }
1655
1656 /*
1657 ======================
1658 spectate mode routines
1659 ======================
1660 */
1661
1662 void SpectateCopy(entity this, entity spectatee)
1663 {
1664     TC(Client, this); TC(Client, spectatee);
1665
1666         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1667         PS(this) = PS(spectatee);
1668         this.armortype = spectatee.armortype;
1669         this.armorvalue = spectatee.armorvalue;
1670         this.ammo_cells = spectatee.ammo_cells;
1671         this.ammo_plasma = spectatee.ammo_plasma;
1672         this.ammo_shells = spectatee.ammo_shells;
1673         this.ammo_nails = spectatee.ammo_nails;
1674         this.ammo_rockets = spectatee.ammo_rockets;
1675         this.ammo_fuel = spectatee.ammo_fuel;
1676         this.clip_load = spectatee.clip_load;
1677         this.clip_size = spectatee.clip_size;
1678         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1679         this.health = spectatee.health;
1680         this.impulse = 0;
1681         this.items = spectatee.items;
1682         this.last_pickup = spectatee.last_pickup;
1683         this.hit_time = spectatee.hit_time;
1684         this.strength_finished = spectatee.strength_finished;
1685         this.invincible_finished = spectatee.invincible_finished;
1686         this.superweapons_finished = spectatee.superweapons_finished;
1687         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1688         this.weapons = spectatee.weapons;
1689         this.vortex_charge = spectatee.vortex_charge;
1690         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1691         this.hagar_load = spectatee.hagar_load;
1692         this.arc_heat_percent = spectatee.arc_heat_percent;
1693         this.minelayer_mines = spectatee.minelayer_mines;
1694         this.punchangle = spectatee.punchangle;
1695         this.view_ofs = spectatee.view_ofs;
1696         this.velocity = spectatee.velocity;
1697         this.dmg_take = spectatee.dmg_take;
1698         this.dmg_save = spectatee.dmg_save;
1699         this.dmg_inflictor = spectatee.dmg_inflictor;
1700         this.v_angle = spectatee.v_angle;
1701         this.angles = spectatee.v_angle;
1702         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1703         this.revive_progress = spectatee.revive_progress;
1704         this.viewloc = spectatee.viewloc;
1705         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1706                 this.fixangle = true;
1707         setorigin(this, spectatee.origin);
1708         setsize(this, spectatee.mins, spectatee.maxs);
1709         SetZoomState(this, spectatee.zoomstate);
1710
1711         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1712         {
1713                 .entity weaponentity = weaponentities[slot];
1714                 this.(weaponentity) = spectatee.(weaponentity);
1715         }
1716
1717         for(int slot = 0; slot < MAX_AXH; ++slot)
1718         {
1719                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1720         }
1721
1722     anticheat_spectatecopy(this, spectatee);
1723         this.hud = spectatee.hud;
1724         if(spectatee.vehicle)
1725     {
1726         this.angles = spectatee.v_angle;
1727
1728         //this.fixangle = false;
1729         //this.velocity = spectatee.vehicle.velocity;
1730         this.vehicle_health = spectatee.vehicle_health;
1731         this.vehicle_shield = spectatee.vehicle_shield;
1732         this.vehicle_energy = spectatee.vehicle_energy;
1733         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1734         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1735         this.vehicle_reload1 = spectatee.vehicle_reload1;
1736         this.vehicle_reload2 = spectatee.vehicle_reload2;
1737
1738         //msg_entity = this;
1739
1740        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1741             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1742            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1743            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1744
1745         //WriteByte (MSG_ONE, SVC_SETVIEW);
1746         //    WriteEntity(MSG_ONE, this);
1747         //makevectors(spectatee.v_angle);
1748         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1749     }
1750 }
1751
1752 bool SpectateUpdate(entity this)
1753 {
1754         if(!this.enemy)
1755                 return false;
1756
1757         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1758         {
1759                 SetSpectatee(this, NULL);
1760                 return false;
1761         }
1762
1763         SpectateCopy(this, this.enemy);
1764
1765         return true;
1766 }
1767
1768 bool SpectateSet(entity this)
1769 {
1770         if(!IS_PLAYER(this.enemy))
1771                 return false;
1772
1773         ClientData_Touch(this.enemy);
1774
1775         msg_entity = this;
1776         WriteByte(MSG_ONE, SVC_SETVIEW);
1777         WriteEntity(MSG_ONE, this.enemy);
1778         set_movetype(this, MOVETYPE_NONE);
1779         accuracy_resend(this);
1780
1781         if(!SpectateUpdate(this))
1782                 PutObserverInServer(this);
1783
1784         return true;
1785 }
1786
1787 void SetSpectatee_status(entity this, int spectatee_num)
1788 {
1789         int oldspectatee_status = this.spectatee_status;
1790         this.spectatee_status = spectatee_num;
1791
1792         if (this.spectatee_status != oldspectatee_status)
1793         {
1794                 ClientData_Touch(this);
1795                 if (g_race || g_cts) race_InitSpectator();
1796         }
1797 }
1798
1799 void SetSpectatee(entity this, entity spectatee)
1800 {
1801         entity old_spectatee = this.enemy;
1802
1803         this.enemy = spectatee;
1804
1805         // WEAPONTODO
1806         // these are required to fix the spectator bug with arc
1807         if(old_spectatee)
1808         {
1809                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1810                 {
1811                         .entity weaponentity = weaponentities[slot];
1812                         if(old_spectatee.(weaponentity).arc_beam)
1813                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1814                 }
1815         }
1816         if(this.enemy)
1817         {
1818                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1819                 {
1820                         .entity weaponentity = weaponentities[slot];
1821                         if(this.enemy.(weaponentity).arc_beam)
1822                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1823                 }
1824         }
1825
1826         if (this.enemy)
1827                 SetSpectatee_status(this, etof(this.enemy));
1828
1829         // needed to update spectator list
1830         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1831 }
1832
1833 bool Spectate(entity this, entity pl)
1834 {
1835         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1836                 return false;
1837         pl = M_ARGV(1, entity);
1838
1839         SetSpectatee(this, pl);
1840         return SpectateSet(this);
1841 }
1842
1843 bool SpectateNext(entity this)
1844 {
1845         entity ent = find(this.enemy, classname, STR_PLAYER);
1846
1847         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1848                 ent = M_ARGV(1, entity);
1849         else if (!ent)
1850                 ent = find(ent, classname, STR_PLAYER);
1851
1852         if(ent) { SetSpectatee(this, ent); }
1853
1854         return SpectateSet(this);
1855 }
1856
1857 bool SpectatePrev(entity this)
1858 {
1859         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1860         entity ent = findchain(classname, STR_PLAYER);
1861         if (!ent) // no player
1862                 return false;
1863
1864         entity first = ent;
1865         // skip players until current spectated player
1866         if(this.enemy)
1867         while(ent && ent != this.enemy)
1868                 ent = ent.chain;
1869
1870         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1871         {
1872                 case MUT_SPECPREV_FOUND:
1873                     ent = M_ARGV(1, entity);
1874                     break;
1875                 case MUT_SPECPREV_RETURN:
1876                     return true;
1877                 case MUT_SPECPREV_CONTINUE:
1878                 default:
1879                 {
1880                         if(ent.chain)
1881                                 ent = ent.chain;
1882                         else
1883                                 ent = first;
1884                         break;
1885                 }
1886         }
1887
1888         SetSpectatee(this, ent);
1889         return SpectateSet(this);
1890 }
1891
1892 /*
1893 =============
1894 ShowRespawnCountdown()
1895
1896 Update a respawn countdown display.
1897 =============
1898 */
1899 void ShowRespawnCountdown(entity this)
1900 {
1901         float number;
1902         if(!IS_DEAD(this)) // just respawned?
1903                 return;
1904         else
1905         {
1906                 number = ceil(this.respawn_time - time);
1907                 if(number <= 0)
1908                         return;
1909                 if(number <= this.respawn_countdown)
1910                 {
1911                         this.respawn_countdown = number - 1;
1912                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1913                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1914                 }
1915         }
1916 }
1917
1918 .bool team_selected;
1919 bool ShowTeamSelection(entity this)
1920 {
1921         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1922                 return false;
1923         stuffcmd(this, "menu_showteamselect\n");
1924         return true;
1925 }
1926 void Join(entity this)
1927 {
1928         TRANSMUTE(Player, this);
1929
1930         if(!this.team_selected)
1931         if(autocvar_g_campaign || autocvar_g_balance_teams)
1932                 JoinBestTeam(this, false, true);
1933
1934         if(autocvar_g_campaign)
1935                 campaign_bots_may_start = true;
1936
1937         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1938
1939         PutClientInServer(this);
1940
1941         if(teamplay && this.team != -1)
1942                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1943         else
1944                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1945         this.team_selected = false;
1946 }
1947
1948 /**
1949  * Determines whether the player is allowed to join. This depends on cvar
1950  * g_maxplayers, if it isn't used this function always return true, otherwise
1951  * it checks whether the number of currently playing players exceeds g_maxplayers.
1952  * @return int number of free slots for players, 0 if none
1953  */
1954 int nJoinAllowed(entity this, entity ignore)
1955 {
1956         if(!ignore)
1957         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1958         // so report 0 free slots if restricted
1959         {
1960                 if(autocvar_g_forced_team_otherwise == "spectate")
1961                         return 0;
1962                 if(autocvar_g_forced_team_otherwise == "spectator")
1963                         return 0;
1964         }
1965
1966         if(this && this.team_forced < 0)
1967                 return 0; // forced spectators can never join
1968
1969         // TODO simplify this
1970         int totalClients = 0;
1971         int currentlyPlaying = 0;
1972         FOREACH_CLIENT(true, LAMBDA(
1973                 if(it != ignore)
1974                         ++totalClients;
1975                 if(IS_REAL_CLIENT(it))
1976                 if(IS_PLAYER(it) || it.caplayer)
1977                         ++currentlyPlaying;
1978         ));
1979
1980         float free_slots = 0;
1981         if (!autocvar_g_maxplayers)
1982                 free_slots = maxclients - totalClients;
1983         else if(currentlyPlaying < autocvar_g_maxplayers)
1984                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1985
1986         static float join_prevent_msg_time = 0;
1987         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1988         {
1989                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1990                 join_prevent_msg_time = time + 3;
1991         }
1992
1993         return free_slots;
1994 }
1995
1996 /**
1997  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1998  * g_maxplayers_spectator_blocktime seconds
1999  */
2000 void checkSpectatorBlock(entity this)
2001 {
2002         if(IS_SPEC(this) || IS_OBSERVER(this))
2003         if(!this.caplayer)
2004         if(IS_REAL_CLIENT(this))
2005         {
2006                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2007                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2008                         dropclient(this);
2009                 }
2010         }
2011 }
2012
2013 void PrintWelcomeMessage(entity this)
2014 {
2015         if(this.motd_actived_time == 0)
2016         {
2017                 if (autocvar_g_campaign) {
2018                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2019                                 this.motd_actived_time = time;
2020                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2021                         }
2022                 } else {
2023                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2024                                 this.motd_actived_time = time;
2025                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2026                         }
2027                 }
2028         }
2029         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2030         {
2031                 if (autocvar_g_campaign) {
2032                         if (PHYS_INPUT_BUTTON_INFO(this))
2033                                 this.motd_actived_time = time;
2034                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2035                                 this.motd_actived_time = 0;
2036                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2037                         }
2038                 } else {
2039                         if (PHYS_INPUT_BUTTON_INFO(this))
2040                                 this.motd_actived_time = time;
2041                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2042                                 this.motd_actived_time = 0;
2043                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2044                         }
2045                 }
2046         }
2047         else //if(this.motd_actived_time < 0) // just connected, motd is active
2048         {
2049                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2050                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2051                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2052                 {
2053                         // instanctly hide MOTD
2054                         this.motd_actived_time = 0;
2055                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2056                 }
2057         }
2058 }
2059
2060 bool joinAllowed(entity this)
2061 {
2062         if (this.version_mismatch) return false;
2063         if (!nJoinAllowed(this, this)) return false;
2064         if (teamplay && lockteams) return false;
2065         if (ShowTeamSelection(this)) return false;
2066         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2067         return true;
2068 }
2069
2070 void ObserverThink(entity this)
2071 {
2072         if ( this.impulse )
2073         {
2074                 MinigameImpulse(this, this.impulse);
2075                 this.impulse = 0;
2076         }
2077
2078         if (this.flags & FL_JUMPRELEASED) {
2079                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2080                         this.flags &= ~FL_JUMPRELEASED;
2081                         this.flags |= FL_SPAWNING;
2082                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2083                         this.flags &= ~FL_JUMPRELEASED;
2084                         if(SpectateNext(this)) {
2085                                 TRANSMUTE(Spectator, this);
2086                         }
2087                 } else {
2088                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2089                         set_movetype(this, preferred_movetype);
2090                 }
2091         } else {
2092                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2093                         this.flags |= FL_JUMPRELEASED;
2094                         if(this.flags & FL_SPAWNING)
2095                         {
2096                                 this.flags &= ~FL_SPAWNING;
2097                                 Join(this);
2098                                 return;
2099                         }
2100                 }
2101         }
2102 }
2103
2104 void SpectatorThink(entity this)
2105 {
2106         if ( this.impulse )
2107         {
2108                 if(MinigameImpulse(this, this.impulse))
2109                         this.impulse = 0;
2110
2111                 if (this.impulse == IMP_weapon_drop.impulse)
2112                 {
2113                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2114                         this.impulse = 0;
2115                         return;
2116                 }
2117         }
2118
2119         if (this.flags & FL_JUMPRELEASED) {
2120                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2121                         this.flags &= ~FL_JUMPRELEASED;
2122                         this.flags |= FL_SPAWNING;
2123                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2124                         this.flags &= ~FL_JUMPRELEASED;
2125                         if(SpectateNext(this)) {
2126                                 TRANSMUTE(Spectator, this);
2127                         } else {
2128                                 TRANSMUTE(Observer, this);
2129                                 PutClientInServer(this);
2130                         }
2131                         this.impulse = 0;
2132                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2133                         this.flags &= ~FL_JUMPRELEASED;
2134                         if(SpectatePrev(this)) {
2135                                 TRANSMUTE(Spectator, this);
2136                         } else {
2137                                 TRANSMUTE(Observer, this);
2138                                 PutClientInServer(this);
2139                         }
2140                         this.impulse = 0;
2141                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2142                         this.flags &= ~FL_JUMPRELEASED;
2143                         TRANSMUTE(Observer, this);
2144                         PutClientInServer(this);
2145                 } else {
2146                         if(!SpectateUpdate(this))
2147                                 PutObserverInServer(this);
2148                 }
2149         } else {
2150                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2151                         this.flags |= FL_JUMPRELEASED;
2152                         if(this.flags & FL_SPAWNING)
2153                         {
2154                                 this.flags &= ~FL_SPAWNING;
2155                                 Join(this);
2156                                 return;
2157                         }
2158                 }
2159                 if(!SpectateUpdate(this))
2160                         PutObserverInServer(this);
2161         }
2162
2163         this.flags |= FL_CLIENT | FL_NOTARGET;
2164 }
2165
2166 void vehicles_enter (entity pl, entity veh);
2167 void PlayerUseKey(entity this)
2168 {
2169         if (!IS_PLAYER(this))
2170                 return;
2171
2172         if(this.vehicle)
2173         {
2174                 if(!game_stopped)
2175                 {
2176                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2177                         return;
2178                 }
2179         }
2180         else if(autocvar_g_vehicles_enter)
2181         {
2182                 if(!STAT(FROZEN, this))
2183                 if(!IS_DEAD(this))
2184                 if(!game_stopped)
2185                 {
2186                         entity head, closest_target = NULL;
2187                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2188
2189                         while(head) // find the closest acceptable target to enter
2190                         {
2191                                 if(IS_VEHICLE(head))
2192                                 if(!IS_DEAD(head))
2193                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2194                                 if(head.takedamage != DAMAGE_NO)
2195                                 {
2196                                         if(closest_target)
2197                                         {
2198                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2199                                                 { closest_target = head; }
2200                                         }
2201                                         else { closest_target = head; }
2202                                 }
2203
2204                                 head = head.chain;
2205                         }
2206
2207                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2208                 }
2209         }
2210
2211         // a use key was pressed; call handlers
2212         MUTATOR_CALLHOOK(PlayerUseKey, this);
2213 }
2214
2215
2216 /*
2217 =============
2218 PlayerPreThink
2219
2220 Called every frame for each client before the physics are run
2221 =============
2222 */
2223 .float usekeypressed;
2224 .float last_vehiclecheck;
2225 .int items_added;
2226 void PlayerPreThink (entity this)
2227 {
2228         WarpZone_PlayerPhysics_FixVAngle(this);
2229
2230     STAT(GAMESTARTTIME, this) = game_starttime;
2231         STAT(ROUNDSTARTTIME, this) = round_starttime;
2232         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2233         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2234
2235         STAT(WEAPONSINMAP, this) = weaponsInMap;
2236
2237         if (frametime) {
2238                 // physics frames: update anticheat stuff
2239                 anticheat_prethink(this);
2240         }
2241
2242         if (blockSpectators && frametime) {
2243                 // WORKAROUND: only use dropclient in server frames (frametime set).
2244                 // Never use it in cl_movement frames (frametime zero).
2245                 checkSpectatorBlock(this);
2246     }
2247
2248         zoomstate_set = false;
2249
2250         // Check for nameless players
2251         if (isInvisibleString(this.netname)) {
2252                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2253                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2254         }
2255         if (this.netname != this.netname_previous) {
2256                 if (autocvar_sv_eventlog) {
2257                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2258         }
2259                 if (this.netname_previous) strunzone(this.netname_previous);
2260                 this.netname_previous = strzone(this.netname);
2261         }
2262
2263         // version nagging
2264         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2265         this.version_nagtime = 0;
2266         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2267             // git client
2268         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2269             // git server
2270             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2271         } else {
2272             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2273             if (r < 0) { // old client
2274                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2275             } else if (r > 0) { // old server
2276                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2277             }
2278         }
2279     }
2280
2281         // GOD MODE info
2282         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2283         {
2284                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2285                 this.max_armorvalue = 0;
2286         }
2287
2288         if (STAT(FROZEN, this) == 2)
2289         {
2290                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2291                 this.health = max(1, this.revive_progress * start_health);
2292                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2293
2294                 if (this.revive_progress >= 1)
2295                         Unfreeze(this);
2296         }
2297         else if (STAT(FROZEN, this) == 3)
2298         {
2299                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2300                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2301
2302                 if (this.health < 1)
2303                 {
2304                         if (this.vehicle)
2305                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2306                         if(this.event_damage)
2307                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2308                 }
2309                 else if (this.revive_progress <= 0)
2310                         Unfreeze(this);
2311         }
2312
2313         MUTATOR_CALLHOOK(PlayerPreThink, this);
2314
2315         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2316         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2317         {
2318                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2319                 {
2320                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2321                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2322                         {
2323                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2324                         }
2325                         else if(!it.owner)
2326                         {
2327                                 if(!it.team || SAME_TEAM(this, it))
2328                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2329                                 else if(autocvar_g_vehicles_steal)
2330                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2331                         }
2332                 });
2333
2334                 this.last_vehiclecheck = time + 1;
2335         }
2336
2337         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2338         {
2339                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2340                         PlayerUseKey(this);
2341                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2342         }
2343
2344         if (IS_REAL_CLIENT(this))
2345                 PrintWelcomeMessage(this);
2346
2347         if (IS_PLAYER(this)) {
2348                 CheckRules_Player(this);
2349
2350                 if (game_stopped || intermission_running) {
2351                         this.modelflags &= ~MF_ROCKET;
2352                         if(intermission_running)
2353                                 IntermissionThink(this);
2354                         return;
2355                 }
2356
2357                 if (timeout_status == TIMEOUT_ACTIVE) {
2358             // don't allow the player to turn around while game is paused
2359                         // FIXME turn this into CSQC stuff
2360                         this.v_angle = this.lastV_angle;
2361                         this.angles = this.lastV_angle;
2362                         this.fixangle = true;
2363                 }
2364
2365                 if (frametime) player_powerups(this);
2366
2367                 if (IS_DEAD(this)) {
2368                         if (this.personal && g_race_qualifying) {
2369                                 if (time > this.respawn_time) {
2370                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2371                                         respawn(this);
2372                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2373                                 }
2374                         } else {
2375                                 if (frametime) player_anim(this);
2376                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2377
2378                                 switch(this.deadflag)
2379                                 {
2380                                         case DEAD_DYING:
2381                                         {
2382                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2383                                                         this.deadflag = DEAD_RESPAWNING;
2384                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2385                                                         this.deadflag = DEAD_DEAD;
2386                                                 break;
2387                                         }
2388                                         case DEAD_DEAD:
2389                                         {
2390                                                 if (button_pressed)
2391                                                         this.deadflag = DEAD_RESPAWNABLE;
2392                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2393                                                         this.deadflag = DEAD_RESPAWNING;
2394                                                 break;
2395                                         }
2396                                         case DEAD_RESPAWNABLE:
2397                                         {
2398                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2399                                                         this.deadflag = DEAD_RESPAWNING;
2400                                                 break;
2401                                         }
2402                                         case DEAD_RESPAWNING:
2403                                         {
2404                                                 if (time > this.respawn_time)
2405                                                 {
2406                                                         this.respawn_time = time + 1; // only retry once a second
2407                                                         this.respawn_time_max = this.respawn_time;
2408                                                         respawn(this);
2409                                                 }
2410                                                 break;
2411                                         }
2412                                 }
2413
2414                                 ShowRespawnCountdown(this);
2415
2416                                 if (this.respawn_flags & RESPAWN_SILENT)
2417                                         STAT(RESPAWN_TIME, this) = 0;
2418                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2419                                 {
2420                                         if (time < this.respawn_time)
2421                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2422                                         else if (this.deadflag != DEAD_RESPAWNING)
2423                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2424                                 }
2425                                 else
2426                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2427                         }
2428
2429                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2430                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2431                                 STAT(RESPAWN_TIME, this) *= -1;
2432
2433                         return;
2434                 }
2435
2436                 this.prevorigin = this.origin;
2437
2438                 bool have_hook = false;
2439                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2440                 {
2441                         .entity weaponentity = weaponentities[slot];
2442                         if(this.(weaponentity).hook.state)
2443                         {
2444                                 have_hook = true;
2445                                 break;
2446                         }
2447                 }
2448                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2449                 if (have_hook) {
2450                         do_crouch = false;
2451                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2452                         do_crouch = false;
2453                 } else if (this.vehicle) {
2454                         do_crouch = false;
2455                 } else if (STAT(FROZEN, this)) {
2456                         do_crouch = false;
2457         }
2458
2459                 if (do_crouch) {
2460                         if (!this.crouch) {
2461                                 this.crouch = true;
2462                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2463                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2464                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2465                         }
2466                 } else if (this.crouch) {
2467             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2468             if (!trace_startsolid) {
2469                 this.crouch = false;
2470                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2471                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2472             }
2473                 }
2474
2475                 FixPlayermodel(this);
2476
2477                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2478                 //if(frametime)
2479                 {
2480                         this.items &= ~this.items_added;
2481
2482                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2483                         {
2484                                 .entity weaponentity = weaponentities[slot];
2485                                 W_WeaponFrame(this, weaponentity);
2486
2487                                 if(slot == 0)
2488                                 {
2489                                         this.clip_load = this.(weaponentity).clip_load;
2490                                         this.clip_size = this.(weaponentity).clip_size;
2491                                 }
2492                         }
2493
2494                         this.items_added = 0;
2495                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2496                 this.items_added |= IT_FUEL;
2497
2498                         this.items |= this.items_added;
2499                 }
2500
2501                 player_regen(this);
2502
2503                 // WEAPONTODO: Add a weapon request for this
2504                 // rot vortex charge to the charge limit
2505                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2506                 {
2507                         .entity weaponentity = weaponentities[slot];
2508                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2509                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2510                 }
2511
2512                 if (frametime) player_anim(this);
2513
2514                 // secret status
2515                 secrets_setstatus(this);
2516
2517                 // monsters status
2518                 monsters_setstatus(this);
2519
2520                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2521         }
2522         else if (game_stopped || intermission_running) {
2523                 if(intermission_running)
2524                         IntermissionThink(this);
2525                 return;
2526         }
2527         else if (IS_OBSERVER(this)) {
2528                 ObserverThink(this);
2529         }
2530         else if (IS_SPEC(this)) {
2531                 SpectatorThink(this);
2532         }
2533
2534         // WEAPONTODO: Add weapon request for this
2535         if (!zoomstate_set) {
2536                 bool wep_zoomed = false;
2537                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2538                 {
2539                         .entity weaponentity = weaponentities[slot];
2540                         Weapon thiswep = this.(weaponentity).m_weapon;
2541                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2542                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2543                 }
2544                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2545     }
2546
2547         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2548         {
2549                 this.teamkill_soundtime = 0;
2550
2551                 entity e = this.teamkill_soundsource;
2552                 entity oldpusher = e.pusher;
2553                 e.pusher = this;
2554                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2555                 e.pusher = oldpusher;
2556         }
2557
2558         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2559                 this.taunt_soundtime = 0;
2560                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2561         }
2562
2563         target_voicescript_next(this);
2564
2565         // WEAPONTODO: Move into weaponsystem somehow
2566         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2567         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2568         {
2569                 .entity weaponentity = weaponentities[slot];
2570                 if(this.(weaponentity).m_weapon == WEP_Null)
2571                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2572         }
2573 }
2574
2575 void DrownPlayer(entity this)
2576 {
2577         if(IS_DEAD(this))
2578                 return;
2579
2580         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2581         {
2582                 if(this.air_finished < time)
2583                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2584                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2585                 this.dmg = 2;
2586         }
2587         else if (this.air_finished < time)
2588         {       // drown!
2589                 if (this.pain_finished < time)
2590                 {
2591                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2592                         this.pain_finished = time + 0.5;
2593                 }
2594         }
2595 }
2596
2597 .bool move_qcphysics;
2598
2599 void Player_Physics(entity this)
2600 {
2601         set_movetype(this, this.move_movetype);
2602
2603         if(!this.move_qcphysics)
2604                 return;
2605
2606         if(!frametime && !this.pm_frametime)
2607                 return;
2608
2609         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2610
2611         this.pm_frametime = 0;
2612 }
2613
2614 /*
2615 =============
2616 PlayerPostThink
2617
2618 Called every frame for each client after the physics are run
2619 =============
2620 */
2621 .float idlekick_lasttimeleft;
2622 void PlayerPostThink (entity this)
2623 {
2624         Player_Physics(this);
2625
2626         if (sv_maxidle > 0)
2627         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2628         if (IS_REAL_CLIENT(this))
2629         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2630         {
2631                 int totalClients = 0;
2632                 if(sv_maxidle_slots > 0)
2633                 {
2634                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2635                         {
2636                                 ++totalClients;
2637                         });
2638                 }
2639
2640                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2641                 { /* do nothing */ }
2642                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2643                 {
2644                         if (this.idlekick_lasttimeleft)
2645                         {
2646                                 this.idlekick_lasttimeleft = 0;
2647                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2648                         }
2649                 }
2650                 else
2651                 {
2652                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2653                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2654                                 if (!this.idlekick_lasttimeleft)
2655                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2656                         }
2657                         if (timeleft <= 0) {
2658                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2659                                 dropclient(this);
2660                                 return;
2661                         }
2662                         else if (timeleft <= 10) {
2663                                 if (timeleft != this.idlekick_lasttimeleft) {
2664                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2665                 }
2666                                 this.idlekick_lasttimeleft = timeleft;
2667                         }
2668                 }
2669         }
2670
2671         CheatFrame(this);
2672
2673         //CheckPlayerJump();
2674         if (game_stopped)
2675         {
2676                 this.solid = SOLID_NOT;
2677                 this.takedamage = DAMAGE_NO;
2678                 set_movetype(this, MOVETYPE_NONE);
2679         }
2680
2681         if (IS_PLAYER(this)) {
2682                 DrownPlayer(this);
2683                 CheckRules_Player(this);
2684                 UpdateChatBubble(this);
2685                 if (this.impulse) ImpulseCommands(this);
2686                 if (game_stopped)
2687                 {
2688                         CSQCMODEL_AUTOUPDATE(this);
2689                         return;
2690                 }
2691                 GetPressedKeys(this);
2692         }
2693
2694         if (this.waypointsprite_attachedforcarrier) {
2695             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2696                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2697     }
2698
2699         playerdemo_write(this);
2700
2701         CSQCMODEL_AUTOUPDATE(this);
2702 }