qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!game_stopped)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.dual_weapons = '0 0 0';
 342         this.drawonlytoclient = this;
 343
 344         this.weaponmodel = "";
 345         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 346         {
 347                 this.weaponentities[slot] = NULL;
 348         }
 349         this.exteriorweaponentity = NULL;
 350         this.killcount = FRAGS_SPECTATOR;
 351         this.velocity = '0 0 0';
 352         this.avelocity = '0 0 0';
 353         this.punchangle = '0 0 0';
 354         this.punchvector = '0 0 0';
 355         this.oldvelocity = this.velocity;
 356         this.fire_endtime = -1;
 357         this.event_damage = func_null;
 358
 359         for(int slot = 0; slot < MAX_AXH; ++slot)
 360         {
 361                 entity axh = this.(AuxiliaryXhair[slot]);
 362                 this.(AuxiliaryXhair[slot]) = NULL;
 363
 364                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 365                         delete(axh);
 366         }
 367 }
 368
 369 int player_getspecies(entity this)
 370 {
 371         get_model_parameters(this.model, this.skin);
 372         int s = get_model_parameters_species;
 373         get_model_parameters(string_null, 0);
 374         if (s < 0) return SPECIES_HUMAN;
 375         return s;
 376 }
 377
 378 .float model_randomizer;
 379 void FixPlayermodel(entity player)
 380 {
 381         string defaultmodel = "";
 382         int defaultskin = 0;
 383         if(autocvar_sv_defaultcharacter)
 384         {
 385                 if(teamplay)
 386                 {
 387                         switch(player.team)
 388                         {
 389                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 390                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 391                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 392                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 393                         }
 394                 }
 395
 396                 if(defaultmodel == "")
 397                 {
 398                         defaultmodel = autocvar_sv_defaultplayermodel;
 399                         defaultskin = autocvar_sv_defaultplayerskin;
 400                 }
 401
 402                 int n = tokenize_console(defaultmodel);
 403                 if(n > 0)
 404                 {
 405                         defaultmodel = argv(floor(n * player.model_randomizer));
 406                         // However, do NOT randomize if the player-selected model is in the list.
 407                         for (int i = 0; i < n; ++i)
 408                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 409                                         defaultmodel = argv(i);
 410                 }
 411
 412                 int i = strstrofs(defaultmodel, ":", 0);
 413                 if(i >= 0)
 414                 {
 415                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 416                         defaultmodel = substring(defaultmodel, 0, i);
 417                 }
 418         }
 419         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 420         {
 421                 if(teamplay)
 422                 {
 423                         switch(player.team)
 424                         {
 425                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 426                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 427                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 428                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 429                         }
 430                 }
 431
 432                 if(!defaultskin)
 433                         defaultskin = autocvar_sv_defaultplayerskin;
 434         }
 435
 436         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 437         defaultmodel = M_ARGV(0, string);
 438         defaultskin = M_ARGV(1, int);
 439
 440         bool chmdl = false;
 441         int oldskin;
 442         if(defaultmodel != "")
 443         {
 444                 if (defaultmodel != player.model)
 445                 {
 446                         vector m1 = player.mins;
 447                         vector m2 = player.maxs;
 448                         setplayermodel (player, defaultmodel);
 449                         setsize (player, m1, m2);
 450                         chmdl = true;
 451                 }
 452
 453                 oldskin = player.skin;
 454                 player.skin = defaultskin;
 455         } else {
 456                 if (player.playermodel != player.model || player.playermodel == "")
 457                 {
 458                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 459                         vector m1 = player.mins;
 460                         vector m2 = player.maxs;
 461                         setplayermodel (player, player.playermodel);
 462                         setsize (player, m1, m2);
 463                         chmdl = true;
 464                 }
 465
 466                 if(!autocvar_sv_defaultcharacterskin)
 467                 {
 468                         oldskin = player.skin;
 469                         player.skin = stof(player.playerskin);
 470                 }
 471                 else
 472                 {
 473                         oldskin = player.skin;
 474                         player.skin = defaultskin;
 475                 }
 476         }
 477
 478         if(chmdl || oldskin != player.skin) // model or skin has changed
 479         {
 480                 player.species = player_getspecies(player); // update species
 481                 if(!autocvar_g_debug_globalsounds)
 482                         UpdatePlayerSounds(player); // update skin sounds
 483         }
 484
 485         if(!teamplay)
 486                 if(strlen(autocvar_sv_defaultplayercolors))
 487                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 488                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 489 }
 490
 491 void PutPlayerInServer(entity this)
 492 {
 493         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 494
 495         PlayerState_attach(this);
 496         accuracy_resend(this);
 497
 498         if (this.team < 0)
 499                 JoinBestTeam(this, false, true);
 500
 501         entity spot = SelectSpawnPoint(this, false);
 502         if (!spot) {
 503                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 504                 return; // spawn failed
 505         }
 506
 507         TRANSMUTE(Player, this);
 508
 509         this.wasplayer = true;
 510         this.iscreature = true;
 511         this.teleportable = TELEPORT_NORMAL;
 512         if(!this.damagedbycontents)
 513                 IL_PUSH(g_damagedbycontents, this);
 514         this.damagedbycontents = true;
 515         set_movetype(this, MOVETYPE_WALK);
 516         this.solid = SOLID_SLIDEBOX;
 517         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 518         if (autocvar_g_playerclip_collisions)
 519                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 520         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 521                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 522         this.frags = FRAGS_PLAYER;
 523         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 524         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 525         if (autocvar__notarget)
 526                 this.flags |= FL_NOTARGET;
 527         this.takedamage = DAMAGE_AIM;
 528         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 529         this.dmg = 2; // WTF
 530
 531         if (warmup_stage) {
 532                 this.ammo_shells = warmup_start_ammo_shells;
 533                 this.ammo_nails = warmup_start_ammo_nails;
 534                 this.ammo_rockets = warmup_start_ammo_rockets;
 535                 this.ammo_cells = warmup_start_ammo_cells;
 536                 this.ammo_plasma = warmup_start_ammo_plasma;
 537                 this.ammo_fuel = warmup_start_ammo_fuel;
 538                 this.health = warmup_start_health;
 539                 this.armorvalue = warmup_start_armorvalue;
 540                 this.weapons = WARMUP_START_WEAPONS;
 541         } else {
 542                 this.ammo_shells = start_ammo_shells;
 543                 this.ammo_nails = start_ammo_nails;
 544                 this.ammo_rockets = start_ammo_rockets;
 545                 this.ammo_cells = start_ammo_cells;
 546                 this.ammo_plasma = start_ammo_plasma;
 547                 this.ammo_fuel = start_ammo_fuel;
 548                 this.health = start_health;
 549                 this.armorvalue = start_armorvalue;
 550                 this.weapons = start_weapons;
 551         }
 552         SetSpectatee_status(this, 0);
 553
 554         this.dual_weapons = '0 0 0';
 555
 556         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 557
 558         this.items = start_items;
 559
 560         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 561         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 562         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 563         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 564         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 565         // extend the pause of rotting if client was reset at the beginning of the countdown
 566         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 567                 float f = game_starttime - time;
 568                 this.spawnshieldtime += f;
 569                 this.pauserotarmor_finished += f;
 570                 this.pauserothealth_finished += f;
 571                 this.pauseregen_finished += f;
 572         }
 573         this.damageforcescale = 2;
 574         this.death_time = 0;
 575         this.respawn_flags = 0;
 576         this.respawn_time = 0;
 577         this.stat_respawn_time = 0;
 578         this.scale = autocvar_sv_player_scale;
 579         this.fade_time = 0;
 580         this.pain_frame = 0;
 581         this.pain_finished = 0;
 582         this.pushltime = 0;
 583         setthink(this, func_null); // players have no think function
 584         this.nextthink = 0;
 585         this.dmg_team = 0;
 586         this.ballistics_density = autocvar_g_ballistics_density_player;
 587
 588         this.deadflag = DEAD_NO;
 589
 590         this.angles = spot.angles;
 591         this.angles_z = 0; // never spawn tilted even if the spot says to
 592         if (IS_BOT_CLIENT(this))
 593                 this.v_angle = this.angles;
 594         this.fixangle = true; // turn this way immediately
 595         this.oldvelocity = this.velocity = '0 0 0';
 596         this.avelocity = '0 0 0';
 597         this.punchangle = '0 0 0';
 598         this.punchvector = '0 0 0';
 599
 600         this.strength_finished = 0;
 601         this.invincible_finished = 0;
 602         this.fire_endtime = -1;
 603         this.revive_progress = 0;
 604         this.revival_time = 0;
 605         this.air_finished = time + 12;
 606
 607         entity spawnevent = new_pure(spawnevent);
 608         spawnevent.owner = this;
 609         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 610
 611         // Cut off any still running player sounds.
 612         stopsound(this, CH_PLAYER_SINGLE);
 613
 614         this.model = "";
 615         FixPlayermodel(this);
 616         this.drawonlytoclient = NULL;
 617
 618         this.viewloc = NULL;
 619
 620         this.crouch = false;
 621         this.view_ofs = STAT(PL_VIEW_OFS, this);
 622         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 623         this.spawnorigin = spot.origin;
 624         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 625         // don't reset back to last position, even if new position is stuck in solid
 626         this.oldorigin = this.origin;
 627         this.prevorigin = this.origin;
 628         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 629         if(this.conveyor)
 630                 IL_REMOVE(g_conveyed, this);
 631         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 632         this.hud = HUD_NORMAL;
 633
 634         this.event_damage = PlayerDamage;
 635
 636         if(!this.bot_attack)
 637                 IL_PUSH(g_bot_targets, this);
 638         this.bot_attack = true;
 639         if(!this.monster_attack)
 640                 IL_PUSH(g_monster_targets, this);
 641         this.monster_attack = true;
 642         navigation_dynamicgoal_init(this, false);
 643
 644         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 645
 646         if (this.killcount == FRAGS_SPECTATOR) {
 647                 PlayerScore_Clear(this);
 648                 this.killcount = 0;
 649         }
 650
 651         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 652         {
 653                 .entity weaponentity = weaponentities[slot];
 654                 entity oldwep = this.(weaponentity);
 655                 CL_SpawnWeaponentity(this, weaponentity);
 656                 if(oldwep && oldwep.owner == this)
 657                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 658         }
 659         this.alpha = default_player_alpha;
 660         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 661         this.exteriorweaponentity.alpha = default_weapon_alpha;
 662
 663         this.speedrunning = false;
 664
 665         target_voicescript_clear(this);
 666
 667         // reset fields the weapons may use
 668         FOREACH(Weapons, true, LAMBDA(
 669                 it.wr_resetplayer(it, this);
 670                         // reload all reloadable weapons
 671                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 672                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 673                         {
 674                                 .entity weaponentity = weaponentities[slot];
 675                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 676                         }
 677                 }
 678         ));
 679
 680         {
 681                 string s = spot.target;
 682                 spot.target = string_null;
 683                 SUB_UseTargets(spot, this, NULL);
 684                 spot.target = s;
 685         }
 686
 687         Unfreeze(this);
 688
 689         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 690
 691         if (autocvar_spawn_debug)
 692         {
 693                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 694                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 695         }
 696
 697         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 698         {
 699                 .entity weaponentity = weaponentities[slot];
 700                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 701                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 702                 else
 703                         this.(weaponentity).m_switchweapon = WEP_Null;
 704                 this.(weaponentity).m_weapon = WEP_Null;
 705                 this.(weaponentity).weaponname = "";
 706                 this.(weaponentity).m_switchingweapon = WEP_Null;
 707                 this.(weaponentity).cnt = -1;
 708         }
 709
 710         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 711
 712         if (!warmup_stage && !this.alivetime)
 713                 this.alivetime = time;
 714
 715         antilag_clear(this, CS(this));
 716 }
 717
 718 /** Called when a client spawns in the server */
 719 void PutClientInServer(entity this)
 720 {
 721         if (IS_BOT_CLIENT(this)) {
 722                 TRANSMUTE(Player, this);
 723         } else if (IS_REAL_CLIENT(this)) {
 724                 msg_entity = this;
 725                 WriteByte(MSG_ONE, SVC_SETVIEW);
 726                 WriteEntity(MSG_ONE, this);
 727         }
 728         if (game_stopped)
 729                 TRANSMUTE(Observer, this);
 730
 731         SetSpectatee(this, NULL);
 732
 733         // reset player keys
 734         this.itemkeys = 0;
 735
 736         MUTATOR_CALLHOOK(PutClientInServer, this);
 737
 738         if (IS_OBSERVER(this)) {
 739                 PutObserverInServer(this);
 740         } else if (IS_PLAYER(this)) {
 741                 PutPlayerInServer(this);
 742         }
 743 }
 744
 745 void ClientInit_misc(entity this);
 746
 747 // TODO do we need all these fields, or should we stop autodetecting runtime
 748 // changes and just have a console command to update this?
 749 bool ClientInit_SendEntity(entity this, entity to, int sf)
 750 {
 751         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 752         return = true;
 753         msg_entity = to;
 754         // MSG_INIT replacement
 755         // TODO: make easier to use
 756         Registry_send_all();
 757         W_PROP_reload(MSG_ONE, to);
 758         ClientInit_misc(this);
 759         MUTATOR_CALLHOOK(Ent_Init);
 760 }
 761 void ClientInit_misc(entity this)
 762 {
 763         int channel = MSG_ONE;
 764         WriteHeader(channel, ENT_CLIENT_INIT);
 765         WriteByte(channel, g_nexball_meter_period * 32);
 766         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 767         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 768         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 769         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 770         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 771         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 772         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 773         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 774
 775         if(sv_foginterval && world.fog != "")
 776                 WriteString(channel, world.fog);
 777         else
 778                 WriteString(channel, "");
 779         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 780         WriteByte(channel, serverflags);
 781         WriteCoord(channel, autocvar_g_trueaim_minrange);
 782 }
 783
 784 void ClientInit_CheckUpdate(entity this)
 785 {
 786         this.nextthink = time;
 787         if(this.count != autocvar_g_balance_armor_blockpercent)
 788         {
 789                 this.count = autocvar_g_balance_armor_blockpercent;
 790                 this.SendFlags |= 1;
 791         }
 792 }
 793
 794 void ClientInit_Spawn()
 795 {
 796         entity e = new_pure(clientinit);
 797         setthink(e, ClientInit_CheckUpdate);
 798         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 799
 800         ClientInit_CheckUpdate(e);
 801 }
 802
 803 /*
 804 =============
 805 SetNewParms
 806 =============
 807 */
 808 void SetNewParms ()
 809 {
 810         // initialize parms for a new player
 811         parm1 = -(86400 * 366);
 812
 813         MUTATOR_CALLHOOK(SetNewParms);
 814 }
 815
 816 /*
 817 =============
 818 SetChangeParms
 819 =============
 820 */
 821 void SetChangeParms (entity this)
 822 {
 823         // save parms for level change
 824         parm1 = CS(this).parm_idlesince - time;
 825
 826         MUTATOR_CALLHOOK(SetChangeParms);
 827 }
 828
 829 /*
 830 =============
 831 DecodeLevelParms
 832 =============
 833 */
 834 void DecodeLevelParms(entity this)
 835 {
 836         // load parms
 837         CS(this).parm_idlesince = parm1;
 838         if (CS(this).parm_idlesince == -(86400 * 366))
 839                 CS(this).parm_idlesince = time;
 840
 841         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 842         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 843
 844         MUTATOR_CALLHOOK(DecodeLevelParms);
 845 }
 846
 847 /*
 848 =============
 849 ClientKill
 850
 851 Called when a client types 'kill' in the console
 852 =============
 853 */
 854
 855 .float clientkill_nexttime;
 856 void ClientKill_Now_TeamChange(entity this)
 857 {
 858         if(CS(this).killindicator_teamchange == -1)
 859         {
 860                 JoinBestTeam( this, false, true );
 861         }
 862         else if(CS(this).killindicator_teamchange == -2)
 863         {
 864                 if(blockSpectators)
 865                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 866                 PutObserverInServer(this);
 867         }
 868         else
 869                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 870         CS(this).killindicator_teamchange = 0;
 871 }
 872
 873 void ClientKill_Now(entity this)
 874 {
 875         if(this.vehicle)
 876         {
 877             vehicles_exit(this.vehicle, VHEF_RELEASE);
 878             if(!CS(this).killindicator_teamchange)
 879             {
 880             this.vehicle_health = -1;
 881             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 882             }
 883         }
 884
 885         if(this.killindicator && !wasfreed(this.killindicator))
 886                 delete(this.killindicator);
 887
 888         this.killindicator = NULL;
 889
 890         if(CS(this).killindicator_teamchange)
 891                 ClientKill_Now_TeamChange(this);
 892
 893         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 894                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 895
 896         // now I am sure the player IS dead
 897 }
 898 void KillIndicator_Think(entity this)
 899 {
 900         if (game_stopped)
 901         {
 902                 this.owner.killindicator = NULL;
 903                 delete(this);
 904                 return;
 905         }
 906
 907         if (this.owner.alpha < 0 && !this.owner.vehicle)
 908         {
 909                 this.owner.killindicator = NULL;
 910                 delete(this);
 911                 return;
 912         }
 913
 914         if(this.cnt <= 0)
 915         {
 916                 ClientKill_Now(this.owner);
 917                 return;
 918         }
 919     else if(this.health == 1) // health == 1 means that it's silent
 920     {
 921         this.nextthink = time + 1;
 922         this.cnt -= 1;
 923     }
 924         else
 925         {
 926                 if(this.cnt <= 10)
 927                         setmodel(this, MDL_NUM(this.cnt));
 928                 if(IS_REAL_CLIENT(this.owner))
 929                 {
 930                         if(this.cnt <= 10)
 931                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 932                 }
 933                 this.nextthink = time + 1;
 934                 this.cnt -= 1;
 935         }
 936 }
 937
 938 float clientkilltime;
 939 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 940 {
 941         float killtime;
 942         float starttime;
 943
 944         if (game_stopped)
 945                 return;
 946
 947         killtime = autocvar_g_balance_kill_delay;
 948
 949     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 950         return;
 951     killtime = M_ARGV(1, float);
 952
 953         CS(this).killindicator_teamchange = targetteam;
 954
 955     if(!this.killindicator)
 956         {
 957                 if(!IS_DEAD(this))
 958                 {
 959                         killtime = max(killtime, this.clientkill_nexttime - time);
 960                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 961                 }
 962
 963                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 964                 {
 965                         ClientKill_Now(this);
 966                 }
 967                 else
 968                 {
 969                         starttime = max(time, clientkilltime);
 970
 971                         this.killindicator = spawn();
 972                         this.killindicator.owner = this;
 973                         this.killindicator.scale = 0.5;
 974                         setattachment(this.killindicator, this, "");
 975                         setorigin(this.killindicator, '0 0 52');
 976                         setthink(this.killindicator, KillIndicator_Think);
 977                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 978                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 979                         this.killindicator.cnt = ceil(killtime);
 980                         this.killindicator.count = bound(0, ceil(killtime), 10);
 981                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 982
 983                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 984                         {
 985                                 it.killindicator = spawn();
 986                                 it.killindicator.owner = it;
 987                                 it.killindicator.scale = 0.5;
 988                                 setattachment(it.killindicator, it, "");
 989                                 setorigin(it.killindicator, '0 0 52');
 990                                 setthink(it.killindicator, KillIndicator_Think);
 991                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 992                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 993                                 it.killindicator.cnt = ceil(killtime);
 994                         });
 995                         this.lip = 0;
 996                 }
 997         }
 998         if(this.killindicator)
 999         {
1000                 if(targetteam == 0) // just die
1001                 {
1002                         this.killindicator.colormod = '0 0 0';
1003                         if(IS_REAL_CLIENT(this))
1004                         if(this.killindicator.cnt > 0)
1005                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1006                 }
1007                 else if(targetteam == -1) // auto
1008                 {
1009                         this.killindicator.colormod = '0 1 0';
1010                         if(IS_REAL_CLIENT(this))
1011                         if(this.killindicator.cnt > 0)
1012                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1013                 }
1014                 else if(targetteam == -2) // spectate
1015                 {
1016                         this.killindicator.colormod = '0.5 0.5 0.5';
1017                         if(IS_REAL_CLIENT(this))
1018                         if(this.killindicator.cnt > 0)
1019                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1020                 }
1021                 else
1022                 {
1023                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1024                         if(IS_REAL_CLIENT(this))
1025                         if(this.killindicator.cnt > 0)
1026                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1027                 }
1028         }
1029
1030 }
1031
1032 void ClientKill (entity this)
1033 {
1034         if(game_stopped) return;
1035         if(this.player_blocked) return;
1036         if(STAT(FROZEN, this)) return;
1037
1038         ClientKill_TeamChange(this, 0);
1039 }
1040
1041 void FixClientCvars(entity e)
1042 {
1043         // send prediction settings to the client
1044         stuffcmd(e, "\nin_bindmap 0 0\n");
1045         if(autocvar_g_antilag == 3) // client side hitscan
1046                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1047         if(autocvar_sv_gentle)
1048                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1049
1050         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1051         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1052
1053         MUTATOR_CALLHOOK(FixClientCvars, e);
1054 }
1055
1056 bool findinlist_abbrev(string tofind, string list)
1057 {
1058         // this function allows abbreviated strings!
1059         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1060         {
1061                 return true;
1062         });
1063
1064         return false;
1065 }
1066
1067 bool PlayerInIPList(entity p, string iplist)
1068 {
1069         // some safety checks (never allow local?)
1070         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1071                 return false;
1072
1073         return findinlist_abbrev(p.netaddress, iplist);
1074 }
1075
1076 bool PlayerInIDList(entity p, string idlist)
1077 {
1078         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1079         if(!p.crypto_idfp)
1080                 return false;
1081
1082         return findinlist_abbrev(p.crypto_idfp, idlist);
1083 }
1084
1085 bool PlayerInList(entity player, string list)
1086 {
1087         return PlayerInIDList(player, list) || PlayerInIPList(player, list);
1088 }
1089
1090 #ifdef DP_EXT_PRECONNECT
1091 /*
1092 =============
1093 ClientPreConnect
1094
1095 Called once (not at each match start) when a client begins a connection to the server
1096 =============
1097 */
1098 void ClientPreConnect(entity this)
1099 {
1100         if(autocvar_sv_eventlog)
1101         {
1102                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1103                         this.playerid,
1104                         etof(this),
1105                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1106                 ));
1107         }
1108 }
1109 #endif
1110
1111 /**
1112 =============
1113 ClientConnect
1114
1115 Called when a client connects to the server
1116 =============
1117 */
1118 void ClientConnect(entity this)
1119 {
1120         if (Ban_MaybeEnforceBanOnce(this)) return;
1121         assert(!IS_CLIENT(this), return);
1122         this.flags |= FL_CLIENT;
1123         assert(player_count >= 0, player_count = 0);
1124
1125 #ifdef WATERMARK
1126         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1127 #endif
1128         this.version_nagtime = time + 10 + random() * 10;
1129         TRANSMUTE(Client, this);
1130
1131         // identify the right forced team
1132         if (autocvar_g_campaign)
1133         {
1134                 if (IS_REAL_CLIENT(this)) // only players, not bots
1135                 {
1136                         switch (autocvar_g_campaign_forceteam)
1137                         {
1138                                 case 1: this.team_forced = NUM_TEAM_1; break;
1139                                 case 2: this.team_forced = NUM_TEAM_2; break;
1140                                 case 3: this.team_forced = NUM_TEAM_3; break;
1141                                 case 4: this.team_forced = NUM_TEAM_4; break;
1142                                 default: this.team_forced = 0;
1143                         }
1144                 }
1145         }
1146         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1147         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1148         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1149         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1150         else switch (autocvar_g_forced_team_otherwise)
1151         {
1152                 default: this.team_forced = 0; break;
1153                 case "red": this.team_forced = NUM_TEAM_1; break;
1154                 case "blue": this.team_forced = NUM_TEAM_2; break;
1155                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1156                 case "pink": this.team_forced = NUM_TEAM_4; break;
1157                 case "spectate":
1158                 case "spectator":
1159                         this.team_forced = -1;
1160                         break;
1161         }
1162         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1163
1164     {
1165         int id = this.playerid;
1166         this.playerid = 0; // silent
1167             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1168             this.playerid = id;
1169     }
1170
1171         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1172                 TRANSMUTE(Observer, this);
1173         } else {
1174                 if (!teamplay || autocvar_g_balance_teams) {
1175                         TRANSMUTE(Player, this);
1176                         campaign_bots_may_start = true;
1177                 } else {
1178                         TRANSMUTE(Observer, this); // do it anyway
1179                 }
1180         }
1181
1182         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1183
1184         // always track bots, don't ask for cl_allow_uidtracking
1185     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1186
1187         if (autocvar_sv_eventlog)
1188                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1189
1190         LogTeamchange(this.playerid, this.team, 1);
1191
1192         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1193
1194         this.netname_previous = strzone(this.netname);
1195
1196         if(teamplay && IS_PLAYER(this))
1197                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1198         else
1199                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1200
1201         stuffcmd(this, clientstuff, "\n");
1202         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1203
1204         FixClientCvars(this);
1205
1206         // get version info from player
1207         stuffcmd(this, "cmd clientversion $gameversion\n");
1208
1209         // notify about available teams
1210         if (teamplay)
1211         {
1212                 CheckAllowedTeams(this);
1213                 int t = 0;
1214                 if (c1 >= 0) t |= BIT(0);
1215                 if (c2 >= 0) t |= BIT(1);
1216                 if (c3 >= 0) t |= BIT(2);
1217                 if (c4 >= 0) t |= BIT(3);
1218                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1219         }
1220         else
1221         {
1222                 stuffcmd(this, "set _teams_available 0\n");
1223         }
1224
1225         bot_relinkplayerlist();
1226
1227         this.spectatortime = time;
1228         if (blockSpectators)
1229         {
1230                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1231         }
1232
1233         CS(this).jointime = time;
1234         this.allowed_timeouts = autocvar_sv_timeout_number;
1235
1236         if (IS_REAL_CLIENT(this))
1237         {
1238                 if (g_weaponarena_weapons == WEPSET(TUBA))
1239                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1240         }
1241
1242         if (!sv_foginterval && world.fog != "")
1243                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1244
1245         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1246                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1247                         send_CSQC_teamnagger();
1248
1249         CSQCMODEL_AUTOINIT(this);
1250
1251         this.model_randomizer = random();
1252
1253         if (IS_REAL_CLIENT(this))
1254                 sv_notice_join(this);
1255
1256         // update physics stats (players can spawn before physics runs)
1257         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1258         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1259         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1260
1261         IL_EACH(g_initforplayer, it.init_for_player, {
1262                 it.init_for_player(it, this);
1263         });
1264
1265         MUTATOR_CALLHOOK(ClientConnect, this);
1266
1267         if (IS_REAL_CLIENT(this))
1268         {
1269                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1270                 {
1271                         CS(this).motd_actived_time = -1;
1272                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1273                 }
1274         }
1275 }
1276 /*
1277 =============
1278 ClientDisconnect
1279
1280 Called when a client disconnects from the server
1281 =============
1282 */
1283 .entity chatbubbleentity;
1284 void ReadyCount();
1285 void ClientDisconnect(entity this)
1286 {
1287         assert(IS_CLIENT(this), return);
1288
1289         PlayerStats_GameReport_FinalizePlayer(this);
1290         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1291         if (this.active_minigame) part_minigame(this);
1292         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1293
1294         if (autocvar_sv_eventlog)
1295                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1296
1297         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1298
1299         if(IS_SPEC(this))
1300                 SetSpectatee(this, NULL);
1301
1302     MUTATOR_CALLHOOK(ClientDisconnect, this);
1303
1304         ClientState_detach(this);
1305
1306         Portal_ClearAll(this);
1307
1308         Unfreeze(this);
1309
1310         RemoveGrapplingHooks(this);
1311
1312         // Here, everything has been done that requires this player to be a client.
1313
1314         this.flags &= ~FL_CLIENT;
1315
1316         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1317         if (this.killindicator) delete(this.killindicator);
1318
1319         WaypointSprite_PlayerGone(this);
1320
1321         bot_relinkplayerlist();
1322
1323         if (this.netname_previous) strunzone(this.netname_previous);
1324         if (this.clientstatus) strunzone(this.clientstatus);
1325         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1326         if (this.personal) delete(this.personal);
1327
1328         this.playerid = 0;
1329         ReadyCount();
1330         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1331
1332         ONREMOVE(this);
1333 }
1334
1335 void ChatBubbleThink(entity this)
1336 {
1337         this.nextthink = time;
1338         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1339         {
1340                 if(this.owner) // but why can that ever be NULL?
1341                         this.owner.chatbubbleentity = NULL;
1342                 delete(this);
1343                 return;
1344         }
1345
1346         this.mdl = "";
1347
1348         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1349         {
1350                 if ( this.owner.active_minigame )
1351                         this.mdl = "models/sprites/minigame_busy.iqm";
1352                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1353                         this.mdl = "models/misc/chatbubble.spr";
1354         }
1355
1356         if ( this.model != this.mdl )
1357                 _setmodel(this, this.mdl);
1358
1359 }
1360
1361 void UpdateChatBubble(entity this)
1362 {
1363         if (this.alpha < 0)
1364                 return;
1365         // spawn a chatbubble entity if needed
1366         if (!this.chatbubbleentity)
1367         {
1368                 this.chatbubbleentity = new(chatbubbleentity);
1369                 this.chatbubbleentity.owner = this;
1370                 this.chatbubbleentity.exteriormodeltoclient = this;
1371                 setthink(this.chatbubbleentity, ChatBubbleThink);
1372                 this.chatbubbleentity.nextthink = time;
1373                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1374                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1375                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1376                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1377                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1378                 //this.chatbubbleentity.model = "";
1379                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1380         }
1381 }
1382
1383
1384 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1385 // added to the model skins
1386 /*void UpdateColorModHack()
1387 {
1388         float c;
1389         c = this.clientcolors & 15;
1390         // LordHavoc: only bothering to support white, green, red, yellow, blue
1391              if (!teamplay) this.colormod = '0 0 0';
1392         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1393         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1394         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1395         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1396         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1397         else this.colormod = '1 1 1';
1398 }*/
1399
1400 void respawn(entity this)
1401 {
1402         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1403         {
1404                 this.solid = SOLID_NOT;
1405                 this.takedamage = DAMAGE_NO;
1406                 set_movetype(this, MOVETYPE_FLY);
1407                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1408                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1409                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1410                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1411                 if(autocvar_g_respawn_ghosts_maxtime)
1412                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1413         }
1414
1415         CopyBody(this, 1);
1416
1417         this.effects |= EF_NODRAW; // prevent another CopyBody
1418         PutClientInServer(this);
1419 }
1420
1421 void play_countdown(entity this, float finished, Sound samp)
1422 {
1423     TC(Sound, samp);
1424         if(IS_REAL_CLIENT(this))
1425                 if(floor(finished - time - frametime) != floor(finished - time))
1426                         if(finished - time < 6)
1427                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1428 }
1429
1430 void player_powerups(entity this)
1431 {
1432         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1433         int items_prev = this.items;
1434
1435         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1436                 this.modelflags |= MF_ROCKET;
1437         else
1438                 this.modelflags &= ~MF_ROCKET;
1439
1440         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1441
1442         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1443                 return;
1444
1445         Fire_ApplyDamage(this);
1446         Fire_ApplyEffect(this);
1447
1448         if (!g_instagib)
1449         {
1450                 if (this.items & ITEM_Strength.m_itemid)
1451                 {
1452                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1453                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1454                         if (time > this.strength_finished)
1455                         {
1456                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1457                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1458                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1459                         }
1460                 }
1461                 else
1462                 {
1463                         if (time < this.strength_finished)
1464                         {
1465                                 this.items = this.items | ITEM_Strength.m_itemid;
1466                                 if(!g_cts)
1467                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1468                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1469                         }
1470                 }
1471                 if (this.items & ITEM_Shield.m_itemid)
1472                 {
1473                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1474                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1475                         if (time > this.invincible_finished)
1476                         {
1477                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1478                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1479                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1480                         }
1481                 }
1482                 else
1483                 {
1484                         if (time < this.invincible_finished)
1485                         {
1486                                 this.items = this.items | ITEM_Shield.m_itemid;
1487                                 if(!g_cts)
1488                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1489                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1490                         }
1491                 }
1492                 if (this.items & IT_SUPERWEAPON)
1493                 {
1494                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1495                         {
1496                                 this.superweapons_finished = 0;
1497                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1498                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1499                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1500                         }
1501                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1502                         {
1503                                 // don't let them run out
1504                         }
1505                         else
1506                         {
1507                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1508                                 if (time > this.superweapons_finished)
1509                                 {
1510                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1511                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1512                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1513                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1514                                 }
1515                         }
1516                 }
1517                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1518                 {
1519                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1520                         {
1521                                 this.items = this.items | IT_SUPERWEAPON;
1522                                 if(!g_cts)
1523                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1524                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1525                         }
1526                         else
1527                         {
1528                                 this.superweapons_finished = 0;
1529                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1530                         }
1531                 }
1532                 else
1533                 {
1534                         this.superweapons_finished = 0;
1535                 }
1536         }
1537
1538         if(autocvar_g_nodepthtestplayers)
1539                 this.effects = this.effects | EF_NODEPTHTEST;
1540
1541         if(autocvar_g_fullbrightplayers)
1542                 this.effects = this.effects | EF_FULLBRIGHT;
1543
1544         if (time >= game_starttime)
1545         if (time < this.spawnshieldtime)
1546                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1547
1548         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1549 }
1550
1551 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1552 {
1553         if(current > stable)
1554                 return current;
1555         else if(current > stable - 0.25) // when close enough, "snap"
1556                 return stable;
1557         else
1558                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1559 }
1560
1561 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1562 {
1563         if(current < stable)
1564                 return current;
1565         else if(current < stable + 0.25) // when close enough, "snap"
1566                 return stable;
1567         else
1568                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1569 }
1570
1571 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1572 {
1573         if(current > rotstable)
1574         {
1575                 if(rotframetime > 0)
1576                 {
1577                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1578                         current = max(rotstable, current - rotlinear * rotframetime);
1579                 }
1580         }
1581         else if(current < regenstable)
1582         {
1583                 if(regenframetime > 0)
1584                 {
1585                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1586                         current = min(regenstable, current + regenlinear * regenframetime);
1587                 }
1588         }
1589
1590         if(current > limit)
1591                 current = limit;
1592
1593         return current;
1594 }
1595
1596 void player_regen(entity this)
1597 {
1598         float max_mod, regen_mod, rot_mod, limit_mod;
1599         max_mod = regen_mod = rot_mod = limit_mod = 1;
1600
1601         float regen_health = autocvar_g_balance_health_regen;
1602         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1603         float regen_health_rot = autocvar_g_balance_health_rot;
1604         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1605         float regen_health_stable = autocvar_g_balance_health_regenstable;
1606         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1607         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1608                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1609         max_mod = M_ARGV(1, float);
1610         regen_mod = M_ARGV(2, float);
1611         rot_mod = M_ARGV(3, float);
1612         limit_mod = M_ARGV(4, float);
1613         regen_health = M_ARGV(5, float);
1614         regen_health_linear = M_ARGV(6, float);
1615         regen_health_rot = M_ARGV(7, float);
1616         regen_health_rotlinear = M_ARGV(8, float);
1617         regen_health_stable = M_ARGV(9, float);
1618         regen_health_rotstable = M_ARGV(10, float);
1619
1620
1621         if(!mutator_returnvalue)
1622         if(!STAT(FROZEN, this))
1623         {
1624                 float mina, maxa, limith, limita;
1625                 maxa = autocvar_g_balance_armor_rotstable;
1626                 mina = autocvar_g_balance_armor_regenstable;
1627                 limith = autocvar_g_balance_health_limit;
1628                 limita = autocvar_g_balance_armor_limit;
1629
1630                 regen_health_rotstable = regen_health_rotstable * max_mod;
1631                 regen_health_stable = regen_health_stable * max_mod;
1632                 limith = limith * limit_mod;
1633                 limita = limita * limit_mod;
1634
1635                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1636                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1637         }
1638
1639         // if player rotted to death...  die!
1640         // check this outside above checks, as player may still be able to rot to death
1641         if(this.health < 1)
1642         {
1643                 if(this.vehicle)
1644                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1645                 if(this.event_damage)
1646                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1647         }
1648
1649         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1650         {
1651                 float minf, maxf, limitf;
1652
1653                 maxf = autocvar_g_balance_fuel_rotstable;
1654                 minf = autocvar_g_balance_fuel_regenstable;
1655                 limitf = autocvar_g_balance_fuel_limit;
1656
1657                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1658         }
1659 }
1660
1661 bool zoomstate_set;
1662 void SetZoomState(entity this, float newzoom)
1663 {
1664         if(newzoom != this.zoomstate)
1665         {
1666                 this.zoomstate = newzoom;
1667                 ClientData_Touch(this);
1668         }
1669         zoomstate_set = true;
1670 }
1671
1672 void GetPressedKeys(entity this)
1673 {
1674         MUTATOR_CALLHOOK(GetPressedKeys, this);
1675         int keys = STAT(PRESSED_KEYS, this);
1676         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1677         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1678         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1679         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1680
1681         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1682         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1683         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1684         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1685         CS(this).pressedkeys = keys; // store for other users
1686
1687         STAT(PRESSED_KEYS, this) = keys;
1688 }
1689
1690 /*
1691 ======================
1692 spectate mode routines
1693 ======================
1694 */
1695
1696 void SpectateCopy(entity this, entity spectatee)
1697 {
1698     TC(Client, this); TC(Client, spectatee);
1699
1700         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1701         PS(this) = PS(spectatee);
1702         this.armortype = spectatee.armortype;
1703         this.armorvalue = spectatee.armorvalue;
1704         this.ammo_cells = spectatee.ammo_cells;
1705         this.ammo_plasma = spectatee.ammo_plasma;
1706         this.ammo_shells = spectatee.ammo_shells;
1707         this.ammo_nails = spectatee.ammo_nails;
1708         this.ammo_rockets = spectatee.ammo_rockets;
1709         this.ammo_fuel = spectatee.ammo_fuel;
1710         this.clip_load = spectatee.clip_load;
1711         this.clip_size = spectatee.clip_size;
1712         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1713         this.health = spectatee.health;
1714         CS(this).impulse = 0;
1715         this.items = spectatee.items;
1716         this.last_pickup = spectatee.last_pickup;
1717         this.hit_time = spectatee.hit_time;
1718         this.strength_finished = spectatee.strength_finished;
1719         this.invincible_finished = spectatee.invincible_finished;
1720         this.superweapons_finished = spectatee.superweapons_finished;
1721         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1722         this.weapons = spectatee.weapons;
1723         this.dual_weapons = spectatee.dual_weapons;
1724         this.vortex_charge = spectatee.vortex_charge;
1725         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1726         this.hagar_load = spectatee.hagar_load;
1727         this.arc_heat_percent = spectatee.arc_heat_percent;
1728         this.minelayer_mines = spectatee.minelayer_mines;
1729         this.punchangle = spectatee.punchangle;
1730         this.view_ofs = spectatee.view_ofs;
1731         this.velocity = spectatee.velocity;
1732         this.dmg_take = spectatee.dmg_take;
1733         this.dmg_save = spectatee.dmg_save;
1734         this.dmg_inflictor = spectatee.dmg_inflictor;
1735         this.v_angle = spectatee.v_angle;
1736         this.angles = spectatee.v_angle;
1737         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1738         this.revive_progress = spectatee.revive_progress;
1739         this.viewloc = spectatee.viewloc;
1740         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1741                 this.fixangle = true;
1742         setorigin(this, spectatee.origin);
1743         setsize(this, spectatee.mins, spectatee.maxs);
1744         SetZoomState(this, spectatee.zoomstate);
1745
1746         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1747         {
1748                 .entity weaponentity = weaponentities[slot];
1749                 this.(weaponentity) = spectatee.(weaponentity);
1750         }
1751
1752         for(int slot = 0; slot < MAX_AXH; ++slot)
1753         {
1754                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1755         }
1756
1757     anticheat_spectatecopy(this, spectatee);
1758         this.hud = spectatee.hud;
1759         if(spectatee.vehicle)
1760     {
1761         this.angles = spectatee.v_angle;
1762
1763         //this.fixangle = false;
1764         //this.velocity = spectatee.vehicle.velocity;
1765         this.vehicle_health = spectatee.vehicle_health;
1766         this.vehicle_shield = spectatee.vehicle_shield;
1767         this.vehicle_energy = spectatee.vehicle_energy;
1768         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1769         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1770         this.vehicle_reload1 = spectatee.vehicle_reload1;
1771         this.vehicle_reload2 = spectatee.vehicle_reload2;
1772
1773         //msg_entity = this;
1774
1775        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1776             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1777            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1778            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1779
1780         //WriteByte (MSG_ONE, SVC_SETVIEW);
1781         //    WriteEntity(MSG_ONE, this);
1782         //makevectors(spectatee.v_angle);
1783         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1784     }
1785 }
1786
1787 bool SpectateUpdate(entity this)
1788 {
1789         if(!this.enemy)
1790                 return false;
1791
1792         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1793         {
1794                 SetSpectatee(this, NULL);
1795                 return false;
1796         }
1797
1798         SpectateCopy(this, this.enemy);
1799
1800         return true;
1801 }
1802
1803 bool SpectateSet(entity this)
1804 {
1805         if(!IS_PLAYER(this.enemy))
1806                 return false;
1807
1808         ClientData_Touch(this.enemy);
1809
1810         msg_entity = this;
1811         WriteByte(MSG_ONE, SVC_SETVIEW);
1812         WriteEntity(MSG_ONE, this.enemy);
1813         set_movetype(this, MOVETYPE_NONE);
1814         accuracy_resend(this);
1815
1816         if(!SpectateUpdate(this))
1817                 PutObserverInServer(this);
1818
1819         return true;
1820 }
1821
1822 void SetSpectatee_status(entity this, int spectatee_num)
1823 {
1824         int oldspectatee_status = this.spectatee_status;
1825         this.spectatee_status = spectatee_num;
1826
1827         if (this.spectatee_status != oldspectatee_status)
1828         {
1829                 ClientData_Touch(this);
1830                 if (g_race || g_cts) race_InitSpectator();
1831         }
1832 }
1833
1834 void SetSpectatee(entity this, entity spectatee)
1835 {
1836         if(IS_BOT_CLIENT(this))
1837                 return; // bots abuse .enemy, this code is useless to them
1838
1839         entity old_spectatee = this.enemy;
1840
1841         this.enemy = spectatee;
1842
1843         // WEAPONTODO
1844         // these are required to fix the spectator bug with arc
1845         if(old_spectatee)
1846         {
1847                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1848                 {
1849                         .entity weaponentity = weaponentities[slot];
1850                         if(old_spectatee.(weaponentity).arc_beam)
1851                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1852                 }
1853         }
1854         if(this.enemy)
1855         {
1856                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1857                 {
1858                         .entity weaponentity = weaponentities[slot];
1859                         if(this.enemy.(weaponentity).arc_beam)
1860                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1861                 }
1862         }
1863
1864         if (this.enemy)
1865                 SetSpectatee_status(this, etof(this.enemy));
1866
1867         // needed to update spectator list
1868         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1869 }
1870
1871 bool Spectate(entity this, entity pl)
1872 {
1873         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1874                 return false;
1875         pl = M_ARGV(1, entity);
1876
1877         SetSpectatee(this, pl);
1878         return SpectateSet(this);
1879 }
1880
1881 bool SpectateNext(entity this)
1882 {
1883         entity ent = find(this.enemy, classname, STR_PLAYER);
1884
1885         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1886                 ent = M_ARGV(1, entity);
1887         else if (!ent)
1888                 ent = find(ent, classname, STR_PLAYER);
1889
1890         if(ent) { SetSpectatee(this, ent); }
1891
1892         return SpectateSet(this);
1893 }
1894
1895 bool SpectatePrev(entity this)
1896 {
1897         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1898         entity ent = findchain(classname, STR_PLAYER);
1899         if (!ent) // no player
1900                 return false;
1901
1902         entity first = ent;
1903         // skip players until current spectated player
1904         if(this.enemy)
1905         while(ent && ent != this.enemy)
1906                 ent = ent.chain;
1907
1908         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1909         {
1910                 case MUT_SPECPREV_FOUND:
1911                     ent = M_ARGV(1, entity);
1912                     break;
1913                 case MUT_SPECPREV_RETURN:
1914                     return true;
1915                 case MUT_SPECPREV_CONTINUE:
1916                 default:
1917                 {
1918                         if(ent.chain)
1919                                 ent = ent.chain;
1920                         else
1921                                 ent = first;
1922                         break;
1923                 }
1924         }
1925
1926         SetSpectatee(this, ent);
1927         return SpectateSet(this);
1928 }
1929
1930 /*
1931 =============
1932 ShowRespawnCountdown()
1933
1934 Update a respawn countdown display.
1935 =============
1936 */
1937 void ShowRespawnCountdown(entity this)
1938 {
1939         float number;
1940         if(!IS_DEAD(this)) // just respawned?
1941                 return;
1942         else
1943         {
1944                 number = ceil(this.respawn_time - time);
1945                 if(number <= 0)
1946                         return;
1947                 if(number <= this.respawn_countdown)
1948                 {
1949                         this.respawn_countdown = number - 1;
1950                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1951                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1952                 }
1953         }
1954 }
1955
1956 .bool team_selected;
1957 bool ShowTeamSelection(entity this)
1958 {
1959         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1960                 return false;
1961         stuffcmd(this, "menu_showteamselect\n");
1962         return true;
1963 }
1964 void Join(entity this)
1965 {
1966         TRANSMUTE(Player, this);
1967
1968         if(!this.team_selected)
1969         if(autocvar_g_campaign || autocvar_g_balance_teams)
1970                 JoinBestTeam(this, false, true);
1971
1972         if(autocvar_g_campaign)
1973                 campaign_bots_may_start = true;
1974
1975         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1976
1977         PutClientInServer(this);
1978
1979         if(IS_PLAYER(this))
1980         if(teamplay && this.team != -1)
1981                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1982         else
1983                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1984         this.team_selected = false;
1985 }
1986
1987 /**
1988  * Determines whether the player is allowed to join. This depends on cvar
1989  * g_maxplayers, if it isn't used this function always return true, otherwise
1990  * it checks whether the number of currently playing players exceeds g_maxplayers.
1991  * @return int number of free slots for players, 0 if none
1992  */
1993 int nJoinAllowed(entity this, entity ignore)
1994 {
1995         if(!ignore)
1996         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1997         // so report 0 free slots if restricted
1998         {
1999                 if(autocvar_g_forced_team_otherwise == "spectate")
2000                         return 0;
2001                 if(autocvar_g_forced_team_otherwise == "spectator")
2002                         return 0;
2003         }
2004
2005         if(this && this.team_forced < 0)
2006                 return 0; // forced spectators can never join
2007
2008         // TODO simplify this
2009         int totalClients = 0;
2010         int currentlyPlaying = 0;
2011         FOREACH_CLIENT(true, LAMBDA(
2012                 if(it != ignore)
2013                         ++totalClients;
2014                 if(IS_REAL_CLIENT(it))
2015                 if(IS_PLAYER(it) || it.caplayer)
2016                         ++currentlyPlaying;
2017         ));
2018
2019         float free_slots = 0;
2020         if (!autocvar_g_maxplayers)
2021                 free_slots = maxclients - totalClients;
2022         else if(currentlyPlaying < autocvar_g_maxplayers)
2023                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2024
2025         static float join_prevent_msg_time = 0;
2026         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2027         {
2028                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2029                 join_prevent_msg_time = time + 3;
2030         }
2031
2032         return free_slots;
2033 }
2034
2035 /**
2036  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2037  * g_maxplayers_spectator_blocktime seconds
2038  */
2039 void checkSpectatorBlock(entity this)
2040 {
2041         if(IS_SPEC(this) || IS_OBSERVER(this))
2042         if(!this.caplayer)
2043         if(IS_REAL_CLIENT(this))
2044         {
2045                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2046                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2047                         dropclient(this);
2048                 }
2049         }
2050 }
2051
2052 void PrintWelcomeMessage(entity this)
2053 {
2054         if(CS(this).motd_actived_time == 0)
2055         {
2056                 if (autocvar_g_campaign) {
2057                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2058                                 CS(this).motd_actived_time = time;
2059                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2060                         }
2061                 } else {
2062                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2063                                 CS(this).motd_actived_time = time;
2064                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2065                         }
2066                 }
2067         }
2068         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2069         {
2070                 if (autocvar_g_campaign) {
2071                         if (PHYS_INPUT_BUTTON_INFO(this))
2072                                 CS(this).motd_actived_time = time;
2073                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2074                                 CS(this).motd_actived_time = 0;
2075                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2076                         }
2077                 } else {
2078                         if (PHYS_INPUT_BUTTON_INFO(this))
2079                                 CS(this).motd_actived_time = time;
2080                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2081                                 CS(this).motd_actived_time = 0;
2082                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2083                         }
2084                 }
2085         }
2086         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2087         {
2088                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2089                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2090                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2091                 {
2092                         // instanctly hide MOTD
2093                         CS(this).motd_actived_time = 0;
2094                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2095                 }
2096         }
2097 }
2098
2099 bool joinAllowed(entity this)
2100 {
2101         if (this.version_mismatch) return false;
2102         if (!nJoinAllowed(this, this)) return false;
2103         if (teamplay && lockteams) return false;
2104         if (ShowTeamSelection(this)) return false;
2105         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2106         return true;
2107 }
2108
2109 .int items_added;
2110 bool PlayerThink(entity this)
2111 {
2112         CheckRules_Player(this);
2113
2114         if (game_stopped || intermission_running) {
2115                 this.modelflags &= ~MF_ROCKET;
2116                 if(intermission_running)
2117                         IntermissionThink(this);
2118                 return false;
2119         }
2120
2121         if (timeout_status == TIMEOUT_ACTIVE) {
2122         // don't allow the player to turn around while game is paused
2123                 // FIXME turn this into CSQC stuff
2124                 this.v_angle = this.lastV_angle;
2125                 this.angles = this.lastV_angle;
2126                 this.fixangle = true;
2127         }
2128
2129         if (frametime) player_powerups(this);
2130
2131         if (IS_DEAD(this)) {
2132                 if (this.personal && g_race_qualifying) {
2133                         if (time > this.respawn_time) {
2134                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2135                                 respawn(this);
2136                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2137                         }
2138                 } else {
2139                         if (frametime) player_anim(this);
2140
2141                         if (this.respawn_flags & RESPAWN_DENY)
2142                         {
2143                                 STAT(RESPAWN_TIME, this) = 0;
2144                                 return false;
2145                         }
2146
2147                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2148
2149                         switch(this.deadflag)
2150                         {
2151                                 case DEAD_DYING:
2152                                 {
2153                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2154                                                 this.deadflag = DEAD_RESPAWNING;
2155                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2156                                                 this.deadflag = DEAD_DEAD;
2157                                         break;
2158                                 }
2159                                 case DEAD_DEAD:
2160                                 {
2161                                         if (button_pressed)
2162                                                 this.deadflag = DEAD_RESPAWNABLE;
2163                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2164                                                 this.deadflag = DEAD_RESPAWNING;
2165                                         break;
2166                                 }
2167                                 case DEAD_RESPAWNABLE:
2168                                 {
2169                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2170                                                 this.deadflag = DEAD_RESPAWNING;
2171                                         break;
2172                                 }
2173                                 case DEAD_RESPAWNING:
2174                                 {
2175                                         if (time > this.respawn_time)
2176                                         {
2177                                                 this.respawn_time = time + 1; // only retry once a second
2178                                                 this.respawn_time_max = this.respawn_time;
2179                                                 respawn(this);
2180                                         }
2181                                         break;
2182                                 }
2183                         }
2184
2185                         ShowRespawnCountdown(this);
2186
2187                         if (this.respawn_flags & RESPAWN_SILENT)
2188                                 STAT(RESPAWN_TIME, this) = 0;
2189                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2190                         {
2191                                 if (time < this.respawn_time)
2192                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2193                                 else if (this.deadflag != DEAD_RESPAWNING)
2194                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2195                         }
2196                         else
2197                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2198                 }
2199
2200                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2201                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2202                         STAT(RESPAWN_TIME, this) *= -1;
2203
2204                 return false;
2205         }
2206
2207         this.prevorigin = this.origin;
2208
2209         bool have_hook = false;
2210         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2211         {
2212                 .entity weaponentity = weaponentities[slot];
2213                 if(this.(weaponentity).hook.state)
2214                 {
2215                         have_hook = true;
2216                         break;
2217                 }
2218         }
2219         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2220         if (have_hook) {
2221                 do_crouch = false;
2222         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2223                 do_crouch = false;
2224         } else if (this.vehicle) {
2225                 do_crouch = false;
2226         } else if (STAT(FROZEN, this)) {
2227                 do_crouch = false;
2228     }
2229
2230         if (do_crouch) {
2231                 if (!this.crouch) {
2232                         this.crouch = true;
2233                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2234                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2235                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2236                 }
2237         } else if (this.crouch) {
2238         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2239         if (!trace_startsolid) {
2240             this.crouch = false;
2241             this.view_ofs = STAT(PL_VIEW_OFS, this);
2242             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2243         }
2244         }
2245
2246         FixPlayermodel(this);
2247
2248         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2249         //if(frametime)
2250         {
2251                 this.items &= ~this.items_added;
2252
2253                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2254                 {
2255                         .entity weaponentity = weaponentities[slot];
2256                         W_WeaponFrame(this, weaponentity);
2257
2258                         if(slot == 0)
2259                         {
2260                                 this.clip_load = this.(weaponentity).clip_load;
2261                                 this.clip_size = this.(weaponentity).clip_size;
2262                         }
2263                 }
2264
2265                 this.items_added = 0;
2266                 if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2267             this.items_added |= IT_FUEL;
2268
2269                 this.items |= this.items_added;
2270         }
2271
2272         player_regen(this);
2273
2274         // WEAPONTODO: Add a weapon request for this
2275         // rot vortex charge to the charge limit
2276         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2277         {
2278                 .entity weaponentity = weaponentities[slot];
2279                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2280                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2281         }
2282
2283         if (frametime) player_anim(this);
2284
2285         // secret status
2286         secrets_setstatus(this);
2287
2288         // monsters status
2289         monsters_setstatus(this);
2290
2291         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2292
2293         return true;
2294 }
2295
2296 void ObserverThink(entity this)
2297 {
2298         if ( CS(this).impulse )
2299         {
2300                 MinigameImpulse(this, CS(this).impulse);
2301                 CS(this).impulse = 0;
2302         }
2303
2304         if (this.flags & FL_JUMPRELEASED) {
2305                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2306                         this.flags &= ~FL_JUMPRELEASED;
2307                         this.flags |= FL_SPAWNING;
2308                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2309                         this.flags &= ~FL_JUMPRELEASED;
2310                         if(SpectateNext(this)) {
2311                                 TRANSMUTE(Spectator, this);
2312                         }
2313                 } else {
2314                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2315                         set_movetype(this, preferred_movetype);
2316                 }
2317         } else {
2318                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2319                         this.flags |= FL_JUMPRELEASED;
2320                         if(this.flags & FL_SPAWNING)
2321                         {
2322                                 this.flags &= ~FL_SPAWNING;
2323                                 Join(this);
2324                                 return;
2325                         }
2326                 }
2327         }
2328 }
2329
2330 void SpectatorThink(entity this)
2331 {
2332         if ( CS(this).impulse )
2333         {
2334                 if(MinigameImpulse(this, CS(this).impulse))
2335                         CS(this).impulse = 0;
2336
2337                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2338                 {
2339                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2340                         CS(this).impulse = 0;
2341                         return;
2342                 }
2343         }
2344
2345         if (this.flags & FL_JUMPRELEASED) {
2346                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2347                         this.flags &= ~FL_JUMPRELEASED;
2348                         this.flags |= FL_SPAWNING;
2349                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2350                         this.flags &= ~FL_JUMPRELEASED;
2351                         if(SpectateNext(this)) {
2352                                 TRANSMUTE(Spectator, this);
2353                         } else {
2354                                 TRANSMUTE(Observer, this);
2355                                 PutClientInServer(this);
2356                         }
2357                         CS(this).impulse = 0;
2358                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2359                         this.flags &= ~FL_JUMPRELEASED;
2360                         if(SpectatePrev(this)) {
2361                                 TRANSMUTE(Spectator, this);
2362                         } else {
2363                                 TRANSMUTE(Observer, this);
2364                                 PutClientInServer(this);
2365                         }
2366                         CS(this).impulse = 0;
2367                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2368                         this.flags &= ~FL_JUMPRELEASED;
2369                         TRANSMUTE(Observer, this);
2370                         PutClientInServer(this);
2371                 } else {
2372                         if(!SpectateUpdate(this))
2373                                 PutObserverInServer(this);
2374                 }
2375         } else {
2376                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2377                         this.flags |= FL_JUMPRELEASED;
2378                         if(this.flags & FL_SPAWNING)
2379                         {
2380                                 this.flags &= ~FL_SPAWNING;
2381                                 Join(this);
2382                                 return;
2383                         }
2384                 }
2385                 if(!SpectateUpdate(this))
2386                         PutObserverInServer(this);
2387         }
2388
2389         this.flags |= FL_CLIENT | FL_NOTARGET;
2390 }
2391
2392 void vehicles_enter (entity pl, entity veh);
2393 void PlayerUseKey(entity this)
2394 {
2395         if (!IS_PLAYER(this))
2396                 return;
2397
2398         if(this.vehicle)
2399         {
2400                 if(!game_stopped)
2401                 {
2402                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2403                         return;
2404                 }
2405         }
2406         else if(autocvar_g_vehicles_enter)
2407         {
2408                 if(!STAT(FROZEN, this))
2409                 if(!IS_DEAD(this))
2410                 if(!game_stopped)
2411                 {
2412                         entity head, closest_target = NULL;
2413                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2414
2415                         while(head) // find the closest acceptable target to enter
2416                         {
2417                                 if(IS_VEHICLE(head))
2418                                 if(!IS_DEAD(head))
2419                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2420                                 if(head.takedamage != DAMAGE_NO)
2421                                 {
2422                                         if(closest_target)
2423                                         {
2424                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2425                                                 { closest_target = head; }
2426                                         }
2427                                         else { closest_target = head; }
2428                                 }
2429
2430                                 head = head.chain;
2431                         }
2432
2433                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2434                 }
2435         }
2436
2437         // a use key was pressed; call handlers
2438         MUTATOR_CALLHOOK(PlayerUseKey, this);
2439 }
2440
2441
2442 /*
2443 =============
2444 PlayerPreThink
2445
2446 Called every frame for each client before the physics are run
2447 =============
2448 */
2449 .float last_vehiclecheck;
2450 void PlayerPreThink (entity this)
2451 {
2452         WarpZone_PlayerPhysics_FixVAngle(this);
2453
2454     STAT(GAMESTARTTIME, this) = game_starttime;
2455         STAT(ROUNDSTARTTIME, this) = round_starttime;
2456         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2457         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2458
2459         STAT(WEAPONSINMAP, this) = weaponsInMap;
2460
2461         if (frametime) {
2462                 // physics frames: update anticheat stuff
2463                 anticheat_prethink(this);
2464         }
2465
2466         if (blockSpectators && frametime) {
2467                 // WORKAROUND: only use dropclient in server frames (frametime set).
2468                 // Never use it in cl_movement frames (frametime zero).
2469                 checkSpectatorBlock(this);
2470     }
2471
2472         zoomstate_set = false;
2473
2474         // Check for nameless players
2475         if (isInvisibleString(this.netname)) {
2476                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2477                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2478         }
2479         if (this.netname != this.netname_previous) {
2480                 if (autocvar_sv_eventlog) {
2481                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2482         }
2483                 if (this.netname_previous) strunzone(this.netname_previous);
2484                 this.netname_previous = strzone(this.netname);
2485         }
2486
2487         // version nagging
2488         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2489         this.version_nagtime = 0;
2490         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2491             // git client
2492         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2493             // git server
2494             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2495         } else {
2496             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2497             if (r < 0) { // old client
2498                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2499             } else if (r > 0) { // old server
2500                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2501             }
2502         }
2503     }
2504
2505         // GOD MODE info
2506         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2507         {
2508                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2509                 this.max_armorvalue = 0;
2510         }
2511
2512         if (STAT(FROZEN, this) == 2)
2513         {
2514                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2515                 this.health = max(1, this.revive_progress * start_health);
2516                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2517
2518                 if (this.revive_progress >= 1)
2519                         Unfreeze(this);
2520         }
2521         else if (STAT(FROZEN, this) == 3)
2522         {
2523                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2524                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2525
2526                 if (this.health < 1)
2527                 {
2528                         if (this.vehicle)
2529                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2530                         if(this.event_damage)
2531                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2532                 }
2533                 else if (this.revive_progress <= 0)
2534                         Unfreeze(this);
2535         }
2536
2537         MUTATOR_CALLHOOK(PlayerPreThink, this);
2538
2539         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2540         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2541         {
2542                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2543                 {
2544                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2545                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2546                         {
2547                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2548                         }
2549                         else if(!it.owner)
2550                         {
2551                                 if(!it.team || SAME_TEAM(this, it))
2552                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2553                                 else if(autocvar_g_vehicles_steal)
2554                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2555                         }
2556                 });
2557
2558                 this.last_vehiclecheck = time + 1;
2559         }
2560
2561         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2562         {
2563                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2564                         PlayerUseKey(this);
2565                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2566         }
2567
2568         if (IS_REAL_CLIENT(this))
2569                 PrintWelcomeMessage(this);
2570
2571         if (IS_PLAYER(this)) {
2572                 if(!PlayerThink(this))
2573                         return;
2574         }
2575         else if (game_stopped || intermission_running) {
2576                 if(intermission_running)
2577                         IntermissionThink(this);
2578                 return;
2579         }
2580         else if (IS_OBSERVER(this)) {
2581                 ObserverThink(this);
2582         }
2583         else if (IS_SPEC(this)) {
2584                 SpectatorThink(this);
2585         }
2586
2587         // WEAPONTODO: Add weapon request for this
2588         if (!zoomstate_set) {
2589                 bool wep_zoomed = false;
2590                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2591                 {
2592                         .entity weaponentity = weaponentities[slot];
2593                         Weapon thiswep = this.(weaponentity).m_weapon;
2594                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2595                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2596                 }
2597                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2598     }
2599
2600         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2601         {
2602                 CS(this).teamkill_soundtime = 0;
2603
2604                 entity e = CS(this).teamkill_soundsource;
2605                 entity oldpusher = e.pusher;
2606                 e.pusher = this;
2607                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2608                 e.pusher = oldpusher;
2609         }
2610
2611         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2612                 this.taunt_soundtime = 0;
2613                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2614         }
2615
2616         target_voicescript_next(this);
2617
2618         // WEAPONTODO: Move into weaponsystem somehow
2619         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2620         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2621         {
2622                 .entity weaponentity = weaponentities[slot];
2623                 if(this.(weaponentity).m_weapon == WEP_Null)
2624                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2625         }
2626 }
2627
2628 void DrownPlayer(entity this)
2629 {
2630         if(IS_DEAD(this))
2631                 return;
2632
2633         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2634         {
2635                 if(this.air_finished < time)
2636                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2637                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2638                 this.dmg = 2;
2639         }
2640         else if (this.air_finished < time)
2641         {       // drown!
2642                 if (this.pain_finished < time)
2643                 {
2644                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2645                         this.pain_finished = time + 0.5;
2646                 }
2647         }
2648 }
2649
2650 .bool move_qcphysics;
2651
2652 void Player_Physics(entity this)
2653 {
2654         set_movetype(this, this.move_movetype);
2655
2656         if(!this.move_qcphysics)
2657                 return;
2658
2659         if(!frametime && !CS(this).pm_frametime)
2660                 return;
2661
2662         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2663
2664         CS(this).pm_frametime = 0;
2665 }
2666
2667 /*
2668 =============
2669 PlayerPostThink
2670
2671 Called every frame for each client after the physics are run
2672 =============
2673 */
2674 void PlayerPostThink (entity this)
2675 {
2676         Player_Physics(this);
2677
2678         if (sv_maxidle > 0)
2679         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2680         if (IS_REAL_CLIENT(this))
2681         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2682         {
2683                 int totalClients = 0;
2684                 if(sv_maxidle_slots > 0)
2685                 {
2686                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2687                         {
2688                                 ++totalClients;
2689                         });
2690                 }
2691
2692                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2693                 { /* do nothing */ }
2694                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2695                 {
2696                         if (CS(this).idlekick_lasttimeleft)
2697                         {
2698                                 CS(this).idlekick_lasttimeleft = 0;
2699                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2700                         }
2701                 }
2702                 else
2703                 {
2704                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2705                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2706                                 if (!CS(this).idlekick_lasttimeleft)
2707                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2708                         }
2709                         if (timeleft <= 0) {
2710                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2711                                 dropclient(this);
2712                                 return;
2713                         }
2714                         else if (timeleft <= 10) {
2715                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2716                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2717                 }
2718                                 CS(this).idlekick_lasttimeleft = timeleft;
2719                         }
2720                 }
2721         }
2722
2723         CheatFrame(this);
2724
2725         //CheckPlayerJump();
2726         if (game_stopped)
2727         {
2728                 this.solid = SOLID_NOT;
2729                 this.takedamage = DAMAGE_NO;
2730                 set_movetype(this, MOVETYPE_NONE);
2731         }
2732
2733         if (IS_PLAYER(this)) {
2734                 DrownPlayer(this);
2735                 CheckRules_Player(this);
2736                 UpdateChatBubble(this);
2737                 if (CS(this).impulse) ImpulseCommands(this);
2738                 if (game_stopped)
2739                 {
2740                         CSQCMODEL_AUTOUPDATE(this);
2741                         return;
2742                 }
2743                 GetPressedKeys(this);
2744         }
2745
2746         if (this.waypointsprite_attachedforcarrier) {
2747             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2748                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2749     }
2750
2751         playerdemo_write(this);
2752
2753         CSQCMODEL_AUTOUPDATE(this);
2754 }
2755
2756 // hack to copy the button fields from the client entity to the Client State
2757 void PM_UpdateButtons(entity this, entity store)
2758 {
2759         if(this.impulse)
2760                 store.impulse = this.impulse;
2761         this.impulse = 0;
2762
2763         store.button0 = this.button0;
2764         store.button2 = this.button2;
2765         store.button3 = this.button3;
2766         store.button4 = this.button4;
2767         store.button5 = this.button5;
2768         store.button6 = this.button6;
2769         store.button7 = this.button7;
2770         store.button8 = this.button8;
2771         store.button9 = this.button9;
2772         store.button10 = this.button10;
2773         store.button11 = this.button11;
2774         store.button12 = this.button12;
2775         store.button13 = this.button13;
2776         store.button14 = this.button14;
2777         store.button15 = this.button15;
2778         store.button16 = this.button16;
2779         store.buttonuse = this.buttonuse;
2780         store.buttonchat = this.buttonchat;
2781
2782         store.cursor_active = this.cursor_active;
2783         store.cursor_screen = this.cursor_screen;
2784         store.cursor_trace_start = this.cursor_trace_start;
2785         store.cursor_trace_endpos = this.cursor_trace_endpos;
2786         store.cursor_trace_ent = this.cursor_trace_ent;
2787
2788         store.ping = this.ping;
2789         store.ping_packetloss = this.ping_packetloss;
2790         store.ping_movementloss = this.ping_movementloss;
2791
2792         store.v_angle = this.v_angle;
2793         store.movement = this.movement;
2794 }