qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include <common/effects/qc/globalsound.qh>
  36
  37 #include "../common/mapobjects/func/conveyor.qh"
  38 #include "../common/mapobjects/teleporters.qh"
  39 #include "../common/mapobjects/target/spawnpoint.qh"
  40
  41 #include "../common/vehicles/all.qh"
  42
  43 #include "weapons/hitplot.qh"
  44 #include "weapons/weaponsystem.qh"
  45
  46 #include "../common/net_notice.qh"
  47 #include "../common/net_linked.qh"
  48 #include "../common/physics/player.qh"
  49
  50 #include <common/vehicles/sv_vehicles.qh>
  51
  52 #include "../common/items/_mod.qh"
  53
  54 #include "../common/mutators/mutator/waypoints/all.qh"
  55 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  56 #include <common/gamemodes/_mod.qh>
  57
  58 #include "../common/mapobjects/subs.qh"
  59 #include "../common/mapobjects/triggers.qh"
  60 #include "../common/mapobjects/trigger/secret.qh"
  61
  62 #include "../common/minigames/sv_minigames.qh"
  63
  64 #include "../common/items/inventory.qh"
  65
  66 #include "../common/monsters/sv_monsters.qh"
  67
  68 #include "../lib/warpzone/server.qh"
  69
  70 #include <common/mutators/mutator/overkill/oknex.qh>
  71
  72 STATIC_METHOD(Client, Add, void(Client this, int _team))
  73 {
  74     ClientConnect(this);
  75     TRANSMUTE(Player, this);
  76     this.frame = 12; // 7
  77     this.team = _team;
  78     PutClientInServer(this);
  79 }
  80
  81 STATIC_METHOD(Client, Remove, void(Client this))
  82 {
  83     TRANSMUTE(Observer, this);
  84     PutClientInServer(this);
  85     ClientDisconnect(this);
  86 }
  87
  88 void send_CSQC_teamnagger() {
  89         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  90 }
  91
  92 int CountSpectators(entity player, entity to)
  93 {
  94         if(!player) { return 0; } // not sure how, but best to be safe
  95
  96         int spec_count = 0;
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 spec_count++;
 101         });
 102
 103         return spec_count;
 104 }
 105
 106 void WriteSpectators(entity player, entity to)
 107 {
 108         if(!player) { return; } // not sure how, but best to be safe
 109
 110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 111         {
 112                 WriteByte(MSG_ENTITY, num_for_edict(it));
 113         });
 114 }
 115
 116 bool ClientData_Send(entity this, entity to, int sf)
 117 {
 118         assert(to == this.owner, return false);
 119
 120         entity e = to;
 121         if (IS_SPEC(e)) e = e.enemy;
 122
 123         sf = 0;
 124         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 125         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 126         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 127         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 128
 129         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 130         WriteByte(MSG_ENTITY, sf);
 131
 132         if (sf & BIT(1))
 133                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 134
 135         if(sf & BIT(4))
 136         {
 137                 float specs = CountSpectators(e, to);
 138                 WriteByte(MSG_ENTITY, specs);
 139                 WriteSpectators(e, to);
 140         }
 141
 142         return true;
 143 }
 144
 145 void ClientData_Attach(entity this)
 146 {
 147         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 148         CS(this).clientdata.drawonlytoclient = this;
 149         CS(this).clientdata.owner = this;
 150 }
 151
 152 void ClientData_Detach(entity this)
 153 {
 154         delete(CS(this).clientdata);
 155         CS(this).clientdata = NULL;
 156 }
 157
 158 void ClientData_Touch(entity e)
 159 {
 160         entity cd = CS(e).clientdata;
 161         if (cd) { cd.SendFlags = 1; }
 162
 163         // make it spectatable
 164         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 165         {
 166                 entity cd = CS(it).clientdata;
 167                 if (cd) { cd.SendFlags = 1; }
 168         });
 169 }
 170
 171
 172 /*
 173 =============
 174 CheckPlayerModel
 175
 176 Checks if the argument string can be a valid playermodel.
 177 Returns a valid one in doubt.
 178 =============
 179 */
 180 string FallbackPlayerModel;
 181 string CheckPlayerModel(string plyermodel) {
 182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 183         {
 184                 // note: we cannot summon Don Strunzone here, some player may
 185                 // still have the model string set. In case anyone manages how
 186                 // to change a cvar default, we'll have a small leak here.
 187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 188         }
 189         // only in right path
 190         if( substring(plyermodel,0,14) != "models/player/")
 191                 return FallbackPlayerModel;
 192         // only good file extensions
 193         if(substring(plyermodel,-4,4) != ".zym")
 194         if(substring(plyermodel,-4,4) != ".dpm")
 195         if(substring(plyermodel,-4,4) != ".iqm")
 196         if(substring(plyermodel,-4,4) != ".md3")
 197         if(substring(plyermodel,-4,4) != ".psk")
 198                 return FallbackPlayerModel;
 199         // forbid the LOD models
 200         if(substring(plyermodel, -9,5) == "_lod1")
 201                 return FallbackPlayerModel;
 202         if(substring(plyermodel, -9,5) == "_lod2")
 203                 return FallbackPlayerModel;
 204         if(plyermodel != strtolower(plyermodel))
 205                 return FallbackPlayerModel;
 206         // also, restrict to server models
 207         if(autocvar_sv_servermodelsonly)
 208         {
 209                 if(!fexists(plyermodel))
 210                         return FallbackPlayerModel;
 211         }
 212         return plyermodel;
 213 }
 214
 215 void setplayermodel(entity e, string modelname)
 216 {
 217         precache_model(modelname);
 218         _setmodel(e, modelname);
 219         player_setupanimsformodel(e);
 220         if(!autocvar_g_debug_globalsounds)
 221                 UpdatePlayerSounds(e);
 222 }
 223
 224 /** putting a client as observer in the server */
 225 void PutObserverInServer(entity this)
 226 {
 227     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 228         PlayerState_detach(this);
 229
 230         if (IS_PLAYER(this))
 231         {
 232                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 233                 {
 234                         // despawn effect
 235                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 236                 }
 237
 238                 // was a player, recount votes and ready status
 239                 if(IS_REAL_CLIENT(this))
 240                 {
 241                         if (vote_called) { VoteCount(false); }
 242                         ReadyCount();
 243                 }
 244     }
 245
 246     {
 247         entity spot = SelectSpawnPoint(this, true);
 248         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 249         this.angles = vec2(spot.angles);
 250         this.fixangle = true;
 251         // offset it so that the spectator spawns higher off the ground, looks better this way
 252         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 253         if (IS_REAL_CLIENT(this))
 254         {
 255             msg_entity = this;
 256             WriteByte(MSG_ONE, SVC_SETVIEW);
 257             WriteEntity(MSG_ONE, this);
 258         }
 259         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 260         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 261         if(!autocvar_g_debug_globalsounds)
 262         {
 263                 // needed for player sounds
 264                 this.model = "";
 265                 FixPlayermodel(this);
 266         }
 267         setmodel(this, MDL_Null);
 268         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 269         this.view_ofs = '0 0 0';
 270     }
 271
 272     RemoveGrapplingHooks(this);
 273         Portal_ClearAll(this);
 274         Unfreeze(this);
 275         SetSpectatee(this, NULL);
 276
 277         if (this.alivetime)
 278         {
 279                 if (!warmup_stage)
 280                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 281                 this.alivetime = 0;
 282         }
 283
 284         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 285
 286         WaypointSprite_PlayerDead(this);
 287
 288         if (CS(this).killcount != FRAGS_SPECTATOR)
 289         {
 290                 if(!game_stopped)
 291                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 292                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 293         }
 294
 295         accuracy_resend(this);
 296
 297         CS(this).spectatortime = time;
 298         if(this.bot_attack)
 299                 IL_REMOVE(g_bot_targets, this);
 300         this.bot_attack = false;
 301         if(this.monster_attack)
 302                 IL_REMOVE(g_monster_targets, this);
 303         this.monster_attack = false;
 304     STAT(HUD, this) = HUD_NORMAL;
 305         TRANSMUTE(Observer, this);
 306         this.iscreature = false;
 307         this.teleportable = TELEPORT_SIMPLE;
 308         if(this.damagedbycontents)
 309                 IL_REMOVE(g_damagedbycontents, this);
 310         this.damagedbycontents = false;
 311         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 312         SetSpectatee_status(this, etof(this));
 313         this.takedamage = DAMAGE_NO;
 314         this.solid = SOLID_NOT;
 315         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 316         this.flags = FL_CLIENT | FL_NOTARGET;
 317         this.effects = 0;
 318         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 319         this.pauserotarmor_finished = 0;
 320         this.pauserothealth_finished = 0;
 321         this.pauseregen_finished = 0;
 322         this.damageforcescale = 0;
 323         this.death_time = 0;
 324         this.respawn_flags = 0;
 325         this.respawn_time = 0;
 326         STAT(RESPAWN_TIME, this) = 0;
 327         this.alpha = 0;
 328         this.scale = 0;
 329         this.fade_time = 0;
 330         this.pain_frame = 0;
 331         this.pain_finished = 0;
 332         this.strength_finished = 0;
 333         this.invincible_finished = 0;
 334         this.superweapons_finished = 0;
 335         //this.dphitcontentsmask = 0;
 336         this.dphitcontentsmask = DPCONTENTS_SOLID;
 337         if (autocvar_g_playerclip_collisions)
 338                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 339         this.pushltime = 0;
 340         this.istypefrag = 0;
 341         setthink(this, func_null);
 342         this.nextthink = 0;
 343         this.deadflag = DEAD_NO;
 344         this.crouch = false;
 345         STAT(REVIVE_PROGRESS, this) = 0;
 346         this.revival_time = 0;
 347
 348         this.items = 0;
 349         STAT(WEAPONS, this) = '0 0 0';
 350         this.drawonlytoclient = this;
 351
 352         this.viewloc = NULL;
 353
 354         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 355
 356         this.weaponmodel = "";
 357         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 358         {
 359                 this.weaponentities[slot] = NULL;
 360         }
 361         this.exteriorweaponentity = NULL;
 362         CS(this).killcount = FRAGS_SPECTATOR;
 363         this.velocity = '0 0 0';
 364         this.avelocity = '0 0 0';
 365         this.punchangle = '0 0 0';
 366         this.punchvector = '0 0 0';
 367         this.oldvelocity = this.velocity;
 368         this.fire_endtime = -1;
 369         this.event_damage = func_null;
 370         this.event_heal = func_null;
 371
 372         for(int slot = 0; slot < MAX_AXH; ++slot)
 373         {
 374                 entity axh = this.(AuxiliaryXhair[slot]);
 375                 this.(AuxiliaryXhair[slot]) = NULL;
 376
 377                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 378                         delete(axh);
 379         }
 380
 381         if (mutator_returnvalue)
 382         {
 383                 // mutator prevents resetting teams+score
 384         }
 385         else
 386         {
 387                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 388                 this.frags = FRAGS_SPECTATOR;
 389     }
 390 }
 391
 392 int player_getspecies(entity this)
 393 {
 394         get_model_parameters(this.model, this.skin);
 395         int s = get_model_parameters_species;
 396         get_model_parameters(string_null, 0);
 397         if (s < 0) return SPECIES_HUMAN;
 398         return s;
 399 }
 400
 401 .float model_randomizer;
 402 void FixPlayermodel(entity player)
 403 {
 404         string defaultmodel = "";
 405         int defaultskin = 0;
 406         if(autocvar_sv_defaultcharacter)
 407         {
 408                 if(teamplay)
 409                 {
 410                         switch(player.team)
 411                         {
 412                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 413                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 414                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 415                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 416                         }
 417                 }
 418
 419                 if(defaultmodel == "")
 420                 {
 421                         defaultmodel = autocvar_sv_defaultplayermodel;
 422                         defaultskin = autocvar_sv_defaultplayerskin;
 423                 }
 424
 425                 int n = tokenize_console(defaultmodel);
 426                 if(n > 0)
 427                 {
 428                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 429                         // However, do NOT randomize if the player-selected model is in the list.
 430                         for (int i = 0; i < n; ++i)
 431                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 432                                         defaultmodel = argv(i);
 433                 }
 434
 435                 int i = strstrofs(defaultmodel, ":", 0);
 436                 if(i >= 0)
 437                 {
 438                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 439                         defaultmodel = substring(defaultmodel, 0, i);
 440                 }
 441         }
 442         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 443         {
 444                 if(teamplay)
 445                 {
 446                         switch(player.team)
 447                         {
 448                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 449                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 450                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 451                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 452                         }
 453                 }
 454
 455                 if(!defaultskin)
 456                         defaultskin = autocvar_sv_defaultplayerskin;
 457         }
 458
 459         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 460         defaultmodel = M_ARGV(0, string);
 461         defaultskin = M_ARGV(1, int);
 462
 463         bool chmdl = false;
 464         int oldskin;
 465         if(defaultmodel != "")
 466         {
 467                 if (defaultmodel != player.model)
 468                 {
 469                         vector m1 = player.mins;
 470                         vector m2 = player.maxs;
 471                         setplayermodel (player, defaultmodel);
 472                         setsize (player, m1, m2);
 473                         chmdl = true;
 474                 }
 475
 476                 oldskin = player.skin;
 477                 player.skin = defaultskin;
 478         } else {
 479                 if (player.playermodel != player.model || player.playermodel == "")
 480                 {
 481                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 482                         vector m1 = player.mins;
 483                         vector m2 = player.maxs;
 484                         setplayermodel (player, player.playermodel);
 485                         setsize (player, m1, m2);
 486                         chmdl = true;
 487                 }
 488
 489                 if(!autocvar_sv_defaultcharacterskin)
 490                 {
 491                         oldskin = player.skin;
 492                         player.skin = stof(player.playerskin);
 493                 }
 494                 else
 495                 {
 496                         oldskin = player.skin;
 497                         player.skin = defaultskin;
 498                 }
 499         }
 500
 501         if(chmdl || oldskin != player.skin) // model or skin has changed
 502         {
 503                 player.species = player_getspecies(player); // update species
 504                 if(!autocvar_g_debug_globalsounds)
 505                         UpdatePlayerSounds(player); // update skin sounds
 506         }
 507
 508         if(!teamplay)
 509                 if(strlen(autocvar_sv_defaultplayercolors))
 510                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 511                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 512 }
 513
 514 void PutPlayerInServer(entity this)
 515 {
 516         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 517
 518         PlayerState_attach(this);
 519         accuracy_resend(this);
 520
 521         if (this.team < 0)
 522                 TeamBalance_JoinBestTeam(this);
 523
 524         entity spot = SelectSpawnPoint(this, false);
 525         if (!spot) {
 526                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 527                 return; // spawn failed
 528         }
 529
 530         TRANSMUTE(Player, this);
 531
 532         CS(this).wasplayer = true;
 533         this.iscreature = true;
 534         this.teleportable = TELEPORT_NORMAL;
 535         if(!this.damagedbycontents)
 536                 IL_PUSH(g_damagedbycontents, this);
 537         this.damagedbycontents = true;
 538         set_movetype(this, MOVETYPE_WALK);
 539         this.solid = SOLID_SLIDEBOX;
 540         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 541         if (autocvar_g_playerclip_collisions)
 542                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 543         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 544                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 545         this.frags = FRAGS_PLAYER;
 546         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 547         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 548         if (autocvar__notarget)
 549                 this.flags |= FL_NOTARGET;
 550         this.takedamage = DAMAGE_AIM;
 551         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 552
 553         if (warmup_stage) {
 554                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 555                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 556                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 557                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 558                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 559                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 560                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 561                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 562                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 563         } else {
 564                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 565                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 566                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 567                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 568                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 569                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 570                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 571                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 572                 STAT(WEAPONS, this) = start_weapons;
 573                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 574                 {
 575                         GiveRandomWeapons(this, random_start_weapons_count,
 576                                 autocvar_g_random_start_weapons, random_start_ammo);
 577                 }
 578         }
 579         SetSpectatee_status(this, 0);
 580
 581         PS(this).dual_weapons = '0 0 0';
 582
 583         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 584
 585         this.items = start_items;
 586
 587         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 588         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 589         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 590         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 591         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 592         if (!sv_ready_restart_after_countdown && time < game_starttime)
 593         {
 594                 float f = game_starttime - time;
 595                 this.spawnshieldtime += f;
 596                 this.pauserotarmor_finished += f;
 597                 this.pauserothealth_finished += f;
 598                 this.pauseregen_finished += f;
 599         }
 600
 601         this.damageforcescale = 2;
 602         this.death_time = 0;
 603         this.respawn_flags = 0;
 604         this.respawn_time = 0;
 605         STAT(RESPAWN_TIME, this) = 0;
 606         this.scale = autocvar_sv_player_scale;
 607         this.fade_time = 0;
 608         this.pain_frame = 0;
 609         this.pain_finished = 0;
 610         this.pushltime = 0;
 611         setthink(this, func_null); // players have no think function
 612         this.nextthink = 0;
 613         this.dmg_team = 0;
 614         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 615
 616         this.deadflag = DEAD_NO;
 617
 618         this.angles = spot.angles;
 619         this.angles_z = 0; // never spawn tilted even if the spot says to
 620         if (IS_BOT_CLIENT(this))
 621                 this.v_angle = this.angles;
 622         this.fixangle = true; // turn this way immediately
 623         this.oldvelocity = this.velocity = '0 0 0';
 624         this.avelocity = '0 0 0';
 625         this.punchangle = '0 0 0';
 626         this.punchvector = '0 0 0';
 627
 628         this.strength_finished = 0;
 629         this.invincible_finished = 0;
 630         this.fire_endtime = -1;
 631         STAT(REVIVE_PROGRESS, this) = 0;
 632         this.revival_time = 0;
 633
 634         this.air_finished = time + 12;
 635         this.waterlevel = WATERLEVEL_NONE;
 636         this.watertype = CONTENT_EMPTY;
 637
 638         entity spawnevent = new_pure(spawnevent);
 639         spawnevent.owner = this;
 640         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 641
 642         // Cut off any still running player sounds.
 643         stopsound(this, CH_PLAYER_SINGLE);
 644
 645         this.model = "";
 646         FixPlayermodel(this);
 647         this.drawonlytoclient = NULL;
 648
 649         this.viewloc = NULL;
 650
 651         for(int slot = 0; slot < MAX_AXH; ++slot)
 652         {
 653                 entity axh = this.(AuxiliaryXhair[slot]);
 654                 this.(AuxiliaryXhair[slot]) = NULL;
 655
 656                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 657                         delete(axh);
 658         }
 659
 660         this.spawnpoint_targ = NULL;
 661
 662         this.crouch = false;
 663         this.view_ofs = STAT(PL_VIEW_OFS, this);
 664         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 665         this.spawnorigin = spot.origin;
 666         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 667         // don't reset back to last position, even if new position is stuck in solid
 668         this.oldorigin = this.origin;
 669         if(this.conveyor)
 670                 IL_REMOVE(g_conveyed, this);
 671         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 672         STAT(HUD, this) = HUD_NORMAL;
 673
 674         this.event_damage = PlayerDamage;
 675         this.event_heal = PlayerHeal;
 676
 677         if(!this.bot_attack)
 678                 IL_PUSH(g_bot_targets, this);
 679         this.bot_attack = true;
 680         if(!this.monster_attack)
 681                 IL_PUSH(g_monster_targets, this);
 682         this.monster_attack = true;
 683         navigation_dynamicgoal_init(this, false);
 684
 685         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 686
 687         // player was spectator
 688         if (CS(this).killcount == FRAGS_SPECTATOR) {
 689                 PlayerScore_Clear(this);
 690                 CS(this).killcount = 0;
 691                 CS(this).startplaytime = time;
 692         }
 693
 694         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 695         {
 696                 .entity weaponentity = weaponentities[slot];
 697                 entity oldwep = this.(weaponentity);
 698                 CL_SpawnWeaponentity(this, weaponentity);
 699                 if(oldwep && oldwep.owner == this)
 700                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 701         }
 702         this.alpha = default_player_alpha;
 703         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 704         this.exteriorweaponentity.alpha = default_weapon_alpha;
 705
 706         this.speedrunning = false;
 707
 708         target_voicescript_clear(this);
 709
 710         // reset fields the weapons may use
 711         FOREACH(Weapons, true, {
 712                 it.wr_resetplayer(it, this);
 713                         // reload all reloadable weapons
 714                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 715                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 716                         {
 717                                 .entity weaponentity = weaponentities[slot];
 718                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 719                         }
 720                 }
 721         });
 722
 723         {
 724                 //string s = spot.target;
 725                 //spot.target = string_null;
 726                 SUB_UseTargets(spot, this, NULL);
 727                 //spot.target = s;
 728         }
 729
 730         Unfreeze(this);
 731
 732         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 733
 734         if (autocvar_spawn_debug)
 735         {
 736                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 737                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 738         }
 739
 740         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 741         {
 742                 .entity weaponentity = weaponentities[slot];
 743                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 744                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 745                 else
 746                         this.(weaponentity).m_switchweapon = WEP_Null;
 747                 this.(weaponentity).m_weapon = WEP_Null;
 748                 this.(weaponentity).weaponname = "";
 749                 this.(weaponentity).m_switchingweapon = WEP_Null;
 750                 this.(weaponentity).cnt = -1;
 751         }
 752
 753         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 754
 755         if (CS(this).impulse) ImpulseCommands(this);
 756
 757         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758         {
 759                 .entity weaponentity = weaponentities[slot];
 760                 W_WeaponFrame(this, weaponentity);
 761         }
 762
 763         if (!warmup_stage && !this.alivetime)
 764                 this.alivetime = time;
 765
 766         antilag_clear(this, CS(this));
 767 }
 768
 769 /** Called when a client spawns in the server */
 770 void PutClientInServer(entity this)
 771 {
 772         if (IS_BOT_CLIENT(this)) {
 773                 TRANSMUTE(Player, this);
 774         } else if (IS_REAL_CLIENT(this)) {
 775                 msg_entity = this;
 776                 WriteByte(MSG_ONE, SVC_SETVIEW);
 777                 WriteEntity(MSG_ONE, this);
 778         }
 779         if (game_stopped)
 780                 TRANSMUTE(Observer, this);
 781
 782         SetSpectatee(this, NULL);
 783
 784         // reset player keys
 785         if(PS(this))
 786                 PS(this).itemkeys = 0;
 787
 788         MUTATOR_CALLHOOK(PutClientInServer, this);
 789
 790         if (IS_OBSERVER(this)) {
 791                 PutObserverInServer(this);
 792         } else if (IS_PLAYER(this)) {
 793                 PutPlayerInServer(this);
 794         }
 795 }
 796
 797 // TODO do we need all these fields, or should we stop autodetecting runtime
 798 // changes and just have a console command to update this?
 799 bool ClientInit_SendEntity(entity this, entity to, int sf)
 800 {
 801         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 802         return = true;
 803         msg_entity = to;
 804         // MSG_INIT replacement
 805         // TODO: make easier to use
 806         Registry_send_all();
 807         W_PROP_reload(MSG_ONE, to);
 808         ClientInit_misc(this);
 809         MUTATOR_CALLHOOK(Ent_Init);
 810 }
 811 void ClientInit_misc(entity this)
 812 {
 813         int channel = MSG_ONE;
 814         WriteHeader(channel, ENT_CLIENT_INIT);
 815         WriteByte(channel, g_nexball_meter_period * 32);
 816         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 817         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 818         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 819         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 820         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 821         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 822         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 823         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 824
 825         if(sv_foginterval && world.fog != "")
 826                 WriteString(channel, world.fog);
 827         else
 828                 WriteString(channel, "");
 829         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 830         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 831         WriteByte(channel, serverflags);
 832         WriteCoord(channel, autocvar_g_trueaim_minrange);
 833 }
 834
 835 void ClientInit_CheckUpdate(entity this)
 836 {
 837         this.nextthink = time;
 838         if(this.count != autocvar_g_balance_armor_blockpercent)
 839         {
 840                 this.count = autocvar_g_balance_armor_blockpercent;
 841                 this.SendFlags |= 1;
 842         }
 843         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 844         {
 845                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 846                 this.SendFlags |= 1;
 847         }
 848 }
 849
 850 void ClientInit_Spawn()
 851 {
 852         entity e = new_pure(clientinit);
 853         setthink(e, ClientInit_CheckUpdate);
 854         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 855
 856         ClientInit_CheckUpdate(e);
 857 }
 858
 859 /*
 860 =============
 861 SetNewParms
 862 =============
 863 */
 864 void SetNewParms ()
 865 {
 866         // initialize parms for a new player
 867         parm1 = -(86400 * 366);
 868
 869         MUTATOR_CALLHOOK(SetNewParms);
 870 }
 871
 872 /*
 873 =============
 874 SetChangeParms
 875 =============
 876 */
 877 void SetChangeParms (entity this)
 878 {
 879         // save parms for level change
 880         parm1 = CS(this).parm_idlesince - time;
 881
 882         MUTATOR_CALLHOOK(SetChangeParms);
 883 }
 884
 885 /*
 886 =============
 887 DecodeLevelParms
 888 =============
 889 */
 890 void DecodeLevelParms(entity this)
 891 {
 892         // load parms
 893         CS(this).parm_idlesince = parm1;
 894         if (CS(this).parm_idlesince == -(86400 * 366))
 895                 CS(this).parm_idlesince = time;
 896
 897         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 898         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 899
 900         MUTATOR_CALLHOOK(DecodeLevelParms);
 901 }
 902
 903 void FixClientCvars(entity e)
 904 {
 905         // send prediction settings to the client
 906         stuffcmd(e, "\nin_bindmap 0 0\n");
 907         if(autocvar_g_antilag == 3) // client side hitscan
 908                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 909         if(autocvar_sv_gentle)
 910                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 911
 912         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 913         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 914
 915         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 916
 917         MUTATOR_CALLHOOK(FixClientCvars, e);
 918 }
 919
 920 bool findinlist_abbrev(string tofind, string list)
 921 {
 922         if(list == "" || tofind == "")
 923                 return false; // empty list or search, just return
 924
 925         // this function allows abbreviated strings!
 926         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 927         {
 928                 return true;
 929         });
 930
 931         return false;
 932 }
 933
 934 bool PlayerInIPList(entity p, string iplist)
 935 {
 936         // some safety checks (never allow local?)
 937         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 938                 return false;
 939
 940         return findinlist_abbrev(p.netaddress, iplist);
 941 }
 942
 943 bool PlayerInIDList(entity p, string idlist)
 944 {
 945         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 946         if(!p.crypto_idfp)
 947                 return false;
 948
 949         return findinlist_abbrev(p.crypto_idfp, idlist);
 950 }
 951
 952 bool PlayerInList(entity player, string list)
 953 {
 954         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 955 }
 956
 957 #ifdef DP_EXT_PRECONNECT
 958 /*
 959 =============
 960 ClientPreConnect
 961
 962 Called once (not at each match start) when a client begins a connection to the server
 963 =============
 964 */
 965 void ClientPreConnect(entity this)
 966 {
 967         if(autocvar_sv_eventlog)
 968         {
 969                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 970                         this.playerid,
 971                         etof(this),
 972                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 973                 ));
 974         }
 975 }
 976 #endif
 977
 978 string GetClientVersionMessage(entity this)
 979 {
 980         if (CS(this).version_mismatch) {
 981                 if(CS(this).version < autocvar_gameversion) {
 982                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 983                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
 984                 } else {
 985                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 986                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
 987                 }
 988         } else {
 989                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
 990         }
 991 }
 992
 993 string getwelcomemessage(entity this)
 994 {
 995         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 996         string modifications = M_ARGV(0, string);
 997
 998         if(g_weaponarena)
 999         {
1000                 if(g_weaponarena_random)
1001                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1002                 else
1003                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1004         }
1005         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1006                 modifications = strcat(modifications, ", No start weapons");
1007         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1008                 modifications = strcat(modifications, ", Low gravity");
1009         if(g_weapon_stay && !g_cts)
1010                 modifications = strcat(modifications, ", Weapons stay");
1011         if(g_jetpack)
1012                 modifications = strcat(modifications, ", Jet pack");
1013         if(autocvar_g_powerups == 0)
1014                 modifications = strcat(modifications, ", No powerups");
1015         if(autocvar_g_powerups > 0)
1016                 modifications = strcat(modifications, ", Powerups");
1017         modifications = substring(modifications, 2, strlen(modifications) - 2);
1018
1019         string versionmessage = GetClientVersionMessage(this);
1020         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1021
1022         if(modifications != "")
1023                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1024
1025         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1026         {
1027                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1028                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1029         }
1030
1031         if (cache_mutatormsg != "") {
1032                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1033         }
1034
1035         string mutator_msg = "";
1036         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1037         mutator_msg = M_ARGV(0, string);
1038
1039         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1040
1041         string motd = autocvar_sv_motd;
1042         if (motd != "") {
1043                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1044         }
1045         return s;
1046 }
1047
1048 /**
1049 =============
1050 ClientConnect
1051
1052 Called when a client connects to the server
1053 =============
1054 */
1055 void ClientConnect(entity this)
1056 {
1057         if (Ban_MaybeEnforceBanOnce(this)) return;
1058         assert(!IS_CLIENT(this), return);
1059         this.flags |= FL_CLIENT;
1060         assert(player_count >= 0, player_count = 0);
1061
1062 #ifdef WATERMARK
1063         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1064 #endif
1065         TRANSMUTE(Client, this);
1066         CS(this).version_nagtime = time + 10 + random() * 10;
1067
1068         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1069
1070         bot_clientconnect(this);
1071
1072         Player_DetermineForcedTeam(this);
1073
1074         TRANSMUTE(Observer, this);
1075
1076         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1077
1078         // always track bots, don't ask for cl_allow_uidtracking
1079         if (IS_BOT_CLIENT(this))
1080                 PlayerStats_GameReport_AddPlayer(this);
1081         else
1082                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1083
1084         if (autocvar_sv_eventlog)
1085                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1086
1087         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1088
1089         stuffcmd(this, clientstuff, "\n");
1090         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1091
1092         FixClientCvars(this);
1093
1094         // get version info from player
1095         stuffcmd(this, "cmd clientversion $gameversion\n");
1096
1097         // notify about available teams
1098         if (teamplay)
1099         {
1100                 entity balance = TeamBalance_CheckAllowedTeams(this);
1101                 int t = TeamBalance_GetAllowedTeams(balance);
1102                 TeamBalance_Destroy(balance);
1103                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1104         }
1105         else
1106         {
1107                 stuffcmd(this, "set _teams_available 0\n");
1108         }
1109
1110         bot_relinkplayerlist();
1111
1112         CS(this).spectatortime = time;
1113         if (blockSpectators)
1114         {
1115                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1116         }
1117
1118         CS(this).jointime = time;
1119
1120         if (IS_REAL_CLIENT(this))
1121         {
1122                 if (g_weaponarena_weapons == WEPSET(TUBA))
1123                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1124         }
1125
1126         if (!sv_foginterval && world.fog != "")
1127                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1128
1129         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1130                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1131                         send_CSQC_teamnagger();
1132
1133         CSQCMODEL_AUTOINIT(this);
1134
1135         CS(this).model_randomizer = random();
1136
1137         if (IS_REAL_CLIENT(this))
1138                 sv_notice_join(this);
1139
1140         // update physics stats (players can spawn before physics runs)
1141         Physics_UpdateStats(this);
1142
1143         IL_EACH(g_initforplayer, it.init_for_player, {
1144                 it.init_for_player(it, this);
1145         });
1146
1147         Handicap_Initialize(this);
1148
1149         MUTATOR_CALLHOOK(ClientConnect, this);
1150
1151         if (IS_REAL_CLIENT(this))
1152         {
1153                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1154                 {
1155                         CS(this).motd_actived_time = -1;
1156                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1157                 }
1158         }
1159 }
1160 /*
1161 =============
1162 ClientDisconnect
1163
1164 Called when a client disconnects from the server
1165 =============
1166 */
1167 .entity chatbubbleentity;
1168 void ClientDisconnect(entity this)
1169 {
1170         assert(IS_CLIENT(this), return);
1171
1172         PlayerStats_GameReport_FinalizePlayer(this);
1173         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1174         if (CS(this).active_minigame) part_minigame(this);
1175         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1176
1177         if (autocvar_sv_eventlog)
1178                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1179
1180         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1181
1182         if(IS_SPEC(this))
1183                 SetSpectatee(this, NULL);
1184
1185     MUTATOR_CALLHOOK(ClientDisconnect, this);
1186
1187         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1188         strfree(CS(this).weaponorder_byimpulse);
1189         ClientState_detach(this);
1190
1191         Portal_ClearAll(this);
1192
1193         Unfreeze(this);
1194
1195         RemoveGrapplingHooks(this);
1196
1197         // Here, everything has been done that requires this player to be a client.
1198
1199         this.flags &= ~FL_CLIENT;
1200
1201         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1202         if (this.killindicator) delete(this.killindicator);
1203
1204         WaypointSprite_PlayerGone(this);
1205
1206         bot_relinkplayerlist();
1207
1208         strfree(this.clientstatus);
1209         if (this.personal) delete(this.personal);
1210
1211         this.playerid = 0;
1212         ReadyCount();
1213         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1214
1215         ONREMOVE(this);
1216 }
1217
1218 void ChatBubbleThink(entity this)
1219 {
1220         this.nextthink = time;
1221         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1222         {
1223                 if(this.owner) // but why can that ever be NULL?
1224                         this.owner.chatbubbleentity = NULL;
1225                 delete(this);
1226                 return;
1227         }
1228
1229         this.mdl = "";
1230
1231         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1232         {
1233                 if ( CS(this.owner).active_minigame )
1234                         this.mdl = "models/sprites/minigame_busy.iqm";
1235                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1236                         this.mdl = "models/misc/chatbubble.spr";
1237         }
1238
1239         if ( this.model != this.mdl )
1240                 _setmodel(this, this.mdl);
1241
1242 }
1243
1244 void UpdateChatBubble(entity this)
1245 {
1246         if (this.alpha < 0)
1247                 return;
1248         // spawn a chatbubble entity if needed
1249         if (!this.chatbubbleentity)
1250         {
1251                 this.chatbubbleentity = new(chatbubbleentity);
1252                 this.chatbubbleentity.owner = this;
1253                 this.chatbubbleentity.exteriormodeltoclient = this;
1254                 setthink(this.chatbubbleentity, ChatBubbleThink);
1255                 this.chatbubbleentity.nextthink = time;
1256                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1257                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1258                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1259                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1260                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1261                 //this.chatbubbleentity.model = "";
1262                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1263         }
1264 }
1265
1266
1267 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1268 // added to the model skins
1269 /*void UpdateColorModHack()
1270 {
1271         float c;
1272         c = this.clientcolors & 15;
1273         // LordHavoc: only bothering to support white, green, red, yellow, blue
1274              if (!teamplay) this.colormod = '0 0 0';
1275         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1276         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1277         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1278         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1279         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1280         else this.colormod = '1 1 1';
1281 }*/
1282
1283 void respawn(entity this)
1284 {
1285         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1286         {
1287                 this.solid = SOLID_NOT;
1288                 this.takedamage = DAMAGE_NO;
1289                 set_movetype(this, MOVETYPE_FLY);
1290                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1291                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1292                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1293                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1294                 if(autocvar_g_respawn_ghosts_maxtime)
1295                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1296         }
1297
1298         CopyBody(this, 1);
1299
1300         this.effects |= EF_NODRAW; // prevent another CopyBody
1301         PutClientInServer(this);
1302 }
1303
1304 void PrintToChat(entity client, string text)
1305 {
1306         text = strcat("\{1}^7", text, "\n");
1307         sprint(client, text);
1308 }
1309
1310 void DebugPrintToChat(entity client, string text)
1311 {
1312         if (autocvar_developer)
1313         {
1314                 PrintToChat(client, text);
1315         }
1316 }
1317
1318 void PrintToChatAll(string text)
1319 {
1320         text = strcat("\{1}^7", text, "\n");
1321         bprint(text);
1322 }
1323
1324 void DebugPrintToChatAll(string text)
1325 {
1326         if (autocvar_developer)
1327         {
1328                 PrintToChatAll(text);
1329         }
1330 }
1331
1332 void PrintToChatTeam(int team_num, string text)
1333 {
1334         text = strcat("\{1}^7", text, "\n");
1335         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1336         {
1337                 if (it.team == team_num)
1338                 {
1339                         sprint(it, text);
1340                 }
1341         });
1342 }
1343
1344 void DebugPrintToChatTeam(int team_num, string text)
1345 {
1346         if (autocvar_developer)
1347         {
1348                 PrintToChatTeam(team_num, text);
1349         }
1350 }
1351
1352 void play_countdown(entity this, float finished, Sound samp)
1353 {
1354         TC(Sound, samp);
1355         if(IS_REAL_CLIENT(this))
1356                 if(floor(finished - time - frametime) != floor(finished - time))
1357                         if(finished - time < 6)
1358                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1359 }
1360
1361 void player_powerups(entity this)
1362 {
1363         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1364         int items_prev = this.items;
1365
1366         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1367                 this.modelflags |= MF_ROCKET;
1368         else
1369                 this.modelflags &= ~MF_ROCKET;
1370
1371         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1372
1373         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1374                 return;
1375
1376         Fire_ApplyDamage(this);
1377         Fire_ApplyEffect(this);
1378
1379         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1380         {
1381                 if (this.items & ITEM_Strength.m_itemid)
1382                 {
1383                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1384                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1385                         if (time > this.strength_finished)
1386                         {
1387                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1388                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1389                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1390                         }
1391                 }
1392                 else
1393                 {
1394                         if (time < this.strength_finished)
1395                         {
1396                                 this.items = this.items | ITEM_Strength.m_itemid;
1397                                 if(!g_cts)
1398                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1399                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1400                         }
1401                 }
1402                 if (this.items & ITEM_Shield.m_itemid)
1403                 {
1404                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1405                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1406                         if (time > this.invincible_finished)
1407                         {
1408                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1409                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1410                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1411                         }
1412                 }
1413                 else
1414                 {
1415                         if (time < this.invincible_finished)
1416                         {
1417                                 this.items = this.items | ITEM_Shield.m_itemid;
1418                                 if(!g_cts)
1419                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1420                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1421                         }
1422                 }
1423                 if (this.items & IT_SUPERWEAPON)
1424                 {
1425                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1426                         {
1427                                 this.superweapons_finished = 0;
1428                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1429                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1430                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1431                         }
1432                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1433                         {
1434                                 // don't let them run out
1435                         }
1436                         else
1437                         {
1438                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1439                                 if (time > this.superweapons_finished)
1440                                 {
1441                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1442                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1443                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1444                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1445                                 }
1446                         }
1447                 }
1448                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1449                 {
1450                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1451                         {
1452                                 this.items = this.items | IT_SUPERWEAPON;
1453                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1454                                 {
1455                                         if(!g_cts)
1456                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1457                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1458                                 }
1459                         }
1460                         else
1461                         {
1462                                 this.superweapons_finished = 0;
1463                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1464                         }
1465                 }
1466                 else
1467                 {
1468                         this.superweapons_finished = 0;
1469                 }
1470         }
1471
1472         if(autocvar_g_nodepthtestplayers)
1473                 this.effects = this.effects | EF_NODEPTHTEST;
1474
1475         if(autocvar_g_fullbrightplayers)
1476                 this.effects = this.effects | EF_FULLBRIGHT;
1477
1478         if (time >= game_starttime)
1479         if (time < this.spawnshieldtime)
1480                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1481
1482         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1483 }
1484
1485 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1486 {
1487         if(current > stable)
1488                 return current;
1489         else if(current > stable - 0.25) // when close enough, "snap"
1490                 return stable;
1491         else
1492                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1493 }
1494
1495 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1496 {
1497         if(current < stable)
1498                 return current;
1499         else if(current < stable + 0.25) // when close enough, "snap"
1500                 return stable;
1501         else
1502                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1503 }
1504
1505 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1506 {
1507         if(current > rotstable)
1508         {
1509                 if(rotframetime > 0)
1510                 {
1511                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1512                         current = max(rotstable, current - rotlinear * rotframetime);
1513                 }
1514         }
1515         else if(current < regenstable)
1516         {
1517                 if(regenframetime > 0)
1518                 {
1519                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1520                         current = min(regenstable, current + regenlinear * regenframetime);
1521                 }
1522         }
1523
1524         if(current > limit)
1525                 current = limit;
1526
1527         return current;
1528 }
1529
1530 void player_regen(entity this)
1531 {
1532         float max_mod, regen_mod, rot_mod, limit_mod;
1533         max_mod = regen_mod = rot_mod = limit_mod = 1;
1534
1535         float regen_health = autocvar_g_balance_health_regen;
1536         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1537         float regen_health_rot = autocvar_g_balance_health_rot;
1538         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1539         float regen_health_stable = autocvar_g_balance_health_regenstable;
1540         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1541         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1542                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1543         max_mod = M_ARGV(1, float);
1544         regen_mod = M_ARGV(2, float);
1545         rot_mod = M_ARGV(3, float);
1546         limit_mod = M_ARGV(4, float);
1547         regen_health = M_ARGV(5, float);
1548         regen_health_linear = M_ARGV(6, float);
1549         regen_health_rot = M_ARGV(7, float);
1550         regen_health_rotlinear = M_ARGV(8, float);
1551         regen_health_stable = M_ARGV(9, float);
1552         regen_health_rotstable = M_ARGV(10, float);
1553
1554         if(!mutator_returnvalue)
1555         if(!STAT(FROZEN, this))
1556         {
1557                 float mina, maxa, limith, limita;
1558                 maxa = autocvar_g_balance_armor_rotstable;
1559                 mina = autocvar_g_balance_armor_regenstable;
1560                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1561                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1562
1563                 regen_health_rotstable = regen_health_rotstable * max_mod;
1564                 regen_health_stable = regen_health_stable * max_mod;
1565                 limith = limith * limit_mod;
1566                 limita = limita * limit_mod;
1567
1568                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1569                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1570                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1571                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1572                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1573                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1574         }
1575
1576         // if player rotted to death...  die!
1577         // check this outside above checks, as player may still be able to rot to death
1578         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1579         {
1580                 if(this.vehicle)
1581                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1582                 if(this.event_damage)
1583                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1584         }
1585
1586         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1587         {
1588                 float minf, maxf, limitf;
1589
1590                 maxf = autocvar_g_balance_fuel_rotstable;
1591                 minf = autocvar_g_balance_fuel_regenstable;
1592                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1593
1594                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1595                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1596                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1597         }
1598 }
1599
1600 bool zoomstate_set;
1601 void SetZoomState(entity this, float newzoom)
1602 {
1603         if(newzoom != CS(this).zoomstate)
1604         {
1605                 CS(this).zoomstate = newzoom;
1606                 ClientData_Touch(this);
1607         }
1608         zoomstate_set = true;
1609 }
1610
1611 void GetPressedKeys(entity this)
1612 {
1613         MUTATOR_CALLHOOK(GetPressedKeys, this);
1614         int keys = STAT(PRESSED_KEYS, this);
1615         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1616         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1617         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1618         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1619
1620         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1621         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1622         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1623         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1624         CS(this).pressedkeys = keys; // store for other users
1625
1626         STAT(PRESSED_KEYS, this) = keys;
1627 }
1628
1629 /*
1630 ======================
1631 spectate mode routines
1632 ======================
1633 */
1634
1635 void SpectateCopy(entity this, entity spectatee)
1636 {
1637         TC(Client, this); TC(Client, spectatee);
1638
1639         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1640         PS(this) = PS(spectatee);
1641         this.armortype = spectatee.armortype;
1642         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1643         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1644         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1645         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1646         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1647         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1648         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1649         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1650         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1651         CS(this).impulse = 0;
1652         this.items = spectatee.items;
1653         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1654         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1655         this.strength_finished = spectatee.strength_finished;
1656         this.invincible_finished = spectatee.invincible_finished;
1657         this.superweapons_finished = spectatee.superweapons_finished;
1658         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1659         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1660         this.punchangle = spectatee.punchangle;
1661         this.view_ofs = spectatee.view_ofs;
1662         this.velocity = spectatee.velocity;
1663         this.dmg_take = spectatee.dmg_take;
1664         this.dmg_save = spectatee.dmg_save;
1665         this.dmg_inflictor = spectatee.dmg_inflictor;
1666         this.v_angle = spectatee.v_angle;
1667         this.angles = spectatee.v_angle;
1668         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1669         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1670         this.viewloc = spectatee.viewloc;
1671         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1672                 this.fixangle = true;
1673         setorigin(this, spectatee.origin);
1674         setsize(this, spectatee.mins, spectatee.maxs);
1675         SetZoomState(this, CS(spectatee).zoomstate);
1676
1677     anticheat_spectatecopy(this, spectatee);
1678         STAT(HUD, this) = STAT(HUD, spectatee);
1679         if(spectatee.vehicle)
1680     {
1681         this.angles = spectatee.v_angle;
1682
1683         //this.fixangle = false;
1684         //this.velocity = spectatee.vehicle.velocity;
1685         this.vehicle_health = spectatee.vehicle_health;
1686         this.vehicle_shield = spectatee.vehicle_shield;
1687         this.vehicle_energy = spectatee.vehicle_energy;
1688         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1689         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1690         this.vehicle_reload1 = spectatee.vehicle_reload1;
1691         this.vehicle_reload2 = spectatee.vehicle_reload2;
1692
1693         //msg_entity = this;
1694
1695        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1696             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1697            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1698            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1699
1700         //WriteByte (MSG_ONE, SVC_SETVIEW);
1701         //    WriteEntity(MSG_ONE, this);
1702         //makevectors(spectatee.v_angle);
1703         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1704     }
1705 }
1706
1707 bool SpectateUpdate(entity this)
1708 {
1709         if(!this.enemy)
1710                 return false;
1711
1712         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1713         {
1714                 SetSpectatee(this, NULL);
1715                 return false;
1716         }
1717
1718         SpectateCopy(this, this.enemy);
1719
1720         return true;
1721 }
1722
1723 bool SpectateSet(entity this)
1724 {
1725         if(!IS_PLAYER(this.enemy))
1726                 return false;
1727
1728         ClientData_Touch(this.enemy);
1729
1730         msg_entity = this;
1731         WriteByte(MSG_ONE, SVC_SETVIEW);
1732         WriteEntity(MSG_ONE, this.enemy);
1733         set_movetype(this, MOVETYPE_NONE);
1734         accuracy_resend(this);
1735
1736         if(!SpectateUpdate(this))
1737                 PutObserverInServer(this);
1738
1739         return true;
1740 }
1741
1742 void SetSpectatee_status(entity this, int spectatee_num)
1743 {
1744         int oldspectatee_status = CS(this).spectatee_status;
1745         CS(this).spectatee_status = spectatee_num;
1746
1747         if (CS(this).spectatee_status != oldspectatee_status)
1748         {
1749                 ClientData_Touch(this);
1750                 if (g_race || g_cts) race_InitSpectator();
1751         }
1752 }
1753
1754 void SetSpectatee(entity this, entity spectatee)
1755 {
1756         if(IS_BOT_CLIENT(this))
1757                 return; // bots abuse .enemy, this code is useless to them
1758
1759         entity old_spectatee = this.enemy;
1760
1761         this.enemy = spectatee;
1762
1763         // WEAPONTODO
1764         // these are required to fix the spectator bug with arc
1765         if(old_spectatee)
1766         {
1767                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1768                 {
1769                         .entity weaponentity = weaponentities[slot];
1770                         if(old_spectatee.(weaponentity).arc_beam)
1771                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1772                 }
1773         }
1774         if(this.enemy)
1775         {
1776                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1777                 {
1778                         .entity weaponentity = weaponentities[slot];
1779                         if(this.enemy.(weaponentity).arc_beam)
1780                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1781                 }
1782         }
1783
1784         if (this.enemy)
1785                 SetSpectatee_status(this, etof(this.enemy));
1786
1787         // needed to update spectator list
1788         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1789 }
1790
1791 bool Spectate(entity this, entity pl)
1792 {
1793         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1794                 return false;
1795         pl = M_ARGV(1, entity);
1796
1797         SetSpectatee(this, pl);
1798         return SpectateSet(this);
1799 }
1800
1801 bool SpectateNext(entity this)
1802 {
1803         entity ent = find(this.enemy, classname, STR_PLAYER);
1804
1805         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1806                 ent = M_ARGV(1, entity);
1807         else if (!ent)
1808                 ent = find(ent, classname, STR_PLAYER);
1809
1810         if(ent) { SetSpectatee(this, ent); }
1811
1812         return SpectateSet(this);
1813 }
1814
1815 bool SpectatePrev(entity this)
1816 {
1817         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1818         entity ent = findchain(classname, STR_PLAYER);
1819         if (!ent) // no player
1820                 return false;
1821
1822         entity first = ent;
1823         // skip players until current spectated player
1824         if(this.enemy)
1825         while(ent && ent != this.enemy)
1826                 ent = ent.chain;
1827
1828         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1829         {
1830                 case MUT_SPECPREV_FOUND:
1831                     ent = M_ARGV(1, entity);
1832                     break;
1833                 case MUT_SPECPREV_RETURN:
1834                     return true;
1835                 case MUT_SPECPREV_CONTINUE:
1836                 default:
1837                 {
1838                         if(ent.chain)
1839                                 ent = ent.chain;
1840                         else
1841                                 ent = first;
1842                         break;
1843                 }
1844         }
1845
1846         SetSpectatee(this, ent);
1847         return SpectateSet(this);
1848 }
1849
1850 /*
1851 =============
1852 ShowRespawnCountdown()
1853
1854 Update a respawn countdown display.
1855 =============
1856 */
1857 void ShowRespawnCountdown(entity this)
1858 {
1859         float number;
1860         if(!IS_DEAD(this)) // just respawned?
1861                 return;
1862         else
1863         {
1864                 number = ceil(this.respawn_time - time);
1865                 if(number <= 0)
1866                         return;
1867                 if(number <= this.respawn_countdown)
1868                 {
1869                         this.respawn_countdown = number - 1;
1870                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1871                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1872                 }
1873         }
1874 }
1875
1876 .bool team_selected;
1877 bool ShowTeamSelection(entity this)
1878 {
1879         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1880                 return false;
1881         stuffcmd(this, "menu_showteamselect\n");
1882         return true;
1883 }
1884 void Join(entity this)
1885 {
1886         TRANSMUTE(Player, this);
1887
1888         if(!this.team_selected)
1889         if(autocvar_g_campaign || autocvar_g_balance_teams)
1890                 TeamBalance_JoinBestTeam(this);
1891
1892         if(autocvar_g_campaign)
1893                 campaign_bots_may_start = true;
1894
1895         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1896
1897         PutClientInServer(this);
1898
1899         if(IS_PLAYER(this))
1900         if(teamplay && this.team != -1)
1901         {
1902         }
1903         else
1904                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1905         this.team_selected = false;
1906 }
1907
1908 /**
1909  * Determines whether the player is allowed to join. This depends on cvar
1910  * g_maxplayers, if it isn't used this function always return true, otherwise
1911  * it checks whether the number of currently playing players exceeds g_maxplayers.
1912  * @return int number of free slots for players, 0 if none
1913  */
1914 int nJoinAllowed(entity this, entity ignore)
1915 {
1916         if(!ignore)
1917         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1918         // so report 0 free slots if restricted
1919         {
1920                 if(autocvar_g_forced_team_otherwise == "spectate")
1921                         return 0;
1922                 if(autocvar_g_forced_team_otherwise == "spectator")
1923                         return 0;
1924         }
1925
1926         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1927                 return 0; // forced spectators can never join
1928
1929         // TODO simplify this
1930         int totalClients = 0;
1931         int currentlyPlaying = 0;
1932         FOREACH_CLIENT(true, {
1933                 if(it != ignore)
1934                         ++totalClients;
1935                 if(IS_REAL_CLIENT(it))
1936                 if(IS_PLAYER(it) || it.caplayer)
1937                         ++currentlyPlaying;
1938         });
1939
1940         float free_slots = 0;
1941         if (!autocvar_g_maxplayers)
1942                 free_slots = maxclients - totalClients;
1943         else if(currentlyPlaying < autocvar_g_maxplayers)
1944                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1945
1946         static float join_prevent_msg_time = 0;
1947         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1948         {
1949                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1950                 join_prevent_msg_time = time + 3;
1951         }
1952
1953         return free_slots;
1954 }
1955
1956 /**
1957  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1958  * g_maxplayers_spectator_blocktime seconds
1959  */
1960 void checkSpectatorBlock(entity this)
1961 {
1962         if(IS_SPEC(this) || IS_OBSERVER(this))
1963         if(!this.caplayer)
1964         if(IS_REAL_CLIENT(this))
1965         {
1966                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1967                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1968                         dropclient(this);
1969                 }
1970         }
1971 }
1972
1973 void PrintWelcomeMessage(entity this)
1974 {
1975         if(CS(this).motd_actived_time == 0)
1976         {
1977                 if (autocvar_g_campaign) {
1978                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1979                                 CS(this).motd_actived_time = time;
1980                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1981                         }
1982                 } else {
1983                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1984                                 CS(this).motd_actived_time = time;
1985                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1986                         }
1987                 }
1988         }
1989         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
1990         {
1991                 if (autocvar_g_campaign) {
1992                         if (PHYS_INPUT_BUTTON_INFO(this))
1993                                 CS(this).motd_actived_time = time;
1994                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1995                                 CS(this).motd_actived_time = 0;
1996                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1997                         }
1998                 } else {
1999                         if (PHYS_INPUT_BUTTON_INFO(this))
2000                                 CS(this).motd_actived_time = time;
2001                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2002                                 CS(this).motd_actived_time = 0;
2003                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2004                         }
2005                 }
2006         }
2007         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2008         {
2009                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2010                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2011                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2012                 {
2013                         // instanctly hide MOTD
2014                         CS(this).motd_actived_time = 0;
2015                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2016                 }
2017         }
2018 }
2019
2020 const int MIN_SPEC_TIME = 1;
2021 bool joinAllowed(entity this)
2022 {
2023         if (CS(this).version_mismatch) return false;
2024         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2025         if (!nJoinAllowed(this, this)) return false;
2026         if (teamplay && lockteams) return false;
2027         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2028         if (ShowTeamSelection(this)) return false;
2029         return true;
2030 }
2031
2032 .int items_added;
2033 .string shootfromfixedorigin;
2034 bool PlayerThink(entity this)
2035 {
2036         if (game_stopped || intermission_running) {
2037                 this.modelflags &= ~MF_ROCKET;
2038                 if(intermission_running)
2039                         IntermissionThink(this);
2040                 return false;
2041         }
2042
2043         if (timeout_status == TIMEOUT_ACTIVE) {
2044         // don't allow the player to turn around while game is paused
2045                 // FIXME turn this into CSQC stuff
2046                 this.v_angle = this.lastV_angle;
2047                 this.angles = this.lastV_angle;
2048                 this.fixangle = true;
2049         }
2050
2051         if (frametime) player_powerups(this);
2052
2053         if (IS_DEAD(this)) {
2054                 if (this.personal && g_race_qualifying) {
2055                         if (time > this.respawn_time) {
2056                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2057                                 respawn(this);
2058                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2059                         }
2060                 } else {
2061                         if (frametime) player_anim(this);
2062
2063                         if (this.respawn_flags & RESPAWN_DENY)
2064                         {
2065                                 STAT(RESPAWN_TIME, this) = 0;
2066                                 return false;
2067                         }
2068
2069                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2070
2071                         switch(this.deadflag)
2072                         {
2073                                 case DEAD_DYING:
2074                                 {
2075                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2076                                                 this.deadflag = DEAD_RESPAWNING;
2077                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2078                                                 this.deadflag = DEAD_DEAD;
2079                                         break;
2080                                 }
2081                                 case DEAD_DEAD:
2082                                 {
2083                                         if (button_pressed)
2084                                                 this.deadflag = DEAD_RESPAWNABLE;
2085                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2086                                                 this.deadflag = DEAD_RESPAWNING;
2087                                         break;
2088                                 }
2089                                 case DEAD_RESPAWNABLE:
2090                                 {
2091                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2092                                                 this.deadflag = DEAD_RESPAWNING;
2093                                         break;
2094                                 }
2095                                 case DEAD_RESPAWNING:
2096                                 {
2097                                         if (time > this.respawn_time)
2098                                         {
2099                                                 this.respawn_time = time + 1; // only retry once a second
2100                                                 this.respawn_time_max = this.respawn_time;
2101                                                 respawn(this);
2102                                         }
2103                                         break;
2104                                 }
2105                         }
2106
2107                         ShowRespawnCountdown(this);
2108
2109                         if (this.respawn_flags & RESPAWN_SILENT)
2110                                 STAT(RESPAWN_TIME, this) = 0;
2111                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2112                         {
2113                                 if (time < this.respawn_time)
2114                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2115                                 else if (this.deadflag != DEAD_RESPAWNING)
2116                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2117                         }
2118                         else
2119                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2120                 }
2121
2122                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2123                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2124                         STAT(RESPAWN_TIME, this) *= -1;
2125
2126                 return false;
2127         }
2128
2129         FixPlayermodel(this);
2130
2131         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2132                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2133                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2134         }
2135
2136         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2137         //if(frametime)
2138         {
2139                 this.items &= ~this.items_added;
2140
2141                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2142                 {
2143                         .entity weaponentity = weaponentities[slot];
2144                         W_WeaponFrame(this, weaponentity);
2145                 }
2146
2147                 this.items_added = 0;
2148                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2149             this.items_added |= IT_FUEL;
2150
2151                 this.items |= this.items_added;
2152         }
2153
2154         player_regen(this);
2155
2156         // WEAPONTODO: Add a weapon request for this
2157         // rot vortex charge to the charge limit
2158         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2159         {
2160                 .entity weaponentity = weaponentities[slot];
2161                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2162                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2163         }
2164
2165         if (frametime) player_anim(this);
2166
2167         // secret status
2168         secrets_setstatus(this);
2169
2170         // monsters status
2171         monsters_setstatus(this);
2172
2173         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2174
2175         return true;
2176 }
2177
2178 .bool would_spectate;
2179 void ObserverThink(entity this)
2180 {
2181         if ( CS(this).impulse )
2182         {
2183                 MinigameImpulse(this, CS(this).impulse);
2184                 CS(this).impulse = 0;
2185         }
2186
2187         if (this.flags & FL_JUMPRELEASED) {
2188                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2189                         this.flags &= ~FL_JUMPRELEASED;
2190                         this.flags |= FL_SPAWNING;
2191                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2192                         this.flags &= ~FL_JUMPRELEASED;
2193                         if(SpectateNext(this)) {
2194                                 TRANSMUTE(Spectator, this);
2195                         }
2196                 } else {
2197                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2198                         set_movetype(this, preferred_movetype);
2199                 }
2200         } else {
2201                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2202                         this.flags |= FL_JUMPRELEASED;
2203                         if(this.flags & FL_SPAWNING)
2204                         {
2205                                 this.flags &= ~FL_SPAWNING;
2206                                 Join(this);
2207                                 return;
2208                         }
2209                 }
2210         }
2211 }
2212
2213 void SpectatorThink(entity this)
2214 {
2215         if ( CS(this).impulse )
2216         {
2217                 if(MinigameImpulse(this, CS(this).impulse))
2218                         CS(this).impulse = 0;
2219
2220                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2221                 {
2222                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2223                         CS(this).impulse = 0;
2224                         return;
2225                 }
2226         }
2227
2228         if (this.flags & FL_JUMPRELEASED) {
2229                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2230                         this.flags &= ~FL_JUMPRELEASED;
2231                         this.flags |= FL_SPAWNING;
2232                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2233                         this.flags &= ~FL_JUMPRELEASED;
2234                         if(SpectateNext(this)) {
2235                                 TRANSMUTE(Spectator, this);
2236                         } else {
2237                                 TRANSMUTE(Observer, this);
2238                                 PutClientInServer(this);
2239                         }
2240                         CS(this).impulse = 0;
2241                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2242                         this.flags &= ~FL_JUMPRELEASED;
2243                         if(SpectatePrev(this)) {
2244                                 TRANSMUTE(Spectator, this);
2245                         } else {
2246                                 TRANSMUTE(Observer, this);
2247                                 PutClientInServer(this);
2248                         }
2249                         CS(this).impulse = 0;
2250                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2251                         this.would_spectate = false;
2252                         this.flags &= ~FL_JUMPRELEASED;
2253                         TRANSMUTE(Observer, this);
2254                         PutClientInServer(this);
2255                 } else {
2256                         if(!SpectateUpdate(this))
2257                         {
2258                                 if(!SpectateNext(this))
2259                                 {
2260                                         PutObserverInServer(this);
2261                                         this.would_spectate = true;
2262                                 }
2263                         }
2264                 }
2265         } else {
2266                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2267                         this.flags |= FL_JUMPRELEASED;
2268                         if(this.flags & FL_SPAWNING)
2269                         {
2270                                 this.flags &= ~FL_SPAWNING;
2271                                 Join(this);
2272                                 return;
2273                         }
2274                 }
2275                 if(!SpectateUpdate(this))
2276                         PutObserverInServer(this);
2277         }
2278
2279         this.flags |= FL_CLIENT | FL_NOTARGET;
2280 }
2281
2282 void PlayerUseKey(entity this)
2283 {
2284         if (!IS_PLAYER(this))
2285                 return;
2286
2287         if(this.vehicle)
2288         {
2289                 if(!game_stopped)
2290                 {
2291                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2292                         return;
2293                 }
2294         }
2295         else if(autocvar_g_vehicles_enter)
2296         {
2297                 if(!STAT(FROZEN, this))
2298                 if(!IS_DEAD(this))
2299                 if(!game_stopped)
2300                 {
2301                         entity head, closest_target = NULL;
2302                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2303
2304                         while(head) // find the closest acceptable target to enter
2305                         {
2306                                 if(IS_VEHICLE(head))
2307                                 if(!IS_DEAD(head))
2308                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2309                                 if(head.takedamage != DAMAGE_NO)
2310                                 {
2311                                         if(closest_target)
2312                                         {
2313                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2314                                                 { closest_target = head; }
2315                                         }
2316                                         else { closest_target = head; }
2317                                 }
2318
2319                                 head = head.chain;
2320                         }
2321
2322                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2323                 }
2324         }
2325
2326         // a use key was pressed; call handlers
2327         MUTATOR_CALLHOOK(PlayerUseKey, this);
2328 }
2329
2330
2331 /*
2332 =============
2333 PlayerPreThink
2334
2335 Called every frame for each client before the physics are run
2336 =============
2337 */
2338 .float last_vehiclecheck;
2339 void PlayerPreThink (entity this)
2340 {
2341         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2342         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2343
2344         WarpZone_PlayerPhysics_FixVAngle(this);
2345
2346         if (frametime) {
2347                 // physics frames: update anticheat stuff
2348                 anticheat_prethink(this);
2349         }
2350
2351         if (blockSpectators && frametime) {
2352                 // WORKAROUND: only use dropclient in server frames (frametime set).
2353                 // Never use it in cl_movement frames (frametime zero).
2354                 checkSpectatorBlock(this);
2355         }
2356
2357         zoomstate_set = false;
2358
2359         // Check for nameless players
2360         if (this.netname == "" || this.netname != CS(this).netname_previous)
2361         {
2362                 bool assume_unchanged = (CS(this).netname_previous == "");
2363                 if (isInvisibleString(this.netname))
2364                 {
2365                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2366                         assume_unchanged = false;
2367                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2368                 }
2369                 if (!assume_unchanged && autocvar_sv_eventlog)
2370                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2371                 strcpy(CS(this).netname_previous, this.netname);
2372         }
2373
2374         // version nagging
2375         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2376         CS(this).version_nagtime = 0;
2377         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2378             // git client
2379         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2380             // git server
2381             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2382         } else {
2383             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2384             if (r < 0) { // old client
2385                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2386             } else if (r > 0) { // old server
2387                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2388             }
2389         }
2390     }
2391
2392         // GOD MODE info
2393         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2394         {
2395                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2396                 this.max_armorvalue = 0;
2397         }
2398
2399         if(IS_PLAYER(this))
2400         {
2401                 if (STAT(FROZEN, this) == 2)
2402                 {
2403                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2404                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2405                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2406
2407                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2408                                 Unfreeze(this);
2409                 }
2410                 else if (STAT(FROZEN, this) == 3)
2411                 {
2412                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2413                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2414
2415                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2416                         {
2417                                 if (this.vehicle)
2418                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2419                                 if(this.event_damage)
2420                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2421                         }
2422                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2423                                 Unfreeze(this);
2424                 }
2425         }
2426
2427         MUTATOR_CALLHOOK(PlayerPreThink, this);
2428
2429         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2430         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2431         {
2432                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2433                 {
2434                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2435                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2436                         {
2437                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2438                         }
2439                         else if(!it.owner)
2440                         {
2441                                 if(!it.team || SAME_TEAM(this, it))
2442                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2443                                 else if(autocvar_g_vehicles_steal)
2444                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2445                         }
2446                 });
2447
2448                 this.last_vehiclecheck = time + 1;
2449         }
2450
2451         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2452         {
2453                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2454                         PlayerUseKey(this);
2455                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2456         }
2457
2458         if (IS_REAL_CLIENT(this))
2459                 PrintWelcomeMessage(this);
2460
2461         if (IS_PLAYER(this)) {
2462                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2463                         error("Client can't be spawned as player on connection!");
2464                 if(!PlayerThink(this))
2465                         return;
2466         }
2467         else if (game_stopped || intermission_running) {
2468                 if(intermission_running)
2469                         IntermissionThink(this);
2470                 return;
2471         }
2472         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2473         {
2474                 CS(this).autojoin_checked = true;
2475                 // don't do this in ClientConnect
2476                 // many things can go wrong if a client is spawned as player on connection
2477                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2478                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2479                                 && (!teamplay || autocvar_g_balance_teams)))
2480                 {
2481                         campaign_bots_may_start = true;
2482                         Join(this);
2483                         return;
2484                 }
2485         }
2486         else if (IS_OBSERVER(this)) {
2487                 ObserverThink(this);
2488         }
2489         else if (IS_SPEC(this)) {
2490                 SpectatorThink(this);
2491         }
2492
2493         // WEAPONTODO: Add weapon request for this
2494         if (!zoomstate_set) {
2495                 bool wep_zoomed = false;
2496                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2497                 {
2498                         .entity weaponentity = weaponentities[slot];
2499                         Weapon thiswep = this.(weaponentity).m_weapon;
2500                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2501                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2502                 }
2503                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2504     }
2505
2506         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2507         {
2508                 CS(this).teamkill_soundtime = 0;
2509
2510                 entity e = CS(this).teamkill_soundsource;
2511                 entity oldpusher = e.pusher;
2512                 e.pusher = this;
2513                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2514                 e.pusher = oldpusher;
2515         }
2516
2517         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2518                 CS(this).taunt_soundtime = 0;
2519                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2520         }
2521
2522         target_voicescript_next(this);
2523
2524         // WEAPONTODO: Move into weaponsystem somehow
2525         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2526         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2527         {
2528                 .entity weaponentity = weaponentities[slot];
2529                 if(this.(weaponentity).m_weapon == WEP_Null)
2530                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2531         }
2532 }
2533
2534 void DrownPlayer(entity this)
2535 {
2536         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2537                 return;
2538
2539         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2540         {
2541                 if(this.air_finished < time)
2542                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2543                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2544         }
2545         else if (this.air_finished < time)
2546         {       // drown!
2547                 if (this.pain_finished < time)
2548                 {
2549                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2550                         this.pain_finished = time + 0.5;
2551                 }
2552         }
2553 }
2554
2555 .bool move_qcphysics;
2556
2557 void Player_Physics(entity this)
2558 {
2559         set_movetype(this, this.move_movetype);
2560
2561         if(!this.move_qcphysics)
2562                 return;
2563
2564         if(!frametime && !CS(this).pm_frametime)
2565                 return;
2566
2567         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2568
2569         CS(this).pm_frametime = 0;
2570 }
2571
2572 /*
2573 =============
2574 PlayerPostThink
2575
2576 Called every frame for each client after the physics are run
2577 =============
2578 */
2579 void PlayerPostThink (entity this)
2580 {
2581         Player_Physics(this);
2582
2583         if (sv_maxidle > 0)
2584         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2585         if (IS_REAL_CLIENT(this))
2586         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2587         {
2588                 int totalClients = 0;
2589                 if(sv_maxidle_slots > 0)
2590                 {
2591                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2592                         {
2593                                 ++totalClients;
2594                         });
2595                 }
2596
2597                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2598                 { /* do nothing */ }
2599                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2600                 {
2601                         if (CS(this).idlekick_lasttimeleft)
2602                         {
2603                                 CS(this).idlekick_lasttimeleft = 0;
2604                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2605                         }
2606                 }
2607                 else
2608                 {
2609                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2610                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2611                                 if (!CS(this).idlekick_lasttimeleft)
2612                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2613                         }
2614                         if (timeleft <= 0) {
2615                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2616                                 dropclient(this);
2617                                 return;
2618                         }
2619                         else if (timeleft <= 10) {
2620                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2621                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2622                 }
2623                                 CS(this).idlekick_lasttimeleft = timeleft;
2624                         }
2625                 }
2626         }
2627
2628         CheatFrame(this);
2629
2630         if (game_stopped)
2631         {
2632                 this.solid = SOLID_NOT;
2633                 this.takedamage = DAMAGE_NO;
2634                 set_movetype(this, MOVETYPE_NONE);
2635         }
2636
2637         if (IS_PLAYER(this)) {
2638                 if(this.death_time == time && IS_DEAD(this))
2639                 {
2640                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2641                         // once all the damage events of this frame have been processed with normal size
2642                         this.maxs.z = 5;
2643                         setsize(this, this.mins, this.maxs);
2644                 }
2645                 DrownPlayer(this);
2646                 UpdateChatBubble(this);
2647                 if (CS(this).impulse) ImpulseCommands(this);
2648                 if (game_stopped)
2649                 {
2650                         CSQCMODEL_AUTOUPDATE(this);
2651                         return;
2652                 }
2653                 GetPressedKeys(this);
2654         }
2655
2656         if (this.waypointsprite_attachedforcarrier) {
2657             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2658                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2659     }
2660
2661         CSQCMODEL_AUTOUPDATE(this);
2662 }
2663
2664 // hack to copy the button fields from the client entity to the Client State
2665 void PM_UpdateButtons(entity this, entity store)
2666 {
2667         if(this.impulse)
2668                 store.impulse = this.impulse;
2669         this.impulse = 0;
2670
2671         bool typing = this.buttonchat;
2672
2673         store.button0 = (typing) ? 0 : this.button0;
2674         //button1?!
2675         store.button2 = (typing) ? 0 : this.button2;
2676         store.button3 = (typing) ? 0 : this.button3;
2677         store.button4 = this.button4;
2678         store.button5 = (typing) ? 0 : this.button5;
2679         store.button6 = this.button6;
2680         store.button7 = this.button7;
2681         store.button8 = this.button8;
2682         store.button9 = this.button9;
2683         store.button10 = this.button10;
2684         store.button11 = this.button11;
2685         store.button12 = this.button12;
2686         store.button13 = this.button13;
2687         store.button14 = this.button14;
2688         store.button15 = this.button15;
2689         store.button16 = this.button16;
2690         store.buttonuse = this.buttonuse;
2691         store.buttonchat = this.buttonchat;
2692
2693         store.cursor_active = this.cursor_active;
2694         store.cursor_screen = this.cursor_screen;
2695         store.cursor_trace_start = this.cursor_trace_start;
2696         store.cursor_trace_endpos = this.cursor_trace_endpos;
2697         store.cursor_trace_ent = this.cursor_trace_ent;
2698
2699         store.ping = this.ping;
2700         store.ping_packetloss = this.ping_packetloss;
2701         store.ping_movementloss = this.ping_movementloss;
2702
2703         store.v_angle = this.v_angle;
2704         store.movement = (typing) ? '0 0 0' : this.movement;
2705 }
2706
2707 NET_HANDLE(fpsreport, bool)
2708 {
2709         int fps = ReadShort();
2710         PlayerScore_Set(sender, SP_FPS, fps);
2711         return true;
2712 }