qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38
  39 #include "../common/vehicles/all.qh"
  40
  41 #include "weapons/hitplot.qh"
  42 #include "weapons/weaponsystem.qh"
  43
  44 #include "../common/net_notice.qh"
  45 #include "../common/net_linked.qh"
  46 #include "../common/physics/player.qh"
  47
  48 #include "../common/items/_mod.qh"
  49
  50 #include "../common/mutators/mutator/waypoints/all.qh"
  51
  52 #include "../common/triggers/subs.qh"
  53 #include "../common/triggers/triggers.qh"
  54 #include "../common/triggers/trigger/secret.qh"
  55
  56 #include "../common/minigames/sv_minigames.qh"
  57
  58 #include "../common/items/inventory.qh"
  59
  60 #include "../common/monsters/sv_monsters.qh"
  61
  62 #include "../lib/warpzone/server.qh"
  63
  64 STATIC_METHOD(Client, Add, void(Client this, int _team))
  65 {
  66     ClientConnect(this);
  67     TRANSMUTE(Player, this);
  68     this.frame = 12; // 7
  69     this.team = _team;
  70     PutClientInServer(this);
  71 }
  72
  73 void PutObserverInServer(entity this);
  74
  75 STATIC_METHOD(Client, Remove, void(Client this))
  76 {
  77     TRANSMUTE(Observer, this);
  78     PutClientInServer(this);
  79     ClientDisconnect(this);
  80 }
  81
  82 void send_CSQC_teamnagger() {
  83         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  84 }
  85
  86 int CountSpectators(entity player, entity to)
  87 {
  88         if(!player) { return 0; } // not sure how, but best to be safe
  89
  90         int spec_count = 0;
  91
  92         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  93         {
  94                 spec_count++;
  95         });
  96
  97         return spec_count;
  98 }
  99
 100 void WriteSpectators(entity player, entity to)
 101 {
 102         if(!player) { return; } // not sure how, but best to be safe
 103
 104         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 105         {
 106                 WriteByte(MSG_ENTITY, num_for_edict(it));
 107         });
 108 }
 109
 110 bool ClientData_Send(entity this, entity to, int sf)
 111 {
 112         assert(to == this.owner, return false);
 113
 114         entity e = to;
 115         if (IS_SPEC(e)) e = e.enemy;
 116
 117         sf = 0;
 118         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 119         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 120         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 121         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 122
 123         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 124         WriteByte(MSG_ENTITY, sf);
 125
 126         if (sf & BIT(1))
 127                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 128
 129         if(sf & BIT(4))
 130         {
 131                 float specs = CountSpectators(e, to);
 132                 WriteByte(MSG_ENTITY, specs);
 133                 WriteSpectators(e, to);
 134         }
 135
 136         return true;
 137 }
 138
 139 void ClientData_Attach(entity this)
 140 {
 141         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 142         CS(this).clientdata.drawonlytoclient = this;
 143         CS(this).clientdata.owner = this;
 144 }
 145
 146 void ClientData_Detach(entity this)
 147 {
 148         delete(CS(this).clientdata);
 149         CS(this).clientdata = NULL;
 150 }
 151
 152 void ClientData_Touch(entity e)
 153 {
 154         CS(e).clientdata.SendFlags = 1;
 155
 156         // make it spectatable
 157         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 158 }
 159
 160 void SetSpectatee(entity this, entity spectatee);
 161 void SetSpectatee_status(entity this, int spectatee_num);
 162
 163
 164 /*
 165 =============
 166 CheckPlayerModel
 167
 168 Checks if the argument string can be a valid playermodel.
 169 Returns a valid one in doubt.
 170 =============
 171 */
 172 string FallbackPlayerModel;
 173 string CheckPlayerModel(string plyermodel) {
 174         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 175         {
 176                 // note: we cannot summon Don Strunzone here, some player may
 177                 // still have the model string set. In case anyone manages how
 178                 // to change a cvar default, we'll have a small leak here.
 179                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 180         }
 181         // only in right path
 182         if( substring(plyermodel,0,14) != "models/player/")
 183                 return FallbackPlayerModel;
 184         // only good file extensions
 185         if(substring(plyermodel,-4,4) != ".zym")
 186         if(substring(plyermodel,-4,4) != ".dpm")
 187         if(substring(plyermodel,-4,4) != ".iqm")
 188         if(substring(plyermodel,-4,4) != ".md3")
 189         if(substring(plyermodel,-4,4) != ".psk")
 190                 return FallbackPlayerModel;
 191         // forbid the LOD models
 192         if(substring(plyermodel, -9,5) == "_lod1")
 193                 return FallbackPlayerModel;
 194         if(substring(plyermodel, -9,5) == "_lod2")
 195                 return FallbackPlayerModel;
 196         if(plyermodel != strtolower(plyermodel))
 197                 return FallbackPlayerModel;
 198         // also, restrict to server models
 199         if(autocvar_sv_servermodelsonly)
 200         {
 201                 if(!fexists(plyermodel))
 202                         return FallbackPlayerModel;
 203         }
 204         return plyermodel;
 205 }
 206
 207 void setplayermodel(entity e, string modelname)
 208 {
 209         precache_model(modelname);
 210         _setmodel(e, modelname);
 211         player_setupanimsformodel(e);
 212         if(!autocvar_g_debug_globalsounds)
 213                 UpdatePlayerSounds(e);
 214 }
 215
 216 void FixPlayermodel(entity player);
 217 /** putting a client as observer in the server */
 218 void PutObserverInServer(entity this)
 219 {
 220     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 221         PlayerState_detach(this);
 222
 223         if (IS_PLAYER(this))
 224         {
 225                 if(this.health >= 1)
 226                 {
 227                         // despawn effect
 228                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 229                 }
 230
 231                 // was a player, recount votes and ready status
 232                 if(IS_REAL_CLIENT(this))
 233                 {
 234                         if (vote_called) { VoteCount(false); }
 235                         ReadyCount();
 236                 }
 237     }
 238
 239     {
 240         entity spot = SelectSpawnPoint(this, true);
 241         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 242         this.angles = vec2(spot.angles);
 243         this.fixangle = true;
 244         // offset it so that the spectator spawns higher off the ground, looks better this way
 245         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 246         if (IS_REAL_CLIENT(this))
 247         {
 248             msg_entity = this;
 249             WriteByte(MSG_ONE, SVC_SETVIEW);
 250             WriteEntity(MSG_ONE, this);
 251         }
 252         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254         if(!autocvar_g_debug_globalsounds)
 255         {
 256                 // needed for player sounds
 257                 this.model = "";
 258                 FixPlayermodel(this);
 259         }
 260         setmodel(this, MDL_Null);
 261         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 262         this.view_ofs = '0 0 0';
 263     }
 264
 265     RemoveGrapplingHooks(this);
 266         Portal_ClearAll(this);
 267         Unfreeze(this);
 268         SetSpectatee(this, NULL);
 269
 270         if (this.alivetime)
 271         {
 272                 if (!warmup_stage)
 273                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 274                 this.alivetime = 0;
 275         }
 276
 277         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 278
 279         WaypointSprite_PlayerDead(this);
 280
 281         if (mutator_returnvalue) {
 282             // mutator prevents resetting teams+score
 283         } else {
 284                 int oldteam = this.team;
 285                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 286                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 287         this.frags = FRAGS_SPECTATOR;
 288         PlayerScore_Clear(this);  // clear scores when needed
 289     }
 290
 291         if (CS(this).killcount != FRAGS_SPECTATOR)
 292         {
 293                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 294                 if(!game_stopped)
 295                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 296                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 297
 298                 if(!CS(this).just_joined)
 299                         LogTeamchange(this.playerid, -1, 4);
 300                 else
 301                         CS(this).just_joined = false;
 302         }
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310     this.hud = HUD_NORMAL;
 311         TRANSMUTE(Observer, this);
 312         this.iscreature = false;
 313         this.teleportable = TELEPORT_SIMPLE;
 314         if(this.damagedbycontents)
 315                 IL_REMOVE(g_damagedbycontents, this);
 316         this.damagedbycontents = false;
 317         this.health = FRAGS_SPECTATOR;
 318         SetSpectatee_status(this, etof(this));
 319         this.takedamage = DAMAGE_NO;
 320         this.solid = SOLID_NOT;
 321         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 322         this.flags = FL_CLIENT | FL_NOTARGET;
 323         this.armorvalue = 666;
 324         this.effects = 0;
 325         this.armorvalue = autocvar_g_balance_armor_start;
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         this.stat_respawn_time = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_frame = 0;
 338         this.pain_finished = 0;
 339         this.strength_finished = 0;
 340         this.invincible_finished = 0;
 341         this.superweapons_finished = 0;
 342         this.pushltime = 0;
 343         this.istypefrag = 0;
 344         setthink(this, func_null);
 345         this.nextthink = 0;
 346         this.deadflag = DEAD_NO;
 347         this.crouch = false;
 348         this.revive_progress = 0;
 349         this.revival_time = 0;
 350
 351         this.items = 0;
 352         this.weapons = '0 0 0';
 353         this.drawonlytoclient = this;
 354
 355         this.viewloc = NULL;
 356
 357         this.weaponmodel = "";
 358         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 359         {
 360                 this.weaponentities[slot] = NULL;
 361         }
 362         this.exteriorweaponentity = NULL;
 363         CS(this).killcount = FRAGS_SPECTATOR;
 364         this.velocity = '0 0 0';
 365         this.avelocity = '0 0 0';
 366         this.punchangle = '0 0 0';
 367         this.punchvector = '0 0 0';
 368         this.oldvelocity = this.velocity;
 369         this.fire_endtime = -1;
 370         this.event_damage = func_null;
 371
 372         for(int slot = 0; slot < MAX_AXH; ++slot)
 373         {
 374                 entity axh = this.(AuxiliaryXhair[slot]);
 375                 this.(AuxiliaryXhair[slot]) = NULL;
 376
 377                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 378                         delete(axh);
 379         }
 380 }
 381
 382 int player_getspecies(entity this)
 383 {
 384         get_model_parameters(this.model, this.skin);
 385         int s = get_model_parameters_species;
 386         get_model_parameters(string_null, 0);
 387         if (s < 0) return SPECIES_HUMAN;
 388         return s;
 389 }
 390
 391 .float model_randomizer;
 392 void FixPlayermodel(entity player)
 393 {
 394         string defaultmodel = "";
 395         int defaultskin = 0;
 396         if(autocvar_sv_defaultcharacter)
 397         {
 398                 if(teamplay)
 399                 {
 400                         switch(player.team)
 401                         {
 402                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 403                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 404                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 405                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 406                         }
 407                 }
 408
 409                 if(defaultmodel == "")
 410                 {
 411                         defaultmodel = autocvar_sv_defaultplayermodel;
 412                         defaultskin = autocvar_sv_defaultplayerskin;
 413                 }
 414
 415                 int n = tokenize_console(defaultmodel);
 416                 if(n > 0)
 417                 {
 418                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 419                         // However, do NOT randomize if the player-selected model is in the list.
 420                         for (int i = 0; i < n; ++i)
 421                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 422                                         defaultmodel = argv(i);
 423                 }
 424
 425                 int i = strstrofs(defaultmodel, ":", 0);
 426                 if(i >= 0)
 427                 {
 428                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 429                         defaultmodel = substring(defaultmodel, 0, i);
 430                 }
 431         }
 432         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 433         {
 434                 if(teamplay)
 435                 {
 436                         switch(player.team)
 437                         {
 438                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 439                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 440                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 441                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 442                         }
 443                 }
 444
 445                 if(!defaultskin)
 446                         defaultskin = autocvar_sv_defaultplayerskin;
 447         }
 448
 449         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 450         defaultmodel = M_ARGV(0, string);
 451         defaultskin = M_ARGV(1, int);
 452
 453         bool chmdl = false;
 454         int oldskin;
 455         if(defaultmodel != "")
 456         {
 457                 if (defaultmodel != player.model)
 458                 {
 459                         vector m1 = player.mins;
 460                         vector m2 = player.maxs;
 461                         setplayermodel (player, defaultmodel);
 462                         setsize (player, m1, m2);
 463                         chmdl = true;
 464                 }
 465
 466                 oldskin = player.skin;
 467                 player.skin = defaultskin;
 468         } else {
 469                 if (player.playermodel != player.model || player.playermodel == "")
 470                 {
 471                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 472                         vector m1 = player.mins;
 473                         vector m2 = player.maxs;
 474                         setplayermodel (player, player.playermodel);
 475                         setsize (player, m1, m2);
 476                         chmdl = true;
 477                 }
 478
 479                 if(!autocvar_sv_defaultcharacterskin)
 480                 {
 481                         oldskin = player.skin;
 482                         player.skin = stof(player.playerskin);
 483                 }
 484                 else
 485                 {
 486                         oldskin = player.skin;
 487                         player.skin = defaultskin;
 488                 }
 489         }
 490
 491         if(chmdl || oldskin != player.skin) // model or skin has changed
 492         {
 493                 player.species = player_getspecies(player); // update species
 494                 if(!autocvar_g_debug_globalsounds)
 495                         UpdatePlayerSounds(player); // update skin sounds
 496         }
 497
 498         if(!teamplay)
 499                 if(strlen(autocvar_sv_defaultplayercolors))
 500                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 501                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 502 }
 503
 504 void PutPlayerInServer(entity this)
 505 {
 506         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 507
 508         PlayerState_attach(this);
 509         accuracy_resend(this);
 510
 511         if (this.team < 0)
 512                 JoinBestTeam(this, true);
 513
 514         entity spot = SelectSpawnPoint(this, false);
 515         if (!spot) {
 516                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 517                 return; // spawn failed
 518         }
 519
 520         TRANSMUTE(Player, this);
 521
 522         CS(this).wasplayer = true;
 523         this.iscreature = true;
 524         this.teleportable = TELEPORT_NORMAL;
 525         if(!this.damagedbycontents)
 526                 IL_PUSH(g_damagedbycontents, this);
 527         this.damagedbycontents = true;
 528         set_movetype(this, MOVETYPE_WALK);
 529         this.solid = SOLID_SLIDEBOX;
 530         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 531         if (autocvar_g_playerclip_collisions)
 532                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 533         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 534                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 535         this.frags = FRAGS_PLAYER;
 536         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 537         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 538         if (autocvar__notarget)
 539                 this.flags |= FL_NOTARGET;
 540         this.takedamage = DAMAGE_AIM;
 541         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 542
 543         if (warmup_stage) {
 544                 this.ammo_shells = warmup_start_ammo_shells;
 545                 this.ammo_nails = warmup_start_ammo_nails;
 546                 this.ammo_rockets = warmup_start_ammo_rockets;
 547                 this.ammo_cells = warmup_start_ammo_cells;
 548                 this.ammo_plasma = warmup_start_ammo_plasma;
 549                 this.ammo_fuel = warmup_start_ammo_fuel;
 550                 this.health = warmup_start_health;
 551                 this.armorvalue = warmup_start_armorvalue;
 552                 this.weapons = WARMUP_START_WEAPONS;
 553         } else {
 554                 this.ammo_shells = start_ammo_shells;
 555                 this.ammo_nails = start_ammo_nails;
 556                 this.ammo_rockets = start_ammo_rockets;
 557                 this.ammo_cells = start_ammo_cells;
 558                 this.ammo_plasma = start_ammo_plasma;
 559                 this.ammo_fuel = start_ammo_fuel;
 560                 this.health = start_health;
 561                 this.armorvalue = start_armorvalue;
 562                 this.weapons = start_weapons;
 563                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 564                 {
 565                         GiveRandomWeapons(this, random_start_weapons_count,
 566                                 autocvar_g_random_start_weapons, random_start_ammo);
 567                 }
 568         }
 569         SetSpectatee_status(this, 0);
 570
 571         PS(this).dual_weapons = '0 0 0';
 572
 573         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 574
 575         this.items = start_items;
 576
 577         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 578         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 579         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 580         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 581         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 582         // extend the pause of rotting if client was reset at the beginning of the countdown
 583         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 584                 float f = game_starttime - time;
 585                 this.spawnshieldtime += f;
 586                 this.pauserotarmor_finished += f;
 587                 this.pauserothealth_finished += f;
 588                 this.pauseregen_finished += f;
 589         }
 590         this.damageforcescale = 2;
 591         this.death_time = 0;
 592         this.respawn_flags = 0;
 593         this.respawn_time = 0;
 594         this.stat_respawn_time = 0;
 595         this.scale = autocvar_sv_player_scale;
 596         this.fade_time = 0;
 597         this.pain_frame = 0;
 598         this.pain_finished = 0;
 599         this.pushltime = 0;
 600         setthink(this, func_null); // players have no think function
 601         this.nextthink = 0;
 602         this.dmg_team = 0;
 603         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 604
 605         this.deadflag = DEAD_NO;
 606
 607         this.angles = spot.angles;
 608         this.angles_z = 0; // never spawn tilted even if the spot says to
 609         if (IS_BOT_CLIENT(this))
 610                 this.v_angle = this.angles;
 611         this.fixangle = true; // turn this way immediately
 612         this.oldvelocity = this.velocity = '0 0 0';
 613         this.avelocity = '0 0 0';
 614         this.punchangle = '0 0 0';
 615         this.punchvector = '0 0 0';
 616
 617         this.strength_finished = 0;
 618         this.invincible_finished = 0;
 619         this.fire_endtime = -1;
 620         this.revive_progress = 0;
 621         this.revival_time = 0;
 622
 623         this.air_finished = time + 12;
 624         this.waterlevel = WATERLEVEL_NONE;
 625         this.watertype = CONTENT_EMPTY;
 626
 627         entity spawnevent = new_pure(spawnevent);
 628         spawnevent.owner = this;
 629         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 630
 631         // Cut off any still running player sounds.
 632         stopsound(this, CH_PLAYER_SINGLE);
 633
 634         this.model = "";
 635         FixPlayermodel(this);
 636         this.drawonlytoclient = NULL;
 637
 638         this.viewloc = NULL;
 639
 640         this.crouch = false;
 641         this.view_ofs = STAT(PL_VIEW_OFS, this);
 642         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 643         this.spawnorigin = spot.origin;
 644         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 645         // don't reset back to last position, even if new position is stuck in solid
 646         this.oldorigin = this.origin;
 647         if(this.conveyor)
 648                 IL_REMOVE(g_conveyed, this);
 649         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 650         this.hud = HUD_NORMAL;
 651
 652         this.event_damage = PlayerDamage;
 653
 654         if(!this.bot_attack)
 655                 IL_PUSH(g_bot_targets, this);
 656         this.bot_attack = true;
 657         if(!this.monster_attack)
 658                 IL_PUSH(g_monster_targets, this);
 659         this.monster_attack = true;
 660         navigation_dynamicgoal_init(this, false);
 661
 662         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 663
 664         // player was spectator
 665         if (CS(this).killcount == FRAGS_SPECTATOR) {
 666                 PlayerScore_Clear(this);
 667                 CS(this).killcount = 0;
 668                 CS(this).startplaytime = time;
 669         }
 670
 671         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 672         {
 673                 .entity weaponentity = weaponentities[slot];
 674                 entity oldwep = this.(weaponentity);
 675                 CL_SpawnWeaponentity(this, weaponentity);
 676                 if(oldwep && oldwep.owner == this)
 677                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 678         }
 679         this.alpha = default_player_alpha;
 680         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 681         this.exteriorweaponentity.alpha = default_weapon_alpha;
 682
 683         this.speedrunning = false;
 684
 685         target_voicescript_clear(this);
 686
 687         // reset fields the weapons may use
 688         FOREACH(Weapons, true, {
 689                 it.wr_resetplayer(it, this);
 690                         // reload all reloadable weapons
 691                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 692                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 693                         {
 694                                 .entity weaponentity = weaponentities[slot];
 695                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 696                         }
 697                 }
 698         });
 699
 700         {
 701                 string s = spot.target;
 702                 spot.target = string_null;
 703                 SUB_UseTargets(spot, this, NULL);
 704                 spot.target = s;
 705         }
 706
 707         Unfreeze(this);
 708
 709         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 710
 711         if (autocvar_spawn_debug)
 712         {
 713                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 714                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 715         }
 716
 717         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 718         {
 719                 .entity weaponentity = weaponentities[slot];
 720                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 721                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 722                 else
 723                         this.(weaponentity).m_switchweapon = WEP_Null;
 724                 this.(weaponentity).m_weapon = WEP_Null;
 725                 this.(weaponentity).weaponname = "";
 726                 this.(weaponentity).m_switchingweapon = WEP_Null;
 727                 this.(weaponentity).cnt = -1;
 728         }
 729
 730         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 731
 732         if (!warmup_stage && !this.alivetime)
 733                 this.alivetime = time;
 734
 735         antilag_clear(this, CS(this));
 736 }
 737
 738 /** Called when a client spawns in the server */
 739 void PutClientInServer(entity this)
 740 {
 741         if (IS_BOT_CLIENT(this)) {
 742                 TRANSMUTE(Player, this);
 743         } else if (IS_REAL_CLIENT(this)) {
 744                 msg_entity = this;
 745                 WriteByte(MSG_ONE, SVC_SETVIEW);
 746                 WriteEntity(MSG_ONE, this);
 747         }
 748         if (game_stopped)
 749                 TRANSMUTE(Observer, this);
 750
 751         SetSpectatee(this, NULL);
 752
 753         // reset player keys
 754         if(PS(this))
 755                 PS(this).itemkeys = 0;
 756
 757         MUTATOR_CALLHOOK(PutClientInServer, this);
 758
 759         if (IS_OBSERVER(this)) {
 760                 PutObserverInServer(this);
 761         } else if (IS_PLAYER(this)) {
 762                 PutPlayerInServer(this);
 763         }
 764 }
 765
 766 void ClientInit_misc(entity this);
 767
 768 // TODO do we need all these fields, or should we stop autodetecting runtime
 769 // changes and just have a console command to update this?
 770 bool ClientInit_SendEntity(entity this, entity to, int sf)
 771 {
 772         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 773         return = true;
 774         msg_entity = to;
 775         // MSG_INIT replacement
 776         // TODO: make easier to use
 777         Registry_send_all();
 778         W_PROP_reload(MSG_ONE, to);
 779         ClientInit_misc(this);
 780         MUTATOR_CALLHOOK(Ent_Init);
 781 }
 782 void ClientInit_misc(entity this)
 783 {
 784         int channel = MSG_ONE;
 785         WriteHeader(channel, ENT_CLIENT_INIT);
 786         WriteByte(channel, g_nexball_meter_period * 32);
 787         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 788         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 789         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 790         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 791         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 792         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 793         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 794         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 795
 796         if(sv_foginterval && world.fog != "")
 797                 WriteString(channel, world.fog);
 798         else
 799                 WriteString(channel, "");
 800         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 801         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 802         WriteByte(channel, serverflags);
 803         WriteCoord(channel, autocvar_g_trueaim_minrange);
 804 }
 805
 806 void ClientInit_CheckUpdate(entity this)
 807 {
 808         this.nextthink = time;
 809         if(this.count != autocvar_g_balance_armor_blockpercent)
 810         {
 811                 this.count = autocvar_g_balance_armor_blockpercent;
 812                 this.SendFlags |= 1;
 813         }
 814         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 815         {
 816                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 817                 this.SendFlags |= 1;
 818         }
 819 }
 820
 821 void ClientInit_Spawn()
 822 {
 823         entity e = new_pure(clientinit);
 824         setthink(e, ClientInit_CheckUpdate);
 825         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 826
 827         ClientInit_CheckUpdate(e);
 828 }
 829
 830 /*
 831 =============
 832 SetNewParms
 833 =============
 834 */
 835 void SetNewParms ()
 836 {
 837         // initialize parms for a new player
 838         parm1 = -(86400 * 366);
 839
 840         MUTATOR_CALLHOOK(SetNewParms);
 841 }
 842
 843 /*
 844 =============
 845 SetChangeParms
 846 =============
 847 */
 848 void SetChangeParms (entity this)
 849 {
 850         // save parms for level change
 851         parm1 = CS(this).parm_idlesince - time;
 852
 853         MUTATOR_CALLHOOK(SetChangeParms);
 854 }
 855
 856 /*
 857 =============
 858 DecodeLevelParms
 859 =============
 860 */
 861 void DecodeLevelParms(entity this)
 862 {
 863         // load parms
 864         CS(this).parm_idlesince = parm1;
 865         if (CS(this).parm_idlesince == -(86400 * 366))
 866                 CS(this).parm_idlesince = time;
 867
 868         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 869         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 870
 871         MUTATOR_CALLHOOK(DecodeLevelParms);
 872 }
 873
 874 /*
 875 =============
 876 ClientKill
 877
 878 Called when a client types 'kill' in the console
 879 =============
 880 */
 881
 882 .float clientkill_nexttime;
 883 void ClientKill_Now_TeamChange(entity this)
 884 {
 885         if(this.killindicator_teamchange == -1)
 886         {
 887                 JoinBestTeam( this, true );
 888         }
 889         else if(this.killindicator_teamchange == -2)
 890         {
 891                 if(blockSpectators)
 892                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 893                 PutObserverInServer(this);
 894         }
 895         else
 896                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 897         this.killindicator_teamchange = 0;
 898 }
 899
 900 void ClientKill_Now(entity this)
 901 {
 902         if(this.vehicle)
 903         {
 904             vehicles_exit(this.vehicle, VHEF_RELEASE);
 905             if(!this.killindicator_teamchange)
 906             {
 907             this.vehicle_health = -1;
 908             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 909             }
 910         }
 911
 912         if(this.killindicator && !wasfreed(this.killindicator))
 913                 delete(this.killindicator);
 914
 915         this.killindicator = NULL;
 916
 917         if(this.killindicator_teamchange)
 918                 ClientKill_Now_TeamChange(this);
 919
 920         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 921         {
 922                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 923         }
 924
 925         // now I am sure the player IS dead
 926 }
 927 void KillIndicator_Think(entity this)
 928 {
 929         if (game_stopped)
 930         {
 931                 this.owner.killindicator = NULL;
 932                 delete(this);
 933                 return;
 934         }
 935
 936         if (this.owner.alpha < 0 && !this.owner.vehicle)
 937         {
 938                 this.owner.killindicator = NULL;
 939                 delete(this);
 940                 return;
 941         }
 942
 943         if(this.cnt <= 0)
 944         {
 945                 ClientKill_Now(this.owner);
 946                 return;
 947         }
 948     else if(this.health == 1) // health == 1 means that it's silent
 949     {
 950         this.nextthink = time + 1;
 951         this.cnt -= 1;
 952     }
 953         else
 954         {
 955                 if(this.cnt <= 10)
 956                         setmodel(this, MDL_NUM(this.cnt));
 957                 if(IS_REAL_CLIENT(this.owner))
 958                 {
 959                         if(this.cnt <= 10)
 960                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 961                 }
 962                 this.nextthink = time + 1;
 963                 this.cnt -= 1;
 964         }
 965 }
 966
 967 float clientkilltime;
 968 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 969 {
 970         float killtime;
 971         float starttime;
 972
 973         if (game_stopped)
 974                 return;
 975
 976         killtime = autocvar_g_balance_kill_delay;
 977
 978     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 979         return;
 980     killtime = M_ARGV(1, float);
 981
 982         this.killindicator_teamchange = targetteam;
 983
 984     if(!this.killindicator)
 985         {
 986                 if(!IS_DEAD(this))
 987                 {
 988                         killtime = max(killtime, this.clientkill_nexttime - time);
 989                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 990                 }
 991
 992                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 993                 {
 994                         ClientKill_Now(this);
 995                 }
 996                 else
 997                 {
 998                         starttime = max(time, clientkilltime);
 999
1000                         this.killindicator = spawn();
1001                         this.killindicator.owner = this;
1002                         this.killindicator.scale = 0.5;
1003                         setattachment(this.killindicator, this, "");
1004                         setorigin(this.killindicator, '0 0 52');
1005                         setthink(this.killindicator, KillIndicator_Think);
1006                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1007                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1008                         this.killindicator.cnt = ceil(killtime);
1009                         this.killindicator.count = bound(0, ceil(killtime), 10);
1010                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1011
1012                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1013                         {
1014                                 it.killindicator = spawn();
1015                                 it.killindicator.owner = it;
1016                                 it.killindicator.scale = 0.5;
1017                                 setattachment(it.killindicator, it, "");
1018                                 setorigin(it.killindicator, '0 0 52');
1019                                 setthink(it.killindicator, KillIndicator_Think);
1020                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1021                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1022                                 it.killindicator.cnt = ceil(killtime);
1023                         });
1024                         this.lip = 0;
1025                 }
1026         }
1027         if(this.killindicator)
1028         {
1029                 if(targetteam == 0) // just die
1030                 {
1031                         this.killindicator.colormod = '0 0 0';
1032                         if(IS_REAL_CLIENT(this))
1033                         if(this.killindicator.cnt > 0)
1034                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1035                 }
1036                 else if(targetteam == -1) // auto
1037                 {
1038                         this.killindicator.colormod = '0 1 0';
1039                         if(IS_REAL_CLIENT(this))
1040                         if(this.killindicator.cnt > 0)
1041                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1042                 }
1043                 else if(targetteam == -2) // spectate
1044                 {
1045                         this.killindicator.colormod = '0.5 0.5 0.5';
1046                         if(IS_REAL_CLIENT(this))
1047                         if(this.killindicator.cnt > 0)
1048                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1049                 }
1050                 else
1051                 {
1052                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1053                         if(IS_REAL_CLIENT(this))
1054                         if(this.killindicator.cnt > 0)
1055                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1056                 }
1057         }
1058
1059 }
1060
1061 void ClientKill (entity this)
1062 {
1063         if(game_stopped) return;
1064         if(this.player_blocked) return;
1065         if(STAT(FROZEN, this)) return;
1066
1067         ClientKill_TeamChange(this, 0);
1068 }
1069
1070 void FixClientCvars(entity e)
1071 {
1072         // send prediction settings to the client
1073         stuffcmd(e, "\nin_bindmap 0 0\n");
1074         if(autocvar_g_antilag == 3) // client side hitscan
1075                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1076         if(autocvar_sv_gentle)
1077                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1078
1079         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1080         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1081
1082         MUTATOR_CALLHOOK(FixClientCvars, e);
1083 }
1084
1085 bool findinlist_abbrev(string tofind, string list)
1086 {
1087         if(list == "" || tofind == "")
1088                 return false; // empty list or search, just return
1089
1090         // this function allows abbreviated strings!
1091         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1092         {
1093                 return true;
1094         });
1095
1096         return false;
1097 }
1098
1099 bool PlayerInIPList(entity p, string iplist)
1100 {
1101         // some safety checks (never allow local?)
1102         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1103                 return false;
1104
1105         return findinlist_abbrev(p.netaddress, iplist);
1106 }
1107
1108 bool PlayerInIDList(entity p, string idlist)
1109 {
1110         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1111         if(!p.crypto_idfp)
1112                 return false;
1113
1114         return findinlist_abbrev(p.crypto_idfp, idlist);
1115 }
1116
1117 bool PlayerInList(entity player, string list)
1118 {
1119         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1120 }
1121
1122 #ifdef DP_EXT_PRECONNECT
1123 /*
1124 =============
1125 ClientPreConnect
1126
1127 Called once (not at each match start) when a client begins a connection to the server
1128 =============
1129 */
1130 void ClientPreConnect(entity this)
1131 {
1132         if(autocvar_sv_eventlog)
1133         {
1134                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1135                         this.playerid,
1136                         etof(this),
1137                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1138                 ));
1139         }
1140 }
1141 #endif
1142
1143 /**
1144 =============
1145 ClientConnect
1146
1147 Called when a client connects to the server
1148 =============
1149 */
1150 void ClientConnect(entity this)
1151 {
1152         if (Ban_MaybeEnforceBanOnce(this)) return;
1153         assert(!IS_CLIENT(this), return);
1154         this.flags |= FL_CLIENT;
1155         assert(player_count >= 0, player_count = 0);
1156
1157 #ifdef WATERMARK
1158         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1159 #endif
1160         TRANSMUTE(Client, this);
1161         CS(this).version_nagtime = time + 10 + random() * 10;
1162
1163         // identify the right forced team
1164         if (autocvar_g_campaign)
1165         {
1166                 if (IS_REAL_CLIENT(this)) // only players, not bots
1167                 {
1168                         switch (autocvar_g_campaign_forceteam)
1169                         {
1170                                 case 1: this.team_forced = NUM_TEAM_1; break;
1171                                 case 2: this.team_forced = NUM_TEAM_2; break;
1172                                 case 3: this.team_forced = NUM_TEAM_3; break;
1173                                 case 4: this.team_forced = NUM_TEAM_4; break;
1174                                 default: this.team_forced = 0;
1175                         }
1176                 }
1177         }
1178         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1179         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1180         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1181         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1182         else switch (autocvar_g_forced_team_otherwise)
1183         {
1184                 default: this.team_forced = 0; break;
1185                 case "red": this.team_forced = NUM_TEAM_1; break;
1186                 case "blue": this.team_forced = NUM_TEAM_2; break;
1187                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1188                 case "pink": this.team_forced = NUM_TEAM_4; break;
1189                 case "spectate":
1190                 case "spectator":
1191                         this.team_forced = -1;
1192                         break;
1193         }
1194         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1195
1196         int playerid_save = this.playerid;
1197         this.playerid = 0; // silent
1198         JoinBestTeam(this, false); // if the team number is valid, keep it
1199         this.playerid = playerid_save;
1200
1201         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1202                 TRANSMUTE(Observer, this);
1203         } else {
1204                 if (!teamplay || autocvar_g_balance_teams) {
1205                         TRANSMUTE(Player, this);
1206                         campaign_bots_may_start = true;
1207                 } else {
1208                         TRANSMUTE(Observer, this); // do it anyway
1209                 }
1210         }
1211
1212         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1213
1214         // always track bots, don't ask for cl_allow_uidtracking
1215         if (IS_BOT_CLIENT(this))
1216                 PlayerStats_GameReport_AddPlayer(this);
1217         else
1218                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1219
1220         if (autocvar_sv_eventlog)
1221                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1222
1223         LogTeamchange(this.playerid, this.team, 1);
1224
1225         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1226
1227         if(teamplay && IS_PLAYER(this))
1228                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1229         else
1230                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1231
1232         stuffcmd(this, clientstuff, "\n");
1233         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1234
1235         FixClientCvars(this);
1236
1237         // get version info from player
1238         stuffcmd(this, "cmd clientversion $gameversion\n");
1239
1240         // notify about available teams
1241         if (teamplay)
1242         {
1243                 CheckAllowedTeams(this);
1244                 int t = 0;
1245                 if (c1 >= 0) t |= BIT(0);
1246                 if (c2 >= 0) t |= BIT(1);
1247                 if (c3 >= 0) t |= BIT(2);
1248                 if (c4 >= 0) t |= BIT(3);
1249                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1250         }
1251         else
1252         {
1253                 stuffcmd(this, "set _teams_available 0\n");
1254         }
1255
1256         bot_relinkplayerlist();
1257
1258         CS(this).spectatortime = time;
1259         if (blockSpectators)
1260         {
1261                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1262         }
1263
1264         CS(this).jointime = time;
1265
1266         if (IS_REAL_CLIENT(this))
1267         {
1268                 if (g_weaponarena_weapons == WEPSET(TUBA))
1269                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1270         }
1271
1272         if (!sv_foginterval && world.fog != "")
1273                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1274
1275         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1276                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1277                         send_CSQC_teamnagger();
1278
1279         CSQCMODEL_AUTOINIT(this);
1280
1281         CS(this).model_randomizer = random();
1282
1283         if (IS_REAL_CLIENT(this))
1284                 sv_notice_join(this);
1285
1286         // update physics stats (players can spawn before physics runs)
1287         Physics_UpdateStats(this);
1288
1289         IL_EACH(g_initforplayer, it.init_for_player, {
1290                 it.init_for_player(it, this);
1291         });
1292
1293         Handicap_Initialize(this);
1294
1295         MUTATOR_CALLHOOK(ClientConnect, this);
1296
1297         if (IS_REAL_CLIENT(this))
1298         {
1299                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1300                 {
1301                         CS(this).motd_actived_time = -1;
1302                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1303                 }
1304         }
1305 }
1306 /*
1307 =============
1308 ClientDisconnect
1309
1310 Called when a client disconnects from the server
1311 =============
1312 */
1313 .entity chatbubbleentity;
1314 void ReadyCount();
1315 void ClientDisconnect(entity this)
1316 {
1317         assert(IS_CLIENT(this), return);
1318
1319         PlayerStats_GameReport_FinalizePlayer(this);
1320         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1321         if (CS(this).active_minigame) part_minigame(this);
1322         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1323
1324         if (autocvar_sv_eventlog)
1325                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1326
1327         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1328
1329         if(IS_SPEC(this))
1330                 SetSpectatee(this, NULL);
1331
1332     MUTATOR_CALLHOOK(ClientDisconnect, this);
1333
1334         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1335         ClientState_detach(this);
1336
1337         Portal_ClearAll(this);
1338
1339         Unfreeze(this);
1340
1341         RemoveGrapplingHooks(this);
1342
1343         // Here, everything has been done that requires this player to be a client.
1344
1345         this.flags &= ~FL_CLIENT;
1346
1347         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1348         if (this.killindicator) delete(this.killindicator);
1349
1350         WaypointSprite_PlayerGone(this);
1351
1352         bot_relinkplayerlist();
1353
1354         if (this.clientstatus) strunzone(this.clientstatus);
1355         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1356         if (this.personal) delete(this.personal);
1357
1358         this.playerid = 0;
1359         ReadyCount();
1360         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1361
1362         ONREMOVE(this);
1363 }
1364
1365 void ChatBubbleThink(entity this)
1366 {
1367         this.nextthink = time;
1368         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1369         {
1370                 if(this.owner) // but why can that ever be NULL?
1371                         this.owner.chatbubbleentity = NULL;
1372                 delete(this);
1373                 return;
1374         }
1375
1376         this.mdl = "";
1377
1378         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1379         {
1380                 if ( CS(this.owner).active_minigame )
1381                         this.mdl = "models/sprites/minigame_busy.iqm";
1382                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1383                         this.mdl = "models/misc/chatbubble.spr";
1384         }
1385
1386         if ( this.model != this.mdl )
1387                 _setmodel(this, this.mdl);
1388
1389 }
1390
1391 void UpdateChatBubble(entity this)
1392 {
1393         if (this.alpha < 0)
1394                 return;
1395         // spawn a chatbubble entity if needed
1396         if (!this.chatbubbleentity)
1397         {
1398                 this.chatbubbleentity = new(chatbubbleentity);
1399                 this.chatbubbleentity.owner = this;
1400                 this.chatbubbleentity.exteriormodeltoclient = this;
1401                 setthink(this.chatbubbleentity, ChatBubbleThink);
1402                 this.chatbubbleentity.nextthink = time;
1403                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1404                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1405                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1406                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1407                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1408                 //this.chatbubbleentity.model = "";
1409                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1410         }
1411 }
1412
1413
1414 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1415 // added to the model skins
1416 /*void UpdateColorModHack()
1417 {
1418         float c;
1419         c = this.clientcolors & 15;
1420         // LordHavoc: only bothering to support white, green, red, yellow, blue
1421              if (!teamplay) this.colormod = '0 0 0';
1422         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1423         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1424         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1425         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1426         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1427         else this.colormod = '1 1 1';
1428 }*/
1429
1430 void respawn(entity this)
1431 {
1432         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1433         {
1434                 this.solid = SOLID_NOT;
1435                 this.takedamage = DAMAGE_NO;
1436                 set_movetype(this, MOVETYPE_FLY);
1437                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1438                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1439                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1440                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1441                 if(autocvar_g_respawn_ghosts_maxtime)
1442                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1443         }
1444
1445         CopyBody(this, 1);
1446
1447         this.effects |= EF_NODRAW; // prevent another CopyBody
1448         PutClientInServer(this);
1449 }
1450
1451 void play_countdown(entity this, float finished, Sound samp)
1452 {
1453     TC(Sound, samp);
1454         if(IS_REAL_CLIENT(this))
1455                 if(floor(finished - time - frametime) != floor(finished - time))
1456                         if(finished - time < 6)
1457                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1458 }
1459
1460 void player_powerups(entity this)
1461 {
1462         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1463         int items_prev = this.items;
1464
1465         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1466                 this.modelflags |= MF_ROCKET;
1467         else
1468                 this.modelflags &= ~MF_ROCKET;
1469
1470         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1471
1472         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1473                 return;
1474
1475         Fire_ApplyDamage(this);
1476         Fire_ApplyEffect(this);
1477
1478         if (!g_instagib)
1479         {
1480                 if (this.items & ITEM_Strength.m_itemid)
1481                 {
1482                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1483                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1484                         if (time > this.strength_finished)
1485                         {
1486                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1487                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1488                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1489                         }
1490                 }
1491                 else
1492                 {
1493                         if (time < this.strength_finished)
1494                         {
1495                                 this.items = this.items | ITEM_Strength.m_itemid;
1496                                 if(!g_cts)
1497                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1498                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1499                         }
1500                 }
1501                 if (this.items & ITEM_Shield.m_itemid)
1502                 {
1503                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1504                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1505                         if (time > this.invincible_finished)
1506                         {
1507                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1508                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1509                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1510                         }
1511                 }
1512                 else
1513                 {
1514                         if (time < this.invincible_finished)
1515                         {
1516                                 this.items = this.items | ITEM_Shield.m_itemid;
1517                                 if(!g_cts)
1518                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1519                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1520                         }
1521                 }
1522                 if (this.items & IT_SUPERWEAPON)
1523                 {
1524                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1525                         {
1526                                 this.superweapons_finished = 0;
1527                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1528                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1529                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1530                         }
1531                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1532                         {
1533                                 // don't let them run out
1534                         }
1535                         else
1536                         {
1537                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1538                                 if (time > this.superweapons_finished)
1539                                 {
1540                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1541                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1542                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1543                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1544                                 }
1545                         }
1546                 }
1547                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1548                 {
1549                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1550                         {
1551                                 this.items = this.items | IT_SUPERWEAPON;
1552                                 if(!g_cts)
1553                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1554                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1555                         }
1556                         else
1557                         {
1558                                 this.superweapons_finished = 0;
1559                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1560                         }
1561                 }
1562                 else
1563                 {
1564                         this.superweapons_finished = 0;
1565                 }
1566         }
1567
1568         if(autocvar_g_nodepthtestplayers)
1569                 this.effects = this.effects | EF_NODEPTHTEST;
1570
1571         if(autocvar_g_fullbrightplayers)
1572                 this.effects = this.effects | EF_FULLBRIGHT;
1573
1574         if (time >= game_starttime)
1575         if (time < this.spawnshieldtime)
1576                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1577
1578         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1579 }
1580
1581 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1582 {
1583         if(current > stable)
1584                 return current;
1585         else if(current > stable - 0.25) // when close enough, "snap"
1586                 return stable;
1587         else
1588                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1589 }
1590
1591 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1592 {
1593         if(current < stable)
1594                 return current;
1595         else if(current < stable + 0.25) // when close enough, "snap"
1596                 return stable;
1597         else
1598                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1599 }
1600
1601 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1602 {
1603         if(current > rotstable)
1604         {
1605                 if(rotframetime > 0)
1606                 {
1607                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1608                         current = max(rotstable, current - rotlinear * rotframetime);
1609                 }
1610         }
1611         else if(current < regenstable)
1612         {
1613                 if(regenframetime > 0)
1614                 {
1615                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1616                         current = min(regenstable, current + regenlinear * regenframetime);
1617                 }
1618         }
1619
1620         if(current > limit)
1621                 current = limit;
1622
1623         return current;
1624 }
1625
1626 void player_regen(entity this)
1627 {
1628         float max_mod, regen_mod, rot_mod, limit_mod;
1629         max_mod = regen_mod = rot_mod = limit_mod = 1;
1630
1631         float regen_health = autocvar_g_balance_health_regen;
1632         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1633         float regen_health_rot = autocvar_g_balance_health_rot;
1634         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1635         float regen_health_stable = autocvar_g_balance_health_regenstable;
1636         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1637         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1638                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1639         max_mod = M_ARGV(1, float);
1640         regen_mod = M_ARGV(2, float);
1641         rot_mod = M_ARGV(3, float);
1642         limit_mod = M_ARGV(4, float);
1643         regen_health = M_ARGV(5, float);
1644         regen_health_linear = M_ARGV(6, float);
1645         regen_health_rot = M_ARGV(7, float);
1646         regen_health_rotlinear = M_ARGV(8, float);
1647         regen_health_stable = M_ARGV(9, float);
1648         regen_health_rotstable = M_ARGV(10, float);
1649
1650         if(!mutator_returnvalue)
1651         if(!STAT(FROZEN, this))
1652         {
1653                 float mina, maxa, limith, limita;
1654                 maxa = autocvar_g_balance_armor_rotstable;
1655                 mina = autocvar_g_balance_armor_regenstable;
1656                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1657                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1658
1659                 regen_health_rotstable = regen_health_rotstable * max_mod;
1660                 regen_health_stable = regen_health_stable * max_mod;
1661                 limith = limith * limit_mod;
1662                 limita = limita * limit_mod;
1663
1664                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1665                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1666         }
1667
1668         // if player rotted to death...  die!
1669         // check this outside above checks, as player may still be able to rot to death
1670         if(this.health < 1)
1671         {
1672                 if(this.vehicle)
1673                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1674                 if(this.event_damage)
1675                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1676         }
1677
1678         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1679         {
1680                 float minf, maxf, limitf;
1681
1682                 maxf = autocvar_g_balance_fuel_rotstable;
1683                 minf = autocvar_g_balance_fuel_regenstable;
1684                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1685
1686                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1687         }
1688         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1689         // TODO: Remove this hack when all code uses GivePlayerHealth and
1690         // GivePlayerArmor.
1691         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1692         {
1693                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1694         }
1695         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1696         {
1697                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1698         }
1699         // End hack.
1700 }
1701
1702 bool zoomstate_set;
1703 void SetZoomState(entity this, float newzoom)
1704 {
1705         if(newzoom != CS(this).zoomstate)
1706         {
1707                 CS(this).zoomstate = newzoom;
1708                 ClientData_Touch(this);
1709         }
1710         zoomstate_set = true;
1711 }
1712
1713 void GetPressedKeys(entity this)
1714 {
1715         MUTATOR_CALLHOOK(GetPressedKeys, this);
1716         int keys = STAT(PRESSED_KEYS, this);
1717         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1718         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1719         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1720         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1721
1722         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1723         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1724         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1725         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1726         CS(this).pressedkeys = keys; // store for other users
1727
1728         STAT(PRESSED_KEYS, this) = keys;
1729 }
1730
1731 /*
1732 ======================
1733 spectate mode routines
1734 ======================
1735 */
1736
1737 void SpectateCopy(entity this, entity spectatee)
1738 {
1739     TC(Client, this); TC(Client, spectatee);
1740
1741         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1742         PS(this) = PS(spectatee);
1743         this.armortype = spectatee.armortype;
1744         this.armorvalue = spectatee.armorvalue;
1745         this.ammo_cells = spectatee.ammo_cells;
1746         this.ammo_plasma = spectatee.ammo_plasma;
1747         this.ammo_shells = spectatee.ammo_shells;
1748         this.ammo_nails = spectatee.ammo_nails;
1749         this.ammo_rockets = spectatee.ammo_rockets;
1750         this.ammo_fuel = spectatee.ammo_fuel;
1751         this.clip_load = spectatee.clip_load;
1752         this.clip_size = spectatee.clip_size;
1753         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1754         this.health = spectatee.health;
1755         CS(this).impulse = 0;
1756         this.items = spectatee.items;
1757         this.last_pickup = spectatee.last_pickup;
1758         this.hit_time = spectatee.hit_time;
1759         this.strength_finished = spectatee.strength_finished;
1760         this.invincible_finished = spectatee.invincible_finished;
1761         this.superweapons_finished = spectatee.superweapons_finished;
1762         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1763         this.weapons = spectatee.weapons;
1764         this.vortex_charge = spectatee.vortex_charge;
1765         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1766         this.hagar_load = spectatee.hagar_load;
1767         this.arc_heat_percent = spectatee.arc_heat_percent;
1768         this.minelayer_mines = spectatee.minelayer_mines;
1769         this.punchangle = spectatee.punchangle;
1770         this.view_ofs = spectatee.view_ofs;
1771         this.velocity = spectatee.velocity;
1772         this.dmg_take = spectatee.dmg_take;
1773         this.dmg_save = spectatee.dmg_save;
1774         this.dmg_inflictor = spectatee.dmg_inflictor;
1775         this.v_angle = spectatee.v_angle;
1776         this.angles = spectatee.v_angle;
1777         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1778         this.revive_progress = spectatee.revive_progress;
1779         this.viewloc = spectatee.viewloc;
1780         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1781                 this.fixangle = true;
1782         setorigin(this, spectatee.origin);
1783         setsize(this, spectatee.mins, spectatee.maxs);
1784         SetZoomState(this, CS(spectatee).zoomstate);
1785
1786         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1787         {
1788                 .entity weaponentity = weaponentities[slot];
1789                 this.(weaponentity) = spectatee.(weaponentity);
1790         }
1791
1792         for(int slot = 0; slot < MAX_AXH; ++slot)
1793         {
1794                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1795         }
1796
1797     anticheat_spectatecopy(this, spectatee);
1798         this.hud = spectatee.hud;
1799         if(spectatee.vehicle)
1800     {
1801         this.angles = spectatee.v_angle;
1802
1803         //this.fixangle = false;
1804         //this.velocity = spectatee.vehicle.velocity;
1805         this.vehicle_health = spectatee.vehicle_health;
1806         this.vehicle_shield = spectatee.vehicle_shield;
1807         this.vehicle_energy = spectatee.vehicle_energy;
1808         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1809         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1810         this.vehicle_reload1 = spectatee.vehicle_reload1;
1811         this.vehicle_reload2 = spectatee.vehicle_reload2;
1812
1813         //msg_entity = this;
1814
1815        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1816             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1817            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1818            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1819
1820         //WriteByte (MSG_ONE, SVC_SETVIEW);
1821         //    WriteEntity(MSG_ONE, this);
1822         //makevectors(spectatee.v_angle);
1823         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1824     }
1825 }
1826
1827 bool SpectateUpdate(entity this)
1828 {
1829         if(!this.enemy)
1830                 return false;
1831
1832         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1833         {
1834                 SetSpectatee(this, NULL);
1835                 return false;
1836         }
1837
1838         SpectateCopy(this, this.enemy);
1839
1840         return true;
1841 }
1842
1843 bool SpectateSet(entity this)
1844 {
1845         if(!IS_PLAYER(this.enemy))
1846                 return false;
1847
1848         ClientData_Touch(this.enemy);
1849
1850         msg_entity = this;
1851         WriteByte(MSG_ONE, SVC_SETVIEW);
1852         WriteEntity(MSG_ONE, this.enemy);
1853         set_movetype(this, MOVETYPE_NONE);
1854         accuracy_resend(this);
1855
1856         if(!SpectateUpdate(this))
1857                 PutObserverInServer(this);
1858
1859         return true;
1860 }
1861
1862 void SetSpectatee_status(entity this, int spectatee_num)
1863 {
1864         int oldspectatee_status = CS(this).spectatee_status;
1865         CS(this).spectatee_status = spectatee_num;
1866
1867         if (CS(this).spectatee_status != oldspectatee_status)
1868         {
1869                 ClientData_Touch(this);
1870                 if (g_race || g_cts) race_InitSpectator();
1871         }
1872 }
1873
1874 void SetSpectatee(entity this, entity spectatee)
1875 {
1876         if(IS_BOT_CLIENT(this))
1877                 return; // bots abuse .enemy, this code is useless to them
1878
1879         entity old_spectatee = this.enemy;
1880
1881         this.enemy = spectatee;
1882
1883         // WEAPONTODO
1884         // these are required to fix the spectator bug with arc
1885         if(old_spectatee)
1886         {
1887                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1888                 {
1889                         .entity weaponentity = weaponentities[slot];
1890                         if(old_spectatee.(weaponentity).arc_beam)
1891                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1892                 }
1893         }
1894         if(this.enemy)
1895         {
1896                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1897                 {
1898                         .entity weaponentity = weaponentities[slot];
1899                         if(this.enemy.(weaponentity).arc_beam)
1900                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1901                 }
1902         }
1903
1904         if (this.enemy)
1905                 SetSpectatee_status(this, etof(this.enemy));
1906
1907         // needed to update spectator list
1908         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1909 }
1910
1911 bool Spectate(entity this, entity pl)
1912 {
1913         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1914                 return false;
1915         pl = M_ARGV(1, entity);
1916
1917         SetSpectatee(this, pl);
1918         return SpectateSet(this);
1919 }
1920
1921 bool SpectateNext(entity this)
1922 {
1923         entity ent = find(this.enemy, classname, STR_PLAYER);
1924
1925         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1926                 ent = M_ARGV(1, entity);
1927         else if (!ent)
1928                 ent = find(ent, classname, STR_PLAYER);
1929
1930         if(ent) { SetSpectatee(this, ent); }
1931
1932         return SpectateSet(this);
1933 }
1934
1935 bool SpectatePrev(entity this)
1936 {
1937         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1938         entity ent = findchain(classname, STR_PLAYER);
1939         if (!ent) // no player
1940                 return false;
1941
1942         entity first = ent;
1943         // skip players until current spectated player
1944         if(this.enemy)
1945         while(ent && ent != this.enemy)
1946                 ent = ent.chain;
1947
1948         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1949         {
1950                 case MUT_SPECPREV_FOUND:
1951                     ent = M_ARGV(1, entity);
1952                     break;
1953                 case MUT_SPECPREV_RETURN:
1954                     return true;
1955                 case MUT_SPECPREV_CONTINUE:
1956                 default:
1957                 {
1958                         if(ent.chain)
1959                                 ent = ent.chain;
1960                         else
1961                                 ent = first;
1962                         break;
1963                 }
1964         }
1965
1966         SetSpectatee(this, ent);
1967         return SpectateSet(this);
1968 }
1969
1970 /*
1971 =============
1972 ShowRespawnCountdown()
1973
1974 Update a respawn countdown display.
1975 =============
1976 */
1977 void ShowRespawnCountdown(entity this)
1978 {
1979         float number;
1980         if(!IS_DEAD(this)) // just respawned?
1981                 return;
1982         else
1983         {
1984                 number = ceil(this.respawn_time - time);
1985                 if(number <= 0)
1986                         return;
1987                 if(number <= this.respawn_countdown)
1988                 {
1989                         this.respawn_countdown = number - 1;
1990                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1991                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1992                 }
1993         }
1994 }
1995
1996 .bool team_selected;
1997 bool ShowTeamSelection(entity this)
1998 {
1999         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2000                 return false;
2001         stuffcmd(this, "menu_showteamselect\n");
2002         return true;
2003 }
2004 void Join(entity this)
2005 {
2006         TRANSMUTE(Player, this);
2007
2008         if(!this.team_selected)
2009         if(autocvar_g_campaign || autocvar_g_balance_teams)
2010                 JoinBestTeam(this, true);
2011
2012         if(autocvar_g_campaign)
2013                 campaign_bots_may_start = true;
2014
2015         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2016
2017         PutClientInServer(this);
2018
2019         if(IS_PLAYER(this))
2020         if(teamplay && this.team != -1)
2021                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2022         else
2023                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2024         this.team_selected = false;
2025 }
2026
2027 /**
2028  * Determines whether the player is allowed to join. This depends on cvar
2029  * g_maxplayers, if it isn't used this function always return true, otherwise
2030  * it checks whether the number of currently playing players exceeds g_maxplayers.
2031  * @return int number of free slots for players, 0 if none
2032  */
2033 int nJoinAllowed(entity this, entity ignore)
2034 {
2035         if(!ignore)
2036         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2037         // so report 0 free slots if restricted
2038         {
2039                 if(autocvar_g_forced_team_otherwise == "spectate")
2040                         return 0;
2041                 if(autocvar_g_forced_team_otherwise == "spectator")
2042                         return 0;
2043         }
2044
2045         if(this && this.team_forced < 0)
2046                 return 0; // forced spectators can never join
2047
2048         // TODO simplify this
2049         int totalClients = 0;
2050         int currentlyPlaying = 0;
2051         FOREACH_CLIENT(true, {
2052                 if(it != ignore)
2053                         ++totalClients;
2054                 if(IS_REAL_CLIENT(it))
2055                 if(IS_PLAYER(it) || it.caplayer)
2056                         ++currentlyPlaying;
2057         });
2058
2059         float free_slots = 0;
2060         if (!autocvar_g_maxplayers)
2061                 free_slots = maxclients - totalClients;
2062         else if(currentlyPlaying < autocvar_g_maxplayers)
2063                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2064
2065         static float join_prevent_msg_time = 0;
2066         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2067         {
2068                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2069                 join_prevent_msg_time = time + 3;
2070         }
2071
2072         return free_slots;
2073 }
2074
2075 /**
2076  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2077  * g_maxplayers_spectator_blocktime seconds
2078  */
2079 void checkSpectatorBlock(entity this)
2080 {
2081         if(IS_SPEC(this) || IS_OBSERVER(this))
2082         if(!this.caplayer)
2083         if(IS_REAL_CLIENT(this))
2084         {
2085                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2086                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2087                         dropclient(this);
2088                 }
2089         }
2090 }
2091
2092 void PrintWelcomeMessage(entity this)
2093 {
2094         if(CS(this).motd_actived_time == 0)
2095         {
2096                 if (autocvar_g_campaign) {
2097                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2098                                 CS(this).motd_actived_time = time;
2099                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2100                         }
2101                 } else {
2102                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2103                                 CS(this).motd_actived_time = time;
2104                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2105                         }
2106                 }
2107         }
2108         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2109         {
2110                 if (autocvar_g_campaign) {
2111                         if (PHYS_INPUT_BUTTON_INFO(this))
2112                                 CS(this).motd_actived_time = time;
2113                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2114                                 CS(this).motd_actived_time = 0;
2115                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2116                         }
2117                 } else {
2118                         if (PHYS_INPUT_BUTTON_INFO(this))
2119                                 CS(this).motd_actived_time = time;
2120                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2121                                 CS(this).motd_actived_time = 0;
2122                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2123                         }
2124                 }
2125         }
2126         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2127         {
2128                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2129                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2130                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2131                 {
2132                         // instanctly hide MOTD
2133                         CS(this).motd_actived_time = 0;
2134                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2135                 }
2136         }
2137 }
2138
2139 bool joinAllowed(entity this)
2140 {
2141         if (CS(this).version_mismatch) return false;
2142         if (!nJoinAllowed(this, this)) return false;
2143         if (teamplay && lockteams) return false;
2144         if (ShowTeamSelection(this)) return false;
2145         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2146         return true;
2147 }
2148
2149 .int items_added;
2150 bool PlayerThink(entity this)
2151 {
2152         if (game_stopped || intermission_running) {
2153                 this.modelflags &= ~MF_ROCKET;
2154                 if(intermission_running)
2155                         IntermissionThink(this);
2156                 return false;
2157         }
2158
2159         if (timeout_status == TIMEOUT_ACTIVE) {
2160         // don't allow the player to turn around while game is paused
2161                 // FIXME turn this into CSQC stuff
2162                 this.v_angle = this.lastV_angle;
2163                 this.angles = this.lastV_angle;
2164                 this.fixangle = true;
2165         }
2166
2167         if (frametime) player_powerups(this);
2168
2169         if (IS_DEAD(this)) {
2170                 if (this.personal && g_race_qualifying) {
2171                         if (time > this.respawn_time) {
2172                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2173                                 respawn(this);
2174                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2175                         }
2176                 } else {
2177                         if (frametime) player_anim(this);
2178
2179                         if (this.respawn_flags & RESPAWN_DENY)
2180                         {
2181                                 STAT(RESPAWN_TIME, this) = 0;
2182                                 return false;
2183                         }
2184
2185                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2186
2187                         switch(this.deadflag)
2188                         {
2189                                 case DEAD_DYING:
2190                                 {
2191                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2192                                                 this.deadflag = DEAD_RESPAWNING;
2193                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2194                                                 this.deadflag = DEAD_DEAD;
2195                                         break;
2196                                 }
2197                                 case DEAD_DEAD:
2198                                 {
2199                                         if (button_pressed)
2200                                                 this.deadflag = DEAD_RESPAWNABLE;
2201                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2202                                                 this.deadflag = DEAD_RESPAWNING;
2203                                         break;
2204                                 }
2205                                 case DEAD_RESPAWNABLE:
2206                                 {
2207                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2208                                                 this.deadflag = DEAD_RESPAWNING;
2209                                         break;
2210                                 }
2211                                 case DEAD_RESPAWNING:
2212                                 {
2213                                         if (time > this.respawn_time)
2214                                         {
2215                                                 this.respawn_time = time + 1; // only retry once a second
2216                                                 this.respawn_time_max = this.respawn_time;
2217                                                 respawn(this);
2218                                         }
2219                                         break;
2220                                 }
2221                         }
2222
2223                         ShowRespawnCountdown(this);
2224
2225                         if (this.respawn_flags & RESPAWN_SILENT)
2226                                 STAT(RESPAWN_TIME, this) = 0;
2227                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2228                         {
2229                                 if (time < this.respawn_time)
2230                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2231                                 else if (this.deadflag != DEAD_RESPAWNING)
2232                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2233                         }
2234                         else
2235                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2236                 }
2237
2238                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2239                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2240                         STAT(RESPAWN_TIME, this) *= -1;
2241
2242                 return false;
2243         }
2244
2245         bool have_hook = false;
2246         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2247         {
2248                 .entity weaponentity = weaponentities[slot];
2249                 if(this.(weaponentity).hook.state)
2250                 {
2251                         have_hook = true;
2252                         break;
2253                 }
2254         }
2255         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2256         if (have_hook) {
2257                 do_crouch = false;
2258         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2259                 do_crouch = false;
2260         } else if (this.vehicle) {
2261                 do_crouch = false;
2262         } else if (STAT(FROZEN, this)) {
2263                 do_crouch = false;
2264     }
2265
2266         if (do_crouch) {
2267                 if (!this.crouch) {
2268                         this.crouch = true;
2269                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2270                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2271                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2272                 }
2273         } else if (this.crouch) {
2274         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2275         if (!trace_startsolid) {
2276             this.crouch = false;
2277             this.view_ofs = STAT(PL_VIEW_OFS, this);
2278             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2279         }
2280         }
2281
2282         FixPlayermodel(this);
2283
2284         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2285         //if(frametime)
2286         {
2287                 this.items &= ~this.items_added;
2288
2289                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2290                 {
2291                         .entity weaponentity = weaponentities[slot];
2292                         W_WeaponFrame(this, weaponentity);
2293
2294                         if(slot == 0)
2295                         {
2296                                 this.clip_load = this.(weaponentity).clip_load;
2297                                 this.clip_size = this.(weaponentity).clip_size;
2298                         }
2299                 }
2300
2301                 this.items_added = 0;
2302                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2303             this.items_added |= IT_FUEL;
2304
2305                 this.items |= this.items_added;
2306         }
2307
2308         player_regen(this);
2309
2310         // WEAPONTODO: Add a weapon request for this
2311         // rot vortex charge to the charge limit
2312         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2313         {
2314                 .entity weaponentity = weaponentities[slot];
2315                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2316                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2317         }
2318
2319         if (frametime) player_anim(this);
2320
2321         // secret status
2322         secrets_setstatus(this);
2323
2324         // monsters status
2325         monsters_setstatus(this);
2326
2327         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2328
2329         return true;
2330 }
2331
2332 void ObserverThink(entity this)
2333 {
2334         if ( CS(this).impulse )
2335         {
2336                 MinigameImpulse(this, CS(this).impulse);
2337                 CS(this).impulse = 0;
2338         }
2339
2340         if (this.flags & FL_JUMPRELEASED) {
2341                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2342                         this.flags &= ~FL_JUMPRELEASED;
2343                         this.flags |= FL_SPAWNING;
2344                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2345                         this.flags &= ~FL_JUMPRELEASED;
2346                         if(SpectateNext(this)) {
2347                                 TRANSMUTE(Spectator, this);
2348                         }
2349                 } else {
2350                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2351                         set_movetype(this, preferred_movetype);
2352                 }
2353         } else {
2354                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2355                         this.flags |= FL_JUMPRELEASED;
2356                         if(this.flags & FL_SPAWNING)
2357                         {
2358                                 this.flags &= ~FL_SPAWNING;
2359                                 Join(this);
2360                                 return;
2361                         }
2362                 }
2363         }
2364 }
2365
2366 void SpectatorThink(entity this)
2367 {
2368         if ( CS(this).impulse )
2369         {
2370                 if(MinigameImpulse(this, CS(this).impulse))
2371                         CS(this).impulse = 0;
2372
2373                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2374                 {
2375                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2376                         CS(this).impulse = 0;
2377                         return;
2378                 }
2379         }
2380
2381         if (this.flags & FL_JUMPRELEASED) {
2382                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2383                         this.flags &= ~FL_JUMPRELEASED;
2384                         this.flags |= FL_SPAWNING;
2385                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2386                         this.flags &= ~FL_JUMPRELEASED;
2387                         if(SpectateNext(this)) {
2388                                 TRANSMUTE(Spectator, this);
2389                         } else {
2390                                 TRANSMUTE(Observer, this);
2391                                 PutClientInServer(this);
2392                         }
2393                         CS(this).impulse = 0;
2394                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2395                         this.flags &= ~FL_JUMPRELEASED;
2396                         if(SpectatePrev(this)) {
2397                                 TRANSMUTE(Spectator, this);
2398                         } else {
2399                                 TRANSMUTE(Observer, this);
2400                                 PutClientInServer(this);
2401                         }
2402                         CS(this).impulse = 0;
2403                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2404                         this.flags &= ~FL_JUMPRELEASED;
2405                         TRANSMUTE(Observer, this);
2406                         PutClientInServer(this);
2407                 } else {
2408                         if(!SpectateUpdate(this))
2409                                 PutObserverInServer(this);
2410                 }
2411         } else {
2412                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2413                         this.flags |= FL_JUMPRELEASED;
2414                         if(this.flags & FL_SPAWNING)
2415                         {
2416                                 this.flags &= ~FL_SPAWNING;
2417                                 Join(this);
2418                                 return;
2419                         }
2420                 }
2421                 if(!SpectateUpdate(this))
2422                         PutObserverInServer(this);
2423         }
2424
2425         this.flags |= FL_CLIENT | FL_NOTARGET;
2426 }
2427
2428 void vehicles_enter (entity pl, entity veh);
2429 void PlayerUseKey(entity this)
2430 {
2431         if (!IS_PLAYER(this))
2432                 return;
2433
2434         if(this.vehicle)
2435         {
2436                 if(!game_stopped)
2437                 {
2438                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2439                         return;
2440                 }
2441         }
2442         else if(autocvar_g_vehicles_enter)
2443         {
2444                 if(!STAT(FROZEN, this))
2445                 if(!IS_DEAD(this))
2446                 if(!game_stopped)
2447                 {
2448                         entity head, closest_target = NULL;
2449                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2450
2451                         while(head) // find the closest acceptable target to enter
2452                         {
2453                                 if(IS_VEHICLE(head))
2454                                 if(!IS_DEAD(head))
2455                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2456                                 if(head.takedamage != DAMAGE_NO)
2457                                 {
2458                                         if(closest_target)
2459                                         {
2460                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2461                                                 { closest_target = head; }
2462                                         }
2463                                         else { closest_target = head; }
2464                                 }
2465
2466                                 head = head.chain;
2467                         }
2468
2469                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2470                 }
2471         }
2472
2473         // a use key was pressed; call handlers
2474         MUTATOR_CALLHOOK(PlayerUseKey, this);
2475 }
2476
2477
2478 /*
2479 =============
2480 PlayerPreThink
2481
2482 Called every frame for each client before the physics are run
2483 =============
2484 */
2485 .float last_vehiclecheck;
2486 void PlayerPreThink (entity this)
2487 {
2488         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2489         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2490
2491         WarpZone_PlayerPhysics_FixVAngle(this);
2492
2493         if (frametime) {
2494                 // physics frames: update anticheat stuff
2495                 anticheat_prethink(this);
2496         }
2497
2498         if (blockSpectators && frametime) {
2499                 // WORKAROUND: only use dropclient in server frames (frametime set).
2500                 // Never use it in cl_movement frames (frametime zero).
2501                 checkSpectatorBlock(this);
2502         }
2503
2504         zoomstate_set = false;
2505
2506         // Check for nameless players
2507         if (this.netname == "" || this.netname != CS(this).netname_previous)
2508         {
2509                 bool assume_unchanged = (CS(this).netname_previous == "");
2510                 if (isInvisibleString(this.netname))
2511                 {
2512                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2513                         assume_unchanged = false;
2514                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2515                 }
2516                 if (!assume_unchanged && autocvar_sv_eventlog)
2517                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2518                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2519                 CS(this).netname_previous = strzone(this.netname);
2520         }
2521
2522         // version nagging
2523         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2524         CS(this).version_nagtime = 0;
2525         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2526             // git client
2527         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2528             // git server
2529             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2530         } else {
2531             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2532             if (r < 0) { // old client
2533                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2534             } else if (r > 0) { // old server
2535                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2536             }
2537         }
2538     }
2539
2540         // GOD MODE info
2541         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2542         {
2543                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2544                 this.max_armorvalue = 0;
2545         }
2546
2547         if(IS_PLAYER(this))
2548         {
2549                 if (STAT(FROZEN, this) == 2)
2550                 {
2551                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2552                         this.health = max(1, this.revive_progress * start_health);
2553                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2554
2555                         if (this.revive_progress >= 1)
2556                                 Unfreeze(this);
2557                 }
2558                 else if (STAT(FROZEN, this) == 3)
2559                 {
2560                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2561                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2562
2563                         if (this.health < 1)
2564                         {
2565                                 if (this.vehicle)
2566                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2567                                 if(this.event_damage)
2568                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2569                         }
2570                         else if (this.revive_progress <= 0)
2571                                 Unfreeze(this);
2572                 }
2573         }
2574
2575         MUTATOR_CALLHOOK(PlayerPreThink, this);
2576
2577         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2578         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2579         {
2580                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2581                 {
2582                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2583                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2584                         {
2585                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2586                         }
2587                         else if(!it.owner)
2588                         {
2589                                 if(!it.team || SAME_TEAM(this, it))
2590                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2591                                 else if(autocvar_g_vehicles_steal)
2592                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2593                         }
2594                 });
2595
2596                 this.last_vehiclecheck = time + 1;
2597         }
2598
2599         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2600         {
2601                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2602                         PlayerUseKey(this);
2603                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2604         }
2605
2606         if (IS_REAL_CLIENT(this))
2607                 PrintWelcomeMessage(this);
2608
2609         if (IS_PLAYER(this)) {
2610                 if(!PlayerThink(this))
2611                         return;
2612         }
2613         else if (game_stopped || intermission_running) {
2614                 if(intermission_running)
2615                         IntermissionThink(this);
2616                 return;
2617         }
2618         else if (IS_OBSERVER(this)) {
2619                 ObserverThink(this);
2620         }
2621         else if (IS_SPEC(this)) {
2622                 SpectatorThink(this);
2623         }
2624
2625         // WEAPONTODO: Add weapon request for this
2626         if (!zoomstate_set) {
2627                 bool wep_zoomed = false;
2628                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2629                 {
2630                         .entity weaponentity = weaponentities[slot];
2631                         Weapon thiswep = this.(weaponentity).m_weapon;
2632                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2633                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2634                 }
2635                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2636     }
2637
2638         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2639         {
2640                 CS(this).teamkill_soundtime = 0;
2641
2642                 entity e = CS(this).teamkill_soundsource;
2643                 entity oldpusher = e.pusher;
2644                 e.pusher = this;
2645                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2646                 e.pusher = oldpusher;
2647         }
2648
2649         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2650                 CS(this).taunt_soundtime = 0;
2651                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2652         }
2653
2654         target_voicescript_next(this);
2655
2656         // WEAPONTODO: Move into weaponsystem somehow
2657         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2658         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2659         {
2660                 .entity weaponentity = weaponentities[slot];
2661                 if(this.(weaponentity).m_weapon == WEP_Null)
2662                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2663         }
2664 }
2665
2666 void DrownPlayer(entity this)
2667 {
2668         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2669                 return;
2670
2671         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2672         {
2673                 if(this.air_finished < time)
2674                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2675                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2676         }
2677         else if (this.air_finished < time)
2678         {       // drown!
2679                 if (this.pain_finished < time)
2680                 {
2681                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2682                         this.pain_finished = time + 0.5;
2683                 }
2684         }
2685 }
2686
2687 .bool move_qcphysics;
2688
2689 void Player_Physics(entity this)
2690 {
2691         set_movetype(this, this.move_movetype);
2692
2693         if(!this.move_qcphysics)
2694                 return;
2695
2696         if(!frametime && !CS(this).pm_frametime)
2697                 return;
2698
2699         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2700
2701         CS(this).pm_frametime = 0;
2702 }
2703
2704 /*
2705 =============
2706 PlayerPostThink
2707
2708 Called every frame for each client after the physics are run
2709 =============
2710 */
2711 void PlayerPostThink (entity this)
2712 {
2713         Player_Physics(this);
2714
2715         if (sv_maxidle > 0)
2716         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2717         if (IS_REAL_CLIENT(this))
2718         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2719         {
2720                 int totalClients = 0;
2721                 if(sv_maxidle_slots > 0)
2722                 {
2723                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2724                         {
2725                                 ++totalClients;
2726                         });
2727                 }
2728
2729                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2730                 { /* do nothing */ }
2731                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2732                 {
2733                         if (CS(this).idlekick_lasttimeleft)
2734                         {
2735                                 CS(this).idlekick_lasttimeleft = 0;
2736                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2737                         }
2738                 }
2739                 else
2740                 {
2741                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2742                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2743                                 if (!CS(this).idlekick_lasttimeleft)
2744                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2745                         }
2746                         if (timeleft <= 0) {
2747                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2748                                 dropclient(this);
2749                                 return;
2750                         }
2751                         else if (timeleft <= 10) {
2752                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2753                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2754                 }
2755                                 CS(this).idlekick_lasttimeleft = timeleft;
2756                         }
2757                 }
2758         }
2759
2760         CheatFrame(this);
2761
2762         if (game_stopped)
2763         {
2764                 this.solid = SOLID_NOT;
2765                 this.takedamage = DAMAGE_NO;
2766                 set_movetype(this, MOVETYPE_NONE);
2767         }
2768
2769         if (IS_PLAYER(this)) {
2770                 DrownPlayer(this);
2771                 UpdateChatBubble(this);
2772                 if (CS(this).impulse) ImpulseCommands(this);
2773                 if (game_stopped)
2774                 {
2775                         CSQCMODEL_AUTOUPDATE(this);
2776                         return;
2777                 }
2778                 GetPressedKeys(this);
2779         }
2780
2781         if (this.waypointsprite_attachedforcarrier) {
2782             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2783                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2784     }
2785
2786         playerdemo_write(this);
2787
2788         CSQCMODEL_AUTOUPDATE(this);
2789 }
2790
2791 // hack to copy the button fields from the client entity to the Client State
2792 void PM_UpdateButtons(entity this, entity store)
2793 {
2794         if(this.impulse)
2795                 store.impulse = this.impulse;
2796         this.impulse = 0;
2797
2798         store.button0 = this.button0;
2799         store.button2 = this.button2;
2800         store.button3 = this.button3;
2801         store.button4 = this.button4;
2802         store.button5 = this.button5;
2803         store.button6 = this.button6;
2804         store.button7 = this.button7;
2805         store.button8 = this.button8;
2806         store.button9 = this.button9;
2807         store.button10 = this.button10;
2808         store.button11 = this.button11;
2809         store.button12 = this.button12;
2810         store.button13 = this.button13;
2811         store.button14 = this.button14;
2812         store.button15 = this.button15;
2813         store.button16 = this.button16;
2814         store.buttonuse = this.buttonuse;
2815         store.buttonchat = this.buttonchat;
2816
2817         store.cursor_active = this.cursor_active;
2818         store.cursor_screen = this.cursor_screen;
2819         store.cursor_trace_start = this.cursor_trace_start;
2820         store.cursor_trace_endpos = this.cursor_trace_endpos;
2821         store.cursor_trace_ent = this.cursor_trace_ent;
2822
2823         store.ping = this.ping;
2824         store.ping_packetloss = this.ping_packetloss;
2825         store.ping_movementloss = this.ping_movementloss;
2826
2827         store.v_angle = this.v_angle;
2828         store.movement = this.movement;
2829 }