qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/state.qh>
  34 #include <common/stats.qh>
  35 #include <common/vehicles/all.qh>
  36 #include <common/vehicles/sv_vehicles.qh>
  37 #include <common/viewloc.qh>
  38 #include <common/weapons/_all.qh>
  39 #include <common/weapons/weapon/vortex.qh>
  40 #include <common/wepent.qh>
  41 #include <lib/csqcmodel/sv_model.qh>
  42 #include <lib/warpzone/common.qh>
  43 #include <lib/warpzone/server.qh>
  44 #include <server/anticheat.qh>
  45 #include <server/antilag.qh>
  46 #include <server/bot/api.qh>
  47 #include <server/bot/default/cvars.qh>
  48 #include <server/campaign.qh>
  49 #include <server/chat.qh>
  50 #include <server/cheats.qh>
  51 #include <server/clientkill.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/vote.qh>
  55 #include <server/compat/quake3.qh>
  56 #include <server/damage.qh>
  57 #include <server/gamelog.qh>
  58 #include <server/handicap.qh>
  59 #include <server/hook.qh>
  60 #include <server/impulse.qh>
  61 #include <server/intermission.qh>
  62 #include <server/ipban.qh>
  63 #include <server/main.qh>
  64 #include <server/mutators/_mod.qh>
  65 #include <server/player.qh>
  66 #include <server/portals.qh>
  67 #include <server/race.qh>
  68 #include <server/resources.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 241         PlayerState_detach(this);
 242
 243         if (IS_PLAYER(this))
 244         {
 245                 if(GetResource(this, RES_HEALTH) >= 1)
 246                 {
 247                         // despawn effect
 248                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 249                 }
 250
 251                 // was a player, recount votes and ready status
 252                 if(IS_REAL_CLIENT(this))
 253                 {
 254                         if (vote_called) { VoteCount(false); }
 255                         ReadyCount();
 256                 }
 257                 entcs_update_players(this);
 258         }
 259
 260         entity spot = SelectSpawnPoint(this, true);
 261         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 262         this.angles = vec2(spot.angles);
 263         this.fixangle = true;
 264         // offset it so that the spectator spawns higher off the ground, looks better this way
 265         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 266         if (IS_REAL_CLIENT(this))
 267         {
 268                 msg_entity = this;
 269                 WriteByte(MSG_ONE, SVC_SETVIEW);
 270                 WriteEntity(MSG_ONE, this);
 271         }
 272         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 273         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 274         if(!autocvar_g_debug_globalsounds)
 275         {
 276                 // needed for player sounds
 277                 this.model = "";
 278                 FixPlayermodel(this);
 279         }
 280         setmodel(this, MDL_Null);
 281         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 282         this.view_ofs = '0 0 0';
 283
 284         RemoveGrapplingHooks(this);
 285         Portal_ClearAll(this);
 286         Unfreeze(this, false);
 287         SetSpectatee(this, NULL);
 288
 289         if (this.alivetime)
 290         {
 291                 if (!warmup_stage)
 292                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 293                 this.alivetime = 0;
 294         }
 295
 296         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 297
 298         WaypointSprite_PlayerDead(this);
 299
 300         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 301                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 302
 303         accuracy_resend(this);
 304
 305         CS(this).spectatortime = time;
 306         if(this.bot_attack)
 307                 IL_REMOVE(g_bot_targets, this);
 308         this.bot_attack = false;
 309         if(this.monster_attack)
 310                 IL_REMOVE(g_monster_targets, this);
 311         this.monster_attack = false;
 312         STAT(HUD, this) = HUD_NORMAL;
 313         TRANSMUTE(Observer, this);
 314         this.iscreature = false;
 315         this.teleportable = TELEPORT_SIMPLE;
 316         if(this.damagedbycontents)
 317                 IL_REMOVE(g_damagedbycontents, this);
 318         this.damagedbycontents = false;
 319         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 320         SetSpectatee_status(this, etof(this));
 321         this.takedamage = DAMAGE_NO;
 322         this.solid = SOLID_NOT;
 323         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 324         this.flags = FL_CLIENT | FL_NOTARGET;
 325         this.effects = 0;
 326         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 327         this.pauserotarmor_finished = 0;
 328         this.pauserothealth_finished = 0;
 329         this.pauseregen_finished = 0;
 330         this.damageforcescale = 0;
 331         this.death_time = 0;
 332         this.respawn_flags = 0;
 333         this.respawn_time = 0;
 334         STAT(RESPAWN_TIME, this) = 0;
 335         this.alpha = 0;
 336         this.scale = 0;
 337         this.fade_time = 0;
 338         this.pain_finished = 0;
 339         STAT(AIR_FINISHED, this) = 0;
 340         //this.dphitcontentsmask = 0;
 341         this.dphitcontentsmask = DPCONTENTS_SOLID;
 342         if (autocvar_g_playerclip_collisions)
 343                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 344         this.pushltime = 0;
 345         this.istypefrag = 0;
 346         setthink(this, func_null);
 347         this.nextthink = 0;
 348         this.deadflag = DEAD_NO;
 349         UNSET_DUCKED(this);
 350         STAT(REVIVE_PROGRESS, this) = 0;
 351         this.revival_time = 0;
 352         this.draggable = drag_undraggable;
 353
 354         this.items = 0;
 355         STAT(WEAPONS, this) = '0 0 0';
 356         this.drawonlytoclient = this;
 357
 358         this.viewloc = NULL;
 359
 360         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 361
 362         this.weaponmodel = "";
 363         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 364         {
 365                 this.weaponentities[slot] = NULL;
 366         }
 367         this.exteriorweaponentity = NULL;
 368         CS(this).killcount = FRAGS_SPECTATOR;
 369         this.velocity = '0 0 0';
 370         this.avelocity = '0 0 0';
 371         this.punchangle = '0 0 0';
 372         this.punchvector = '0 0 0';
 373         this.oldvelocity = this.velocity;
 374         this.event_damage = func_null;
 375         this.event_heal = func_null;
 376
 377         for(int slot = 0; slot < MAX_AXH; ++slot)
 378         {
 379                 entity axh = this.(AuxiliaryXhair[slot]);
 380                 this.(AuxiliaryXhair[slot]) = NULL;
 381
 382                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 383                         delete(axh);
 384         }
 385
 386         if (mutator_returnvalue)
 387         {
 388                 // mutator prevents resetting teams+score
 389         }
 390         else
 391         {
 392                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 393                 this.frags = FRAGS_SPECTATOR;
 394         }
 395
 396         bot_relinkplayerlist();
 397
 398         if (CS(this).just_joined)
 399                 CS(this).just_joined = false;
 400 }
 401
 402 int player_getspecies(entity this)
 403 {
 404         get_model_parameters(this.model, this.skin);
 405         int s = get_model_parameters_species;
 406         get_model_parameters(string_null, 0);
 407         if (s < 0) return SPECIES_HUMAN;
 408         return s;
 409 }
 410
 411 .float model_randomizer;
 412 void FixPlayermodel(entity player)
 413 {
 414         string defaultmodel = "";
 415         int defaultskin = 0;
 416         if(autocvar_sv_defaultcharacter)
 417         {
 418                 if(teamplay)
 419                 {
 420                         switch(player.team)
 421                         {
 422                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 423                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 424                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 425                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 426                         }
 427                 }
 428
 429                 if(defaultmodel == "")
 430                 {
 431                         defaultmodel = autocvar_sv_defaultplayermodel;
 432                         defaultskin = autocvar_sv_defaultplayerskin;
 433                 }
 434
 435                 int n = tokenize_console(defaultmodel);
 436                 if(n > 0)
 437                 {
 438                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 439                         // However, do NOT randomize if the player-selected model is in the list.
 440                         for (int i = 0; i < n; ++i)
 441                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 442                                         defaultmodel = argv(i);
 443                 }
 444
 445                 int i = strstrofs(defaultmodel, ":", 0);
 446                 if(i >= 0)
 447                 {
 448                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 449                         defaultmodel = substring(defaultmodel, 0, i);
 450                 }
 451         }
 452         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 453         {
 454                 if(teamplay)
 455                 {
 456                         switch(player.team)
 457                         {
 458                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 459                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 460                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 461                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 462                         }
 463                 }
 464
 465                 if(!defaultskin)
 466                         defaultskin = autocvar_sv_defaultplayerskin;
 467         }
 468
 469         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 470         defaultmodel = M_ARGV(0, string);
 471         defaultskin = M_ARGV(1, int);
 472
 473         bool chmdl = false;
 474         int oldskin;
 475         if(defaultmodel != "")
 476         {
 477                 if (defaultmodel != player.model)
 478                 {
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, defaultmodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 oldskin = player.skin;
 487                 player.skin = defaultskin;
 488         } else {
 489                 if (player.playermodel != player.model || player.playermodel == "")
 490                 {
 491                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, player.playermodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 if(!autocvar_sv_defaultcharacterskin)
 500                 {
 501                         oldskin = player.skin;
 502                         player.skin = stof(player.playerskin);
 503                 }
 504                 else
 505                 {
 506                         oldskin = player.skin;
 507                         player.skin = defaultskin;
 508                 }
 509         }
 510
 511         if(chmdl || oldskin != player.skin) // model or skin has changed
 512         {
 513                 player.species = player_getspecies(player); // update species
 514                 if(!autocvar_g_debug_globalsounds)
 515                         UpdatePlayerSounds(player); // update skin sounds
 516         }
 517
 518         if(!teamplay)
 519                 if(strlen(autocvar_sv_defaultplayercolors))
 520                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 521                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 522 }
 523
 524 void PutPlayerInServer(entity this)
 525 {
 526         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 527
 528         PlayerState_attach(this);
 529         accuracy_resend(this);
 530
 531         if (this.team < 0)
 532                 TeamBalance_JoinBestTeam(this);
 533
 534         entity spot = SelectSpawnPoint(this, false);
 535         if (!spot) {
 536                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 537                 return; // spawn failed
 538         }
 539
 540         TRANSMUTE(Player, this);
 541
 542         CS(this).wasplayer = true;
 543         this.iscreature = true;
 544         this.teleportable = TELEPORT_NORMAL;
 545         if(!this.damagedbycontents)
 546                 IL_PUSH(g_damagedbycontents, this);
 547         this.damagedbycontents = true;
 548         set_movetype(this, MOVETYPE_WALK);
 549         this.solid = SOLID_SLIDEBOX;
 550         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 551         if (autocvar_g_playerclip_collisions)
 552                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 553         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 554                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 555         this.frags = FRAGS_PLAYER;
 556         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 557         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 558         if (autocvar__notarget)
 559                 this.flags |= FL_NOTARGET;
 560         this.takedamage = DAMAGE_AIM;
 561         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 562
 563         if (warmup_stage) {
 564                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 565                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 566                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 567                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 568                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 569                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 570                 SetResource(this, RES_HEALTH, warmup_start_health);
 571                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 572                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 573         } else {
 574                 SetResource(this, RES_SHELLS, start_ammo_shells);
 575                 SetResource(this, RES_BULLETS, start_ammo_nails);
 576                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 577                 SetResource(this, RES_CELLS, start_ammo_cells);
 578                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 579                 SetResource(this, RES_FUEL, start_ammo_fuel);
 580                 SetResource(this, RES_HEALTH, start_health);
 581                 SetResource(this, RES_ARMOR, start_armorvalue);
 582                 STAT(WEAPONS, this) = start_weapons;
 583                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 584                 {
 585                         GiveRandomWeapons(this, random_start_weapons_count,
 586                                 autocvar_g_random_start_weapons, random_start_ammo);
 587                 }
 588         }
 589         SetSpectatee_status(this, 0);
 590
 591         PS(this).dual_weapons = '0 0 0';
 592
 593         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 594                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 595
 596         this.items = start_items;
 597
 598         float shieldtime = time + autocvar_g_spawnshieldtime;
 599
 600         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 601         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 602         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 603         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 604         if (!sv_ready_restart_after_countdown && time < game_starttime)
 605         {
 606                 float f = game_starttime - time;
 607                 shieldtime += f;
 608                 this.pauserotarmor_finished += f;
 609                 this.pauserothealth_finished += f;
 610                 this.pauseregen_finished += f;
 611         }
 612
 613         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 614
 615         this.damageforcescale = autocvar_g_player_damageforcescale;
 616         this.death_time = 0;
 617         this.respawn_flags = 0;
 618         this.respawn_time = 0;
 619         STAT(RESPAWN_TIME, this) = 0;
 620         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 621         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 622         this.fade_time = 0;
 623         this.pain_finished = 0;
 624         this.pushltime = 0;
 625         setthink(this, func_null); // players have no think function
 626         this.nextthink = 0;
 627         this.dmg_team = 0;
 628         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 629
 630         this.deadflag = DEAD_NO;
 631
 632         this.angles = spot.angles;
 633         this.angles_z = 0; // never spawn tilted even if the spot says to
 634         if (IS_BOT_CLIENT(this))
 635         {
 636                 this.v_angle = this.angles;
 637                 bot_aim_reset(this);
 638         }
 639         this.fixangle = true; // turn this way immediately
 640         this.oldvelocity = this.velocity = '0 0 0';
 641         this.avelocity = '0 0 0';
 642         this.punchangle = '0 0 0';
 643         this.punchvector = '0 0 0';
 644
 645         STAT(REVIVE_PROGRESS, this) = 0;
 646         this.revival_time = 0;
 647
 648         STAT(AIR_FINISHED, this) = 0;
 649         this.waterlevel = WATERLEVEL_NONE;
 650         this.watertype = CONTENT_EMPTY;
 651
 652         entity spawnevent = new_pure(spawnevent);
 653         spawnevent.owner = this;
 654         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 655
 656         // Cut off any still running player sounds.
 657         stopsound(this, CH_PLAYER_SINGLE);
 658
 659         this.model = "";
 660         FixPlayermodel(this);
 661         this.drawonlytoclient = NULL;
 662
 663         this.viewloc = NULL;
 664
 665         for(int slot = 0; slot < MAX_AXH; ++slot)
 666         {
 667                 entity axh = this.(AuxiliaryXhair[slot]);
 668                 this.(AuxiliaryXhair[slot]) = NULL;
 669
 670                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 671                         delete(axh);
 672         }
 673
 674         this.spawnpoint_targ = NULL;
 675
 676         UNSET_DUCKED(this);
 677         this.view_ofs = STAT(PL_VIEW_OFS, this);
 678         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 679         this.spawnorigin = spot.origin;
 680         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 681         // don't reset back to last position, even if new position is stuck in solid
 682         this.oldorigin = this.origin;
 683         if(this.conveyor)
 684                 IL_REMOVE(g_conveyed, this);
 685         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 686         if(this.swampslug)
 687                 IL_REMOVE(g_swamped, this);
 688         this.swampslug = NULL;
 689         this.swamp_interval = 0;
 690         if(this.ladder_entity)
 691                 IL_REMOVE(g_ladderents, this);
 692         this.ladder_entity = NULL;
 693         IL_EACH(g_counters, it.realowner == this,
 694         {
 695                 delete(it);
 696         });
 697         STAT(HUD, this) = HUD_NORMAL;
 698
 699         this.event_damage = PlayerDamage;
 700         this.event_heal = PlayerHeal;
 701
 702         this.draggable = func_null;
 703
 704         if(!this.bot_attack)
 705                 IL_PUSH(g_bot_targets, this);
 706         this.bot_attack = true;
 707         if(!this.monster_attack)
 708                 IL_PUSH(g_monster_targets, this);
 709         this.monster_attack = true;
 710         navigation_dynamicgoal_init(this, false);
 711
 712         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 713
 714         // player was spectator
 715         if (CS(this).killcount == FRAGS_SPECTATOR) {
 716                 PlayerScore_Clear(this);
 717                 CS(this).killcount = 0;
 718                 CS(this).startplaytime = time;
 719         }
 720
 721         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 722         {
 723                 .entity weaponentity = weaponentities[slot];
 724                 CL_SpawnWeaponentity(this, weaponentity);
 725         }
 726         this.alpha = default_player_alpha;
 727         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 728         this.exteriorweaponentity.alpha = default_weapon_alpha;
 729
 730         this.speedrunning = false;
 731
 732         this.counter_cnt = 0;
 733         this.fragsfilter_cnt = 0;
 734
 735         target_voicescript_clear(this);
 736
 737         // reset fields the weapons may use
 738         FOREACH(Weapons, true, {
 739                 it.wr_resetplayer(it, this);
 740                         // reload all reloadable weapons
 741                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 742                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 743                         {
 744                                 .entity weaponentity = weaponentities[slot];
 745                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 746                         }
 747                 }
 748         });
 749
 750         Unfreeze(this, false);
 751
 752         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 753
 754         {
 755                 string s = spot.target;
 756                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 757                         spot.target = string_null;
 758                 SUB_UseTargets(spot, this, NULL);
 759                 if(g_assault || g_race)
 760                         spot.target = s;
 761         }
 762
 763         if (autocvar_spawn_debug)
 764         {
 765                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 766                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 767         }
 768
 769         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 770         {
 771                 .entity weaponentity = weaponentities[slot];
 772                 entity w_ent = this.(weaponentity);
 773                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 774                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 775                 else
 776                         w_ent.m_switchweapon = WEP_Null;
 777                 w_ent.m_weapon = WEP_Null;
 778                 w_ent.weaponname = "";
 779                 w_ent.m_switchingweapon = WEP_Null;
 780                 w_ent.cnt = -1;
 781         }
 782
 783         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 784
 785         if (CS(this).impulse) ImpulseCommands(this);
 786
 787         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 788         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 789         {
 790                 .entity weaponentity = weaponentities[slot];
 791                 W_WeaponFrame(this, weaponentity);
 792         }
 793
 794         if (!warmup_stage && !this.alivetime)
 795                 this.alivetime = time;
 796
 797         antilag_clear(this, CS(this));
 798 }
 799
 800 /** Called when a client spawns in the server */
 801 void PutClientInServer(entity this)
 802 {
 803         if (IS_BOT_CLIENT(this)) {
 804                 TRANSMUTE(Player, this);
 805         } else if (IS_REAL_CLIENT(this)) {
 806                 msg_entity = this;
 807                 WriteByte(MSG_ONE, SVC_SETVIEW);
 808                 WriteEntity(MSG_ONE, this);
 809         }
 810         if (game_stopped)
 811                 TRANSMUTE(Observer, this);
 812
 813         SetSpectatee(this, NULL);
 814
 815         // reset player keys
 816         if(PS(this))
 817                 PS(this).itemkeys = 0;
 818
 819         MUTATOR_CALLHOOK(PutClientInServer, this);
 820
 821         if (IS_OBSERVER(this)) {
 822                 PutObserverInServer(this);
 823         } else if (IS_PLAYER(this)) {
 824                 PutPlayerInServer(this);
 825         }
 826
 827         bot_relinkplayerlist();
 828 }
 829
 830 // TODO do we need all these fields, or should we stop autodetecting runtime
 831 // changes and just have a console command to update this?
 832 bool ClientInit_SendEntity(entity this, entity to, int sf)
 833 {
 834         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 835         return = true;
 836         msg_entity = to;
 837         // MSG_INIT replacement
 838         // TODO: make easier to use
 839         Registry_send_all();
 840         W_PROP_reload(MSG_ONE, to);
 841         ClientInit_misc(this);
 842         MUTATOR_CALLHOOK(Ent_Init);
 843 }
 844 void ClientInit_misc(entity this)
 845 {
 846         int channel = MSG_ONE;
 847         WriteHeader(channel, ENT_CLIENT_INIT);
 848         WriteByte(channel, g_nexball_meter_period * 32);
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 852         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 856         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 857
 858         if(autocvar_sv_foginterval && world.fog != "")
 859                 WriteString(channel, world.fog);
 860         else
 861                 WriteString(channel, "");
 862         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 863         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 864         WriteByte(channel, serverflags);
 865         WriteCoord(channel, autocvar_g_trueaim_minrange);
 866 }
 867
 868 void ClientInit_CheckUpdate(entity this)
 869 {
 870         this.nextthink = time;
 871         if(this.count != autocvar_g_balance_armor_blockpercent)
 872         {
 873                 this.count = autocvar_g_balance_armor_blockpercent;
 874                 this.SendFlags |= 1;
 875         }
 876         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 877         {
 878                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 879                 this.SendFlags |= 1;
 880         }
 881 }
 882
 883 void ClientInit_Spawn()
 884 {
 885         entity e = new_pure(clientinit);
 886         setthink(e, ClientInit_CheckUpdate);
 887         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 888
 889         ClientInit_CheckUpdate(e);
 890 }
 891
 892 /*
 893 =============
 894 SetNewParms
 895 =============
 896 */
 897 void SetNewParms ()
 898 {
 899         // initialize parms for a new player
 900         parm1 = -(86400 * 366);
 901
 902         MUTATOR_CALLHOOK(SetNewParms);
 903 }
 904
 905 /*
 906 =============
 907 SetChangeParms
 908 =============
 909 */
 910 void SetChangeParms (entity this)
 911 {
 912         // save parms for level change
 913         parm1 = CS(this).parm_idlesince - time;
 914
 915         MUTATOR_CALLHOOK(SetChangeParms);
 916 }
 917
 918 /*
 919 =============
 920 DecodeLevelParms
 921 =============
 922 */
 923 void DecodeLevelParms(entity this)
 924 {
 925         // load parms
 926         CS(this).parm_idlesince = parm1;
 927         if (CS(this).parm_idlesince == -(86400 * 366))
 928                 CS(this).parm_idlesince = time;
 929
 930         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 931         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 932
 933         MUTATOR_CALLHOOK(DecodeLevelParms);
 934 }
 935
 936 void FixClientCvars(entity e)
 937 {
 938         // send prediction settings to the client
 939         stuffcmd(e, "\nin_bindmap 0 0\n");
 940         if(autocvar_g_antilag == 3) // client side hitscan
 941                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 942         if(autocvar_sv_gentle)
 943                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 944
 945         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 946         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 947
 948         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 949
 950         MUTATOR_CALLHOOK(FixClientCvars, e);
 951 }
 952
 953 bool findinlist_abbrev(string tofind, string list)
 954 {
 955         if(list == "" || tofind == "")
 956                 return false; // empty list or search, just return
 957
 958         // this function allows abbreviated strings!
 959         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 960         {
 961                 return true;
 962         });
 963
 964         return false;
 965 }
 966
 967 bool PlayerInIPList(entity p, string iplist)
 968 {
 969         // some safety checks (never allow local?)
 970         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 971                 return false;
 972
 973         return findinlist_abbrev(p.netaddress, iplist);
 974 }
 975
 976 bool PlayerInIDList(entity p, string idlist)
 977 {
 978         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 979         if(!p.crypto_idfp)
 980                 return false;
 981
 982         return findinlist_abbrev(p.crypto_idfp, idlist);
 983 }
 984
 985 bool PlayerInList(entity player, string list)
 986 {
 987         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 988 }
 989
 990 #ifdef DP_EXT_PRECONNECT
 991 /*
 992 =============
 993 ClientPreConnect
 994
 995 Called once (not at each match start) when a client begins a connection to the server
 996 =============
 997 */
 998 void ClientPreConnect(entity this)
 999 {
1000         if(autocvar_sv_eventlog)
1001         {
1002                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1003                         this.playerid,
1004                         etof(this),
1005                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1006                 ));
1007         }
1008 }
1009 #endif
1010
1011 string GetClientVersionMessage(entity this)
1012 {
1013         if (CS(this).version_mismatch) {
1014                 if(CS(this).version < autocvar_gameversion) {
1015                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1016                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1017                 } else {
1018                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1019                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1020                 }
1021         } else {
1022                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1023         }
1024 }
1025
1026 string getwelcomemessage(entity this)
1027 {
1028         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1029         string modifications = M_ARGV(0, string);
1030
1031         if(g_weaponarena)
1032         {
1033                 if(g_weaponarena_random)
1034                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1035                 else
1036                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1037         }
1038         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1039                 modifications = strcat(modifications, ", No start weapons");
1040         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1041                 modifications = strcat(modifications, ", Low gravity");
1042         if(g_weapon_stay && !g_cts)
1043                 modifications = strcat(modifications, ", Weapons stay");
1044         if(autocvar_g_jetpack)
1045                 modifications = strcat(modifications, ", Jet pack");
1046         modifications = substring(modifications, 2, strlen(modifications) - 2);
1047
1048         string versionmessage = GetClientVersionMessage(this);
1049         string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1050
1051         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1052
1053         if(modifications != "")
1054                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1055
1056         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1057         {
1058                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1059                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1060         }
1061
1062         if (cache_mutatormsg != "") {
1063                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1064         }
1065
1066         string mutator_msg = "";
1067         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1068         mutator_msg = M_ARGV(0, string);
1069
1070         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1071
1072         string motd = autocvar_sv_motd;
1073         if (motd != "") {
1074                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1075         }
1076         return s;
1077 }
1078
1079 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1080
1081 /**
1082 =============
1083 ClientConnect
1084
1085 Called when a client connects to the server
1086 =============
1087 */
1088 void ClientConnect(entity this)
1089 {
1090         if (Ban_MaybeEnforceBanOnce(this)) return;
1091         assert(!IS_CLIENT(this), return);
1092         this.flags |= FL_CLIENT;
1093         assert(player_count >= 0, player_count = 0);
1094
1095         TRANSMUTE(Client, this);
1096         CS(this).version_nagtime = time + 10 + random() * 10;
1097
1098         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1099
1100         bot_clientconnect(this);
1101
1102         Player_DetermineForcedTeam(this);
1103
1104         TRANSMUTE(Observer, this);
1105
1106         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1107
1108         // always track bots, don't ask for cl_allow_uidtracking
1109         if (IS_BOT_CLIENT(this))
1110                 PlayerStats_GameReport_AddPlayer(this);
1111         else
1112                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1113
1114         if (autocvar_sv_eventlog)
1115                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1116
1117         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1118
1119         stuffcmd(this, clientstuff, "\n");
1120         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1121
1122         FixClientCvars(this);
1123
1124         // get version info from player
1125         stuffcmd(this, "cmd clientversion $gameversion\n");
1126
1127         // notify about available teams
1128         if (teamplay)
1129         {
1130                 entity balance = TeamBalance_CheckAllowedTeams(this);
1131                 int t = TeamBalance_GetAllowedTeams(balance);
1132                 TeamBalance_Destroy(balance);
1133                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1134         }
1135         else
1136         {
1137                 stuffcmd(this, "set _teams_available 0\n");
1138         }
1139
1140         bot_relinkplayerlist();
1141
1142         CS(this).spectatortime = time;
1143         if (blockSpectators)
1144         {
1145                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1146         }
1147
1148         CS(this).jointime = time;
1149
1150         if (IS_REAL_CLIENT(this))
1151         {
1152                 if (g_weaponarena_weapons == WEPSET(TUBA))
1153                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1154         }
1155
1156         if (!autocvar_sv_foginterval && world.fog != "")
1157                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1158
1159         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1160                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1161                         send_CSQC_teamnagger();
1162
1163         CSQCMODEL_AUTOINIT(this);
1164
1165         CS(this).model_randomizer = random();
1166
1167         if (IS_REAL_CLIENT(this))
1168                 sv_notice_join(this);
1169
1170         this.move_qcphysics = autocvar_sv_qcphysics;
1171
1172         // update physics stats (players can spawn before physics runs)
1173         Physics_UpdateStats(this);
1174
1175         IL_EACH(g_initforplayer, it.init_for_player, {
1176                 it.init_for_player(it, this);
1177         });
1178
1179         Handicap_Initialize(this);
1180
1181         MUTATOR_CALLHOOK(ClientConnect, this);
1182
1183         if (IS_REAL_CLIENT(this))
1184         {
1185                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1186                 {
1187                         CS(this).motd_actived_time = -1;
1188                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1189                 }
1190         }
1191 }
1192 /*
1193 =============
1194 ClientDisconnect
1195
1196 Called when a client disconnects from the server
1197 =============
1198 */
1199 .entity chatbubbleentity;
1200 void player_powerups_remove_all(entity this);
1201
1202 void ClientDisconnect(entity this)
1203 {
1204         assert(IS_CLIENT(this), return);
1205
1206         PlayerStats_GameReport_FinalizePlayer(this);
1207         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1208         if (CS(this).active_minigame) part_minigame(this);
1209         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1210
1211         if (autocvar_sv_eventlog)
1212                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1213
1214         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1215
1216         if(IS_SPEC(this))
1217                 SetSpectatee(this, NULL);
1218
1219         MUTATOR_CALLHOOK(ClientDisconnect, this);
1220
1221         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1222         strfree(CS_CVAR(this).weaponorder_byimpulse);
1223         ClientState_detach(this);
1224
1225         Portal_ClearAll(this);
1226
1227         Unfreeze(this, false);
1228
1229         RemoveGrapplingHooks(this);
1230
1231         // Here, everything has been done that requires this player to be a client.
1232
1233         this.flags &= ~FL_CLIENT;
1234
1235         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1236         if (this.killindicator) delete(this.killindicator);
1237
1238         IL_EACH(g_counters, it.realowner == this,
1239         {
1240                 delete(it);
1241         });
1242
1243         WaypointSprite_PlayerGone(this);
1244
1245         bot_relinkplayerlist();
1246
1247         strfree(this.clientstatus);
1248         if (this.personal) delete(this.personal);
1249
1250         this.playerid = 0;
1251         ReadyCount();
1252         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1253
1254         player_powerups_remove_all(this); // stop powerup sound
1255
1256         ONREMOVE(this);
1257 }
1258
1259 void ChatBubbleThink(entity this)
1260 {
1261         this.nextthink = time;
1262         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1263         {
1264                 if(this.owner) // but why can that ever be NULL?
1265                         this.owner.chatbubbleentity = NULL;
1266                 delete(this);
1267                 return;
1268         }
1269
1270         this.mdl = "";
1271
1272         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1273         {
1274                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1275                         this.mdl = "models/sprites/minigame_busy.iqm";
1276                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1277                         this.mdl = "models/misc/chatbubble.spr";
1278         }
1279
1280         if ( this.model != this.mdl )
1281                 _setmodel(this, this.mdl);
1282
1283 }
1284
1285 void UpdateChatBubble(entity this)
1286 {
1287         if (this.alpha < 0)
1288                 return;
1289         // spawn a chatbubble entity if needed
1290         if (!this.chatbubbleentity)
1291         {
1292                 this.chatbubbleentity = new(chatbubbleentity);
1293                 this.chatbubbleentity.owner = this;
1294                 this.chatbubbleentity.exteriormodeltoclient = this;
1295                 setthink(this.chatbubbleentity, ChatBubbleThink);
1296                 this.chatbubbleentity.nextthink = time;
1297                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1298                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1299                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1300                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1301                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1302                 //this.chatbubbleentity.model = "";
1303                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1304         }
1305 }
1306
1307 void calculate_player_respawn_time(entity this)
1308 {
1309         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1310                 return;
1311
1312         float gametype_setting_tmp;
1313         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1314         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1315         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1316         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1317         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1318         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1319
1320         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1321         if (teamplay)
1322         {
1323                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1324                         if(it.team == this.team)
1325                                 ++pcount;
1326                 });
1327                 if (sdelay_small_count == 0)
1328                         sdelay_small_count = 1;
1329                 if (sdelay_large_count == 0)
1330                         sdelay_large_count = 1;
1331         }
1332         else
1333         {
1334                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1335                         ++pcount;
1336                 });
1337                 if (sdelay_small_count == 0)
1338                 {
1339                         if (IS_INDEPENDENT_PLAYER(this))
1340                         {
1341                                 // Players play independently. No point in requiring enemies.
1342                                 sdelay_small_count = 1;
1343                         }
1344                         else
1345                         {
1346                                 // Players play AGAINST each other. Enemies required.
1347                                 sdelay_small_count = 2;
1348                         }
1349                 }
1350                 if (sdelay_large_count == 0)
1351                 {
1352                         if (IS_INDEPENDENT_PLAYER(this))
1353                         {
1354                                 // Players play independently. No point in requiring enemies.
1355                                 sdelay_large_count = 1;
1356                         }
1357                         else
1358                         {
1359                                 // Players play AGAINST each other. Enemies required.
1360                                 sdelay_large_count = 2;
1361                         }
1362                 }
1363         }
1364
1365         float sdelay;
1366
1367         if (pcount <= sdelay_small_count)
1368                 sdelay = sdelay_small;
1369         else if (pcount >= sdelay_large_count)
1370                 sdelay = sdelay_large;
1371         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1372                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1373
1374         if(waves)
1375                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1376         else
1377                 this.respawn_time = time + sdelay;
1378
1379         if(sdelay < sdelay_max)
1380                 this.respawn_time_max = time + sdelay_max;
1381         else
1382                 this.respawn_time_max = this.respawn_time;
1383
1384         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1385                 this.respawn_countdown = 10; // first number to count down from is 10
1386         else
1387                 this.respawn_countdown = -1; // do not count down
1388
1389         if(autocvar_g_forced_respawn)
1390                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1391 }
1392
1393 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1394 // added to the model skins
1395 /*void UpdateColorModHack()
1396 {
1397         float c;
1398         c = this.clientcolors & 15;
1399         // LordHavoc: only bothering to support white, green, red, yellow, blue
1400              if (!teamplay) this.colormod = '0 0 0';
1401         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1402         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1403         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1404         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1405         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1406         else this.colormod = '1 1 1';
1407 }*/
1408
1409 void respawn(entity this)
1410 {
1411         bool damagedbycontents_prev = this.damagedbycontents;
1412         if(this.alpha >= 0)
1413         {
1414                 if(autocvar_g_respawn_ghosts)
1415                 {
1416                         this.solid = SOLID_NOT;
1417                         this.takedamage = DAMAGE_NO;
1418                         this.damagedbycontents = false;
1419                         set_movetype(this, MOVETYPE_FLY);
1420                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1421                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1422                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1423                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1424                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1425                         if(autocvar_g_respawn_ghosts_time > 0)
1426                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1427                 }
1428                 else
1429                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1430         }
1431
1432         CopyBody(this, 1);
1433         this.damagedbycontents = damagedbycontents_prev;
1434
1435         this.effects |= EF_NODRAW; // prevent another CopyBody
1436         PutClientInServer(this);
1437 }
1438
1439 void play_countdown(entity this, float finished, Sound samp)
1440 {
1441         TC(Sound, samp);
1442         if(IS_REAL_CLIENT(this))
1443                 if(floor(finished - time - frametime) != floor(finished - time))
1444                         if(finished - time < 6)
1445                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1446 }
1447
1448 void player_powerups_remove_all(entity this)
1449 {
1450         if (this.items & IT_SUPERWEAPON)
1451         {
1452                 // don't play the poweroff sound when the game restarts or the player disconnects
1453                 if (time > game_starttime + 1 && IS_CLIENT(this))
1454                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1455                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1456                 this.items -= (this.items & IT_SUPERWEAPON);
1457         }
1458 }
1459
1460 void player_powerups(entity this)
1461 {
1462         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1463                 this.modelflags |= MF_ROCKET;
1464         else
1465                 this.modelflags &= ~MF_ROCKET;
1466
1467         this.effects &= ~EF_NODEPTHTEST;
1468
1469         if (IS_DEAD(this))
1470                 player_powerups_remove_all(this);
1471
1472         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1473                 return;
1474
1475         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1476         int items_prev = this.items;
1477
1478         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1479         {
1480                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1481                 if (this.items & IT_SUPERWEAPON)
1482                 {
1483                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1484                         {
1485                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1486                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1487                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1488                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1489                         }
1490                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1491                         {
1492                                 // don't let them run out
1493                         }
1494                         else
1495                         {
1496                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1497                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1498                                 {
1499                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1500                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1501                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1502                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1503                                 }
1504                         }
1505                 }
1506                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1507                 {
1508                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1509                         {
1510                                 this.items = this.items | IT_SUPERWEAPON;
1511                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1512                                 {
1513                                         if(!g_cts)
1514                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1515                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1516                                 }
1517                         }
1518                         else
1519                         {
1520                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1521                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1522                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1523                         }
1524                 }
1525                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1526                 {
1527                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1528                 }
1529         }
1530
1531         if(autocvar_g_nodepthtestplayers)
1532                 this.effects = this.effects | EF_NODEPTHTEST;
1533
1534         if(autocvar_g_fullbrightplayers)
1535                 this.effects = this.effects | EF_FULLBRIGHT;
1536
1537         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1538 }
1539
1540 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1541 {
1542         if(current > stable)
1543                 return current;
1544         else if(current > stable - 0.25) // when close enough, "snap"
1545                 return stable;
1546         else
1547                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1548 }
1549
1550 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1551 {
1552         if(current < stable)
1553                 return current;
1554         else if(current < stable + 0.25) // when close enough, "snap"
1555                 return stable;
1556         else
1557                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1558 }
1559
1560 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1561 {
1562         float old = GetResource(this, res);
1563         float current = old;
1564         if(current > rotstable)
1565         {
1566                 if(rotframetime > 0)
1567                 {
1568                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1569                         current = max(rotstable, current - rotlinear * rotframetime);
1570                 }
1571         }
1572         else if(current < regenstable)
1573         {
1574                 if(regenframetime > 0)
1575                 {
1576                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1577                         current = min(regenstable, current + regenlinear * regenframetime);
1578                 }
1579         }
1580
1581         float limit = GetResourceLimit(this, res) * limit_mod;
1582         if(current > limit)
1583                 current = limit;
1584
1585         if (current != old)
1586                 SetResource(this, res, current);
1587 }
1588
1589 void player_regen(entity this)
1590 {
1591         float max_mod, regen_mod, rot_mod, limit_mod;
1592         max_mod = regen_mod = rot_mod = limit_mod = 1;
1593
1594         float regen_health = autocvar_g_balance_health_regen;
1595         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1596         float regen_health_rot = autocvar_g_balance_health_rot;
1597         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1598         float regen_health_stable = autocvar_g_balance_health_regenstable;
1599         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1600         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1601                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1602         max_mod = M_ARGV(1, float);
1603         regen_mod = M_ARGV(2, float);
1604         rot_mod = M_ARGV(3, float);
1605         limit_mod = M_ARGV(4, float);
1606         regen_health = M_ARGV(5, float);
1607         regen_health_linear = M_ARGV(6, float);
1608         regen_health_rot = M_ARGV(7, float);
1609         regen_health_rotlinear = M_ARGV(8, float);
1610         regen_health_stable = M_ARGV(9, float);
1611         regen_health_rotstable = M_ARGV(10, float);
1612
1613         if(!mutator_returnvalue)
1614         if(!STAT(FROZEN, this))
1615         {
1616                 float maxa = autocvar_g_balance_armor_rotstable;
1617                 float mina = autocvar_g_balance_armor_regenstable;
1618
1619                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1620                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1621                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1622
1623                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1624                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1625                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1626         }
1627
1628         // if player rotted to death...  die!
1629         // check this outside above checks, as player may still be able to rot to death
1630         if(GetResource(this, RES_HEALTH) < 1)
1631         {
1632                 if(this.vehicle)
1633                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1634                 if(this.event_damage)
1635                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1636         }
1637
1638         if (!(this.items & IT_UNLIMITED_AMMO))
1639         {
1640                 float maxf = autocvar_g_balance_fuel_rotstable;
1641                 float minf = autocvar_g_balance_fuel_regenstable;
1642
1643                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1644                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1645                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1646         }
1647 }
1648
1649 bool zoomstate_set;
1650 void SetZoomState(entity this, float newzoom)
1651 {
1652         if(newzoom != CS(this).zoomstate)
1653         {
1654                 CS(this).zoomstate = newzoom;
1655                 ClientData_Touch(this);
1656         }
1657         zoomstate_set = true;
1658 }
1659
1660 void GetPressedKeys(entity this)
1661 {
1662         MUTATOR_CALLHOOK(GetPressedKeys, this);
1663         if (game_stopped)
1664         {
1665                 CS(this).pressedkeys = 0;
1666                 STAT(PRESSED_KEYS, this) = 0;
1667                 return;
1668         }
1669
1670         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1671         int keys = STAT(PRESSED_KEYS, this);
1672         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1673         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1674         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1675         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1676
1677         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1678         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1679         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1680         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1681         CS(this).pressedkeys = keys; // store for other users
1682
1683         STAT(PRESSED_KEYS, this) = keys;
1684 }
1685
1686 /*
1687 ======================
1688 spectate mode routines
1689 ======================
1690 */
1691
1692 void SpectateCopy(entity this, entity spectatee)
1693 {
1694         TC(Client, this); TC(Client, spectatee);
1695
1696         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1697         PS(this) = PS(spectatee);
1698         this.armortype = spectatee.armortype;
1699         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1700         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1701         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1702         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1703         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1704         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1705         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1706         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1707         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1708         CS(this).impulse = 0;
1709         this.disableclientprediction = 1; // no need to run prediction on a spectator
1710         this.items = spectatee.items;
1711         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1712         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1713         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1714         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1715         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1716         this.punchangle = spectatee.punchangle;
1717         this.view_ofs = spectatee.view_ofs;
1718         this.velocity = spectatee.velocity;
1719         this.dmg_take = spectatee.dmg_take;
1720         this.dmg_save = spectatee.dmg_save;
1721         this.dmg_inflictor = spectatee.dmg_inflictor;
1722         this.v_angle = spectatee.v_angle;
1723         this.angles = spectatee.v_angle;
1724         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1725         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1726         this.viewloc = spectatee.viewloc;
1727         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1728                 this.fixangle = true;
1729         setorigin(this, spectatee.origin);
1730         setsize(this, spectatee.mins, spectatee.maxs);
1731         SetZoomState(this, CS(spectatee).zoomstate);
1732
1733     anticheat_spectatecopy(this, spectatee);
1734         STAT(HUD, this) = STAT(HUD, spectatee);
1735         if(spectatee.vehicle)
1736     {
1737         this.angles = spectatee.v_angle;
1738
1739         //this.fixangle = false;
1740         //this.velocity = spectatee.vehicle.velocity;
1741         this.vehicle_health = spectatee.vehicle_health;
1742         this.vehicle_shield = spectatee.vehicle_shield;
1743         this.vehicle_energy = spectatee.vehicle_energy;
1744         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1745         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1746         this.vehicle_reload1 = spectatee.vehicle_reload1;
1747         this.vehicle_reload2 = spectatee.vehicle_reload2;
1748
1749         //msg_entity = this;
1750
1751        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1752             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1753            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1754            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1755
1756         //WriteByte (MSG_ONE, SVC_SETVIEW);
1757         //    WriteEntity(MSG_ONE, this);
1758         //makevectors(spectatee.v_angle);
1759         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1760     }
1761 }
1762
1763 bool SpectateUpdate(entity this)
1764 {
1765         if(!this.enemy)
1766                 return false;
1767
1768         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1769         {
1770                 SetSpectatee(this, NULL);
1771                 return false;
1772         }
1773
1774         SpectateCopy(this, this.enemy);
1775
1776         return true;
1777 }
1778
1779 bool SpectateSet(entity this)
1780 {
1781         if(!IS_PLAYER(this.enemy))
1782                 return false;
1783
1784         ClientData_Touch(this.enemy);
1785
1786         msg_entity = this;
1787         WriteByte(MSG_ONE, SVC_SETVIEW);
1788         WriteEntity(MSG_ONE, this.enemy);
1789         set_movetype(this, MOVETYPE_NONE);
1790         accuracy_resend(this);
1791
1792         if(!SpectateUpdate(this))
1793                 PutObserverInServer(this);
1794
1795         return true;
1796 }
1797
1798 void SetSpectatee_status(entity this, int spectatee_num)
1799 {
1800         int oldspectatee_status = CS(this).spectatee_status;
1801         CS(this).spectatee_status = spectatee_num;
1802
1803         if (CS(this).spectatee_status != oldspectatee_status)
1804         {
1805                 if (STAT(PRESSED_KEYS, this))
1806                 {
1807                         CS(this).pressedkeys = 0;
1808                         STAT(PRESSED_KEYS, this) = 0;
1809                 }
1810                 ClientData_Touch(this);
1811                 if (g_race || g_cts) race_InitSpectator();
1812         }
1813 }
1814
1815 void SetSpectatee(entity this, entity spectatee)
1816 {
1817         if(IS_BOT_CLIENT(this))
1818                 return; // bots abuse .enemy, this code is useless to them
1819
1820         entity old_spectatee = this.enemy;
1821
1822         this.enemy = spectatee;
1823
1824         // WEAPONTODO
1825         // these are required to fix the spectator bug with arc
1826         if(old_spectatee)
1827         {
1828                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1829                 {
1830                         .entity weaponentity = weaponentities[slot];
1831                         if(old_spectatee.(weaponentity).arc_beam)
1832                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1833                 }
1834         }
1835         if(this.enemy)
1836         {
1837                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1838                 {
1839                         .entity weaponentity = weaponentities[slot];
1840                         if(this.enemy.(weaponentity).arc_beam)
1841                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1842                 }
1843         }
1844
1845         if (this.enemy)
1846                 SetSpectatee_status(this, etof(this.enemy));
1847
1848         // needed to update spectator list
1849         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1850 }
1851
1852 bool Spectate(entity this, entity pl)
1853 {
1854         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1855                 return false;
1856         pl = M_ARGV(1, entity);
1857
1858         SetSpectatee(this, pl);
1859         return SpectateSet(this);
1860 }
1861
1862 bool SpectateNext(entity this)
1863 {
1864         entity ent = find(this.enemy, classname, STR_PLAYER);
1865
1866         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1867                 ent = M_ARGV(1, entity);
1868         else if (!ent)
1869                 ent = find(ent, classname, STR_PLAYER);
1870
1871         if(ent) { SetSpectatee(this, ent); }
1872
1873         return SpectateSet(this);
1874 }
1875
1876 bool SpectatePrev(entity this)
1877 {
1878         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1879         entity ent = findchain(classname, STR_PLAYER);
1880         if (!ent) // no player
1881                 return false;
1882
1883         entity first = ent;
1884         // skip players until current spectated player
1885         if(this.enemy)
1886         while(ent && ent != this.enemy)
1887                 ent = ent.chain;
1888
1889         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1890         {
1891                 case MUT_SPECPREV_FOUND:
1892                         ent = M_ARGV(1, entity);
1893                         break;
1894                 case MUT_SPECPREV_RETURN:
1895                         return true;
1896                 case MUT_SPECPREV_CONTINUE:
1897                 default:
1898                 {
1899                         if(ent.chain)
1900                                 ent = ent.chain;
1901                         else
1902                                 ent = first;
1903                         break;
1904                 }
1905         }
1906
1907         SetSpectatee(this, ent);
1908         return SpectateSet(this);
1909 }
1910
1911 /*
1912 =============
1913 ShowRespawnCountdown()
1914
1915 Update a respawn countdown display.
1916 =============
1917 */
1918 void ShowRespawnCountdown(entity this)
1919 {
1920         float number;
1921         if(!IS_DEAD(this)) // just respawned?
1922                 return;
1923         else
1924         {
1925                 number = ceil(this.respawn_time - time);
1926                 if(number <= 0)
1927                         return;
1928                 if(number <= this.respawn_countdown)
1929                 {
1930                         this.respawn_countdown = number - 1;
1931                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1932                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1933                 }
1934         }
1935 }
1936
1937 .bool team_selected;
1938 bool ShowTeamSelection(entity this)
1939 {
1940         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1941                 return false;
1942         stuffcmd(this, "menu_showteamselect\n");
1943         return true;
1944 }
1945 void Join(entity this)
1946 {
1947         TRANSMUTE(Player, this);
1948
1949         if(!this.team_selected)
1950         if(autocvar_g_campaign || autocvar_g_balance_teams)
1951                 TeamBalance_JoinBestTeam(this);
1952
1953         if(autocvar_g_campaign)
1954                 campaign_bots_may_start = true;
1955
1956         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1957
1958         PutClientInServer(this);
1959
1960         if(IS_PLAYER(this))
1961         if(teamplay && this.team != -1)
1962         {
1963         }
1964         else
1965                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1966         this.team_selected = false;
1967 }
1968
1969 int GetPlayerLimit()
1970 {
1971         if(g_duel)
1972                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1973         int player_limit = autocvar_g_maxplayers;
1974         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1975         player_limit = M_ARGV(0, int);
1976         return player_limit;
1977 }
1978
1979 /**
1980  * Determines whether the player is allowed to join. This depends on cvar
1981  * g_maxplayers, if it isn't used this function always return true, otherwise
1982  * it checks whether the number of currently playing players exceeds g_maxplayers.
1983  * @return int number of free slots for players, 0 if none
1984  */
1985 int nJoinAllowed(entity this, entity ignore)
1986 {
1987         if(!ignore)
1988         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1989         // so report 0 free slots if restricted
1990         {
1991                 if(autocvar_g_forced_team_otherwise == "spectate")
1992                         return 0;
1993                 if(autocvar_g_forced_team_otherwise == "spectator")
1994                         return 0;
1995         }
1996
1997         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1998                 return 0; // forced spectators can never join
1999
2000         // TODO simplify this
2001         int totalClients = 0;
2002         int currentlyPlaying = 0;
2003         FOREACH_CLIENT(true, {
2004                 if(it != ignore)
2005                         ++totalClients;
2006                 if(IS_REAL_CLIENT(it))
2007                 if(IS_PLAYER(it) || it.caplayer)
2008                         ++currentlyPlaying;
2009         });
2010
2011         int player_limit = GetPlayerLimit();
2012
2013         int free_slots = 0;
2014         if (!player_limit)
2015                 free_slots = maxclients - totalClients;
2016         else if(player_limit > 0 && currentlyPlaying < player_limit)
2017                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2018
2019         static float msg_time = 0;
2020         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2021         {
2022                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2023                 msg_time = time + 0.5;
2024         }
2025
2026         return free_slots;
2027 }
2028
2029 void PrintWelcomeMessage(entity this)
2030 {
2031         if(CS(this).motd_actived_time == 0)
2032         {
2033                 if (autocvar_g_campaign) {
2034                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2035                                 CS(this).motd_actived_time = time;
2036                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2037                         }
2038                 } else {
2039                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2040                                 CS(this).motd_actived_time = time;
2041                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2042                         }
2043                 }
2044         }
2045         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2046         {
2047                 if (autocvar_g_campaign) {
2048                         if (PHYS_INPUT_BUTTON_INFO(this))
2049                                 CS(this).motd_actived_time = time;
2050                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2051                                 CS(this).motd_actived_time = 0;
2052                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2053                         }
2054                 } else {
2055                         if (PHYS_INPUT_BUTTON_INFO(this))
2056                                 CS(this).motd_actived_time = time;
2057                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2058                                 CS(this).motd_actived_time = 0;
2059                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2060                         }
2061                 }
2062         }
2063         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2064         {
2065                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2066                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2067                 else if (CS(this).motd_actived_time == -2)
2068                 {
2069                         // instantly hide MOTD
2070                         CS(this).motd_actived_time = 0;
2071                         if (autocvar_g_campaign)
2072                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2073                         else
2074                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2075                 }
2076                 else if (IS_PLAYER(this) || IS_SPEC(this))
2077                 {
2078                         // FIXME occasionally for some reason MOTD never goes away
2079                         // delay MOTD removal a little bit in the hope it fixes this bug
2080                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2081                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2082                         else //if (CS(this).motd_actived_time < -2)
2083                                 CS(this).motd_actived_time++;
2084                 }
2085         }
2086 }
2087
2088 bool joinAllowed(entity this)
2089 {
2090         if (CS(this).version_mismatch) return false;
2091         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2092         if (!nJoinAllowed(this, this)) return false;
2093         if (teamplay && lockteams) return false;
2094         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2095         if (ShowTeamSelection(this)) return false;
2096         return true;
2097 }
2098
2099 .string shootfromfixedorigin;
2100 .bool dualwielding_prev;
2101 bool PlayerThink(entity this)
2102 {
2103         if (game_stopped || intermission_running) {
2104                 this.modelflags &= ~MF_ROCKET;
2105                 if(intermission_running)
2106                         IntermissionThink(this);
2107                 return false;
2108         }
2109
2110         if (timeout_status == TIMEOUT_ACTIVE) {
2111                 // don't allow the player to turn around while game is paused
2112                 // FIXME turn this into CSQC stuff
2113                 this.v_angle = this.lastV_angle;
2114                 this.angles = this.lastV_angle;
2115                 this.fixangle = true;
2116         }
2117
2118         if (frametime) player_powerups(this);
2119
2120         if (IS_DEAD(this)) {
2121                 if (this.personal && g_race_qualifying) {
2122                         if (time > this.respawn_time) {
2123                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2124                                 respawn(this);
2125                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2126                         }
2127                 } else {
2128                         if (frametime) player_anim(this);
2129
2130                         if (this.respawn_flags & RESPAWN_DENY)
2131                         {
2132                                 STAT(RESPAWN_TIME, this) = 0;
2133                                 return false;
2134                         }
2135
2136                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2137
2138                         switch(this.deadflag)
2139                         {
2140                                 case DEAD_DYING:
2141                                 {
2142                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2143                                                 this.deadflag = DEAD_RESPAWNING;
2144                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2145                                                 this.deadflag = DEAD_DEAD;
2146                                         break;
2147                                 }
2148                                 case DEAD_DEAD:
2149                                 {
2150                                         if (button_pressed)
2151                                                 this.deadflag = DEAD_RESPAWNABLE;
2152                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2153                                                 this.deadflag = DEAD_RESPAWNING;
2154                                         break;
2155                                 }
2156                                 case DEAD_RESPAWNABLE:
2157                                 {
2158                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2159                                                 this.deadflag = DEAD_RESPAWNING;
2160                                         break;
2161                                 }
2162                                 case DEAD_RESPAWNING:
2163                                 {
2164                                         if (time > this.respawn_time)
2165                                         {
2166                                                 this.respawn_time = time + 1; // only retry once a second
2167                                                 this.respawn_time_max = this.respawn_time;
2168                                                 respawn(this);
2169                                         }
2170                                         break;
2171                                 }
2172                         }
2173
2174                         ShowRespawnCountdown(this);
2175
2176                         if (this.respawn_flags & RESPAWN_SILENT)
2177                                 STAT(RESPAWN_TIME, this) = 0;
2178                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2179                         {
2180                                 if (time < this.respawn_time)
2181                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2182                                 else if (this.deadflag != DEAD_RESPAWNING)
2183                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2184                         }
2185                         else
2186                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2187                 }
2188
2189                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2190                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2191                         STAT(RESPAWN_TIME, this) *= -1;
2192
2193                 return false;
2194         }
2195
2196         FixPlayermodel(this);
2197
2198         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2199                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2200                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2201         }
2202
2203         // reset gun alignment when dual wielding status changes
2204         // to ensure guns are always aligned right and left
2205         bool dualwielding = W_DualWielding(this);
2206         if(this.dualwielding_prev != dualwielding)
2207         {
2208                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2209                 this.dualwielding_prev = dualwielding;
2210         }
2211
2212         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2213         //if(frametime)
2214         {
2215                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2216                 {
2217                         .entity weaponentity = weaponentities[slot];
2218                         if(WEP_CVAR(vortex, charge_always))
2219                                 W_Vortex_Charge(this, weaponentity, frametime);
2220                         W_WeaponFrame(this, weaponentity);
2221                 }
2222         }
2223
2224         if (frametime)
2225         {
2226                 // WEAPONTODO: Add a weapon request for this
2227                 // rot vortex charge to the charge limit
2228                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2229                 {
2230                         .entity weaponentity = weaponentities[slot];
2231                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2232                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2233                 }
2234
2235                 player_regen(this);
2236                 player_anim(this);
2237                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2238         }
2239
2240         monsters_setstatus(this);
2241
2242         return true;
2243 }
2244
2245 .bool would_spectate;
2246 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2247 void ObserverOrSpectatorThink(entity this)
2248 {
2249         bool is_spec = IS_SPEC(this);
2250         if ( CS(this).impulse )
2251         {
2252                 int r = MinigameImpulse(this, CS(this).impulse);
2253                 if (!is_spec || r)
2254                         CS(this).impulse = 0;
2255
2256                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2257                 {
2258                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2259                         CS(this).impulse = 0;
2260                         return;
2261                 }
2262         }
2263
2264         if (this.flags & FL_JUMPRELEASED) {
2265                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2266                         this.flags &= ~FL_JUMPRELEASED;
2267                         this.flags |= FL_SPAWNING;
2268                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2269                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2270                         this.flags &= ~FL_JUMPRELEASED;
2271                         if(SpectateNext(this)) {
2272                                 TRANSMUTE(Spectator, this);
2273                         } else if (is_spec) {
2274                                 TRANSMUTE(Observer, this);
2275                                 PutClientInServer(this);
2276                         }
2277                         else
2278                                 this.would_spectate = false; // unable to spectate anyone
2279                         if (is_spec)
2280                                 CS(this).impulse = 0;
2281                 } else if (is_spec) {
2282                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2283                                 this.flags &= ~FL_JUMPRELEASED;
2284                                 if(SpectatePrev(this)) {
2285                                         TRANSMUTE(Spectator, this);
2286                                 } else {
2287                                         TRANSMUTE(Observer, this);
2288                                         PutClientInServer(this);
2289                                 }
2290                                 CS(this).impulse = 0;
2291                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2292                                 this.would_spectate = false;
2293                                 this.flags &= ~FL_JUMPRELEASED;
2294                                 TRANSMUTE(Observer, this);
2295                                 PutClientInServer(this);
2296                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2297                                 PutObserverInServer(this);
2298                                 this.would_spectate = true;
2299                         }
2300                 }
2301                 else {
2302                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2303                         if (PHYS_INPUT_BUTTON_USE(this))
2304                                 wouldclip = !wouldclip;
2305                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2306                         set_movetype(this, preferred_movetype);
2307                 }
2308         } else { // jump pressed
2309                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2310                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2311                         this.flags |= FL_JUMPRELEASED;
2312                         if(this.flags & FL_SPAWNING)
2313                         {
2314                                 this.flags &= ~FL_SPAWNING;
2315                                 if(joinAllowed(this))
2316                                         Join(this);
2317                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2318                                         CS(this).autojoin_checked = -1;
2319                                 return;
2320                         }
2321                 }
2322                 if(is_spec && !SpectateUpdate(this))
2323                         PutObserverInServer(this);
2324         }
2325         if (is_spec)
2326                 this.flags |= FL_CLIENT | FL_NOTARGET;
2327 }
2328
2329 void PlayerUseKey(entity this)
2330 {
2331         if (!IS_PLAYER(this))
2332                 return;
2333
2334         if(this.vehicle)
2335         {
2336                 if(!game_stopped)
2337                 {
2338                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2339                         return;
2340                 }
2341         }
2342         else if(autocvar_g_vehicles_enter)
2343         {
2344                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2345                 {
2346                         entity head, closest_target = NULL;
2347                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2348
2349                         while(head) // find the closest acceptable target to enter
2350                         {
2351                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2352                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2353                                 {
2354                                         if(closest_target)
2355                                         {
2356                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2357                                                 { closest_target = head; }
2358                                         }
2359                                         else { closest_target = head; }
2360                                 }
2361
2362                                 head = head.chain;
2363                         }
2364
2365                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2366                 }
2367         }
2368
2369         // a use key was pressed; call handlers
2370         MUTATOR_CALLHOOK(PlayerUseKey, this);
2371 }
2372
2373
2374 /*
2375 =============
2376 PlayerPreThink
2377
2378 Called every frame for each client before the physics are run
2379 =============
2380 */
2381 .float last_vehiclecheck;
2382 void PlayerPreThink (entity this)
2383 {
2384         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2385         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2386
2387         WarpZone_PlayerPhysics_FixVAngle(this);
2388
2389         if (frametime) {
2390                 // physics frames: update anticheat stuff
2391                 anticheat_prethink(this);
2392
2393                 // WORKAROUND: only use dropclient in server frames (frametime set).
2394                 // Never use it in cl_movement frames (frametime zero).
2395                 if (blockSpectators && IS_REAL_CLIENT(this)
2396                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2397                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2398                 {
2399                         if (dropclient_schedule(this))
2400                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2401                 }
2402         }
2403
2404         zoomstate_set = false;
2405
2406         // Check for nameless players
2407         if (this.netname == "" || this.netname != CS(this).netname_previous)
2408         {
2409                 bool assume_unchanged = (CS(this).netname_previous == "");
2410                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2411                 {
2412                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2413                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2414                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2415                         assume_unchanged = false;
2416                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2417                 }
2418                 if (isInvisibleString(this.netname))
2419                 {
2420                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2421                         sprint(this, "Warning: invisible names are not allowed.\n");
2422                         assume_unchanged = false;
2423                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2424                 }
2425                 if (!assume_unchanged && autocvar_sv_eventlog)
2426                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2427                 strcpy(CS(this).netname_previous, this.netname);
2428         }
2429
2430         // version nagging
2431         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2432         CS(this).version_nagtime = 0;
2433         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2434             // git client
2435         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2436             // git server
2437             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2438         } else {
2439             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2440             if (r < 0) { // old client
2441                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2442             } else if (r > 0) { // old server
2443                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2444             }
2445         }
2446     }
2447
2448         // GOD MODE info
2449         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2450         {
2451                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2452                 this.max_armorvalue = 0;
2453         }
2454
2455         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2456         {
2457                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2458                 {
2459                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2460                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2461                         if (this.iceblock)
2462                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2463
2464                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2465                                 Unfreeze(this, false);
2466                 }
2467                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2468                 {
2469                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2470                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2471
2472                         if (GetResource(this, RES_HEALTH) < 1)
2473                         {
2474                                 if (this.vehicle)
2475                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2476                                 if(this.event_damage)
2477                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2478                         }
2479                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2480                                 Unfreeze(this, false);
2481                 }
2482         }
2483
2484         MUTATOR_CALLHOOK(PlayerPreThink, this);
2485
2486         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2487         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2488         {
2489                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2490                 {
2491                         if(!it.owner)
2492                         {
2493                                 if(!it.team || SAME_TEAM(this, it))
2494                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2495                                 else if(autocvar_g_vehicles_steal)
2496                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2497                         }
2498                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2499                         {
2500                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2501                         }
2502                 });
2503
2504                 this.last_vehiclecheck = time + 1;
2505         }
2506
2507         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2508         {
2509                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2510                         PlayerUseKey(this);
2511                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2512         }
2513
2514         if (IS_REAL_CLIENT(this))
2515                 PrintWelcomeMessage(this);
2516
2517         if (IS_PLAYER(this)) {
2518                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2519                         error("Client can't be spawned as player on connection!");
2520                 if(!PlayerThink(this))
2521                         return;
2522         }
2523         else if (game_stopped || intermission_running) {
2524                 if(intermission_running)
2525                         IntermissionThink(this);
2526                 return;
2527         }
2528         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2529         {
2530                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2531                 CS(this).autojoin_checked = 1;
2532                 // don't do this in ClientConnect
2533                 // many things can go wrong if a client is spawned as player on connection
2534                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2535                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2536                                 && (!teamplay || autocvar_g_balance_teams)))
2537                 {
2538                         campaign_bots_may_start = true;
2539                         if(joinAllowed(this))
2540                                 Join(this);
2541                         return;
2542                 }
2543         }
2544         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2545                 ObserverOrSpectatorThink(this);
2546         }
2547
2548         // WEAPONTODO: Add weapon request for this
2549         if (!zoomstate_set) {
2550                 bool wep_zoomed = false;
2551                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2552                 {
2553                         .entity weaponentity = weaponentities[slot];
2554                         Weapon thiswep = this.(weaponentity).m_weapon;
2555                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2556                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2557                 }
2558                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2559         }
2560
2561         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2562         {
2563                 CS(this).teamkill_soundtime = 0;
2564
2565                 entity e = CS(this).teamkill_soundsource;
2566                 entity oldpusher = e.pusher;
2567                 e.pusher = this;
2568                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2569                 e.pusher = oldpusher;
2570         }
2571
2572         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2573                 CS(this).taunt_soundtime = 0;
2574                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2575         }
2576
2577         target_voicescript_next(this);
2578 }
2579
2580 void DrownPlayer(entity this)
2581 {
2582         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2583                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2584         {
2585                 STAT(AIR_FINISHED, this) = 0;
2586                 return;
2587         }
2588
2589         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2590         {
2591                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2592                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2593                 STAT(AIR_FINISHED, this) = 0;
2594         }
2595         else
2596         {
2597                 if (!STAT(AIR_FINISHED, this))
2598                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2599                 if (STAT(AIR_FINISHED, this) < time)
2600                 {       // drown!
2601                         if (this.pain_finished < time)
2602                         {
2603                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2604                                 this.pain_finished = time + 0.5;
2605                         }
2606                 }
2607         }
2608 }
2609
2610 .bool move_qcphysics;
2611
2612 void Player_Physics(entity this)
2613 {
2614         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2615
2616         if(!this.move_qcphysics)
2617                 return;
2618
2619         if(!frametime && !CS(this).pm_frametime)
2620                 return;
2621
2622         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2623
2624         CS(this).pm_frametime = 0;
2625 }
2626
2627 /*
2628 =============
2629 PlayerPostThink
2630
2631 Called every frame for each client after the physics are run
2632 =============
2633 */
2634 void PlayerPostThink (entity this)
2635 {
2636         Player_Physics(this);
2637
2638         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2639         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2640         if (IS_REAL_CLIENT(this))
2641         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2642         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2643         {
2644                 int totalClients = 0;
2645                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2646                 {
2647                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2648                         {
2649                                 ++totalClients;
2650                         });
2651                 }
2652
2653                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2654                 { /* do nothing */ }
2655                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2656                 {
2657                         if (CS(this).idlekick_lasttimeleft)
2658                         {
2659                                 CS(this).idlekick_lasttimeleft = 0;
2660                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2661                         }
2662                 }
2663                 else
2664                 {
2665                         float maxidle_time = autocvar_sv_maxidle;
2666                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2667                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2668                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2669                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2670                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2671                         {
2672                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2673                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2674                                 else
2675                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2676                         }
2677                         if (timeleft <= 0) {
2678                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2679                                 {
2680                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2681                                         if (this.caplayer)
2682                                                 this.caplayer = 0;
2683                                         PutObserverInServer(this);
2684                                 }
2685                                 else
2686                                 {
2687                                         if (dropclient_schedule(this))
2688                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2689                                 }
2690                                 return;
2691                         }
2692                         else if (timeleft <= countdown_time) {
2693                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2694                                         play2(this, SND(TALK2));
2695                                 CS(this).idlekick_lasttimeleft = timeleft;
2696                         }
2697                 }
2698         }
2699
2700         CheatFrame(this);
2701
2702         if (game_stopped)
2703         {
2704                 this.solid = SOLID_NOT;
2705                 this.takedamage = DAMAGE_NO;
2706                 set_movetype(this, MOVETYPE_NONE);
2707                 CS(this).teamkill_complain = 0;
2708                 CS(this).teamkill_soundtime = 0;
2709                 CS(this).teamkill_soundsource = NULL;
2710         }
2711
2712         if (IS_PLAYER(this)) {
2713                 if(this.death_time == time && IS_DEAD(this))
2714                 {
2715                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2716                         // once all the damage events of this frame have been processed with normal size
2717                         this.maxs.z = 5;
2718                         setsize(this, this.mins, this.maxs);
2719                 }
2720                 DrownPlayer(this);
2721                 UpdateChatBubble(this);
2722                 if (CS(this).impulse) ImpulseCommands(this);
2723                 GetPressedKeys(this);
2724                 if (game_stopped)
2725                 {
2726                         CSQCMODEL_AUTOUPDATE(this);
2727                         return;
2728                 }
2729         }
2730         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2731         {
2732                 CS(this).pressedkeys = 0;
2733                 STAT(PRESSED_KEYS, this) = 0;
2734         }
2735
2736         if (this.waypointsprite_attachedforcarrier) {
2737                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2738                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2739         }
2740
2741         CSQCMODEL_AUTOUPDATE(this);
2742 }
2743
2744 // hack to copy the button fields from the client entity to the Client State
2745 void PM_UpdateButtons(entity this, entity store)
2746 {
2747         if(this.impulse)
2748                 store.impulse = this.impulse;
2749         this.impulse = 0;
2750
2751         bool typing = this.buttonchat || this.button12;
2752
2753         store.button0 = (typing) ? 0 : this.button0;
2754         //button1?!
2755         store.button2 = (typing) ? 0 : this.button2;
2756         store.button3 = (typing) ? 0 : this.button3;
2757         store.button4 = this.button4;
2758         store.button5 = (typing) ? 0 : this.button5;
2759         store.button6 = this.button6;
2760         store.button7 = this.button7;
2761         store.button8 = this.button8;
2762         store.button9 = this.button9;
2763         store.button10 = this.button10;
2764         store.button11 = this.button11;
2765         store.button12 = this.button12;
2766         store.button13 = this.button13;
2767         store.button14 = this.button14;
2768         store.button15 = this.button15;
2769         store.button16 = this.button16;
2770         store.buttonuse = this.buttonuse;
2771         store.buttonchat = this.buttonchat;
2772
2773         store.cursor_active = this.cursor_active;
2774         store.cursor_screen = this.cursor_screen;
2775         store.cursor_trace_start = this.cursor_trace_start;
2776         store.cursor_trace_endpos = this.cursor_trace_endpos;
2777         store.cursor_trace_ent = this.cursor_trace_ent;
2778
2779         store.ping = this.ping;
2780         store.ping_packetloss = this.ping_packetloss;
2781         store.ping_movementloss = this.ping_movementloss;
2782
2783         store.v_angle = this.v_angle;
2784         store.movement = this.movement;
2785 }
2786
2787 NET_HANDLE(fpsreport, bool)
2788 {
2789         int fps = ReadShort();
2790         PlayerScore_Set(sender, SP_FPS, fps);
2791         return true;
2792 }