qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/state.qh>
  34 #include <common/stats.qh>
  35 #include <common/vehicles/all.qh>
  36 #include <common/vehicles/sv_vehicles.qh>
  37 #include <common/viewloc.qh>
  38 #include <common/weapons/_all.qh>
  39 #include <common/weapons/weapon/vortex.qh>
  40 #include <common/wepent.qh>
  41 #include <lib/csqcmodel/sv_model.qh>
  42 #include <lib/warpzone/common.qh>
  43 #include <lib/warpzone/server.qh>
  44 #include <server/anticheat.qh>
  45 #include <server/antilag.qh>
  46 #include <server/bot/api.qh>
  47 #include <server/bot/default/cvars.qh>
  48 #include <server/campaign.qh>
  49 #include <server/chat.qh>
  50 #include <server/cheats.qh>
  51 #include <server/clientkill.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/vote.qh>
  55 #include <server/compat/quake3.qh>
  56 #include <server/damage.qh>
  57 #include <server/gamelog.qh>
  58 #include <server/handicap.qh>
  59 #include <server/hook.qh>
  60 #include <server/impulse.qh>
  61 #include <server/intermission.qh>
  62 #include <server/ipban.qh>
  63 #include <server/main.qh>
  64 #include <server/mutators/_mod.qh>
  65 #include <server/player.qh>
  66 #include <server/portals.qh>
  67 #include <server/race.qh>
  68 #include <server/resources.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         PlayerState_detach(this);
 242
 243         if (IS_PLAYER(this))
 244         {
 245                 if(GetResource(this, RES_HEALTH) >= 1)
 246                 {
 247                         // despawn effect
 248                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 249                 }
 250
 251                 // was a player, recount votes and ready status
 252                 if(IS_REAL_CLIENT(this))
 253                 {
 254                         if (vote_called) { VoteCount(false); }
 255                         ReadyCount();
 256                 }
 257                 entcs_update_players(this);
 258         }
 259
 260         entity spot = SelectSpawnPoint(this, true);
 261         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 262         this.angles = vec2(spot.angles);
 263         this.fixangle = true;
 264         // offset it so that the spectator spawns higher off the ground, looks better this way
 265         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 266         if (IS_REAL_CLIENT(this))
 267         {
 268                 msg_entity = this;
 269                 WriteByte(MSG_ONE, SVC_SETVIEW);
 270                 WriteEntity(MSG_ONE, this);
 271         }
 272         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 273         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 274         if(!autocvar_g_debug_globalsounds)
 275         {
 276                 // needed for player sounds
 277                 this.model = "";
 278                 FixPlayermodel(this);
 279         }
 280         setmodel(this, MDL_Null);
 281         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 282         this.view_ofs = '0 0 0';
 283
 284         RemoveGrapplingHooks(this);
 285         Portal_ClearAll(this);
 286         Unfreeze(this, false);
 287         SetSpectatee(this, NULL);
 288
 289         if (this.alivetime)
 290         {
 291                 if (!warmup_stage)
 292                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 293                 this.alivetime = 0;
 294         }
 295
 296         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 297
 298         WaypointSprite_PlayerDead(this);
 299
 300         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 301                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 302
 303         accuracy_resend(this);
 304
 305         CS(this).spectatortime = time;
 306         if(this.bot_attack)
 307                 IL_REMOVE(g_bot_targets, this);
 308         this.bot_attack = false;
 309         if(this.monster_attack)
 310                 IL_REMOVE(g_monster_targets, this);
 311         this.monster_attack = false;
 312         STAT(HUD, this) = HUD_NORMAL;
 313         TRANSMUTE(Observer, this);
 314         this.iscreature = false;
 315         this.teleportable = TELEPORT_SIMPLE;
 316         if(this.damagedbycontents)
 317                 IL_REMOVE(g_damagedbycontents, this);
 318         this.damagedbycontents = false;
 319         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 320         SetSpectatee_status(this, etof(this));
 321         this.takedamage = DAMAGE_NO;
 322         this.solid = SOLID_NOT;
 323         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 324         this.flags = FL_CLIENT | FL_NOTARGET;
 325         this.effects = 0;
 326         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 327         this.pauserotarmor_finished = 0;
 328         this.pauserothealth_finished = 0;
 329         this.pauseregen_finished = 0;
 330         this.damageforcescale = 0;
 331         this.death_time = 0;
 332         this.respawn_flags = 0;
 333         this.respawn_time = 0;
 334         STAT(RESPAWN_TIME, this) = 0;
 335         this.alpha = 0;
 336         this.scale = 0;
 337         this.fade_time = 0;
 338         this.pain_finished = 0;
 339         STAT(AIR_FINISHED, this) = 0;
 340         //this.dphitcontentsmask = 0;
 341         this.dphitcontentsmask = DPCONTENTS_SOLID;
 342         if (autocvar_g_playerclip_collisions)
 343                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 344         this.pushltime = 0;
 345         this.istypefrag = 0;
 346         setthink(this, func_null);
 347         this.nextthink = 0;
 348         this.deadflag = DEAD_NO;
 349         UNSET_DUCKED(this);
 350         STAT(REVIVE_PROGRESS, this) = 0;
 351         this.revival_time = 0;
 352         this.draggable = drag_undraggable;
 353
 354         this.items = 0;
 355         STAT(WEAPONS, this) = '0 0 0';
 356         this.drawonlytoclient = this;
 357
 358         this.viewloc = NULL;
 359
 360         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 361
 362         this.weaponmodel = "";
 363         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 364         {
 365                 this.weaponentities[slot] = NULL;
 366         }
 367         this.exteriorweaponentity = NULL;
 368         CS(this).killcount = FRAGS_SPECTATOR;
 369         this.velocity = '0 0 0';
 370         this.avelocity = '0 0 0';
 371         this.punchangle = '0 0 0';
 372         this.punchvector = '0 0 0';
 373         this.oldvelocity = this.velocity;
 374         this.event_damage = func_null;
 375         this.event_heal = func_null;
 376
 377         for(int slot = 0; slot < MAX_AXH; ++slot)
 378         {
 379                 entity axh = this.(AuxiliaryXhair[slot]);
 380                 this.(AuxiliaryXhair[slot]) = NULL;
 381
 382                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 383                         delete(axh);
 384         }
 385
 386         if (mutator_returnvalue)
 387         {
 388                 // mutator prevents resetting teams+score
 389         }
 390         else
 391         {
 392                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 393                 this.frags = FRAGS_SPECTATOR;
 394         }
 395
 396         bot_relinkplayerlist();
 397
 398         if (CS(this).just_joined)
 399                 CS(this).just_joined = false;
 400 }
 401
 402 int player_getspecies(entity this)
 403 {
 404         get_model_parameters(this.model, this.skin);
 405         int s = get_model_parameters_species;
 406         get_model_parameters(string_null, 0);
 407         if (s < 0) return SPECIES_HUMAN;
 408         return s;
 409 }
 410
 411 .float model_randomizer;
 412 void FixPlayermodel(entity player)
 413 {
 414         string defaultmodel = "";
 415         int defaultskin = 0;
 416         if(autocvar_sv_defaultcharacter)
 417         {
 418                 if(teamplay)
 419                 {
 420                         switch(player.team)
 421                         {
 422                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 423                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 424                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 425                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 426                         }
 427                 }
 428
 429                 if(defaultmodel == "")
 430                 {
 431                         defaultmodel = autocvar_sv_defaultplayermodel;
 432                         defaultskin = autocvar_sv_defaultplayerskin;
 433                 }
 434
 435                 int n = tokenize_console(defaultmodel);
 436                 if(n > 0)
 437                 {
 438                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 439                         // However, do NOT randomize if the player-selected model is in the list.
 440                         for (int i = 0; i < n; ++i)
 441                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 442                                         defaultmodel = argv(i);
 443                 }
 444
 445                 int i = strstrofs(defaultmodel, ":", 0);
 446                 if(i >= 0)
 447                 {
 448                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 449                         defaultmodel = substring(defaultmodel, 0, i);
 450                 }
 451         }
 452         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 453         {
 454                 if(teamplay)
 455                 {
 456                         switch(player.team)
 457                         {
 458                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 459                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 460                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 461                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 462                         }
 463                 }
 464
 465                 if(!defaultskin)
 466                         defaultskin = autocvar_sv_defaultplayerskin;
 467         }
 468
 469         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 470         defaultmodel = M_ARGV(0, string);
 471         defaultskin = M_ARGV(1, int);
 472
 473         bool chmdl = false;
 474         int oldskin;
 475         if(defaultmodel != "")
 476         {
 477                 if (defaultmodel != player.model)
 478                 {
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, defaultmodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 oldskin = player.skin;
 487                 player.skin = defaultskin;
 488         } else {
 489                 if (player.playermodel != player.model || player.playermodel == "")
 490                 {
 491                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, player.playermodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 if(!autocvar_sv_defaultcharacterskin)
 500                 {
 501                         oldskin = player.skin;
 502                         player.skin = stof(player.playerskin);
 503                 }
 504                 else
 505                 {
 506                         oldskin = player.skin;
 507                         player.skin = defaultskin;
 508                 }
 509         }
 510
 511         if(chmdl || oldskin != player.skin) // model or skin has changed
 512         {
 513                 player.species = player_getspecies(player); // update species
 514                 if(!autocvar_g_debug_globalsounds)
 515                         UpdatePlayerSounds(player); // update skin sounds
 516         }
 517
 518         if(!teamplay)
 519                 if(strlen(autocvar_sv_defaultplayercolors))
 520                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 521                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 522 }
 523
 524 void PutPlayerInServer(entity this)
 525 {
 526         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 527
 528         PlayerState_attach(this);
 529         accuracy_resend(this);
 530
 531         if (this.team < 0)
 532                 TeamBalance_JoinBestTeam(this);
 533
 534         entity spot = SelectSpawnPoint(this, false);
 535         if (!spot) {
 536                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 537                 return; // spawn failed
 538         }
 539
 540         TRANSMUTE(Player, this);
 541
 542         CS(this).wasplayer = true;
 543         this.iscreature = true;
 544         this.teleportable = TELEPORT_NORMAL;
 545         if(!this.damagedbycontents)
 546                 IL_PUSH(g_damagedbycontents, this);
 547         this.damagedbycontents = true;
 548         set_movetype(this, MOVETYPE_WALK);
 549         this.solid = SOLID_SLIDEBOX;
 550         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 551         if (autocvar_g_playerclip_collisions)
 552                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 553         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 554                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 555         this.frags = FRAGS_PLAYER;
 556         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 557         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 558         if (autocvar__notarget)
 559                 this.flags |= FL_NOTARGET;
 560         this.takedamage = DAMAGE_AIM;
 561         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 562
 563         if (warmup_stage) {
 564                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 565                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 566                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 567                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 568                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 569                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 570                 SetResource(this, RES_HEALTH, warmup_start_health);
 571                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 572                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 573         } else {
 574                 SetResource(this, RES_SHELLS, start_ammo_shells);
 575                 SetResource(this, RES_BULLETS, start_ammo_nails);
 576                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 577                 SetResource(this, RES_CELLS, start_ammo_cells);
 578                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 579                 SetResource(this, RES_FUEL, start_ammo_fuel);
 580                 SetResource(this, RES_HEALTH, start_health);
 581                 SetResource(this, RES_ARMOR, start_armorvalue);
 582                 STAT(WEAPONS, this) = start_weapons;
 583                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 584                 {
 585                         GiveRandomWeapons(this, random_start_weapons_count,
 586                                 autocvar_g_random_start_weapons, random_start_ammo);
 587                 }
 588         }
 589         SetSpectatee_status(this, 0);
 590
 591         PS(this).dual_weapons = '0 0 0';
 592
 593         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 594                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 595
 596         this.items = start_items;
 597
 598         float shieldtime = time + autocvar_g_spawnshieldtime;
 599
 600         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 601         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 602         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 603         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 604         if (!sv_ready_restart_after_countdown && time < game_starttime)
 605         {
 606                 float f = game_starttime - time;
 607                 shieldtime += f;
 608                 this.pauserotarmor_finished += f;
 609                 this.pauserothealth_finished += f;
 610                 this.pauseregen_finished += f;
 611         }
 612
 613         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 614
 615         this.damageforcescale = autocvar_g_player_damageforcescale;
 616         this.death_time = 0;
 617         this.respawn_flags = 0;
 618         this.respawn_time = 0;
 619         STAT(RESPAWN_TIME, this) = 0;
 620         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 621         this.fade_time = 0;
 622         this.pain_finished = 0;
 623         this.pushltime = 0;
 624         setthink(this, func_null); // players have no think function
 625         this.nextthink = 0;
 626         this.dmg_team = 0;
 627         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 628
 629         this.deadflag = DEAD_NO;
 630
 631         this.angles = spot.angles;
 632         this.angles_z = 0; // never spawn tilted even if the spot says to
 633         if (IS_BOT_CLIENT(this))
 634         {
 635                 this.v_angle = this.angles;
 636                 bot_aim_reset(this);
 637         }
 638         this.fixangle = true; // turn this way immediately
 639         this.oldvelocity = this.velocity = '0 0 0';
 640         this.avelocity = '0 0 0';
 641         this.punchangle = '0 0 0';
 642         this.punchvector = '0 0 0';
 643
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         STAT(AIR_FINISHED, this) = 0;
 648         this.waterlevel = WATERLEVEL_NONE;
 649         this.watertype = CONTENT_EMPTY;
 650
 651         entity spawnevent = new_pure(spawnevent);
 652         spawnevent.owner = this;
 653         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 654
 655         // Cut off any still running player sounds.
 656         stopsound(this, CH_PLAYER_SINGLE);
 657
 658         this.model = "";
 659         FixPlayermodel(this);
 660         this.drawonlytoclient = NULL;
 661
 662         this.viewloc = NULL;
 663
 664         for(int slot = 0; slot < MAX_AXH; ++slot)
 665         {
 666                 entity axh = this.(AuxiliaryXhair[slot]);
 667                 this.(AuxiliaryXhair[slot]) = NULL;
 668
 669                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 670                         delete(axh);
 671         }
 672
 673         this.spawnpoint_targ = NULL;
 674
 675         UNSET_DUCKED(this);
 676         this.view_ofs = STAT(PL_VIEW_OFS, this);
 677         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 678         this.spawnorigin = spot.origin;
 679         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 680         // don't reset back to last position, even if new position is stuck in solid
 681         this.oldorigin = this.origin;
 682         if(this.conveyor)
 683                 IL_REMOVE(g_conveyed, this);
 684         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 685         if(this.swampslug)
 686                 IL_REMOVE(g_swamped, this);
 687         this.swampslug = NULL;
 688         this.swamp_interval = 0;
 689         if(this.ladder_entity)
 690                 IL_REMOVE(g_ladderents, this);
 691         this.ladder_entity = NULL;
 692         IL_EACH(g_counters, it.realowner == this,
 693         {
 694                 delete(it);
 695         });
 696         STAT(HUD, this) = HUD_NORMAL;
 697
 698         this.event_damage = PlayerDamage;
 699         this.event_heal = PlayerHeal;
 700
 701         this.draggable = func_null;
 702
 703         if(!this.bot_attack)
 704                 IL_PUSH(g_bot_targets, this);
 705         this.bot_attack = true;
 706         if(!this.monster_attack)
 707                 IL_PUSH(g_monster_targets, this);
 708         this.monster_attack = true;
 709         navigation_dynamicgoal_init(this, false);
 710
 711         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 712
 713         // player was spectator
 714         if (CS(this).killcount == FRAGS_SPECTATOR) {
 715                 PlayerScore_Clear(this);
 716                 CS(this).killcount = 0;
 717                 CS(this).startplaytime = time;
 718         }
 719
 720         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 721         {
 722                 .entity weaponentity = weaponentities[slot];
 723                 CL_SpawnWeaponentity(this, weaponentity);
 724         }
 725         this.alpha = default_player_alpha;
 726         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 727         this.exteriorweaponentity.alpha = default_weapon_alpha;
 728
 729         this.speedrunning = false;
 730
 731         this.counter_cnt = 0;
 732         this.fragsfilter_cnt = 0;
 733
 734         target_voicescript_clear(this);
 735
 736         // reset fields the weapons may use
 737         FOREACH(Weapons, true, {
 738                 it.wr_resetplayer(it, this);
 739                         // reload all reloadable weapons
 740                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 741                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 742                         {
 743                                 .entity weaponentity = weaponentities[slot];
 744                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 745                         }
 746                 }
 747         });
 748
 749         Unfreeze(this, false);
 750
 751         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 752
 753         {
 754                 string s = spot.target;
 755                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 756                         spot.target = string_null;
 757                 SUB_UseTargets(spot, this, NULL);
 758                 if(g_assault || g_race)
 759                         spot.target = s;
 760         }
 761
 762         if (autocvar_spawn_debug)
 763         {
 764                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 765                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 766         }
 767
 768         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 769         {
 770                 .entity weaponentity = weaponentities[slot];
 771                 entity w_ent = this.(weaponentity);
 772                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 773                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 774                 else
 775                         w_ent.m_switchweapon = WEP_Null;
 776                 w_ent.m_weapon = WEP_Null;
 777                 w_ent.weaponname = "";
 778                 w_ent.m_switchingweapon = WEP_Null;
 779                 w_ent.cnt = -1;
 780         }
 781
 782         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 783
 784         if (CS(this).impulse) ImpulseCommands(this);
 785
 786         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 787         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 788         {
 789                 .entity weaponentity = weaponentities[slot];
 790                 W_WeaponFrame(this, weaponentity);
 791         }
 792
 793         if (!warmup_stage && !this.alivetime)
 794                 this.alivetime = time;
 795
 796         antilag_clear(this, CS(this));
 797 }
 798
 799 /** Called when a client spawns in the server */
 800 void PutClientInServer(entity this)
 801 {
 802         if (IS_BOT_CLIENT(this)) {
 803                 TRANSMUTE(Player, this);
 804         } else if (IS_REAL_CLIENT(this)) {
 805                 msg_entity = this;
 806                 WriteByte(MSG_ONE, SVC_SETVIEW);
 807                 WriteEntity(MSG_ONE, this);
 808         }
 809         if (game_stopped)
 810                 TRANSMUTE(Observer, this);
 811
 812         SetSpectatee(this, NULL);
 813
 814         // reset player keys
 815         if(PS(this))
 816                 PS(this).itemkeys = 0;
 817
 818         MUTATOR_CALLHOOK(PutClientInServer, this);
 819
 820         if (IS_OBSERVER(this)) {
 821                 PutObserverInServer(this, false);
 822         } else if (IS_PLAYER(this)) {
 823                 PutPlayerInServer(this);
 824         }
 825
 826         bot_relinkplayerlist();
 827 }
 828
 829 // TODO do we need all these fields, or should we stop autodetecting runtime
 830 // changes and just have a console command to update this?
 831 bool ClientInit_SendEntity(entity this, entity to, int sf)
 832 {
 833         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 834         return = true;
 835         msg_entity = to;
 836         // MSG_INIT replacement
 837         // TODO: make easier to use
 838         Registry_send_all();
 839         W_PROP_reload(MSG_ONE, to);
 840         ClientInit_misc(this);
 841         MUTATOR_CALLHOOK(Ent_Init);
 842 }
 843 void ClientInit_misc(entity this)
 844 {
 845         int channel = MSG_ONE;
 846         WriteHeader(channel, ENT_CLIENT_INIT);
 847         WriteByte(channel, g_nexball_meter_period * 32);
 848         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 852         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 856
 857         if(autocvar_sv_foginterval && world.fog != "")
 858                 WriteString(channel, world.fog);
 859         else
 860                 WriteString(channel, "");
 861         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 862         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 863         WriteByte(channel, serverflags);
 864         WriteCoord(channel, autocvar_g_trueaim_minrange);
 865 }
 866
 867 void ClientInit_CheckUpdate(entity this)
 868 {
 869         this.nextthink = time;
 870         if(this.count != autocvar_g_balance_armor_blockpercent)
 871         {
 872                 this.count = autocvar_g_balance_armor_blockpercent;
 873                 this.SendFlags |= 1;
 874         }
 875         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 876         {
 877                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 878                 this.SendFlags |= 1;
 879         }
 880 }
 881
 882 void ClientInit_Spawn()
 883 {
 884         entity e = new_pure(clientinit);
 885         setthink(e, ClientInit_CheckUpdate);
 886         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 887
 888         ClientInit_CheckUpdate(e);
 889 }
 890
 891 /*
 892 =============
 893 SetNewParms
 894 =============
 895 */
 896 void SetNewParms ()
 897 {
 898         // initialize parms for a new player
 899         parm1 = -(86400 * 366);
 900
 901         MUTATOR_CALLHOOK(SetNewParms);
 902 }
 903
 904 /*
 905 =============
 906 SetChangeParms
 907 =============
 908 */
 909 void SetChangeParms (entity this)
 910 {
 911         // save parms for level change
 912         parm1 = CS(this).parm_idlesince - time;
 913
 914         MUTATOR_CALLHOOK(SetChangeParms);
 915 }
 916
 917 /*
 918 =============
 919 DecodeLevelParms
 920 =============
 921 */
 922 void DecodeLevelParms(entity this)
 923 {
 924         // load parms
 925         CS(this).parm_idlesince = parm1;
 926         if (CS(this).parm_idlesince == -(86400 * 366))
 927                 CS(this).parm_idlesince = time;
 928
 929         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 930         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 931
 932         MUTATOR_CALLHOOK(DecodeLevelParms);
 933 }
 934
 935 void FixClientCvars(entity e)
 936 {
 937         // send prediction settings to the client
 938         stuffcmd(e, "\nin_bindmap 0 0\n");
 939         if(autocvar_g_antilag == 3) // client side hitscan
 940                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 941         if(autocvar_sv_gentle)
 942                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 943
 944         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 945         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 946
 947         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 948
 949         MUTATOR_CALLHOOK(FixClientCvars, e);
 950 }
 951
 952 bool findinlist_abbrev(string tofind, string list)
 953 {
 954         if(list == "" || tofind == "")
 955                 return false; // empty list or search, just return
 956
 957         // this function allows abbreviated strings!
 958         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 959         {
 960                 return true;
 961         });
 962
 963         return false;
 964 }
 965
 966 bool PlayerInIPList(entity p, string iplist)
 967 {
 968         // some safety checks (never allow local?)
 969         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 970                 return false;
 971
 972         return findinlist_abbrev(p.netaddress, iplist);
 973 }
 974
 975 bool PlayerInIDList(entity p, string idlist)
 976 {
 977         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 978         if(!p.crypto_idfp)
 979                 return false;
 980
 981         return findinlist_abbrev(p.crypto_idfp, idlist);
 982 }
 983
 984 bool PlayerInList(entity player, string list)
 985 {
 986         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 987 }
 988
 989 #ifdef DP_EXT_PRECONNECT
 990 /*
 991 =============
 992 ClientPreConnect
 993
 994 Called once (not at each match start) when a client begins a connection to the server
 995 =============
 996 */
 997 void ClientPreConnect(entity this)
 998 {
 999         if(autocvar_sv_eventlog)
1000         {
1001                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1002                         this.playerid,
1003                         etof(this),
1004                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1005                 ));
1006         }
1007 }
1008 #endif
1009
1010 string GetClientVersionMessage(entity this)
1011 {
1012         if (CS(this).version_mismatch) {
1013                 if(CS(this).version < autocvar_gameversion) {
1014                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1015                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1016                 } else {
1017                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1018                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1019                 }
1020         } else {
1021                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1022         }
1023 }
1024
1025 string getwelcomemessage(entity this)
1026 {
1027         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1028         string modifications = M_ARGV(0, string);
1029
1030         if(g_weaponarena)
1031         {
1032                 if(g_weaponarena_random)
1033                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1034                 else
1035                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1036         }
1037         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1038                 modifications = strcat(modifications, ", No start weapons");
1039         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1040                 modifications = strcat(modifications, ", Low gravity");
1041         if(g_weapon_stay && !g_cts)
1042                 modifications = strcat(modifications, ", Weapons stay");
1043         if(autocvar_g_jetpack)
1044                 modifications = strcat(modifications, ", Jet pack");
1045         modifications = substring(modifications, 2, strlen(modifications) - 2);
1046
1047         string versionmessage = GetClientVersionMessage(this);
1048         string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1049
1050         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1051
1052         if(modifications != "")
1053                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1054
1055         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1056         {
1057                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1058                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1059         }
1060
1061         if (cache_mutatormsg != "") {
1062                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1063         }
1064
1065         string mutator_msg = "";
1066         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1067         mutator_msg = M_ARGV(0, string);
1068
1069         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1070
1071         string motd = autocvar_sv_motd;
1072         if (motd != "") {
1073                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1074         }
1075         return s;
1076 }
1077
1078 /**
1079 =============
1080 ClientConnect
1081
1082 Called when a client connects to the server
1083 =============
1084 */
1085 void ClientConnect(entity this)
1086 {
1087         if (Ban_MaybeEnforceBanOnce(this)) return;
1088         assert(!IS_CLIENT(this), return);
1089         this.flags |= FL_CLIENT;
1090         assert(player_count >= 0, player_count = 0);
1091
1092         TRANSMUTE(Client, this);
1093         CS(this).version_nagtime = time + 10 + random() * 10;
1094
1095         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1096
1097         bot_clientconnect(this);
1098
1099         Player_DetermineForcedTeam(this);
1100
1101         TRANSMUTE(Observer, this);
1102
1103         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1104
1105         // always track bots, don't ask for cl_allow_uidtracking
1106         if (IS_BOT_CLIENT(this))
1107                 PlayerStats_GameReport_AddPlayer(this);
1108         else
1109                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1110
1111         if (autocvar_sv_eventlog)
1112                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1113
1114         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1115
1116         stuffcmd(this, clientstuff, "\n");
1117         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1118
1119         FixClientCvars(this);
1120
1121         // get version info from player
1122         stuffcmd(this, "cmd clientversion $gameversion\n");
1123
1124         // notify about available teams
1125         if (teamplay)
1126         {
1127                 entity balance = TeamBalance_CheckAllowedTeams(this);
1128                 int t = TeamBalance_GetAllowedTeams(balance);
1129                 TeamBalance_Destroy(balance);
1130                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1131         }
1132         else
1133         {
1134                 stuffcmd(this, "set _teams_available 0\n");
1135         }
1136
1137         bot_relinkplayerlist();
1138
1139         CS(this).spectatortime = time;
1140         if (blockSpectators)
1141         {
1142                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1143         }
1144
1145         CS(this).jointime = time;
1146
1147         if (IS_REAL_CLIENT(this))
1148         {
1149                 if (g_weaponarena_weapons == WEPSET(TUBA))
1150                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1151         }
1152
1153         if (!autocvar_sv_foginterval && world.fog != "")
1154                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1155
1156         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1157                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1158                         send_CSQC_teamnagger();
1159
1160         CSQCMODEL_AUTOINIT(this);
1161
1162         CS(this).model_randomizer = random();
1163
1164         if (IS_REAL_CLIENT(this))
1165                 sv_notice_join(this);
1166
1167         this.move_qcphysics = autocvar_sv_qcphysics;
1168
1169         // update physics stats (players can spawn before physics runs)
1170         Physics_UpdateStats(this);
1171
1172         IL_EACH(g_initforplayer, it.init_for_player, {
1173                 it.init_for_player(it, this);
1174         });
1175
1176         Handicap_Initialize(this);
1177
1178         MUTATOR_CALLHOOK(ClientConnect, this);
1179
1180         if (IS_REAL_CLIENT(this))
1181         {
1182                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1183                 {
1184                         CS(this).motd_actived_time = -1;
1185                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1186                 }
1187         }
1188 }
1189 /*
1190 =============
1191 ClientDisconnect
1192
1193 Called when a client disconnects from the server
1194 =============
1195 */
1196 .entity chatbubbleentity;
1197 void player_powerups_remove_all(entity this);
1198
1199 void ClientDisconnect(entity this)
1200 {
1201         assert(IS_CLIENT(this), return);
1202
1203         PlayerStats_GameReport_FinalizePlayer(this);
1204         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1205         if (CS(this).active_minigame) part_minigame(this);
1206         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1207
1208         if (autocvar_sv_eventlog)
1209                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1210
1211         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1212
1213         if(IS_SPEC(this))
1214                 SetSpectatee(this, NULL);
1215
1216         MUTATOR_CALLHOOK(ClientDisconnect, this);
1217
1218         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1219         strfree(CS_CVAR(this).weaponorder_byimpulse);
1220         ClientState_detach(this);
1221
1222         Portal_ClearAll(this);
1223
1224         Unfreeze(this, false);
1225
1226         RemoveGrapplingHooks(this);
1227
1228         // Here, everything has been done that requires this player to be a client.
1229
1230         this.flags &= ~FL_CLIENT;
1231
1232         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1233         if (this.killindicator) delete(this.killindicator);
1234
1235         IL_EACH(g_counters, it.realowner == this,
1236         {
1237                 delete(it);
1238         });
1239
1240         WaypointSprite_PlayerGone(this);
1241
1242         bot_relinkplayerlist();
1243
1244         strfree(this.clientstatus);
1245         if (this.personal) delete(this.personal);
1246
1247         this.playerid = 0;
1248         ReadyCount();
1249         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1250
1251         player_powerups_remove_all(this); // stop powerup sound
1252
1253         ONREMOVE(this);
1254 }
1255
1256 void ChatBubbleThink(entity this)
1257 {
1258         this.nextthink = time;
1259         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1260         {
1261                 if(this.owner) // but why can that ever be NULL?
1262                         this.owner.chatbubbleentity = NULL;
1263                 delete(this);
1264                 return;
1265         }
1266
1267         this.mdl = "";
1268
1269         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1270         {
1271                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1272                         this.mdl = "models/sprites/minigame_busy.iqm";
1273                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1274                         this.mdl = "models/misc/chatbubble.spr";
1275         }
1276
1277         if ( this.model != this.mdl )
1278                 _setmodel(this, this.mdl);
1279
1280 }
1281
1282 void UpdateChatBubble(entity this)
1283 {
1284         if (this.alpha < 0)
1285                 return;
1286         // spawn a chatbubble entity if needed
1287         if (!this.chatbubbleentity)
1288         {
1289                 this.chatbubbleentity = new(chatbubbleentity);
1290                 this.chatbubbleentity.owner = this;
1291                 this.chatbubbleentity.exteriormodeltoclient = this;
1292                 setthink(this.chatbubbleentity, ChatBubbleThink);
1293                 this.chatbubbleentity.nextthink = time;
1294                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1295                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1296                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1297                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1298                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1299                 //this.chatbubbleentity.model = "";
1300                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1301         }
1302 }
1303
1304 void calculate_player_respawn_time(entity this)
1305 {
1306         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1307                 return;
1308
1309         float gametype_setting_tmp;
1310         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1311         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1312         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1313         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1314         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1315         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1316
1317         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1318         if (teamplay)
1319         {
1320                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1321                         if(it.team == this.team)
1322                                 ++pcount;
1323                 });
1324                 if (sdelay_small_count == 0)
1325                         sdelay_small_count = 1;
1326                 if (sdelay_large_count == 0)
1327                         sdelay_large_count = 1;
1328         }
1329         else
1330         {
1331                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1332                         ++pcount;
1333                 });
1334                 if (sdelay_small_count == 0)
1335                 {
1336                         if (IS_INDEPENDENT_PLAYER(this))
1337                         {
1338                                 // Players play independently. No point in requiring enemies.
1339                                 sdelay_small_count = 1;
1340                         }
1341                         else
1342                         {
1343                                 // Players play AGAINST each other. Enemies required.
1344                                 sdelay_small_count = 2;
1345                         }
1346                 }
1347                 if (sdelay_large_count == 0)
1348                 {
1349                         if (IS_INDEPENDENT_PLAYER(this))
1350                         {
1351                                 // Players play independently. No point in requiring enemies.
1352                                 sdelay_large_count = 1;
1353                         }
1354                         else
1355                         {
1356                                 // Players play AGAINST each other. Enemies required.
1357                                 sdelay_large_count = 2;
1358                         }
1359                 }
1360         }
1361
1362         float sdelay;
1363
1364         if (pcount <= sdelay_small_count)
1365                 sdelay = sdelay_small;
1366         else if (pcount >= sdelay_large_count)
1367                 sdelay = sdelay_large;
1368         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1369                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1370
1371         if(waves)
1372                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1373         else
1374                 this.respawn_time = time + sdelay;
1375
1376         if(sdelay < sdelay_max)
1377                 this.respawn_time_max = time + sdelay_max;
1378         else
1379                 this.respawn_time_max = this.respawn_time;
1380
1381         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1382                 this.respawn_countdown = 10; // first number to count down from is 10
1383         else
1384                 this.respawn_countdown = -1; // do not count down
1385
1386         if(autocvar_g_forced_respawn)
1387                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1388 }
1389
1390 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1391 // added to the model skins
1392 /*void UpdateColorModHack()
1393 {
1394         float c;
1395         c = this.clientcolors & 15;
1396         // LordHavoc: only bothering to support white, green, red, yellow, blue
1397              if (!teamplay) this.colormod = '0 0 0';
1398         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1399         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1400         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1401         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1402         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1403         else this.colormod = '1 1 1';
1404 }*/
1405
1406 void respawn(entity this)
1407 {
1408         bool damagedbycontents_prev = this.damagedbycontents;
1409         if(this.alpha >= 0)
1410         {
1411                 if(autocvar_g_respawn_ghosts)
1412                 {
1413                         this.solid = SOLID_NOT;
1414                         this.takedamage = DAMAGE_NO;
1415                         this.damagedbycontents = false;
1416                         set_movetype(this, MOVETYPE_FLY);
1417                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1418                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1419                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1420                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1421                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1422                         if(autocvar_g_respawn_ghosts_time > 0)
1423                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1424                 }
1425                 else
1426                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1427         }
1428
1429         CopyBody(this, 1);
1430         this.damagedbycontents = damagedbycontents_prev;
1431
1432         this.effects |= EF_NODRAW; // prevent another CopyBody
1433         PutClientInServer(this);
1434 }
1435
1436 void play_countdown(entity this, float finished, Sound samp)
1437 {
1438         TC(Sound, samp);
1439         if(IS_REAL_CLIENT(this))
1440                 if(floor(finished - time - frametime) != floor(finished - time))
1441                         if(finished - time < 6)
1442                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1443 }
1444
1445 void player_powerups_remove_all(entity this)
1446 {
1447         if (this.items & IT_SUPERWEAPON)
1448         {
1449                 // don't play the poweroff sound when the game restarts or the player disconnects
1450                 if (time > game_starttime + 1 && IS_CLIENT(this))
1451                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1452                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1453                 this.items -= (this.items & IT_SUPERWEAPON);
1454         }
1455 }
1456
1457 void player_powerups(entity this)
1458 {
1459         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1460                 this.modelflags |= MF_ROCKET;
1461         else
1462                 this.modelflags &= ~MF_ROCKET;
1463
1464         this.effects &= ~EF_NODEPTHTEST;
1465
1466         if (IS_DEAD(this))
1467                 player_powerups_remove_all(this);
1468
1469         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1470                 return;
1471
1472         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1473         int items_prev = this.items;
1474
1475         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1476         {
1477                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1478                 if (this.items & IT_SUPERWEAPON)
1479                 {
1480                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1481                         {
1482                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1483                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1484                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1485                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1486                         }
1487                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1488                         {
1489                                 // don't let them run out
1490                         }
1491                         else
1492                         {
1493                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1494                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1495                                 {
1496                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1497                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1498                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1499                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1500                                 }
1501                         }
1502                 }
1503                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1504                 {
1505                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1506                         {
1507                                 this.items = this.items | IT_SUPERWEAPON;
1508                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1509                                 {
1510                                         if(!g_cts)
1511                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1512                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1513                                 }
1514                         }
1515                         else
1516                         {
1517                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1518                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1519                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1520                         }
1521                 }
1522                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1523                 {
1524                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1525                 }
1526         }
1527
1528         if(autocvar_g_nodepthtestplayers)
1529                 this.effects = this.effects | EF_NODEPTHTEST;
1530
1531         if(autocvar_g_fullbrightplayers)
1532                 this.effects = this.effects | EF_FULLBRIGHT;
1533
1534         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1535 }
1536
1537 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1538 {
1539         if(current > stable)
1540                 return current;
1541         else if(current > stable - 0.25) // when close enough, "snap"
1542                 return stable;
1543         else
1544                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1545 }
1546
1547 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1548 {
1549         if(current < stable)
1550                 return current;
1551         else if(current < stable + 0.25) // when close enough, "snap"
1552                 return stable;
1553         else
1554                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1555 }
1556
1557 void RotRegen(entity this, int res, float limit_mod,
1558         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1559         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1560 {
1561         float old = GetResource(this, res);
1562         float current = old;
1563         if(current > rotstable)
1564         {
1565                 if(rotframetime > 0)
1566                 {
1567                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1568                         current = max(rotstable, current - rotlinear * rotframetime);
1569                 }
1570         }
1571         else if(current < regenstable)
1572         {
1573                 if(regenframetime > 0)
1574                 {
1575                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1576                         current = min(regenstable, current + regenlinear * regenframetime);
1577                 }
1578         }
1579
1580         float limit = GetResourceLimit(this, res) * limit_mod;
1581         if(current > limit)
1582                 current = limit;
1583
1584         if (current != old)
1585                 SetResource(this, res, current);
1586 }
1587
1588 void player_regen(entity this)
1589 {
1590         float max_mod, regen_mod, rot_mod, limit_mod;
1591         max_mod = regen_mod = rot_mod = limit_mod = 1;
1592
1593         float regen_health = autocvar_g_balance_health_regen;
1594         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1595         float regen_health_rot = autocvar_g_balance_health_rot;
1596         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1597         float regen_health_stable = autocvar_g_balance_health_regenstable;
1598         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1599         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1600                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1601         max_mod = M_ARGV(1, float);
1602         regen_mod = M_ARGV(2, float);
1603         rot_mod = M_ARGV(3, float);
1604         limit_mod = M_ARGV(4, float);
1605         regen_health = M_ARGV(5, float);
1606         regen_health_linear = M_ARGV(6, float);
1607         regen_health_rot = M_ARGV(7, float);
1608         regen_health_rotlinear = M_ARGV(8, float);
1609         regen_health_stable = M_ARGV(9, float);
1610         regen_health_rotstable = M_ARGV(10, float);
1611
1612         float rotstable, regenstable, rotframetime, regenframetime;
1613
1614         if(!mutator_returnvalue)
1615         if(!STAT(FROZEN, this))
1616         {
1617                 regenstable = autocvar_g_balance_armor_regenstable;
1618                 rotstable = autocvar_g_balance_armor_rotstable;
1619                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1620                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1621                 RotRegen(this, RES_ARMOR, limit_mod,
1622                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1623                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1624
1625                 // NOTE: max_mod is only applied to health
1626                 regenstable = regen_health_stable * max_mod;
1627                 rotstable = regen_health_rotstable * max_mod;
1628                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1629                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1630                 RotRegen(this, RES_HEALTH, limit_mod,
1631                         regenstable, regen_health, regen_health_linear, regenframetime,
1632                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1633         }
1634
1635         // if player rotted to death...  die!
1636         // check this outside above checks, as player may still be able to rot to death
1637         if(GetResource(this, RES_HEALTH) < 1)
1638         {
1639                 if(this.vehicle)
1640                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1641                 if(this.event_damage)
1642                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1643         }
1644
1645         if (!(this.items & IT_UNLIMITED_AMMO))
1646         {
1647                 regenstable = autocvar_g_balance_fuel_regenstable;
1648                 rotstable = autocvar_g_balance_fuel_rotstable;
1649                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1650                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1651                 RotRegen(this, RES_FUEL, 1,
1652                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1653                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1654         }
1655 }
1656
1657 bool zoomstate_set;
1658 void SetZoomState(entity this, float newzoom)
1659 {
1660         if(newzoom != CS(this).zoomstate)
1661         {
1662                 CS(this).zoomstate = newzoom;
1663                 ClientData_Touch(this);
1664         }
1665         zoomstate_set = true;
1666 }
1667
1668 void GetPressedKeys(entity this)
1669 {
1670         MUTATOR_CALLHOOK(GetPressedKeys, this);
1671         if (game_stopped)
1672         {
1673                 CS(this).pressedkeys = 0;
1674                 STAT(PRESSED_KEYS, this) = 0;
1675                 return;
1676         }
1677
1678         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1679         int keys = STAT(PRESSED_KEYS, this);
1680         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1681         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1682         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1683         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1684
1685         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1686         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1687         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1688         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1689         CS(this).pressedkeys = keys; // store for other users
1690
1691         STAT(PRESSED_KEYS, this) = keys;
1692 }
1693
1694 /*
1695 ======================
1696 spectate mode routines
1697 ======================
1698 */
1699
1700 void SpectateCopy(entity this, entity spectatee)
1701 {
1702         TC(Client, this); TC(Client, spectatee);
1703
1704         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1705         PS(this) = PS(spectatee);
1706         this.armortype = spectatee.armortype;
1707         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1708         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1709         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1710         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1711         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1712         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1713         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1714         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1715         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1716         CS(this).impulse = 0;
1717         this.disableclientprediction = 1; // no need to run prediction on a spectator
1718         this.items = spectatee.items;
1719         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1720         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1721         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1722         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1723         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1724         this.punchangle = spectatee.punchangle;
1725         this.view_ofs = spectatee.view_ofs;
1726         this.velocity = spectatee.velocity;
1727         this.dmg_take = spectatee.dmg_take;
1728         this.dmg_save = spectatee.dmg_save;
1729         this.dmg_inflictor = spectatee.dmg_inflictor;
1730         this.v_angle = spectatee.v_angle;
1731         this.angles = spectatee.v_angle;
1732         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1733         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1734         this.viewloc = spectatee.viewloc;
1735         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1736                 this.fixangle = true;
1737         setorigin(this, spectatee.origin);
1738         setsize(this, spectatee.mins, spectatee.maxs);
1739         SetZoomState(this, CS(spectatee).zoomstate);
1740
1741     anticheat_spectatecopy(this, spectatee);
1742         STAT(HUD, this) = STAT(HUD, spectatee);
1743         if(spectatee.vehicle)
1744     {
1745         this.angles = spectatee.v_angle;
1746
1747         //this.fixangle = false;
1748         //this.velocity = spectatee.vehicle.velocity;
1749         this.vehicle_health = spectatee.vehicle_health;
1750         this.vehicle_shield = spectatee.vehicle_shield;
1751         this.vehicle_energy = spectatee.vehicle_energy;
1752         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1753         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1754         this.vehicle_reload1 = spectatee.vehicle_reload1;
1755         this.vehicle_reload2 = spectatee.vehicle_reload2;
1756
1757         //msg_entity = this;
1758
1759        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1760             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1761            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1762            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1763
1764         //WriteByte (MSG_ONE, SVC_SETVIEW);
1765         //    WriteEntity(MSG_ONE, this);
1766         //makevectors(spectatee.v_angle);
1767         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1768     }
1769 }
1770
1771 bool SpectateUpdate(entity this)
1772 {
1773         if(!this.enemy)
1774                 return false;
1775
1776         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1777         {
1778                 SetSpectatee(this, NULL);
1779                 return false;
1780         }
1781
1782         SpectateCopy(this, this.enemy);
1783
1784         return true;
1785 }
1786
1787 bool SpectateSet(entity this)
1788 {
1789         if(!IS_PLAYER(this.enemy))
1790                 return false;
1791
1792         ClientData_Touch(this.enemy);
1793
1794         msg_entity = this;
1795         WriteByte(MSG_ONE, SVC_SETVIEW);
1796         WriteEntity(MSG_ONE, this.enemy);
1797         set_movetype(this, MOVETYPE_NONE);
1798         accuracy_resend(this);
1799
1800         if(!SpectateUpdate(this))
1801                 PutObserverInServer(this, false);
1802
1803         return true;
1804 }
1805
1806 void SetSpectatee_status(entity this, int spectatee_num)
1807 {
1808         int oldspectatee_status = CS(this).spectatee_status;
1809         CS(this).spectatee_status = spectatee_num;
1810
1811         if (CS(this).spectatee_status != oldspectatee_status)
1812         {
1813                 if (STAT(PRESSED_KEYS, this))
1814                 {
1815                         CS(this).pressedkeys = 0;
1816                         STAT(PRESSED_KEYS, this) = 0;
1817                 }
1818                 ClientData_Touch(this);
1819                 if (g_race || g_cts) race_InitSpectator();
1820         }
1821 }
1822
1823 void SetSpectatee(entity this, entity spectatee)
1824 {
1825         if(IS_BOT_CLIENT(this))
1826                 return; // bots abuse .enemy, this code is useless to them
1827
1828         entity old_spectatee = this.enemy;
1829
1830         this.enemy = spectatee;
1831
1832         // WEAPONTODO
1833         // these are required to fix the spectator bug with arc
1834         if(old_spectatee)
1835         {
1836                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1837                 {
1838                         .entity weaponentity = weaponentities[slot];
1839                         if(old_spectatee.(weaponentity).arc_beam)
1840                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1841                 }
1842         }
1843         if(this.enemy)
1844         {
1845                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1846                 {
1847                         .entity weaponentity = weaponentities[slot];
1848                         if(this.enemy.(weaponentity).arc_beam)
1849                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1850                 }
1851         }
1852
1853         if (this.enemy)
1854                 SetSpectatee_status(this, etof(this.enemy));
1855
1856         // needed to update spectator list
1857         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1858 }
1859
1860 bool Spectate(entity this, entity pl)
1861 {
1862         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1863                 return false;
1864         pl = M_ARGV(1, entity);
1865
1866         SetSpectatee(this, pl);
1867         return SpectateSet(this);
1868 }
1869
1870 bool SpectateNext(entity this)
1871 {
1872         entity ent = find(this.enemy, classname, STR_PLAYER);
1873
1874         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1875                 ent = M_ARGV(1, entity);
1876         else if (!ent)
1877                 ent = find(ent, classname, STR_PLAYER);
1878
1879         if(ent) { SetSpectatee(this, ent); }
1880
1881         return SpectateSet(this);
1882 }
1883
1884 bool SpectatePrev(entity this)
1885 {
1886         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1887         entity ent = findchain(classname, STR_PLAYER);
1888         if (!ent) // no player
1889                 return false;
1890
1891         entity first = ent;
1892         // skip players until current spectated player
1893         if(this.enemy)
1894         while(ent && ent != this.enemy)
1895                 ent = ent.chain;
1896
1897         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1898         {
1899                 case MUT_SPECPREV_FOUND:
1900                         ent = M_ARGV(1, entity);
1901                         break;
1902                 case MUT_SPECPREV_RETURN:
1903                         return true;
1904                 case MUT_SPECPREV_CONTINUE:
1905                 default:
1906                 {
1907                         if(ent.chain)
1908                                 ent = ent.chain;
1909                         else
1910                                 ent = first;
1911                         break;
1912                 }
1913         }
1914
1915         SetSpectatee(this, ent);
1916         return SpectateSet(this);
1917 }
1918
1919 /*
1920 =============
1921 ShowRespawnCountdown()
1922
1923 Update a respawn countdown display.
1924 =============
1925 */
1926 void ShowRespawnCountdown(entity this)
1927 {
1928         float number;
1929         if(!IS_DEAD(this)) // just respawned?
1930                 return;
1931         else
1932         {
1933                 number = ceil(this.respawn_time - time);
1934                 if(number <= 0)
1935                         return;
1936                 if(number <= this.respawn_countdown)
1937                 {
1938                         this.respawn_countdown = number - 1;
1939                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1940                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1941                 }
1942         }
1943 }
1944
1945 .bool team_selected;
1946 bool ShowTeamSelection(entity this)
1947 {
1948         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1949                 return false;
1950         stuffcmd(this, "menu_showteamselect\n");
1951         return true;
1952 }
1953 void Join(entity this)
1954 {
1955         TRANSMUTE(Player, this);
1956
1957         if(!this.team_selected)
1958         if(autocvar_g_campaign || autocvar_g_balance_teams)
1959                 TeamBalance_JoinBestTeam(this);
1960
1961         if(autocvar_g_campaign)
1962                 campaign_bots_may_start = true;
1963
1964         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1965
1966         PutClientInServer(this);
1967
1968         if(IS_PLAYER(this))
1969         if(teamplay && this.team != -1)
1970         {
1971         }
1972         else
1973                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1974         this.team_selected = false;
1975 }
1976
1977 int GetPlayerLimit()
1978 {
1979         if(g_duel)
1980                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1981         int player_limit = autocvar_g_maxplayers;
1982         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1983         player_limit = M_ARGV(0, int);
1984         return player_limit;
1985 }
1986
1987 /**
1988  * Determines whether the player is allowed to join. This depends on cvar
1989  * g_maxplayers, if it isn't used this function always return true, otherwise
1990  * it checks whether the number of currently playing players exceeds g_maxplayers.
1991  * @return int number of free slots for players, 0 if none
1992  */
1993 int nJoinAllowed(entity this, entity ignore)
1994 {
1995         if(!ignore)
1996         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1997         // so report 0 free slots if restricted
1998         {
1999                 if(autocvar_g_forced_team_otherwise == "spectate")
2000                         return 0;
2001                 if(autocvar_g_forced_team_otherwise == "spectator")
2002                         return 0;
2003         }
2004
2005         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2006                 return 0; // forced spectators can never join
2007
2008         // TODO simplify this
2009         int totalClients = 0;
2010         int currentlyPlaying = 0;
2011         FOREACH_CLIENT(true, {
2012                 if(it != ignore)
2013                         ++totalClients;
2014                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2015                         ++currentlyPlaying;
2016         });
2017
2018         int player_limit = GetPlayerLimit();
2019
2020         int free_slots = 0;
2021         if (!player_limit)
2022                 free_slots = maxclients - totalClients;
2023         else if(player_limit > 0 && currentlyPlaying < player_limit)
2024                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2025
2026         static float msg_time = 0;
2027         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2028         {
2029                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2030                 msg_time = time + 0.5;
2031         }
2032
2033         return free_slots;
2034 }
2035
2036 void PrintWelcomeMessage(entity this)
2037 {
2038         if(CS(this).motd_actived_time == 0)
2039         {
2040                 if (autocvar_g_campaign) {
2041                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2042                                 CS(this).motd_actived_time = time;
2043                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2044                         }
2045                 } else {
2046                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2047                                 CS(this).motd_actived_time = time;
2048                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2049                         }
2050                 }
2051         }
2052         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2053         {
2054                 if (autocvar_g_campaign) {
2055                         if (PHYS_INPUT_BUTTON_INFO(this))
2056                                 CS(this).motd_actived_time = time;
2057                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2058                                 CS(this).motd_actived_time = 0;
2059                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2060                         }
2061                 } else {
2062                         if (PHYS_INPUT_BUTTON_INFO(this))
2063                                 CS(this).motd_actived_time = time;
2064                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2065                                 CS(this).motd_actived_time = 0;
2066                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2067                         }
2068                 }
2069         }
2070         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2071         {
2072                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2073                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2074                 else if (CS(this).motd_actived_time == -2)
2075                 {
2076                         // instantly hide MOTD
2077                         CS(this).motd_actived_time = 0;
2078                         if (autocvar_g_campaign)
2079                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2080                         else
2081                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2082                 }
2083                 else if (IS_PLAYER(this) || IS_SPEC(this))
2084                 {
2085                         // FIXME occasionally for some reason MOTD never goes away
2086                         // delay MOTD removal a little bit in the hope it fixes this bug
2087                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2088                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2089                         else //if (CS(this).motd_actived_time < -2)
2090                                 CS(this).motd_actived_time++;
2091                 }
2092         }
2093 }
2094
2095 bool joinAllowed(entity this)
2096 {
2097         if (CS(this).version_mismatch) return false;
2098         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2099         if (!nJoinAllowed(this, this)) return false;
2100         if (teamplay && lockteams) return false;
2101         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2102         if (ShowTeamSelection(this)) return false;
2103         return true;
2104 }
2105
2106 .string shootfromfixedorigin;
2107 .bool dualwielding_prev;
2108 bool PlayerThink(entity this)
2109 {
2110         if (game_stopped || intermission_running) {
2111                 this.modelflags &= ~MF_ROCKET;
2112                 if(intermission_running)
2113                         IntermissionThink(this);
2114                 return false;
2115         }
2116
2117         if (timeout_status == TIMEOUT_ACTIVE) {
2118                 // don't allow the player to turn around while game is paused
2119                 // FIXME turn this into CSQC stuff
2120                 this.v_angle = this.lastV_angle;
2121                 this.angles = this.lastV_angle;
2122                 this.fixangle = true;
2123         }
2124
2125         if (frametime) player_powerups(this);
2126
2127         if (IS_DEAD(this)) {
2128                 if (this.personal && g_race_qualifying) {
2129                         if (time > this.respawn_time) {
2130                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2131                                 respawn(this);
2132                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2133                         }
2134                 } else {
2135                         if (frametime) player_anim(this);
2136
2137                         if (this.respawn_flags & RESPAWN_DENY)
2138                         {
2139                                 STAT(RESPAWN_TIME, this) = 0;
2140                                 return false;
2141                         }
2142
2143                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2144
2145                         switch(this.deadflag)
2146                         {
2147                                 case DEAD_DYING:
2148                                 {
2149                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2150                                                 this.deadflag = DEAD_RESPAWNING;
2151                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2152                                                 this.deadflag = DEAD_DEAD;
2153                                         break;
2154                                 }
2155                                 case DEAD_DEAD:
2156                                 {
2157                                         if (button_pressed)
2158                                                 this.deadflag = DEAD_RESPAWNABLE;
2159                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2160                                                 this.deadflag = DEAD_RESPAWNING;
2161                                         break;
2162                                 }
2163                                 case DEAD_RESPAWNABLE:
2164                                 {
2165                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2166                                                 this.deadflag = DEAD_RESPAWNING;
2167                                         break;
2168                                 }
2169                                 case DEAD_RESPAWNING:
2170                                 {
2171                                         if (time > this.respawn_time)
2172                                         {
2173                                                 this.respawn_time = time + 1; // only retry once a second
2174                                                 this.respawn_time_max = this.respawn_time;
2175                                                 respawn(this);
2176                                         }
2177                                         break;
2178                                 }
2179                         }
2180
2181                         ShowRespawnCountdown(this);
2182
2183                         if (this.respawn_flags & RESPAWN_SILENT)
2184                                 STAT(RESPAWN_TIME, this) = 0;
2185                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2186                         {
2187                                 if (time < this.respawn_time)
2188                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2189                                 else if (this.deadflag != DEAD_RESPAWNING)
2190                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2191                         }
2192                         else
2193                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2194                 }
2195
2196                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2197                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2198                         STAT(RESPAWN_TIME, this) *= -1;
2199
2200                 return false;
2201         }
2202
2203         FixPlayermodel(this);
2204
2205         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2206                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2207                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2208         }
2209
2210         // reset gun alignment when dual wielding status changes
2211         // to ensure guns are always aligned right and left
2212         bool dualwielding = W_DualWielding(this);
2213         if(this.dualwielding_prev != dualwielding)
2214         {
2215                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2216                 this.dualwielding_prev = dualwielding;
2217         }
2218
2219         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2220         //if(frametime)
2221         {
2222                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2223                 {
2224                         .entity weaponentity = weaponentities[slot];
2225                         if(WEP_CVAR(vortex, charge_always))
2226                                 W_Vortex_Charge(this, weaponentity, frametime);
2227                         W_WeaponFrame(this, weaponentity);
2228                 }
2229         }
2230
2231         if (frametime)
2232         {
2233                 // WEAPONTODO: Add a weapon request for this
2234                 // rot vortex charge to the charge limit
2235                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2236                 {
2237                         .entity weaponentity = weaponentities[slot];
2238                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2239                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2240                 }
2241
2242                 player_regen(this);
2243                 player_anim(this);
2244                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2245         }
2246
2247         monsters_setstatus(this);
2248
2249         return true;
2250 }
2251
2252 .bool would_spectate;
2253 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2254 void ObserverOrSpectatorThink(entity this)
2255 {
2256         bool is_spec = IS_SPEC(this);
2257         if ( CS(this).impulse )
2258         {
2259                 int r = MinigameImpulse(this, CS(this).impulse);
2260                 if (!is_spec || r)
2261                         CS(this).impulse = 0;
2262
2263                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2264                 {
2265                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2266                         CS(this).impulse = 0;
2267                         return;
2268                 }
2269         }
2270
2271         if (this.flags & FL_JUMPRELEASED) {
2272                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2273                         this.flags &= ~FL_JUMPRELEASED;
2274                         this.flags |= FL_SPAWNING;
2275                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2276                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2277                         this.flags &= ~FL_JUMPRELEASED;
2278                         if(SpectateNext(this)) {
2279                                 TRANSMUTE(Spectator, this);
2280                         } else if (is_spec) {
2281                                 TRANSMUTE(Observer, this);
2282                                 PutClientInServer(this);
2283                         }
2284                         else
2285                                 this.would_spectate = false; // unable to spectate anyone
2286                         if (is_spec)
2287                                 CS(this).impulse = 0;
2288                 } else if (is_spec) {
2289                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2290                                 this.flags &= ~FL_JUMPRELEASED;
2291                                 if(SpectatePrev(this)) {
2292                                         TRANSMUTE(Spectator, this);
2293                                 } else {
2294                                         TRANSMUTE(Observer, this);
2295                                         PutClientInServer(this);
2296                                 }
2297                                 CS(this).impulse = 0;
2298                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2299                                 this.would_spectate = false;
2300                                 this.flags &= ~FL_JUMPRELEASED;
2301                                 TRANSMUTE(Observer, this);
2302                                 PutClientInServer(this);
2303                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2304                                 PutObserverInServer(this, false);
2305                                 this.would_spectate = true;
2306                         }
2307                 }
2308                 else {
2309                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2310                         if (PHYS_INPUT_BUTTON_USE(this))
2311                                 wouldclip = !wouldclip;
2312                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2313                         set_movetype(this, preferred_movetype);
2314                 }
2315         } else { // jump pressed
2316                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2317                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2318                         this.flags |= FL_JUMPRELEASED;
2319                         if(this.flags & FL_SPAWNING)
2320                         {
2321                                 this.flags &= ~FL_SPAWNING;
2322                                 if(joinAllowed(this))
2323                                         Join(this);
2324                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2325                                         CS(this).autojoin_checked = -1;
2326                                 return;
2327                         }
2328                 }
2329                 if(is_spec && !SpectateUpdate(this))
2330                         PutObserverInServer(this, false);
2331         }
2332         if (is_spec)
2333                 this.flags |= FL_CLIENT | FL_NOTARGET;
2334 }
2335
2336 void PlayerUseKey(entity this)
2337 {
2338         if (!IS_PLAYER(this))
2339                 return;
2340
2341         if(this.vehicle)
2342         {
2343                 if(!game_stopped)
2344                 {
2345                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2346                         return;
2347                 }
2348         }
2349         else if(autocvar_g_vehicles_enter)
2350         {
2351                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2352                 {
2353                         entity head, closest_target = NULL;
2354                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2355
2356                         while(head) // find the closest acceptable target to enter
2357                         {
2358                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2359                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2360                                 {
2361                                         if(closest_target)
2362                                         {
2363                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2364                                                 { closest_target = head; }
2365                                         }
2366                                         else { closest_target = head; }
2367                                 }
2368
2369                                 head = head.chain;
2370                         }
2371
2372                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2373                 }
2374         }
2375
2376         // a use key was pressed; call handlers
2377         MUTATOR_CALLHOOK(PlayerUseKey, this);
2378 }
2379
2380
2381 /*
2382 =============
2383 PlayerPreThink
2384
2385 Called every frame for each client before the physics are run
2386 =============
2387 */
2388 .float last_vehiclecheck;
2389 void PlayerPreThink (entity this)
2390 {
2391         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2392         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2393
2394         WarpZone_PlayerPhysics_FixVAngle(this);
2395
2396         if (frametime) {
2397                 // physics frames: update anticheat stuff
2398                 anticheat_prethink(this);
2399
2400                 // WORKAROUND: only use dropclient in server frames (frametime set).
2401                 // Never use it in cl_movement frames (frametime zero).
2402                 if (blockSpectators && IS_REAL_CLIENT(this)
2403                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2404                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2405                 {
2406                         if (dropclient_schedule(this))
2407                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2408                 }
2409         }
2410
2411         zoomstate_set = false;
2412
2413         // Check for nameless players
2414         if (this.netname == "" || this.netname != CS(this).netname_previous)
2415         {
2416                 bool assume_unchanged = (CS(this).netname_previous == "");
2417                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2418                 {
2419                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2420                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2421                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2422                         assume_unchanged = false;
2423                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2424                 }
2425                 if (isInvisibleString(this.netname))
2426                 {
2427                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2428                         sprint(this, "Warning: invisible names are not allowed.\n");
2429                         assume_unchanged = false;
2430                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2431                 }
2432                 if (!assume_unchanged && autocvar_sv_eventlog)
2433                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2434                 strcpy(CS(this).netname_previous, this.netname);
2435         }
2436
2437         // version nagging
2438         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2439         CS(this).version_nagtime = 0;
2440         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2441             // git client
2442         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2443             // git server
2444             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2445         } else {
2446             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2447             if (r < 0) { // old client
2448                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2449             } else if (r > 0) { // old server
2450                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2451             }
2452         }
2453     }
2454
2455         // GOD MODE info
2456         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2457         {
2458                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2459                 this.max_armorvalue = 0;
2460         }
2461
2462         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2463         {
2464                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2465                 {
2466                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2467                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2468                         if (this.iceblock)
2469                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2470
2471                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2472                                 Unfreeze(this, false);
2473                 }
2474                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2475                 {
2476                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2477                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2478
2479                         if (GetResource(this, RES_HEALTH) < 1)
2480                         {
2481                                 if (this.vehicle)
2482                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2483                                 if(this.event_damage)
2484                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2485                         }
2486                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2487                                 Unfreeze(this, false);
2488                 }
2489         }
2490
2491         MUTATOR_CALLHOOK(PlayerPreThink, this);
2492
2493         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2494         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2495         {
2496                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2497                 {
2498                         if(!it.owner)
2499                         {
2500                                 if(!it.team || SAME_TEAM(this, it))
2501                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2502                                 else if(autocvar_g_vehicles_steal)
2503                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2504                         }
2505                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2506                         {
2507                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2508                         }
2509                 });
2510
2511                 this.last_vehiclecheck = time + 1;
2512         }
2513
2514         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2515         {
2516                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2517                         PlayerUseKey(this);
2518                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2519         }
2520
2521         if (IS_REAL_CLIENT(this))
2522                 PrintWelcomeMessage(this);
2523
2524         if (IS_PLAYER(this)) {
2525                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2526                         error("Client can't be spawned as player on connection!");
2527                 if(!PlayerThink(this))
2528                         return;
2529         }
2530         else if (game_stopped || intermission_running) {
2531                 if(intermission_running)
2532                         IntermissionThink(this);
2533                 return;
2534         }
2535         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2536         {
2537                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2538                 CS(this).autojoin_checked = 1;
2539                 // don't do this in ClientConnect
2540                 // many things can go wrong if a client is spawned as player on connection
2541                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2542                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2543                                 && (!teamplay || autocvar_g_balance_teams)))
2544                 {
2545                         campaign_bots_may_start = true;
2546                         if(joinAllowed(this))
2547                                 Join(this);
2548                         return;
2549                 }
2550         }
2551         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2552                 ObserverOrSpectatorThink(this);
2553         }
2554
2555         // WEAPONTODO: Add weapon request for this
2556         if (!zoomstate_set) {
2557                 bool wep_zoomed = false;
2558                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2559                 {
2560                         .entity weaponentity = weaponentities[slot];
2561                         Weapon thiswep = this.(weaponentity).m_weapon;
2562                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2563                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2564                 }
2565                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2566         }
2567
2568         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2569         {
2570                 CS(this).teamkill_soundtime = 0;
2571
2572                 entity e = CS(this).teamkill_soundsource;
2573                 entity oldpusher = e.pusher;
2574                 e.pusher = this;
2575                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2576                 e.pusher = oldpusher;
2577         }
2578
2579         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2580                 CS(this).taunt_soundtime = 0;
2581                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2582         }
2583
2584         target_voicescript_next(this);
2585 }
2586
2587 void DrownPlayer(entity this)
2588 {
2589         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2590                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2591         {
2592                 STAT(AIR_FINISHED, this) = 0;
2593                 return;
2594         }
2595
2596         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2597         {
2598                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2599                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2600                 STAT(AIR_FINISHED, this) = 0;
2601         }
2602         else
2603         {
2604                 if (!STAT(AIR_FINISHED, this))
2605                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2606                 if (STAT(AIR_FINISHED, this) < time)
2607                 {       // drown!
2608                         if (this.pain_finished < time)
2609                         {
2610                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2611                                 this.pain_finished = time + 0.5;
2612                         }
2613                 }
2614         }
2615 }
2616
2617 .bool move_qcphysics;
2618
2619 void Player_Physics(entity this)
2620 {
2621         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2622
2623         if(!this.move_qcphysics)
2624                 return;
2625
2626         if(!frametime && !CS(this).pm_frametime)
2627                 return;
2628
2629         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2630
2631         CS(this).pm_frametime = 0;
2632 }
2633
2634 /*
2635 =============
2636 PlayerPostThink
2637
2638 Called every frame for each client after the physics are run
2639 =============
2640 */
2641 void PlayerPostThink (entity this)
2642 {
2643         Player_Physics(this);
2644
2645         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2646         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2647         if (IS_REAL_CLIENT(this))
2648         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2649         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2650         {
2651                 int totalClients = 0;
2652                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2653                 {
2654                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2655                         if (server_is_dedicated)
2656                         {
2657                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2658                                 {
2659                                         ++totalClients;
2660                                 });
2661                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2662                                         totalClients = 0;
2663                         }
2664                 }
2665                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2666                 {
2667                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2668                         {
2669                                 ++totalClients;
2670                         });
2671                 }
2672
2673                 if (totalClients < autocvar_sv_maxidle_minplayers)
2674                 {
2675                         // idle kick disabled
2676                         CS(this).parm_idlesince = time;
2677                 }
2678                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2679                 {
2680                         if (CS(this).idlekick_lasttimeleft)
2681                         {
2682                                 CS(this).idlekick_lasttimeleft = 0;
2683                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2684                         }
2685                 }
2686                 else
2687                 {
2688                         float maxidle_time = autocvar_sv_maxidle;
2689                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2690                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2691                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2692                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2693                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2694                         {
2695                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2696                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2697                                 else
2698                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2699                         }
2700                         if (timeleft <= 0) {
2701                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2702                                 {
2703                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2704                                         PutObserverInServer(this, true);
2705                                 }
2706                                 else
2707                                 {
2708                                         if (dropclient_schedule(this))
2709                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2710                                 }
2711                                 return;
2712                         }
2713                         else if (timeleft <= countdown_time) {
2714                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2715                                         play2(this, SND(TALK2));
2716                                 CS(this).idlekick_lasttimeleft = timeleft;
2717                         }
2718                 }
2719         }
2720
2721         CheatFrame(this);
2722
2723         if (game_stopped)
2724         {
2725                 this.solid = SOLID_NOT;
2726                 this.takedamage = DAMAGE_NO;
2727                 set_movetype(this, MOVETYPE_NONE);
2728                 CS(this).teamkill_complain = 0;
2729                 CS(this).teamkill_soundtime = 0;
2730                 CS(this).teamkill_soundsource = NULL;
2731         }
2732
2733         if (IS_PLAYER(this)) {
2734                 if(this.death_time == time && IS_DEAD(this))
2735                 {
2736                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2737                         // once all the damage events of this frame have been processed with normal size
2738                         this.maxs.z = 5;
2739                         setsize(this, this.mins, this.maxs);
2740                 }
2741                 DrownPlayer(this);
2742                 UpdateChatBubble(this);
2743                 if (CS(this).impulse) ImpulseCommands(this);
2744                 GetPressedKeys(this);
2745                 if (game_stopped)
2746                 {
2747                         CSQCMODEL_AUTOUPDATE(this);
2748                         return;
2749                 }
2750         }
2751         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2752         {
2753                 CS(this).pressedkeys = 0;
2754                 STAT(PRESSED_KEYS, this) = 0;
2755         }
2756
2757         if (this.waypointsprite_attachedforcarrier) {
2758                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2759                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2760         }
2761
2762         CSQCMODEL_AUTOUPDATE(this);
2763 }
2764
2765 // hack to copy the button fields from the client entity to the Client State
2766 void PM_UpdateButtons(entity this, entity store)
2767 {
2768         if(this.impulse)
2769                 store.impulse = this.impulse;
2770         this.impulse = 0;
2771
2772         bool typing = this.buttonchat || this.button12;
2773
2774         store.button0 = (typing) ? 0 : this.button0;
2775         //button1?!
2776         store.button2 = (typing) ? 0 : this.button2;
2777         store.button3 = (typing) ? 0 : this.button3;
2778         store.button4 = this.button4;
2779         store.button5 = (typing) ? 0 : this.button5;
2780         store.button6 = this.button6;
2781         store.button7 = this.button7;
2782         store.button8 = this.button8;
2783         store.button9 = this.button9;
2784         store.button10 = this.button10;
2785         store.button11 = this.button11;
2786         store.button12 = this.button12;
2787         store.button13 = this.button13;
2788         store.button14 = this.button14;
2789         store.button15 = this.button15;
2790         store.button16 = this.button16;
2791         store.buttonuse = this.buttonuse;
2792         store.buttonchat = this.buttonchat;
2793
2794         store.cursor_active = this.cursor_active;
2795         store.cursor_screen = this.cursor_screen;
2796         store.cursor_trace_start = this.cursor_trace_start;
2797         store.cursor_trace_endpos = this.cursor_trace_endpos;
2798         store.cursor_trace_ent = this.cursor_trace_ent;
2799
2800         store.ping = this.ping;
2801         store.ping_packetloss = this.ping_packetloss;
2802         store.ping_movementloss = this.ping_movementloss;
2803
2804         store.v_angle = this.v_angle;
2805         store.movement = this.movement;
2806 }
2807
2808 NET_HANDLE(fpsreport, bool)
2809 {
2810         int fps = ReadShort();
2811         PlayerScore_Set(sender, SP_FPS, fps);
2812         return true;
2813 }