qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/lms/sv_lms.qh>
  10 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  11 #include <common/items/_mod.qh>
  12 #include <common/items/inventory.qh>
  13 #include <common/mapobjects/func/conveyor.qh>
  14 #include <common/mapobjects/func/ladder.qh>
  15 #include <common/mapobjects/subs.qh>
  16 #include <common/mapobjects/target/spawnpoint.qh>
  17 #include <common/mapobjects/teleporters.qh>
  18 #include <common/mapobjects/trigger/counter.qh>
  19 #include <common/mapobjects/trigger/secret.qh>
  20 #include <common/mapobjects/trigger/swamp.qh>
  21 #include <common/mapobjects/triggers.qh>
  22 #include <common/minigames/sv_minigames.qh>
  23 #include <common/monsters/sv_monsters.qh>
  24 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  25 #include <common/mutators/mutator/nades/nades.qh>
  26 #include <common/mutators/mutator/overkill/oknex.qh>
  27 #include <common/mutators/mutator/status_effects/_mod.qh>
  28 #include <common/mutators/mutator/waypoints/all.qh>
  29 #include <common/net_linked.qh>
  30 #include <common/net_notice.qh>
  31 #include <common/notifications/all.qh>
  32 #include <common/physics/player.qh>
  33 #include <common/playerstats.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/resources.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 142
 143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 144         WriteByte(MSG_ENTITY, sf);
 145
 146         if (sf & BIT(1))
 147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 148
 149         if(sf & BIT(4))
 150         {
 151                 float specs = CountSpectators(e, to);
 152                 WriteByte(MSG_ENTITY, specs);
 153                 WriteSpectators(e, to);
 154         }
 155
 156         return true;
 157 }
 158
 159 void ClientData_Attach(entity this)
 160 {
 161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 162         CS(this).clientdata.drawonlytoclient = this;
 163         CS(this).clientdata.owner = this;
 164 }
 165
 166 void ClientData_Detach(entity this)
 167 {
 168         delete(CS(this).clientdata);
 169         CS(this).clientdata = NULL;
 170 }
 171
 172 void ClientData_Touch(entity e)
 173 {
 174         entity cd = CS(e).clientdata;
 175         if (cd) { cd.SendFlags = 1; }
 176
 177         // make it spectatable
 178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 179         {
 180                 entity cd = CS(it).clientdata;
 181                 if (cd) { cd.SendFlags = 1; }
 182         });
 183 }
 184
 185
 186 /*
 187 =============
 188 CheckPlayerModel
 189
 190 Checks if the argument string can be a valid playermodel.
 191 Returns a valid one in doubt.
 192 =============
 193 */
 194 string FallbackPlayerModel;
 195 string CheckPlayerModel(string plyermodel) {
 196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 197         {
 198                 // note: we cannot summon Don Strunzone here, some player may
 199                 // still have the model string set. In case anyone manages how
 200                 // to change a cvar default, we'll have a small leak here.
 201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 202         }
 203         // only in right path
 204         if(substring(plyermodel, 0, 14) != "models/player/")
 205                 return FallbackPlayerModel;
 206         // only good file extensions
 207         if(substring(plyermodel, -4, 4) != ".iqm"
 208                 && substring(plyermodel, -4, 4) != ".zym"
 209                 && substring(plyermodel, -4, 4) != ".dpm"
 210                 && substring(plyermodel, -4, 4) != ".md3"
 211                 && substring(plyermodel, -4, 4) != ".psk")
 212         {
 213                 return FallbackPlayerModel;
 214         }
 215         // forbid the LOD models
 216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 217                 return FallbackPlayerModel;
 218         if(plyermodel != strtolower(plyermodel))
 219                 return FallbackPlayerModel;
 220         // also, restrict to server models
 221         if(autocvar_sv_servermodelsonly)
 222         {
 223                 if(!fexists(plyermodel))
 224                         return FallbackPlayerModel;
 225         }
 226         return plyermodel;
 227 }
 228
 229 void setplayermodel(entity e, string modelname)
 230 {
 231         precache_model(modelname);
 232         _setmodel(e, modelname);
 233         player_setupanimsformodel(e);
 234         if(!autocvar_g_debug_globalsounds)
 235                 UpdatePlayerSounds(e);
 236 }
 237
 238 /** putting a client as observer in the server */
 239 void PutObserverInServer(entity this)
 240 {
 241         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         ReadyCount();
 257                 }
 258                 entcs_update_players(this);
 259         }
 260
 261         entity spot = SelectSpawnPoint(this, true);
 262         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 263         this.angles = vec2(spot.angles);
 264         this.fixangle = true;
 265         // offset it so that the spectator spawns higher off the ground, looks better this way
 266         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 267         if (IS_REAL_CLIENT(this))
 268         {
 269                 msg_entity = this;
 270                 WriteByte(MSG_ONE, SVC_SETVIEW);
 271                 WriteEntity(MSG_ONE, this);
 272         }
 273         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 274         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 275         if(!autocvar_g_debug_globalsounds)
 276         {
 277                 // needed for player sounds
 278                 this.model = "";
 279                 FixPlayermodel(this);
 280         }
 281         setmodel(this, MDL_Null);
 282         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 283         this.view_ofs = '0 0 0';
 284
 285         RemoveGrapplingHooks(this);
 286         Portal_ClearAll(this);
 287         Unfreeze(this, false);
 288         SetSpectatee(this, NULL);
 289
 290         if (this.alivetime)
 291         {
 292                 if (!warmup_stage)
 293                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 294                 this.alivetime = 0;
 295         }
 296
 297         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 298
 299         WaypointSprite_PlayerDead(this);
 300
 301         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 302                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 303
 304         accuracy_resend(this);
 305
 306         CS(this).spectatortime = time;
 307         if(this.bot_attack)
 308                 IL_REMOVE(g_bot_targets, this);
 309         this.bot_attack = false;
 310         if(this.monster_attack)
 311                 IL_REMOVE(g_monster_targets, this);
 312         this.monster_attack = false;
 313         STAT(HUD, this) = HUD_NORMAL;
 314         TRANSMUTE(Observer, this);
 315         this.iscreature = false;
 316         this.teleportable = TELEPORT_SIMPLE;
 317         if(this.damagedbycontents)
 318                 IL_REMOVE(g_damagedbycontents, this);
 319         this.damagedbycontents = false;
 320         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 321         SetSpectatee_status(this, etof(this));
 322         this.takedamage = DAMAGE_NO;
 323         this.solid = SOLID_NOT;
 324         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 325         this.flags = FL_CLIENT | FL_NOTARGET;
 326         this.effects = 0;
 327         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 328         this.pauserotarmor_finished = 0;
 329         this.pauserothealth_finished = 0;
 330         this.pauseregen_finished = 0;
 331         this.damageforcescale = 0;
 332         this.death_time = 0;
 333         this.respawn_flags = 0;
 334         this.respawn_time = 0;
 335         STAT(RESPAWN_TIME, this) = 0;
 336         this.alpha = 0;
 337         this.scale = 0;
 338         this.fade_time = 0;
 339         this.pain_finished = 0;
 340         STAT(AIR_FINISHED, this) = 0;
 341         //this.dphitcontentsmask = 0;
 342         this.dphitcontentsmask = DPCONTENTS_SOLID;
 343         if (autocvar_g_playerclip_collisions)
 344                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 345         this.pushltime = 0;
 346         this.istypefrag = 0;
 347         setthink(this, func_null);
 348         this.nextthink = 0;
 349         this.deadflag = DEAD_NO;
 350         UNSET_DUCKED(this);
 351         STAT(REVIVE_PROGRESS, this) = 0;
 352         this.revival_time = 0;
 353         this.draggable = drag_undraggable;
 354
 355         this.items = 0;
 356         STAT(WEAPONS, this) = '0 0 0';
 357         this.drawonlytoclient = this;
 358
 359         this.viewloc = NULL;
 360
 361         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 362
 363         this.weaponmodel = "";
 364         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         {
 366                 this.weaponentities[slot] = NULL;
 367         }
 368         this.exteriorweaponentity = NULL;
 369         CS(this).killcount = FRAGS_SPECTATOR;
 370         this.velocity = '0 0 0';
 371         this.avelocity = '0 0 0';
 372         this.punchangle = '0 0 0';
 373         this.punchvector = '0 0 0';
 374         this.oldvelocity = this.velocity;
 375         this.event_damage = func_null;
 376         this.event_heal = func_null;
 377
 378         for(int slot = 0; slot < MAX_AXH; ++slot)
 379         {
 380                 entity axh = this.(AuxiliaryXhair[slot]);
 381                 this.(AuxiliaryXhair[slot]) = NULL;
 382
 383                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 384                         delete(axh);
 385         }
 386
 387         if (mutator_returnvalue)
 388         {
 389                 // mutator prevents resetting teams+score
 390         }
 391         else
 392         {
 393                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 394                 this.frags = FRAGS_SPECTATOR;
 395         }
 396
 397         bot_relinkplayerlist();
 398
 399         if (CS(this).just_joined)
 400                 CS(this).just_joined = false;
 401 }
 402
 403 int player_getspecies(entity this)
 404 {
 405         get_model_parameters(this.model, this.skin);
 406         int s = get_model_parameters_species;
 407         get_model_parameters(string_null, 0);
 408         if (s < 0) return SPECIES_HUMAN;
 409         return s;
 410 }
 411
 412 .float model_randomizer;
 413 void FixPlayermodel(entity player)
 414 {
 415         string defaultmodel = "";
 416         int defaultskin = 0;
 417         if(autocvar_sv_defaultcharacter)
 418         {
 419                 if(teamplay)
 420                 {
 421                         switch(player.team)
 422                         {
 423                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 424                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 425                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 426                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 427                         }
 428                 }
 429
 430                 if(defaultmodel == "")
 431                 {
 432                         defaultmodel = autocvar_sv_defaultplayermodel;
 433                         defaultskin = autocvar_sv_defaultplayerskin;
 434                 }
 435
 436                 int n = tokenize_console(defaultmodel);
 437                 if(n > 0)
 438                 {
 439                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 440                         // However, do NOT randomize if the player-selected model is in the list.
 441                         for (int i = 0; i < n; ++i)
 442                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 443                                         defaultmodel = argv(i);
 444                 }
 445
 446                 int i = strstrofs(defaultmodel, ":", 0);
 447                 if(i >= 0)
 448                 {
 449                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 450                         defaultmodel = substring(defaultmodel, 0, i);
 451                 }
 452         }
 453         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 454         {
 455                 if(teamplay)
 456                 {
 457                         switch(player.team)
 458                         {
 459                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 460                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 461                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 462                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 463                         }
 464                 }
 465
 466                 if(!defaultskin)
 467                         defaultskin = autocvar_sv_defaultplayerskin;
 468         }
 469
 470         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 471         defaultmodel = M_ARGV(0, string);
 472         defaultskin = M_ARGV(1, int);
 473
 474         bool chmdl = false;
 475         int oldskin;
 476         if(defaultmodel != "")
 477         {
 478                 if (defaultmodel != player.model)
 479                 {
 480                         vector m1 = player.mins;
 481                         vector m2 = player.maxs;
 482                         setplayermodel (player, defaultmodel);
 483                         setsize (player, m1, m2);
 484                         chmdl = true;
 485                 }
 486
 487                 oldskin = player.skin;
 488                 player.skin = defaultskin;
 489         } else {
 490                 if (player.playermodel != player.model || player.playermodel == "")
 491                 {
 492                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 493                         vector m1 = player.mins;
 494                         vector m2 = player.maxs;
 495                         setplayermodel (player, player.playermodel);
 496                         setsize (player, m1, m2);
 497                         chmdl = true;
 498                 }
 499
 500                 if(!autocvar_sv_defaultcharacterskin)
 501                 {
 502                         oldskin = player.skin;
 503                         player.skin = stof(player.playerskin);
 504                 }
 505                 else
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = defaultskin;
 509                 }
 510         }
 511
 512         if(chmdl || oldskin != player.skin) // model or skin has changed
 513         {
 514                 player.species = player_getspecies(player); // update species
 515                 if(!autocvar_g_debug_globalsounds)
 516                         UpdatePlayerSounds(player); // update skin sounds
 517         }
 518
 519         if(!teamplay)
 520                 if(strlen(autocvar_sv_defaultplayercolors))
 521                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 522                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 523 }
 524
 525 void PutPlayerInServer(entity this)
 526 {
 527         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 528
 529         PlayerState_attach(this);
 530         accuracy_resend(this);
 531
 532         if (this.team < 0)
 533                 TeamBalance_JoinBestTeam(this);
 534
 535         entity spot = SelectSpawnPoint(this, false);
 536         if (!spot) {
 537                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 538                 return; // spawn failed
 539         }
 540
 541         TRANSMUTE(Player, this);
 542
 543         CS(this).wasplayer = true;
 544         this.iscreature = true;
 545         this.teleportable = TELEPORT_NORMAL;
 546         if(!this.damagedbycontents)
 547                 IL_PUSH(g_damagedbycontents, this);
 548         this.damagedbycontents = true;
 549         set_movetype(this, MOVETYPE_WALK);
 550         this.solid = SOLID_SLIDEBOX;
 551         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 552         if (autocvar_g_playerclip_collisions)
 553                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 554         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 555                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 556         this.frags = FRAGS_PLAYER;
 557         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 558         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 559         if (autocvar__notarget)
 560                 this.flags |= FL_NOTARGET;
 561         this.takedamage = DAMAGE_AIM;
 562         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 563
 564         if (warmup_stage) {
 565                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 566                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 567                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 568                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 569                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 570                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 571                 SetResource(this, RES_HEALTH, warmup_start_health);
 572                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 573                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 574         } else {
 575                 SetResource(this, RES_SHELLS, start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, start_health);
 582                 SetResource(this, RES_ARMOR, start_armorvalue);
 583                 STAT(WEAPONS, this) = start_weapons;
 584                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 585                 {
 586                         GiveRandomWeapons(this, random_start_weapons_count,
 587                                 autocvar_g_random_start_weapons, random_start_ammo);
 588                 }
 589         }
 590         SetSpectatee_status(this, 0);
 591
 592         PS(this).dual_weapons = '0 0 0';
 593
 594         this.items = start_items;
 595
 596         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 597         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 598         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 599         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 600         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 601         if (!sv_ready_restart_after_countdown && time < game_starttime)
 602         {
 603                 float f = game_starttime - time;
 604                 this.spawnshieldtime += f;
 605                 this.pauserotarmor_finished += f;
 606                 this.pauserothealth_finished += f;
 607                 this.pauseregen_finished += f;
 608         }
 609
 610         this.damageforcescale = autocvar_g_player_damageforcescale;
 611         this.death_time = 0;
 612         this.respawn_flags = 0;
 613         this.respawn_time = 0;
 614         STAT(RESPAWN_TIME, this) = 0;
 615         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 616         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 617         this.fade_time = 0;
 618         this.pain_finished = 0;
 619         this.pushltime = 0;
 620         setthink(this, func_null); // players have no think function
 621         this.nextthink = 0;
 622         this.dmg_team = 0;
 623         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 624
 625         this.deadflag = DEAD_NO;
 626
 627         this.angles = spot.angles;
 628         this.angles_z = 0; // never spawn tilted even if the spot says to
 629         if (IS_BOT_CLIENT(this))
 630         {
 631                 this.v_angle = this.angles;
 632                 bot_aim_reset(this);
 633         }
 634         this.fixangle = true; // turn this way immediately
 635         this.oldvelocity = this.velocity = '0 0 0';
 636         this.avelocity = '0 0 0';
 637         this.punchangle = '0 0 0';
 638         this.punchvector = '0 0 0';
 639
 640         STAT(REVIVE_PROGRESS, this) = 0;
 641         this.revival_time = 0;
 642
 643         STAT(AIR_FINISHED, this) = 0;
 644         this.waterlevel = WATERLEVEL_NONE;
 645         this.watertype = CONTENT_EMPTY;
 646
 647         entity spawnevent = new_pure(spawnevent);
 648         spawnevent.owner = this;
 649         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 650
 651         // Cut off any still running player sounds.
 652         stopsound(this, CH_PLAYER_SINGLE);
 653
 654         this.model = "";
 655         FixPlayermodel(this);
 656         this.drawonlytoclient = NULL;
 657
 658         this.viewloc = NULL;
 659
 660         for(int slot = 0; slot < MAX_AXH; ++slot)
 661         {
 662                 entity axh = this.(AuxiliaryXhair[slot]);
 663                 this.(AuxiliaryXhair[slot]) = NULL;
 664
 665                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 666                         delete(axh);
 667         }
 668
 669         this.spawnpoint_targ = NULL;
 670
 671         UNSET_DUCKED(this);
 672         this.view_ofs = STAT(PL_VIEW_OFS, this);
 673         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 674         this.spawnorigin = spot.origin;
 675         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 676         // don't reset back to last position, even if new position is stuck in solid
 677         this.oldorigin = this.origin;
 678         if(this.conveyor)
 679                 IL_REMOVE(g_conveyed, this);
 680         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 681         if(this.swampslug)
 682                 IL_REMOVE(g_swamped, this);
 683         this.swampslug = NULL;
 684         this.swamp_interval = 0;
 685         if(this.ladder_entity)
 686                 IL_REMOVE(g_ladderents, this);
 687         this.ladder_entity = NULL;
 688         IL_EACH(g_counters, it.realowner == this,
 689         {
 690                 delete(it);
 691         });
 692         STAT(HUD, this) = HUD_NORMAL;
 693
 694         this.event_damage = PlayerDamage;
 695         this.event_heal = PlayerHeal;
 696
 697         this.draggable = func_null;
 698
 699         if(!this.bot_attack)
 700                 IL_PUSH(g_bot_targets, this);
 701         this.bot_attack = true;
 702         if(!this.monster_attack)
 703                 IL_PUSH(g_monster_targets, this);
 704         this.monster_attack = true;
 705         navigation_dynamicgoal_init(this, false);
 706
 707         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 708
 709         // player was spectator
 710         if (CS(this).killcount == FRAGS_SPECTATOR) {
 711                 PlayerScore_Clear(this);
 712                 CS(this).killcount = 0;
 713                 CS(this).startplaytime = time;
 714         }
 715
 716         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 717         {
 718                 .entity weaponentity = weaponentities[slot];
 719                 CL_SpawnWeaponentity(this, weaponentity);
 720         }
 721         this.alpha = default_player_alpha;
 722         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 723         this.exteriorweaponentity.alpha = default_weapon_alpha;
 724
 725         this.speedrunning = false;
 726
 727         this.counter_cnt = 0;
 728         this.fragsfilter_cnt = 0;
 729
 730         target_voicescript_clear(this);
 731
 732         // reset fields the weapons may use
 733         FOREACH(Weapons, true, {
 734                 it.wr_resetplayer(it, this);
 735                         // reload all reloadable weapons
 736                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 737                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 738                         {
 739                                 .entity weaponentity = weaponentities[slot];
 740                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 741                         }
 742                 }
 743         });
 744
 745         Unfreeze(this, false);
 746
 747         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 748
 749         {
 750                 string s = spot.target;
 751                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 752                         spot.target = string_null;
 753                 SUB_UseTargets(spot, this, NULL);
 754                 if(g_assault || g_race)
 755                         spot.target = s;
 756         }
 757
 758         if (autocvar_spawn_debug)
 759         {
 760                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 761                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 762         }
 763
 764         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 765         {
 766                 .entity weaponentity = weaponentities[slot];
 767                 entity w_ent = this.(weaponentity);
 768                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 769                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 770                 else
 771                         w_ent.m_switchweapon = WEP_Null;
 772                 w_ent.m_weapon = WEP_Null;
 773                 w_ent.weaponname = "";
 774                 w_ent.m_switchingweapon = WEP_Null;
 775                 w_ent.cnt = -1;
 776         }
 777
 778         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 779
 780         if (CS(this).impulse) ImpulseCommands(this);
 781
 782         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 783         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 784         {
 785                 .entity weaponentity = weaponentities[slot];
 786                 W_WeaponFrame(this, weaponentity);
 787         }
 788
 789         if (!warmup_stage && !this.alivetime)
 790                 this.alivetime = time;
 791
 792         antilag_clear(this, CS(this));
 793 }
 794
 795 /** Called when a client spawns in the server */
 796 void PutClientInServer(entity this)
 797 {
 798         if (IS_BOT_CLIENT(this)) {
 799                 TRANSMUTE(Player, this);
 800         } else if (IS_REAL_CLIENT(this)) {
 801                 msg_entity = this;
 802                 WriteByte(MSG_ONE, SVC_SETVIEW);
 803                 WriteEntity(MSG_ONE, this);
 804         }
 805         if (game_stopped)
 806                 TRANSMUTE(Observer, this);
 807
 808         SetSpectatee(this, NULL);
 809
 810         // reset player keys
 811         if(PS(this))
 812                 PS(this).itemkeys = 0;
 813
 814         MUTATOR_CALLHOOK(PutClientInServer, this);
 815
 816         if (IS_OBSERVER(this)) {
 817                 PutObserverInServer(this);
 818         } else if (IS_PLAYER(this)) {
 819                 PutPlayerInServer(this);
 820         }
 821
 822         bot_relinkplayerlist();
 823 }
 824
 825 // TODO do we need all these fields, or should we stop autodetecting runtime
 826 // changes and just have a console command to update this?
 827 bool ClientInit_SendEntity(entity this, entity to, int sf)
 828 {
 829         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 830         return = true;
 831         msg_entity = to;
 832         // MSG_INIT replacement
 833         // TODO: make easier to use
 834         Registry_send_all();
 835         W_PROP_reload(MSG_ONE, to);
 836         ClientInit_misc(this);
 837         MUTATOR_CALLHOOK(Ent_Init);
 838 }
 839 void ClientInit_misc(entity this)
 840 {
 841         int channel = MSG_ONE;
 842         WriteHeader(channel, ENT_CLIENT_INIT);
 843         WriteByte(channel, g_nexball_meter_period * 32);
 844         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 845         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 846         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 847         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 848         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 849         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 850         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 851         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 852
 853         if(autocvar_sv_foginterval && world.fog != "")
 854                 WriteString(channel, world.fog);
 855         else
 856                 WriteString(channel, "");
 857         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 858         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 859         WriteByte(channel, serverflags);
 860         WriteCoord(channel, autocvar_g_trueaim_minrange);
 861 }
 862
 863 void ClientInit_CheckUpdate(entity this)
 864 {
 865         this.nextthink = time;
 866         if(this.count != autocvar_g_balance_armor_blockpercent)
 867         {
 868                 this.count = autocvar_g_balance_armor_blockpercent;
 869                 this.SendFlags |= 1;
 870         }
 871         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 872         {
 873                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 874                 this.SendFlags |= 1;
 875         }
 876 }
 877
 878 void ClientInit_Spawn()
 879 {
 880         entity e = new_pure(clientinit);
 881         setthink(e, ClientInit_CheckUpdate);
 882         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 883
 884         ClientInit_CheckUpdate(e);
 885 }
 886
 887 /*
 888 =============
 889 SetNewParms
 890 =============
 891 */
 892 void SetNewParms ()
 893 {
 894         // initialize parms for a new player
 895         parm1 = -(86400 * 366);
 896
 897         MUTATOR_CALLHOOK(SetNewParms);
 898 }
 899
 900 /*
 901 =============
 902 SetChangeParms
 903 =============
 904 */
 905 void SetChangeParms (entity this)
 906 {
 907         // save parms for level change
 908         parm1 = CS(this).parm_idlesince - time;
 909
 910         MUTATOR_CALLHOOK(SetChangeParms);
 911 }
 912
 913 /*
 914 =============
 915 DecodeLevelParms
 916 =============
 917 */
 918 void DecodeLevelParms(entity this)
 919 {
 920         // load parms
 921         CS(this).parm_idlesince = parm1;
 922         if (CS(this).parm_idlesince == -(86400 * 366))
 923                 CS(this).parm_idlesince = time;
 924
 925         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 926         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 927
 928         MUTATOR_CALLHOOK(DecodeLevelParms);
 929 }
 930
 931 void FixClientCvars(entity e)
 932 {
 933         // send prediction settings to the client
 934         stuffcmd(e, "\nin_bindmap 0 0\n");
 935         if(autocvar_g_antilag == 3) // client side hitscan
 936                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 937         if(autocvar_sv_gentle)
 938                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 939
 940         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 941         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 942
 943         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 944
 945         MUTATOR_CALLHOOK(FixClientCvars, e);
 946 }
 947
 948 bool findinlist_abbrev(string tofind, string list)
 949 {
 950         if(list == "" || tofind == "")
 951                 return false; // empty list or search, just return
 952
 953         // this function allows abbreviated strings!
 954         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 955         {
 956                 return true;
 957         });
 958
 959         return false;
 960 }
 961
 962 bool PlayerInIPList(entity p, string iplist)
 963 {
 964         // some safety checks (never allow local?)
 965         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 966                 return false;
 967
 968         return findinlist_abbrev(p.netaddress, iplist);
 969 }
 970
 971 bool PlayerInIDList(entity p, string idlist)
 972 {
 973         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 974         if(!p.crypto_idfp)
 975                 return false;
 976
 977         return findinlist_abbrev(p.crypto_idfp, idlist);
 978 }
 979
 980 bool PlayerInList(entity player, string list)
 981 {
 982         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 983 }
 984
 985 #ifdef DP_EXT_PRECONNECT
 986 /*
 987 =============
 988 ClientPreConnect
 989
 990 Called once (not at each match start) when a client begins a connection to the server
 991 =============
 992 */
 993 void ClientPreConnect(entity this)
 994 {
 995         if(autocvar_sv_eventlog)
 996         {
 997                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 998                         this.playerid,
 999                         etof(this),
1000                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1001                 ));
1002         }
1003 }
1004 #endif
1005
1006 string GetClientVersionMessage(entity this)
1007 {
1008         if (CS(this).version_mismatch) {
1009                 if(CS(this).version < autocvar_gameversion) {
1010                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1011                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1012                 } else {
1013                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1014                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1015                 }
1016         } else {
1017                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1018         }
1019 }
1020
1021 string getwelcomemessage(entity this)
1022 {
1023         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1024         string modifications = M_ARGV(0, string);
1025
1026         if(g_weaponarena)
1027         {
1028                 if(g_weaponarena_random)
1029                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1030                 else
1031                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1032         }
1033         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1034                 modifications = strcat(modifications, ", No start weapons");
1035         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1036                 modifications = strcat(modifications, ", Low gravity");
1037         if(g_weapon_stay && !g_cts)
1038                 modifications = strcat(modifications, ", Weapons stay");
1039         if(autocvar_g_jetpack)
1040                 modifications = strcat(modifications, ", Jet pack");
1041         if(autocvar_g_powerups == 0)
1042                 modifications = strcat(modifications, ", No powerups");
1043         if(autocvar_g_powerups > 0)
1044                 modifications = strcat(modifications, ", Powerups");
1045         modifications = substring(modifications, 2, strlen(modifications) - 2);
1046
1047         string versionmessage = GetClientVersionMessage(this);
1048         string s = strcat(versionmessage, "^8\n^8\nserver is ^9", autocvar_hostname, "^8\n");
1049
1050         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1051
1052         if(modifications != "")
1053                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1054
1055         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1056         {
1057                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1058                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1059         }
1060
1061         if (cache_mutatormsg != "") {
1062                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1063         }
1064
1065         string mutator_msg = "";
1066         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1067         mutator_msg = M_ARGV(0, string);
1068
1069         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1070
1071         string motd = autocvar_sv_motd;
1072         if (motd != "") {
1073                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1074         }
1075         return s;
1076 }
1077
1078 /**
1079 =============
1080 ClientConnect
1081
1082 Called when a client connects to the server
1083 =============
1084 */
1085 void ClientConnect(entity this)
1086 {
1087         if (Ban_MaybeEnforceBanOnce(this)) return;
1088         assert(!IS_CLIENT(this), return);
1089         this.flags |= FL_CLIENT;
1090         assert(player_count >= 0, player_count = 0);
1091
1092         TRANSMUTE(Client, this);
1093         CS(this).version_nagtime = time + 10 + random() * 10;
1094
1095         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1096
1097         bot_clientconnect(this);
1098
1099         Player_DetermineForcedTeam(this);
1100
1101         TRANSMUTE(Observer, this);
1102
1103         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1104
1105         // always track bots, don't ask for cl_allow_uidtracking
1106         if (IS_BOT_CLIENT(this))
1107                 PlayerStats_GameReport_AddPlayer(this);
1108         else
1109                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1110
1111         if (autocvar_sv_eventlog)
1112                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1113
1114         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1115
1116         stuffcmd(this, clientstuff, "\n");
1117         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1118
1119         FixClientCvars(this);
1120
1121         // get version info from player
1122         stuffcmd(this, "cmd clientversion $gameversion\n");
1123
1124         // notify about available teams
1125         if (teamplay)
1126         {
1127                 entity balance = TeamBalance_CheckAllowedTeams(this);
1128                 int t = TeamBalance_GetAllowedTeams(balance);
1129                 TeamBalance_Destroy(balance);
1130                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1131         }
1132         else
1133         {
1134                 stuffcmd(this, "set _teams_available 0\n");
1135         }
1136
1137         bot_relinkplayerlist();
1138
1139         CS(this).spectatortime = time;
1140         if (blockSpectators)
1141         {
1142                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1143         }
1144
1145         CS(this).jointime = time;
1146
1147         if (IS_REAL_CLIENT(this))
1148         {
1149                 if (g_weaponarena_weapons == WEPSET(TUBA))
1150                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1151         }
1152
1153         if (!autocvar_sv_foginterval && world.fog != "")
1154                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1155
1156         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1157                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1158                         send_CSQC_teamnagger();
1159
1160         CSQCMODEL_AUTOINIT(this);
1161
1162         CS(this).model_randomizer = random();
1163
1164         if (IS_REAL_CLIENT(this))
1165                 sv_notice_join(this);
1166
1167         this.move_qcphysics = autocvar_sv_qcphysics;
1168
1169         // update physics stats (players can spawn before physics runs)
1170         Physics_UpdateStats(this);
1171
1172         IL_EACH(g_initforplayer, it.init_for_player, {
1173                 it.init_for_player(it, this);
1174         });
1175
1176         Handicap_Initialize(this);
1177
1178         MUTATOR_CALLHOOK(ClientConnect, this);
1179
1180         if (IS_REAL_CLIENT(this))
1181         {
1182                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1183                 {
1184                         CS(this).motd_actived_time = -1;
1185                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1186                 }
1187         }
1188 }
1189 /*
1190 =============
1191 ClientDisconnect
1192
1193 Called when a client disconnects from the server
1194 =============
1195 */
1196 .entity chatbubbleentity;
1197 void player_powerups_remove_all(entity this);
1198
1199 void ClientDisconnect(entity this)
1200 {
1201         assert(IS_CLIENT(this), return);
1202
1203         PlayerStats_GameReport_FinalizePlayer(this);
1204         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1205         if (CS(this).active_minigame) part_minigame(this);
1206         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1207
1208         if (autocvar_sv_eventlog)
1209                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1210
1211         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1212
1213         if(IS_SPEC(this))
1214                 SetSpectatee(this, NULL);
1215
1216         MUTATOR_CALLHOOK(ClientDisconnect, this);
1217
1218         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1219         strfree(CS_CVAR(this).weaponorder_byimpulse);
1220         ClientState_detach(this);
1221
1222         Portal_ClearAll(this);
1223
1224         Unfreeze(this, false);
1225
1226         RemoveGrapplingHooks(this);
1227
1228         // Here, everything has been done that requires this player to be a client.
1229
1230         this.flags &= ~FL_CLIENT;
1231
1232         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1233         if (this.killindicator) delete(this.killindicator);
1234
1235         IL_EACH(g_counters, it.realowner == this,
1236         {
1237                 delete(it);
1238         });
1239
1240         WaypointSprite_PlayerGone(this);
1241
1242         bot_relinkplayerlist();
1243
1244         strfree(this.clientstatus);
1245         if (this.personal) delete(this.personal);
1246
1247         this.playerid = 0;
1248         ReadyCount();
1249         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1250
1251         player_powerups_remove_all(this); // stop powerup sound
1252
1253         ONREMOVE(this);
1254 }
1255
1256 void ChatBubbleThink(entity this)
1257 {
1258         this.nextthink = time;
1259         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1260         {
1261                 if(this.owner) // but why can that ever be NULL?
1262                         this.owner.chatbubbleentity = NULL;
1263                 delete(this);
1264                 return;
1265         }
1266
1267         this.mdl = "";
1268
1269         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1270         {
1271                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1272                         this.mdl = "models/sprites/minigame_busy.iqm";
1273                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1274                         this.mdl = "models/misc/chatbubble.spr";
1275         }
1276
1277         if ( this.model != this.mdl )
1278                 _setmodel(this, this.mdl);
1279
1280 }
1281
1282 void UpdateChatBubble(entity this)
1283 {
1284         if (this.alpha < 0)
1285                 return;
1286         // spawn a chatbubble entity if needed
1287         if (!this.chatbubbleentity)
1288         {
1289                 this.chatbubbleentity = new(chatbubbleentity);
1290                 this.chatbubbleentity.owner = this;
1291                 this.chatbubbleentity.exteriormodeltoclient = this;
1292                 setthink(this.chatbubbleentity, ChatBubbleThink);
1293                 this.chatbubbleentity.nextthink = time;
1294                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1295                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1296                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1297                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1298                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1299                 //this.chatbubbleentity.model = "";
1300                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1301         }
1302 }
1303
1304 void calculate_player_respawn_time(entity this)
1305 {
1306         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1307                 return;
1308
1309         float gametype_setting_tmp;
1310         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1311         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1312         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1313         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1314         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1315         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1316
1317         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1318         if (teamplay)
1319         {
1320                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1321                         if(it.team == this.team)
1322                                 ++pcount;
1323                 });
1324                 if (sdelay_small_count == 0)
1325                         sdelay_small_count = 1;
1326                 if (sdelay_large_count == 0)
1327                         sdelay_large_count = 1;
1328         }
1329         else
1330         {
1331                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1332                         ++pcount;
1333                 });
1334                 if (sdelay_small_count == 0)
1335                 {
1336                         if (IS_INDEPENDENT_PLAYER(this))
1337                         {
1338                                 // Players play independently. No point in requiring enemies.
1339                                 sdelay_small_count = 1;
1340                         }
1341                         else
1342                         {
1343                                 // Players play AGAINST each other. Enemies required.
1344                                 sdelay_small_count = 2;
1345                         }
1346                 }
1347                 if (sdelay_large_count == 0)
1348                 {
1349                         if (IS_INDEPENDENT_PLAYER(this))
1350                         {
1351                                 // Players play independently. No point in requiring enemies.
1352                                 sdelay_large_count = 1;
1353                         }
1354                         else
1355                         {
1356                                 // Players play AGAINST each other. Enemies required.
1357                                 sdelay_large_count = 2;
1358                         }
1359                 }
1360         }
1361
1362         float sdelay;
1363
1364         if (pcount <= sdelay_small_count)
1365                 sdelay = sdelay_small;
1366         else if (pcount >= sdelay_large_count)
1367                 sdelay = sdelay_large;
1368         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1369                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1370
1371         if(waves)
1372                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1373         else
1374                 this.respawn_time = time + sdelay;
1375
1376         if(sdelay < sdelay_max)
1377                 this.respawn_time_max = time + sdelay_max;
1378         else
1379                 this.respawn_time_max = this.respawn_time;
1380
1381         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1382                 this.respawn_countdown = 10; // first number to count down from is 10
1383         else
1384                 this.respawn_countdown = -1; // do not count down
1385
1386         if(autocvar_g_forced_respawn)
1387                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1388 }
1389
1390 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1391 // added to the model skins
1392 /*void UpdateColorModHack()
1393 {
1394         float c;
1395         c = this.clientcolors & 15;
1396         // LordHavoc: only bothering to support white, green, red, yellow, blue
1397              if (!teamplay) this.colormod = '0 0 0';
1398         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1399         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1400         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1401         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1402         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1403         else this.colormod = '1 1 1';
1404 }*/
1405
1406 void respawn(entity this)
1407 {
1408         bool damagedbycontents_prev = this.damagedbycontents;
1409         if(this.alpha >= 0)
1410         {
1411                 if(autocvar_g_respawn_ghosts)
1412                 {
1413                         this.solid = SOLID_NOT;
1414                         this.takedamage = DAMAGE_NO;
1415                         this.damagedbycontents = false;
1416                         set_movetype(this, MOVETYPE_FLY);
1417                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1418                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1419                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1420                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1421                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1422                         if(autocvar_g_respawn_ghosts_time > 0)
1423                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1424                 }
1425                 else
1426                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1427         }
1428
1429         CopyBody(this, 1);
1430         this.damagedbycontents = damagedbycontents_prev;
1431
1432         this.effects |= EF_NODRAW; // prevent another CopyBody
1433         PutClientInServer(this);
1434 }
1435
1436 void play_countdown(entity this, float finished, Sound samp)
1437 {
1438         TC(Sound, samp);
1439         if(IS_REAL_CLIENT(this))
1440                 if(floor(finished - time - frametime) != floor(finished - time))
1441                         if(finished - time < 6)
1442                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1443 }
1444
1445 void player_powerups_remove_all(entity this)
1446 {
1447         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1448         {
1449                 // don't play the poweroff sound when the game restarts or the player disconnects
1450                 if (time > game_starttime + 1 && IS_CLIENT(this))
1451                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1452                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1453                 this.items &= ~ITEM_Strength.m_itemid;
1454                 this.items &= ~ITEM_Shield.m_itemid;
1455                 this.items -= (this.items & IT_SUPERWEAPON);
1456         }
1457 }
1458
1459 void player_powerups(entity this)
1460 {
1461         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1462                 this.modelflags |= MF_ROCKET;
1463         else
1464                 this.modelflags &= ~MF_ROCKET;
1465
1466         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_NODEPTHTEST);
1467
1468         if (IS_DEAD(this))
1469                 player_powerups_remove_all(this);
1470
1471         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1472                 return;
1473
1474         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1475         int items_prev = this.items;
1476
1477         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1478         {
1479                 if (this.items & ITEM_Strength.m_itemid)
1480                 {
1481                         play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Strength, this), SND_POWEROFF);
1482                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1483                         if (time > StatusEffects_gettime(STATUSEFFECT_Strength, this))
1484                         {
1485                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1486                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1487                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1488                         }
1489                 }
1490                 else
1491                 {
1492                         if (time < StatusEffects_gettime(STATUSEFFECT_Strength, this))
1493                         {
1494                                 this.items = this.items | ITEM_Strength.m_itemid;
1495                                 if(!g_cts)
1496                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1497                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1498                         }
1499                 }
1500                 if (this.items & ITEM_Shield.m_itemid)
1501                 {
1502                         play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Shield, this), SND_POWEROFF);
1503                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1504                         if (time > StatusEffects_gettime(STATUSEFFECT_Shield, this))
1505                         {
1506                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1507                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1508                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1509                         }
1510                 }
1511                 else
1512                 {
1513                         if (time < StatusEffects_gettime(STATUSEFFECT_Shield, this))
1514                         {
1515                                 this.items = this.items | ITEM_Shield.m_itemid;
1516                                 if(!g_cts)
1517                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1518                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1519                         }
1520                 }
1521                 if (this.items & IT_SUPERWEAPON)
1522                 {
1523                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1524                         {
1525                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1526                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1527                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1528                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1529                         }
1530                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1531                         {
1532                                 // don't let them run out
1533                         }
1534                         else
1535                         {
1536                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1537                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1538                                 {
1539                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1540                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1541                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1542                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1543                                 }
1544                         }
1545                 }
1546                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1547                 {
1548                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1549                         {
1550                                 this.items = this.items | IT_SUPERWEAPON;
1551                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1552                                 {
1553                                         if(!g_cts)
1554                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1555                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1556                                 }
1557                         }
1558                         else
1559                         {
1560                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1561                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1562                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1563                         }
1564                 }
1565                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1566                 {
1567                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1568                 }
1569         }
1570
1571         if(autocvar_g_nodepthtestplayers)
1572                 this.effects = this.effects | EF_NODEPTHTEST;
1573
1574         if(autocvar_g_fullbrightplayers)
1575                 this.effects = this.effects | EF_FULLBRIGHT;
1576
1577         if (time >= game_starttime)
1578         if (time < this.spawnshieldtime)
1579                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1580
1581         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1582 }
1583
1584 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1585 {
1586         if(current > stable)
1587                 return current;
1588         else if(current > stable - 0.25) // when close enough, "snap"
1589                 return stable;
1590         else
1591                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1592 }
1593
1594 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1595 {
1596         if(current < stable)
1597                 return current;
1598         else if(current < stable + 0.25) // when close enough, "snap"
1599                 return stable;
1600         else
1601                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1602 }
1603
1604 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1605 {
1606         float old = GetResource(this, res);
1607         float current = old;
1608         if(current > rotstable)
1609         {
1610                 if(rotframetime > 0)
1611                 {
1612                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1613                         current = max(rotstable, current - rotlinear * rotframetime);
1614                 }
1615         }
1616         else if(current < regenstable)
1617         {
1618                 if(regenframetime > 0)
1619                 {
1620                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1621                         current = min(regenstable, current + regenlinear * regenframetime);
1622                 }
1623         }
1624
1625         float limit = GetResourceLimit(this, res) * limit_mod;
1626         if(current > limit)
1627                 current = limit;
1628
1629         if (current != old)
1630                 SetResource(this, res, current);
1631 }
1632
1633 void player_regen(entity this)
1634 {
1635         float max_mod, regen_mod, rot_mod, limit_mod;
1636         max_mod = regen_mod = rot_mod = limit_mod = 1;
1637
1638         float regen_health = autocvar_g_balance_health_regen;
1639         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1640         float regen_health_rot = autocvar_g_balance_health_rot;
1641         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1642         float regen_health_stable = autocvar_g_balance_health_regenstable;
1643         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1644         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1645                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1646         max_mod = M_ARGV(1, float);
1647         regen_mod = M_ARGV(2, float);
1648         rot_mod = M_ARGV(3, float);
1649         limit_mod = M_ARGV(4, float);
1650         regen_health = M_ARGV(5, float);
1651         regen_health_linear = M_ARGV(6, float);
1652         regen_health_rot = M_ARGV(7, float);
1653         regen_health_rotlinear = M_ARGV(8, float);
1654         regen_health_stable = M_ARGV(9, float);
1655         regen_health_rotstable = M_ARGV(10, float);
1656
1657         if(!mutator_returnvalue)
1658         if(!STAT(FROZEN, this))
1659         {
1660                 float maxa = autocvar_g_balance_armor_rotstable;
1661                 float mina = autocvar_g_balance_armor_regenstable;
1662
1663                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1664                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1665                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1666
1667                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1668                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1669                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1670         }
1671
1672         // if player rotted to death...  die!
1673         // check this outside above checks, as player may still be able to rot to death
1674         if(GetResource(this, RES_HEALTH) < 1)
1675         {
1676                 if(this.vehicle)
1677                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1678                 if(this.event_damage)
1679                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1680         }
1681
1682         if (!(this.items & IT_UNLIMITED_AMMO))
1683         {
1684                 float maxf = autocvar_g_balance_fuel_rotstable;
1685                 float minf = autocvar_g_balance_fuel_regenstable;
1686
1687                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1688                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1689                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1690         }
1691 }
1692
1693 bool zoomstate_set;
1694 void SetZoomState(entity this, float newzoom)
1695 {
1696         if(newzoom != CS(this).zoomstate)
1697         {
1698                 CS(this).zoomstate = newzoom;
1699                 ClientData_Touch(this);
1700         }
1701         zoomstate_set = true;
1702 }
1703
1704 void GetPressedKeys(entity this)
1705 {
1706         MUTATOR_CALLHOOK(GetPressedKeys, this);
1707         if (game_stopped)
1708         {
1709                 CS(this).pressedkeys = 0;
1710                 STAT(PRESSED_KEYS, this) = 0;
1711                 return;
1712         }
1713
1714         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1715         int keys = STAT(PRESSED_KEYS, this);
1716         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1717         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1718         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1719         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1720
1721         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1722         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1723         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1724         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1725         CS(this).pressedkeys = keys; // store for other users
1726
1727         STAT(PRESSED_KEYS, this) = keys;
1728 }
1729
1730 /*
1731 ======================
1732 spectate mode routines
1733 ======================
1734 */
1735
1736 void SpectateCopy(entity this, entity spectatee)
1737 {
1738         TC(Client, this); TC(Client, spectatee);
1739
1740         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1741         PS(this) = PS(spectatee);
1742         this.armortype = spectatee.armortype;
1743         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1744         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1745         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1746         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1747         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1748         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1749         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1750         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1751         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1752         CS(this).impulse = 0;
1753         this.disableclientprediction = 1; // no need to run prediction on a spectator
1754         this.items = spectatee.items;
1755         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1756         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1757         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1758         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1759         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1760         this.punchangle = spectatee.punchangle;
1761         this.view_ofs = spectatee.view_ofs;
1762         this.velocity = spectatee.velocity;
1763         this.dmg_take = spectatee.dmg_take;
1764         this.dmg_save = spectatee.dmg_save;
1765         this.dmg_inflictor = spectatee.dmg_inflictor;
1766         this.v_angle = spectatee.v_angle;
1767         this.angles = spectatee.v_angle;
1768         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1769         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1770         this.viewloc = spectatee.viewloc;
1771         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1772                 this.fixangle = true;
1773         setorigin(this, spectatee.origin);
1774         setsize(this, spectatee.mins, spectatee.maxs);
1775         SetZoomState(this, CS(spectatee).zoomstate);
1776
1777     anticheat_spectatecopy(this, spectatee);
1778         STAT(HUD, this) = STAT(HUD, spectatee);
1779         if(spectatee.vehicle)
1780     {
1781         this.angles = spectatee.v_angle;
1782
1783         //this.fixangle = false;
1784         //this.velocity = spectatee.vehicle.velocity;
1785         this.vehicle_health = spectatee.vehicle_health;
1786         this.vehicle_shield = spectatee.vehicle_shield;
1787         this.vehicle_energy = spectatee.vehicle_energy;
1788         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1789         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1790         this.vehicle_reload1 = spectatee.vehicle_reload1;
1791         this.vehicle_reload2 = spectatee.vehicle_reload2;
1792
1793         //msg_entity = this;
1794
1795        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1796             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1797            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1798            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1799
1800         //WriteByte (MSG_ONE, SVC_SETVIEW);
1801         //    WriteEntity(MSG_ONE, this);
1802         //makevectors(spectatee.v_angle);
1803         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1804     }
1805 }
1806
1807 bool SpectateUpdate(entity this)
1808 {
1809         if(!this.enemy)
1810                 return false;
1811
1812         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1813         {
1814                 SetSpectatee(this, NULL);
1815                 return false;
1816         }
1817
1818         SpectateCopy(this, this.enemy);
1819
1820         return true;
1821 }
1822
1823 bool SpectateSet(entity this)
1824 {
1825         if(!IS_PLAYER(this.enemy))
1826                 return false;
1827
1828         ClientData_Touch(this.enemy);
1829
1830         msg_entity = this;
1831         WriteByte(MSG_ONE, SVC_SETVIEW);
1832         WriteEntity(MSG_ONE, this.enemy);
1833         set_movetype(this, MOVETYPE_NONE);
1834         accuracy_resend(this);
1835
1836         if(!SpectateUpdate(this))
1837                 PutObserverInServer(this);
1838
1839         return true;
1840 }
1841
1842 void SetSpectatee_status(entity this, int spectatee_num)
1843 {
1844         int oldspectatee_status = CS(this).spectatee_status;
1845         CS(this).spectatee_status = spectatee_num;
1846
1847         if (CS(this).spectatee_status != oldspectatee_status)
1848         {
1849                 if (STAT(PRESSED_KEYS, this))
1850                 {
1851                         CS(this).pressedkeys = 0;
1852                         STAT(PRESSED_KEYS, this) = 0;
1853                 }
1854                 ClientData_Touch(this);
1855                 if (g_race || g_cts) race_InitSpectator();
1856         }
1857 }
1858
1859 void SetSpectatee(entity this, entity spectatee)
1860 {
1861         if(IS_BOT_CLIENT(this))
1862                 return; // bots abuse .enemy, this code is useless to them
1863
1864         entity old_spectatee = this.enemy;
1865
1866         this.enemy = spectatee;
1867
1868         // WEAPONTODO
1869         // these are required to fix the spectator bug with arc
1870         if(old_spectatee)
1871         {
1872                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1873                 {
1874                         .entity weaponentity = weaponentities[slot];
1875                         if(old_spectatee.(weaponentity).arc_beam)
1876                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1877                 }
1878         }
1879         if(this.enemy)
1880         {
1881                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1882                 {
1883                         .entity weaponentity = weaponentities[slot];
1884                         if(this.enemy.(weaponentity).arc_beam)
1885                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1886                 }
1887         }
1888
1889         if (this.enemy)
1890                 SetSpectatee_status(this, etof(this.enemy));
1891
1892         // needed to update spectator list
1893         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1894 }
1895
1896 bool Spectate(entity this, entity pl)
1897 {
1898         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1899                 return false;
1900         pl = M_ARGV(1, entity);
1901
1902         SetSpectatee(this, pl);
1903         return SpectateSet(this);
1904 }
1905
1906 bool SpectateNext(entity this)
1907 {
1908         entity ent = find(this.enemy, classname, STR_PLAYER);
1909
1910         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1911                 ent = M_ARGV(1, entity);
1912         else if (!ent)
1913                 ent = find(ent, classname, STR_PLAYER);
1914
1915         if(ent) { SetSpectatee(this, ent); }
1916
1917         return SpectateSet(this);
1918 }
1919
1920 bool SpectatePrev(entity this)
1921 {
1922         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1923         entity ent = findchain(classname, STR_PLAYER);
1924         if (!ent) // no player
1925                 return false;
1926
1927         entity first = ent;
1928         // skip players until current spectated player
1929         if(this.enemy)
1930         while(ent && ent != this.enemy)
1931                 ent = ent.chain;
1932
1933         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1934         {
1935                 case MUT_SPECPREV_FOUND:
1936                         ent = M_ARGV(1, entity);
1937                         break;
1938                 case MUT_SPECPREV_RETURN:
1939                         return true;
1940                 case MUT_SPECPREV_CONTINUE:
1941                 default:
1942                 {
1943                         if(ent.chain)
1944                                 ent = ent.chain;
1945                         else
1946                                 ent = first;
1947                         break;
1948                 }
1949         }
1950
1951         SetSpectatee(this, ent);
1952         return SpectateSet(this);
1953 }
1954
1955 /*
1956 =============
1957 ShowRespawnCountdown()
1958
1959 Update a respawn countdown display.
1960 =============
1961 */
1962 void ShowRespawnCountdown(entity this)
1963 {
1964         float number;
1965         if(!IS_DEAD(this)) // just respawned?
1966                 return;
1967         else
1968         {
1969                 number = ceil(this.respawn_time - time);
1970                 if(number <= 0)
1971                         return;
1972                 if(number <= this.respawn_countdown)
1973                 {
1974                         this.respawn_countdown = number - 1;
1975                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1976                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1977                 }
1978         }
1979 }
1980
1981 .bool team_selected;
1982 bool ShowTeamSelection(entity this)
1983 {
1984         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1985                 return false;
1986         stuffcmd(this, "menu_showteamselect\n");
1987         return true;
1988 }
1989 void Join(entity this)
1990 {
1991         TRANSMUTE(Player, this);
1992
1993         if(!this.team_selected)
1994         if(autocvar_g_campaign || autocvar_g_balance_teams)
1995                 TeamBalance_JoinBestTeam(this);
1996
1997         if(autocvar_g_campaign)
1998                 campaign_bots_may_start = true;
1999
2000         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2001
2002         PutClientInServer(this);
2003
2004         if(IS_PLAYER(this))
2005         if(teamplay && this.team != -1)
2006         {
2007         }
2008         else
2009                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2010         this.team_selected = false;
2011 }
2012
2013 int GetPlayerLimit()
2014 {
2015         if(g_duel)
2016                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2017         int player_limit = autocvar_g_maxplayers;
2018         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2019         player_limit = M_ARGV(0, int);
2020         return player_limit;
2021 }
2022
2023 /**
2024  * Determines whether the player is allowed to join. This depends on cvar
2025  * g_maxplayers, if it isn't used this function always return true, otherwise
2026  * it checks whether the number of currently playing players exceeds g_maxplayers.
2027  * @return int number of free slots for players, 0 if none
2028  */
2029 int nJoinAllowed(entity this, entity ignore)
2030 {
2031         if(!ignore)
2032         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2033         // so report 0 free slots if restricted
2034         {
2035                 if(autocvar_g_forced_team_otherwise == "spectate")
2036                         return 0;
2037                 if(autocvar_g_forced_team_otherwise == "spectator")
2038                         return 0;
2039         }
2040
2041         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2042                 return 0; // forced spectators can never join
2043
2044         // TODO simplify this
2045         int totalClients = 0;
2046         int currentlyPlaying = 0;
2047         FOREACH_CLIENT(true, {
2048                 if(it != ignore)
2049                         ++totalClients;
2050                 if(IS_REAL_CLIENT(it))
2051                 if(IS_PLAYER(it) || it.caplayer)
2052                         ++currentlyPlaying;
2053         });
2054
2055         int player_limit = GetPlayerLimit();
2056
2057         int free_slots = 0;
2058         if (!player_limit)
2059                 free_slots = maxclients - totalClients;
2060         else if(player_limit > 0 && currentlyPlaying < player_limit)
2061                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2062
2063         static float msg_time = 0;
2064         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2065         {
2066                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2067                 msg_time = time + 0.5;
2068         }
2069
2070         return free_slots;
2071 }
2072
2073 void PrintWelcomeMessage(entity this)
2074 {
2075         if(CS(this).motd_actived_time == 0)
2076         {
2077                 if (autocvar_g_campaign) {
2078                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2079                                 CS(this).motd_actived_time = time;
2080                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2081                         }
2082                 } else {
2083                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2084                                 CS(this).motd_actived_time = time;
2085                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2086                         }
2087                 }
2088         }
2089         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2090         {
2091                 if (autocvar_g_campaign) {
2092                         if (PHYS_INPUT_BUTTON_INFO(this))
2093                                 CS(this).motd_actived_time = time;
2094                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2095                                 CS(this).motd_actived_time = 0;
2096                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2097                         }
2098                 } else {
2099                         if (PHYS_INPUT_BUTTON_INFO(this))
2100                                 CS(this).motd_actived_time = time;
2101                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2102                                 CS(this).motd_actived_time = 0;
2103                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2104                         }
2105                 }
2106         }
2107         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2108         {
2109                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2110                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2111                 else if (CS(this).motd_actived_time == -2)
2112                 {
2113                         // instantly hide MOTD
2114                         CS(this).motd_actived_time = 0;
2115                         if (autocvar_g_campaign)
2116                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2117                         else
2118                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2119                 }
2120                 else if (IS_PLAYER(this) || IS_SPEC(this))
2121                 {
2122                         // FIXME occasionally for some reason MOTD never goes away
2123                         // delay MOTD removal a little bit in the hope it fixes this bug
2124                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2125                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2126                         else //if (CS(this).motd_actived_time < -2)
2127                                 CS(this).motd_actived_time++;
2128                 }
2129         }
2130 }
2131
2132 bool joinAllowed(entity this)
2133 {
2134         if (CS(this).version_mismatch) return false;
2135         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2136         if (!nJoinAllowed(this, this)) return false;
2137         if (teamplay && lockteams) return false;
2138         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2139         if (ShowTeamSelection(this)) return false;
2140         return true;
2141 }
2142
2143 .string shootfromfixedorigin;
2144 .bool dualwielding_prev;
2145 bool PlayerThink(entity this)
2146 {
2147         if (game_stopped || intermission_running) {
2148                 this.modelflags &= ~MF_ROCKET;
2149                 if(intermission_running)
2150                         IntermissionThink(this);
2151                 return false;
2152         }
2153
2154         if (timeout_status == TIMEOUT_ACTIVE) {
2155                 // don't allow the player to turn around while game is paused
2156                 // FIXME turn this into CSQC stuff
2157                 this.v_angle = this.lastV_angle;
2158                 this.angles = this.lastV_angle;
2159                 this.fixangle = true;
2160         }
2161
2162         if (frametime) player_powerups(this);
2163
2164         if (IS_DEAD(this)) {
2165                 if (this.personal && g_race_qualifying) {
2166                         if (time > this.respawn_time) {
2167                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2168                                 respawn(this);
2169                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2170                         }
2171                 } else {
2172                         if (frametime) player_anim(this);
2173
2174                         if (this.respawn_flags & RESPAWN_DENY)
2175                         {
2176                                 STAT(RESPAWN_TIME, this) = 0;
2177                                 return false;
2178                         }
2179
2180                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2181
2182                         switch(this.deadflag)
2183                         {
2184                                 case DEAD_DYING:
2185                                 {
2186                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2187                                                 this.deadflag = DEAD_RESPAWNING;
2188                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2189                                                 this.deadflag = DEAD_DEAD;
2190                                         break;
2191                                 }
2192                                 case DEAD_DEAD:
2193                                 {
2194                                         if (button_pressed)
2195                                                 this.deadflag = DEAD_RESPAWNABLE;
2196                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2197                                                 this.deadflag = DEAD_RESPAWNING;
2198                                         break;
2199                                 }
2200                                 case DEAD_RESPAWNABLE:
2201                                 {
2202                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2203                                                 this.deadflag = DEAD_RESPAWNING;
2204                                         break;
2205                                 }
2206                                 case DEAD_RESPAWNING:
2207                                 {
2208                                         if (time > this.respawn_time)
2209                                         {
2210                                                 this.respawn_time = time + 1; // only retry once a second
2211                                                 this.respawn_time_max = this.respawn_time;
2212                                                 respawn(this);
2213                                         }
2214                                         break;
2215                                 }
2216                         }
2217
2218                         ShowRespawnCountdown(this);
2219
2220                         if (this.respawn_flags & RESPAWN_SILENT)
2221                                 STAT(RESPAWN_TIME, this) = 0;
2222                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2223                         {
2224                                 if (time < this.respawn_time)
2225                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2226                                 else if (this.deadflag != DEAD_RESPAWNING)
2227                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2228                         }
2229                         else
2230                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2231                 }
2232
2233                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2234                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2235                         STAT(RESPAWN_TIME, this) *= -1;
2236
2237                 return false;
2238         }
2239
2240         FixPlayermodel(this);
2241
2242         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2243                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2244                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2245         }
2246
2247         // reset gun alignment when dual wielding status changes
2248         // to ensure guns are always aligned right and left
2249         bool dualwielding = W_DualWielding(this);
2250         if(this.dualwielding_prev != dualwielding)
2251         {
2252                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2253                 this.dualwielding_prev = dualwielding;
2254         }
2255
2256         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2257         //if(frametime)
2258         {
2259                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2260                 {
2261                         .entity weaponentity = weaponentities[slot];
2262                         if(WEP_CVAR(vortex, charge_always))
2263                                 W_Vortex_Charge(this, weaponentity, frametime);
2264                         W_WeaponFrame(this, weaponentity);
2265                 }
2266         }
2267
2268         if (frametime)
2269         {
2270                 // WEAPONTODO: Add a weapon request for this
2271                 // rot vortex charge to the charge limit
2272                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2273                 {
2274                         .entity weaponentity = weaponentities[slot];
2275                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2276                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2277                 }
2278
2279                 player_regen(this);
2280                 player_anim(this);
2281                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2282         }
2283
2284         monsters_setstatus(this);
2285
2286         return true;
2287 }
2288
2289 .bool would_spectate;
2290 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2291 void ObserverOrSpectatorThink(entity this)
2292 {
2293         bool is_spec = IS_SPEC(this);
2294         if ( CS(this).impulse )
2295         {
2296                 int r = MinigameImpulse(this, CS(this).impulse);
2297                 if (!is_spec || r)
2298                         CS(this).impulse = 0;
2299
2300                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2301                 {
2302                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2303                         CS(this).impulse = 0;
2304                         return;
2305                 }
2306         }
2307
2308         if (this.flags & FL_JUMPRELEASED) {
2309                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2310                         this.flags &= ~FL_JUMPRELEASED;
2311                         this.flags |= FL_SPAWNING;
2312                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2313                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2314                         this.flags &= ~FL_JUMPRELEASED;
2315                         if(SpectateNext(this)) {
2316                                 TRANSMUTE(Spectator, this);
2317                         } else if (is_spec) {
2318                                 TRANSMUTE(Observer, this);
2319                                 PutClientInServer(this);
2320                         }
2321                         else
2322                                 this.would_spectate = false; // unable to spectate anyone
2323                         if (is_spec)
2324                                 CS(this).impulse = 0;
2325                 } else if (is_spec) {
2326                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2327                                 this.flags &= ~FL_JUMPRELEASED;
2328                                 if(SpectatePrev(this)) {
2329                                         TRANSMUTE(Spectator, this);
2330                                 } else {
2331                                         TRANSMUTE(Observer, this);
2332                                         PutClientInServer(this);
2333                                 }
2334                                 CS(this).impulse = 0;
2335                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2336                                 this.would_spectate = false;
2337                                 this.flags &= ~FL_JUMPRELEASED;
2338                                 TRANSMUTE(Observer, this);
2339                                 PutClientInServer(this);
2340                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2341                                 PutObserverInServer(this);
2342                                 this.would_spectate = true;
2343                         }
2344                 }
2345                 else {
2346                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2347                         if (PHYS_INPUT_BUTTON_USE(this))
2348                                 wouldclip = !wouldclip;
2349                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2350                         set_movetype(this, preferred_movetype);
2351                 }
2352         } else { // jump pressed
2353                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2354                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2355                         this.flags |= FL_JUMPRELEASED;
2356                         if(this.flags & FL_SPAWNING)
2357                         {
2358                                 this.flags &= ~FL_SPAWNING;
2359                                 if(joinAllowed(this))
2360                                         Join(this);
2361                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2362                                         CS(this).autojoin_checked = -1;
2363                                 return;
2364                         }
2365                 }
2366                 if(is_spec && !SpectateUpdate(this))
2367                         PutObserverInServer(this);
2368         }
2369         if (is_spec)
2370                 this.flags |= FL_CLIENT | FL_NOTARGET;
2371 }
2372
2373 void PlayerUseKey(entity this)
2374 {
2375         if (!IS_PLAYER(this))
2376                 return;
2377
2378         if(this.vehicle)
2379         {
2380                 if(!game_stopped)
2381                 {
2382                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2383                         return;
2384                 }
2385         }
2386         else if(autocvar_g_vehicles_enter)
2387         {
2388                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2389                 {
2390                         entity head, closest_target = NULL;
2391                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2392
2393                         while(head) // find the closest acceptable target to enter
2394                         {
2395                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2396                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2397                                 {
2398                                         if(closest_target)
2399                                         {
2400                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2401                                                 { closest_target = head; }
2402                                         }
2403                                         else { closest_target = head; }
2404                                 }
2405
2406                                 head = head.chain;
2407                         }
2408
2409                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2410                 }
2411         }
2412
2413         // a use key was pressed; call handlers
2414         MUTATOR_CALLHOOK(PlayerUseKey, this);
2415 }
2416
2417
2418 /*
2419 =============
2420 PlayerPreThink
2421
2422 Called every frame for each client before the physics are run
2423 =============
2424 */
2425 .float last_vehiclecheck;
2426 void PlayerPreThink (entity this)
2427 {
2428         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2429         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2430
2431         WarpZone_PlayerPhysics_FixVAngle(this);
2432
2433         if (frametime) {
2434                 // physics frames: update anticheat stuff
2435                 anticheat_prethink(this);
2436
2437                 // WORKAROUND: only use dropclient in server frames (frametime set).
2438                 // Never use it in cl_movement frames (frametime zero).
2439                 if (blockSpectators && IS_REAL_CLIENT(this)
2440                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !this.caplayer
2441                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2442                 {
2443                         if (dropclient_schedule(this))
2444                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2445                 }
2446         }
2447
2448         zoomstate_set = false;
2449
2450         // Check for nameless players
2451         if (this.netname == "" || this.netname != CS(this).netname_previous)
2452         {
2453                 bool assume_unchanged = (CS(this).netname_previous == "");
2454                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2455                 {
2456                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2457                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2458                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2459                         assume_unchanged = false;
2460                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2461                 }
2462                 if (isInvisibleString(this.netname))
2463                 {
2464                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2465                         sprint(this, "Warning: invisible names are not allowed.\n");
2466                         assume_unchanged = false;
2467                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2468                 }
2469                 if (!assume_unchanged && autocvar_sv_eventlog)
2470                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2471                 strcpy(CS(this).netname_previous, this.netname);
2472         }
2473
2474         // version nagging
2475         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2476         CS(this).version_nagtime = 0;
2477         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2478             // git client
2479         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2480             // git server
2481             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2482         } else {
2483             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2484             if (r < 0) { // old client
2485                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2486             } else if (r > 0) { // old server
2487                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2488             }
2489         }
2490     }
2491
2492         // GOD MODE info
2493         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2494         {
2495                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2496                 this.max_armorvalue = 0;
2497         }
2498
2499         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2500         {
2501                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2502                 {
2503                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2504                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2505                         if (this.iceblock)
2506                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2507
2508                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2509                                 Unfreeze(this, false);
2510                 }
2511                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2512                 {
2513                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2514                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2515
2516                         if (GetResource(this, RES_HEALTH) < 1)
2517                         {
2518                                 if (this.vehicle)
2519                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2520                                 if(this.event_damage)
2521                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2522                         }
2523                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2524                                 Unfreeze(this, false);
2525                 }
2526         }
2527
2528         MUTATOR_CALLHOOK(PlayerPreThink, this);
2529
2530         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2531         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2532         {
2533                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2534                 {
2535                         if(!it.owner)
2536                         {
2537                                 if(!it.team || SAME_TEAM(this, it))
2538                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2539                                 else if(autocvar_g_vehicles_steal)
2540                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2541                         }
2542                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2543                         {
2544                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2545                         }
2546                 });
2547
2548                 this.last_vehiclecheck = time + 1;
2549         }
2550
2551         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2552         {
2553                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2554                         PlayerUseKey(this);
2555                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2556         }
2557
2558         if (IS_REAL_CLIENT(this))
2559                 PrintWelcomeMessage(this);
2560
2561         if (IS_PLAYER(this)) {
2562                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2563                         error("Client can't be spawned as player on connection!");
2564                 if(!PlayerThink(this))
2565                         return;
2566         }
2567         else if (game_stopped || intermission_running) {
2568                 if(intermission_running)
2569                         IntermissionThink(this);
2570                 return;
2571         }
2572         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2573         {
2574                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2575                 CS(this).autojoin_checked = 1;
2576                 // don't do this in ClientConnect
2577                 // many things can go wrong if a client is spawned as player on connection
2578                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2579                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2580                                 && (!teamplay || autocvar_g_balance_teams)))
2581                 {
2582                         campaign_bots_may_start = true;
2583                         if(joinAllowed(this))
2584                                 Join(this);
2585                         return;
2586                 }
2587         }
2588         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2589                 ObserverOrSpectatorThink(this);
2590         }
2591
2592         // WEAPONTODO: Add weapon request for this
2593         if (!zoomstate_set) {
2594                 bool wep_zoomed = false;
2595                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2596                 {
2597                         .entity weaponentity = weaponentities[slot];
2598                         Weapon thiswep = this.(weaponentity).m_weapon;
2599                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2600                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2601                 }
2602                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2603         }
2604
2605         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2606         {
2607                 CS(this).teamkill_soundtime = 0;
2608
2609                 entity e = CS(this).teamkill_soundsource;
2610                 entity oldpusher = e.pusher;
2611                 e.pusher = this;
2612                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2613                 e.pusher = oldpusher;
2614         }
2615
2616         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2617                 CS(this).taunt_soundtime = 0;
2618                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2619         }
2620
2621         target_voicescript_next(this);
2622 }
2623
2624 void DrownPlayer(entity this)
2625 {
2626         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2627                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2628         {
2629                 STAT(AIR_FINISHED, this) = 0;
2630                 return;
2631         }
2632
2633         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2634         {
2635                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2636                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2637                 STAT(AIR_FINISHED, this) = 0;
2638         }
2639         else
2640         {
2641                 if (!STAT(AIR_FINISHED, this))
2642                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2643                 if (STAT(AIR_FINISHED, this) < time)
2644                 {       // drown!
2645                         if (this.pain_finished < time)
2646                         {
2647                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2648                                 this.pain_finished = time + 0.5;
2649                         }
2650                 }
2651         }
2652 }
2653
2654 .bool move_qcphysics;
2655
2656 void Player_Physics(entity this)
2657 {
2658         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2659
2660         if(!this.move_qcphysics)
2661                 return;
2662
2663         if(!frametime && !CS(this).pm_frametime)
2664                 return;
2665
2666         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2667
2668         CS(this).pm_frametime = 0;
2669 }
2670
2671 /*
2672 =============
2673 PlayerPostThink
2674
2675 Called every frame for each client after the physics are run
2676 =============
2677 */
2678 void PlayerPostThink (entity this)
2679 {
2680         Player_Physics(this);
2681
2682         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2683         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2684         if (IS_REAL_CLIENT(this))
2685         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2686         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2687         {
2688                 int totalClients = 0;
2689                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2690                 {
2691                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2692                         {
2693                                 ++totalClients;
2694                         });
2695                 }
2696
2697                 if (autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2698                 { /* do nothing */ }
2699                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2700                 {
2701                         if (CS(this).idlekick_lasttimeleft)
2702                         {
2703                                 CS(this).idlekick_lasttimeleft = 0;
2704                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2705                         }
2706                 }
2707                 else
2708                 {
2709                         float maxidle_time = autocvar_sv_maxidle;
2710                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2711                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2712                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2713                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2714                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2715                         {
2716                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2717                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2718                                 else
2719                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2720                         }
2721                         if (timeleft <= 0) {
2722                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2723                                 {
2724                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2725                                         if (this.caplayer)
2726                                                 this.caplayer = 0;
2727                                         this.lms_spectate_warning = 2; // TODO: mutator hook for players forcibly moved to spectator?
2728                                         PutObserverInServer(this);
2729                                 }
2730                                 else
2731                                 {
2732                                         if (dropclient_schedule(this))
2733                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2734                                 }
2735                                 return;
2736                         }
2737                         else if (timeleft <= countdown_time) {
2738                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2739                                         play2(this, SND(TALK2));
2740                                 CS(this).idlekick_lasttimeleft = timeleft;
2741                         }
2742                 }
2743         }
2744
2745         CheatFrame(this);
2746
2747         if (game_stopped)
2748         {
2749                 this.solid = SOLID_NOT;
2750                 this.takedamage = DAMAGE_NO;
2751                 set_movetype(this, MOVETYPE_NONE);
2752                 CS(this).teamkill_complain = 0;
2753                 CS(this).teamkill_soundtime = 0;
2754                 CS(this).teamkill_soundsource = NULL;
2755         }
2756
2757         if (IS_PLAYER(this)) {
2758                 if(this.death_time == time && IS_DEAD(this))
2759                 {
2760                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2761                         // once all the damage events of this frame have been processed with normal size
2762                         this.maxs.z = 5;
2763                         setsize(this, this.mins, this.maxs);
2764                 }
2765                 DrownPlayer(this);
2766                 UpdateChatBubble(this);
2767                 if (CS(this).impulse) ImpulseCommands(this);
2768                 GetPressedKeys(this);
2769                 if (game_stopped)
2770                 {
2771                         CSQCMODEL_AUTOUPDATE(this);
2772                         return;
2773                 }
2774         }
2775         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2776         {
2777                 CS(this).pressedkeys = 0;
2778                 STAT(PRESSED_KEYS, this) = 0;
2779         }
2780
2781         if (this.waypointsprite_attachedforcarrier) {
2782                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2783                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2784         }
2785
2786         CSQCMODEL_AUTOUPDATE(this);
2787 }
2788
2789 // hack to copy the button fields from the client entity to the Client State
2790 void PM_UpdateButtons(entity this, entity store)
2791 {
2792         if(this.impulse)
2793                 store.impulse = this.impulse;
2794         this.impulse = 0;
2795
2796         bool typing = this.buttonchat || this.button12;
2797
2798         store.button0 = (typing) ? 0 : this.button0;
2799         //button1?!
2800         store.button2 = (typing) ? 0 : this.button2;
2801         store.button3 = (typing) ? 0 : this.button3;
2802         store.button4 = this.button4;
2803         store.button5 = (typing) ? 0 : this.button5;
2804         store.button6 = this.button6;
2805         store.button7 = this.button7;
2806         store.button8 = this.button8;
2807         store.button9 = this.button9;
2808         store.button10 = this.button10;
2809         store.button11 = this.button11;
2810         store.button12 = this.button12;
2811         store.button13 = this.button13;
2812         store.button14 = this.button14;
2813         store.button15 = this.button15;
2814         store.button16 = this.button16;
2815         store.buttonuse = this.buttonuse;
2816         store.buttonchat = this.buttonchat;
2817
2818         store.cursor_active = this.cursor_active;
2819         store.cursor_screen = this.cursor_screen;
2820         store.cursor_trace_start = this.cursor_trace_start;
2821         store.cursor_trace_endpos = this.cursor_trace_endpos;
2822         store.cursor_trace_ent = this.cursor_trace_ent;
2823
2824         store.ping = this.ping;
2825         store.ping_packetloss = this.ping_packetloss;
2826         store.ping_movementloss = this.ping_movementloss;
2827
2828         store.v_angle = this.v_angle;
2829         store.movement = this.movement;
2830 }
2831
2832 NET_HANDLE(fpsreport, bool)
2833 {
2834         int fps = ReadShort();
2835         PlayerScore_Set(sender, SP_FPS, fps);
2836         return true;
2837 }