qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/mapobjects/func/conveyor.qh"
  37 #include "../common/mapobjects/teleporters.qh"
  38 #include "../common/mapobjects/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  53 #include <common/gamemodes/_mod.qh>
  54
  55 #include "../common/mapobjects/subs.qh"
  56 #include "../common/mapobjects/triggers.qh"
  57 #include "../common/mapobjects/trigger/secret.qh"
  58
  59 #include "../common/minigames/sv_minigames.qh"
  60
  61 #include "../common/items/inventory.qh"
  62
  63 #include "../common/monsters/sv_monsters.qh"
  64
  65 #include "../lib/warpzone/server.qh"
  66
  67 #include <common/mutators/mutator/overkill/oknex.qh>
  68
  69 STATIC_METHOD(Client, Add, void(Client this, int _team))
  70 {
  71     ClientConnect(this);
  72     TRANSMUTE(Player, this);
  73     this.frame = 12; // 7
  74     this.team = _team;
  75     PutClientInServer(this);
  76 }
  77
  78 void PutObserverInServer(entity this);
  79
  80 STATIC_METHOD(Client, Remove, void(Client this))
  81 {
  82     TRANSMUTE(Observer, this);
  83     PutClientInServer(this);
  84     ClientDisconnect(this);
  85 }
  86
  87 void send_CSQC_teamnagger() {
  88         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  89 }
  90
  91 int CountSpectators(entity player, entity to)
  92 {
  93         if(!player) { return 0; } // not sure how, but best to be safe
  94
  95         int spec_count = 0;
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 spec_count++;
 100         });
 101
 102         return spec_count;
 103 }
 104
 105 void WriteSpectators(entity player, entity to)
 106 {
 107         if(!player) { return; } // not sure how, but best to be safe
 108
 109         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 110         {
 111                 WriteByte(MSG_ENTITY, num_for_edict(it));
 112         });
 113 }
 114
 115 bool ClientData_Send(entity this, entity to, int sf)
 116 {
 117         assert(to == this.owner, return false);
 118
 119         entity e = to;
 120         if (IS_SPEC(e)) e = e.enemy;
 121
 122         sf = 0;
 123         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 124         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 125         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 126         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 127
 128         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 129         WriteByte(MSG_ENTITY, sf);
 130
 131         if (sf & BIT(1))
 132                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 133
 134         if(sf & BIT(4))
 135         {
 136                 float specs = CountSpectators(e, to);
 137                 WriteByte(MSG_ENTITY, specs);
 138                 WriteSpectators(e, to);
 139         }
 140
 141         return true;
 142 }
 143
 144 void ClientData_Attach(entity this)
 145 {
 146         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 147         CS(this).clientdata.drawonlytoclient = this;
 148         CS(this).clientdata.owner = this;
 149 }
 150
 151 void ClientData_Detach(entity this)
 152 {
 153         delete(CS(this).clientdata);
 154         CS(this).clientdata = NULL;
 155 }
 156
 157 void ClientData_Touch(entity e)
 158 {
 159         entity cd = CS(e).clientdata;
 160         if (cd) { cd.SendFlags = 1; }
 161
 162         // make it spectatable
 163         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 164         {
 165                 entity cd = CS(it).clientdata;
 166                 if (cd) { cd.SendFlags = 1; }
 167         });
 168 }
 169
 170 void SetSpectatee(entity this, entity spectatee);
 171 void SetSpectatee_status(entity this, int spectatee_num);
 172
 173
 174 /*
 175 =============
 176 CheckPlayerModel
 177
 178 Checks if the argument string can be a valid playermodel.
 179 Returns a valid one in doubt.
 180 =============
 181 */
 182 string FallbackPlayerModel;
 183 string CheckPlayerModel(string plyermodel) {
 184         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 185         {
 186                 // note: we cannot summon Don Strunzone here, some player may
 187                 // still have the model string set. In case anyone manages how
 188                 // to change a cvar default, we'll have a small leak here.
 189                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 190         }
 191         // only in right path
 192         if( substring(plyermodel,0,14) != "models/player/")
 193                 return FallbackPlayerModel;
 194         // only good file extensions
 195         if(substring(plyermodel,-4,4) != ".zym")
 196         if(substring(plyermodel,-4,4) != ".dpm")
 197         if(substring(plyermodel,-4,4) != ".iqm")
 198         if(substring(plyermodel,-4,4) != ".md3")
 199         if(substring(plyermodel,-4,4) != ".psk")
 200                 return FallbackPlayerModel;
 201         // forbid the LOD models
 202         if(substring(plyermodel, -9,5) == "_lod1")
 203                 return FallbackPlayerModel;
 204         if(substring(plyermodel, -9,5) == "_lod2")
 205                 return FallbackPlayerModel;
 206         if(plyermodel != strtolower(plyermodel))
 207                 return FallbackPlayerModel;
 208         // also, restrict to server models
 209         if(autocvar_sv_servermodelsonly)
 210         {
 211                 if(!fexists(plyermodel))
 212                         return FallbackPlayerModel;
 213         }
 214         return plyermodel;
 215 }
 216
 217 void setplayermodel(entity e, string modelname)
 218 {
 219         precache_model(modelname);
 220         _setmodel(e, modelname);
 221         player_setupanimsformodel(e);
 222         if(!autocvar_g_debug_globalsounds)
 223                 UpdatePlayerSounds(e);
 224 }
 225
 226 void FixPlayermodel(entity player);
 227 /** putting a client as observer in the server */
 228 void PutObserverInServer(entity this)
 229 {
 230     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 231         PlayerState_detach(this);
 232
 233         if (IS_PLAYER(this))
 234         {
 235                 if(this.health >= 1)
 236                 {
 237                         // despawn effect
 238                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 239                 }
 240
 241                 // was a player, recount votes and ready status
 242                 if(IS_REAL_CLIENT(this))
 243                 {
 244                         if (vote_called) { VoteCount(false); }
 245                         ReadyCount();
 246                 }
 247     }
 248
 249     {
 250         entity spot = SelectSpawnPoint(this, true);
 251         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 252         this.angles = vec2(spot.angles);
 253         this.fixangle = true;
 254         // offset it so that the spectator spawns higher off the ground, looks better this way
 255         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 256         if (IS_REAL_CLIENT(this))
 257         {
 258             msg_entity = this;
 259             WriteByte(MSG_ONE, SVC_SETVIEW);
 260             WriteEntity(MSG_ONE, this);
 261         }
 262         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 263         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 264         if(!autocvar_g_debug_globalsounds)
 265         {
 266                 // needed for player sounds
 267                 this.model = "";
 268                 FixPlayermodel(this);
 269         }
 270         setmodel(this, MDL_Null);
 271         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 272         this.view_ofs = '0 0 0';
 273     }
 274
 275     RemoveGrapplingHooks(this);
 276         Portal_ClearAll(this);
 277         Unfreeze(this);
 278         SetSpectatee(this, NULL);
 279
 280         if (this.alivetime)
 281         {
 282                 if (!warmup_stage)
 283                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 284                 this.alivetime = 0;
 285         }
 286
 287         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 288
 289         WaypointSprite_PlayerDead(this);
 290
 291         if (mutator_returnvalue) {
 292             // mutator prevents resetting teams+score
 293         } else {
 294                 Player_SetTeamIndex(this, -1);
 295                 this.frags = FRAGS_SPECTATOR;
 296         PlayerScore_Clear(this);  // clear scores when needed
 297     }
 298
 299         if (CS(this).killcount != FRAGS_SPECTATOR)
 300         {
 301                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 302                 if(!game_stopped)
 303                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 304                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 305
 306                 if(!CS(this).just_joined)
 307                         LogTeamchange(this.playerid, -1, TEAM_CHANGE_SPECTATOR);
 308                 else
 309                         CS(this).just_joined = false;
 310         }
 311
 312         accuracy_resend(this);
 313
 314         CS(this).spectatortime = time;
 315         if(this.bot_attack)
 316                 IL_REMOVE(g_bot_targets, this);
 317         this.bot_attack = false;
 318         if(this.monster_attack)
 319                 IL_REMOVE(g_monster_targets, this);
 320         this.monster_attack = false;
 321     STAT(HUD, this) = HUD_NORMAL;
 322         TRANSMUTE(Observer, this);
 323         this.iscreature = false;
 324         this.teleportable = TELEPORT_SIMPLE;
 325         if(this.damagedbycontents)
 326                 IL_REMOVE(g_damagedbycontents, this);
 327         this.damagedbycontents = false;
 328         this.health = FRAGS_SPECTATOR;
 329         SetSpectatee_status(this, etof(this));
 330         this.takedamage = DAMAGE_NO;
 331         this.solid = SOLID_NOT;
 332         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 333         this.flags = FL_CLIENT | FL_NOTARGET;
 334         this.armorvalue = 666;
 335         this.effects = 0;
 336         this.armorvalue = autocvar_g_balance_armor_start;
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_frame = 0;
 349         this.pain_finished = 0;
 350         this.strength_finished = 0;
 351         this.invincible_finished = 0;
 352         this.superweapons_finished = 0;
 353         this.dphitcontentsmask = 0;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         this.crouch = false;
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362
 363         this.items = 0;
 364         STAT(WEAPONS, this) = '0 0 0';
 365         this.drawonlytoclient = this;
 366
 367         this.viewloc = NULL;
 368
 369         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 370
 371         this.weaponmodel = "";
 372         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 373         {
 374                 this.weaponentities[slot] = NULL;
 375         }
 376         this.exteriorweaponentity = NULL;
 377         CS(this).killcount = FRAGS_SPECTATOR;
 378         this.velocity = '0 0 0';
 379         this.avelocity = '0 0 0';
 380         this.punchangle = '0 0 0';
 381         this.punchvector = '0 0 0';
 382         this.oldvelocity = this.velocity;
 383         this.fire_endtime = -1;
 384         this.event_damage = func_null;
 385
 386         for(int slot = 0; slot < MAX_AXH; ++slot)
 387         {
 388                 entity axh = this.(AuxiliaryXhair[slot]);
 389                 this.(AuxiliaryXhair[slot]) = NULL;
 390
 391                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 392                         delete(axh);
 393         }
 394 }
 395
 396 int player_getspecies(entity this)
 397 {
 398         get_model_parameters(this.model, this.skin);
 399         int s = get_model_parameters_species;
 400         get_model_parameters(string_null, 0);
 401         if (s < 0) return SPECIES_HUMAN;
 402         return s;
 403 }
 404
 405 .float model_randomizer;
 406 void FixPlayermodel(entity player)
 407 {
 408         string defaultmodel = "";
 409         int defaultskin = 0;
 410         if(autocvar_sv_defaultcharacter)
 411         {
 412                 if(teamplay)
 413                 {
 414                         switch(player.team)
 415                         {
 416                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 417                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 418                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 419                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 420                         }
 421                 }
 422
 423                 if(defaultmodel == "")
 424                 {
 425                         defaultmodel = autocvar_sv_defaultplayermodel;
 426                         defaultskin = autocvar_sv_defaultplayerskin;
 427                 }
 428
 429                 int n = tokenize_console(defaultmodel);
 430                 if(n > 0)
 431                 {
 432                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 433                         // However, do NOT randomize if the player-selected model is in the list.
 434                         for (int i = 0; i < n; ++i)
 435                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 436                                         defaultmodel = argv(i);
 437                 }
 438
 439                 int i = strstrofs(defaultmodel, ":", 0);
 440                 if(i >= 0)
 441                 {
 442                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 443                         defaultmodel = substring(defaultmodel, 0, i);
 444                 }
 445         }
 446         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 447         {
 448                 if(teamplay)
 449                 {
 450                         switch(player.team)
 451                         {
 452                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 453                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 454                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 455                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 456                         }
 457                 }
 458
 459                 if(!defaultskin)
 460                         defaultskin = autocvar_sv_defaultplayerskin;
 461         }
 462
 463         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 464         defaultmodel = M_ARGV(0, string);
 465         defaultskin = M_ARGV(1, int);
 466
 467         bool chmdl = false;
 468         int oldskin;
 469         if(defaultmodel != "")
 470         {
 471                 if (defaultmodel != player.model)
 472                 {
 473                         vector m1 = player.mins;
 474                         vector m2 = player.maxs;
 475                         setplayermodel (player, defaultmodel);
 476                         setsize (player, m1, m2);
 477                         chmdl = true;
 478                 }
 479
 480                 oldskin = player.skin;
 481                 player.skin = defaultskin;
 482         } else {
 483                 if (player.playermodel != player.model || player.playermodel == "")
 484                 {
 485                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 486                         vector m1 = player.mins;
 487                         vector m2 = player.maxs;
 488                         setplayermodel (player, player.playermodel);
 489                         setsize (player, m1, m2);
 490                         chmdl = true;
 491                 }
 492
 493                 if(!autocvar_sv_defaultcharacterskin)
 494                 {
 495                         oldskin = player.skin;
 496                         player.skin = stof(player.playerskin);
 497                 }
 498                 else
 499                 {
 500                         oldskin = player.skin;
 501                         player.skin = defaultskin;
 502                 }
 503         }
 504
 505         if(chmdl || oldskin != player.skin) // model or skin has changed
 506         {
 507                 player.species = player_getspecies(player); // update species
 508                 if(!autocvar_g_debug_globalsounds)
 509                         UpdatePlayerSounds(player); // update skin sounds
 510         }
 511
 512         if(!teamplay)
 513                 if(strlen(autocvar_sv_defaultplayercolors))
 514                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 515                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 516 }
 517
 518 void PutPlayerInServer(entity this)
 519 {
 520         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 521
 522         PlayerState_attach(this);
 523         accuracy_resend(this);
 524
 525         if (this.team < 0)
 526                 TeamBalance_JoinBestTeam(this, true);
 527
 528         entity spot = SelectSpawnPoint(this, false);
 529         if (!spot) {
 530                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 531                 return; // spawn failed
 532         }
 533
 534         TRANSMUTE(Player, this);
 535
 536         CS(this).wasplayer = true;
 537         this.iscreature = true;
 538         this.teleportable = TELEPORT_NORMAL;
 539         if(!this.damagedbycontents)
 540                 IL_PUSH(g_damagedbycontents, this);
 541         this.damagedbycontents = true;
 542         set_movetype(this, MOVETYPE_WALK);
 543         this.solid = SOLID_SLIDEBOX;
 544         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 545         if (autocvar_g_playerclip_collisions)
 546                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 547         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 548                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 549         this.frags = FRAGS_PLAYER;
 550         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 551         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 552         if (autocvar__notarget)
 553                 this.flags |= FL_NOTARGET;
 554         this.takedamage = DAMAGE_AIM;
 555         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 556
 557         if (warmup_stage) {
 558                 this.ammo_shells = warmup_start_ammo_shells;
 559                 this.ammo_nails = warmup_start_ammo_nails;
 560                 this.ammo_rockets = warmup_start_ammo_rockets;
 561                 this.ammo_cells = warmup_start_ammo_cells;
 562                 this.ammo_plasma = warmup_start_ammo_plasma;
 563                 this.ammo_fuel = warmup_start_ammo_fuel;
 564                 this.health = warmup_start_health;
 565                 this.armorvalue = warmup_start_armorvalue;
 566                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 567         } else {
 568                 this.ammo_shells = start_ammo_shells;
 569                 this.ammo_nails = start_ammo_nails;
 570                 this.ammo_rockets = start_ammo_rockets;
 571                 this.ammo_cells = start_ammo_cells;
 572                 this.ammo_plasma = start_ammo_plasma;
 573                 this.ammo_fuel = start_ammo_fuel;
 574                 this.health = start_health;
 575                 this.armorvalue = start_armorvalue;
 576                 STAT(WEAPONS, this) = start_weapons;
 577                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 578                 {
 579                         GiveRandomWeapons(this, random_start_weapons_count,
 580                                 autocvar_g_random_start_weapons, random_start_ammo);
 581                 }
 582         }
 583         SetSpectatee_status(this, 0);
 584
 585         PS(this).dual_weapons = '0 0 0';
 586
 587         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 588
 589         this.items = start_items;
 590
 591         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 592         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 593         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 594         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 595         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 596         if (!sv_ready_restart_after_countdown && time < game_starttime)
 597         {
 598                 float f = game_starttime - time;
 599                 this.spawnshieldtime += f;
 600                 this.pauserotarmor_finished += f;
 601                 this.pauserothealth_finished += f;
 602                 this.pauseregen_finished += f;
 603         }
 604
 605         this.damageforcescale = 2;
 606         this.death_time = 0;
 607         this.respawn_flags = 0;
 608         this.respawn_time = 0;
 609         STAT(RESPAWN_TIME, this) = 0;
 610         this.scale = autocvar_sv_player_scale;
 611         this.fade_time = 0;
 612         this.pain_frame = 0;
 613         this.pain_finished = 0;
 614         this.pushltime = 0;
 615         setthink(this, func_null); // players have no think function
 616         this.nextthink = 0;
 617         this.dmg_team = 0;
 618         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 619
 620         this.deadflag = DEAD_NO;
 621
 622         this.angles = spot.angles;
 623         this.angles_z = 0; // never spawn tilted even if the spot says to
 624         if (IS_BOT_CLIENT(this))
 625                 this.v_angle = this.angles;
 626         this.fixangle = true; // turn this way immediately
 627         this.oldvelocity = this.velocity = '0 0 0';
 628         this.avelocity = '0 0 0';
 629         this.punchangle = '0 0 0';
 630         this.punchvector = '0 0 0';
 631
 632         this.strength_finished = 0;
 633         this.invincible_finished = 0;
 634         this.fire_endtime = -1;
 635         STAT(REVIVE_PROGRESS, this) = 0;
 636         this.revival_time = 0;
 637
 638         this.air_finished = time + 12;
 639         this.waterlevel = WATERLEVEL_NONE;
 640         this.watertype = CONTENT_EMPTY;
 641
 642         entity spawnevent = new_pure(spawnevent);
 643         spawnevent.owner = this;
 644         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 645
 646         // Cut off any still running player sounds.
 647         stopsound(this, CH_PLAYER_SINGLE);
 648
 649         this.model = "";
 650         FixPlayermodel(this);
 651         this.drawonlytoclient = NULL;
 652
 653         this.viewloc = NULL;
 654
 655         for(int slot = 0; slot < MAX_AXH; ++slot)
 656         {
 657                 entity axh = this.(AuxiliaryXhair[slot]);
 658                 this.(AuxiliaryXhair[slot]) = NULL;
 659
 660                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 661                         delete(axh);
 662         }
 663
 664         this.spawnpoint_targ = NULL;
 665
 666         this.crouch = false;
 667         this.view_ofs = STAT(PL_VIEW_OFS, this);
 668         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 669         this.spawnorigin = spot.origin;
 670         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 671         // don't reset back to last position, even if new position is stuck in solid
 672         this.oldorigin = this.origin;
 673         if(this.conveyor)
 674                 IL_REMOVE(g_conveyed, this);
 675         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 676         STAT(HUD, this) = HUD_NORMAL;
 677
 678         this.event_damage = PlayerDamage;
 679
 680         if(!this.bot_attack)
 681                 IL_PUSH(g_bot_targets, this);
 682         this.bot_attack = true;
 683         if(!this.monster_attack)
 684                 IL_PUSH(g_monster_targets, this);
 685         this.monster_attack = true;
 686         navigation_dynamicgoal_init(this, false);
 687
 688         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 689
 690         // player was spectator
 691         if (CS(this).killcount == FRAGS_SPECTATOR) {
 692                 PlayerScore_Clear(this);
 693                 CS(this).killcount = 0;
 694                 CS(this).startplaytime = time;
 695         }
 696
 697         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 698         {
 699                 .entity weaponentity = weaponentities[slot];
 700                 entity oldwep = this.(weaponentity);
 701                 CL_SpawnWeaponentity(this, weaponentity);
 702                 if(oldwep && oldwep.owner == this)
 703                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 704         }
 705         this.alpha = default_player_alpha;
 706         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 707         this.exteriorweaponentity.alpha = default_weapon_alpha;
 708
 709         this.speedrunning = false;
 710
 711         target_voicescript_clear(this);
 712
 713         // reset fields the weapons may use
 714         FOREACH(Weapons, true, {
 715                 it.wr_resetplayer(it, this);
 716                         // reload all reloadable weapons
 717                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 718                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 719                         {
 720                                 .entity weaponentity = weaponentities[slot];
 721                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 722                         }
 723                 }
 724         });
 725
 726         {
 727                 string s = spot.target;
 728                 spot.target = string_null;
 729                 SUB_UseTargets(spot, this, NULL);
 730                 spot.target = s;
 731         }
 732
 733         Unfreeze(this);
 734
 735         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 736
 737         if (autocvar_spawn_debug)
 738         {
 739                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 740                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 741         }
 742
 743         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 744         {
 745                 .entity weaponentity = weaponentities[slot];
 746                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 747                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 748                 else
 749                         this.(weaponentity).m_switchweapon = WEP_Null;
 750                 this.(weaponentity).m_weapon = WEP_Null;
 751                 this.(weaponentity).weaponname = "";
 752                 this.(weaponentity).m_switchingweapon = WEP_Null;
 753                 this.(weaponentity).cnt = -1;
 754         }
 755
 756         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 757
 758         if (!warmup_stage && !this.alivetime)
 759                 this.alivetime = time;
 760
 761         antilag_clear(this, CS(this));
 762 }
 763
 764 /** Called when a client spawns in the server */
 765 void PutClientInServer(entity this)
 766 {
 767         if (IS_BOT_CLIENT(this)) {
 768                 TRANSMUTE(Player, this);
 769         } else if (IS_REAL_CLIENT(this)) {
 770                 msg_entity = this;
 771                 WriteByte(MSG_ONE, SVC_SETVIEW);
 772                 WriteEntity(MSG_ONE, this);
 773         }
 774         if (game_stopped)
 775                 TRANSMUTE(Observer, this);
 776
 777         SetSpectatee(this, NULL);
 778
 779         // reset player keys
 780         if(PS(this))
 781                 PS(this).itemkeys = 0;
 782
 783         MUTATOR_CALLHOOK(PutClientInServer, this);
 784
 785         if (IS_OBSERVER(this)) {
 786                 PutObserverInServer(this);
 787         } else if (IS_PLAYER(this)) {
 788                 PutPlayerInServer(this);
 789         }
 790 }
 791
 792 void ClientInit_misc(entity this);
 793
 794 // TODO do we need all these fields, or should we stop autodetecting runtime
 795 // changes and just have a console command to update this?
 796 bool ClientInit_SendEntity(entity this, entity to, int sf)
 797 {
 798         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 799         return = true;
 800         msg_entity = to;
 801         // MSG_INIT replacement
 802         // TODO: make easier to use
 803         Registry_send_all();
 804         W_PROP_reload(MSG_ONE, to);
 805         ClientInit_misc(this);
 806         MUTATOR_CALLHOOK(Ent_Init);
 807 }
 808 void ClientInit_misc(entity this)
 809 {
 810         int channel = MSG_ONE;
 811         WriteHeader(channel, ENT_CLIENT_INIT);
 812         WriteByte(channel, g_nexball_meter_period * 32);
 813         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 814         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 815         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 816         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 817         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 818         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 819         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 820         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 821
 822         if(sv_foginterval && world.fog != "")
 823                 WriteString(channel, world.fog);
 824         else
 825                 WriteString(channel, "");
 826         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 827         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 828         WriteByte(channel, serverflags);
 829         WriteCoord(channel, autocvar_g_trueaim_minrange);
 830 }
 831
 832 void ClientInit_CheckUpdate(entity this)
 833 {
 834         this.nextthink = time;
 835         if(this.count != autocvar_g_balance_armor_blockpercent)
 836         {
 837                 this.count = autocvar_g_balance_armor_blockpercent;
 838                 this.SendFlags |= 1;
 839         }
 840         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 841         {
 842                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 843                 this.SendFlags |= 1;
 844         }
 845 }
 846
 847 void ClientInit_Spawn()
 848 {
 849         entity e = new_pure(clientinit);
 850         setthink(e, ClientInit_CheckUpdate);
 851         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 852
 853         ClientInit_CheckUpdate(e);
 854 }
 855
 856 /*
 857 =============
 858 SetNewParms
 859 =============
 860 */
 861 void SetNewParms ()
 862 {
 863         // initialize parms for a new player
 864         parm1 = -(86400 * 366);
 865
 866         MUTATOR_CALLHOOK(SetNewParms);
 867 }
 868
 869 /*
 870 =============
 871 SetChangeParms
 872 =============
 873 */
 874 void SetChangeParms (entity this)
 875 {
 876         // save parms for level change
 877         parm1 = CS(this).parm_idlesince - time;
 878
 879         MUTATOR_CALLHOOK(SetChangeParms);
 880 }
 881
 882 /*
 883 =============
 884 DecodeLevelParms
 885 =============
 886 */
 887 void DecodeLevelParms(entity this)
 888 {
 889         // load parms
 890         CS(this).parm_idlesince = parm1;
 891         if (CS(this).parm_idlesince == -(86400 * 366))
 892                 CS(this).parm_idlesince = time;
 893
 894         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 895         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 896
 897         MUTATOR_CALLHOOK(DecodeLevelParms);
 898 }
 899
 900 /*
 901 =============
 902 ClientKill
 903
 904 Called when a client types 'kill' in the console
 905 =============
 906 */
 907
 908 .float clientkill_nexttime;
 909 void ClientKill_Now_TeamChange(entity this)
 910 {
 911         if(this.killindicator_teamchange == -1)
 912         {
 913                 TeamBalance_JoinBestTeam(this, true);
 914         }
 915         else if(this.killindicator_teamchange == -2)
 916         {
 917                 if(blockSpectators)
 918                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 919                 PutObserverInServer(this);
 920         }
 921         else
 922                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 923         this.killindicator_teamchange = 0;
 924 }
 925
 926 void ClientKill_Now(entity this)
 927 {
 928         if(this.vehicle)
 929         {
 930             vehicles_exit(this.vehicle, VHEF_RELEASE);
 931             if(!this.killindicator_teamchange)
 932             {
 933             this.vehicle_health = -1;
 934             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 935             }
 936         }
 937
 938         if(this.killindicator && !wasfreed(this.killindicator))
 939                 delete(this.killindicator);
 940
 941         this.killindicator = NULL;
 942
 943         if(this.killindicator_teamchange)
 944                 ClientKill_Now_TeamChange(this);
 945
 946         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 947         {
 948                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 949         }
 950
 951         // now I am sure the player IS dead
 952 }
 953 void KillIndicator_Think(entity this)
 954 {
 955         if (game_stopped)
 956         {
 957                 this.owner.killindicator = NULL;
 958                 delete(this);
 959                 return;
 960         }
 961
 962         if (this.owner.alpha < 0 && !this.owner.vehicle)
 963         {
 964                 this.owner.killindicator = NULL;
 965                 delete(this);
 966                 return;
 967         }
 968
 969         if(this.cnt <= 0)
 970         {
 971                 ClientKill_Now(this.owner);
 972                 return;
 973         }
 974     else if(this.health == 1) // health == 1 means that it's silent
 975     {
 976         this.nextthink = time + 1;
 977         this.cnt -= 1;
 978     }
 979         else
 980         {
 981                 if(this.cnt <= 10)
 982                         setmodel(this, MDL_NUM(this.cnt));
 983                 if(IS_REAL_CLIENT(this.owner))
 984                 {
 985                         if(this.cnt <= 10)
 986                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 987                 }
 988                 this.nextthink = time + 1;
 989                 this.cnt -= 1;
 990         }
 991 }
 992
 993 float clientkilltime;
 994 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 995 {
 996         float killtime;
 997         float starttime;
 998
 999         if (game_stopped)
1000                 return;
1001
1002         killtime = autocvar_g_balance_kill_delay;
1003
1004     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1005         return;
1006     killtime = M_ARGV(1, float);
1007
1008         this.killindicator_teamchange = targetteam;
1009
1010     if(!this.killindicator)
1011         {
1012                 if(!IS_DEAD(this))
1013                 {
1014                         killtime = max(killtime, this.clientkill_nexttime - time);
1015                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1016                 }
1017
1018                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1019                 {
1020                         ClientKill_Now(this);
1021                 }
1022                 else
1023                 {
1024                         starttime = max(time, clientkilltime);
1025
1026                         this.killindicator = spawn();
1027                         this.killindicator.owner = this;
1028                         this.killindicator.scale = 0.5;
1029                         setattachment(this.killindicator, this, "");
1030                         setorigin(this.killindicator, '0 0 52');
1031                         setthink(this.killindicator, KillIndicator_Think);
1032                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1033                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1034                         this.killindicator.cnt = ceil(killtime);
1035                         this.killindicator.count = bound(0, ceil(killtime), 10);
1036                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1037
1038                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1039                         {
1040                                 it.killindicator = spawn();
1041                                 it.killindicator.owner = it;
1042                                 it.killindicator.scale = 0.5;
1043                                 setattachment(it.killindicator, it, "");
1044                                 setorigin(it.killindicator, '0 0 52');
1045                                 setthink(it.killindicator, KillIndicator_Think);
1046                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1047                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1048                                 it.killindicator.cnt = ceil(killtime);
1049                         });
1050                         this.lip = 0;
1051                 }
1052         }
1053         if(this.killindicator)
1054         {
1055                 if(targetteam == 0) // just die
1056                 {
1057                         this.killindicator.colormod = '0 0 0';
1058                         if(IS_REAL_CLIENT(this))
1059                         if(this.killindicator.cnt > 0)
1060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1061                 }
1062                 else if(targetteam == -1) // auto
1063                 {
1064                         this.killindicator.colormod = '0 1 0';
1065                         if(IS_REAL_CLIENT(this))
1066                         if(this.killindicator.cnt > 0)
1067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1068                 }
1069                 else if(targetteam == -2) // spectate
1070                 {
1071                         this.killindicator.colormod = '0.5 0.5 0.5';
1072                         if(IS_REAL_CLIENT(this))
1073                         if(this.killindicator.cnt > 0)
1074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1075                 }
1076                 else
1077                 {
1078                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1079                         if(IS_REAL_CLIENT(this))
1080                         if(this.killindicator.cnt > 0)
1081                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1082                 }
1083         }
1084
1085 }
1086
1087 void ClientKill (entity this)
1088 {
1089         if(game_stopped) return;
1090         if(this.player_blocked) return;
1091         if(STAT(FROZEN, this)) return;
1092
1093         ClientKill_TeamChange(this, 0);
1094 }
1095
1096 void FixClientCvars(entity e)
1097 {
1098         // send prediction settings to the client
1099         stuffcmd(e, "\nin_bindmap 0 0\n");
1100         if(autocvar_g_antilag == 3) // client side hitscan
1101                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1102         if(autocvar_sv_gentle)
1103                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1104
1105         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1106         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1107
1108         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1109
1110         MUTATOR_CALLHOOK(FixClientCvars, e);
1111 }
1112
1113 bool findinlist_abbrev(string tofind, string list)
1114 {
1115         if(list == "" || tofind == "")
1116                 return false; // empty list or search, just return
1117
1118         // this function allows abbreviated strings!
1119         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1120         {
1121                 return true;
1122         });
1123
1124         return false;
1125 }
1126
1127 bool PlayerInIPList(entity p, string iplist)
1128 {
1129         // some safety checks (never allow local?)
1130         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1131                 return false;
1132
1133         return findinlist_abbrev(p.netaddress, iplist);
1134 }
1135
1136 bool PlayerInIDList(entity p, string idlist)
1137 {
1138         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1139         if(!p.crypto_idfp)
1140                 return false;
1141
1142         return findinlist_abbrev(p.crypto_idfp, idlist);
1143 }
1144
1145 bool PlayerInList(entity player, string list)
1146 {
1147         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1148 }
1149
1150 #ifdef DP_EXT_PRECONNECT
1151 /*
1152 =============
1153 ClientPreConnect
1154
1155 Called once (not at each match start) when a client begins a connection to the server
1156 =============
1157 */
1158 void ClientPreConnect(entity this)
1159 {
1160         if(autocvar_sv_eventlog)
1161         {
1162                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1163                         this.playerid,
1164                         etof(this),
1165                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1166                 ));
1167         }
1168 }
1169 #endif
1170
1171 string GetClientVersionMessage(entity this)
1172 {
1173         if (CS(this).version_mismatch) {
1174                 if(CS(this).version < autocvar_gameversion) {
1175                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1176                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1177                 } else {
1178                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1179                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1180                 }
1181         } else {
1182                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1183         }
1184 }
1185
1186 string getwelcomemessage(entity this)
1187 {
1188         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1189         string modifications = M_ARGV(0, string);
1190
1191         if(g_weaponarena)
1192         {
1193                 if(g_weaponarena_random)
1194                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1195                 else
1196                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1197         }
1198         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1199                 modifications = strcat(modifications, ", No start weapons");
1200         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1201                 modifications = strcat(modifications, ", Low gravity");
1202         if(g_weapon_stay && !g_cts)
1203                 modifications = strcat(modifications, ", Weapons stay");
1204         if(g_jetpack)
1205                 modifications = strcat(modifications, ", Jet pack");
1206         if(autocvar_g_powerups == 0)
1207                 modifications = strcat(modifications, ", No powerups");
1208         if(autocvar_g_powerups > 0)
1209                 modifications = strcat(modifications, ", Powerups");
1210         modifications = substring(modifications, 2, strlen(modifications) - 2);
1211
1212         string versionmessage = GetClientVersionMessage(this);
1213         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1214
1215         if(modifications != "")
1216                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1217
1218         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1219         {
1220                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1221                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1222         }
1223
1224         if (cache_mutatormsg != "") {
1225                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1226         }
1227
1228         string mutator_msg = "";
1229         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1230         mutator_msg = M_ARGV(0, string);
1231
1232         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1233
1234         string motd = autocvar_sv_motd;
1235         if (motd != "") {
1236                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1237         }
1238         return s;
1239 }
1240
1241 /**
1242 =============
1243 ClientConnect
1244
1245 Called when a client connects to the server
1246 =============
1247 */
1248 void ClientConnect(entity this)
1249 {
1250         if (Ban_MaybeEnforceBanOnce(this)) return;
1251         assert(!IS_CLIENT(this), return);
1252         this.flags |= FL_CLIENT;
1253         assert(player_count >= 0, player_count = 0);
1254
1255 #ifdef WATERMARK
1256         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1257 #endif
1258         TRANSMUTE(Client, this);
1259         CS(this).version_nagtime = time + 10 + random() * 10;
1260
1261         // identify the right forced team
1262         if (autocvar_g_campaign)
1263         {
1264                 if (IS_REAL_CLIENT(this)) // only players, not bots
1265                 {
1266                         switch (autocvar_g_campaign_forceteam)
1267                         {
1268                                 case 1: this.team_forced = NUM_TEAM_1; break;
1269                                 case 2: this.team_forced = NUM_TEAM_2; break;
1270                                 case 3: this.team_forced = NUM_TEAM_3; break;
1271                                 case 4: this.team_forced = NUM_TEAM_4; break;
1272                                 default: this.team_forced = 0;
1273                         }
1274                 }
1275         }
1276         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1277         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1278         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1279         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1280         else switch (autocvar_g_forced_team_otherwise)
1281         {
1282                 default: this.team_forced = 0; break;
1283                 case "red": this.team_forced = NUM_TEAM_1; break;
1284                 case "blue": this.team_forced = NUM_TEAM_2; break;
1285                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1286                 case "pink": this.team_forced = NUM_TEAM_4; break;
1287                 case "spectate":
1288                 case "spectator":
1289                         this.team_forced = -1;
1290                         break;
1291         }
1292         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1293
1294         int playerid_save = this.playerid;
1295         this.playerid = 0; // silent
1296         TeamBalance_JoinBestTeam(this, false); // if the team number is valid, keep it
1297         this.playerid = playerid_save;
1298
1299         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1300                 TRANSMUTE(Observer, this);
1301         } else {
1302                 if (!teamplay || autocvar_g_balance_teams) {
1303                         TRANSMUTE(Player, this);
1304                         campaign_bots_may_start = true;
1305                 } else {
1306                         TRANSMUTE(Observer, this); // do it anyway
1307                 }
1308         }
1309
1310         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1311
1312         // always track bots, don't ask for cl_allow_uidtracking
1313         if (IS_BOT_CLIENT(this))
1314                 PlayerStats_GameReport_AddPlayer(this);
1315         else
1316                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1317
1318         if (autocvar_sv_eventlog)
1319                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1320
1321         LogTeamchange(this.playerid, this.team, TEAM_CHANGE_CONNECT);
1322
1323         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1324
1325         if(teamplay && IS_PLAYER(this))
1326                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1327         else
1328                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1329
1330         stuffcmd(this, clientstuff, "\n");
1331         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1332
1333         FixClientCvars(this);
1334
1335         // get version info from player
1336         stuffcmd(this, "cmd clientversion $gameversion\n");
1337
1338         // notify about available teams
1339         if (teamplay)
1340         {
1341                 entity balance = TeamBalance_CheckAllowedTeams(this);
1342                 int t = TeamBalance_GetAllowedTeams(balance);
1343                 TeamBalance_Destroy(balance);
1344                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1345         }
1346         else
1347         {
1348                 stuffcmd(this, "set _teams_available 0\n");
1349         }
1350
1351         bot_relinkplayerlist();
1352
1353         CS(this).spectatortime = time;
1354         if (blockSpectators)
1355         {
1356                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1357         }
1358
1359         CS(this).jointime = time;
1360
1361         if (IS_REAL_CLIENT(this))
1362         {
1363                 if (g_weaponarena_weapons == WEPSET(TUBA))
1364                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1365         }
1366
1367         if (!sv_foginterval && world.fog != "")
1368                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1369
1370         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1371                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1372                         send_CSQC_teamnagger();
1373
1374         CSQCMODEL_AUTOINIT(this);
1375
1376         CS(this).model_randomizer = random();
1377
1378         if (IS_REAL_CLIENT(this))
1379                 sv_notice_join(this);
1380
1381         // update physics stats (players can spawn before physics runs)
1382         Physics_UpdateStats(this);
1383
1384         IL_EACH(g_initforplayer, it.init_for_player, {
1385                 it.init_for_player(it, this);
1386         });
1387
1388         Handicap_Initialize(this);
1389
1390         MUTATOR_CALLHOOK(ClientConnect, this);
1391
1392         if (IS_REAL_CLIENT(this))
1393         {
1394                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1395                 {
1396                         CS(this).motd_actived_time = -1;
1397                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1398                 }
1399         }
1400 }
1401 /*
1402 =============
1403 ClientDisconnect
1404
1405 Called when a client disconnects from the server
1406 =============
1407 */
1408 .entity chatbubbleentity;
1409 void ReadyCount();
1410 void ClientDisconnect(entity this)
1411 {
1412         assert(IS_CLIENT(this), return);
1413
1414         PlayerStats_GameReport_FinalizePlayer(this);
1415         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1416         if (CS(this).active_minigame) part_minigame(this);
1417         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1418
1419         if (autocvar_sv_eventlog)
1420                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1421
1422         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1423
1424         if(IS_SPEC(this))
1425                 SetSpectatee(this, NULL);
1426
1427     MUTATOR_CALLHOOK(ClientDisconnect, this);
1428
1429         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1430         strfree(CS(this).weaponorder_byimpulse);
1431         ClientState_detach(this);
1432
1433         Portal_ClearAll(this);
1434
1435         Unfreeze(this);
1436
1437         RemoveGrapplingHooks(this);
1438
1439         // Here, everything has been done that requires this player to be a client.
1440
1441         this.flags &= ~FL_CLIENT;
1442
1443         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1444         if (this.killindicator) delete(this.killindicator);
1445
1446         WaypointSprite_PlayerGone(this);
1447
1448         bot_relinkplayerlist();
1449
1450         strfree(this.clientstatus);
1451         if (this.personal) delete(this.personal);
1452
1453         this.playerid = 0;
1454         ReadyCount();
1455         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1456
1457         ONREMOVE(this);
1458 }
1459
1460 void ChatBubbleThink(entity this)
1461 {
1462         this.nextthink = time;
1463         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1464         {
1465                 if(this.owner) // but why can that ever be NULL?
1466                         this.owner.chatbubbleentity = NULL;
1467                 delete(this);
1468                 return;
1469         }
1470
1471         this.mdl = "";
1472
1473         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1474         {
1475                 if ( CS(this.owner).active_minigame )
1476                         this.mdl = "models/sprites/minigame_busy.iqm";
1477                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1478                         this.mdl = "models/misc/chatbubble.spr";
1479         }
1480
1481         if ( this.model != this.mdl )
1482                 _setmodel(this, this.mdl);
1483
1484 }
1485
1486 void UpdateChatBubble(entity this)
1487 {
1488         if (this.alpha < 0)
1489                 return;
1490         // spawn a chatbubble entity if needed
1491         if (!this.chatbubbleentity)
1492         {
1493                 this.chatbubbleentity = new(chatbubbleentity);
1494                 this.chatbubbleentity.owner = this;
1495                 this.chatbubbleentity.exteriormodeltoclient = this;
1496                 setthink(this.chatbubbleentity, ChatBubbleThink);
1497                 this.chatbubbleentity.nextthink = time;
1498                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1499                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1500                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1501                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1502                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1503                 //this.chatbubbleentity.model = "";
1504                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1505         }
1506 }
1507
1508
1509 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1510 // added to the model skins
1511 /*void UpdateColorModHack()
1512 {
1513         float c;
1514         c = this.clientcolors & 15;
1515         // LordHavoc: only bothering to support white, green, red, yellow, blue
1516              if (!teamplay) this.colormod = '0 0 0';
1517         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1518         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1519         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1520         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1521         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1522         else this.colormod = '1 1 1';
1523 }*/
1524
1525 void respawn(entity this)
1526 {
1527         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1528         {
1529                 this.solid = SOLID_NOT;
1530                 this.takedamage = DAMAGE_NO;
1531                 set_movetype(this, MOVETYPE_FLY);
1532                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1533                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1534                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1535                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1536                 if(autocvar_g_respawn_ghosts_maxtime)
1537                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1538         }
1539
1540         CopyBody(this, 1);
1541
1542         this.effects |= EF_NODRAW; // prevent another CopyBody
1543         PutClientInServer(this);
1544 }
1545
1546 void play_countdown(entity this, float finished, Sound samp)
1547 {
1548     TC(Sound, samp);
1549         if(IS_REAL_CLIENT(this))
1550                 if(floor(finished - time - frametime) != floor(finished - time))
1551                         if(finished - time < 6)
1552                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1553 }
1554
1555 void player_powerups(entity this)
1556 {
1557         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1558         int items_prev = this.items;
1559
1560         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1561                 this.modelflags |= MF_ROCKET;
1562         else
1563                 this.modelflags &= ~MF_ROCKET;
1564
1565         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1566
1567         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1568                 return;
1569
1570         Fire_ApplyDamage(this);
1571         Fire_ApplyEffect(this);
1572
1573         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1574         {
1575                 if (this.items & ITEM_Strength.m_itemid)
1576                 {
1577                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1578                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1579                         if (time > this.strength_finished)
1580                         {
1581                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1582                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1583                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1584                         }
1585                 }
1586                 else
1587                 {
1588                         if (time < this.strength_finished)
1589                         {
1590                                 this.items = this.items | ITEM_Strength.m_itemid;
1591                                 if(!g_cts)
1592                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1593                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1594                         }
1595                 }
1596                 if (this.items & ITEM_Shield.m_itemid)
1597                 {
1598                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1599                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1600                         if (time > this.invincible_finished)
1601                         {
1602                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1603                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1604                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1605                         }
1606                 }
1607                 else
1608                 {
1609                         if (time < this.invincible_finished)
1610                         {
1611                                 this.items = this.items | ITEM_Shield.m_itemid;
1612                                 if(!g_cts)
1613                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1614                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1615                         }
1616                 }
1617                 if (this.items & IT_SUPERWEAPON)
1618                 {
1619                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1620                         {
1621                                 this.superweapons_finished = 0;
1622                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1623                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1624                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1625                         }
1626                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1627                         {
1628                                 // don't let them run out
1629                         }
1630                         else
1631                         {
1632                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1633                                 if (time > this.superweapons_finished)
1634                                 {
1635                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1636                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1637                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1638                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1639                                 }
1640                         }
1641                 }
1642                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1643                 {
1644                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1645                         {
1646                                 this.items = this.items | IT_SUPERWEAPON;
1647                                 if(!g_cts)
1648                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1649                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1650                         }
1651                         else
1652                         {
1653                                 this.superweapons_finished = 0;
1654                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1655                         }
1656                 }
1657                 else
1658                 {
1659                         this.superweapons_finished = 0;
1660                 }
1661         }
1662
1663         if(autocvar_g_nodepthtestplayers)
1664                 this.effects = this.effects | EF_NODEPTHTEST;
1665
1666         if(autocvar_g_fullbrightplayers)
1667                 this.effects = this.effects | EF_FULLBRIGHT;
1668
1669         if (time >= game_starttime)
1670         if (time < this.spawnshieldtime)
1671                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1672
1673         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1674 }
1675
1676 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1677 {
1678         if(current > stable)
1679                 return current;
1680         else if(current > stable - 0.25) // when close enough, "snap"
1681                 return stable;
1682         else
1683                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1684 }
1685
1686 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1687 {
1688         if(current < stable)
1689                 return current;
1690         else if(current < stable + 0.25) // when close enough, "snap"
1691                 return stable;
1692         else
1693                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1694 }
1695
1696 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1697 {
1698         if(current > rotstable)
1699         {
1700                 if(rotframetime > 0)
1701                 {
1702                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1703                         current = max(rotstable, current - rotlinear * rotframetime);
1704                 }
1705         }
1706         else if(current < regenstable)
1707         {
1708                 if(regenframetime > 0)
1709                 {
1710                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1711                         current = min(regenstable, current + regenlinear * regenframetime);
1712                 }
1713         }
1714
1715         if(current > limit)
1716                 current = limit;
1717
1718         return current;
1719 }
1720
1721 void player_regen(entity this)
1722 {
1723         float max_mod, regen_mod, rot_mod, limit_mod;
1724         max_mod = regen_mod = rot_mod = limit_mod = 1;
1725
1726         float regen_health = autocvar_g_balance_health_regen;
1727         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1728         float regen_health_rot = autocvar_g_balance_health_rot;
1729         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1730         float regen_health_stable = autocvar_g_balance_health_regenstable;
1731         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1732         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1733                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1734         max_mod = M_ARGV(1, float);
1735         regen_mod = M_ARGV(2, float);
1736         rot_mod = M_ARGV(3, float);
1737         limit_mod = M_ARGV(4, float);
1738         regen_health = M_ARGV(5, float);
1739         regen_health_linear = M_ARGV(6, float);
1740         regen_health_rot = M_ARGV(7, float);
1741         regen_health_rotlinear = M_ARGV(8, float);
1742         regen_health_stable = M_ARGV(9, float);
1743         regen_health_rotstable = M_ARGV(10, float);
1744
1745         if(!mutator_returnvalue)
1746         if(!STAT(FROZEN, this))
1747         {
1748                 float mina, maxa, limith, limita;
1749                 maxa = autocvar_g_balance_armor_rotstable;
1750                 mina = autocvar_g_balance_armor_regenstable;
1751                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1752                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1753
1754                 regen_health_rotstable = regen_health_rotstable * max_mod;
1755                 regen_health_stable = regen_health_stable * max_mod;
1756                 limith = limith * limit_mod;
1757                 limita = limita * limit_mod;
1758
1759                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1760                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1761         }
1762
1763         // if player rotted to death...  die!
1764         // check this outside above checks, as player may still be able to rot to death
1765         if(this.health < 1)
1766         {
1767                 if(this.vehicle)
1768                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1769                 if(this.event_damage)
1770                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1771         }
1772
1773         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1774         {
1775                 float minf, maxf, limitf;
1776
1777                 maxf = autocvar_g_balance_fuel_rotstable;
1778                 minf = autocvar_g_balance_fuel_regenstable;
1779                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1780
1781                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1782         }
1783         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1784         // TODO: Remove this hack when all code uses GivePlayerHealth and
1785         // GivePlayerArmor.
1786         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1787         {
1788                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1789         }
1790         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1791         {
1792                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1793         }
1794         // End hack.
1795 }
1796
1797 bool zoomstate_set;
1798 void SetZoomState(entity this, float newzoom)
1799 {
1800         if(newzoom != CS(this).zoomstate)
1801         {
1802                 CS(this).zoomstate = newzoom;
1803                 ClientData_Touch(this);
1804         }
1805         zoomstate_set = true;
1806 }
1807
1808 void GetPressedKeys(entity this)
1809 {
1810         MUTATOR_CALLHOOK(GetPressedKeys, this);
1811         int keys = STAT(PRESSED_KEYS, this);
1812         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1813         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1814         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1815         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1816
1817         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1818         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1819         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1820         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1821         CS(this).pressedkeys = keys; // store for other users
1822
1823         STAT(PRESSED_KEYS, this) = keys;
1824 }
1825
1826 /*
1827 ======================
1828 spectate mode routines
1829 ======================
1830 */
1831
1832 void SpectateCopy(entity this, entity spectatee)
1833 {
1834     TC(Client, this); TC(Client, spectatee);
1835
1836         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1837         PS(this) = PS(spectatee);
1838         this.armortype = spectatee.armortype;
1839         this.armorvalue = spectatee.armorvalue;
1840         this.ammo_cells = spectatee.ammo_cells;
1841         this.ammo_plasma = spectatee.ammo_plasma;
1842         this.ammo_shells = spectatee.ammo_shells;
1843         this.ammo_nails = spectatee.ammo_nails;
1844         this.ammo_rockets = spectatee.ammo_rockets;
1845         this.ammo_fuel = spectatee.ammo_fuel;
1846         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1847         this.health = spectatee.health;
1848         CS(this).impulse = 0;
1849         this.items = spectatee.items;
1850         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1851         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1852         this.strength_finished = spectatee.strength_finished;
1853         this.invincible_finished = spectatee.invincible_finished;
1854         this.superweapons_finished = spectatee.superweapons_finished;
1855         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1856         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1857         this.punchangle = spectatee.punchangle;
1858         this.view_ofs = spectatee.view_ofs;
1859         this.velocity = spectatee.velocity;
1860         this.dmg_take = spectatee.dmg_take;
1861         this.dmg_save = spectatee.dmg_save;
1862         this.dmg_inflictor = spectatee.dmg_inflictor;
1863         this.v_angle = spectatee.v_angle;
1864         this.angles = spectatee.v_angle;
1865         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1866         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1867         this.viewloc = spectatee.viewloc;
1868         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1869                 this.fixangle = true;
1870         setorigin(this, spectatee.origin);
1871         setsize(this, spectatee.mins, spectatee.maxs);
1872         SetZoomState(this, CS(spectatee).zoomstate);
1873
1874     anticheat_spectatecopy(this, spectatee);
1875         STAT(HUD, this) = STAT(HUD, spectatee);
1876         if(spectatee.vehicle)
1877     {
1878         this.angles = spectatee.v_angle;
1879
1880         //this.fixangle = false;
1881         //this.velocity = spectatee.vehicle.velocity;
1882         this.vehicle_health = spectatee.vehicle_health;
1883         this.vehicle_shield = spectatee.vehicle_shield;
1884         this.vehicle_energy = spectatee.vehicle_energy;
1885         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1886         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1887         this.vehicle_reload1 = spectatee.vehicle_reload1;
1888         this.vehicle_reload2 = spectatee.vehicle_reload2;
1889
1890         //msg_entity = this;
1891
1892        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1893             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1894            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1895            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1896
1897         //WriteByte (MSG_ONE, SVC_SETVIEW);
1898         //    WriteEntity(MSG_ONE, this);
1899         //makevectors(spectatee.v_angle);
1900         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1901     }
1902 }
1903
1904 bool SpectateUpdate(entity this)
1905 {
1906         if(!this.enemy)
1907                 return false;
1908
1909         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1910         {
1911                 SetSpectatee(this, NULL);
1912                 return false;
1913         }
1914
1915         SpectateCopy(this, this.enemy);
1916
1917         return true;
1918 }
1919
1920 bool SpectateSet(entity this)
1921 {
1922         if(!IS_PLAYER(this.enemy))
1923                 return false;
1924
1925         ClientData_Touch(this.enemy);
1926
1927         msg_entity = this;
1928         WriteByte(MSG_ONE, SVC_SETVIEW);
1929         WriteEntity(MSG_ONE, this.enemy);
1930         set_movetype(this, MOVETYPE_NONE);
1931         accuracy_resend(this);
1932
1933         if(!SpectateUpdate(this))
1934                 PutObserverInServer(this);
1935
1936         return true;
1937 }
1938
1939 void SetSpectatee_status(entity this, int spectatee_num)
1940 {
1941         int oldspectatee_status = CS(this).spectatee_status;
1942         CS(this).spectatee_status = spectatee_num;
1943
1944         if (CS(this).spectatee_status != oldspectatee_status)
1945         {
1946                 ClientData_Touch(this);
1947                 if (g_race || g_cts) race_InitSpectator();
1948         }
1949 }
1950
1951 void SetSpectatee(entity this, entity spectatee)
1952 {
1953         if(IS_BOT_CLIENT(this))
1954                 return; // bots abuse .enemy, this code is useless to them
1955
1956         entity old_spectatee = this.enemy;
1957
1958         this.enemy = spectatee;
1959
1960         // WEAPONTODO
1961         // these are required to fix the spectator bug with arc
1962         if(old_spectatee)
1963         {
1964                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1965                 {
1966                         .entity weaponentity = weaponentities[slot];
1967                         if(old_spectatee.(weaponentity).arc_beam)
1968                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1969                 }
1970         }
1971         if(this.enemy)
1972         {
1973                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1974                 {
1975                         .entity weaponentity = weaponentities[slot];
1976                         if(this.enemy.(weaponentity).arc_beam)
1977                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1978                 }
1979         }
1980
1981         if (this.enemy)
1982                 SetSpectatee_status(this, etof(this.enemy));
1983
1984         // needed to update spectator list
1985         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1986 }
1987
1988 bool Spectate(entity this, entity pl)
1989 {
1990         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1991                 return false;
1992         pl = M_ARGV(1, entity);
1993
1994         SetSpectatee(this, pl);
1995         return SpectateSet(this);
1996 }
1997
1998 bool SpectateNext(entity this)
1999 {
2000         entity ent = find(this.enemy, classname, STR_PLAYER);
2001
2002         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
2003                 ent = M_ARGV(1, entity);
2004         else if (!ent)
2005                 ent = find(ent, classname, STR_PLAYER);
2006
2007         if(ent) { SetSpectatee(this, ent); }
2008
2009         return SpectateSet(this);
2010 }
2011
2012 bool SpectatePrev(entity this)
2013 {
2014         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2015         entity ent = findchain(classname, STR_PLAYER);
2016         if (!ent) // no player
2017                 return false;
2018
2019         entity first = ent;
2020         // skip players until current spectated player
2021         if(this.enemy)
2022         while(ent && ent != this.enemy)
2023                 ent = ent.chain;
2024
2025         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2026         {
2027                 case MUT_SPECPREV_FOUND:
2028                     ent = M_ARGV(1, entity);
2029                     break;
2030                 case MUT_SPECPREV_RETURN:
2031                     return true;
2032                 case MUT_SPECPREV_CONTINUE:
2033                 default:
2034                 {
2035                         if(ent.chain)
2036                                 ent = ent.chain;
2037                         else
2038                                 ent = first;
2039                         break;
2040                 }
2041         }
2042
2043         SetSpectatee(this, ent);
2044         return SpectateSet(this);
2045 }
2046
2047 /*
2048 =============
2049 ShowRespawnCountdown()
2050
2051 Update a respawn countdown display.
2052 =============
2053 */
2054 void ShowRespawnCountdown(entity this)
2055 {
2056         float number;
2057         if(!IS_DEAD(this)) // just respawned?
2058                 return;
2059         else
2060         {
2061                 number = ceil(this.respawn_time - time);
2062                 if(number <= 0)
2063                         return;
2064                 if(number <= this.respawn_countdown)
2065                 {
2066                         this.respawn_countdown = number - 1;
2067                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2068                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2069                 }
2070         }
2071 }
2072
2073 .bool team_selected;
2074 bool ShowTeamSelection(entity this)
2075 {
2076         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
2077                 return false;
2078         stuffcmd(this, "menu_showteamselect\n");
2079         return true;
2080 }
2081 void Join(entity this)
2082 {
2083         TRANSMUTE(Player, this);
2084
2085         if(!this.team_selected)
2086         if(autocvar_g_campaign || autocvar_g_balance_teams)
2087                 TeamBalance_JoinBestTeam(this, true);
2088
2089         if(autocvar_g_campaign)
2090                 campaign_bots_may_start = true;
2091
2092         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2093
2094         PutClientInServer(this);
2095
2096         if(IS_PLAYER(this))
2097         if(teamplay && this.team != -1)
2098         {
2099                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2100         }
2101         else
2102                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2103         this.team_selected = false;
2104 }
2105
2106 /**
2107  * Determines whether the player is allowed to join. This depends on cvar
2108  * g_maxplayers, if it isn't used this function always return true, otherwise
2109  * it checks whether the number of currently playing players exceeds g_maxplayers.
2110  * @return int number of free slots for players, 0 if none
2111  */
2112 int nJoinAllowed(entity this, entity ignore)
2113 {
2114         if(!ignore)
2115         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2116         // so report 0 free slots if restricted
2117         {
2118                 if(autocvar_g_forced_team_otherwise == "spectate")
2119                         return 0;
2120                 if(autocvar_g_forced_team_otherwise == "spectator")
2121                         return 0;
2122         }
2123
2124         if(this && this.team_forced < 0)
2125                 return 0; // forced spectators can never join
2126
2127         // TODO simplify this
2128         int totalClients = 0;
2129         int currentlyPlaying = 0;
2130         FOREACH_CLIENT(true, {
2131                 if(it != ignore)
2132                         ++totalClients;
2133                 if(IS_REAL_CLIENT(it))
2134                 if(IS_PLAYER(it) || it.caplayer)
2135                         ++currentlyPlaying;
2136         });
2137
2138         float free_slots = 0;
2139         if (!autocvar_g_maxplayers)
2140                 free_slots = maxclients - totalClients;
2141         else if(currentlyPlaying < autocvar_g_maxplayers)
2142                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2143
2144         static float join_prevent_msg_time = 0;
2145         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2146         {
2147                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2148                 join_prevent_msg_time = time + 3;
2149         }
2150
2151         return free_slots;
2152 }
2153
2154 /**
2155  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2156  * g_maxplayers_spectator_blocktime seconds
2157  */
2158 void checkSpectatorBlock(entity this)
2159 {
2160         if(IS_SPEC(this) || IS_OBSERVER(this))
2161         if(!this.caplayer)
2162         if(IS_REAL_CLIENT(this))
2163         {
2164                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2165                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2166                         dropclient(this);
2167                 }
2168         }
2169 }
2170
2171 void PrintWelcomeMessage(entity this)
2172 {
2173         if(CS(this).motd_actived_time == 0)
2174         {
2175                 if (autocvar_g_campaign) {
2176                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2177                                 CS(this).motd_actived_time = time;
2178                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2179                         }
2180                 } else {
2181                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2182                                 CS(this).motd_actived_time = time;
2183                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2184                         }
2185                 }
2186         }
2187         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2188         {
2189                 if (autocvar_g_campaign) {
2190                         if (PHYS_INPUT_BUTTON_INFO(this))
2191                                 CS(this).motd_actived_time = time;
2192                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2193                                 CS(this).motd_actived_time = 0;
2194                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2195                         }
2196                 } else {
2197                         if (PHYS_INPUT_BUTTON_INFO(this))
2198                                 CS(this).motd_actived_time = time;
2199                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2200                                 CS(this).motd_actived_time = 0;
2201                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2202                         }
2203                 }
2204         }
2205         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2206         {
2207                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2208                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2209                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2210                 {
2211                         // instanctly hide MOTD
2212                         CS(this).motd_actived_time = 0;
2213                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2214                 }
2215         }
2216 }
2217
2218 bool joinAllowed(entity this)
2219 {
2220         if (CS(this).version_mismatch) return false;
2221         if (!nJoinAllowed(this, this)) return false;
2222         if (teamplay && lockteams) return false;
2223         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2224         if (ShowTeamSelection(this)) return false;
2225         return true;
2226 }
2227
2228 .int items_added;
2229 .string shootfromfixedorigin;
2230 bool PlayerThink(entity this)
2231 {
2232         if (game_stopped || intermission_running) {
2233                 this.modelflags &= ~MF_ROCKET;
2234                 if(intermission_running)
2235                         IntermissionThink(this);
2236                 return false;
2237         }
2238
2239         if (timeout_status == TIMEOUT_ACTIVE) {
2240         // don't allow the player to turn around while game is paused
2241                 // FIXME turn this into CSQC stuff
2242                 this.v_angle = this.lastV_angle;
2243                 this.angles = this.lastV_angle;
2244                 this.fixangle = true;
2245         }
2246
2247         if (frametime) player_powerups(this);
2248
2249         if (IS_DEAD(this)) {
2250                 if (this.personal && g_race_qualifying) {
2251                         if (time > this.respawn_time) {
2252                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2253                                 respawn(this);
2254                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2255                         }
2256                 } else {
2257                         if (frametime) player_anim(this);
2258
2259                         if (this.respawn_flags & RESPAWN_DENY)
2260                         {
2261                                 STAT(RESPAWN_TIME, this) = 0;
2262                                 return false;
2263                         }
2264
2265                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2266
2267                         switch(this.deadflag)
2268                         {
2269                                 case DEAD_DYING:
2270                                 {
2271                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2272                                                 this.deadflag = DEAD_RESPAWNING;
2273                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2274                                                 this.deadflag = DEAD_DEAD;
2275                                         break;
2276                                 }
2277                                 case DEAD_DEAD:
2278                                 {
2279                                         if (button_pressed)
2280                                                 this.deadflag = DEAD_RESPAWNABLE;
2281                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2282                                                 this.deadflag = DEAD_RESPAWNING;
2283                                         break;
2284                                 }
2285                                 case DEAD_RESPAWNABLE:
2286                                 {
2287                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2288                                                 this.deadflag = DEAD_RESPAWNING;
2289                                         break;
2290                                 }
2291                                 case DEAD_RESPAWNING:
2292                                 {
2293                                         if (time > this.respawn_time)
2294                                         {
2295                                                 this.respawn_time = time + 1; // only retry once a second
2296                                                 this.respawn_time_max = this.respawn_time;
2297                                                 respawn(this);
2298                                         }
2299                                         break;
2300                                 }
2301                         }
2302
2303                         ShowRespawnCountdown(this);
2304
2305                         if (this.respawn_flags & RESPAWN_SILENT)
2306                                 STAT(RESPAWN_TIME, this) = 0;
2307                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2308                         {
2309                                 if (time < this.respawn_time)
2310                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2311                                 else if (this.deadflag != DEAD_RESPAWNING)
2312                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2313                         }
2314                         else
2315                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2316                 }
2317
2318                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2319                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2320                         STAT(RESPAWN_TIME, this) *= -1;
2321
2322                 return false;
2323         }
2324
2325         FixPlayermodel(this);
2326
2327         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2328                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2329                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2330         }
2331
2332         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2333         //if(frametime)
2334         {
2335                 this.items &= ~this.items_added;
2336
2337                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2338                 {
2339                         .entity weaponentity = weaponentities[slot];
2340                         W_WeaponFrame(this, weaponentity);
2341                 }
2342
2343                 this.items_added = 0;
2344                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2345             this.items_added |= IT_FUEL;
2346
2347                 this.items |= this.items_added;
2348         }
2349
2350         player_regen(this);
2351
2352         // WEAPONTODO: Add a weapon request for this
2353         // rot vortex charge to the charge limit
2354         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2355         {
2356                 .entity weaponentity = weaponentities[slot];
2357                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2358                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2359         }
2360
2361         if (frametime) player_anim(this);
2362
2363         // secret status
2364         secrets_setstatus(this);
2365
2366         // monsters status
2367         monsters_setstatus(this);
2368
2369         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2370
2371         return true;
2372 }
2373
2374 .bool would_spectate;
2375 void ObserverThink(entity this)
2376 {
2377         if ( CS(this).impulse )
2378         {
2379                 MinigameImpulse(this, CS(this).impulse);
2380                 CS(this).impulse = 0;
2381         }
2382
2383         if (this.flags & FL_JUMPRELEASED) {
2384                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2385                         this.flags &= ~FL_JUMPRELEASED;
2386                         this.flags |= FL_SPAWNING;
2387                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2388                         this.flags &= ~FL_JUMPRELEASED;
2389                         if(SpectateNext(this)) {
2390                                 TRANSMUTE(Spectator, this);
2391                         }
2392                 } else {
2393                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2394                         set_movetype(this, preferred_movetype);
2395                 }
2396         } else {
2397                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2398                         this.flags |= FL_JUMPRELEASED;
2399                         if(this.flags & FL_SPAWNING)
2400                         {
2401                                 this.flags &= ~FL_SPAWNING;
2402                                 Join(this);
2403                                 return;
2404                         }
2405                 }
2406         }
2407 }
2408
2409 void SpectatorThink(entity this)
2410 {
2411         if ( CS(this).impulse )
2412         {
2413                 if(MinigameImpulse(this, CS(this).impulse))
2414                         CS(this).impulse = 0;
2415
2416                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2417                 {
2418                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2419                         CS(this).impulse = 0;
2420                         return;
2421                 }
2422         }
2423
2424         if (this.flags & FL_JUMPRELEASED) {
2425                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2426                         this.flags &= ~FL_JUMPRELEASED;
2427                         this.flags |= FL_SPAWNING;
2428                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2429                         this.flags &= ~FL_JUMPRELEASED;
2430                         if(SpectateNext(this)) {
2431                                 TRANSMUTE(Spectator, this);
2432                         } else {
2433                                 TRANSMUTE(Observer, this);
2434                                 PutClientInServer(this);
2435                         }
2436                         CS(this).impulse = 0;
2437                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2438                         this.flags &= ~FL_JUMPRELEASED;
2439                         if(SpectatePrev(this)) {
2440                                 TRANSMUTE(Spectator, this);
2441                         } else {
2442                                 TRANSMUTE(Observer, this);
2443                                 PutClientInServer(this);
2444                         }
2445                         CS(this).impulse = 0;
2446                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2447                         this.would_spectate = false;
2448                         this.flags &= ~FL_JUMPRELEASED;
2449                         TRANSMUTE(Observer, this);
2450                         PutClientInServer(this);
2451                 } else {
2452                         if(!SpectateUpdate(this))
2453                         {
2454                                 if(!SpectateNext(this))
2455                                 {
2456                                         PutObserverInServer(this);
2457                                         this.would_spectate = true;
2458                                 }
2459                         }
2460                 }
2461         } else {
2462                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2463                         this.flags |= FL_JUMPRELEASED;
2464                         if(this.flags & FL_SPAWNING)
2465                         {
2466                                 this.flags &= ~FL_SPAWNING;
2467                                 Join(this);
2468                                 return;
2469                         }
2470                 }
2471                 if(!SpectateUpdate(this))
2472                         PutObserverInServer(this);
2473         }
2474
2475         this.flags |= FL_CLIENT | FL_NOTARGET;
2476 }
2477
2478 void vehicles_enter (entity pl, entity veh);
2479 void PlayerUseKey(entity this)
2480 {
2481         if (!IS_PLAYER(this))
2482                 return;
2483
2484         if(this.vehicle)
2485         {
2486                 if(!game_stopped)
2487                 {
2488                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2489                         return;
2490                 }
2491         }
2492         else if(autocvar_g_vehicles_enter)
2493         {
2494                 if(!STAT(FROZEN, this))
2495                 if(!IS_DEAD(this))
2496                 if(!game_stopped)
2497                 {
2498                         entity head, closest_target = NULL;
2499                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2500
2501                         while(head) // find the closest acceptable target to enter
2502                         {
2503                                 if(IS_VEHICLE(head))
2504                                 if(!IS_DEAD(head))
2505                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2506                                 if(head.takedamage != DAMAGE_NO)
2507                                 {
2508                                         if(closest_target)
2509                                         {
2510                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2511                                                 { closest_target = head; }
2512                                         }
2513                                         else { closest_target = head; }
2514                                 }
2515
2516                                 head = head.chain;
2517                         }
2518
2519                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2520                 }
2521         }
2522
2523         // a use key was pressed; call handlers
2524         MUTATOR_CALLHOOK(PlayerUseKey, this);
2525 }
2526
2527
2528 /*
2529 =============
2530 PlayerPreThink
2531
2532 Called every frame for each client before the physics are run
2533 =============
2534 */
2535 .float last_vehiclecheck;
2536 void PlayerPreThink (entity this)
2537 {
2538         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2539         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2540
2541         WarpZone_PlayerPhysics_FixVAngle(this);
2542
2543         if (frametime) {
2544                 // physics frames: update anticheat stuff
2545                 anticheat_prethink(this);
2546         }
2547
2548         if (blockSpectators && frametime) {
2549                 // WORKAROUND: only use dropclient in server frames (frametime set).
2550                 // Never use it in cl_movement frames (frametime zero).
2551                 checkSpectatorBlock(this);
2552         }
2553
2554         zoomstate_set = false;
2555
2556         // Check for nameless players
2557         if (this.netname == "" || this.netname != CS(this).netname_previous)
2558         {
2559                 bool assume_unchanged = (CS(this).netname_previous == "");
2560                 if (isInvisibleString(this.netname))
2561                 {
2562                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2563                         assume_unchanged = false;
2564                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2565                 }
2566                 if (!assume_unchanged && autocvar_sv_eventlog)
2567                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2568                 strcpy(CS(this).netname_previous, this.netname);
2569         }
2570
2571         // version nagging
2572         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2573         CS(this).version_nagtime = 0;
2574         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2575             // git client
2576         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2577             // git server
2578             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2579         } else {
2580             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2581             if (r < 0) { // old client
2582                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2583             } else if (r > 0) { // old server
2584                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2585             }
2586         }
2587     }
2588
2589         // GOD MODE info
2590         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2591         {
2592                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2593                 this.max_armorvalue = 0;
2594         }
2595
2596         if(IS_PLAYER(this))
2597         {
2598                 if (STAT(FROZEN, this) == 2)
2599                 {
2600                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2601                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2602                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2603
2604                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2605                                 Unfreeze(this);
2606                 }
2607                 else if (STAT(FROZEN, this) == 3)
2608                 {
2609                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2610                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2611
2612                         if (this.health < 1)
2613                         {
2614                                 if (this.vehicle)
2615                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2616                                 if(this.event_damage)
2617                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2618                         }
2619                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2620                                 Unfreeze(this);
2621                 }
2622         }
2623
2624         MUTATOR_CALLHOOK(PlayerPreThink, this);
2625
2626         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2627         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2628         {
2629                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2630                 {
2631                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2632                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2633                         {
2634                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2635                         }
2636                         else if(!it.owner)
2637                         {
2638                                 if(!it.team || SAME_TEAM(this, it))
2639                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2640                                 else if(autocvar_g_vehicles_steal)
2641                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2642                         }
2643                 });
2644
2645                 this.last_vehiclecheck = time + 1;
2646         }
2647
2648         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2649         {
2650                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2651                         PlayerUseKey(this);
2652                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2653         }
2654
2655         if (IS_REAL_CLIENT(this))
2656                 PrintWelcomeMessage(this);
2657
2658         if (IS_PLAYER(this)) {
2659                 if(!PlayerThink(this))
2660                         return;
2661         }
2662         else if (game_stopped || intermission_running) {
2663                 if(intermission_running)
2664                         IntermissionThink(this);
2665                 return;
2666         }
2667         else if (IS_OBSERVER(this)) {
2668                 ObserverThink(this);
2669         }
2670         else if (IS_SPEC(this)) {
2671                 SpectatorThink(this);
2672         }
2673
2674         // WEAPONTODO: Add weapon request for this
2675         if (!zoomstate_set) {
2676                 bool wep_zoomed = false;
2677                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2678                 {
2679                         .entity weaponentity = weaponentities[slot];
2680                         Weapon thiswep = this.(weaponentity).m_weapon;
2681                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2682                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2683                 }
2684                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2685     }
2686
2687         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2688         {
2689                 CS(this).teamkill_soundtime = 0;
2690
2691                 entity e = CS(this).teamkill_soundsource;
2692                 entity oldpusher = e.pusher;
2693                 e.pusher = this;
2694                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2695                 e.pusher = oldpusher;
2696         }
2697
2698         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2699                 CS(this).taunt_soundtime = 0;
2700                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2701         }
2702
2703         target_voicescript_next(this);
2704
2705         // WEAPONTODO: Move into weaponsystem somehow
2706         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2707         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2708         {
2709                 .entity weaponentity = weaponentities[slot];
2710                 if(this.(weaponentity).m_weapon == WEP_Null)
2711                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2712         }
2713 }
2714
2715 void DrownPlayer(entity this)
2716 {
2717         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2718                 return;
2719
2720         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2721         {
2722                 if(this.air_finished < time)
2723                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2724                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2725         }
2726         else if (this.air_finished < time)
2727         {       // drown!
2728                 if (this.pain_finished < time)
2729                 {
2730                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2731                         this.pain_finished = time + 0.5;
2732                 }
2733         }
2734 }
2735
2736 .bool move_qcphysics;
2737
2738 void Player_Physics(entity this)
2739 {
2740         set_movetype(this, this.move_movetype);
2741
2742         if(!this.move_qcphysics)
2743                 return;
2744
2745         if(!frametime && !CS(this).pm_frametime)
2746                 return;
2747
2748         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2749
2750         CS(this).pm_frametime = 0;
2751 }
2752
2753 /*
2754 =============
2755 PlayerPostThink
2756
2757 Called every frame for each client after the physics are run
2758 =============
2759 */
2760 void PlayerPostThink (entity this)
2761 {
2762         Player_Physics(this);
2763
2764         if (sv_maxidle > 0)
2765         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2766         if (IS_REAL_CLIENT(this))
2767         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2768         {
2769                 int totalClients = 0;
2770                 if(sv_maxidle_slots > 0)
2771                 {
2772                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2773                         {
2774                                 ++totalClients;
2775                         });
2776                 }
2777
2778                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2779                 { /* do nothing */ }
2780                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2781                 {
2782                         if (CS(this).idlekick_lasttimeleft)
2783                         {
2784                                 CS(this).idlekick_lasttimeleft = 0;
2785                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2786                         }
2787                 }
2788                 else
2789                 {
2790                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2791                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2792                                 if (!CS(this).idlekick_lasttimeleft)
2793                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2794                         }
2795                         if (timeleft <= 0) {
2796                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2797                                 dropclient(this);
2798                                 return;
2799                         }
2800                         else if (timeleft <= 10) {
2801                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2802                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2803                 }
2804                                 CS(this).idlekick_lasttimeleft = timeleft;
2805                         }
2806                 }
2807         }
2808
2809         CheatFrame(this);
2810
2811         if (game_stopped)
2812         {
2813                 this.solid = SOLID_NOT;
2814                 this.takedamage = DAMAGE_NO;
2815                 set_movetype(this, MOVETYPE_NONE);
2816         }
2817
2818         if (IS_PLAYER(this)) {
2819                 if(this.death_time == time && IS_DEAD(this))
2820                 {
2821                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2822                         // once all the damage events of this frame have been processed with normal size
2823                         this.maxs.z = 5;
2824                         setsize(this, this.mins, this.maxs);
2825                 }
2826                 DrownPlayer(this);
2827                 UpdateChatBubble(this);
2828                 if (CS(this).impulse) ImpulseCommands(this);
2829                 if (game_stopped)
2830                 {
2831                         CSQCMODEL_AUTOUPDATE(this);
2832                         return;
2833                 }
2834                 GetPressedKeys(this);
2835         }
2836
2837         if (this.waypointsprite_attachedforcarrier) {
2838             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2839                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2840     }
2841
2842         playerdemo_write(this);
2843
2844         CSQCMODEL_AUTOUPDATE(this);
2845 }
2846
2847 // hack to copy the button fields from the client entity to the Client State
2848 void PM_UpdateButtons(entity this, entity store)
2849 {
2850         if(this.impulse)
2851                 store.impulse = this.impulse;
2852         this.impulse = 0;
2853
2854         bool typing = this.buttonchat;
2855
2856         store.button0 = (typing) ? 0 : this.button0;
2857         //button1?!
2858         store.button2 = (typing) ? 0 : this.button2;
2859         store.button3 = (typing) ? 0 : this.button3;
2860         store.button4 = this.button4;
2861         store.button5 = (typing) ? 0 : this.button5;
2862         store.button6 = this.button6;
2863         store.button7 = this.button7;
2864         store.button8 = this.button8;
2865         store.button9 = this.button9;
2866         store.button10 = this.button10;
2867         store.button11 = this.button11;
2868         store.button12 = this.button12;
2869         store.button13 = this.button13;
2870         store.button14 = this.button14;
2871         store.button15 = this.button15;
2872         store.button16 = this.button16;
2873         store.buttonuse = this.buttonuse;
2874         store.buttonchat = this.buttonchat;
2875
2876         store.cursor_active = this.cursor_active;
2877         store.cursor_screen = this.cursor_screen;
2878         store.cursor_trace_start = this.cursor_trace_start;
2879         store.cursor_trace_endpos = this.cursor_trace_endpos;
2880         store.cursor_trace_ent = this.cursor_trace_ent;
2881
2882         store.ping = this.ping;
2883         store.ping_packetloss = this.ping_packetloss;
2884         store.ping_movementloss = this.ping_movementloss;
2885
2886         store.v_angle = this.v_angle;
2887         store.movement = (typing) ? '0 0 0' : this.movement;
2888 }
2889
2890 NET_HANDLE(fpsreport, bool)
2891 {
2892         int fps = ReadShort();
2893         PlayerScore_Set(sender, SP_FPS, fps);
2894         return true;
2895 }