qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         bool recount_ready = false;
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         this.ready = false;
 257                         recount_ready = true;
 258                 }
 259                 entcs_update_players(this);
 260         }
 261
 262         if (use_spawnpoint)
 263         {
 264                 entity spot = SelectSpawnPoint(this, true);
 265                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 266                 this.angles = vec2(spot.angles);
 267                 // offset it so that the spectator spawns higher off the ground, looks better this way
 268                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 269         }
 270         else // change origin to restore previous view origin
 271                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 272         this.fixangle = true;
 273
 274         if (IS_REAL_CLIENT(this))
 275         {
 276                 msg_entity = this;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, this);
 279         }
 280         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 281         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 282         if(!autocvar_g_debug_globalsounds)
 283         {
 284                 // needed for player sounds
 285                 this.model = "";
 286                 FixPlayermodel(this);
 287         }
 288         setmodel(this, MDL_Null);
 289         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 290         this.view_ofs = '0 0 0';
 291
 292         RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         TRANSMUTE(Observer, this);
 307
 308         if(recount_ready) ReadyCount();
 309
 310         WaypointSprite_PlayerDead(this);
 311         accuracy_resend(this);
 312
 313         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 314                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323         STAT(HUD, this) = HUD_NORMAL;
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         player_powerups_remove_all(this);
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406
 407         bot_relinkplayerlist();
 408
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void PutPlayerInServer(entity this)
 536 {
 537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 538
 539         PlayerState_attach(this);
 540         accuracy_resend(this);
 541
 542         if (this.team < 0)
 543                 TeamBalance_JoinBestTeam(this);
 544
 545         entity spot = SelectSpawnPoint(this, false);
 546         if (!spot) {
 547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 548                 return; // spawn failed
 549         }
 550
 551         TRANSMUTE(Player, this);
 552
 553         CS(this).wasplayer = true;
 554         this.iscreature = true;
 555         this.teleportable = TELEPORT_NORMAL;
 556         if(!this.damagedbycontents)
 557                 IL_PUSH(g_damagedbycontents, this);
 558         this.damagedbycontents = true;
 559         set_movetype(this, MOVETYPE_WALK);
 560         this.solid = SOLID_SLIDEBOX;
 561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 562         if (autocvar_g_playerclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 566         this.frags = FRAGS_PLAYER;
 567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 569         if (autocvar__notarget)
 570                 this.flags |= FL_NOTARGET;
 571         this.takedamage = DAMAGE_AIM;
 572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 573
 574         if (warmup_stage) {
 575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, warmup_start_health);
 582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 584         } else {
 585                 SetResource(this, RES_SHELLS, start_ammo_shells);
 586                 SetResource(this, RES_BULLETS, start_ammo_nails);
 587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 588                 SetResource(this, RES_CELLS, start_ammo_cells);
 589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 590                 SetResource(this, RES_FUEL, start_ammo_fuel);
 591                 SetResource(this, RES_HEALTH, start_health);
 592                 SetResource(this, RES_ARMOR, start_armorvalue);
 593                 STAT(WEAPONS, this) = start_weapons;
 594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 595                 {
 596                         GiveRandomWeapons(this, random_start_weapons_count,
 597                                 autocvar_g_random_start_weapons, random_start_ammo);
 598                 }
 599         }
 600         SetSpectatee_status(this, 0);
 601
 602         PS(this).dual_weapons = '0 0 0';
 603
 604         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 605                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 606
 607         this.items = start_items;
 608
 609         float shieldtime = time + autocvar_g_spawnshieldtime;
 610
 611         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 612         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 613         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 614         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 615         if (!sv_ready_restart_after_countdown && time < game_starttime)
 616         {
 617                 float f = game_starttime - time;
 618                 shieldtime += f;
 619                 this.pauserotarmor_finished += f;
 620                 this.pauserothealth_finished += f;
 621                 this.pauseregen_finished += f;
 622         }
 623
 624         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 625
 626         this.damageforcescale = autocvar_g_player_damageforcescale;
 627         this.death_time = 0;
 628         this.respawn_flags = 0;
 629         this.respawn_time = 0;
 630         STAT(RESPAWN_TIME, this) = 0;
 631         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 632         this.fade_time = 0;
 633         this.pain_finished = 0;
 634         this.pushltime = 0;
 635         setthink(this, func_null); // players have no think function
 636         this.nextthink = 0;
 637         this.dmg_team = 0;
 638         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 639
 640         this.deadflag = DEAD_NO;
 641
 642         this.angles = spot.angles;
 643         this.angles_z = 0; // never spawn tilted even if the spot says to
 644         if (IS_BOT_CLIENT(this))
 645         {
 646                 this.v_angle = this.angles;
 647                 bot_aim_reset(this);
 648         }
 649         this.fixangle = true; // turn this way immediately
 650         this.oldvelocity = this.velocity = '0 0 0';
 651         this.avelocity = '0 0 0';
 652         this.punchangle = '0 0 0';
 653         this.punchvector = '0 0 0';
 654
 655         STAT(REVIVE_PROGRESS, this) = 0;
 656         this.revival_time = 0;
 657
 658         STAT(AIR_FINISHED, this) = 0;
 659         this.waterlevel = WATERLEVEL_NONE;
 660         this.watertype = CONTENT_EMPTY;
 661
 662         entity spawnevent = new_pure(spawnevent);
 663         spawnevent.owner = this;
 664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665
 666         // Cut off any still running player sounds.
 667         stopsound(this, CH_PLAYER_SINGLE);
 668
 669         this.model = "";
 670         FixPlayermodel(this);
 671         this.drawonlytoclient = NULL;
 672
 673         this.viewloc = NULL;
 674
 675         for(int slot = 0; slot < MAX_AXH; ++slot)
 676         {
 677                 entity axh = this.(AuxiliaryXhair[slot]);
 678                 this.(AuxiliaryXhair[slot]) = NULL;
 679
 680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 681                         delete(axh);
 682         }
 683
 684         this.spawnpoint_targ = NULL;
 685
 686         UNSET_DUCKED(this);
 687         this.view_ofs = STAT(PL_VIEW_OFS, this);
 688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 689         this.spawnorigin = spot.origin;
 690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 691         // don't reset back to last position, even if new position is stuck in solid
 692         this.oldorigin = this.origin;
 693         if(this.conveyor)
 694                 IL_REMOVE(g_conveyed, this);
 695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 696         if(this.swampslug)
 697                 IL_REMOVE(g_swamped, this);
 698         this.swampslug = NULL;
 699         this.swamp_interval = 0;
 700         if(this.ladder_entity)
 701                 IL_REMOVE(g_ladderents, this);
 702         this.ladder_entity = NULL;
 703         IL_EACH(g_counters, it.realowner == this,
 704         {
 705                 delete(it);
 706         });
 707         STAT(HUD, this) = HUD_NORMAL;
 708
 709         this.event_damage = PlayerDamage;
 710         this.event_heal = PlayerHeal;
 711
 712         this.draggable = func_null;
 713
 714         if(!this.bot_attack)
 715                 IL_PUSH(g_bot_targets, this);
 716         this.bot_attack = true;
 717         if(!this.monster_attack)
 718                 IL_PUSH(g_monster_targets, this);
 719         this.monster_attack = true;
 720         navigation_dynamicgoal_init(this, false);
 721
 722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 723
 724         // player was spectator
 725         if (CS(this).killcount == FRAGS_SPECTATOR) {
 726                 PlayerScore_Clear(this);
 727                 CS(this).killcount = 0;
 728                 CS(this).startplaytime = time;
 729         }
 730
 731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 732         {
 733                 .entity weaponentity = weaponentities[slot];
 734                 CL_SpawnWeaponentity(this, weaponentity);
 735         }
 736         this.alpha = default_player_alpha;
 737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 738         this.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740         this.speedrunning = false;
 741
 742         this.counter_cnt = 0;
 743         this.fragsfilter_cnt = 0;
 744
 745         target_voicescript_clear(this);
 746
 747         // reset fields the weapons may use
 748         FOREACH(Weapons, true, {
 749                 it.wr_resetplayer(it, this);
 750                         // reload all reloadable weapons
 751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753                         {
 754                                 .entity weaponentity = weaponentities[slot];
 755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 756                         }
 757                 }
 758         });
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763
 764         {
 765                 string s = spot.target;
 766                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 767                         spot.target = string_null;
 768                 SUB_UseTargets(spot, this, NULL);
 769                 if(g_assault || g_race)
 770                         spot.target = s;
 771         }
 772
 773         if (autocvar_spawn_debug)
 774         {
 775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 777         }
 778
 779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780         {
 781                 .entity weaponentity = weaponentities[slot];
 782                 entity w_ent = this.(weaponentity);
 783                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 784                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 785                 else
 786                         w_ent.m_switchweapon = WEP_Null;
 787                 w_ent.m_weapon = WEP_Null;
 788                 w_ent.weaponname = "";
 789                 w_ent.m_switchingweapon = WEP_Null;
 790                 w_ent.cnt = -1;
 791         }
 792
 793         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 794
 795         if (CS(this).impulse) ImpulseCommands(this);
 796
 797         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 W_WeaponFrame(this, weaponentity);
 802         }
 803
 804         if (!warmup_stage && !this.alivetime)
 805                 this.alivetime = time;
 806
 807         antilag_clear(this, CS(this));
 808 }
 809
 810 /** Called when a client spawns in the server */
 811 void PutClientInServer(entity this)
 812 {
 813         if (IS_BOT_CLIENT(this)) {
 814                 TRANSMUTE(Player, this);
 815         } else if (IS_REAL_CLIENT(this)) {
 816                 msg_entity = this;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, this);
 819         }
 820         if (game_stopped)
 821                 TRANSMUTE(Observer, this);
 822
 823         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this, false, use_spawnpoint);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837
 838         bot_relinkplayerlist();
 839 }
 840
 841 // TODO do we need all these fields, or should we stop autodetecting runtime
 842 // changes and just have a console command to update this?
 843 bool ClientInit_SendEntity(entity this, entity to, int sf)
 844 {
 845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 846         return = true;
 847         msg_entity = to;
 848         // MSG_INIT replacement
 849         // TODO: make easier to use
 850         Registry_send_all();
 851         W_PROP_reload(MSG_ONE, to);
 852         ClientInit_misc(this);
 853         MUTATOR_CALLHOOK(Ent_Init);
 854 }
 855 void ClientInit_misc(entity this)
 856 {
 857         int channel = MSG_ONE;
 858         WriteHeader(channel, ENT_CLIENT_INIT);
 859         WriteByte(channel, g_nexball_meter_period * 32);
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 868
 869         if(autocvar_sv_foginterval && world.fog != "")
 870                 WriteString(channel, world.fog);
 871         else
 872                 WriteString(channel, "");
 873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 875         WriteByte(channel, serverflags);
 876         WriteCoord(channel, autocvar_g_trueaim_minrange);
 877 }
 878
 879 void ClientInit_CheckUpdate(entity this)
 880 {
 881         this.nextthink = time;
 882         if(this.count != autocvar_g_balance_armor_blockpercent)
 883         {
 884                 this.count = autocvar_g_balance_armor_blockpercent;
 885                 this.SendFlags |= 1;
 886         }
 887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 888         {
 889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 890                 this.SendFlags |= 1;
 891         }
 892 }
 893
 894 void ClientInit_Spawn()
 895 {
 896         entity e = new_pure(clientinit);
 897         setthink(e, ClientInit_CheckUpdate);
 898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 899
 900         ClientInit_CheckUpdate(e);
 901 }
 902
 903 /*
 904 =============
 905 SetNewParms
 906 =============
 907 */
 908 void SetNewParms ()
 909 {
 910         // initialize parms for a new player
 911         parm1 = -(86400 * 366);
 912
 913         MUTATOR_CALLHOOK(SetNewParms);
 914 }
 915
 916 /*
 917 =============
 918 SetChangeParms
 919 =============
 920 */
 921 void SetChangeParms (entity this)
 922 {
 923         // save parms for level change
 924         parm1 = CS(this).parm_idlesince - time;
 925
 926         MUTATOR_CALLHOOK(SetChangeParms);
 927 }
 928
 929 /*
 930 =============
 931 DecodeLevelParms
 932 =============
 933 */
 934 void DecodeLevelParms(entity this)
 935 {
 936         // load parms
 937         CS(this).parm_idlesince = parm1;
 938         if (CS(this).parm_idlesince == -(86400 * 366))
 939                 CS(this).parm_idlesince = time;
 940
 941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 943
 944         MUTATOR_CALLHOOK(DecodeLevelParms);
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 957
 958         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 959
 960         MUTATOR_CALLHOOK(FixClientCvars, e);
 961 }
 962
 963 bool findinlist_abbrev(string tofind, string list)
 964 {
 965         if(list == "" || tofind == "")
 966                 return false; // empty list or search, just return
 967
 968         // this function allows abbreviated strings!
 969         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 970         {
 971                 return true;
 972         });
 973
 974         return false;
 975 }
 976
 977 bool PlayerInIPList(entity p, string iplist)
 978 {
 979         // some safety checks (never allow local?)
 980         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 981                 return false;
 982
 983         return findinlist_abbrev(p.netaddress, iplist);
 984 }
 985
 986 bool PlayerInIDList(entity p, string idlist)
 987 {
 988         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 989         if(!p.crypto_idfp)
 990                 return false;
 991
 992         return findinlist_abbrev(p.crypto_idfp, idlist);
 993 }
 994
 995 bool PlayerInList(entity player, string list)
 996 {
 997         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 998 }
 999
