qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 #include <common/mutators/mutator/overkill/okvortex.qh>
  60
  61 STATIC_METHOD(Client, Add, void(Client this, int _team))
  62 {
  63     ClientConnect(this);
  64     TRANSMUTE(Player, this);
  65     this.frame = 12; // 7
  66     this.team = _team;
  67     PutClientInServer(this);
  68 }
  69
  70 void PutObserverInServer(entity this);
  71
  72 STATIC_METHOD(Client, Remove, void(Client this))
  73 {
  74     TRANSMUTE(Observer, this);
  75     PutClientInServer(this);
  76     ClientDisconnect(this);
  77 }
  78
  79 void send_CSQC_teamnagger() {
  80         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  81 }
  82
  83 int CountSpectators(entity player, entity to)
  84 {
  85         if(!player) { return 0; } // not sure how, but best to be safe
  86
  87         int spec_count = 0;
  88
  89         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  90         {
  91                 spec_count++;
  92         });
  93
  94         return spec_count;
  95 }
  96
  97 void WriteSpectators(entity player, entity to)
  98 {
  99         if(!player) { return; } // not sure how, but best to be safe
 100
 101         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 102         {
 103                 WriteByte(MSG_ENTITY, num_for_edict(it));
 104         });
 105 }
 106
 107 bool ClientData_Send(entity this, entity to, int sf)
 108 {
 109         assert(to == this.owner, return false);
 110
 111         entity e = to;
 112         if (IS_SPEC(e)) e = e.enemy;
 113
 114         sf = 0;
 115         if (e.race_completed)       sf |= 1; // forced scoreboard
 116         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 117         if (e.zoomstate)            sf |= 4; // zoomed
 118         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 119
 120         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 121         WriteByte(MSG_ENTITY, sf);
 122
 123         if (sf & 2)
 124         {
 125                 WriteByte(MSG_ENTITY, to.spectatee_status);
 126         }
 127
 128         if(sf & 16)
 129         {
 130                 float specs = CountSpectators(e, to);
 131                 WriteByte(MSG_ENTITY, specs);
 132                 WriteSpectators(e, to);
 133         }
 134
 135         return true;
 136 }
 137
 138 void ClientData_Attach(entity this)
 139 {
 140         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 141         this.clientdata.drawonlytoclient = this;
 142         this.clientdata.owner = this;
 143 }
 144
 145 void ClientData_Detach(entity this)
 146 {
 147         delete(this.clientdata);
 148         this.clientdata = NULL;
 149 }
 150
 151 void ClientData_Touch(entity e)
 152 {
 153         e.clientdata.SendFlags = 1;
 154
 155         // make it spectatable
 156         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 157 }
 158
 159 .string netname_previous;
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this) && this.health >= 1) {
 225         // despawn effect
 226                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 227     }
 228
 229     {
 230         entity spot = SelectSpawnPoint(this, true);
 231         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 232         this.angles = spot.angles;
 233         this.angles_z = 0;
 234         this.fixangle = true;
 235         // offset it so that the spectator spawns higher off the ground, looks better this way
 236         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 237         this.prevorigin = this.origin;
 238         if (IS_REAL_CLIENT(this))
 239         {
 240             msg_entity = this;
 241             WriteByte(MSG_ONE, SVC_SETVIEW);
 242             WriteEntity(MSG_ONE, this);
 243         }
 244         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 245         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 246         if(!autocvar_g_debug_globalsounds)
 247         {
 248                 // needed for player sounds
 249                 this.model = "";
 250                 FixPlayermodel(this);
 251         }
 252         setmodel(this, MDL_Null);
 253         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 254         this.view_ofs = '0 0 0';
 255     }
 256
 257     RemoveGrapplingHooks(this);
 258         Portal_ClearAll(this);
 259         Unfreeze(this);
 260         SetSpectatee(this, NULL);
 261
 262         if (this.alivetime)
 263         {
 264                 if (!warmup_stage)
 265                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 266                 this.alivetime = 0;
 267         }
 268
 269         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 270
 271         WaypointSprite_PlayerDead(this);
 272
 273         if (mutator_returnvalue) {
 274             // mutator prevents resetting teams+score
 275         } else {
 276                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 277         this.frags = FRAGS_SPECTATOR;
 278         PlayerScore_Clear(this);  // clear scores when needed
 279     }
 280
 281         if (this.killcount != FRAGS_SPECTATOR)
 282         {
 283                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 284                 if(!game_stopped)
 285                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 286                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 287
 288                 if(this.just_joined == false) {
 289                         LogTeamchange(this.playerid, -1, 4);
 290                 } else
 291                         this.just_joined = false;
 292         }
 293
 294         accuracy_resend(this);
 295
 296         this.spectatortime = time;
 297         if(this.bot_attack)
 298                 IL_REMOVE(g_bot_targets, this);
 299         this.bot_attack = false;
 300     this.hud = HUD_NORMAL;
 301         TRANSMUTE(Observer, this);
 302         this.iscreature = false;
 303         this.teleportable = TELEPORT_SIMPLE;
 304         if(this.damagedbycontents)
 305                 IL_REMOVE(g_damagedbycontents, this);
 306         this.damagedbycontents = false;
 307         this.health = FRAGS_SPECTATOR;
 308         SetSpectatee_status(this, etof(this));
 309         this.takedamage = DAMAGE_NO;
 310         this.solid = SOLID_NOT;
 311         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 312         this.flags = FL_CLIENT | FL_NOTARGET;
 313         this.armorvalue = 666;
 314         this.effects = 0;
 315         this.armorvalue = autocvar_g_balance_armor_start;
 316         this.pauserotarmor_finished = 0;
 317         this.pauserothealth_finished = 0;
 318         this.pauseregen_finished = 0;
 319         this.damageforcescale = 0;
 320         this.death_time = 0;
 321         this.respawn_flags = 0;
 322         this.respawn_time = 0;
 323         this.stat_respawn_time = 0;
 324         this.alpha = 0;
 325         this.scale = 0;
 326         this.fade_time = 0;
 327         this.pain_frame = 0;
 328         this.pain_finished = 0;
 329         this.strength_finished = 0;
 330         this.invincible_finished = 0;
 331         this.superweapons_finished = 0;
 332         this.pushltime = 0;
 333         this.istypefrag = 0;
 334         setthink(this, func_null);
 335         this.nextthink = 0;
 336         this.deadflag = DEAD_NO;
 337         this.crouch = false;
 338         this.revive_progress = 0;
 339         this.revival_time = 0;
 340
 341         this.items = 0;
 342         this.weapons = '0 0 0';
 343         this.drawonlytoclient = this;
 344
 345         this.weaponmodel = "";
 346         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 347         {
 348                 this.weaponentities[slot] = NULL;
 349         }
 350         this.exteriorweaponentity = NULL;
 351         this.killcount = FRAGS_SPECTATOR;
 352         this.velocity = '0 0 0';
 353         this.avelocity = '0 0 0';
 354         this.punchangle = '0 0 0';
 355         this.punchvector = '0 0 0';
 356         this.oldvelocity = this.velocity;
 357         this.fire_endtime = -1;
 358         this.event_damage = func_null;
 359
 360         for(int slot = 0; slot < MAX_AXH; ++slot)
 361         {
 362                 entity axh = this.(AuxiliaryXhair[slot]);
 363                 this.(AuxiliaryXhair[slot]) = NULL;
 364
 365                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 366                         delete(axh);
 367         }
 368 }
 369
 370 int player_getspecies(entity this)
 371 {
 372         get_model_parameters(this.model, this.skin);
 373         int s = get_model_parameters_species;
 374         get_model_parameters(string_null, 0);
 375         if (s < 0) return SPECIES_HUMAN;
 376         return s;
 377 }
 378
 379 .float model_randomizer;
 380 void FixPlayermodel(entity player)
 381 {
 382         string defaultmodel = "";
 383         int defaultskin = 0;
 384         if(autocvar_sv_defaultcharacter)
 385         {
 386                 if(teamplay)
 387                 {
 388                         switch(player.team)
 389                         {
 390                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 391                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 392                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 393                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 394                         }
 395                 }
 396
 397                 if(defaultmodel == "")
 398                 {
 399                         defaultmodel = autocvar_sv_defaultplayermodel;
 400                         defaultskin = autocvar_sv_defaultplayerskin;
 401                 }
 402
 403                 int n = tokenize_console(defaultmodel);
 404                 if(n > 0)
 405                 {
 406                         defaultmodel = argv(floor(n * player.model_randomizer));
 407                         // However, do NOT randomize if the player-selected model is in the list.
 408                         for (int i = 0; i < n; ++i)
 409                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 410                                         defaultmodel = argv(i);
 411                 }
 412
 413                 int i = strstrofs(defaultmodel, ":", 0);
 414                 if(i >= 0)
 415                 {
 416                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 417                         defaultmodel = substring(defaultmodel, 0, i);
 418                 }
 419         }
 420         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 421         {
 422                 if(teamplay)
 423                 {
 424                         switch(player.team)
 425                         {
 426                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 427                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 428                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 429                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 430                         }
 431                 }
 432
 433                 if(!defaultskin)
 434                         defaultskin = autocvar_sv_defaultplayerskin;
 435         }
 436
 437         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 438         defaultmodel = M_ARGV(0, string);
 439         defaultskin = M_ARGV(1, int);
 440
 441         bool chmdl = false;
 442         int oldskin;
 443         if(defaultmodel != "")
 444         {
 445                 if (defaultmodel != player.model)
 446                 {
 447                         vector m1 = player.mins;
 448                         vector m2 = player.maxs;
 449                         setplayermodel (player, defaultmodel);
 450                         setsize (player, m1, m2);
 451                         chmdl = true;
 452                 }
 453
 454                 oldskin = player.skin;
 455                 player.skin = defaultskin;
 456         } else {
 457                 if (player.playermodel != player.model || player.playermodel == "")
 458                 {
 459                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 460                         vector m1 = player.mins;
 461                         vector m2 = player.maxs;
 462                         setplayermodel (player, player.playermodel);
 463                         setsize (player, m1, m2);
 464                         chmdl = true;
 465                 }
 466
 467                 if(!autocvar_sv_defaultcharacterskin)
 468                 {
 469                         oldskin = player.skin;
 470                         player.skin = stof(player.playerskin);
 471                 }
 472                 else
 473                 {
 474                         oldskin = player.skin;
 475                         player.skin = defaultskin;
 476                 }
 477         }
 478
 479         if(chmdl || oldskin != player.skin) // model or skin has changed
 480         {
 481                 player.species = player_getspecies(player); // update species
 482                 if(!autocvar_g_debug_globalsounds)
 483                         UpdatePlayerSounds(player); // update skin sounds
 484         }
 485
 486         if(!teamplay)
 487                 if(strlen(autocvar_sv_defaultplayercolors))
 488                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 489                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 490 }
 491
 492
 493 /** Called when a client spawns in the server */
 494 void PutClientInServer(entity this)
 495 {
 496         if (IS_BOT_CLIENT(this)) {
 497                 TRANSMUTE(Player, this);
 498         } else if (IS_REAL_CLIENT(this)) {
 499                 msg_entity = this;
 500                 WriteByte(MSG_ONE, SVC_SETVIEW);
 501                 WriteEntity(MSG_ONE, this);
 502         }
 503         if (game_stopped)
 504                 TRANSMUTE(Observer, this);
 505
 506         SetSpectatee(this, NULL);
 507
 508         // reset player keys
 509         this.itemkeys = 0;
 510
 511         MUTATOR_CALLHOOK(PutClientInServer, this);
 512
 513         if (IS_OBSERVER(this)) {
 514                 PutObserverInServer(this);
 515         } else if (IS_PLAYER(this)) {
 516                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 517
 518                 PlayerState_attach(this);
 519                 accuracy_resend(this);
 520
 521                 if (this.team < 0)
 522                         JoinBestTeam(this, false, true);
 523
 524                 entity spot = SelectSpawnPoint(this, false);
 525                 if (!spot) {
 526                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 527                         return; // spawn failed
 528                 }
 529
 530                 TRANSMUTE(Player, this);
 531
 532                 this.wasplayer = true;
 533                 this.iscreature = true;
 534                 this.teleportable = TELEPORT_NORMAL;
 535                 if(!this.damagedbycontents)
 536                         IL_PUSH(g_damagedbycontents, this);
 537                 this.damagedbycontents = true;
 538                 set_movetype(this, MOVETYPE_WALK);
 539                 this.solid = SOLID_SLIDEBOX;
 540                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 541                 if (autocvar_g_playerclip_collisions)
 542                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 543                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 544                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 545                 this.frags = FRAGS_PLAYER;
 546                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 547                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 548                 if (autocvar__notarget)
 549                         this.flags |= FL_NOTARGET;
 550                 this.takedamage = DAMAGE_AIM;
 551                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 552                 this.dmg = 2; // WTF
 553
 554                 if (warmup_stage) {
 555                         this.ammo_shells = warmup_start_ammo_shells;
 556                         this.ammo_nails = warmup_start_ammo_nails;
 557                         this.ammo_rockets = warmup_start_ammo_rockets;
 558                         this.ammo_cells = warmup_start_ammo_cells;
 559                         this.ammo_plasma = warmup_start_ammo_plasma;
 560                         this.ammo_fuel = warmup_start_ammo_fuel;
 561                         this.health = warmup_start_health;
 562                         this.armorvalue = warmup_start_armorvalue;
 563                         this.weapons = WARMUP_START_WEAPONS;
 564                 } else {
 565                         this.ammo_shells = start_ammo_shells;
 566                         this.ammo_nails = start_ammo_nails;
 567                         this.ammo_rockets = start_ammo_rockets;
 568                         this.ammo_cells = start_ammo_cells;
 569                         this.ammo_plasma = start_ammo_plasma;
 570                         this.ammo_fuel = start_ammo_fuel;
 571                         this.health = start_health;
 572                         this.armorvalue = start_armorvalue;
 573                         this.weapons = start_weapons;
 574                 }
 575                 SetSpectatee_status(this, 0);
 576
 577                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 578
 579                 this.items = start_items;
 580
 581                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 582                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 583                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 584                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 585                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 586                 // extend the pause of rotting if client was reset at the beginning of the countdown
 587                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 588                         float f = game_starttime - time;
 589                         this.spawnshieldtime += f;
 590                         this.pauserotarmor_finished += f;
 591                         this.pauserothealth_finished += f;
 592                         this.pauseregen_finished += f;
 593                 }
 594                 this.damageforcescale = 2;
 595                 this.death_time = 0;
 596                 this.respawn_flags = 0;
 597                 this.respawn_time = 0;
 598                 this.stat_respawn_time = 0;
 599                 this.scale = autocvar_sv_player_scale;
 600                 this.fade_time = 0;
 601                 this.pain_frame = 0;
 602                 this.pain_finished = 0;
 603                 this.pushltime = 0;
 604                 setthink(this, func_null); // players have no think function
 605                 this.nextthink = 0;
 606                 this.dmg_team = 0;
 607                 this.ballistics_density = autocvar_g_ballistics_density_player;
 608
 609                 this.deadflag = DEAD_NO;
 610
 611                 this.angles = spot.angles;
 612                 this.angles_z = 0; // never spawn tilted even if the spot says to
 613                 if (IS_BOT_CLIENT(this))
 614                         this.v_angle = this.angles;
 615                 this.fixangle = true; // turn this way immediately
 616                 this.oldvelocity = this.velocity = '0 0 0';
 617                 this.avelocity = '0 0 0';
 618                 this.punchangle = '0 0 0';
 619                 this.punchvector = '0 0 0';
 620
 621                 this.strength_finished = 0;
 622                 this.invincible_finished = 0;
 623                 this.fire_endtime = -1;
 624                 this.revive_progress = 0;
 625                 this.revival_time = 0;
 626                 this.air_finished = time + 12;
 627
 628                 entity spawnevent = new_pure(spawnevent);
 629                 spawnevent.owner = this;
 630                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 631
 632                 // Cut off any still running player sounds.
 633                 stopsound(this, CH_PLAYER_SINGLE);
 634
 635                 this.model = "";
 636                 FixPlayermodel(this);
 637                 this.drawonlytoclient = NULL;
 638
 639                 this.viewloc = NULL;
 640
 641                 this.crouch = false;
 642                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 643                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 644                 this.spawnorigin = spot.origin;
 645                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 646                 // don't reset back to last position, even if new position is stuck in solid
 647                 this.oldorigin = this.origin;
 648                 this.prevorigin = this.origin;
 649                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 650                 if(this.conveyor)
 651                         IL_REMOVE(g_conveyed, this);
 652                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 653                 this.hud = HUD_NORMAL;
 654
 655                 this.event_damage = PlayerDamage;
 656
 657                 if(!this.bot_attack)
 658                         IL_PUSH(g_bot_targets, this);
 659                 this.bot_attack = true;
 660                 this.monster_attack = true;
 661                 navigation_dynamicgoal_init(this, false);
 662
 663                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 664
 665                 if (this.killcount == FRAGS_SPECTATOR) {
 666                         PlayerScore_Clear(this);
 667                         this.killcount = 0;
 668                 }
 669
 670                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 671                 {
 672                         .entity weaponentity = weaponentities[slot];
 673                         entity oldwep = this.(weaponentity);
 674                         CL_SpawnWeaponentity(this, weaponentity);
 675                         if(oldwep && oldwep.owner == this)
 676                                 this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 677                 }
 678                 this.alpha = default_player_alpha;
 679                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 680                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 681
 682                 this.speedrunning = false;
 683
 684                 target_voicescript_clear(this);
 685
 686                 // reset fields the weapons may use
 687                 FOREACH(Weapons, true, LAMBDA(
 688                         it.wr_resetplayer(it, this);
 689                         // reload all reloadable weapons
 690                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 691                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 692                                 {
 693                                         .entity weaponentity = weaponentities[slot];
 694                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 695                                 }
 696                         }
 697                 ));
 698
 699                 {
 700                         string s = spot.target;
 701                         spot.target = string_null;
 702                         SUB_UseTargets(spot, this, NULL);
 703                         spot.target = s;
 704                 }
 705
 706                 Unfreeze(this);
 707
 708                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 709
 710                 if (autocvar_spawn_debug)
 711                 {
 712                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 713                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 714                 }
 715
 716                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 717                 {
 718                         .entity weaponentity = weaponentities[slot];
 719                         if(slot == 0)
 720                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 721                         else
 722                                 this.(weaponentity).m_switchweapon = WEP_Null;
 723                         this.(weaponentity).m_weapon = WEP_Null;
 724                         this.(weaponentity).weaponname = "";
 725                         this.(weaponentity).m_switchingweapon = WEP_Null;
 726                         this.(weaponentity).cnt = -1;
 727                 }
 728
 729                 MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 730
 731                 if (!warmup_stage && !this.alivetime)
 732                         this.alivetime = time;
 733
 734                 antilag_clear(this, CS(this));
 735         }
 736 }
 737
 738 void ClientInit_misc(entity this);
 739
 740 // TODO do we need all these fields, or should we stop autodetecting runtime
 741 // changes and just have a console command to update this?
 742 bool ClientInit_SendEntity(entity this, entity to, int sf)
 743 {
 744         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 745         return = true;
 746         msg_entity = to;
 747         // MSG_INIT replacement
 748         // TODO: make easier to use
 749         Registry_send_all();
 750         W_PROP_reload(MSG_ONE, to);
 751         ClientInit_misc(this);
 752         MUTATOR_CALLHOOK(Ent_Init);
 753 }
 754 void ClientInit_misc(entity this)
 755 {
 756         int channel = MSG_ONE;
 757         WriteHeader(channel, ENT_CLIENT_INIT);
 758         WriteByte(channel, g_nexball_meter_period * 32);
 759         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 760         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 761         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 763         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 764         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 765         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 767
 768         if(sv_foginterval && world.fog != "")
 769                 WriteString(channel, world.fog);
 770         else
 771                 WriteString(channel, "");
 772         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 773         WriteByte(channel, serverflags);
 774         WriteCoord(channel, autocvar_g_trueaim_minrange);
 775 }
 776
 777 void ClientInit_CheckUpdate(entity this)
 778 {
 779         this.nextthink = time;
 780         if(this.count != autocvar_g_balance_armor_blockpercent)
 781         {
 782                 this.count = autocvar_g_balance_armor_blockpercent;
 783                 this.SendFlags |= 1;
 784         }
 785 }
 786
 787 void ClientInit_Spawn()
 788 {
 789         entity e = new_pure(clientinit);
 790         setthink(e, ClientInit_CheckUpdate);
 791         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 792
 793         ClientInit_CheckUpdate(e);
 794 }
 795
 796 /*
 797 =============
 798 SetNewParms
 799 =============
 800 */
 801 void SetNewParms ()
 802 {
 803         // initialize parms for a new player
 804         parm1 = -(86400 * 366);
 805
 806         MUTATOR_CALLHOOK(SetNewParms);
 807 }
 808
 809 /*
 810 =============
 811 SetChangeParms
 812 =============
 813 */
 814 void SetChangeParms (entity this)
 815 {
 816         // save parms for level change
 817         parm1 = this.parm_idlesince - time;
 818
 819         MUTATOR_CALLHOOK(SetChangeParms);
 820 }
 821
 822 /*
 823 =============
 824 DecodeLevelParms
 825 =============
 826 */
 827 void DecodeLevelParms(entity this)
 828 {
 829         // load parms
 830         this.parm_idlesince = parm1;
 831         if (this.parm_idlesince == -(86400 * 366))
 832                 this.parm_idlesince = time;
 833
 834         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 835         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 836
 837         MUTATOR_CALLHOOK(DecodeLevelParms);
 838 }
 839
 840 /*
 841 =============
 842 ClientKill
 843
 844 Called when a client types 'kill' in the console
 845 =============
 846 */
 847
 848 .float clientkill_nexttime;
 849 void ClientKill_Now_TeamChange(entity this)
 850 {
 851         if(this.killindicator_teamchange == -1)
 852         {
 853                 JoinBestTeam( this, false, true );
 854         }
 855         else if(this.killindicator_teamchange == -2)
 856         {
 857                 if(blockSpectators)
 858                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 859                 PutObserverInServer(this);
 860         }
 861         else
 862                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 863         this.killindicator_teamchange = 0;
 864 }
 865
 866 void ClientKill_Now(entity this)
 867 {
 868         if(this.vehicle)
 869         {
 870             vehicles_exit(this.vehicle, VHEF_RELEASE);
 871             if(!this.killindicator_teamchange)
 872             {
 873             this.vehicle_health = -1;
 874             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 875             }
 876         }
 877
 878         if(this.killindicator && !wasfreed(this.killindicator))
 879                 delete(this.killindicator);
 880
 881         this.killindicator = NULL;
 882
 883         if(this.killindicator_teamchange)
 884                 ClientKill_Now_TeamChange(this);
 885
 886         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 887                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 888
 889         // now I am sure the player IS dead
 890 }
 891 void KillIndicator_Think(entity this)
 892 {
 893         if (game_stopped)
 894         {
 895                 this.owner.killindicator = NULL;
 896                 delete(this);
 897                 return;
 898         }
 899
 900         if (this.owner.alpha < 0 && !this.owner.vehicle)
 901         {
 902                 this.owner.killindicator = NULL;
 903                 delete(this);
 904                 return;
 905         }
 906
 907         if(this.cnt <= 0)
 908         {
 909                 ClientKill_Now(this.owner);
 910                 return;
 911         }
 912     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 913     {
 914         this.nextthink = time + 1;
 915         this.cnt -= 1;
 916     }
 917         else
 918         {
 919                 if(this.cnt <= 10)
 920                         setmodel(this, MDL_NUM(this.cnt));
 921                 if(IS_REAL_CLIENT(this.owner))
 922                 {
 923                         if(this.cnt <= 10)
 924                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 925                 }
 926                 this.nextthink = time + 1;
 927                 this.cnt -= 1;
 928         }
 929 }
 930
 931 float clientkilltime;
 932 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 933 {
 934         float killtime;
 935         float starttime;
 936
 937         if (game_stopped)
 938                 return;
 939
 940         killtime = autocvar_g_balance_kill_delay;
 941
 942         if(g_race_qualifying || g_cts)
 943                 killtime = 0;
 944
 945     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 946         return;
 947
 948         this.killindicator_teamchange = targetteam;
 949
 950     if(!this.killindicator)
 951         {
 952                 if(!IS_DEAD(this))
 953                 {
 954                         killtime = max(killtime, this.clientkill_nexttime - time);
 955                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 956                 }
 957
 958                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 959                 {
 960                         ClientKill_Now(this);
 961                 }
 962                 else
 963                 {
 964                         starttime = max(time, clientkilltime);
 965
 966                         this.killindicator = spawn();
 967                         this.killindicator.owner = this;
 968                         this.killindicator.scale = 0.5;
 969                         setattachment(this.killindicator, this, "");
 970                         setorigin(this.killindicator, '0 0 52');
 971                         setthink(this.killindicator, KillIndicator_Think);
 972                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 973                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 974                         this.killindicator.cnt = ceil(killtime);
 975                         this.killindicator.count = bound(0, ceil(killtime), 10);
 976                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 977
 978                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 979                         {
 980                                 it.killindicator = spawn();
 981                                 it.killindicator.owner = it;
 982                                 it.killindicator.scale = 0.5;
 983                                 setattachment(it.killindicator, it, "");
 984                                 setorigin(it.killindicator, '0 0 52');
 985                                 setthink(it.killindicator, KillIndicator_Think);
 986                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 987                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 988                                 it.killindicator.cnt = ceil(killtime);
 989                         });
 990                         this.lip = 0;
 991                 }
 992         }
 993         if(this.killindicator)
 994         {
 995                 if(targetteam == 0) // just die
 996                 {
 997                         this.killindicator.colormod = '0 0 0';
 998                         if(IS_REAL_CLIENT(this))
 999                         if(this.killindicator.cnt > 0)
1000                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1001                 }
1002                 else if(targetteam == -1) // auto
1003                 {
1004                         this.killindicator.colormod = '0 1 0';
1005                         if(IS_REAL_CLIENT(this))
1006                         if(this.killindicator.cnt > 0)
1007                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1008                 }
1009                 else if(targetteam == -2) // spectate
1010                 {
1011                         this.killindicator.colormod = '0.5 0.5 0.5';
1012                         if(IS_REAL_CLIENT(this))
1013                         if(this.killindicator.cnt > 0)
1014                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1015                 }
1016                 else
1017                 {
1018                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1019                         if(IS_REAL_CLIENT(this))
1020                         if(this.killindicator.cnt > 0)
1021                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1022                 }
1023         }
1024
1025 }
1026
1027 void ClientKill (entity this)
1028 {
1029         if(game_stopped) return;
1030         if(this.player_blocked) return;
1031         if(STAT(FROZEN, this)) return;
1032
1033         ClientKill_TeamChange(this, 0);
1034 }
1035
1036 void FixClientCvars(entity e)
1037 {
1038         // send prediction settings to the client
1039         stuffcmd(e, "\nin_bindmap 0 0\n");
1040         if(autocvar_g_antilag == 3) // client side hitscan
1041                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1042         if(autocvar_sv_gentle)
1043                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1044
1045         MUTATOR_CALLHOOK(FixClientCvars, e);
1046 }
1047
1048 float PlayerInIDList(entity p, string idlist)
1049 {
1050         float n, i;
1051         string s;
1052
1053         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1054         if (!p.crypto_idfp)
1055                 return 0;
1056
1057         // this function allows abbreviated player IDs too!
1058         n = tokenize_console(idlist);
1059         for(i = 0; i < n; ++i)
1060         {
1061                 s = argv(i);
1062                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1063                         return 1;
1064         }
1065
1066         return 0;
1067 }
1068
1069 #ifdef DP_EXT_PRECONNECT
1070 /*
1071 =============
1072 ClientPreConnect
1073
1074 Called once (not at each match start) when a client begins a connection to the server
1075 =============
1076 */
1077 void ClientPreConnect(entity this)
1078 {
1079         if(autocvar_sv_eventlog)
1080         {
1081                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1082                         this.playerid,
1083                         etof(this),
1084                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1085                 ));
1086         }
1087 }
1088 #endif
1089
1090 /**
1091 =============
1092 ClientConnect
1093
1094 Called when a client connects to the server
1095 =============
1096 */
1097 void ClientConnect(entity this)
1098 {
1099         if (Ban_MaybeEnforceBanOnce(this)) return;
1100         assert(!IS_CLIENT(this), return);
1101         this.flags |= FL_CLIENT;
1102         assert(player_count >= 0, player_count = 0);
1103
1104 #ifdef WATERMARK
1105         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1106 #endif
1107         this.version_nagtime = time + 10 + random() * 10;
1108         TRANSMUTE(Client, this);
1109
1110         // identify the right forced team
1111         if (autocvar_g_campaign)
1112         {
1113                 if (IS_REAL_CLIENT(this)) // only players, not bots
1114                 {
1115                         switch (autocvar_g_campaign_forceteam)
1116                         {
1117                                 case 1: this.team_forced = NUM_TEAM_1; break;
1118                                 case 2: this.team_forced = NUM_TEAM_2; break;
1119                                 case 3: this.team_forced = NUM_TEAM_3; break;
1120                                 case 4: this.team_forced = NUM_TEAM_4; break;
1121                                 default: this.team_forced = 0;
1122                         }
1123                 }
1124         }
1125         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1126         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1127         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1128         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1129         else switch (autocvar_g_forced_team_otherwise)
1130         {
1131                 default: this.team_forced = 0; break;
1132                 case "red": this.team_forced = NUM_TEAM_1; break;
1133                 case "blue": this.team_forced = NUM_TEAM_2; break;
1134                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1135                 case "pink": this.team_forced = NUM_TEAM_4; break;
1136                 case "spectate":
1137                 case "spectator":
1138                         this.team_forced = -1;
1139                         break;
1140         }
1141         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1142
1143     {
1144         int id = this.playerid;
1145         this.playerid = 0; // silent
1146             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1147             this.playerid = id;
1148     }
1149
1150         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1151                 TRANSMUTE(Observer, this);
1152         } else {
1153                 if (!teamplay || autocvar_g_balance_teams) {
1154                         TRANSMUTE(Player, this);
1155                         campaign_bots_may_start = true;
1156                 } else {
1157                         TRANSMUTE(Observer, this); // do it anyway
1158                 }
1159         }
1160
1161         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1162
1163         // always track bots, don't ask for cl_allow_uidtracking
1164     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1165
1166         if (autocvar_sv_eventlog)
1167                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1168
1169         LogTeamchange(this.playerid, this.team, 1);
1170
1171         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1172
1173         this.netname_previous = strzone(this.netname);
1174
1175         if(teamplay && IS_PLAYER(this))
1176                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1177         else
1178                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1179
1180         stuffcmd(this, clientstuff, "\n");
1181         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1182
1183         FixClientCvars(this);
1184
1185         // get version info from player
1186         stuffcmd(this, "cmd clientversion $gameversion\n");
1187
1188         // notify about available teams
1189         if (teamplay)
1190         {
1191                 CheckAllowedTeams(this);
1192                 int t = 0;
1193                 if (c1 >= 0) t |= BIT(0);
1194                 if (c2 >= 0) t |= BIT(1);
1195                 if (c3 >= 0) t |= BIT(2);
1196                 if (c4 >= 0) t |= BIT(3);
1197                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1198         }
1199         else
1200         {
1201                 stuffcmd(this, "set _teams_available 0\n");
1202         }
1203
1204         bot_relinkplayerlist();
1205
1206         this.spectatortime = time;
1207         if (blockSpectators)
1208         {
1209                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1210         }
1211
1212         this.jointime = time;
1213         this.allowed_timeouts = autocvar_sv_timeout_number;
1214
1215         if (IS_REAL_CLIENT(this))
1216         {
1217                 if (g_weaponarena_weapons == WEPSET(TUBA))
1218                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1219         }
1220
1221         if (!sv_foginterval && world.fog != "")
1222                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1223
1224         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1225                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1226                         send_CSQC_teamnagger();
1227
1228         CSQCMODEL_AUTOINIT(this);
1229
1230         this.model_randomizer = random();
1231
1232         if (IS_REAL_CLIENT(this))
1233                 sv_notice_join(this);
1234
1235         // update physics stats (players can spawn before physics runs)
1236         STAT(MOVEVARS_HIGHSPEED, this) = autocvar_g_movement_highspeed;
1237         MUTATOR_CALLHOOK(PlayerPhysics_UpdateStats, this); // do it BEFORE the function so we can modify highspeed!
1238         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1239
1240         IL_EACH(g_initforplayer, it.init_for_player, {
1241                 it.init_for_player(it, this);
1242         });
1243
1244         MUTATOR_CALLHOOK(ClientConnect, this);
1245
1246         if (IS_REAL_CLIENT(this))
1247         {
1248                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1249                 {
1250                         this.motd_actived_time = -1;
1251                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1252                 }
1253         }
1254 }
1255 /*
1256 =============
1257 ClientDisconnect
1258
1259 Called when a client disconnects from the server
1260 =============
1261 */
1262 .entity chatbubbleentity;
1263 void ReadyCount();
1264 void ClientDisconnect(entity this)
1265 {
1266         assert(IS_CLIENT(this), return);
1267
1268         PlayerStats_GameReport_FinalizePlayer(this);
1269         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1270         if (this.active_minigame) part_minigame(this);
1271         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1272
1273         if (autocvar_sv_eventlog)
1274                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1275
1276         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1277
1278         if(IS_SPEC(this))
1279                 SetSpectatee(this, NULL);
1280
1281     MUTATOR_CALLHOOK(ClientDisconnect, this);
1282
1283         ClientState_detach(this);
1284
1285         Portal_ClearAll(this);
1286
1287         Unfreeze(this);
1288
1289         RemoveGrapplingHooks(this);
1290
1291         // Here, everything has been done that requires this player to be a client.
1292
1293         this.flags &= ~FL_CLIENT;
1294
1295         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1296         if (this.killindicator) delete(this.killindicator);
1297
1298         WaypointSprite_PlayerGone(this);
1299
1300         bot_relinkplayerlist();
1301
1302         if (this.netname_previous) strunzone(this.netname_previous);
1303         if (this.clientstatus) strunzone(this.clientstatus);
1304         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1305         if (this.personal) delete(this.personal);
1306
1307         this.playerid = 0;
1308         ReadyCount();
1309         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1310
1311         ONREMOVE(this);
1312 }
1313
1314 void ChatBubbleThink(entity this)
1315 {
1316         this.nextthink = time;
1317         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1318         {
1319                 if(this.owner) // but why can that ever be NULL?
1320                         this.owner.chatbubbleentity = NULL;
1321                 delete(this);
1322                 return;
1323         }
1324
1325         this.mdl = "";
1326
1327         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1328         {
1329                 if ( this.owner.active_minigame )
1330                         this.mdl = "models/sprites/minigame_busy.iqm";
1331                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1332                         this.mdl = "models/misc/chatbubble.spr";
1333         }
1334
1335         if ( this.model != this.mdl )
1336                 _setmodel(this, this.mdl);
1337
1338 }
1339
1340 void UpdateChatBubble(entity this)
1341 {
1342         if (this.alpha < 0)
1343                 return;
1344         // spawn a chatbubble entity if needed
1345         if (!this.chatbubbleentity)
1346         {
1347                 this.chatbubbleentity = new(chatbubbleentity);
1348                 this.chatbubbleentity.owner = this;
1349                 this.chatbubbleentity.exteriormodeltoclient = this;
1350                 setthink(this.chatbubbleentity, ChatBubbleThink);
1351                 this.chatbubbleentity.nextthink = time;
1352                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1353                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1354                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1355                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1356                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1357                 //this.chatbubbleentity.model = "";
1358                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1359         }
1360 }
1361
1362
1363 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1364 // added to the model skins
1365 /*void UpdateColorModHack()
1366 {
1367         float c;
1368         c = this.clientcolors & 15;
1369         // LordHavoc: only bothering to support white, green, red, yellow, blue
1370              if (!teamplay) this.colormod = '0 0 0';
1371         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1372         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1373         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1374         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1375         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1376         else this.colormod = '1 1 1';
1377 }*/
1378
1379 void respawn(entity this)
1380 {
1381         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1382         {
1383                 this.solid = SOLID_NOT;
1384                 this.takedamage = DAMAGE_NO;
1385                 set_movetype(this, MOVETYPE_FLY);
1386                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1387                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1388                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1389                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1390                 if(autocvar_g_respawn_ghosts_maxtime)
1391                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1392         }
1393
1394         CopyBody(this, 1);
1395
1396         this.effects |= EF_NODRAW; // prevent another CopyBody
1397         PutClientInServer(this);
1398 }
1399
1400 void play_countdown(entity this, float finished, Sound samp)
1401 {
1402     TC(Sound, samp);
1403         if(IS_REAL_CLIENT(this))
1404                 if(floor(finished - time - frametime) != floor(finished - time))
1405                         if(finished - time < 6)
1406                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1407 }
1408
1409 void player_powerups(entity this)
1410 {
1411         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1412         int items_prev = this.items;
1413
1414         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1415                 this.modelflags |= MF_ROCKET;
1416         else
1417                 this.modelflags &= ~MF_ROCKET;
1418
1419         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1420
1421         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1422                 return;
1423
1424         Fire_ApplyDamage(this);
1425         Fire_ApplyEffect(this);
1426
1427         if (!g_instagib)
1428         {
1429                 if (this.items & ITEM_Strength.m_itemid)
1430                 {
1431                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1432                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1433                         if (time > this.strength_finished)
1434                         {
1435                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1436                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1437                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1438                         }
1439                 }
1440                 else
1441                 {
1442                         if (time < this.strength_finished)
1443                         {
1444                                 this.items = this.items | ITEM_Strength.m_itemid;
1445                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1446                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1447                         }
1448                 }
1449                 if (this.items & ITEM_Shield.m_itemid)
1450                 {
1451                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1452                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1453                         if (time > this.invincible_finished)
1454                         {
1455                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1456                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1457                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1458                         }
1459                 }
1460                 else
1461                 {
1462                         if (time < this.invincible_finished)
1463                         {
1464                                 this.items = this.items | ITEM_Shield.m_itemid;
1465                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1466                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1467                         }
1468                 }
1469                 if (this.items & IT_SUPERWEAPON)
1470                 {
1471                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1472                         {
1473                                 this.superweapons_finished = 0;
1474                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1475                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1476                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1477                         }
1478                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1479                         {
1480                                 // don't let them run out
1481                         }
1482                         else
1483                         {
1484                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1485                                 if (time > this.superweapons_finished)
1486                                 {
1487                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1488                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1489                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1490                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1491                                 }
1492                         }
1493                 }
1494                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1495                 {
1496                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1497                         {
1498                                 this.items = this.items | IT_SUPERWEAPON;
1499                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1500                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1501                         }
1502                         else
1503                         {
1504                                 this.superweapons_finished = 0;
1505                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1506                         }
1507                 }
1508                 else
1509                 {
1510                         this.superweapons_finished = 0;
1511                 }
1512         }
1513
1514         if(autocvar_g_nodepthtestplayers)
1515                 this.effects = this.effects | EF_NODEPTHTEST;
1516
1517         if(autocvar_g_fullbrightplayers)
1518                 this.effects = this.effects | EF_FULLBRIGHT;
1519
1520         if (time >= game_starttime)
1521         if (time < this.spawnshieldtime)
1522                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1523
1524         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1525 }
1526
1527 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1528 {
1529         if(current > stable)
1530                 return current;
1531         else if(current > stable - 0.25) // when close enough, "snap"
1532                 return stable;
1533         else
1534                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1535 }
1536
1537 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1538 {
1539         if(current < stable)
1540                 return current;
1541         else if(current < stable + 0.25) // when close enough, "snap"
1542                 return stable;
1543         else
1544                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1545 }
1546
1547 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1548 {
1549         if(current > rotstable)
1550         {
1551                 if(rotframetime > 0)
1552                 {
1553                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1554                         current = max(rotstable, current - rotlinear * rotframetime);
1555                 }
1556         }
1557         else if(current < regenstable)
1558         {
1559                 if(regenframetime > 0)
1560                 {
1561                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1562                         current = min(regenstable, current + regenlinear * regenframetime);
1563                 }
1564         }
1565
1566         if(current > limit)
1567                 current = limit;
1568
1569         return current;
1570 }
1571
1572 void player_regen(entity this)
1573 {
1574         float max_mod, regen_mod, rot_mod, limit_mod;
1575         max_mod = regen_mod = rot_mod = limit_mod = 1;
1576
1577         float regen_health = autocvar_g_balance_health_regen;
1578         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1579         float regen_health_rot = autocvar_g_balance_health_rot;
1580         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1581         float regen_health_stable = autocvar_g_balance_health_regenstable;
1582         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1583         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1584                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1585         max_mod = M_ARGV(1, float);
1586         regen_mod = M_ARGV(2, float);
1587         rot_mod = M_ARGV(3, float);
1588         limit_mod = M_ARGV(4, float);
1589         regen_health = M_ARGV(5, float);
1590         regen_health_linear = M_ARGV(6, float);
1591         regen_health_rot = M_ARGV(7, float);
1592         regen_health_rotlinear = M_ARGV(8, float);
1593         regen_health_stable = M_ARGV(9, float);
1594         regen_health_rotstable = M_ARGV(10, float);
1595
1596
1597         if(!mutator_returnvalue)
1598         if(!STAT(FROZEN, this))
1599         {
1600                 float mina, maxa, limith, limita;
1601                 maxa = autocvar_g_balance_armor_rotstable;
1602                 mina = autocvar_g_balance_armor_regenstable;
1603                 limith = autocvar_g_balance_health_limit;
1604                 limita = autocvar_g_balance_armor_limit;
1605
1606                 regen_health_rotstable = regen_health_rotstable * max_mod;
1607                 regen_health_stable = regen_health_stable * max_mod;
1608                 limith = limith * limit_mod;
1609                 limita = limita * limit_mod;
1610
1611                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1612                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1613         }
1614
1615         // if player rotted to death...  die!
1616         // check this outside above checks, as player may still be able to rot to death
1617         if(this.health < 1)
1618         {
1619                 if(this.vehicle)
1620                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1621                 if(this.event_damage)
1622                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1623         }
1624
1625         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1626         {
1627                 float minf, maxf, limitf;
1628
1629                 maxf = autocvar_g_balance_fuel_rotstable;
1630                 minf = autocvar_g_balance_fuel_regenstable;
1631                 limitf = autocvar_g_balance_fuel_limit;
1632
1633                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1634         }
1635 }
1636
1637 bool zoomstate_set;
1638 void SetZoomState(entity this, float newzoom)
1639 {
1640         if(newzoom != this.zoomstate)
1641         {
1642                 this.zoomstate = newzoom;
1643                 ClientData_Touch(this);
1644         }
1645         zoomstate_set = true;
1646 }
1647
1648 void GetPressedKeys(entity this)
1649 {
1650         MUTATOR_CALLHOOK(GetPressedKeys, this);
1651         int keys = STAT(PRESSED_KEYS, this);
1652         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1653         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1654         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1655         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1656
1657         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1658         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1659         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1660         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1661         this.pressedkeys = keys; // store for other users
1662
1663         STAT(PRESSED_KEYS, this) = keys;
1664 }
1665
1666 /*
1667 ======================
1668 spectate mode routines
1669 ======================
1670 */
1671
1672 void SpectateCopy(entity this, entity spectatee)
1673 {
1674     TC(Client, this); TC(Client, spectatee);
1675
1676         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1677         PS(this) = PS(spectatee);
1678         this.armortype = spectatee.armortype;
1679         this.armorvalue = spectatee.armorvalue;
1680         this.ammo_cells = spectatee.ammo_cells;
1681         this.ammo_plasma = spectatee.ammo_plasma;
1682         this.ammo_shells = spectatee.ammo_shells;
1683         this.ammo_nails = spectatee.ammo_nails;
1684         this.ammo_rockets = spectatee.ammo_rockets;
1685         this.ammo_fuel = spectatee.ammo_fuel;
1686         this.clip_load = spectatee.clip_load;
1687         this.clip_size = spectatee.clip_size;
1688         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1689         this.health = spectatee.health;
1690         this.impulse = 0;
1691         this.items = spectatee.items;
1692         this.last_pickup = spectatee.last_pickup;
1693         this.hit_time = spectatee.hit_time;
1694         this.strength_finished = spectatee.strength_finished;
1695         this.invincible_finished = spectatee.invincible_finished;
1696         this.superweapons_finished = spectatee.superweapons_finished;
1697         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1698         this.weapons = spectatee.weapons;
1699         this.vortex_charge = spectatee.vortex_charge;
1700         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1701         this.okvortex_charge = spectatee.okvortex_charge;
1702         this.okvortex_chargepool_ammo = spectatee.okvortex_chargepool_ammo;
1703         this.hagar_load = spectatee.hagar_load;
1704         this.arc_heat_percent = spectatee.arc_heat_percent;
1705         this.minelayer_mines = spectatee.minelayer_mines;
1706         this.punchangle = spectatee.punchangle;
1707         this.view_ofs = spectatee.view_ofs;
1708         this.velocity = spectatee.velocity;
1709         this.dmg_take = spectatee.dmg_take;
1710         this.dmg_save = spectatee.dmg_save;
1711         this.dmg_inflictor = spectatee.dmg_inflictor;
1712         this.v_angle = spectatee.v_angle;
1713         this.angles = spectatee.v_angle;
1714         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1715         this.revive_progress = spectatee.revive_progress;
1716         this.viewloc = spectatee.viewloc;
1717         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1718                 this.fixangle = true;
1719         setorigin(this, spectatee.origin);
1720         setsize(this, spectatee.mins, spectatee.maxs);
1721         SetZoomState(this, spectatee.zoomstate);
1722
1723         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1724         {
1725                 .entity weaponentity = weaponentities[slot];
1726                 this.(weaponentity) = spectatee.(weaponentity);
1727         }
1728
1729         for(int slot = 0; slot < MAX_AXH; ++slot)
1730         {
1731                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1732         }
1733
1734     anticheat_spectatecopy(this, spectatee);
1735         this.hud = spectatee.hud;
1736         if(spectatee.vehicle)
1737     {
1738         this.angles = spectatee.v_angle;
1739
1740         //this.fixangle = false;
1741         //this.velocity = spectatee.vehicle.velocity;
1742         this.vehicle_health = spectatee.vehicle_health;
1743         this.vehicle_shield = spectatee.vehicle_shield;
1744         this.vehicle_energy = spectatee.vehicle_energy;
1745         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1746         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1747         this.vehicle_reload1 = spectatee.vehicle_reload1;
1748         this.vehicle_reload2 = spectatee.vehicle_reload2;
1749
1750         //msg_entity = this;
1751
1752        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1753             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1754            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1755            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1756
1757         //WriteByte (MSG_ONE, SVC_SETVIEW);
1758         //    WriteEntity(MSG_ONE, this);
1759         //makevectors(spectatee.v_angle);
1760         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1761     }
1762 }
1763
1764 bool SpectateUpdate(entity this)
1765 {
1766         if(!this.enemy)
1767                 return false;
1768
1769         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1770         {
1771                 SetSpectatee(this, NULL);
1772                 return false;
1773         }
1774
1775         SpectateCopy(this, this.enemy);
1776
1777         return true;
1778 }
1779
1780 bool SpectateSet(entity this)
1781 {
1782         if(!IS_PLAYER(this.enemy))
1783                 return false;
1784
1785         ClientData_Touch(this.enemy);
1786
1787         msg_entity = this;
1788         WriteByte(MSG_ONE, SVC_SETVIEW);
1789         WriteEntity(MSG_ONE, this.enemy);
1790         set_movetype(this, MOVETYPE_NONE);
1791         accuracy_resend(this);
1792
1793         if(!SpectateUpdate(this))
1794                 PutObserverInServer(this);
1795
1796         return true;
1797 }
1798
1799 void SetSpectatee_status(entity this, int spectatee_num)
1800 {
1801         int oldspectatee_status = this.spectatee_status;
1802         this.spectatee_status = spectatee_num;
1803
1804         if (this.spectatee_status != oldspectatee_status)
1805         {
1806                 ClientData_Touch(this);
1807                 if (g_race || g_cts) race_InitSpectator();
1808         }
1809 }
1810
1811 void SetSpectatee(entity this, entity spectatee)
1812 {
1813         entity old_spectatee = this.enemy;
1814
1815         this.enemy = spectatee;
1816
1817         // WEAPONTODO
1818         // these are required to fix the spectator bug with arc
1819         if(old_spectatee)
1820         {
1821                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1822                 {
1823                         .entity weaponentity = weaponentities[slot];
1824                         if(old_spectatee.(weaponentity).arc_beam)
1825                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1826                 }
1827         }
1828         if(this.enemy)
1829         {
1830                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1831                 {
1832                         .entity weaponentity = weaponentities[slot];
1833                         if(this.enemy.(weaponentity).arc_beam)
1834                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1835                 }
1836         }
1837
1838         if (this.enemy)
1839                 SetSpectatee_status(this, etof(this.enemy));
1840
1841         // needed to update spectator list
1842         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1843 }
1844
1845 bool Spectate(entity this, entity pl)
1846 {
1847         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1848                 return false;
1849         pl = M_ARGV(1, entity);
1850
1851         SetSpectatee(this, pl);
1852         return SpectateSet(this);
1853 }
1854
1855 bool SpectateNext(entity this)
1856 {
1857         entity ent = find(this.enemy, classname, STR_PLAYER);
1858
1859         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1860                 ent = M_ARGV(1, entity);
1861         else if (!ent)
1862                 ent = find(ent, classname, STR_PLAYER);
1863
1864         if(ent) { SetSpectatee(this, ent); }
1865
1866         return SpectateSet(this);
1867 }
1868
1869 bool SpectatePrev(entity this)
1870 {
1871         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1872         entity ent = findchain(classname, STR_PLAYER);
1873         if (!ent) // no player
1874                 return false;
1875
1876         entity first = ent;
1877         // skip players until current spectated player
1878         if(this.enemy)
1879         while(ent && ent != this.enemy)
1880                 ent = ent.chain;
1881
1882         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1883         {
1884                 case MUT_SPECPREV_FOUND:
1885                     ent = M_ARGV(1, entity);
1886                     break;
1887                 case MUT_SPECPREV_RETURN:
1888                     return true;
1889                 case MUT_SPECPREV_CONTINUE:
1890                 default:
1891                 {
1892                         if(ent.chain)
1893                                 ent = ent.chain;
1894                         else
1895                                 ent = first;
1896                         break;
1897                 }
1898         }
1899
1900         SetSpectatee(this, ent);
1901         return SpectateSet(this);
1902 }
1903
1904 /*
1905 =============
1906 ShowRespawnCountdown()
1907
1908 Update a respawn countdown display.
1909 =============
1910 */
1911 void ShowRespawnCountdown(entity this)
1912 {
1913         float number;
1914         if(!IS_DEAD(this)) // just respawned?
1915                 return;
1916         else
1917         {
1918                 number = ceil(this.respawn_time - time);
1919                 if(number <= 0)
1920                         return;
1921                 if(number <= this.respawn_countdown)
1922                 {
1923                         this.respawn_countdown = number - 1;
1924                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1925                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1926                 }
1927         }
1928 }
1929
1930 .bool team_selected;
1931 bool ShowTeamSelection(entity this)
1932 {
1933         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1934                 return false;
1935         stuffcmd(this, "menu_showteamselect\n");
1936         return true;
1937 }
1938 void Join(entity this)
1939 {
1940         TRANSMUTE(Player, this);
1941
1942         if(!this.team_selected)
1943         if(autocvar_g_campaign || autocvar_g_balance_teams)
1944                 JoinBestTeam(this, false, true);
1945
1946         if(autocvar_g_campaign)
1947                 campaign_bots_may_start = true;
1948
1949         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1950
1951         PutClientInServer(this);
1952
1953         if(teamplay && this.team != -1)
1954                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1955         else
1956                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1957         this.team_selected = false;
1958 }
1959
1960 /**
1961  * Determines whether the player is allowed to join. This depends on cvar
1962  * g_maxplayers, if it isn't used this function always return true, otherwise
1963  * it checks whether the number of currently playing players exceeds g_maxplayers.
1964  * @return int number of free slots for players, 0 if none
1965  */
1966 int nJoinAllowed(entity this, entity ignore)
1967 {
1968         if(!ignore)
1969         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1970         // so report 0 free slots if restricted
1971         {
1972                 if(autocvar_g_forced_team_otherwise == "spectate")
1973                         return 0;
1974                 if(autocvar_g_forced_team_otherwise == "spectator")
1975                         return 0;
1976         }
1977
1978         if(this && this.team_forced < 0)
1979                 return 0; // forced spectators can never join
1980
1981         // TODO simplify this
1982         int totalClients = 0;
1983         int currentlyPlaying = 0;
1984         FOREACH_CLIENT(true, LAMBDA(
1985                 if(it != ignore)
1986                         ++totalClients;
1987                 if(IS_REAL_CLIENT(it))
1988                 if(IS_PLAYER(it) || it.caplayer)
1989                         ++currentlyPlaying;
1990         ));
1991
1992         float free_slots = 0;
1993         if (!autocvar_g_maxplayers)
1994                 free_slots = maxclients - totalClients;
1995         else if(currentlyPlaying < autocvar_g_maxplayers)
1996                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1997
1998         static float join_prevent_msg_time = 0;
1999         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2000         {
2001                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2002                 join_prevent_msg_time = time + 3;
2003         }
2004
2005         return free_slots;
2006 }
2007
2008 /**
2009  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2010  * g_maxplayers_spectator_blocktime seconds
2011  */
2012 void checkSpectatorBlock(entity this)
2013 {
2014         if(IS_SPEC(this) || IS_OBSERVER(this))
2015         if(!this.caplayer)
2016         if(IS_REAL_CLIENT(this))
2017         {
2018                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2019                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2020                         dropclient(this);
2021                 }
2022         }
2023 }
2024
2025 void PrintWelcomeMessage(entity this)
2026 {
2027         if(this.motd_actived_time == 0)
2028         {
2029                 if (autocvar_g_campaign) {
2030                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2031                                 this.motd_actived_time = time;
2032                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2033                         }
2034                 } else {
2035                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2036                                 this.motd_actived_time = time;
2037                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2038                         }
2039                 }
2040         }
2041         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2042         {
2043                 if (autocvar_g_campaign) {
2044                         if (PHYS_INPUT_BUTTON_INFO(this))
2045                                 this.motd_actived_time = time;
2046                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2047                                 this.motd_actived_time = 0;
2048                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2049                         }
2050                 } else {
2051                         if (PHYS_INPUT_BUTTON_INFO(this))
2052                                 this.motd_actived_time = time;
2053                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2054                                 this.motd_actived_time = 0;
2055                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2056                         }
2057                 }
2058         }
2059         else //if(this.motd_actived_time < 0) // just connected, motd is active
2060         {
2061                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2062                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2063                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2064                 {
2065                         // instanctly hide MOTD
2066                         this.motd_actived_time = 0;
2067                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2068                 }
2069         }
2070 }
2071
2072 bool joinAllowed(entity this)
2073 {
2074         if (this.version_mismatch) return false;
2075         if (!nJoinAllowed(this, this)) return false;
2076         if (teamplay && lockteams) return false;
2077         if (ShowTeamSelection(this)) return false;
2078         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2079         return true;
2080 }
2081
2082 void ObserverThink(entity this)
2083 {
2084         if ( this.impulse )
2085         {
2086                 MinigameImpulse(this, this.impulse);
2087                 this.impulse = 0;
2088         }
2089
2090         if (this.flags & FL_JUMPRELEASED) {
2091                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2092                         this.flags &= ~FL_JUMPRELEASED;
2093                         this.flags |= FL_SPAWNING;
2094                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2095                         this.flags &= ~FL_JUMPRELEASED;
2096                         if(SpectateNext(this)) {
2097                                 TRANSMUTE(Spectator, this);
2098                         }
2099                 } else {
2100                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2101                         set_movetype(this, preferred_movetype);
2102                 }
2103         } else {
2104                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2105                         this.flags |= FL_JUMPRELEASED;
2106                         if(this.flags & FL_SPAWNING)
2107                         {
2108                                 this.flags &= ~FL_SPAWNING;
2109                                 Join(this);
2110                                 return;
2111                         }
2112                 }
2113         }
2114 }
2115
2116 void SpectatorThink(entity this)
2117 {
2118         if ( this.impulse )
2119         {
2120                 if(MinigameImpulse(this, this.impulse))
2121                         this.impulse = 0;
2122
2123                 if (this.impulse == IMP_weapon_drop.impulse)
2124                 {
2125                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2126                         this.impulse = 0;
2127                         return;
2128                 }
2129         }
2130
2131         if (this.flags & FL_JUMPRELEASED) {
2132                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2133                         this.flags &= ~FL_JUMPRELEASED;
2134                         this.flags |= FL_SPAWNING;
2135                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2136                         this.flags &= ~FL_JUMPRELEASED;
2137                         if(SpectateNext(this)) {
2138                                 TRANSMUTE(Spectator, this);
2139                         } else {
2140                                 TRANSMUTE(Observer, this);
2141                                 PutClientInServer(this);
2142                         }
2143                         this.impulse = 0;
2144                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2145                         this.flags &= ~FL_JUMPRELEASED;
2146                         if(SpectatePrev(this)) {
2147                                 TRANSMUTE(Spectator, this);
2148                         } else {
2149                                 TRANSMUTE(Observer, this);
2150                                 PutClientInServer(this);
2151                         }
2152                         this.impulse = 0;
2153                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2154                         this.flags &= ~FL_JUMPRELEASED;
2155                         TRANSMUTE(Observer, this);
2156                         PutClientInServer(this);
2157                 } else {
2158                         if(!SpectateUpdate(this))
2159                                 PutObserverInServer(this);
2160                 }
2161         } else {
2162                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2163                         this.flags |= FL_JUMPRELEASED;
2164                         if(this.flags & FL_SPAWNING)
2165                         {
2166                                 this.flags &= ~FL_SPAWNING;
2167                                 Join(this);
2168                                 return;
2169                         }
2170                 }
2171                 if(!SpectateUpdate(this))
2172                         PutObserverInServer(this);
2173         }
2174
2175         this.flags |= FL_CLIENT | FL_NOTARGET;
2176 }
2177
2178 void vehicles_enter (entity pl, entity veh);
2179 void PlayerUseKey(entity this)
2180 {
2181         if (!IS_PLAYER(this))
2182                 return;
2183
2184         if(this.vehicle)
2185         {
2186                 if(!game_stopped)
2187                 {
2188                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2189                         return;
2190                 }
2191         }
2192         else if(autocvar_g_vehicles_enter)
2193         {
2194                 if(!STAT(FROZEN, this))
2195                 if(!IS_DEAD(this))
2196                 if(!game_stopped)
2197                 {
2198                         entity head, closest_target = NULL;
2199                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2200
2201                         while(head) // find the closest acceptable target to enter
2202                         {
2203                                 if(IS_VEHICLE(head))
2204                                 if(!IS_DEAD(head))
2205                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2206                                 if(head.takedamage != DAMAGE_NO)
2207                                 {
2208                                         if(closest_target)
2209                                         {
2210                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2211                                                 { closest_target = head; }
2212                                         }
2213                                         else { closest_target = head; }
2214                                 }
2215
2216                                 head = head.chain;
2217                         }
2218
2219                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2220                 }
2221         }
2222
2223         // a use key was pressed; call handlers
2224         MUTATOR_CALLHOOK(PlayerUseKey, this);
2225 }
2226
2227
2228 /*
2229 =============
2230 PlayerPreThink
2231
2232 Called every frame for each client before the physics are run
2233 =============
2234 */
2235 .float usekeypressed;
2236 .float last_vehiclecheck;
2237 .int items_added;
2238 void PlayerPreThink (entity this)
2239 {
2240         WarpZone_PlayerPhysics_FixVAngle(this);
2241
2242     STAT(GAMESTARTTIME, this) = game_starttime;
2243         STAT(ROUNDSTARTTIME, this) = round_starttime;
2244         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2245         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2246
2247         STAT(WEAPONSINMAP, this) = weaponsInMap;
2248
2249         if (frametime) {
2250                 // physics frames: update anticheat stuff
2251                 anticheat_prethink(this);
2252         }
2253
2254         if (blockSpectators && frametime) {
2255                 // WORKAROUND: only use dropclient in server frames (frametime set).
2256                 // Never use it in cl_movement frames (frametime zero).
2257                 checkSpectatorBlock(this);
2258     }
2259
2260         zoomstate_set = false;
2261
2262         // Check for nameless players
2263         if (isInvisibleString(this.netname)) {
2264                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2265                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2266         }
2267         if (this.netname != this.netname_previous) {
2268                 if (autocvar_sv_eventlog) {
2269                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2270         }
2271                 if (this.netname_previous) strunzone(this.netname_previous);
2272                 this.netname_previous = strzone(this.netname);
2273         }
2274
2275         // version nagging
2276         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2277         this.version_nagtime = 0;
2278         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2279             // git client
2280         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2281             // git server
2282             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2283         } else {
2284             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2285             if (r < 0) { // old client
2286                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2287             } else if (r > 0) { // old server
2288                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2289             }
2290         }
2291     }
2292
2293         // GOD MODE info
2294         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2295         {
2296                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2297                 this.max_armorvalue = 0;
2298         }
2299
2300         if (STAT(FROZEN, this) == 2)
2301         {
2302                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2303                 this.health = max(1, this.revive_progress * start_health);
2304                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2305
2306                 if (this.revive_progress >= 1)
2307                         Unfreeze(this);
2308         }
2309         else if (STAT(FROZEN, this) == 3)
2310         {
2311                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2312                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2313
2314                 if (this.health < 1)
2315                 {
2316                         if (this.vehicle)
2317                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2318                         if(this.event_damage)
2319                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2320                 }
2321                 else if (this.revive_progress <= 0)
2322                         Unfreeze(this);
2323         }
2324
2325         MUTATOR_CALLHOOK(PlayerPreThink, this);
2326
2327         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2328         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2329         {
2330                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2331                 {
2332                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2333                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2334                         {
2335                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2336                         }
2337                         else if(!it.owner)
2338                         {
2339                                 if(!it.team || SAME_TEAM(this, it))
2340                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2341                                 else if(autocvar_g_vehicles_steal)
2342                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2343                         }
2344                 });
2345
2346                 this.last_vehiclecheck = time + 1;
2347         }
2348
2349         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2350         {
2351                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2352                         PlayerUseKey(this);
2353                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2354         }
2355
2356         if (IS_REAL_CLIENT(this))
2357                 PrintWelcomeMessage(this);
2358
2359         if (IS_PLAYER(this)) {
2360                 CheckRules_Player(this);
2361
2362                 if (game_stopped || intermission_running) {
2363                         this.modelflags &= ~MF_ROCKET;
2364                         if(intermission_running)
2365                                 IntermissionThink(this);
2366                         return;
2367                 }
2368
2369                 if (timeout_status == TIMEOUT_ACTIVE) {
2370             // don't allow the player to turn around while game is paused
2371                         // FIXME turn this into CSQC stuff
2372                         this.v_angle = this.lastV_angle;
2373                         this.angles = this.lastV_angle;
2374                         this.fixangle = true;
2375                 }
2376
2377                 if (frametime) player_powerups(this);
2378
2379                 if (IS_DEAD(this)) {
2380                         if (this.personal && g_race_qualifying) {
2381                                 if (time > this.respawn_time) {
2382                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2383                                         respawn(this);
2384                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2385                                 }
2386                         } else {
2387                                 if (frametime) player_anim(this);
2388
2389                                 if (this.respawn_flags & RESPAWN_DENY)
2390                                 {
2391                                         STAT(RESPAWN_TIME, this) = 0;
2392                                         return;
2393                                 }
2394
2395                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2396
2397                                 switch(this.deadflag)
2398                                 {
2399                                         case DEAD_DYING:
2400                                         {
2401                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2402                                                         this.deadflag = DEAD_RESPAWNING;
2403                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2404                                                         this.deadflag = DEAD_DEAD;
2405                                                 break;
2406                                         }
2407                                         case DEAD_DEAD:
2408                                         {
2409                                                 if (button_pressed)
2410                                                         this.deadflag = DEAD_RESPAWNABLE;
2411                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2412                                                         this.deadflag = DEAD_RESPAWNING;
2413                                                 break;
2414                                         }
2415                                         case DEAD_RESPAWNABLE:
2416                                         {
2417                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2418                                                         this.deadflag = DEAD_RESPAWNING;
2419                                                 break;
2420                                         }
2421                                         case DEAD_RESPAWNING:
2422                                         {
2423                                                 if (time > this.respawn_time)
2424                                                 {
2425                                                         this.respawn_time = time + 1; // only retry once a second
2426                                                         this.respawn_time_max = this.respawn_time;
2427                                                         respawn(this);
2428                                                 }
2429                                                 break;
2430                                         }
2431                                 }
2432
2433                                 ShowRespawnCountdown(this);
2434
2435                                 if (this.respawn_flags & RESPAWN_SILENT)
2436                                         STAT(RESPAWN_TIME, this) = 0;
2437                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2438                                 {
2439                                         if (time < this.respawn_time)
2440                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2441                                         else if (this.deadflag != DEAD_RESPAWNING)
2442                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2443                                 }
2444                                 else
2445                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2446                         }
2447
2448                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2449                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2450                                 STAT(RESPAWN_TIME, this) *= -1;
2451
2452                         return;
2453                 }
2454
2455                 this.prevorigin = this.origin;
2456
2457                 bool have_hook = false;
2458                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2459                 {
2460                         .entity weaponentity = weaponentities[slot];
2461                         if(this.(weaponentity).hook.state)
2462                         {
2463                                 have_hook = true;
2464                                 break;
2465                         }
2466                 }
2467                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2468                 if (have_hook) {
2469                         do_crouch = false;
2470                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2471                         do_crouch = false;
2472                 } else if (this.vehicle) {
2473                         do_crouch = false;
2474                 } else if (STAT(FROZEN, this)) {
2475                         do_crouch = false;
2476         }
2477
2478                 if (do_crouch) {
2479                         if (!this.crouch) {
2480                                 this.crouch = true;
2481                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2482                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2483                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2484                         }
2485                 } else if (this.crouch) {
2486             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2487             if (!trace_startsolid) {
2488                 this.crouch = false;
2489                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2490                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2491             }
2492                 }
2493
2494                 FixPlayermodel(this);
2495
2496                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2497                 //if(frametime)
2498                 {
2499                         this.items &= ~this.items_added;
2500
2501                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2502                         {
2503                                 .entity weaponentity = weaponentities[slot];
2504                                 W_WeaponFrame(this, weaponentity);
2505
2506                                 if(slot == 0)
2507                                 {
2508                                         this.clip_load = this.(weaponentity).clip_load;
2509                                         this.clip_size = this.(weaponentity).clip_size;
2510                                 }
2511                         }
2512
2513                         this.items_added = 0;
2514                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2515                 this.items_added |= IT_FUEL;
2516
2517                         this.items |= this.items_added;
2518                 }
2519
2520                 player_regen(this);
2521
2522                 // WEAPONTODO: Add a weapon request for this
2523                 // rot vortex charge to the charge limit
2524                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2525                 {
2526                         .entity weaponentity = weaponentities[slot];
2527                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2528                         {
2529                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2530                         }
2531                         if (WEP_CVAR(okvortex, charge_rot_rate) && this.(weaponentity).okvortex_charge > WEP_CVAR(okvortex, charge_limit) && this.(weaponentity).okvortex_charge_rottime < time)
2532                         {
2533                                 this.(weaponentity).okvortex_charge = bound(WEP_CVAR(okvortex, charge_limit), this.(weaponentity).okvortex_charge - WEP_CVAR(okvortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2534                         }
2535                 }
2536
2537                 if (frametime) player_anim(this);
2538
2539                 // secret status
2540                 secrets_setstatus(this);
2541
2542                 // monsters status
2543                 monsters_setstatus(this);
2544
2545                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2546         }
2547         else if (game_stopped || intermission_running) {
2548                 if(intermission_running)
2549                         IntermissionThink(this);
2550                 return;
2551         }
2552         else if (IS_OBSERVER(this)) {
2553                 ObserverThink(this);
2554         }
2555         else if (IS_SPEC(this)) {
2556                 SpectatorThink(this);
2557         }
2558
2559         // WEAPONTODO: Add weapon request for this
2560         if (!zoomstate_set) {
2561                 bool wep_zoomed = false;
2562                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2563                 {
2564                         .entity weaponentity = weaponentities[slot];
2565                         Weapon thiswep = this.(weaponentity).m_weapon;
2566                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2567                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2568                 }
2569                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2570     }
2571
2572         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2573         {
2574                 this.teamkill_soundtime = 0;
2575
2576                 entity e = this.teamkill_soundsource;
2577                 entity oldpusher = e.pusher;
2578                 e.pusher = this;
2579                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2580                 e.pusher = oldpusher;
2581         }
2582
2583         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2584                 this.taunt_soundtime = 0;
2585                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2586         }
2587
2588         target_voicescript_next(this);
2589
2590         // WEAPONTODO: Move into weaponsystem somehow
2591         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2592         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2593         {
2594                 .entity weaponentity = weaponentities[slot];
2595                 if(this.(weaponentity).m_weapon == WEP_Null)
2596                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2597         }
2598 }
2599
2600 void DrownPlayer(entity this)
2601 {
2602         if(IS_DEAD(this))
2603                 return;
2604
2605         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2606         {
2607                 if(this.air_finished < time)
2608                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2609                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2610                 this.dmg = 2;
2611         }
2612         else if (this.air_finished < time)
2613         {       // drown!
2614                 if (this.pain_finished < time)
2615                 {
2616                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2617                         this.pain_finished = time + 0.5;
2618                 }
2619         }
2620 }
2621
2622 .bool move_qcphysics;
2623
2624 void Player_Physics(entity this)
2625 {
2626         set_movetype(this, this.move_movetype);
2627
2628         if(!this.move_qcphysics)
2629                 return;
2630
2631         if(!frametime && !this.pm_frametime)
2632                 return;
2633
2634         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2635
2636         this.pm_frametime = 0;
2637 }
2638
2639 /*
2640 =============
2641 PlayerPostThink
2642
2643 Called every frame for each client after the physics are run
2644 =============
2645 */
2646 .float idlekick_lasttimeleft;
2647 void PlayerPostThink (entity this)
2648 {
2649         Player_Physics(this);
2650
2651         if (sv_maxidle > 0)
2652         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2653         if (IS_REAL_CLIENT(this))
2654         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2655         {
2656                 int totalClients = 0;
2657                 if(sv_maxidle_slots > 0)
2658                 {
2659                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2660                         {
2661                                 ++totalClients;
2662                         });
2663                 }
2664
2665                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2666                 { /* do nothing */ }
2667                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2668                 {
2669                         if (this.idlekick_lasttimeleft)
2670                         {
2671                                 this.idlekick_lasttimeleft = 0;
2672                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2673                         }
2674                 }
2675                 else
2676                 {
2677                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2678                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2679                                 if (!this.idlekick_lasttimeleft)
2680                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2681                         }
2682                         if (timeleft <= 0) {
2683                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2684                                 dropclient(this);
2685                                 return;
2686                         }
2687                         else if (timeleft <= 10) {
2688                                 if (timeleft != this.idlekick_lasttimeleft) {
2689                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2690                 }
2691                                 this.idlekick_lasttimeleft = timeleft;
2692                         }
2693                 }
2694         }
2695
2696         CheatFrame(this);
2697
2698         //CheckPlayerJump();
2699         if (game_stopped)
2700         {
2701                 this.solid = SOLID_NOT;
2702                 this.takedamage = DAMAGE_NO;
2703                 set_movetype(this, MOVETYPE_NONE);
2704         }
2705
2706         if (IS_PLAYER(this)) {
2707                 DrownPlayer(this);
2708                 CheckRules_Player(this);
2709                 UpdateChatBubble(this);
2710                 if (this.impulse) ImpulseCommands(this);
2711                 if (game_stopped)
2712                 {
2713                         CSQCMODEL_AUTOUPDATE(this);
2714                         return;
2715                 }
2716                 GetPressedKeys(this);
2717         }
2718
2719         if (this.waypointsprite_attachedforcarrier) {
2720             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2721                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2722     }
2723
2724         playerdemo_write(this);
2725
2726         CSQCMODEL_AUTOUPDATE(this);
2727 }