qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/func/conveyor.qh"
  31 #include "../common/triggers/teleporters.qh"
  32
  33 #include "../common/vehicles/all.qh"
  34
  35 #include "weapons/hitplot.qh"
  36 #include "weapons/weaponsystem.qh"
  37
  38 #include "../common/net_notice.qh"
  39 #include "../common/net_linked.qh"
  40 #include "../common/physics/player.qh"
  41
  42 #include "../common/items/_mod.qh"
  43
  44 #include "../common/mutators/mutator/waypoints/all.qh"
  45
  46 #include "../common/triggers/subs.qh"
  47 #include "../common/triggers/triggers.qh"
  48 #include "../common/triggers/trigger/secret.qh"
  49
  50 #include "../common/minigames/sv_minigames.qh"
  51
  52 #include "../common/items/inventory.qh"
  53
  54 #include "../common/monsters/sv_monsters.qh"
  55
  56 #include "../lib/warpzone/server.qh"
  57
  58 STATIC_METHOD(Client, Add, void(Client this, int _team))
  59 {
  60     ClientConnect(this);
  61     TRANSMUTE(Player, this);
  62     this.frame = 12; // 7
  63     this.team = _team;
  64     PutClientInServer(this);
  65 }
  66
  67 void PutObserverInServer(entity this);
  68
  69 STATIC_METHOD(Client, Remove, void(Client this))
  70 {
  71     TRANSMUTE(Observer, this);
  72     PutClientInServer(this);
  73     ClientDisconnect(this);
  74 }
  75
  76 void send_CSQC_teamnagger() {
  77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  78 }
  79
  80 int CountSpectators(entity player, entity to)
  81 {
  82         if(!player) { return 0; } // not sure how, but best to be safe
  83
  84         int spec_count = 0;
  85
  86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  87         {
  88                 spec_count++;
  89         });
  90
  91         return spec_count;
  92 }
  93
  94 void WriteSpectators(entity player, entity to)
  95 {
  96         if(!player) { return; } // not sure how, but best to be safe
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 WriteByte(MSG_ENTITY, num_for_edict(it));
 101         });
 102 }
 103
 104 bool ClientData_Send(entity this, entity to, int sf)
 105 {
 106         assert(to == this.owner, return false);
 107
 108         entity e = to;
 109         if (IS_SPEC(e)) e = e.enemy;
 110
 111         sf = 0;
 112         if (e.race_completed)       sf |= 1; // forced scoreboard
 113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 114         if (e.zoomstate)            sf |= 4; // zoomed
 115         if (e.porto_v_angle_held)   sf |= 8; // angles held
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125         if (sf & 8)
 126         {
 127                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 128                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 129         }
 130
 131         if(sf & 16)
 132         {
 133                 float specs = CountSpectators(e, to);
 134                 WriteByte(MSG_ENTITY, specs);
 135                 WriteSpectators(e, to);
 136         }
 137
 138         return true;
 139 }
 140
 141 void ClientData_Attach(entity this)
 142 {
 143         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 144         this.clientdata.drawonlytoclient = this;
 145         this.clientdata.owner = this;
 146 }
 147
 148 void ClientData_Detach(entity this)
 149 {
 150         delete(this.clientdata);
 151         this.clientdata = NULL;
 152 }
 153
 154 void ClientData_Touch(entity e)
 155 {
 156         e.clientdata.SendFlags = 1;
 157
 158         // make it spectatable
 159         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 160 }
 161
 162 .string netname_previous;
 163
 164 void SetSpectatee(entity this, entity spectatee);
 165 void SetSpectatee_status(entity this, int spectatee_num);
 166
 167
 168 /*
 169 =============
 170 CheckPlayerModel
 171
 172 Checks if the argument string can be a valid playermodel.
 173 Returns a valid one in doubt.
 174 =============
 175 */
 176 string FallbackPlayerModel;
 177 string CheckPlayerModel(string plyermodel) {
 178         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 179         {
 180                 // note: we cannot summon Don Strunzone here, some player may
 181                 // still have the model string set. In case anyone manages how
 182                 // to change a cvar default, we'll have a small leak here.
 183                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 184         }
 185         // only in right path
 186         if( substring(plyermodel,0,14) != "models/player/")
 187                 return FallbackPlayerModel;
 188         // only good file extensions
 189         if(substring(plyermodel,-4,4) != ".zym")
 190         if(substring(plyermodel,-4,4) != ".dpm")
 191         if(substring(plyermodel,-4,4) != ".iqm")
 192         if(substring(plyermodel,-4,4) != ".md3")
 193         if(substring(plyermodel,-4,4) != ".psk")
 194                 return FallbackPlayerModel;
 195         // forbid the LOD models
 196         if(substring(plyermodel, -9,5) == "_lod1")
 197                 return FallbackPlayerModel;
 198         if(substring(plyermodel, -9,5) == "_lod2")
 199                 return FallbackPlayerModel;
 200         if(plyermodel != strtolower(plyermodel))
 201                 return FallbackPlayerModel;
 202         // also, restrict to server models
 203         if(autocvar_sv_servermodelsonly)
 204         {
 205                 if(!fexists(plyermodel))
 206                         return FallbackPlayerModel;
 207         }
 208         return plyermodel;
 209 }
 210
 211 void setplayermodel(entity e, string modelname)
 212 {
 213         precache_model(modelname);
 214         _setmodel(e, modelname);
 215         player_setupanimsformodel(e);
 216         if(!autocvar_g_debug_globalsounds)
 217                 UpdatePlayerSounds(e);
 218 }
 219
 220 void FixPlayermodel(entity player);
 221 /** putting a client as observer in the server */
 222 void PutObserverInServer(entity this)
 223 {
 224     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 225         PlayerState_detach(this);
 226
 227         if (IS_PLAYER(this) && this.health >= 1) {
 228         // despawn effect
 229                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230     }
 231
 232     {
 233         entity spot = SelectSpawnPoint(this, true);
 234         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 235         this.angles = spot.angles;
 236         this.angles_z = 0;
 237         this.fixangle = true;
 238         // offset it so that the spectator spawns higher off the ground, looks better this way
 239         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 240         this.prevorigin = this.origin;
 241         if (IS_REAL_CLIENT(this))
 242         {
 243             msg_entity = this;
 244             WriteByte(MSG_ONE, SVC_SETVIEW);
 245             WriteEntity(MSG_ONE, this);
 246         }
 247         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 248         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 249         if(!autocvar_g_debug_globalsounds)
 250         {
 251                 // needed for player sounds
 252                 this.model = "";
 253                 FixPlayermodel(this);
 254         }
 255         setmodel(this, MDL_Null);
 256         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 257         this.view_ofs = '0 0 0';
 258     }
 259
 260     RemoveGrapplingHook(this);
 261         Portal_ClearAll(this);
 262         Unfreeze(this);
 263         SetSpectatee(this, NULL);
 264
 265         if (this.alivetime)
 266         {
 267                 if (!warmup_stage)
 268                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 269                 this.alivetime = 0;
 270         }
 271
 272         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 273
 274         WaypointSprite_PlayerDead(this);
 275
 276         if (mutator_returnvalue) {
 277             // mutator prevents resetting teams+score
 278         } else {
 279                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 280         this.frags = FRAGS_SPECTATOR;
 281         PlayerScore_Clear(this);  // clear scores when needed
 282     }
 283
 284         if (this.killcount != FRAGS_SPECTATOR)
 285         {
 286                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 287                 if(!gameover)
 288                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 289                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 290
 291                 if(this.just_joined == false) {
 292                         LogTeamchange(this.playerid, -1, 4);
 293                 } else
 294                         this.just_joined = false;
 295         }
 296
 297         accuracy_resend(this);
 298
 299         this.spectatortime = time;
 300         if(this.bot_attack)
 301                 IL_REMOVE(g_bot_targets, this);
 302         this.bot_attack = false;
 303     this.hud = HUD_NORMAL;
 304         TRANSMUTE(Observer, this);
 305         this.iscreature = false;
 306         this.teleportable = TELEPORT_SIMPLE;
 307         if(this.damagedbycontents)
 308                 IL_REMOVE(g_damagedbycontents, this);
 309         this.damagedbycontents = false;
 310         this.health = FRAGS_SPECTATOR;
 311         SetSpectatee_status(this, etof(this));
 312         this.takedamage = DAMAGE_NO;
 313         this.solid = SOLID_NOT;
 314         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 315         this.flags = FL_CLIENT | FL_NOTARGET;
 316         this.armorvalue = 666;
 317         this.effects = 0;
 318         this.armorvalue = autocvar_g_balance_armor_start;
 319         this.pauserotarmor_finished = 0;
 320         this.pauserothealth_finished = 0;
 321         this.pauseregen_finished = 0;
 322         this.damageforcescale = 0;
 323         this.death_time = 0;
 324         this.respawn_flags = 0;
 325         this.respawn_time = 0;
 326         this.stat_respawn_time = 0;
 327         this.alpha = 0;
 328         this.scale = 0;
 329         this.fade_time = 0;
 330         this.pain_frame = 0;
 331         this.pain_finished = 0;
 332         this.strength_finished = 0;
 333         this.invincible_finished = 0;
 334         this.superweapons_finished = 0;
 335         this.pushltime = 0;
 336         this.istypefrag = 0;
 337         setthink(this, func_null);
 338         this.nextthink = 0;
 339         this.hook_time = 0;
 340         this.deadflag = DEAD_NO;
 341         this.crouch = false;
 342         this.revive_progress = 0;
 343         this.revival_time = 0;
 344
 345         this.items = 0;
 346         this.weapons = '0 0 0';
 347         this.drawonlytoclient = this;
 348
 349         this.weaponname = "";
 350         this.weaponmodel = "";
 351         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 352         {
 353                 this.weaponentities[slot] = NULL;
 354         }
 355         this.exteriorweaponentity = NULL;
 356         this.killcount = FRAGS_SPECTATOR;
 357         this.velocity = '0 0 0';
 358         this.avelocity = '0 0 0';
 359         this.punchangle = '0 0 0';
 360         this.punchvector = '0 0 0';
 361         this.oldvelocity = this.velocity;
 362         this.fire_endtime = -1;
 363         this.event_damage = func_null;
 364
 365         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 366         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 367         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 368 }
 369
 370 int player_getspecies(entity this)
 371 {
 372         get_model_parameters(this.model, this.skin);
 373         int s = get_model_parameters_species;
 374         get_model_parameters(string_null, 0);
 375         if (s < 0) return SPECIES_HUMAN;
 376         return s;
 377 }
 378
 379 .float model_randomizer;
 380 void FixPlayermodel(entity player)
 381 {
 382         string defaultmodel = "";
 383         int defaultskin = 0;
 384         if(autocvar_sv_defaultcharacter)
 385         {
 386                 if(teamplay)
 387                 {
 388                         string s = Static_Team_ColorName_Lower(player.team);
 389                         if (s != "neutral")
 390                         {
 391                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 392                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 393                         }
 394                 }
 395
 396                 if(defaultmodel == "")
 397                 {
 398                         defaultmodel = autocvar_sv_defaultplayermodel;
 399                         defaultskin = autocvar_sv_defaultplayerskin;
 400                 }
 401
 402                 int n = tokenize_console(defaultmodel);
 403                 if(n > 0)
 404                 {
 405                         defaultmodel = argv(floor(n * player.model_randomizer));
 406                         // However, do NOT randomize if the player-selected model is in the list.
 407                         for (int i = 0; i < n; ++i)
 408                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 409                                         defaultmodel = argv(i);
 410                 }
 411
 412                 int i = strstrofs(defaultmodel, ":", 0);
 413                 if(i >= 0)
 414                 {
 415                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 416                         defaultmodel = substring(defaultmodel, 0, i);
 417                 }
 418         }
 419         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 420         {
 421                 if(teamplay)
 422                 {
 423                         string s = Static_Team_ColorName_Lower(player.team);
 424                         if (s != "neutral")
 425                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 426                 }
 427
 428                 if(!defaultskin)
 429                         defaultskin = autocvar_sv_defaultplayerskin;
 430         }
 431
 432         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 433         defaultmodel = M_ARGV(0, string);
 434         defaultskin = M_ARGV(1, int);
 435
 436         bool chmdl = false;
 437         int oldskin;
 438         if(defaultmodel != "")
 439         {
 440                 if (defaultmodel != player.model)
 441                 {
 442                         vector m1 = player.mins;
 443                         vector m2 = player.maxs;
 444                         setplayermodel (player, defaultmodel);
 445                         setsize (player, m1, m2);
 446                         chmdl = true;
 447                 }
 448
 449                 oldskin = player.skin;
 450                 player.skin = defaultskin;
 451         } else {
 452                 if (player.playermodel != player.model || player.playermodel == "")
 453                 {
 454                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 455                         vector m1 = player.mins;
 456                         vector m2 = player.maxs;
 457                         setplayermodel (player, player.playermodel);
 458                         setsize (player, m1, m2);
 459                         chmdl = true;
 460                 }
 461
 462                 if(!autocvar_sv_defaultcharacterskin)
 463                 {
 464                         oldskin = player.skin;
 465                         player.skin = stof(player.playerskin);
 466                 }
 467                 else
 468                 {
 469                         oldskin = player.skin;
 470                         player.skin = defaultskin;
 471                 }
 472         }
 473
 474         if(chmdl || oldskin != player.skin) // model or skin has changed
 475         {
 476                 player.species = player_getspecies(player); // update species
 477                 if(!autocvar_g_debug_globalsounds)
 478                         UpdatePlayerSounds(player); // update skin sounds
 479         }
 480
 481         if(!teamplay)
 482                 if(strlen(autocvar_sv_defaultplayercolors))
 483                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 484                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 485 }
 486
 487
 488 /** Called when a client spawns in the server */
 489 void PutClientInServer(entity this)
 490 {
 491         if (IS_BOT_CLIENT(this)) {
 492                 TRANSMUTE(Player, this);
 493         } else if (IS_REAL_CLIENT(this)) {
 494                 msg_entity = this;
 495                 WriteByte(MSG_ONE, SVC_SETVIEW);
 496                 WriteEntity(MSG_ONE, this);
 497         }
 498         if (gameover) {
 499                 TRANSMUTE(Observer, this);
 500         }
 501
 502         SetSpectatee(this, NULL);
 503
 504         // reset player keys
 505         this.itemkeys = 0;
 506
 507         MUTATOR_CALLHOOK(PutClientInServer, this);
 508
 509         if (IS_OBSERVER(this)) {
 510                 PutObserverInServer(this);
 511         } else if (IS_PLAYER(this)) {
 512                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 513
 514                 PlayerState_attach(this);
 515                 accuracy_resend(this);
 516
 517                 if (this.team < 0)
 518                         JoinBestTeam(this, false, true);
 519
 520                 entity spot = SelectSpawnPoint(this, false);
 521                 if (!spot) {
 522                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 523                         return; // spawn failed
 524                 }
 525
 526                 TRANSMUTE(Player, this);
 527
 528                 this.wasplayer = true;
 529                 this.iscreature = true;
 530                 this.teleportable = TELEPORT_NORMAL;
 531                 if(!this.damagedbycontents)
 532                         IL_PUSH(g_damagedbycontents, this);
 533                 this.damagedbycontents = true;
 534                 set_movetype(this, MOVETYPE_WALK);
 535                 this.solid = SOLID_SLIDEBOX;
 536                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 537                 if (autocvar_g_playerclip_collisions)
 538                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 539                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 540                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 541                 this.frags = FRAGS_PLAYER;
 542                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 543                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 544                 if (autocvar__notarget)
 545                         this.flags |= FL_NOTARGET;
 546                 this.takedamage = DAMAGE_AIM;
 547                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 548                 this.dmg = 2; // WTF
 549
 550                 if (warmup_stage) {
 551                         this.ammo_shells = warmup_start_ammo_shells;
 552                         this.ammo_nails = warmup_start_ammo_nails;
 553                         this.ammo_rockets = warmup_start_ammo_rockets;
 554                         this.ammo_cells = warmup_start_ammo_cells;
 555                         this.ammo_plasma = warmup_start_ammo_plasma;
 556                         this.ammo_fuel = warmup_start_ammo_fuel;
 557                         this.health = warmup_start_health;
 558                         this.armorvalue = warmup_start_armorvalue;
 559                         this.weapons = WARMUP_START_WEAPONS;
 560                 } else {
 561                         this.ammo_shells = start_ammo_shells;
 562                         this.ammo_nails = start_ammo_nails;
 563                         this.ammo_rockets = start_ammo_rockets;
 564                         this.ammo_cells = start_ammo_cells;
 565                         this.ammo_plasma = start_ammo_plasma;
 566                         this.ammo_fuel = start_ammo_fuel;
 567                         this.health = start_health;
 568                         this.armorvalue = start_armorvalue;
 569                         this.weapons = start_weapons;
 570                 }
 571                 SetSpectatee_status(this, 0);
 572
 573                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 574
 575                 this.items = start_items;
 576
 577                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 578                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 579                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 580                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 581                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 582                 // extend the pause of rotting if client was reset at the beginning of the countdown
 583                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 584                         float f = game_starttime - time;
 585                         this.spawnshieldtime += f;
 586                         this.pauserotarmor_finished += f;
 587                         this.pauserothealth_finished += f;
 588                         this.pauseregen_finished += f;
 589                 }
 590                 this.damageforcescale = 2;
 591                 this.death_time = 0;
 592                 this.respawn_flags = 0;
 593                 this.respawn_time = 0;
 594                 this.stat_respawn_time = 0;
 595                 this.scale = autocvar_sv_player_scale;
 596                 this.fade_time = 0;
 597                 this.pain_frame = 0;
 598                 this.pain_finished = 0;
 599                 this.pushltime = 0;
 600                 setthink(this, func_null); // players have no think function
 601                 this.nextthink = 0;
 602                 this.dmg_team = 0;
 603                 this.ballistics_density = autocvar_g_ballistics_density_player;
 604
 605                 this.deadflag = DEAD_NO;
 606
 607                 this.angles = spot.angles;
 608                 this.angles_z = 0; // never spawn tilted even if the spot says to
 609                 if (IS_BOT_CLIENT(this))
 610                         this.v_angle = this.angles;
 611                 this.fixangle = true; // turn this way immediately
 612                 this.oldvelocity = this.velocity = '0 0 0';
 613                 this.avelocity = '0 0 0';
 614                 this.punchangle = '0 0 0';
 615                 this.punchvector = '0 0 0';
 616
 617                 this.strength_finished = 0;
 618                 this.invincible_finished = 0;
 619                 this.fire_endtime = -1;
 620                 this.revive_progress = 0;
 621                 this.revival_time = 0;
 622                 this.air_finished = time + 12;
 623
 624                 entity spawnevent = new_pure(spawnevent);
 625                 spawnevent.owner = this;
 626                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 627
 628                 // Cut off any still running player sounds.
 629                 stopsound(this, CH_PLAYER_SINGLE);
 630
 631                 this.model = "";
 632                 FixPlayermodel(this);
 633                 this.drawonlytoclient = NULL;
 634
 635                 this.viewloc = NULL;
 636
 637                 this.crouch = false;
 638                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 639                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 640                 this.spawnorigin = spot.origin;
 641                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 642                 // don't reset back to last position, even if new position is stuck in solid
 643                 this.oldorigin = this.origin;
 644                 this.prevorigin = this.origin;
 645                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 646                 if(this.conveyor)
 647                         IL_REMOVE(g_conveyed, this);
 648                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 649                 this.hud = HUD_NORMAL;
 650
 651                 this.event_damage = PlayerDamage;
 652
 653                 if(!this.bot_attack)
 654                         IL_PUSH(g_bot_targets, this);
 655                 this.bot_attack = true;
 656                 this.monster_attack = true;
 657
 658                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 659
 660                 if (this.killcount == FRAGS_SPECTATOR) {
 661                         PlayerScore_Clear(this);
 662                         this.killcount = 0;
 663                 }
 664
 665                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 666                 {
 667                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 668                 }
 669                 this.alpha = default_player_alpha;
 670                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 671                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 672
 673                 this.speedrunning = false;
 674
 675                 target_voicescript_clear(this);
 676
 677                 // reset fields the weapons may use
 678                 FOREACH(Weapons, true, LAMBDA(
 679                         it.wr_resetplayer(it, this);
 680                         // reload all reloadable weapons
 681                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 682                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 683                         }
 684                 ));
 685
 686                 {
 687                         string s = spot.target;
 688                         spot.target = string_null;
 689                         SUB_UseTargets(spot, this, NULL);
 690                         spot.target = s;
 691                 }
 692
 693                 Unfreeze(this);
 694
 695                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 696
 697                 if (autocvar_spawn_debug)
 698                 {
 699                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 700                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 701                 }
 702
 703                 PS(this).m_switchweapon = w_getbestweapon(this);
 704                 this.cnt = -1; // W_LastWeapon will not complain
 705                 PS(this).m_weapon = WEP_Null;
 706                 this.weaponname = "";
 707                 PS(this).m_switchingweapon = WEP_Null;
 708
 709                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 710
 711                 if (!warmup_stage && !this.alivetime)
 712                         this.alivetime = time;
 713
 714                 antilag_clear(this, CS(this));
 715         }
 716 }
 717
 718 void ClientInit_misc(entity this);
 719
 720 // TODO do we need all these fields, or should we stop autodetecting runtime
 721 // changes and just have a console command to update this?
 722 bool ClientInit_SendEntity(entity this, entity to, int sf)
 723 {
 724         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 725         return = true;
 726         msg_entity = to;
 727         // MSG_INIT replacement
 728         // TODO: make easier to use
 729         Registry_send_all();
 730         W_PROP_reload(MSG_ONE, to);
 731         ClientInit_misc(this);
 732         MUTATOR_CALLHOOK(Ent_Init);
 733 }
 734 void ClientInit_misc(entity this)
 735 {
 736         int channel = MSG_ONE;
 737         WriteHeader(channel, ENT_CLIENT_INIT);
 738         WriteByte(channel, g_nexball_meter_period * 32);
 739         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 740         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 741         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 742         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 743         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 744         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 745         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 746         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 747
 748         if(sv_foginterval && world.fog != "")
 749                 WriteString(channel, world.fog);
 750         else
 751                 WriteString(channel, "");
 752         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 753         WriteByte(channel, serverflags);
 754         WriteCoord(channel, autocvar_g_trueaim_minrange);
 755 }
 756
 757 void ClientInit_CheckUpdate(entity this)
 758 {
 759         this.nextthink = time;
 760         if(this.count != autocvar_g_balance_armor_blockpercent)
 761         {
 762                 this.count = autocvar_g_balance_armor_blockpercent;
 763                 this.SendFlags |= 1;
 764         }
 765 }
 766
 767 void ClientInit_Spawn()
 768 {
 769         entity e = new_pure(clientinit);
 770         setthink(e, ClientInit_CheckUpdate);
 771         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 772
 773         ClientInit_CheckUpdate(e);
 774 }
 775
 776 /*
 777 =============
 778 SetNewParms
 779 =============
 780 */
 781 void SetNewParms ()
 782 {
 783         // initialize parms for a new player
 784         parm1 = -(86400 * 366);
 785
 786         MUTATOR_CALLHOOK(SetNewParms);
 787 }
 788
 789 /*
 790 =============
 791 SetChangeParms
 792 =============
 793 */
 794 void SetChangeParms (entity this)
 795 {
 796         // save parms for level change
 797         parm1 = this.parm_idlesince - time;
 798
 799         MUTATOR_CALLHOOK(SetChangeParms);
 800 }
 801
 802 /*
 803 =============
 804 DecodeLevelParms
 805 =============
 806 */
 807 void DecodeLevelParms(entity this)
 808 {
 809         // load parms
 810         this.parm_idlesince = parm1;
 811         if (this.parm_idlesince == -(86400 * 366))
 812                 this.parm_idlesince = time;
 813
 814         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 815         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 816
 817         MUTATOR_CALLHOOK(DecodeLevelParms);
 818 }
 819
 820 /*
 821 =============
 822 ClientKill
 823
 824 Called when a client types 'kill' in the console
 825 =============
 826 */
 827
 828 .float clientkill_nexttime;
 829 void ClientKill_Now_TeamChange(entity this)
 830 {
 831         if(this.killindicator_teamchange == -1)
 832         {
 833                 JoinBestTeam( this, false, true );
 834         }
 835         else if(this.killindicator_teamchange == -2)
 836         {
 837                 if(blockSpectators)
 838                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 839                 PutObserverInServer(this);
 840         }
 841         else
 842                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 843         this.killindicator_teamchange = 0;
 844 }
 845
 846 void ClientKill_Now(entity this)
 847 {
 848         if(this.vehicle)
 849         {
 850             vehicles_exit(this.vehicle, VHEF_RELEASE);
 851             if(!this.killindicator_teamchange)
 852             {
 853             this.vehicle_health = -1;
 854             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 855             }
 856         }
 857
 858         if(this.killindicator && !wasfreed(this.killindicator))
 859                 delete(this.killindicator);
 860
 861         this.killindicator = NULL;
 862
 863         if(this.killindicator_teamchange)
 864                 ClientKill_Now_TeamChange(this);
 865
 866         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 867                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 868
 869         // now I am sure the player IS dead
 870 }
 871 void KillIndicator_Think(entity this)
 872 {
 873         if (gameover)
 874         {
 875                 this.owner.killindicator = NULL;
 876                 delete(this);
 877                 return;
 878         }
 879
 880         if (this.owner.alpha < 0 && !this.owner.vehicle)
 881         {
 882                 this.owner.killindicator = NULL;
 883                 delete(this);
 884                 return;
 885         }
 886
 887         if(this.cnt <= 0)
 888         {
 889                 ClientKill_Now(this.owner);
 890                 return;
 891         }
 892     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 893     {
 894         this.nextthink = time + 1;
 895         this.cnt -= 1;
 896     }
 897         else
 898         {
 899                 if(this.cnt <= 10)
 900                         setmodel(this, MDL_NUM(this.cnt));
 901                 if(IS_REAL_CLIENT(this.owner))
 902                 {
 903                         if(this.cnt <= 10)
 904                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 905                 }
 906                 this.nextthink = time + 1;
 907                 this.cnt -= 1;
 908         }
 909 }
 910
 911 float clientkilltime;
 912 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 913 {
 914         float killtime;
 915         float starttime;
 916
 917         if (gameover)
 918                 return;
 919
 920         killtime = autocvar_g_balance_kill_delay;
 921
 922         if(g_race_qualifying || g_cts)
 923                 killtime = 0;
 924
 925     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 926         return;
 927
 928         this.killindicator_teamchange = targetteam;
 929
 930     if(!this.killindicator)
 931         {
 932                 if(!IS_DEAD(this))
 933                 {
 934                         killtime = max(killtime, this.clientkill_nexttime - time);
 935                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 936                 }
 937
 938                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 939                 {
 940                         ClientKill_Now(this);
 941                 }
 942                 else
 943                 {
 944                         starttime = max(time, clientkilltime);
 945
 946                         this.killindicator = spawn();
 947                         this.killindicator.owner = this;
 948                         this.killindicator.scale = 0.5;
 949                         setattachment(this.killindicator, this, "");
 950                         setorigin(this.killindicator, '0 0 52');
 951                         setthink(this.killindicator, KillIndicator_Think);
 952                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 953                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 954                         this.killindicator.cnt = ceil(killtime);
 955                         this.killindicator.count = bound(0, ceil(killtime), 10);
 956                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 957
 958                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 959                         {
 960                                 it.killindicator = spawn();
 961                                 it.killindicator.owner = it;
 962                                 it.killindicator.scale = 0.5;
 963                                 setattachment(it.killindicator, it, "");
 964                                 setorigin(it.killindicator, '0 0 52');
 965                                 setthink(it.killindicator, KillIndicator_Think);
 966                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 967                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 968                                 it.killindicator.cnt = ceil(killtime);
 969                         });
 970                         this.lip = 0;
 971                 }
 972         }
 973         if(this.killindicator)
 974         {
 975                 if(targetteam == 0) // just die
 976                 {
 977                         this.killindicator.colormod = '0 0 0';
 978                         if(IS_REAL_CLIENT(this))
 979                         if(this.killindicator.cnt > 0)
 980                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 981                 }
 982                 else if(targetteam == -1) // auto
 983                 {
 984                         this.killindicator.colormod = '0 1 0';
 985                         if(IS_REAL_CLIENT(this))
 986                         if(this.killindicator.cnt > 0)
 987                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 988                 }
 989                 else if(targetteam == -2) // spectate
 990                 {
 991                         this.killindicator.colormod = '0.5 0.5 0.5';
 992                         if(IS_REAL_CLIENT(this))
 993                         if(this.killindicator.cnt > 0)
 994                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 995                 }
 996                 else
 997                 {
 998                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 999                         if(IS_REAL_CLIENT(this))
1000                         if(this.killindicator.cnt > 0)
1001                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1002                 }
1003         }
1004
1005 }
1006
1007 void ClientKill (entity this)
1008 {
1009         if(gameover) return;
1010         if(this.player_blocked) return;
1011         if(STAT(FROZEN, this)) return;
1012
1013         ClientKill_TeamChange(this, 0);
1014 }
1015
1016 void FixClientCvars(entity e)
1017 {
1018         // send prediction settings to the client
1019         stuffcmd(e, "\nin_bindmap 0 0\n");
1020         if(autocvar_g_antilag == 3) // client side hitscan
1021                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1022         if(autocvar_sv_gentle)
1023                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1024
1025         MUTATOR_CALLHOOK(FixClientCvars, e);
1026 }
1027
1028 float PlayerInIDList(entity p, string idlist)
1029 {
1030         float n, i;
1031         string s;
1032
1033         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1034         if (!p.crypto_idfp)
1035                 return 0;
1036
1037         // this function allows abbreviated player IDs too!
1038         n = tokenize_console(idlist);
1039         for(i = 0; i < n; ++i)
1040         {
1041                 s = argv(i);
1042                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1043                         return 1;
1044         }
1045
1046         return 0;
1047 }
1048
1049 #ifdef DP_EXT_PRECONNECT
1050 /*
1051 =============
1052 ClientPreConnect
1053
1054 Called once (not at each match start) when a client begins a connection to the server
1055 =============
1056 */
1057 void ClientPreConnect(entity this)
1058 {
1059         if(autocvar_sv_eventlog)
1060         {
1061                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1062                         this.playerid,
1063                         etof(this),
1064                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1065                 ));
1066         }
1067 }
1068 #endif
1069
1070 /**
1071 =============
1072 ClientConnect
1073
1074 Called when a client connects to the server
1075 =============
1076 */
1077 void ClientConnect(entity this)
1078 {
1079         if (Ban_MaybeEnforceBanOnce(this)) return;
1080         assert(!IS_CLIENT(this), return);
1081         this.flags |= FL_CLIENT;
1082         assert(player_count >= 0, player_count = 0);
1083
1084 #ifdef WATERMARK
1085         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1086 #endif
1087         this.version_nagtime = time + 10 + random() * 10;
1088         TRANSMUTE(Client, this);
1089
1090         // identify the right forced team
1091         if (autocvar_g_campaign)
1092         {
1093                 if (IS_REAL_CLIENT(this)) // only players, not bots
1094                 {
1095                         switch (autocvar_g_campaign_forceteam)
1096                         {
1097                                 case 1: this.team_forced = NUM_TEAM_1; break;
1098                                 case 2: this.team_forced = NUM_TEAM_2; break;
1099                                 case 3: this.team_forced = NUM_TEAM_3; break;
1100                                 case 4: this.team_forced = NUM_TEAM_4; break;
1101                                 default: this.team_forced = 0;
1102                         }
1103                 }
1104         }
1105         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1106         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1107         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1108         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1109         else switch (autocvar_g_forced_team_otherwise)
1110         {
1111                 default: this.team_forced = 0; break;
1112                 case "red": this.team_forced = NUM_TEAM_1; break;
1113                 case "blue": this.team_forced = NUM_TEAM_2; break;
1114                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1115                 case "pink": this.team_forced = NUM_TEAM_4; break;
1116                 case "spectate":
1117                 case "spectator":
1118                         this.team_forced = -1;
1119                         break;
1120         }
1121         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1122
1123     {
1124         int id = this.playerid;
1125         this.playerid = 0; // silent
1126             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1127             this.playerid = id;
1128     }
1129
1130         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1131                 TRANSMUTE(Observer, this);
1132         } else {
1133                 if (!teamplay || autocvar_g_balance_teams) {
1134                         TRANSMUTE(Player, this);
1135                         campaign_bots_may_start = true;
1136                 } else {
1137                         TRANSMUTE(Observer, this); // do it anyway
1138                 }
1139         }
1140
1141         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1142
1143         // always track bots, don't ask for cl_allow_uidtracking
1144     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1145
1146         if (autocvar_sv_eventlog)
1147                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1148
1149         LogTeamchange(this.playerid, this.team, 1);
1150
1151         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1152
1153         this.netname_previous = strzone(this.netname);
1154
1155         if(teamplay && IS_PLAYER(this))
1156                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1157         else
1158                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1159
1160         stuffcmd(this, clientstuff, "\n");
1161         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1162
1163         FixClientCvars(this);
1164
1165         // get version info from player
1166         stuffcmd(this, "cmd clientversion $gameversion\n");
1167
1168         // notify about available teams
1169         if (teamplay)
1170         {
1171                 CheckAllowedTeams(this);
1172                 int t = 0;
1173                 if (c1 >= 0) t |= BIT(0);
1174                 if (c2 >= 0) t |= BIT(1);
1175                 if (c3 >= 0) t |= BIT(2);
1176                 if (c4 >= 0) t |= BIT(3);
1177                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1178         }
1179         else
1180         {
1181                 stuffcmd(this, "set _teams_available 0\n");
1182         }
1183
1184         bot_relinkplayerlist();
1185
1186         this.spectatortime = time;
1187         if (blockSpectators)
1188         {
1189                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1190         }
1191
1192         this.jointime = time;
1193         this.allowed_timeouts = autocvar_sv_timeout_number;
1194
1195         if (IS_REAL_CLIENT(this))
1196         {
1197                 if (g_weaponarena_weapons == WEPSET(TUBA))
1198                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1199         }
1200
1201         if (!sv_foginterval && world.fog != "")
1202                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1203
1204         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1205                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1206                         send_CSQC_teamnagger();
1207
1208         CSQCMODEL_AUTOINIT(this);
1209
1210         this.model_randomizer = random();
1211
1212         if (IS_REAL_CLIENT(this))
1213                 sv_notice_join(this);
1214
1215         // update physics stats (players can spawn before physics runs)
1216         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1217
1218         IL_EACH(g_initforplayer, it.init_for_player, {
1219                 it.init_for_player(it, this);
1220         });
1221
1222         MUTATOR_CALLHOOK(ClientConnect, this);
1223
1224         if (IS_REAL_CLIENT(this))
1225         {
1226                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1227                 {
1228                         this.motd_actived_time = -1;
1229                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1230                 }
1231         }
1232 }
1233 /*
1234 =============
1235 ClientDisconnect
1236
1237 Called when a client disconnects from the server
1238 =============
1239 */
1240 .entity chatbubbleentity;
1241 void ReadyCount();
1242 void ClientDisconnect(entity this)
1243 {
1244         assert(IS_CLIENT(this), return);
1245
1246         PlayerStats_GameReport_FinalizePlayer(this);
1247         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1248         if (this.active_minigame) part_minigame(this);
1249         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1250
1251         if (autocvar_sv_eventlog)
1252                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1253
1254         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1255
1256         SetSpectatee(this, NULL);
1257
1258     MUTATOR_CALLHOOK(ClientDisconnect, this);
1259
1260         ClientState_detach(this);
1261
1262         Portal_ClearAll(this);
1263
1264         Unfreeze(this);
1265
1266         RemoveGrapplingHook(this);
1267
1268         // Here, everything has been done that requires this player to be a client.
1269
1270         this.flags &= ~FL_CLIENT;
1271
1272         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1273         if (this.killindicator) delete(this.killindicator);
1274
1275         WaypointSprite_PlayerGone(this);
1276
1277         bot_relinkplayerlist();
1278
1279         if (this.netname_previous) strunzone(this.netname_previous);
1280         if (this.clientstatus) strunzone(this.clientstatus);
1281         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1282         if (this.personal) delete(this.personal);
1283
1284         this.playerid = 0;
1285         ReadyCount();
1286         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1287
1288         ONREMOVE(this);
1289 }
1290
1291 void ChatBubbleThink(entity this)
1292 {
1293         this.nextthink = time;
1294         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1295         {
1296                 if(this.owner) // but why can that ever be NULL?
1297                         this.owner.chatbubbleentity = NULL;
1298                 delete(this);
1299                 return;
1300         }
1301
1302         this.mdl = "";
1303
1304         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1305         {
1306                 if ( this.owner.active_minigame )
1307                         this.mdl = "models/sprites/minigame_busy.iqm";
1308                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1309                         this.mdl = "models/misc/chatbubble.spr";
1310         }
1311
1312         if ( this.model != this.mdl )
1313                 _setmodel(this, this.mdl);
1314
1315 }
1316
1317 void UpdateChatBubble(entity this)
1318 {
1319         if (this.alpha < 0)
1320                 return;
1321         // spawn a chatbubble entity if needed
1322         if (!this.chatbubbleentity)
1323         {
1324                 this.chatbubbleentity = new(chatbubbleentity);
1325                 this.chatbubbleentity.owner = this;
1326                 this.chatbubbleentity.exteriormodeltoclient = this;
1327                 setthink(this.chatbubbleentity, ChatBubbleThink);
1328                 this.chatbubbleentity.nextthink = time;
1329                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1330                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1331                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1332                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1333                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1334                 //this.chatbubbleentity.model = "";
1335                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1336         }
1337 }
1338
1339
1340 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1341 // added to the model skins
1342 /*void UpdateColorModHack()
1343 {
1344         float c;
1345         c = this.clientcolors & 15;
1346         // LordHavoc: only bothering to support white, green, red, yellow, blue
1347              if (!teamplay) this.colormod = '0 0 0';
1348         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1349         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1350         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1351         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1352         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1353         else this.colormod = '1 1 1';
1354 }*/
1355
1356 void respawn(entity this)
1357 {
1358         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1359         {
1360                 this.solid = SOLID_NOT;
1361                 this.takedamage = DAMAGE_NO;
1362                 set_movetype(this, MOVETYPE_FLY);
1363                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1364                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1365                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1366                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1367                 if(autocvar_g_respawn_ghosts_maxtime)
1368                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1369         }
1370
1371         CopyBody(this, 1);
1372
1373         this.effects |= EF_NODRAW; // prevent another CopyBody
1374         PutClientInServer(this);
1375 }
1376
1377 void play_countdown(entity this, float finished, Sound samp)
1378 {
1379     TC(Sound, samp);
1380         if(IS_REAL_CLIENT(this))
1381                 if(floor(finished - time - frametime) != floor(finished - time))
1382                         if(finished - time < 6)
1383                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1384 }
1385
1386 void player_powerups(entity this)
1387 {
1388         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1389         int items_prev = this.items;
1390
1391         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1392                 this.modelflags |= MF_ROCKET;
1393         else
1394                 this.modelflags &= ~MF_ROCKET;
1395
1396         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1397
1398         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1399                 return;
1400
1401         Fire_ApplyDamage(this);
1402         Fire_ApplyEffect(this);
1403
1404         if (!g_instagib)
1405         {
1406                 if (this.items & ITEM_Strength.m_itemid)
1407                 {
1408                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1409                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1410                         if (time > this.strength_finished)
1411                         {
1412                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1413                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1414                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1415                         }
1416                 }
1417                 else
1418                 {
1419                         if (time < this.strength_finished)
1420                         {
1421                                 this.items = this.items | ITEM_Strength.m_itemid;
1422                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1423                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1424                         }
1425                 }
1426                 if (this.items & ITEM_Shield.m_itemid)
1427                 {
1428                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1429                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1430                         if (time > this.invincible_finished)
1431                         {
1432                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1433                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1434                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1435                         }
1436                 }
1437                 else
1438                 {
1439                         if (time < this.invincible_finished)
1440                         {
1441                                 this.items = this.items | ITEM_Shield.m_itemid;
1442                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1443                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1444                         }
1445                 }
1446                 if (this.items & IT_SUPERWEAPON)
1447                 {
1448                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1449                         {
1450                                 this.superweapons_finished = 0;
1451                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1452                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1453                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1454                         }
1455                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1456                         {
1457                                 // don't let them run out
1458                         }
1459                         else
1460                         {
1461                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1462                                 if (time > this.superweapons_finished)
1463                                 {
1464                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1465                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1466                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1467                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1468                                 }
1469                         }
1470                 }
1471                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1472                 {
1473                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1474                         {
1475                                 this.items = this.items | IT_SUPERWEAPON;
1476                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1477                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1478                         }
1479                         else
1480                         {
1481                                 this.superweapons_finished = 0;
1482                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1483                         }
1484                 }
1485                 else
1486                 {
1487                         this.superweapons_finished = 0;
1488                 }
1489         }
1490
1491         if(autocvar_g_nodepthtestplayers)
1492                 this.effects = this.effects | EF_NODEPTHTEST;
1493
1494         if(autocvar_g_fullbrightplayers)
1495                 this.effects = this.effects | EF_FULLBRIGHT;
1496
1497         if (time >= game_starttime)
1498         if (time < this.spawnshieldtime)
1499                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1500
1501         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1502 }
1503
1504 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1505 {
1506         if(current > stable)
1507                 return current;
1508         else if(current > stable - 0.25) // when close enough, "snap"
1509                 return stable;
1510         else
1511                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1512 }
1513
1514 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1515 {
1516         if(current < stable)
1517                 return current;
1518         else if(current < stable + 0.25) // when close enough, "snap"
1519                 return stable;
1520         else
1521                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1522 }
1523
1524 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1525 {
1526         if(current > rotstable)
1527         {
1528                 if(rotframetime > 0)
1529                 {
1530                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1531                         current = max(rotstable, current - rotlinear * rotframetime);
1532                 }
1533         }
1534         else if(current < regenstable)
1535         {
1536                 if(regenframetime > 0)
1537                 {
1538                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1539                         current = min(regenstable, current + regenlinear * regenframetime);
1540                 }
1541         }
1542
1543         if(current > limit)
1544                 current = limit;
1545
1546         return current;
1547 }
1548
1549 void player_regen(entity this)
1550 {
1551         float max_mod, regen_mod, rot_mod, limit_mod;
1552         max_mod = regen_mod = rot_mod = limit_mod = 1;
1553
1554         float regen_health = autocvar_g_balance_health_regen;
1555         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1556         float regen_health_rot = autocvar_g_balance_health_rot;
1557         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1558         float regen_health_stable = autocvar_g_balance_health_regenstable;
1559         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1560         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1561                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1562         max_mod = M_ARGV(1, float);
1563         regen_mod = M_ARGV(2, float);
1564         rot_mod = M_ARGV(3, float);
1565         limit_mod = M_ARGV(4, float);
1566         regen_health = M_ARGV(5, float);
1567         regen_health_linear = M_ARGV(6, float);
1568         regen_health_rot = M_ARGV(7, float);
1569         regen_health_rotlinear = M_ARGV(8, float);
1570         regen_health_stable = M_ARGV(9, float);
1571         regen_health_rotstable = M_ARGV(10, float);
1572
1573
1574         if(!mutator_returnvalue)
1575         if(!STAT(FROZEN, this))
1576         {
1577                 float mina, maxa, limith, limita;
1578                 maxa = autocvar_g_balance_armor_rotstable;
1579                 mina = autocvar_g_balance_armor_regenstable;
1580                 limith = autocvar_g_balance_health_limit;
1581                 limita = autocvar_g_balance_armor_limit;
1582
1583                 regen_health_rotstable = regen_health_rotstable * max_mod;
1584                 regen_health_stable = regen_health_stable * max_mod;
1585                 limith = limith * limit_mod;
1586                 limita = limita * limit_mod;
1587
1588                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1589                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1590         }
1591
1592         // if player rotted to death...  die!
1593         // check this outside above checks, as player may still be able to rot to death
1594         if(this.health < 1)
1595         {
1596                 if(this.vehicle)
1597                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1598                 if(this.event_damage)
1599                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1600         }
1601
1602         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1603         {
1604                 float minf, maxf, limitf;
1605
1606                 maxf = autocvar_g_balance_fuel_rotstable;
1607                 minf = autocvar_g_balance_fuel_regenstable;
1608                 limitf = autocvar_g_balance_fuel_limit;
1609
1610                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1611         }
1612 }
1613
1614 bool zoomstate_set;
1615 void SetZoomState(entity this, float newzoom)
1616 {
1617         if(newzoom != this.zoomstate)
1618         {
1619                 this.zoomstate = newzoom;
1620                 ClientData_Touch(this);
1621         }
1622         zoomstate_set = true;
1623 }
1624
1625 void GetPressedKeys(entity this)
1626 {
1627         MUTATOR_CALLHOOK(GetPressedKeys, this);
1628         int keys = STAT(PRESSED_KEYS, this);
1629         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1630         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1631         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1632         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1633
1634         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1635         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1636         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1637         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1638         this.pressedkeys = keys; // store for other users
1639
1640         STAT(PRESSED_KEYS, this) = keys;
1641 }
1642
1643 /*
1644 ======================
1645 spectate mode routines
1646 ======================
1647 */
1648
1649 void SpectateCopy(entity this, entity spectatee)
1650 {
1651     TC(Client, this); TC(Client, spectatee);
1652
1653         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1654         PS(this) = PS(spectatee);
1655         this.armortype = spectatee.armortype;
1656         this.armorvalue = spectatee.armorvalue;
1657         this.ammo_cells = spectatee.ammo_cells;
1658         this.ammo_plasma = spectatee.ammo_plasma;
1659         this.ammo_shells = spectatee.ammo_shells;
1660         this.ammo_nails = spectatee.ammo_nails;
1661         this.ammo_rockets = spectatee.ammo_rockets;
1662         this.ammo_fuel = spectatee.ammo_fuel;
1663         this.clip_load = spectatee.clip_load;
1664         this.clip_size = spectatee.clip_size;
1665         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1666         this.health = spectatee.health;
1667         this.impulse = 0;
1668         this.items = spectatee.items;
1669         this.last_pickup = spectatee.last_pickup;
1670         this.hit_time = spectatee.hit_time;
1671         this.strength_finished = spectatee.strength_finished;
1672         this.invincible_finished = spectatee.invincible_finished;
1673         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1674         this.weapons = spectatee.weapons;
1675         this.vortex_charge = spectatee.vortex_charge;
1676         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1677         this.hagar_load = spectatee.hagar_load;
1678         this.arc_heat_percent = spectatee.arc_heat_percent;
1679         this.minelayer_mines = spectatee.minelayer_mines;
1680         this.punchangle = spectatee.punchangle;
1681         this.view_ofs = spectatee.view_ofs;
1682         this.velocity = spectatee.velocity;
1683         this.dmg_take = spectatee.dmg_take;
1684         this.dmg_save = spectatee.dmg_save;
1685         this.dmg_inflictor = spectatee.dmg_inflictor;
1686         this.v_angle = spectatee.v_angle;
1687         this.angles = spectatee.v_angle;
1688         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1689         this.revive_progress = spectatee.revive_progress;
1690         this.viewloc = spectatee.viewloc;
1691         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1692                 this.fixangle = true;
1693         setorigin(this, spectatee.origin);
1694         setsize(this, spectatee.mins, spectatee.maxs);
1695         SetZoomState(this, spectatee.zoomstate);
1696
1697     anticheat_spectatecopy(this, spectatee);
1698         this.hud = spectatee.hud;
1699         if(spectatee.vehicle)
1700     {
1701         this.angles = spectatee.v_angle;
1702
1703         //this.fixangle = false;
1704         //this.velocity = spectatee.vehicle.velocity;
1705         this.vehicle_health = spectatee.vehicle_health;
1706         this.vehicle_shield = spectatee.vehicle_shield;
1707         this.vehicle_energy = spectatee.vehicle_energy;
1708         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1709         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1710         this.vehicle_reload1 = spectatee.vehicle_reload1;
1711         this.vehicle_reload2 = spectatee.vehicle_reload2;
1712
1713         //msg_entity = this;
1714
1715        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1716             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1717            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1718            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1719
1720         //WriteByte (MSG_ONE, SVC_SETVIEW);
1721         //    WriteEntity(MSG_ONE, this);
1722         //makevectors(spectatee.v_angle);
1723         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1724     }
1725 }
1726
1727 bool SpectateUpdate(entity this)
1728 {
1729         if(!this.enemy)
1730                 return false;
1731
1732         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1733         {
1734                 SetSpectatee(this, NULL);
1735                 return false;
1736         }
1737
1738         SpectateCopy(this, this.enemy);
1739
1740         return true;
1741 }
1742
1743 bool SpectateSet(entity this)
1744 {
1745         if(!IS_PLAYER(this.enemy))
1746                 return false;
1747
1748         ClientData_Touch(this.enemy);
1749
1750         msg_entity = this;
1751         WriteByte(MSG_ONE, SVC_SETVIEW);
1752         WriteEntity(MSG_ONE, this.enemy);
1753         set_movetype(this, MOVETYPE_NONE);
1754         accuracy_resend(this);
1755
1756         if(!SpectateUpdate(this))
1757                 PutObserverInServer(this);
1758
1759         return true;
1760 }
1761
1762 void SetSpectatee_status(entity this, int spectatee_num)
1763 {
1764         int oldspectatee_status = this.spectatee_status;
1765         this.spectatee_status = spectatee_num;
1766
1767         if (this.spectatee_status != oldspectatee_status)
1768         {
1769                 ClientData_Touch(this);
1770                 if (g_race || g_cts) race_InitSpectator();
1771         }
1772 }
1773
1774 void SetSpectatee(entity this, entity spectatee)
1775 {
1776         entity old_spectatee = this.enemy;
1777
1778         this.enemy = spectatee;
1779
1780         // WEAPONTODO
1781         // these are required to fix the spectator bug with arc
1782         if(old_spectatee)
1783         {
1784                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1785                 {
1786                         .entity weaponentity = weaponentities[slot];
1787                         if(old_spectatee.(weaponentity).arc_beam)
1788                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1789                 }
1790         }
1791         if(this.enemy)
1792         {
1793                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1794                 {
1795                         .entity weaponentity = weaponentities[slot];
1796                         if(this.enemy.(weaponentity).arc_beam)
1797                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1798                 }
1799         }
1800
1801         if (this.enemy)
1802                 SetSpectatee_status(this, etof(this.enemy));
1803
1804         // needed to update spectator list
1805         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1806 }
1807
1808 bool Spectate(entity this, entity pl)
1809 {
1810         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1811                 return false;
1812         pl = M_ARGV(1, entity);
1813
1814         SetSpectatee(this, pl);
1815         return SpectateSet(this);
1816 }
1817
1818 bool SpectateNext(entity this)
1819 {
1820         entity ent = find(this.enemy, classname, STR_PLAYER);
1821
1822         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1823                 ent = M_ARGV(1, entity);
1824         else if (!ent)
1825                 ent = find(ent, classname, STR_PLAYER);
1826
1827         if(ent) { SetSpectatee(this, ent); }
1828
1829         return SpectateSet(this);
1830 }
1831
1832 bool SpectatePrev(entity this)
1833 {
1834         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1835         entity ent = findchain(classname, STR_PLAYER);
1836         if (!ent) // no player
1837                 return false;
1838
1839         entity first = ent;
1840         // skip players until current spectated player
1841         if(this.enemy)
1842         while(ent && ent != this.enemy)
1843                 ent = ent.chain;
1844
1845         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1846         {
1847                 case MUT_SPECPREV_FOUND:
1848                     ent = M_ARGV(1, entity);
1849                     break;
1850                 case MUT_SPECPREV_RETURN:
1851                     return true;
1852                 case MUT_SPECPREV_CONTINUE:
1853                 default:
1854                 {
1855                         if(ent.chain)
1856                                 ent = ent.chain;
1857                         else
1858                                 ent = first;
1859                         break;
1860                 }
1861         }
1862
1863         SetSpectatee(this, ent);
1864         return SpectateSet(this);
1865 }
1866
1867 /*
1868 =============
1869 ShowRespawnCountdown()
1870
1871 Update a respawn countdown display.
1872 =============
1873 */
1874 void ShowRespawnCountdown(entity this)
1875 {
1876         float number;
1877         if(!IS_DEAD(this)) // just respawned?
1878                 return;
1879         else
1880         {
1881                 number = ceil(this.respawn_time - time);
1882                 if(number <= 0)
1883                         return;
1884                 if(number <= this.respawn_countdown)
1885                 {
1886                         this.respawn_countdown = number - 1;
1887                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1888                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1889                 }
1890         }
1891 }
1892
1893 .bool team_selected;
1894 bool ShowTeamSelection(entity this)
1895 {
1896         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1897                 return false;
1898         stuffcmd(this, "menu_showteamselect\n");
1899         return true;
1900 }
1901 void Join(entity this)
1902 {
1903         TRANSMUTE(Player, this);
1904
1905         if(!this.team_selected)
1906         if(autocvar_g_campaign || autocvar_g_balance_teams)
1907                 JoinBestTeam(this, false, true);
1908
1909         if(autocvar_g_campaign)
1910                 campaign_bots_may_start = true;
1911
1912         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1913
1914         PutClientInServer(this);
1915
1916         if(teamplay && this.team != -1)
1917                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1918         else
1919                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1920         this.team_selected = false;
1921 }
1922
1923 /**
1924  * Determines whether the player is allowed to join. This depends on cvar
1925  * g_maxplayers, if it isn't used this function always return true, otherwise
1926  * it checks whether the number of currently playing players exceeds g_maxplayers.
1927  * @return int number of free slots for players, 0 if none
1928  */
1929 int nJoinAllowed(entity this, entity ignore)
1930 {
1931         if(!ignore)
1932         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1933         // so report 0 free slots if restricted
1934         {
1935                 if(autocvar_g_forced_team_otherwise == "spectate")
1936                         return 0;
1937                 if(autocvar_g_forced_team_otherwise == "spectator")
1938                         return 0;
1939         }
1940
1941         if(this && this.team_forced < 0)
1942                 return 0; // forced spectators can never join
1943
1944         // TODO simplify this
1945         int totalClients = 0;
1946         int currentlyPlaying = 0;
1947         FOREACH_CLIENT(true, LAMBDA(
1948                 if(it != ignore)
1949                         ++totalClients;
1950                 if(IS_REAL_CLIENT(it))
1951                 if(IS_PLAYER(it) || it.caplayer)
1952                         ++currentlyPlaying;
1953         ));
1954
1955         float free_slots = 0;
1956         if (!autocvar_g_maxplayers)
1957                 free_slots = maxclients - totalClients;
1958         else if(currentlyPlaying < autocvar_g_maxplayers)
1959                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1960
1961         static float join_prevent_msg_time = 0;
1962         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1963         {
1964                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1965                 join_prevent_msg_time = time + 3;
1966         }
1967
1968         return free_slots;
1969 }
1970
1971 /**
1972  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1973  * g_maxplayers_spectator_blocktime seconds
1974  */
1975 void checkSpectatorBlock(entity this)
1976 {
1977         if(IS_SPEC(this) || IS_OBSERVER(this))
1978         if(!this.caplayer)
1979         if(IS_REAL_CLIENT(this))
1980         {
1981                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1982                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1983                         dropclient(this);
1984                 }
1985         }
1986 }
1987
1988 void PrintWelcomeMessage(entity this)
1989 {
1990         if(this.motd_actived_time == 0)
1991         {
1992                 if (autocvar_g_campaign) {
1993                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1994                                 this.motd_actived_time = time;
1995                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1996                         }
1997                 } else {
1998                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1999                                 this.motd_actived_time = time;
2000                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2001                         }
2002                 }
2003         }
2004         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2005         {
2006                 if (autocvar_g_campaign) {
2007                         if (PHYS_INPUT_BUTTON_INFO(this))
2008                                 this.motd_actived_time = time;
2009                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2010                                 this.motd_actived_time = 0;
2011                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2012                         }
2013                 } else {
2014                         if (PHYS_INPUT_BUTTON_INFO(this))
2015                                 this.motd_actived_time = time;
2016                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2017                                 this.motd_actived_time = 0;
2018                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2019                         }
2020                 }
2021         }
2022         else //if(this.motd_actived_time < 0) // just connected, motd is active
2023         {
2024                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2025                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2026                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2027                 {
2028                         // instanctly hide MOTD
2029                         this.motd_actived_time = 0;
2030                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2031                 }
2032         }
2033 }
2034
2035 bool joinAllowed(entity this)
2036 {
2037         if (this.version_mismatch) return false;
2038         if (!nJoinAllowed(this, this)) return false;
2039         if (teamplay && lockteams) return false;
2040         if (ShowTeamSelection(this)) return false;
2041         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2042         return true;
2043 }
2044
2045 void ObserverThink(entity this)
2046 {
2047         if ( this.impulse )
2048         {
2049                 MinigameImpulse(this, this.impulse);
2050                 this.impulse = 0;
2051         }
2052
2053         if (this.flags & FL_JUMPRELEASED) {
2054                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2055                         this.flags &= ~FL_JUMPRELEASED;
2056                         this.flags |= FL_SPAWNING;
2057                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2058                         this.flags &= ~FL_JUMPRELEASED;
2059                         if(SpectateNext(this)) {
2060                                 TRANSMUTE(Spectator, this);
2061                         }
2062                 } else {
2063                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2064                         set_movetype(this, preferred_movetype);
2065                 }
2066         } else {
2067                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2068                         this.flags |= FL_JUMPRELEASED;
2069                         if(this.flags & FL_SPAWNING)
2070                         {
2071                                 this.flags &= ~FL_SPAWNING;
2072                                 Join(this);
2073                                 return;
2074                         }
2075                 }
2076         }
2077 }
2078
2079 void SpectatorThink(entity this)
2080 {
2081         if ( this.impulse )
2082         {
2083                 if(MinigameImpulse(this, this.impulse))
2084                         this.impulse = 0;
2085
2086                 if (this.impulse == IMP_weapon_drop.impulse)
2087                 {
2088                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2089                         this.impulse = 0;
2090                         return;
2091                 }
2092         }
2093
2094         if (this.flags & FL_JUMPRELEASED) {
2095                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2096                         this.flags &= ~FL_JUMPRELEASED;
2097                         this.flags |= FL_SPAWNING;
2098                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2099                         this.flags &= ~FL_JUMPRELEASED;
2100                         if(SpectateNext(this)) {
2101                                 TRANSMUTE(Spectator, this);
2102                         } else {
2103                                 TRANSMUTE(Observer, this);
2104                                 PutClientInServer(this);
2105                         }
2106                         this.impulse = 0;
2107                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2108                         this.flags &= ~FL_JUMPRELEASED;
2109                         if(SpectatePrev(this)) {
2110                                 TRANSMUTE(Spectator, this);
2111                         } else {
2112                                 TRANSMUTE(Observer, this);
2113                                 PutClientInServer(this);
2114                         }
2115                         this.impulse = 0;
2116                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2117                         this.flags &= ~FL_JUMPRELEASED;
2118                         TRANSMUTE(Observer, this);
2119                         PutClientInServer(this);
2120                 } else {
2121                         if(!SpectateUpdate(this))
2122                                 PutObserverInServer(this);
2123                 }
2124         } else {
2125                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2126                         this.flags |= FL_JUMPRELEASED;
2127                         if(this.flags & FL_SPAWNING)
2128                         {
2129                                 this.flags &= ~FL_SPAWNING;
2130                                 Join(this);
2131                                 return;
2132                         }
2133                 }
2134                 if(!SpectateUpdate(this))
2135                         PutObserverInServer(this);
2136         }
2137
2138         this.flags |= FL_CLIENT | FL_NOTARGET;
2139 }
2140
2141 void vehicles_enter (entity pl, entity veh);
2142 void PlayerUseKey(entity this)
2143 {
2144         if (!IS_PLAYER(this))
2145                 return;
2146
2147         if(this.vehicle)
2148         {
2149                 if(!gameover)
2150                 {
2151                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2152                         return;
2153                 }
2154         }
2155         else if(autocvar_g_vehicles_enter)
2156         {
2157                 if(!STAT(FROZEN, this))
2158                 if(!IS_DEAD(this))
2159                 if(!gameover)
2160                 {
2161                         entity head, closest_target = NULL;
2162                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2163
2164                         while(head) // find the closest acceptable target to enter
2165                         {
2166                                 if(IS_VEHICLE(head))
2167                                 if(!IS_DEAD(head))
2168                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2169                                 if(head.takedamage != DAMAGE_NO)
2170                                 {
2171                                         if(closest_target)
2172                                         {
2173                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2174                                                 { closest_target = head; }
2175                                         }
2176                                         else { closest_target = head; }
2177                                 }
2178
2179                                 head = head.chain;
2180                         }
2181
2182                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2183                 }
2184         }
2185
2186         // a use key was pressed; call handlers
2187         MUTATOR_CALLHOOK(PlayerUseKey, this);
2188 }
2189
2190
2191 /*
2192 =============
2193 PlayerPreThink
2194
2195 Called every frame for each client before the physics are run
2196 =============
2197 */
2198 .float usekeypressed;
2199 .float last_vehiclecheck;
2200 .int items_added;
2201 void PlayerPreThink (entity this)
2202 {
2203         WarpZone_PlayerPhysics_FixVAngle(this);
2204
2205     STAT(GAMESTARTTIME, this) = game_starttime;
2206         STAT(ROUNDSTARTTIME, this) = round_starttime;
2207         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2208         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2209
2210         STAT(WEAPONSINMAP, this) = weaponsInMap;
2211
2212         if (frametime) {
2213                 // physics frames: update anticheat stuff
2214                 anticheat_prethink(this);
2215         }
2216
2217         if (blockSpectators && frametime) {
2218                 // WORKAROUND: only use dropclient in server frames (frametime set).
2219                 // Never use it in cl_movement frames (frametime zero).
2220                 checkSpectatorBlock(this);
2221     }
2222
2223         zoomstate_set = false;
2224
2225         // Check for nameless players
2226         if (isInvisibleString(this.netname)) {
2227                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2228                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2229         }
2230         if (this.netname != this.netname_previous) {
2231                 if (autocvar_sv_eventlog) {
2232                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2233         }
2234                 if (this.netname_previous) strunzone(this.netname_previous);
2235                 this.netname_previous = strzone(this.netname);
2236         }
2237
2238         // version nagging
2239         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2240         this.version_nagtime = 0;
2241         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2242             // git client
2243         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2244             // git server
2245             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2246         } else {
2247             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2248             if (r < 0) { // old client
2249                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2250             } else if (r > 0) { // old server
2251                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2252             }
2253         }
2254     }
2255
2256         // GOD MODE info
2257         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2258         {
2259                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2260                 this.max_armorvalue = 0;
2261         }
2262
2263         if (STAT(FROZEN, this) == 2)
2264         {
2265                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2266                 this.health = max(1, this.revive_progress * start_health);
2267                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2268
2269                 if (this.revive_progress >= 1)
2270                         Unfreeze(this);
2271         }
2272         else if (STAT(FROZEN, this) == 3)
2273         {
2274                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2275                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2276
2277                 if (this.health < 1)
2278                 {
2279                         if (this.vehicle)
2280                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2281                         if(this.event_damage)
2282                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2283                 }
2284                 else if (this.revive_progress <= 0)
2285                         Unfreeze(this);
2286         }
2287
2288         MUTATOR_CALLHOOK(PlayerPreThink, this);
2289
2290         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2291         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2292         {
2293                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2294                 {
2295                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2296                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2297                         {
2298                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2299                         }
2300                         else if(!it.owner)
2301                         {
2302                                 if(!it.team || SAME_TEAM(this, it))
2303                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2304                                 else if(autocvar_g_vehicles_steal)
2305                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2306                         }
2307                 });
2308
2309                 this.last_vehiclecheck = time + 1;
2310         }
2311
2312         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2313         {
2314                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2315                         PlayerUseKey(this);
2316                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2317         }
2318
2319         if (IS_REAL_CLIENT(this))
2320                 PrintWelcomeMessage(this);
2321
2322         if (IS_PLAYER(this)) {
2323                 CheckRules_Player(this);
2324
2325                 if (gameover || intermission_running) {
2326                         if(intermission_running)
2327                                 IntermissionThink(this);
2328                         return;
2329                 }
2330
2331                 if (timeout_status == TIMEOUT_ACTIVE) {
2332             // don't allow the player to turn around while game is paused
2333                         // FIXME turn this into CSQC stuff
2334                         this.v_angle = this.lastV_angle;
2335                         this.angles = this.lastV_angle;
2336                         this.fixangle = true;
2337                 }
2338
2339                 if (frametime) player_powerups(this);
2340
2341                 if (IS_DEAD(this)) {
2342                         if (this.personal && g_race_qualifying) {
2343                                 if (time > this.respawn_time) {
2344                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2345                                         respawn(this);
2346                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2347                                 }
2348                         } else {
2349                                 if (frametime) player_anim(this);
2350                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2351
2352                                 switch(this.deadflag)
2353                                 {
2354                                         case DEAD_DYING:
2355                                         {
2356                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2357                                                         this.deadflag = DEAD_RESPAWNING;
2358                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2359                                                         this.deadflag = DEAD_DEAD;
2360                                                 break;
2361                                         }
2362                                         case DEAD_DEAD:
2363                                         {
2364                                                 if (button_pressed)
2365                                                         this.deadflag = DEAD_RESPAWNABLE;
2366                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2367                                                         this.deadflag = DEAD_RESPAWNING;
2368                                                 break;
2369                                         }
2370                                         case DEAD_RESPAWNABLE:
2371                                         {
2372                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2373                                                         this.deadflag = DEAD_RESPAWNING;
2374                                                 break;
2375                                         }
2376                                         case DEAD_RESPAWNING:
2377                                         {
2378                                                 if (time > this.respawn_time)
2379                                                 {
2380                                                         this.respawn_time = time + 1; // only retry once a second
2381                                                         this.respawn_time_max = this.respawn_time;
2382                                                         respawn(this);
2383                                                 }
2384                                                 break;
2385                                         }
2386                                 }
2387
2388                                 ShowRespawnCountdown(this);
2389
2390                                 if (this.respawn_flags & RESPAWN_SILENT)
2391                                         STAT(RESPAWN_TIME, this) = 0;
2392                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2393                                 {
2394                                         if (time < this.respawn_time)
2395                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2396                                         else if (this.deadflag != DEAD_RESPAWNING)
2397                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2398                                 }
2399                                 else
2400                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2401                         }
2402
2403                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2404                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2405                                 STAT(RESPAWN_TIME, this) *= -1;
2406
2407                         return;
2408                 }
2409
2410                 this.prevorigin = this.origin;
2411
2412                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2413                 if (this.hook.state) {
2414                         do_crouch = false;
2415                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2416                         do_crouch = false;
2417                 } else if (this.vehicle) {
2418                         do_crouch = false;
2419                 } else if (STAT(FROZEN, this)) {
2420                         do_crouch = false;
2421         }
2422
2423                 if (do_crouch) {
2424                         if (!this.crouch) {
2425                                 this.crouch = true;
2426                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2427                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2428                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2429                         }
2430                 } else if (this.crouch) {
2431             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2432             if (!trace_startsolid) {
2433                 this.crouch = false;
2434                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2435                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2436             }
2437                 }
2438
2439                 FixPlayermodel(this);
2440
2441                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2442                 //if(frametime)
2443                 {
2444                         this.items &= ~this.items_added;
2445
2446                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2447                         //{
2448                                 //.entity weaponentity = weaponentities[slot];
2449                                 //W_WeaponFrame(this, weaponentity);
2450                         //}
2451                         .entity weaponentity = weaponentities[0]; // TODO
2452                         W_WeaponFrame(this, weaponentity);
2453
2454                         this.items_added = 0;
2455                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2456                 this.items_added |= IT_FUEL;
2457
2458                         this.items |= this.items_added;
2459                 }
2460
2461                 player_regen(this);
2462
2463                 // WEAPONTODO: Add a weapon request for this
2464                 // rot vortex charge to the charge limit
2465                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2466                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2467
2468                 if (frametime) player_anim(this);
2469
2470                 // secret status
2471                 secrets_setstatus(this);
2472
2473                 // monsters status
2474                 monsters_setstatus(this);
2475
2476                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2477         }
2478         else if (gameover || intermission_running) {
2479                 if(intermission_running)
2480                         IntermissionThink(this);
2481                 return;
2482         }
2483         else if (IS_OBSERVER(this)) {
2484                 ObserverThink(this);
2485         }
2486         else if (IS_SPEC(this)) {
2487                 SpectatorThink(this);
2488         }
2489
2490         // WEAPONTODO: Add weapon request for this
2491         if (!zoomstate_set) {
2492                 SetZoomState(this,
2493                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2494                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2495                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2496                 );
2497     }
2498
2499         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2500         {
2501                 this.teamkill_soundtime = 0;
2502
2503                 entity e = this.teamkill_soundsource;
2504                 entity oldpusher = e.pusher;
2505                 e.pusher = this;
2506                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2507                 e.pusher = oldpusher;
2508         }
2509
2510         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2511                 this.taunt_soundtime = 0;
2512                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2513         }
2514
2515         target_voicescript_next(this);
2516
2517         // WEAPONTODO: Move into weaponsystem somehow
2518         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2519         if (PS(this).m_weapon == WEP_Null)
2520                 this.clip_load = this.clip_size = 0;
2521 }
2522
2523 void DrownPlayer(entity this)
2524 {
2525         if(IS_DEAD(this))
2526                 return;
2527
2528         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2529         {
2530                 if(this.air_finished < time)
2531                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2532                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2533                 this.dmg = 2;
2534         }
2535         else if (this.air_finished < time)
2536         {       // drown!
2537                 if (this.pain_finished < time)
2538                 {
2539                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2540                         this.pain_finished = time + 0.5;
2541                 }
2542         }
2543 }
2544
2545 .bool move_qcphysics;
2546
2547 void Player_Physics(entity this)
2548 {
2549         set_movetype(this, this.move_movetype);
2550
2551         if(!this.move_qcphysics)
2552                 return;
2553
2554         if(!frametime && !this.pm_frametime)
2555                 return;
2556
2557         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2558
2559         this.pm_frametime = 0;
2560 }
2561
2562 /*
2563 =============
2564 PlayerPostThink
2565
2566 Called every frame for each client after the physics are run
2567 =============
2568 */
2569 .float idlekick_lasttimeleft;
2570 void PlayerPostThink (entity this)
2571 {
2572         Player_Physics(this);
2573
2574         if (sv_maxidle > 0)
2575         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2576         if (IS_REAL_CLIENT(this))
2577         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2578         {
2579                 int totalClients = 0;
2580                 if(sv_maxidle_slots > 0)
2581                 {
2582                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2583                         {
2584                                 ++totalClients;
2585                         });
2586                 }
2587
2588                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2589                 { /* do nothing */ }
2590                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2591                 {
2592                         if (this.idlekick_lasttimeleft)
2593                         {
2594                                 this.idlekick_lasttimeleft = 0;
2595                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2596                         }
2597                 }
2598                 else
2599                 {
2600                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2601                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2602                                 if (!this.idlekick_lasttimeleft)
2603                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2604                         }
2605                         if (timeleft <= 0) {
2606                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2607                                 dropclient(this);
2608                                 return;
2609                         }
2610                         else if (timeleft <= 10) {
2611                                 if (timeleft != this.idlekick_lasttimeleft) {
2612                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2613                 }
2614                                 this.idlekick_lasttimeleft = timeleft;
2615                         }
2616                 }
2617         }
2618
2619         CheatFrame(this);
2620
2621         //CheckPlayerJump();
2622         if (gameover)
2623         {
2624                 this.solid = SOLID_NOT;
2625                 this.takedamage = DAMAGE_NO;
2626                 set_movetype(this, MOVETYPE_NONE);
2627         }
2628
2629         if (IS_PLAYER(this)) {
2630                 DrownPlayer(this);
2631                 CheckRules_Player(this);
2632                 UpdateChatBubble(this);
2633                 if (this.impulse) ImpulseCommands(this);
2634                 if (gameover)
2635                 {
2636                         CSQCMODEL_AUTOUPDATE(this);
2637                         return;
2638                 }
2639                 GetPressedKeys(this);
2640         }
2641
2642         if (this.waypointsprite_attachedforcarrier) {
2643             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2644                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2645     }
2646
2647         playerdemo_write(this);
2648
2649         CSQCMODEL_AUTOUPDATE(this);
2650 }