1000 #ifdef DP_EXT_PRECONNECT
1001 /*
1002 =============
1003 ClientPreConnect
1004
1005 Called once (not at each match start) when a client begins a connection to the server
1006 =============
1007 */
1008 void ClientPreConnect(entity this)
1009 {
1010         if(autocvar_sv_eventlog)
1011         {
1012                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1013                         this.playerid,
1014                         etof(this),
1015                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1016                 ));
1017         }
1018 }
1019 #endif
1020
1021 string GetClientVersionMessage(entity this)
1022 {
1023         if (CS(this).version_mismatch) {
1024                 if(CS(this).version < autocvar_gameversion) {
1025                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1026                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1027                 } else {
1028                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1029                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1030                 }
1031         } else {
1032                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1033         }
1034 }
1035
1036 void SendWelcomemessage(entity this, bool force_centerprint)
1037 {
1038         msg_entity = this;
1039         WriteHeader(MSG_ONE, TE_CSQC_SERVERINFO);
1040         WriteByte(MSG_ONE, force_centerprint);
1041         WriteString(MSG_ONE, autocvar_hostname);
1042         WriteString(MSG_ONE, GetClientVersionMessage(this));
1043         WriteString(MSG_ONE, gamemode_name);
1044
1045         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1046         string modifications = M_ARGV(0, string);
1047
1048         if(g_weaponarena)
1049         {
1050                 if(g_weaponarena_random)
1051                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1052                 else
1053                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1054         }
1055         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1056                 modifications = strcat(modifications, ", No start weapons");
1057         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1058                 modifications = strcat(modifications, ", Low gravity");
1059         if(g_weapon_stay && !g_cts)
1060                 modifications = strcat(modifications, ", Weapons stay");
1061         if(autocvar_g_jetpack)
1062                 modifications = strcat(modifications, ", Jet pack");
1063         modifications = substring(modifications, 2, strlen(modifications) - 2);
1064
1065         WriteString(MSG_ONE, modifications);
1066
1067         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1068         {
1069                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1070                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1071         }
1072
1073         WriteString(MSG_ONE, cache_mutatormsg);
1074
1075         string mutator_msg = "";
1076         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1077         mutator_msg = M_ARGV(0, string);
1078
1079         WriteString(MSG_ONE, mutator_msg); // trust that the mutator will do proper formatting
1080         WriteString(MSG_ONE, strreplace("\\n", "\n", autocvar_sv_motd));
1081 }
1082
1083 /**
1084 =============
1085 ClientConnect
1086
1087 Called when a client connects to the server
1088 =============
1089 */
1090 void ClientConnect(entity this)
1091 {
1092         if (Ban_MaybeEnforceBanOnce(this)) return;
1093         assert(!IS_CLIENT(this), return);
1094         this.flags |= FL_CLIENT;
1095         assert(player_count >= 0, player_count = 0);
1096
1097         TRANSMUTE(Client, this);
1098         CS(this).version_nagtime = time + 10 + random() * 10;
1099
1100         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1101
1102         bot_clientconnect(this);
1103
1104         Player_DetermineForcedTeam(this);
1105
1106         TRANSMUTE(Observer, this);
1107
1108         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1109
1110         // always track bots, don't ask for cl_allow_uidtracking
1111         if (IS_BOT_CLIENT(this))
1112                 PlayerStats_GameReport_AddPlayer(this);
1113         else
1114                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1115
1116         if (autocvar_sv_eventlog)
1117                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1118
1119         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1120
1121         stuffcmd(this, clientstuff, "\n");
1122         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1123
1124         FixClientCvars(this);
1125
1126         // get version info from player
1127         stuffcmd(this, "cmd clientversion $gameversion\n");
1128
1129         // notify about available teams
1130         if (teamplay)
1131         {
1132                 entity balance = TeamBalance_CheckAllowedTeams(this);
1133                 int t = TeamBalance_GetAllowedTeams(balance);
1134                 TeamBalance_Destroy(balance);
1135                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1136         }
1137         else
1138         {
1139                 stuffcmd(this, "set _teams_available 0\n");
1140         }
1141
1142         bot_relinkplayerlist();
1143
1144         CS(this).spectatortime = time;
1145         if (blockSpectators)
1146         {
1147                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1148         }
1149
1150         CS(this).jointime = time;
1151
1152         if (IS_REAL_CLIENT(this))
1153         {
1154                 if (g_weaponarena_weapons == WEPSET(TUBA))
1155                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1156         }
1157
1158         if (!autocvar_sv_foginterval && world.fog != "")
1159                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1160
1161         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1162                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1163                         send_CSQC_teamnagger();
1164
1165         CSQCMODEL_AUTOINIT(this);
1166
1167         CS(this).model_randomizer = random();
1168
1169         if (IS_REAL_CLIENT(this))
1170         {
1171                 if (!autocvar_g_campaign)
1172                         SendWelcomemessage(this, false);
1173                 sv_notice_join(this);
1174         }
1175
1176         this.move_qcphysics = autocvar_sv_qcphysics;
1177
1178         // update physics stats (players can spawn before physics runs)
1179         Physics_UpdateStats(this);
1180
1181         IL_EACH(g_initforplayer, it.init_for_player, {
1182                 it.init_for_player(it, this);
1183         });
1184
1185         Handicap_Initialize(this);
1186
1187         MUTATOR_CALLHOOK(ClientConnect, this);
1188
1189         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1190                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1191 }
1192 /*
1193 =============
1194 ClientDisconnect
1195
1196 Called when a client disconnects from the server
1197 =============
1198 */
1199 .entity chatbubbleentity;
1200 void player_powerups_remove_all(entity this);
1201
1202 void ClientDisconnect(entity this)
1203 {
1204         assert(IS_CLIENT(this), return);
1205
1206         PlayerStats_GameReport_FinalizePlayer(this);
1207         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1208         if (CS(this).active_minigame) part_minigame(this);
1209         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1210
1211         if (autocvar_sv_eventlog)
1212                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1213
1214         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1215
1216         if(IS_SPEC(this))
1217                 SetSpectatee(this, NULL);
1218
1219         MUTATOR_CALLHOOK(ClientDisconnect, this);
1220
1221         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1222         strfree(CS_CVAR(this).weaponorder_byimpulse);
1223         ClientState_detach(this);
1224
1225         Portal_ClearAll(this);
1226
1227         Unfreeze(this, false);
1228
1229         RemoveGrapplingHooks(this);
1230
1231         // Here, everything has been done that requires this player to be a client.
1232
1233         this.flags &= ~FL_CLIENT;
1234
1235         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1236         if (this.killindicator) delete(this.killindicator);
1237
1238         IL_EACH(g_counters, it.realowner == this,
1239         {
1240                 delete(it);
1241         });
1242
1243         WaypointSprite_PlayerGone(this);
1244
1245         bot_relinkplayerlist();
1246
1247         strfree(this.clientstatus);
1248         if (this.personal) delete(this.personal);
1249
1250         this.playerid = 0;
1251         ReadyCount();
1252         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1253
1254         player_powerups_remove_all(this); // stop powerup sound
1255
1256         ONREMOVE(this);
1257 }
1258
1259 void ChatBubbleThink(entity this)
1260 {
1261         this.nextthink = time;
1262         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1263         {
1264                 if(this.owner) // but why can that ever be NULL?
1265                         this.owner.chatbubbleentity = NULL;
1266                 delete(this);
1267                 return;
1268         }
1269
1270         this.mdl = "";
1271
1272         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1273         {
1274                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1275                         this.mdl = "models/sprites/minigame_busy.iqm";
1276                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1277                         this.mdl = "models/misc/chatbubble.spr";
1278         }
1279
1280         if ( this.model != this.mdl )
1281                 _setmodel(this, this.mdl);
1282
1283 }
1284
1285 void UpdateChatBubble(entity this)
1286 {
1287         if (this.alpha < 0)
1288                 return;
1289         // spawn a chatbubble entity if needed
1290         if (!this.chatbubbleentity)
1291         {
1292                 this.chatbubbleentity = new(chatbubbleentity);
1293                 this.chatbubbleentity.owner = this;
1294                 this.chatbubbleentity.exteriormodeltoclient = this;
1295                 setthink(this.chatbubbleentity, ChatBubbleThink);
1296                 this.chatbubbleentity.nextthink = time;
1297                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1298                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1299                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1300                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1301                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1302                 //this.chatbubbleentity.model = "";
1303                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1304         }
1305 }
1306
1307 void calculate_player_respawn_time(entity this)
1308 {
1309         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1310                 return;
1311
1312         float gametype_setting_tmp;
1313         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1314         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1315         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1316         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1317         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1318         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1319
1320         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1321         if (teamplay)
1322         {
1323                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1324                         if(it.team == this.team)
1325                                 ++pcount;
1326                 });
1327                 if (sdelay_small_count == 0)
1328                         sdelay_small_count = 1;
1329                 if (sdelay_large_count == 0)
1330                         sdelay_large_count = 1;
1331         }
1332         else
1333         {
1334                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1335                         ++pcount;
1336                 });
1337                 if (sdelay_small_count == 0)
1338                 {
1339                         if (IS_INDEPENDENT_PLAYER(this))
1340                         {
1341                                 // Players play independently. No point in requiring enemies.
1342                                 sdelay_small_count = 1;
1343                         }
1344                         else
1345                         {
1346                                 // Players play AGAINST each other. Enemies required.
1347                                 sdelay_small_count = 2;
1348                         }
1349                 }
1350                 if (sdelay_large_count == 0)
1351                 {
1352                         if (IS_INDEPENDENT_PLAYER(this))
1353                         {
1354                                 // Players play independently. No point in requiring enemies.
1355                                 sdelay_large_count = 1;
1356                         }
1357                         else
1358                         {
1359                                 // Players play AGAINST each other. Enemies required.
1360                                 sdelay_large_count = 2;
1361                         }
1362                 }
1363         }
1364
1365         float sdelay;
1366
1367         if (pcount <= sdelay_small_count)
1368                 sdelay = sdelay_small;
1369         else if (pcount >= sdelay_large_count)
1370                 sdelay = sdelay_large;
1371         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1372                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1373
1374         if(waves)
1375                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1376         else
1377                 this.respawn_time = time + sdelay;
1378
1379         if(sdelay < sdelay_max)
1380                 this.respawn_time_max = time + sdelay_max;
1381         else
1382                 this.respawn_time_max = this.respawn_time;
1383
1384         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1385                 this.respawn_countdown = 10; // first number to count down from is 10
1386         else
1387                 this.respawn_countdown = -1; // do not count down
1388
1389         if(autocvar_g_forced_respawn)
1390                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1391 }
1392
1393 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1394 // added to the model skins
1395 /*void UpdateColorModHack()
1396 {
1397         float c;
1398         c = this.clientcolors & 15;
1399         // LordHavoc: only bothering to support white, green, red, yellow, blue
1400              if (!teamplay) this.colormod = '0 0 0';
1401         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1402         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1403         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1404         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1405         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1406         else this.colormod = '1 1 1';
1407 }*/
1408
1409 void respawn(entity this)
1410 {
1411         bool damagedbycontents_prev = this.damagedbycontents;
1412         if(this.alpha >= 0)
1413         {
1414                 if(autocvar_g_respawn_ghosts)
1415                 {
1416                         this.solid = SOLID_NOT;
1417                         this.takedamage = DAMAGE_NO;
1418                         this.damagedbycontents = false;
1419                         set_movetype(this, MOVETYPE_FLY);
1420                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1421                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1422                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1423                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1424                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1425                         if(autocvar_g_respawn_ghosts_time > 0)
1426                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1427                 }
1428                 else
1429                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1430         }
1431
1432         CopyBody(this, 1);
1433         this.damagedbycontents = damagedbycontents_prev;
1434
1435         this.effects |= EF_NODRAW; // prevent another CopyBody
1436         PutClientInServer(this);
1437 }
1438
1439 void play_countdown(entity this, float finished, Sound samp)
1440 {
1441         TC(Sound, samp);
1442         if(IS_REAL_CLIENT(this))
1443                 if(floor(finished - time - frametime) != floor(finished - time))
1444                         if(finished - time < 6)
1445                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1446 }
1447
1448 // it removes special powerups not handled by StatusEffects
1449 void player_powerups_remove_all(entity this)
1450 {
1451         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1452         {
1453                 // don't play the poweroff sound when the game restarts or the player disconnects
1454                 if (time > game_starttime + 1 && IS_CLIENT(this))
1455                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1456                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1457                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1458                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1459         }
1460 }
1461
1462 void player_powerups(entity this)
1463 {
1464         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1465                 this.modelflags |= MF_ROCKET;
1466         else
1467                 this.modelflags &= ~MF_ROCKET;
1468
1469         this.effects &= ~EF_NODEPTHTEST;
1470
1471         if (IS_DEAD(this))
1472                 player_powerups_remove_all(this);
1473
1474         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1475                 return;
1476
1477         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1478         int items_prev = this.items;
1479
1480         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1481         {
1482                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1483                 if (this.items & IT_SUPERWEAPON)
1484                 {
1485                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1486                         {
1487                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1488                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1489                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1490                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1491                         }
1492                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1493                         {
1494                                 // don't let them run out
1495                         }
1496                         else
1497                         {
1498                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1499                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1500                                 {
1501                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1502                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1503                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1504                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1505                                 }
1506                         }
1507                 }
1508                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1509                 {
1510                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1511                         {
1512                                 this.items = this.items | IT_SUPERWEAPON;
1513                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1514                                 {
1515                                         if(!g_cts)
1516                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1517                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1518                                 }
1519                         }
1520                         else
1521                         {
1522                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1523                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1524                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1525                         }
1526                 }
1527                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1528                 {
1529                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1530                 }
1531         }
1532
1533         if(autocvar_g_nodepthtestplayers)
1534                 this.effects = this.effects | EF_NODEPTHTEST;
1535
1536         if(autocvar_g_fullbrightplayers)
1537                 this.effects = this.effects | EF_FULLBRIGHT;
1538
1539         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1540 }
1541
1542 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1543 {
1544         if(current > stable)
1545                 return current;
1546         else if(current > stable - 0.25) // when close enough, "snap"
1547                 return stable;
1548         else
1549                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1550 }
1551
1552 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1553 {
1554         if(current < stable)
1555                 return current;
1556         else if(current < stable + 0.25) // when close enough, "snap"
1557                 return stable;
1558         else
1559                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1560 }
1561
1562 void RotRegen(entity this, Resource res, float limit_mod,
1563         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1564         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1565 {
1566         float old = GetResource(this, res);
1567         float current = old;
1568         if(current > rotstable)
1569         {
1570                 if(rotframetime > 0)
1571                 {
1572                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1573                         current = max(rotstable, current - rotlinear * rotframetime);
1574                 }
1575         }
1576         else if(current < regenstable)
1577         {
1578                 if(regenframetime > 0)
1579                 {
1580                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1581                         current = min(regenstable, current + regenlinear * regenframetime);
1582                 }
1583         }
1584
1585         float limit = GetResourceLimit(this, res) * limit_mod;
1586         if(current > limit)
1587                 current = limit;
1588
1589         if (current != old)
1590                 SetResource(this, res, current);
1591 }
1592
1593 void player_regen(entity this)
1594 {
1595         float max_mod, regen_mod, rot_mod, limit_mod;
1596         max_mod = regen_mod = rot_mod = limit_mod = 1;
1597
1598         float regen_health = autocvar_g_balance_health_regen;
1599         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1600         float regen_health_rot = autocvar_g_balance_health_rot;
1601         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1602         float regen_health_stable = autocvar_g_balance_health_regenstable;
1603         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1604         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1605                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1606         max_mod = M_ARGV(1, float);
1607         regen_mod = M_ARGV(2, float);
1608         rot_mod = M_ARGV(3, float);
1609         limit_mod = M_ARGV(4, float);
1610         regen_health = M_ARGV(5, float);
1611         regen_health_linear = M_ARGV(6, float);
1612         regen_health_rot = M_ARGV(7, float);
1613         regen_health_rotlinear = M_ARGV(8, float);
1614         regen_health_stable = M_ARGV(9, float);
1615         regen_health_rotstable = M_ARGV(10, float);
1616
1617         float rotstable, regenstable, rotframetime, regenframetime;
1618
1619         if(!mutator_returnvalue)
1620         if(!STAT(FROZEN, this))
1621         {
1622                 regenstable = autocvar_g_balance_armor_regenstable;
1623                 rotstable = autocvar_g_balance_armor_rotstable;
1624                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1625                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1626                 RotRegen(this, RES_ARMOR, limit_mod,
1627                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1628                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1629
1630                 // NOTE: max_mod is only applied to health
1631                 regenstable = regen_health_stable * max_mod;
1632                 rotstable = regen_health_rotstable * max_mod;
1633                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1634                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1635                 RotRegen(this, RES_HEALTH, limit_mod,
1636                         regenstable, regen_health, regen_health_linear, regenframetime,
1637                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1638         }
1639
1640         // if player rotted to death...  die!
1641         // check this outside above checks, as player may still be able to rot to death
1642         if(GetResource(this, RES_HEALTH) < 1)
1643         {
1644                 if(this.vehicle)
1645                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1646                 if(this.event_damage)
1647                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1648         }
1649
1650         if (!(this.items & IT_UNLIMITED_AMMO))
1651         {
1652                 regenstable = autocvar_g_balance_fuel_regenstable;
1653                 rotstable = autocvar_g_balance_fuel_rotstable;
1654                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1655                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1656                 RotRegen(this, RES_FUEL, 1,
1657                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1658                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1659         }
1660 }
1661
1662 bool zoomstate_set;
1663 void SetZoomState(entity this, float newzoom)
1664 {
1665         if(newzoom != CS(this).zoomstate)
1666         {
1667                 CS(this).zoomstate = newzoom;
1668                 ClientData_Touch(this);
1669         }
1670         zoomstate_set = true;
1671 }
1672
1673 void GetPressedKeys(entity this)
1674 {
1675         MUTATOR_CALLHOOK(GetPressedKeys, this);
1676         if (game_stopped)
1677         {
1678                 CS(this).pressedkeys = 0;
1679                 STAT(PRESSED_KEYS, this) = 0;
1680                 return;
1681         }
1682
1683         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1684         int keys = STAT(PRESSED_KEYS, this);
1685         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1686         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1687         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1688         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1689
1690         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1691         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1692         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1693         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1694         CS(this).pressedkeys = keys; // store for other users
1695
1696         STAT(PRESSED_KEYS, this) = keys;
1697 }
1698
1699 /*
1700 ======================
1701 spectate mode routines
1702 ======================
1703 */
1704
1705 void SpectateCopy(entity this, entity spectatee)
1706 {
1707         TC(Client, this); TC(Client, spectatee);
1708
1709         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1710         PS(this) = PS(spectatee);
1711         this.armortype = spectatee.armortype;
1712         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1713         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1714         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1715         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1716         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1717         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1718         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1719         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1720         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1721         CS(this).impulse = 0;
1722         this.disableclientprediction = 1; // no need to run prediction on a spectator
1723         this.items = spectatee.items;
1724         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1725         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1726         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1727         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1728         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1729         this.punchangle = spectatee.punchangle;
1730         this.view_ofs = spectatee.view_ofs;
1731         this.velocity = spectatee.velocity;
1732         this.dmg_take = spectatee.dmg_take;
1733         this.dmg_save = spectatee.dmg_save;
1734         this.dmg_inflictor = spectatee.dmg_inflictor;
1735         this.v_angle = spectatee.v_angle;
1736         this.angles = spectatee.v_angle;
1737         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1738         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1739         this.viewloc = spectatee.viewloc;
1740         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1741                 this.fixangle = true;
1742         setorigin(this, spectatee.origin);
1743         setsize(this, spectatee.mins, spectatee.maxs);
1744         SetZoomState(this, CS(spectatee).zoomstate);
1745
1746     anticheat_spectatecopy(this, spectatee);
1747         STAT(HUD, this) = STAT(HUD, spectatee);
1748         if(spectatee.vehicle)
1749     {
1750         this.angles = spectatee.v_angle;
1751
1752         //this.fixangle = false;
1753         //this.velocity = spectatee.vehicle.velocity;
1754         this.vehicle_health = spectatee.vehicle_health;
1755         this.vehicle_shield = spectatee.vehicle_shield;
1756         this.vehicle_energy = spectatee.vehicle_energy;
1757         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1758         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1759         this.vehicle_reload1 = spectatee.vehicle_reload1;
1760         this.vehicle_reload2 = spectatee.vehicle_reload2;
1761
1762         //msg_entity = this;
1763
1764        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1765             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1766            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1767            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1768
1769         //WriteByte (MSG_ONE, SVC_SETVIEW);
1770         //    WriteEntity(MSG_ONE, this);
1771         //makevectors(spectatee.v_angle);
1772         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1773     }
1774 }
1775
1776 bool SpectateUpdate(entity this)
1777 {
1778         if(!this.enemy)
1779                 return false;
1780
1781         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1782         {
1783                 SetSpectatee(this, NULL);
1784                 return false;
1785         }
1786
1787         SpectateCopy(this, this.enemy);
1788
1789         return true;
1790 }
1791
1792 bool SpectateSet(entity this)
1793 {
1794         if(!IS_PLAYER(this.enemy))
1795                 return false;
1796
1797         ClientData_Touch(this.enemy);
1798
1799         msg_entity = this;
1800         WriteByte(MSG_ONE, SVC_SETVIEW);
1801         WriteEntity(MSG_ONE, this.enemy);
1802         set_movetype(this, MOVETYPE_NONE);
1803         accuracy_resend(this);
1804
1805         if(!SpectateUpdate(this))
1806                 PutObserverInServer(this, false, true);
1807
1808         return true;
1809 }
1810
1811 void SetSpectatee_status(entity this, int spectatee_num)
1812 {
1813         int oldspectatee_status = CS(this).spectatee_status;
1814         CS(this).spectatee_status = spectatee_num;
1815
1816         if (CS(this).spectatee_status != oldspectatee_status)
1817         {
1818                 if (STAT(PRESSED_KEYS, this))
1819                 {
1820                         CS(this).pressedkeys = 0;
1821                         STAT(PRESSED_KEYS, this) = 0;
1822                 }
1823                 ClientData_Touch(this);
1824                 if (g_race || g_cts) race_InitSpectator();
1825         }
1826 }
1827
1828 void SetSpectatee(entity this, entity spectatee)
1829 {
1830         if(IS_BOT_CLIENT(this))
1831                 return; // bots abuse .enemy, this code is useless to them
1832
1833         entity old_spectatee = this.enemy;
1834
1835         this.enemy = spectatee;
1836
1837         // WEAPONTODO
1838         // these are required to fix the spectator bug with arc
1839         if(old_spectatee)
1840         {
1841                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1842                 {
1843                         .entity weaponentity = weaponentities[slot];
1844                         if(old_spectatee.(weaponentity).arc_beam)
1845                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1846                 }
1847         }
1848         if(spectatee)
1849         {
1850                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1851                 {
1852                         .entity weaponentity = weaponentities[slot];
1853                         if(spectatee.(weaponentity).arc_beam)
1854                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1855                 }
1856         }
1857
1858         if (spectatee)
1859                 SetSpectatee_status(this, etof(spectatee));
1860
1861         // needed to update spectator list
1862         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1863 }
1864
1865 bool Spectate(entity this, entity pl)
1866 {
1867         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1868                 return false;
1869         pl = M_ARGV(1, entity);
1870
1871         SetSpectatee(this, pl);
1872         return SpectateSet(this);
1873 }
1874
1875 bool SpectateNext(entity this)
1876 {
1877         entity ent = find(this.enemy, classname, STR_PLAYER);
1878
1879         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1880                 ent = M_ARGV(1, entity);
1881         else if (!ent)
1882                 ent = find(ent, classname, STR_PLAYER);
1883
1884         if(ent) { SetSpectatee(this, ent); }
1885
1886         return SpectateSet(this);
1887 }
1888
1889 bool SpectatePrev(entity this)
1890 {
1891         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1892         entity ent = findchain(classname, STR_PLAYER);
1893         if (!ent) // no player
1894                 return false;
1895
1896         entity first = ent;
1897         // skip players until current spectated player
1898         if(this.enemy)
1899         while(ent && ent != this.enemy)
1900                 ent = ent.chain;
1901
1902         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1903         {
1904                 case MUT_SPECPREV_FOUND:
1905                         ent = M_ARGV(1, entity);
1906                         break;
1907                 case MUT_SPECPREV_RETURN:
1908                         return true;
1909                 case MUT_SPECPREV_CONTINUE:
1910                 default:
1911                 {
1912                         if(ent.chain)
1913                                 ent = ent.chain;
1914                         else
1915                                 ent = first;
1916                         break;
1917                 }
1918         }
1919
1920         SetSpectatee(this, ent);
1921         return SpectateSet(this);
1922 }
1923
1924 /*
1925 =============
1926 ShowRespawnCountdown()
1927
1928 Update a respawn countdown display.
1929 =============
1930 */
1931 void ShowRespawnCountdown(entity this)
1932 {
1933         float number;
1934         if(!IS_DEAD(this)) // just respawned?
1935                 return;
1936         else
1937         {
1938                 number = ceil(this.respawn_time - time);
1939                 if(number <= 0)
1940                         return;
1941                 if(number <= this.respawn_countdown)
1942                 {
1943                         this.respawn_countdown = number - 1;
1944                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1945                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1946                 }
1947         }
1948 }
1949
1950 .bool team_selected;
1951 bool ShowTeamSelection(entity this)
1952 {
1953         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1954                 return false;
1955         stuffcmd(this, "menu_showteamselect\n");
1956         return true;
1957 }
1958 void Join(entity this)
1959 {
1960         TRANSMUTE(Player, this);
1961
1962         if(!this.team_selected)
1963         if(autocvar_g_campaign || autocvar_g_balance_teams)
1964                 TeamBalance_JoinBestTeam(this);
1965
1966         if(autocvar_g_campaign)
1967                 campaign_bots_may_start = true;
1968
1969         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1970
1971         PutClientInServer(this);
1972
1973         if(IS_PLAYER(this))
1974         if(teamplay && this.team != -1)
1975         {
1976         }
1977         else
1978                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1979         this.team_selected = false;
1980 }
1981
1982 int GetPlayerLimit()
1983 {
1984         if(g_duel)
1985                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1986         int player_limit = autocvar_g_maxplayers;
1987         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1988         player_limit = M_ARGV(0, int);
1989         return player_limit;
1990 }
1991
1992 /**
1993  * Determines whether the player is allowed to join. This depends on cvar
1994  * g_maxplayers, if it isn't used this function always return true, otherwise
1995  * it checks whether the number of currently playing players exceeds g_maxplayers.
1996  * @return int number of free slots for players, 0 if none
1997  */
1998 int nJoinAllowed(entity this, entity ignore)
1999 {
2000         if(!ignore)
2001         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2002         // so report 0 free slots if restricted
2003         {
2004                 if(autocvar_g_forced_team_otherwise == "spectate")
2005                         return 0;
2006                 if(autocvar_g_forced_team_otherwise == "spectator")
2007                         return 0;
2008         }
2009
2010         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2011                 return 0; // forced spectators can never join
2012
2013         // TODO simplify this
2014         int totalClients = 0;
2015         int currentlyPlaying = 0;
2016         FOREACH_CLIENT(true, {
2017                 if(it != ignore)
2018                         ++totalClients;
2019                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2020                         ++currentlyPlaying;
2021         });
2022
2023         int player_limit = GetPlayerLimit();
2024
2025         int free_slots = 0;
2026         if (!player_limit)
2027                 free_slots = maxclients - totalClients;
2028         else if(player_limit > 0 && currentlyPlaying < player_limit)
2029                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2030
2031         static float msg_time = 0;
2032         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2033         {
2034                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2035                 msg_time = time + 0.5;
2036         }
2037
2038         return free_slots;
2039 }
2040
2041 void PrintWelcomeMessage(entity this)
2042 {
2043         if(CS(this).motd_actived_time == 0)
2044         {
2045                 if (autocvar_g_campaign) {
2046                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2047                                 CS(this).motd_actived_time = time;
2048                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2049                         }
2050                 } else {
2051                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2052                                 CS(this).motd_actived_time = time;
2053                                 SendWelcomemessage(this, true);
2054                         }
2055                 }
2056         }
2057         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2058         {
2059                 if (autocvar_g_campaign) {
2060                         if (PHYS_INPUT_BUTTON_INFO(this))
2061                                 CS(this).motd_actived_time = time;
2062                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2063                                 CS(this).motd_actived_time = 0;
2064                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2065                         }
2066                 } else {
2067                         if (PHYS_INPUT_BUTTON_INFO(this))
2068                                 CS(this).motd_actived_time = time;
2069                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2070                                 CS(this).motd_actived_time = 0;
2071                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2072                         }
2073                 }
2074         }
2075         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2076         {
2077                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2078                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2079                 else if (CS(this).motd_actived_time == -2)
2080                 {
2081                         // instantly hide MOTD
2082                         CS(this).motd_actived_time = 0;
2083                         if (autocvar_g_campaign)
2084                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2085                         else
2086                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2087                 }
2088                 else if (IS_PLAYER(this) || IS_SPEC(this))
2089                 {
2090                         // FIXME occasionally for some reason MOTD never goes away
2091                         // delay MOTD removal a little bit in the hope it fixes this bug
2092                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2093                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2094                         else //if (CS(this).motd_actived_time < -2)
2095                                 CS(this).motd_actived_time++;
2096                 }
2097         }
2098 }
2099
2100 bool joinAllowed(entity this)
2101 {
2102         if (CS(this).version_mismatch) return false;
2103         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2104         if (!nJoinAllowed(this, this)) return false;
2105         if (teamplay && lockteams) return false;
2106         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2107         if (ShowTeamSelection(this)) return false;
2108         return true;
2109 }
2110
2111 .string shootfromfixedorigin;
2112 .bool dualwielding_prev;
2113 bool PlayerThink(entity this)
2114 {
2115         if (game_stopped || intermission_running) {
2116                 this.modelflags &= ~MF_ROCKET;
2117                 if(intermission_running)
2118                         IntermissionThink(this);
2119                 return false;
2120         }
2121
2122         if (timeout_status == TIMEOUT_ACTIVE) {
2123                 // don't allow the player to turn around while game is paused
2124                 // FIXME turn this into CSQC stuff
2125                 this.v_angle = this.lastV_angle;
2126                 this.angles = this.lastV_angle;
2127                 this.fixangle = true;
2128         }
2129
2130         if (frametime) player_powerups(this);
2131
2132         if (IS_DEAD(this)) {
2133                 if (this.personal && g_race_qualifying) {
2134                         if (time > this.respawn_time) {
2135                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2136                                 respawn(this);
2137                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2138                         }
2139                 } else {
2140                         if (frametime) player_anim(this);
2141
2142                         if (this.respawn_flags & RESPAWN_DENY)
2143                         {
2144                                 STAT(RESPAWN_TIME, this) = 0;
2145                                 return false;
2146                         }
2147
2148                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2149
2150                         switch(this.deadflag)
2151                         {
2152                                 case DEAD_DYING:
2153                                 {
2154                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2155                                                 this.deadflag = DEAD_RESPAWNING;
2156                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2157                                                 this.deadflag = DEAD_DEAD;
2158                                         break;
2159                                 }
2160                                 case DEAD_DEAD:
2161                                 {
2162                                         if (button_pressed)
2163                                                 this.deadflag = DEAD_RESPAWNABLE;
2164                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2165                                                 this.deadflag = DEAD_RESPAWNING;
2166                                         break;
2167                                 }
2168                                 case DEAD_RESPAWNABLE:
2169                                 {
2170                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2171                                                 this.deadflag = DEAD_RESPAWNING;
2172                                         break;
2173                                 }
2174                                 case DEAD_RESPAWNING:
2175                                 {
2176                                         if (time > this.respawn_time)
2177                                         {
2178                                                 this.respawn_time = time + 1; // only retry once a second
2179                                                 this.respawn_time_max = this.respawn_time;
2180                                                 respawn(this);
2181                                         }
2182                                         break;
2183                                 }
2184                         }
2185
2186                         ShowRespawnCountdown(this);
2187
2188                         if (this.respawn_flags & RESPAWN_SILENT)
2189                                 STAT(RESPAWN_TIME, this) = 0;
2190                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2191                         {
2192                                 if (time < this.respawn_time)
2193                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2194                                 else if (this.deadflag != DEAD_RESPAWNING)
2195                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2196                         }
2197                         else
2198                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2199                 }
2200
2201                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2202                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2203                         STAT(RESPAWN_TIME, this) *= -1;
2204
2205                 return false;
2206         }
2207
2208         FixPlayermodel(this);
2209
2210         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2211                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2212                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2213         }
2214
2215         // reset gun alignment when dual wielding status changes
2216         // to ensure guns are always aligned right and left
2217         bool dualwielding = W_DualWielding(this);
2218         if(this.dualwielding_prev != dualwielding)
2219         {
2220                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2221                 this.dualwielding_prev = dualwielding;
2222         }
2223
2224         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2225         //if(frametime)
2226         {
2227                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2228                 {
2229                         .entity weaponentity = weaponentities[slot];
2230                         if(WEP_CVAR(vortex, charge_always))
2231                                 W_Vortex_Charge(this, weaponentity, frametime);
2232                         W_WeaponFrame(this, weaponentity);
2233                 }
2234         }
2235
2236         if (frametime)
2237         {
2238                 // WEAPONTODO: Add a weapon request for this
2239                 // rot vortex charge to the charge limit
2240                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2241                 {
2242                         .entity weaponentity = weaponentities[slot];
2243                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2244                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2245                 }
2246
2247                 player_regen(this);
2248                 player_anim(this);
2249                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2250         }
2251
2252         monsters_setstatus(this);
2253
2254         return true;
2255 }
2256
2257 .bool would_spectate;
2258 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2259 void ObserverOrSpectatorThink(entity this)
2260 {
2261         bool is_spec = IS_SPEC(this);
2262         if ( CS(this).impulse )
2263         {
2264                 int r = MinigameImpulse(this, CS(this).impulse);
2265                 if (!is_spec || r)
2266                         CS(this).impulse = 0;
2267
2268                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2269                 {
2270                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2271                         CS(this).impulse = 0;
2272                         return;
2273                 }
2274         }
2275
2276         if (this.flags & FL_JUMPRELEASED) {
2277                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2278                         this.flags &= ~FL_JUMPRELEASED;
2279                         this.flags |= FL_SPAWNING;
2280                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2281                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2282                         this.flags &= ~FL_JUMPRELEASED;
2283                         if(SpectateNext(this)) {
2284                                 TRANSMUTE(Spectator, this);
2285                         } else if (is_spec) {
2286                                 TRANSMUTE(Observer, this);
2287                                 PutClientInServer(this);
2288                         }
2289                         else
2290                                 this.would_spectate = false; // unable to spectate anyone
2291                         if (is_spec)
2292                                 CS(this).impulse = 0;
2293                 } else if (is_spec) {
2294                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2295                                 this.flags &= ~FL_JUMPRELEASED;
2296                                 if(SpectatePrev(this)) {
2297                                         TRANSMUTE(Spectator, this);
2298                                 } else {
2299                                         TRANSMUTE(Observer, this);
2300                                         PutClientInServer(this);
2301                                 }
2302                                 CS(this).impulse = 0;
2303                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2304                                 this.would_spectate = false;
2305                                 this.flags &= ~FL_JUMPRELEASED;
2306                                 TRANSMUTE(Observer, this);
2307                                 PutClientInServer(this);
2308                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2309                                 PutObserverInServer(this, false, true);
2310                                 this.would_spectate = true;
2311                         }
2312                 }
2313                 else {
2314                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2315                         if (PHYS_INPUT_BUTTON_USE(this))
2316                                 wouldclip = !wouldclip;
2317                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2318                         set_movetype(this, preferred_movetype);
2319                 }
2320         } else { // jump pressed
2321                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2322                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2323                         this.flags |= FL_JUMPRELEASED;
2324                         if(this.flags & FL_SPAWNING)
2325                         {
2326                                 this.flags &= ~FL_SPAWNING;
2327                                 if(joinAllowed(this))
2328                                         Join(this);
2329                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2330                                         CS(this).autojoin_checked = -1;
2331                                 return;
2332                         }
2333                 }
2334                 if(is_spec && !SpectateUpdate(this))
2335                         PutObserverInServer(this, false, true);
2336         }
2337         if (is_spec)
2338                 this.flags |= FL_CLIENT | FL_NOTARGET;
2339 }
2340
2341 void PlayerUseKey(entity this)
2342 {
2343         if (!IS_PLAYER(this))
2344                 return;
2345
2346         if(this.vehicle)
2347         {
2348                 if(!game_stopped)
2349                 {
2350                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2351                         return;
2352                 }
2353         }
2354         else if(autocvar_g_vehicles_enter)
2355         {
2356                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2357                 {
2358                         entity head, closest_target = NULL;
2359                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2360
2361                         while(head) // find the closest acceptable target to enter
2362                         {
2363                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2364                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2365                                 {
2366                                         if(closest_target)
2367                                         {
2368                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2369                                                 { closest_target = head; }
2370                                         }
2371                                         else { closest_target = head; }
2372                                 }
2373
2374                                 head = head.chain;
2375                         }
2376
2377                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2378                 }
2379         }
2380
2381         // a use key was pressed; call handlers
2382         MUTATOR_CALLHOOK(PlayerUseKey, this);
2383 }
2384
2385
2386 /*
2387 =============
2388 PlayerPreThink
2389
2390 Called every frame for each client before the physics are run
2391 =============
2392 */
2393 .float last_vehiclecheck;
2394 void PlayerPreThink (entity this)
2395 {
2396         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2397         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2398
2399         WarpZone_PlayerPhysics_FixVAngle(this);
2400
2401         if (frametime) {
2402                 // physics frames: update anticheat stuff
2403                 anticheat_prethink(this);
2404
2405                 // WORKAROUND: only use dropclient in server frames (frametime set).
2406                 // Never use it in cl_movement frames (frametime zero).
2407                 if (blockSpectators && IS_REAL_CLIENT(this)
2408                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2409                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2410                 {
2411                         if (dropclient_schedule(this))
2412                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2413                 }
2414         }
2415
2416         zoomstate_set = false;
2417
2418         // Check for nameless players
2419         if (this.netname == "" || this.netname != CS(this).netname_previous)
2420         {
2421                 bool assume_unchanged = (CS(this).netname_previous == "");
2422                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2423                 {
2424                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2425                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2426                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2427                         assume_unchanged = false;
2428                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2429                 }
2430                 if (isInvisibleString(this.netname))
2431                 {
2432                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2433                         sprint(this, "Warning: invisible names are not allowed.\n");
2434                         assume_unchanged = false;
2435                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2436                 }
2437                 if (!assume_unchanged && autocvar_sv_eventlog)
2438                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2439                 strcpy(CS(this).netname_previous, this.netname);
2440         }
2441
2442         // version nagging
2443         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2444         CS(this).version_nagtime = 0;
2445         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2446             // git client
2447         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2448             // git server
2449             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2450         } else {
2451             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2452             if (r < 0) { // old client
2453                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2454             } else if (r > 0) { // old server
2455                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2456             }
2457         }
2458     }
2459
2460         // GOD MODE info
2461         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2462         {
2463                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2464                 this.max_armorvalue = 0;
2465         }
2466
2467         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2468         {
2469                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2470                 {
2471                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2472                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2473                         if (this.iceblock)
2474                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2475
2476                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2477                                 Unfreeze(this, false);
2478                 }
2479                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2480                 {
2481                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2482                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2483
2484                         if (GetResource(this, RES_HEALTH) < 1)
2485                         {
2486                                 if (this.vehicle)
2487                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2488                                 if(this.event_damage)
2489                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2490                         }
2491                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2492                                 Unfreeze(this, false);
2493                 }
2494         }
2495
2496         MUTATOR_CALLHOOK(PlayerPreThink, this);
2497
2498         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2499         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2500         {
2501                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2502                 {
2503                         if(!it.owner)
2504                         {
2505                                 if(!it.team || SAME_TEAM(this, it))
2506                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2507                                 else if(autocvar_g_vehicles_steal)
2508                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2509                         }
2510                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2511                         {
2512                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2513                         }
2514                 });
2515
2516                 this.last_vehiclecheck = time + 1;
2517         }
2518
2519         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2520                 PlayerUseKey(this);
2521         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2522
2523         if (IS_REAL_CLIENT(this))
2524                 PrintWelcomeMessage(this);
2525
2526         if (IS_PLAYER(this)) {
2527                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2528                         error("Client can't be spawned as player on connection!");
2529                 if(!PlayerThink(this))
2530                         return;
2531         }
2532         else if (game_stopped || intermission_running) {
2533                 if(intermission_running)
2534                         IntermissionThink(this);
2535                 return;
2536         }
2537         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2538         {
2539                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2540                 CS(this).autojoin_checked = 1;
2541                 // don't do this in ClientConnect
2542                 // many things can go wrong if a client is spawned as player on connection
2543                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2544                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2545                                 && (!teamplay || autocvar_g_balance_teams)))
2546                 {
2547                         campaign_bots_may_start = true;
2548                         if(joinAllowed(this))
2549                                 Join(this);
2550                         return;
2551                 }
2552         }
2553         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2554                 ObserverOrSpectatorThink(this);
2555         }
2556
2557         // WEAPONTODO: Add weapon request for this
2558         if (!zoomstate_set) {
2559                 bool wep_zoomed = false;
2560                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2561                 {
2562                         .entity weaponentity = weaponentities[slot];
2563                         Weapon thiswep = this.(weaponentity).m_weapon;
2564                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2565                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2566                 }
2567                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2568         }
2569
2570         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2571         {
2572                 CS(this).teamkill_soundtime = 0;
2573
2574                 entity e = CS(this).teamkill_soundsource;
2575                 entity oldpusher = e.pusher;
2576                 e.pusher = this;
2577                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2578                 e.pusher = oldpusher;
2579         }
2580
2581         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2582                 CS(this).taunt_soundtime = 0;
2583                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2584         }
2585
2586         target_voicescript_next(this);
2587 }
2588
2589 void DrownPlayer(entity this)
2590 {
2591         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2592                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2593         {
2594                 STAT(AIR_FINISHED, this) = 0;
2595                 return;
2596         }
2597
2598         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2599         {
2600                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2601                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2602                 STAT(AIR_FINISHED, this) = 0;
2603         }
2604         else
2605         {
2606                 if (!STAT(AIR_FINISHED, this))
2607                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2608                 if (STAT(AIR_FINISHED, this) < time)
2609                 {       // drown!
2610                         if (this.pain_finished < time)
2611                         {
2612                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2613                                 this.pain_finished = time + 0.5;
2614                         }
2615                 }
2616         }
2617 }
2618
2619 .bool move_qcphysics;
2620
2621 void Player_Physics(entity this)
2622 {
2623         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2624
2625         if(!this.move_qcphysics)
2626                 return;
2627
2628         if(!frametime && !CS(this).pm_frametime)
2629                 return;
2630
2631         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2632
2633         CS(this).pm_frametime = 0;
2634 }
2635
2636 /*
2637 =============
2638 PlayerPostThink
2639
2640 Called every frame for each client after the physics are run
2641 =============
2642 */
2643 void PlayerPostThink (entity this)
2644 {
2645         Player_Physics(this);
2646
2647         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2648         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2649         if (IS_REAL_CLIENT(this))
2650         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2651         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2652         {
2653                 int totalClients = 0;
2654                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2655                 {
2656                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2657                         if (server_is_dedicated)
2658                         {
2659                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2660                                 {
2661                                         ++totalClients;
2662                                 });
2663                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2664                                         totalClients = 0;
2665                         }
2666                 }
2667                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2668                 {
2669                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2670                         {
2671                                 ++totalClients;
2672                         });
2673                 }
2674
2675                 if (totalClients < autocvar_sv_maxidle_minplayers)
2676                 {
2677                         // idle kick disabled
2678                         CS(this).parm_idlesince = time;
2679                 }
2680                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2681                 {
2682                         if (CS(this).idlekick_lasttimeleft)
2683                         {
2684                                 CS(this).idlekick_lasttimeleft = 0;
2685                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2686                         }
2687                 }
2688                 else
2689                 {
2690                         float maxidle_time = autocvar_sv_maxidle;
2691                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2692                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2693                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2694                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2695                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2696                         {
2697                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2698                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2699                                 else
2700                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2701                         }
2702                         if (timeleft <= 0) {
2703                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2704                                 {
2705                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2706                                         PutObserverInServer(this, true, true);
2707                                 }
2708                                 else
2709                                 {
2710                                         if (dropclient_schedule(this))
2711                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2712                                 }
2713                                 return;
2714                         }
2715                         else if (timeleft <= countdown_time) {
2716                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2717                                         play2(this, SND(TALK2));
2718                                 CS(this).idlekick_lasttimeleft = timeleft;
2719                         }
2720                 }
2721         }
2722
2723         CheatFrame(this);
2724
2725         if (game_stopped)
2726         {
2727                 this.solid = SOLID_NOT;
2728                 this.takedamage = DAMAGE_NO;
2729                 set_movetype(this, MOVETYPE_NONE);
2730                 CS(this).teamkill_complain = 0;
2731                 CS(this).teamkill_soundtime = 0;
2732                 CS(this).teamkill_soundsource = NULL;
2733         }
2734
2735         if (IS_PLAYER(this)) {
2736                 if(this.death_time == time && IS_DEAD(this))
2737                 {
2738                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2739                         // once all the damage events of this frame have been processed with normal size
2740                         this.maxs.z = 5;
2741                         setsize(this, this.mins, this.maxs);
2742                 }
2743                 DrownPlayer(this);
2744                 UpdateChatBubble(this);
2745                 if (CS(this).impulse) ImpulseCommands(this);
2746                 GetPressedKeys(this);
2747                 if (game_stopped)
2748                 {
2749                         CSQCMODEL_AUTOUPDATE(this);
2750                         return;
2751                 }
2752         }
2753         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2754         {
2755                 CS(this).pressedkeys = 0;
2756                 STAT(PRESSED_KEYS, this) = 0;
2757         }
2758
2759         if (this.waypointsprite_attachedforcarrier) {
2760                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2761                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2762         }
2763
2764         CSQCMODEL_AUTOUPDATE(this);
2765 }
2766
2767 // hack to copy the button fields from the client entity to the Client State
2768 void PM_UpdateButtons(entity this, entity store)
2769 {
2770         if(this.impulse)
2771                 store.impulse = this.impulse;
2772         this.impulse = 0;
2773
2774         bool typing = this.buttonchat || this.button12;
2775
2776         store.button0 = (typing) ? 0 : this.button0;
2777         //button1?!
2778         store.button2 = (typing) ? 0 : this.button2;
2779         store.button3 = (typing) ? 0 : this.button3;
2780         store.button4 = this.button4;
2781         store.button5 = (typing) ? 0 : this.button5;
2782         store.button6 = this.button6;
2783         store.button7 = this.button7;
2784         store.button8 = this.button8;
2785         store.button9 = this.button9;
2786         store.button10 = this.button10;
2787         store.button11 = this.button11;
2788         store.button12 = this.button12;
2789         store.button13 = this.button13;
2790         store.button14 = this.button14;
2791         store.button15 = this.button15;
2792         store.button16 = this.button16;
2793         store.buttonuse = this.buttonuse;
2794         store.buttonchat = this.buttonchat;
2795
2796         store.cursor_active = this.cursor_active;
2797         store.cursor_screen = this.cursor_screen;
2798         store.cursor_trace_start = this.cursor_trace_start;
2799         store.cursor_trace_endpos = this.cursor_trace_endpos;
2800         store.cursor_trace_ent = this.cursor_trace_ent;
2801
2802         store.ping = this.ping;
2803         store.ping_packetloss = this.ping_packetloss;
2804         store.ping_movementloss = this.ping_movementloss;
2805
2806         store.v_angle = this.v_angle;
2807         store.movement = this.movement;
2808 }
2809
2810 NET_HANDLE(fpsreport, bool)
2811 {
2812         int fps = ReadShort();
2813         PlayerScore_Set(sender, SP_FPS, fps);
2814         return true;
2815 }